qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         float teamcheck;
 321         entity firstspot_new;
 322         entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         if (g_minstagib)
 618                 minstagib_stop_countdown();
 619
 620         Portal_ClearAll(self);
 621
 622         if(self.alivetime)
 623         {
 624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                 self.alivetime = 0;
 626         }
 627
 628         if(self.vehicle)
 629             vehicles_exit(VHEF_RELESE);
 630
 631         if(self.flagcarried)
 632                 DropFlag(self.flagcarried, world, world);
 633
 634         if(self.ballcarried && g_nexball)
 635                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 636
 637         WaypointSprite_PlayerDead();
 638
 639         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 640                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 641
 642         if(self.killcount != -666) {
 643                 if(g_lms) {
 644                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 645                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 646                         else
 647                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 648                 } else
 649                         bprint ("^4", self.netname, "^4 is spectating now\n");
 650
 651                 if(self.just_joined == FALSE) {
 652                         LogTeamchange(self.playerid, -1, 4);
 653                 } else
 654                         self.just_joined = FALSE;
 655         }
 656
 657         PlayerScore_Clear(self); // clear scores when needed
 658
 659         accuracy_resend(self);
 660
 661         self.spectatortime = time;
 662
 663         self.classname = "observer";
 664         self.iscreature = FALSE;
 665         self.damagedbycontents = FALSE;
 666         self.health = -666;
 667         self.takedamage = DAMAGE_NO;
 668         self.solid = SOLID_NOT;
 669         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 670         self.flags = FL_CLIENT | FL_NOTARGET;
 671         self.armorvalue = 666;
 672         self.effects = 0;
 673         self.armorvalue = autocvar_g_balance_armor_start;
 674         self.pauserotarmor_finished = 0;
 675         self.pauserothealth_finished = 0;
 676         self.pauseregen_finished = 0;
 677         self.damageforcescale = 0;
 678         self.death_time = 0;
 679         self.dead_frame = 0;
 680         self.alpha = 0;
 681         self.scale = 0;
 682         self.fade_time = 0;
 683         self.pain_frame = 0;
 684         self.pain_finished = 0;
 685         self.strength_finished = 0;
 686         self.invincible_finished = 0;
 687         self.pushltime = 0;
 688         self.think = SUB_Null;
 689         self.nextthink = 0;
 690         self.hook_time = 0;
 691         self.runes = 0;
 692         self.deadflag = DEAD_NO;
 693         self.angles = spot.angles;
 694         self.angles_z = 0;
 695         self.fixangle = TRUE;
 696         self.crouch = FALSE;
 697
 698         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 699         setorigin (self, spot.origin);
 700         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 701         self.prevorigin = self.origin;
 702         self.items = 0;
 703         self.weapons = 0;
 704         self.model = "";
 705         FixPlayermodel();
 706         self.model = "";
 707         self.modelindex = 0;
 708         self.weapon = 0;
 709         self.weaponname = "";
 710         self.switchingweapon = 0;
 711         self.weaponmodel = "";
 712         self.weaponentity = world;
 713         self.exteriorweaponentity = world;
 714         self.killcount = -666;
 715         self.velocity = '0 0 0';
 716         self.avelocity = '0 0 0';
 717         self.punchangle = '0 0 0';
 718         self.punchvector = '0 0 0';
 719         self.oldvelocity = self.velocity;
 720         self.fire_endtime = -1;
 721
 722         if(sv_loddistance1)
 723                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 724
 725         if(g_arena)
 726         {
 727                 if(self.version_mismatch)
 728                 {
 729                         Spawnqueue_Unmark(self);
 730                         Spawnqueue_Remove(self);
 731                 }
 732                 else
 733                 {
 734                         Spawnqueue_Insert(self);
 735                 }
 736         }
 737         else if(g_lms)
 738         {
 739                 // Only if the player cannot play at all
 740                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 741                         self.frags = FRAGS_SPECTATOR;
 742                 else
 743                         self.frags = FRAGS_LMS_LOSER;
 744         }
 745         else if(g_ca)
 746         {
 747                 if(self.caplayer)
 748                         self.frags = FRAGS_LMS_LOSER;
 749                 else
 750                         self.frags = FRAGS_SPECTATOR;
 751         }
 752         else
 753                 self.frags = FRAGS_SPECTATOR;
 754 }
 755
 756 void FixPlayermodel()
 757 {
 758         string defaultmodel;
 759         float defaultskin, chmdl, oldskin;
 760         vector m1, m2;
 761
 762         defaultmodel = "";
 763
 764         if(autocvar_sv_defaultcharacter == 1) {
 765                 defaultskin = 0;
 766
 767                 if(teamplay)
 768                 {
 769                         string s;
 770                         s = Team_ColorNameLowerCase(self.team);
 771                         if(s != "neutral")
 772                         {
 773                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 774                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 775                         }
 776                 }
 777
 778                 if(defaultmodel == "")
 779                 {
 780                         defaultmodel = autocvar_sv_defaultplayermodel;
 781                         defaultskin = autocvar_sv_defaultplayerskin;
 782                 }
 783         }
 784
 785         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 786         {
 787                 if(self.model != "")
 788                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 789                 self.model = ""; // force the != checks to return true
 790         }
 791
 792         if(defaultmodel != "")
 793         {
 794                 if (defaultmodel != self.model)
 795                 {
 796                         m1 = self.mins;
 797                         m2 = self.maxs;
 798                         setmodel_lod (self, defaultmodel);
 799                         setsize (self, m1, m2);
 800                         chmdl = TRUE;
 801                 }
 802
 803                 oldskin = self.skinindex;
 804                 self.skinindex = defaultskin;
 805         } else {
 806                 if (self.playermodel != self.model || self.playermodel == "")
 807                 {
 808                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 809                         m1 = self.mins;
 810                         m2 = self.maxs;
 811                         setmodel_lod (self, self.playermodel);
 812                         setsize (self, m1, m2);
 813                         chmdl = TRUE;
 814                 }
 815
 816                 oldskin = self.skinindex;
 817                 self.skinindex = stof(self.playerskin);
 818         }
 819
 820         if(chmdl || oldskin != self.skinindex)
 821                 self.species = player_getspecies(); // model or skin has changed
 822
 823         if(!teamplay)
 824                 if(strlen(autocvar_sv_defaultplayercolors))
 825                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 826                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 827 }
 828
 829 void PlayerTouchExplode(entity p1, entity p2)
 830 {
 831         vector org;
 832         org = (p1.origin + p2.origin) * 0.5;
 833         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 834
 835         te_explosion(org);
 836
 837         entity e;
 838         e = spawn();
 839         setorigin(e, org);
 840         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 841         remove(e);
 842 }
 843
 844 /*
 845 =============
 846 PutClientInServer
 847
 848 Called when a client spawns in the server
 849 =============
 850 */
 851 //void() ctf_playerchanged;
 852 void PutClientInServer (void)
 853 {
 854         if(clienttype(self) == CLIENTTYPE_BOT)
 855         {
 856                 self.classname = "player";
 857         }
 858         else if(clienttype(self) == CLIENTTYPE_REAL)
 859         {
 860                 msg_entity = self;
 861                 WriteByte(MSG_ONE, SVC_SETVIEW);
 862                 WriteEntity(MSG_ONE, self);
 863         }
 864
 865         // reset player keys
 866         self.itemkeys = 0;
 867
 868         // player is dead and becomes observer
 869         // FIXME fix LMS scoring for new system
 870         if(g_lms)
 871         {
 872                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 873                         self.classname = "observer";
 874         }
 875
 876         if(g_arena || (g_ca && !allowed_to_spawn))
 877         if(!self.spawned)
 878                 self.classname = "observer";
 879
 880         if(gameover)
 881                 self.classname = "observer";
 882
 883         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 884                 entity spot, oldself;
 885                 float j;
 886
 887                 accuracy_resend(self);
 888
 889                 if(self.team < 0)
 890                         JoinBestTeam(self, FALSE, TRUE);
 891
 892                 race_PreSpawn();
 893
 894                 spot = SelectSpawnPoint (FALSE);
 895                 if(!spot)
 896                 {
 897                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 898                         return; // spawn failed
 899                 }
 900
 901                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 902
 903                 self.classname = "player";
 904                 self.wasplayer = TRUE;
 905                 self.iscreature = TRUE;
 906                 self.damagedbycontents = TRUE;
 907                 self.movetype = MOVETYPE_WALK;
 908                 self.solid = SOLID_SLIDEBOX;
 909                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 910                 if(autocvar_g_playerclip_collisions)
 911                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 912                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 913                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 914                 self.frags = FRAGS_PLAYER;
 915                 if(INDEPENDENT_PLAYERS)
 916                         MAKE_INDEPENDENT_PLAYER(self);
 917                 self.flags = FL_CLIENT;
 918                 self.takedamage = DAMAGE_AIM;
 919                 if(g_minstagib)
 920                         self.effects = EF_FULLBRIGHT;
 921                 else
 922                         self.effects = 0;
 923                 self.air_finished = time + 12;
 924                 self.dmg = 2;
 925                 if(autocvar_g_balance_nex_charge)
 926                 {
 927                         if(autocvar_g_balance_nex_secondary_chargepool)
 928                                 self.nex_chargepool_ammo = 1;
 929                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 930                 }
 931
 932                 if(inWarmupStage)
 933                 {
 934                         self.ammo_shells = warmup_start_ammo_shells;
 935                         self.ammo_nails = warmup_start_ammo_nails;
 936                         self.ammo_rockets = warmup_start_ammo_rockets;
 937                         self.ammo_cells = warmup_start_ammo_cells;
 938                         self.ammo_fuel = warmup_start_ammo_fuel;
 939                         self.health = warmup_start_health;
 940                         self.armorvalue = warmup_start_armorvalue;
 941                         self.weapons = warmup_start_weapons;
 942                 }
 943                 else
 944                 {
 945                         self.ammo_shells = start_ammo_shells;
 946                         self.ammo_nails = start_ammo_nails;
 947                         self.ammo_rockets = start_ammo_rockets;
 948                         self.ammo_cells = start_ammo_cells;
 949                         self.ammo_fuel = start_ammo_fuel;
 950                         self.health = start_health;
 951                         self.armorvalue = start_armorvalue;
 952                         self.weapons = start_weapons;
 953                 }
 954
 955                 if(g_weaponarena_random)
 956                 {
 957                         if(g_weaponarena_random_with_laser)
 958                                 self.weapons &~= WEPBIT_LASER;
 959                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 960                         if(g_weaponarena_random_with_laser)
 961                                 self.weapons |= WEPBIT_LASER;
 962                 }
 963
 964                 self.items = start_items;
 965                 self.jump_interval = time;
 966
 967                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 968                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 969                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 970                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 971                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 972                 //extend the pause of rotting if client was reset at the beginning of the countdown
 973                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 974                         self.spawnshieldtime += game_starttime - time;
 975                         self.pauserotarmor_finished += game_starttime - time;
 976                         self.pauserothealth_finished += game_starttime - time;
 977                         self.pauseregen_finished += game_starttime - time;
 978                 }
 979                 self.damageforcescale = 2;
 980                 self.death_time = 0;
 981                 self.dead_frame = 0;
 982                 self.alpha = 0;
 983                 self.scale = 0;
 984                 self.fade_time = 0;
 985                 self.pain_frame = 0;
 986                 self.pain_finished = 0;
 987                 self.strength_finished = 0;
 988                 self.invincible_finished = 0;
 989                 self.pushltime = 0;
 990                 // players have no think function
 991                 self.think = SUB_Null;
 992                 self.nextthink = 0;
 993                 self.hook_time = 0;
 994                 self.dmg_team = 0;
 995                 self.ballistics_density = autocvar_g_ballistics_density_player;
 996
 997                 self.metertime = 0;
 998
 999                 self.runes = 0;
