turn NIX into a mutator; fix keyhunt
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         msg_entity = e;
17         WriteByte(MSG_ONE, SVC_TEMPENTITY);
18         WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
19         WriteString(MSG_ONE, snd);
20 }
21
22 float ClientData_Send(entity to, float sf)
23 {
24         if(to != self.owner)
25         {
26                 error("wtf");
27                 return FALSE;
28         }
29
30         entity e;
31
32         e = to;
33         if(to.classname == "spectator")
34                 e = to.enemy;
35
36         sf = 0;
37
38         if(e.race_completed)
39                 sf |= 1; // forced scoreboard
40         if(to.spectatee_status)
41                 sf |= 2; // spectator ent number follows
42         if(e.zoomstate)
43                 sf |= 4; // zoomed
44         if(e.porto_v_angle_held)
45                 sf |= 8; // angles held
46
47         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
48         WriteByte(MSG_ENTITY, sf);
49
50         if(sf & 2)
51                 WriteByte(MSG_ENTITY, to.spectatee_status);
52
53         if(sf & 8)
54         {
55                 WriteAngle(MSG_ENTITY, e.v_angle_x);
56                 WriteAngle(MSG_ENTITY, e.v_angle_y);
57         }
58
59         return TRUE;
60 }
61
62 void ClientData_Attach()
63 {
64         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
65         self.clientdata.drawonlytoclient = self;
66         self.clientdata.owner = self;
67 }
68
69 void ClientData_Detach()
70 {
71         remove(self.clientdata);
72         self.clientdata = world;
73 }
74
75 void ClientData_Touch(entity e)
76 {
77         e.clientdata.SendFlags = 1;
78
79         // make it spectatable
80         entity e2;
81         FOR_EACH_REALCLIENT(e2)
82         {
83                 if(e2 != e)
84                         if(e2.classname == "spectator")
85                                 if(e2.enemy == e)
86                                         e2.clientdata.SendFlags = 1;
87         }
88 }
89
90
91 .vector spawnpoint_score;
92 .string netname_previous;
93
94 void spawnfunc_info_player_survivor (void)
95 {
96         spawnfunc_info_player_deathmatch();
97 }
98
99 void spawnfunc_info_player_start (void)
100 {
101         spawnfunc_info_player_deathmatch();
102 }
103
104 void spawnfunc_info_player_deathmatch (void)
105 {
106         self.classname = "info_player_deathmatch";
107         relocate_spawnpoint();
108 }
109
110 void spawnpoint_use()
111 {
112         if(teams_matter)
113         if(have_team_spawns > 0)
114         {
115                 self.team = activator.team;
116                 some_spawn_has_been_used = 1;
117         }
118 };
119
120 // Returns:
121 //   _x: prio (-1 if unusable)
122 //   _y: weight
123 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
124 {
125         float shortest, thisdist;
126         float prio;
127         entity player;
128
129         prio = 0;
130
131         // filter out spots for the wrong team
132         if(teamcheck)
133         if(spot.team != teamcheck)
134                 return '-1 0 0';
135
136         if(race_spawns)
137                 if(spot.target == "")
138                         return '-1 0 0';
139
140         if(clienttype(self) == CLIENTTYPE_REAL)
141         {
142                 if(spot.restriction == 1)
143                         return '-1 0 0';
144         }
145         else
146         {
147                 if(spot.restriction == 2)
148                         return '-1 0 0';
149         }
150
151         // filter out spots for assault
152         if(spot.target != "") {
153                 local entity ent;
154                 float good, found;
155                 ent = find(world, targetname, spot.target);
156
157                 while(ent) {
158                         if(ent.classname == "target_objective")
159                         {
160                                 found = 1;
161                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
162                                         return '-1 0 0';
163                                 good = 1;
164                         }
165                         else if(ent.classname == "trigger_race_checkpoint")
166                         {
167                                 found = 1;
168                                 if(!anypoint) // spectators may spawn everywhere
169
170                                 {
171                                         if(g_race_qualifying)
172                                         {
173                                                 // spawn at first
174                                                 if(ent.race_checkpoint != 0)
175                                                         return '-1 0 0';
176                                                 if(spot.race_place != race_lowest_place_spawn)
177                                                         return '-1 0 0';
178                                         }
179                                         else
180                                         {
181                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
182                                                         return '-1 0 0';
183                                                 // try reusing the previous spawn
184                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
185                                                         prio += 1;
186                                                 if(ent.race_checkpoint == 0)
187                                                 {
188                                                         float pl;
189                                                         pl = self.race_place;
190                                                         if(pl > race_highest_place_spawn)
191                                                                 pl = 0;
192                                                         if(pl == 0 && !self.race_started)
193                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
194                                                         if(spot.race_place != pl)
195                                                                 return '-1 0 0';
196                                                 }
197                                         }
198                                 }
199                                 good = 1;
200                         }
201                         ent = find(ent, targetname, spot.target);
202                 }
203
204                 if(found && !good)
205                         return '-1 0 0';
206         }
207
208         player = playerlist;
209         shortest = vlen(world.maxs - world.mins);
210         for(player = playerlist; player; player = player.chain)
211                 if (player != self)
212                 {
213                         thisdist = vlen(player.origin - spot.origin);
214                         if (thisdist < shortest)
215                                 shortest = thisdist;
216                 }
217         return prio * '1 0 0' + shortest * '0 1 0';
218 }
219
220 float spawn_allbad;
221 float spawn_allgood;
222 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
223 {
224         local entity spot, spotlist, spotlistend;
225         spawn_allgood = TRUE;
226         spawn_allbad = TRUE;
227
228         spotlist = world;
229         spotlistend = world;
230
231         for(spot = firstspot; spot; spot = spot.chain)
232         {
233                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
234
235                 if(cvar("spawn_debugview"))
236                 {
237                         setmodel(spot, "models/runematch/rune.mdl");
238                         if(spot.spawnpoint_score_y < mindist)
239                         {
240                                 spot.colormod = '1 0 0';
241                                 spot.scale = 1;
242                         }
243                         else
244                         {
245                                 spot.colormod = '0 1 0';
246                                 spot.scale = spot.spawnpoint_score_y / mindist;
247                         }
248                 }
249
250                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
251                 {
252                         if(spot.spawnpoint_score_y < mindist)
253                         {
254                                 // too short distance
255                                 spawn_allgood = FALSE;
256                         }
257                         else
258                         {
259                                 // perfect
260                                 spawn_allbad = FALSE;
261
262                                 if(spotlistend)
263                                         spotlistend.chain = spot;
264                                 spotlistend = spot;
265                                 if(!spotlist)
266                                         spotlist = spot;
267
268                                 /*
269                                 if(teamcheck)
270                                 if(spot.team != teamcheck)
271                                         error("invalid spawn added");
272
273                                 print("added ", etos(spot), "\n");
274                                 */
275                         }
276                 }
277         }
278         if(spotlistend)
279                 spotlistend.chain = world;
280
281         /*
282                 entity e;
283                 if(teamcheck)
284                         for(e = spotlist; e; e = e.chain)
285                         {
286                                 print("seen ", etos(e), "\n");
287                                 if(e.team != teamcheck)
288                                         error("invalid spawn found");
289                         }
290         */
291
292         return spotlist;
293 }
294
295 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
296 {
297         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
298         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
299         local entity spot;
300
301         RandomSelection_Init();
302         for(spot = firstspot; spot; spot = spot.chain)
303                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
304
305         return RandomSelection_chosen_ent;
306 }
307
308 /*
309 =============
310 SelectSpawnPoint
311
312 Finds a point to respawn
313 =============
314 */
315 entity SelectSpawnPoint (float anypoint)
316 {
317         local float teamcheck;
318         local entity firstspot_new;
319         local entity spot, firstspot, playerlist;
320
321         spot = find (world, classname, "testplayerstart");
322         if (spot)
323                 return spot;
324
325         teamcheck = 0;
326
327         if(!anypoint && have_team_spawns > 0)
328                 teamcheck = self.team;
329
330         // get the list of players
331         playerlist = findchain(classname, "player");
332         // get the entire list of spots
333         firstspot = findchain(classname, "info_player_deathmatch");
334         // filter out the bad ones
335         // (note this returns the original list if none survived)
336         if(anypoint)
337         {
338                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
339         }
340         else
341         {
342                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
343                 if(!firstspot_new)
344                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
345                 firstspot = firstspot_new;
346
347                 // there is 50/50 chance of choosing a random spot or the furthest spot
348                 // (this means that roughly every other spawn will be furthest, so you
349                 // usually won't get fragged at spawn twice in a row)
350                 if (arena_roundbased && !g_ca)
351                 {
352                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
353                         if(firstspot_new)
354                                 firstspot = firstspot_new;
355                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
356                 }
357                 else if (random() > cvar("g_spawn_furthest"))
358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
359                 else
360                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
361         }
362
363         if(cvar("spawn_debugview"))
364         {
365                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
366
367                 entity e;
368                 if(teamcheck)
369                         for(e = firstspot; e; e = e.chain)
370                                 if(e.team != teamcheck)
371                                         error("invalid spawn found");
372         }
373
374         if (!spot)
375         {
376                 if(cvar("spawn_debug"))
377                         GotoNextMap();
378                 else
379                 {
380                         if(some_spawn_has_been_used)
381                                 return world; // team can't spawn any more, because of actions of other team
382                         else
383                                 error("Cannot find a spawn point - please fix the map!");
384                 }
385         }
386
387         return spot;
388 }
389
390 /*
391 =============
392 CheckPlayerModel
393
394 Checks if the argument string can be a valid playermodel.
395 Returns a valid one in doubt.
396 =============
397 */
398 string FallbackPlayerModel = "models/player/marine.zym";
399 string CheckPlayerModel(string plyermodel) {
400         if(strlen(plyermodel) < 4)
401                 return FallbackPlayerModel;
402         if( substring(plyermodel,0,14) != "models/player/")
403                 return FallbackPlayerModel;
404         else if(cvar("sv_servermodelsonly"))
405         {
406                 if(substring(plyermodel,-4,4) != ".zym")
407                 if(substring(plyermodel,-4,4) != ".dpm")
408                 if(substring(plyermodel,-4,4) != ".md3")
409                 if(substring(plyermodel,-4,4) != ".psk")
410                         return FallbackPlayerModel;
411                 // forbid the LOD models
412                 if(substring(plyermodel, -9,5) == "_lod1")
413                         return FallbackPlayerModel;
414                 if(substring(plyermodel, -9,5) == "_lod2")
415                         return FallbackPlayerModel;
416                 if(plyermodel != strtolower(plyermodel))
417                         return FallbackPlayerModel;
418                 if(!fexists(plyermodel))
419                         return FallbackPlayerModel;
420         }
421         return plyermodel;
422 }
423
424 /*
425 =============
426 Client_customizeentityforclient
427
428 LOD reduction
429 =============
430 */
431 void Client_uncustomizeentityforclient()
432 {
433         if(self.modelindex == 0) // no need to uncustomize then
434                 return;
435         self.modelindex = self.modelindex_lod0;
436         self.skin = self.skinindex;
437 }
438
439 float Client_customizeentityforclient()
440 {
441         entity modelsource;
442
443         if(self.modelindex == 0)
444                 return TRUE;
445
446         // forcemodel stuff
447
448 #ifdef PROFILING
449         float t0;
450         t0 = gettime(GETTIME_HIRES); // reference
451 #endif
452
453         modelsource = self;
454
455 #ifdef ALLOW_FORCEMODELS
456         if(other.cvar_cl_forceplayermodelsfromxonotic)
457                 if not(self.modelindex_lod0_from_xonotic)
458                         modelsource = other;
459         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
460                 modelsource = other;
461 #endif
462
463         self.skin = modelsource.skinindex;
464
465 #if 0
466         if(modelsource == self)
467                 self.skin = modelsource.skinindex;
468         else
469                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
470 #endif
471
472         // self: me
473         // other: the player viewing me
474         float distance;
475         float f;
476
477         if(other.cvar_cl_playerdetailreduction <= 0)
478         {
479                 if(other.cvar_cl_playerdetailreduction <= -2)
480                         self.modelindex = modelsource.modelindex_lod2;
481                 else if(other.cvar_cl_playerdetailreduction <= -1)
482                         self.modelindex = modelsource.modelindex_lod1;
483                 else
484                         self.modelindex = modelsource.modelindex_lod0;
485         }
486         else
487         {
488                 distance = vlen(self.origin - other.origin);
489                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
490                 if(f > sv_loddistance2)
491                         self.modelindex = modelsource.modelindex_lod2;
492                 else if(f > sv_loddistance1)
493                         self.modelindex = modelsource.modelindex_lod1;
494                 else
495                         self.modelindex = modelsource.modelindex_lod0;
496         }
497
498 #ifdef PROFILING
499         float t1;
500         t1 = gettime(GETTIME_HIRES); // reference
501         client_cefc_accumulator += (t1 - t0);
502 #endif
503
504         return TRUE;
505 }
506
507 void UpdatePlayerSounds();
508 void setmodel_lod(entity e, string modelname)
509 {
510         string s;
511
512         if(sv_loddistance1)
513         {
514                 // FIXME: this only supports 3-letter extensions
515                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
516                 if(fexists(s))
517                 {
518                         setmodel(e, s); // players have high precision
519                         self.modelindex_lod1 = self.modelindex;
520                 }
521                 else
522                         self.modelindex_lod1 = -1;
523
524                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
525                 if(fexists(s))
526                 {
527                         setmodel(e, s); // players have high precision
528                         self.modelindex_lod2 = self.modelindex;
529                 }
530                 else
531                         self.modelindex_lod2 = -1;
532
533                 precache_model(modelname);
534                 setmodel(e, modelname); // players have high precision
535                 self.modelindex_lod0 = self.modelindex;
536
537                 if(self.modelindex_lod1 < 0)
538                         self.modelindex_lod1 = self.modelindex;
539
540                 if(self.modelindex_lod2 < 0)
541                         self.modelindex_lod2 = self.modelindex;
542         }
543         else
544         {
545                 precache_model(modelname);
546                 setmodel(e, modelname); // players have high precision
547                 self.modelindex_lod0 = self.modelindex;
548                         // save it for possible player model forcing
549         }
550
551         s = whichpack(self.model);
552         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
553
554         player_setupanimsformodel();
555         UpdatePlayerSounds();
556 }
557
558 /*
559 =============
560 PutObserverInServer
561
562 putting a client as observer in the server
563 =============
564 */
565 void FixPlayermodel();
566 void PutObserverInServer (void)
567 {
568         entity  spot;
569
570         race_PreSpawnObserver();
571
572         spot = SelectSpawnPoint (TRUE);
573         if(!spot)
574                 error("No spawnpoints for observers?!?\n");
575         RemoveGrapplingHook(self); // Wazat's Grappling Hook
576
577         if(clienttype(self) == CLIENTTYPE_REAL)
578         {
579                 msg_entity = self;
580                 WriteByte(MSG_ONE, SVC_SETVIEW);
581                 WriteEntity(MSG_ONE, self);
582         }
583
584         DropAllRunes(self);
585
586         Portal_ClearAll(self);
587
588         if(self.flagcarried)
589                 DropFlag(self.flagcarried, world, world);
590
591         if(self.ballcarried)
592                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
593
594         WaypointSprite_PlayerDead();
595
596         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
597                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
598
599         if(self.killcount != -666) {
600                 if(g_lms) {
601                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
602                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
603                         else
604                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
605                 } else
606                         bprint ("^4", self.netname, "^4 is spectating now\n");
607
608                 if(self.just_joined == FALSE) {
609                         LogTeamchange(self.playerid, -1, 4);
610                 } else
611                         self.just_joined = FALSE;
612         }
613
614         PlayerScore_Clear(self); // clear scores when needed
615
616         self.spectatortime = time;
617
618         self.classname = "observer";
619         self.iscreature = FALSE;
620         self.health = -666;
621         self.takedamage = DAMAGE_NO;
622         self.solid = SOLID_NOT;
623         self.movetype = MOVETYPE_NOCLIP;
624         self.flags = FL_CLIENT | FL_NOTARGET;
625         self.armorvalue = 666;
626         self.effects = 0;
627         self.armorvalue = cvar("g_balance_armor_start");
628         self.pauserotarmor_finished = 0;
629         self.pauserothealth_finished = 0;
630         self.pauseregen_finished = 0;
631         self.damageforcescale = 0;
632         self.death_time = 0;
633         self.dead_frame = 0;
634         self.alpha = 0;
635         self.scale = 0;
636         self.fade_time = 0;
637         self.pain_frame = 0;
638         self.pain_finished = 0;
639         self.strength_finished = 0;
640         self.invincible_finished = 0;
641         self.pushltime = 0;
642         self.think = SUB_Null;
643         self.nextthink = 0;
644         self.hook_time = 0;
645         self.runes = 0;
646         self.deadflag = DEAD_NO;
647         self.angles = spot.angles;
648         self.angles_z = 0;
649         self.fixangle = TRUE;
650         self.crouch = FALSE;
651
652         self.view_ofs = PL_VIEW_OFS;
653         setorigin (self, spot.origin);
654         setsize (self, '0 0 0', '0 0 0');
655         self.prevorigin = self.origin;
656         self.items = 0;
657         self.weapons = 0;
658         self.model = "";
659         FixPlayermodel();
660         self.model = "";
661         self.modelindex = 0;
662         self.weapon = 0;
663         self.weaponmodel = "";
664         self.weaponentity = world;
665         self.exteriorweaponentity = world;
666         self.killcount = -666;
667         self.velocity = '0 0 0';
668         self.avelocity = '0 0 0';
669         self.punchangle = '0 0 0';
670         self.punchvector = '0 0 0';
671         self.oldvelocity = self.velocity;
672         self.fire_endtime = -1;
673
674         if(sv_loddistance1)
675                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
676
677         if(g_arena)
678         {
679                 if(self.version_mismatch)
680                 {
681                         Spawnqueue_Unmark(self);
682                         Spawnqueue_Remove(self);
683                 }
684                 else
685                 {
686                         Spawnqueue_Insert(self);
687                 }
688         }
689         else if(g_lms)
690         {
691                 // Only if the player cannot play at all
692                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
693                         self.frags = FRAGS_SPECTATOR;
694                 else
695                         self.frags = FRAGS_LMS_LOSER;
696         }
697         else
698                 self.frags = FRAGS_SPECTATOR;
699
700         MUTATOR_CALLHOOK(MakePlayerObserver);
701 }
702
703 float RestrictSkin(float s)
704 {
705         if(!teams_matter)
706                 return s;
707         if(s == 6)
708                 return 6;
709         return mod(s, 3);
710 }
711
712 void FixPlayermodel()
713 {
714         local string defaultmodel;
715         local float defaultskin, chmdl, oldskin;
716         local vector m1, m2;
717
718         defaultmodel = "";
719
720         if(cvar("sv_defaultcharacter") == 1) {
721                 defaultskin = 0;
722
723                 if(teams_matter)
724                 {
725                         string s;
726                         s = Team_ColorNameLowerCase(self.team);
727                         if(s != "neutral")
728                         {
729                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
730                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
731                         }
732                 }
733
734                 if(defaultmodel == "")
735                 {
736                         defaultmodel = cvar_string("sv_defaultplayermodel");
737                         defaultskin = cvar("sv_defaultplayerskin");
738                 }
739         }
740
741         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
742         {
743                 if(self.model != "")
744                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
745                 self.model = ""; // force the != checks to return true
746         }
747
748         if(defaultmodel != "")
749         {
750                 if (defaultmodel != self.model)
751                 {
752                         m1 = self.mins;
753                         m2 = self.maxs;
754                         setmodel_lod (self, defaultmodel);
755                         setsize (self, m1, m2);
756                         chmdl = TRUE;
757                 }
758
759                 oldskin = self.skinindex;
760                 self.skinindex = defaultskin;
761         } else {
762                 if (self.playermodel != self.model || self.playermodel == "")
763                 {
764                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
765                         m1 = self.mins;
766                         m2 = self.maxs;
767                         setmodel_lod (self, self.playermodel);
768                         setsize (self, m1, m2);
769                         chmdl = TRUE;
770                 }
771
772                 oldskin = self.skinindex;
773                 self.skinindex = RestrictSkin(stof(self.playerskin));
774         }
775
776         if(chmdl || oldskin != self.skinindex)
777                 self.species = player_getspecies(); // model or skin has changed
778
779         if(!teams_matter)
780                 if(strlen(cvar_string("sv_defaultplayercolors")))
781                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
782                                 setcolor(self, cvar("sv_defaultplayercolors"));
783 }
784
785 void PlayerTouchExplode(entity p1, entity p2)
786 {
787         vector org;
788         org = (p1.origin + p2.origin) * 0.5;
789         org_z += (p1.mins_z + p2.mins_z) * 0.5;
790
791         te_explosion(org);
792
793         entity e;
794         e = spawn();
795         setorigin(e, org);
796         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
797         remove(e);
798 }
799
800 /*
801 =============
802 PutClientInServer
803
804 Called when a client spawns in the server
805 =============
806 */
807 //void() ctf_playerchanged;
808 void PutClientInServer (void)
809 {
810         if(clienttype(self) == CLIENTTYPE_BOT)
811         {
812                 self.classname = "player";
813         }
814         else if(clienttype(self) == CLIENTTYPE_REAL)
815         {
816                 msg_entity = self;
817                 WriteByte(MSG_ONE, SVC_SETVIEW);
818                 WriteEntity(MSG_ONE, self);
819         }
820
821         // player is dead and becomes observer
822         // FIXME fix LMS scoring for new system
823         if(g_lms)
824         {
825                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
826                         self.classname = "observer";
827         }
828
829         if(g_arena || (g_ca && !allowed_to_spawn))
830         if(!self.spawned)
831                 self.classname = "observer";
832
833         if(gameover)
834                 self.classname = "observer";
835
836         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
837                 entity spot, oldself;
838                 float j;
839
840                 if(self.team < 0)
841                         JoinBestTeam(self, FALSE, TRUE);
842
843                 race_PreSpawn();
844
845                 spot = SelectSpawnPoint (FALSE);
846                 if(!spot)
847                 {
848                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
849                         return; // spawn failed
850                 }
851
852                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
853
854                 self.classname = "player";
855                 self.wasplayer = TRUE;
856                 self.iscreature = TRUE;
857                 self.movetype = MOVETYPE_WALK;
858                 self.solid = SOLID_SLIDEBOX;
859                 if(cvar("g_playerclip_collisions"))
860                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
861                 else
862                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
863                 self.frags = FRAGS_PLAYER;
864                 if(independent_players)
865                         MAKE_INDEPENDENT_PLAYER(self);
866                 self.flags = FL_CLIENT;
867                 self.takedamage = DAMAGE_AIM;
868                 if(g_minstagib)
869                         self.effects = EF_FULLBRIGHT;
870                 else
871                         self.effects = 0;
872                 self.air_finished = time + 12;
873                 self.dmg = 2;
874
875                 if(inWarmupStage)
876                 {
877                         self.ammo_shells = warmup_start_ammo_shells;
878                         self.ammo_nails = warmup_start_ammo_nails;
879                         self.ammo_rockets = warmup_start_ammo_rockets;
880                         self.ammo_cells = warmup_start_ammo_cells;
881                         self.ammo_fuel = warmup_start_ammo_fuel;
882                         self.health = warmup_start_health;
883                         self.armorvalue = warmup_start_armorvalue;
884                         self.weapons = warmup_start_weapons;
885                 }
886                 else
887                 {
888                         self.ammo_shells = start_ammo_shells;
889                         self.ammo_nails = start_ammo_nails;
890                         self.ammo_rockets = start_ammo_rockets;
891                         self.ammo_cells = start_ammo_cells;
892                         self.ammo_fuel = start_ammo_fuel;
893                         self.health = start_health;
894                         self.armorvalue = start_armorvalue;
895                         self.weapons = start_weapons;
896                 }
897
898                 if(g_weaponarena_random)
899                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
900
901                 self.items = start_items;
902                 self.switchweapon = w_getbestweapon(self);
903                 self.cnt = self.switchweapon;
904                 self.weapon = 0;
905                 self.jump_interval = time;
906
907                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
908                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
909                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
910                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
911                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
912                 //extend the pause of rotting if client was reset at the beginning of the countdown
913                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
914                         self.spawnshieldtime += game_starttime - time;
915                         self.pauserotarmor_finished += game_starttime - time;
916                         self.pauserothealth_finished += game_starttime - time;
917                         self.pauseregen_finished += game_starttime - time;
918                 }
919                 self.damageforcescale = 2;
920                 self.death_time = 0;
921                 self.dead_frame = 0;
922                 self.alpha = 0;
923                 self.scale = 0;
924                 self.fade_time = 0;
925                 self.pain_frame = 0;
926                 self.pain_finished = 0;
927                 self.strength_finished = 0;
928                 self.invincible_finished = 0;
929                 self.pushltime = 0;
930                 // players have no think function
931                 self.think = SUB_Null;
932                 self.nextthink = 0;
933                 self.hook_time = 0;
934                 self.dmg_team = 0;
935
936                 self.metertime = 0;
937
938                 self.runes = 0;
939
940                 self.deadflag = DEAD_NO;
941
942                 self.angles = spot.angles;
943
944                 self.angles_z = 0; // never spawn tilted even if the spot says to
945                 self.fixangle = TRUE; // turn this way immediately
946                 self.velocity = '0 0 0';
947                 self.avelocity = '0 0 0';
948                 self.punchangle = '0 0 0';
949                 self.punchvector = '0 0 0';
950                 self.oldvelocity = self.velocity;
951                 self.fire_endtime = -1;
952
953                 msg_entity = self;
954                 WRITESPECTATABLE_MSG_ONE({
955                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
956                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
957                 });
958
959                 if(sv_loddistance1)
960                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
961
962                 self.model = "";
963                 FixPlayermodel();
964
965                 self.crouch = FALSE;
966                 self.view_ofs = PL_VIEW_OFS;
967                 setsize (self, PL_MIN, PL_MAX);
968                 self.spawnorigin = spot.origin;
969                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
970                 // don't reset back to last position, even if new position is stuck in solid
971                 self.oldorigin = self.origin;
972                 self.prevorigin = self.origin;
973                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
974
975                 if(g_arena)
976                 {
977                         Spawnqueue_Remove(self);
978                         Spawnqueue_Mark(self);
979                 }
980
981                 else if(g_ca)
982                         self.caplayer = 1;
983
984                 self.event_damage = PlayerDamage;
985
986                 self.bot_attack = TRUE;
987
988                 self.statdraintime = time + 5;
989                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
990
991                 if(self.killcount == -666) {
992                         PlayerScore_Clear(self);
993                         self.killcount = 0;
994                 }
995
996                 self.cnt = WEP_LASER;
997
998                 CL_SpawnWeaponentity();
999                 self.alpha = default_player_alpha;
1000                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1001                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1002
1003                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1004                 self.lms_traveled_distance = 0;
1005                 self.speedrunning = FALSE;
1006
1007                 race_PostSpawn(spot);
1008
1009                 if(cvar("spawn_debug"))
1010                 {
1011                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1012                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1013                 }
1014
1015                 //stuffcmd(self, "chase_active 0");
1016                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1017
1018                 if (cvar("g_spawnsound"))
1019                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1020
1021                 if(g_assault) {
1022                         if(self.team == assault_attacker_team)
1023                                 centerprint(self, "You are attacking!");
1024                         else
1025                                 centerprint(self, "You are defending!");
1026                 }
1027
1028                 target_voicescript_clear(self);
1029
1030                 // reset fields the weapons may use
1031                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1032                         weapon_action(j, WR_RESETPLAYER);
1033
1034                 oldself = self;
1035                 self = spot;
1036                         activator = oldself;
1037                                 SUB_UseTargets();
1038                         activator = world;
1039                 self = oldself;
1040
1041                 MUTATOR_CALLHOOK(PlayerSpawn);
1042         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1043                 PutObserverInServer ();
1044         }
1045
1046         //if(g_ctf)
1047         //      ctf_playerchanged();
1048 }
1049
1050 float ClientInit_SendEntity(entity to, float sf)
1051 {
1052         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1053         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1054         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1055         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1056         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1057
1058         if(sv_foginterval && world.fog != "")
1059                 WriteString(MSG_ENTITY, world.fog);
1060         else
1061                 WriteString(MSG_ENTITY, "");
1062         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1063         WriteByte(MSG_ENTITY, cvar("g_balance_weaponswitchdelay") * 255.0);
1064         return TRUE;
1065 }
1066
1067 void ClientInit_Spawn()
1068 {
1069         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1070 }
1071
1072 /*
1073 =============
1074 SetNewParms
1075 =============
1076 */
1077 void SetNewParms (void)
1078 {
1079         // initialize parms for a new player
1080         parm1 = -(86400 * 366);
1081 }
1082
1083 /*
1084 =============
1085 SetChangeParms
1086 =============
1087 */
1088 void SetChangeParms (void)
1089 {
1090         // save parms for level change
1091         parm1 = self.parm_idlesince - time;
1092 }
1093
1094 /*
1095 =============
1096 DecodeLevelParms
1097 =============
1098 */
1099 void DecodeLevelParms (void)
1100 {
1101         // load parms
1102         self.parm_idlesince = parm1;
1103         if(self.parm_idlesince == -(86400 * 366))
1104                 self.parm_idlesince = time;
1105
1106         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1107         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1108 }
1109
1110 /*
1111 =============
1112 ClientKill
1113
1114 Called when a client types 'kill' in the console
1115 =============
1116 */
1117
1118 void ClientKill_Now_TeamChange()
1119 {
1120         if(self.killindicator_teamchange == -1)
1121         {
1122                 self.team = -1;
1123                 JoinBestTeam( self, FALSE, FALSE );
1124         }
1125         else
1126                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1127 }
1128
1129 void ClientKill_Now()
1130 {
1131         if(self.killindicator_teamchange)
1132                 ClientKill_Now_TeamChange();
1133
1134         // in any case:
1135         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1136
1137         if(self.killindicator)
1138         {
1139                 dprint("Cleaned up after a leaked kill indicator.\n");
1140                 remove(self.killindicator);
1141                 self.killindicator = world;
1142         }
1143 }
1144 void KillIndicator_Think()
1145 {
1146         if (!self.owner.modelindex)
1147         {
1148                 self.owner.killindicator = world;
1149                 remove(self);
1150                 return;
1151         }
1152
1153         if(self.cnt <= 0)
1154         {
1155                 self = self.owner;
1156                 ClientKill_Now(); // no oldself needed
1157                 return;
1158         }
1159         else
1160         {
1161                 if(self.cnt <= 10)
1162                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1163                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1164                 {
1165                         if(self.cnt <= 10)
1166                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1167                         if(self.owner.killindicator_teamchange)
1168                         {
1169                                 if(self.owner.killindicator_teamchange == -1)
1170                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1171                                 else
1172                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1173                         }
1174                         else
1175                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1176                 }
1177                 self.nextthink = time + 1;
1178                 self.cnt -= 1;
1179         }
1180 }
1181
1182 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1183 {
1184         float killtime;
1185         entity e;
1186         killtime = cvar("g_balance_kill_delay");
1187
1188         if(g_race_qualifying)
1189                 killtime = 0;
1190
1191         self.killindicator_teamchange = targetteam;
1192
1193         if(!self.killindicator)
1194         {
1195                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1196                 {
1197                         ClientKill_Now();
1198                 }
1199                 else
1200                 {
1201                         self.killindicator = spawn();
1202                         self.killindicator.owner = self;
1203                         self.killindicator.scale = 0.5;
1204                         setattachment(self.killindicator, self, "");
1205                         setorigin(self.killindicator, '0 0 52');
1206                         self.killindicator.think = KillIndicator_Think;
1207                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1208                         self.killindicator.cnt = ceil(killtime);
1209                         self.killindicator.count = bound(0, ceil(killtime), 10);
1210                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1211
1212                         for(e = world; (e = find(e, classname, "body")) != world; )
1213                         {
1214                                 if(e.enemy != self)
1215                                         continue;
1216                                 e.killindicator = spawn();
1217                                 e.killindicator.owner = e;
1218                                 e.killindicator.scale = 0.5;
1219                                 setattachment(e.killindicator, e, "");
1220                                 setorigin(e.killindicator, '0 0 52');
1221                                 e.killindicator.think = KillIndicator_Think;
1222                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1223                                 e.killindicator.cnt = ceil(killtime);
1224                         }
1225                         self.lip = 0;
1226                 }
1227         }
1228         if(self.killindicator)
1229         {
1230                 if(targetteam)
1231                         self.killindicator.colormod = TeamColor(targetteam);
1232                 else
1233                         self.killindicator.colormod = '0 0 0';
1234         }
1235 }
1236
1237 void ClientKill (void)
1238 {
1239         ClientKill_TeamChange(0);
1240 }
1241
1242 void DoTeamChange(float destteam)
1243 {
1244         float t, c0;
1245         if(!teams_matter)
1246         {
1247                 if(destteam >= 0)
1248                         SetPlayerColors(self, destteam);
1249                 return;
1250         }
1251         if(self.classname == "player")
1252         if(destteam == -1)
1253         {
1254                 CheckAllowedTeams(self);
1255                 t = FindSmallestTeam(self, TRUE);
1256                 switch(self.team)
1257                 {
1258                         case COLOR_TEAM1: c0 = c1; break;
1259                         case COLOR_TEAM2: c0 = c2; break;
1260                         case COLOR_TEAM3: c0 = c3; break;
1261                         case COLOR_TEAM4: c0 = c4; break;
1262                         default:          c0 = 999;
1263                 }
1264                 switch(t)
1265                 {
1266                         case 1:
1267                                 if(c0 > c1)
1268                                         destteam = COLOR_TEAM1;
1269                                 break;
1270                         case 2:
1271                                 if(c0 > c2)
1272                                         destteam = COLOR_TEAM2;
1273                                 break;
1274                         case 3:
1275                                 if(c0 > c3)
1276                                         destteam = COLOR_TEAM3;
1277                                 break;
1278                         case 4:
1279                                 if(c0 > c4)
1280                                         destteam = COLOR_TEAM4;
1281                                 break;
1282                 }
1283                 if(destteam == -1)
1284                         return;
1285         }
1286         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1287                 return;
1288         ClientKill_TeamChange(destteam);
1289 }
1290
1291 void FixClientCvars(entity e)
1292 {
1293         // send prediction settings to the client
1294         stuffcmd(e, "\nin_bindmap 0 0\n");
1295         if(g_race || g_cts)
1296                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1297         if(cvar("g_antilag") == 3) // client side hitscan
1298                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1299                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1300         /*
1301          * we no longer need to stuff this. Remove this comment block if you feel
1302          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1303         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1304         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1305         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1306         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1307         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1308         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1309         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1310         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1311         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1312         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1313         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1314         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1315         stuffcmd(e, "cl_movement_edgefriction 1\n");
1316          */
1317 }
1318
1319 /*
1320 =============
1321 ClientConnect
1322
1323 Called when a client connects to the server
1324 =============
1325 */
1326 //void ctf_clientconnect();
1327 string ColoredTeamName(float t);
1328 void DecodeLevelParms (void);
1329 //void dom_player_join_team(entity pl);
1330 #ifdef UID
1331 .float uid_kicktime;
1332 .string uid;
1333 #endif
1334 void ClientConnect (void)
1335 {
1336         float t;
1337
1338         if(self.flags & FL_CLIENT)
1339         {
1340                 print("Warning: ClientConnect, but already connected!\n");
1341                 return;
1342         }
1343
1344         if(Ban_MaybeEnforceBan(self))
1345                 return;
1346
1347         DecodeLevelParms();
1348
1349         self.classname = "player_joining";
1350
1351         self.flags = FL_CLIENT;
1352         self.version_nagtime = time + 10 + random() * 10;
1353
1354         if(player_count<0)
1355         {
1356                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1357                 player_count = 0;
1358         }
1359
1360         PlayerScore_Attach(self);
1361         ClientData_Attach();
1362
1363         bot_clientconnect();
1364
1365         playerdemo_init();
1366
1367         anticheat_init();
1368         
1369         race_PreSpawnObserver();
1370
1371         //if(g_domination)
1372         //      dom_player_join_team(self);
1373
1374         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1375
1376         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1377                 self.classname = "observer";
1378         } else {
1379                 if(teams_matter)
1380                 {
1381                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1382                         {
1383                                 self.classname = "player";
1384                                 campaign_bots_may_start = 1;
1385                         }
1386                         else
1387                         {
1388                                 self.classname = "observer"; // do it anyway
1389                         }
1390                 }
1391                 else
1392                 {
1393                         self.classname = "player";
1394                         campaign_bots_may_start = 1;
1395                 }
1396         }
1397
1398         self.playerid = (playerid_last = playerid_last + 1);
1399
1400         if(cvar("sv_eventlog"))
1401                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1402
1403         LogTeamchange(self.playerid, self.team, 1);
1404
1405         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1406
1407         self.netname_previous = strzone(self.netname);
1408
1409         bprint("^4", self.netname, "^4 connected");
1410
1411         if(self.classname != "observer" && (g_domination || g_ctf))
1412                 bprint(" and joined the ", ColoredTeamName(self.team));
1413
1414         bprint("\n");
1415
1416         self.welcomemessage_time = 0;
1417
1418         stuffcmd(self, strcat(clientstuff, "\n"));
1419         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1420         stuffcmd(self, "cl_particles_reloadeffects\n");
1421
1422         FixClientCvars(self);
1423
1424         // spawnfunc_waypoint sprites
1425         WaypointSprite_InitClient(self);
1426
1427         // Wazat's grappling hook
1428         SetGrappleHookBindings();
1429
1430         // get autoswitch state from player when he toggles it
1431         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1432
1433         // get version info from player
1434         stuffcmd(self, "cmd clientversion $gameversion\n");
1435
1436         // get other cvars from player
1437         GetCvars(0);
1438
1439         // set cvar for team scoreboard
1440         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1441
1442         // notify about available teams
1443         if(teams_matter)
1444         {
1445                 CheckAllowedTeams(self);
1446                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1447                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1448         }
1449         else
1450                 stuffcmd(self, "set _teams_available 0\n");
1451
1452         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1453
1454         if(g_arena || g_ca)
1455         {
1456                 self.classname = "observer";
1457                 if(g_arena)
1458                         Spawnqueue_Insert(self);
1459         }
1460         /*else if(g_ctf)
1461         {
1462                 ctf_clientconnect();
1463         }*/
1464
1465         if(teams_matter || radar_showennemies)
1466                 attach_entcs();
1467
1468         bot_relinkplayerlist();
1469
1470         self.spectatortime = time;
1471         if(blockSpectators)
1472         {
1473                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1474         }
1475
1476         self.jointime = time;
1477         self.allowedTimeouts = cvar("sv_timeout_number");
1478
1479         if(clienttype(self) == CLIENTTYPE_REAL)
1480         {
1481                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1482                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1483         }
1484
1485         if(g_lms)
1486         {
1487                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1488                 {
1489                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1490                         self.frags = FRAGS_SPECTATOR;
1491                 }
1492         }
1493
1494         if(!sv_foginterval && world.fog != "")
1495                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1496
1497         SoundEntity_Attach(self);
1498
1499         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1500         {
1501                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1502                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1503         }
1504         else
1505                 self.hitplotfh = -1;
1506
1507 #ifdef UID
1508         if(clienttype(self) == CLIENTTYPE_REAL)
1509         if not(self.uid)
1510                 self.uid_kicktime = time + 60;
1511 #endif
1512
1513         if(g_race || g_cts) {
1514                 string rr;
1515                 if(g_cts)
1516                         rr = CTS_RECORD;
1517                 else
1518                         rr = RACE_RECORD;
1519                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1520
1521                 race_send_recordtime(MSG_ONE);
1522                 race_send_speedaward(MSG_ONE);
1523
1524                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1525                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1526                 race_send_speedaward_alltimebest(MSG_ONE);
1527
1528                 float i;
1529                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1530                         race_SendRankings(i, 0, 0, MSG_ONE);
1531                 }
1532         }
1533         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1534                 send_CSQC_teamnagger();
1535
1536         CheatInitClient();
1537 }
1538
1539 /*
1540 =============
1541 ClientDisconnect
1542
1543 Called when a client disconnects from the server
1544 =============
1545 */
1546 .entity chatbubbleentity;
1547 .entity teambubbleentity;
1548 void ReadyCount();
1549 void ClientDisconnect (void)
1550 {
1551         if not(self.flags & FL_CLIENT)
1552         {
1553                 print("Warning: ClientDisconnect without ClientConnect\n");
1554                 return;
1555         }
1556
1557         CheatShutdownClient();
1558
1559         if(self.hitplotfh >= 0)
1560         {
1561                 fclose(self.hitplotfh);
1562                 self.hitplotfh = -1;
1563         }
1564
1565         anticheat_report();
1566         anticheat_shutdown();
1567
1568         playerdemo_shutdown();
1569
1570         bot_clientdisconnect();
1571
1572         if(self.entcs)
1573                 detach_entcs();
1574
1575         if(cvar("sv_eventlog"))
1576                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1577         bprint ("^4",self.netname);
1578         bprint ("^4 disconnected\n");
1579
1580         SoundEntity_Detach(self);
1581
1582         DropAllRunes(self);
1583         MUTATOR_CALLHOOK(ClientDisconnect);
1584
1585         Portal_ClearAll(self);
1586
1587         if(self.flagcarried)
1588                 DropFlag(self.flagcarried, world, world);
1589         if(self.ballcarried)
1590                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1591
1592         // Here, everything has been done that requires this player to be a client.
1593
1594         self.flags &~= FL_CLIENT;
1595
1596         if (self.chatbubbleentity)
1597                 remove (self.chatbubbleentity);
1598
1599         if (self.teambubbleentity)
1600                 remove (self.teambubbleentity);
1601
1602         if (self.killindicator)
1603                 remove (self.killindicator);
1604
1605         WaypointSprite_PlayerGone();
1606
1607         bot_relinkplayerlist();
1608
1609         // remove laserdot
1610         if(self.weaponentity)
1611                 if(self.weaponentity.lasertarget)
1612                         remove(self.weaponentity.lasertarget);
1613
1614         if(g_arena)
1615         {
1616                 Spawnqueue_Unmark(self);
1617                 Spawnqueue_Remove(self);
1618         }
1619
1620         ClientData_Detach();
1621         PlayerScore_Detach(self);
1622
1623         if(self.netname_previous)
1624                 strunzone(self.netname_previous);
1625         if(self.clientstatus)
1626                 strunzone(self.clientstatus);
1627
1628         ClearPlayerSounds();
1629
1630         if(self.personal)
1631                 remove(self.personal);
1632
1633         self.playerid = 0;
1634         ReadyCount();
1635
1636         // free cvars
1637         GetCvars(-1);
1638 }
1639
1640 .float BUTTON_CHAT;
1641 void ChatBubbleThink()
1642 {
1643         self.nextthink = time;
1644         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1645         {
1646                 if(self.owner) // but why can that ever be world?
1647                         self.owner.chatbubbleentity = world;
1648                 remove(self);
1649                 return;
1650         }
1651         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1652 #ifdef TETRIS
1653                 || self.owner.tetris_on
1654 #endif
1655         )
1656                 self.model = self.mdl;
1657         else
1658                 self.model = "";
1659 };
1660
1661 void UpdateChatBubble()
1662 {
1663         if (!self.modelindex)
1664                 return;
1665         // spawn a chatbubble entity if needed
1666         if (!self.chatbubbleentity)
1667         {
1668                 self.chatbubbleentity = spawn();
1669                 self.chatbubbleentity.owner = self;
1670                 self.chatbubbleentity.exteriormodeltoclient = self;
1671                 self.chatbubbleentity.think = ChatBubbleThink;
1672                 self.chatbubbleentity.nextthink = time;
1673                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1674                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1675                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1676                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1677                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1678                 self.chatbubbleentity.model = "";
1679                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1680         }
1681 }
1682
1683
1684 void TeamBubbleThink()
1685 {
1686         self.nextthink = time;
1687         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1688         {
1689                 if(self.owner) // but why can that ever be world?
1690                         self.owner.teambubbleentity = world;
1691                 remove(self);
1692                 return;
1693         }
1694 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1695         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1696                 self.model = "";
1697         else
1698                 self.model = self.mdl;
1699
1700 };
1701
1702 float TeamBubble_customizeentityforclient()
1703 {
1704         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1705 }
1706
1707 void UpdateTeamBubble()
1708 {
1709         if (!self.modelindex || !teams_matter)
1710                 return;
1711         // spawn a teambubble entity if needed
1712         if (!self.teambubbleentity && teams_matter)
1713         {
1714                 self.teambubbleentity = spawn();
1715                 self.teambubbleentity.owner = self;
1716                 self.teambubbleentity.exteriormodeltoclient = self;
1717                 self.teambubbleentity.think = TeamBubbleThink;
1718                 self.teambubbleentity.nextthink = time;
1719                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1720 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1721                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1722                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1723                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1724                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1725                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1726                 self.teambubbleentity.effects = EF_LOWPRECISION;
1727         }
1728 }
1729
1730 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1731 // added to the model skins
1732 /*void UpdateColorModHack()
1733 {
1734         local float c;
1735         c = self.clientcolors & 15;
1736         // LordHavoc: only bothering to support white, green, red, yellow, blue
1737              if (!teams_matter) self.colormod = '0 0 0';
1738         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1739         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1740         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1741         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1742         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1743         else self.colormod = '1 1 1';
1744 };*/
1745
1746 void respawn(void)
1747 {
1748         CopyBody(1);
1749         self.effects |= EF_NODRAW; // prevent another CopyBody
1750         PutClientInServer();
1751 }
1752
1753 void play_countdown(float finished, string samp)
1754 {
1755         if(clienttype(self) == CLIENTTYPE_REAL)
1756                 if(floor(finished - time - frametime) != floor(finished - time))
1757                         if(finished - time < 6)
1758                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1759 }
1760
1761 /**
1762  * When sv_timeout is used this function returs strings like
1763  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1764  * Called by centerprint functions
1765  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1766  */
1767 string getTimeoutText(float addOneSecond) {
1768         if (!cvar("sv_timeout") || !timeoutStatus)
1769                 return "";
1770
1771         local string retStr;
1772         if (timeoutStatus == 1) {
1773                 if (addOneSecond == 1) {
1774                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1775                 }
1776                 else {
1777                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1778                 }
1779                 return retStr;
1780         }
1781         else if (timeoutStatus == 2) {
1782                 if (addOneSecond) {
1783                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1784                         //don't show messages like "Timeout ends in 0 seconds"...
1785                         if ((remainingTimeoutTime + 1) > 0)
1786                                 return retStr;
1787                         else
1788                                 return "";
1789                 }
1790                 else {
1791                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1792                         //don't show messages like "Timeout ends in 0 seconds"...
1793                         if (remainingTimeoutTime > 0)
1794                                 return retStr;
1795                         else
1796                                 return "";
1797                 }
1798         }
1799         else return "";
1800 }
1801
1802 void player_powerups (void)
1803 {
1804         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1805         {
1806                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1807                 self.modelflags |= MF_ROCKET;
1808         }
1809         else
1810         {
1811                 SoundEntity_StopSound(self, CHAN_PLAYER);
1812                 self.modelflags &~= MF_ROCKET;
1813         }
1814
1815         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1816
1817         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1818                 return;
1819         
1820         Fire_ApplyDamage(self);
1821         Fire_ApplyEffect(self);
1822
1823         if (g_minstagib)
1824         {
1825                 self.effects |= EF_FULLBRIGHT;
1826
1827                 if (self.items & IT_STRENGTH)
1828                 {
1829                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1830                         if (time > self.strength_finished)
1831                         {
1832                                 self.alpha = default_player_alpha;
1833                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1834                                 self.items &~= IT_STRENGTH;
1835                                 sprint(self, "^3Invisibility has worn off\n");
1836                         }
1837                 }
1838                 else
1839                 {
1840                         if (time < self.strength_finished)
1841                         {
1842                                 self.alpha = g_minstagib_invis_alpha;
1843                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1844                                 self.items |= IT_STRENGTH;
1845                                 sprint(self, "^3You are invisible\n");
1846                         }
1847                 }
1848
1849                 if (self.items & IT_INVINCIBLE)
1850                 {
1851                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1852                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1853                         {
1854                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1855                                 sprint(self, "^3Speed has worn off\n");
1856                         }
1857                 }
1858                 else
1859                 {
1860                         if (time < self.invincible_finished)
1861                         {
1862                                 self.items = self.items | IT_INVINCIBLE;
1863                                 sprint(self, "^3You are on speed\n");
1864                         }
1865                 }
1866                 return;
1867         }
1868
1869         if (self.items & IT_STRENGTH)
1870         {
1871                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1872                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1873                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1874                 {
1875                         self.items = self.items - (self.items & IT_STRENGTH);
1876                         sprint(self, "^3Strength has worn off\n");
1877                 }
1878         }
1879         else
1880         {
1881                 if (time < self.strength_finished)
1882                 {
1883                         self.items = self.items | IT_STRENGTH;
1884                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1885                 }
1886         }
1887         if (self.items & IT_INVINCIBLE)
1888         {
1889                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1890                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1891                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1892                 {
1893                         self.items = self.items - (self.items & IT_INVINCIBLE);
1894                         sprint(self, "^3Shield has worn off\n");
1895                 }
1896         }
1897         else
1898         {
1899                 if (time < self.invincible_finished)
1900                 {
1901                         self.items = self.items | IT_INVINCIBLE;
1902                         sprint(self, "^3Shield surrounds you\n");
1903                 }
1904         }
1905
1906         if(cvar("g_nodepthtestplayers"))
1907                 self.effects = self.effects | EF_NODEPTHTEST;
1908
1909         if(cvar("g_fullbrightplayers"))
1910                 self.effects = self.effects | EF_FULLBRIGHT;
1911
1912         // midair gamemode: damage only while in the air
1913         // if in midair mode, being on ground grants temporary invulnerability
1914         // (this is so that multishot weapon don't clear the ground flag on the
1915         // first damage in the frame, leaving the player vulnerable to the
1916         // remaining hits in the same frame)
1917         if (self.flags & FL_ONGROUND)
1918         if (g_midair)
1919                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1920
1921         if (time >= game_starttime)
1922         if (time < self.spawnshieldtime)
1923                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1924 }
1925
1926 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1927 {
1928         if(current > stable)
1929                 return current;
1930         else if(current > stable - 0.25) // when close enough, "snap"
1931                 return stable;
1932         else
1933                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1934 }
1935
1936 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1937 {
1938         if(current < stable)
1939                 return current;
1940         else if(current < stable + 0.25) // when close enough, "snap"
1941                 return stable;
1942         else
1943                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1944 }
1945
1946 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1947 {
1948         if(current > rotstable)
1949         {
1950                 if(rotframetime > 0)
1951                 {
1952                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1953                         current = max(rotstable, current - rotlinear * rotframetime);
1954                 }
1955         }
1956         else if(current < regenstable)
1957         {
1958                 if(regenframetime > 0)
1959                 {
1960                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1961                         current = min(regenstable, current + regenlinear * regenframetime);
1962                 }
1963         }
1964
1965         if(current > limit)
1966                 current = limit;
1967
1968         return current;
1969 }
1970
1971 void player_regen (void)
1972 {
1973         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1974         maxh = cvar("g_balance_health_rotstable");
1975         maxa = cvar("g_balance_armor_rotstable");
1976         maxf = cvar("g_balance_fuel_rotstable");
1977         minh = cvar("g_balance_health_regenstable");
1978         mina = cvar("g_balance_armor_regenstable");
1979         minf = cvar("g_balance_fuel_regenstable");
1980         limith = cvar("g_balance_health_limit");
1981         limita = cvar("g_balance_armor_limit");
1982         limitf = cvar("g_balance_fuel_limit");
1983
1984         max_mod = regen_mod = rot_mod = limit_mod = 1;
1985
1986         if (self.runes & RUNE_REGEN)
1987         {
1988                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1989                 {
1990                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1991                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1992                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1993                 }
1994                 else
1995                 {
1996                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1997                         max_mod = cvar("g_balance_rune_regen_hpmod");
1998                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1999                 }
2000         }
2001         else if (self.runes & CURSE_VENOM)
2002         {
2003                 max_mod = cvar("g_balance_curse_venom_hpmod");
2004                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2005                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2006                 else
2007                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2008                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2009                 //if (!self.runes & RUNE_REGEN)
2010                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2011         }
2012         maxh = maxh * max_mod;
2013         //maxa = maxa * max_mod;
2014         //maxf = maxf * max_mod;
2015         minh = minh * max_mod;
2016         //mina = mina * max_mod;
2017         //minf = minf * max_mod;
2018         limith = limith * limit_mod;
2019         limita = limita * limit_mod;
2020         //limitf = limitf * limit_mod;
2021
2022         if(g_lms && g_ca)
2023                 rot_mod = 0;
2024
2025         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2026         {
2027                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2028                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2029
2030                 // if player rotted to death...  die!
2031                 if(self.health < 1)
2032                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2033         }
2034
2035         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2036                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2037 }
2038
2039 float zoomstate_set;
2040 void SetZoomState(float z)
2041 {
2042         if(z != self.zoomstate)
2043         {
2044                 self.zoomstate = z;
2045                 ClientData_Touch(self);
2046         }
2047         zoomstate_set = 1;
2048 }
2049
2050 void GetPressedKeys(void) {
2051         if (self.movement_x > 0) // get if movement keys are pressed
2052         {       // forward key pressed
2053                 self.pressedkeys |= KEY_FORWARD;
2054                 self.pressedkeys &~= KEY_BACKWARD;
2055         }
2056         else if (self.movement_x < 0)
2057         {       // backward key pressed
2058                 self.pressedkeys |= KEY_BACKWARD;
2059                 self.pressedkeys &~= KEY_FORWARD;
2060         }
2061         else
2062         {       // no x input
2063                 self.pressedkeys &~= KEY_FORWARD;
2064                 self.pressedkeys &~= KEY_BACKWARD;
2065         }
2066
2067         if (self.movement_y > 0)
2068         {       // right key pressed
2069                 self.pressedkeys |= KEY_RIGHT;
2070                 self.pressedkeys &~= KEY_LEFT;
2071         }
2072         else if (self.movement_y < 0)
2073         {       // left key pressed
2074                 self.pressedkeys |= KEY_LEFT;
2075                 self.pressedkeys &~= KEY_RIGHT;
2076         }
2077         else
2078         {       // no y input
2079                 self.pressedkeys &~= KEY_RIGHT;
2080                 self.pressedkeys &~= KEY_LEFT;
2081         }
2082
2083         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2084                 self.pressedkeys |= KEY_JUMP;
2085         else
2086                 self.pressedkeys &~= KEY_JUMP;
2087         if (self.BUTTON_CROUCH)
2088                 self.pressedkeys |= KEY_CROUCH;
2089         else
2090                 self.pressedkeys &~= KEY_CROUCH;
2091 }
2092
2093 void update_stats (float number, float hit, float fired) {
2094 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2095 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2096
2097         if(number) {
2098                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2099                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2100         } else {
2101                 self.stat_hit = hit * sv_accuracy_data_share;
2102                 self.stat_fired = fired * sv_accuracy_data_share;
2103         }
2104 }
2105
2106 /*
2107 ======================
2108 spectate mode routines
2109 ======================
2110 */
2111
2112 .float weapon_count;
2113 void SpectateCopy(entity spectatee) {
2114         if(spectatee.weapon_count < WEP_LAST) {
2115                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2116                 spectatee.weapon_count ++;
2117         } else
2118                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2119
2120         other = spectatee;
2121         MUTATOR_CALLHOOK(SpectateCopy);
2122         self.armortype = spectatee.armortype;
2123         self.armorvalue = spectatee.armorvalue;
2124         self.ammo_cells = spectatee.ammo_cells;
2125         self.ammo_shells = spectatee.ammo_shells;
2126         self.ammo_nails = spectatee.ammo_nails;
2127         self.ammo_rockets = spectatee.ammo_rockets;
2128         self.ammo_fuel = spectatee.ammo_fuel;
2129         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2130         self.health = spectatee.health;
2131         self.impulse = 0;
2132         self.items = spectatee.items;
2133         self.metertime = spectatee.metertime;
2134         self.strength_finished = spectatee.strength_finished;
2135         self.invincible_finished = spectatee.invincible_finished;
2136         self.pressedkeys = spectatee.pressedkeys;
2137         self.weapons = spectatee.weapons;
2138         self.switchweapon = spectatee.switchweapon;
2139         self.weapon = spectatee.weapon;
2140         self.punchangle = spectatee.punchangle;
2141         self.view_ofs = spectatee.view_ofs;
2142         self.v_angle = spectatee.v_angle;
2143         self.velocity = spectatee.velocity;
2144         self.dmg_take = spectatee.dmg_take;
2145         self.dmg_save = spectatee.dmg_save;
2146         self.dmg_inflictor = spectatee.dmg_inflictor;
2147         self.angles = spectatee.v_angle;
2148         self.fixangle = TRUE;
2149         setorigin(self, spectatee.origin);
2150         setsize(self, spectatee.mins, spectatee.maxs);
2151         SetZoomState(spectatee.zoomstate);
2152
2153         anticheat_spectatecopy(spectatee);
2154 }
2155
2156 float SpectateUpdate() {
2157         if(!self.enemy)
2158                 return 0;
2159
2160         if (self == self.enemy)
2161                 return 0;
2162
2163         if(self.enemy.classname != "player")
2164                 return 0;
2165
2166         SpectateCopy(self.enemy);
2167
2168         return 1;
2169 }
2170
2171 float SpectateNext() {
2172         other = find(self.enemy, classname, "player");
2173
2174         if (!other)
2175                 other = find(other, classname, "player");
2176
2177         if (other)
2178                 self.enemy = other;
2179
2180         if(self.enemy.classname == "player") {
2181                 msg_entity = self;
2182                 WriteByte(MSG_ONE, SVC_SETVIEW);
2183                 WriteEntity(MSG_ONE, self.enemy);
2184                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2185                 self.movetype = MOVETYPE_NONE;
2186
2187                 self.enemy.weapon_count = 0;
2188
2189                 if(!SpectateUpdate())
2190                         PutObserverInServer();
2191
2192                 return 1;
2193         } else {
2194                 return 0;
2195         }
2196 }
2197
2198 /*
2199 =============
2200 ShowRespawnCountdown()
2201
2202 Update a respawn countdown display.
2203 =============
2204 */
2205 void ShowRespawnCountdown()
2206 {
2207         float number;
2208         if(self.deadflag == DEAD_NO) // just respawned?
2209                 return;
2210         else
2211         {
2212                 number = ceil(self.death_time - time);
2213                 if(number <= 0)
2214                         return;
2215                 if(number <= self.respawn_countdown)
2216                 {
2217                         self.respawn_countdown = number - 1;
2218                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2219                                 AnnounceTo(self, strcat(ftos(number), ""));
2220                 }
2221         }
2222 }
2223
2224 void LeaveSpectatorMode()
2225 {
2226         if(isJoinAllowed()) {
2227                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2228                         self.classname = "player";
2229
2230                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2231                                 JoinBestTeam(self, FALSE, TRUE);
2232
2233                         if(cvar("g_campaign"))
2234                                 campaign_bots_may_start = 1;
2235
2236                         self.stat_count = WEP_LAST;
2237
2238                         PutClientInServer();
2239
2240                         if(self.classname == "player")
2241                                 bprint ("^4", self.netname, "^4 is playing now\n");
2242
2243                         if(!cvar("g_campaign"))
2244                                 centerprint(self,""); // clear MOTD
2245
2246                         return;
2247                 } else {
2248                         if (g_ca && self.caplayer) {
2249                         }       // do nothing
2250                         else
2251                                 stuffcmd(self,"menu_showteamselect\n");
2252                         return;
2253                 }
2254         }
2255         else {
2256                 //player may not join because of g_maxplayers is set
2257                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2258         }
2259 }
2260
2261 /**
2262  * Determines whether the player is allowed to join. This depends on cvar
2263  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2264  * it checks whether the number of currently playing players exceeds g_maxplayers.
2265  * @return bool TRUE if the player is allowed to join, false otherwise
2266  */
2267 float isJoinAllowed() {
2268         if (!cvar("g_maxplayers"))
2269                 return TRUE;
2270
2271         local entity e;
2272         local float currentlyPlaying;
2273         FOR_EACH_REALPLAYER(e) {
2274                 if(e.classname == "player")
2275                         currentlyPlaying += 1;
2276         }
2277         if(currentlyPlaying < cvar("g_maxplayers"))
2278                 return TRUE;
2279
2280         return FALSE;
2281 }
2282
2283 /**
2284  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2285  * g_maxplayers_spectator_blocktime seconds
2286  */
2287 void checkSpectatorBlock() {
2288         if(self.classname == "spectator" || self.classname == "observer") {
2289                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2290                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2291                         dropclient(self);
2292                 }
2293         }
2294 }
2295
2296 float vercmp_recursive(string v1, string v2)
2297 {
2298         float dot1, dot2;
2299         string s1, s2;
2300         float r;
2301
2302         dot1 = strstrofs(v1, ".", 0);
2303         dot2 = strstrofs(v2, ".", 0);
2304         if(dot1 == -1)
2305                 s1 = v1;
2306         else
2307                 s1 = substring(v1, 0, dot1);
2308         if(dot2 == -1)
2309                 s2 = v2;
2310         else
2311                 s2 = substring(v2, 0, dot2);
2312
2313         r = stof(s1) - stof(s2);
2314         if(r != 0)
2315                 return r;
2316
2317         r = strcasecmp(s1, s2);
2318         if(r != 0)
2319                 return r;
2320
2321         if(dot1 == -1)
2322                 if(dot2 == -1)
2323                         return 0;
2324                 else
2325                         return -1;
2326         else
2327                 if(dot2 == -1)
2328                         return 1;
2329                 else
2330                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2331 }
2332
2333 float vercmp(string v1, string v2)
2334 {
2335         if(strcasecmp(v1, v2) == 0) // early out check
2336                 return 0;
2337         return vercmp_recursive(v1, v2);
2338 }
2339
2340 void ObserverThink()
2341 {
2342         if (self.flags & FL_JUMPRELEASED) {
2343                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2344                         self.welcomemessage_time = 0;
2345                         self.flags &~= FL_JUMPRELEASED;
2346                         self.flags |= FL_SPAWNING;
2347                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2348                         self.welcomemessage_time = 0;
2349                         self.flags &~= FL_JUMPRELEASED;
2350                         if(SpectateNext() == 1) {
2351                                 self.classname = "spectator";
2352                         }
2353                 }
2354         } else {
2355                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2356                         self.flags |= FL_JUMPRELEASED;
2357                         if(self.flags & FL_SPAWNING)
2358                         {
2359                                 self.flags &~= FL_SPAWNING;
2360                                 LeaveSpectatorMode();
2361                                 return;
2362                         }
2363                 }
2364         }
2365         PrintWelcomeMessage(self);
2366 }
2367
2368 void SpectatorThink()
2369 {
2370         if (self.flags & FL_JUMPRELEASED) {
2371                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2372                         self.welcomemessage_time = 0;
2373                         self.flags &~= FL_JUMPRELEASED;
2374                         self.flags |= FL_SPAWNING;
2375                 } else if(self.BUTTON_ATCK) {
2376                         self.welcomemessage_time = 0;
2377                         self.flags &~= FL_JUMPRELEASED;
2378                         if(SpectateNext() == 1) {
2379                                 self.classname = "spectator";
2380                         } else {
2381                                 self.classname = "observer";
2382                                 self.stat_count = WEP_LAST;
2383                                 PutClientInServer();
2384                         }
2385                 } else if (self.BUTTON_ATCK2) {
2386                         self.welcomemessage_time = 0;
2387                         self.flags &~= FL_JUMPRELEASED;
2388                         self.classname = "observer";
2389                         self.stat_count = WEP_LAST;
2390                         PutClientInServer();
2391                 } else {
2392                         if(!SpectateUpdate())
2393                                 PutObserverInServer();
2394                 }
2395         } else {
2396                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2397                         self.flags |= FL_JUMPRELEASED;
2398                         if(self.flags & FL_SPAWNING)
2399                         {
2400                                 self.flags &~= FL_SPAWNING;
2401                                 LeaveSpectatorMode();
2402                                 return;
2403                         }
2404                 }
2405         }
2406
2407         PrintWelcomeMessage(self);
2408         self.flags |= FL_CLIENT | FL_NOTARGET;
2409 }
2410
2411 .float touchexplode_time;
2412
2413 /*
2414 =============
2415 PlayerPreThink
2416
2417 Called every frame for each client before the physics are run
2418 =============
2419 */
2420 void() ctf_setstatus;
2421 void() nexball_setstatus;
2422 .float items_added;
2423 void PlayerPreThink (void)
2424 {
2425         self.stat_game_starttime = game_starttime;
2426         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2427         self.stat_leadlimit = cvar("leadlimit");
2428
2429         if(frametime)
2430         {
2431                 // physics frames: update anticheat stuff
2432                 anticheat_prethink();
2433         }
2434
2435         if(blockSpectators && frametime)
2436                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2437                 checkSpectatorBlock();
2438
2439         zoomstate_set = 0;
2440
2441         if(self.netname_previous != self.netname)
2442         {
2443                 if(cvar("sv_eventlog"))
2444                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2445                 if(self.netname_previous)
2446                         strunzone(self.netname_previous);
2447                 self.netname_previous = strzone(self.netname);
2448         }
2449
2450         // version nagging
2451         if(self.version_nagtime)
2452                 if(self.cvar_g_xonoticversion)
2453                         if(time > self.version_nagtime)
2454                         {
2455                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2456                                 {
2457                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2458                                         {
2459                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2460                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2461                                         }
2462                                         else
2463                                         {
2464                                                 float r;
2465                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2466                                                 if(r < 0)
2467                                                 {
2468                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2469                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2470                                                 }
2471                                                 else if(r > 0)
2472                                                 {
2473                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2474                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2475                                                 }
2476                                         }
2477                                 }
2478                                 self.version_nagtime = 0;
2479                         }
2480
2481         // GOD MODE info
2482         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2483         {
2484                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2485                 self.max_armorvalue = 0;
2486         }
2487
2488 #ifdef TETRIS
2489         if (TetrisPreFrame())
2490                 return;
2491 #endif
2492
2493         if(self.classname == "player") {
2494 //              if(self.netname == "Wazat")
2495 //                      bprint(self.classname, "\n");
2496
2497                 CheckRules_Player();
2498
2499                 PrintWelcomeMessage(self);
2500
2501                 if (intermission_running)
2502                 {
2503                         IntermissionThink ();   // otherwise a button could be missed between
2504                         return;                                 // the think tics
2505                 }
2506
2507                 if(self.teleport_time)
2508                 if(time > self.teleport_time)
2509                 {
2510                         self.teleport_time = 0;
2511                         self.effects = self.effects - (self.effects & EF_NODRAW);
2512                 }
2513
2514                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2515                         UpdateSelectedPlayer();
2516
2517                 //don't allow the player to turn around while game is paused!
2518                 if(timeoutStatus == 2) {
2519                         self.v_angle = self.lastV_angle;
2520                         self.angles = self.lastV_angle;
2521                         self.fixangle = TRUE;
2522                 }
2523
2524                 if(frametime)
2525                 {
2526                         if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
2527                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2528                         player_powerups();
2529                 }
2530
2531                 if (self.deadflag != DEAD_NO)
2532                 {
2533                         float button_pressed, force_respawn;
2534                         if(self.personal && g_race_qualifying)
2535                         {
2536                                 if(time > self.death_time)
2537                                 {
2538                                         self.death_time = time + 1; // only retry once a second
2539                                         respawn();
2540                                         self.impulse = 141;
2541                                 }
2542                         }
2543                         else
2544                         {
2545                                 if(frametime)
2546                                         player_anim();
2547                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2548                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2549                                 if (self.deadflag == DEAD_DYING)
2550                                 {
2551                                         if(force_respawn)
2552                                                 self.deadflag = DEAD_RESPAWNING;
2553                                         else if(!button_pressed)
2554                                                 self.deadflag = DEAD_DEAD;
2555                                 }
2556                                 else if (self.deadflag == DEAD_DEAD)
2557                                 {
2558                                         if(button_pressed)
2559                                                 self.deadflag = DEAD_RESPAWNABLE;
2560                                 }
2561                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2562                                 {
2563                                         if(!button_pressed)
2564                                                 self.deadflag = DEAD_RESPAWNING;
2565                                 }
2566                                 else if (self.deadflag == DEAD_RESPAWNING)
2567                                 {
2568                                         if(time > self.death_time)
2569                                         {
2570                                                 self.death_time = time + 1; // only retry once a second
2571                                                 respawn();
2572                                         }
2573                                 }
2574                                 ShowRespawnCountdown();
2575                         }
2576                         return;
2577                 }
2578
2579                 if(g_touchexplode)
2580                 if(time > self.touchexplode_time)
2581                 if(self.classname == "player")
2582                 if(self.deadflag == DEAD_NO)
2583                 if not(IS_INDEPENDENT_PLAYER(self))
2584                 FOR_EACH_PLAYER(other) if(self != other)
2585                 {
2586                         if(time > other.touchexplode_time)
2587                         if(other.classname == "player")
2588                         if(other.deadflag == DEAD_NO)
2589                         if not(IS_INDEPENDENT_PLAYER(other))
2590                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2591                         {
2592                                 PlayerTouchExplode(self, other);
2593                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2594                         }
2595                 }
2596
2597                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2598                 {
2599                         vector dist;
2600
2601                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2602                         dist = self.prevorigin - self.origin;
2603                         dist_z = 0;
2604                         self.lms_traveled_distance += fabs(vlen(dist));
2605
2606                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2607                         {
2608                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2609                                 self.lms_traveled_distance = 0;
2610                         }
2611
2612                         if(time > self.lms_nextcheck)
2613                         {
2614                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2615                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2616                                 {
2617                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2618                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2619                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2620                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2621                                 }
2622                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2623                                 self.lms_traveled_distance = 0;
2624                         }
2625                 }
2626
2627                 self.prevorigin = self.origin;
2628
2629                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2630                 {
2631                         if (!self.crouch)
2632                         {
2633                                 self.crouch = TRUE;
2634                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2635                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2636                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2637                         }
2638                 }
2639                 else
2640                 {
2641                         if (self.crouch)
2642                         {
2643                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2644                                 if (!trace_startsolid)
2645                                 {
2646                                         self.crouch = FALSE;
2647                                         self.view_ofs = PL_VIEW_OFS;
2648                                         setsize (self, PL_MIN, PL_MAX);
2649                                 }
2650                         }
2651                 }
2652
2653                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2654                 {
2655                         if(self.bloodloss_timer < time)
2656                         {
2657                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2658                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2659                         }
2660                 }
2661
2662                 FixPlayermodel();
2663
2664                 GrapplingHookFrame();
2665
2666                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2667                 //if(frametime)
2668                 {
2669                         self.items &~= self.items_added;
2670
2671                         W_WeaponFrame();
2672
2673                         self.items_added = 0;
2674                         if(self.items & IT_JETPACK)
2675                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2676                                         self.items_added |= IT_FUEL;
2677
2678                         self.items |= self.items_added;
2679                 }
2680
2681                 player_regen();
2682                 if(frametime)
2683                         player_anim();
2684
2685                 if (g_minstagib)
2686                         minstagib_ammocheck();
2687
2688                 ctf_setstatus();
2689                 nexball_setstatus();
2690
2691                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2692
2693                 //self.angles_y=self.v_angle_y + 90;   // temp
2694         } else if(gameover) {
2695                 if (intermission_running)
2696                         IntermissionThink ();   // otherwise a button could be missed between
2697                 return;
2698         } else if(self.classname == "observer") {
2699                 ObserverThink();
2700         } else if(self.classname == "spectator") {
2701                 SpectatorThink();
2702         }
2703
2704         if(!zoomstate_set)
2705                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2706
2707         float oldspectatee_status;
2708         oldspectatee_status = self.spectatee_status;
2709         if(self.classname == "spectator")
2710                 self.spectatee_status = num_for_edict(self.enemy);
2711         else if(self.classname == "observer")
2712                 self.spectatee_status = num_for_edict(self);
2713         else
2714                 self.spectatee_status = 0;
2715         if(self.spectatee_status != oldspectatee_status)
2716         {
2717                 ClientData_Touch(self);
2718                 if(g_race || g_cts)
2719                         race_InitSpectator();
2720         }
2721
2722         if(self.teamkill_soundtime)
2723         if(time > self.teamkill_soundtime)
2724         {
2725                 self.teamkill_soundtime = 0;
2726
2727                 entity oldpusher, oldself;
2728
2729                 oldself = self; self = self.teamkill_soundsource;
2730                 oldpusher = self.pusher; self.pusher = oldself;
2731
2732                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2733
2734                 self.pusher = oldpusher;
2735                 self = oldself;
2736         }
2737
2738         if(self.taunt_soundtime)
2739         if(time > self.taunt_soundtime)
2740         {
2741                 self.taunt_soundtime = 0;
2742                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2743         }
2744
2745         target_voicescript_next(self);
2746 }
2747
2748 float isInvisibleString(string s)
2749 {
2750         float i, n, c;
2751         s = strdecolorize(s);
2752         for((i = 0), (n = strlen(s)); i < n; ++i)
2753         {
2754                 c = str2chr(s, i);
2755                 switch(c)
2756                 {
2757                         case 0:
2758                         case 32:
2759                         case 160:
2760                                 break;
2761                         default:
2762                                 return FALSE;
2763                 }
2764         }
2765         return TRUE;
2766 }
2767
2768 /*
2769 =============
2770 PlayerPostThink
2771
2772 Called every frame for each client after the physics are run
2773 =============
2774 */
2775 .float idlekick_lasttimeleft;
2776 void PlayerPostThink (void)
2777 {
2778         // Savage: Check for nameless players
2779         if (isInvisibleString(self.netname)) {
2780                 self.netname = "Player";
2781                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2782         }
2783
2784         // send the clients accuracy stats to the client
2785         if(self.stat_count > 0)
2786         if(frametime)
2787         {
2788                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2789                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2790                 self.stat_count -= 1;
2791         }
2792
2793 #ifdef UID
2794         if(self.uid_kicktime)
2795         if(time > self.uid_kicktime)
2796         {
2797                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2798                 dropclient(self);
2799                 return;
2800         }
2801 #endif
2802
2803         if(sv_maxidle && frametime)
2804         {
2805                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2806                 float timeleft;
2807                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2808                 if(timeleft <= 0)
2809                 {
2810                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2811                         AnnounceTo(self, "terminated");
2812                         dropclient(self);
2813                         return;
2814                 }
2815                 else if(timeleft <= 10)
2816                 {
2817                         if(timeleft != self.idlekick_lasttimeleft)
2818                         {
2819                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2820                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2821                         }
2822                 }
2823                 else
2824                 {
2825                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2826                 }
2827                 self.idlekick_lasttimeleft = timeleft;
2828         }
2829
2830 #ifdef TETRIS
2831         if(self.impulse == 100)
2832                 ImpulseCommands();
2833         if (TetrisPostFrame())
2834                 return;
2835 #endif
2836
2837         CheatFrame();
2838
2839         if(self.classname == "player") {
2840                 CheckRules_Player();
2841                 UpdateChatBubble();
2842                 UpdateTeamBubble();
2843                 if (self.impulse)
2844                         ImpulseCommands();
2845                 if (intermission_running)
2846                         return;         // intermission or finale
2847
2848                 GetPressedKeys();
2849         } else if (self.classname == "observer") {
2850                 //do nothing
2851         } else if (self.classname == "spectator") {
2852                 //do nothing
2853         }
2854
2855         /*
2856         float i;
2857         for(i = 0; i < 1000; ++i)
2858         {
2859                 vector end;
2860                 end = self.origin + '0 0 1024' + 512 * randomvec();
2861                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2862                 if(trace_fraction < 1)
2863                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2864                 {
2865                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2866                         break;
2867                 }
2868         }
2869         */
2870
2871         Arena_Warmup();
2872
2873         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2874
2875         if(self.waypointsprite_attachedforcarrier)
2876                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2877         
2878         playerdemo_write();
2879
2880         /*
2881         if(g_race)
2882                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2883         */
2884 }