qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         Portal_ClearAll(self);
 618
 619         if(self.alivetime)
 620         {
 621                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 622                 self.alivetime = 0;
 623         }
 624
 625         if(self.flagcarried)
 626                 DropFlag(self.flagcarried, world, world);
 627
 628         if(self.ballcarried && g_nexball)
 629                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 630
 631         WaypointSprite_PlayerDead();
 632
 633         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 634                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 635
 636         if(self.killcount != -666) {
 637                 if(g_lms) {
 638                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 639                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 640                         else
 641                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 642                 } else
 643                         bprint ("^4", self.netname, "^4 is spectating now\n");
 644
 645                 if(self.just_joined == FALSE) {
 646                         LogTeamchange(self.playerid, -1, 4);
 647                 } else
 648                         self.just_joined = FALSE;
 649         }
 650
 651         PlayerScore_Clear(self); // clear scores when needed
 652
 653         accuracy_resend(self);
 654
 655         self.spectatortime = time;
 656
 657         self.classname = "observer";
 658         self.iscreature = FALSE;
 659         self.health = -666;
 660         self.takedamage = DAMAGE_NO;
 661         self.solid = SOLID_NOT;
 662         self.movetype = MOVETYPE_NOCLIP;
 663         self.flags = FL_CLIENT | FL_NOTARGET;
 664         self.armorvalue = 666;
 665         self.effects = 0;
 666         self.armorvalue = autocvar_g_balance_armor_start;
 667         self.pauserotarmor_finished = 0;
 668         self.pauserothealth_finished = 0;
 669         self.pauseregen_finished = 0;
 670         self.damageforcescale = 0;
 671         self.death_time = 0;
 672         self.dead_frame = 0;
 673         self.alpha = 0;
 674         self.scale = 0;
 675         self.fade_time = 0;
 676         self.pain_frame = 0;
 677         self.pain_finished = 0;
 678         self.strength_finished = 0;
 679         self.invincible_finished = 0;
 680         self.pushltime = 0;
 681         self.think = SUB_Null;
 682         self.nextthink = 0;
 683         self.hook_time = 0;
 684         self.runes = 0;
 685         self.deadflag = DEAD_NO;
 686         self.angles = spot.angles;
 687         self.angles_z = 0;
 688         self.fixangle = TRUE;
 689         self.crouch = FALSE;
 690
 691         self.view_ofs = PL_VIEW_OFS;
 692         setorigin (self, spot.origin);
 693         setsize (self, '0 0 0', '0 0 0');
 694         self.prevorigin = self.origin;
 695         self.items = 0;
 696         self.weapons = 0;
 697         self.model = "";
 698         FixPlayermodel();
 699         self.model = "";
 700         self.modelindex = 0;
 701         self.weapon = 0;
 702         self.weaponmodel = "";
 703         self.weaponentity = world;
 704         self.exteriorweaponentity = world;
 705         self.killcount = -666;
 706         self.velocity = '0 0 0';
 707         self.avelocity = '0 0 0';
 708         self.punchangle = '0 0 0';
 709         self.punchvector = '0 0 0';
 710         self.oldvelocity = self.velocity;
 711         self.fire_endtime = -1;
 712
 713         if(sv_loddistance1)
 714                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 715
 716         if(g_arena)
 717         {
 718                 if(self.version_mismatch)
 719                 {
 720                         Spawnqueue_Unmark(self);
 721                         Spawnqueue_Remove(self);
 722                 }
 723                 else
 724                 {
 725                         Spawnqueue_Insert(self);
 726                 }
 727         }
 728         else if(g_lms)
 729         {
 730                 // Only if the player cannot play at all
 731                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 732                         self.frags = FRAGS_SPECTATOR;
 733                 else
 734                         self.frags = FRAGS_LMS_LOSER;
 735         }
 736         else
 737                 self.frags = FRAGS_SPECTATOR;
 738 }
 739
 740 void FixPlayermodel()
 741 {
 742         local string defaultmodel;
 743         local float defaultskin, chmdl, oldskin;
 744         local vector m1, m2;
 745
 746         defaultmodel = "";
 747
 748         if(autocvar_sv_defaultcharacter == 1) {
 749                 defaultskin = 0;
 750
 751                 if(teams_matter)
 752                 {
 753                         string s;
 754                         s = Team_ColorNameLowerCase(self.team);
 755                         if(s != "neutral")
 756                         {
 757                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 758                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 759                         }
 760                 }
 761
 762                 if(defaultmodel == "")
 763                 {
 764                         defaultmodel = autocvar_sv_defaultplayermodel;
 765                         defaultskin = autocvar_sv_defaultplayerskin;
 766                 }
 767         }
 768
 769         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 770         {
 771                 if(self.model != "")
 772                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 773                 self.model = ""; // force the != checks to return true
 774         }
 775
 776         if(defaultmodel != "")
 777         {
 778                 if (defaultmodel != self.model)
 779                 {
 780                         m1 = self.mins;
 781                         m2 = self.maxs;
 782                         setmodel_lod (self, defaultmodel);
 783                         setsize (self, m1, m2);
 784                         chmdl = TRUE;
 785                 }
 786
 787                 oldskin = self.skinindex;
 788                 self.skinindex = defaultskin;
 789         } else {
 790                 if (self.playermodel != self.model || self.playermodel == "")
 791                 {
 792                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 793                         m1 = self.mins;
 794                         m2 = self.maxs;
 795                         setmodel_lod (self, self.playermodel);
 796                         setsize (self, m1, m2);
 797                         chmdl = TRUE;
 798                 }
 799
 800                 oldskin = self.skinindex;
 801                 self.skinindex = stof(self.playerskin);
 802         }
 803
 804         if(chmdl || oldskin != self.skinindex)
 805                 self.species = player_getspecies(); // model or skin has changed
 806
 807         if(!teams_matter)
 808                 if(strlen(autocvar_sv_defaultplayercolors))
 809                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 810                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 811 }
 812
 813 void PlayerTouchExplode(entity p1, entity p2)
 814 {
 815         vector org;
 816         org = (p1.origin + p2.origin) * 0.5;
 817         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 818
 819         te_explosion(org);
 820
 821         entity e;
 822         e = spawn();
 823         setorigin(e, org);
 824         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 825         remove(e);
 826 }
 827
 828 /*
 829 =============
 830 PutClientInServer
 831
 832 Called when a client spawns in the server
 833 =============
 834 */
 835 //void() ctf_playerchanged;
 836 void PutClientInServer (void)
 837 {
 838         if(clienttype(self) == CLIENTTYPE_BOT)
 839         {
 840                 self.classname = "player";
 841         }
 842         else if(clienttype(self) == CLIENTTYPE_REAL)
 843         {
 844                 msg_entity = self;
 845                 WriteByte(MSG_ONE, SVC_SETVIEW);
 846                 WriteEntity(MSG_ONE, self);
 847         }
 848
 849         // player is dead and becomes observer
 850         // FIXME fix LMS scoring for new system
 851         if(g_lms)
 852         {
 853                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 854                         self.classname = "observer";
 855         }
 856
 857         if(g_arena || (g_ca && !allowed_to_spawn))
 858         if(!self.spawned)
 859                 self.classname = "observer";
 860
 861         if(gameover)
 862                 self.classname = "observer";
 863
 864         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 865                 entity spot, oldself;
 866                 float j;
 867
 868                 accuracy_resend(self);
 869
 870                 if(self.team < 0)
 871                         JoinBestTeam(self, FALSE, TRUE);
 872
 873                 race_PreSpawn();
 874
 875                 spot = SelectSpawnPoint (FALSE);
 876                 if(!spot)
 877                 {
 878                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 879                         return; // spawn failed
 880                 }
 881
 882                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 883
 884                 self.classname = "player";
 885                 self.wasplayer = TRUE;
 886                 self.iscreature = TRUE;
 887                 self.movetype = MOVETYPE_WALK;
 888                 self.solid = SOLID_SLIDEBOX;
 889                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 890                 if(autocvar_g_playerclip_collisions)
 891                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 892                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 893                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 894                 self.frags = FRAGS_PLAYER;
 895                 if(independent_players)
 896                         MAKE_INDEPENDENT_PLAYER(self);
 897                 self.flags = FL_CLIENT;
 898                 self.takedamage = DAMAGE_AIM;
 899                 if(g_minstagib)
 900                         self.effects = EF_FULLBRIGHT;
 901                 else
 902                         self.effects = 0;
 903                 self.air_finished = time + 12;
 904                 self.dmg = 2;
 905                 if(autocvar_g_balance_nex_charge)
 906                 {
 907                         if(autocvar_g_balance_nex_secondary_chargepool)
 908                                 self.nex_chargepool_ammo = 1;
 909                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 910                 }
 911
 912                 if(inWarmupStage)
 913                 {
 914                         self.ammo_shells = warmup_start_ammo_shells;
 915                         self.ammo_nails = warmup_start_ammo_nails;
 916                         self.ammo_rockets = warmup_start_ammo_rockets;
 917                         self.ammo_cells = warmup_start_ammo_cells;
 918                         self.ammo_fuel = warmup_start_ammo_fuel;
 919                         self.health = warmup_start_health;
 920                         self.armorvalue = warmup_start_armorvalue;
 921                         self.weapons = warmup_start_weapons;
 922                 }
 923                 else
 924                 {
 925                         self.ammo_shells = start_ammo_shells;
 926                         self.ammo_nails = start_ammo_nails;
 927                         self.ammo_rockets = start_ammo_rockets;
 928                         self.ammo_cells = start_ammo_cells;
 929                         self.ammo_fuel = start_ammo_fuel;
 930                         self.health = start_health;
 931                         self.armorvalue = start_armorvalue;
 932                         self.weapons = start_weapons;
 933                 }
 934
 935                 if(g_weaponarena_random)
 936                 {
 937                         if(g_weaponarena_random_with_laser)
 938                                 self.weapons &~= WEPBIT_LASER;
 939                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 940                         if(g_weaponarena_random_with_laser)
 941                                 self.weapons |= WEPBIT_LASER;
 942                 }
 943
 944                 self.items = start_items;
 945                 self.jump_interval = time;
 946
 947                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 948                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 949                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 950                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 951                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 952                 //extend the pause of rotting if client was reset at the beginning of the countdown
 953                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 954                         self.spawnshieldtime += game_starttime - time;
 955                         self.pauserotarmor_finished += game_starttime - time;
 956                         self.pauserothealth_finished += game_starttime - time;
 957                         self.pauseregen_finished += game_starttime - time;
 958                 }
 959                 self.damageforcescale = 2;
 960                 self.death_time = 0;
 961                 self.dead_frame = 0;
 962                 self.alpha = 0;
 963                 self.scale = 0;
 964                 self.fade_time = 0;
 965                 self.pain_frame = 0;
 966                 self.pain_finished = 0;
 967                 self.strength_finished = 0;
 968                 self.invincible_finished = 0;
 969                 self.pushltime = 0;
 970                 // players have no think function
 971                 self.think = SUB_Null;
 972                 self.nextthink = 0;
 973                 self.hook_time = 0;
 974                 self.dmg_team = 0;
 975                 self.ballistics_density = autocvar_g_ballistics_density_player;
 976
 977                 self.metertime = 0;
 978
 979                 self.runes = 0;
 980
 981                 self.deadflag = DEAD_NO;
 982
 983                 self.angles = spot.angles;
 984
 985                 self.angles_z = 0; // never spawn tilted even if the spot says to
 986                 self.fixangle = TRUE; // turn this way immediately
 987                 self.velocity = '0 0 0';
 988                 self.avelocity = '0 0 0';
 989                 self.punchangle = '0 0 0';
 990                 self.punchvector = '0 0 0';
 991                 self.oldvelocity = self.velocity;
 992                 self.fire_endtime = -1;
 993
 994                 msg_entity = self;
 995                 WRITESPECTATABLE_MSG_ONE({
 996                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 997                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 998                 });
 999
