qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76
  77 /*
  78 =============
  79 CheckPlayerModel
  80
  81 Checks if the argument string can be a valid playermodel.
  82 Returns a valid one in doubt.
  83 =============
  84 */
  85 string FallbackPlayerModel;
  86 string CheckPlayerModel(string plyermodel) {
  87         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  88         {
  89                 // note: we cannot summon Don Strunzone here, some player may
  90                 // still have the model string set. In case anyone manages how
  91                 // to change a cvar default, we'll have a small leak here.
  92                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  93         }
  94         // only in right path
  95         if( substring(plyermodel,0,14) != "models/player/")
  96                 return FallbackPlayerModel;
  97         // only good file extensions
  98         if(substring(plyermodel,-4,4) != ".zym")
  99         if(substring(plyermodel,-4,4) != ".dpm")
 100         if(substring(plyermodel,-4,4) != ".iqm")
 101         if(substring(plyermodel,-4,4) != ".md3")
 102         if(substring(plyermodel,-4,4) != ".psk")
 103                 return FallbackPlayerModel;
 104         // forbid the LOD models
 105         if(substring(plyermodel, -9,5) == "_lod1")
 106                 return FallbackPlayerModel;
 107         if(substring(plyermodel, -9,5) == "_lod2")
 108                 return FallbackPlayerModel;
 109         if(plyermodel != strtolower(plyermodel))
 110                 return FallbackPlayerModel;
 111         // also, restrict to server models
 112         if(autocvar_sv_servermodelsonly)
 113         {
 114                 if(!fexists(plyermodel))
 115                         return FallbackPlayerModel;
 116         }
 117         return plyermodel;
 118 }
 119
 120 void setplayermodel(entity e, string modelname)
 121 {
 122         precache_model(modelname);
 123         setmodel(e, modelname);
 124         player_setupanimsformodel();
 125         UpdatePlayerSounds();
 126 }
 127
 128 /*
 129 =============
 130 PutObserverInServer
 131
 132 putting a client as observer in the server
 133 =============
 134 */
 135 void FixPlayermodel();
 136 void PutObserverInServer (void)
 137 {
 138         entity  spot;
 139     self.hud = HUD_NORMAL;
 140
 141         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 142
 143         spot = SelectSpawnPoint (TRUE);
 144         if(!spot)
 145                 error("No spawnpoints for observers?!?\n");
 146         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 147
 148         if(IS_REAL_CLIENT(self))
 149         {
 150                 msg_entity = self;
 151                 WriteByte(MSG_ONE, SVC_SETVIEW);
 152                 WriteEntity(MSG_ONE, self);
 153         }
 154
 155         self.frags = FRAGS_SPECTATOR;
 156
 157         MUTATOR_CALLHOOK(MakePlayerObserver);
 158
 159         Portal_ClearAll(self);
 160
 161         Unfreeze(self);
 162
 163         if(self.alivetime)
 164         {
 165                 if(!warmup_stage)
 166                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 167                 self.alivetime = 0;
 168         }
 169
 170         if(self.vehicle)
 171                 vehicles_exit(VHEF_RELESE);
 172
 173         WaypointSprite_PlayerDead();
 174
 175         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 176                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 177
 178         if(self.killcount != -666)
 179         {
 180                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 181                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 182                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 183
 184                 if(self.just_joined == FALSE) {
 185                         LogTeamchange(self.playerid, -1, 4);
 186                 } else
 187                         self.just_joined = FALSE;
 188         }
 189
 190         PlayerScore_Clear(self); // clear scores when needed
 191
 192         accuracy_resend(self);
 193
 194         self.spectatortime = time;
 195
 196         self.classname = "observer";
 197         self.iscreature = FALSE;
 198         self.teleportable = TELEPORT_SIMPLE;
 199         self.damagedbycontents = FALSE;
 200         self.health = -666;
 201         self.takedamage = DAMAGE_NO;
 202         self.solid = SOLID_NOT;
 203         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 204         self.flags = FL_CLIENT | FL_NOTARGET;
 205         self.armorvalue = 666;
 206         self.effects = 0;
 207         self.armorvalue = autocvar_g_balance_armor_start;
 208         self.pauserotarmor_finished = 0;
 209         self.pauserothealth_finished = 0;
 210         self.pauseregen_finished = 0;
 211         self.damageforcescale = 0;
 212         self.death_time = 0;
 213         self.respawn_flags = 0;
 214         self.respawn_time = 0;
 215         self.stat_respawn_time = 0;
 216         self.alpha = 0;
 217         self.scale = 0;
 218         self.fade_time = 0;
 219         self.pain_frame = 0;
 220         self.pain_finished = 0;
 221         self.strength_finished = 0;
 222         self.invincible_finished = 0;
 223         self.superweapons_finished = 0;
 224         self.pushltime = 0;
 225         self.istypefrag = 0;
 226         self.think = func_null;
 227         self.nextthink = 0;
 228         self.hook_time = 0;
 229         self.deadflag = DEAD_NO;
 230         self.angles = spot.angles;
 231         self.angles_z = 0;
 232         self.fixangle = TRUE;
 233         self.crouch = FALSE;
 234         self.revival_time = 0;
 235
 236         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 237         self.prevorigin = self.origin;
 238         self.items = 0;
 239         self.weapons = '0 0 0';
 240         self.model = "";
 241         FixPlayermodel();
 242         setmodel(self, "null");
 243         self.drawonlytoclient = self;
 244
 245         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 246         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 247
 248         self.weapon = 0;
 249         self.weaponname = "";
 250         self.switchingweapon = 0;
 251         self.weaponmodel = "";
 252         self.weaponentity = world;
 253         self.exteriorweaponentity = world;
 254         self.killcount = -666;
 255         self.velocity = '0 0 0';
 256         self.avelocity = '0 0 0';
 257         self.punchangle = '0 0 0';
 258         self.punchvector = '0 0 0';
 259         self.oldvelocity = self.velocity;
 260         self.fire_endtime = -1;
 261 }
 262
 263 .float model_randomizer;
 264 void FixPlayermodel()
 265 {
 266         string defaultmodel;
 267         float defaultskin, chmdl, oldskin, n, i;
 268         vector m1, m2;
 269
 270         defaultmodel = "";
 271         defaultskin = 0;
 272         chmdl = FALSE;
 273
 274         if(autocvar_sv_defaultcharacter == 1)
 275         {
 276                 if(teamplay)
 277                 {
 278                         string s;
 279                         s = Static_Team_ColorName_Lower(self.team);
 280                         if(s != "neutral")
 281                         {
 282                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 283                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 284                         }
 285                 }
 286
 287                 if(defaultmodel == "")
 288                 {
 289                         defaultmodel = autocvar_sv_defaultplayermodel;
 290                         defaultskin = autocvar_sv_defaultplayerskin;
 291                 }
 292
 293                 n = tokenize_console(defaultmodel);
 294                 if(n > 0)
 295                 {
 296                         defaultmodel = argv(floor(n * self.model_randomizer));
 297                         // However, do NOT randomize if the player-selected model is in the list.
 298                         for (i = 0; i < n; ++i)
 299                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 300                                         defaultmodel = argv(i);
 301                 }
 302
 303                 i = strstrofs(defaultmodel, ":", 0);
 304                 if(i >= 0)
 305                 {
 306                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 307                         defaultmodel = substring(defaultmodel, 0, i);
 308                 }
 309         }
 310
 311         if(defaultmodel != "")
 312         {
 313                 if (defaultmodel != self.model)
 314                 {
 315                         m1 = self.mins;
 316                         m2 = self.maxs;
 317                         setplayermodel (self, defaultmodel);
 318                         setsize (self, m1, m2);
 319                         chmdl = TRUE;
 320                 }
 321
 322                 oldskin = self.skin;
 323                 self.skin = defaultskin;
 324         } else {
 325                 if (self.playermodel != self.model || self.playermodel == "")
 326                 {
 327                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 328                         m1 = self.mins;
 329                         m2 = self.maxs;
 330                         setplayermodel (self, self.playermodel);
 331                         setsize (self, m1, m2);
 332                         chmdl = TRUE;
 333                 }
 334
 335                 oldskin = self.skin;
 336                 self.skin = stof(self.playerskin);
 337         }
 338
 339         if(chmdl || oldskin != self.skin) // model or skin has changed
 340         {
 341                 self.species = player_getspecies(); // update species
 342                 UpdatePlayerSounds(); // update skin sounds
 343         }
 344
 345         if(!teamplay)
 346                 if(strlen(autocvar_sv_defaultplayercolors))
 347                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 348                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 349 }
 350
 351 /*
 352 =============
 353 PutClientInServer
 354
 355 Called when a client spawns in the server
 356 =============
 357 */
 358 void PutClientInServer (void)
 359 {
 360         if(IS_BOT_CLIENT(self))
 361                 self.classname = "player";
 362         else if(IS_REAL_CLIENT(self))
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         // reset player keys
 370         self.itemkeys = 0;
 371
 372         MUTATOR_CALLHOOK(PutClientInServer);
 373
 374         if(gameover)
 375                 self.classname = "observer";
 376
 377         if(IS_PLAYER(self))
 378         {
 379                 entity spot, oldself;
 380                 float j;
 381
 382                 accuracy_resend(self);
 383
 384                 if(self.team < 0)
 385                         JoinBestTeam(self, FALSE, TRUE);
 386
 387                 spot = SelectSpawnPoint (FALSE);
 388                 if(!spot)
 389                 {
 390                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 391                         return; // spawn failed
 392                 }
 393
 394                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 395
 396                 if(self.vehicle)
 397                         vehicles_exit(VHEF_RELESE);
 398
 399                 self.classname = "player";
 400                 self.wasplayer = TRUE;
 401                 self.iscreature = TRUE;
 402                 self.teleportable = TELEPORT_NORMAL;
 403                 self.damagedbycontents = TRUE;
 404                 self.movetype = MOVETYPE_WALK;
 405                 self.solid = SOLID_SLIDEBOX;
 406                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 407                 if(autocvar_g_playerclip_collisions)
 408                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 409                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 410                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 411                 self.frags = FRAGS_PLAYER;
 412                 if(INDEPENDENT_PLAYERS)
 413                         MAKE_INDEPENDENT_PLAYER(self);
 414                 self.flags = FL_CLIENT;
 415                 if(autocvar__notarget)
 416                         self.flags |= FL_NOTARGET;
 417                 self.takedamage = DAMAGE_AIM;
 418                 self.effects = 0;
 419                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 420                 self.air_finished = time + 12;
 421                 self.dmg = 2;
 422                 if(autocvar_g_balance_nex_charge)
 423                 {
 424                         if(autocvar_g_balance_nex_secondary_chargepool)
 425                                 self.nex_chargepool_ammo = 1;
 426                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 427                 }
 428
 429                 if(warmup_stage)
 430                 {
 431                         self.ammo_shells = warmup_start_ammo_shells;
 432                         self.ammo_nails = warmup_start_ammo_nails;
 433                         self.ammo_rockets = warmup_start_ammo_rockets;
 434                         self.ammo_cells = warmup_start_ammo_cells;
 435                         self.ammo_fuel = warmup_start_ammo_fuel;
 436                         self.health = warmup_start_health;
 437                         self.armorvalue = warmup_start_armorvalue;
 438                         self.weapons = WARMUP_START_WEAPONS;
 439                 }
 440                 else
 441                 {
 442                         self.ammo_shells = start_ammo_shells;
 443                         self.ammo_nails = start_ammo_nails;
 444                         self.ammo_rockets = start_ammo_rockets;
 445                         self.ammo_cells = start_ammo_cells;
 446                         self.ammo_fuel = start_ammo_fuel;
 447                         self.health = start_health;
 448                         self.armorvalue = start_armorvalue;
 449                         self.weapons = start_weapons;
 450                 }
 451
 452                 if(self.weapons & WEPSET_SUPERWEAPONS)
 453                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 454                 else
 455                         self.superweapons_finished = 0;
 456
 457                 if(g_weaponarena_random)
 458                 {
 459                         if(g_weaponarena_random_with_laser)
 460                                 self.weapons &= ~WEPSET_LASER;
 461                         W_RandomWeapons(self, g_weaponarena_random);
 462                         if(g_weaponarena_random_with_laser)
 463                                 self.weapons |= WEPSET_LASER;
 464                 }
 465
 466                 self.items = start_items;
 467
 468                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 469                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 470                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 471                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 472                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 473                 //extend the pause of rotting if client was reset at the beginning of the countdown
 474                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 475                         self.spawnshieldtime += game_starttime - time;
 476                         self.pauserotarmor_finished += game_starttime - time;
 477                         self.pauserothealth_finished += game_starttime - time;
 478                         self.pauseregen_finished += game_starttime - time;
 479                 }
 480                 self.damageforcescale = 2;
 481                 self.death_time = 0;
 482                 self.respawn_flags = 0;
 483                 self.respawn_time = 0;
 484                 self.stat_respawn_time = 0;
 485                 self.scale = 0;
 486                 self.fade_time = 0;
 487                 self.pain_frame = 0;
 488                 self.pain_finished = 0;
 489                 self.strength_finished = 0;
 490                 self.invincible_finished = 0;
 491                 self.pushltime = 0;
 492                 // players have no think function
 493                 self.think = func_null;
 494                 self.nextthink = 0;
 495                 self.hook_time = 0;
 496                 self.dmg_team = 0;
 497                 self.ballistics_density = autocvar_g_ballistics_density_player;
 498
 499                 self.metertime = 0;
 500
 501                 self.deadflag = DEAD_NO;
 502
 503                 self.angles = spot.angles;
 504
 505                 self.angles_z = 0; // never spawn tilted even if the spot says to
 506                 self.fixangle = TRUE; // turn this way immediately
 507                 self.velocity = '0 0 0';
 508                 self.avelocity = '0 0 0';
 509                 self.punchangle = '0 0 0';
 510                 self.punchvector = '0 0 0';
 511                 self.oldvelocity = self.velocity;
 512                 self.fire_endtime = -1;
 513                 self.revival_time = 0;
 514
 515                 entity spawnevent = spawn();
 516                 spawnevent.owner = self;
 517                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 518
 519                 // Cut off any still running player sounds.
 520                 stopsound(self, CH_PLAYER_SINGLE);
 521
 522                 self.model = "";
 523                 FixPlayermodel();
 524                 self.drawonlytoclient = world;
 525
 526                 self.crouch = FALSE;
 527                 self.view_ofs = PL_VIEW_OFS;
 528                 setsize (self, PL_MIN, PL_MAX);
 529                 self.spawnorigin = spot.origin;
 530                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 531                 // don't reset back to last position, even if new position is stuck in solid
 532                 self.oldorigin = self.origin;
 533                 self.prevorigin = self.origin;
 534                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 535                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 536         self.hud = HUD_NORMAL;
 537
 538                 self.event_damage = PlayerDamage;
 539
 540                 self.bot_attack = TRUE;
 541                 self.monster_attack = TRUE;
 542
 543                 self.spider_slowness = 0;
 544
 545                 self.statdraintime = time + 5;
 546                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 547
 548                 if(self.killcount == -666) {
 549                         PlayerScore_Clear(self);
 550                         self.killcount = 0;
 551                 }
 552
 553                 CL_SpawnWeaponentity();
 554                 self.alpha = default_player_alpha;
 555                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 556                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 557
 558                 self.speedrunning = FALSE;
 559
 560                 //stuffcmd(self, "chase_active 0");
 561                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 562
 563                 target_voicescript_clear(self);
 564
 565                 // reset fields the weapons may use
 566                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 567                 {
 568                         weapon_action(j, WR_RESETPLAYER);
 569
 570                         // all weapons must be fully loaded when we spawn
 571                         entity e;
 572                         e = get_weaponinfo(j);
 573                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 574                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 575                 }
 576
 577                 oldself = self;
 578                 self = spot;
 579                         activator = oldself;
 580                                 string s;
 581                                 s = self.target;
 582                                 self.target = string_null;
 583                                 SUB_UseTargets();
 584                                 self.target = s;
 585                         activator = world;
 586                 self = oldself;
 587
 588                 Unfreeze(self);
 589
 590                 spawn_spot = spot;
 591                 MUTATOR_CALLHOOK(PlayerSpawn);
 592
 593                 if(autocvar_spawn_debug)
 594                 {
 595                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 596                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 597                 }
 598
 599                 self.switchweapon = w_getbestweapon(self);
 600                 self.cnt = -1; // W_LastWeapon will not complain
 601                 self.weapon = 0;
 602                 self.weaponname = "";
 603                 self.switchingweapon = 0;
 604
 605                 if(!warmup_stage)
 606                         if(!self.alivetime)
 607                                 self.alivetime = time;
 608
 609                 antilag_clear(self);
 610         }
 611         else if(IS_OBSERVER(self))
 612         {
 613                 PutObserverInServer ();
 614         }
 615 }
 616
 617 .float ebouncefactor, ebouncestop; // electro's values
 618 // TODO do we need all these fields, or should we stop autodetecting runtime
 619 // changes and just have a console command to update this?
 620 float ClientInit_SendEntity(entity to, float sf)
 621 {
 622         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 623         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 636         if(sv_foginterval && world.fog != "")
 637                 WriteString(MSG_ENTITY, world.fog);
 638         else
 639                 WriteString(MSG_ENTITY, "");
 640         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 641         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 642         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 643         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 644         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 645         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 646         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 647         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 648         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 649         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 650         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 651         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 652         return TRUE;
 653 }
 654
 655 void ClientInit_CheckUpdate()
 656 {
 657         self.nextthink = time;
 658         if(self.count != autocvar_g_balance_armor_blockpercent)
 659         {
 660                 self.count = autocvar_g_balance_armor_blockpercent;
 661                 self.SendFlags |= 1;
 662         }
 663         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 664         {
 665                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 666                 self.SendFlags |= 1;
 667         }
 668         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 669         {
 670                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 671                 self.SendFlags |= 1;
 672         }
 673         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 674         {
 675                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 676                 self.SendFlags |= 1;
 677         }
 678         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 679         {
 680                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 681                 self.SendFlags |= 1;
 682         }
 683 }
 684
 685 void ClientInit_Spawn()
 686 {
 687         entity o;
 688         entity e;
 689         e = spawn();
 690         e.classname = "clientinit";
 691         e.think = ClientInit_CheckUpdate;
 692         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 693
 694         o = self;
 695         self = e;
 696         ClientInit_CheckUpdate();
 697         self = o;
 698 }
 699
 700 /*
 701 =============
 702 SetNewParms
 703 =============
 704 */
 705 void SetNewParms (void)
 706 {
 707         // initialize parms for a new player
 708         parm1 = -(86400 * 366);
 709 }
 710
 711 /*
 712 =============
 713 SetChangeParms
 714 =============
 715 */
 716 void SetChangeParms (void)
 717 {
 718         // save parms for level change
 719         parm1 = self.parm_idlesince - time;
 720 }
 721
 722 /*
 723 =============
 724 DecodeLevelParms
 725 =============
 726 */
 727 void DecodeLevelParms (void)
 728 {
 729         // load parms
 730         self.parm_idlesince = parm1;
 731         if(self.parm_idlesince == -(86400 * 366))
 732                 self.parm_idlesince = time;
 733
 734         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 735         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 736 }
 737
 738 /*
 739 =============
 740 ClientKill
 741
 742 Called when a client types 'kill' in the console
 743 =============
 744 */
 745
 746 .float clientkill_nexttime;
 747 void ClientKill_Now_TeamChange()
 748 {
 749         if(self.killindicator_teamchange == -1)
 750         {
 751                 JoinBestTeam( self, FALSE, TRUE );
 752         }
 753         else if(self.killindicator_teamchange == -2)
 754         {
 755                 if(blockSpectators)
 756                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 757                 PutObserverInServer();
 758         }
 759         else
 760                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 761         self.killindicator_teamchange = 0;
 762 }
 763
 764 void ClientKill_Now()
 765 {
 766         if(self.vehicle)
 767         {
 768             vehicles_exit(VHEF_RELESE);
 769             if(!self.killindicator_teamchange)
 770             {
 771             self.vehicle_health = -1;
 772             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 773             }
 774         }
 775
 776         if(self.killindicator && !wasfreed(self.killindicator))
 777                 remove(self.killindicator);
 778
 779         self.killindicator = world;
 780
 781         if(self.killindicator_teamchange)
 782                 ClientKill_Now_TeamChange();
 783
 784         // in any case:
 785         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 786
 787         // now I am sure the player IS dead
 788 }
 789 void KillIndicator_Think()
 790 {
 791         if (gameover)
 792         {
 793                 self.owner.killindicator = world;
 794                 remove(self);
 795                 return;
 796         }
 797
 798         if (self.owner.alpha < 0 && !self.owner.vehicle)
 799         {
 800                 self.owner.killindicator = world;
 801                 remove(self);
 802                 return;
 803         }
 804
 805         if(self.cnt <= 0)
 806         {
 807                 self = self.owner;
 808                 ClientKill_Now(); // no oldself needed
 809                 return;
 810         }
 811     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 812     {
 813         self.nextthink = time + 1;
 814         self.cnt -= 1;
 815     }
 816         else
 817         {
 818                 if(self.cnt <= 10)
 819                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 820                 if(IS_REAL_CLIENT(self.owner))
 821                 {
 822                         if(self.cnt <= 10)
 823                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 824                 }
 825                 self.nextthink = time + 1;
 826                 self.cnt -= 1;
 827         }
 828 }
 829
 830 float clientkilltime;
 831 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 832 {
 833         float killtime;
 834         float starttime;
 835         entity e;
 836
 837         if (gameover)
 838                 return;
 839
 840         killtime = autocvar_g_balance_kill_delay;
 841
 842         if(g_race_qualifying || g_cts)
 843                 killtime = 0;
 844
 845     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 846     {
 847                 remove(self.killindicator);
 848                 self.killindicator = world;
 849
 850         ClientKill_Now(); // allow instant kill in this case
 851         return;
 852     }
 853
 854         self.killindicator_teamchange = targetteam;
 855
 856     if(!self.killindicator)
 857         {
 858                 if(self.deadflag == DEAD_NO)
 859                 {
 860                         killtime = max(killtime, self.clientkill_nexttime - time);
 861                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 862                 }
 863
 864                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 865                 {
 866                         ClientKill_Now();
 867                 }
 868                 else
 869                 {
 870                         starttime = max(time, clientkilltime);
 871
 872                         self.killindicator = spawn();
 873                         self.killindicator.owner = self;
 874                         self.killindicator.scale = 0.5;
 875                         setattachment(self.killindicator, self, "");
 876                         setorigin(self.killindicator, '0 0 52');
 877                         self.killindicator.think = KillIndicator_Think;
 878                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 879                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 880                         self.killindicator.cnt = ceil(killtime);
 881                         self.killindicator.count = bound(0, ceil(killtime), 10);
 882                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 883
 884                         for(e = world; (e = find(e, classname, "body")) != world; )
 885                         {
 886                                 if(e.enemy != self)
 887                                         continue;
 888                                 e.killindicator = spawn();
 889                                 e.killindicator.owner = e;
 890                                 e.killindicator.scale = 0.5;
 891                                 setattachment(e.killindicator, e, "");
 892                                 setorigin(e.killindicator, '0 0 52');
 893                                 e.killindicator.think = KillIndicator_Think;
 894                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 895                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 896                                 e.killindicator.cnt = ceil(killtime);
 897                         }
 898                         self.lip = 0;
 899                 }
 900         }
 901         if(self.killindicator)
 902         {
 903                 if(targetteam == 0) // just die
 904                 {
 905                         self.killindicator.colormod = '0 0 0';
 906                         if(IS_REAL_CLIENT(self))
 907                         if(self.killindicator.cnt > 0)
 908                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 909                 }
 910                 else if(targetteam == -1) // auto
 911                 {
 912                         self.killindicator.colormod = '0 1 0';
 913                         if(IS_REAL_CLIENT(self))
 914                         if(self.killindicator.cnt > 0)
 915                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 916                 }
 917                 else if(targetteam == -2) // spectate
 918                 {
 919                         self.killindicator.colormod = '0.5 0.5 0.5';
 920                         if(IS_REAL_CLIENT(self))
 921                         if(self.killindicator.cnt > 0)
 922                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 923                 }
 924                 else
 925                 {
 926                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 927                         if(IS_REAL_CLIENT(self))
 928                         if(self.killindicator.cnt > 0)
 929                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 930                 }
 931         }
 932
 933 }
 934
 935 void ClientKill (void)
 936 {
 937         if(gameover) return;
 938         if(self.player_blocked) return;
 939         if(self.frozen) return;
 940
 941         ClientKill_TeamChange(0);
 942 }
 943
 944 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 945 {
 946     e.killindicator = spawn();
 947     e.killindicator.owner = e;
 948     e.killindicator.think = KillIndicator_Think;
 949     e.killindicator.nextthink = time + (e.lip) * 0.05;
 950     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 951     e.killindicator.health = 1; // this is used to indicate that it should be silent
 952     e.lip = 0;
 953 }
 954
 955 void FixClientCvars(entity e)
 956 {
 957         // send prediction settings to the client
 958         stuffcmd(e, "\nin_bindmap 0 0\n");
 959         if(g_race || g_cts)
 960                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 961         if(autocvar_g_antilag == 3) // client side hitscan
 962                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 963         if(autocvar_sv_gentle)
 964                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 965         /*
 966          * we no longer need to stuff this. Remove this comment block if you feel
 967          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 968         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 969         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 970         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 971         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 972         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 973         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 974         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 975         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 976         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 977         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 978         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 979         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 980         stuffcmd(e, "cl_movement_edgefriction 1\n");
 981          */
 982 }
 983
 984 float PlayerInIDList(entity p, string idlist)
 985 {
 986         float n, i;
 987         string s;
 988
 989         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 990         if (!p.crypto_idfp)
 991                 return 0;
 992
 993         // this function allows abbreviated player IDs too!
 994         n = tokenize_console(idlist);
 995         for(i = 0; i < n; ++i)
 996         {
 997                 s = argv(i);
 998                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 999                         return 1;
1000         }
1001
1002         return 0;
1003 }
1004
1005 /*
1006 =============
1007 ClientConnect
1008
1009 Called when a client connects to the server
1010 =============
1011 */
1012 void DecodeLevelParms (void);
1013 //void dom_player_join_team(entity pl);
1014 void set_dom_state(entity e);
1015 void ClientConnect (void)
1016 {
1017         float t;
1018
1019         if(IS_CLIENT(self))
1020         {
1021                 print("Warning: ClientConnect, but already connected!\n");
1022                 return;
1023         }
1024
1025         if(Ban_MaybeEnforceBanOnce(self))
1026                 return;
1027
1028         DecodeLevelParms();
1029
1030 #ifdef WATERMARK
1031         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1032 #endif
1033
1034         self.classname = "player_joining";
1035
1036         self.flags = FL_CLIENT;
1037         self.version_nagtime = time + 10 + random() * 10;
1038
1039         if(player_count<0)
1040         {
1041                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1042                 player_count = 0;
1043         }
1044
1045         PlayerScore_Attach(self);
1046         ClientData_Attach();
1047         accuracy_init(self);
1048
1049         bot_clientconnect();
1050
1051         playerdemo_init();
1052
1053         anticheat_init();
1054
1055         // identify the right forced team
1056         if(autocvar_g_campaign)
1057         {
1058                 if(IS_REAL_CLIENT(self)) // only players, not bots
1059                 {
1060                         switch(autocvar_g_campaign_forceteam)
1061                         {
1062                                 case 1: self.team_forced = NUM_TEAM_1; break;
1063                                 case 2: self.team_forced = NUM_TEAM_2; break;
1064                                 case 3: self.team_forced = NUM_TEAM_3; break;
1065                                 case 4: self.team_forced = NUM_TEAM_4; break;
1066                                 default: self.team_forced = 0;
1067                         }
1068                 }
1069         }
1070         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1071                 self.team_forced = NUM_TEAM_1;
1072         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1073                 self.team_forced = NUM_TEAM_2;
1074         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1075                 self.team_forced = NUM_TEAM_3;
1076         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1077                 self.team_forced = NUM_TEAM_4;
1078         else if(autocvar_g_forced_team_otherwise == "red")
1079                 self.team_forced = NUM_TEAM_1;
1080         else if(autocvar_g_forced_team_otherwise == "blue")
1081                 self.team_forced = NUM_TEAM_2;
1082         else if(autocvar_g_forced_team_otherwise == "yellow")
1083                 self.team_forced = NUM_TEAM_3;
1084         else if(autocvar_g_forced_team_otherwise == "pink")
1085                 self.team_forced = NUM_TEAM_4;
1086         else if(autocvar_g_forced_team_otherwise == "spectate")
1087                 self.team_forced = -1;
1088         else if(autocvar_g_forced_team_otherwise == "spectator")
1089                 self.team_forced = -1;
1090         else
1091                 self.team_forced = 0;
1092
1093         if(!teamplay)
1094                 if(self.team_forced > 0)
1095                         self.team_forced = 0;
1096
1097         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1098
1099         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1100                 self.classname = "observer";
1101         } else {
1102                 if(teamplay)
1103                 {
1104                         if(autocvar_g_balance_teams)
1105                         {
1106                                 self.classname = "player";
1107                                 campaign_bots_may_start = 1;
1108                         }
1109                         else
1110                         {
1111                                 self.classname = "observer"; // do it anyway
1112                         }
1113                 }
1114                 else
1115                 {
1116                         self.classname = "player";
1117                         campaign_bots_may_start = 1;
1118                 }
1119         }
1120
1121         self.playerid = (playerid_last = playerid_last + 1);
1122
1123         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1124
1125     if(IS_BOT_CLIENT(self))
1126         PlayerStats_AddPlayer(self);
1127
1128         if(autocvar_sv_eventlog)
1129                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1130
1131         LogTeamchange(self.playerid, self.team, 1);
1132
1133         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1134
1135         self.netname_previous = strzone(self.netname);
1136
1137         if(IS_PLAYER(self) && teamplay)
1138                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1139         else
1140                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1141
1142         stuffcmd(self, strcat(clientstuff, "\n"));
1143         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1144
1145         FixClientCvars(self);
1146
1147         // spawnfunc_waypoint sprites
1148         WaypointSprite_InitClient(self);
1149
1150         // Wazat's grappling hook
1151         SetGrappleHookBindings();
1152
1153         // get version info from player
1154         stuffcmd(self, "cmd clientversion $gameversion\n");
1155
1156         // get other cvars from player
1157         GetCvars(0);
1158
1159         // notify about available teams
1160         if(teamplay)
1161         {
1162                 CheckAllowedTeams(self);
1163                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1164                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1165         }
1166         else
1167                 stuffcmd(self, "set _teams_available 0\n");
1168
1169         attach_entcs();
1170
1171         bot_relinkplayerlist();
1172
1173         self.spectatortime = time;
1174         if(blockSpectators)
1175         {
1176                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1177         }
1178
1179         self.jointime = time;
1180         self.allowed_timeouts = autocvar_sv_timeout_number;
1181
1182         if(IS_REAL_CLIENT(self))
1183         {
1184                 if(!autocvar_g_campaign)
1185                 {
1186                         self.motd_actived_time = -1;
1187                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1188                 }
1189
1190                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1191                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1192         }
1193
1194         if(!sv_foginterval && world.fog != "")
1195                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1196
1197         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1198         {
1199                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1200                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1201         }
1202         else
1203                 self.hitplotfh = -1;
1204
1205         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1206                 send_CSQC_teamnagger();
1207
1208         CheatInitClient();
1209
1210         CSQCMODEL_AUTOINIT();
1211
1212         self.model_randomizer = random();
1213
1214         if(IS_REAL_CLIENT(self))
1215                 sv_notice_join();
1216
1217         MUTATOR_CALLHOOK(ClientConnect);
1218 }
1219 /*
1220 =============
1221 ClientDisconnect
1222
1223 Called when a client disconnects from the server
1224 =============
1225 */
1226 .entity chatbubbleentity;
1227 void ReadyCount();
1228 void ClientDisconnect (void)
1229 {
1230         if(self.vehicle)
1231             vehicles_exit(VHEF_RELESE);
1232
1233         if (!IS_CLIENT(self))
1234         {
1235                 print("Warning: ClientDisconnect without ClientConnect\n");
1236                 return;
1237         }
1238
1239         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1240
1241         PlayerStats_AddGlobalInfo(self);
1242
1243         CheatShutdownClient();
1244
1245         if(self.hitplotfh >= 0)
1246         {
1247                 fclose(self.hitplotfh);
1248                 self.hitplotfh = -1;
1249         }
1250
1251         anticheat_report();
1252         anticheat_shutdown();
1253
1254         playerdemo_shutdown();
1255
1256         bot_clientdisconnect();
1257
1258         if(self.entcs)
1259                 detach_entcs();
1260
1261         if(autocvar_sv_eventlog)
1262                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1263
1264         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1265
1266         MUTATOR_CALLHOOK(ClientDisconnect);
1267
1268         Portal_ClearAll(self);
1269
1270         Unfreeze(self);
1271
1272         RemoveGrapplingHook(self);
1273
1274         // Here, everything has been done that requires this player to be a client.
1275
1276         self.flags &= ~FL_CLIENT;
1277
1278         if (self.chatbubbleentity)
1279                 remove (self.chatbubbleentity);
1280
1281         if (self.killindicator)
1282                 remove (self.killindicator);
1283
1284         WaypointSprite_PlayerGone();
1285
1286         bot_relinkplayerlist();
1287
1288         accuracy_free(self);
1289         ClientData_Detach();
1290         PlayerScore_Detach(self);
1291
1292         if(self.netname_previous)
1293                 strunzone(self.netname_previous);
1294         if(self.clientstatus)
1295                 strunzone(self.clientstatus);
1296         if(self.weaponorder_byimpulse)
1297                 strunzone(self.weaponorder_byimpulse);
1298
1299         ClearPlayerSounds();
1300
1301         if(self.personal)
1302                 remove(self.personal);
1303
1304         self.playerid = 0;
1305         ReadyCount();
1306
1307         // free cvars
1308         GetCvars(-1);
1309 }
1310
1311 .float BUTTON_CHAT;
1312 void ChatBubbleThink()
1313 {
1314         self.nextthink = time;
1315         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1316         {
1317                 if(self.owner) // but why can that ever be world?
1318                         self.owner.chatbubbleentity = world;
1319                 remove(self);
1320                 return;
1321         }
1322         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1323 #ifdef TETRIS
1324                 || self.owner.tetris_on
1325 #endif
1326         )
1327                 self.model = self.mdl;
1328         else
1329                 self.model = "";
1330 }
1331
1332 void UpdateChatBubble()
1333 {
1334         if (self.alpha < 0)
1335                 return;
1336         // spawn a chatbubble entity if needed
1337         if (!self.chatbubbleentity)
1338         {
1339                 self.chatbubbleentity = spawn();
1340                 self.chatbubbleentity.owner = self;
1341                 self.chatbubbleentity.exteriormodeltoclient = self;
1342                 self.chatbubbleentity.think = ChatBubbleThink;
1343                 self.chatbubbleentity.nextthink = time;
1344                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1345                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1346                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1347                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1348                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1349                 self.chatbubbleentity.model = "";
1350                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1351         }
1352 }
1353
1354
1355 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1356 // added to the model skins
1357 /*void UpdateColorModHack()
1358 {
1359         float c;
1360         c = self.clientcolors & 15;
1361         // LordHavoc: only bothering to support white, green, red, yellow, blue
1362              if (!teamplay) self.colormod = '0 0 0';
1363         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1364         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1365         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1366         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1367         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1368         else self.colormod = '1 1 1';
1369 }*/
1370
1371 void respawn(void)
1372 {
1373         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1374         {
1375                 self.solid = SOLID_NOT;
1376                 self.takedamage = DAMAGE_NO;
1377                 self.movetype = MOVETYPE_FLY;
1378                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1379                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1380                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1381                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1382                 if(autocvar_g_respawn_ghosts_maxtime)
1383                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1384         }
1385
1386         CopyBody(1);
1387
1388         self.effects |= EF_NODRAW; // prevent another CopyBody
1389         PutClientInServer();
1390 }
1391
1392 void play_countdown(float finished, string samp)
1393 {
1394         if(IS_REAL_CLIENT(self))
1395                 if(floor(finished - time - frametime) != floor(finished - time))
1396                         if(finished - time < 6)
1397                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1398 }
1399
1400 void player_powerups (void)
1401 {
1402         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1403         olditems = self.items;
1404
1405         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1406                 self.modelflags |= MF_ROCKET;
1407         else
1408                 self.modelflags &= ~MF_ROCKET;
1409
1410         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1411
1412         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1413                 return;
1414
1415         Fire_ApplyDamage(self);
1416         Fire_ApplyEffect(self);
1417
1418         if (!g_minstagib)
1419         {
1420                 if (self.items & IT_STRENGTH)
1421                 {
1422                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1423                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1424                         if (time > self.strength_finished)
1425                         {
1426                                 self.items = self.items - (self.items & IT_STRENGTH);
1427                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1428                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1429                         }
1430                 }
1431                 else
1432                 {
1433                         if (time < self.strength_finished)
1434                         {
1435                                 self.items = self.items | IT_STRENGTH;
1436                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1437                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1438                         }
1439                 }
1440                 if (self.items & IT_INVINCIBLE)
1441                 {
1442                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1443                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1444                         if (time > self.invincible_finished)
1445                         {
1446                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1447                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1448                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1449                         }
1450                 }
1451                 else
1452                 {
1453                         if (time < self.invincible_finished)
1454                         {
1455                                 self.items = self.items | IT_INVINCIBLE;
1456                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1457                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1458                         }
1459                 }
1460                 if (self.items & IT_SUPERWEAPON)
1461                 {
1462                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1463                         {
1464                                 self.superweapons_finished = 0;
1465                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1466                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1467                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1468                         }
1469                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1470                         {
1471                                 // don't let them run out
1472                         }
1473                         else
1474                         {
1475                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1476                                 if (time > self.superweapons_finished)
1477                                 {
1478                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1479                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1480                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1481                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1482                                 }
1483                         }
1484                 }
1485                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1486                 {
1487                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1488                         {
1489                                 self.items = self.items | IT_SUPERWEAPON;
1490                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1491                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1492                         }
1493                         else
1494                         {
1495                                 self.superweapons_finished = 0;
1496                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1497                         }
1498                 }
1499                 else
1500                 {
1501                         self.superweapons_finished = 0;
1502                 }
1503         }
1504
1505         if(autocvar_g_nodepthtestplayers)
1506                 self.effects = self.effects | EF_NODEPTHTEST;
1507
1508         if(autocvar_g_fullbrightplayers)
1509                 self.effects = self.effects | EF_FULLBRIGHT;
1510
1511         if (time >= game_starttime)
1512         if (time < self.spawnshieldtime)
1513                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1514
1515         MUTATOR_CALLHOOK(PlayerPowerups);
1516 }
1517
1518 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1519 {
1520         if(current > stable)
1521                 return current;
1522         else if(current > stable - 0.25) // when close enough, "snap"
1523                 return stable;
1524         else
1525                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1526 }
1527
1528 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1529 {
1530         if(current < stable)
1531                 return current;
1532         else if(current < stable + 0.25) // when close enough, "snap"
1533                 return stable;
1534         else
1535                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1536 }
1537
1538 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1539 {
1540         if(current > rotstable)
1541         {
1542                 if(rotframetime > 0)
1543                 {
1544                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1545                         current = max(rotstable, current - rotlinear * rotframetime);
1546                 }
1547         }
1548         else if(current < regenstable)
1549         {
1550                 if(regenframetime > 0)
1551                 {
1552                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1553                         current = min(regenstable, current + regenlinear * regenframetime);
1554                 }
1555         }
1556
1557         if(current > limit)
1558                 current = limit;
1559
1560         return current;
1561 }
1562
1563 void player_regen (void)
1564 {
1565         float max_mod, regen_mod, rot_mod, limit_mod;
1566         max_mod = regen_mod = rot_mod = limit_mod = 1;
1567         regen_mod_max = max_mod;
1568         regen_mod_regen = regen_mod;
1569         regen_mod_rot = rot_mod;
1570         regen_mod_limit = limit_mod;
1571         if(!MUTATOR_CALLHOOK(PlayerRegen))
1572         if(!self.frozen)
1573         {
1574                 float minh, mina, maxh, maxa, limith, limita;
1575                 maxh = autocvar_g_balance_health_rotstable;
1576                 maxa = autocvar_g_balance_armor_rotstable;
1577                 minh = autocvar_g_balance_health_regenstable;
1578                 mina = autocvar_g_balance_armor_regenstable;
1579                 limith = autocvar_g_balance_health_limit;
1580                 limita = autocvar_g_balance_armor_limit;
1581
1582                 max_mod = regen_mod_max;
1583                 regen_mod = regen_mod_regen;
1584                 rot_mod = regen_mod_rot;
1585                 limit_mod = regen_mod_limit;
1586
1587                 maxh = maxh * max_mod;
1588                 minh = minh * max_mod;
1589                 limith = limith * limit_mod;
1590                 limita = limita * limit_mod;
1591
1592                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1593                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1594         }
1595
1596         // if player rotted to death...  die!
1597         // check this outside above checks, as player may still be able to rot to death
1598         if(self.health < 1)
1599                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1600
1601         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1602         {
1603                 float minf, maxf, limitf;
1604
1605                 maxf = autocvar_g_balance_fuel_rotstable;
1606                 minf = autocvar_g_balance_fuel_regenstable;
1607                 limitf = autocvar_g_balance_fuel_limit;
1608
1609                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1610         }
1611 }
1612
1613 float zoomstate_set;
1614 void SetZoomState(float z)
1615 {
1616         if(z != self.zoomstate)
1617         {
1618                 self.zoomstate = z;
1619                 ClientData_Touch(self);
1620         }
1621         zoomstate_set = 1;
1622 }
1623
1624 void GetPressedKeys(void) {
1625         MUTATOR_CALLHOOK(GetPressedKeys);
1626         if (self.movement_x > 0) // get if movement keys are pressed
1627         {       // forward key pressed
1628                 self.pressedkeys |= KEY_FORWARD;
1629                 self.pressedkeys &= ~KEY_BACKWARD;
1630         }
1631         else if (self.movement_x < 0)
1632         {       // backward key pressed
1633                 self.pressedkeys |= KEY_BACKWARD;
1634                 self.pressedkeys &= ~KEY_FORWARD;
1635         }
1636         else
1637         {       // no x input
1638                 self.pressedkeys &= ~KEY_FORWARD;
1639                 self.pressedkeys &= ~KEY_BACKWARD;
1640         }
1641
1642         if (self.movement_y > 0)
1643         {       // right key pressed
1644                 self.pressedkeys |= KEY_RIGHT;
1645                 self.pressedkeys &= ~KEY_LEFT;
1646         }
1647         else if (self.movement_y < 0)
1648         {       // left key pressed
1649                 self.pressedkeys |= KEY_LEFT;
1650                 self.pressedkeys &= ~KEY_RIGHT;
1651         }
1652         else
1653         {       // no y input
1654                 self.pressedkeys &= ~KEY_RIGHT;
1655                 self.pressedkeys &= ~KEY_LEFT;
1656         }
1657
1658         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1659                 self.pressedkeys |= KEY_JUMP;
1660         else
1661                 self.pressedkeys &= ~KEY_JUMP;
1662         if (self.BUTTON_CROUCH)
1663                 self.pressedkeys |= KEY_CROUCH;
1664         else
1665                 self.pressedkeys &= ~KEY_CROUCH;
1666
1667         if (self.BUTTON_ATCK)
1668                 self.pressedkeys |= KEY_ATCK;
1669         else
1670                 self.pressedkeys &= ~KEY_ATCK;
1671         if (self.BUTTON_ATCK2)
1672                 self.pressedkeys |= KEY_ATCK2;
1673         else
1674                 self.pressedkeys &= ~KEY_ATCK2;
1675 }
1676
1677 /*
1678 ======================
1679 spectate mode routines
1680 ======================
1681 */
1682
1683 void SpectateCopy(entity spectatee) {
1684         other = spectatee;
1685         MUTATOR_CALLHOOK(SpectateCopy);
1686         self.armortype = spectatee.armortype;
1687         self.armorvalue = spectatee.armorvalue;
1688         self.ammo_cells = spectatee.ammo_cells;
1689         self.ammo_shells = spectatee.ammo_shells;
1690         self.ammo_nails = spectatee.ammo_nails;
1691         self.ammo_rockets = spectatee.ammo_rockets;
1692         self.ammo_fuel = spectatee.ammo_fuel;
1693         self.clip_load = spectatee.clip_load;
1694         self.clip_size = spectatee.clip_size;
1695         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1696         self.health = spectatee.health;
1697         self.impulse = 0;
1698         self.items = spectatee.items;
1699         self.last_pickup = spectatee.last_pickup;
1700         self.hit_time = spectatee.hit_time;
1701         self.metertime = spectatee.metertime;
1702         self.strength_finished = spectatee.strength_finished;
1703         self.invincible_finished = spectatee.invincible_finished;
1704         self.pressedkeys = spectatee.pressedkeys;
1705         self.weapons = spectatee.weapons;
1706         self.switchweapon = spectatee.switchweapon;
1707         self.switchingweapon = spectatee.switchingweapon;
1708         self.weapon = spectatee.weapon;
1709         self.nex_charge = spectatee.nex_charge;
1710         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1711         self.hagar_load = spectatee.hagar_load;
1712         self.minelayer_mines = spectatee.minelayer_mines;
1713         self.punchangle = spectatee.punchangle;
1714         self.view_ofs = spectatee.view_ofs;
1715         self.velocity = spectatee.velocity;
1716         self.dmg_take = spectatee.dmg_take;
1717         self.dmg_save = spectatee.dmg_save;
1718         self.dmg_inflictor = spectatee.dmg_inflictor;
1719         self.v_angle = spectatee.v_angle;
1720         self.angles = spectatee.v_angle;
1721         self.frozen = spectatee.frozen;
1722         self.revive_progress = spectatee.revive_progress;
1723         if(!self.BUTTON_USE)
1724                 self.fixangle = TRUE;
1725         setorigin(self, spectatee.origin);
1726         setsize(self, spectatee.mins, spectatee.maxs);
1727         SetZoomState(spectatee.zoomstate);
1728
1729     anticheat_spectatecopy(spectatee);
1730         self.hud = spectatee.hud;
1731         if(spectatee.vehicle)
1732     {
1733         self.fixangle = FALSE;
1734         //self.velocity = spectatee.vehicle.velocity;
1735         self.vehicle_health = spectatee.vehicle_health;
1736         self.vehicle_shield = spectatee.vehicle_shield;
1737         self.vehicle_energy = spectatee.vehicle_energy;
1738         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1739         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1740         self.vehicle_reload1 = spectatee.vehicle_reload1;
1741         self.vehicle_reload2 = spectatee.vehicle_reload2;
1742
1743         msg_entity = self;
1744
1745         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1746             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1747             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1748             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1749
1750         //WriteByte (MSG_ONE, SVC_SETVIEW);
1751         //    WriteEntity(MSG_ONE, self);
1752         //makevectors(spectatee.v_angle);
1753         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1754     }
1755 }
1756
1757 float SpectateUpdate() {
1758         if(!self.enemy)
1759             return 0;
1760
1761         if (self == self.enemy)
1762                 return 0;
1763
1764         if (!IS_PLAYER(self.enemy))
1765                 return 0;
1766
1767         SpectateCopy(self.enemy);
1768
1769         return 1;
1770 }
1771
1772
1773 float SpectateSet()
1774 {
1775         if(self.enemy.classname != "player")
1776                 return FALSE;
1777         /*if(self.enemy.vehicle)
1778         {
1779
1780                 msg_entity = self;
1781                 WriteByte(MSG_ONE, SVC_SETVIEW);
1782                 WriteEntity(MSG_ONE, self.enemy);
1783                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1784
1785                 self.movetype = MOVETYPE_NONE;
1786                 accuracy_resend(self);
1787         }
1788         else
1789         {*/
1790                 msg_entity = self;
1791                 WriteByte(MSG_ONE, SVC_SETVIEW);
1792                 WriteEntity(MSG_ONE, self.enemy);
1793                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1794                 self.movetype = MOVETYPE_NONE;
1795                 accuracy_resend(self);
1796
1797                 if(!SpectateUpdate())
1798                         PutObserverInServer();
1799         //}
1800         return TRUE;
1801 }
1802
1803 float Spectate(entity pl)
1804 {
1805         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1806         if(pl.team != self.team)
1807                 return 0;
1808
1809         self.enemy = pl;
1810         return SpectateSet();
1811 }
1812
1813 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1814 entity CA_SpectateNext(entity start) {
1815         if (start.team == self.team) {
1816                 return start;
1817         }
1818
1819         other = start;
1820         // continue from current player
1821         while(other && other.team != self.team) {
1822                 other = find(other, classname, "player");
1823         }
1824
1825         if (!other) {
1826                 // restart from begining
1827                 other = find(other, classname, "player");
1828                 while(other && other.team != self.team) {
1829                         other = find(other, classname, "player");
1830                 }
1831         }
1832
1833         return other;
1834 }
1835
1836 float SpectateNext()
1837 {
1838         other = find(self.enemy, classname, "player");
1839
1840         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1841                 // CA and ca players when spectating enemies is forbidden
1842                 other = CA_SpectateNext(other);
1843         } else {
1844                 // other modes and ca spectators or spectating enemies is allowed
1845                 if (!other)
1846                         other = find(other, classname, "player");
1847         }
1848
1849         if (other)
1850                 self.enemy = other;
1851
1852         return SpectateSet();
1853 }
1854
1855 float SpectatePrev()
1856 {
1857         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1858         other = findchain(classname, "player");
1859         if (!other) // no player
1860                 return FALSE;
1861
1862         entity first = other;
1863         // skip players until current spectated player
1864         if(self.enemy)
1865         while(other && other != self.enemy)
1866                 other = other.chain;
1867
1868         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1869         {
1870                 do { other = other.chain; }
1871                 while(other && other.team != self.team);
1872
1873                 if (!other)
1874                 {
1875                         other = first;
1876                         while(other.team != self.team)
1877                                 other = other.chain;
1878                         if(other == self.enemy)
1879                                 return TRUE;
1880                 }
1881         }
1882         else
1883         {
1884                 if(other.chain)
1885                         other = other.chain;
1886                 else
1887                         other = first;
1888         }
1889         self.enemy = other;
1890         return SpectateSet();
1891 }
1892
1893 /*
1894 =============
1895 ShowRespawnCountdown()
1896
1897 Update a respawn countdown display.
1898 =============
1899 */
1900 void ShowRespawnCountdown()
1901 {
1902         float number;
1903         if(self.deadflag == DEAD_NO) // just respawned?
1904                 return;
1905         else
1906         {
1907                 number = ceil(self.respawn_time - time);
1908                 if(number <= 0)
1909                         return;
1910                 if(number <= self.respawn_countdown)
1911                 {
1912                         self.respawn_countdown = number - 1;
1913                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1914                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1915                 }
1916         }
1917 }
1918
1919 void LeaveSpectatorMode()
1920 {
1921         if(self.caplayer)
1922                 return;
1923         if(nJoinAllowed(self))
1924         {
1925                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1926                 {
1927                         self.classname = "player";
1928                         nades_RemoveBonus(self);
1929
1930                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1931                                 { JoinBestTeam(self, FALSE, TRUE); }
1932
1933                         if(autocvar_g_campaign)
1934                                 { campaign_bots_may_start = 1; }
1935
1936                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1937
1938                         PutClientInServer();
1939
1940                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1941                 }
1942                 else
1943                         stuffcmd(self, "menu_showteamselect\n");
1944         }
1945         else
1946         {
1947                 // Player may not join because g_maxplayers is set
1948                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1949         }
1950 }
1951
1952 /**
1953  * Determines whether the player is allowed to join. This depends on cvar
1954  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1955  * it checks whether the number of currently playing players exceeds g_maxplayers.
1956  * @return int number of free slots for players, 0 if none
1957  */
1958 float nJoinAllowed(entity ignore) {
1959         if(!ignore)
1960         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1961         // so report 0 free slots if restricted
1962         {
1963                 if(autocvar_g_forced_team_otherwise == "spectate")
1964                         return 0;
1965                 if(autocvar_g_forced_team_otherwise == "spectator")
1966                         return 0;
1967         }
1968
1969         if(self.team_forced < 0)
1970                 return 0; // forced spectators can never join
1971
1972         // TODO simplify this
1973         entity e;
1974         float totalClients = 0;
1975         FOR_EACH_CLIENT(e)
1976                 if(e != ignore)
1977                         totalClients += 1;
1978
1979         if (!autocvar_g_maxplayers)
1980                 return maxclients - totalClients;
1981
1982         float currentlyPlaying = 0;
1983         FOR_EACH_REALCLIENT(e)
1984                 if(IS_PLAYER(e) || e.caplayer == 1)
1985                         currentlyPlaying += 1;
1986
1987         if(currentlyPlaying < autocvar_g_maxplayers)
1988                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1989
1990         return 0;
1991 }
1992
1993 /**
1994  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1995  * g_maxplayers_spectator_blocktime seconds
1996  */
1997 void checkSpectatorBlock() {
1998         if(IS_SPEC(self) || IS_OBSERVER(self)) {
1999                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2000                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2001                         dropclient(self);
2002                 }
2003         }
2004 }
2005
2006 void PrintWelcomeMessage()
2007 {
2008         if(self.motd_actived_time == 0)
2009         {
2010                 if (autocvar_g_campaign) {
2011                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2012                                 self.motd_actived_time = time;
2013                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2014                         }
2015                 } else {
2016                         if (self.BUTTON_INFO) {
2017                                 self.motd_actived_time = time;
2018                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2019                         }
2020                 }
2021         }
2022         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2023         {
2024                 if (autocvar_g_campaign) {
2025                         if (self.BUTTON_INFO)
2026                                 self.motd_actived_time = time;
2027                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2028                                 self.motd_actived_time = 0;
2029                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2030                         }
2031                 } else {
2032                         if (self.BUTTON_INFO)
2033                                 self.motd_actived_time = time;
2034                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2035                                 self.motd_actived_time = 0;
2036                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2037                         }
2038                 }
2039         }
2040         else //if(self.motd_actived_time < 0) // just connected, motd is active
2041         {
2042                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2043                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2044                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2045                 {
2046                         // instanctly hide MOTD
2047                         self.motd_actived_time = 0;
2048                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2049                 }
2050         }
2051 }
2052
2053 void ObserverThink()
2054 {
2055         float prefered_movetype;
2056         if (self.flags & FL_JUMPRELEASED) {
2057                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2058                         self.flags &= ~FL_JUMPRELEASED;
2059                         self.flags |= FL_SPAWNING;
2060                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2061                         self.flags &= ~FL_JUMPRELEASED;
2062                         if(SpectateNext()) {
2063                                 self.classname = "spectator";
2064                         }
2065                 } else {
2066                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2067                         if (self.movetype != prefered_movetype)
2068                                 self.movetype = prefered_movetype;
2069                 }
2070         } else {
2071                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2072                         self.flags |= FL_JUMPRELEASED;
2073                         if(self.flags & FL_SPAWNING)
2074                         {
2075                                 self.flags &= ~FL_SPAWNING;
2076                                 LeaveSpectatorMode();
2077                                 return;
2078                         }
2079                 }
2080         }
2081 }
2082
2083 void SpectatorThink()
2084 {
2085         if (self.flags & FL_JUMPRELEASED) {
2086                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2087                         self.flags &= ~FL_JUMPRELEASED;
2088                         self.flags |= FL_SPAWNING;
2089                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2090                         self.flags &= ~FL_JUMPRELEASED;
2091                         if(SpectateNext()) {
2092                                 self.classname = "spectator";
2093                         } else {
2094                                 self.classname = "observer";
2095                                 PutClientInServer();
2096                         }
2097                         self.impulse = 0;
2098                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2099                         self.flags &= ~FL_JUMPRELEASED;
2100                         if(SpectatePrev()) {
2101                                 self.classname = "spectator";
2102                         } else {
2103                                 self.classname = "observer";
2104                                 PutClientInServer();
2105                         }
2106                         self.impulse = 0;
2107                 } else if (self.BUTTON_ATCK2) {
2108                         self.flags &= ~FL_JUMPRELEASED;
2109                         self.classname = "observer";
2110                         PutClientInServer();
2111                 } else {
2112                         if(!SpectateUpdate())
2113                                 PutObserverInServer();
2114                 }
2115         } else {
2116                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2117                         self.flags |= FL_JUMPRELEASED;
2118                         if(self.flags & FL_SPAWNING)
2119                         {
2120                                 self.flags &= ~FL_SPAWNING;
2121                                 LeaveSpectatorMode();
2122                                 return;
2123                         }
2124                 }
2125                 if(!SpectateUpdate())
2126                         PutObserverInServer();
2127         }
2128
2129         self.flags |= FL_CLIENT | FL_NOTARGET;
2130 }
2131
2132 void PlayerUseKey()
2133 {
2134         if (!IS_PLAYER(self))
2135                 return;
2136
2137         if(self.vehicle)
2138         {
2139         vehicles_exit(VHEF_NORMAL);
2140         return;
2141         }
2142
2143         // a use key was pressed; call handlers
2144         MUTATOR_CALLHOOK(PlayerUseKey);
2145 }
2146
2147 /*
2148 =============
2149 PlayerPreThink
2150
2151 Called every frame for each client before the physics are run
2152 =============
2153 */
2154 .float usekeypressed;
2155 void() nexball_setstatus;
2156 .float items_added;
2157 void PlayerPreThink (void)
2158 {
2159         WarpZone_PlayerPhysics_FixVAngle();
2160
2161         self.stat_game_starttime = game_starttime;
2162         self.stat_round_starttime = round_starttime;
2163         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2164         self.stat_leadlimit = autocvar_leadlimit;
2165
2166         if(frametime)
2167         {
2168                 // physics frames: update anticheat stuff
2169                 anticheat_prethink();
2170         }
2171
2172         if(blockSpectators && frametime)
2173                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2174                 checkSpectatorBlock();
2175
2176         zoomstate_set = 0;
2177
2178         if(self.netname_previous != self.netname)
2179         {
2180                 if(autocvar_sv_eventlog)
2181                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2182                 if(self.netname_previous)
2183                         strunzone(self.netname_previous);
2184                 self.netname_previous = strzone(self.netname);
2185         }
2186
2187         // version nagging
2188         if(self.version_nagtime)
2189                 if(self.cvar_g_xonoticversion)
2190                         if(time > self.version_nagtime)
2191                         {
2192                                 // don't notify git users
2193                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2194                                 {
2195                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2196                                         {
2197                                                 // notify release users if connecting to git
2198                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2199                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2200                                         }
2201                                         else
2202                                         {
2203                                                 float r;
2204                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2205                                                 if(r < 0)
2206                                                 {
2207                                                         // give users new version
2208                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2209                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2210                                                 }
2211                                                 else if(r > 0)
2212                                                 {
2213                                                         // notify users about old server version
2214                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2215                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2216                                                 }
2217                                         }
2218                                 }
2219                                 self.version_nagtime = 0;
2220                         }
2221
2222         // GOD MODE info
2223         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2224         {
2225                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2226                 self.max_armorvalue = 0;
2227         }
2228
2229 #ifdef TETRIS
2230         if (TetrisPreFrame())
2231                 return;
2232 #endif
2233
2234         if(self.frozen == 2)
2235         {
2236                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2237                 self.health = max(1, self.revive_progress * start_health);
2238                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2239
2240                 if(self.revive_progress >= 1)
2241                         Unfreeze(self);
2242         }
2243         else if(self.frozen == 3)
2244         {
2245                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2246                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2247
2248                 if(self.health < 1)
2249                 {
2250                         if(self.vehicle)
2251                                 vehicles_exit(VHEF_RELESE);
2252                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2253                 }
2254                 else if ( self.revive_progress <= 0 )
2255                         Unfreeze(self);
2256         }
2257
2258         MUTATOR_CALLHOOK(PlayerPreThink);
2259
2260         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2261         {
2262                 if(self.BUTTON_USE && !self.usekeypressed)
2263                         PlayerUseKey();
2264                 self.usekeypressed = self.BUTTON_USE;
2265         }
2266
2267         if(IS_REAL_CLIENT(self))
2268                 PrintWelcomeMessage();
2269
2270         if(IS_PLAYER(self))
2271         {
2272
2273                 CheckRules_Player();
2274
2275                 if (intermission_running)
2276                 {
2277                         IntermissionThink ();   // otherwise a button could be missed between
2278                         return;                                 // the think tics
2279                 }
2280
2281                 //don't allow the player to turn around while game is paused!
2282                 if(timeout_status == TIMEOUT_ACTIVE) {
2283                         // FIXME turn this into CSQC stuff
2284                         self.v_angle = self.lastV_angle;
2285                         self.angles = self.lastV_angle;
2286                         self.fixangle = TRUE;
2287                 }
2288
2289                 if(frametime)
2290                 {
2291                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2292                         {
2293                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2294                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2295                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2296
2297                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2298                                 {
2299                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2300                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2301                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2302                                 }
2303                         }
2304                         else
2305                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2306
2307                         player_powerups();
2308                 }
2309
2310                 if (self.deadflag != DEAD_NO)
2311                 {
2312                         if(self.personal && g_race_qualifying)
2313                         {
2314                                 if(time > self.respawn_time)
2315                                 {
2316                                         self.respawn_time = time + 1; // only retry once a second
2317                                         self.stat_respawn_time = self.respawn_time;
2318                                         respawn();
2319                                         self.impulse = 141;
2320                                 }
2321                         }
2322                         else
2323                         {
2324                                 float button_pressed;
2325                                 if(frametime)
2326                                         player_anim();
2327                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2328
2329                                 if (self.deadflag == DEAD_DYING)
2330                                 {
2331                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2332                                                 self.deadflag = DEAD_RESPAWNING;
2333                                         else if(!button_pressed)
2334                                                 self.deadflag = DEAD_DEAD;
2335                                 }
2336                                 else if (self.deadflag == DEAD_DEAD)
2337                                 {
2338                                         if(button_pressed)
2339                                                 self.deadflag = DEAD_RESPAWNABLE;
2340                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2341                                                 self.deadflag = DEAD_RESPAWNING;
2342                                 }
2343                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2344                                 {
2345                                         if(!button_pressed)
2346                                                 self.deadflag = DEAD_RESPAWNING;
2347                                 }
2348                                 else if (self.deadflag == DEAD_RESPAWNING)
2349                                 {
2350                                         if(time > self.respawn_time)
2351                                         {
2352                                                 self.respawn_time = time + 1; // only retry once a second
2353                                                 self.respawn_time_max = self.respawn_time;
2354                                                 respawn();
2355                                         }
2356                                 }
2357
2358                                 ShowRespawnCountdown();
2359
2360                                 if(self.respawn_flags & RESPAWN_SILENT)
2361                                         self.stat_respawn_time = 0;
2362                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2363                                         self.stat_respawn_time = self.respawn_time_max;
2364                                 else
2365                                         self.stat_respawn_time = self.respawn_time;
2366                         }
2367
2368                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2369                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2370                                 self.stat_respawn_time *= -1;
2371
2372                         return;
2373                 }
2374
2375                 self.prevorigin = self.origin;
2376
2377                 float do_crouch = self.BUTTON_CROUCH;
2378                 if(self.hook.state)
2379                         do_crouch = 0;
2380                 if(self.vehicle)
2381                         do_crouch = 0;
2382                 if(self.frozen)
2383                         do_crouch = 0;
2384                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2385                         do_crouch = 0;
2386
2387                 if (do_crouch)
2388                 {
2389                         if (!self.crouch)
2390                         {
2391                                 self.crouch = TRUE;
2392                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2393                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2394                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2395                         }
2396                 }
2397                 else
2398                 {
2399                         if (self.crouch)
2400                         {
2401                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2402                                 if (!trace_startsolid)
2403                                 {
2404                                         self.crouch = FALSE;
2405                                         self.view_ofs = PL_VIEW_OFS;
2406                                         setsize (self, PL_MIN, PL_MAX);
2407                                 }
2408                         }
2409                 }
2410
2411                 FixPlayermodel();
2412
2413                 GrapplingHookFrame();
2414
2415                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2416                 //if(frametime)
2417                 {
2418                         self.items &= ~self.items_added;
2419
2420                         W_WeaponFrame();
2421
2422                         self.items_added = 0;
2423                         if(self.items & IT_JETPACK)
2424                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2425                                         self.items_added |= IT_FUEL;
2426
2427                         self.items |= self.items_added;
2428                 }
2429
2430                 player_regen();
2431
2432                 // rot nex charge to the charge limit
2433                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2434                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2435
2436                 if(frametime)
2437                         player_anim();
2438
2439                 // secret status
2440                 secrets_setstatus();
2441
2442                 // monsters status
2443                 monsters_setstatus();
2444
2445                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2446
2447                 //self.angles_y=self.v_angle_y + 90;   // temp
2448         } else if(gameover) {
2449                 if (intermission_running)
2450                         IntermissionThink ();   // otherwise a button could be missed between
2451                 return;
2452         } else if(IS_OBSERVER(self)) {
2453                 ObserverThink();
2454         } else if(IS_SPEC(self)) {
2455                 SpectatorThink();
2456         }
2457
2458         if(!zoomstate_set)
2459                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2460
2461         float oldspectatee_status;
2462         oldspectatee_status = self.spectatee_status;
2463         if(IS_SPEC(self))
2464                 self.spectatee_status = num_for_edict(self.enemy);
2465         else if(IS_OBSERVER(self))
2466                 self.spectatee_status = num_for_edict(self);
2467         else
2468                 self.spectatee_status = 0;
2469         if(self.spectatee_status != oldspectatee_status)
2470         {
2471                 ClientData_Touch(self);
2472         }
2473
2474         if(self.teamkill_soundtime)
2475         if(time > self.teamkill_soundtime)
2476         {
2477                 self.teamkill_soundtime = 0;
2478
2479                 entity oldpusher, oldself;
2480
2481                 oldself = self; self = self.teamkill_soundsource;
2482                 oldpusher = self.pusher; self.pusher = oldself;
2483
2484                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2485
2486                 self.pusher = oldpusher;
2487                 self = oldself;
2488         }
2489
2490         if(self.taunt_soundtime)
2491         if(time > self.taunt_soundtime)
2492         {
2493                 self.taunt_soundtime = 0;
2494                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2495         }
2496
2497         target_voicescript_next(self);
2498
2499         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2500         if(!self.weapon)
2501                 self.clip_load = self.clip_size = 0;
2502 }
2503
2504 float isInvisibleString(string s)
2505 {
2506         float i, n, c;
2507         s = strdecolorize(s);
2508         for((i = 0), (n = strlen(s)); i < n; ++i)
2509         {
2510                 c = str2chr(s, i);
2511                 switch(c)
2512                 {
2513                         case 0:
2514                         case 32: // space
2515                                 break;
2516                         case 192: // charmap space
2517                                 if (!autocvar_utf8_enable)
2518                                         break;
2519                                 return FALSE;
2520                         case 160: // space in unicode fonts
2521                         case 0xE000 + 192: // utf8 charmap space
2522                                 if (autocvar_utf8_enable)
2523                                         break;
2524                         default:
2525                                 return FALSE;
2526                 }
2527         }
2528         return TRUE;
2529 }
2530
2531 /*
2532 =============
2533 PlayerPostThink
2534
2535 Called every frame for each client after the physics are run
2536 =============
2537 */
2538 .float idlekick_lasttimeleft;
2539 void PlayerPostThink (void)
2540 {
2541         // Savage: Check for nameless players
2542         if (isInvisibleString(self.netname)) {
2543                 self.netname = "Player";
2544                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2545         }
2546
2547         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2548         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2549         {
2550                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2551                 {
2552                         if(self.idlekick_lasttimeleft)
2553                         {
2554                                 self.idlekick_lasttimeleft = 0;
2555                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2556                         }
2557                 }
2558                 else
2559                 {
2560                         float timeleft;
2561                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2562                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2563                         {
2564                                 if(!self.idlekick_lasttimeleft)
2565                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2566                         }
2567                         if(timeleft <= 0)
2568                         {
2569                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2570                                 dropclient(self);
2571                                 return;
2572                         }
2573                         else if(timeleft <= 10)
2574                         {
2575                                 if(timeleft != self.idlekick_lasttimeleft)
2576                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2577                                 self.idlekick_lasttimeleft = timeleft;
2578                         }
2579                 }
2580         }
2581
2582 #ifdef TETRIS
2583         if(self.impulse == 100)
2584                 ImpulseCommands();
2585         if (!TetrisPostFrame())
2586         {
2587 #endif
2588
2589         CheatFrame();
2590
2591         //CheckPlayerJump();
2592
2593         if(IS_PLAYER(self)) {
2594                 CheckRules_Player();
2595                 UpdateChatBubble();
2596                 if (self.impulse)
2597                         ImpulseCommands();
2598                 if (intermission_running)
2599                         return;         // intermission or finale
2600                 GetPressedKeys();
2601         }
2602
2603 #ifdef TETRIS
2604         }
2605 #endif
2606
2607         /*
2608         float i;
2609         for(i = 0; i < 1000; ++i)
2610         {
2611                 vector end;
2612                 end = self.origin + '0 0 1024' + 512 * randomvec();
2613                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2614                 if(trace_fraction < 1)
2615                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2616                 {
2617                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2618                         break;
2619                 }
2620         }
2621         */
2622
2623         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2624
2625         if(self.waypointsprite_attachedforcarrier)
2626                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2627
2628         playerdemo_write();
2629
2630         CSQCMODEL_AUTOUPDATE();
2631 }