qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418             vehicles_exit(VHEF_RELESE);
 419
 420         if(self.flagcarried)
 421                 DropFlag(self.flagcarried, world, world);
 422
 423         WaypointSprite_PlayerDead();
 424
 425         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 426                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 427
 428         if(self.killcount != -666) {
 429                 if(g_lms) {
 430                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 431                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 432                         else
 433                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 434                 } else
 435                         bprint ("^4", self.netname, "^4 is spectating now\n");
 436
 437                 if(self.just_joined == FALSE) {
 438                         LogTeamchange(self.playerid, -1, 4);
 439                 } else
 440                         self.just_joined = FALSE;
 441         }
 442
 443         PlayerScore_Clear(self); // clear scores when needed
 444
 445         accuracy_resend(self);
 446
 447         self.spectatortime = time;
 448
 449         self.classname = "observer";
 450         self.iscreature = FALSE;
 451         self.damagedbycontents = FALSE;
 452         self.health = -666;
 453         self.takedamage = DAMAGE_NO;
 454         self.solid = SOLID_NOT;
 455         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 456         self.flags = FL_CLIENT | FL_NOTARGET;
 457         self.armorvalue = 666;
 458         self.effects = 0;
 459         self.armorvalue = autocvar_g_balance_armor_start;
 460         self.pauserotarmor_finished = 0;
 461         self.pauserothealth_finished = 0;
 462         self.pauseregen_finished = 0;
 463         self.damageforcescale = 0;
 464         self.death_time = 0;
 465         self.respawn_time = 0;
 466         self.alpha = 0;
 467         self.scale = 0;
 468         self.fade_time = 0;
 469         self.pain_frame = 0;
 470         self.pain_finished = 0;
 471         self.strength_finished = 0;
 472         self.invincible_finished = 0;
 473         self.superweapons_finished = 0;
 474         self.pushltime = 0;
 475         self.think = SUB_Null;
 476         self.nextthink = 0;
 477         self.hook_time = 0;
 478         self.runes = 0;
 479         self.deadflag = DEAD_NO;
 480         self.angles = spot.angles;
 481         self.angles_z = 0;
 482         self.fixangle = TRUE;
 483         self.crouch = FALSE;
 484
 485         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 486         self.prevorigin = self.origin;
 487         self.items = 0;
 488         self.weapons = 0;
 489         self.model = "";
 490         FixPlayermodel();
 491         setmodel(self, "null");
 492         self.drawonlytoclient = self;
 493
 494         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 495         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 496
 497         self.weapon = 0;
 498         self.weaponname = "";
 499         self.switchingweapon = 0;
 500         self.weaponmodel = "";
 501         self.weaponentity = world;
 502         self.exteriorweaponentity = world;
 503         self.killcount = -666;
 504         self.velocity = '0 0 0';
 505         self.avelocity = '0 0 0';
 506         self.punchangle = '0 0 0';
 507         self.punchvector = '0 0 0';
 508         self.oldvelocity = self.velocity;
 509         self.fire_endtime = -1;
 510
 511         if(g_arena)
 512         {
 513                 if(self.version_mismatch)
 514                 {
 515                         Spawnqueue_Unmark(self);
 516                         Spawnqueue_Remove(self);
 517                 }
 518                 else
 519                 {
 520                         Spawnqueue_Insert(self);
 521                 }
 522         }
 523         else if(g_lms)
 524         {
 525                 // Only if the player cannot play at all
 526                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 527                         self.frags = FRAGS_SPECTATOR;
 528                 else
 529                         self.frags = FRAGS_LMS_LOSER;
 530         }
 531         else if(g_ca)
 532         {
 533                 if(self.caplayer)
 534                         self.frags = FRAGS_LMS_LOSER;
 535                 else
 536                         self.frags = FRAGS_SPECTATOR;
 537         }
 538         else
 539                 self.frags = FRAGS_SPECTATOR;
 540 }
 541
 542 .float model_randomizer;
 543 void FixPlayermodel()
 544 {
 545         string defaultmodel;
 546         float defaultskin, chmdl, oldskin, n, i;
 547         vector m1, m2;
 548
 549         defaultmodel = "";
 550
 551         if(autocvar_sv_defaultcharacter == 1)
 552         {
 553                 defaultskin = 0;
 554
 555                 if(teamplay)
 556                 {
 557                         string s;
 558                         s = Team_ColorNameLowerCase(self.team);
 559                         if(s != "neutral")
 560                         {
 561                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 562                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 563                         }
 564                 }
 565
 566                 if(defaultmodel == "")
 567                 {
 568                         defaultmodel = autocvar_sv_defaultplayermodel;
 569                         defaultskin = autocvar_sv_defaultplayerskin;
 570                 }
 571
 572                 n = tokenize_console(defaultmodel);
 573                 if(n > 0)
 574                         defaultmodel = argv(floor(n * self.model_randomizer));
 575
 576                 i = strstrofs(defaultmodel, ":", 0);
 577                 if(i >= 0)
 578                 {
 579                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 580                         defaultmodel = substring(defaultmodel, 0, i);
 581                 }
 582         }
 583
 584         if(defaultmodel != "")
 585         {
 586                 if (defaultmodel != self.model)
 587                 {
 588                         m1 = self.mins;
 589                         m2 = self.maxs;
 590                         setplayermodel (self, defaultmodel);
 591                         setsize (self, m1, m2);
 592                         chmdl = TRUE;
 593                 }
 594
 595                 oldskin = self.skin;
 596                 self.skin = defaultskin;
 597         } else {
 598                 if (self.playermodel != self.model || self.playermodel == "")
 599                 {
 600                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 601                         m1 = self.mins;
 602                         m2 = self.maxs;
 603                         setplayermodel (self, self.playermodel);
 604                         setsize (self, m1, m2);
 605                         chmdl = TRUE;
 606                 }
 607
 608                 oldskin = self.skin;
 609                 self.skin = stof(self.playerskin);
 610         }
 611
 612         if(chmdl || oldskin != self.skin)
 613                 self.species = player_getspecies(); // model or skin has changed
 614
 615         if(!teamplay)
 616                 if(strlen(autocvar_sv_defaultplayercolors))
 617                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 618                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 619 }
 620
 621 void PlayerTouchExplode(entity p1, entity p2)
 622 {
 623         vector org;
 624         org = (p1.origin + p2.origin) * 0.5;
 625         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 626
 627         te_explosion(org);
 628
 629         entity e;
 630         e = spawn();
 631         setorigin(e, org);
 632         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 633         remove(e);
 634 }
 635
 636 /*
 637 =============
 638 PutClientInServer
 639
 640 Called when a client spawns in the server
 641 =============
 642 */
 643 //void() ctf_playerchanged;
 644
 645 void PutClientInServer (void)
 646 {
 647         if(clienttype(self) == CLIENTTYPE_BOT)
 648         {
 649                 self.classname = "player";
 650                 if(g_ca)
 651                         self.caplayer = 1;
 652         }
 653         else if(clienttype(self) == CLIENTTYPE_REAL)
 654         {
 655                 msg_entity = self;
 656                 WriteByte(MSG_ONE, SVC_SETVIEW);
 657                 WriteEntity(MSG_ONE, self);
 658         }
 659
 660         // reset player keys
 661         self.itemkeys = 0;
 662
 663         // player is dead and becomes observer
 664         // FIXME fix LMS scoring for new system
 665         if(g_lms)
 666         {
 667                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 668                         self.classname = "observer";
 669         }
 670
 671         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 672                 self.classname = "observer";
 673
 674         if(gameover)
 675                 self.classname = "observer";
 676
 677         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 678                 entity spot, oldself;
 679                 float j;
 680
 681                 accuracy_resend(self);
 682
 683                 if(self.team < 0)
 684                         JoinBestTeam(self, FALSE, TRUE);
 685
 686                 race_PreSpawn();
 687
 688                 spot = SelectSpawnPoint (FALSE);
 689                 if(!spot)
 690                 {
 691                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 692                         return; // spawn failed
 693                 }
 694
 695                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 696
 697                 self.classname = "player";
 698                 self.wasplayer = TRUE;
 699                 self.iscreature = TRUE;
 700                 self.damagedbycontents = TRUE;
 701                 self.movetype = MOVETYPE_WALK;
 702                 self.solid = SOLID_SLIDEBOX;
 703                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 704                 if(autocvar_g_playerclip_collisions)
 705                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 706                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 707                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 708                 self.frags = FRAGS_PLAYER;
 709                 if(INDEPENDENT_PLAYERS)
 710                         MAKE_INDEPENDENT_PLAYER(self);
 711                 self.flags = FL_CLIENT;
 712                 if(autocvar__notarget)
 713                         self.flags |= FL_NOTARGET;
 714                 self.takedamage = DAMAGE_AIM;
 715                 if(g_minstagib)
 716                         self.effects = EF_FULLBRIGHT;
 717                 else
 718                         self.effects = 0;
 719                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 720                 self.air_finished = time + 12;
 721                 self.dmg = 2;
 722                 if(autocvar_g_balance_nex_charge)
 723                 {
 724                         if(autocvar_g_balance_nex_secondary_chargepool)
 725                                 self.nex_chargepool_ammo = 1;
 726                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 727                 }
 728
 729                 if(inWarmupStage)
 730                 {
 731                         self.ammo_shells = warmup_start_ammo_shells;
 732                         self.ammo_nails = warmup_start_ammo_nails;
 733                         self.ammo_rockets = warmup_start_ammo_rockets;
 734                         self.ammo_cells = warmup_start_ammo_cells;
 735                         self.ammo_fuel = warmup_start_ammo_fuel;
 736                         self.health = warmup_start_health;
 737                         self.armorvalue = warmup_start_armorvalue;
 738                         self.weapons = warmup_start_weapons;
 739                 }
 740                 else
 741                 {
 742                         self.ammo_shells = start_ammo_shells;
 743                         self.ammo_nails = start_ammo_nails;
 744                         self.ammo_rockets = start_ammo_rockets;
 745                         self.ammo_cells = start_ammo_cells;
 746                         self.ammo_fuel = start_ammo_fuel;
 747                         self.health = start_health;
 748                         self.armorvalue = start_armorvalue;
 749                         self.weapons = start_weapons;
 750                 }
 751
 752                 if(self.weapons & WEPBIT_SUPERWEAPONS) // exception for minstagib, as minstanex is a superweapon
 753                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 754                 else
 755                         self.superweapons_finished = 0;
 756
 757                 if(g_weaponarena_random)
 758                 {
 759                         if(g_weaponarena_random_with_laser)
 760                                 self.weapons &~= WEPBIT_LASER;
 761                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 762                         if(g_weaponarena_random_with_laser)
 763                                 self.weapons |= WEPBIT_LASER;
 764                 }
 765
 766                 self.items = start_items;
 767
 768                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 769                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 770                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 771                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 772                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 773                 //extend the pause of rotting if client was reset at the beginning of the countdown
 774                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 775                         self.spawnshieldtime += game_starttime - time;
 776                         self.pauserotarmor_finished += game_starttime - time;
 777                         self.pauserothealth_finished += game_starttime - time;
 778                         self.pauseregen_finished += game_starttime - time;
 779                 }
 780                 self.damageforcescale = 2;
 781                 self.death_time = 0;
 782                 self.respawn_time = 0;
 783                 self.scale = 0;
 784                 self.fade_time = 0;
 785                 self.pain_frame = 0;
 786                 self.pain_finished = 0;
 787                 self.strength_finished = 0;
 788                 self.invincible_finished = 0;
 789                 self.pushltime = 0;
 790                 // players have no think function
 791                 self.think = SUB_Null;
 792                 self.nextthink = 0;
 793                 self.hook_time = 0;
 794                 self.dmg_team = 0;
 795                 self.ballistics_density = autocvar_g_ballistics_density_player;
 796
 797                 self.metertime = 0;
 798
 799                 self.runes = 0;
 800
 801                 self.deadflag = DEAD_NO;
 802
 803                 self.angles = spot.angles;
 804
 805                 self.angles_z = 0; // never spawn tilted even if the spot says to
 806                 self.fixangle = TRUE; // turn this way immediately
 807                 self.velocity = '0 0 0';
 808                 self.avelocity = '0 0 0';
 809                 self.punchangle = '0 0 0';
 810                 self.punchvector = '0 0 0';
 811                 self.oldvelocity = self.velocity;
 812                 self.fire_endtime = -1;
 813
 814                 msg_entity = self;
 815                 WRITESPECTATABLE_MSG_ONE({
 816                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 817                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 818                 });
 819
 820                 self.model = "";
 821                 FixPlayermodel();
 822                 self.drawonlytoclient = world;
 823
 824                 self.crouch = FALSE;
 825                 self.view_ofs = PL_VIEW_OFS;
 826                 setsize (self, PL_MIN, PL_MAX);
 827                 self.spawnorigin = spot.origin;
 828                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 829                 // don't reset back to last position, even if new position is stuck in solid
 830                 self.oldorigin = self.origin;
 831                 self.prevorigin = self.origin;
 832                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 833                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 834         self.hud = HUD_NORMAL;
 835
 836                 if(g_arena)
 837                 {
 838                         Spawnqueue_Remove(self);
 839                         Spawnqueue_Mark(self);
 840                 }
 841                 else if(g_ca)
 842                         self.caplayer = 1;
 843
 844                 self.event_damage = PlayerDamage;
 845
 846                 self.bot_attack = TRUE;
 847
 848                 self.statdraintime = time + 5;
 849                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 850
 851                 if(self.killcount == -666) {
 852                         PlayerScore_Clear(self);
 853                         self.killcount = 0;
 854                 }
 855
 856                 CL_SpawnWeaponentity();
 857                 self.alpha = default_player_alpha;
 858                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 859                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 860
 861                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 862                 self.lms_traveled_distance = 0;
 863                 self.speedrunning = FALSE;
 864
 865                 race_PostSpawn(spot);
 866
 867                 //stuffcmd(self, "chase_active 0");
 868                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 869
 870                 if (autocvar_g_spawnsound)
 871                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 872
 873                 if(g_assault) {
 874                         if(self.team == assault_attacker_team)
 875                                 centerprint(self, "You are attacking!");
 876                         else
 877                                 centerprint(self, "You are defending!");
 878                 }
 879
 880                 target_voicescript_clear(self);
 881
 882                 // reset fields the weapons may use
 883                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 884                 {
 885                         weapon_action(j, WR_RESETPLAYER);
 886
 887                         // all weapons must be fully loaded when we spawn
 888                         entity e;
 889                         e = get_weaponinfo(j);
 890                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 891                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 892                 }
 893
 894                 oldself = self;
 895                 self = spot;
 896                         activator = oldself;
 897                                 string s;
 898                                 s = self.target;
 899                                 self.target = string_null;
 900                                 SUB_UseTargets();
 901                                 self.target = s;
 902                         activator = world;
 903                 self = oldself;
 904
 905                 spawn_spot = spot;
 906                 MUTATOR_CALLHOOK(PlayerSpawn);
 907
 908                 if(autocvar_spawn_debug)
 909                 {
 910                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 911                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 912                 }
 913
 914                 self.switchweapon = w_getbestweapon(self);
 915                 self.cnt = -1; // W_LastWeapon will not complain
 916                 self.weapon = 0;
 917                 self.weaponname = "";
 918                 self.switchingweapon = 0;
 919
 920                 if(!self.alivetime)
 921                         self.alivetime = time;
 922
 923                 antilag_clear(self);
 924         } else if(self.classname == "observer") {
 925                 PutObserverInServer ();
 926         }
 927
 928         //if(g_ctf)
 929         //      ctf_playerchanged();
 930 }
 931
 932 .float ebouncefactor, ebouncestop; // electro's values
 933 // TODO do we need all these fields, or should we stop autodetecting runtime
 934 // changes and just have a console command to update this?
 935 float ClientInit_SendEntity(entity to, float sf)
 936 {
 937         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 938         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 951         if(sv_foginterval && world.fog != "")
 952                 WriteString(MSG_ENTITY, world.fog);
 953         else
 954                 WriteString(MSG_ENTITY, "");
 955         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 956         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 957         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 958         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 959         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 960         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 961         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 962         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 963         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 964         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 965         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 966         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 967         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 968         return TRUE;
 969 }
 970
 971 void ClientInit_CheckUpdate()
 972 {
 973         self.nextthink = time;
 974         if(self.count != autocvar_g_balance_armor_blockpercent)
 975         {
 976                 self.count = autocvar_g_balance_armor_blockpercent;
 977                 self.SendFlags |= 1;
 978         }
 979         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 980         {
 981                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 982                 self.SendFlags |= 1;
 983         }
 984         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 985         {
 986                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 987                 self.SendFlags |= 1;
 988         }
 989         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 990         {
 991                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 992                 self.SendFlags |= 1;
 993         }
 994         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 995         {
 996                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 997                 self.SendFlags |= 1;
 998         }
 999         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1000         {
1001                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1002                 self.SendFlags |= 1;
1003         }
1004 }
1005
1006 void ClientInit_Spawn()
1007 {
1008         entity o;
1009         entity e;
1010         e = spawn();
1011         e.classname = "clientinit";
1012         e.think = ClientInit_CheckUpdate;
1013         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1014
1015         o = self;
1016         self = e;
1017         ClientInit_CheckUpdate();
1018         self = o;
1019 }
1020
1021 /*
1022 =============
1023 SetNewParms
1024 =============
1025 */
1026 void SetNewParms (void)
1027 {
1028         // initialize parms for a new player
1029         parm1 = -(86400 * 366);
1030 }
1031
1032 /*
1033 =============
1034 SetChangeParms
1035 =============
1036 */
1037 void SetChangeParms (void)
1038 {
1039         // save parms for level change
1040         parm1 = self.parm_idlesince - time;
1041 }
1042
1043 /*
1044 =============
1045 DecodeLevelParms
1046 =============
1047 */
1048 void DecodeLevelParms (void)
1049 {
1050         // load parms
1051         self.parm_idlesince = parm1;
1052         if(self.parm_idlesince == -(86400 * 366))
1053                 self.parm_idlesince = time;
1054
1055         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1056         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1057 }
1058
1059 /*
1060 =============
1061 ClientKill
1062
1063 Called when a client types 'kill' in the console
1064 =============
1065 */
1066
1067 .float clientkill_nexttime;
1068 void ClientKill_Now_TeamChange()
1069 {
1070         if(self.killindicator_teamchange == -1)
1071         {
1072                 self.team = -1;
1073                 JoinBestTeam( self, FALSE, FALSE );
1074         }
1075         else if(self.killindicator_teamchange == -2)
1076         {
1077                 if(g_ca)
1078                         self.caplayer = 0;
1079                 if(blockSpectators)
1080                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1081                 PutObserverInServer();
1082         }
1083         else
1084                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1085 }
1086
1087 void ClientKill_Now()
1088 {
1089         if(self.vehicle)
1090         {
1091             vehicles_exit(VHEF_RELESE);
1092             if(!self.killindicator_teamchange)
1093             {
1094             self.vehicle_health = -1;
1095             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1096             }
1097         }
1098
1099         if(self.killindicator && !wasfreed(self.killindicator))
1100                 remove(self.killindicator);
1101
1102         self.killindicator = world;
1103
1104         if(self.killindicator_teamchange)
1105                 ClientKill_Now_TeamChange();
1106
1107         // in any case:
1108         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1109
1110         // now I am sure the player IS dead
1111 }
1112 void KillIndicator_Think()
1113 {
1114         if (gameover)
1115         {
1116                 self.owner.killindicator = world;
1117                 remove(self);
1118                 return;
1119         }
1120
1121         if (self.owner.alpha < 0)
1122         {
1123                 self.owner.killindicator = world;
1124                 remove(self);
1125                 return;
1126         }
1127
1128         if(self.cnt <= 0)
1129         {
1130                 self = self.owner;
1131                 ClientKill_Now(); // no oldself needed
1132                 return;
1133         }
1134     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1135     {
1136         self.nextthink = time + 1;
1137         self.cnt -= 1;
1138     }
1139         else
1140         {
1141                 if(self.cnt <= 10)
1142                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1143                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1144                 {
1145                         if(self.cnt <= 10)
1146                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1147                 }
1148                 self.nextthink = time + 1;
1149                 self.cnt -= 1;
1150         }
1151 }
1152
1153 float clientkilltime;
1154 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1155 {
1156         float killtime;
1157         float starttime;
1158         entity e;
1159
1160         if (gameover)
1161                 return;
1162
1163         killtime = autocvar_g_balance_kill_delay;
1164
1165         if(g_race_qualifying || g_cts)
1166                 killtime = 0;
1167
1168     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1169     {
1170                 remove(self.killindicator);
1171                 self.killindicator = world;
1172
1173         ClientKill_Now(); // allow instant kill in this case
1174         return;
1175     }
1176
1177         self.killindicator_teamchange = targetteam;
1178
1179     if(!self.killindicator)
1180         {
1181                 if(self.deadflag == DEAD_NO)
1182                 {
1183                         killtime = max(killtime, self.clientkill_nexttime - time);
1184                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1185                 }
1186
1187                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1188                 {
1189                         ClientKill_Now();
1190                 }
1191                 else
1192                 {
1193                         starttime = max(time, clientkilltime);
1194
1195                         self.killindicator = spawn();
1196                         self.killindicator.owner = self;
1197                         self.killindicator.scale = 0.5;
1198                         setattachment(self.killindicator, self, "");
1199                         setorigin(self.killindicator, '0 0 52');
1200                         self.killindicator.think = KillIndicator_Think;
1201                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1202                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1203                         self.killindicator.cnt = ceil(killtime);
1204                         self.killindicator.count = bound(0, ceil(killtime), 10);
1205                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1206
1207                         for(e = world; (e = find(e, classname, "body")) != world; )
1208                         {
1209                                 if(e.enemy != self)
1210                                         continue;
1211                                 e.killindicator = spawn();
1212                                 e.killindicator.owner = e;
1213                                 e.killindicator.scale = 0.5;
1214                                 setattachment(e.killindicator, e, "");
1215                                 setorigin(e.killindicator, '0 0 52');
1216                                 e.killindicator.think = KillIndicator_Think;
1217                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1218                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1219                                 e.killindicator.cnt = ceil(killtime);
1220                         }
1221                         self.lip = 0;
1222                 }
1223         }
1224         if(self.killindicator)
1225         {
1226                 if(targetteam == 0) // just die
1227                 {
1228                         self.killindicator.colormod = '0 0 0';
1229                         if(clienttype(self) == CLIENTTYPE_REAL)
1230                         if(self.killindicator.cnt > 0)
1231                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1232                 }
1233                 else if(targetteam == -1) // auto
1234                 {
1235                         self.killindicator.colormod = '0 1 0';
1236                         if(clienttype(self) == CLIENTTYPE_REAL)
1237                         if(self.killindicator.cnt > 0)
1238                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1239                 }
1240                 else if(targetteam == -2) // spectate
1241                 {
1242                         self.killindicator.colormod = '0.5 0.5 0.5';
1243                         if(clienttype(self) == CLIENTTYPE_REAL)
1244                         if(self.killindicator.cnt > 0)
1245                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1246                 }
1247                 else
1248                 {
1249                         self.killindicator.colormod = TeamColor(targetteam);
1250                         if(clienttype(self) == CLIENTTYPE_REAL)
1251                         if(self.killindicator.cnt > 0)
1252                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1253                 }
1254         }
1255
1256 }
1257
1258 void ClientKill (void)
1259 {
1260         if (gameover)
1261                 return;
1262
1263         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1264         {
1265                 // do nothing
1266         }
1267     else if(self.freezetag_frozen)
1268     {
1269         // do nothing
1270     }
1271         else
1272                 ClientKill_TeamChange(0);
1273 }
1274
1275 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1276 {
1277     e.killindicator = spawn();
1278     e.killindicator.owner = e;
1279     e.killindicator.think = KillIndicator_Think;
1280     e.killindicator.nextthink = time + (e.lip) * 0.05;
1281     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1282     e.killindicator.health = 1; // this is used to indicate that it should be silent
1283     e.lip = 0;
1284 }
1285
1286 void FixClientCvars(entity e)
1287 {
1288         // send prediction settings to the client
1289         stuffcmd(e, "\nin_bindmap 0 0\n");
1290         if(g_race || g_cts)
1291                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1292         if(autocvar_g_antilag == 3) // client side hitscan
1293                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1294         if(sv_gentle)
1295                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1296         /*
1297          * we no longer need to stuff this. Remove this comment block if you feel
1298          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1299         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1300         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1301         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1302         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1303         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1304         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1305         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1306         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1307         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1308         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1309         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1310         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1311         stuffcmd(e, "cl_movement_edgefriction 1\n");
1312          */
1313 }
1314
1315 float PlayerInIDList(entity p, string idlist)
1316 {
1317         float n, i;
1318         string s;
1319
1320         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1321         if not(p.crypto_idfp)
1322                 return 0;
1323
1324         // this function allows abbreviated player IDs too!
1325         n = tokenize_console(idlist);
1326         for(i = 0; i < n; ++i)
1327         {
1328                 s = argv(i);
1329                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1330                         return 1;
1331         }
1332
1333         return 0;
1334 }
1335
1336 /*
1337 =============
1338 ClientConnect
1339
1340 Called when a client connects to the server
1341 =============
1342 */
1343 //void ctf_clientconnect();
1344 string ColoredTeamName(float t);
1345 void DecodeLevelParms (void);
1346 //void dom_player_join_team(entity pl);
1347 void set_dom_state(entity e);
1348 void ClientConnect (void)
1349 {
1350         float t;
1351
1352         if(self.flags & FL_CLIENT)
1353         {
1354                 print("Warning: ClientConnect, but already connected!\n");
1355                 return;
1356         }
1357
1358         if(Ban_MaybeEnforceBan(self))
1359                 return;
1360
1361         DecodeLevelParms();
1362
1363 #ifdef WATERMARK
1364         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1365 #endif
1366
1367         self.classname = "player_joining";
1368
1369         self.flags = FL_CLIENT;
1370         self.version_nagtime = time + 10 + random() * 10;
1371
1372         if(player_count<0)
1373         {
1374                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1375                 player_count = 0;
1376         }
1377
1378         PlayerScore_Attach(self);
1379         ClientData_Attach();
1380         accuracy_init(self);
1381
1382         bot_clientconnect();
1383
1384         playerdemo_init();
1385
1386         anticheat_init();
1387
1388         race_PreSpawnObserver();
1389
1390         //if(g_domination)
1391         //      dom_player_join_team(self);
1392
1393         // identify the right forced team
1394         if(autocvar_g_campaign)
1395         {
1396                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1397                 {
1398                         switch(autocvar_g_campaign_forceteam)
1399                         {
1400                                 case 1: self.team_forced = COLOR_TEAM1; break;
1401                                 case 2: self.team_forced = COLOR_TEAM2; break;
1402                                 case 3: self.team_forced = COLOR_TEAM3; break;
1403                                 case 4: self.team_forced = COLOR_TEAM4; break;
1404                                 default: self.team_forced = 0;
1405                         }
1406                 }
1407         }
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1409                 self.team_forced = COLOR_TEAM1;
1410         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1411                 self.team_forced = COLOR_TEAM2;
1412         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1413                 self.team_forced = COLOR_TEAM3;
1414         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1415                 self.team_forced = COLOR_TEAM4;
1416         else if(autocvar_g_forced_team_otherwise == "red")
1417                 self.team_forced = COLOR_TEAM1;
1418         else if(autocvar_g_forced_team_otherwise == "blue")
1419                 self.team_forced = COLOR_TEAM2;
1420         else if(autocvar_g_forced_team_otherwise == "yellow")
1421                 self.team_forced = COLOR_TEAM3;
1422         else if(autocvar_g_forced_team_otherwise == "pink")
1423                 self.team_forced = COLOR_TEAM4;
1424         else if(autocvar_g_forced_team_otherwise == "spectate")
1425                 self.team_forced = -1;
1426         else if(autocvar_g_forced_team_otherwise == "spectator")
1427                 self.team_forced = -1;
1428         else
1429                 self.team_forced = 0;
1430
1431         if(!teamplay)
1432                 if(self.team_forced > 0)
1433                         self.team_forced = 0;
1434
1435         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1436
1437         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1438                 self.classname = "observer";
1439         } else {
1440                 if(teamplay)
1441                 {
1442                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1443                         {
1444                                 self.classname = "player";
1445                                 campaign_bots_may_start = 1;
1446                         }
1447                         else
1448                         {
1449                                 self.classname = "observer"; // do it anyway
1450                         }
1451                 }
1452                 else
1453                 {
1454                         self.classname = "player";
1455                         campaign_bots_may_start = 1;
1456                 }
1457         }
1458
1459         self.playerid = (playerid_last = playerid_last + 1);
1460
1461         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1462
1463     if(clienttype(self) == CLIENTTYPE_BOT)
1464         PlayerStats_AddPlayer(self);
1465
1466         if(autocvar_sv_eventlog)
1467                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1468
1469         LogTeamchange(self.playerid, self.team, 1);
1470
1471         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1472
1473         self.netname_previous = strzone(self.netname);
1474
1475         bprint("^4", self.netname, "^4 connected");
1476
1477         if(self.classname != "observer" && (g_domination || g_ctf))
1478                 bprint(" and joined the ", ColoredTeamName(self.team));
1479
1480         bprint("\n");
1481
1482         stuffcmd(self, strcat(clientstuff, "\n"));
1483         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1484
1485         FixClientCvars(self);
1486
1487         // spawnfunc_waypoint sprites
1488         WaypointSprite_InitClient(self);
1489
1490         // Wazat's grappling hook
1491         SetGrappleHookBindings();
1492
1493         // get version info from player
1494         stuffcmd(self, "cmd clientversion $gameversion\n");
1495
1496         // get other cvars from player
1497         GetCvars(0);
1498
1499         // notify about available teams
1500         if(teamplay)
1501         {
1502                 CheckAllowedTeams(self);
1503                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1504                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1505         }
1506         else
1507                 stuffcmd(self, "set _teams_available 0\n");
1508
1509         if(g_arena || g_ca)
1510         {
1511                 self.classname = "observer";
1512                 if(g_arena)
1513                         Spawnqueue_Insert(self);
1514         }
1515         /*else if(g_ctf)
1516         {
1517                 ctf_clientconnect();
1518         }*/
1519
1520         attach_entcs();
1521
1522         bot_relinkplayerlist();
1523
1524         self.spectatortime = time;
1525         if(blockSpectators)
1526         {
1527                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1528         }
1529
1530         self.jointime = time;
1531         self.allowed_timeouts = autocvar_sv_timeout_number;
1532
1533         if(clienttype(self) == CLIENTTYPE_REAL)
1534         {
1535                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1536                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1537         }
1538
1539         if(g_lms)
1540         {
1541                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1542                 {
1543                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1544                         self.frags = FRAGS_SPECTATOR;
1545                 }
1546         }
1547
1548         if(!sv_foginterval && world.fog != "")
1549                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1550
1551         SoundEntity_Attach(self);
1552
1553         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1554         {
1555                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1556                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1557         }
1558         else
1559                 self.hitplotfh = -1;
1560
1561         if(g_race || g_cts) {
1562                 string rr;
1563                 if(g_cts)
1564                         rr = CTS_RECORD;
1565                 else
1566                         rr = RACE_RECORD;
1567                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1568
1569                 msg_entity = self;
1570                 race_send_recordtime(MSG_ONE);
1571                 race_send_speedaward(MSG_ONE);
1572
1573                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1574                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1575                 race_send_speedaward_alltimebest(MSG_ONE);
1576
1577                 float i;
1578                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1579                         race_SendRankings(i, 0, 0, MSG_ONE);
1580                 }
1581         }
1582         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1583                 send_CSQC_teamnagger();
1584
1585         if (g_domination)
1586                 set_dom_state(self);
1587
1588         CheatInitClient();
1589
1590         if(!autocvar_g_campaign)
1591                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1592
1593         CSQCMODEL_AUTOINIT();
1594
1595         self.model_randomizer = random();
1596
1597     if(clienttype(self) != CLIENTTYPE_REAL)
1598         return;
1599
1600     sv_notice_join();
1601 }
1602 /*
1603 =============
1604 ClientDisconnect
1605
1606 Called when a client disconnects from the server
1607 =============
1608 */
1609 .entity chatbubbleentity;
1610 void ReadyCount();
1611 void ClientDisconnect (void)
1612 {
1613         if(self.vehicle)
1614             vehicles_exit(VHEF_RELESE);
1615
1616         if not(self.flags & FL_CLIENT)
1617         {
1618                 print("Warning: ClientDisconnect without ClientConnect\n");
1619                 return;
1620         }
1621
1622         PlayerStats_AddGlobalInfo(self);
1623
1624         CheatShutdownClient();
1625
1626         if(self.hitplotfh >= 0)
1627         {
1628                 fclose(self.hitplotfh);
1629                 self.hitplotfh = -1;
1630         }
1631
1632         anticheat_report();
1633         anticheat_shutdown();
1634
1635         playerdemo_shutdown();
1636
1637         bot_clientdisconnect();
1638
1639         if(self.entcs)
1640                 detach_entcs();
1641
1642         if(autocvar_sv_eventlog)
1643                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1644         bprint ("^4",self.netname);
1645         bprint ("^4 disconnected\n");
1646
1647         SoundEntity_Detach(self);
1648
1649         DropAllRunes(self);
1650         MUTATOR_CALLHOOK(ClientDisconnect);
1651
1652         Portal_ClearAll(self);
1653
1654         RemoveGrapplingHook(self);
1655         if(self.flagcarried)
1656                 DropFlag(self.flagcarried, world, world);
1657
1658         // Here, everything has been done that requires this player to be a client.
1659
1660         self.flags &~= FL_CLIENT;
1661
1662         if (self.chatbubbleentity)
1663                 remove (self.chatbubbleentity);
1664
1665         if (self.killindicator)
1666                 remove (self.killindicator);
1667
1668         WaypointSprite_PlayerGone();
1669
1670         bot_relinkplayerlist();
1671
1672         if(g_arena)
1673         {
1674                 Spawnqueue_Unmark(self);
1675                 Spawnqueue_Remove(self);
1676         }
1677
1678         accuracy_free(self);
1679         ClientData_Detach();
1680         PlayerScore_Detach(self);
1681
1682         if(self.netname_previous)
1683                 strunzone(self.netname_previous);
1684         if(self.clientstatus)
1685                 strunzone(self.clientstatus);
1686         if(self.weaponorder_byimpulse)
1687                 strunzone(self.weaponorder_byimpulse);
1688
1689         ClearPlayerSounds();
1690
1691         if(self.personal)
1692                 remove(self.personal);
1693
1694         self.playerid = 0;
1695         ReadyCount();
1696
1697         // free cvars
1698         GetCvars(-1);
1699 }
1700
1701 .float BUTTON_CHAT;
1702 void ChatBubbleThink()
1703 {
1704         self.nextthink = time;
1705         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1706         {
1707                 if(self.owner) // but why can that ever be world?
1708                         self.owner.chatbubbleentity = world;
1709                 remove(self);
1710                 return;
1711         }
1712         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1713 #ifdef TETRIS
1714                 || self.owner.tetris_on
1715 #endif
1716         )
1717                 self.model = self.mdl;
1718         else
1719                 self.model = "";
1720 }
1721
1722 void UpdateChatBubble()
1723 {
1724         if (self.alpha < 0)
1725                 return;
1726         // spawn a chatbubble entity if needed
1727         if (!self.chatbubbleentity)
1728         {
1729                 self.chatbubbleentity = spawn();
1730                 self.chatbubbleentity.owner = self;
1731                 self.chatbubbleentity.exteriormodeltoclient = self;
1732                 self.chatbubbleentity.think = ChatBubbleThink;
1733                 self.chatbubbleentity.nextthink = time;
1734                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1735                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1736                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1737                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1738                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1739                 self.chatbubbleentity.model = "";
1740                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1741         }
1742 }
1743
1744
1745 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1746 // added to the model skins
1747 /*void UpdateColorModHack()
1748 {
1749         float c;
1750         c = self.clientcolors & 15;
1751         // LordHavoc: only bothering to support white, green, red, yellow, blue
1752              if (!teamplay) self.colormod = '0 0 0';
1753         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1754         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1755         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1756         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1757         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1758         else self.colormod = '1 1 1';
1759 }*/
1760
1761 void respawn(void)
1762 {
1763         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1764         {
1765                 self.solid = SOLID_NOT;
1766                 self.takedamage = DAMAGE_NO;
1767                 self.movetype = MOVETYPE_FLY;
1768                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1769                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1770                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1771                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1772                 if(autocvar_g_respawn_ghosts_maxtime)
1773                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1774         }
1775
1776         CopyBody(1);
1777
1778         self.effects |= EF_NODRAW; // prevent another CopyBody
1779         PutClientInServer();
1780 }
1781
1782 void play_countdown(float finished, string samp)
1783 {
1784         if(clienttype(self) == CLIENTTYPE_REAL)
1785                 if(floor(finished - time - frametime) != floor(finished - time))
1786                         if(finished - time < 6)
1787                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1788 }
1789
1790 void player_powerups (void)
1791 {
1792         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1793         olditems = self.items;
1794
1795         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1796         {
1797                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1798                 self.modelflags |= MF_ROCKET;
1799         }
1800         else
1801         {
1802                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1803                 self.modelflags &~= MF_ROCKET;
1804         }
1805
1806         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1807
1808         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1809                 return;
1810
1811         Fire_ApplyDamage(self);
1812         Fire_ApplyEffect(self);
1813
1814         if (g_minstagib)
1815         {
1816                 self.effects |= EF_FULLBRIGHT;
1817
1818                 if (self.items & IT_STRENGTH)
1819                 {
1820                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1821                         if (time > self.strength_finished)
1822                         {
1823                                 self.alpha = default_player_alpha;
1824                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1825                                 self.items &~= IT_STRENGTH;
1826                                 sprint(self, "^3Invisibility has worn off\n");
1827                         }
1828                 }
1829                 else
1830                 {
1831                         if (time < self.strength_finished)
1832                         {
1833                                 self.alpha = g_minstagib_invis_alpha;
1834                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1835                                 self.items |= IT_STRENGTH;
1836                                 sprint(self, "^3You are invisible\n");
1837                         }
1838                 }
1839
1840                 if (self.items & IT_INVINCIBLE)
1841                 {
1842                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1843                         if (time > self.invincible_finished)
1844                         {
1845                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1846                                 sprint(self, "^3Speed has worn off\n");
1847                         }
1848                 }
1849                 else
1850                 {
1851                         if (time < self.invincible_finished)
1852                         {
1853                                 self.items = self.items | IT_INVINCIBLE;
1854                                 sprint(self, "^3You are on speed\n");
1855                         }
1856                 }
1857         }
1858         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1859         {
1860                 if (self.items & IT_STRENGTH)
1861                 {
1862                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1863                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1864                         if (time > self.strength_finished)
1865                         {
1866                                 self.items = self.items - (self.items & IT_STRENGTH);
1867                                 sprint(self, "^3Strength has worn off\n");
1868                         }
1869                 }
1870                 else
1871                 {
1872                         if (time < self.strength_finished)
1873                         {
1874                                 self.items = self.items | IT_STRENGTH;
1875                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1876                         }
1877                 }
1878                 if (self.items & IT_INVINCIBLE)
1879                 {
1880                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1881                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1882                         if (time > self.invincible_finished)
1883                         {
1884                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1885                                 sprint(self, "^3Shield has worn off\n");
1886                         }
1887                 }
1888                 else
1889                 {
1890                         if (time < self.invincible_finished)
1891                         {
1892                                 self.items = self.items | IT_INVINCIBLE;
1893                                 sprint(self, "^3Shield surrounds you\n");
1894                         }
1895                 }
1896                 if (self.items & IT_SUPERWEAPON)
1897                 {
1898                         //if(W_WeaponBit(self.weapon) & WEPBIT_SUPERWEAPONS)
1899                         //      self.effects = self.effects | EF_RED;
1900                         if (!(self.weapons & WEPBIT_SUPERWEAPONS))
1901                         {
1902                                 self.superweapons_finished = 0;
1903                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1904                                 sprint(self, "^3Superweapons have been lost\n");
1905                         }
1906                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1907                         {
1908                                 // don't let them run out
1909                         }
1910                         else
1911                         {
1912                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1913                                 if (time > self.superweapons_finished)
1914                                 {
1915                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1916                                         self.weapons &~= WEPBIT_SUPERWEAPONS;
1917                                         sprint(self, "^3Superweapons have broken down\n");
1918                                 }
1919                         }
1920                 }
1921                 else if(self.weapons & WEPBIT_SUPERWEAPONS)
1922                 {
1923                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1924                         {
1925                                 self.items = self.items | IT_SUPERWEAPON;
1926                                 sprint(self, "^3You now have a superweapon\n");
1927                         }
1928                         else
1929                         {
1930                                 self.superweapons_finished = 0;
1931                                 self.weapons &~= WEPBIT_SUPERWEAPONS; // just in case
1932                         }
1933                 }
1934                 else
1935                 {
1936                         self.superweapons_finished = 0;
1937                 }
1938         }
1939
1940         if(autocvar_g_nodepthtestplayers)
1941                 self.effects = self.effects | EF_NODEPTHTEST;
1942
1943         if(autocvar_g_fullbrightplayers)
1944                 self.effects = self.effects | EF_FULLBRIGHT;
1945
1946         // midair gamemode: damage only while in the air
1947         // if in midair mode, being on ground grants temporary invulnerability
1948         // (this is so that multishot weapon don't clear the ground flag on the
1949         // first damage in the frame, leaving the player vulnerable to the
1950         // remaining hits in the same frame)
1951         if (self.flags & FL_ONGROUND)
1952         if (g_midair)
1953                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1954
1955         if (time >= game_starttime)
1956         if (time < self.spawnshieldtime)
1957                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1958
1959         MUTATOR_CALLHOOK(PlayerPowerups);
1960 }
1961
1962 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1963 {
1964         if(current > stable)
1965                 return current;
1966         else if(current > stable - 0.25) // when close enough, "snap"
1967                 return stable;
1968         else
1969                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1970 }
1971
1972 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1973 {
1974         if(current < stable)
1975                 return current;
1976         else if(current < stable + 0.25) // when close enough, "snap"
1977                 return stable;
1978         else
1979                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1980 }
1981
1982 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1983 {
1984         if(current > rotstable)
1985         {
1986                 if(rotframetime > 0)
1987                 {
1988                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1989                         current = max(rotstable, current - rotlinear * rotframetime);
1990                 }
1991         }
1992         else if(current < regenstable)
1993         {
1994                 if(regenframetime > 0)
1995                 {
1996                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1997                         current = min(regenstable, current + regenlinear * regenframetime);
1998                 }
1999         }
2000
2001         if(current > limit)
2002                 current = limit;
2003
2004         return current;
2005 }
2006
2007 void player_regen (void)
2008 {
2009         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2010         maxh = autocvar_g_balance_health_rotstable;
2011         maxa = autocvar_g_balance_armor_rotstable;
2012         maxf = autocvar_g_balance_fuel_rotstable;
2013         minh = autocvar_g_balance_health_regenstable;
2014         mina = autocvar_g_balance_armor_regenstable;
2015         minf = autocvar_g_balance_fuel_regenstable;
2016         limith = autocvar_g_balance_health_limit;
2017         limita = autocvar_g_balance_armor_limit;
2018         limitf = autocvar_g_balance_fuel_limit;
2019
2020         max_mod = regen_mod = rot_mod = limit_mod = 1;
2021
2022         if (self.runes & RUNE_REGEN)
2023         {
2024                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2025                 {
2026                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2027                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2028                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2029                 }
2030                 else
2031                 {
2032                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2033                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2034                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2035                 }
2036         }
2037         else if (self.runes & CURSE_VENOM)
2038         {
2039                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2040                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2041                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2042                 else
2043                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2044                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2045                 //if (!self.runes & RUNE_REGEN)
2046                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2047         }
2048         maxh = maxh * max_mod;
2049         //maxa = maxa * max_mod;
2050         //maxf = maxf * max_mod;
2051         minh = minh * max_mod;
2052         //mina = mina * max_mod;
2053         //minf = minf * max_mod;
2054         limith = limith * limit_mod;
2055         limita = limita * limit_mod;
2056         //limitf = limitf * limit_mod;
2057
2058         if(g_lms && g_ca)
2059                 rot_mod = 0;
2060
2061         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2062         {
2063                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2064                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2065
2066                 // if player rotted to death...  die!
2067                 if(self.health < 1)
2068                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2069         }
2070
2071         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2072                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2073 }
2074
2075 float zoomstate_set;
2076 void SetZoomState(float z)
2077 {
2078         if(z != self.zoomstate)
2079         {
2080                 self.zoomstate = z;
2081                 ClientData_Touch(self);
2082         }
2083         zoomstate_set = 1;
2084 }
2085
2086 void GetPressedKeys(void) {
2087         MUTATOR_CALLHOOK(GetPressedKeys);
2088         if (self.movement_x > 0) // get if movement keys are pressed
2089         {       // forward key pressed
2090                 self.pressedkeys |= KEY_FORWARD;
2091                 self.pressedkeys &~= KEY_BACKWARD;
2092         }
2093         else if (self.movement_x < 0)
2094         {       // backward key pressed
2095                 self.pressedkeys |= KEY_BACKWARD;
2096                 self.pressedkeys &~= KEY_FORWARD;
2097         }
2098         else
2099         {       // no x input
2100                 self.pressedkeys &~= KEY_FORWARD;
2101                 self.pressedkeys &~= KEY_BACKWARD;
2102         }
2103
2104         if (self.movement_y > 0)
2105         {       // right key pressed
2106                 self.pressedkeys |= KEY_RIGHT;
2107                 self.pressedkeys &~= KEY_LEFT;
2108         }
2109         else if (self.movement_y < 0)
2110         {       // left key pressed
2111                 self.pressedkeys |= KEY_LEFT;
2112                 self.pressedkeys &~= KEY_RIGHT;
2113         }
2114         else
2115         {       // no y input
2116                 self.pressedkeys &~= KEY_RIGHT;
2117                 self.pressedkeys &~= KEY_LEFT;
2118         }
2119
2120         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2121                 self.pressedkeys |= KEY_JUMP;
2122         else
2123                 self.pressedkeys &~= KEY_JUMP;
2124         if (self.BUTTON_CROUCH)
2125                 self.pressedkeys |= KEY_CROUCH;
2126         else
2127                 self.pressedkeys &~= KEY_CROUCH;
2128 }
2129
2130 /*
2131 ======================
2132 spectate mode routines
2133 ======================
2134 */
2135
2136 void SpectateCopy(entity spectatee) {
2137         other = spectatee;
2138         MUTATOR_CALLHOOK(SpectateCopy);
2139         self.armortype = spectatee.armortype;
2140         self.armorvalue = spectatee.armorvalue;
2141         self.ammo_cells = spectatee.ammo_cells;
2142         self.ammo_shells = spectatee.ammo_shells;
2143         self.ammo_nails = spectatee.ammo_nails;
2144         self.ammo_rockets = spectatee.ammo_rockets;
2145         self.ammo_fuel = spectatee.ammo_fuel;
2146         self.clip_load = spectatee.clip_load;
2147         self.clip_size = spectatee.clip_size;
2148         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2149         self.health = spectatee.health;
2150         self.impulse = 0;
2151         self.items = spectatee.items;
2152         self.last_pickup = spectatee.last_pickup;
2153         self.hit_time = spectatee.hit_time;
2154         self.metertime = spectatee.metertime;
2155         self.strength_finished = spectatee.strength_finished;
2156         self.invincible_finished = spectatee.invincible_finished;
2157         self.pressedkeys = spectatee.pressedkeys;
2158         self.weapons = spectatee.weapons;
2159         self.switchweapon = spectatee.switchweapon;
2160         self.switchingweapon = spectatee.switchingweapon;
2161         self.weapon = spectatee.weapon;
2162         self.nex_charge = spectatee.nex_charge;
2163         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2164         self.hagar_load = spectatee.hagar_load;
2165         self.minelayer_mines = spectatee.minelayer_mines;
2166         self.punchangle = spectatee.punchangle;
2167         self.view_ofs = spectatee.view_ofs;
2168         self.v_angle = spectatee.v_angle;
2169         self.velocity = spectatee.velocity;
2170         self.dmg_take = spectatee.dmg_take;
2171         self.dmg_save = spectatee.dmg_save;
2172         self.dmg_inflictor = spectatee.dmg_inflictor;
2173         self.angles = spectatee.v_angle;
2174         if(!self.BUTTON_USE)
2175                 self.fixangle = TRUE;
2176         setorigin(self, spectatee.origin);
2177         setsize(self, spectatee.mins, spectatee.maxs);
2178         SetZoomState(spectatee.zoomstate);
2179
2180         anticheat_spectatecopy(spectatee);
2181
2182         //self.vehicle = spectatee.vehicle;
2183
2184         self.hud = spectatee.hud;
2185         if(spectatee.vehicle)
2186     {
2187         setorigin(self, spectatee.origin);
2188         self.velocity = spectatee.vehicle.velocity;
2189         self.v_angle += spectatee.vehicle.angles;
2190         //self.v_angle_x *= -1;
2191         self.vehicle_health = spectatee.vehicle_health;
2192         self.vehicle_shield = spectatee.vehicle_shield;
2193         self.vehicle_energy = spectatee.vehicle_energy;
2194         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2195         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2196         self.vehicle_reload1 = spectatee.vehicle_reload1;
2197         self.vehicle_reload2 = spectatee.vehicle_reload2;
2198
2199         msg_entity = self;
2200         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2201         WriteEntity(MSG_ONE, spectatee);
2202         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2203     }
2204 }
2205
2206 float SpectateUpdate() {
2207         if(!self.enemy)
2208             return 0;
2209
2210         if (self == self.enemy)
2211                 return 0;
2212
2213         if(self.enemy.classname != "player")
2214                 return 0;
2215
2216         SpectateCopy(self.enemy);
2217
2218         return 1;
2219 }
2220
2221
2222 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2223 entity CA_SpectateNext(entity start) {
2224         if (start.team == self.team) {
2225                 return start;
2226         }
2227
2228         other = start;
2229         // continue from current player
2230         while(other && other.team != self.team) {
2231                 other = find(other, classname, "player");
2232         }
2233
2234         if (!other) {
2235                 // restart from begining
2236                 other = find(other, classname, "player");
2237                 while(other && other.team != self.team) {
2238                         other = find(other, classname, "player");
2239                 }
2240         }
2241
2242         return other;
2243 }
2244
2245 float SpectateNext() {
2246         other = find(self.enemy, classname, "player");
2247         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2248                 // CA and ca players when spectating enemies is forbidden
2249                 other = CA_SpectateNext(other);
2250         } else {
2251                 // other modes and ca spectators or spectating enemies is allowed
2252                 if (!other)
2253                         other = find(other, classname, "player");
2254         }
2255
2256         if (other)
2257                 self.enemy = other;
2258
2259         if(self.enemy.classname == "player") {
2260             if(self.enemy.vehicle)
2261             {
2262             msg_entity = self;
2263             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2264             WriteEntity(MSG_ONE, self.enemy);
2265             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2266             self.movetype = MOVETYPE_NONE;
2267             accuracy_resend(self);
2268             }
2269             else
2270             {
2271             msg_entity = self;
2272             WriteByte(MSG_ONE, SVC_SETVIEW);
2273             WriteEntity(MSG_ONE, self.enemy);
2274             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2275             self.movetype = MOVETYPE_NONE;
2276             accuracy_resend(self);
2277
2278             if(!SpectateUpdate())
2279                 PutObserverInServer();
2280         }
2281         return 1;
2282         } else {
2283                 return 0;
2284         }
2285 }
2286
2287 /*
2288 =============
2289 ShowRespawnCountdown()
2290
2291 Update a respawn countdown display.
2292 =============
2293 */
2294 void ShowRespawnCountdown()
2295 {
2296         float number;
2297         if(self.deadflag == DEAD_NO) // just respawned?
2298                 return;
2299         else
2300         {
2301                 number = ceil(self.respawn_time - time);
2302                 if(number <= 0)
2303                         return;
2304                 if(number <= self.respawn_countdown)
2305                 {
2306                         self.respawn_countdown = number - 1;
2307                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2308                                 AnnounceTo(self, strcat(ftos(number), ""));
2309                 }
2310         }
2311 }
2312
2313 .float prevent_join_msgtime;
2314 void LeaveSpectatorMode()
2315 {
2316         if(nJoinAllowed(self)) {
2317                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2318                         self.classname = "player";
2319
2320                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2321                                 JoinBestTeam(self, FALSE, TRUE);
2322
2323                         if(autocvar_g_campaign)
2324                                 campaign_bots_may_start = 1;
2325
2326                         PutClientInServer();
2327
2328                         if(self.classname == "player")
2329                                 bprint ("^4", self.netname, "^4 is playing now\n");
2330
2331                         if(!autocvar_g_campaign)
2332                         if (time < self.jointime + autocvar_welcome_message_time)
2333                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2334
2335                         if (self.prevent_join_msgtime)
2336                         {
2337                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2338                                 self.prevent_join_msgtime = 0;
2339                         }
2340
2341                         return;
2342                 } else {
2343                         if (g_ca && self.caplayer) {
2344                         }       // do nothing
2345                         else
2346                                 stuffcmd(self,"menu_showteamselect\n");
2347                         return;
2348                 }
2349         }
2350         else {
2351                 //player may not join because of g_maxplayers is set
2352                 if (time - self.prevent_join_msgtime > 2)
2353                 {
2354                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2355                         self.prevent_join_msgtime = time;
2356                 }
2357         }
2358 }
2359
2360 /**
2361  * Determines whether the player is allowed to join. This depends on cvar
2362  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2363  * it checks whether the number of currently playing players exceeds g_maxplayers.
2364  * @return int number of free slots for players, 0 if none
2365  */
2366 float nJoinAllowed(entity ignore) {
2367         if(!ignore)
2368         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2369         // so report 0 free slots if restricted
2370         {
2371                 if(autocvar_g_forced_team_otherwise == "spectate")
2372                         return 0;
2373                 if(autocvar_g_forced_team_otherwise == "spectator")
2374                         return 0;
2375         }
2376
2377         if(self.team_forced < 0)
2378                 return 0; // forced spectators can never join
2379
2380         // TODO simplify this
2381         entity e;
2382         float totalClients;
2383         FOR_EACH_CLIENT(e)
2384                 if(e != ignore)
2385                         totalClients += 1;
2386
2387         if (!autocvar_g_maxplayers)
2388                 return maxclients - totalClients;
2389
2390         float currentlyPlaying;
2391         FOR_EACH_REALPLAYER(e)
2392                 currentlyPlaying += 1;
2393
2394         if(currentlyPlaying < autocvar_g_maxplayers)
2395                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2396
2397         return 0;
2398 }
2399
2400 /**
2401  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2402  * g_maxplayers_spectator_blocktime seconds
2403  */
2404 void checkSpectatorBlock() {
2405         if(self.classname == "spectator" || self.classname == "observer") {
2406                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2407                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2408                         dropclient(self);
2409                 }
2410         }
2411 }
2412
2413 .float motd_actived_time; // used for both motd and campaign_message
2414 void PrintWelcomeMessage()
2415 {
2416         if (self.motd_actived_time == 0) { // is there already a message showing?
2417                 if (autocvar_g_campaign) {
2418                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2419                                 self.motd_actived_time = time;
2420                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2421                         }
2422                 } else {
2423                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2424                                 self.motd_actived_time = time;
2425                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2426                         }
2427                 }
2428         } else { // showing MOTD or campaign message
2429                 if (autocvar_g_campaign) {
2430                         if (self.BUTTON_INFO)
2431                                 self.motd_actived_time = time;
2432                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2433                                 self.motd_actived_time = 0;
2434                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2435                         }
2436                 } else {
2437                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2438                                 if (self.BUTTON_INFO)
2439                                         self.motd_actived_time = time;
2440                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2441                                         self.motd_actived_time = 0;
2442                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2443                                 }
2444                         }
2445                 }
2446         }
2447 }
2448
2449 void ObserverThink()
2450 {
2451         float prefered_movetype;
2452         if (self.flags & FL_JUMPRELEASED) {
2453                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2454                         self.flags &~= FL_JUMPRELEASED;
2455                         self.flags |= FL_SPAWNING;
2456                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2457                         self.flags &~= FL_JUMPRELEASED;
2458                         if(SpectateNext() == 1) {
2459                                 self.classname = "spectator";
2460                         }
2461                 } else {
2462                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2463                         if (self.movetype != prefered_movetype)
2464                                 self.movetype = prefered_movetype;
2465                 }
2466         } else {
2467                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2468                         self.flags |= FL_JUMPRELEASED;
2469                         if(self.flags & FL_SPAWNING)
2470                         {
2471                                 self.flags &~= FL_SPAWNING;
2472                                 LeaveSpectatorMode();
2473                                 return;
2474                         }
2475                 }
2476         }
2477
2478         PrintWelcomeMessage();
2479 }
2480
2481 void SpectatorThink()
2482 {
2483         if (self.flags & FL_JUMPRELEASED) {
2484                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2485                         self.flags &~= FL_JUMPRELEASED;
2486                         self.flags |= FL_SPAWNING;
2487                 } else if(self.BUTTON_ATCK) {
2488                         self.flags &~= FL_JUMPRELEASED;
2489                         if(SpectateNext() == 1) {
2490                                 self.classname = "spectator";
2491                         } else {
2492                                 self.classname = "observer";
2493                                 PutClientInServer();
2494                         }
2495                 } else if (self.BUTTON_ATCK2) {
2496                         self.flags &~= FL_JUMPRELEASED;
2497                         self.classname = "observer";
2498                         PutClientInServer();
2499                 } else {
2500                         if(!SpectateUpdate())
2501                                 PutObserverInServer();
2502                 }
2503         } else {
2504                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2505                         self.flags |= FL_JUMPRELEASED;
2506                         if(self.flags & FL_SPAWNING)
2507                         {
2508                                 self.flags &~= FL_SPAWNING;
2509                                 LeaveSpectatorMode();
2510                                 return;
2511                         }
2512                 }
2513                 if(!SpectateUpdate())
2514                         PutObserverInServer();
2515         }
2516
2517         PrintWelcomeMessage();
2518         self.flags |= FL_CLIENT | FL_NOTARGET;
2519 }
2520
2521 float ctf_usekey();
2522 void PlayerUseKey()
2523 {
2524         if(self.classname != "player")
2525                 return;
2526
2527         if(self.vehicle)
2528         {
2529         vehicles_exit(VHEF_NORMAL);
2530         return;
2531         }
2532
2533         // a use key was pressed; call handlers
2534         if(ctf_usekey())
2535                 return;
2536
2537         MUTATOR_CALLHOOK(PlayerUseKey);
2538 }
2539
2540 .float touchexplode_time;
2541
2542 /*
2543 =============
2544 PlayerPreThink
2545
2546 Called every frame for each client before the physics are run
2547 =============
2548 */
2549 .float usekeypressed;
2550 void() ctf_setstatus;
2551 void() nexball_setstatus;
2552 .float items_added;
2553 void PlayerPreThink (void)
2554 {
2555         WarpZone_PlayerPhysics_FixVAngle();
2556
2557         self.stat_game_starttime = game_starttime;
2558         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2559         self.stat_leadlimit = autocvar_leadlimit;
2560
2561         if(frametime)
2562         {
2563                 // physics frames: update anticheat stuff
2564                 anticheat_prethink();
2565         }
2566
2567         if(blockSpectators && frametime)
2568                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2569                 checkSpectatorBlock();
2570
2571         zoomstate_set = 0;
2572
2573         if(self.netname_previous != self.netname)
2574         {
2575                 if(autocvar_sv_eventlog)
2576                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2577                 if(self.netname_previous)
2578                         strunzone(self.netname_previous);
2579                 self.netname_previous = strzone(self.netname);
2580         }
2581
2582         // version nagging
2583         if(self.version_nagtime)
2584                 if(self.cvar_g_xonoticversion)
2585                         if(time > self.version_nagtime)
2586                         {
2587                                 // don't notify git users
2588                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2589                                 {
2590                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2591                                         {
2592                                                 // notify release users if connecting to git
2593                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2594                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2595                                         }
2596                                         else
2597                                         {
2598                                                 float r;
2599                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2600                                                 if(r < 0)
2601                                                 {
2602                                                         // give users new version
2603                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2604                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2605                                                 }
2606                                                 else if(r > 0)
2607                                                 {
2608                                                         // notify users about old server version
2609                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2610                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2611                                                 }
2612                                         }
2613                                 }
2614                                 self.version_nagtime = 0;
2615                         }
2616
2617         // GOD MODE info
2618         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2619         {
2620                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2621                 self.max_armorvalue = 0;
2622         }
2623
2624 #ifdef TETRIS
2625         if (TetrisPreFrame())
2626                 return;
2627 #endif
2628
2629         MUTATOR_CALLHOOK(PlayerPreThink);
2630
2631         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2632         {
2633                 if(self.BUTTON_USE && !self.usekeypressed)
2634                         PlayerUseKey();
2635                 self.usekeypressed = self.BUTTON_USE;
2636         }
2637
2638         PrintWelcomeMessage();
2639
2640         if(self.classname == "player") {
2641 //              if(self.netname == "Wazat")
2642 //                      bprint(self.classname, "\n");
2643
2644                 CheckRules_Player();
2645
2646                 if (intermission_running)
2647                 {
2648                         IntermissionThink ();   // otherwise a button could be missed between
2649                         return;                                 // the think tics
2650                 }
2651
2652                 //don't allow the player to turn around while game is paused!
2653                 if(timeout_status == TIMEOUT_ACTIVE) {
2654                         // FIXME turn this into CSQC stuff
2655                         self.v_angle = self.lastV_angle;
2656                         self.angles = self.lastV_angle;
2657                         self.fixangle = TRUE;
2658                 }
2659
2660                 if(frametime)
2661                 {
2662 #ifndef NO_LEGACY_NETWORKING
2663                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2664 #endif
2665
2666                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2667                         {
2668                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2669                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2670                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2671
2672                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2673                                 {
2674                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2675                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2676                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2677                                 }
2678                         }
2679                         else
2680                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2681
2682                         player_powerups();
2683                 }
2684
2685                 if (g_minstagib)
2686                         minstagib_ammocheck();
2687
2688                 if (self.deadflag != DEAD_NO)
2689                 {
2690                         float button_pressed, force_respawn;
2691                         if(self.personal && g_race_qualifying)
2692                         {
2693                                 if(time > self.respawn_time)
2694                                 {
2695                                         self.respawn_time = time + 1; // only retry once a second
2696                                         respawn();
2697                                         self.impulse = 141;
2698                                 }
2699                         }
2700                         else
2701                         {
2702                                 if(frametime)
2703                                         player_anim();
2704                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2705                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2706                                 if (self.deadflag == DEAD_DYING)
2707                                 {
2708                                         if(force_respawn)
2709                                                 self.deadflag = DEAD_RESPAWNING;
2710                                         else if(!button_pressed)
2711                                                 self.deadflag = DEAD_DEAD;
2712                                 }
2713                                 else if (self.deadflag == DEAD_DEAD)
2714                                 {
2715                                         if(button_pressed)
2716                                                 self.deadflag = DEAD_RESPAWNABLE;
2717                                 }
2718                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2719                                 {
2720                                         if(!button_pressed)
2721                                                 self.deadflag = DEAD_RESPAWNING;
2722                                 }
2723                                 else if (self.deadflag == DEAD_RESPAWNING)
2724                                 {
2725                                         if(time > self.respawn_time)
2726                                         {
2727                                                 self.respawn_time = time + 1; // only retry once a second
2728                                                 respawn();
2729                                         }
2730                                 }
2731                                 ShowRespawnCountdown();
2732                         }
2733                         return;
2734                 }
2735                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2736                 // so (self.deadflag == DEAD_NO) is always true in the code below
2737
2738                 if(g_touchexplode)
2739                 if(time > self.touchexplode_time)
2740                 if(self.classname == "player")
2741                 if(self.deadflag == DEAD_NO)
2742                 if not(IS_INDEPENDENT_PLAYER(self))
2743                 FOR_EACH_PLAYER(other) if(self != other)
2744                 {
2745                         if(time > other.touchexplode_time)
2746                         if(other.deadflag == DEAD_NO)
2747                         if not(IS_INDEPENDENT_PLAYER(other))
2748                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2749                         {
2750                                 PlayerTouchExplode(self, other);
2751                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2752                         }
2753                 }
2754
2755                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2756                 {
2757                         vector dist;
2758
2759                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2760                         dist = self.prevorigin - self.origin;
2761                         dist_z = 0;
2762                         self.lms_traveled_distance += fabs(vlen(dist));
2763
2764                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2765                         {
2766                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2767                                 self.lms_traveled_distance = 0;
2768                         }
2769
2770                         if(time > self.lms_nextcheck)
2771                         {
2772                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2773                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2774                                 {
2775                                         centerprint(self, autocvar_g_lms_campcheck_message);
2776                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2777                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2778                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2779                                 }
2780                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2781                                 self.lms_traveled_distance = 0;
2782                         }
2783                 }
2784
2785                 self.prevorigin = self.origin;
2786
2787                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && !self.freezetag_frozen && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2788                 {
2789                         if (!self.crouch)
2790                         {
2791                                 self.crouch = TRUE;
2792                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2793                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2794                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2795                         }
2796                 }
2797                 else
2798                 {
2799                         if (self.crouch)
2800                         {
2801                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2802                                 if (!trace_startsolid)
2803                                 {
2804                                         self.crouch = FALSE;
2805                                         self.view_ofs = PL_VIEW_OFS;
2806                                         setsize (self, PL_MIN, PL_MAX);
2807                                 }
2808                         }
2809                 }
2810
2811                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2812                 {
2813                         if(self.bloodloss_timer < time)
2814                         {
2815                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2816                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2817                         }
2818                 }
2819
2820                 FixPlayermodel();
2821
2822                 GrapplingHookFrame();
2823
2824                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2825                 //if(frametime)
2826                 {
2827                         self.items &~= self.items_added;
2828
2829                         W_WeaponFrame();
2830
2831                         self.items_added = 0;
2832                         if(self.items & IT_JETPACK)
2833                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2834                                         self.items_added |= IT_FUEL;
2835
2836                         self.items |= self.items_added;
2837                 }
2838
2839                 player_regen();
2840
2841                 // rot nex charge to the charge limit
2842                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2843                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2844
2845                 if(frametime)
2846                         player_anim();
2847
2848                 if(g_ctf)
2849                         ctf_setstatus();
2850
2851                 if(g_nexball)
2852                         nexball_setstatus();
2853
2854                 // secret status
2855                 secrets_setstatus();
2856
2857                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2858
2859                 //self.angles_y=self.v_angle_y + 90;   // temp
2860         } else if(gameover) {
2861                 if (intermission_running)
2862                         IntermissionThink ();   // otherwise a button could be missed between
2863                 return;
2864         } else if(self.classname == "observer") {
2865                 ObserverThink();
2866         } else if(self.classname == "spectator") {
2867                 SpectatorThink();
2868         }
2869
2870         if(!zoomstate_set)
2871                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2872
2873         float oldspectatee_status;
2874         oldspectatee_status = self.spectatee_status;
2875         if(self.classname == "spectator")
2876                 self.spectatee_status = num_for_edict(self.enemy);
2877         else if(self.classname == "observer")
2878                 self.spectatee_status = num_for_edict(self);
2879         else
2880                 self.spectatee_status = 0;
2881         if(self.spectatee_status != oldspectatee_status)
2882         {
2883                 ClientData_Touch(self);
2884                 if(g_race || g_cts)
2885                         race_InitSpectator();
2886         }
2887
2888         if(self.teamkill_soundtime)
2889         if(time > self.teamkill_soundtime)
2890         {
2891                 self.teamkill_soundtime = 0;
2892
2893                 entity oldpusher, oldself;
2894
2895                 oldself = self; self = self.teamkill_soundsource;
2896                 oldpusher = self.pusher; self.pusher = oldself;
2897
2898                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2899
2900                 self.pusher = oldpusher;
2901                 self = oldself;
2902         }
2903
2904         if(self.taunt_soundtime)
2905         if(time > self.taunt_soundtime)
2906         {
2907                 self.taunt_soundtime = 0;
2908                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2909         }
2910
2911         target_voicescript_next(self);
2912
2913         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2914         if(!self.weapon)
2915                 self.clip_load = self.clip_size = 0;
2916 }
2917
2918 float isInvisibleString(string s)
2919 {
2920         float i, n, c;
2921         s = strdecolorize(s);
2922         for((i = 0), (n = strlen(s)); i < n; ++i)
2923         {
2924                 c = str2chr(s, i);
2925                 switch(c)
2926                 {
2927                         case 0:
2928                         case 32: // space
2929                                 break;
2930                         case 192: // charmap space
2931                                 if (!autocvar_utf8_enable)
2932                                         break;
2933                                 return FALSE;
2934                         case 160: // space in unicode fonts
2935                         case 0xE000 + 192: // utf8 charmap space
2936                                 if (autocvar_utf8_enable)
2937                                         break;
2938                         default:
2939                                 return FALSE;
2940                 }
2941         }
2942         return TRUE;
2943 }
2944
2945 /*
2946 =============
2947 PlayerPostThink
2948
2949 Called every frame for each client after the physics are run
2950 =============
2951 */
2952 .float idlekick_lasttimeleft;
2953 .entity showheadshotbbox;
2954 void showheadshotbbox_think()
2955 {
2956         if(self.owner.showheadshotbbox != self)
2957         {
2958                 remove(self);
2959                 return;
2960         }
2961         self.nextthink = time;
2962         setorigin(self, self.owner.origin);
2963         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2964 }
2965 void PlayerPostThink (void)
2966 {
2967         // Savage: Check for nameless players
2968         if (isInvisibleString(self.netname)) {
2969                 self.netname = "Player";
2970                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2971         }
2972
2973         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2974         {
2975                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2976                 {
2977                         if(self.idlekick_lasttimeleft)
2978                         {
2979                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2980                                 self.idlekick_lasttimeleft = 0;
2981                         }
2982                 }
2983                 else
2984                 {
2985                         float timeleft;
2986                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2987                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2988                         {
2989                                 if(!self.idlekick_lasttimeleft)
2990                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2991                         }
2992                         if(timeleft <= 0)
2993                         {
2994                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2995                                 AnnounceTo(self, "terminated");
2996                                 dropclient(self);
2997                                 return;
2998                         }
2999                         else if(timeleft <= 10)
3000                         {
3001                                 if(timeleft != self.idlekick_lasttimeleft)
3002                                         AnnounceTo(self, ftos(timeleft));
3003                                 self.idlekick_lasttimeleft = timeleft;
3004                         }
3005                 }
3006         }
3007
3008 #ifdef TETRIS
3009         if(self.impulse == 100)
3010                 ImpulseCommands();
3011         if (!TetrisPostFrame())
3012         {
3013 #endif
3014
3015         CheatFrame();
3016
3017         //CheckPlayerJump();
3018
3019         if(self.classname == "player") {
3020                 CheckRules_Player();
3021                 UpdateChatBubble();
3022                 if (self.impulse)
3023                         ImpulseCommands();
3024                 if (intermission_running)
3025                         return;         // intermission or finale
3026                 GetPressedKeys();
3027         } else if (self.classname == "observer") {
3028                 //do nothing
3029         } else if (self.classname == "spectator") {
3030                 //do nothing
3031         }
3032
3033 #ifdef TETRIS
3034         }
3035 #endif
3036
3037         /*
3038         float i;
3039         for(i = 0; i < 1000; ++i)
3040         {
3041                 vector end;
3042                 end = self.origin + '0 0 1024' + 512 * randomvec();
3043                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3044                 if(trace_fraction < 1)
3045                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3046                 {
3047                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3048                         break;
3049                 }
3050         }
3051         */
3052
3053         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3054
3055         if(self.waypointsprite_attachedforcarrier)
3056                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3057
3058         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3059         {
3060                 if(!self.showheadshotbbox)
3061                 {
3062                         self.showheadshotbbox = spawn();
3063                         self.showheadshotbbox.classname = "headshotbbox";
3064                         self.showheadshotbbox.owner = self;
3065                         self.showheadshotbbox.think = showheadshotbbox_think;
3066                         self.showheadshotbbox.nextthink = time;
3067                         self = self.showheadshotbbox;
3068                         self.think();
3069                         self = self.owner;
3070                 }
3071         }
3072         else
3073         {
3074                 if(self.showheadshotbbox)
3075                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3076                 remove(self.showheadshotbbox);
3077         }
3078
3079         playerdemo_write();
3080
3081         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3082         {
3083                 if(!self.stored_netname)
3084                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3085                 if(self.stored_netname != self.netname)
3086                 {
3087                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3088                         strunzone(self.stored_netname);
3089                         self.stored_netname = strzone(self.netname);
3090                 }
3091         }
3092
3093         /*
3094         if(g_race)
3095                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3096         */
3097
3098         CSQCMODEL_AUTOUPDATE();
3099 }