qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel = "models/player/marine.zym";
 402 string CheckPlayerModel(string plyermodel) {
 403         if(strlen(plyermodel) < 4)
 404                 return FallbackPlayerModel;
 405         if( substring(plyermodel,0,14) != "models/player/")
 406                 return FallbackPlayerModel;
 407         else if(cvar("sv_servermodelsonly"))
 408         {
 409                 if(substring(plyermodel,-4,4) != ".zym")
 410                 if(substring(plyermodel,-4,4) != ".dpm")
 411                 if(substring(plyermodel,-4,4) != ".iqm")
 412                 if(substring(plyermodel,-4,4) != ".md3")
 413                 if(substring(plyermodel,-4,4) != ".psk")
 414                         return FallbackPlayerModel;
 415                 // forbid the LOD models
 416                 if(substring(plyermodel, -9,5) == "_lod1")
 417                         return FallbackPlayerModel;
 418                 if(substring(plyermodel, -9,5) == "_lod2")
 419                         return FallbackPlayerModel;
 420                 if(plyermodel != strtolower(plyermodel))
 421                         return FallbackPlayerModel;
 422                 if(!fexists(plyermodel))
 423                         return FallbackPlayerModel;
 424         }
 425         return plyermodel;
 426 }
 427
 428 /*
 429 =============
 430 Client_customizeentityforclient
 431
 432 LOD reduction
 433 =============
 434 */
 435 void Client_uncustomizeentityforclient()
 436 {
 437         if(self.modelindex == 0) // no need to uncustomize then
 438                 return;
 439         self.modelindex = self.modelindex_lod0;
 440         self.skin = self.skinindex;
 441 }
 442
 443 float Client_customizeentityforclient()
 444 {
 445         entity modelsource;
 446
 447         if(self.modelindex == 0)
 448                 return TRUE;
 449
 450         // forcemodel stuff
 451
 452 #ifdef PROFILING
 453         float t0;
 454         t0 = gettime(GETTIME_HIRES); // reference
 455 #endif
 456
 457         modelsource = self;
 458
 459 #ifdef ALLOW_FORCEMODELS
 460         if(other.cvar_cl_forceplayermodelsfromxonotic)
 461                 if not(self.modelindex_lod0_from_xonotic)
 462                         modelsource = other;
 463         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 464                 modelsource = other;
 465 #endif
 466
 467         self.skin = modelsource.skinindex;
 468
 469 #if 0
 470         if(modelsource == self)
 471                 self.skin = modelsource.skinindex;
 472         else
 473                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 474 #endif
 475
 476         // self: me
 477         // other: the player viewing me
 478         float distance;
 479         float f;
 480
 481         if(other.cvar_cl_playerdetailreduction <= 0)
 482         {
 483                 if(other.cvar_cl_playerdetailreduction <= -2)
 484                         self.modelindex = modelsource.modelindex_lod2;
 485                 else if(other.cvar_cl_playerdetailreduction <= -1)
 486                         self.modelindex = modelsource.modelindex_lod1;
 487                 else
 488                         self.modelindex = modelsource.modelindex_lod0;
 489         }
 490         else
 491         {
 492                 distance = vlen(self.origin - other.origin);
 493                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 494                 if(f > sv_loddistance2)
 495                         self.modelindex = modelsource.modelindex_lod2;
 496                 else if(f > sv_loddistance1)
 497                         self.modelindex = modelsource.modelindex_lod1;
 498                 else
 499                         self.modelindex = modelsource.modelindex_lod0;
 500         }
 501
 502 #ifdef PROFILING
 503         float t1;
 504         t1 = gettime(GETTIME_HIRES); // reference
 505         client_cefc_accumulator += (t1 - t0);
 506 #endif
 507
 508         return TRUE;
 509 }
 510
 511 void setmodel_lod(entity e, string modelname)
 512 {
 513         string s;
 514
 515         if(sv_loddistance1)
 516         {
 517                 // FIXME: this only supports 3-letter extensions
 518                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 519                 if(fexists(s))
 520                 {
 521                         setmodel(e, s); // players have high precision
 522                         self.modelindex_lod1 = self.modelindex;
 523                 }
 524                 else
 525                         self.modelindex_lod1 = -1;
 526
 527                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 528                 if(fexists(s))
 529                 {
 530                         setmodel(e, s); // players have high precision
 531                         self.modelindex_lod2 = self.modelindex;
 532                 }
 533                 else
 534                         self.modelindex_lod2 = -1;
 535
 536                 precache_model(modelname);
 537                 setmodel(e, modelname); // players have high precision
 538                 self.modelindex_lod0 = self.modelindex;
 539
 540                 if(self.modelindex_lod1 < 0)
 541                         self.modelindex_lod1 = self.modelindex;
 542
 543                 if(self.modelindex_lod2 < 0)
 544                         self.modelindex_lod2 = self.modelindex;
 545         }
 546         else
 547         {
 548                 precache_model(modelname);
 549                 setmodel(e, modelname); // players have high precision
 550                 self.modelindex_lod0 = self.modelindex;
 551                         // save it for possible player model forcing
 552         }
 553
 554         s = whichpack(self.model);
 555         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 556
 557         player_setupanimsformodel();
 558         UpdatePlayerSounds();
 559 }
 560
 561 /*
 562 =============
 563 PutObserverInServer
 564
 565 putting a client as observer in the server
 566 =============
 567 */
 568 void FixPlayermodel();
 569 void PutObserverInServer (void)
 570 {
 571         entity  spot;
 572
 573         race_PreSpawnObserver();
 574
 575         spot = SelectSpawnPoint (TRUE);
 576         if(!spot)
 577                 error("No spawnpoints for observers?!?\n");
 578         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 579
 580         if(clienttype(self) == CLIENTTYPE_REAL)
 581         {
 582                 msg_entity = self;
 583                 WriteByte(MSG_ONE, SVC_SETVIEW);
 584                 WriteEntity(MSG_ONE, self);
 585         }
 586
 587         DropAllRunes(self);
 588
 589         Portal_ClearAll(self);
 590
 591         if(self.flagcarried)
 592                 DropFlag(self.flagcarried, world, world);
 593
 594         if(self.ballcarried)
 595                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 596
 597         WaypointSprite_PlayerDead();
 598
 599         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 600                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 601
 602         if(self.killcount != -666) {
 603                 if(g_lms) {
 604                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 605                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 606                         else
 607                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 608                 } else
 609                         bprint ("^4", self.netname, "^4 is spectating now\n");
 610
 611                 if(self.just_joined == FALSE) {
 612                         LogTeamchange(self.playerid, -1, 4);
 613                 } else
 614                         self.just_joined = FALSE;
 615         }
 616
 617         PlayerScore_Clear(self); // clear scores when needed
 618
 619         self.spectatortime = time;
 620
 621         self.classname = "observer";
 622         self.iscreature = FALSE;
 623         self.health = -666;
 624         self.takedamage = DAMAGE_NO;
 625         self.solid = SOLID_NOT;
 626         self.movetype = MOVETYPE_NOCLIP;
 627         self.flags = FL_CLIENT | FL_NOTARGET;
 628         self.armorvalue = 666;
 629         self.effects = 0;
 630         self.armorvalue = cvar("g_balance_armor_start");
 631         self.pauserotarmor_finished = 0;
 632         self.pauserothealth_finished = 0;
 633         self.pauseregen_finished = 0;
 634         self.damageforcescale = 0;
 635         self.death_time = 0;
 636         self.dead_frame = 0;
 637         self.alpha = 0;
 638         self.scale = 0;
 639         self.fade_time = 0;
 640         self.pain_frame = 0;
 641         self.pain_finished = 0;
 642         self.strength_finished = 0;
 643         self.invincible_finished = 0;
 644         self.pushltime = 0;
 645         self.think = SUB_Null;
 646         self.nextthink = 0;
 647         self.hook_time = 0;
 648         self.runes = 0;
 649         self.deadflag = DEAD_NO;
 650         self.angles = spot.angles;
 651         self.angles_z = 0;
 652         self.fixangle = TRUE;
 653         self.crouch = FALSE;
 654
 655         self.view_ofs = PL_VIEW_OFS;
 656         setorigin (self, spot.origin);
 657         setsize (self, '0 0 0', '0 0 0');
 658         self.prevorigin = self.origin;
 659         self.items = 0;
 660         self.weapons = 0;
 661         self.model = "";
 662         FixPlayermodel();
 663         self.model = "";
 664         self.modelindex = 0;
 665         self.weapon = 0;
 666         self.weaponmodel = "";
 667         self.weaponentity = world;
 668         self.exteriorweaponentity = world;
 669         self.killcount = -666;
 670         self.velocity = '0 0 0';
 671         self.avelocity = '0 0 0';
 672         self.punchangle = '0 0 0';
 673         self.punchvector = '0 0 0';
 674         self.oldvelocity = self.velocity;
 675         self.fire_endtime = -1;
 676
 677         if(sv_loddistance1)
 678                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 679
 680         if(g_arena)
 681         {
 682                 if(self.version_mismatch)
 683                 {
 684                         Spawnqueue_Unmark(self);
 685                         Spawnqueue_Remove(self);
 686                 }
 687                 else
 688                 {
 689                         Spawnqueue_Insert(self);
 690                 }
 691         }
 692         else if(g_lms)
 693         {
 694                 // Only if the player cannot play at all
 695                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 696                         self.frags = FRAGS_SPECTATOR;
 697                 else
 698                         self.frags = FRAGS_LMS_LOSER;
 699         }
 700         else
 701                 self.frags = FRAGS_SPECTATOR;
 702
 703         MUTATOR_CALLHOOK(MakePlayerObserver);
 704 }
 705
 706 float RestrictSkin(float s)
 707 {
 708         if(!teams_matter)
 709                 return s;
 710         if(s == 6)
 711                 return 6;
 712         return mod(s, 3);
 713 }
 714
 715 void FixPlayermodel()
 716 {
 717         local string defaultmodel;
 718         local float defaultskin, chmdl, oldskin;
 719         local vector m1, m2;
 720
 721         defaultmodel = "";
 722
 723         if(cvar("sv_defaultcharacter") == 1) {
 724                 defaultskin = 0;
 725
 726                 if(teams_matter)
 727                 {
 728                         string s;
 729                         s = Team_ColorNameLowerCase(self.team);
 730                         if(s != "neutral")
 731                         {
 732                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 733                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 734                         }
 735                 }
 736
 737                 if(defaultmodel == "")
 738                 {
 739                         defaultmodel = cvar_string("sv_defaultplayermodel");
 740                         defaultskin = cvar("sv_defaultplayerskin");
 741                 }
 742         }
 743
 744         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 745         {
 746                 if(self.model != "")
 747                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 748                 self.model = ""; // force the != checks to return true
 749         }
 750
 751         if(defaultmodel != "")
 752         {
 753                 if (defaultmodel != self.model)
 754                 {
 755                         m1 = self.mins;
 756                         m2 = self.maxs;
 757                         setmodel_lod (self, defaultmodel);
 758                         setsize (self, m1, m2);
 759                         chmdl = TRUE;
 760                 }
 761
 762                 oldskin = self.skinindex;
 763                 self.skinindex = defaultskin;
 764         } else {
 765                 if (self.playermodel != self.model || self.playermodel == "")
 766                 {
 767                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 768                         m1 = self.mins;
 769                         m2 = self.maxs;
 770                         setmodel_lod (self, self.playermodel);
 771                         setsize (self, m1, m2);
 772                         chmdl = TRUE;
 773                 }
 774
 775                 oldskin = self.skinindex;
 776                 self.skinindex = RestrictSkin(stof(self.playerskin));
 777         }
 778
 779         if(chmdl || oldskin != self.skinindex)
 780                 self.species = player_getspecies(); // model or skin has changed
 781
 782         if(!teams_matter)
 783                 if(strlen(cvar_string("sv_defaultplayercolors")))
 784                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 785                                 setcolor(self, cvar("sv_defaultplayercolors"));
 786 }
 787
 788 void PlayerTouchExplode(entity p1, entity p2)
 789 {
 790         vector org;
 791         org = (p1.origin + p2.origin) * 0.5;
 792         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 793
 794         te_explosion(org);
 795
 796         entity e;
 797         e = spawn();
 798         setorigin(e, org);
 799         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 800         remove(e);
 801 }
 802
 803 /*
 804 =============
 805 PutClientInServer
 806
 807 Called when a client spawns in the server
 808 =============
 809 */
 810 //void() ctf_playerchanged;
 811 void PutClientInServer (void)
 812 {
 813         if(clienttype(self) == CLIENTTYPE_BOT)
 814         {
 815                 self.classname = "player";
 816         }
 817         else if(clienttype(self) == CLIENTTYPE_REAL)
 818         {
 819                 msg_entity = self;
 820                 WriteByte(MSG_ONE, SVC_SETVIEW);
 821                 WriteEntity(MSG_ONE, self);
 822         }
 823
 824         // player is dead and becomes observer
 825         // FIXME fix LMS scoring for new system
 826         if(g_lms)
 827         {
 828                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 829                         self.classname = "observer";
 830         }
 831
 832         if(g_arena || (g_ca && !allowed_to_spawn))
 833         if(!self.spawned)
 834                 self.classname = "observer";
 835
 836         if(gameover)
 837                 self.classname = "observer";
 838
 839         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 840                 entity spot, oldself;
 841                 float j;
 842
 843                 if(self.team < 0)
 844                         JoinBestTeam(self, FALSE, TRUE);
 845
 846                 race_PreSpawn();
 847
 848                 spot = SelectSpawnPoint (FALSE);
 849                 if(!spot)
 850                 {
 851                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 852                         return; // spawn failed
 853                 }
 854
 855                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 856
 857                 self.classname = "player";
 858                 self.wasplayer = TRUE;
 859                 self.iscreature = TRUE;
 860                 self.movetype = MOVETYPE_WALK;
 861                 self.solid = SOLID_SLIDEBOX;
 862                 if(cvar("g_playerclip_collisions"))
 863                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 864                 else
 865                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 866                 self.frags = FRAGS_PLAYER;
 867                 if(independent_players)
 868                         MAKE_INDEPENDENT_PLAYER(self);
 869                 self.flags = FL_CLIENT;
 870                 self.takedamage = DAMAGE_AIM;
 871                 if(g_minstagib)
 872                         self.effects = EF_FULLBRIGHT;
 873                 else
 874                         self.effects = 0;
 875                 self.air_finished = time + 12;
 876                 self.dmg = 2;
 877
 878                 if(inWarmupStage)
 879                 {
 880                         self.ammo_shells = warmup_start_ammo_shells;
 881                         self.ammo_nails = warmup_start_ammo_nails;
 882                         self.ammo_rockets = warmup_start_ammo_rockets;
 883                         self.ammo_cells = warmup_start_ammo_cells;
 884                         self.ammo_fuel = warmup_start_ammo_fuel;
 885                         self.health = warmup_start_health;
 886                         self.armorvalue = warmup_start_armorvalue;
 887                         self.weapons = warmup_start_weapons;
 888                 }
 889                 else
 890                 {
 891                         self.ammo_shells = start_ammo_shells;
 892                         self.ammo_nails = start_ammo_nails;
 893                         self.ammo_rockets = start_ammo_rockets;
 894                         self.ammo_cells = start_ammo_cells;
 895                         self.ammo_fuel = start_ammo_fuel;
 896                         self.health = start_health;
 897                         self.armorvalue = start_armorvalue;
 898                         self.weapons = start_weapons;
 899                 }
 900
 901                 if(g_weaponarena_random)
 902                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 903
 904                 self.items = start_items;
 905                 self.jump_interval = time;
 906
 907                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 908                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 909                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 910                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 911                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 912                 //extend the pause of rotting if client was reset at the beginning of the countdown
 913                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 914                         self.spawnshieldtime += game_starttime - time;
 915                         self.pauserotarmor_finished += game_starttime - time;
 916                         self.pauserothealth_finished += game_starttime - time;
 917                         self.pauseregen_finished += game_starttime - time;
 918                 }
 919                 self.damageforcescale = 2;
 920                 self.death_time = 0;
 921                 self.dead_frame = 0;
 922                 self.alpha = 0;
 923                 self.scale = 0;
 924                 self.fade_time = 0;
 925                 self.pain_frame = 0;
 926                 self.pain_finished = 0;
 927                 self.strength_finished = 0;
 928                 self.invincible_finished = 0;
 929                 self.pushltime = 0;
 930                 // players have no think function
 931                 self.think = SUB_Null;
 932                 self.nextthink = 0;
 933                 self.hook_time = 0;
 934                 self.dmg_team = 0;
 935
 936                 self.metertime = 0;
 937
 938                 self.runes = 0;
 939
 940                 self.deadflag = DEAD_NO;
 941
 942                 self.angles = spot.angles;
 943
 944                 self.angles_z = 0; // never spawn tilted even if the spot says to
 945                 self.fixangle = TRUE; // turn this way immediately
 946                 self.velocity = '0 0 0';
 947                 self.avelocity = '0 0 0';
 948                 self.punchangle = '0 0 0';
 949                 self.punchvector = '0 0 0';
 950                 self.oldvelocity = self.velocity;
 951                 self.fire_endtime = -1;
 952
 953                 msg_entity = self;
 954                 WRITESPECTATABLE_MSG_ONE({
 955                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 956                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 957                 });
 958
 959                 if(sv_loddistance1)
 960                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 961
 962                 self.model = "";
 963                 FixPlayermodel();
 964
 965                 self.crouch = FALSE;
 966                 self.view_ofs = PL_VIEW_OFS;
 967                 setsize (self, PL_MIN, PL_MAX);
 968                 self.spawnorigin = spot.origin;
 969                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 970                 // don't reset back to last position, even if new position is stuck in solid
 971                 self.oldorigin = self.origin;
 972                 self.prevorigin = self.origin;
 973                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 974
 975                 if(g_arena)
 976                 {
 977                         Spawnqueue_Remove(self);
 978                         Spawnqueue_Mark(self);
 979                 }
 980
 981                 else if(g_ca)
 982                         self.caplayer = 1;
 983
 984                 self.event_damage = PlayerDamage;
 985
 986                 self.bot_attack = TRUE;
 987
 988                 self.statdraintime = time + 5;
 989                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 990
 991                 if(self.killcount == -666) {
 992                         PlayerScore_Clear(self);
 993                         self.killcount = 0;
 994                 }
 995
 996                 self.cnt = WEP_LASER;
 997
 998                 CL_SpawnWeaponentity();
 999                 self.alpha = default_player_alpha;