1000
1001                 self.deadflag = DEAD_NO;
1002
1003                 self.angles = spot.angles;
1004
1005                 self.angles_z = 0; // never spawn tilted even if the spot says to
1006                 self.fixangle = TRUE; // turn this way immediately
1007                 self.velocity = '0 0 0';
1008                 self.avelocity = '0 0 0';
1009                 self.punchangle = '0 0 0';
1010                 self.punchvector = '0 0 0';
1011                 self.oldvelocity = self.velocity;
1012                 self.fire_endtime = -1;
1013
1014                 msg_entity = self;
1015                 WRITESPECTATABLE_MSG_ONE({
1016                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1017                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1018                 });
1019
1020                 if(sv_loddistance1)
1021                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1022
1023                 self.model = "";
1024                 FixPlayermodel();
1025
1026                 self.crouch = FALSE;
1027                 self.view_ofs = PL_VIEW_OFS;
1028                 setsize (self, PL_MIN, PL_MAX);
1029                 self.spawnorigin = spot.origin;
1030                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1031                 // don't reset back to last position, even if new position is stuck in solid
1032                 self.oldorigin = self.origin;
1033                 self.prevorigin = self.origin;
1034                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1035                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1036         self.hud = HUD_NORMAL;
1037
1038                 if(g_arena)
1039                 {
1040                         Spawnqueue_Remove(self);
1041                         Spawnqueue_Mark(self);
1042                 }
1043
1044                 else if(g_ca)
1045                         self.caplayer = 1;
1046
1047                 self.event_damage = PlayerDamage;
1048
1049                 self.bot_attack = TRUE;
1050
1051                 self.statdraintime = time + 5;
1052                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1053
1054                 if(self.killcount == -666) {
1055                         PlayerScore_Clear(self);
1056                         self.killcount = 0;
1057                 }
1058
1059                 CL_SpawnWeaponentity();
1060                 self.alpha = default_player_alpha;
1061                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1062                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1063
1064                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1065                 self.lms_traveled_distance = 0;
1066                 self.speedrunning = FALSE;
1067
1068                 race_PostSpawn(spot);
1069
1070                 if(autocvar_spawn_debug)
1071                 {
1072                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1073                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1074                 }
1075
1076                 //stuffcmd(self, "chase_active 0");
1077                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1078
1079                 if (autocvar_g_spawnsound)
1080                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1081
1082                 if(g_assault) {
1083                         if(self.team == assault_attacker_team)
1084                                 centerprint(self, "You are attacking!");
1085                         else
1086                                 centerprint(self, "You are defending!");
1087                 }
1088
1089                 target_voicescript_clear(self);
1090
1091                 // reset fields the weapons may use
1092                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1093                 {
1094                         weapon_action(j, WR_RESETPLAYER);
1095
1096                         // all weapons must be fully loaded when we spawn
1097                         entity e;
1098                         e = get_weaponinfo(j);
1099                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1100                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1101                 }
1102
1103                 oldself = self;
1104                 self = spot;
1105                         activator = oldself;
1106                                 string s;
1107                                 s = self.target;
1108                                 self.target = string_null;
1109                                 SUB_UseTargets();
1110                                 self.target = s;
1111                         activator = world;
1112                 self = oldself;
1113
1114                 MUTATOR_CALLHOOK(PlayerSpawn);
1115
1116                 self.switchweapon = w_getbestweapon(self);
1117                 self.cnt = -1; // W_LastWeapon will not complain
1118                 self.weapon = 0;
1119                 self.weaponname = "";
1120                 self.switchingweapon = 0;
1121
1122                 if(!self.alivetime)
1123                         self.alivetime = time;
1124         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1125                 PutObserverInServer ();
1126         }
1127
1128         //if(g_ctf)
1129         //      ctf_playerchanged();
1130 }
1131
1132 .float ebouncefactor, ebouncestop; // electro's values
1133 // TODO do we need all these fields, or should we stop autodetecting runtime
1134 // changes and just have a console command to update this?
1135 float ClientInit_SendEntity(entity to, float sf)
1136 {
1137         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1138         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1139         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1140         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1141         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1142         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1143         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1144         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1145         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1146         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1147         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1148         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1149         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1150         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1151         if(sv_foginterval && world.fog != "")
1152                 WriteString(MSG_ENTITY, world.fog);
1153         else
1154                 WriteString(MSG_ENTITY, "");
1155         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1156         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1157         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1158         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1159         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1160         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1161         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1162         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1163         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1164         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1165         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1166         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1167         return TRUE;
1168 }
1169
1170 void ClientInit_CheckUpdate()
1171 {
1172         self.nextthink = time;
1173         if(self.count != autocvar_g_balance_armor_blockpercent)
1174         {
1175                 self.count = autocvar_g_balance_armor_blockpercent;
1176                 self.SendFlags |= 1;
1177         }
1178         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1179         {
1180                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1181                 self.SendFlags |= 1;
1182         }
1183         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1184         {
1185                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1186                 self.SendFlags |= 1;
1187         }
1188         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1189         {
1190                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1191                 self.SendFlags |= 1;
1192         }
1193         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1194         {
1195                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1196                 self.SendFlags |= 1;
1197         }
1198         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1199         {
1200                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1201                 self.SendFlags |= 1;
1202         }
1203 }
1204
1205 void ClientInit_Spawn()
1206 {
1207         entity o;
1208         entity e;
1209         e = spawn();
1210         e.classname = "clientinit";
1211         e.think = ClientInit_CheckUpdate;
1212         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1213
1214         o = self;
1215         self = e;
1216         ClientInit_CheckUpdate();
1217         self = o;
1218 }
1219
1220 /*
1221 =============
1222 SetNewParms
1223 =============
1224 */
1225 void SetNewParms (void)
1226 {
1227         // initialize parms for a new player
1228         parm1 = -(86400 * 366);
1229 }
1230
1231 /*
1232 =============
1233 SetChangeParms
1234 =============
1235 */
1236 void SetChangeParms (void)
1237 {
1238         // save parms for level change
1239         parm1 = self.parm_idlesince - time;
1240 }
1241
1242 /*
1243 =============
1244 DecodeLevelParms
1245 =============
1246 */
1247 void DecodeLevelParms (void)
1248 {
1249         // load parms
1250         self.parm_idlesince = parm1;
1251         if(self.parm_idlesince == -(86400 * 366))
1252                 self.parm_idlesince = time;
1253
1254         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1255         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1256 }
1257
1258 /*
1259 =============
1260 ClientKill
1261
1262 Called when a client types 'kill' in the console
1263 =============
1264 */
1265
1266 .float clientkill_nexttime;
1267 void ClientKill_Now_TeamChange()
1268 {
1269         if(self.killindicator_teamchange == -1)
1270         {
1271                 self.team = -1;
1272                 JoinBestTeam( self, FALSE, FALSE );
1273         }
1274         else if(self.killindicator_teamchange == -2)
1275         {
1276                 if(g_ca)
1277                         self.caplayer = 0;
1278                 if(blockSpectators)
1279                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1280                 PutObserverInServer();
1281         }
1282         else
1283                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1284 }
1285
1286 void ClientKill_Now()
1287 {
1288         if(self.vehicle)
1289         {
1290             vehicles_exit(VHEF_RELESE);
1291             if(!self.killindicator_teamchange)
1292             {
1293             self.vehicle_health = -1;
1294             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1295             }
1296         }
1297
1298         if(self.killindicator && !wasfreed(self.killindicator))
1299                 remove(self.killindicator);
1300
1301         self.killindicator = world;
1302
1303         if(self.killindicator_teamchange)
1304                 ClientKill_Now_TeamChange();
1305
1306         // in any case:
1307         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1308
1309         // now I am sure the player IS dead
1310 }
1311 void KillIndicator_Think()
1312 {
1313         if (gameover)
1314         {
1315                 self.owner.killindicator = world;
1316                 remove(self);
1317                 return;
1318         }
1319
1320         if (!self.owner.modelindex)
1321         {
1322                 self.owner.killindicator = world;
1323                 remove(self);
1324                 return;
1325         }
1326
1327         if(self.cnt <= 0)
1328         {
1329                 self = self.owner;
1330                 ClientKill_Now(); // no oldself needed
1331                 return;
1332         }
1333     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1334     {
1335         self.nextthink = time + 1;
1336         self.cnt -= 1;
1337     }
1338         else
1339         {
1340                 if(self.cnt <= 10)
1341                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1342                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1343                 {
1344                         if(self.cnt <= 10)
1345                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1346                 }
1347                 self.nextthink = time + 1;
1348                 self.cnt -= 1;
1349         }
1350 }
1351
1352 float clientkilltime;
1353 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1354 {
1355         float killtime;
1356         float starttime;
1357         entity e;
1358
1359         if (gameover)
1360                 return;
1361
1362         killtime = autocvar_g_balance_kill_delay;
1363
1364         if(g_race_qualifying || g_cts)
1365                 killtime = 0;
1366
1367     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1368     {
1369                 remove(self.killindicator);
1370                 self.killindicator = world;
1371
1372         ClientKill_Now(); // allow instant kill in this case
1373         return;
1374     }
1375
1376         self.killindicator_teamchange = targetteam;
1377
1378     if(!self.killindicator)
1379         {
1380                 if(self.modelindex && self.deadflag == DEAD_NO)
1381                 {
1382                         killtime = max(killtime, self.clientkill_nexttime - time);
1383                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1384                 }
1385
1386                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1387                 {
1388                         ClientKill_Now();
1389                 }
1390                 else
1391                 {
1392                         starttime = max(time, clientkilltime);
1393
1394                         self.killindicator = spawn();
1395                         self.killindicator.owner = self;
1396                         self.killindicator.scale = 0.5;
1397                         setattachment(self.killindicator, self, "");
1398                         setorigin(self.killindicator, '0 0 52');
1399                         self.killindicator.think = KillIndicator_Think;
1400                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1401                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1402                         self.killindicator.cnt = ceil(killtime);
1403                         self.killindicator.count = bound(0, ceil(killtime), 10);
1404                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1405
1406                         for(e = world; (e = find(e, classname, "body")) != world; )
1407                         {
1408                                 if(e.enemy != self)
1409                                         continue;
1410                                 e.killindicator = spawn();
1411                                 e.killindicator.owner = e;
1412                                 e.killindicator.scale = 0.5;
1413                                 setattachment(e.killindicator, e, "");
1414                                 setorigin(e.killindicator, '0 0 52');
1415                                 e.killindicator.think = KillIndicator_Think;
1416                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1417                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1418                                 e.killindicator.cnt = ceil(killtime);
1419                         }
1420                         self.lip = 0;
1421                 }
1422         }
1423         if(self.killindicator)
1424         {
1425                 if(targetteam == 0) // just die
1426                 {
1427                         self.killindicator.colormod = '0 0 0';
1428                         if(clienttype(self) == CLIENTTYPE_REAL)
1429                         if(self.killindicator.cnt > 0)
1430                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1431                 }
1432                 else if(targetteam == -1) // auto
1433                 {
1434                         self.killindicator.colormod = '0 1 0';
1435                         if(clienttype(self) == CLIENTTYPE_REAL)
1436                         if(self.killindicator.cnt > 0)
1437                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1438                 }
1439                 else if(targetteam == -2) // spectate
1440                 {
1441                         self.killindicator.colormod = '0.5 0.5 0.5';
1442                         if(clienttype(self) == CLIENTTYPE_REAL)
1443                         if(self.killindicator.cnt > 0)
1444                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1445                 }
1446                 else
1447                 {
1448                         self.killindicator.colormod = TeamColor(targetteam);
1449                         if(clienttype(self) == CLIENTTYPE_REAL)
1450                         if(self.killindicator.cnt > 0)
1451                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1452                 }
1453         }
1454
1455 }
1456
1457 void ClientKill (void)
1458 {
1459         if (gameover)
1460                 return;
1461
1462         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1463         {
1464                 // do nothing
1465         }
1466     else if(self.freezetag_frozen)
1467     {
1468         // do nothing
1469     }
1470         else
1471                 ClientKill_TeamChange(0);
1472 }
1473
1474 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1475 {
1476     e.killindicator = spawn();
1477     e.killindicator.owner = e;
1478     e.killindicator.think = KillIndicator_Think;
1479     e.killindicator.nextthink = time + (e.lip) * 0.05;
1480     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1481     e.killindicator.health = 1; // this is used to indicate that it should be silent
1482     e.lip = 0;
1483 }
1484
1485 void FixClientCvars(entity e)
1486 {
1487         // send prediction settings to the client
1488         stuffcmd(e, "\nin_bindmap 0 0\n");
1489         if(g_race || g_cts)
1490                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1491         if(autocvar_g_antilag == 3) // client side hitscan
1492                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1493         if(sv_gentle)
1494                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1495         /*
1496          * we no longer need to stuff this. Remove this comment block if you feel
1497          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1498         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1499         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1500         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1501         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1502         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1503         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1504         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1505         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1506         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1507         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1508         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1509         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1510         stuffcmd(e, "cl_movement_edgefriction 1\n");
1511          */
1512 }
1513
1514 float PlayerInIDList(entity p, string idlist)
1515 {
1516         float n, i;
1517         string s;
1518
1519         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1520         if not(p.crypto_idfp)
1521                 return 0;
1522
1523         // this function allows abbreviated player IDs too!
1524         n = tokenize_console(idlist);
1525         for(i = 0; i < n; ++i)
1526         {
1527                 s = argv(i);
1528                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1529                         return 1;
1530         }
1531
1532         return 0;
1533 }
1534
1535 /*
1536 =============
1537 ClientConnect
1538
1539 Called when a client connects to the server
1540 =============
1541 */
1542 //void ctf_clientconnect();
1543 string ColoredTeamName(float t);
1544 void DecodeLevelParms (void);
1545 //void dom_player_join_team(entity pl);
1546 void set_dom_state(entity e);
1547 void ClientConnect (void)
1548 {
1549         float t;
1550
1551         if(self.flags & FL_CLIENT)
1552         {
1553                 print("Warning: ClientConnect, but already connected!\n");
1554                 return;
1555         }
1556
1557         if(Ban_MaybeEnforceBan(self))
1558                 return;
1559
1560         DecodeLevelParms();
1561
1562 #ifdef WATERMARK
1563         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1564 #endif
1565
1566         self.classname = "player_joining";
1567
1568         self.flags = FL_CLIENT;
1569         self.version_nagtime = time + 10 + random() * 10;
1570
1571         if(player_count<0)
1572         {
1573                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1574                 player_count = 0;
1575         }
1576
1577         PlayerScore_Attach(self);
1578         ClientData_Attach();
1579         accuracy_init(self);
1580
1581         bot_clientconnect();
1582
1583         playerdemo_init();
1584
1585         anticheat_init();
1586
1587         race_PreSpawnObserver();
1588
1589         //if(g_domination)
1590         //      dom_player_join_team(self);
1591
1592         // identify the right forced team
1593         if(autocvar_g_campaign)
1594         {
1595                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1596                 {
1597                         switch(autocvar_g_campaign_forceteam)
1598                         {
1599                                 case 1: self.team_forced = COLOR_TEAM1; break;
1600                                 case 2: self.team_forced = COLOR_TEAM2; break;
1601                                 case 3: self.team_forced = COLOR_TEAM3; break;
1602                                 case 4: self.team_forced = COLOR_TEAM4; break;
1603                                 default: self.team_forced = 0;
1604                         }
1605                 }
1606         }
1607         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1608                 self.team_forced = COLOR_TEAM1;
1609         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1610                 self.team_forced = COLOR_TEAM2;
1611         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1612                 self.team_forced = COLOR_TEAM3;
1613         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1614                 self.team_forced = COLOR_TEAM4;
1615         else if(autocvar_g_forced_team_otherwise == "red")
1616                 self.team_forced = COLOR_TEAM1;
1617         else if(autocvar_g_forced_team_otherwise == "blue")
1618                 self.team_forced = COLOR_TEAM2;
1619         else if(autocvar_g_forced_team_otherwise == "yellow")
1620                 self.team_forced = COLOR_TEAM3;
1621         else if(autocvar_g_forced_team_otherwise == "pink")
1622                 self.team_forced = COLOR_TEAM4;
1623         else if(autocvar_g_forced_team_otherwise == "spectate")
1624                 self.team_forced = -1;
1625         else if(autocvar_g_forced_team_otherwise == "spectator")
1626                 self.team_forced = -1;
1627         else
1628                 self.team_forced = 0;
1629
1630         if(!teamplay)
1631                 if(self.team_forced > 0)
1632                         self.team_forced = 0;
1633
1634         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1635
1636         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1637                 self.classname = "observer";
1638         } else {
1639                 if(teamplay)
1640                 {
1641                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1642                         {
1643                                 self.classname = "player";
1644                                 campaign_bots_may_start = 1;
1645                         }
1646                         else
1647                         {
1648                                 self.classname = "observer"; // do it anyway
1649                         }
1650                 }
1651                 else
1652                 {
1653                         self.classname = "player";
1654                         campaign_bots_may_start = 1;
1655                 }
1656         }
1657
1658         self.playerid = (playerid_last = playerid_last + 1);
1659
1660         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1661
1662     if(clienttype(self) == CLIENTTYPE_BOT)
1663         PlayerStats_AddPlayer(self);
1664
1665         if(autocvar_sv_eventlog)
1666                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1667
1668         LogTeamchange(self.playerid, self.team, 1);
1669
1670         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1671
1672         self.netname_previous = strzone(self.netname);
1673
1674         bprint("^4", self.netname, "^4 connected");
1675
1676         if(self.classname != "observer" && (g_domination || g_ctf))
1677                 bprint(" and joined the ", ColoredTeamName(self.team));
1678
1679         bprint("\n");
1680
1681         stuffcmd(self, strcat(clientstuff, "\n"));
1682         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1683
1684         FixClientCvars(self);
1685
1686         // spawnfunc_waypoint sprites
1687         WaypointSprite_InitClient(self);
1688
1689         // Wazat's grappling hook
1690         SetGrappleHookBindings();
1691
1692         // get autoswitch state from player when he toggles it
1693         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1694
1695         // get version info from player
1696         stuffcmd(self, "cmd clientversion $gameversion\n");
1697
1698         // get other cvars from player
1699         GetCvars(0);
1700
1701         // notify about available teams
1702         if(teamplay)
1703         {
1704                 CheckAllowedTeams(self);
1705                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1706                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1707         }
1708         else
1709                 stuffcmd(self, "set _teams_available 0\n");
1710
1711         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1712
1713         if(g_arena || g_ca)
1714         {
1715                 self.classname = "observer";
1716                 if(g_arena)
1717                         Spawnqueue_Insert(self);
1718         }
1719         /*else if(g_ctf)
1720         {
1721                 ctf_clientconnect();
1722         }*/
1723
1724         attach_entcs();
1725
1726         bot_relinkplayerlist();
1727
1728         self.spectatortime = time;
1729         if(blockSpectators)
1730         {
1731                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1732         }
1733
1734         self.jointime = time;
1735         self.allowedTimeouts = autocvar_sv_timeout_number;
1736
1737         if(clienttype(self) == CLIENTTYPE_REAL)
1738         {
1739                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1740                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1741         }
1742
1743         if(g_lms)
1744         {
1745                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1746                 {
1747                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1748                         self.frags = FRAGS_SPECTATOR;
1749                 }
1750         }
1751
1752         if(!sv_foginterval && world.fog != "")
1753                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1754
1755         SoundEntity_Attach(self);
1756
1757         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1758         {
1759                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1760                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1761         }
1762         else
1763                 self.hitplotfh = -1;
1764
1765         if(g_race || g_cts) {
1766                 string rr;
1767                 if(g_cts)
1768                         rr = CTS_RECORD;
1769                 else
1770                         rr = RACE_RECORD;
1771                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1772
1773                 msg_entity = self;
1774                 race_send_recordtime(MSG_ONE);
1775                 race_send_speedaward(MSG_ONE);
1776
1777                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1778                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1779                 race_send_speedaward_alltimebest(MSG_ONE);
1780
1781                 float i;
1782                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1783                         race_SendRankings(i, 0, 0, MSG_ONE);
1784                 }
1785         }
1786         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1787                 send_CSQC_teamnagger();
1788
1789         if (g_domination)
1790                 set_dom_state(self);
1791
1792         CheatInitClient();
1793
1794         if(!autocvar_g_campaign)
1795                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1796 }
1797
1798 /*
1799 =============
1800 ClientDisconnect
1801
1802 Called when a client disconnects from the server
1803 =============
1804 */
1805 .entity chatbubbleentity;
1806 void ReadyCount();
1807 void ClientDisconnect (void)
1808 {
1809         if(self.vehicle)
1810             vehicles_exit(VHEF_RELESE);
1811
1812         if not(self.flags & FL_CLIENT)
1813         {
1814                 print("Warning: ClientDisconnect without ClientConnect\n");
1815                 return;
1816         }
1817
1818         PlayerStats_AddGlobalInfo(self);
1819
1820         CheatShutdownClient();
1821
1822         if(self.hitplotfh >= 0)
1823         {
1824                 fclose(self.hitplotfh);
1825                 self.hitplotfh = -1;
1826         }
1827
1828         anticheat_report();
1829         anticheat_shutdown();
1830
1831         playerdemo_shutdown();
1832
1833         bot_clientdisconnect();
1834
1835         if(self.entcs)
1836                 detach_entcs();
1837
1838         if(autocvar_sv_eventlog)
1839                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1840         bprint ("^4",self.netname);
1841         bprint ("^4 disconnected\n");
1842
1843         SoundEntity_Detach(self);
1844
1845         DropAllRunes(self);
1846         MUTATOR_CALLHOOK(ClientDisconnect);
1847
1848         Portal_ClearAll(self);
1849
1850         RemoveGrapplingHook(self);
1851         if(self.flagcarried)
1852                 DropFlag(self.flagcarried, world, world);
1853         if(self.ballcarried && g_nexball)
1854                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1855
1856         // Here, everything has been done that requires this player to be a client.
1857
1858         self.flags &~= FL_CLIENT;
1859
1860         if (self.chatbubbleentity)
1861                 remove (self.chatbubbleentity);
1862
1863         if (self.killindicator)
1864                 remove (self.killindicator);
1865
1866         WaypointSprite_PlayerGone();
1867
1868         bot_relinkplayerlist();
1869
1870         if(g_arena)
1871         {
1872                 Spawnqueue_Unmark(self);
1873                 Spawnqueue_Remove(self);
1874         }
1875
1876         accuracy_free(self);
1877         ClientData_Detach();
1878         PlayerScore_Detach(self);
1879
1880         if(self.netname_previous)
1881                 strunzone(self.netname_previous);
1882         if(self.clientstatus)
1883                 strunzone(self.clientstatus);
1884         if(self.weaponorder_byimpulse)
1885                 strunzone(self.weaponorder_byimpulse);
1886
1887         ClearPlayerSounds();
1888
1889         if(self.personal)
1890                 remove(self.personal);
1891
1892         self.playerid = 0;
1893         ReadyCount();
1894
1895         // free cvars
1896         GetCvars(-1);
1897 }
1898
1899 .float BUTTON_CHAT;
1900 void ChatBubbleThink()
1901 {
1902         self.nextthink = time;
1903         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1904         {
1905                 if(self.owner) // but why can that ever be world?
1906                         self.owner.chatbubbleentity = world;
1907                 remove(self);
1908                 return;
1909         }
1910         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1911 #ifdef TETRIS
1912                 || self.owner.tetris_on
1913 #endif
1914         )
1915                 self.model = self.mdl;
1916         else
1917                 self.model = "";
1918 }
1919
1920 void UpdateChatBubble()
1921 {
1922         if (!self.modelindex)
1923                 return;
1924         // spawn a chatbubble entity if needed
1925         if (!self.chatbubbleentity)
1926         {
1927                 self.chatbubbleentity = spawn();
1928                 self.chatbubbleentity.owner = self;
1929                 self.chatbubbleentity.exteriormodeltoclient = self;
1930                 self.chatbubbleentity.think = ChatBubbleThink;
1931                 self.chatbubbleentity.nextthink = time;
1932                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1933                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1934                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1935                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1936                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1937                 self.chatbubbleentity.model = "";
1938                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1939         }
1940 }
1941
1942
1943 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1944 // added to the model skins
1945 /*void UpdateColorModHack()
1946 {
1947         float c;
1948         c = self.clientcolors & 15;
1949         // LordHavoc: only bothering to support white, green, red, yellow, blue
1950              if (!teamplay) self.colormod = '0 0 0';
1951         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1952         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1953         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1954         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1955         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1956         else self.colormod = '1 1 1';
1957 }*/
1958
1959 .float oldcolormap;
1960 void respawn(void)
1961 {
1962         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1963         {
1964                 self.solid = SOLID_NOT;
1965                 self.takedamage = DAMAGE_NO;
1966                 self.movetype = MOVETYPE_FLY;
1967                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1968                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1969                 self.effects |= EF_ADDITIVE;
1970                 self.oldcolormap = self.colormap;
1971                 self.colormap = 512;
1972                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1973                 if(autocvar_g_respawn_ghosts_maxtime)
1974                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1975         }
1976
1977         CopyBody(1);
1978         self.effects |= EF_NODRAW; // prevent another CopyBody
1979         if(self.oldcolormap)
1980         {
1981                 self.colormap = self.oldcolormap;
1982                 self.oldcolormap = 0;
1983         }
1984         PutClientInServer();
1985 }
1986
1987 void play_countdown(float finished, string samp)
1988 {
1989         if(clienttype(self) == CLIENTTYPE_REAL)
1990                 if(floor(finished - time - frametime) != floor(finished - time))
1991                         if(finished - time < 6)
1992                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1993 }
1994
1995 void player_powerups (void)
1996 {
1997         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1998         olditems = self.items;
1999
2000         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2001         {
2002                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2003                 self.modelflags |= MF_ROCKET;
2004         }
2005         else
2006         {
2007                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
2008                 self.modelflags &~= MF_ROCKET;
2009         }
2010
2011         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2012
2013         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2014                 return;
2015
2016         Fire_ApplyDamage(self);
2017         Fire_ApplyEffect(self);
2018
2019         if (g_minstagib)
2020         {
2021                 self.effects |= EF_FULLBRIGHT;
2022
2023                 if (self.items & IT_STRENGTH)
2024                 {
2025                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2026                         if (time > self.strength_finished)
2027                         {
2028                                 self.alpha = default_player_alpha;
2029                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2030                                 self.items &~= IT_STRENGTH;
2031                                 sprint(self, "^3Invisibility has worn off\n");
2032                         }
2033                 }
2034                 else
2035                 {
2036                         if (time < self.strength_finished)
2037                         {
2038                                 self.alpha = g_minstagib_invis_alpha;
2039                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2040                                 self.items |= IT_STRENGTH;
2041                                 sprint(self, "^3You are invisible\n");
2042                         }
2043                 }
2044
2045                 if (self.items & IT_INVINCIBLE)
2046                 {
2047                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2048                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2049                         {
2050                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2051                                 sprint(self, "^3Speed has worn off\n");
2052                         }
2053                 }
2054                 else
2055                 {
2056                         if (time < self.invincible_finished)
2057                         {
2058                                 self.items = self.items | IT_INVINCIBLE;
2059                                 sprint(self, "^3You are on speed\n");
2060                         }
2061                 }
2062         }
2063         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2064         {
2065                 if (self.items & IT_STRENGTH)
2066                 {
2067                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2068                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2069                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2070                         {
2071                                 self.items = self.items - (self.items & IT_STRENGTH);
2072                                 sprint(self, "^3Strength has worn off\n");
2073                         }
2074                 }
2075                 else
2076                 {
2077                         if (time < self.strength_finished)
2078                         {
2079                                 self.items = self.items | IT_STRENGTH;
2080                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2081                         }
2082                 }
2083                 if (self.items & IT_INVINCIBLE)
2084                 {
2085                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2086                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2087                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2088                         {
2089                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2090                                 sprint(self, "^3Shield has worn off\n");
2091                         }
2092                 }
2093                 else
2094                 {
2095                         if (time < self.invincible_finished)
2096                         {
2097                                 self.items = self.items | IT_INVINCIBLE;
2098                                 sprint(self, "^3Shield surrounds you\n");
2099                         }
2100                 }
2101
2102                 if(autocvar_g_nodepthtestplayers)
2103                         self.effects = self.effects | EF_NODEPTHTEST;
2104
2105                 if(autocvar_g_fullbrightplayers)
2106                         self.effects = self.effects | EF_FULLBRIGHT;
2107
2108                 // midair gamemode: damage only while in the air
2109                 // if in midair mode, being on ground grants temporary invulnerability
2110                 // (this is so that multishot weapon don't clear the ground flag on the
2111                 // first damage in the frame, leaving the player vulnerable to the
2112                 // remaining hits in the same frame)
2113                 if (self.flags & FL_ONGROUND)
2114                 if (g_midair)
2115                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2116
2117                 if (time >= game_starttime)
2118                 if (time < self.spawnshieldtime)
2119                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2120         }
2121
2122         MUTATOR_CALLHOOK(PlayerPowerups);
2123 }
2124
2125 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2126 {
2127         if(current > stable)
2128                 return current;
2129         else if(current > stable - 0.25) // when close enough, "snap"
2130                 return stable;
2131         else
2132                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2133 }
2134
2135 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2136 {
2137         if(current < stable)
2138                 return current;
2139         else if(current < stable + 0.25) // when close enough, "snap"
2140                 return stable;
2141         else
2142                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2143 }
2144
2145 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2146 {
2147         if(current > rotstable)
2148         {
2149                 if(rotframetime > 0)
2150                 {
2151                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2152                         current = max(rotstable, current - rotlinear * rotframetime);
2153                 }
2154         }
2155         else if(current < regenstable)
2156         {
2157                 if(regenframetime > 0)
2158                 {
2159                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2160                         current = min(regenstable, current + regenlinear * regenframetime);
2161                 }
2162         }
2163
2164         if(current > limit)
2165                 current = limit;
2166
2167         return current;
2168 }
2169
2170 void player_regen (void)
2171 {
2172         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2173         maxh = autocvar_g_balance_health_rotstable;
2174         maxa = autocvar_g_balance_armor_rotstable;
2175         maxf = autocvar_g_balance_fuel_rotstable;
2176         minh = autocvar_g_balance_health_regenstable;
2177         mina = autocvar_g_balance_armor_regenstable;
2178         minf = autocvar_g_balance_fuel_regenstable;
2179         limith = autocvar_g_balance_health_limit;
2180         limita = autocvar_g_balance_armor_limit;
2181         limitf = autocvar_g_balance_fuel_limit;
2182
2183         max_mod = regen_mod = rot_mod = limit_mod = 1;
2184
2185         if (self.runes & RUNE_REGEN)
2186         {
2187                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2188                 {
2189                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2190                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2191                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2192                 }
2193                 else
2194                 {
2195                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2196                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2197                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2198                 }
2199         }
2200         else if (self.runes & CURSE_VENOM)
2201         {
2202                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2203                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2204                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2205                 else
2206                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2207                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2208                 //if (!self.runes & RUNE_REGEN)
2209                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2210         }
2211         maxh = maxh * max_mod;
2212         //maxa = maxa * max_mod;
2213         //maxf = maxf * max_mod;
2214         minh = minh * max_mod;
2215         //mina = mina * max_mod;
2216         //minf = minf * max_mod;
2217         limith = limith * limit_mod;
2218         limita = limita * limit_mod;
2219         //limitf = limitf * limit_mod;
2220
2221         if(g_lms && g_ca)
2222                 rot_mod = 0;
2223
2224         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2225         {
2226                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2227                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2228
2229                 // if player rotted to death...  die!
2230                 if(self.health < 1)
2231                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2232         }
2233
2234         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2235                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2236 }
2237
2238 float zoomstate_set;
2239 void SetZoomState(float z)
2240 {
2241         if(z != self.zoomstate)
2242         {
2243                 self.zoomstate = z;
2244                 ClientData_Touch(self);
2245         }
2246         zoomstate_set = 1;
2247 }
2248
2249 void GetPressedKeys(void) {
2250         MUTATOR_CALLHOOK(GetPressedKeys);
2251         if (self.movement_x > 0) // get if movement keys are pressed
2252         {       // forward key pressed
2253                 self.pressedkeys |= KEY_FORWARD;
2254                 self.pressedkeys &~= KEY_BACKWARD;
2255         }
2256         else if (self.movement_x < 0)
2257         {       // backward key pressed
2258                 self.pressedkeys |= KEY_BACKWARD;
2259                 self.pressedkeys &~= KEY_FORWARD;
2260         }
2261         else
2262         {       // no x input
2263                 self.pressedkeys &~= KEY_FORWARD;
2264                 self.pressedkeys &~= KEY_BACKWARD;
2265         }
2266
2267         if (self.movement_y > 0)
2268         {       // right key pressed
2269                 self.pressedkeys |= KEY_RIGHT;
2270                 self.pressedkeys &~= KEY_LEFT;
2271         }
2272         else if (self.movement_y < 0)
2273         {       // left key pressed
2274                 self.pressedkeys |= KEY_LEFT;
2275                 self.pressedkeys &~= KEY_RIGHT;
2276         }
2277         else
2278         {       // no y input
2279                 self.pressedkeys &~= KEY_RIGHT;
2280                 self.pressedkeys &~= KEY_LEFT;
2281         }
2282
2283         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2284                 self.pressedkeys |= KEY_JUMP;
2285         else
2286                 self.pressedkeys &~= KEY_JUMP;
2287         if (self.BUTTON_CROUCH)
2288                 self.pressedkeys |= KEY_CROUCH;
2289         else
2290                 self.pressedkeys &~= KEY_CROUCH;
2291 }
2292
2293 /*
2294 ======================
2295 spectate mode routines
2296 ======================
2297 */
2298
2299 void SpectateCopy(entity spectatee) {
2300         other = spectatee;
2301         MUTATOR_CALLHOOK(SpectateCopy);
2302         self.armortype = spectatee.armortype;
2303         self.armorvalue = spectatee.armorvalue;
2304         self.ammo_cells = spectatee.ammo_cells;
2305         self.ammo_shells = spectatee.ammo_shells;
2306         self.ammo_nails = spectatee.ammo_nails;
2307         self.ammo_rockets = spectatee.ammo_rockets;
2308         self.ammo_fuel = spectatee.ammo_fuel;
2309         self.clip_load = spectatee.clip_load;
2310         self.clip_size = spectatee.clip_size;
2311         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2312         self.health = spectatee.health;
2313         self.impulse = 0;
2314         self.items = spectatee.items;
2315         self.last_pickup = spectatee.last_pickup;
2316         self.hit_time = spectatee.hit_time;
2317         self.metertime = spectatee.metertime;
2318         self.strength_finished = spectatee.strength_finished;
2319         self.invincible_finished = spectatee.invincible_finished;
2320         self.pressedkeys = spectatee.pressedkeys;
2321         self.weapons = spectatee.weapons;
2322         self.switchweapon = spectatee.switchweapon;
2323         self.switchingweapon = spectatee.switchingweapon;
2324         self.weapon = spectatee.weapon;
2325         self.nex_charge = spectatee.nex_charge;
2326         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2327         self.hagar_load = spectatee.hagar_load;
2328         self.minelayer_mines = spectatee.minelayer_mines;
2329         self.punchangle = spectatee.punchangle;
2330         self.view_ofs = spectatee.view_ofs;
2331         self.v_angle = spectatee.v_angle;
2332         self.velocity = spectatee.velocity;
2333         self.dmg_take = spectatee.dmg_take;
2334         self.dmg_save = spectatee.dmg_save;
2335         self.dmg_inflictor = spectatee.dmg_inflictor;
2336         self.angles = spectatee.v_angle;
2337         if(!self.BUTTON_USE)
2338                 self.fixangle = TRUE;
2339         setorigin(self, spectatee.origin);
2340         setsize(self, spectatee.mins, spectatee.maxs);
2341         SetZoomState(spectatee.zoomstate);
2342
2343         anticheat_spectatecopy(spectatee);
2344
2345         //self.vehicle = spectatee.vehicle;
2346
2347         self.hud = spectatee.hud;
2348         if(spectatee.vehicle)
2349     {
2350         setorigin(self, spectatee.origin);
2351         self.velocity = spectatee.vehicle.velocity;
2352         self.v_angle += spectatee.vehicle.angles;
2353         //self.v_angle_x *= -1;
2354         self.vehicle_health = spectatee.vehicle_health;
2355         self.vehicle_shield = spectatee.vehicle_shield;
2356         self.vehicle_energy = spectatee.vehicle_energy;
2357         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2358         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2359         self.vehicle_reload1 = spectatee.vehicle_reload1;
2360         self.vehicle_reload2 = spectatee.vehicle_reload2;
2361
2362         msg_entity = self;
2363         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2364         WriteEntity(MSG_ONE, spectatee);
2365         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2366     }
2367 }
2368
2369 float SpectateUpdate() {
2370         if(!self.enemy)
2371             return 0;
2372
2373         if (self == self.enemy)
2374                 return 0;
2375
2376         if(self.enemy.classname != "player")
2377                 return 0;
2378
2379         SpectateCopy(self.enemy);
2380
2381         return 1;
2382 }
2383
2384
2385 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2386 entity CA_SpectateNext(entity start) {
2387         if (start.team == self.team) {
2388                 return start;
2389         }
2390
2391         other = start;
2392         // continue from current player
2393         while(other && other.team != self.team) {
2394                 other = find(other, classname, "player");
2395         }
2396
2397         if (!other) {
2398                 // restart from begining
2399                 other = find(other, classname, "player");
2400                 while(other && other.team != self.team) {
2401                         other = find(other, classname, "player");
2402                 }
2403         }
2404
2405         return other;
2406 }
2407
2408 float SpectateNext() {
2409         other = find(self.enemy, classname, "player");
2410         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2411                 // CA and ca players when spectating enemies is forbidden
2412                 other = CA_SpectateNext(other);
2413         } else {
2414                 // other modes and ca spectators or spectating enemies is allowed
2415                 if (!other)
2416                         other = find(other, classname, "player");
2417         }
2418
2419         if (other)
2420                 self.enemy = other;
2421
2422         if(self.enemy.classname == "player") {
2423             if(self.enemy.vehicle)
2424             {
2425             msg_entity = self;
2426             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2427             WriteEntity(MSG_ONE, self.enemy);
2428             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2429             self.movetype = MOVETYPE_NONE;
2430             accuracy_resend(self);
2431             }
2432             else
2433             {
2434             msg_entity = self;
2435             WriteByte(MSG_ONE, SVC_SETVIEW);
2436             WriteEntity(MSG_ONE, self.enemy);
2437             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2438             self.movetype = MOVETYPE_NONE;
2439             accuracy_resend(self);
2440
2441             if(!SpectateUpdate())
2442                 PutObserverInServer();
2443         }
2444         return 1;
2445         } else {
2446                 return 0;
2447         }
2448 }
2449
2450 /*
2451 =============
2452 ShowRespawnCountdown()
2453
2454 Update a respawn countdown display.
2455 =============
2456 */
2457 void ShowRespawnCountdown()
2458 {
2459         float number;
2460         if(self.deadflag == DEAD_NO) // just respawned?
2461                 return;
2462         else
2463         {
2464                 number = ceil(self.death_time - time);
2465                 if(number <= 0)
2466                         return;
2467                 if(number <= self.respawn_countdown)
2468                 {
2469                         self.respawn_countdown = number - 1;
2470                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2471                                 AnnounceTo(self, strcat(ftos(number), ""));
2472                 }
2473         }
2474 }
2475
2476 .float prevent_join_msgtime;
2477 void LeaveSpectatorMode()
2478 {
2479         if(nJoinAllowed(1)) {
2480                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2481                         self.classname = "player";
2482
2483                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2484                                 JoinBestTeam(self, FALSE, TRUE);
2485
2486                         if(autocvar_g_campaign)
2487                                 campaign_bots_may_start = 1;
2488
2489                         PutClientInServer();
2490
2491                         if(self.classname == "player")
2492                                 bprint ("^4", self.netname, "^4 is playing now\n");
2493
2494                         if(!autocvar_g_campaign)
2495                         if (time < self.jointime + autocvar_welcome_message_time)
2496                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2497
2498                         if (self.prevent_join_msgtime)
2499                         {
2500                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2501                                 self.prevent_join_msgtime = 0;
2502                         }
2503
2504                         return;
2505                 } else {
2506                         if (g_ca && self.caplayer) {
2507                         }       // do nothing
2508                         else
2509                                 stuffcmd(self,"menu_showteamselect\n");
2510                         return;
2511                 }
2512         }
2513         else {
2514                 //player may not join because of g_maxplayers is set
2515                 if (time - self.prevent_join_msgtime > 2)
2516                 {
2517                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2518                         self.prevent_join_msgtime = time;
2519                 }
2520         }
2521 }
2522
2523 /**
2524  * Determines whether the player is allowed to join. This depends on cvar
2525  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2526  * it checks whether the number of currently playing players exceeds g_maxplayers.
2527  * @return int number of free slots for players, 0 if none
2528  */
2529 float nJoinAllowed(float includeMe) {
2530         if(self.team_forced < 0)
2531                 return FALSE; // forced spectators can never join
2532
2533         // TODO simplify this
2534         entity e;
2535
2536         float totalClients;
2537         FOR_EACH_CLIENT(e)
2538                 totalClients += 1;
2539
2540         if (!autocvar_g_maxplayers)
2541                 return maxclients - totalClients + includeMe;
2542
2543         float currentlyPlaying;
2544         FOR_EACH_REALPLAYER(e)
2545                 currentlyPlaying += 1;
2546
2547         if(currentlyPlaying < autocvar_g_maxplayers)
2548                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2549
2550         return 0;
2551 }
2552
2553 /**
2554  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2555  * g_maxplayers_spectator_blocktime seconds
2556  */
2557 void checkSpectatorBlock() {
2558         if(self.classname == "spectator" || self.classname == "observer") {
2559                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2560                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2561                         dropclient(self);
2562                 }
2563         }
2564 }
2565
2566 .float motd_actived_time; // used for both motd and campaign_message
2567 void PrintWelcomeMessage()
2568 {
2569         if (self.motd_actived_time == 0) { // is there already a message showing?
2570                 if (autocvar_g_campaign) {
2571                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2572                                 self.motd_actived_time = time;
2573                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2574                         }
2575                 } else {
2576                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2577                                 self.motd_actived_time = time;
2578                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2579                         }
2580                 }
2581         } else { // showing MOTD or campaign message
2582                 if (autocvar_g_campaign) {
2583                         if (self.BUTTON_INFO)
2584                                 self.motd_actived_time = time;
2585                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2586                                 self.motd_actived_time = 0;
2587                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2588                         }
2589                 } else {
2590                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2591                                 if (self.BUTTON_INFO)
2592                                         self.motd_actived_time = time;
2593                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2594                                         self.motd_actived_time = 0;
2595                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2596                                 }
2597                         }
2598                 }
2599         }
2600 }
2601
2602 void ObserverThink()
2603 {
2604         float prefered_movetype;
2605         if (self.flags & FL_JUMPRELEASED) {
2606                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2607                         self.flags &~= FL_JUMPRELEASED;
2608                         self.flags |= FL_SPAWNING;
2609                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2610                         self.flags &~= FL_JUMPRELEASED;
2611                         if(SpectateNext() == 1) {
2612                                 self.classname = "spectator";
2613                         }
2614                 } else {
2615                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2616                         if (self.movetype != prefered_movetype)
2617                                 self.movetype = prefered_movetype;
2618                 }
2619         } else {
2620                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2621                         self.flags |= FL_JUMPRELEASED;
2622                         if(self.flags & FL_SPAWNING)
2623                         {
2624                                 self.flags &~= FL_SPAWNING;
2625                                 LeaveSpectatorMode();
2626                                 return;
2627                         }
2628                 }
2629         }
2630
2631         PrintWelcomeMessage();
2632 }
2633
2634 void SpectatorThink()
2635 {
2636         if (self.flags & FL_JUMPRELEASED) {
2637                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2638                         self.flags &~= FL_JUMPRELEASED;
2639                         self.flags |= FL_SPAWNING;
2640                 } else if(self.BUTTON_ATCK) {
2641                         self.flags &~= FL_JUMPRELEASED;
2642                         if(SpectateNext() == 1) {
2643                                 self.classname = "spectator";
2644                         } else {
2645                                 self.classname = "observer";
2646                                 PutClientInServer();
2647                         }
2648                 } else if (self.BUTTON_ATCK2) {
2649                         self.flags &~= FL_JUMPRELEASED;
2650                         self.classname = "observer";
2651                         PutClientInServer();
2652                 } else {
2653                         if(!SpectateUpdate())
2654                                 PutObserverInServer();
2655                 }
2656         } else {
2657                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2658                         self.flags |= FL_JUMPRELEASED;
2659                         if(self.flags & FL_SPAWNING)
2660                         {
2661                                 self.flags &~= FL_SPAWNING;
2662                                 LeaveSpectatorMode();
2663                                 return;
2664                         }
2665                 }
2666                 if(!SpectateUpdate())
2667                         PutObserverInServer();
2668         }
2669
2670         PrintWelcomeMessage();
2671         self.flags |= FL_CLIENT | FL_NOTARGET;
2672 }
2673
2674 float ctf_usekey();
2675 void PlayerUseKey()
2676 {
2677         if(self.classname != "player")
2678                 return;
2679
2680         if(self.vehicle)
2681         {
2682         vehicles_exit(VHEF_NORMAL);
2683         return;
2684         }
2685
2686         // a use key was pressed; call handlers
2687         if(ctf_usekey())
2688                 return;
2689
2690         MUTATOR_CALLHOOK(PlayerUseKey);
2691 }
2692
2693 .float touchexplode_time;
2694
2695 /*
2696 =============
2697 PlayerPreThink
2698
2699 Called every frame for each client before the physics are run
2700 =============
2701 */
2702 .float usekeypressed;
2703 void() ctf_setstatus;
2704 void() nexball_setstatus;
2705 .float items_added;
2706 void PlayerPreThink (void)
2707 {
2708         WarpZone_PlayerPhysics_FixVAngle();
2709
2710         self.stat_game_starttime = game_starttime;
2711         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2712         self.stat_leadlimit = autocvar_leadlimit;
2713
2714         if(frametime)
2715         {
2716                 // physics frames: update anticheat stuff
2717                 anticheat_prethink();
2718         }
2719
2720         if(blockSpectators && frametime)
2721                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2722                 checkSpectatorBlock();
2723
2724         zoomstate_set = 0;
2725
2726         if(self.netname_previous != self.netname)
2727         {
2728                 if(autocvar_sv_eventlog)
2729                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2730                 if(self.netname_previous)
2731                         strunzone(self.netname_previous);
2732                 self.netname_previous = strzone(self.netname);
2733         }
2734
2735         // version nagging
2736         if(self.version_nagtime)
2737                 if(self.cvar_g_xonoticversion)
2738                         if(time > self.version_nagtime)
2739                         {
2740                                 // don't notify git users
2741                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2742                                 {
2743                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2744                                         {
2745                                                 // notify release users if connecting to git
2746                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2747                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2748                                         }
2749                                         else
2750                                         {
2751                                                 float r;
2752                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2753                                                 if(r < 0)
2754                                                 {
2755                                                         // give users new version
2756                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2757                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2758                                                 }
2759                                                 else if(r > 0)
2760                                                 {
2761                                                         // notify users about old server version
2762                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2763                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2764                                                 }
2765                                         }
2766                                 }
2767                                 self.version_nagtime = 0;
2768                         }
2769
2770         // GOD MODE info
2771         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2772         {
2773                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2774                 self.max_armorvalue = 0;
2775         }
2776
2777 #ifdef TETRIS
2778         if (TetrisPreFrame())
2779                 return;
2780 #endif
2781
2782         MUTATOR_CALLHOOK(PlayerPreThink);
2783
2784         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2785         {
2786                 if(self.BUTTON_USE && !self.usekeypressed)
2787                         PlayerUseKey();
2788                 self.usekeypressed = self.BUTTON_USE;
2789         }
2790
2791         PrintWelcomeMessage();
2792
2793         if(self.classname == "player") {
2794 //              if(self.netname == "Wazat")
2795 //                      bprint(self.classname, "\n");
2796
2797                 CheckRules_Player();
2798
2799                 if (intermission_running)
2800                 {
2801                         IntermissionThink ();   // otherwise a button could be missed between
2802                         return;                                 // the think tics
2803                 }
2804
2805                 //don't allow the player to turn around while game is paused!
2806                 if(timeoutStatus == 2) {
2807                         // FIXME turn this into CSQC stuff
2808                         self.v_angle = self.lastV_angle;
2809                         self.angles = self.lastV_angle;
2810                         self.fixangle = TRUE;
2811                 }
2812
2813                 if(frametime)
2814                 {
2815                         if(self.health <= 0 && autocvar_g_deathglow)
2816                         {
2817                                 if(self.glowmod_x > 0)
2818                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2819                                 else
2820                                         self.glowmod_x = -1;
2821                                 if(self.glowmod_y > 0)
2822                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2823                                 else
2824                                         self.glowmod_y = -1;
2825                                 if(self.glowmod_z > 0)
2826                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2827                                 else
2828                                         self.glowmod_z = -1;
2829                         }
2830                         else
2831                         {
2832                                 // set weapon and player glowmod
2833                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2834
2835                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2836                                 {
2837                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2838                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2839                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2840
2841                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2842                                         {
2843                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2844                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2845                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2846                                         }
2847                                 }
2848                                 else
2849                                         self.weaponentity_glowmod = self.glowmod;
2850                         }
2851                         player_powerups();
2852                 }
2853
2854                 if (g_minstagib)
2855                         minstagib_ammocheck();
2856
2857                 if (self.deadflag != DEAD_NO)
2858                 {
2859                         float button_pressed, force_respawn;
2860                         if(self.personal && g_race_qualifying)
2861                         {
2862                                 if(time > self.death_time)
2863                                 {
2864                                         self.death_time = time + 1; // only retry once a second
2865                                         respawn();
2866                                         self.impulse = 141;
2867                                 }
2868                         }
2869                         else
2870                         {
2871                                 if(frametime)
2872                                         player_anim();
2873                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2874                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2875                                 if (self.deadflag == DEAD_DYING)
2876                                 {
2877                                         if(force_respawn)
2878                                                 self.deadflag = DEAD_RESPAWNING;
2879                                         else if(!button_pressed)
2880                                                 self.deadflag = DEAD_DEAD;
2881                                 }
2882                                 else if (self.deadflag == DEAD_DEAD)
2883                                 {
2884                                         if(button_pressed)
2885                                                 self.deadflag = DEAD_RESPAWNABLE;
2886                                 }
2887                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2888                                 {
2889                                         if(!button_pressed)
2890                                                 self.deadflag = DEAD_RESPAWNING;
2891                                 }
2892                                 else if (self.deadflag == DEAD_RESPAWNING)
2893                                 {
2894                                         if(time > self.death_time)
2895                                         {
2896                                                 self.death_time = time + 1; // only retry once a second
2897                                                 respawn();
2898                                         }
2899                                 }
2900                                 ShowRespawnCountdown();
2901                         }
2902                         return;
2903                 }
2904                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2905                 // so (self.deadflag == DEAD_NO) is always true in the code below
2906
2907                 if(g_touchexplode)
2908                 if(time > self.touchexplode_time)
2909                 if(self.classname == "player")
2910                 if(self.deadflag == DEAD_NO)
2911                 if not(IS_INDEPENDENT_PLAYER(self))
2912                 FOR_EACH_PLAYER(other) if(self != other)
2913                 {
2914                         if(time > other.touchexplode_time)
2915                         if(other.deadflag == DEAD_NO)
2916                         if not(IS_INDEPENDENT_PLAYER(other))
2917                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2918                         {
2919                                 PlayerTouchExplode(self, other);
2920                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2921                         }
2922                 }
2923
2924                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2925                 {
2926                         vector dist;
2927
2928                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2929                         dist = self.prevorigin - self.origin;
2930                         dist_z = 0;
2931                         self.lms_traveled_distance += fabs(vlen(dist));
2932
2933                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2934                         {
2935                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2936                                 self.lms_traveled_distance = 0;
2937                         }
2938
2939                         if(time > self.lms_nextcheck)
2940                         {
2941                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2942                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2943                                 {
2944                                         centerprint(self, autocvar_g_lms_campcheck_message);
2945                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2946                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2947                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2948                                 }
2949                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2950                                 self.lms_traveled_distance = 0;
2951                         }
2952                 }
2953
2954                 self.prevorigin = self.origin;
2955
2956                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2957                 {
2958                         if (!self.crouch)
2959                         {
2960                                 self.crouch = TRUE;
2961                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2962                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2963                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2964                         }
2965                 }
2966                 else
2967                 {
2968                         if (self.crouch)
2969                         {
2970                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2971                                 if (!trace_startsolid)
2972                                 {
2973                                         self.crouch = FALSE;
2974                                         self.view_ofs = PL_VIEW_OFS;
2975                                         setsize (self, PL_MIN, PL_MAX);
2976                                 }
2977                         }
2978                 }
2979
2980                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2981                 {
2982                         if(self.bloodloss_timer < time)
2983                         {
2984                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2985                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2986                         }
2987                 }
2988
2989                 FixPlayermodel();
2990
2991                 GrapplingHookFrame();
2992
2993                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2994                 //if(frametime)
2995                 {
2996                         self.items &~= self.items_added;
2997
2998                         W_WeaponFrame();
2999
3000                         self.items_added = 0;
3001                         if(self.items & IT_JETPACK)
3002                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
3003                                         self.items_added |= IT_FUEL;
3004
3005                         self.items |= self.items_added;
3006                 }
3007
3008                 player_regen();
3009
3010                 // rot nex charge to the charge limit
3011                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
3012                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
3013
3014                 if(frametime)
3015                         player_anim();
3016
3017                 if(g_ctf)
3018                         ctf_setstatus();
3019
3020                 if(g_nexball)
3021                         nexball_setstatus();
3022
3023                 // secret status
3024                 secrets_setstatus();
3025
3026                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
3027
3028                 //self.angles_y=self.v_angle_y + 90;   // temp
3029         } else if(gameover) {
3030                 if (intermission_running)
3031                         IntermissionThink ();   // otherwise a button could be missed between
3032                 return;
3033         } else if(self.classname == "observer") {
3034                 ObserverThink();
3035         } else if(self.classname == "spectator") {
3036                 SpectatorThink();
3037         }
3038
3039         if(!zoomstate_set)
3040                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
3041
3042         float oldspectatee_status;
3043         oldspectatee_status = self.spectatee_status;
3044         if(self.classname == "spectator")
3045                 self.spectatee_status = num_for_edict(self.enemy);
3046         else if(self.classname == "observer")
3047                 self.spectatee_status = num_for_edict(self);
3048         else
3049                 self.spectatee_status = 0;
3050         if(self.spectatee_status != oldspectatee_status)
3051         {
3052                 ClientData_Touch(self);
3053                 if(g_race || g_cts)
3054                         race_InitSpectator();
3055         }
3056
3057         if(self.teamkill_soundtime)
3058         if(time > self.teamkill_soundtime)
3059         {
3060                 self.teamkill_soundtime = 0;
3061
3062                 entity oldpusher, oldself;
3063
3064                 oldself = self; self = self.teamkill_soundsource;
3065                 oldpusher = self.pusher; self.pusher = oldself;
3066
3067                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3068
3069                 self.pusher = oldpusher;
3070                 self = oldself;
3071         }
3072
3073         if(self.taunt_soundtime)
3074         if(time > self.taunt_soundtime)
3075         {
3076                 self.taunt_soundtime = 0;
3077                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
3078         }
3079
3080         target_voicescript_next(self);
3081
3082         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3083         if(!self.weapon)
3084                 self.clip_load = self.clip_size = 0;
3085 }
3086
3087 float isInvisibleString(string s)
3088 {
3089         float i, n, c;
3090         s = strdecolorize(s);
3091         for((i = 0), (n = strlen(s)); i < n; ++i)
3092         {
3093                 c = str2chr(s, i);
3094                 switch(c)
3095                 {
3096                         case 0:
3097                         case 32: // space
3098                                 break;
3099                         case 192: // charmap space
3100                                 if (!autocvar_utf8_enable)
3101                                         break;
3102                                 return FALSE;
3103                         case 160: // space in unicode fonts
3104                         case 0xE000 + 192: // utf8 charmap space
3105                                 if (autocvar_utf8_enable)
3106                                         break;
3107                         default:
3108                                 return FALSE;
3109                 }
3110         }
3111         return TRUE;
3112 }
3113
3114 /*
3115 =============
3116 PlayerPostThink
3117
3118 Called every frame for each client after the physics are run
3119 =============
3120 */
3121 .float idlekick_lasttimeleft;
3122 .entity showheadshotbbox;
3123 void showheadshotbbox_think()
3124 {
3125         if(self.owner.showheadshotbbox != self)
3126         {
3127                 remove(self);
3128                 return;
3129         }
3130         self.nextthink = time;
3131         setorigin(self, self.owner.origin);
3132         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3133 }
3134 void PlayerPostThink (void)
3135 {
3136         // Savage: Check for nameless players
3137         if (isInvisibleString(self.netname)) {
3138                 self.netname = "Player";
3139                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3140         }
3141
3142         if(sv_maxidle && frametime)
3143         {
3144                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3145                 float timeleft;
3146                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
3147                 {
3148                         if(self.idlekick_lasttimeleft)
3149                         {
3150                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
3151                                 self.idlekick_lasttimeleft = 0;
3152                         }
3153                         return;
3154                 }
3155                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3156                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3157                 {
3158                         if(!self.idlekick_lasttimeleft)
3159                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3160                 }
3161                 if(timeleft <= 0)
3162                 {
3163                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3164                         AnnounceTo(self, "terminated");
3165                         dropclient(self);
3166                         return;
3167                 }
3168                 else if(timeleft <= 10)
3169                 {
3170                         if(timeleft != self.idlekick_lasttimeleft)
3171                                 AnnounceTo(self, ftos(timeleft));
3172                         self.idlekick_lasttimeleft = timeleft;
3173                 }
3174         }
3175
3176 #ifdef TETRIS
3177         if(self.impulse == 100)
3178                 ImpulseCommands();
3179         if (TetrisPostFrame())
3180                 return;
3181 #endif
3182
3183         CheatFrame();
3184
3185         //CheckPlayerJump();
3186
3187         if(self.classname == "player") {
3188                 CheckRules_Player();
3189                 UpdateChatBubble();
3190                 if (self.impulse)
3191                         ImpulseCommands();
3192                 if (intermission_running)
3193                         return;         // intermission or finale
3194                 GetPressedKeys();
3195         } else if (self.classname == "observer") {
3196                 //do nothing
3197         } else if (self.classname == "spectator") {
3198                 //do nothing
3199         }
3200
3201         /*
3202         float i;
3203         for(i = 0; i < 1000; ++i)
3204         {
3205                 vector end;
3206                 end = self.origin + '0 0 1024' + 512 * randomvec();
3207                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3208                 if(trace_fraction < 1)
3209                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3210                 {
3211                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3212                         break;
3213                 }
3214         }
3215         */
3216
3217         Arena_Warmup();
3218
3219         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3220
3221         if(self.waypointsprite_attachedforcarrier)
3222                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3223
3224         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3225         {
3226                 if(!self.showheadshotbbox)
3227                 {
3228                         self.showheadshotbbox = spawn();
3229                         self.showheadshotbbox.classname = "headshotbbox";
3230                         self.showheadshotbbox.owner = self;
3231                         self.showheadshotbbox.think = showheadshotbbox_think;
3232                         self.showheadshotbbox.nextthink = time;
3233                         self = self.showheadshotbbox;
3234                         self.think();
3235                         self = self.owner;
3236                 }
3237         }
3238         else
3239         {
3240                 if(self.showheadshotbbox)
3241                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3242                 remove(self.showheadshotbbox);
3243         }
3244
3245         playerdemo_write();
3246
3247         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3248         {
3249                 if(!self.stored_netname)
3250                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3251                 if(self.stored_netname != self.netname)
3252                 {
3253                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3254                         strunzone(self.stored_netname);
3255                         self.stored_netname = strzone(self.netname);
3256                 }
3257         }
3258
3259         /*
3260         if(g_race)
3261                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3262         */
3263 }