qcsrc/server/cl_client.qc

   1 #include "waypointsprites.qh"
   2
   3 #include "cl_impulse.qh"
   4 #include "cl_player.qh"
   5 #include "ent_cs.qh"
   6 #include "g_subs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "secret.qh"
  13
  14 #include "bot/bot.qh"
  15 #include "bot/navigation.qh"
  16
  17 #include "weapons/hitplot.qh"
  18 #include "weapons/weaponsystem.qh"
  19
  20 #include "../common/net_notice.qh"
  21
  22 #include "../common/monsters/sv_monsters.qh"
  23
  24 #include "../warpzonelib/server.qh"
  25
  26 float c1, c2, c3, c4;
  27
  28 void send_CSQC_teamnagger() {
  29         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  30         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  31 }
  32
  33 float ClientData_Send(entity to, int sf)
  34 {
  35         if(to != self.owner)
  36         {
  37                 error("wtf");
  38                 return false;
  39         }
  40
  41         entity e;
  42
  43         e = to;
  44         if(IS_SPEC(to))
  45                 e = to.enemy;
  46
  47         sf = 0;
  48
  49         if(e.race_completed)
  50                 sf |= 1; // forced scoreboard
  51         if(to.spectatee_status)
  52                 sf |= 2; // spectator ent number follows
  53         if(e.zoomstate)
  54                 sf |= 4; // zoomed
  55         if(e.porto_v_angle_held)
  56                 sf |= 8; // angles held
  57
  58         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  59         WriteByte(MSG_ENTITY, sf);
  60
  61         if(sf & 2)
  62                 WriteByte(MSG_ENTITY, to.spectatee_status);
  63
  64         if(sf & 8)
  65         {
  66                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  67                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  68         }
  69
  70         return true;
  71 }
  72
  73 void ClientData_Attach()
  74 {
  75         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  76         self.clientdata.drawonlytoclient = self;
  77         self.clientdata.owner = self;
  78 }
  79
  80 void ClientData_Detach()
  81 {
  82         remove(self.clientdata);
  83         self.clientdata = world;
  84 }
  85
  86 void ClientData_Touch(entity e)
  87 {
  88         e.clientdata.SendFlags = 1;
  89
  90         // make it spectatable
  91         entity e2;
  92         FOR_EACH_REALCLIENT(e2)
  93         {
  94                 if(e2 != e)
  95                         if(IS_SPEC(e2))
  96                                 if(e2.enemy == e)
  97                                         e2.clientdata.SendFlags = 1;
  98         }
  99 }
 100
 101 .string netname_previous;
 102
 103 void SetSpectator(entity player, entity spectatee);
 104
 105
 106 /*
 107 =============
 108 CheckPlayerModel
 109
 110 Checks if the argument string can be a valid playermodel.
 111 Returns a valid one in doubt.
 112 =============
 113 */
 114 string FallbackPlayerModel;
 115 string CheckPlayerModel(string plyermodel) {
 116         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 117         {
 118                 // note: we cannot summon Don Strunzone here, some player may
 119                 // still have the model string set. In case anyone manages how
 120                 // to change a cvar default, we'll have a small leak here.
 121                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 122         }
 123         // only in right path
 124         if( substring(plyermodel,0,14) != "models/player/")
 125                 return FallbackPlayerModel;
 126         // only good file extensions
 127         if(substring(plyermodel,-4,4) != ".zym")
 128         if(substring(plyermodel,-4,4) != ".dpm")
 129         if(substring(plyermodel,-4,4) != ".iqm")
 130         if(substring(plyermodel,-4,4) != ".md3")
 131         if(substring(plyermodel,-4,4) != ".psk")
 132                 return FallbackPlayerModel;
 133         // forbid the LOD models
 134         if(substring(plyermodel, -9,5) == "_lod1")
 135                 return FallbackPlayerModel;
 136         if(substring(plyermodel, -9,5) == "_lod2")
 137                 return FallbackPlayerModel;
 138         if(plyermodel != strtolower(plyermodel))
 139                 return FallbackPlayerModel;
 140         // also, restrict to server models
 141         if(autocvar_sv_servermodelsonly)
 142         {
 143                 if(!fexists(plyermodel))
 144                         return FallbackPlayerModel;
 145         }
 146         return plyermodel;
 147 }
 148
 149 void setplayermodel(entity e, string modelname)
 150 {
 151         precache_model(modelname);
 152         setmodel(e, modelname);
 153         player_setupanimsformodel();
 154         UpdatePlayerSounds();
 155 }
 156
 157 /*
 158 =============
 159 PutObserverInServer
 160
 161 putting a client as observer in the server
 162 =============
 163 */
 164 void FixPlayermodel();
 165 void PutObserverInServer (void)
 166 {
 167         entity  spot;
 168     self.hud = HUD_NORMAL;
 169
 170         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 171
 172         spot = SelectSpawnPoint (true);
 173         if(!spot)
 174                 error("No spawnpoints for observers?!?\n");
 175         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 176
 177         if(IS_REAL_CLIENT(self))
 178         {
 179                 msg_entity = self;
 180                 WriteByte(MSG_ONE, SVC_SETVIEW);
 181                 WriteEntity(MSG_ONE, self);
 182         }
 183
 184         self.frags = FRAGS_SPECTATOR;
 185
 186         MUTATOR_CALLHOOK(MakePlayerObserver);
 187
 188         Portal_ClearAll(self);
 189
 190         Unfreeze(self);
 191
 192         if(self.alivetime)
 193         {
 194                 if(!warmup_stage)
 195                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 196                 self.alivetime = 0;
 197         }
 198
 199         if(self.vehicle)
 200                 vehicles_exit(VHEF_RELESE);
 201
 202         WaypointSprite_PlayerDead();
 203
 204         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 205                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 206
 207         if(self.killcount != -666)
 208         {
 209                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 210                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 211                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 212
 213                 if(self.just_joined == false) {
 214                         LogTeamchange(self.playerid, -1, 4);
 215                 } else
 216                         self.just_joined = false;
 217         }
 218
 219         PlayerScore_Clear(self); // clear scores when needed
 220
 221         accuracy_resend(self);
 222
 223         self.spectatortime = time;
 224
 225         self.classname = "observer";
 226         self.iscreature = false;
 227         self.teleportable = TELEPORT_SIMPLE;
 228         self.damagedbycontents = false;
 229         self.health = -666;
 230         self.takedamage = DAMAGE_NO;
 231         self.solid = SOLID_NOT;
 232         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 233         self.flags = FL_CLIENT | FL_NOTARGET;
 234         self.armorvalue = 666;
 235         self.effects = 0;
 236         self.armorvalue = autocvar_g_balance_armor_start;
 237         self.pauserotarmor_finished = 0;
 238         self.pauserothealth_finished = 0;
 239         self.pauseregen_finished = 0;
 240         self.damageforcescale = 0;
 241         self.death_time = 0;
 242         self.respawn_flags = 0;
 243         self.respawn_time = 0;
 244         self.stat_respawn_time = 0;
 245         self.alpha = 0;
 246         self.scale = 0;
 247         self.fade_time = 0;
 248         self.pain_frame = 0;
 249         self.pain_finished = 0;
 250         self.strength_finished = 0;
 251         self.invincible_finished = 0;
 252         self.superweapons_finished = 0;
 253         self.pushltime = 0;
 254         self.istypefrag = 0;
 255         self.think = func_null;
 256         self.nextthink = 0;
 257         self.hook_time = 0;
 258         self.deadflag = DEAD_NO;
 259         self.angles = spot.angles;
 260         self.angles_z = 0;
 261         self.fixangle = true;
 262         self.crouch = false;
 263         self.revival_time = 0;
 264
 265         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 266         self.prevorigin = self.origin;
 267         self.items = 0;
 268         self.weapons = '0 0 0';
 269         self.model = "";
 270         FixPlayermodel();
 271         setmodel(self, "null");
 272         self.drawonlytoclient = self;
 273
 274         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 275         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 276
 277         self.weapon = 0;
 278         self.weaponname = "";
 279         self.switchingweapon = 0;
 280         self.weaponmodel = "";
 281         self.weaponentity = world;
 282         self.exteriorweaponentity = world;
 283         self.killcount = -666;
 284         self.velocity = '0 0 0';
 285         self.avelocity = '0 0 0';
 286         self.punchangle = '0 0 0';
 287         self.punchvector = '0 0 0';
 288         self.oldvelocity = self.velocity;
 289         self.fire_endtime = -1;
 290         self.event_damage = func_null;
 291 }
 292
 293 .float model_randomizer;
 294 void FixPlayermodel()
 295 {
 296         string defaultmodel;
 297         float defaultskin, chmdl, oldskin, n, i;
 298         vector m1, m2;
 299
 300         defaultmodel = "";
 301         defaultskin = 0;
 302         chmdl = false;
 303
 304         if(autocvar_sv_defaultcharacter == 1)
 305         {
 306                 if(teamplay)
 307                 {
 308                         string s;
 309                         s = Static_Team_ColorName_Lower(self.team);
 310                         if(s != "neutral")
 311                         {
 312                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 313                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 314                         }
 315                 }
 316
 317                 if(defaultmodel == "")
 318                 {
 319                         defaultmodel = autocvar_sv_defaultplayermodel;
 320                         defaultskin = autocvar_sv_defaultplayerskin;
 321                 }
 322
 323                 n = tokenize_console(defaultmodel);
 324                 if(n > 0)
 325                 {
 326                         defaultmodel = argv(floor(n * self.model_randomizer));
 327                         // However, do NOT randomize if the player-selected model is in the list.
 328                         for (i = 0; i < n; ++i)
 329                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 330                                         defaultmodel = argv(i);
 331                 }
 332
 333                 i = strstrofs(defaultmodel, ":", 0);
 334                 if(i >= 0)
 335                 {
 336                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 337                         defaultmodel = substring(defaultmodel, 0, i);
 338                 }
 339         }
 340
 341         if(defaultmodel != "")
 342         {
 343                 if (defaultmodel != self.model)
 344                 {
 345                         m1 = self.mins;
 346                         m2 = self.maxs;
 347                         setplayermodel (self, defaultmodel);
 348                         setsize (self, m1, m2);
 349                         chmdl = true;
 350                 }
 351
 352                 oldskin = self.skin;
 353                 self.skin = defaultskin;
 354         } else {
 355                 if (self.playermodel != self.model || self.playermodel == "")
 356                 {
 357                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 358                         m1 = self.mins;
 359                         m2 = self.maxs;
 360                         setplayermodel (self, self.playermodel);
 361                         setsize (self, m1, m2);
 362                         chmdl = true;
 363                 }
 364
 365                 oldskin = self.skin;
 366                 self.skin = stof(self.playerskin);
 367         }
 368
 369         if(chmdl || oldskin != self.skin) // model or skin has changed
 370         {
 371                 self.species = player_getspecies(); // update species
 372                 UpdatePlayerSounds(); // update skin sounds
 373         }
 374
 375         if(!teamplay)
 376                 if(strlen(autocvar_sv_defaultplayercolors))
 377                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 378                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 379 }
 380
 381 /*
 382 =============
 383 PutClientInServer
 384
 385 Called when a client spawns in the server
 386 =============
 387 */
 388 void PutClientInServer (void)
 389 {
 390         if(IS_BOT_CLIENT(self))
 391                 self.classname = "player";
 392         else if(IS_REAL_CLIENT(self))
 393         {
 394                 msg_entity = self;
 395                 WriteByte(MSG_ONE, SVC_SETVIEW);
 396                 WriteEntity(MSG_ONE, self);
 397         }
 398
 399         SetSpectator(self, world);
 400
 401         // reset player keys
 402         self.itemkeys = 0;
 403
 404         MUTATOR_CALLHOOK(PutClientInServer);
 405
 406         if(gameover)
 407                 self.classname = "observer";
 408
 409         if(IS_PLAYER(self))
 410         {
 411                 entity spot, oldself;
 412                 float j;
 413
 414                 accuracy_resend(self);
 415
 416                 if(self.team < 0)
 417                         JoinBestTeam(self, false, true);
 418
 419                 spot = SelectSpawnPoint (false);
 420                 if(!spot)
 421                 {
 422                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 423                         return; // spawn failed
 424                 }
 425
 426                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 427
 428                 if(self.vehicle)
 429                         vehicles_exit(VHEF_RELESE);
 430
 431                 self.classname = "player";
 432                 self.wasplayer = true;
 433                 self.iscreature = true;
 434                 self.teleportable = TELEPORT_NORMAL;
 435                 self.damagedbycontents = true;
 436                 self.movetype = MOVETYPE_WALK;
 437                 self.solid = SOLID_SLIDEBOX;
 438                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 439                 if(autocvar_g_playerclip_collisions)
 440                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 441                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 442                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 443                 self.frags = FRAGS_PLAYER;
 444                 if(INDEPENDENT_PLAYERS)
 445                         MAKE_INDEPENDENT_PLAYER(self);
 446                 self.flags = FL_CLIENT;
 447                 if(autocvar__notarget)
 448                         self.flags |= FL_NOTARGET;
 449                 self.takedamage = DAMAGE_AIM;
 450                 self.effects = 0;
 451                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 452                 self.air_finished = time + 12;
 453                 self.dmg = 2;
 454                 if(WEP_CVAR(vortex, charge))
 455                 {
 456                         if(WEP_CVAR_SEC(vortex, chargepool))
 457                                 self.vortex_chargepool_ammo = 1;
 458                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 459                 }
 460
 461                 if(warmup_stage)
 462                 {
 463                         self.ammo_shells = warmup_start_ammo_shells;
 464                         self.ammo_nails = warmup_start_ammo_nails;
 465                         self.ammo_rockets = warmup_start_ammo_rockets;
 466                         self.ammo_cells = warmup_start_ammo_cells;
 467                         self.ammo_plasma = warmup_start_ammo_plasma;
 468                         self.ammo_fuel = warmup_start_ammo_fuel;
 469                         self.health = warmup_start_health;
 470                         self.armorvalue = warmup_start_armorvalue;
 471                         self.weapons = WARMUP_START_WEAPONS;
 472                 }
 473                 else
 474                 {
 475                         self.ammo_shells = start_ammo_shells;
 476                         self.ammo_nails = start_ammo_nails;
 477                         self.ammo_rockets = start_ammo_rockets;
 478                         self.ammo_cells = start_ammo_cells;
 479                         self.ammo_plasma = start_ammo_plasma;
 480                         self.ammo_fuel = start_ammo_fuel;
 481                         self.health = start_health;
 482                         self.armorvalue = start_armorvalue;
 483                         self.weapons = start_weapons;
 484                 }
 485
 486                 if(self.weapons & WEPSET_SUPERWEAPONS)
 487                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 488                 else
 489                         self.superweapons_finished = 0;
 490
 491                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 492                 {
 493                         if(g_weaponarena_random_with_blaster)
 494                                 self.weapons &= ~WEPSET_BLASTER;
 495                         W_RandomWeapons(self, g_weaponarena_random);
 496                         if(g_weaponarena_random_with_blaster)
 497                                 self.weapons |= WEPSET_BLASTER;
 498                 }
 499
 500                 self.items = start_items;
 501
 502                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 503                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 504                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 505                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 506                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 507                 //extend the pause of rotting if client was reset at the beginning of the countdown
 508                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 509                         self.spawnshieldtime += game_starttime - time;
 510                         self.pauserotarmor_finished += game_starttime - time;
 511                         self.pauserothealth_finished += game_starttime - time;
 512                         self.pauseregen_finished += game_starttime - time;
 513                 }
 514                 self.damageforcescale = 2;
 515                 self.death_time = 0;
 516                 self.respawn_flags = 0;
 517                 self.respawn_time = 0;
 518                 self.stat_respawn_time = 0;
 519                 self.scale = 0;
 520                 self.fade_time = 0;
 521                 self.pain_frame = 0;
 522                 self.pain_finished = 0;
 523                 self.strength_finished = 0;
 524                 self.invincible_finished = 0;
 525                 self.pushltime = 0;
 526                 // players have no think function
 527                 self.think = func_null;
 528                 self.nextthink = 0;
 529                 self.hook_time = 0;
 530                 self.dmg_team = 0;
 531                 self.ballistics_density = autocvar_g_ballistics_density_player;
 532
 533                 self.metertime = 0;
 534
 535                 self.deadflag = DEAD_NO;
 536
 537                 self.angles = spot.angles;
 538
 539                 self.angles_z = 0; // never spawn tilted even if the spot says to
 540                 if(IS_BOT_CLIENT(self))
 541                         self.v_angle = self.angles;
 542                 self.fixangle = true; // turn this way immediately
 543                 self.velocity = '0 0 0';
 544                 self.avelocity = '0 0 0';
 545                 self.punchangle = '0 0 0';
 546                 self.punchvector = '0 0 0';
 547                 self.oldvelocity = self.velocity;
 548                 self.fire_endtime = -1;
 549                 self.revival_time = 0;
 550
 551                 entity spawnevent = spawn();
 552                 spawnevent.owner = self;
 553                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 554
 555                 // Cut off any still running player sounds.
 556                 stopsound(self, CH_PLAYER_SINGLE);
 557
 558                 self.model = "";
 559                 FixPlayermodel();
 560                 self.drawonlytoclient = world;
 561
 562                 self.crouch = false;
 563                 self.view_ofs = PL_VIEW_OFS;
 564                 setsize (self, PL_MIN, PL_MAX);
 565                 self.spawnorigin = spot.origin;
 566                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 567                 // don't reset back to last position, even if new position is stuck in solid
 568                 self.oldorigin = self.origin;
 569                 self.prevorigin = self.origin;
 570                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 571                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 572         self.hud = HUD_NORMAL;
 573
 574                 self.event_damage = PlayerDamage;
 575
 576                 self.bot_attack = true;
 577                 self.monster_attack = true;
 578
 579                 self.spider_slowness = 0;
 580
 581                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 582
 583                 if(self.killcount == -666) {
 584                         PlayerScore_Clear(self);
 585                         self.killcount = 0;
 586                 }
 587
 588                 CL_SpawnWeaponentity();
 589                 self.alpha = default_player_alpha;
 590                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 591                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 592
 593                 self.speedrunning = false;
 594
 595                 //stuffcmd(self, "chase_active 0");
 596                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 597
 598                 target_voicescript_clear(self);
 599
 600                 // reset fields the weapons may use
 601                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 602                 {
 603                         WEP_ACTION(j, WR_RESETPLAYER);
 604
 605                         // all weapons must be fully loaded when we spawn
 606                         entity e = get_weaponinfo(j);
 607                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 608                                 self.(weapon_load[j]) = e.reloading_ammo;
 609                 }
 610
 611                 oldself = self;
 612                 self = spot;
 613                         activator = oldself;
 614                                 string s;
 615                                 s = self.target;
 616                                 self.target = string_null;
 617                                 SUB_UseTargets();
 618                                 self.target = s;
 619                         activator = world;
 620                 self = oldself;
 621
 622                 Unfreeze(self);
 623
 624                 spawn_spot = spot;
 625                 MUTATOR_CALLHOOK(PlayerSpawn);
 626
 627                 if(autocvar_spawn_debug)
 628                 {
 629                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 630                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 631                 }
 632
 633                 self.switchweapon = w_getbestweapon(self);
 634                 self.cnt = -1; // W_LastWeapon will not complain
 635                 self.weapon = 0;
 636                 self.weaponname = "";
 637                 self.switchingweapon = 0;
 638
 639                 if(!warmup_stage)
 640                         if(!self.alivetime)
 641                                 self.alivetime = time;
 642
 643                 antilag_clear(self);
 644         }
 645         else if(IS_OBSERVER(self))
 646         {
 647                 PutObserverInServer ();
 648         }
 649 }
 650
 651 .float ebouncefactor, ebouncestop; // electro's values
 652 // TODO do we need all these fields, or should we stop autodetecting runtime
 653 // changes and just have a console command to update this?
 654 float ClientInit_SendEntity(entity to, int sf)
 655 {
 656         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 657         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 658         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 659         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 660         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 661         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 662         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 663         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 664         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 665         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 666
 667         if(sv_foginterval && world.fog != "")
 668                 WriteString(MSG_ENTITY, world.fog);
 669         else
 670                 WriteString(MSG_ENTITY, "");
 671         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 672         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 673         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 674         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 675         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 676         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 677         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 678         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 679         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 680         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 681         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 682         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 683         return true;
 684 }
 685
 686 void ClientInit_CheckUpdate()
 687 {
 688         self.nextthink = time;
 689         if(self.count != autocvar_g_balance_armor_blockpercent)
 690         {
 691                 self.count = autocvar_g_balance_armor_blockpercent;
 692                 self.SendFlags |= 1;
 693         }
 694         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 695         {
 696                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 697                 self.SendFlags |= 1;
 698         }
 699         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 700         {
 701                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 702                 self.SendFlags |= 1;
 703         }
 704         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 705         {
 706                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 707                 self.SendFlags |= 1;
 708         }
 709         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 710         {
 711                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 712                 self.SendFlags |= 1;
 713         }
 714 }
 715
 716 void ClientInit_Spawn()
 717 {
 718         entity o;
 719         entity e;
 720         e = spawn();
 721         e.classname = "clientinit";
 722         e.think = ClientInit_CheckUpdate;
 723         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 724
 725         o = self;
 726         self = e;
 727         ClientInit_CheckUpdate();
 728         self = o;
 729 }
 730
 731 /*
 732 =============
 733 SetNewParms
 734 =============
 735 */
 736 void SetNewParms (void)
 737 {
 738         // initialize parms for a new player
 739         parm1 = -(86400 * 366);
 740 }
 741
 742 /*
 743 =============
 744 SetChangeParms
 745 =============
 746 */
 747 void SetChangeParms (void)
 748 {
 749         // save parms for level change
 750         parm1 = self.parm_idlesince - time;
 751 }
 752
 753 /*
 754 =============
 755 DecodeLevelParms
 756 =============
 757 */
 758 void DecodeLevelParms (void)
 759 {
 760         // load parms
 761         self.parm_idlesince = parm1;
 762         if(self.parm_idlesince == -(86400 * 366))
 763                 self.parm_idlesince = time;
 764
 765         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 766         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 767 }
 768
 769 /*
 770 =============
 771 ClientKill
 772
 773 Called when a client types 'kill' in the console
 774 =============
 775 */
 776
 777 .float clientkill_nexttime;
 778 void ClientKill_Now_TeamChange()
 779 {
 780         if(self.killindicator_teamchange == -1)
 781         {
 782                 JoinBestTeam( self, false, true );
 783         }
 784         else if(self.killindicator_teamchange == -2)
 785         {
 786                 if(blockSpectators)
 787                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 788                 PutObserverInServer();
 789         }
 790         else
 791                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 792         self.killindicator_teamchange = 0;
 793 }
 794
 795 void ClientKill_Now()
 796 {
 797         if(self.vehicle)
 798         {
 799             vehicles_exit(VHEF_RELESE);
 800             if(!self.killindicator_teamchange)
 801             {
 802             self.vehicle_health = -1;
 803             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 804             }
 805         }
 806
 807         if(self.killindicator && !wasfreed(self.killindicator))
 808                 remove(self.killindicator);
 809
 810         self.killindicator = world;
 811
 812         if(self.killindicator_teamchange)
 813                 ClientKill_Now_TeamChange();
 814
 815         if(IS_PLAYER(self))
 816                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 817
 818         // now I am sure the player IS dead
 819 }
 820 void KillIndicator_Think()
 821 {
 822         if (gameover)
 823         {
 824                 self.owner.killindicator = world;
 825                 remove(self);
 826                 return;
 827         }
 828
 829         if (self.owner.alpha < 0 && !self.owner.vehicle)
 830         {
 831                 self.owner.killindicator = world;
 832                 remove(self);
 833                 return;
 834         }
 835
 836         if(self.cnt <= 0)
 837         {
 838                 self = self.owner;
 839                 ClientKill_Now(); // no oldself needed
 840                 return;
 841         }
 842     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 843     {
 844         self.nextthink = time + 1;
 845         self.cnt -= 1;
 846     }
 847         else
 848         {
 849                 if(self.cnt <= 10)
 850                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 851                 if(IS_REAL_CLIENT(self.owner))
 852                 {
 853                         if(self.cnt <= 10)
 854                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 855                 }
 856                 self.nextthink = time + 1;
 857                 self.cnt -= 1;
 858         }
 859 }
 860
 861 float clientkilltime;
 862 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 863 {
 864         float killtime;
 865         float starttime;
 866         entity e;
 867
 868         if (gameover)
 869                 return;
 870
 871         killtime = autocvar_g_balance_kill_delay;
 872
 873         if(g_race_qualifying || g_cts)
 874                 killtime = 0;
 875
 876     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 877     {
 878                 remove(self.killindicator);
 879                 self.killindicator = world;
 880
 881         ClientKill_Now(); // allow instant kill in this case
 882         return;
 883     }
 884
 885         self.killindicator_teamchange = targetteam;
 886
 887     if(!self.killindicator)
 888         {
 889                 if(self.deadflag == DEAD_NO)
 890                 {
 891                         killtime = max(killtime, self.clientkill_nexttime - time);
 892                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 893                 }
 894
 895                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 896                 {
 897                         ClientKill_Now();
 898                 }
 899                 else
 900                 {
 901                         starttime = max(time, clientkilltime);
 902
 903                         self.killindicator = spawn();
 904                         self.killindicator.owner = self;
 905                         self.killindicator.scale = 0.5;
 906                         setattachment(self.killindicator, self, "");
 907                         setorigin(self.killindicator, '0 0 52');
 908                         self.killindicator.think = KillIndicator_Think;
 909                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 910                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 911                         self.killindicator.cnt = ceil(killtime);
 912                         self.killindicator.count = bound(0, ceil(killtime), 10);
 913                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 914
 915                         for(e = world; (e = find(e, classname, "body")) != world; )
 916                         {
 917                                 if(e.enemy != self)
 918                                         continue;
 919                                 e.killindicator = spawn();
 920                                 e.killindicator.owner = e;
 921                                 e.killindicator.scale = 0.5;
 922                                 setattachment(e.killindicator, e, "");
 923                                 setorigin(e.killindicator, '0 0 52');
 924                                 e.killindicator.think = KillIndicator_Think;
 925                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 926                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 927                                 e.killindicator.cnt = ceil(killtime);
 928                         }
 929                         self.lip = 0;
 930                 }
 931         }
 932         if(self.killindicator)
 933         {
 934                 if(targetteam == 0) // just die
 935                 {
 936                         self.killindicator.colormod = '0 0 0';
 937                         if(IS_REAL_CLIENT(self))
 938                         if(self.killindicator.cnt > 0)
 939                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 940                 }
 941                 else if(targetteam == -1) // auto
 942                 {
 943                         self.killindicator.colormod = '0 1 0';
 944                         if(IS_REAL_CLIENT(self))
 945                         if(self.killindicator.cnt > 0)
 946                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 947                 }
 948                 else if(targetteam == -2) // spectate
 949                 {
 950                         self.killindicator.colormod = '0.5 0.5 0.5';
 951                         if(IS_REAL_CLIENT(self))
 952                         if(self.killindicator.cnt > 0)
 953                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 954                 }
 955                 else
 956                 {
 957                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 958                         if(IS_REAL_CLIENT(self))
 959                         if(self.killindicator.cnt > 0)
 960                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 961                 }
 962         }
 963
 964 }
 965
 966 void ClientKill (void)
 967 {
 968         if(gameover) return;
 969         if(self.player_blocked) return;
 970         if(self.frozen) return;
 971
 972         ClientKill_TeamChange(0);
 973 }
 974
 975 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 976 {
 977     e.killindicator = spawn();
 978     e.killindicator.owner = e;
 979     e.killindicator.think = KillIndicator_Think;
 980     e.killindicator.nextthink = time + (e.lip) * 0.05;
 981     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 982     e.killindicator.health = 1; // this is used to indicate that it should be silent
 983     e.lip = 0;
 984 }
 985
 986 void FixClientCvars(entity e)
 987 {
 988         // send prediction settings to the client
 989         stuffcmd(e, "\nin_bindmap 0 0\n");
 990         if(g_race || g_cts)
 991                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 992         if(autocvar_g_antilag == 3) // client side hitscan
 993                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 994         if(autocvar_sv_gentle)
 995                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 996 }
 997
 998 float PlayerInIDList(entity p, string idlist)
 999 {
1000         float n, i;
1001         string s;
1002
1003         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1004         if (!p.crypto_idfp)
1005                 return 0;
1006
1007         // this function allows abbreviated player IDs too!
1008         n = tokenize_console(idlist);
1009         for(i = 0; i < n; ++i)
1010         {
1011                 s = argv(i);
1012                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1013                         return 1;
1014         }
1015
1016         return 0;
1017 }
1018
1019 #ifdef DP_EXT_PRECONNECT
1020 /*
1021 =============
1022 ClientPreConnect
1023
1024 Called once (not at each match start) when a client begins a connection to the server
1025 =============
1026 */
1027 void ClientPreConnect (void)
1028 {
1029         if(autocvar_sv_eventlog)
1030         {
1031                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1032                         self.playerid,
1033                         num_for_edict(self),
1034                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1035                 ));
1036         }
1037 }
1038 #endif
1039
1040 /*
1041 =============
1042 ClientConnect
1043
1044 Called when a client connects to the server
1045 =============
1046 */
1047 void DecodeLevelParms (void);
1048 //void dom_player_join_team(entity pl);
1049 void set_dom_state(entity e);
1050 void ClientConnect (void)
1051 {
1052         float t;
1053
1054         if(IS_CLIENT(self))
1055         {
1056                 print("Warning: ClientConnect, but already connected!\n");
1057                 return;
1058         }
1059
1060         if(Ban_MaybeEnforceBanOnce(self))
1061                 return;
1062
1063         DecodeLevelParms();
1064
1065 #ifdef WATERMARK
1066         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1067 #endif
1068
1069         self.classname = "player_joining";
1070
1071         self.flags = FL_CLIENT;
1072         self.version_nagtime = time + 10 + random() * 10;
1073
1074         if(player_count<0)
1075         {
1076                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1077                 player_count = 0;
1078         }
1079
1080         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1081
1082         PlayerScore_Attach(self);
1083         ClientData_Attach();
1084         accuracy_init(self);
1085
1086         bot_clientconnect();
1087
1088         playerdemo_init();
1089
1090         anticheat_init();
1091
1092         // identify the right forced team
1093         if(autocvar_g_campaign)
1094         {
1095                 if(IS_REAL_CLIENT(self)) // only players, not bots
1096                 {
1097                         switch(autocvar_g_campaign_forceteam)
1098                         {
1099                                 case 1: self.team_forced = NUM_TEAM_1; break;
1100                                 case 2: self.team_forced = NUM_TEAM_2; break;
1101                                 case 3: self.team_forced = NUM_TEAM_3; break;
1102                                 case 4: self.team_forced = NUM_TEAM_4; break;
1103                                 default: self.team_forced = 0;
1104                         }
1105                 }
1106         }
1107         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1108                 self.team_forced = NUM_TEAM_1;
1109         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1110                 self.team_forced = NUM_TEAM_2;
1111         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1112                 self.team_forced = NUM_TEAM_3;
1113         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1114                 self.team_forced = NUM_TEAM_4;
1115         else if(autocvar_g_forced_team_otherwise == "red")
1116                 self.team_forced = NUM_TEAM_1;
1117         else if(autocvar_g_forced_team_otherwise == "blue")
1118                 self.team_forced = NUM_TEAM_2;
1119         else if(autocvar_g_forced_team_otherwise == "yellow")
1120                 self.team_forced = NUM_TEAM_3;
1121         else if(autocvar_g_forced_team_otherwise == "pink")
1122                 self.team_forced = NUM_TEAM_4;
1123         else if(autocvar_g_forced_team_otherwise == "spectate")
1124                 self.team_forced = -1;
1125         else if(autocvar_g_forced_team_otherwise == "spectator")
1126                 self.team_forced = -1;
1127         else
1128                 self.team_forced = 0;
1129
1130         if(!teamplay)
1131                 if(self.team_forced > 0)
1132                         self.team_forced = 0;
1133
1134         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1135
1136         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1137                 self.classname = "observer";
1138         } else {
1139                 if(teamplay)
1140                 {
1141                         if(autocvar_g_balance_teams)
1142                         {
1143                                 self.classname = "player";
1144                                 campaign_bots_may_start = 1;
1145                         }
1146                         else
1147                         {
1148                                 self.classname = "observer"; // do it anyway
1149                         }
1150                 }
1151                 else
1152                 {
1153                         self.classname = "player";
1154                         campaign_bots_may_start = 1;
1155                 }
1156         }
1157
1158         self.playerid = (playerid_last = playerid_last + 1);
1159
1160         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1161
1162     if(IS_BOT_CLIENT(self))
1163         PlayerStats_GameReport_AddPlayer(self);
1164
1165         if(autocvar_sv_eventlog)
1166                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1167
1168         LogTeamchange(self.playerid, self.team, 1);
1169
1170         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1171
1172         self.netname_previous = strzone(self.netname);
1173
1174         if(IS_PLAYER(self) && teamplay)
1175                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1176         else
1177                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1178
1179         stuffcmd(self, strcat(clientstuff, "\n"));
1180         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1181
1182         FixClientCvars(self);
1183
1184         // spawnfunc_waypoint sprites
1185         WaypointSprite_InitClient(self);
1186
1187         // Wazat's grappling hook
1188         SetGrappleHookBindings();
1189
1190         // Jetpack binds
1191         stuffcmd(self, "alias +jetpack +button10\n");
1192         stuffcmd(self, "alias -jetpack -button10\n");
1193
1194         // get version info from player
1195         stuffcmd(self, "cmd clientversion $gameversion\n");
1196
1197         // get other cvars from player
1198         GetCvars(0);
1199
1200         // notify about available teams
1201         if(teamplay)
1202         {
1203                 CheckAllowedTeams(self);
1204                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1205                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1206         }
1207         else
1208                 stuffcmd(self, "set _teams_available 0\n");
1209
1210         attach_entcs();
1211
1212         bot_relinkplayerlist();
1213
1214         self.spectatortime = time;
1215         if(blockSpectators)
1216         {
1217                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1218         }
1219
1220         self.jointime = time;
1221         self.allowed_timeouts = autocvar_sv_timeout_number;
1222
1223         if(IS_REAL_CLIENT(self))
1224         {
1225                 if(!autocvar_g_campaign)
1226                 {
1227                         self.motd_actived_time = -1;
1228                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1229                 }
1230
1231                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1232                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1233         }
1234
1235         if(!sv_foginterval && world.fog != "")
1236                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1237
1238         W_HitPlotOpen(self);
1239
1240         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1241                 send_CSQC_teamnagger();
1242
1243         CheatInitClient();
1244
1245         CSQCMODEL_AUTOINIT();
1246
1247         self.model_randomizer = random();
1248
1249         if(IS_REAL_CLIENT(self))
1250                 sv_notice_join();
1251
1252         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1253                 entity oldself = self;
1254                 self = e;
1255                 e.init_for_player(oldself);
1256                 self = oldself;
1257         }
1258
1259         MUTATOR_CALLHOOK(ClientConnect);
1260 }
1261 /*
1262 =============
1263 ClientDisconnect
1264
1265 Called when a client disconnects from the server
1266 =============
1267 */
1268 .entity chatbubbleentity;
1269 void ReadyCount();
1270 void ClientDisconnect (void)
1271 {
1272         if(self.vehicle)
1273             vehicles_exit(VHEF_RELESE);
1274
1275         if (!IS_CLIENT(self))
1276         {
1277                 print("Warning: ClientDisconnect without ClientConnect\n");
1278                 return;
1279         }
1280
1281         PlayerStats_GameReport_FinalizePlayer(self);
1282
1283         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1284
1285         CheatShutdownClient();
1286
1287         W_HitPlotClose(self);
1288
1289         anticheat_report();
1290         anticheat_shutdown();
1291
1292         playerdemo_shutdown();
1293
1294         bot_clientdisconnect();
1295
1296         if(self.entcs)
1297                 detach_entcs();
1298
1299         if(autocvar_sv_eventlog)
1300                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1301
1302         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1303
1304         MUTATOR_CALLHOOK(ClientDisconnect);
1305
1306         Portal_ClearAll(self);
1307
1308         Unfreeze(self);
1309
1310         RemoveGrapplingHook(self);
1311
1312         // Here, everything has been done that requires this player to be a client.
1313
1314         self.flags &= ~FL_CLIENT;
1315
1316         if (self.chatbubbleentity)
1317                 remove (self.chatbubbleentity);
1318
1319         if (self.killindicator)
1320                 remove (self.killindicator);
1321
1322         WaypointSprite_PlayerGone();
1323
1324         bot_relinkplayerlist();
1325
1326         accuracy_free(self);
1327         ClientData_Detach();
1328         PlayerScore_Detach(self);
1329
1330         if(self.netname_previous)
1331                 strunzone(self.netname_previous);
1332         if(self.clientstatus)
1333                 strunzone(self.clientstatus);
1334         if(self.weaponorder_byimpulse)
1335                 strunzone(self.weaponorder_byimpulse);
1336
1337         ClearPlayerSounds();
1338
1339         if(self.personal)
1340                 remove(self.personal);
1341
1342         self.playerid = 0;
1343         ReadyCount();
1344
1345         // free cvars
1346         GetCvars(-1);
1347 }
1348
1349 .float BUTTON_CHAT;
1350 void ChatBubbleThink()
1351 {
1352         self.nextthink = time;
1353         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1354         {
1355                 if(self.owner) // but why can that ever be world?
1356                         self.owner.chatbubbleentity = world;
1357                 remove(self);
1358                 return;
1359         }
1360         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1361 #ifdef TETRIS
1362                 || self.owner.tetris_on
1363 #endif
1364         )
1365                 self.model = self.mdl;
1366         else
1367                 self.model = "";
1368 }
1369
1370 void UpdateChatBubble()
1371 {
1372         if (self.alpha < 0)
1373                 return;
1374         // spawn a chatbubble entity if needed
1375         if (!self.chatbubbleentity)
1376         {
1377                 self.chatbubbleentity = spawn();
1378                 self.chatbubbleentity.owner = self;
1379                 self.chatbubbleentity.exteriormodeltoclient = self;
1380                 self.chatbubbleentity.think = ChatBubbleThink;
1381                 self.chatbubbleentity.nextthink = time;
1382                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1383                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1384                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1385                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1386                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1387                 self.chatbubbleentity.model = "";
1388                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1389         }
1390 }
1391
1392
1393 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1394 // added to the model skins
1395 /*void UpdateColorModHack()
1396 {
1397         float c;
1398         c = self.clientcolors & 15;
1399         // LordHavoc: only bothering to support white, green, red, yellow, blue
1400              if (!teamplay) self.colormod = '0 0 0';
1401         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1402         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1403         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1404         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1405         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1406         else self.colormod = '1 1 1';
1407 }*/
1408
1409 void respawn(void)
1410 {
1411         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1412         {
1413                 self.solid = SOLID_NOT;
1414                 self.takedamage = DAMAGE_NO;
1415                 self.movetype = MOVETYPE_FLY;
1416                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1417                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1418                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1419                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1420                 if(autocvar_g_respawn_ghosts_maxtime)
1421                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1422         }
1423
1424         CopyBody(1);
1425
1426         self.effects |= EF_NODRAW; // prevent another CopyBody
1427         PutClientInServer();
1428 }
1429
1430 void play_countdown(float finished, string samp)
1431 {
1432         if(IS_REAL_CLIENT(self))
1433                 if(floor(finished - time - frametime) != floor(finished - time))
1434                         if(finished - time < 6)
1435                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1436 }
1437
1438 void player_powerups (void)
1439 {
1440         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1441         olditems = self.items;
1442
1443         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1444                 self.modelflags |= MF_ROCKET;
1445         else
1446                 self.modelflags &= ~MF_ROCKET;
1447
1448         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1449
1450         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1451                 return;
1452
1453         Fire_ApplyDamage(self);
1454         Fire_ApplyEffect(self);
1455
1456         if (!g_instagib)
1457         {
1458                 if (self.items & IT_STRENGTH)
1459                 {
1460                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1461                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1462                         if (time > self.strength_finished)
1463                         {
1464                                 self.items = self.items - (self.items & IT_STRENGTH);
1465                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1466                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1467                         }
1468                 }
1469                 else
1470                 {
1471                         if (time < self.strength_finished)
1472                         {
1473                                 self.items = self.items | IT_STRENGTH;
1474                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1475                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1476                         }
1477                 }
1478                 if (self.items & IT_INVINCIBLE)
1479                 {
1480                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1481                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1482                         if (time > self.invincible_finished)
1483                         {
1484                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1485                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1486                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1487                         }
1488                 }
1489                 else
1490                 {
1491                         if (time < self.invincible_finished)
1492                         {
1493                                 self.items = self.items | IT_INVINCIBLE;
1494                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1495                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1496                         }
1497                 }
1498                 if (self.items & IT_SUPERWEAPON)
1499                 {
1500                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1501                         {
1502                                 self.superweapons_finished = 0;
1503                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1504                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1505                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1506                         }
1507                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1508                         {
1509                                 // don't let them run out
1510                         }
1511                         else
1512                         {
1513                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1514                                 if (time > self.superweapons_finished)
1515                                 {
1516                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1517                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1518                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1519                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1520                                 }
1521                         }
1522                 }
1523                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1524                 {
1525                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1526                         {
1527                                 self.items = self.items | IT_SUPERWEAPON;
1528                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1529                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1530                         }
1531                         else
1532                         {
1533                                 self.superweapons_finished = 0;
1534                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1535                         }
1536                 }
1537                 else
1538                 {
1539                         self.superweapons_finished = 0;
1540                 }
1541         }
1542
1543         if(autocvar_g_nodepthtestplayers)
1544                 self.effects = self.effects | EF_NODEPTHTEST;
1545
1546         if(autocvar_g_fullbrightplayers)
1547                 self.effects = self.effects | EF_FULLBRIGHT;
1548
1549         if (time >= game_starttime)
1550         if (time < self.spawnshieldtime)
1551                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1552
1553         MUTATOR_CALLHOOK(PlayerPowerups);
1554 }
1555
1556 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1557 {
1558         if(current > stable)
1559                 return current;
1560         else if(current > stable - 0.25) // when close enough, "snap"
1561                 return stable;
1562         else
1563                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1564 }
1565
1566 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1567 {
1568         if(current < stable)
1569                 return current;
1570         else if(current < stable + 0.25) // when close enough, "snap"
1571                 return stable;
1572         else
1573                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1574 }
1575
1576 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1577 {
1578         if(current > rotstable)
1579         {
1580                 if(rotframetime > 0)
1581                 {
1582                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1583                         current = max(rotstable, current - rotlinear * rotframetime);
1584                 }
1585         }
1586         else if(current < regenstable)
1587         {
1588                 if(regenframetime > 0)
1589                 {
1590                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1591                         current = min(regenstable, current + regenlinear * regenframetime);
1592                 }
1593         }
1594
1595         if(current > limit)
1596                 current = limit;
1597
1598         return current;
1599 }
1600
1601 void player_regen (void)
1602 {
1603         float max_mod, regen_mod, rot_mod, limit_mod;
1604         max_mod = regen_mod = rot_mod = limit_mod = 1;
1605         regen_mod_max = max_mod;
1606         regen_mod_regen = regen_mod;
1607         regen_mod_rot = rot_mod;
1608         regen_mod_limit = limit_mod;
1609         if(!MUTATOR_CALLHOOK(PlayerRegen))
1610         if(!self.frozen)
1611         {
1612                 float minh, mina, maxh, maxa, limith, limita;
1613                 maxh = autocvar_g_balance_health_rotstable;
1614                 maxa = autocvar_g_balance_armor_rotstable;
1615                 minh = autocvar_g_balance_health_regenstable;
1616                 mina = autocvar_g_balance_armor_regenstable;
1617                 limith = autocvar_g_balance_health_limit;
1618                 limita = autocvar_g_balance_armor_limit;
1619
1620                 max_mod = regen_mod_max;
1621                 regen_mod = regen_mod_regen;
1622                 rot_mod = regen_mod_rot;
1623                 limit_mod = regen_mod_limit;
1624
1625                 maxh = maxh * max_mod;
1626                 minh = minh * max_mod;
1627                 limith = limith * limit_mod;
1628                 limita = limita * limit_mod;
1629
1630                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1631                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1632         }
1633
1634         // if player rotted to death...  die!
1635         // check this outside above checks, as player may still be able to rot to death
1636         if(self.health < 1)
1637                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1638
1639         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1640         {
1641                 float minf, maxf, limitf;
1642
1643                 maxf = autocvar_g_balance_fuel_rotstable;
1644                 minf = autocvar_g_balance_fuel_regenstable;
1645                 limitf = autocvar_g_balance_fuel_limit;
1646
1647                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1648         }
1649 }
1650
1651 float zoomstate_set;
1652 void SetZoomState(float z)
1653 {
1654         if(z != self.zoomstate)
1655         {
1656                 self.zoomstate = z;
1657                 ClientData_Touch(self);
1658         }
1659         zoomstate_set = 1;
1660 }
1661
1662 void GetPressedKeys(void) {
1663         MUTATOR_CALLHOOK(GetPressedKeys);
1664         if (self.movement.x > 0) // get if movement keys are pressed
1665         {       // forward key pressed
1666                 self.pressedkeys |= KEY_FORWARD;
1667                 self.pressedkeys &= ~KEY_BACKWARD;
1668         }
1669         else if (self.movement.x < 0)
1670         {       // backward key pressed
1671                 self.pressedkeys |= KEY_BACKWARD;
1672                 self.pressedkeys &= ~KEY_FORWARD;
1673         }
1674         else
1675         {       // no x input
1676                 self.pressedkeys &= ~KEY_FORWARD;
1677                 self.pressedkeys &= ~KEY_BACKWARD;
1678         }
1679
1680         if (self.movement.y > 0)
1681         {       // right key pressed
1682                 self.pressedkeys |= KEY_RIGHT;
1683                 self.pressedkeys &= ~KEY_LEFT;
1684         }
1685         else if (self.movement.y < 0)
1686         {       // left key pressed
1687                 self.pressedkeys |= KEY_LEFT;
1688                 self.pressedkeys &= ~KEY_RIGHT;
1689         }
1690         else
1691         {       // no y input
1692                 self.pressedkeys &= ~KEY_RIGHT;
1693                 self.pressedkeys &= ~KEY_LEFT;
1694         }
1695
1696         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1697                 self.pressedkeys |= KEY_JUMP;
1698         else
1699                 self.pressedkeys &= ~KEY_JUMP;
1700         if (self.BUTTON_CROUCH)
1701                 self.pressedkeys |= KEY_CROUCH;
1702         else
1703                 self.pressedkeys &= ~KEY_CROUCH;
1704
1705         if (self.BUTTON_ATCK)
1706                 self.pressedkeys |= KEY_ATCK;
1707         else
1708                 self.pressedkeys &= ~KEY_ATCK;
1709         if (self.BUTTON_ATCK2)
1710                 self.pressedkeys |= KEY_ATCK2;
1711         else
1712                 self.pressedkeys &= ~KEY_ATCK2;
1713 }
1714
1715 /*
1716 ======================
1717 spectate mode routines
1718 ======================
1719 */
1720
1721 void SpectateCopy(entity spectatee) {
1722         other = spectatee;
1723         MUTATOR_CALLHOOK(SpectateCopy);
1724         self.armortype = spectatee.armortype;
1725         self.armorvalue = spectatee.armorvalue;
1726         self.ammo_cells = spectatee.ammo_cells;
1727         self.ammo_plasma = spectatee.ammo_plasma;
1728         self.ammo_shells = spectatee.ammo_shells;
1729         self.ammo_nails = spectatee.ammo_nails;
1730         self.ammo_rockets = spectatee.ammo_rockets;
1731         self.ammo_fuel = spectatee.ammo_fuel;
1732         self.clip_load = spectatee.clip_load;
1733         self.clip_size = spectatee.clip_size;
1734         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1735         self.health = spectatee.health;
1736         self.impulse = 0;
1737         self.items = spectatee.items;
1738         self.last_pickup = spectatee.last_pickup;
1739         self.hit_time = spectatee.hit_time;
1740         self.metertime = spectatee.metertime;
1741         self.strength_finished = spectatee.strength_finished;
1742         self.invincible_finished = spectatee.invincible_finished;
1743         self.pressedkeys = spectatee.pressedkeys;
1744         self.weapons = spectatee.weapons;
1745         self.switchweapon = spectatee.switchweapon;
1746         self.switchingweapon = spectatee.switchingweapon;
1747         self.weapon = spectatee.weapon;
1748         self.vortex_charge = spectatee.vortex_charge;
1749         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1750         self.hagar_load = spectatee.hagar_load;
1751         self.arc_heat_percent = spectatee.arc_heat_percent;
1752         self.minelayer_mines = spectatee.minelayer_mines;
1753         self.punchangle = spectatee.punchangle;
1754         self.view_ofs = spectatee.view_ofs;
1755         self.velocity = spectatee.velocity;
1756         self.dmg_take = spectatee.dmg_take;
1757         self.dmg_save = spectatee.dmg_save;
1758         self.dmg_inflictor = spectatee.dmg_inflictor;
1759         self.v_angle = spectatee.v_angle;
1760         self.angles = spectatee.v_angle;
1761         self.frozen = spectatee.frozen;
1762         self.revive_progress = spectatee.revive_progress;
1763         if(!self.BUTTON_USE)
1764                 self.fixangle = true;
1765         setorigin(self, spectatee.origin);
1766         setsize(self, spectatee.mins, spectatee.maxs);
1767         SetZoomState(spectatee.zoomstate);
1768
1769     anticheat_spectatecopy(spectatee);
1770         self.hud = spectatee.hud;
1771         if(spectatee.vehicle)
1772     {
1773         self.fixangle = false;
1774         //self.velocity = spectatee.vehicle.velocity;
1775         self.vehicle_health = spectatee.vehicle_health;
1776         self.vehicle_shield = spectatee.vehicle_shield;
1777         self.vehicle_energy = spectatee.vehicle_energy;
1778         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1779         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1780         self.vehicle_reload1 = spectatee.vehicle_reload1;
1781         self.vehicle_reload2 = spectatee.vehicle_reload2;
1782
1783         msg_entity = self;
1784
1785         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1786             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1787             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1788             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1789
1790         //WriteByte (MSG_ONE, SVC_SETVIEW);
1791         //    WriteEntity(MSG_ONE, self);
1792         //makevectors(spectatee.v_angle);
1793         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1794     }
1795 }
1796
1797 float SpectateUpdate()
1798 {
1799         if(!self.enemy)
1800             return 0;
1801
1802         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1803         {
1804                 SetSpectator(self, world);
1805                 return 0;
1806         }
1807
1808         SpectateCopy(self.enemy);
1809
1810         return 1;
1811 }
1812
1813 float SpectateSet()
1814 {
1815         if(self.enemy.classname != "player")
1816                 return false;
1817         /*if(self.enemy.vehicle)
1818         {
1819
1820                 msg_entity = self;
1821                 WriteByte(MSG_ONE, SVC_SETVIEW);
1822                 WriteEntity(MSG_ONE, self.enemy);
1823                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1824
1825                 self.movetype = MOVETYPE_NONE;
1826                 accuracy_resend(self);
1827         }
1828         else
1829         {*/
1830                 msg_entity = self;
1831                 WriteByte(MSG_ONE, SVC_SETVIEW);
1832                 WriteEntity(MSG_ONE, self.enemy);
1833                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1834                 self.movetype = MOVETYPE_NONE;
1835                 accuracy_resend(self);
1836
1837                 if(!SpectateUpdate())
1838                         PutObserverInServer();
1839         //}
1840         return true;
1841 }
1842
1843 void SetSpectator(entity player, entity spectatee)
1844 {
1845         entity old_spectatee = player.enemy;
1846
1847         player.enemy = spectatee;
1848
1849         // WEAPONTODO
1850         // these are required to fix the spectator bug with arc
1851         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1852         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1853 }
1854
1855 float Spectate(entity pl)
1856 {
1857         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1858         if(pl.team != self.team)
1859                 return 0;
1860
1861         SetSpectator(self, pl);
1862         return SpectateSet();
1863 }
1864
1865 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1866 entity CA_SpectateNext(entity start) {
1867         if (start.team == self.team) {
1868                 return start;
1869         }
1870
1871         other = start;
1872         // continue from current player
1873         while(other && other.team != self.team) {
1874                 other = find(other, classname, "player");
1875         }
1876
1877         if (!other) {
1878                 // restart from begining
1879                 other = find(other, classname, "player");
1880                 while(other && other.team != self.team) {
1881                         other = find(other, classname, "player");
1882                 }
1883         }
1884
1885         return other;
1886 }
1887
1888 float SpectateNext()
1889 {
1890         other = find(self.enemy, classname, "player");
1891
1892         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1893                 // CA and ca players when spectating enemies is forbidden
1894                 other = CA_SpectateNext(other);
1895         } else {
1896                 // other modes and ca spectators or spectating enemies is allowed
1897                 if (!other)
1898                         other = find(other, classname, "player");
1899         }
1900
1901         if(other) { SetSpectator(self, other); }
1902
1903         return SpectateSet();
1904 }
1905
1906 float SpectatePrev()
1907 {
1908         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1909         other = findchain(classname, "player");
1910         if (!other) // no player
1911                 return false;
1912
1913         entity first = other;
1914         // skip players until current spectated player
1915         if(self.enemy)
1916         while(other && other != self.enemy)
1917                 other = other.chain;
1918
1919         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1920         {
1921                 do { other = other.chain; }
1922                 while(other && other.team != self.team);
1923
1924                 if (!other)
1925                 {
1926                         other = first;
1927                         while(other.team != self.team)
1928                                 other = other.chain;
1929                         if(other == self.enemy)
1930                                 return true;
1931                 }
1932         }
1933         else
1934         {
1935                 if(other.chain)
1936                         other = other.chain;
1937                 else
1938                         other = first;
1939         }
1940         SetSpectator(self, other);
1941         return SpectateSet();
1942 }
1943
1944 /*
1945 =============
1946 ShowRespawnCountdown()
1947
1948 Update a respawn countdown display.
1949 =============
1950 */
1951 void ShowRespawnCountdown()
1952 {
1953         float number;
1954         if(self.deadflag == DEAD_NO) // just respawned?
1955                 return;
1956         else
1957         {
1958                 number = ceil(self.respawn_time - time);
1959                 if(number <= 0)
1960                         return;
1961                 if(number <= self.respawn_countdown)
1962                 {
1963                         self.respawn_countdown = number - 1;
1964                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1965                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1966                 }
1967         }
1968 }
1969
1970 void LeaveSpectatorMode()
1971 {
1972         if(self.caplayer)
1973                 return;
1974         if(nJoinAllowed(self))
1975         {
1976                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1977                 {
1978                         self.classname = "player";
1979                         nades_RemoveBonus(self);
1980
1981                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1982                                 { JoinBestTeam(self, false, true); }
1983
1984                         if(autocvar_g_campaign)
1985                                 { campaign_bots_may_start = 1; }
1986
1987                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1988
1989                         PutClientInServer();
1990
1991                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1992                 }
1993                 else
1994                         stuffcmd(self, "menu_showteamselect\n");
1995         }
1996         else
1997         {
1998                 // Player may not join because g_maxplayers is set
1999                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2000         }
2001 }
2002
2003 /**
2004  * Determines whether the player is allowed to join. This depends on cvar
2005  * g_maxplayers, if it isn't used this function always return true, otherwise
2006  * it checks whether the number of currently playing players exceeds g_maxplayers.
2007  * @return int number of free slots for players, 0 if none
2008  */
2009 float nJoinAllowed(entity ignore) {
2010         if(!ignore)
2011         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2012         // so report 0 free slots if restricted
2013         {
2014                 if(autocvar_g_forced_team_otherwise == "spectate")
2015                         return 0;
2016                 if(autocvar_g_forced_team_otherwise == "spectator")
2017                         return 0;
2018         }
2019
2020         if(self.team_forced < 0)
2021                 return 0; // forced spectators can never join
2022
2023         // TODO simplify this
2024         entity e;
2025         float totalClients = 0;
2026         FOR_EACH_CLIENT(e)
2027                 if(e != ignore)
2028                         totalClients += 1;
2029
2030         if (!autocvar_g_maxplayers)
2031                 return maxclients - totalClients;
2032
2033         float currentlyPlaying = 0;
2034         FOR_EACH_REALCLIENT(e)
2035                 if(IS_PLAYER(e) || e.caplayer)
2036                         currentlyPlaying += 1;
2037
2038         if(currentlyPlaying < autocvar_g_maxplayers)
2039                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2040
2041         return 0;
2042 }
2043
2044 /**
2045  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2046  * g_maxplayers_spectator_blocktime seconds
2047  */
2048 void checkSpectatorBlock() {
2049         if(IS_SPEC(self) || IS_OBSERVER(self))
2050         if(!self.caplayer)
2051         if(IS_REAL_CLIENT(self))
2052         {
2053                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2054                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2055                         dropclient(self);
2056                 }
2057         }
2058 }
2059
2060 void PrintWelcomeMessage()
2061 {
2062         if(self.motd_actived_time == 0)
2063         {
2064                 if (autocvar_g_campaign) {
2065                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2066                                 self.motd_actived_time = time;
2067                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2068                         }
2069                 } else {
2070                         if (self.BUTTON_INFO) {
2071                                 self.motd_actived_time = time;
2072                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2073                         }
2074                 }
2075         }
2076         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2077         {
2078                 if (autocvar_g_campaign) {
2079                         if (self.BUTTON_INFO)
2080                                 self.motd_actived_time = time;
2081                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2082                                 self.motd_actived_time = 0;
2083                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2084                         }
2085                 } else {
2086                         if (self.BUTTON_INFO)
2087                                 self.motd_actived_time = time;
2088                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2089                                 self.motd_actived_time = 0;
2090                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2091                         }
2092                 }
2093         }
2094         else //if(self.motd_actived_time < 0) // just connected, motd is active
2095         {
2096                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2097                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2098                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2099                 {
2100                         // instanctly hide MOTD
2101                         self.motd_actived_time = 0;
2102                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2103                 }
2104         }
2105 }
2106
2107 void ObserverThink()
2108 {
2109         float prefered_movetype;
2110         if (self.flags & FL_JUMPRELEASED) {
2111                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2112                         self.flags &= ~FL_JUMPRELEASED;
2113                         self.flags |= FL_SPAWNING;
2114                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2115                         self.flags &= ~FL_JUMPRELEASED;
2116                         if(SpectateNext()) {
2117                                 self.classname = "spectator";
2118                         }
2119                 } else {
2120                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2121                         if (self.movetype != prefered_movetype)
2122                                 self.movetype = prefered_movetype;
2123                 }
2124         } else {
2125                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2126                         self.flags |= FL_JUMPRELEASED;
2127                         if(self.flags & FL_SPAWNING)
2128                         {
2129                                 self.flags &= ~FL_SPAWNING;
2130                                 LeaveSpectatorMode();
2131                                 return;
2132                         }
2133                 }
2134         }
2135 }
2136
2137 void SpectatorThink()
2138 {
2139         if (self.flags & FL_JUMPRELEASED) {
2140                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2141                         self.flags &= ~FL_JUMPRELEASED;
2142                         self.flags |= FL_SPAWNING;
2143                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2144                         self.flags &= ~FL_JUMPRELEASED;
2145                         if(SpectateNext()) {
2146                                 self.classname = "spectator";
2147                         } else {
2148                                 self.classname = "observer";
2149                                 PutClientInServer();
2150                         }
2151                         self.impulse = 0;
2152                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2153                         self.flags &= ~FL_JUMPRELEASED;
2154                         if(SpectatePrev()) {
2155                                 self.classname = "spectator";
2156                         } else {
2157                                 self.classname = "observer";
2158                                 PutClientInServer();
2159                         }
2160                         self.impulse = 0;
2161                 } else if (self.BUTTON_ATCK2) {
2162                         self.flags &= ~FL_JUMPRELEASED;
2163                         self.classname = "observer";
2164                         PutClientInServer();
2165                 } else {
2166                         if(!SpectateUpdate())
2167                                 PutObserverInServer();
2168                 }
2169         } else {
2170                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2171                         self.flags |= FL_JUMPRELEASED;
2172                         if(self.flags & FL_SPAWNING)
2173                         {
2174                                 self.flags &= ~FL_SPAWNING;
2175                                 LeaveSpectatorMode();
2176                                 return;
2177                         }
2178                 }
2179                 if(!SpectateUpdate())
2180                         PutObserverInServer();
2181         }
2182
2183         self.flags |= FL_CLIENT | FL_NOTARGET;
2184 }
2185
2186 void PlayerUseKey()
2187 {
2188         if (!IS_PLAYER(self))
2189                 return;
2190
2191         if(self.vehicle)
2192         {
2193         vehicles_exit(VHEF_NORMAL);
2194         return;
2195         }
2196
2197         // a use key was pressed; call handlers
2198         MUTATOR_CALLHOOK(PlayerUseKey);
2199 }
2200
2201 float isInvisibleString(string s)
2202 {
2203         float i, n, c;
2204         s = strdecolorize(s);
2205         for((i = 0), (n = strlen(s)); i < n; ++i)
2206         {
2207                 c = str2chr(s, i);
2208                 switch(c)
2209                 {
2210                         case 0:
2211                         case 32: // space
2212                                 break;
2213                         case 192: // charmap space
2214                                 if (!autocvar_utf8_enable)
2215                                         break;
2216                                 return false;
2217                         case 160: // space in unicode fonts
2218                         case 0xE000 + 192: // utf8 charmap space
2219                                 if (autocvar_utf8_enable)
2220                                         break;
2221                         default:
2222                                 return false;
2223                 }
2224         }
2225         return true;
2226 }
2227
2228 /*
2229 =============
2230 PlayerPreThink
2231
2232 Called every frame for each client before the physics are run
2233 =============
2234 */
2235 .float usekeypressed;
2236 void() nexball_setstatus;
2237 .int items_added;
2238 void PlayerPreThink (void)
2239 {
2240         WarpZone_PlayerPhysics_FixVAngle();
2241
2242         self.stat_game_starttime = game_starttime;
2243         self.stat_round_starttime = round_starttime;
2244         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2245         self.stat_leadlimit = autocvar_leadlimit;
2246
2247         if(frametime)
2248         {
2249                 // physics frames: update anticheat stuff
2250                 anticheat_prethink();
2251         }
2252
2253         if(blockSpectators && frametime)
2254                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2255                 checkSpectatorBlock();
2256
2257         zoomstate_set = 0;
2258
2259         // Savage: Check for nameless players
2260         if (isInvisibleString(self.netname)) {
2261                 string new_name = strzone(strcat("Player@", self.netaddress));
2262                 if(autocvar_sv_eventlog)
2263                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2264                 if(self.netname_previous)
2265                         strunzone(self.netname_previous);
2266                 self.netname_previous = strzone(new_name);
2267                 self.netname = self.netname_previous;
2268                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2269         } else if(self.netname_previous != self.netname) {
2270                 if(autocvar_sv_eventlog)
2271                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2272                 if(self.netname_previous)
2273                         strunzone(self.netname_previous);
2274                 self.netname_previous = strzone(self.netname);
2275         }
2276
2277         // version nagging
2278         if(self.version_nagtime)
2279                 if(self.cvar_g_xonoticversion)
2280                         if(time > self.version_nagtime)
2281                         {
2282                                 // don't notify git users
2283                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2284                                 {
2285                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2286                                         {
2287                                                 // notify release users if connecting to git
2288                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2289                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2290                                         }
2291                                         else
2292                                         {
2293                                                 float r;
2294                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2295                                                 if(r < 0)
2296                                                 {
2297                                                         // give users new version
2298                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2299                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2300                                                 }
2301                                                 else if(r > 0)
2302                                                 {
2303                                                         // notify users about old server version
2304                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2305                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2306                                                 }
2307                                         }
2308                                 }
2309                                 self.version_nagtime = 0;
2310                         }
2311
2312         // GOD MODE info
2313         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2314         {
2315                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2316                 self.max_armorvalue = 0;
2317         }
2318
2319 #ifdef TETRIS
2320         if (TetrisPreFrame())
2321                 return;
2322 #endif
2323
2324         if(self.frozen == 2)
2325         {
2326                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2327                 self.health = max(1, self.revive_progress * start_health);
2328                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2329
2330                 if(self.revive_progress >= 1)
2331                         Unfreeze(self);
2332         }
2333         else if(self.frozen == 3)
2334         {
2335                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2336                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2337
2338                 if(self.health < 1)
2339                 {
2340                         if(self.vehicle)
2341                                 vehicles_exit(VHEF_RELESE);
2342                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2343                 }
2344                 else if ( self.revive_progress <= 0 )
2345                         Unfreeze(self);
2346         }
2347
2348         MUTATOR_CALLHOOK(PlayerPreThink);
2349
2350         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2351         {
2352                 if(self.BUTTON_USE && !self.usekeypressed)
2353                         PlayerUseKey();
2354                 self.usekeypressed = self.BUTTON_USE;
2355         }
2356
2357         if(IS_REAL_CLIENT(self))
2358                 PrintWelcomeMessage();
2359
2360         if(IS_PLAYER(self))
2361         {
2362
2363                 CheckRules_Player();
2364
2365                 if (intermission_running)
2366                 {
2367                         IntermissionThink ();   // otherwise a button could be missed between
2368                         return;                                 // the think tics
2369                 }
2370
2371                 //don't allow the player to turn around while game is paused!
2372                 if(timeout_status == TIMEOUT_ACTIVE) {
2373                         // FIXME turn this into CSQC stuff
2374                         self.v_angle = self.lastV_angle;
2375                         self.angles = self.lastV_angle;
2376                         self.fixangle = true;
2377                 }
2378
2379                 if(frametime)
2380                 {
2381                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2382                         {
2383                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2384                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2385                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2386
2387                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2388                                 {
2389                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2390                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2391                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2392                                 }
2393                         }
2394                         else
2395                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2396
2397                         player_powerups();
2398                 }
2399
2400                 if (self.deadflag != DEAD_NO)
2401                 {
2402                         if(self.personal && g_race_qualifying)
2403                         {
2404                                 if(time > self.respawn_time)
2405                                 {
2406                                         self.respawn_time = time + 1; // only retry once a second
2407                                         self.stat_respawn_time = self.respawn_time;
2408                                         respawn();
2409                                         self.impulse = 141;
2410                                 }
2411                         }
2412                         else
2413                         {
2414                                 float button_pressed;
2415                                 if(frametime)
2416                                         player_anim();
2417                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2418
2419                                 if (self.deadflag == DEAD_DYING)
2420                                 {
2421                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2422                                                 self.deadflag = DEAD_RESPAWNING;
2423                                         else if(!button_pressed)
2424                                                 self.deadflag = DEAD_DEAD;
2425                                 }
2426                                 else if (self.deadflag == DEAD_DEAD)
2427                                 {
2428                                         if(button_pressed)
2429                                                 self.deadflag = DEAD_RESPAWNABLE;
2430                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2431                                                 self.deadflag = DEAD_RESPAWNING;
2432                                 }
2433                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2434                                 {
2435                                         if(!button_pressed)
2436                                                 self.deadflag = DEAD_RESPAWNING;
2437                                 }
2438                                 else if (self.deadflag == DEAD_RESPAWNING)
2439                                 {
2440                                         if(time > self.respawn_time)
2441                                         {
2442                                                 self.respawn_time = time + 1; // only retry once a second
2443                                                 self.respawn_time_max = self.respawn_time;
2444                                                 respawn();
2445                                         }
2446                                 }
2447
2448                                 ShowRespawnCountdown();
2449
2450                                 if(self.respawn_flags & RESPAWN_SILENT)
2451                                         self.stat_respawn_time = 0;
2452                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2453                                         self.stat_respawn_time = self.respawn_time_max;
2454                                 else
2455                                         self.stat_respawn_time = self.respawn_time;
2456                         }
2457
2458                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2459                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2460                                 self.stat_respawn_time *= -1;
2461
2462                         return;
2463                 }
2464
2465                 self.prevorigin = self.origin;
2466
2467                 float do_crouch = self.BUTTON_CROUCH;
2468                 if(self.hook.state)
2469                         do_crouch = 0;
2470                 if(self.vehicle)
2471                         do_crouch = 0;
2472                 if(self.frozen)
2473                         do_crouch = 0;
2474
2475                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2476                 // It cannot be predicted by the engine!
2477                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2478                         do_crouch = 0;
2479
2480                 if (do_crouch)
2481                 {
2482                         if (!self.crouch)
2483                         {
2484                                 self.crouch = true;
2485                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2486                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2487                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2488                         }
2489                 }
2490                 else
2491                 {
2492                         if (self.crouch)
2493                         {
2494                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2495                                 if (!trace_startsolid)
2496                                 {
2497                                         self.crouch = false;
2498                                         self.view_ofs = PL_VIEW_OFS;
2499                                         setsize (self, PL_MIN, PL_MAX);
2500                                 }
2501                         }
2502                 }
2503
2504                 FixPlayermodel();
2505
2506                 GrapplingHookFrame();
2507
2508                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2509                 //if(frametime)
2510                 {
2511                         self.items &= ~self.items_added;
2512
2513                         W_WeaponFrame();
2514
2515                         self.items_added = 0;
2516                         if(self.items & IT_JETPACK)
2517                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2518                                         self.items_added |= IT_FUEL;
2519
2520                         self.items |= self.items_added;
2521                 }
2522
2523                 player_regen();
2524
2525                 // WEAPONTODO: Add a weapon request for this
2526                 // rot vortex charge to the charge limit
2527                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2528                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2529
2530                 if(frametime)
2531                         player_anim();
2532
2533                 // secret status
2534                 secrets_setstatus();
2535
2536                 // monsters status
2537                 monsters_setstatus();
2538
2539                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2540
2541                 //self.angles_y=self.v_angle_y + 90;   // temp
2542         } else if(gameover) {
2543                 if (intermission_running)
2544                         IntermissionThink ();   // otherwise a button could be missed between
2545                 return;
2546         } else if(IS_OBSERVER(self)) {
2547                 ObserverThink();
2548         } else if(IS_SPEC(self)) {
2549                 SpectatorThink();
2550         }
2551
2552         // WEAPONTODO: Add weapon request for this
2553         if(!zoomstate_set)
2554                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2555
2556         float oldspectatee_status;
2557         oldspectatee_status = self.spectatee_status;
2558         if(IS_SPEC(self))
2559                 self.spectatee_status = num_for_edict(self.enemy);
2560         else if(IS_OBSERVER(self))
2561                 self.spectatee_status = num_for_edict(self);
2562         else
2563                 self.spectatee_status = 0;
2564         if(self.spectatee_status != oldspectatee_status)
2565         {
2566                 ClientData_Touch(self);
2567         }
2568
2569         if(self.teamkill_soundtime)
2570         if(time > self.teamkill_soundtime)
2571         {
2572                 self.teamkill_soundtime = 0;
2573
2574                 entity oldpusher, oldself;
2575
2576                 oldself = self; self = self.teamkill_soundsource;
2577                 oldpusher = self.pusher; self.pusher = oldself;
2578
2579                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2580
2581                 self.pusher = oldpusher;
2582                 self = oldself;
2583         }
2584
2585         if(self.taunt_soundtime)
2586         if(time > self.taunt_soundtime)
2587         {
2588                 self.taunt_soundtime = 0;
2589                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2590         }
2591
2592         target_voicescript_next(self);
2593
2594         // WEAPONTODO: Move into weaponsystem somehow
2595         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2596         if(!self.weapon)
2597                 self.clip_load = self.clip_size = 0;
2598 }
2599
2600 /*
2601 =============
2602 PlayerPostThink
2603
2604 Called every frame for each client after the physics are run
2605 =============
2606 */
2607 .float idlekick_lasttimeleft;
2608 void PlayerPostThink (void)
2609 {
2610         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2611         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2612         {
2613                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2614                 {
2615                         if(self.idlekick_lasttimeleft)
2616                         {
2617                                 self.idlekick_lasttimeleft = 0;
2618                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2619                         }
2620                 }
2621                 else
2622                 {
2623                         float timeleft;
2624                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2625                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2626                         {
2627                                 if(!self.idlekick_lasttimeleft)
2628                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2629                         }
2630                         if(timeleft <= 0)
2631                         {
2632                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2633                                 dropclient(self);
2634                                 return;
2635                         }
2636                         else if(timeleft <= 10)
2637                         {
2638                                 if(timeleft != self.idlekick_lasttimeleft)
2639                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2640                                 self.idlekick_lasttimeleft = timeleft;
2641                         }
2642                 }
2643         }
2644
2645 #ifdef TETRIS
2646         if(self.impulse == 100)
2647                 ImpulseCommands();
2648         if (!TetrisPostFrame())
2649         {
2650 #endif
2651
2652         CheatFrame();
2653
2654         //CheckPlayerJump();
2655
2656         if(IS_PLAYER(self)) {
2657                 CheckRules_Player();
2658                 UpdateChatBubble();
2659                 if (self.impulse)
2660                         ImpulseCommands();
2661                 if (intermission_running)
2662                         return;         // intermission or finale
2663                 GetPressedKeys();
2664         }
2665
2666 #ifdef TETRIS
2667         }
2668 #endif
2669
2670         /*
2671         float i;
2672         for(i = 0; i < 1000; ++i)
2673         {
2674                 vector end;
2675                 end = self.origin + '0 0 1024' + 512 * randomvec();
2676                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2677                 if(trace_fraction < 1)
2678                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2679                 {
2680                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2681                         break;
2682                 }
2683         }
2684         */
2685
2686         if(self.waypointsprite_attachedforcarrier)
2687                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2688
2689         playerdemo_write();
2690
2691         CSQCMODEL_AUTOUPDATE();
2692 }