1000                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1001                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1002
1003                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1004                 self.lms_traveled_distance = 0;
1005                 self.speedrunning = FALSE;
1006
1007                 race_PostSpawn(spot);
1008
1009                 if(cvar("spawn_debug"))
1010                 {
1011                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1012                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1013                 }
1014
1015                 //stuffcmd(self, "chase_active 0");
1016                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1017
1018                 if (cvar("g_spawnsound"))
1019                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1020
1021                 if(g_assault) {
1022                         if(self.team == assault_attacker_team)
1023                                 centerprint(self, "You are attacking!");
1024                         else
1025                                 centerprint(self, "You are defending!");
1026                 }
1027
1028                 target_voicescript_clear(self);
1029
1030                 // reset fields the weapons may use
1031                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1032                         weapon_action(j, WR_RESETPLAYER);
1033
1034                 oldself = self;
1035                 self = spot;
1036                         activator = oldself;
1037                                 SUB_UseTargets();
1038                         activator = world;
1039                 self = oldself;
1040
1041                 MUTATOR_CALLHOOK(PlayerSpawn);
1042
1043                 self.switchweapon = w_getbestweapon(self);
1044                 self.cnt = self.switchweapon;
1045                 self.weapon = 0;
1046         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1047                 PutObserverInServer ();
1048         }
1049
1050         //if(g_ctf)
1051         //      ctf_playerchanged();
1052 }
1053
1054 float ClientInit_SendEntity(entity to, float sf)
1055 {
1056         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1057         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1058         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1059         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1060         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1061         if(sv_foginterval && world.fog != "")
1062                 WriteString(MSG_ENTITY, world.fog);
1063         else
1064                 WriteString(MSG_ENTITY, "");
1065         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1066         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1067         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1068         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1069         return TRUE;
1070 }
1071
1072 void ClientInit_CheckUpdate()
1073 {
1074         self.nextthink = time;
1075         if(self.count != cvar("g_balance_armor_blockpercent"))
1076         {
1077                 self.count = cvar("g_balance_armor_blockpercent");
1078                 self.SendFlags |= 1;
1079         }
1080         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1081         {
1082                 self.cnt = cvar("g_balance_weaponswitchdelay");
1083                 self.SendFlags |= 1;
1084         }
1085         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1086         {
1087                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1088                 self.SendFlags |= 1;
1089         }
1090         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1091         {
1092                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1093                 self.SendFlags |= 1;
1094         }
1095 }
1096
1097 void ClientInit_Spawn()
1098 {
1099         entity o;
1100         entity e;
1101         e = spawn();
1102         e.classname = "clientinit";
1103         e.think = ClientInit_CheckUpdate;
1104         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1105
1106         o = self;
1107         self = e;
1108         ClientInit_CheckUpdate();
1109         self = o;
1110 }
1111
1112 /*
1113 =============
1114 SetNewParms
1115 =============
1116 */
1117 void SetNewParms (void)
1118 {
1119         // initialize parms for a new player
1120         parm1 = -(86400 * 366);
1121 }
1122
1123 /*
1124 =============
1125 SetChangeParms
1126 =============
1127 */
1128 void SetChangeParms (void)
1129 {
1130         // save parms for level change
1131         parm1 = self.parm_idlesince - time;
1132 }
1133
1134 /*
1135 =============
1136 DecodeLevelParms
1137 =============
1138 */
1139 void DecodeLevelParms (void)
1140 {
1141         // load parms
1142         self.parm_idlesince = parm1;
1143         if(self.parm_idlesince == -(86400 * 366))
1144                 self.parm_idlesince = time;
1145
1146         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1147         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1148 }
1149
1150 /*
1151 =============
1152 ClientKill
1153
1154 Called when a client types 'kill' in the console
1155 =============
1156 */
1157
1158 void ClientKill_Now_TeamChange()
1159 {
1160         if(self.killindicator_teamchange == -1)
1161         {
1162                 self.team = -1;
1163                 JoinBestTeam( self, FALSE, FALSE );
1164         }
1165         else
1166                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1167 }
1168
1169 void ClientKill_Now()
1170 {
1171         if(self.killindicator_teamchange)
1172                 ClientKill_Now_TeamChange();
1173
1174         // in any case:
1175         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1176
1177         if(self.killindicator)
1178         {
1179                 dprint("Cleaned up after a leaked kill indicator.\n");
1180                 remove(self.killindicator);
1181                 self.killindicator = world;
1182         }
1183 }
1184 void KillIndicator_Think()
1185 {
1186         if (!self.owner.modelindex)
1187         {
1188                 self.owner.killindicator = world;
1189                 remove(self);
1190                 return;
1191         }
1192
1193         if(self.cnt <= 0)
1194         {
1195                 self = self.owner;
1196                 ClientKill_Now(); // no oldself needed
1197                 return;
1198         }
1199         else
1200         {
1201                 if(self.cnt <= 10)
1202                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1203                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1204                 {
1205                         if(self.cnt <= 10)
1206                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1207                         if(self.owner.killindicator_teamchange)
1208                         {
1209                                 if(self.owner.killindicator_teamchange == -1)
1210                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1211                                 else
1212                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1213                         }
1214                         else
1215                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1216                 }
1217                 self.nextthink = time + 1;
1218                 self.cnt -= 1;
1219         }
1220 }
1221
1222 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1223 {
1224         float killtime;
1225         entity e;
1226         killtime = cvar("g_balance_kill_delay");
1227
1228         if(g_race_qualifying)
1229                 killtime = 0;
1230
1231         self.killindicator_teamchange = targetteam;
1232
1233         if(!self.killindicator)
1234         {
1235                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1236                 {
1237                         ClientKill_Now();
1238                 }
1239                 else
1240                 {
1241                         self.killindicator = spawn();
1242                         self.killindicator.owner = self;
1243                         self.killindicator.scale = 0.5;
1244                         setattachment(self.killindicator, self, "");
1245                         setorigin(self.killindicator, '0 0 52');
1246                         self.killindicator.think = KillIndicator_Think;
1247                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1248                         self.killindicator.cnt = ceil(killtime);
1249                         self.killindicator.count = bound(0, ceil(killtime), 10);
1250                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1251
1252                         for(e = world; (e = find(e, classname, "body")) != world; )
1253                         {
1254                                 if(e.enemy != self)
1255                                         continue;
1256                                 e.killindicator = spawn();
1257                                 e.killindicator.owner = e;
1258                                 e.killindicator.scale = 0.5;
1259                                 setattachment(e.killindicator, e, "");
1260                                 setorigin(e.killindicator, '0 0 52');
1261                                 e.killindicator.think = KillIndicator_Think;
1262                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1263                                 e.killindicator.cnt = ceil(killtime);
1264                         }
1265                         self.lip = 0;
1266                 }
1267         }
1268         if(self.killindicator)
1269         {
1270                 if(targetteam)
1271                         self.killindicator.colormod = TeamColor(targetteam);
1272                 else
1273                         self.killindicator.colormod = '0 0 0';
1274         }
1275 }
1276
1277 void ClientKill (void)
1278 {
1279         ClientKill_TeamChange(0);
1280 }
1281
1282 void DoTeamChange(float destteam)
1283 {
1284         float t, c0;
1285         if(!teams_matter)
1286         {
1287                 if(destteam >= 0)
1288                         SetPlayerColors(self, destteam);
1289                 return;
1290         }
1291         if(self.classname == "player")
1292         if(destteam == -1)
1293         {
1294                 CheckAllowedTeams(self);
1295                 t = FindSmallestTeam(self, TRUE);
1296                 switch(self.team)
1297                 {
1298                         case COLOR_TEAM1: c0 = c1; break;
1299                         case COLOR_TEAM2: c0 = c2; break;
1300                         case COLOR_TEAM3: c0 = c3; break;
1301                         case COLOR_TEAM4: c0 = c4; break;
1302                         default:          c0 = 999;
1303                 }
1304                 switch(t)
1305                 {
1306                         case 1:
1307                                 if(c0 > c1)
1308                                         destteam = COLOR_TEAM1;
1309                                 break;
1310                         case 2:
1311                                 if(c0 > c2)
1312                                         destteam = COLOR_TEAM2;
1313                                 break;
1314                         case 3:
1315                                 if(c0 > c3)
1316                                         destteam = COLOR_TEAM3;
1317                                 break;
1318                         case 4:
1319                                 if(c0 > c4)
1320                                         destteam = COLOR_TEAM4;
1321                                 break;
1322                 }
1323                 if(destteam == -1)
1324                         return;
1325         }
1326         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1327                 return;
1328         ClientKill_TeamChange(destteam);
1329 }
1330
1331 void FixClientCvars(entity e)
1332 {
1333         // send prediction settings to the client
1334         stuffcmd(e, "\nin_bindmap 0 0\n");
1335         if(g_race || g_cts)
1336                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1337         if(cvar("g_antilag") == 3) // client side hitscan
1338                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1339                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1340         /*
1341          * we no longer need to stuff this. Remove this comment block if you feel
1342          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1343         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1344         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1345         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1346         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1347         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1348         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1349         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1350         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1351         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1352         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1353         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1354         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1355         stuffcmd(e, "cl_movement_edgefriction 1\n");
1356          */
1357 }
1358
1359 /*
1360 =============
1361 ClientConnect
1362
1363 Called when a client connects to the server
1364 =============
1365 */
1366 //void ctf_clientconnect();
1367 string ColoredTeamName(float t);
1368 void DecodeLevelParms (void);
1369 //void dom_player_join_team(entity pl);
1370 #ifdef UID
1371 .float uid_kicktime;
1372 .string uid;
1373 #endif
1374 void ClientConnect (void)
1375 {
1376         float t;
1377
1378         if(self.flags & FL_CLIENT)
1379         {
1380                 print("Warning: ClientConnect, but already connected!\n");
1381                 return;
1382         }
1383
1384         if(Ban_MaybeEnforceBan(self))
1385                 return;
1386
1387         DecodeLevelParms();
1388
1389         self.classname = "player_joining";
1390
1391         self.flags = FL_CLIENT;
1392         self.version_nagtime = time + 10 + random() * 10;
1393
1394         if(player_count<0)
1395         {
1396                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1397                 player_count = 0;
1398         }
1399
1400         PlayerScore_Attach(self);
1401         ClientData_Attach();
1402
1403         bot_clientconnect();
1404
1405         playerdemo_init();
1406
1407         anticheat_init();
1408
1409         race_PreSpawnObserver();
1410
1411         //if(g_domination)
1412         //      dom_player_join_team(self);
1413
1414         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1415
1416         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1417                 self.classname = "observer";
1418         } else {
1419                 if(teams_matter)
1420                 {
1421                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1422                         {
1423                                 self.classname = "player";
1424                                 campaign_bots_may_start = 1;
1425                         }
1426                         else
1427                         {
1428                                 self.classname = "observer"; // do it anyway
1429                         }
1430                 }
1431                 else
1432                 {
1433                         self.classname = "player";
1434                         campaign_bots_may_start = 1;
1435                 }
1436         }
1437
1438         self.playerid = (playerid_last = playerid_last + 1);
1439
1440         if(cvar("sv_eventlog"))
1441                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1442
1443         LogTeamchange(self.playerid, self.team, 1);
1444
1445         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1446
1447         self.netname_previous = strzone(self.netname);
1448
1449         bprint("^4", self.netname, "^4 connected");
1450
1451         if(self.classname != "observer" && (g_domination || g_ctf))
1452                 bprint(" and joined the ", ColoredTeamName(self.team));
1453
1454         bprint("\n");
1455
1456         self.welcomemessage_time = 0;
1457
1458         stuffcmd(self, strcat(clientstuff, "\n"));
1459         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1460         stuffcmd(self, "cl_particles_reloadeffects\n");
1461
1462         FixClientCvars(self);
1463
1464         // spawnfunc_waypoint sprites
1465         WaypointSprite_InitClient(self);
1466
1467         // Wazat's grappling hook
1468         SetGrappleHookBindings();
1469
1470         // get autoswitch state from player when he toggles it
1471         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1472
1473         // get version info from player
1474         stuffcmd(self, "cmd clientversion $gameversion\n");
1475
1476         // get other cvars from player
1477         GetCvars(0);
1478
1479         // set cvar for team scoreboard
1480         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1481
1482         // notify about available teams
1483         if(teams_matter)
1484         {
1485                 CheckAllowedTeams(self);
1486                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1487                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1488         }
1489         else
1490                 stuffcmd(self, "set _teams_available 0\n");
1491
1492         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1493
1494         if(g_arena || g_ca)
1495         {
1496                 self.classname = "observer";
1497                 if(g_arena)
1498                         Spawnqueue_Insert(self);
1499         }
1500         /*else if(g_ctf)
1501         {
1502                 ctf_clientconnect();
1503         }*/
1504
1505         if(teams_matter || radar_showennemies)
1506                 attach_entcs();
1507
1508         bot_relinkplayerlist();
1509
1510         self.spectatortime = time;
1511         if(blockSpectators)
1512         {
1513                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1514         }
1515
1516         self.jointime = time;
1517         self.allowedTimeouts = cvar("sv_timeout_number");
1518
1519         if(clienttype(self) == CLIENTTYPE_REAL)
1520         {
1521                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1522                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1523         }
1524
1525         if(g_lms)
1526         {
1527                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1528                 {
1529                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1530                         self.frags = FRAGS_SPECTATOR;
1531                 }
1532         }
1533
1534         if(!sv_foginterval && world.fog != "")
1535                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1536
1537         SoundEntity_Attach(self);
1538
1539         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1540         {
1541                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1542                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1543         }
1544         else
1545                 self.hitplotfh = -1;
1546
1547 #ifdef UID
1548         if(clienttype(self) == CLIENTTYPE_REAL)
1549         if not(self.uid)
1550                 self.uid_kicktime = time + 60;
1551 #endif
1552
1553         if(g_race || g_cts) {
1554                 string rr;
1555                 if(g_cts)
1556                         rr = CTS_RECORD;
1557                 else
1558                         rr = RACE_RECORD;
1559                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1560
1561                 race_send_recordtime(MSG_ONE);
1562                 race_send_speedaward(MSG_ONE);
1563
1564                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1565                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1566                 race_send_speedaward_alltimebest(MSG_ONE);
1567
1568                 float i;
1569                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1570                         race_SendRankings(i, 0, 0, MSG_ONE);
1571                 }
1572         }
1573         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1574                 send_CSQC_teamnagger();
1575
1576         CheatInitClient();
1577 }
1578
1579 /*
1580 =============
1581 ClientDisconnect
1582
1583 Called when a client disconnects from the server
1584 =============
1585 */
1586 .entity chatbubbleentity;
1587 .entity teambubbleentity;
1588 void ReadyCount();
1589 void ClientDisconnect (void)
1590 {
1591         if not(self.flags & FL_CLIENT)
1592         {
1593                 print("Warning: ClientDisconnect without ClientConnect\n");
1594                 return;
1595         }
1596
1597         CheatShutdownClient();
1598
1599         if(self.hitplotfh >= 0)
1600         {
1601                 fclose(self.hitplotfh);
1602                 self.hitplotfh = -1;
1603         }
1604
1605         anticheat_report();
1606         anticheat_shutdown();
1607
1608         playerdemo_shutdown();
1609
1610         bot_clientdisconnect();
1611
1612         if(self.entcs)
1613                 detach_entcs();
1614
1615         if(cvar("sv_eventlog"))
1616                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1617         bprint ("^4",self.netname);
1618         bprint ("^4 disconnected\n");
1619
1620         SoundEntity_Detach(self);
1621
1622         DropAllRunes(self);
1623         MUTATOR_CALLHOOK(ClientDisconnect);
1624
1625         Portal_ClearAll(self);
1626
1627         if(self.flagcarried)
1628                 DropFlag(self.flagcarried, world, world);
1629         if(self.ballcarried)
1630                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1631
1632         // Here, everything has been done that requires this player to be a client.
1633
1634         self.flags &~= FL_CLIENT;
1635
1636         if (self.chatbubbleentity)
1637                 remove (self.chatbubbleentity);
1638
1639         if (self.teambubbleentity)
1640                 remove (self.teambubbleentity);
1641
1642         if (self.killindicator)
1643                 remove (self.killindicator);
1644
1645         WaypointSprite_PlayerGone();
1646
1647         bot_relinkplayerlist();
1648
1649         // remove laserdot
1650         if(self.weaponentity)
1651                 if(self.weaponentity.lasertarget)
1652                         remove(self.weaponentity.lasertarget);
1653
1654         if(g_arena)
1655         {
1656                 Spawnqueue_Unmark(self);
1657                 Spawnqueue_Remove(self);
1658         }
1659
1660         ClientData_Detach();
1661         PlayerScore_Detach(self);
1662
1663         if(self.netname_previous)
1664                 strunzone(self.netname_previous);
1665         if(self.clientstatus)
1666                 strunzone(self.clientstatus);
1667
1668         ClearPlayerSounds();
1669
1670         if(self.personal)
1671                 remove(self.personal);
1672
1673         self.playerid = 0;
1674         ReadyCount();
1675
1676         // free cvars
1677         GetCvars(-1);
1678 }
1679
1680 .float BUTTON_CHAT;
1681 void ChatBubbleThink()
1682 {
1683         self.nextthink = time;
1684         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1685         {
1686                 if(self.owner) // but why can that ever be world?
1687                         self.owner.chatbubbleentity = world;
1688                 remove(self);
1689                 return;
1690         }
1691         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1692 #ifdef TETRIS
1693                 || self.owner.tetris_on
1694 #endif
1695         )
1696                 self.model = self.mdl;
1697         else
1698                 self.model = "";
1699 };
1700
1701 void UpdateChatBubble()
1702 {
1703         if (!self.modelindex)
1704                 return;
1705         // spawn a chatbubble entity if needed
1706         if (!self.chatbubbleentity)
1707         {
1708                 self.chatbubbleentity = spawn();
1709                 self.chatbubbleentity.owner = self;
1710                 self.chatbubbleentity.exteriormodeltoclient = self;
1711                 self.chatbubbleentity.think = ChatBubbleThink;
1712                 self.chatbubbleentity.nextthink = time;
1713                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1714                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1715                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1716                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1717                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1718                 self.chatbubbleentity.model = "";
1719                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1720         }
1721 }
1722
1723
1724 void TeamBubbleThink()
1725 {
1726         self.nextthink = time;
1727         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1728         {
1729                 if(self.owner) // but why can that ever be world?
1730                         self.owner.teambubbleentity = world;
1731                 remove(self);
1732                 return;
1733         }
1734 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1735         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1736                 self.model = "";
1737         else
1738                 self.model = self.mdl;
1739
1740 };
1741
1742 float TeamBubble_customizeentityforclient()
1743 {
1744         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1745 }
1746
1747 void UpdateTeamBubble()
1748 {
1749         if (!self.modelindex || !teams_matter)
1750                 return;
1751         // spawn a teambubble entity if needed
1752         if (!self.teambubbleentity && teams_matter)
1753         {
1754                 self.teambubbleentity = spawn();
1755                 self.teambubbleentity.owner = self;
1756                 self.teambubbleentity.exteriormodeltoclient = self;
1757                 self.teambubbleentity.think = TeamBubbleThink;
1758                 self.teambubbleentity.nextthink = time;
1759                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1760 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1761                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1762                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1763                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1764                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1765                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1766                 self.teambubbleentity.effects = EF_LOWPRECISION;
1767         }
1768 }
1769
1770 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1771 // added to the model skins
1772 /*void UpdateColorModHack()
1773 {
1774         local float c;
1775         c = self.clientcolors & 15;
1776         // LordHavoc: only bothering to support white, green, red, yellow, blue
1777              if (!teams_matter) self.colormod = '0 0 0';
1778         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1779         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1780         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1781         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1782         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1783         else self.colormod = '1 1 1';
1784 };*/
1785
1786 .float oldcolormap;
1787 void respawn(void)
1788 {
1789         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1790         {
1791                 self.solid = SOLID_NOT;
1792                 self.takedamage = DAMAGE_NO;
1793                 self.movetype = MOVETYPE_FLY;
1794                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1795                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1796                 self.effects |= EF_ADDITIVE;
1797                 self.oldcolormap = self.colormap;
1798                 self.colormap = 512;
1799                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1800                 if(cvar("g_respawn_ghosts_maxtime"))
1801                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1802         }
1803
1804         CopyBody(1);
1805         self.effects |= EF_NODRAW; // prevent another CopyBody
1806         if(self.oldcolormap)
1807         {
1808                 self.colormap = self.oldcolormap;
1809                 self.oldcolormap = 0;
1810         }
1811         PutClientInServer();
1812 }
1813
1814 void play_countdown(float finished, string samp)
1815 {
1816         if(clienttype(self) == CLIENTTYPE_REAL)
1817                 if(floor(finished - time - frametime) != floor(finished - time))
1818                         if(finished - time < 6)
1819                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1820 }
1821
1822 /**
1823  * When sv_timeout is used this function returs strings like
1824  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1825  * Called by centerprint functions
1826  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1827  */
1828 string getTimeoutText(float addOneSecond) {
1829         if (!cvar("sv_timeout") || !timeoutStatus)
1830                 return "";
1831
1832         local string retStr;
1833         if (timeoutStatus == 1) {
1834                 if (addOneSecond == 1) {
1835                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1836                 }
1837                 else {
1838                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1839                 }
1840                 return retStr;
1841         }
1842         else if (timeoutStatus == 2) {
1843                 if (addOneSecond) {
1844                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1845                         //don't show messages like "Timeout ends in 0 seconds"...
1846                         if ((remainingTimeoutTime + 1) > 0)
1847                                 return retStr;
1848                         else
1849                                 return "";
1850                 }
1851                 else {
1852                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1853                         //don't show messages like "Timeout ends in 0 seconds"...
1854                         if (remainingTimeoutTime > 0)
1855                                 return retStr;
1856                         else
1857                                 return "";
1858                 }
1859         }
1860         else return "";
1861 }
1862
1863 void player_powerups (void)
1864 {
1865         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1866         {
1867                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1868                 self.modelflags |= MF_ROCKET;
1869         }
1870         else
1871         {
1872                 SoundEntity_StopSound(self, CHAN_PLAYER);
1873                 self.modelflags &~= MF_ROCKET;
1874         }
1875
1876         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1877
1878         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1879                 return;
1880
1881         Fire_ApplyDamage(self);
1882         Fire_ApplyEffect(self);
1883
1884         if (g_minstagib)
1885         {
1886                 self.effects |= EF_FULLBRIGHT;
1887
1888                 if (self.items & IT_STRENGTH)
1889                 {
1890                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1891                         if (time > self.strength_finished)
1892                         {
1893                                 self.alpha = default_player_alpha;
1894                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1895                                 self.items &~= IT_STRENGTH;
1896                                 sprint(self, "^3Invisibility has worn off\n");
1897                         }
1898                 }
1899                 else
1900                 {
1901                         if (time < self.strength_finished)
1902                         {
1903                                 self.alpha = g_minstagib_invis_alpha;
1904                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1905                                 self.items |= IT_STRENGTH;
1906                                 sprint(self, "^3You are invisible\n");
1907                         }
1908                 }
1909
1910                 if (self.items & IT_INVINCIBLE)
1911                 {
1912                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1913                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1914                         {
1915                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1916                                 sprint(self, "^3Speed has worn off\n");
1917                         }
1918                 }
1919                 else
1920                 {
1921                         if (time < self.invincible_finished)
1922                         {
1923                                 self.items = self.items | IT_INVINCIBLE;
1924                                 sprint(self, "^3You are on speed\n");
1925                         }
1926                 }
1927                 return;
1928         }
1929
1930         if (self.items & IT_STRENGTH)
1931         {
1932                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1933                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1934                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1935                 {
1936                         self.items = self.items - (self.items & IT_STRENGTH);
1937                         sprint(self, "^3Strength has worn off\n");
1938                 }
1939         }
1940         else
1941         {
1942                 if (time < self.strength_finished)
1943                 {
1944                         self.items = self.items | IT_STRENGTH;
1945                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1946                 }
1947         }
1948         if (self.items & IT_INVINCIBLE)
1949         {
1950                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1951                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1952                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1953                 {
1954                         self.items = self.items - (self.items & IT_INVINCIBLE);
1955                         sprint(self, "^3Shield has worn off\n");
1956                 }
1957         }
1958         else
1959         {
1960                 if (time < self.invincible_finished)
1961                 {
1962                         self.items = self.items | IT_INVINCIBLE;
1963                         sprint(self, "^3Shield surrounds you\n");
1964                 }
1965         }
1966
1967         if(cvar("g_nodepthtestplayers"))
1968                 self.effects = self.effects | EF_NODEPTHTEST;
1969
1970         if(cvar("g_fullbrightplayers"))
1971                 self.effects = self.effects | EF_FULLBRIGHT;
1972
1973         // midair gamemode: damage only while in the air
1974         // if in midair mode, being on ground grants temporary invulnerability
1975         // (this is so that multishot weapon don't clear the ground flag on the
1976         // first damage in the frame, leaving the player vulnerable to the
1977         // remaining hits in the same frame)
1978         if (self.flags & FL_ONGROUND)
1979         if (g_midair)
1980                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1981
1982         if (time >= game_starttime)
1983         if (time < self.spawnshieldtime)
1984                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1985 }
1986
1987 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1988 {
1989         if(current > stable)
1990                 return current;
1991         else if(current > stable - 0.25) // when close enough, "snap"
1992                 return stable;
1993         else
1994                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1995 }
1996
1997 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1998 {
1999         if(current < stable)
2000                 return current;
2001         else if(current < stable + 0.25) // when close enough, "snap"
2002                 return stable;
2003         else
2004                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2005 }
2006
2007 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2008 {
2009         if(current > rotstable)
2010         {
2011                 if(rotframetime > 0)
2012                 {
2013                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2014                         current = max(rotstable, current - rotlinear * rotframetime);
2015                 }
2016         }
2017         else if(current < regenstable)
2018         {
2019                 if(regenframetime > 0)
2020                 {
2021                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2022                         current = min(regenstable, current + regenlinear * regenframetime);
2023                 }
2024         }
2025
2026         if(current > limit)
2027                 current = limit;
2028
2029         return current;
2030 }
2031
2032 void player_regen (void)
2033 {
2034         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2035         maxh = cvar("g_balance_health_rotstable");
2036         maxa = cvar("g_balance_armor_rotstable");
2037         maxf = cvar("g_balance_fuel_rotstable");
2038         minh = cvar("g_balance_health_regenstable");
2039         mina = cvar("g_balance_armor_regenstable");
2040         minf = cvar("g_balance_fuel_regenstable");
2041         limith = cvar("g_balance_health_limit");
2042         limita = cvar("g_balance_armor_limit");
2043         limitf = cvar("g_balance_fuel_limit");
2044
2045         max_mod = regen_mod = rot_mod = limit_mod = 1;
2046
2047         if (self.runes & RUNE_REGEN)
2048         {
2049                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2050                 {
2051                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2052                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2053                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2054                 }
2055                 else
2056                 {
2057                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2058                         max_mod = cvar("g_balance_rune_regen_hpmod");
2059                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2060                 }
2061         }
2062         else if (self.runes & CURSE_VENOM)
2063         {
2064                 max_mod = cvar("g_balance_curse_venom_hpmod");
2065                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2066                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2067                 else
2068                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2069                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2070                 //if (!self.runes & RUNE_REGEN)
2071                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2072         }
2073         maxh = maxh * max_mod;
2074         //maxa = maxa * max_mod;
2075         //maxf = maxf * max_mod;
2076         minh = minh * max_mod;
2077         //mina = mina * max_mod;
2078         //minf = minf * max_mod;
2079         limith = limith * limit_mod;
2080         limita = limita * limit_mod;
2081         //limitf = limitf * limit_mod;
2082
2083         if(g_lms && g_ca)
2084                 rot_mod = 0;
2085
2086         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2087         {
2088                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2089                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2090
2091                 // if player rotted to death...  die!
2092                 if(self.health < 1)
2093                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2094         }
2095
2096         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2097                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2098 }
2099
2100 float zoomstate_set;
2101 void SetZoomState(float z)
2102 {
2103         if(z != self.zoomstate)
2104         {
2105                 self.zoomstate = z;
2106                 ClientData_Touch(self);
2107         }
2108         zoomstate_set = 1;
2109 }
2110
2111 void GetPressedKeys(void) {
2112         MUTATOR_CALLHOOK(GetPressedKeys);
2113         if (self.movement_x > 0) // get if movement keys are pressed
2114         {       // forward key pressed
2115                 self.pressedkeys |= KEY_FORWARD;
2116                 self.pressedkeys &~= KEY_BACKWARD;
2117         }
2118         else if (self.movement_x < 0)
2119         {       // backward key pressed
2120                 self.pressedkeys |= KEY_BACKWARD;
2121                 self.pressedkeys &~= KEY_FORWARD;
2122         }
2123         else
2124         {       // no x input
2125                 self.pressedkeys &~= KEY_FORWARD;
2126                 self.pressedkeys &~= KEY_BACKWARD;
2127         }
2128
2129         if (self.movement_y > 0)
2130         {       // right key pressed
2131                 self.pressedkeys |= KEY_RIGHT;
2132                 self.pressedkeys &~= KEY_LEFT;
2133         }
2134         else if (self.movement_y < 0)
2135         {       // left key pressed
2136                 self.pressedkeys |= KEY_LEFT;
2137                 self.pressedkeys &~= KEY_RIGHT;
2138         }
2139         else
2140         {       // no y input
2141                 self.pressedkeys &~= KEY_RIGHT;
2142                 self.pressedkeys &~= KEY_LEFT;
2143         }
2144
2145         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2146                 self.pressedkeys |= KEY_JUMP;
2147         else
2148                 self.pressedkeys &~= KEY_JUMP;
2149         if (self.BUTTON_CROUCH)
2150                 self.pressedkeys |= KEY_CROUCH;
2151         else
2152                 self.pressedkeys &~= KEY_CROUCH;
2153 }
2154
2155 void update_stats (float number, float hit, float fired) {
2156 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2157 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2158
2159         if(number) {
2160                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2161                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2162         } else {
2163                 self.stat_hit = hit * sv_accuracy_data_share;
2164                 self.stat_fired = fired * sv_accuracy_data_share;
2165         }
2166 }
2167
2168 /*
2169 ======================
2170 spectate mode routines
2171 ======================
2172 */
2173
2174 .float weapon_count;
2175 void SpectateCopy(entity spectatee) {
2176         if(spectatee.weapon_count < WEP_LAST) {
2177                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2178                 spectatee.weapon_count ++;
2179         } else
2180                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2181
2182         other = spectatee;
2183         MUTATOR_CALLHOOK(SpectateCopy);
2184         self.armortype = spectatee.armortype;
2185         self.armorvalue = spectatee.armorvalue;
2186         self.ammo_cells = spectatee.ammo_cells;
2187         self.ammo_shells = spectatee.ammo_shells;
2188         self.ammo_nails = spectatee.ammo_nails;
2189         self.ammo_rockets = spectatee.ammo_rockets;
2190         self.ammo_fuel = spectatee.ammo_fuel;
2191         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2192         self.health = spectatee.health;
2193         self.impulse = 0;
2194         self.items = spectatee.items;
2195         self.metertime = spectatee.metertime;
2196         self.strength_finished = spectatee.strength_finished;
2197         self.invincible_finished = spectatee.invincible_finished;
2198         self.pressedkeys = spectatee.pressedkeys;
2199         self.weapons = spectatee.weapons;
2200         self.switchweapon = spectatee.switchweapon;
2201         self.weapon = spectatee.weapon;
2202         self.punchangle = spectatee.punchangle;
2203         self.view_ofs = spectatee.view_ofs;
2204         self.v_angle = spectatee.v_angle;
2205         self.velocity = spectatee.velocity;
2206         self.dmg_take = spectatee.dmg_take;
2207         self.dmg_save = spectatee.dmg_save;
2208         self.dmg_inflictor = spectatee.dmg_inflictor;
2209         self.angles = spectatee.v_angle;
2210         self.fixangle = TRUE;
2211         setorigin(self, spectatee.origin);
2212         setsize(self, spectatee.mins, spectatee.maxs);
2213         SetZoomState(spectatee.zoomstate);
2214
2215         anticheat_spectatecopy(spectatee);
2216 }
2217
2218 float SpectateUpdate() {
2219         if(!self.enemy)
2220                 return 0;
2221
2222         if (self == self.enemy)
2223                 return 0;
2224
2225         if(self.enemy.classname != "player")
2226                 return 0;
2227
2228         SpectateCopy(self.enemy);
2229
2230         return 1;
2231 }
2232
2233 float SpectateNext() {
2234         other = find(self.enemy, classname, "player");
2235
2236         if (!other)
2237                 other = find(other, classname, "player");
2238
2239         if (other)
2240                 self.enemy = other;
2241
2242         if(self.enemy.classname == "player") {
2243                 msg_entity = self;
2244                 WriteByte(MSG_ONE, SVC_SETVIEW);
2245                 WriteEntity(MSG_ONE, self.enemy);
2246                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2247                 self.movetype = MOVETYPE_NONE;
2248
2249                 self.enemy.weapon_count = 0;
2250
2251                 if(!SpectateUpdate())
2252                         PutObserverInServer();
2253
2254                 return 1;
2255         } else {
2256                 return 0;
2257         }
2258 }
2259
2260 /*
2261 =============
2262 ShowRespawnCountdown()
2263
2264 Update a respawn countdown display.
2265 =============
2266 */
2267 void ShowRespawnCountdown()
2268 {
2269         float number;
2270         if(self.deadflag == DEAD_NO) // just respawned?
2271                 return;
2272         else
2273         {
2274                 number = ceil(self.death_time - time);
2275                 if(number <= 0)
2276                         return;
2277                 if(number <= self.respawn_countdown)
2278                 {
2279                         self.respawn_countdown = number - 1;
2280                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2281                                 AnnounceTo(self, strcat(ftos(number), ""));
2282                 }
2283         }
2284 }
2285
2286 void LeaveSpectatorMode()
2287 {
2288         if(isJoinAllowed()) {
2289                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2290                         self.classname = "player";
2291
2292                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2293                                 JoinBestTeam(self, FALSE, TRUE);
2294
2295                         if(cvar("g_campaign"))
2296                                 campaign_bots_may_start = 1;
2297
2298                         self.stat_count = WEP_LAST;
2299
2300                         PutClientInServer();
2301
2302                         if(self.classname == "player")
2303                                 bprint ("^4", self.netname, "^4 is playing now\n");
2304
2305                         if(!cvar("g_campaign"))
2306                                 centerprint(self,""); // clear MOTD
2307
2308                         return;
2309                 } else {
2310                         if (g_ca && self.caplayer) {
2311                         }       // do nothing
2312                         else
2313                                 stuffcmd(self,"menu_showteamselect\n");
2314                         return;
2315                 }
2316         }
2317         else {
2318                 //player may not join because of g_maxplayers is set
2319                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2320         }
2321 }
2322
2323 /**
2324  * Determines whether the player is allowed to join. This depends on cvar
2325  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2326  * it checks whether the number of currently playing players exceeds g_maxplayers.
2327  * @return bool TRUE if the player is allowed to join, false otherwise
2328  */
2329 float isJoinAllowed() {
2330         if (!cvar("g_maxplayers"))
2331                 return TRUE;
2332
2333         local entity e;
2334         local float currentlyPlaying;
2335         FOR_EACH_REALPLAYER(e) {
2336                 if(e.classname == "player")
2337                         currentlyPlaying += 1;
2338         }
2339         if(currentlyPlaying < cvar("g_maxplayers"))
2340                 return TRUE;
2341
2342         return FALSE;
2343 }
2344
2345 /**
2346  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2347  * g_maxplayers_spectator_blocktime seconds
2348  */
2349 void checkSpectatorBlock() {
2350         if(self.classname == "spectator" || self.classname == "observer") {
2351                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2352                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2353                         dropclient(self);
2354                 }
2355         }
2356 }
2357
2358 float vercmp_recursive(string v1, string v2)
2359 {
2360         float dot1, dot2;
2361         string s1, s2;
2362         float r;
2363
2364         dot1 = strstrofs(v1, ".", 0);
2365         dot2 = strstrofs(v2, ".", 0);
2366         if(dot1 == -1)
2367                 s1 = v1;
2368         else
2369                 s1 = substring(v1, 0, dot1);
2370         if(dot2 == -1)
2371                 s2 = v2;
2372         else
2373                 s2 = substring(v2, 0, dot2);
2374
2375         r = stof(s1) - stof(s2);
2376         if(r != 0)
2377                 return r;
2378
2379         r = strcasecmp(s1, s2);
2380         if(r != 0)
2381                 return r;
2382
2383         if(dot1 == -1)
2384                 if(dot2 == -1)
2385                         return 0;
2386                 else
2387                         return -1;
2388         else
2389                 if(dot2 == -1)
2390                         return 1;
2391                 else
2392                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2393 }
2394
2395 float vercmp(string v1, string v2)
2396 {
2397         if(strcasecmp(v1, v2) == 0) // early out check
2398                 return 0;
2399         return vercmp_recursive(v1, v2);
2400 }
2401
2402 void ObserverThink()
2403 {
2404         if (self.flags & FL_JUMPRELEASED) {
2405                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2406                         self.welcomemessage_time = 0;
2407                         self.flags &~= FL_JUMPRELEASED;
2408                         self.flags |= FL_SPAWNING;
2409                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2410                         self.welcomemessage_time = 0;
2411                         self.flags &~= FL_JUMPRELEASED;
2412                         if(SpectateNext() == 1) {
2413                                 self.classname = "spectator";
2414                         }
2415                 }
2416         } else {
2417                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2418                         self.flags |= FL_JUMPRELEASED;
2419                         if(self.flags & FL_SPAWNING)
2420                         {
2421                                 self.flags &~= FL_SPAWNING;
2422                                 LeaveSpectatorMode();
2423                                 return;
2424                         }
2425                 }
2426         }
2427         PrintWelcomeMessage(self);
2428 }
2429
2430 void SpectatorThink()
2431 {
2432         if (self.flags & FL_JUMPRELEASED) {
2433                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2434                         self.welcomemessage_time = 0;
2435                         self.flags &~= FL_JUMPRELEASED;
2436                         self.flags |= FL_SPAWNING;
2437                 } else if(self.BUTTON_ATCK) {
2438                         self.welcomemessage_time = 0;
2439                         self.flags &~= FL_JUMPRELEASED;
2440                         if(SpectateNext() == 1) {
2441                                 self.classname = "spectator";
2442                         } else {
2443                                 self.classname = "observer";
2444                                 self.stat_count = WEP_LAST;
2445                                 PutClientInServer();
2446                         }
2447                 } else if (self.BUTTON_ATCK2) {
2448                         self.welcomemessage_time = 0;
2449                         self.flags &~= FL_JUMPRELEASED;
2450                         self.classname = "observer";
2451                         self.stat_count = WEP_LAST;
2452                         PutClientInServer();
2453                 } else {
2454                         if(!SpectateUpdate())
2455                                 PutObserverInServer();
2456                 }
2457         } else {
2458                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2459                         self.flags |= FL_JUMPRELEASED;
2460                         if(self.flags & FL_SPAWNING)
2461                         {
2462                                 self.flags &~= FL_SPAWNING;
2463                                 LeaveSpectatorMode();
2464                                 return;
2465                         }
2466                 }
2467         }
2468
2469         PrintWelcomeMessage(self);
2470         self.flags |= FL_CLIENT | FL_NOTARGET;
2471 }
2472
2473 .float touchexplode_time;
2474
2475 /*
2476 =============
2477 PlayerPreThink
2478
2479 Called every frame for each client before the physics are run
2480 =============
2481 */
2482 void() ctf_setstatus;
2483 void() nexball_setstatus;
2484 .float items_added;
2485 void PlayerPreThink (void)
2486 {
2487         self.stat_game_starttime = game_starttime;
2488         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2489         self.stat_leadlimit = cvar("leadlimit");
2490
2491         if(frametime)
2492         {
2493                 // physics frames: update anticheat stuff
2494                 anticheat_prethink();
2495         }
2496
2497         if(blockSpectators && frametime)
2498                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2499                 checkSpectatorBlock();
2500
2501         zoomstate_set = 0;
2502
2503         if(self.netname_previous != self.netname)
2504         {
2505                 if(cvar("sv_eventlog"))
2506                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2507                 if(self.netname_previous)
2508                         strunzone(self.netname_previous);
2509                 self.netname_previous = strzone(self.netname);
2510         }
2511
2512         // version nagging
2513         if(self.version_nagtime)
2514                 if(self.cvar_g_xonoticversion)
2515                         if(time > self.version_nagtime)
2516                         {
2517                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2518                                 {
2519                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2520                                         {
2521                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2522                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2523                                         }
2524                                         else
2525                                         {
2526                                                 float r;
2527                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2528                                                 if(r < 0)
2529                                                 {
2530                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2531                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2532                                                 }
2533                                                 else if(r > 0)
2534                                                 {
2535                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2536                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2537                                                 }
2538                                         }
2539                                 }
2540                                 self.version_nagtime = 0;
2541                         }
2542
2543         // GOD MODE info
2544         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2545         {
2546                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2547                 self.max_armorvalue = 0;
2548         }
2549
2550 #ifdef TETRIS
2551         if (TetrisPreFrame())
2552                 return;
2553 #endif
2554
2555         MUTATOR_CALLHOOK(PlayerPreThink);
2556
2557         if(self.classname == "player") {
2558 //              if(self.netname == "Wazat")
2559 //                      bprint(self.classname, "\n");
2560
2561                 CheckRules_Player();
2562
2563                 PrintWelcomeMessage(self);
2564
2565                 if (intermission_running)
2566                 {
2567                         IntermissionThink ();   // otherwise a button could be missed between
2568                         return;                                 // the think tics
2569                 }
2570
2571                 if(self.teleport_time)
2572                 if(time > self.teleport_time)
2573                 {
2574                         self.teleport_time = 0;
2575                         self.effects = self.effects - (self.effects & EF_NODRAW);
2576                 }
2577
2578                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2579                         UpdateSelectedPlayer();
2580
2581                 //don't allow the player to turn around while game is paused!
2582                 if(timeoutStatus == 2) {
2583                         self.v_angle = self.lastV_angle;
2584                         self.angles = self.lastV_angle;
2585                         self.fixangle = TRUE;
2586                 }
2587
2588                 if(frametime)
2589                 {
2590                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2591                         player_powerups();
2592                 }
2593
2594                 if (self.deadflag != DEAD_NO)
2595                 {
2596                         float button_pressed, force_respawn;
2597                         if(self.personal && g_race_qualifying)
2598                         {
2599                                 if(time > self.death_time)
2600                                 {
2601                                         self.death_time = time + 1; // only retry once a second
2602                                         respawn();
2603                                         self.impulse = 141;
2604                                 }
2605                         }
2606                         else
2607                         {
2608                                 if(frametime)
2609                                         player_anim();
2610                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2611                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2612                                 if (self.deadflag == DEAD_DYING)
2613                                 {
2614                                         if(force_respawn)
2615                                                 self.deadflag = DEAD_RESPAWNING;
2616                                         else if(!button_pressed)
2617                                                 self.deadflag = DEAD_DEAD;
2618                                 }
2619                                 else if (self.deadflag == DEAD_DEAD)
2620                                 {
2621                                         if(button_pressed)
2622                                                 self.deadflag = DEAD_RESPAWNABLE;
2623                                 }
2624                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2625                                 {
2626                                         if(!button_pressed)
2627                                                 self.deadflag = DEAD_RESPAWNING;
2628                                 }
2629                                 else if (self.deadflag == DEAD_RESPAWNING)
2630                                 {
2631                                         if(time > self.death_time)
2632                                         {
2633                                                 self.death_time = time + 1; // only retry once a second
2634                                                 respawn();
2635                                         }
2636                                 }
2637                                 ShowRespawnCountdown();
2638                         }
2639                         return;
2640                 }
2641
2642                 if(g_touchexplode)
2643                 if(time > self.touchexplode_time)
2644                 if(self.classname == "player")
2645                 if(self.deadflag == DEAD_NO)
2646                 if not(IS_INDEPENDENT_PLAYER(self))
2647                 FOR_EACH_PLAYER(other) if(self != other)
2648                 {
2649                         if(time > other.touchexplode_time)
2650                         if(other.classname == "player")
2651                         if(other.deadflag == DEAD_NO)
2652                         if not(IS_INDEPENDENT_PLAYER(other))
2653                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2654                         {
2655                                 PlayerTouchExplode(self, other);
2656                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2657                         }
2658                 }
2659
2660                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2661                 {
2662                         vector dist;
2663
2664                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2665                         dist = self.prevorigin - self.origin;
2666                         dist_z = 0;
2667                         self.lms_traveled_distance += fabs(vlen(dist));
2668
2669                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2670                         {
2671                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2672                                 self.lms_traveled_distance = 0;
2673                         }
2674
2675                         if(time > self.lms_nextcheck)
2676                         {
2677                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2678                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2679                                 {
2680                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2681                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2682                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2683                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2684                                 }
2685                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2686                                 self.lms_traveled_distance = 0;
2687                         }
2688                 }
2689
2690                 self.prevorigin = self.origin;
2691
2692                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2693                 {
2694                         if (!self.crouch)
2695                         {
2696                                 self.crouch = TRUE;
2697                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2698                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2699                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2700                         }
2701                 }
2702                 else
2703                 {
2704                         if (self.crouch)
2705                         {
2706                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2707                                 if (!trace_startsolid)
2708                                 {
2709                                         self.crouch = FALSE;
2710                                         self.view_ofs = PL_VIEW_OFS;
2711                                         setsize (self, PL_MIN, PL_MAX);
2712                                 }
2713                         }
2714                 }
2715
2716                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2717                 {
2718                         if(self.bloodloss_timer < time)
2719                         {
2720                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2721                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2722                         }
2723                 }
2724
2725                 FixPlayermodel();
2726
2727                 GrapplingHookFrame();
2728
2729                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2730                 //if(frametime)
2731                 {
2732                         self.items &~= self.items_added;
2733
2734                         W_WeaponFrame();
2735
2736                         self.items_added = 0;
2737                         if(self.items & IT_JETPACK)
2738                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2739                                         self.items_added |= IT_FUEL;
2740
2741                         self.items |= self.items_added;
2742                 }
2743
2744                 player_regen();
2745                 if(frametime)
2746                         player_anim();
2747
2748                 if (g_minstagib)
2749                         minstagib_ammocheck();
2750
2751                 ctf_setstatus();
2752                 nexball_setstatus();
2753
2754                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2755
2756                 //self.angles_y=self.v_angle_y + 90;   // temp
2757         } else if(gameover) {
2758                 if (intermission_running)
2759                         IntermissionThink ();   // otherwise a button could be missed between
2760                 return;
2761         } else if(self.classname == "observer") {
2762                 ObserverThink();
2763         } else if(self.classname == "spectator") {
2764                 SpectatorThink();
2765         }
2766
2767         if(!zoomstate_set)
2768                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2769
2770         float oldspectatee_status;
2771         oldspectatee_status = self.spectatee_status;
2772         if(self.classname == "spectator")
2773                 self.spectatee_status = num_for_edict(self.enemy);
2774         else if(self.classname == "observer")
2775                 self.spectatee_status = num_for_edict(self);
2776         else
2777                 self.spectatee_status = 0;
2778         if(self.spectatee_status != oldspectatee_status)
2779         {
2780                 ClientData_Touch(self);
2781                 if(g_race || g_cts)
2782                         race_InitSpectator();
2783         }
2784
2785         if(self.teamkill_soundtime)
2786         if(time > self.teamkill_soundtime)
2787         {
2788                 self.teamkill_soundtime = 0;
2789
2790                 entity oldpusher, oldself;
2791
2792                 oldself = self; self = self.teamkill_soundsource;
2793                 oldpusher = self.pusher; self.pusher = oldself;
2794
2795                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2796
2797                 self.pusher = oldpusher;
2798                 self = oldself;
2799         }
2800
2801         if(self.taunt_soundtime)
2802         if(time > self.taunt_soundtime)
2803         {
2804                 self.taunt_soundtime = 0;
2805                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2806         }
2807
2808         target_voicescript_next(self);
2809 }
2810
2811 float isInvisibleString(string s)
2812 {
2813         float i, n, c;
2814         s = strdecolorize(s);
2815         for((i = 0), (n = strlen(s)); i < n; ++i)
2816         {
2817                 c = str2chr(s, i);
2818                 switch(c)
2819                 {
2820                         case 0:
2821                         case 32:
2822                         case 160:
2823                                 break;
2824                         default:
2825                                 return FALSE;
2826                 }
2827         }
2828         return TRUE;
2829 }
2830
2831 /*
2832 =============
2833 PlayerPostThink
2834
2835 Called every frame for each client after the physics are run
2836 =============
2837 */
2838 .float idlekick_lasttimeleft;
2839 void PlayerPostThink (void)
2840 {
2841         // Savage: Check for nameless players
2842         if (isInvisibleString(self.netname)) {
2843                 self.netname = "Player";
2844                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2845         }
2846
2847         // send the clients accuracy stats to the client
2848         if(self.stat_count > 0)
2849         if(frametime)
2850         {
2851                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2852                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2853                 self.stat_count -= 1;
2854         }
2855
2856 #ifdef UID
2857         if(self.uid_kicktime)
2858         if(time > self.uid_kicktime)
2859         {
2860                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2861                 dropclient(self);
2862                 return;
2863         }
2864 #endif
2865
2866         if(sv_maxidle && frametime)
2867         {
2868                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2869                 float timeleft;
2870                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2871                 if(timeleft <= 0)
2872                 {
2873                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2874                         AnnounceTo(self, "terminated");
2875                         dropclient(self);
2876                         return;
2877                 }
2878                 else if(timeleft <= 10)
2879                 {
2880                         if(timeleft != self.idlekick_lasttimeleft)
2881                         {
2882                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2883                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2884                         }
2885                 }
2886                 else
2887                 {
2888                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2889                 }
2890                 self.idlekick_lasttimeleft = timeleft;
2891         }
2892
2893 #ifdef TETRIS
2894         if(self.impulse == 100)
2895                 ImpulseCommands();
2896         if (TetrisPostFrame())
2897                 return;
2898 #endif
2899
2900         CheatFrame();
2901
2902         if(self.classname == "player") {
2903                 CheckRules_Player();
2904                 UpdateChatBubble();
2905                 UpdateTeamBubble();
2906                 if (self.impulse)
2907                         ImpulseCommands();
2908                 if (intermission_running)
2909                         return;         // intermission or finale
2910                 GetPressedKeys();
2911         } else if (self.classname == "observer") {
2912                 //do nothing
2913         } else if (self.classname == "spectator") {
2914                 //do nothing
2915         }
2916
2917         /*
2918         float i;
2919         for(i = 0; i < 1000; ++i)
2920         {
2921                 vector end;
2922                 end = self.origin + '0 0 1024' + 512 * randomvec();
2923                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2924                 if(trace_fraction < 1)
2925                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2926                 {
2927                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2928                         break;
2929                 }
2930         }
2931         */
2932
2933         Arena_Warmup();
2934
2935         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2936
2937         if(self.waypointsprite_attachedforcarrier)
2938                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2939
2940         playerdemo_write();
2941
2942         /*
2943         if(g_race)
2944                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2945         */
2946 }