1000                 if(sv_loddistance1)
1001                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1002
1003                 self.model = "";
1004                 FixPlayermodel();
1005
1006                 self.crouch = FALSE;
1007                 self.view_ofs = PL_VIEW_OFS;
1008                 setsize (self, PL_MIN, PL_MAX);
1009                 self.spawnorigin = spot.origin;
1010                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1011                 // don't reset back to last position, even if new position is stuck in solid
1012                 self.oldorigin = self.origin;
1013                 self.prevorigin = self.origin;
1014                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1015
1016                 if(g_arena)
1017                 {
1018                         Spawnqueue_Remove(self);
1019                         Spawnqueue_Mark(self);
1020                 }
1021
1022                 else if(g_ca)
1023                         self.caplayer = 1;
1024
1025                 self.event_damage = PlayerDamage;
1026
1027                 self.bot_attack = TRUE;
1028
1029                 self.statdraintime = time + 5;
1030                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1031
1032                 if(self.killcount == -666) {
1033                         PlayerScore_Clear(self);
1034                         self.killcount = 0;
1035                 }
1036
1037                 self.cnt = WEP_LASER;
1038
1039                 CL_SpawnWeaponentity();
1040                 self.alpha = default_player_alpha;
1041                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1042                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1043
1044                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1045                 self.lms_traveled_distance = 0;
1046                 self.speedrunning = FALSE;
1047
1048                 race_PostSpawn(spot);
1049
1050                 if(autocvar_spawn_debug)
1051                 {
1052                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1053                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1054                 }
1055
1056                 //stuffcmd(self, "chase_active 0");
1057                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1058
1059                 if (autocvar_g_spawnsound)
1060                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1061
1062                 if(g_assault) {
1063                         if(self.team == assault_attacker_team)
1064                                 centerprint(self, "You are attacking!");
1065                         else
1066                                 centerprint(self, "You are defending!");
1067                 }
1068
1069                 target_voicescript_clear(self);
1070
1071                 // reset fields the weapons may use
1072                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1073                 {
1074                         weapon_action(j, WR_RESETPLAYER);
1075
1076                         // all weapons must be fully loaded when we spawn
1077                         entity e;
1078                         e = get_weaponinfo(j);
1079                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1080                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1081                 }
1082                 self.weapon_forbidchange = FALSE;
1083
1084                 oldself = self;
1085                 self = spot;
1086                         activator = oldself;
1087                                 SUB_UseTargets();
1088                         activator = world;
1089                 self = oldself;
1090
1091                 MUTATOR_CALLHOOK(PlayerSpawn);
1092
1093                 self.switchweapon = w_getbestweapon(self);
1094                 self.cnt = self.switchweapon;
1095                 self.weapon = 0;
1096
1097                 if(!self.alivetime)
1098                         self.alivetime = time;
1099         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1100                 PutObserverInServer ();
1101         }
1102
1103         //if(g_ctf)
1104         //      ctf_playerchanged();
1105 }
1106
1107 .float ebouncefactor, ebouncestop; // electro's values
1108 // TODO do we need all these fields, or should we stop autodetecting runtime
1109 // changes and just have a console command to update this?
1110 float ClientInit_SendEntity(entity to, float sf)
1111 {
1112         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1113         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1114         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1115         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1116         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1117         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1118         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1119         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1120         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1121         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1122         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1123         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1124         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1126         if(sv_foginterval && world.fog != "")
1127                 WriteString(MSG_ENTITY, world.fog);
1128         else
1129                 WriteString(MSG_ENTITY, "");
1130         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1131         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1132         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1133         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1134         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1135         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1136         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1137         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1138         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1139         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1140         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1141         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1142         return TRUE;
1143 }
1144
1145 void ClientInit_CheckUpdate()
1146 {
1147         self.nextthink = time;
1148         if(self.count != autocvar_g_balance_armor_blockpercent)
1149         {
1150                 self.count = autocvar_g_balance_armor_blockpercent;
1151                 self.SendFlags |= 1;
1152         }
1153         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1154         {
1155                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1156                 self.SendFlags |= 1;
1157         }
1158         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1159         {
1160                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1161                 self.SendFlags |= 1;
1162         }
1163         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1164         {
1165                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1166                 self.SendFlags |= 1;
1167         }
1168         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1169         {
1170                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1171                 self.SendFlags |= 1;
1172         }
1173         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1174         {
1175                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1176                 self.SendFlags |= 1;
1177         }
1178 }
1179
1180 void ClientInit_Spawn()
1181 {
1182         entity o;
1183         entity e;
1184         e = spawn();
1185         e.classname = "clientinit";
1186         e.think = ClientInit_CheckUpdate;
1187         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1188
1189         o = self;
1190         self = e;
1191         ClientInit_CheckUpdate();
1192         self = o;
1193 }
1194
1195 /*
1196 =============
1197 SetNewParms
1198 =============
1199 */
1200 void SetNewParms (void)
1201 {
1202         // initialize parms for a new player
1203         parm1 = -(86400 * 366);
1204 }
1205
1206 /*
1207 =============
1208 SetChangeParms
1209 =============
1210 */
1211 void SetChangeParms (void)
1212 {
1213         // save parms for level change
1214         parm1 = self.parm_idlesince - time;
1215 }
1216
1217 /*
1218 =============
1219 DecodeLevelParms
1220 =============
1221 */
1222 void DecodeLevelParms (void)
1223 {
1224         // load parms
1225         self.parm_idlesince = parm1;
1226         if(self.parm_idlesince == -(86400 * 366))
1227                 self.parm_idlesince = time;
1228
1229         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1230         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1231 }
1232
1233 /*
1234 =============
1235 ClientKill
1236
1237 Called when a client types 'kill' in the console
1238 =============
1239 */
1240
1241 .float clientkill_nexttime;
1242 void ClientKill_Now_TeamChange()
1243 {
1244         if(self.killindicator_teamchange == -1)
1245         {
1246                 self.team = -1;
1247                 JoinBestTeam( self, FALSE, FALSE );
1248         }
1249         else if(self.killindicator_teamchange == -2)
1250         {
1251                 if(g_ca)
1252                         self.caplayer = 0;
1253                 if(blockSpectators)
1254                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1255                 PutObserverInServer();
1256         }
1257         else
1258                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1259 }
1260
1261 void ClientKill_Now()
1262 {
1263         remove(self.killindicator);
1264         self.killindicator = world;
1265
1266         if(self.killindicator_teamchange)
1267                 ClientKill_Now_TeamChange();
1268
1269         // in any case:
1270         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1271
1272         // now I am sure the player IS dead
1273 }
1274 void KillIndicator_Think()
1275 {
1276         if (!self.owner.modelindex)
1277         {
1278                 self.owner.killindicator = world;
1279                 remove(self);
1280                 return;
1281         }
1282
1283         if(self.cnt <= 0)
1284         {
1285                 self = self.owner;
1286                 ClientKill_Now(); // no oldself needed
1287                 return;
1288         }
1289     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1290     {
1291         self.nextthink = time + 1;
1292         self.cnt -= 1;
1293     }
1294         else
1295         {
1296                 if(self.cnt <= 10)
1297                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1298                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1299                 {
1300                         if(self.cnt <= 10)
1301                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1302                         if(self.owner.killindicator_teamchange)
1303                         {
1304                                 if(self.owner.killindicator_teamchange == -1)
1305                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1306                                 else if(self.owner.killindicator_teamchange == -2)
1307                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1308                                 else
1309                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1310                         }
1311                         else
1312                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1313                 }
1314                 self.nextthink = time + 1;
1315                 self.cnt -= 1;
1316         }
1317 }
1318
1319 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1320 {
1321         float killtime;
1322         entity e;
1323         killtime = autocvar_g_balance_kill_delay;
1324
1325         if(g_race_qualifying || g_cts)
1326                 killtime = 0;
1327
1328     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1329     {
1330                 remove(self.killindicator);
1331                 self.killindicator = world;
1332
1333         ClientKill_Now(); // allow instant kill in this case
1334         return;
1335     }
1336
1337         self.killindicator_teamchange = targetteam;
1338
1339     if(!self.killindicator)
1340         {
1341                 if(self.modelindex && self.deadflag == DEAD_NO)
1342                 {
1343                         killtime = max(killtime, self.clientkill_nexttime - time);
1344                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1345                 }
1346
1347                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1348                 {
1349                         ClientKill_Now();
1350                 }
1351                 else
1352                 {
1353                         self.killindicator = spawn();
1354                         self.killindicator.owner = self;
1355                         self.killindicator.scale = 0.5;
1356                         setattachment(self.killindicator, self, "");
1357                         setorigin(self.killindicator, '0 0 52');
1358                         self.killindicator.think = KillIndicator_Think;
1359                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1360                         self.killindicator.cnt = ceil(killtime);
1361                         self.killindicator.count = bound(0, ceil(killtime), 10);
1362                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1363
1364                         for(e = world; (e = find(e, classname, "body")) != world; )
1365                         {
1366                                 if(e.enemy != self)
1367                                         continue;
1368                                 e.killindicator = spawn();
1369                                 e.killindicator.owner = e;
1370                                 e.killindicator.scale = 0.5;
1371                                 setattachment(e.killindicator, e, "");
1372                                 setorigin(e.killindicator, '0 0 52');
1373                                 e.killindicator.think = KillIndicator_Think;
1374                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1375                                 e.killindicator.cnt = ceil(killtime);
1376                         }
1377                         self.lip = 0;
1378                 }
1379         }
1380         if(self.killindicator)
1381         {
1382                 if(targetteam == 0) // just die
1383                         self.killindicator.colormod = '0 0 0';
1384                 else if(targetteam == -1) // auto
1385                         self.killindicator.colormod = '0 1 0';
1386                 else if(targetteam == -2) // spectate
1387                         self.killindicator.colormod = '0.5 0.5 0.5';
1388                 else
1389                         self.killindicator.colormod = TeamColor(targetteam);
1390         }
1391 }
1392
1393 void ClientKill (void)
1394 {
1395         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1396         {
1397                 // do nothing
1398         }
1399     else if(self.freezetag_frozen)
1400     {
1401         // do nothing
1402     }
1403         else
1404                 ClientKill_TeamChange(0);
1405 }
1406
1407 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1408 {
1409     e.killindicator = spawn();
1410     e.killindicator.owner = e;
1411     e.killindicator.think = KillIndicator_Think;
1412     e.killindicator.nextthink = time + (e.lip) * 0.05;
1413     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1414     e.killindicator.health = 1; // this is used to indicate that it should be silent
1415     e.lip = 0;
1416 }
1417
1418 void DoTeamChange(float destteam)
1419 {
1420         float t, c0;
1421         if(!teams_matter)
1422         {
1423                 if(destteam >= 0)
1424                         SetPlayerColors(self, destteam);
1425                 return;
1426         }
1427         if(self.classname == "player")
1428         if(destteam == -1)
1429         {
1430                 CheckAllowedTeams(self);
1431                 t = FindSmallestTeam(self, TRUE);
1432                 switch(self.team)
1433                 {
1434                         case COLOR_TEAM1: c0 = c1; break;
1435                         case COLOR_TEAM2: c0 = c2; break;
1436                         case COLOR_TEAM3: c0 = c3; break;
1437                         case COLOR_TEAM4: c0 = c4; break;
1438                         default:          c0 = 999;
1439                 }
1440                 switch(t)
1441                 {
1442                         case 1:
1443                                 if(c0 > c1)
1444                                         destteam = COLOR_TEAM1;
1445                                 break;
1446                         case 2:
1447                                 if(c0 > c2)
1448                                         destteam = COLOR_TEAM2;
1449                                 break;
1450                         case 3:
1451                                 if(c0 > c3)
1452                                         destteam = COLOR_TEAM3;
1453                                 break;
1454                         case 4:
1455                                 if(c0 > c4)
1456                                         destteam = COLOR_TEAM4;
1457                                 break;
1458                 }
1459                 if(destteam == -1)
1460                         return;
1461         }
1462         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1463                 return;
1464         ClientKill_TeamChange(destteam);
1465 }
1466
1467 void FixClientCvars(entity e)
1468 {
1469         // send prediction settings to the client
1470         stuffcmd(e, "\nin_bindmap 0 0\n");
1471         if(g_race || g_cts)
1472                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1473         if(autocvar_g_antilag == 3) // client side hitscan
1474                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1475         if(sv_gentle)
1476                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1477         /*
1478          * we no longer need to stuff this. Remove this comment block if you feel
1479          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1480         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1481         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1482         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1483         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1484         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1485         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1486         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1487         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1488         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1489         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1490         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1491         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1492         stuffcmd(e, "cl_movement_edgefriction 1\n");
1493          */
1494 }
1495
1496 float PlayerInIDList(entity p, string idlist)
1497 {
1498         float n, i;
1499         string s;
1500
1501         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1502         if not(p.crypto_idfp)
1503                 return 0;
1504
1505         // this function allows abbreviated player IDs too!
1506         n = tokenize_console(idlist);
1507         for(i = 0; i < n; ++i)
1508         {
1509                 s = argv(i);
1510                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1511                         return 1;
1512         }
1513
1514         return 0;
1515 }
1516
1517 /*
1518 =============
1519 ClientConnect
1520
1521 Called when a client connects to the server
1522 =============
1523 */
1524 //void ctf_clientconnect();
1525 string ColoredTeamName(float t);
1526 void DecodeLevelParms (void);
1527 //void dom_player_join_team(entity pl);
1528 void set_dom_state(entity e);
1529 void ClientConnect (void)
1530 {
1531         float t;
1532
1533         if(self.flags & FL_CLIENT)
1534         {
1535                 print("Warning: ClientConnect, but already connected!\n");
1536                 return;
1537         }
1538
1539         if(Ban_MaybeEnforceBan(self))
1540                 return;
1541
1542         DecodeLevelParms();
1543
1544 #ifdef WATERMARK
1545         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1546 #endif
1547
1548         self.classname = "player_joining";
1549
1550         self.flags = FL_CLIENT;
1551         self.version_nagtime = time + 10 + random() * 10;
1552
1553         if(player_count<0)
1554         {
1555                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1556                 player_count = 0;
1557         }
1558
1559         PlayerScore_Attach(self);
1560         ClientData_Attach();
1561         accuracy_init(self);
1562
1563         bot_clientconnect();
1564
1565         playerdemo_init();
1566
1567         anticheat_init();
1568
1569         race_PreSpawnObserver();
1570
1571         //if(g_domination)
1572         //      dom_player_join_team(self);
1573
1574         // identify the right forced team
1575         if(autocvar_g_campaign)
1576         {
1577                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1578                 {
1579                         switch(autocvar_g_campaign_forceteam)
1580                         {
1581                                 case 1: self.team_forced = COLOR_TEAM1; break;
1582                                 case 2: self.team_forced = COLOR_TEAM2; break;
1583                                 case 3: self.team_forced = COLOR_TEAM3; break;
1584                                 case 4: self.team_forced = COLOR_TEAM4; break;
1585                                 default: self.team_forced = 0;
1586                         }
1587                 }
1588         }
1589         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1590                 self.team_forced = COLOR_TEAM1;
1591         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1592                 self.team_forced = COLOR_TEAM2;
1593         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1594                 self.team_forced = COLOR_TEAM3;
1595         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1596                 self.team_forced = COLOR_TEAM4;
1597         else if(autocvar_g_forced_team_otherwise == "red")
1598                 self.team_forced = COLOR_TEAM1;
1599         else if(autocvar_g_forced_team_otherwise == "blue")
1600                 self.team_forced = COLOR_TEAM2;
1601         else if(autocvar_g_forced_team_otherwise == "yellow")
1602                 self.team_forced = COLOR_TEAM3;
1603         else if(autocvar_g_forced_team_otherwise == "pink")
1604                 self.team_forced = COLOR_TEAM4;
1605         else if(autocvar_g_forced_team_otherwise == "spectate")
1606                 self.team_forced = -1;
1607         else if(autocvar_g_forced_team_otherwise == "spectator")
1608                 self.team_forced = -1;
1609         else
1610                 self.team_forced = 0;
1611
1612         if(!teams_matter)
1613                 if(self.team_forced > 0)
1614                         self.team_forced = 0;
1615
1616         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1617
1618         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1619                 self.classname = "observer";
1620         } else {
1621                 if(teams_matter)
1622                 {
1623                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1624                         {
1625                                 self.classname = "player";
1626                                 campaign_bots_may_start = 1;
1627                         }
1628                         else
1629                         {
1630                                 self.classname = "observer"; // do it anyway
1631                         }
1632                 }
1633                 else
1634                 {
1635                         self.classname = "player";
1636                         campaign_bots_may_start = 1;
1637                 }
1638         }
1639
1640         self.playerid = (playerid_last = playerid_last + 1);
1641
1642         if(autocvar_sv_eventlog)
1643                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1644
1645         LogTeamchange(self.playerid, self.team, 1);
1646
1647         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1648
1649         self.netname_previous = strzone(self.netname);
1650
1651         bprint("^4", self.netname, "^4 connected");
1652
1653         if(self.classname != "observer" && (g_domination || g_ctf))
1654                 bprint(" and joined the ", ColoredTeamName(self.team));
1655
1656         bprint("\n");
1657
1658         self.welcomemessage_time = 0;
1659
1660         stuffcmd(self, strcat(clientstuff, "\n"));
1661         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1662         stuffcmd(self, "cl_particles_reloadeffects\n");
1663
1664         FixClientCvars(self);
1665
1666         // spawnfunc_waypoint sprites
1667         WaypointSprite_InitClient(self);
1668
1669         // Wazat's grappling hook
1670         SetGrappleHookBindings();
1671
1672         // get autoswitch state from player when he toggles it
1673         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1674
1675         // get version info from player
1676         stuffcmd(self, "cmd clientversion $gameversion\n");
1677
1678         // get other cvars from player
1679         GetCvars(0);
1680
1681         // notify about available teams
1682         if(teams_matter)
1683         {
1684                 CheckAllowedTeams(self);
1685                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1686                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1687         }
1688         else
1689                 stuffcmd(self, "set _teams_available 0\n");
1690
1691         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1692
1693         if(g_arena || g_ca)
1694         {
1695                 self.classname = "observer";
1696                 if(g_arena)
1697                         Spawnqueue_Insert(self);
1698         }
1699         /*else if(g_ctf)
1700         {
1701                 ctf_clientconnect();
1702         }*/
1703
1704         attach_entcs();
1705
1706         bot_relinkplayerlist();
1707
1708         self.spectatortime = time;
1709         if(blockSpectators)
1710         {
1711                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1712         }
1713
1714         self.jointime = time;
1715         self.allowedTimeouts = autocvar_sv_timeout_number;
1716
1717         if(clienttype(self) == CLIENTTYPE_REAL)
1718         {
1719                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1720                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1721         }
1722
1723         if(g_lms)
1724         {
1725                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1726                 {
1727                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1728                         self.frags = FRAGS_SPECTATOR;
1729                 }
1730         }
1731
1732         if(!sv_foginterval && world.fog != "")
1733                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1734
1735         SoundEntity_Attach(self);
1736
1737         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1738         {
1739                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1740                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1741         }
1742         else
1743                 self.hitplotfh = -1;
1744
1745         if(g_race || g_cts) {
1746                 string rr;
1747                 if(g_cts)
1748                         rr = CTS_RECORD;
1749                 else
1750                         rr = RACE_RECORD;
1751                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1752
1753                 msg_entity = self;
1754                 race_send_recordtime(MSG_ONE);
1755                 race_send_speedaward(MSG_ONE);
1756
1757                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1758                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1759                 race_send_speedaward_alltimebest(MSG_ONE);
1760
1761                 float i;
1762                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1763                         race_SendRankings(i, 0, 0, MSG_ONE);
1764                 }
1765         }
1766         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1767                 send_CSQC_teamnagger();
1768
1769         if (g_domination)
1770                 set_dom_state(self);
1771
1772         CheatInitClient();
1773 }
1774
1775 /*
1776 =============
1777 ClientDisconnect
1778
1779 Called when a client disconnects from the server
1780 =============
1781 */
1782 .entity chatbubbleentity;
1783 void ReadyCount();
1784 void ClientDisconnect (void)
1785 {
1786         if not(self.flags & FL_CLIENT)
1787         {
1788                 print("Warning: ClientDisconnect without ClientConnect\n");
1789                 return;
1790         }
1791
1792         PlayerStats_AddGlobalInfo(self);
1793
1794         CheatShutdownClient();
1795
1796         if(self.hitplotfh >= 0)
1797         {
1798                 fclose(self.hitplotfh);
1799                 self.hitplotfh = -1;
1800         }
1801
1802         anticheat_report();
1803         anticheat_shutdown();
1804
1805         playerdemo_shutdown();
1806
1807         bot_clientdisconnect();
1808
1809         if(self.entcs)
1810                 detach_entcs();
1811
1812         if(autocvar_sv_eventlog)
1813                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1814         bprint ("^4",self.netname);
1815         bprint ("^4 disconnected\n");
1816
1817         SoundEntity_Detach(self);
1818
1819         DropAllRunes(self);
1820         MUTATOR_CALLHOOK(ClientDisconnect);
1821
1822         Portal_ClearAll(self);
1823
1824         if(self.flagcarried)
1825                 DropFlag(self.flagcarried, world, world);
1826         if(self.ballcarried && g_nexball)
1827                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1828
1829         // Here, everything has been done that requires this player to be a client.
1830
1831         self.flags &~= FL_CLIENT;
1832
1833         if (self.chatbubbleentity)
1834                 remove (self.chatbubbleentity);
1835
1836         if (self.killindicator)
1837                 remove (self.killindicator);
1838
1839         WaypointSprite_PlayerGone();
1840
1841         bot_relinkplayerlist();
1842
1843         if(g_arena)
1844         {
1845                 Spawnqueue_Unmark(self);
1846                 Spawnqueue_Remove(self);
1847         }
1848
1849         accuracy_free(self);
1850         ClientData_Detach();
1851         PlayerScore_Detach(self);
1852
1853         if(self.netname_previous)
1854                 strunzone(self.netname_previous);
1855         if(self.clientstatus)
1856                 strunzone(self.clientstatus);
1857         if(self.weaponorder_byimpulse)
1858                 strunzone(self.weaponorder_byimpulse);
1859
1860         ClearPlayerSounds();
1861
1862         if(self.personal)
1863                 remove(self.personal);
1864
1865         self.playerid = 0;
1866         ReadyCount();
1867
1868         // free cvars
1869         GetCvars(-1);
1870 }
1871
1872 .float BUTTON_CHAT;
1873 void ChatBubbleThink()
1874 {
1875         self.nextthink = time;
1876         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1877         {
1878                 if(self.owner) // but why can that ever be world?
1879                         self.owner.chatbubbleentity = world;
1880                 remove(self);
1881                 return;
1882         }
1883         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1884 #ifdef TETRIS
1885                 || self.owner.tetris_on
1886 #endif
1887         )
1888                 self.model = self.mdl;
1889         else
1890                 self.model = "";
1891 };
1892
1893 void UpdateChatBubble()
1894 {
1895         if (!self.modelindex)
1896                 return;
1897         // spawn a chatbubble entity if needed
1898         if (!self.chatbubbleentity)
1899         {
1900                 self.chatbubbleentity = spawn();
1901                 self.chatbubbleentity.owner = self;
1902                 self.chatbubbleentity.exteriormodeltoclient = self;
1903                 self.chatbubbleentity.think = ChatBubbleThink;
1904                 self.chatbubbleentity.nextthink = time;
1905                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1906                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1907                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1908                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1909                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1910                 self.chatbubbleentity.model = "";
1911                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1912         }
1913 }
1914
1915
1916 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1917 // added to the model skins
1918 /*void UpdateColorModHack()
1919 {
1920         local float c;
1921         c = self.clientcolors & 15;
1922         // LordHavoc: only bothering to support white, green, red, yellow, blue
1923              if (!teams_matter) self.colormod = '0 0 0';
1924         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1925         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1926         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1927         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1928         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1929         else self.colormod = '1 1 1';
1930 };*/
1931
1932 .float oldcolormap;
1933 void respawn(void)
1934 {
1935         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1936         {
1937                 self.solid = SOLID_NOT;
1938                 self.takedamage = DAMAGE_NO;
1939                 self.movetype = MOVETYPE_FLY;
1940                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1941                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1942                 self.effects |= EF_ADDITIVE;
1943                 self.oldcolormap = self.colormap;
1944                 self.colormap = 512;
1945                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1946                 if(autocvar_g_respawn_ghosts_maxtime)
1947                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1948         }
1949
1950         CopyBody(1);
1951         self.effects |= EF_NODRAW; // prevent another CopyBody
1952         if(self.oldcolormap)
1953         {
1954                 self.colormap = self.oldcolormap;
1955                 self.oldcolormap = 0;
1956         }
1957         PutClientInServer();
1958 }
1959
1960 void play_countdown(float finished, string samp)
1961 {
1962         if(clienttype(self) == CLIENTTYPE_REAL)
1963                 if(floor(finished - time - frametime) != floor(finished - time))
1964                         if(finished - time < 6)
1965                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1966 }
1967
1968 /**
1969  * When sv_timeout is used this function returs strings like
1970  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1971  * Called by centerprint functions
1972  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1973  */
1974 string getTimeoutText(float addOneSecond) {
1975         if (!autocvar_sv_timeout || !timeoutStatus)
1976                 return "";
1977
1978         local string retStr;
1979         if (timeoutStatus == 1) {
1980                 if (addOneSecond == 1) {
1981                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1982                 }
1983                 else {
1984                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1985                 }
1986                 return retStr;
1987         }
1988         else if (timeoutStatus == 2) {
1989                 if (addOneSecond) {
1990                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1991                         //don't show messages like "Timeout ends in 0 seconds"...
1992                         if ((remainingTimeoutTime + 1) > 0)
1993                                 return retStr;
1994                         else
1995                                 return "";
1996                 }
1997                 else {
1998                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1999                         //don't show messages like "Timeout ends in 0 seconds"...
2000                         if (remainingTimeoutTime > 0)
2001                                 return retStr;
2002                         else
2003                                 return "";
2004                 }
2005         }
2006         else return "";
2007 }
2008
2009 void player_powerups (void)
2010 {
2011         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2012         olditems = self.items;
2013
2014         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2015         {
2016                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2017                 self.modelflags |= MF_ROCKET;
2018         }
2019         else
2020         {
2021                 SoundEntity_StopSound(self, CHAN_PLAYER);
2022                 self.modelflags &~= MF_ROCKET;
2023         }
2024
2025         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2026
2027         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2028                 return;
2029
2030         Fire_ApplyDamage(self);
2031         Fire_ApplyEffect(self);
2032
2033         if (g_minstagib)
2034         {
2035                 self.effects |= EF_FULLBRIGHT;
2036
2037                 if (self.items & IT_STRENGTH)
2038                 {
2039                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2040                         if (time > self.strength_finished)
2041                         {
2042                                 self.alpha = default_player_alpha;
2043                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2044                                 self.items &~= IT_STRENGTH;
2045                                 sprint(self, "^3Invisibility has worn off\n");
2046                         }
2047                 }
2048                 else
2049                 {
2050                         if (time < self.strength_finished)
2051                         {
2052                                 self.alpha = g_minstagib_invis_alpha;
2053                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2054                                 self.items |= IT_STRENGTH;
2055                                 sprint(self, "^3You are invisible\n");
2056                         }
2057                 }
2058
2059                 if (self.items & IT_INVINCIBLE)
2060                 {
2061                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2062                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2063                         {
2064                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2065                                 sprint(self, "^3Speed has worn off\n");
2066                         }
2067                 }
2068                 else
2069                 {
2070                         if (time < self.invincible_finished)
2071                         {
2072                                 self.items = self.items | IT_INVINCIBLE;
2073                                 sprint(self, "^3You are on speed\n");
2074                         }
2075                 }
2076         }
2077         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2078         {
2079                 if (self.items & IT_STRENGTH)
2080                 {
2081                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2082                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2083                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2084                         {
2085                                 self.items = self.items - (self.items & IT_STRENGTH);
2086                                 sprint(self, "^3Strength has worn off\n");
2087                         }
2088                 }
2089                 else
2090                 {
2091                         if (time < self.strength_finished)
2092                         {
2093                                 self.items = self.items | IT_STRENGTH;
2094                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2095                         }
2096                 }
2097                 if (self.items & IT_INVINCIBLE)
2098                 {
2099                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2100                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2101                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2102                         {
2103                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2104                                 sprint(self, "^3Shield has worn off\n");
2105                         }
2106                 }
2107                 else
2108                 {
2109                         if (time < self.invincible_finished)
2110                         {
2111                                 self.items = self.items | IT_INVINCIBLE;
2112                                 sprint(self, "^3Shield surrounds you\n");
2113                         }
2114                 }
2115
2116                 if(autocvar_g_nodepthtestplayers)
2117                         self.effects = self.effects | EF_NODEPTHTEST;
2118
2119                 if(autocvar_g_fullbrightplayers)
2120                         self.effects = self.effects | EF_FULLBRIGHT;
2121
2122                 // midair gamemode: damage only while in the air
2123                 // if in midair mode, being on ground grants temporary invulnerability
2124                 // (this is so that multishot weapon don't clear the ground flag on the
2125                 // first damage in the frame, leaving the player vulnerable to the
2126                 // remaining hits in the same frame)
2127                 if (self.flags & FL_ONGROUND)
2128                 if (g_midair)
2129                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2130
2131                 if (time >= game_starttime)
2132                 if (time < self.spawnshieldtime)
2133                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2134         }
2135
2136         MUTATOR_CALLHOOK(PlayerPowerups);
2137 }
2138
2139 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2140 {
2141         if(current > stable)
2142                 return current;
2143         else if(current > stable - 0.25) // when close enough, "snap"
2144                 return stable;
2145         else
2146                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2147 }
2148
2149 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2150 {
2151         if(current < stable)
2152                 return current;
2153         else if(current < stable + 0.25) // when close enough, "snap"
2154                 return stable;
2155         else
2156                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2157 }
2158
2159 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2160 {
2161         if(current > rotstable)
2162         {
2163                 if(rotframetime > 0)
2164                 {
2165                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2166                         current = max(rotstable, current - rotlinear * rotframetime);
2167                 }
2168         }
2169         else if(current < regenstable)
2170         {
2171                 if(regenframetime > 0)
2172                 {
2173                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2174                         current = min(regenstable, current + regenlinear * regenframetime);
2175                 }
2176         }
2177
2178         if(current > limit)
2179                 current = limit;
2180
2181         return current;
2182 }
2183
2184 void player_regen (void)
2185 {
2186         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2187         maxh = autocvar_g_balance_health_rotstable;
2188         maxa = autocvar_g_balance_armor_rotstable;
2189         maxf = autocvar_g_balance_fuel_rotstable;
2190         minh = autocvar_g_balance_health_regenstable;
2191         mina = autocvar_g_balance_armor_regenstable;
2192         minf = autocvar_g_balance_fuel_regenstable;
2193         limith = autocvar_g_balance_health_limit;
2194         limita = autocvar_g_balance_armor_limit;
2195         limitf = autocvar_g_balance_fuel_limit;
2196
2197         max_mod = regen_mod = rot_mod = limit_mod = 1;
2198
2199         if (self.runes & RUNE_REGEN)
2200         {
2201                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2202                 {
2203                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2204                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2205                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2206                 }
2207                 else
2208                 {
2209                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2210                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2211                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2212                 }
2213         }
2214         else if (self.runes & CURSE_VENOM)
2215         {
2216                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2217                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2218                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2219                 else
2220                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2221                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2222                 //if (!self.runes & RUNE_REGEN)
2223                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2224         }
2225         maxh = maxh * max_mod;
2226         //maxa = maxa * max_mod;
2227         //maxf = maxf * max_mod;
2228         minh = minh * max_mod;
2229         //mina = mina * max_mod;
2230         //minf = minf * max_mod;
2231         limith = limith * limit_mod;
2232         limita = limita * limit_mod;
2233         //limitf = limitf * limit_mod;
2234
2235         if(g_lms && g_ca)
2236                 rot_mod = 0;
2237
2238         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2239         {
2240                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2241                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2242
2243                 // if player rotted to death...  die!
2244                 if(self.health < 1)
2245                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2246         }
2247
2248         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2249                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2250 }
2251
2252 float zoomstate_set;
2253 void SetZoomState(float z)
2254 {
2255         if(z != self.zoomstate)
2256         {
2257                 self.zoomstate = z;
2258                 ClientData_Touch(self);
2259         }
2260         zoomstate_set = 1;
2261 }
2262
2263 void GetPressedKeys(void) {
2264         MUTATOR_CALLHOOK(GetPressedKeys);
2265         if (self.movement_x > 0) // get if movement keys are pressed
2266         {       // forward key pressed
2267                 self.pressedkeys |= KEY_FORWARD;
2268                 self.pressedkeys &~= KEY_BACKWARD;
2269         }
2270         else if (self.movement_x < 0)
2271         {       // backward key pressed
2272                 self.pressedkeys |= KEY_BACKWARD;
2273                 self.pressedkeys &~= KEY_FORWARD;
2274         }
2275         else
2276         {       // no x input
2277                 self.pressedkeys &~= KEY_FORWARD;
2278                 self.pressedkeys &~= KEY_BACKWARD;
2279         }
2280
2281         if (self.movement_y > 0)
2282         {       // right key pressed
2283                 self.pressedkeys |= KEY_RIGHT;
2284                 self.pressedkeys &~= KEY_LEFT;
2285         }
2286         else if (self.movement_y < 0)
2287         {       // left key pressed
2288                 self.pressedkeys |= KEY_LEFT;
2289                 self.pressedkeys &~= KEY_RIGHT;
2290         }
2291         else
2292         {       // no y input
2293                 self.pressedkeys &~= KEY_RIGHT;
2294                 self.pressedkeys &~= KEY_LEFT;
2295         }
2296
2297         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2298                 self.pressedkeys |= KEY_JUMP;
2299         else
2300                 self.pressedkeys &~= KEY_JUMP;
2301         if (self.BUTTON_CROUCH)
2302                 self.pressedkeys |= KEY_CROUCH;
2303         else
2304                 self.pressedkeys &~= KEY_CROUCH;
2305 }
2306
2307 /*
2308 ======================
2309 spectate mode routines
2310 ======================
2311 */
2312
2313 void SpectateCopy(entity spectatee) {
2314         other = spectatee;
2315         MUTATOR_CALLHOOK(SpectateCopy);
2316         self.armortype = spectatee.armortype;
2317         self.armorvalue = spectatee.armorvalue;
2318         self.ammo_cells = spectatee.ammo_cells;
2319         self.ammo_shells = spectatee.ammo_shells;
2320         self.ammo_nails = spectatee.ammo_nails;
2321         self.ammo_rockets = spectatee.ammo_rockets;
2322         self.ammo_fuel = spectatee.ammo_fuel;
2323         self.clip_load = spectatee.clip_load;
2324         self.clip_size = spectatee.clip_size;
2325         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2326         self.health = spectatee.health;
2327         self.impulse = 0;
2328         self.items = spectatee.items;
2329         self.last_pickup = spectatee.last_pickup;
2330         self.hit_time = spectatee.hit_time;
2331         self.metertime = spectatee.metertime;
2332         self.strength_finished = spectatee.strength_finished;
2333         self.invincible_finished = spectatee.invincible_finished;
2334         self.pressedkeys = spectatee.pressedkeys;
2335         self.weapons = spectatee.weapons;
2336         self.switchweapon = spectatee.switchweapon;
2337         self.weapon = spectatee.weapon;
2338         self.nex_charge = spectatee.nex_charge;
2339         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2340         self.hagar_load = spectatee.hagar_load;
2341         self.minelayer_mines = spectatee.minelayer_mines;
2342         self.punchangle = spectatee.punchangle;
2343         self.view_ofs = spectatee.view_ofs;
2344         self.v_angle = spectatee.v_angle;
2345         self.velocity = spectatee.velocity;
2346         self.dmg_take = spectatee.dmg_take;
2347         self.dmg_save = spectatee.dmg_save;
2348         self.dmg_inflictor = spectatee.dmg_inflictor;
2349         self.angles = spectatee.v_angle;
2350         self.fixangle = TRUE;
2351         setorigin(self, spectatee.origin);
2352         setsize(self, spectatee.mins, spectatee.maxs);
2353         SetZoomState(spectatee.zoomstate);
2354
2355         anticheat_spectatecopy(spectatee);
2356 }
2357
2358 float SpectateUpdate() {
2359         if(!self.enemy)
2360                 return 0;
2361
2362         if (self == self.enemy)
2363                 return 0;
2364
2365         if(self.enemy.classname != "player")
2366                 return 0;
2367
2368         SpectateCopy(self.enemy);
2369
2370         return 1;
2371 }
2372
2373 float SpectateNext() {
2374         other = find(self.enemy, classname, "player");
2375
2376         if (!other)
2377                 other = find(other, classname, "player");
2378
2379         if (other)
2380                 self.enemy = other;
2381
2382         if(self.enemy.classname == "player") {
2383                 msg_entity = self;
2384                 WriteByte(MSG_ONE, SVC_SETVIEW);
2385                 WriteEntity(MSG_ONE, self.enemy);
2386                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2387                 self.movetype = MOVETYPE_NONE;
2388                 accuracy_resend(self);
2389
2390                 if(!SpectateUpdate())
2391                         PutObserverInServer();
2392
2393                 return 1;
2394         } else {
2395                 return 0;
2396         }
2397 }
2398
2399 /*
2400 =============
2401 ShowRespawnCountdown()
2402
2403 Update a respawn countdown display.
2404 =============
2405 */
2406 void ShowRespawnCountdown()
2407 {
2408         float number;
2409         if(self.deadflag == DEAD_NO) // just respawned?
2410                 return;
2411         else
2412         {
2413                 number = ceil(self.death_time - time);
2414                 if(number <= 0)
2415                         return;
2416                 if(number <= self.respawn_countdown)
2417                 {
2418                         self.respawn_countdown = number - 1;
2419                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2420                                 AnnounceTo(self, strcat(ftos(number), ""));
2421                 }
2422         }
2423 }
2424
2425 void LeaveSpectatorMode()
2426 {
2427         if(nJoinAllowed(1)) {
2428                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2429                         self.classname = "player";
2430
2431                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2432                                 JoinBestTeam(self, FALSE, TRUE);
2433
2434                         if(autocvar_g_campaign)
2435                                 campaign_bots_may_start = 1;
2436
2437                         PutClientInServer();
2438
2439                         if(self.classname == "player")
2440                                 bprint ("^4", self.netname, "^4 is playing now\n");
2441
2442                         if(!autocvar_g_campaign)
2443                                 centerprint(self,""); // clear MOTD
2444
2445                         return;
2446                 } else {
2447                         if (g_ca && self.caplayer) {
2448                         }       // do nothing
2449                         else
2450                                 stuffcmd(self,"menu_showteamselect\n");
2451                         return;
2452                 }
2453         }
2454         else {
2455                 //player may not join because of g_maxplayers is set
2456                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2457         }
2458 }
2459
2460 /**
2461  * Determines whether the player is allowed to join. This depends on cvar
2462  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2463  * it checks whether the number of currently playing players exceeds g_maxplayers.
2464  * @return int number of free slots for players, 0 if none
2465  */
2466 float nJoinAllowed(float includeMe) {
2467         if(self.team_forced < 0)
2468                 return FALSE; // forced spectators can never join
2469
2470         // TODO simplify this
2471         local entity e;
2472
2473         local float totalClients;
2474         FOR_EACH_CLIENT(e)
2475                 totalClients += 1;
2476
2477         if (!autocvar_g_maxplayers)
2478                 return maxclients - totalClients + includeMe;
2479
2480         local float currentlyPlaying;
2481         FOR_EACH_REALPLAYER(e)
2482                 currentlyPlaying += 1;
2483
2484         if(currentlyPlaying < autocvar_g_maxplayers)
2485                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2486
2487         return 0;
2488 }
2489
2490 /**
2491  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2492  * g_maxplayers_spectator_blocktime seconds
2493  */
2494 void checkSpectatorBlock() {
2495         if(self.classname == "spectator" || self.classname == "observer") {
2496                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2497                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2498                         dropclient(self);
2499                 }
2500         }
2501 }
2502
2503 void ObserverThink()
2504 {
2505         if (self.flags & FL_JUMPRELEASED) {
2506                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2507                         self.welcomemessage_time = 0;
2508                         self.flags &~= FL_JUMPRELEASED;
2509                         self.flags |= FL_SPAWNING;
2510                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2511                         self.welcomemessage_time = 0;
2512                         self.flags &~= FL_JUMPRELEASED;
2513                         if(SpectateNext() == 1) {
2514                                 self.classname = "spectator";
2515                         }
2516                 }
2517         } else {
2518                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2519                         self.flags |= FL_JUMPRELEASED;
2520                         if(self.flags & FL_SPAWNING)
2521                         {
2522                                 self.flags &~= FL_SPAWNING;
2523                                 LeaveSpectatorMode();
2524                                 return;
2525                         }
2526                 }
2527         }
2528         PrintWelcomeMessage(self);
2529 }
2530
2531 void SpectatorThink()
2532 {
2533         if (self.flags & FL_JUMPRELEASED) {
2534                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2535                         self.welcomemessage_time = 0;
2536                         self.flags &~= FL_JUMPRELEASED;
2537                         self.flags |= FL_SPAWNING;
2538                 } else if(self.BUTTON_ATCK) {
2539                         self.welcomemessage_time = 0;
2540                         self.flags &~= FL_JUMPRELEASED;
2541                         if(SpectateNext() == 1) {
2542                                 self.classname = "spectator";
2543                         } else {
2544                                 self.classname = "observer";
2545                                 PutClientInServer();
2546                         }
2547                 } else if (self.BUTTON_ATCK2) {
2548                         self.welcomemessage_time = 0;
2549                         self.flags &~= FL_JUMPRELEASED;
2550                         self.classname = "observer";
2551                         PutClientInServer();
2552                 } else {
2553                         if(!SpectateUpdate())
2554                                 PutObserverInServer();
2555                 }
2556         } else {
2557                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2558                         self.flags |= FL_JUMPRELEASED;
2559                         if(self.flags & FL_SPAWNING)
2560                         {
2561                                 self.flags &~= FL_SPAWNING;
2562                                 LeaveSpectatorMode();
2563                                 return;
2564                         }
2565                 }
2566         }
2567
2568         PrintWelcomeMessage(self);
2569         self.flags |= FL_CLIENT | FL_NOTARGET;
2570 }
2571
2572 .float touchexplode_time;
2573
2574 /*
2575 =============
2576 PlayerPreThink
2577
2578 Called every frame for each client before the physics are run
2579 =============
2580 */
2581 void() ctf_setstatus;
2582 void() nexball_setstatus;
2583 .float items_added;
2584 void PlayerPreThink (void)
2585 {
2586         WarpZone_PlayerPhysics_FixVAngle();
2587
2588         self.stat_game_starttime = game_starttime;
2589         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2590         self.stat_leadlimit = autocvar_leadlimit;
2591
2592         if(frametime)
2593         {
2594                 // physics frames: update anticheat stuff
2595                 anticheat_prethink();
2596         }
2597
2598         if(blockSpectators && frametime)
2599                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2600                 checkSpectatorBlock();
2601
2602         zoomstate_set = 0;
2603
2604         if(self.netname_previous != self.netname)
2605         {
2606                 if(autocvar_sv_eventlog)
2607                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2608                 if(self.netname_previous)
2609                         strunzone(self.netname_previous);
2610                 self.netname_previous = strzone(self.netname);
2611         }
2612
2613         // version nagging
2614         if(self.version_nagtime)
2615                 if(self.cvar_g_xonoticversion)
2616                         if(time > self.version_nagtime)
2617                         {
2618                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2619                                 {
2620                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2621                                         {
2622                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2623                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2624                                         }
2625                                         else
2626                                         {
2627                                                 float r;
2628                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2629                                                 if(r < 0)
2630                                                 {
2631                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2632                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2633                                                 }
2634                                                 else if(r > 0)
2635                                                 {
2636                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2637                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2638                                                 }
2639                                         }
2640                                 }
2641                                 self.version_nagtime = 0;
2642                         }
2643
2644         // GOD MODE info
2645         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2646         {
2647                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2648                 self.max_armorvalue = 0;
2649         }
2650
2651 #ifdef TETRIS
2652         if (TetrisPreFrame())
2653                 return;
2654 #endif
2655
2656         MUTATOR_CALLHOOK(PlayerPreThink);
2657
2658         if(self.classname == "player") {
2659 //              if(self.netname == "Wazat")
2660 //                      bprint(self.classname, "\n");
2661
2662                 CheckRules_Player();
2663
2664                 PrintWelcomeMessage(self);
2665
2666                 if (intermission_running)
2667                 {
2668                         IntermissionThink ();   // otherwise a button could be missed between
2669                         return;                                 // the think tics
2670                 }
2671
2672                 //don't allow the player to turn around while game is paused!
2673                 if(timeoutStatus == 2) {
2674                         self.v_angle = self.lastV_angle;
2675                         self.angles = self.lastV_angle;
2676                         self.fixangle = TRUE;
2677                 }
2678
2679                 if(frametime)
2680                 {
2681                         if(self.health <= 0 && autocvar_g_deathglow)
2682                         {
2683                                 if(self.glowmod_x > 0)
2684                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2685                                 else
2686                                         self.glowmod_x = -1;
2687                                 if(self.glowmod_y > 0)
2688                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2689                                 else
2690                                         self.glowmod_y = -1;
2691                                 if(self.glowmod_z > 0)
2692                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2693                                 else
2694                                         self.glowmod_z = -1;
2695                         }
2696                         else
2697                         {
2698                                 // set weapon and player glowmod
2699                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2700
2701                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2702                                 {
2703                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2704                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2705                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2706
2707                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2708                                         {
2709                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2710                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2711                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2712                                         }
2713                                 }
2714                                 else
2715                                         self.weaponentity_glowmod = self.glowmod;
2716                         }
2717                         player_powerups();
2718                 }
2719
2720                 if (self.deadflag != DEAD_NO)
2721                 {
2722                         float button_pressed, force_respawn;
2723                         if(self.personal && g_race_qualifying)
2724                         {
2725                                 if(time > self.death_time)
2726                                 {
2727                                         self.death_time = time + 1; // only retry once a second
2728                                         respawn();
2729                                         self.impulse = 141;
2730                                 }
2731                         }
2732                         else
2733                         {
2734                                 if(frametime)
2735                                         player_anim();
2736                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2737                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2738                                 if (self.deadflag == DEAD_DYING)
2739                                 {
2740                                         if(force_respawn)
2741                                                 self.deadflag = DEAD_RESPAWNING;
2742                                         else if(!button_pressed)
2743                                                 self.deadflag = DEAD_DEAD;
2744                                 }
2745                                 else if (self.deadflag == DEAD_DEAD)
2746                                 {
2747                                         if(button_pressed)
2748                                                 self.deadflag = DEAD_RESPAWNABLE;
2749                                 }
2750                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2751                                 {
2752                                         if(!button_pressed)
2753                                                 self.deadflag = DEAD_RESPAWNING;
2754                                 }
2755                                 else if (self.deadflag == DEAD_RESPAWNING)
2756                                 {
2757                                         if(time > self.death_time)
2758                                         {
2759                                                 self.death_time = time + 1; // only retry once a second
2760                                                 respawn();
2761                                         }
2762                                 }
2763                                 ShowRespawnCountdown();
2764                         }
2765                         return;
2766                 }
2767
2768                 if(g_touchexplode)
2769                 if(time > self.touchexplode_time)
2770                 if(self.classname == "player")
2771                 if(self.deadflag == DEAD_NO)
2772                 if not(IS_INDEPENDENT_PLAYER(self))
2773                 FOR_EACH_PLAYER(other) if(self != other)
2774                 {
2775                         if(time > other.touchexplode_time)
2776                         if(other.deadflag == DEAD_NO)
2777                         if not(IS_INDEPENDENT_PLAYER(other))
2778                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2779                         {
2780                                 PlayerTouchExplode(self, other);
2781                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2782                         }
2783                 }
2784
2785                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2786                 {
2787                         vector dist;
2788
2789                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2790                         dist = self.prevorigin - self.origin;
2791                         dist_z = 0;
2792                         self.lms_traveled_distance += fabs(vlen(dist));
2793
2794                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2795                         {
2796                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2797                                 self.lms_traveled_distance = 0;
2798                         }
2799
2800                         if(time > self.lms_nextcheck)
2801                         {
2802                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2803                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2804                                 {
2805                                         centerprint(self, autocvar_g_lms_campcheck_message);
2806                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2807                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2808                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2809                                 }
2810                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2811                                 self.lms_traveled_distance = 0;
2812                         }
2813                 }
2814
2815                 self.prevorigin = self.origin;
2816
2817                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2818                 {
2819                         if (!self.crouch)
2820                         {
2821                                 self.crouch = TRUE;
2822                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2823                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2824                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2825                         }
2826                 }
2827                 else
2828                 {
2829                         if (self.crouch)
2830                         {
2831                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2832                                 if (!trace_startsolid)
2833                                 {
2834                                         self.crouch = FALSE;
2835                                         self.view_ofs = PL_VIEW_OFS;
2836                                         setsize (self, PL_MIN, PL_MAX);
2837                                 }
2838                         }
2839                 }
2840
2841                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2842                 {
2843                         if(self.bloodloss_timer < time)
2844                         {
2845                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2846                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2847                         }
2848                 }
2849
2850                 FixPlayermodel();
2851
2852                 GrapplingHookFrame();
2853
2854                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2855                 //if(frametime)
2856                 {
2857                         self.items &~= self.items_added;
2858
2859                         W_WeaponFrame();
2860
2861                         self.items_added = 0;
2862                         if(self.items & IT_JETPACK)
2863                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2864                                         self.items_added |= IT_FUEL;
2865
2866                         self.items |= self.items_added;
2867                 }
2868
2869                 player_regen();
2870
2871                 // rot nex charge to the charge limit
2872                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2873                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2874
2875                 if(frametime)
2876                         player_anim();
2877
2878                 if (g_minstagib)
2879                         minstagib_ammocheck();
2880
2881                 if(g_ctf)
2882                         ctf_setstatus();
2883
2884                 if(g_nexball)
2885                         nexball_setstatus();
2886
2887                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2888
2889                 //self.angles_y=self.v_angle_y + 90;   // temp
2890         } else if(gameover) {
2891                 if (intermission_running)
2892                         IntermissionThink ();   // otherwise a button could be missed between
2893                 return;
2894         } else if(self.classname == "observer") {
2895                 ObserverThink();
2896         } else if(self.classname == "spectator") {
2897                 SpectatorThink();
2898         }
2899
2900         if(!zoomstate_set)
2901                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2902
2903         float oldspectatee_status;
2904         oldspectatee_status = self.spectatee_status;
2905         if(self.classname == "spectator")
2906                 self.spectatee_status = num_for_edict(self.enemy);
2907         else if(self.classname == "observer")
2908                 self.spectatee_status = num_for_edict(self);
2909         else
2910                 self.spectatee_status = 0;
2911         if(self.spectatee_status != oldspectatee_status)
2912         {
2913                 ClientData_Touch(self);
2914                 if(g_race || g_cts)
2915                         race_InitSpectator();
2916         }
2917
2918         if(self.teamkill_soundtime)
2919         if(time > self.teamkill_soundtime)
2920         {
2921                 self.teamkill_soundtime = 0;
2922
2923                 entity oldpusher, oldself;
2924
2925                 oldself = self; self = self.teamkill_soundsource;
2926                 oldpusher = self.pusher; self.pusher = oldself;
2927
2928                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2929
2930                 self.pusher = oldpusher;
2931                 self = oldself;
2932         }
2933
2934         if(self.taunt_soundtime)
2935         if(time > self.taunt_soundtime)
2936         {
2937                 self.taunt_soundtime = 0;
2938                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2939         }
2940
2941         target_voicescript_next(self);
2942
2943         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2944         if(!self.weapon)
2945                 self.clip_load = self.clip_size = 0;
2946 }
2947
2948 float isInvisibleString(string s)
2949 {
2950         float i, n, c;
2951         s = strdecolorize(s);
2952         for((i = 0), (n = strlen(s)); i < n; ++i)
2953         {
2954                 c = str2chr(s, i);
2955                 switch(c)
2956                 {
2957                         case 0:
2958                         case 32: // space
2959                                 break;
2960                         case 192: // charmap space
2961                                 if (!autocvar_utf8_enable)
2962                                         break;
2963                                 return FALSE;
2964                         case 160: // space in unicode fonts
2965                         case 0xE000 + 192: // utf8 charmap space
2966                                 if (autocvar_utf8_enable)
2967                                         break;
2968                         default:
2969                                 return FALSE;
2970                 }
2971         }
2972         return TRUE;
2973 }
2974
2975 /*
2976 =============
2977 PlayerPostThink
2978
2979 Called every frame for each client after the physics are run
2980 =============
2981 */
2982 .float idlekick_lasttimeleft;
2983 .entity showheadshotbbox;
2984 void showheadshotbbox_think()
2985 {
2986         if(self.owner.showheadshotbbox != self)
2987         {
2988                 remove(self);
2989                 return;
2990         }
2991         self.nextthink = time;
2992         setorigin(self, self.owner.origin);
2993         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2994 }
2995 void PlayerPostThink (void)
2996 {
2997         // Savage: Check for nameless players
2998         if (isInvisibleString(self.netname)) {
2999                 self.netname = "Player";
3000                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3001         }
3002
3003         if(sv_maxidle && frametime)
3004         {
3005                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3006                 float timeleft;
3007                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3008                 if(timeleft <= 0)
3009                 {
3010                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3011                         AnnounceTo(self, "terminated");
3012                         dropclient(self);
3013                         return;
3014                 }
3015                 else if(timeleft <= 10)
3016                 {
3017                         if(timeleft != self.idlekick_lasttimeleft)
3018                         {
3019                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3020                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3021                         }
3022                 }
3023                 else
3024                 {
3025                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3026                 }
3027                 self.idlekick_lasttimeleft = timeleft;
3028         }
3029
3030 #ifdef TETRIS
3031         if(self.impulse == 100)
3032                 ImpulseCommands();
3033         if (TetrisPostFrame())
3034                 return;
3035 #endif
3036
3037         CheatFrame();
3038
3039         if(self.classname == "player") {
3040                 CheckRules_Player();
3041                 UpdateChatBubble();
3042                 if (self.impulse)
3043                         ImpulseCommands();
3044                 if (intermission_running)
3045                         return;         // intermission or finale
3046                 GetPressedKeys();
3047         } else if (self.classname == "observer") {
3048                 //do nothing
3049         } else if (self.classname == "spectator") {
3050                 //do nothing
3051         }
3052
3053         /*
3054         float i;
3055         for(i = 0; i < 1000; ++i)
3056         {
3057                 vector end;
3058                 end = self.origin + '0 0 1024' + 512 * randomvec();
3059                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3060                 if(trace_fraction < 1)
3061                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3062                 {
3063                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3064                         break;
3065                 }
3066         }
3067         */
3068
3069         Arena_Warmup();
3070
3071         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3072
3073         if(self.waypointsprite_attachedforcarrier)
3074                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3075
3076         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3077         {
3078                 if(!self.showheadshotbbox)
3079                 {
3080                         self.showheadshotbbox = spawn();
3081                         self.showheadshotbbox.classname = "headshotbbox";
3082                         self.showheadshotbbox.owner = self;
3083                         self.showheadshotbbox.think = showheadshotbbox_think;
3084                         self.showheadshotbbox.nextthink = time;
3085                         self = self.showheadshotbbox;
3086                         self.think();
3087                         self = self.owner;
3088                 }
3089         }
3090         else
3091         {
3092                 if(self.showheadshotbbox)
3093                         remove(self.showheadshotbbox);
3094         }
3095
3096         playerdemo_write();
3097
3098         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3099         {
3100                 if(!self.stored_netname)
3101                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3102                 if(self.stored_netname != self.netname)
3103                 {
3104                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3105                         strunzone(self.stored_netname);
3106                         self.stored_netname = strzone(self.netname);
3107                 }
3108         }
3109
3110         /*
3111         if(g_race)
3112                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3113         */
3114 }