qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap();
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         if (g_minstagib)
 408                 minstagib_stop_countdown();
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         if(self.ballcarried && g_nexball)
 425                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 426
 427         WaypointSprite_PlayerDead();
 428
 429         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 430                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 431
 432         if(self.killcount != -666) {
 433                 if(g_lms) {
 434                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 435                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 436                         else
 437                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 438                 } else
 439                         bprint ("^4", self.netname, "^4 is spectating now\n");
 440
 441                 if(self.just_joined == FALSE) {
 442                         LogTeamchange(self.playerid, -1, 4);
 443                 } else
 444                         self.just_joined = FALSE;
 445         }
 446
 447         PlayerScore_Clear(self); // clear scores when needed
 448
 449         accuracy_resend(self);
 450
 451         self.spectatortime = time;
 452
 453         self.classname = "observer";
 454         self.iscreature = FALSE;
 455         self.damagedbycontents = FALSE;
 456         self.health = -666;
 457         self.takedamage = DAMAGE_NO;
 458         self.solid = SOLID_NOT;
 459         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 460         self.flags = FL_CLIENT | FL_NOTARGET;
 461         self.armorvalue = 666;
 462         self.effects = 0;
 463         self.armorvalue = autocvar_g_balance_armor_start;
 464         self.pauserotarmor_finished = 0;
 465         self.pauserothealth_finished = 0;
 466         self.pauseregen_finished = 0;
 467         self.damageforcescale = 0;
 468         self.death_time = 0;
 469         self.dead_frame = 0;
 470         self.alpha = 0;
 471         self.scale = 0;
 472         self.fade_time = 0;
 473         self.pain_frame = 0;
 474         self.pain_finished = 0;
 475         self.strength_finished = 0;
 476         self.invincible_finished = 0;
 477         self.pushltime = 0;
 478         self.think = SUB_Null;
 479         self.nextthink = 0;
 480         self.hook_time = 0;
 481         self.runes = 0;
 482         self.deadflag = DEAD_NO;
 483         self.angles = spot.angles;
 484         self.angles_z = 0;
 485         self.fixangle = TRUE;
 486         self.crouch = FALSE;
 487
 488         setorigin (self, spot.origin);
 489         self.prevorigin = self.origin;
 490         self.items = 0;
 491         self.weapons = 0;
 492         self.model = "";
 493         FixPlayermodel();
 494         setmodel(self, "null");
 495         self.drawonlytoclient = self;
 496
 497         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 498         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 499
 500         self.weapon = 0;
 501         self.weaponname = "";
 502         self.switchingweapon = 0;
 503         self.weaponmodel = "";
 504         self.weaponentity = world;
 505         self.exteriorweaponentity = world;
 506         self.killcount = -666;
 507         self.velocity = '0 0 0';
 508         self.avelocity = '0 0 0';
 509         self.punchangle = '0 0 0';
 510         self.punchvector = '0 0 0';
 511         self.oldvelocity = self.velocity;
 512         self.fire_endtime = -1;
 513
 514         if(g_arena)
 515         {
 516                 if(self.version_mismatch)
 517                 {
 518                         Spawnqueue_Unmark(self);
 519                         Spawnqueue_Remove(self);
 520                 }
 521                 else
 522                 {
 523                         Spawnqueue_Insert(self);
 524                 }
 525         }
 526         else if(g_lms)
 527         {
 528                 // Only if the player cannot play at all
 529                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 530                         self.frags = FRAGS_SPECTATOR;
 531                 else
 532                         self.frags = FRAGS_LMS_LOSER;
 533         }
 534         else if(g_ca)
 535         {
 536                 if(self.caplayer)
 537                         self.frags = FRAGS_LMS_LOSER;
 538                 else
 539                         self.frags = FRAGS_SPECTATOR;
 540         }
 541         else
 542                 self.frags = FRAGS_SPECTATOR;
 543 }
 544
 545 .float model_randomizer;
 546 void FixPlayermodel()
 547 {
 548         string defaultmodel;
 549         float defaultskin, chmdl, oldskin, n, i;
 550         vector m1, m2;
 551
 552         defaultmodel = "";
 553
 554         if(autocvar_sv_defaultcharacter == 1)
 555         {
 556                 defaultskin = 0;
 557
 558                 if(teamplay)
 559                 {
 560                         string s;
 561                         s = Team_ColorNameLowerCase(self.team);
 562                         if(s != "neutral")
 563                         {
 564                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 565                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 566                         }
 567                 }
 568
 569                 if(defaultmodel == "")
 570                 {
 571                         defaultmodel = autocvar_sv_defaultplayermodel;
 572                         defaultskin = autocvar_sv_defaultplayerskin;
 573                 }
 574
 575                 n = tokenize_console(defaultmodel);
 576                 if(n > 0)
 577                         defaultmodel = argv(floor(n * self.model_randomizer));
 578
 579                 i = strstrofs(defaultmodel, ":", 0);
 580                 if(i >= 0)
 581                 {
 582                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 583                         defaultmodel = substring(defaultmodel, 0, i);
 584                 }
 585         }
 586
 587         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 588         {
 589                 if(self.model != "")
 590                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 591                 self.model = ""; // force the != checks to return true
 592         }
 593
 594         if(defaultmodel != "")
 595         {
 596                 if (defaultmodel != self.model)
 597                 {
 598                         m1 = self.mins;
 599                         m2 = self.maxs;
 600                         setplayermodel (self, defaultmodel);
 601                         setsize (self, m1, m2);
 602                         chmdl = TRUE;
 603                 }
 604
 605                 oldskin = self.skin;
 606                 self.skin = defaultskin;
 607         } else {
 608                 if (self.playermodel != self.model || self.playermodel == "")
 609                 {
 610                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 611                         m1 = self.mins;
 612                         m2 = self.maxs;
 613                         setplayermodel (self, self.playermodel);
 614                         setsize (self, m1, m2);
 615                         chmdl = TRUE;
 616                 }
 617
 618                 oldskin = self.skin;
 619                 self.skin = stof(self.playerskin);
 620         }
 621
 622         if(chmdl || oldskin != self.skin)
 623                 self.species = player_getspecies(); // model or skin has changed
 624
 625         if(!teamplay)
 626                 if(strlen(autocvar_sv_defaultplayercolors))
 627                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 628                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 629 }
 630
 631 void PlayerTouchExplode(entity p1, entity p2)
 632 {
 633         vector org;
 634         org = (p1.origin + p2.origin) * 0.5;
 635         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 636
 637         te_explosion(org);
 638
 639         entity e;
 640         e = spawn();
 641         setorigin(e, org);
 642         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 643         remove(e);
 644 }
 645
 646 /*
 647 =============
 648 PutClientInServer
 649
 650 Called when a client spawns in the server
 651 =============
 652 */
 653 //void() ctf_playerchanged;
 654 void PutClientInServer (void)
 655 {
 656         if(clienttype(self) == CLIENTTYPE_BOT)
 657         {
 658                 self.classname = "player";
 659         }
 660         else if(clienttype(self) == CLIENTTYPE_REAL)
 661         {
 662                 msg_entity = self;
 663                 WriteByte(MSG_ONE, SVC_SETVIEW);
 664                 WriteEntity(MSG_ONE, self);
 665         }
 666
 667         // reset player keys
 668         self.itemkeys = 0;
 669
 670         // player is dead and becomes observer
 671         // FIXME fix LMS scoring for new system
 672         if(g_lms)
 673         {
 674                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 675                         self.classname = "observer";
 676         }
 677
 678         if(g_arena || (g_ca && !allowed_to_spawn))
 679         if(!self.spawned)
 680                 self.classname = "observer";
 681
 682         if(gameover)
 683                 self.classname = "observer";
 684
 685         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 686                 entity spot, oldself;
 687                 float j;
 688
 689                 accuracy_resend(self);
 690
 691                 if(self.team < 0)
 692                         JoinBestTeam(self, FALSE, TRUE);
 693
 694                 race_PreSpawn();
 695
 696                 spot = SelectSpawnPoint (FALSE);
 697                 if(!spot)
 698                 {
 699                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 700                         return; // spawn failed
 701                 }
 702
 703                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 704
 705                 self.classname = "player";
 706                 self.wasplayer = TRUE;
 707                 self.iscreature = TRUE;
 708                 self.damagedbycontents = TRUE;
 709                 self.movetype = MOVETYPE_WALK;
 710                 self.solid = SOLID_SLIDEBOX;
 711                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 712                 if(autocvar_g_playerclip_collisions)
 713                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 714                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 715                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 716                 self.frags = FRAGS_PLAYER;
 717                 if(INDEPENDENT_PLAYERS)
 718                         MAKE_INDEPENDENT_PLAYER(self);
 719                 self.flags = FL_CLIENT;
 720                 if(autocvar__notarget)
 721                         self.flags |= FL_NOTARGET;
 722                 self.takedamage = DAMAGE_AIM;
 723                 if(g_minstagib)
 724                         self.effects = EF_FULLBRIGHT;
 725                 else
 726                         self.effects = 0;
 727                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 728                 self.air_finished = time + 12;
 729                 self.dmg = 2;
 730                 if(autocvar_g_balance_nex_charge)
 731                 {
 732                         if(autocvar_g_balance_nex_secondary_chargepool)
 733                                 self.nex_chargepool_ammo = 1;
 734                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 735                 }
 736
 737                 if(inWarmupStage)
 738                 {
 739                         self.ammo_shells = warmup_start_ammo_shells;
 740                         self.ammo_nails = warmup_start_ammo_nails;
 741                         self.ammo_rockets = warmup_start_ammo_rockets;
 742                         self.ammo_cells = warmup_start_ammo_cells;
 743                         self.ammo_fuel = warmup_start_ammo_fuel;
 744                         self.health = warmup_start_health;
 745                         self.armorvalue = warmup_start_armorvalue;
 746                         self.weapons = warmup_start_weapons;
 747                 }
 748                 else
 749                 {
 750                         self.ammo_shells = start_ammo_shells;
 751                         self.ammo_nails = start_ammo_nails;
 752                         self.ammo_rockets = start_ammo_rockets;
 753                         self.ammo_cells = start_ammo_cells;
 754                         self.ammo_fuel = start_ammo_fuel;
 755                         self.health = start_health;
 756                         self.armorvalue = start_armorvalue;
 757                         self.weapons = start_weapons;
 758                 }
 759
 760                 if(g_weaponarena_random)
 761                 {
 762                         if(g_weaponarena_random_with_laser)
 763                                 self.weapons &~= WEPBIT_LASER;
 764                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 765                         if(g_weaponarena_random_with_laser)
 766                                 self.weapons |= WEPBIT_LASER;
 767                 }
 768
 769                 self.items = start_items;
 770                 self.jump_interval = time;
 771
 772                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 773                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 774                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 775                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 776                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 777                 //extend the pause of rotting if client was reset at the beginning of the countdown
 778                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 779                         self.spawnshieldtime += game_starttime - time;
 780                         self.pauserotarmor_finished += game_starttime - time;
 781                         self.pauserothealth_finished += game_starttime - time;
 782                         self.pauseregen_finished += game_starttime - time;
 783                 }
 784                 self.damageforcescale = 2;
 785                 self.death_time = 0;
 786                 self.dead_frame = 0;
 787                 self.alpha = 0;
 788                 self.scale = 0;
 789                 self.fade_time = 0;
 790                 self.pain_frame = 0;
 791                 self.pain_finished = 0;
 792                 self.strength_finished = 0;
 793                 self.invincible_finished = 0;
 794                 self.pushltime = 0;
 795                 // players have no think function
 796                 self.think = SUB_Null;
 797                 self.nextthink = 0;
 798                 self.hook_time = 0;
 799                 self.dmg_team = 0;
 800                 self.ballistics_density = autocvar_g_ballistics_density_player;
 801
 802                 self.metertime = 0;
 803
 804                 self.runes = 0;
 805
 806                 self.deadflag = DEAD_NO;
 807
 808                 self.angles = spot.angles;
 809
 810                 self.angles_z = 0; // never spawn tilted even if the spot says to
 811                 self.fixangle = TRUE; // turn this way immediately
 812                 self.velocity = '0 0 0';
 813                 self.avelocity = '0 0 0';
 814                 self.punchangle = '0 0 0';
 815                 self.punchvector = '0 0 0';
 816                 self.oldvelocity = self.velocity;
 817                 self.fire_endtime = -1;
 818
 819                 msg_entity = self;
 820                 WRITESPECTATABLE_MSG_ONE({
 821                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 822                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 823                 });
 824
 825                 self.model = "";
 826                 FixPlayermodel();
 827                 self.drawonlytoclient = world;
 828
 829                 self.crouch = FALSE;
 830                 self.view_ofs = PL_VIEW_OFS;
 831                 setsize (self, PL_MIN, PL_MAX);
 832                 self.spawnorigin = spot.origin;
 833                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 834                 // don't reset back to last position, even if new position is stuck in solid
 835                 self.oldorigin = self.origin;
 836                 self.prevorigin = self.origin;
 837                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 838                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 839         self.hud = HUD_NORMAL;
 840
 841                 if(g_arena)
 842                 {
 843                         Spawnqueue_Remove(self);
 844                         Spawnqueue_Mark(self);
 845                 }
 846
 847                 else if(g_ca)
 848                         self.caplayer = 1;
 849
 850                 self.event_damage = PlayerDamage;
 851
 852                 self.bot_attack = TRUE;
 853
 854                 self.statdraintime = time + 5;
 855                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 856
 857                 if(self.killcount == -666) {
 858                         PlayerScore_Clear(self);
 859                         self.killcount = 0;
 860                 }
 861
 862                 CL_SpawnWeaponentity();
 863                 self.alpha = default_player_alpha;
 864                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 865                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 866
 867                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 868                 self.lms_traveled_distance = 0;
 869                 self.speedrunning = FALSE;
 870
 871                 race_PostSpawn(spot);
 872
 873                 //stuffcmd(self, "chase_active 0");
 874                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 875
 876                 if (autocvar_g_spawnsound)
 877                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 878
 879                 if(g_assault) {
 880                         if(self.team == assault_attacker_team)
 881                                 centerprint(self, "You are attacking!");
 882                         else
 883                                 centerprint(self, "You are defending!");
 884                 }
 885
 886                 target_voicescript_clear(self);
 887
 888                 // reset fields the weapons may use
 889                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 890                 {
 891                         weapon_action(j, WR_RESETPLAYER);
 892
 893                         // all weapons must be fully loaded when we spawn
 894                         entity e;
 895                         e = get_weaponinfo(j);
 896                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 897                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 898                 }
 899
 900                 oldself = self;
 901                 self = spot;
 902                         activator = oldself;
 903                                 string s;
 904                                 s = self.target;
 905                                 self.target = string_null;
 906                                 SUB_UseTargets();
 907                                 self.target = s;
 908                         activator = world;
 909                 self = oldself;
 910
 911                 spawn_spot = spot;
 912                 MUTATOR_CALLHOOK(PlayerSpawn);
 913
 914                 if(autocvar_spawn_debug)
 915                 {
 916                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 917                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 918                 }
 919
 920                 self.switchweapon = w_getbestweapon(self);
 921                 self.cnt = -1; // W_LastWeapon will not complain
 922                 self.weapon = 0;
 923                 self.weaponname = "";
 924                 self.switchingweapon = 0;
 925
 926                 if(!self.alivetime)
 927                         self.alivetime = time;
 928
 929                 antilag_clear(self);
 930         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
 931                 PutObserverInServer ();
 932         }
 933
 934         //if(g_ctf)
 935         //      ctf_playerchanged();
 936 }
 937
 938 .float ebouncefactor, ebouncestop; // electro's values
 939 // TODO do we need all these fields, or should we stop autodetecting runtime
 940 // changes and just have a console command to update this?
 941 float ClientInit_SendEntity(entity to, float sf)
 942 {
 943         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 944         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 951         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 952         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 953         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 954         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 955         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 956         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 957         if(sv_foginterval && world.fog != "")
 958                 WriteString(MSG_ENTITY, world.fog);
 959         else
 960                 WriteString(MSG_ENTITY, "");
 961         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 962         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 963         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 964         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 965         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 966         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 967         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 968         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 969         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 970         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 971         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 972         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 973         return TRUE;
 974 }
 975
 976 void ClientInit_CheckUpdate()
 977 {
 978         self.nextthink = time;
 979         if(self.count != autocvar_g_balance_armor_blockpercent)
 980         {
 981                 self.count = autocvar_g_balance_armor_blockpercent;
 982                 self.SendFlags |= 1;
 983         }
 984         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 985         {
 986                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 987                 self.SendFlags |= 1;
 988         }
 989         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 990         {
 991                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 992                 self.SendFlags |= 1;
 993         }
 994         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 995         {
 996                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 997                 self.SendFlags |= 1;
 998         }
 999         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1000         {
1001                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1002                 self.SendFlags |= 1;
1003         }
1004         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1005         {
1006                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1007                 self.SendFlags |= 1;
1008         }
1009 }
1010
1011 void ClientInit_Spawn()
1012 {
1013         entity o;
1014         entity e;
1015         e = spawn();
1016         e.classname = "clientinit";
1017         e.think = ClientInit_CheckUpdate;
1018         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1019
1020         o = self;
1021         self = e;
1022         ClientInit_CheckUpdate();
1023         self = o;
1024 }
1025
1026 /*
1027 =============
1028 SetNewParms
1029 =============
1030 */
1031 void SetNewParms (void)
1032 {
1033         // initialize parms for a new player
1034         parm1 = -(86400 * 366);
1035 }
1036
1037 /*
1038 =============
1039 SetChangeParms
1040 =============
1041 */
1042 void SetChangeParms (void)
1043 {
1044         // save parms for level change
1045         parm1 = self.parm_idlesince - time;
1046 }
1047
1048 /*
1049 =============
1050 DecodeLevelParms
1051 =============
1052 */
1053 void DecodeLevelParms (void)
1054 {
1055         // load parms
1056         self.parm_idlesince = parm1;
1057         if(self.parm_idlesince == -(86400 * 366))
1058                 self.parm_idlesince = time;
1059
1060         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1061         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1062 }
1063
1064 /*
1065 =============
1066 ClientKill
1067
1068 Called when a client types 'kill' in the console
1069 =============
1070 */
1071
1072 .float clientkill_nexttime;
1073 void ClientKill_Now_TeamChange()
1074 {
1075         if(self.killindicator_teamchange == -1)
1076         {
1077                 self.team = -1;
1078                 JoinBestTeam( self, FALSE, FALSE );
1079         }
1080         else if(self.killindicator_teamchange == -2)
1081         {
1082                 if(g_ca)
1083                         self.caplayer = 0;
1084                 if(blockSpectators)
1085                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1086                 PutObserverInServer();
1087         }
1088         else
1089                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1090 }
1091
1092 void ClientKill_Now()
1093 {
1094         if(self.vehicle)
1095         {
1096             vehicles_exit(VHEF_RELESE);
1097             if(!self.killindicator_teamchange)
1098             {
1099             self.vehicle_health = -1;
1100             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1101             }
1102         }
1103
1104         if(self.killindicator && !wasfreed(self.killindicator))
1105                 remove(self.killindicator);
1106
1107         self.killindicator = world;
1108
1109         if(self.killindicator_teamchange)
1110                 ClientKill_Now_TeamChange();
1111
1112         // in any case:
1113         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1114
1115         // now I am sure the player IS dead
1116 }
1117 void KillIndicator_Think()
1118 {
1119         if (gameover)
1120         {
1121                 self.owner.killindicator = world;
1122                 remove(self);
1123                 return;
1124         }
1125
1126         if (!self.owner.modelindex)
1127         {
1128                 self.owner.killindicator = world;
1129                 remove(self);
1130                 return;
1131         }
1132
1133         if(self.cnt <= 0)
1134         {
1135                 self = self.owner;
1136                 ClientKill_Now(); // no oldself needed
1137                 return;
1138         }
1139     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1140     {
1141         self.nextthink = time + 1;
1142         self.cnt -= 1;
1143     }
1144         else
1145         {
1146                 if(self.cnt <= 10)
1147                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1148                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1149                 {
1150                         if(self.cnt <= 10)
1151                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1152                 }
1153                 self.nextthink = time + 1;
1154                 self.cnt -= 1;
1155         }
1156 }
1157
1158 float clientkilltime;
1159 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1160 {
1161         float killtime;
1162         float starttime;
1163         entity e;
1164
1165         if (gameover)
1166                 return;
1167
1168         killtime = autocvar_g_balance_kill_delay;
1169
1170         if(g_race_qualifying || g_cts)
1171                 killtime = 0;
1172
1173     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1174     {
1175                 remove(self.killindicator);
1176                 self.killindicator = world;
1177
1178         ClientKill_Now(); // allow instant kill in this case
1179         return;
1180     }
1181
1182         self.killindicator_teamchange = targetteam;
1183
1184     if(!self.killindicator)
1185         {
1186                 if(self.modelindex && self.deadflag == DEAD_NO)
1187                 {
1188                         killtime = max(killtime, self.clientkill_nexttime - time);
1189                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1190                 }
1191
1192                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1193                 {
1194                         ClientKill_Now();
1195                 }
1196                 else
1197                 {
1198                         starttime = max(time, clientkilltime);
1199
1200                         self.killindicator = spawn();
1201                         self.killindicator.owner = self;
1202                         self.killindicator.scale = 0.5;
1203                         setattachment(self.killindicator, self, "");
1204                         setorigin(self.killindicator, '0 0 52');
1205                         self.killindicator.think = KillIndicator_Think;
1206                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1207                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1208                         self.killindicator.cnt = ceil(killtime);
1209                         self.killindicator.count = bound(0, ceil(killtime), 10);
1210                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1211
1212                         for(e = world; (e = find(e, classname, "body")) != world; )
1213                         {
1214                                 if(e.enemy != self)
1215                                         continue;
1216                                 e.killindicator = spawn();
1217                                 e.killindicator.owner = e;
1218                                 e.killindicator.scale = 0.5;
1219                                 setattachment(e.killindicator, e, "");
1220                                 setorigin(e.killindicator, '0 0 52');
1221                                 e.killindicator.think = KillIndicator_Think;
1222                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1223                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1224                                 e.killindicator.cnt = ceil(killtime);
1225                         }
1226                         self.lip = 0;
1227                 }
1228         }
1229         if(self.killindicator)
1230         {
1231                 if(targetteam == 0) // just die
1232                 {
1233                         self.killindicator.colormod = '0 0 0';
1234                         if(clienttype(self) == CLIENTTYPE_REAL)
1235                         if(self.killindicator.cnt > 0)
1236                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1237                 }
1238                 else if(targetteam == -1) // auto
1239                 {
1240                         self.killindicator.colormod = '0 1 0';
1241                         if(clienttype(self) == CLIENTTYPE_REAL)
1242                         if(self.killindicator.cnt > 0)
1243                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1244                 }
1245                 else if(targetteam == -2) // spectate
1246                 {
1247                         self.killindicator.colormod = '0.5 0.5 0.5';
1248                         if(clienttype(self) == CLIENTTYPE_REAL)
1249                         if(self.killindicator.cnt > 0)
1250                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1251                 }
1252                 else
1253                 {
1254                         self.killindicator.colormod = TeamColor(targetteam);
1255                         if(clienttype(self) == CLIENTTYPE_REAL)
1256                         if(self.killindicator.cnt > 0)
1257                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1258                 }
1259         }
1260
1261 }
1262
1263 void ClientKill (void)
1264 {
1265         if (gameover)
1266                 return;
1267
1268         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1269         {
1270                 // do nothing
1271         }
1272     else if(self.freezetag_frozen)
1273     {
1274         // do nothing
1275     }
1276         else
1277                 ClientKill_TeamChange(0);
1278 }
1279
1280 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1281 {
1282     e.killindicator = spawn();
1283     e.killindicator.owner = e;
1284     e.killindicator.think = KillIndicator_Think;
1285     e.killindicator.nextthink = time + (e.lip) * 0.05;
1286     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1287     e.killindicator.health = 1; // this is used to indicate that it should be silent
1288     e.lip = 0;
1289 }
1290
1291 void FixClientCvars(entity e)
1292 {
1293         // send prediction settings to the client
1294         stuffcmd(e, "\nin_bindmap 0 0\n");
1295         if(g_race || g_cts)
1296                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1297         if(autocvar_g_antilag == 3) // client side hitscan
1298                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1299         if(sv_gentle)
1300                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1301         /*
1302          * we no longer need to stuff this. Remove this comment block if you feel
1303          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1304         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1305         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1306         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1307         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1308         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1309         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1310         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1311         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1312         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1313         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1314         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1315         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1316         stuffcmd(e, "cl_movement_edgefriction 1\n");
1317          */
1318 }
1319
1320 float PlayerInIDList(entity p, string idlist)
1321 {
1322         float n, i;
1323         string s;
1324
1325         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1326         if not(p.crypto_idfp)
1327                 return 0;
1328
1329         // this function allows abbreviated player IDs too!
1330         n = tokenize_console(idlist);
1331         for(i = 0; i < n; ++i)
1332         {
1333                 s = argv(i);
1334                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1335                         return 1;
1336         }
1337
1338         return 0;
1339 }
1340
1341 /*
1342 =============
1343 ClientConnect
1344
1345 Called when a client connects to the server
1346 =============
1347 */
1348 //void ctf_clientconnect();
1349 string ColoredTeamName(float t);
1350 void DecodeLevelParms (void);
1351 //void dom_player_join_team(entity pl);
1352 void set_dom_state(entity e);
1353 void ClientConnect (void)
1354 {
1355         float t;
1356
1357         if(self.flags & FL_CLIENT)
1358         {
1359                 print("Warning: ClientConnect, but already connected!\n");
1360                 return;
1361         }
1362
1363         if(Ban_MaybeEnforceBan(self))
1364                 return;
1365
1366         DecodeLevelParms();
1367
1368 #ifdef WATERMARK
1369         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1370 #endif
1371
1372         self.classname = "player_joining";
1373
1374         self.flags = FL_CLIENT;
1375         self.version_nagtime = time + 10 + random() * 10;
1376
1377         if(player_count<0)
1378         {
1379                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1380                 player_count = 0;
1381         }
1382
1383         PlayerScore_Attach(self);
1384         ClientData_Attach();
1385         accuracy_init(self);
1386
1387         bot_clientconnect();
1388
1389         playerdemo_init();
1390
1391         anticheat_init();
1392
1393         race_PreSpawnObserver();
1394
1395         //if(g_domination)
1396         //      dom_player_join_team(self);
1397
1398         // identify the right forced team
1399         if(autocvar_g_campaign)
1400         {
1401                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1402                 {
1403                         switch(autocvar_g_campaign_forceteam)
1404                         {
1405                                 case 1: self.team_forced = COLOR_TEAM1; break;
1406                                 case 2: self.team_forced = COLOR_TEAM2; break;
1407                                 case 3: self.team_forced = COLOR_TEAM3; break;
1408                                 case 4: self.team_forced = COLOR_TEAM4; break;
1409                                 default: self.team_forced = 0;
1410                         }
1411                 }
1412         }
1413         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1414                 self.team_forced = COLOR_TEAM1;
1415         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1416                 self.team_forced = COLOR_TEAM2;
1417         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1418                 self.team_forced = COLOR_TEAM3;
1419         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1420                 self.team_forced = COLOR_TEAM4;
1421         else if(autocvar_g_forced_team_otherwise == "red")
1422                 self.team_forced = COLOR_TEAM1;
1423         else if(autocvar_g_forced_team_otherwise == "blue")
1424                 self.team_forced = COLOR_TEAM2;
1425         else if(autocvar_g_forced_team_otherwise == "yellow")
1426                 self.team_forced = COLOR_TEAM3;
1427         else if(autocvar_g_forced_team_otherwise == "pink")
1428                 self.team_forced = COLOR_TEAM4;
1429         else if(autocvar_g_forced_team_otherwise == "spectate")
1430                 self.team_forced = -1;
1431         else if(autocvar_g_forced_team_otherwise == "spectator")
1432                 self.team_forced = -1;
1433         else
1434                 self.team_forced = 0;
1435
1436         if(!teamplay)
1437                 if(self.team_forced > 0)
1438                         self.team_forced = 0;
1439
1440         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1441
1442         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1443                 self.classname = "observer";
1444         } else {
1445                 if(teamplay)
1446                 {
1447                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1448                         {
1449                                 self.classname = "player";
1450                                 campaign_bots_may_start = 1;
1451                         }
1452                         else
1453                         {
1454                                 self.classname = "observer"; // do it anyway
1455                         }
1456                 }
1457                 else
1458                 {
1459                         self.classname = "player";
1460                         campaign_bots_may_start = 1;
1461                 }
1462         }
1463
1464         self.playerid = (playerid_last = playerid_last + 1);
1465
1466         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1467
1468     if(clienttype(self) == CLIENTTYPE_BOT)
1469         PlayerStats_AddPlayer(self);
1470
1471         if(autocvar_sv_eventlog)
1472                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1473
1474         LogTeamchange(self.playerid, self.team, 1);
1475
1476         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1477
1478         self.netname_previous = strzone(self.netname);
1479
1480         bprint("^4", self.netname, "^4 connected");
1481
1482         if(self.classname != "observer" && (g_domination || g_ctf))
1483                 bprint(" and joined the ", ColoredTeamName(self.team));
1484
1485         bprint("\n");
1486
1487         stuffcmd(self, strcat(clientstuff, "\n"));
1488         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1489
1490         FixClientCvars(self);
1491
1492         // spawnfunc_waypoint sprites
1493         WaypointSprite_InitClient(self);
1494
1495         // Wazat's grappling hook
1496         SetGrappleHookBindings();
1497
1498         // get version info from player
1499         stuffcmd(self, "cmd clientversion $gameversion\n");
1500
1501         // get other cvars from player
1502         GetCvars(0);
1503
1504         // notify about available teams
1505         if(teamplay)
1506         {
1507                 CheckAllowedTeams(self);
1508                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1509                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1510         }
1511         else
1512                 stuffcmd(self, "set _teams_available 0\n");
1513
1514         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1515
1516         if(g_arena || g_ca)
1517         {
1518                 self.classname = "observer";
1519                 if(g_arena)
1520                         Spawnqueue_Insert(self);
1521         }
1522         /*else if(g_ctf)
1523         {
1524                 ctf_clientconnect();
1525         }*/
1526
1527         attach_entcs();
1528
1529         bot_relinkplayerlist();
1530
1531         self.spectatortime = time;
1532         if(blockSpectators)
1533         {
1534                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1535         }
1536
1537         self.jointime = time;
1538         self.allowedTimeouts = autocvar_sv_timeout_number;
1539
1540         if(clienttype(self) == CLIENTTYPE_REAL)
1541         {
1542                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1543                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1544         }
1545
1546         if(g_lms)
1547         {
1548                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1549                 {
1550                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1551                         self.frags = FRAGS_SPECTATOR;
1552                 }
1553         }
1554
1555         if(!sv_foginterval && world.fog != "")
1556                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1557
1558         SoundEntity_Attach(self);
1559
1560         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1561         {
1562                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1563                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1564         }
1565         else
1566                 self.hitplotfh = -1;
1567
1568         if(g_race || g_cts) {
1569                 string rr;
1570                 if(g_cts)
1571                         rr = CTS_RECORD;
1572                 else
1573                         rr = RACE_RECORD;
1574                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1575
1576                 msg_entity = self;
1577                 race_send_recordtime(MSG_ONE);
1578                 race_send_speedaward(MSG_ONE);
1579
1580                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1581                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1582                 race_send_speedaward_alltimebest(MSG_ONE);
1583
1584                 float i;
1585                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1586                         race_SendRankings(i, 0, 0, MSG_ONE);
1587                 }
1588         }
1589         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1590                 send_CSQC_teamnagger();
1591
1592         if (g_domination)
1593                 set_dom_state(self);
1594
1595         CheatInitClient();
1596
1597         if(!autocvar_g_campaign)
1598                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1599
1600         CSQCMODEL_AUTOINIT();
1601
1602         self.model_randomizer = random();
1603 }
1604
1605 /*
1606 =============
1607 ClientDisconnect
1608
1609 Called when a client disconnects from the server
1610 =============
1611 */
1612 .entity chatbubbleentity;
1613 void ReadyCount();
1614 void ClientDisconnect (void)
1615 {
1616         if(self.vehicle)
1617             vehicles_exit(VHEF_RELESE);
1618
1619         if not(self.flags & FL_CLIENT)
1620         {
1621                 print("Warning: ClientDisconnect without ClientConnect\n");
1622                 return;
1623         }
1624
1625         PlayerStats_AddGlobalInfo(self);
1626
1627         CheatShutdownClient();
1628
1629         if(self.hitplotfh >= 0)
1630         {
1631                 fclose(self.hitplotfh);
1632                 self.hitplotfh = -1;
1633         }
1634
1635         anticheat_report();
1636         anticheat_shutdown();
1637
1638         playerdemo_shutdown();
1639
1640         bot_clientdisconnect();
1641
1642         if(self.entcs)
1643                 detach_entcs();
1644
1645         if(autocvar_sv_eventlog)
1646                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1647         bprint ("^4",self.netname);
1648         bprint ("^4 disconnected\n");
1649
1650         SoundEntity_Detach(self);
1651
1652         DropAllRunes(self);
1653         MUTATOR_CALLHOOK(ClientDisconnect);
1654
1655         Portal_ClearAll(self);
1656
1657         RemoveGrapplingHook(self);
1658         if(self.flagcarried)
1659                 DropFlag(self.flagcarried, world, world);
1660         if(self.ballcarried && g_nexball)
1661                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1662
1663         // Here, everything has been done that requires this player to be a client.
1664
1665         self.flags &~= FL_CLIENT;
1666
1667         if (self.chatbubbleentity)
1668                 remove (self.chatbubbleentity);
1669
1670         if (self.killindicator)
1671                 remove (self.killindicator);
1672
1673         WaypointSprite_PlayerGone();
1674
1675         bot_relinkplayerlist();
1676
1677         if(g_arena)
1678         {
1679                 Spawnqueue_Unmark(self);
1680                 Spawnqueue_Remove(self);
1681         }
1682
1683         accuracy_free(self);
1684         ClientData_Detach();
1685         PlayerScore_Detach(self);
1686
1687         if(self.netname_previous)
1688                 strunzone(self.netname_previous);
1689         if(self.clientstatus)
1690                 strunzone(self.clientstatus);
1691         if(self.weaponorder_byimpulse)
1692                 strunzone(self.weaponorder_byimpulse);
1693
1694         ClearPlayerSounds();
1695
1696         if(self.personal)
1697                 remove(self.personal);
1698
1699         self.playerid = 0;
1700         ReadyCount();
1701
1702         // free cvars
1703         GetCvars(-1);
1704 }
1705
1706 .float BUTTON_CHAT;
1707 void ChatBubbleThink()
1708 {
1709         self.nextthink = time;
1710         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1711         {
1712                 if(self.owner) // but why can that ever be world?
1713                         self.owner.chatbubbleentity = world;
1714                 remove(self);
1715                 return;
1716         }
1717         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1718 #ifdef TETRIS
1719                 || self.owner.tetris_on
1720 #endif
1721         )
1722                 self.model = self.mdl;
1723         else
1724                 self.model = "";
1725 }
1726
1727 void UpdateChatBubble()
1728 {
1729         if (!self.modelindex)
1730                 return;
1731         // spawn a chatbubble entity if needed
1732         if (!self.chatbubbleentity)
1733         {
1734                 self.chatbubbleentity = spawn();
1735                 self.chatbubbleentity.owner = self;
1736                 self.chatbubbleentity.exteriormodeltoclient = self;
1737                 self.chatbubbleentity.think = ChatBubbleThink;
1738                 self.chatbubbleentity.nextthink = time;
1739                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1740                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1741                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1742                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1743                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1744                 self.chatbubbleentity.model = "";
1745                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1746         }
1747 }
1748
1749
1750 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1751 // added to the model skins
1752 /*void UpdateColorModHack()
1753 {
1754         float c;
1755         c = self.clientcolors & 15;
1756         // LordHavoc: only bothering to support white, green, red, yellow, blue
1757              if (!teamplay) self.colormod = '0 0 0';
1758         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1759         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1760         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1761         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1762         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1763         else self.colormod = '1 1 1';
1764 }*/
1765
1766 .float oldcolormap;
1767 void respawn(void)
1768 {
1769         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1770         {
1771                 self.solid = SOLID_NOT;
1772                 self.takedamage = DAMAGE_NO;
1773                 self.movetype = MOVETYPE_FLY;
1774                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1775                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1776                 self.effects |= EF_ADDITIVE;
1777                 self.oldcolormap = self.colormap;
1778                 self.colormap = 0; // this originally was 512, but raises a warning in the engine, so get rid of it
1779                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1780                 if(autocvar_g_respawn_ghosts_maxtime)
1781                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1782         }
1783
1784         CopyBody(1);
1785         self.effects |= EF_NODRAW; // prevent another CopyBody
1786         if(self.oldcolormap)
1787         {
1788                 self.colormap = self.oldcolormap;
1789                 self.oldcolormap = 0;
1790         }
1791         PutClientInServer();
1792 }
1793
1794 void play_countdown(float finished, string samp)
1795 {
1796         if(clienttype(self) == CLIENTTYPE_REAL)
1797                 if(floor(finished - time - frametime) != floor(finished - time))
1798                         if(finished - time < 6)
1799                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1800 }
1801
1802 void player_powerups (void)
1803 {
1804         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1805         olditems = self.items;
1806
1807         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1808         {
1809                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1810                 self.modelflags |= MF_ROCKET;
1811         }
1812         else
1813         {
1814                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1815                 self.modelflags &~= MF_ROCKET;
1816         }
1817
1818         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1819
1820         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1821                 return;
1822
1823         Fire_ApplyDamage(self);
1824         Fire_ApplyEffect(self);
1825
1826         if (g_minstagib)
1827         {
1828                 self.effects |= EF_FULLBRIGHT;
1829
1830                 if (self.items & IT_STRENGTH)
1831                 {
1832                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1833                         if (time > self.strength_finished)
1834                         {
1835                                 self.alpha = default_player_alpha;
1836                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1837                                 self.items &~= IT_STRENGTH;
1838                                 sprint(self, "^3Invisibility has worn off\n");
1839                         }
1840                 }
1841                 else
1842                 {
1843                         if (time < self.strength_finished)
1844                         {
1845                                 self.alpha = g_minstagib_invis_alpha;
1846                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1847                                 self.items |= IT_STRENGTH;
1848                                 sprint(self, "^3You are invisible\n");
1849                         }
1850                 }
1851
1852                 if (self.items & IT_INVINCIBLE)
1853                 {
1854                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1855                         if (time > self.invincible_finished)
1856                         {
1857                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1858                                 sprint(self, "^3Speed has worn off\n");
1859                         }
1860                 }
1861                 else
1862                 {
1863                         if (time < self.invincible_finished)
1864                         {
1865                                 self.items = self.items | IT_INVINCIBLE;
1866                                 sprint(self, "^3You are on speed\n");
1867                         }
1868                 }
1869         }
1870         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1871         {
1872                 if (self.items & IT_STRENGTH)
1873                 {
1874                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1875                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1876                         if (time > self.strength_finished)
1877                         {
1878                                 self.items = self.items - (self.items & IT_STRENGTH);
1879                                 sprint(self, "^3Strength has worn off\n");
1880                         }
1881                 }
1882                 else
1883                 {
1884                         if (time < self.strength_finished)
1885                         {
1886                                 self.items = self.items | IT_STRENGTH;
1887                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1888                         }
1889                 }
1890                 if (self.items & IT_INVINCIBLE)
1891                 {
1892                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1893                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1894                         if (time > self.invincible_finished)
1895                         {
1896                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1897                                 sprint(self, "^3Shield has worn off\n");
1898                         }
1899                 }
1900                 else
1901                 {
1902                         if (time < self.invincible_finished)
1903                         {
1904                                 self.items = self.items | IT_INVINCIBLE;
1905                                 sprint(self, "^3Shield surrounds you\n");
1906                         }
1907                 }
1908
1909                 if(autocvar_g_nodepthtestplayers)
1910                         self.effects = self.effects | EF_NODEPTHTEST;
1911
1912                 if(autocvar_g_fullbrightplayers)
1913                         self.effects = self.effects | EF_FULLBRIGHT;
1914
1915                 // midair gamemode: damage only while in the air
1916                 // if in midair mode, being on ground grants temporary invulnerability
1917                 // (this is so that multishot weapon don't clear the ground flag on the
1918                 // first damage in the frame, leaving the player vulnerable to the
1919                 // remaining hits in the same frame)
1920                 if (self.flags & FL_ONGROUND)
1921                 if (g_midair)
1922                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1923
1924                 if (time >= game_starttime)
1925                 if (time < self.spawnshieldtime)
1926                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1927         }
1928
1929         MUTATOR_CALLHOOK(PlayerPowerups);
1930 }
1931
1932 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1933 {
1934         if(current > stable)
1935                 return current;
1936         else if(current > stable - 0.25) // when close enough, "snap"
1937                 return stable;
1938         else
1939                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1940 }
1941
1942 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1943 {
1944         if(current < stable)
1945                 return current;
1946         else if(current < stable + 0.25) // when close enough, "snap"
1947                 return stable;
1948         else
1949                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1950 }
1951
1952 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1953 {
1954         if(current > rotstable)
1955         {
1956                 if(rotframetime > 0)
1957                 {
1958                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1959                         current = max(rotstable, current - rotlinear * rotframetime);
1960                 }
1961         }
1962         else if(current < regenstable)
1963         {
1964                 if(regenframetime > 0)
1965                 {
1966                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1967                         current = min(regenstable, current + regenlinear * regenframetime);
1968                 }
1969         }
1970
1971         if(current > limit)
1972                 current = limit;
1973
1974         return current;
1975 }
1976
1977 void player_regen (void)
1978 {
1979         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1980         maxh = autocvar_g_balance_health_rotstable;
1981         maxa = autocvar_g_balance_armor_rotstable;
1982         maxf = autocvar_g_balance_fuel_rotstable;
1983         minh = autocvar_g_balance_health_regenstable;
1984         mina = autocvar_g_balance_armor_regenstable;
1985         minf = autocvar_g_balance_fuel_regenstable;
1986         limith = autocvar_g_balance_health_limit;
1987         limita = autocvar_g_balance_armor_limit;
1988         limitf = autocvar_g_balance_fuel_limit;
1989
1990         max_mod = regen_mod = rot_mod = limit_mod = 1;
1991
1992         if (self.runes & RUNE_REGEN)
1993         {
1994                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1995                 {
1996                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1997                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1998                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1999                 }
2000                 else
2001                 {
2002                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2003                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2004                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2005                 }
2006         }
2007         else if (self.runes & CURSE_VENOM)
2008         {
2009                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2010                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2011                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2012                 else
2013                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2014                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2015                 //if (!self.runes & RUNE_REGEN)
2016                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2017         }
2018         maxh = maxh * max_mod;
2019         //maxa = maxa * max_mod;
2020         //maxf = maxf * max_mod;
2021         minh = minh * max_mod;
2022         //mina = mina * max_mod;
2023         //minf = minf * max_mod;
2024         limith = limith * limit_mod;
2025         limita = limita * limit_mod;
2026         //limitf = limitf * limit_mod;
2027
2028         if(g_lms && g_ca)
2029                 rot_mod = 0;
2030
2031         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2032         {
2033                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2034                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2035
2036                 // if player rotted to death...  die!
2037                 if(self.health < 1)
2038                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2039         }
2040
2041         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2042                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2043 }
2044
2045 float zoomstate_set;
2046 void SetZoomState(float z)
2047 {
2048         if(z != self.zoomstate)
2049         {
2050                 self.zoomstate = z;
2051                 ClientData_Touch(self);
2052         }
2053         zoomstate_set = 1;
2054 }
2055
2056 void GetPressedKeys(void) {
2057         MUTATOR_CALLHOOK(GetPressedKeys);
2058         if (self.movement_x > 0) // get if movement keys are pressed
2059         {       // forward key pressed
2060                 self.pressedkeys |= KEY_FORWARD;
2061                 self.pressedkeys &~= KEY_BACKWARD;
2062         }
2063         else if (self.movement_x < 0)
2064         {       // backward key pressed
2065                 self.pressedkeys |= KEY_BACKWARD;
2066                 self.pressedkeys &~= KEY_FORWARD;
2067         }
2068         else
2069         {       // no x input
2070                 self.pressedkeys &~= KEY_FORWARD;
2071                 self.pressedkeys &~= KEY_BACKWARD;
2072         }
2073
2074         if (self.movement_y > 0)
2075         {       // right key pressed
2076                 self.pressedkeys |= KEY_RIGHT;
2077                 self.pressedkeys &~= KEY_LEFT;
2078         }
2079         else if (self.movement_y < 0)
2080         {       // left key pressed
2081                 self.pressedkeys |= KEY_LEFT;
2082                 self.pressedkeys &~= KEY_RIGHT;
2083         }
2084         else
2085         {       // no y input
2086                 self.pressedkeys &~= KEY_RIGHT;
2087                 self.pressedkeys &~= KEY_LEFT;
2088         }
2089
2090         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2091                 self.pressedkeys |= KEY_JUMP;
2092         else
2093                 self.pressedkeys &~= KEY_JUMP;
2094         if (self.BUTTON_CROUCH)
2095                 self.pressedkeys |= KEY_CROUCH;
2096         else
2097                 self.pressedkeys &~= KEY_CROUCH;
2098 }
2099
2100 /*
2101 ======================
2102 spectate mode routines
2103 ======================
2104 */
2105
2106 void SpectateCopy(entity spectatee) {
2107         other = spectatee;
2108         MUTATOR_CALLHOOK(SpectateCopy);
2109         self.armortype = spectatee.armortype;
2110         self.armorvalue = spectatee.armorvalue;
2111         self.ammo_cells = spectatee.ammo_cells;
2112         self.ammo_shells = spectatee.ammo_shells;
2113         self.ammo_nails = spectatee.ammo_nails;
2114         self.ammo_rockets = spectatee.ammo_rockets;
2115         self.ammo_fuel = spectatee.ammo_fuel;
2116         self.clip_load = spectatee.clip_load;
2117         self.clip_size = spectatee.clip_size;
2118         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2119         self.health = spectatee.health;
2120         self.impulse = 0;
2121         self.items = spectatee.items;
2122         self.last_pickup = spectatee.last_pickup;
2123         self.hit_time = spectatee.hit_time;
2124         self.metertime = spectatee.metertime;
2125         self.strength_finished = spectatee.strength_finished;
2126         self.invincible_finished = spectatee.invincible_finished;
2127         self.pressedkeys = spectatee.pressedkeys;
2128         self.weapons = spectatee.weapons;
2129         self.switchweapon = spectatee.switchweapon;
2130         self.switchingweapon = spectatee.switchingweapon;
2131         self.weapon = spectatee.weapon;
2132         self.nex_charge = spectatee.nex_charge;
2133         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2134         self.hagar_load = spectatee.hagar_load;
2135         self.minelayer_mines = spectatee.minelayer_mines;
2136         self.punchangle = spectatee.punchangle;
2137         self.view_ofs = spectatee.view_ofs;
2138         self.v_angle = spectatee.v_angle;
2139         self.velocity = spectatee.velocity;
2140         self.dmg_take = spectatee.dmg_take;
2141         self.dmg_save = spectatee.dmg_save;
2142         self.dmg_inflictor = spectatee.dmg_inflictor;
2143         self.angles = spectatee.v_angle;
2144         if(!self.BUTTON_USE)
2145                 self.fixangle = TRUE;
2146         setorigin(self, spectatee.origin);
2147         setsize(self, spectatee.mins, spectatee.maxs);
2148         SetZoomState(spectatee.zoomstate);
2149
2150         anticheat_spectatecopy(spectatee);
2151
2152         //self.vehicle = spectatee.vehicle;
2153
2154         self.hud = spectatee.hud;
2155         if(spectatee.vehicle)
2156     {
2157         setorigin(self, spectatee.origin);
2158         self.velocity = spectatee.vehicle.velocity;
2159         self.v_angle += spectatee.vehicle.angles;
2160         //self.v_angle_x *= -1;
2161         self.vehicle_health = spectatee.vehicle_health;
2162         self.vehicle_shield = spectatee.vehicle_shield;
2163         self.vehicle_energy = spectatee.vehicle_energy;
2164         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2165         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2166         self.vehicle_reload1 = spectatee.vehicle_reload1;
2167         self.vehicle_reload2 = spectatee.vehicle_reload2;
2168
2169         msg_entity = self;
2170         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2171         WriteEntity(MSG_ONE, spectatee);
2172         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2173     }
2174 }
2175
2176 float SpectateUpdate() {
2177         if(!self.enemy)
2178             return 0;
2179
2180         if (self == self.enemy)
2181                 return 0;
2182
2183         if(self.enemy.classname != "player")
2184                 return 0;
2185
2186         SpectateCopy(self.enemy);
2187
2188         return 1;
2189 }
2190
2191
2192 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2193 entity CA_SpectateNext(entity start) {
2194         if (start.team == self.team) {
2195                 return start;
2196         }
2197
2198         other = start;
2199         // continue from current player
2200         while(other && other.team != self.team) {
2201                 other = find(other, classname, "player");
2202         }
2203
2204         if (!other) {
2205                 // restart from begining
2206                 other = find(other, classname, "player");
2207                 while(other && other.team != self.team) {
2208                         other = find(other, classname, "player");
2209                 }
2210         }
2211
2212         return other;
2213 }
2214
2215 float SpectateNext() {
2216         other = find(self.enemy, classname, "player");
2217         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2218                 // CA and ca players when spectating enemies is forbidden
2219                 other = CA_SpectateNext(other);
2220         } else {
2221                 // other modes and ca spectators or spectating enemies is allowed
2222                 if (!other)
2223                         other = find(other, classname, "player");
2224         }
2225
2226         if (other)
2227                 self.enemy = other;
2228
2229         if(self.enemy.classname == "player") {
2230             if(self.enemy.vehicle)
2231             {
2232             msg_entity = self;
2233             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2234             WriteEntity(MSG_ONE, self.enemy);
2235             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2236             self.movetype = MOVETYPE_NONE;
2237             accuracy_resend(self);
2238             }
2239             else
2240             {
2241             msg_entity = self;
2242             WriteByte(MSG_ONE, SVC_SETVIEW);
2243             WriteEntity(MSG_ONE, self.enemy);
2244             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2245             self.movetype = MOVETYPE_NONE;
2246             accuracy_resend(self);
2247
2248             if(!SpectateUpdate())
2249                 PutObserverInServer();
2250         }
2251         return 1;
2252         } else {
2253                 return 0;
2254         }
2255 }
2256
2257 /*
2258 =============
2259 ShowRespawnCountdown()
2260
2261 Update a respawn countdown display.
2262 =============
2263 */
2264 void ShowRespawnCountdown()
2265 {
2266         float number;
2267         if(self.deadflag == DEAD_NO) // just respawned?
2268                 return;
2269         else
2270         {
2271                 number = ceil(self.death_time - time);
2272                 if(number <= 0)
2273                         return;
2274                 if(number <= self.respawn_countdown)
2275                 {
2276                         self.respawn_countdown = number - 1;
2277                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2278                                 AnnounceTo(self, strcat(ftos(number), ""));
2279                 }
2280         }
2281 }
2282
2283 .float prevent_join_msgtime;
2284 void LeaveSpectatorMode()
2285 {
2286         if(nJoinAllowed(1)) {
2287                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2288                         self.classname = "player";
2289
2290                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2291                                 JoinBestTeam(self, FALSE, TRUE);
2292
2293                         if(autocvar_g_campaign)
2294                                 campaign_bots_may_start = 1;
2295
2296                         PutClientInServer();
2297
2298                         if(self.classname == "player")
2299                                 bprint ("^4", self.netname, "^4 is playing now\n");
2300
2301                         if(!autocvar_g_campaign)
2302                         if (time < self.jointime + autocvar_welcome_message_time)
2303                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2304
2305                         if (self.prevent_join_msgtime)
2306                         {
2307                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2308                                 self.prevent_join_msgtime = 0;
2309                         }
2310
2311                         return;
2312                 } else {
2313                         if (g_ca && self.caplayer) {
2314                         }       // do nothing
2315                         else
2316                                 stuffcmd(self,"menu_showteamselect\n");
2317                         return;
2318                 }
2319         }
2320         else {
2321                 //player may not join because of g_maxplayers is set
2322                 if (time - self.prevent_join_msgtime > 2)
2323                 {
2324                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2325                         self.prevent_join_msgtime = time;
2326                 }
2327         }
2328 }
2329
2330 /**
2331  * Determines whether the player is allowed to join. This depends on cvar
2332  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2333  * it checks whether the number of currently playing players exceeds g_maxplayers.
2334  * @return int number of free slots for players, 0 if none
2335  */
2336 float nJoinAllowed(float includeMe) {
2337         if(self.team_forced < 0)
2338                 return FALSE; // forced spectators can never join
2339
2340         // TODO simplify this
2341         entity e;
2342
2343         float totalClients;
2344         FOR_EACH_CLIENT(e)
2345                 totalClients += 1;
2346
2347         if (!autocvar_g_maxplayers)
2348                 return maxclients - totalClients + includeMe;
2349
2350         float currentlyPlaying;
2351         FOR_EACH_REALPLAYER(e)
2352                 currentlyPlaying += 1;
2353
2354         if(currentlyPlaying < autocvar_g_maxplayers)
2355                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2356
2357         return 0;
2358 }
2359
2360 /**
2361  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2362  * g_maxplayers_spectator_blocktime seconds
2363  */
2364 void checkSpectatorBlock() {
2365         if(self.classname == "spectator" || self.classname == "observer") {
2366                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2367                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2368                         dropclient(self);
2369                 }
2370         }
2371 }
2372
2373 .float motd_actived_time; // used for both motd and campaign_message
2374 void PrintWelcomeMessage()
2375 {
2376         if (self.motd_actived_time == 0) { // is there already a message showing?
2377                 if (autocvar_g_campaign) {
2378                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2379                                 self.motd_actived_time = time;
2380                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2381                         }
2382                 } else {
2383                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2384                                 self.motd_actived_time = time;
2385                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2386                         }
2387                 }
2388         } else { // showing MOTD or campaign message
2389                 if (autocvar_g_campaign) {
2390                         if (self.BUTTON_INFO)
2391                                 self.motd_actived_time = time;
2392                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2393                                 self.motd_actived_time = 0;
2394                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2395                         }
2396                 } else {
2397                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2398                                 if (self.BUTTON_INFO)
2399                                         self.motd_actived_time = time;
2400                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2401                                         self.motd_actived_time = 0;
2402                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2403                                 }
2404                         }
2405                 }
2406         }
2407 }
2408
2409 void ObserverThink()
2410 {
2411         float prefered_movetype;
2412         if (self.flags & FL_JUMPRELEASED) {
2413                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2414                         self.flags &~= FL_JUMPRELEASED;
2415                         self.flags |= FL_SPAWNING;
2416                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2417                         self.flags &~= FL_JUMPRELEASED;
2418                         if(SpectateNext() == 1) {
2419                                 self.classname = "spectator";
2420                         }
2421                 } else {
2422                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2423                         if (self.movetype != prefered_movetype)
2424                                 self.movetype = prefered_movetype;
2425                 }
2426         } else {
2427                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2428                         self.flags |= FL_JUMPRELEASED;
2429                         if(self.flags & FL_SPAWNING)
2430                         {
2431                                 self.flags &~= FL_SPAWNING;
2432                                 LeaveSpectatorMode();
2433                                 return;
2434                         }
2435                 }
2436         }
2437
2438         PrintWelcomeMessage();
2439 }
2440
2441 void SpectatorThink()
2442 {
2443         if (self.flags & FL_JUMPRELEASED) {
2444                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2445                         self.flags &~= FL_JUMPRELEASED;
2446                         self.flags |= FL_SPAWNING;
2447                 } else if(self.BUTTON_ATCK) {
2448                         self.flags &~= FL_JUMPRELEASED;
2449                         if(SpectateNext() == 1) {
2450                                 self.classname = "spectator";
2451                         } else {
2452                                 self.classname = "observer";
2453                                 PutClientInServer();
2454                         }
2455                 } else if (self.BUTTON_ATCK2) {
2456                         self.flags &~= FL_JUMPRELEASED;
2457                         self.classname = "observer";
2458                         PutClientInServer();
2459                 } else {
2460                         if(!SpectateUpdate())
2461                                 PutObserverInServer();
2462                 }
2463         } else {
2464                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2465                         self.flags |= FL_JUMPRELEASED;
2466                         if(self.flags & FL_SPAWNING)
2467                         {
2468                                 self.flags &~= FL_SPAWNING;
2469                                 LeaveSpectatorMode();
2470                                 return;
2471                         }
2472                 }
2473                 if(!SpectateUpdate())
2474                         PutObserverInServer();
2475         }
2476
2477         PrintWelcomeMessage();
2478         self.flags |= FL_CLIENT | FL_NOTARGET;
2479 }
2480
2481 float ctf_usekey();
2482 void PlayerUseKey()
2483 {
2484         if(self.classname != "player")
2485                 return;
2486
2487         if(self.vehicle)
2488         {
2489         vehicles_exit(VHEF_NORMAL);
2490         return;
2491         }
2492
2493         // a use key was pressed; call handlers
2494         if(ctf_usekey())
2495                 return;
2496
2497         MUTATOR_CALLHOOK(PlayerUseKey);
2498 }
2499
2500 .float touchexplode_time;
2501
2502 /*
2503 =============
2504 PlayerPreThink
2505
2506 Called every frame for each client before the physics are run
2507 =============
2508 */
2509 .float usekeypressed;
2510 void() ctf_setstatus;
2511 void() nexball_setstatus;
2512 .float items_added;
2513 void PlayerPreThink (void)
2514 {
2515         WarpZone_PlayerPhysics_FixVAngle();
2516
2517         self.stat_game_starttime = game_starttime;
2518         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2519         self.stat_leadlimit = autocvar_leadlimit;
2520
2521         if(frametime)
2522         {
2523                 // physics frames: update anticheat stuff
2524                 anticheat_prethink();
2525         }
2526
2527         if(blockSpectators && frametime)
2528                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2529                 checkSpectatorBlock();
2530
2531         zoomstate_set = 0;
2532
2533         if(self.netname_previous != self.netname)
2534         {
2535                 if(autocvar_sv_eventlog)
2536                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2537                 if(self.netname_previous)
2538                         strunzone(self.netname_previous);
2539                 self.netname_previous = strzone(self.netname);
2540         }
2541
2542         // version nagging
2543         if(self.version_nagtime)
2544                 if(self.cvar_g_xonoticversion)
2545                         if(time > self.version_nagtime)
2546                         {
2547                                 // don't notify git users
2548                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2549                                 {
2550                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2551                                         {
2552                                                 // notify release users if connecting to git
2553                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2554                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2555                                         }
2556                                         else
2557                                         {
2558                                                 float r;
2559                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2560                                                 if(r < 0)
2561                                                 {
2562                                                         // give users new version
2563                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2564                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2565                                                 }
2566                                                 else if(r > 0)
2567                                                 {
2568                                                         // notify users about old server version
2569                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2570                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2571                                                 }
2572                                         }
2573                                 }
2574                                 self.version_nagtime = 0;
2575                         }
2576
2577         // GOD MODE info
2578         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2579         {
2580                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2581                 self.max_armorvalue = 0;
2582         }
2583
2584 #ifdef TETRIS
2585         if (TetrisPreFrame())
2586                 return;
2587 #endif
2588
2589         MUTATOR_CALLHOOK(PlayerPreThink);
2590
2591         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2592         {
2593                 if(self.BUTTON_USE && !self.usekeypressed)
2594                         PlayerUseKey();
2595                 self.usekeypressed = self.BUTTON_USE;
2596         }
2597
2598         PrintWelcomeMessage();
2599
2600         if(self.classname == "player") {
2601 //              if(self.netname == "Wazat")
2602 //                      bprint(self.classname, "\n");
2603
2604                 CheckRules_Player();
2605
2606                 if (intermission_running)
2607                 {
2608                         IntermissionThink ();   // otherwise a button could be missed between
2609                         return;                                 // the think tics
2610                 }
2611
2612                 //don't allow the player to turn around while game is paused!
2613                 if(timeoutStatus == 2) {
2614                         // FIXME turn this into CSQC stuff
2615                         self.v_angle = self.lastV_angle;
2616                         self.angles = self.lastV_angle;
2617                         self.fixangle = TRUE;
2618                 }
2619
2620                 if(frametime)
2621                 {
2622 #ifndef NO_LEGACY_NETWORKING
2623                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2624 #endif
2625
2626                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2627                         {
2628                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2629                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2630                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2631
2632                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2633                                 {
2634                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2635                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2636                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2637                                 }
2638                         }
2639                         else
2640                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2641
2642                         player_powerups();
2643                 }
2644
2645                 if (g_minstagib)
2646                         minstagib_ammocheck();
2647
2648                 if (self.deadflag != DEAD_NO)
2649                 {
2650                         float button_pressed, force_respawn;
2651                         if(self.personal && g_race_qualifying)
2652                         {
2653                                 if(time > self.death_time)
2654                                 {
2655                                         self.death_time = time + 1; // only retry once a second
2656                                         respawn();
2657                                         self.impulse = 141;
2658                                 }
2659                         }
2660                         else
2661                         {
2662                                 if(frametime)
2663                                         player_anim();
2664                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2665                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2666                                 if (self.deadflag == DEAD_DYING)
2667                                 {
2668                                         if(force_respawn)
2669                                                 self.deadflag = DEAD_RESPAWNING;
2670                                         else if(!button_pressed)
2671                                                 self.deadflag = DEAD_DEAD;
2672                                 }
2673                                 else if (self.deadflag == DEAD_DEAD)
2674                                 {
2675                                         if(button_pressed)
2676                                                 self.deadflag = DEAD_RESPAWNABLE;
2677                                 }
2678                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2679                                 {
2680                                         if(!button_pressed)
2681                                                 self.deadflag = DEAD_RESPAWNING;
2682                                 }
2683                                 else if (self.deadflag == DEAD_RESPAWNING)
2684                                 {
2685                                         if(time > self.death_time)
2686                                         {
2687                                                 self.death_time = time + 1; // only retry once a second
2688                                                 respawn();
2689                                         }
2690                                 }
2691                                 ShowRespawnCountdown();
2692                         }
2693                         return;
2694                 }
2695                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2696                 // so (self.deadflag == DEAD_NO) is always true in the code below
2697
2698                 if(g_touchexplode)
2699                 if(time > self.touchexplode_time)
2700                 if(self.classname == "player")
2701                 if(self.deadflag == DEAD_NO)
2702                 if not(IS_INDEPENDENT_PLAYER(self))
2703                 FOR_EACH_PLAYER(other) if(self != other)
2704                 {
2705                         if(time > other.touchexplode_time)
2706                         if(other.deadflag == DEAD_NO)
2707                         if not(IS_INDEPENDENT_PLAYER(other))
2708                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2709                         {
2710                                 PlayerTouchExplode(self, other);
2711                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2712                         }
2713                 }
2714
2715                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2716                 {
2717                         vector dist;
2718
2719                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2720                         dist = self.prevorigin - self.origin;
2721                         dist_z = 0;
2722                         self.lms_traveled_distance += fabs(vlen(dist));
2723
2724                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2725                         {
2726                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2727                                 self.lms_traveled_distance = 0;
2728                         }
2729
2730                         if(time > self.lms_nextcheck)
2731                         {
2732                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2733                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2734                                 {
2735                                         centerprint(self, autocvar_g_lms_campcheck_message);
2736                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2737                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2738                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2739                                 }
2740                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2741                                 self.lms_traveled_distance = 0;
2742                         }
2743                 }
2744
2745                 self.prevorigin = self.origin;
2746
2747                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2748                 {
2749                         if (!self.crouch)
2750                         {
2751                                 self.crouch = TRUE;
2752                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2753                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2754                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2755                         }
2756                 }
2757                 else
2758                 {
2759                         if (self.crouch)
2760                         {
2761                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2762                                 if (!trace_startsolid)
2763                                 {
2764                                         self.crouch = FALSE;
2765                                         self.view_ofs = PL_VIEW_OFS;
2766                                         setsize (self, PL_MIN, PL_MAX);
2767                                 }
2768                         }
2769                 }
2770
2771                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2772                 {
2773                         if(self.bloodloss_timer < time)
2774                         {
2775                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2776                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2777                         }
2778                 }
2779
2780                 FixPlayermodel();
2781
2782                 GrapplingHookFrame();
2783
2784                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2785                 //if(frametime)
2786                 {
2787                         self.items &~= self.items_added;
2788
2789                         W_WeaponFrame();
2790
2791                         self.items_added = 0;
2792                         if(self.items & IT_JETPACK)
2793                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2794                                         self.items_added |= IT_FUEL;
2795
2796                         self.items |= self.items_added;
2797                 }
2798
2799                 player_regen();
2800
2801                 // rot nex charge to the charge limit
2802                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2803                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2804
2805                 if(frametime)
2806                         player_anim();
2807
2808                 if(g_ctf)
2809                         ctf_setstatus();
2810
2811                 if(g_nexball)
2812                         nexball_setstatus();
2813
2814                 // secret status
2815                 secrets_setstatus();
2816
2817                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2818
2819                 //self.angles_y=self.v_angle_y + 90;   // temp
2820         } else if(gameover) {
2821                 if (intermission_running)
2822                         IntermissionThink ();   // otherwise a button could be missed between
2823                 return;
2824         } else if(self.classname == "observer") {
2825                 ObserverThink();
2826         } else if(self.classname == "spectator") {
2827                 SpectatorThink();
2828         }
2829
2830         if(!zoomstate_set)
2831                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2832
2833         float oldspectatee_status;
2834         oldspectatee_status = self.spectatee_status;
2835         if(self.classname == "spectator")
2836                 self.spectatee_status = num_for_edict(self.enemy);
2837         else if(self.classname == "observer")
2838                 self.spectatee_status = num_for_edict(self);
2839         else
2840                 self.spectatee_status = 0;
2841         if(self.spectatee_status != oldspectatee_status)
2842         {
2843                 ClientData_Touch(self);
2844                 if(g_race || g_cts)
2845                         race_InitSpectator();
2846         }
2847
2848         if(self.teamkill_soundtime)
2849         if(time > self.teamkill_soundtime)
2850         {
2851                 self.teamkill_soundtime = 0;
2852
2853                 entity oldpusher, oldself;
2854
2855                 oldself = self; self = self.teamkill_soundsource;
2856                 oldpusher = self.pusher; self.pusher = oldself;
2857
2858                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2859
2860                 self.pusher = oldpusher;
2861                 self = oldself;
2862         }
2863
2864         if(self.taunt_soundtime)
2865         if(time > self.taunt_soundtime)
2866         {
2867                 self.taunt_soundtime = 0;
2868                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2869         }
2870
2871         target_voicescript_next(self);
2872
2873         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2874         if(!self.weapon)
2875                 self.clip_load = self.clip_size = 0;
2876 }
2877
2878 float isInvisibleString(string s)
2879 {
2880         float i, n, c;
2881         s = strdecolorize(s);
2882         for((i = 0), (n = strlen(s)); i < n; ++i)
2883         {
2884                 c = str2chr(s, i);
2885                 switch(c)
2886                 {
2887                         case 0:
2888                         case 32: // space
2889                                 break;
2890                         case 192: // charmap space
2891                                 if (!autocvar_utf8_enable)
2892                                         break;
2893                                 return FALSE;
2894                         case 160: // space in unicode fonts
2895                         case 0xE000 + 192: // utf8 charmap space
2896                                 if (autocvar_utf8_enable)
2897                                         break;
2898                         default:
2899                                 return FALSE;
2900                 }
2901         }
2902         return TRUE;
2903 }
2904
2905 /*
2906 =============
2907 PlayerPostThink
2908
2909 Called every frame for each client after the physics are run
2910 =============
2911 */
2912 .float idlekick_lasttimeleft;
2913 .entity showheadshotbbox;
2914 void showheadshotbbox_think()
2915 {
2916         if(self.owner.showheadshotbbox != self)
2917         {
2918                 remove(self);
2919                 return;
2920         }
2921         self.nextthink = time;
2922         setorigin(self, self.owner.origin);
2923         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2924 }
2925 void PlayerPostThink (void)
2926 {
2927         // Savage: Check for nameless players
2928         if (isInvisibleString(self.netname)) {
2929                 self.netname = "Player";
2930                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2931         }
2932
2933         if(sv_maxidle && frametime)
2934         {
2935                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2936                 float timeleft;
2937                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2938                 {
2939                         if(self.idlekick_lasttimeleft)
2940                         {
2941                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2942                                 self.idlekick_lasttimeleft = 0;
2943                         }
2944                         return;
2945                 }
2946                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2947                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2948                 {
2949                         if(!self.idlekick_lasttimeleft)
2950                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2951                 }
2952                 if(timeleft <= 0)
2953                 {
2954                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2955                         AnnounceTo(self, "terminated");
2956                         dropclient(self);
2957                         return;
2958                 }
2959                 else if(timeleft <= 10)
2960                 {
2961                         if(timeleft != self.idlekick_lasttimeleft)
2962                                 AnnounceTo(self, ftos(timeleft));
2963                         self.idlekick_lasttimeleft = timeleft;
2964                 }
2965         }
2966
2967 #ifdef TETRIS
2968         if(self.impulse == 100)
2969                 ImpulseCommands();
2970         if (TetrisPostFrame())
2971                 return;
2972 #endif
2973
2974         CheatFrame();
2975
2976         //CheckPlayerJump();
2977
2978         if(self.classname == "player") {
2979                 CheckRules_Player();
2980                 UpdateChatBubble();
2981                 if (self.impulse)
2982                         ImpulseCommands();
2983                 if (intermission_running)
2984                         return;         // intermission or finale
2985                 GetPressedKeys();
2986         } else if (self.classname == "observer") {
2987                 //do nothing
2988         } else if (self.classname == "spectator") {
2989                 //do nothing
2990         }
2991
2992         /*
2993         float i;
2994         for(i = 0; i < 1000; ++i)
2995         {
2996                 vector end;
2997                 end = self.origin + '0 0 1024' + 512 * randomvec();
2998                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2999                 if(trace_fraction < 1)
3000                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3001                 {
3002                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3003                         break;
3004                 }
3005         }
3006         */
3007
3008         Arena_Warmup();
3009
3010         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3011
3012         if(self.waypointsprite_attachedforcarrier)
3013                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3014
3015         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3016         {
3017                 if(!self.showheadshotbbox)
3018                 {
3019                         self.showheadshotbbox = spawn();
3020                         self.showheadshotbbox.classname = "headshotbbox";
3021                         self.showheadshotbbox.owner = self;
3022                         self.showheadshotbbox.think = showheadshotbbox_think;
3023                         self.showheadshotbbox.nextthink = time;
3024                         self = self.showheadshotbbox;
3025                         self.think();
3026                         self = self.owner;
3027                 }
3028         }
3029         else
3030         {
3031                 if(self.showheadshotbbox)
3032                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3033                 remove(self.showheadshotbbox);
3034         }
3035
3036         playerdemo_write();
3037
3038         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3039         {
3040                 if(!self.stored_netname)
3041                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3042                 if(self.stored_netname != self.netname)
3043                 {
3044                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3045                         strunzone(self.stored_netname);
3046                         self.stored_netname = strzone(self.netname);
3047                 }
3048         }
3049
3050         /*
3051         if(g_race)
3052                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3053         */
3054
3055         CSQCMODEL_AUTOUPDATE();
3056 }