qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21
  22 #include "bot/bot.qh"
  23 #include "bot/navigation.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/teleporters.qh"
  31
  32 #include "../common/vehicles/all.qh"
  33
  34 #include "weapons/hitplot.qh"
  35 #include "weapons/weaponsystem.qh"
  36
  37 #include "../common/net_notice.qh"
  38 #include "../common/physics/player.qh"
  39
  40 #include "../common/items/all.qc"
  41
  42 #include "../common/mutators/mutator/waypoints/all.qh"
  43
  44 #include "../common/triggers/subs.qh"
  45 #include "../common/triggers/triggers.qh"
  46 #include "../common/triggers/trigger/secret.qh"
  47
  48 #include "../common/minigames/sv_minigames.qh"
  49
  50 #include "../common/items/inventory.qh"
  51
  52 #include "../common/monsters/sv_monsters.qh"
  53
  54 #include "../lib/warpzone/server.qh"
  55
  56
  57 void send_CSQC_teamnagger() {
  58         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  59 }
  60
  61 bool ClientData_Send(entity this, entity to, int sf)
  62 {
  63         assert(to == this.owner, return false);
  64
  65         entity e = to;
  66         if (IS_SPEC(e)) e = e.enemy;
  67
  68         sf = 0;
  69         if (e.race_completed)       sf |= 1; // forced scoreboard
  70         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
  71         if (e.zoomstate)            sf |= 4; // zoomed
  72         if (e.porto_v_angle_held)   sf |= 8; // angles held
  73
  74         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  75         WriteByte(MSG_ENTITY, sf);
  76
  77         if (sf & 2)
  78         {
  79                 WriteByte(MSG_ENTITY, to.spectatee_status);
  80         }
  81         if (sf & 8)
  82         {
  83                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  84                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  85         }
  86         return true;
  87 }
  88
  89 void ClientData_Attach(entity this)
  90 {
  91         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
  92         self.clientdata.drawonlytoclient = this;
  93         self.clientdata.owner = this;
  94 }
  95
  96 void ClientData_Detach(entity this)
  97 {
  98         remove(this.clientdata);
  99         self.clientdata = NULL;
 100 }
 101
 102 void ClientData_Touch(entity e)
 103 {
 104         e.clientdata.SendFlags = 1;
 105
 106         // make it spectatable
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 108 }
 109
 110 .string netname_previous;
 111
 112 void SetSpectatee(entity player, entity spectatee);
 113
 114
 115 /*
 116 =============
 117 CheckPlayerModel
 118
 119 Checks if the argument string can be a valid playermodel.
 120 Returns a valid one in doubt.
 121 =============
 122 */
 123 string FallbackPlayerModel;
 124 string CheckPlayerModel(string plyermodel) {
 125         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 126         {
 127                 // note: we cannot summon Don Strunzone here, some player may
 128                 // still have the model string set. In case anyone manages how
 129                 // to change a cvar default, we'll have a small leak here.
 130                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 131         }
 132         // only in right path
 133         if( substring(plyermodel,0,14) != "models/player/")
 134                 return FallbackPlayerModel;
 135         // only good file extensions
 136         if(substring(plyermodel,-4,4) != ".zym")
 137         if(substring(plyermodel,-4,4) != ".dpm")
 138         if(substring(plyermodel,-4,4) != ".iqm")
 139         if(substring(plyermodel,-4,4) != ".md3")
 140         if(substring(plyermodel,-4,4) != ".psk")
 141                 return FallbackPlayerModel;
 142         // forbid the LOD models
 143         if(substring(plyermodel, -9,5) == "_lod1")
 144                 return FallbackPlayerModel;
 145         if(substring(plyermodel, -9,5) == "_lod2")
 146                 return FallbackPlayerModel;
 147         if(plyermodel != strtolower(plyermodel))
 148                 return FallbackPlayerModel;
 149         // also, restrict to server models
 150         if(autocvar_sv_servermodelsonly)
 151         {
 152                 if(!fexists(plyermodel))
 153                         return FallbackPlayerModel;
 154         }
 155         return plyermodel;
 156 }
 157
 158 void setplayermodel(entity e, string modelname)
 159 {
 160         precache_model(modelname);
 161         _setmodel(e, modelname);
 162         player_setupanimsformodel();
 163         if(!autocvar_g_debug_globalsounds)
 164                 UpdatePlayerSounds(e);
 165 }
 166
 167 void FixPlayermodel(entity player);
 168 /** putting a client as observer in the server */
 169 void PutObserverInServer()
 170 {
 171         SELFPARAM();
 172     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 173         PlayerState_detach(this);
 174
 175         if (IS_PLAYER(this) && this.health >= 1) {
 176         // despawn effect
 177                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 178     }
 179
 180     {
 181         entity spot = SelectSpawnPoint(true);
 182         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 183         this.angles = spot.angles;
 184         this.angles_z = 0;
 185         this.fixangle = true;
 186         // offset it so that the spectator spawns higher off the ground, looks better this way
 187         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 188         this.prevorigin = this.origin;
 189         if (IS_REAL_CLIENT(this))
 190         {
 191             msg_entity = this;
 192             WriteByte(MSG_ONE, SVC_SETVIEW);
 193             WriteEntity(MSG_ONE, this);
 194         }
 195         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 196         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 197         if(!autocvar_g_debug_globalsounds)
 198         {
 199                 // needed for player sounds
 200                 this.model = "";
 201                 FixPlayermodel(this);
 202         }
 203         setmodel(this, MDL_Null);
 204         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 205         this.view_ofs = '0 0 0';
 206     }
 207
 208     RemoveGrapplingHook(this);
 209         Portal_ClearAll(this);
 210         Unfreeze(this);
 211
 212         if (this.alivetime)
 213         {
 214                 if (!warmup_stage)
 215                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 216                 this.alivetime = 0;
 217         }
 218
 219         if (this.vehicle) vehicles_exit(VHEF_RELEASE);
 220
 221         WaypointSprite_PlayerDead(this);
 222
 223         if (mutator_returnvalue) {
 224             // mutator prevents resetting teams+score
 225         } else {
 226                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 227         this.frags = FRAGS_SPECTATOR;
 228         PlayerScore_Clear(this);  // clear scores when needed
 229     }
 230
 231         if (this.killcount != FRAGS_SPECTATOR)
 232         {
 233                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 234                 if(!intermission_running)
 235                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 236                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 237
 238                 if(this.just_joined == false) {
 239                         LogTeamchange(this.playerid, -1, 4);
 240                 } else
 241                         this.just_joined = false;
 242         }
 243
 244         accuracy_resend(this);
 245
 246         this.spectatortime = time;
 247         this.bot_attack = false;
 248     this.hud = HUD_NORMAL;
 249         this.classname = STR_OBSERVER;
 250         this.iscreature = false;
 251         this.teleportable = TELEPORT_SIMPLE;
 252         this.damagedbycontents = false;
 253         this.health = FRAGS_SPECTATOR;
 254         this.takedamage = DAMAGE_NO;
 255         this.solid = SOLID_NOT;
 256         this.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 257         this.flags = FL_CLIENT | FL_NOTARGET;
 258         this.armorvalue = 666;
 259         this.effects = 0;
 260         this.armorvalue = autocvar_g_balance_armor_start;
 261         this.pauserotarmor_finished = 0;
 262         this.pauserothealth_finished = 0;
 263         this.pauseregen_finished = 0;
 264         this.damageforcescale = 0;
 265         this.death_time = 0;
 266         this.respawn_flags = 0;
 267         this.respawn_time = 0;
 268         this.stat_respawn_time = 0;
 269         this.alpha = 0;
 270         this.scale = 0;
 271         this.fade_time = 0;
 272         this.pain_frame = 0;
 273         this.pain_finished = 0;
 274         this.strength_finished = 0;
 275         this.invincible_finished = 0;
 276         this.superweapons_finished = 0;
 277         this.pushltime = 0;
 278         this.istypefrag = 0;
 279         this.think = func_null;
 280         this.nextthink = 0;
 281         this.hook_time = 0;
 282         this.deadflag = DEAD_NO;
 283         this.crouch = false;
 284         this.revival_time = 0;
 285
 286         this.items = 0;
 287         this.weapons = '0 0 0';
 288         this.drawonlytoclient = this;
 289
 290         this.weaponname = "";
 291         this.weaponmodel = "";
 292         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 293         {
 294                 this.weaponentities[slot] = NULL;
 295         }
 296         this.exteriorweaponentity = NULL;
 297         this.killcount = FRAGS_SPECTATOR;
 298         this.velocity = '0 0 0';
 299         this.avelocity = '0 0 0';
 300         this.punchangle = '0 0 0';
 301         this.punchvector = '0 0 0';
 302         this.oldvelocity = this.velocity;
 303         this.fire_endtime = -1;
 304         this.event_damage = func_null;
 305 }
 306
 307 int player_getspecies(entity this)
 308 {
 309         get_model_parameters(this.model, this.skin);
 310         int s = get_model_parameters_species;
 311         get_model_parameters(string_null, 0);
 312         if (s < 0) return SPECIES_HUMAN;
 313         return s;
 314 }
 315
 316 .float model_randomizer;
 317 void FixPlayermodel(entity player)
 318 {
 319         string defaultmodel = "";
 320         int defaultskin = 0;
 321         if(autocvar_sv_defaultcharacter)
 322         {
 323                 if(teamplay)
 324                 {
 325                         string s = Static_Team_ColorName_Lower(player.team);
 326                         if (s != "neutral")
 327                         {
 328                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 329                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 330                         }
 331                 }
 332
 333                 if(defaultmodel == "")
 334                 {
 335                         defaultmodel = autocvar_sv_defaultplayermodel;
 336                         defaultskin = autocvar_sv_defaultplayerskin;
 337                 }
 338
 339                 int n = tokenize_console(defaultmodel);
 340                 if(n > 0)
 341                 {
 342                         defaultmodel = argv(floor(n * player.model_randomizer));
 343                         // However, do NOT randomize if the player-selected model is in the list.
 344                         for (int i = 0; i < n; ++i)
 345                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 346                                         defaultmodel = argv(i);
 347                 }
 348
 349                 int i = strstrofs(defaultmodel, ":", 0);
 350                 if(i >= 0)
 351                 {
 352                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 353                         defaultmodel = substring(defaultmodel, 0, i);
 354                 }
 355         }
 356         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 357         defaultmodel = ret_string;
 358         defaultskin = ret_int;
 359
 360         bool chmdl = false;
 361         int oldskin;
 362         if(defaultmodel != "")
 363         {
 364                 if (defaultmodel != player.model)
 365                 {
 366                         vector m1 = player.mins;
 367                         vector m2 = player.maxs;
 368                         setplayermodel (player, defaultmodel);
 369                         setsize (player, m1, m2);
 370                         chmdl = true;
 371                 }
 372
 373                 oldskin = player.skin;
 374                 player.skin = defaultskin;
 375         } else {
 376                 if (player.playermodel != player.model || player.playermodel == "")
 377                 {
 378                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 379                         vector m1 = player.mins;
 380                         vector m2 = player.maxs;
 381                         setplayermodel (player, player.playermodel);
 382                         setsize (player, m1, m2);
 383                         chmdl = true;
 384                 }
 385
 386                 oldskin = player.skin;
 387                 player.skin = stof(player.playerskin);
 388         }
 389
 390         if(chmdl || oldskin != player.skin) // model or skin has changed
 391         {
 392                 player.species = player_getspecies(player); // update species
 393                 if(!autocvar_g_debug_globalsounds)
 394                         UpdatePlayerSounds(player); // update skin sounds
 395         }
 396
 397         if(!teamplay)
 398                 if(strlen(autocvar_sv_defaultplayercolors))
 399                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 400                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 401 }
 402
 403
 404 /** Called when a client spawns in the server */
 405 void PutClientInServer()
 406 {
 407         SELFPARAM();
 408         if (IS_BOT_CLIENT(this)) {
 409                 this.classname = STR_PLAYER;
 410         } else if (IS_REAL_CLIENT(this)) {
 411                 msg_entity = this;
 412                 WriteByte(MSG_ONE, SVC_SETVIEW);
 413                 WriteEntity(MSG_ONE, this);
 414         }
 415         if (gameover) {
 416                 this.classname = STR_OBSERVER;
 417         }
 418
 419         SetSpectatee(this, NULL);
 420
 421         // reset player keys
 422         this.itemkeys = 0;
 423
 424         MUTATOR_CALLHOOK(PutClientInServer, this);
 425
 426         if (IS_OBSERVER(this)) {
 427                 PutObserverInServer();
 428         } else if (IS_PLAYER(this)) {
 429                 PlayerState_attach(this);
 430                 accuracy_resend(this);
 431
 432                 if (this.team < 0)
 433                         JoinBestTeam(this, false, true);
 434
 435                 entity spot = SelectSpawnPoint(false);
 436                 if (!spot) {
 437                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 438                         return; // spawn failed
 439                 }
 440
 441                 this.classname = STR_PLAYER;
 442                 this.wasplayer = true;
 443                 this.iscreature = true;
 444                 this.teleportable = TELEPORT_NORMAL;
 445                 this.damagedbycontents = true;
 446                 this.movetype = MOVETYPE_WALK;
 447                 this.solid = SOLID_SLIDEBOX;
 448                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 449                 if (autocvar_g_playerclip_collisions)
 450                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 451                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 452                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 453                 this.frags = FRAGS_PLAYER;
 454                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 455                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 456                 if (autocvar__notarget)
 457                         this.flags |= FL_NOTARGET;
 458                 this.takedamage = DAMAGE_AIM;
 459                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 460                 this.dmg = 2; // WTF
 461
 462                 if (warmup_stage) {
 463                         this.ammo_shells = warmup_start_ammo_shells;
 464                         this.ammo_nails = warmup_start_ammo_nails;
 465                         this.ammo_rockets = warmup_start_ammo_rockets;
 466                         this.ammo_cells = warmup_start_ammo_cells;
 467                         this.ammo_plasma = warmup_start_ammo_plasma;
 468                         this.ammo_fuel = warmup_start_ammo_fuel;
 469                         this.health = warmup_start_health;
 470                         this.armorvalue = warmup_start_armorvalue;
 471                         this.weapons = WARMUP_START_WEAPONS;
 472                 } else {
 473                         this.ammo_shells = start_ammo_shells;
 474                         this.ammo_nails = start_ammo_nails;
 475                         this.ammo_rockets = start_ammo_rockets;
 476                         this.ammo_cells = start_ammo_cells;
 477                         this.ammo_plasma = start_ammo_plasma;
 478                         this.ammo_fuel = start_ammo_fuel;
 479                         this.health = start_health;
 480                         this.armorvalue = start_armorvalue;
 481                         this.weapons = start_weapons;
 482                 }
 483
 484                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 485
 486                 this.items = start_items;
 487
 488                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 489                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 490                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 491                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 492                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 493                 // extend the pause of rotting if client was reset at the beginning of the countdown
 494                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 495                         float f = game_starttime - time;
 496                         this.spawnshieldtime += f;
 497                         this.pauserotarmor_finished += f;
 498                         this.pauserothealth_finished += f;
 499                         this.pauseregen_finished += f;
 500                 }
 501                 this.damageforcescale = 2;
 502                 this.death_time = 0;
 503                 this.respawn_flags = 0;
 504                 this.respawn_time = 0;
 505                 this.stat_respawn_time = 0;
 506                 this.scale = autocvar_sv_player_scale;
 507                 this.fade_time = 0;
 508                 this.pain_frame = 0;
 509                 this.pain_finished = 0;
 510                 this.pushltime = 0;
 511                 this.think = func_null; // players have no think function
 512                 this.nextthink = 0;
 513                 this.dmg_team = 0;
 514                 this.ballistics_density = autocvar_g_ballistics_density_player;
 515
 516                 this.deadflag = DEAD_NO;
 517
 518                 this.angles = spot.angles;
 519                 this.angles_z = 0; // never spawn tilted even if the spot says to
 520                 if (IS_BOT_CLIENT(this))
 521                         this.v_angle = this.angles;
 522                 this.fixangle = true; // turn this way immediately
 523                 this.oldvelocity = this.velocity = '0 0 0';
 524                 this.avelocity = '0 0 0';
 525                 this.punchangle = '0 0 0';
 526                 this.punchvector = '0 0 0';
 527
 528                 this.strength_finished = 0;
 529                 this.invincible_finished = 0;
 530                 this.fire_endtime = -1;
 531                 this.revival_time = 0;
 532                 this.air_finished = time + 12;
 533
 534                 entity spawnevent = new_pure(spawnevent);
 535                 spawnevent.owner = this;
 536                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 537
 538                 // Cut off any still running player sounds.
 539                 stopsound(this, CH_PLAYER_SINGLE);
 540
 541                 this.model = "";
 542                 FixPlayermodel(this);
 543                 this.drawonlytoclient = NULL;
 544
 545                 this.crouch = false;
 546                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 547                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 548                 this.spawnorigin = spot.origin;
 549                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 550                 // don't reset back to last position, even if new position is stuck in solid
 551                 this.oldorigin = this.origin;
 552                 this.prevorigin = this.origin;
 553                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 554         this.hud = HUD_NORMAL;
 555
 556                 this.event_damage = PlayerDamage;
 557
 558                 this.bot_attack = true;
 559                 this.monster_attack = true;
 560
 561                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 562
 563                 if (this.killcount == FRAGS_SPECTATOR) {
 564                         PlayerScore_Clear(this);
 565                         this.killcount = 0;
 566                 }
 567
 568                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 569                 {
 570                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 571                 }
 572                 this.alpha = default_player_alpha;
 573                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 574                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 575
 576                 this.speedrunning = false;
 577
 578                 target_voicescript_clear(this);
 579
 580                 // reset fields the weapons may use
 581                 FOREACH(Weapons, true, LAMBDA(
 582                         it.wr_resetplayer(it);
 583                         // reload all reloadable weapons
 584                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 585                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 586                         }
 587                 ));
 588
 589                 {
 590                         string s = spot.target;
 591                         spot.target = string_null;
 592                         WITH(entity, activator, this, LAMBDA(
 593                                 WITH(entity, self, spot, SUB_UseTargets())
 594                         ));
 595                         spot.target = s;
 596                 }
 597
 598                 Unfreeze(this);
 599
 600                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 601
 602                 if (autocvar_spawn_debug)
 603                 {
 604                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 605                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 606                 }
 607
 608                 PS(this).m_switchweapon = w_getbestweapon(this);
 609                 this.cnt = -1; // W_LastWeapon will not complain
 610                 PS(this).m_weapon = WEP_Null;
 611                 this.weaponname = "";
 612                 PS(this).m_switchingweapon = WEP_Null;
 613
 614                 if (!warmup_stage && !this.alivetime)
 615                         this.alivetime = time;
 616
 617                 antilag_clear(this, CS(this));
 618         }
 619 }
 620
 621 void ClientInit_misc();
 622
 623 .float ebouncefactor, ebouncestop; // electro's values
 624 // TODO do we need all these fields, or should we stop autodetecting runtime
 625 // changes and just have a console command to update this?
 626 bool ClientInit_SendEntity(entity this, entity to, int sf)
 627 {
 628         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 629         return = true;
 630         msg_entity = to;
 631         // MSG_INIT replacement
 632         // TODO: make easier to use
 633         Registry_send_all();
 634         W_PROP_reload(MSG_ONE, to);
 635         ClientInit_misc();
 636         MUTATOR_CALLHOOK(Ent_Init);
 637 }
 638 void ClientInit_misc()
 639 {
 640         int channel = MSG_ONE;
 641         WriteHeader(channel, ENT_CLIENT_INIT);
 642         WriteByte(channel, g_nexball_meter_period * 32);
 643         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 644         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 645         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 646         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 647         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 648         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 649         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 650         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 651
 652         if(sv_foginterval && world.fog != "")
 653                 WriteString(channel, world.fog);
 654         else
 655                 WriteString(channel, "");
 656         WriteByte(channel, self.count * 255.0); // g_balance_armor_blockpercent
 657         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 658         WriteCoord(channel, autocvar_g_trueaim_minrange);
 659 }
 660
 661 void ClientInit_CheckUpdate()
 662 {SELFPARAM();
 663         self.nextthink = time;
 664         if(self.count != autocvar_g_balance_armor_blockpercent)
 665         {
 666                 self.count = autocvar_g_balance_armor_blockpercent;
 667                 self.SendFlags |= 1;
 668         }
 669 }
 670
 671 void ClientInit_Spawn()
 672 {SELFPARAM();
 673
 674         entity e = new_pure(clientinit);
 675         e.think = ClientInit_CheckUpdate;
 676         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 677
 678         WITH(entity, self, e, ClientInit_CheckUpdate());
 679 }
 680
 681 /*
 682 =============
 683 SetNewParms
 684 =============
 685 */
 686 void SetNewParms ()
 687 {
 688         // initialize parms for a new player
 689         parm1 = -(86400 * 366);
 690
 691         MUTATOR_CALLHOOK(SetNewParms);
 692 }
 693
 694 /*
 695 =============
 696 SetChangeParms
 697 =============
 698 */
 699 void SetChangeParms ()
 700 {SELFPARAM();
 701         // save parms for level change
 702         parm1 = self.parm_idlesince - time;
 703
 704         MUTATOR_CALLHOOK(SetChangeParms);
 705 }
 706
 707 /*
 708 =============
 709 DecodeLevelParms
 710 =============
 711 */
 712 void DecodeLevelParms(entity this)
 713 {
 714         // load parms
 715         this.parm_idlesince = parm1;
 716         if (this.parm_idlesince == -(86400 * 366))
 717                 this.parm_idlesince = time;
 718
 719         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 720         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 721
 722         MUTATOR_CALLHOOK(DecodeLevelParms);
 723 }
 724
 725 /*
 726 =============
 727 ClientKill
 728
 729 Called when a client types 'kill' in the console
 730 =============
 731 */
 732
 733 .float clientkill_nexttime;
 734 void ClientKill_Now_TeamChange(entity this)
 735 {
 736         if(this.killindicator_teamchange == -1)
 737         {
 738                 JoinBestTeam( this, false, true );
 739         }
 740         else if(this.killindicator_teamchange == -2)
 741         {
 742                 if(blockSpectators)
 743                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 744                 WITH(entity, self, this, PutObserverInServer());
 745         }
 746         else
 747                 WITH(entity, self, this, SV_ChangeTeam(this.killindicator_teamchange - 1));
 748         this.killindicator_teamchange = 0;
 749 }
 750
 751 void ClientKill_Now()
 752 {SELFPARAM();
 753         if(self.vehicle)
 754         {
 755             vehicles_exit(VHEF_RELEASE);
 756             if(!self.killindicator_teamchange)
 757             {
 758             self.vehicle_health = -1;
 759             Damage(self, self, self, 1 , DEATH_KILL.m_id, self.origin, '0 0 0');
 760             }
 761         }
 762
 763         if(self.killindicator && !wasfreed(self.killindicator))
 764                 remove(self.killindicator);
 765
 766         self.killindicator = world;
 767
 768         if(self.killindicator_teamchange)
 769                 ClientKill_Now_TeamChange(self);
 770
 771         if(IS_PLAYER(self))
 772                 Damage(self, self, self, 100000, DEATH_KILL.m_id, self.origin, '0 0 0');
 773
 774         // now I am sure the player IS dead
 775 }
 776 void KillIndicator_Think()
 777 {SELFPARAM();
 778         if (gameover)
 779         {
 780                 self.owner.killindicator = world;
 781                 remove(self);
 782                 return;
 783         }
 784
 785         if (self.owner.alpha < 0 && !self.owner.vehicle)
 786         {
 787                 self.owner.killindicator = world;
 788                 remove(self);
 789                 return;
 790         }
 791
 792         if(self.cnt <= 0)
 793         {
 794                 WITH(entity, self, self.owner, ClientKill_Now());
 795                 return;
 796         }
 797     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 798     {
 799         self.nextthink = time + 1;
 800         self.cnt -= 1;
 801     }
 802         else
 803         {
 804                 if(self.cnt <= 10)
 805                         setmodel(self, MDL_NUM(self.cnt));
 806                 if(IS_REAL_CLIENT(self.owner))
 807                 {
 808                         if(self.cnt <= 10)
 809                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 810                 }
 811                 self.nextthink = time + 1;
 812                 self.cnt -= 1;
 813         }
 814 }
 815
 816 float clientkilltime;
 817 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 818 {SELFPARAM();
 819         float killtime;
 820         float starttime;
 821         entity e;
 822
 823         if (gameover)
 824                 return;
 825
 826         killtime = autocvar_g_balance_kill_delay;
 827
 828         if(g_race_qualifying || g_cts)
 829                 killtime = 0;
 830
 831     if(MUTATOR_CALLHOOK(ClientKill, self, killtime))
 832         return;
 833
 834         self.killindicator_teamchange = targetteam;
 835
 836     if(!self.killindicator)
 837         {
 838                 if(!IS_DEAD(self))
 839                 {
 840                         killtime = max(killtime, self.clientkill_nexttime - time);
 841                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 842                 }
 843
 844                 if(killtime <= 0 || !IS_PLAYER(self) || IS_DEAD(self))
 845                 {
 846                         ClientKill_Now();
 847                 }
 848                 else
 849                 {
 850                         starttime = max(time, clientkilltime);
 851
 852                         self.killindicator = spawn();
 853                         self.killindicator.owner = self;
 854                         self.killindicator.scale = 0.5;
 855                         setattachment(self.killindicator, self, "");
 856                         setorigin(self.killindicator, '0 0 52');
 857                         self.killindicator.think = KillIndicator_Think;
 858                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 859                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 860                         self.killindicator.cnt = ceil(killtime);
 861                         self.killindicator.count = bound(0, ceil(killtime), 10);
 862                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 863
 864                         for(e = world; (e = find(e, classname, "body")) != world; )
 865                         {
 866                                 if(e.enemy != self)
 867                                         continue;
 868                                 e.killindicator = spawn();
 869                                 e.killindicator.owner = e;
 870                                 e.killindicator.scale = 0.5;
 871                                 setattachment(e.killindicator, e, "");
 872                                 setorigin(e.killindicator, '0 0 52');
 873                                 e.killindicator.think = KillIndicator_Think;
 874                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 875                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 876                                 e.killindicator.cnt = ceil(killtime);
 877                         }
 878                         self.lip = 0;
 879                 }
 880         }
 881         if(self.killindicator)
 882         {
 883                 if(targetteam == 0) // just die
 884                 {
 885                         self.killindicator.colormod = '0 0 0';
 886                         if(IS_REAL_CLIENT(self))
 887                         if(self.killindicator.cnt > 0)
 888                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 889                 }
 890                 else if(targetteam == -1) // auto
 891                 {
 892                         self.killindicator.colormod = '0 1 0';
 893                         if(IS_REAL_CLIENT(self))
 894                         if(self.killindicator.cnt > 0)
 895                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 896                 }
 897                 else if(targetteam == -2) // spectate
 898                 {
 899                         self.killindicator.colormod = '0.5 0.5 0.5';
 900                         if(IS_REAL_CLIENT(self))
 901                         if(self.killindicator.cnt > 0)
 902                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 903                 }
 904                 else
 905                 {
 906                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 907                         if(IS_REAL_CLIENT(self))
 908                         if(self.killindicator.cnt > 0)
 909                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), self.killindicator.cnt);
 910                 }
 911         }
 912
 913 }
 914
 915 void ClientKill ()
 916 {SELFPARAM();
 917         if(gameover) return;
 918         if(self.player_blocked) return;
 919         if(STAT(FROZEN, self)) return;
 920
 921         ClientKill_TeamChange(0);
 922 }
 923
 924 void FixClientCvars(entity e)
 925 {
 926         // send prediction settings to the client
 927         stuffcmd(e, "\nin_bindmap 0 0\n");
 928         if(autocvar_g_antilag == 3) // client side hitscan
 929                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 930         if(autocvar_sv_gentle)
 931                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 932
 933         MUTATOR_CALLHOOK(FixClientCvars, e);
 934 }
 935
 936 float PlayerInIDList(entity p, string idlist)
 937 {
 938         float n, i;
 939         string s;
 940
 941         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 942         if (!p.crypto_idfp)
 943                 return 0;
 944
 945         // this function allows abbreviated player IDs too!
 946         n = tokenize_console(idlist);
 947         for(i = 0; i < n; ++i)
 948         {
 949                 s = argv(i);
 950                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 951                         return 1;
 952         }
 953
 954         return 0;
 955 }
 956
 957 #ifdef DP_EXT_PRECONNECT
 958 /*
 959 =============
 960 ClientPreConnect
 961
 962 Called once (not at each match start) when a client begins a connection to the server
 963 =============
 964 */
 965 void ClientPreConnect ()
 966 {SELFPARAM();
 967         if(autocvar_sv_eventlog)
 968         {
 969                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 970                         self.playerid,
 971                         etof(self),
 972                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
 973                 ));
 974         }
 975 }
 976 #endif
 977
 978 /**
 979 =============
 980 ClientConnect
 981
 982 Called when a client connects to the server
 983 =============
 984 */
 985 void ClientConnect()
 986 {
 987         SELFPARAM();
 988         if (Ban_MaybeEnforceBanOnce(this)) return;
 989         assert(!IS_CLIENT(this), return);
 990         assert(player_count >= 0, player_count = 0);
 991         this.classname = "player_joining";
 992         this.flags = FL_CLIENT;
 993
 994 #ifdef WATERMARK
 995         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
 996 #endif
 997         this.version_nagtime = time + 10 + random() * 10;
 998
 999         ClientState_attach(this);
1000
1001         // identify the right forced team
1002         if (autocvar_g_campaign)
1003         {
1004                 if (IS_REAL_CLIENT(this)) // only players, not bots
1005                 {
1006                         switch (autocvar_g_campaign_forceteam)
1007                         {
1008                                 case 1: this.team_forced = NUM_TEAM_1; break;
1009                                 case 2: this.team_forced = NUM_TEAM_2; break;
1010                                 case 3: this.team_forced = NUM_TEAM_3; break;
1011                                 case 4: this.team_forced = NUM_TEAM_4; break;
1012                                 default: this.team_forced = 0;
1013                         }
1014                 }
1015         }
1016         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1017         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1018         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1019         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1020         else switch (autocvar_g_forced_team_otherwise)
1021         {
1022                 default: this.team_forced = 0; break;
1023                 case "red": this.team_forced = NUM_TEAM_1; break;
1024                 case "blue": this.team_forced = NUM_TEAM_2; break;
1025                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1026                 case "pink": this.team_forced = NUM_TEAM_4; break;
1027                 case "spectate":
1028                 case "spectator":
1029                         this.team_forced = -1;
1030                         break;
1031         }
1032         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1033
1034         JoinBestTeam(this, false, false); // if the team number is valid, keep it
1035
1036         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1037                 this.classname = STR_OBSERVER;
1038         } else {
1039                 if (!teamplay || autocvar_g_balance_teams)
1040                 {
1041                         this.classname = STR_PLAYER;
1042                         campaign_bots_may_start = 1;
1043                 }
1044                 else
1045                 {
1046                         this.classname = STR_OBSERVER; // do it anyway
1047                 }
1048         }
1049
1050         this.playerid = ++playerid_last;
1051
1052         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1053
1054         // always track bots, don't ask for cl_allow_uidtracking
1055     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1056
1057         if (autocvar_sv_eventlog)
1058                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1059
1060         LogTeamchange(this.playerid, this.team, 1);
1061
1062         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1063
1064         this.netname_previous = strzone(this.netname);
1065
1066         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1067
1068         stuffcmd(this, clientstuff, "\n");
1069         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1070
1071         FixClientCvars(this);
1072
1073         // get version info from player
1074         stuffcmd(this, "cmd clientversion $gameversion\n");
1075
1076         // notify about available teams
1077         if (teamplay)
1078         {
1079                 CheckAllowedTeams(this);
1080                 int t = 0;
1081                 if (c1 >= 0) t |= BIT(0);
1082                 if (c2 >= 0) t |= BIT(1);
1083                 if (c3 >= 0) t |= BIT(2);
1084                 if (c4 >= 0) t |= BIT(3);
1085                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1086         }
1087         else
1088         {
1089                 stuffcmd(this, "set _teams_available 0\n");
1090         }
1091
1092         bot_relinkplayerlist();
1093
1094         this.spectatortime = time;
1095         if (blockSpectators)
1096         {
1097                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1098         }
1099
1100         this.jointime = time;
1101         this.allowed_timeouts = autocvar_sv_timeout_number;
1102
1103         if (IS_REAL_CLIENT(this))
1104         {
1105                 if (!autocvar_g_campaign)
1106                 {
1107                         this.motd_actived_time = -1;
1108                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1109                 }
1110
1111                 if (g_weaponarena_weapons == WEPSET(TUBA))
1112                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1113         }
1114
1115         if (!sv_foginterval && world.fog != "")
1116                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1117
1118         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)))
1119                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1120                         send_CSQC_teamnagger();
1121
1122         CSQCMODEL_AUTOINIT(this);
1123
1124         this.model_randomizer = random();
1125
1126         if (IS_REAL_CLIENT(this))
1127                 sv_notice_join(this);
1128
1129         FOREACH_ENTITY_FLOAT(init_for_player_needed, true, {
1130                 WITH(entity, self, it, it.init_for_player(it));
1131         });
1132
1133         MUTATOR_CALLHOOK(ClientConnect, this);
1134 }
1135 /*
1136 =============
1137 ClientDisconnect
1138
1139 Called when a client disconnects from the server
1140 =============
1141 */
1142 .entity chatbubbleentity;
1143 void ReadyCount();
1144 void ClientDisconnect()
1145 {
1146         SELFPARAM();
1147         assert(IS_CLIENT(this), return);
1148
1149         PlayerStats_GameReport_FinalizePlayer(this);
1150         if (this.vehicle) vehicles_exit(VHEF_RELEASE);
1151         if (this.active_minigame) part_minigame(this);
1152         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1153
1154         if (autocvar_sv_eventlog)
1155                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1156
1157         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1158
1159     MUTATOR_CALLHOOK(ClientDisconnect);
1160
1161         ClientState_detach(this);
1162
1163         Portal_ClearAll(self);
1164
1165         Unfreeze(self);
1166
1167         RemoveGrapplingHook(self);
1168
1169         // Here, everything has been done that requires this player to be a client.
1170
1171         self.flags &= ~FL_CLIENT;
1172
1173         if (this.chatbubbleentity) remove(this.chatbubbleentity);
1174         if (this.killindicator) remove(this.killindicator);
1175
1176         WaypointSprite_PlayerGone();
1177
1178         bot_relinkplayerlist();
1179
1180         if (self.netname_previous) strunzone(self.netname_previous);
1181         if (self.clientstatus) strunzone(self.clientstatus);
1182         if (self.weaponorder_byimpulse) strunzone(self.weaponorder_byimpulse);
1183         if (self.personal) remove(self.personal);
1184
1185         this.playerid = 0;
1186         ReadyCount();
1187         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1188 }
1189
1190 void ChatBubbleThink()
1191 {SELFPARAM();
1192         self.nextthink = time;
1193         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1194         {
1195                 if(self.owner) // but why can that ever be world?
1196                         self.owner.chatbubbleentity = world;
1197                 remove(self);
1198                 return;
1199         }
1200
1201         self.mdl = "";
1202
1203         if ( !IS_DEAD(self.owner) && IS_PLAYER(self.owner) )
1204         {
1205                 if ( self.owner.active_minigame )
1206                         self.mdl = "models/sprites/minigame_busy.iqm";
1207                 else if (PHYS_INPUT_BUTTON_CHAT(self.owner))
1208                         self.mdl = "models/misc/chatbubble.spr";
1209         }
1210
1211         if ( self.model != self.mdl )
1212                 _setmodel(self, self.mdl);
1213
1214 }
1215
1216 void UpdateChatBubble()
1217 {SELFPARAM();
1218         if (self.alpha < 0)
1219                 return;
1220         // spawn a chatbubble entity if needed
1221         if (!self.chatbubbleentity)
1222         {
1223                 self.chatbubbleentity = new(chatbubbleentity);
1224                 self.chatbubbleentity.owner = self;
1225                 self.chatbubbleentity.exteriormodeltoclient = self;
1226                 self.chatbubbleentity.think = ChatBubbleThink;
1227                 self.chatbubbleentity.nextthink = time;
1228                 setmodel(self.chatbubbleentity, MDL_CHAT); // precision set below
1229                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1230                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1231                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1232                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1233                 //self.chatbubbleentity.model = "";
1234                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1235         }
1236 }
1237
1238
1239 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1240 // added to the model skins
1241 /*void UpdateColorModHack()
1242 {
1243         float c;
1244         c = self.clientcolors & 15;
1245         // LordHavoc: only bothering to support white, green, red, yellow, blue
1246              if (!teamplay) self.colormod = '0 0 0';
1247         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1248         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1249         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1250         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1251         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1252         else self.colormod = '1 1 1';
1253 }*/
1254
1255 void respawn()
1256 {SELFPARAM();
1257         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1258         {
1259                 self.solid = SOLID_NOT;
1260                 self.takedamage = DAMAGE_NO;
1261                 self.movetype = MOVETYPE_FLY;
1262                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1263                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1264                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1265                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1266                 if(autocvar_g_respawn_ghosts_maxtime)
1267                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1268         }
1269
1270         CopyBody(self, 1);
1271
1272         self.effects |= EF_NODRAW; // prevent another CopyBody
1273         PutClientInServer();
1274 }
1275
1276 void play_countdown(float finished, string samp)
1277 {SELFPARAM();
1278         if(IS_REAL_CLIENT(self))
1279                 if(floor(finished - time - frametime) != floor(finished - time))
1280                         if(finished - time < 6)
1281                                 _sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1282 }
1283
1284 void player_powerups ()
1285 {SELFPARAM();
1286         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1287         int items_prev = self.items;
1288
1289         if((self.items & IT_USING_JETPACK) && !IS_DEAD(self) && !gameover)
1290                 self.modelflags |= MF_ROCKET;
1291         else
1292                 self.modelflags &= ~MF_ROCKET;
1293
1294         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1295
1296         if((self.alpha < 0 || IS_DEAD(self)) && !self.vehicle) // don't apply the flags if the player is gibbed
1297                 return;
1298
1299         Fire_ApplyDamage(self);
1300         Fire_ApplyEffect(self);
1301
1302         if (!g_instagib)
1303         {
1304                 if (self.items & ITEM_Strength.m_itemid)
1305                 {
1306                         play_countdown(self.strength_finished, SND(POWEROFF));
1307                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1308                         if (time > self.strength_finished)
1309                         {
1310                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1311                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1312                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1313                         }
1314                 }
1315                 else
1316                 {
1317                         if (time < self.strength_finished)
1318                         {
1319                                 self.items = self.items | ITEM_Strength.m_itemid;
1320                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1321                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1322                         }
1323                 }
1324                 if (self.items & ITEM_Shield.m_itemid)
1325                 {
1326                         play_countdown(self.invincible_finished, SND(POWEROFF));
1327                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1328                         if (time > self.invincible_finished)
1329                         {
1330                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1331                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1332                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1333                         }
1334                 }
1335                 else
1336                 {
1337                         if (time < self.invincible_finished)
1338                         {
1339                                 self.items = self.items | ITEM_Shield.m_itemid;
1340                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1341                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1342                         }
1343                 }
1344                 if (self.items & IT_SUPERWEAPON)
1345                 {
1346                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1347                         {
1348                                 self.superweapons_finished = 0;
1349                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1350                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1351                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1352                         }
1353                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1354                         {
1355                                 // don't let them run out
1356                         }
1357                         else
1358                         {
1359                                 play_countdown(self.superweapons_finished, SND(POWEROFF));
1360                                 if (time > self.superweapons_finished)
1361                                 {
1362                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1363                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1364                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1365                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1366                                 }
1367                         }
1368                 }
1369                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1370                 {
1371                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1372                         {
1373                                 self.items = self.items | IT_SUPERWEAPON;
1374                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1375                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1376                         }
1377                         else
1378                         {
1379                                 self.superweapons_finished = 0;
1380                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1381                         }
1382                 }
1383                 else
1384                 {
1385                         self.superweapons_finished = 0;
1386                 }
1387         }
1388
1389         if(autocvar_g_nodepthtestplayers)
1390                 self.effects = self.effects | EF_NODEPTHTEST;
1391
1392         if(autocvar_g_fullbrightplayers)
1393                 self.effects = self.effects | EF_FULLBRIGHT;
1394
1395         if (time >= game_starttime)
1396         if (time < self.spawnshieldtime)
1397                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1398
1399         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1400 }
1401
1402 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1403 {
1404         if(current > stable)
1405                 return current;
1406         else if(current > stable - 0.25) // when close enough, "snap"
1407                 return stable;
1408         else
1409                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1410 }
1411
1412 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1413 {
1414         if(current < stable)
1415                 return current;
1416         else if(current < stable + 0.25) // when close enough, "snap"
1417                 return stable;
1418         else
1419                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1420 }
1421
1422 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1423 {
1424         if(current > rotstable)
1425         {
1426                 if(rotframetime > 0)
1427                 {
1428                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1429                         current = max(rotstable, current - rotlinear * rotframetime);
1430                 }
1431         }
1432         else if(current < regenstable)
1433         {
1434                 if(regenframetime > 0)
1435                 {
1436                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1437                         current = min(regenstable, current + regenlinear * regenframetime);
1438                 }
1439         }
1440
1441         if(current > limit)
1442                 current = limit;
1443
1444         return current;
1445 }
1446
1447 void player_regen ()
1448 {SELFPARAM();
1449         float max_mod, regen_mod, rot_mod, limit_mod;
1450         max_mod = regen_mod = rot_mod = limit_mod = 1;
1451         regen_mod_max = max_mod;
1452         regen_mod_regen = regen_mod;
1453         regen_mod_rot = rot_mod;
1454         regen_mod_limit = limit_mod;
1455
1456         regen_health = autocvar_g_balance_health_regen;
1457         regen_health_linear = autocvar_g_balance_health_regenlinear;
1458         regen_health_rot = autocvar_g_balance_health_rot;
1459         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1460         regen_health_stable = autocvar_g_balance_health_regenstable;
1461         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1462         if(!MUTATOR_CALLHOOK(PlayerRegen))
1463         if(!STAT(FROZEN, self))
1464         {
1465                 float mina, maxa, limith, limita;
1466                 maxa = autocvar_g_balance_armor_rotstable;
1467                 mina = autocvar_g_balance_armor_regenstable;
1468                 limith = autocvar_g_balance_health_limit;
1469                 limita = autocvar_g_balance_armor_limit;
1470
1471                 max_mod = regen_mod_max;
1472                 regen_mod = regen_mod_regen;
1473                 rot_mod = regen_mod_rot;
1474                 limit_mod = regen_mod_limit;
1475
1476                 regen_health_rotstable = regen_health_rotstable * max_mod;
1477                 regen_health_stable = regen_health_stable * max_mod;
1478                 limith = limith * limit_mod;
1479                 limita = limita * limit_mod;
1480
1481                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1482                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1483         }
1484
1485         // if player rotted to death...  die!
1486         // check this outside above checks, as player may still be able to rot to death
1487         if(self.health < 1)
1488         {
1489                 if(self.vehicle)
1490                         vehicles_exit(VHEF_RELEASE);
1491                 if(self.event_damage)
1492                         self.event_damage(self, self, self, 1, DEATH_ROT.m_id, self.origin, '0 0 0');
1493         }
1494
1495         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1496         {
1497                 float minf, maxf, limitf;
1498
1499                 maxf = autocvar_g_balance_fuel_rotstable;
1500                 minf = autocvar_g_balance_fuel_regenstable;
1501                 limitf = autocvar_g_balance_fuel_limit;
1502
1503                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1504         }
1505 }
1506
1507 float zoomstate_set;
1508 void SetZoomState(float z)
1509 {SELFPARAM();
1510         if(z != self.zoomstate)
1511         {
1512                 self.zoomstate = z;
1513                 ClientData_Touch(self);
1514         }
1515         zoomstate_set = 1;
1516 }
1517
1518 void GetPressedKeys()
1519 {
1520         SELFPARAM();
1521         MUTATOR_CALLHOOK(GetPressedKeys);
1522         int keys = this.pressedkeys;
1523         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1524         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1525         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1526         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1527
1528         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1529         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1530         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1531         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1532         this.pressedkeys = keys;
1533 }
1534
1535 /*
1536 ======================
1537 spectate mode routines
1538 ======================
1539 */
1540
1541 void SpectateCopy(entity this, entity spectatee)
1542 {
1543     TC(Client, this); TC(Client, spectatee);
1544
1545         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1546         PS(this) = PS(spectatee);
1547         this.armortype = spectatee.armortype;
1548         this.armorvalue = spectatee.armorvalue;
1549         this.ammo_cells = spectatee.ammo_cells;
1550         this.ammo_plasma = spectatee.ammo_plasma;
1551         this.ammo_shells = spectatee.ammo_shells;
1552         this.ammo_nails = spectatee.ammo_nails;
1553         this.ammo_rockets = spectatee.ammo_rockets;
1554         this.ammo_fuel = spectatee.ammo_fuel;
1555         this.clip_load = spectatee.clip_load;
1556         this.clip_size = spectatee.clip_size;
1557         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1558         this.health = spectatee.health;
1559         this.impulse = 0;
1560         this.items = spectatee.items;
1561         this.last_pickup = spectatee.last_pickup;
1562         this.hit_time = spectatee.hit_time;
1563         this.strength_finished = spectatee.strength_finished;
1564         this.invincible_finished = spectatee.invincible_finished;
1565         this.pressedkeys = spectatee.pressedkeys;
1566         this.weapons = spectatee.weapons;
1567         this.vortex_charge = spectatee.vortex_charge;
1568         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1569         this.hagar_load = spectatee.hagar_load;
1570         this.arc_heat_percent = spectatee.arc_heat_percent;
1571         this.minelayer_mines = spectatee.minelayer_mines;
1572         this.punchangle = spectatee.punchangle;
1573         this.view_ofs = spectatee.view_ofs;
1574         this.velocity = spectatee.velocity;
1575         this.dmg_take = spectatee.dmg_take;
1576         this.dmg_save = spectatee.dmg_save;
1577         this.dmg_inflictor = spectatee.dmg_inflictor;
1578         this.v_angle = spectatee.v_angle;
1579         this.angles = spectatee.v_angle;
1580         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1581         this.revive_progress = spectatee.revive_progress;
1582         if(!PHYS_INPUT_BUTTON_USE(this))
1583                 this.fixangle = true;
1584         setorigin(this, spectatee.origin);
1585         setsize(this, spectatee.mins, spectatee.maxs);
1586         SetZoomState(spectatee.zoomstate);
1587
1588     anticheat_spectatecopy(spectatee);
1589         this.hud = spectatee.hud;
1590         if(spectatee.vehicle)
1591     {
1592         this.fixangle = false;
1593         //this.velocity = spectatee.vehicle.velocity;
1594         this.vehicle_health = spectatee.vehicle_health;
1595         this.vehicle_shield = spectatee.vehicle_shield;
1596         this.vehicle_energy = spectatee.vehicle_energy;
1597         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1598         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1599         this.vehicle_reload1 = spectatee.vehicle_reload1;
1600         this.vehicle_reload2 = spectatee.vehicle_reload2;
1601
1602         msg_entity = this;
1603
1604         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1605             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1606             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1607             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1608
1609         //WriteByte (MSG_ONE, SVC_SETVIEW);
1610         //    WriteEntity(MSG_ONE, this);
1611         //makevectors(spectatee.v_angle);
1612         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1613     }
1614 }
1615
1616 bool SpectateUpdate()
1617 {SELFPARAM();
1618         if(!self.enemy)
1619             return false;
1620
1621         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1622         {
1623                 SetSpectatee(self, NULL);
1624                 return false;
1625         }
1626
1627         SpectateCopy(this, this.enemy);
1628
1629         return true;
1630 }
1631
1632 bool SpectateSet()
1633 {SELFPARAM();
1634         if(!IS_PLAYER(self.enemy))
1635                 return false;
1636
1637         msg_entity = self;
1638         WriteByte(MSG_ONE, SVC_SETVIEW);
1639         WriteEntity(MSG_ONE, self.enemy);
1640         self.movetype = MOVETYPE_NONE;
1641         accuracy_resend(self);
1642
1643         if(!SpectateUpdate())
1644                 PutObserverInServer();
1645
1646         return true;
1647 }
1648
1649 void SetSpectatee(entity player, entity spectatee)
1650 {
1651         entity old_spectatee = player.enemy;
1652
1653         player.enemy = spectatee;
1654
1655         // WEAPONTODO
1656         // these are required to fix the spectator bug with arc
1657         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1658         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1659 }
1660
1661 bool Spectate(entity pl)
1662 {SELFPARAM();
1663         if(MUTATOR_CALLHOOK(SpectateSet, self, pl))
1664                 return false;
1665         pl = spec_player;
1666
1667         SetSpectatee(self, pl);
1668         return SpectateSet();
1669 }
1670
1671 bool SpectateNext()
1672 {SELFPARAM();
1673         other = find(self.enemy, classname, STR_PLAYER);
1674
1675         if (MUTATOR_CALLHOOK(SpectateNext, self, other))
1676                 other = spec_player;
1677         else if (!other)
1678                 other = find(other, classname, STR_PLAYER);
1679
1680         if(other) { SetSpectatee(self, other); }
1681
1682         return SpectateSet();
1683 }
1684
1685 bool SpectatePrev()
1686 {SELFPARAM();
1687         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1688         other = findchain(classname, STR_PLAYER);
1689         if (!other) // no player
1690                 return false;
1691
1692         entity first = other;
1693         // skip players until current spectated player
1694         if(self.enemy)
1695         while(other && other != self.enemy)
1696                 other = other.chain;
1697
1698         switch (MUTATOR_CALLHOOK(SpectatePrev, self, other, first))
1699         {
1700                 case MUT_SPECPREV_FOUND:
1701                     other = spec_player;
1702                     break;
1703                 case MUT_SPECPREV_RETURN:
1704                     other = spec_player;
1705                     return true;
1706                 case MUT_SPECPREV_CONTINUE:
1707                 default:
1708                 {
1709                         if(other.chain)
1710                                 other = other.chain;
1711                         else
1712                                 other = first;
1713                         break;
1714                 }
1715         }
1716
1717         SetSpectatee(self, other);
1718         return SpectateSet();
1719 }
1720
1721 /*
1722 =============
1723 ShowRespawnCountdown()
1724
1725 Update a respawn countdown display.
1726 =============
1727 */
1728 void ShowRespawnCountdown()
1729 {SELFPARAM();
1730         float number;
1731         if(!IS_DEAD(self)) // just respawned?
1732                 return;
1733         else
1734         {
1735                 number = ceil(self.respawn_time - time);
1736                 if(number <= 0)
1737                         return;
1738                 if(number <= self.respawn_countdown)
1739                 {
1740                         self.respawn_countdown = number - 1;
1741                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1742                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1743                 }
1744         }
1745 }
1746
1747 void LeaveSpectatorMode()
1748 {SELFPARAM();
1749         if(self.caplayer)
1750                 return;
1751         if(nJoinAllowed(self, self))
1752         {
1753                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1754                 {
1755                         self.classname = STR_PLAYER;
1756
1757                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1758                                 { JoinBestTeam(self, false, true); }
1759
1760                         if(autocvar_g_campaign)
1761                                 { campaign_bots_may_start = 1; }
1762
1763                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CPID_PREVENT_JOIN);
1764
1765                         PutClientInServer();
1766
1767                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), self.netname); }
1768                 }
1769                 else
1770                         stuffcmd(self, "menu_showteamselect\n");
1771         }
1772         else
1773         {
1774                 // Player may not join because g_maxplayers is set
1775                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1776         }
1777 }
1778
1779 /**
1780  * Determines whether the player is allowed to join. This depends on cvar
1781  * g_maxplayers, if it isn't used this function always return true, otherwise
1782  * it checks whether the number of currently playing players exceeds g_maxplayers.
1783  * @return int number of free slots for players, 0 if none
1784  */
1785 bool nJoinAllowed(entity this, entity ignore)
1786 {
1787         if(!ignore)
1788         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1789         // so report 0 free slots if restricted
1790         {
1791                 if(autocvar_g_forced_team_otherwise == "spectate")
1792                         return false;
1793                 if(autocvar_g_forced_team_otherwise == "spectator")
1794                         return false;
1795         }
1796
1797         if(this.team_forced < 0)
1798                 return false; // forced spectators can never join
1799
1800         // TODO simplify this
1801         int totalClients = 0;
1802         int currentlyPlaying = 0;
1803         FOREACH_CLIENT(true, LAMBDA(
1804                 if(it != ignore)
1805                         ++totalClients;
1806                 if(IS_REAL_CLIENT(it))
1807                 if(IS_PLAYER(it) || it.caplayer)
1808                         ++currentlyPlaying;
1809         ));
1810
1811         if (!autocvar_g_maxplayers)
1812                 return maxclients - totalClients;
1813
1814         if(currentlyPlaying < autocvar_g_maxplayers)
1815                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1816
1817         return false;
1818 }
1819
1820 /**
1821  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1822  * g_maxplayers_spectator_blocktime seconds
1823  */
1824 void checkSpectatorBlock()
1825 {SELFPARAM();
1826         if(IS_SPEC(self) || IS_OBSERVER(self))
1827         if(!self.caplayer)
1828         if(IS_REAL_CLIENT(self))
1829         {
1830                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1831                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1832                         dropclient(self);
1833                 }
1834         }
1835 }
1836
1837 void PrintWelcomeMessage()
1838 {SELFPARAM();
1839         if(self.motd_actived_time == 0)
1840         {
1841                 if (autocvar_g_campaign) {
1842                         if ((IS_PLAYER(self) && PHYS_INPUT_BUTTON_INFO(self)) || (!IS_PLAYER(self))) {
1843                                 self.motd_actived_time = time;
1844                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1845                         }
1846                 } else {
1847                         if (PHYS_INPUT_BUTTON_INFO(self)) {
1848                                 self.motd_actived_time = time;
1849                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1850                         }
1851                 }
1852         }
1853         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
1854         {
1855                 if (autocvar_g_campaign) {
1856                         if (PHYS_INPUT_BUTTON_INFO(self))
1857                                 self.motd_actived_time = time;
1858                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
1859                                 self.motd_actived_time = 0;
1860                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CPID_MOTD);
1861                         }
1862                 } else {
1863                         if (PHYS_INPUT_BUTTON_INFO(self))
1864                                 self.motd_actived_time = time;
1865                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1866                                 self.motd_actived_time = 0;
1867                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CPID_MOTD);
1868                         }
1869                 }
1870         }
1871         else //if(self.motd_actived_time < 0) // just connected, motd is active
1872         {
1873                 if(PHYS_INPUT_BUTTON_INFO(self)) // BUTTON_INFO hides initial MOTD
1874                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1875                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || IS_SPEC(self))
1876                 {
1877                         // instanctly hide MOTD
1878                         self.motd_actived_time = 0;
1879                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CPID_MOTD);
1880                 }
1881         }
1882 }
1883
1884 void ObserverThink()
1885 {SELFPARAM();
1886         if ( self.impulse )
1887         {
1888                 MinigameImpulse(self, self.impulse);
1889                 self.impulse = 0;
1890         }
1891         float prefered_movetype;
1892         if (self.flags & FL_JUMPRELEASED) {
1893                 if (PHYS_INPUT_BUTTON_JUMP(self) && !self.version_mismatch) {
1894                         self.flags &= ~FL_JUMPRELEASED;
1895                         self.flags |= FL_SPAWNING;
1896                 } else if(PHYS_INPUT_BUTTON_ATCK(self) && !self.version_mismatch) {
1897                         self.flags &= ~FL_JUMPRELEASED;
1898                         if(SpectateNext()) {
1899                                 self.classname = STR_SPECTATOR;
1900                         }
1901                 } else {
1902                         prefered_movetype = ((!PHYS_INPUT_BUTTON_USE(self) ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
1903                         if (self.movetype != prefered_movetype)
1904                                 self.movetype = prefered_movetype;
1905                 }
1906         } else {
1907                 if (!(PHYS_INPUT_BUTTON_ATCK(self) || PHYS_INPUT_BUTTON_JUMP(self))) {
1908                         self.flags |= FL_JUMPRELEASED;
1909                         if(self.flags & FL_SPAWNING)
1910                         {
1911                                 self.flags &= ~FL_SPAWNING;
1912                                 LeaveSpectatorMode();
1913                                 return;
1914                         }
1915                 }
1916         }
1917 }
1918
1919 void SpectatorThink()
1920 {SELFPARAM();
1921         if ( self.impulse )
1922         {
1923                 if(MinigameImpulse(self, self.impulse))
1924                         self.impulse = 0;
1925         }
1926         if (self.flags & FL_JUMPRELEASED) {
1927                 if (PHYS_INPUT_BUTTON_JUMP(self) && !self.version_mismatch) {
1928                         self.flags &= ~FL_JUMPRELEASED;
1929                         self.flags |= FL_SPAWNING;
1930                 } else if(PHYS_INPUT_BUTTON_ATCK(self) || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
1931                         self.flags &= ~FL_JUMPRELEASED;
1932                         if(SpectateNext()) {
1933                                 self.classname = STR_SPECTATOR;
1934                         } else {
1935                                 self.classname = STR_OBSERVER;
1936                                 PutClientInServer();
1937                         }
1938                         self.impulse = 0;
1939                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
1940                         self.flags &= ~FL_JUMPRELEASED;
1941                         if(SpectatePrev()) {
1942                                 self.classname = STR_SPECTATOR;
1943                         } else {
1944                                 self.classname = STR_OBSERVER;
1945                                 PutClientInServer();
1946                         }
1947                         self.impulse = 0;
1948                 } else if (PHYS_INPUT_BUTTON_ATCK2(self)) {
1949                         self.flags &= ~FL_JUMPRELEASED;
1950                         self.classname = STR_OBSERVER;
1951                         PutClientInServer();
1952                 } else {
1953                         if(!SpectateUpdate())
1954                                 PutObserverInServer();
1955                 }
1956         } else {
1957                 if (!(PHYS_INPUT_BUTTON_ATCK(self) || PHYS_INPUT_BUTTON_ATCK2(self))) {
1958                         self.flags |= FL_JUMPRELEASED;
1959                         if(self.flags & FL_SPAWNING)
1960                         {
1961                                 self.flags &= ~FL_SPAWNING;
1962                                 LeaveSpectatorMode();
1963                                 return;
1964                         }
1965                 }
1966                 if(!SpectateUpdate())
1967                         PutObserverInServer();
1968         }
1969
1970         self.flags |= FL_CLIENT | FL_NOTARGET;
1971 }
1972
1973 void vehicles_enter (entity pl, entity veh);
1974 void PlayerUseKey()
1975 {SELFPARAM();
1976         if (!IS_PLAYER(self))
1977                 return;
1978
1979         if(self.vehicle)
1980         {
1981                 if(!gameover)
1982                 {
1983                         vehicles_exit(VHEF_NORMAL);
1984                         return;
1985                 }
1986         }
1987         else if(autocvar_g_vehicles_enter)
1988         {
1989                 if(!STAT(FROZEN, self))
1990                 if(!IS_DEAD(self))
1991                 if(!gameover)
1992                 {
1993                         entity head, closest_target = world;
1994                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, true);
1995
1996                         while(head) // find the closest acceptable target to enter
1997                         {
1998                                 if(head.vehicle_flags & VHF_ISVEHICLE)
1999                                 if(!IS_DEAD(head))
2000                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2001                                 if(head.takedamage != DAMAGE_NO)
2002                                 {
2003                                         if(closest_target)
2004                                         {
2005                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2006                                                 { closest_target = head; }
2007                                         }
2008                                         else { closest_target = head; }
2009                                 }
2010
2011                                 head = head.chain;
2012                         }
2013
2014                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2015                 }
2016         }
2017
2018         // a use key was pressed; call handlers
2019         MUTATOR_CALLHOOK(PlayerUseKey);
2020 }
2021
2022
2023 /*
2024 =============
2025 PlayerPreThink
2026
2027 Called every frame for each client before the physics are run
2028 =============
2029 */
2030 .float usekeypressed;
2031 void() nexball_setstatus;
2032 .float last_vehiclecheck;
2033 .int items_added;
2034 void PlayerPreThink ()
2035 {SELFPARAM();
2036         WarpZone_PlayerPhysics_FixVAngle();
2037
2038         self.stat_game_starttime = game_starttime;
2039         self.stat_round_starttime = round_starttime;
2040         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2041         self.stat_leadlimit = autocvar_leadlimit;
2042
2043         self.weaponsinmap = weaponsInMap;
2044
2045         if(frametime)
2046         {
2047                 // physics frames: update anticheat stuff
2048                 anticheat_prethink();
2049         }
2050
2051         if(blockSpectators && frametime)
2052                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2053                 checkSpectatorBlock();
2054
2055         zoomstate_set = 0;
2056
2057         // Savage: Check for nameless players
2058         if (isInvisibleString(self.netname)) {
2059                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2060                 if(autocvar_sv_eventlog)
2061                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2062                 if(self.netname_previous)
2063                         strunzone(self.netname_previous);
2064                 self.netname_previous = strzone(new_name);
2065                 self.netname = self.netname_previous;
2066                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2067         } else if(self.netname_previous != self.netname) {
2068                 if(autocvar_sv_eventlog)
2069                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2070                 if(self.netname_previous)
2071                         strunzone(self.netname_previous);
2072                 self.netname_previous = strzone(self.netname);
2073         }
2074
2075         // version nagging
2076         if(self.version_nagtime)
2077                 if(self.cvar_g_xonoticversion)
2078                         if(time > self.version_nagtime)
2079                         {
2080                                 // don't notify git users
2081                                 if(strstrofs(self.cvar_g_xonoticversion, "git", 0) < 0 && strstrofs(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2082                                 {
2083                                         if(strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2084                                         {
2085                                                 // notify release users if connecting to git
2086                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2087                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2088                                         }
2089                                         else
2090                                         {
2091                                                 float r;
2092                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2093                                                 if(r < 0)
2094                                                 {
2095                                                         // give users new version
2096                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2097                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2098                                                 }
2099                                                 else if(r > 0)
2100                                                 {
2101                                                         // notify users about old server version
2102                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2103                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2104                                                 }
2105                                         }
2106                                 }
2107                                 self.version_nagtime = 0;
2108                         }
2109
2110         // GOD MODE info
2111         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2112         {
2113                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2114                 self.max_armorvalue = 0;
2115         }
2116
2117         if(STAT(FROZEN, self) == 2)
2118         {
2119                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2120                 self.health = max(1, self.revive_progress * start_health);
2121                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2122
2123                 if(self.revive_progress >= 1)
2124                         Unfreeze(self);
2125         }
2126         else if(STAT(FROZEN, self) == 3)
2127         {
2128                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2129                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2130
2131                 if(self.health < 1)
2132                 {
2133                         if(self.vehicle)
2134                                 vehicles_exit(VHEF_RELEASE);
2135                         self.event_damage(self, self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, self.origin, '0 0 0');
2136                 }
2137                 else if ( self.revive_progress <= 0 )
2138                         Unfreeze(self);
2139         }
2140
2141         MUTATOR_CALLHOOK(PlayerPreThink);
2142
2143         if(autocvar_g_vehicles_enter)
2144         if(time > self.last_vehiclecheck)
2145         if(IS_PLAYER(self))
2146         if(!gameover)
2147         if(!STAT(FROZEN, self))
2148         if(!self.vehicle)
2149         if(!IS_DEAD(self))
2150         {
2151                 entity veh;
2152                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2153                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2154                 if(!IS_DEAD(veh))
2155                 if(veh.takedamage != DAMAGE_NO)
2156                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2157                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2158                 else if(!veh.owner)
2159                 if(!veh.team || SAME_TEAM(self, veh))
2160                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2161                 else if(autocvar_g_vehicles_steal)
2162                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2163
2164                 self.last_vehiclecheck = time + 1;
2165         }
2166
2167         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2168         {
2169                 if(PHYS_INPUT_BUTTON_USE(self) && !self.usekeypressed)
2170                         PlayerUseKey();
2171                 self.usekeypressed = PHYS_INPUT_BUTTON_USE(self);
2172         }
2173
2174         if(IS_REAL_CLIENT(self))
2175                 PrintWelcomeMessage();
2176
2177         if(IS_PLAYER(self))
2178         {
2179
2180                 CheckRules_Player();
2181
2182                 if (intermission_running)
2183                 {
2184                         IntermissionThink ();   // otherwise a button could be missed between
2185                         return;                                 // the think tics
2186                 }
2187
2188                 //don't allow the player to turn around while game is paused!
2189                 if(timeout_status == TIMEOUT_ACTIVE) {
2190                         // FIXME turn this into CSQC stuff
2191                         self.v_angle = self.lastV_angle;
2192                         self.angles = self.lastV_angle;
2193                         self.fixangle = true;
2194                 }
2195
2196                 if(frametime)
2197                 {
2198                         player_powerups();
2199                 }
2200
2201                 if (IS_DEAD(self))
2202                 {
2203                         if(self.personal && g_race_qualifying)
2204                         {
2205                                 if(time > self.respawn_time)
2206                                 {
2207                                         self.respawn_time = time + 1; // only retry once a second
2208                                         self.stat_respawn_time = self.respawn_time;
2209                                         respawn();
2210                                         self.impulse = 141;
2211                                 }
2212                         }
2213                         else
2214                         {
2215                                 float button_pressed;
2216                                 if(frametime)
2217                                         player_anim();
2218                                 button_pressed = (PHYS_INPUT_BUTTON_ATCK(self) || PHYS_INPUT_BUTTON_JUMP(self) || PHYS_INPUT_BUTTON_ATCK2(self) || PHYS_INPUT_BUTTON_HOOK(self) || PHYS_INPUT_BUTTON_USE(self));
2219
2220                                 if (self.deadflag == DEAD_DYING)
2221                                 {
2222                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2223                                                 self.deadflag = DEAD_RESPAWNING;
2224                                         else if(!button_pressed)
2225                                                 self.deadflag = DEAD_DEAD;
2226                                 }
2227                                 else if (self.deadflag == DEAD_DEAD)
2228                                 {
2229                                         if(button_pressed)
2230                                                 self.deadflag = DEAD_RESPAWNABLE;
2231                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2232                                                 self.deadflag = DEAD_RESPAWNING;
2233                                 }
2234                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2235                                 {
2236                                         if(!button_pressed)
2237                                                 self.deadflag = DEAD_RESPAWNING;
2238                                 }
2239                                 else if (self.deadflag == DEAD_RESPAWNING)
2240                                 {
2241                                         if(time > self.respawn_time)
2242                                         {
2243                                                 self.respawn_time = time + 1; // only retry once a second
2244                                                 self.respawn_time_max = self.respawn_time;
2245                                                 respawn();
2246                                         }
2247                                 }
2248
2249                                 ShowRespawnCountdown();
2250
2251                                 if(self.respawn_flags & RESPAWN_SILENT)
2252                                         self.stat_respawn_time = 0;
2253                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2254                                         self.stat_respawn_time = self.respawn_time_max;
2255                                 else
2256                                         self.stat_respawn_time = self.respawn_time;
2257                         }
2258
2259                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2260                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2261                                 self.stat_respawn_time *= -1;
2262
2263                         return;
2264                 }
2265
2266                 self.prevorigin = self.origin;
2267
2268                 float do_crouch = PHYS_INPUT_BUTTON_CROUCH(self);
2269                 if(self.hook.state)
2270                         do_crouch = 0;
2271                 if(self.vehicle)
2272                         do_crouch = 0;
2273                 if(STAT(FROZEN, self))
2274                         do_crouch = 0;
2275
2276                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2277                 // It cannot be predicted by the engine!
2278                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
2279                 if((PS(self).m_weapon == WEP_SHOCKWAVE || PS(self).m_weapon == WEP_SHOTGUN) && self.(weaponentity).wframe == WFRAME_FIRE2 && time < self.(weaponentity).weapon_nextthink)
2280                         do_crouch = 0;
2281
2282                 if (do_crouch)
2283                 {
2284                         if (!self.crouch)
2285                         {
2286                                 self.crouch = true;
2287                                 self.view_ofs = STAT(PL_CROUCH_VIEW_OFS, self);
2288                                 setsize (self, STAT(PL_CROUCH_MIN, self), STAT(PL_CROUCH_MAX, self));
2289                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2290                         }
2291                 }
2292                 else
2293                 {
2294                         if (self.crouch)
2295                         {
2296                                 tracebox(self.origin, STAT(PL_MIN, self), STAT(PL_MAX, self), self.origin, false, self);
2297                                 if (!trace_startsolid)
2298                                 {
2299                                         self.crouch = false;
2300                                         self.view_ofs = STAT(PL_VIEW_OFS, self);
2301                                         setsize (self, STAT(PL_MIN, self), STAT(PL_MAX, self));
2302                                 }
2303                         }
2304                 }
2305
2306                 FixPlayermodel(self);
2307
2308                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2309                 //if(frametime)
2310                 {
2311                         self.items &= ~self.items_added;
2312
2313                         W_WeaponFrame(self);
2314
2315                         self.items_added = 0;
2316                         if(self.items & ITEM_Jetpack.m_itemid)
2317                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2318                                         self.items_added |= IT_FUEL;
2319
2320                         self.items |= self.items_added;
2321                 }
2322
2323                 player_regen();
2324
2325                 // WEAPONTODO: Add a weapon request for this
2326                 // rot vortex charge to the charge limit
2327                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2328                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2329
2330                 if(frametime)
2331                         player_anim();
2332
2333                 // secret status
2334                 secrets_setstatus();
2335
2336                 // monsters status
2337                 monsters_setstatus(self);
2338
2339                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2340
2341                 //self.angles_y=self.v_angle_y + 90;   // temp
2342         } else if(gameover) {
2343                 if (intermission_running)
2344                         IntermissionThink ();   // otherwise a button could be missed between
2345                 return;
2346         } else if(IS_OBSERVER(self)) {
2347                 ObserverThink();
2348         } else if(IS_SPEC(self)) {
2349                 SpectatorThink();
2350         }
2351
2352         // WEAPONTODO: Add weapon request for this
2353         if(!zoomstate_set)
2354                 SetZoomState(
2355                         PHYS_INPUT_BUTTON_ZOOM(self)
2356                         || PHYS_INPUT_BUTTON_ZOOMSCRIPT(self)
2357                         || (PHYS_INPUT_BUTTON_ATCK2(self) && PS(self).m_weapon == WEP_VORTEX)
2358                         || (PHYS_INPUT_BUTTON_ATCK2(self) && PS(self).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2359                 ); // WEAPONTODO
2360
2361         float oldspectatee_status;
2362         oldspectatee_status = self.spectatee_status;
2363         if(IS_SPEC(self))
2364                 self.spectatee_status = etof(self.enemy);
2365         else if(IS_OBSERVER(self))
2366                 self.spectatee_status = etof(self);
2367         else
2368                 self.spectatee_status = 0;
2369         if(self.spectatee_status != oldspectatee_status)
2370         {
2371                 ClientData_Touch(self);
2372                 if(g_race || g_cts)
2373                         race_InitSpectator();
2374         }
2375
2376         if(self.teamkill_soundtime)
2377         if(time > self.teamkill_soundtime)
2378         {
2379                 self.teamkill_soundtime = 0;
2380
2381                 entity e = self.teamkill_soundsource;
2382                 entity oldpusher = e.pusher;
2383                 e.pusher = this;
2384                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2385                 e.pusher = oldpusher;
2386         }
2387
2388         if(self.taunt_soundtime)
2389         if(time > self.taunt_soundtime)
2390         {
2391                 self.taunt_soundtime = 0;
2392                 PlayerSound(self, playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2393         }
2394
2395         target_voicescript_next(self);
2396
2397         // WEAPONTODO: Move into weaponsystem somehow
2398         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2399         if (PS(self).m_weapon == WEP_Null)
2400                 self.clip_load = self.clip_size = 0;
2401 }
2402
2403 void DrownPlayer(entity this)
2404 {
2405         if(IS_DEAD(this))
2406                 return;
2407
2408         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2409         {
2410                 if(this.air_finished < time)
2411                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
2412                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2413                 this.dmg = 2;
2414         }
2415         else if (this.air_finished < time)
2416         {       // drown!
2417                 if (this.pain_finished < time)
2418                 {
2419                         Damage (this, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2420                         this.pain_finished = time + 0.5;
2421                 }
2422         }
2423 }
2424
2425 /*
2426 =============
2427 PlayerPostThink
2428
2429 Called every frame for each client after the physics are run
2430 =============
2431 */
2432 .float idlekick_lasttimeleft;
2433 void PlayerPostThink ()
2434 {SELFPARAM();
2435         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2436         if(IS_REAL_CLIENT(self))
2437         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2438         {
2439                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2440                 {
2441                         if(self.idlekick_lasttimeleft)
2442                         {
2443                                 self.idlekick_lasttimeleft = 0;
2444                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CPID_IDLING);
2445                         }
2446                 }
2447                 else
2448                 {
2449                         float timeleft;
2450                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2451                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2452                         {
2453                                 if(!self.idlekick_lasttimeleft)
2454                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2455                         }
2456                         if(timeleft <= 0)
2457                         {
2458                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2459                                 dropclient(self);
2460                                 return;
2461                         }
2462                         else if(timeleft <= 10)
2463                         {
2464                                 if(timeleft != self.idlekick_lasttimeleft)
2465                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2466                                 self.idlekick_lasttimeleft = timeleft;
2467                         }
2468                 }
2469         }
2470
2471         CheatFrame();
2472
2473         //CheckPlayerJump();
2474
2475         if(IS_PLAYER(self)) {
2476                 DrownPlayer(self);
2477                 CheckRules_Player();
2478                 UpdateChatBubble();
2479                 if (self.impulse)
2480                         ImpulseCommands(self);
2481                 if (intermission_running)
2482                         return;         // intermission or finale
2483                 GetPressedKeys();
2484         }
2485
2486         /*
2487         float i;
2488         for(i = 0; i < 1000; ++i)
2489         {
2490                 vector end;
2491                 end = self.origin + '0 0 1024' + 512 * randomvec();
2492                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2493                 if(trace_fraction < 1)
2494                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2495                 {
2496                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2497                         break;
2498                 }
2499         }
2500         */
2501
2502         if(self.waypointsprite_attachedforcarrier)
2503                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id));
2504
2505         playerdemo_write();
2506
2507         CSQCMODEL_AUTOUPDATE(self);
2508 }