qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         if (g_minstagib)
 408                 minstagib_stop_countdown();
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         if(self.ballcarried && g_nexball)
 425                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 426
 427         WaypointSprite_PlayerDead();
 428
 429         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 430                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 431
 432         if(self.killcount != -666) {
 433                 if(g_lms) {
 434                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 435                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 436                         else
 437                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 438                 } else
 439                         bprint ("^4", self.netname, "^4 is spectating now\n");
 440
 441                 if(self.just_joined == FALSE) {
 442                         LogTeamchange(self.playerid, -1, 4);
 443                 } else
 444                         self.just_joined = FALSE;
 445         }
 446
 447         PlayerScore_Clear(self); // clear scores when needed
 448
 449         accuracy_resend(self);
 450
 451         self.spectatortime = time;
 452
 453         self.classname = "observer";
 454         self.iscreature = FALSE;
 455         self.damagedbycontents = FALSE;
 456         self.health = -666;
 457         self.takedamage = DAMAGE_NO;
 458         self.solid = SOLID_NOT;
 459         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 460         self.flags = FL_CLIENT | FL_NOTARGET;
 461         self.armorvalue = 666;
 462         self.effects = 0;
 463         self.armorvalue = autocvar_g_balance_armor_start;
 464         self.pauserotarmor_finished = 0;
 465         self.pauserothealth_finished = 0;
 466         self.pauseregen_finished = 0;
 467         self.damageforcescale = 0;
 468         self.death_time = 0;
 469         self.alpha = 0;
 470         self.scale = 0;
 471         self.fade_time = 0;
 472         self.pain_frame = 0;
 473         self.pain_finished = 0;
 474         self.strength_finished = 0;
 475         self.invincible_finished = 0;
 476         self.pushltime = 0;
 477         self.think = SUB_Null;
 478         self.nextthink = 0;
 479         self.hook_time = 0;
 480         self.runes = 0;
 481         self.deadflag = DEAD_NO;
 482         self.angles = spot.angles;
 483         self.angles_z = 0;
 484         self.fixangle = TRUE;
 485         self.crouch = FALSE;
 486
 487         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 488         self.prevorigin = self.origin;
 489         self.items = 0;
 490         self.weapons = 0;
 491         self.model = "";
 492         FixPlayermodel();
 493         setmodel(self, "null");
 494         self.drawonlytoclient = self;
 495
 496         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 497         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 498
 499         self.weapon = 0;
 500         self.weaponname = "";
 501         self.switchingweapon = 0;
 502         self.weaponmodel = "";
 503         self.weaponentity = world;
 504         self.exteriorweaponentity = world;
 505         self.killcount = -666;
 506         self.velocity = '0 0 0';
 507         self.avelocity = '0 0 0';
 508         self.punchangle = '0 0 0';
 509         self.punchvector = '0 0 0';
 510         self.oldvelocity = self.velocity;
 511         self.fire_endtime = -1;
 512
 513         if(g_arena)
 514         {
 515                 if(self.version_mismatch)
 516                 {
 517                         Spawnqueue_Unmark(self);
 518                         Spawnqueue_Remove(self);
 519                 }
 520                 else
 521                 {
 522                         Spawnqueue_Insert(self);
 523                 }
 524         }
 525         else if(g_lms)
 526         {
 527                 // Only if the player cannot play at all
 528                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 529                         self.frags = FRAGS_SPECTATOR;
 530                 else
 531                         self.frags = FRAGS_LMS_LOSER;
 532         }
 533         else if(g_ca)
 534         {
 535                 if(self.caplayer)
 536                         self.frags = FRAGS_LMS_LOSER;
 537                 else
 538                         self.frags = FRAGS_SPECTATOR;
 539         }
 540         else
 541                 self.frags = FRAGS_SPECTATOR;
 542 }
 543
 544 .float model_randomizer;
 545 void FixPlayermodel()
 546 {
 547         string defaultmodel;
 548         float defaultskin, chmdl, oldskin, n, i;
 549         vector m1, m2;
 550
 551         defaultmodel = "";
 552
 553         if(autocvar_sv_defaultcharacter == 1)
 554         {
 555                 defaultskin = 0;
 556
 557                 if(teamplay)
 558                 {
 559                         string s;
 560                         s = Team_ColorNameLowerCase(self.team);
 561                         if(s != "neutral")
 562                         {
 563                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 564                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 565                         }
 566                 }
 567
 568                 if(defaultmodel == "")
 569                 {
 570                         defaultmodel = autocvar_sv_defaultplayermodel;
 571                         defaultskin = autocvar_sv_defaultplayerskin;
 572                 }
 573
 574                 n = tokenize_console(defaultmodel);
 575                 if(n > 0)
 576                         defaultmodel = argv(floor(n * self.model_randomizer));
 577
 578                 i = strstrofs(defaultmodel, ":", 0);
 579                 if(i >= 0)
 580                 {
 581                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 582                         defaultmodel = substring(defaultmodel, 0, i);
 583                 }
 584         }
 585
 586         if(defaultmodel != "")
 587         {
 588                 if (defaultmodel != self.model)
 589                 {
 590                         m1 = self.mins;
 591                         m2 = self.maxs;
 592                         setplayermodel (self, defaultmodel);
 593                         setsize (self, m1, m2);
 594                         chmdl = TRUE;
 595                 }
 596
 597                 oldskin = self.skin;
 598                 self.skin = defaultskin;
 599         } else {
 600                 if (self.playermodel != self.model || self.playermodel == "")
 601                 {
 602                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 603                         m1 = self.mins;
 604                         m2 = self.maxs;
 605                         setplayermodel (self, self.playermodel);
 606                         setsize (self, m1, m2);
 607                         chmdl = TRUE;
 608                 }
 609
 610                 oldskin = self.skin;
 611                 self.skin = stof(self.playerskin);
 612         }
 613
 614         if(chmdl || oldskin != self.skin)
 615                 self.species = player_getspecies(); // model or skin has changed
 616
 617         if(!teamplay)
 618                 if(strlen(autocvar_sv_defaultplayercolors))
 619                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 620                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 621 }
 622
 623 void PlayerTouchExplode(entity p1, entity p2)
 624 {
 625         vector org;
 626         org = (p1.origin + p2.origin) * 0.5;
 627         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 628
 629         te_explosion(org);
 630
 631         entity e;
 632         e = spawn();
 633         setorigin(e, org);
 634         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 635         remove(e);
 636 }
 637
 638 /*
 639 =============
 640 PutClientInServer
 641
 642 Called when a client spawns in the server
 643 =============
 644 */
 645 //void() ctf_playerchanged;
 646 void PutClientInServer (void)
 647 {
 648         if(clienttype(self) == CLIENTTYPE_BOT)
 649         {
 650                 self.classname = "player";
 651         }
 652         else if(clienttype(self) == CLIENTTYPE_REAL)
 653         {
 654                 msg_entity = self;
 655                 WriteByte(MSG_ONE, SVC_SETVIEW);
 656                 WriteEntity(MSG_ONE, self);
 657         }
 658
 659         // reset player keys
 660         self.itemkeys = 0;
 661
 662         // player is dead and becomes observer
 663         // FIXME fix LMS scoring for new system
 664         if(g_lms)
 665         {
 666                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 667                         self.classname = "observer";
 668         }
 669
 670         if(g_arena || (g_ca && !allowed_to_spawn))
 671         if(!self.spawned)
 672                 self.classname = "observer";
 673
 674         if(gameover)
 675                 self.classname = "observer";
 676
 677         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 678                 entity spot, oldself;
 679                 float j;
 680
 681                 accuracy_resend(self);
 682
 683                 if(self.team < 0)
 684                         JoinBestTeam(self, FALSE, TRUE);
 685
 686                 race_PreSpawn();
 687
 688                 spot = SelectSpawnPoint (FALSE);
 689                 if(!spot)
 690                 {
 691                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 692                         return; // spawn failed
 693                 }
 694
 695                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 696
 697                 self.classname = "player";
 698                 self.wasplayer = TRUE;
 699                 self.iscreature = TRUE;
 700                 self.damagedbycontents = TRUE;
 701                 self.movetype = MOVETYPE_WALK;
 702                 self.solid = SOLID_SLIDEBOX;
 703                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 704                 if(autocvar_g_playerclip_collisions)
 705                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 706                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 707                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 708                 self.frags = FRAGS_PLAYER;
 709                 if(INDEPENDENT_PLAYERS)
 710                         MAKE_INDEPENDENT_PLAYER(self);
 711                 self.flags = FL_CLIENT;
 712                 if(autocvar__notarget)
 713                         self.flags |= FL_NOTARGET;
 714                 self.takedamage = DAMAGE_AIM;
 715                 if(g_minstagib)
 716                         self.effects = EF_FULLBRIGHT;
 717                 else
 718                         self.effects = 0;
 719                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 720                 self.air_finished = time + 12;
 721                 self.dmg = 2;
 722                 if(autocvar_g_balance_nex_charge)
 723                 {
 724                         if(autocvar_g_balance_nex_secondary_chargepool)
 725                                 self.nex_chargepool_ammo = 1;
 726                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 727                 }
 728
 729                 if(inWarmupStage)
 730                 {
 731                         self.ammo_shells = warmup_start_ammo_shells;
 732                         self.ammo_nails = warmup_start_ammo_nails;
 733                         self.ammo_rockets = warmup_start_ammo_rockets;
 734                         self.ammo_cells = warmup_start_ammo_cells;
 735                         self.ammo_fuel = warmup_start_ammo_fuel;
 736                         self.health = warmup_start_health;
 737                         self.armorvalue = warmup_start_armorvalue;
 738                         self.weapons = warmup_start_weapons;
 739                 }
 740                 else
 741                 {
 742                         self.ammo_shells = start_ammo_shells;
 743                         self.ammo_nails = start_ammo_nails;
 744                         self.ammo_rockets = start_ammo_rockets;
 745                         self.ammo_cells = start_ammo_cells;
 746                         self.ammo_fuel = start_ammo_fuel;
 747                         self.health = start_health;
 748                         self.armorvalue = start_armorvalue;
 749                         self.weapons = start_weapons;
 750                 }
 751
 752                 if(g_weaponarena_random)
 753                 {
 754                         if(g_weaponarena_random_with_laser)
 755                                 self.weapons &~= WEPBIT_LASER;
 756                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 757                         if(g_weaponarena_random_with_laser)
 758                                 self.weapons |= WEPBIT_LASER;
 759                 }
 760
 761                 self.items = start_items;
 762
 763                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 764                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 765                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 766                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 767                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 768                 //extend the pause of rotting if client was reset at the beginning of the countdown
 769                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 770                         self.spawnshieldtime += game_starttime - time;
 771                         self.pauserotarmor_finished += game_starttime - time;
 772                         self.pauserothealth_finished += game_starttime - time;
 773                         self.pauseregen_finished += game_starttime - time;
 774                 }
 775                 self.damageforcescale = 2;
 776                 self.death_time = 0;
 777                 self.scale = 0;
 778                 self.fade_time = 0;
 779                 self.pain_frame = 0;
 780                 self.pain_finished = 0;
 781                 self.strength_finished = 0;
 782                 self.invincible_finished = 0;
 783                 self.pushltime = 0;
 784                 // players have no think function
 785                 self.think = SUB_Null;
 786                 self.nextthink = 0;
 787                 self.hook_time = 0;
 788                 self.dmg_team = 0;
 789                 self.ballistics_density = autocvar_g_ballistics_density_player;
 790
 791                 self.metertime = 0;
 792
 793                 self.runes = 0;
 794
 795                 self.deadflag = DEAD_NO;
 796
 797                 self.angles = spot.angles;
 798
 799                 self.angles_z = 0; // never spawn tilted even if the spot says to
 800                 self.fixangle = TRUE; // turn this way immediately
 801                 self.velocity = '0 0 0';
 802                 self.avelocity = '0 0 0';
 803                 self.punchangle = '0 0 0';
 804                 self.punchvector = '0 0 0';
 805                 self.oldvelocity = self.velocity;
 806                 self.fire_endtime = -1;
 807
 808                 msg_entity = self;
 809                 WRITESPECTATABLE_MSG_ONE({
 810                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 811                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 812                 });
 813
 814                 self.model = "";
 815                 FixPlayermodel();
 816                 self.drawonlytoclient = world;
 817
 818                 self.crouch = FALSE;
 819                 self.view_ofs = PL_VIEW_OFS;
 820                 setsize (self, PL_MIN, PL_MAX);
 821                 self.spawnorigin = spot.origin;
 822                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 823                 // don't reset back to last position, even if new position is stuck in solid
 824                 self.oldorigin = self.origin;
 825                 self.prevorigin = self.origin;
 826                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 827                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 828         self.hud = HUD_NORMAL;
 829
 830                 if(g_arena)
 831                 {
 832                         Spawnqueue_Remove(self);
 833                         Spawnqueue_Mark(self);
 834                 }
 835
 836                 else if(g_ca)
 837                         self.caplayer = 1;
 838
 839                 self.event_damage = PlayerDamage;
 840
 841                 self.bot_attack = TRUE;
 842
 843                 self.statdraintime = time + 5;
 844                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 845
 846                 if(self.killcount == -666) {
 847                         PlayerScore_Clear(self);
 848                         self.killcount = 0;
 849                 }
 850
 851                 CL_SpawnWeaponentity();
 852                 self.alpha = default_player_alpha;
 853                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 854                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 855
 856                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 857                 self.lms_traveled_distance = 0;
 858                 self.speedrunning = FALSE;
 859
 860                 race_PostSpawn(spot);
 861
 862                 //stuffcmd(self, "chase_active 0");
 863                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 864
 865                 if (autocvar_g_spawnsound)
 866                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 867
 868                 if(g_assault) {
 869                         if(self.team == assault_attacker_team)
 870                                 centerprint(self, "You are attacking!");
 871                         else
 872                                 centerprint(self, "You are defending!");
 873                 }
 874
 875                 target_voicescript_clear(self);
 876
 877                 // reset fields the weapons may use
 878                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 879                 {
 880                         weapon_action(j, WR_RESETPLAYER);
 881
 882                         // all weapons must be fully loaded when we spawn
 883                         entity e;
 884                         e = get_weaponinfo(j);
 885                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 886                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 887                 }
 888
 889                 oldself = self;
 890                 self = spot;
 891                         activator = oldself;
 892                                 string s;
 893                                 s = self.target;
 894                                 self.target = string_null;
 895                                 SUB_UseTargets();
 896                                 self.target = s;
 897                         activator = world;
 898                 self = oldself;
 899
 900                 spawn_spot = spot;
 901                 MUTATOR_CALLHOOK(PlayerSpawn);
 902
 903                 if(autocvar_spawn_debug)
 904                 {
 905                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 906                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 907                 }
 908
 909                 self.switchweapon = w_getbestweapon(self);
 910                 self.cnt = -1; // W_LastWeapon will not complain
 911                 self.weapon = 0;
 912                 self.weaponname = "";
 913                 self.switchingweapon = 0;
 914
 915                 if(!self.alivetime)
 916                         self.alivetime = time;
 917
 918                 antilag_clear(self);
 919         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
 920                 PutObserverInServer ();
 921         }
 922
 923         //if(g_ctf)
 924         //      ctf_playerchanged();
 925 }
 926
 927 .float ebouncefactor, ebouncestop; // electro's values
 928 // TODO do we need all these fields, or should we stop autodetecting runtime
 929 // changes and just have a console command to update this?
 930 float ClientInit_SendEntity(entity to, float sf)
 931 {
 932         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 933         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 934         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 935         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 946         if(sv_foginterval && world.fog != "")
 947                 WriteString(MSG_ENTITY, world.fog);
 948         else
 949                 WriteString(MSG_ENTITY, "");
 950         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 951         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 952         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 953         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 954         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 955         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 956         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 957         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 958         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 959         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 960         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 961         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 962         return TRUE;
 963 }
 964
 965 void ClientInit_CheckUpdate()
 966 {
 967         self.nextthink = time;
 968         if(self.count != autocvar_g_balance_armor_blockpercent)
 969         {
 970                 self.count = autocvar_g_balance_armor_blockpercent;
 971                 self.SendFlags |= 1;
 972         }
 973         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 974         {
 975                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 976                 self.SendFlags |= 1;
 977         }
 978         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 979         {
 980                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 981                 self.SendFlags |= 1;
 982         }
 983         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 984         {
 985                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 986                 self.SendFlags |= 1;
 987         }
 988         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 989         {
 990                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 991                 self.SendFlags |= 1;
 992         }
 993         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 994         {
 995                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 996                 self.SendFlags |= 1;
 997         }
 998 }
 999
1000 void ClientInit_Spawn()
1001 {
1002         entity o;
1003         entity e;
1004         e = spawn();
1005         e.classname = "clientinit";
1006         e.think = ClientInit_CheckUpdate;
1007         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1008
1009         o = self;
1010         self = e;
1011         ClientInit_CheckUpdate();
1012         self = o;
1013 }
1014
1015 /*
1016 =============
1017 SetNewParms
1018 =============
1019 */
1020 void SetNewParms (void)
1021 {
1022         // initialize parms for a new player
1023         parm1 = -(86400 * 366);
1024 }
1025
1026 /*
1027 =============
1028 SetChangeParms
1029 =============
1030 */
1031 void SetChangeParms (void)
1032 {
1033         // save parms for level change
1034         parm1 = self.parm_idlesince - time;
1035 }
1036
1037 /*
1038 =============
1039 DecodeLevelParms
1040 =============
1041 */
1042 void DecodeLevelParms (void)
1043 {
1044         // load parms
1045         self.parm_idlesince = parm1;
1046         if(self.parm_idlesince == -(86400 * 366))
1047                 self.parm_idlesince = time;
1048
1049         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1050         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1051 }
1052
1053 /*
1054 =============
1055 ClientKill
1056
1057 Called when a client types 'kill' in the console
1058 =============
1059 */
1060
1061 .float clientkill_nexttime;
1062 void ClientKill_Now_TeamChange()
1063 {
1064         if(self.killindicator_teamchange == -1)
1065         {
1066                 self.team = -1;
1067                 JoinBestTeam( self, FALSE, FALSE );
1068         }
1069         else if(self.killindicator_teamchange == -2)
1070         {
1071                 if(g_ca)
1072                         self.caplayer = 0;
1073                 if(blockSpectators)
1074                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1075                 PutObserverInServer();
1076         }
1077         else
1078                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1079 }
1080
1081 void ClientKill_Now()
1082 {
1083         if(self.vehicle)
1084         {
1085             vehicles_exit(VHEF_RELESE);
1086             if(!self.killindicator_teamchange)
1087             {
1088             self.vehicle_health = -1;
1089             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1090             }
1091         }
1092
1093         if(self.killindicator && !wasfreed(self.killindicator))
1094                 remove(self.killindicator);
1095
1096         self.killindicator = world;
1097
1098         if(self.killindicator_teamchange)
1099                 ClientKill_Now_TeamChange();
1100
1101         // in any case:
1102         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1103
1104         // now I am sure the player IS dead
1105 }
1106 void KillIndicator_Think()
1107 {
1108         if (gameover)
1109         {
1110                 self.owner.killindicator = world;
1111                 remove(self);
1112                 return;
1113         }
1114
1115         if (self.owner.alpha < 0)
1116         {
1117                 self.owner.killindicator = world;
1118                 remove(self);
1119                 return;
1120         }
1121
1122         if(self.cnt <= 0)
1123         {
1124                 self = self.owner;
1125                 ClientKill_Now(); // no oldself needed
1126                 return;
1127         }
1128     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1129     {
1130         self.nextthink = time + 1;
1131         self.cnt -= 1;
1132     }
1133         else
1134         {
1135                 if(self.cnt <= 10)
1136                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1137                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1138                 {
1139                         if(self.cnt <= 10)
1140                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1141                 }
1142                 self.nextthink = time + 1;
1143                 self.cnt -= 1;
1144         }
1145 }
1146
1147 float clientkilltime;
1148 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1149 {
1150         float killtime;
1151         float starttime;
1152         entity e;
1153
1154         if (gameover)
1155                 return;
1156
1157         killtime = autocvar_g_balance_kill_delay;
1158
1159         if(g_race_qualifying || g_cts)
1160                 killtime = 0;
1161
1162     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1163     {
1164                 remove(self.killindicator);
1165                 self.killindicator = world;
1166
1167         ClientKill_Now(); // allow instant kill in this case
1168         return;
1169     }
1170
1171         self.killindicator_teamchange = targetteam;
1172
1173     if(!self.killindicator)
1174         {
1175                 if(self.deadflag == DEAD_NO)
1176                 {
1177                         killtime = max(killtime, self.clientkill_nexttime - time);
1178                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1179                 }
1180
1181                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1182                 {
1183                         ClientKill_Now();
1184                 }
1185                 else
1186                 {
1187                         starttime = max(time, clientkilltime);
1188
1189                         self.killindicator = spawn();
1190                         self.killindicator.owner = self;
1191                         self.killindicator.scale = 0.5;
1192                         setattachment(self.killindicator, self, "");
1193                         setorigin(self.killindicator, '0 0 52');
1194                         self.killindicator.think = KillIndicator_Think;
1195                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1196                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1197                         self.killindicator.cnt = ceil(killtime);
1198                         self.killindicator.count = bound(0, ceil(killtime), 10);
1199                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1200
1201                         for(e = world; (e = find(e, classname, "body")) != world; )
1202                         {
1203                                 if(e.enemy != self)
1204                                         continue;
1205                                 e.killindicator = spawn();
1206                                 e.killindicator.owner = e;
1207                                 e.killindicator.scale = 0.5;
1208                                 setattachment(e.killindicator, e, "");
1209                                 setorigin(e.killindicator, '0 0 52');
1210                                 e.killindicator.think = KillIndicator_Think;
1211                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1212                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1213                                 e.killindicator.cnt = ceil(killtime);
1214                         }
1215                         self.lip = 0;
1216                 }
1217         }
1218         if(self.killindicator)
1219         {
1220                 if(targetteam == 0) // just die
1221                 {
1222                         self.killindicator.colormod = '0 0 0';
1223                         if(clienttype(self) == CLIENTTYPE_REAL)
1224                         if(self.killindicator.cnt > 0)
1225                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1226                 }
1227                 else if(targetteam == -1) // auto
1228                 {
1229                         self.killindicator.colormod = '0 1 0';
1230                         if(clienttype(self) == CLIENTTYPE_REAL)
1231                         if(self.killindicator.cnt > 0)
1232                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1233                 }
1234                 else if(targetteam == -2) // spectate
1235                 {
1236                         self.killindicator.colormod = '0.5 0.5 0.5';
1237                         if(clienttype(self) == CLIENTTYPE_REAL)
1238                         if(self.killindicator.cnt > 0)
1239                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1240                 }
1241                 else
1242                 {
1243                         self.killindicator.colormod = TeamColor(targetteam);
1244                         if(clienttype(self) == CLIENTTYPE_REAL)
1245                         if(self.killindicator.cnt > 0)
1246                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1247                 }
1248         }
1249
1250 }
1251
1252 void ClientKill (void)
1253 {
1254         if (gameover)
1255                 return;
1256
1257         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1258         {
1259                 // do nothing
1260         }
1261     else if(self.freezetag_frozen)
1262     {
1263         // do nothing
1264     }
1265         else
1266                 ClientKill_TeamChange(0);
1267 }
1268
1269 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1270 {
1271     e.killindicator = spawn();
1272     e.killindicator.owner = e;
1273     e.killindicator.think = KillIndicator_Think;
1274     e.killindicator.nextthink = time + (e.lip) * 0.05;
1275     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1276     e.killindicator.health = 1; // this is used to indicate that it should be silent
1277     e.lip = 0;
1278 }
1279
1280 void FixClientCvars(entity e)
1281 {
1282         // send prediction settings to the client
1283         stuffcmd(e, "\nin_bindmap 0 0\n");
1284         if(g_race || g_cts)
1285                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1286         if(autocvar_g_antilag == 3) // client side hitscan
1287                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1288         if(sv_gentle)
1289                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1290         /*
1291          * we no longer need to stuff this. Remove this comment block if you feel
1292          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1293         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1294         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1295         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1296         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1297         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1298         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1299         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1300         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1301         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1302         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1303         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1304         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1305         stuffcmd(e, "cl_movement_edgefriction 1\n");
1306          */
1307 }
1308
1309 float PlayerInIDList(entity p, string idlist)
1310 {
1311         float n, i;
1312         string s;
1313
1314         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1315         if not(p.crypto_idfp)
1316                 return 0;
1317
1318         // this function allows abbreviated player IDs too!
1319         n = tokenize_console(idlist);
1320         for(i = 0; i < n; ++i)
1321         {
1322                 s = argv(i);
1323                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1324                         return 1;
1325         }
1326
1327         return 0;
1328 }
1329
1330 /*
1331 =============
1332 ClientConnect
1333
1334 Called when a client connects to the server
1335 =============
1336 */
1337 //void ctf_clientconnect();
1338 string ColoredTeamName(float t);
1339 void DecodeLevelParms (void);
1340 //void dom_player_join_team(entity pl);
1341 void set_dom_state(entity e);
1342 void ClientConnect (void)
1343 {
1344         float t;
1345
1346         if(self.flags & FL_CLIENT)
1347         {
1348                 print("Warning: ClientConnect, but already connected!\n");
1349                 return;
1350         }
1351
1352         if(Ban_MaybeEnforceBan(self))
1353                 return;
1354
1355         DecodeLevelParms();
1356
1357 #ifdef WATERMARK
1358         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1359 #endif
1360
1361         self.classname = "player_joining";
1362
1363         self.flags = FL_CLIENT;
1364         self.version_nagtime = time + 10 + random() * 10;
1365
1366         if(player_count<0)
1367         {
1368                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1369                 player_count = 0;
1370         }
1371
1372         PlayerScore_Attach(self);
1373         ClientData_Attach();
1374         accuracy_init(self);
1375
1376         bot_clientconnect();
1377
1378         playerdemo_init();
1379
1380         anticheat_init();
1381
1382         race_PreSpawnObserver();
1383
1384         //if(g_domination)
1385         //      dom_player_join_team(self);
1386
1387         // identify the right forced team
1388         if(autocvar_g_campaign)
1389         {
1390                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1391                 {
1392                         switch(autocvar_g_campaign_forceteam)
1393                         {
1394                                 case 1: self.team_forced = COLOR_TEAM1; break;
1395                                 case 2: self.team_forced = COLOR_TEAM2; break;
1396                                 case 3: self.team_forced = COLOR_TEAM3; break;
1397                                 case 4: self.team_forced = COLOR_TEAM4; break;
1398                                 default: self.team_forced = 0;
1399                         }
1400                 }
1401         }
1402         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1403                 self.team_forced = COLOR_TEAM1;
1404         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1405                 self.team_forced = COLOR_TEAM2;
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1407                 self.team_forced = COLOR_TEAM3;
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1409                 self.team_forced = COLOR_TEAM4;
1410         else if(autocvar_g_forced_team_otherwise == "red")
1411                 self.team_forced = COLOR_TEAM1;
1412         else if(autocvar_g_forced_team_otherwise == "blue")
1413                 self.team_forced = COLOR_TEAM2;
1414         else if(autocvar_g_forced_team_otherwise == "yellow")
1415                 self.team_forced = COLOR_TEAM3;
1416         else if(autocvar_g_forced_team_otherwise == "pink")
1417                 self.team_forced = COLOR_TEAM4;
1418         else if(autocvar_g_forced_team_otherwise == "spectate")
1419                 self.team_forced = -1;
1420         else if(autocvar_g_forced_team_otherwise == "spectator")
1421                 self.team_forced = -1;
1422         else
1423                 self.team_forced = 0;
1424
1425         if(!teamplay)
1426                 if(self.team_forced > 0)
1427                         self.team_forced = 0;
1428
1429         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1430
1431         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1432                 self.classname = "observer";
1433         } else {
1434                 if(teamplay)
1435                 {
1436                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1437                         {
1438                                 self.classname = "player";
1439                                 campaign_bots_may_start = 1;
1440                         }
1441                         else
1442                         {
1443                                 self.classname = "observer"; // do it anyway
1444                         }
1445                 }
1446                 else
1447                 {
1448                         self.classname = "player";
1449                         campaign_bots_may_start = 1;
1450                 }
1451         }
1452
1453         self.playerid = (playerid_last = playerid_last + 1);
1454
1455         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1456
1457     if(clienttype(self) == CLIENTTYPE_BOT)
1458         PlayerStats_AddPlayer(self);
1459
1460         if(autocvar_sv_eventlog)
1461                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1462
1463         LogTeamchange(self.playerid, self.team, 1);
1464
1465         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1466
1467         self.netname_previous = strzone(self.netname);
1468
1469         bprint("^4", self.netname, "^4 connected");
1470
1471         if(self.classname != "observer" && (g_domination || g_ctf))
1472                 bprint(" and joined the ", ColoredTeamName(self.team));
1473
1474         bprint("\n");
1475
1476         stuffcmd(self, strcat(clientstuff, "\n"));
1477         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1478
1479         FixClientCvars(self);
1480
1481         // spawnfunc_waypoint sprites
1482         WaypointSprite_InitClient(self);
1483
1484         // Wazat's grappling hook
1485         SetGrappleHookBindings();
1486
1487         // get version info from player
1488         stuffcmd(self, "cmd clientversion $gameversion\n");
1489
1490         // get other cvars from player
1491         GetCvars(0);
1492
1493         // notify about available teams
1494         if(teamplay)
1495         {
1496                 CheckAllowedTeams(self);
1497                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1498                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1499         }
1500         else
1501                 stuffcmd(self, "set _teams_available 0\n");
1502
1503         if(g_arena || g_ca)
1504         {
1505                 self.classname = "observer";
1506                 if(g_arena)
1507                         Spawnqueue_Insert(self);
1508         }
1509         /*else if(g_ctf)
1510         {
1511                 ctf_clientconnect();
1512         }*/
1513
1514         attach_entcs();
1515
1516         bot_relinkplayerlist();
1517
1518         self.spectatortime = time;
1519         if(blockSpectators)
1520         {
1521                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1522         }
1523
1524         self.jointime = time;
1525         self.allowed_timeouts = autocvar_sv_timeout_number;
1526
1527         if(clienttype(self) == CLIENTTYPE_REAL)
1528         {
1529                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1530                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1531         }
1532
1533         if(g_lms)
1534         {
1535                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1536                 {
1537                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1538                         self.frags = FRAGS_SPECTATOR;
1539                 }
1540         }
1541
1542         if(!sv_foginterval && world.fog != "")
1543                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1544
1545         SoundEntity_Attach(self);
1546
1547         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1548         {
1549                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1550                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1551         }
1552         else
1553                 self.hitplotfh = -1;
1554
1555         if(g_race || g_cts) {
1556                 string rr;
1557                 if(g_cts)
1558                         rr = CTS_RECORD;
1559                 else
1560                         rr = RACE_RECORD;
1561                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1562
1563                 msg_entity = self;
1564                 race_send_recordtime(MSG_ONE);
1565                 race_send_speedaward(MSG_ONE);
1566
1567                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1568                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1569                 race_send_speedaward_alltimebest(MSG_ONE);
1570
1571                 float i;
1572                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1573                         race_SendRankings(i, 0, 0, MSG_ONE);
1574                 }
1575         }
1576         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1577                 send_CSQC_teamnagger();
1578
1579         if (g_domination)
1580                 set_dom_state(self);
1581
1582         CheatInitClient();
1583
1584         if(!autocvar_g_campaign)
1585                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1586
1587         CSQCMODEL_AUTOINIT();
1588
1589         self.model_randomizer = random();
1590 }
1591
1592 /*
1593 =============
1594 ClientDisconnect
1595
1596 Called when a client disconnects from the server
1597 =============
1598 */
1599 .entity chatbubbleentity;
1600 void ReadyCount();
1601 void ClientDisconnect (void)
1602 {
1603         if(self.vehicle)
1604             vehicles_exit(VHEF_RELESE);
1605
1606         if not(self.flags & FL_CLIENT)
1607         {
1608                 print("Warning: ClientDisconnect without ClientConnect\n");
1609                 return;
1610         }
1611
1612         PlayerStats_AddGlobalInfo(self);
1613
1614         CheatShutdownClient();
1615
1616         if(self.hitplotfh >= 0)
1617         {
1618                 fclose(self.hitplotfh);
1619                 self.hitplotfh = -1;
1620         }
1621
1622         anticheat_report();
1623         anticheat_shutdown();
1624
1625         playerdemo_shutdown();
1626
1627         bot_clientdisconnect();
1628
1629         if(self.entcs)
1630                 detach_entcs();
1631
1632         if(autocvar_sv_eventlog)
1633                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1634         bprint ("^4",self.netname);
1635         bprint ("^4 disconnected\n");
1636
1637         SoundEntity_Detach(self);
1638
1639         DropAllRunes(self);
1640         MUTATOR_CALLHOOK(ClientDisconnect);
1641
1642         Portal_ClearAll(self);
1643
1644         RemoveGrapplingHook(self);
1645         if(self.flagcarried)
1646                 DropFlag(self.flagcarried, world, world);
1647         if(self.ballcarried && g_nexball)
1648                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1649
1650         // Here, everything has been done that requires this player to be a client.
1651
1652         self.flags &~= FL_CLIENT;
1653
1654         if (self.chatbubbleentity)
1655                 remove (self.chatbubbleentity);
1656
1657         if (self.killindicator)
1658                 remove (self.killindicator);
1659
1660         WaypointSprite_PlayerGone();
1661
1662         bot_relinkplayerlist();
1663
1664         if(g_arena)
1665         {
1666                 Spawnqueue_Unmark(self);
1667                 Spawnqueue_Remove(self);
1668         }
1669
1670         accuracy_free(self);
1671         ClientData_Detach();
1672         PlayerScore_Detach(self);
1673
1674         if(self.netname_previous)
1675                 strunzone(self.netname_previous);
1676         if(self.clientstatus)
1677                 strunzone(self.clientstatus);
1678         if(self.weaponorder_byimpulse)
1679                 strunzone(self.weaponorder_byimpulse);
1680
1681         ClearPlayerSounds();
1682
1683         if(self.personal)
1684                 remove(self.personal);
1685
1686         self.playerid = 0;
1687         ReadyCount();
1688
1689         // free cvars
1690         GetCvars(-1);
1691 }
1692
1693 .float BUTTON_CHAT;
1694 void ChatBubbleThink()
1695 {
1696         self.nextthink = time;
1697         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1698         {
1699                 if(self.owner) // but why can that ever be world?
1700                         self.owner.chatbubbleentity = world;
1701                 remove(self);
1702                 return;
1703         }
1704         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1705 #ifdef TETRIS
1706                 || self.owner.tetris_on
1707 #endif
1708         )
1709                 self.model = self.mdl;
1710         else
1711                 self.model = "";
1712 }
1713
1714 void UpdateChatBubble()
1715 {
1716         if (self.alpha < 0)
1717                 return;
1718         // spawn a chatbubble entity if needed
1719         if (!self.chatbubbleentity)
1720         {
1721                 self.chatbubbleentity = spawn();
1722                 self.chatbubbleentity.owner = self;
1723                 self.chatbubbleentity.exteriormodeltoclient = self;
1724                 self.chatbubbleentity.think = ChatBubbleThink;
1725                 self.chatbubbleentity.nextthink = time;
1726                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1727                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1728                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1729                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1730                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1731                 self.chatbubbleentity.model = "";
1732                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1733         }
1734 }
1735
1736
1737 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1738 // added to the model skins
1739 /*void UpdateColorModHack()
1740 {
1741         float c;
1742         c = self.clientcolors & 15;
1743         // LordHavoc: only bothering to support white, green, red, yellow, blue
1744              if (!teamplay) self.colormod = '0 0 0';
1745         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1746         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1747         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1748         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1749         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1750         else self.colormod = '1 1 1';
1751 }*/
1752
1753 void respawn(void)
1754 {
1755         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1756         {
1757                 self.solid = SOLID_NOT;
1758                 self.takedamage = DAMAGE_NO;
1759                 self.movetype = MOVETYPE_FLY;
1760                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1761                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1762                 self.effects |= EF_ADDITIVE;
1763                 self.oldcolormap = self.colormap; // saved for copybody to use later
1764                 self.colormap = 0; // this originally was 512, but raises a warning in the engine, so get rid of it
1765                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1766                 if(autocvar_g_respawn_ghosts_maxtime)
1767                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1768         }
1769
1770         CopyBody(1);
1771         self.effects |= EF_NODRAW; // prevent another CopyBody
1772
1773         if(self.oldcolormap) // reset it so that when they respawn it'll be back to normal
1774         {
1775                 self.colormap = self.oldcolormap;
1776                 self.oldcolormap = 0;
1777         }
1778
1779         PutClientInServer();
1780 }
1781
1782 void play_countdown(float finished, string samp)
1783 {
1784         if(clienttype(self) == CLIENTTYPE_REAL)
1785                 if(floor(finished - time - frametime) != floor(finished - time))
1786                         if(finished - time < 6)
1787                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1788 }
1789
1790 void player_powerups (void)
1791 {
1792         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1793         olditems = self.items;
1794
1795         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1796         {
1797                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1798                 self.modelflags |= MF_ROCKET;
1799         }
1800         else
1801         {
1802                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1803                 self.modelflags &~= MF_ROCKET;
1804         }
1805
1806         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1807
1808         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1809                 return;
1810
1811         Fire_ApplyDamage(self);
1812         Fire_ApplyEffect(self);
1813
1814         if (g_minstagib)
1815         {
1816                 self.effects |= EF_FULLBRIGHT;
1817
1818                 if (self.items & IT_STRENGTH)
1819                 {
1820                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1821                         if (time > self.strength_finished)
1822                         {
1823                                 self.alpha = default_player_alpha;
1824                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1825                                 self.items &~= IT_STRENGTH;
1826                                 sprint(self, "^3Invisibility has worn off\n");
1827                         }
1828                 }
1829                 else
1830                 {
1831                         if (time < self.strength_finished)
1832                         {
1833                                 self.alpha = g_minstagib_invis_alpha;
1834                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1835                                 self.items |= IT_STRENGTH;
1836                                 sprint(self, "^3You are invisible\n");
1837                         }
1838                 }
1839
1840                 if (self.items & IT_INVINCIBLE)
1841                 {
1842                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1843                         if (time > self.invincible_finished)
1844                         {
1845                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1846                                 sprint(self, "^3Speed has worn off\n");
1847                         }
1848                 }
1849                 else
1850                 {
1851                         if (time < self.invincible_finished)
1852                         {
1853                                 self.items = self.items | IT_INVINCIBLE;
1854                                 sprint(self, "^3You are on speed\n");
1855                         }
1856                 }
1857         }
1858         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1859         {
1860                 if (self.items & IT_STRENGTH)
1861                 {
1862                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1863                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1864                         if (time > self.strength_finished)
1865                         {
1866                                 self.items = self.items - (self.items & IT_STRENGTH);
1867                                 sprint(self, "^3Strength has worn off\n");
1868                         }
1869                 }
1870                 else
1871                 {
1872                         if (time < self.strength_finished)
1873                         {
1874                                 self.items = self.items | IT_STRENGTH;
1875                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1876                         }
1877                 }
1878                 if (self.items & IT_INVINCIBLE)
1879                 {
1880                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1881                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1882                         if (time > self.invincible_finished)
1883                         {
1884                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1885                                 sprint(self, "^3Shield has worn off\n");
1886                         }
1887                 }
1888                 else
1889                 {
1890                         if (time < self.invincible_finished)
1891                         {
1892                                 self.items = self.items | IT_INVINCIBLE;
1893                                 sprint(self, "^3Shield surrounds you\n");
1894                         }
1895                 }
1896         }
1897
1898         if(autocvar_g_nodepthtestplayers)
1899                 self.effects = self.effects | EF_NODEPTHTEST;
1900
1901         if(autocvar_g_fullbrightplayers)
1902                 self.effects = self.effects | EF_FULLBRIGHT;
1903
1904         // midair gamemode: damage only while in the air
1905         // if in midair mode, being on ground grants temporary invulnerability
1906         // (this is so that multishot weapon don't clear the ground flag on the
1907         // first damage in the frame, leaving the player vulnerable to the
1908         // remaining hits in the same frame)
1909         if (self.flags & FL_ONGROUND)
1910         if (g_midair)
1911                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1912
1913         if (time >= game_starttime)
1914         if (time < self.spawnshieldtime)
1915                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1916
1917         MUTATOR_CALLHOOK(PlayerPowerups);
1918 }
1919
1920 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1921 {
1922         if(current > stable)
1923                 return current;
1924         else if(current > stable - 0.25) // when close enough, "snap"
1925                 return stable;
1926         else
1927                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1928 }
1929
1930 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1931 {
1932         if(current < stable)
1933                 return current;
1934         else if(current < stable + 0.25) // when close enough, "snap"
1935                 return stable;
1936         else
1937                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1938 }
1939
1940 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1941 {
1942         if(current > rotstable)
1943         {
1944                 if(rotframetime > 0)
1945                 {
1946                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1947                         current = max(rotstable, current - rotlinear * rotframetime);
1948                 }
1949         }
1950         else if(current < regenstable)
1951         {
1952                 if(regenframetime > 0)
1953                 {
1954                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1955                         current = min(regenstable, current + regenlinear * regenframetime);
1956                 }
1957         }
1958
1959         if(current > limit)
1960                 current = limit;
1961
1962         return current;
1963 }
1964
1965 void player_regen (void)
1966 {
1967         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1968         maxh = autocvar_g_balance_health_rotstable;
1969         maxa = autocvar_g_balance_armor_rotstable;
1970         maxf = autocvar_g_balance_fuel_rotstable;
1971         minh = autocvar_g_balance_health_regenstable;
1972         mina = autocvar_g_balance_armor_regenstable;
1973         minf = autocvar_g_balance_fuel_regenstable;
1974         limith = autocvar_g_balance_health_limit;
1975         limita = autocvar_g_balance_armor_limit;
1976         limitf = autocvar_g_balance_fuel_limit;
1977
1978         max_mod = regen_mod = rot_mod = limit_mod = 1;
1979
1980         if (self.runes & RUNE_REGEN)
1981         {
1982                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1983                 {
1984                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1985                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1986                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1987                 }
1988                 else
1989                 {
1990                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
1991                         max_mod = autocvar_g_balance_rune_regen_hpmod;
1992                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
1993                 }
1994         }
1995         else if (self.runes & CURSE_VENOM)
1996         {
1997                 max_mod = autocvar_g_balance_curse_venom_hpmod;
1998                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1999                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2000                 else
2001                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2002                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2003                 //if (!self.runes & RUNE_REGEN)
2004                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2005         }
2006         maxh = maxh * max_mod;
2007         //maxa = maxa * max_mod;
2008         //maxf = maxf * max_mod;
2009         minh = minh * max_mod;
2010         //mina = mina * max_mod;
2011         //minf = minf * max_mod;
2012         limith = limith * limit_mod;
2013         limita = limita * limit_mod;
2014         //limitf = limitf * limit_mod;
2015
2016         if(g_lms && g_ca)
2017                 rot_mod = 0;
2018
2019         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2020         {
2021                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2022                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2023
2024                 // if player rotted to death...  die!
2025                 if(self.health < 1)
2026                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2027         }
2028
2029         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2030                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2031 }
2032
2033 float zoomstate_set;
2034 void SetZoomState(float z)
2035 {
2036         if(z != self.zoomstate)
2037         {
2038                 self.zoomstate = z;
2039                 ClientData_Touch(self);
2040         }
2041         zoomstate_set = 1;
2042 }
2043
2044 void GetPressedKeys(void) {
2045         MUTATOR_CALLHOOK(GetPressedKeys);
2046         if (self.movement_x > 0) // get if movement keys are pressed
2047         {       // forward key pressed
2048                 self.pressedkeys |= KEY_FORWARD;
2049                 self.pressedkeys &~= KEY_BACKWARD;
2050         }
2051         else if (self.movement_x < 0)
2052         {       // backward key pressed
2053                 self.pressedkeys |= KEY_BACKWARD;
2054                 self.pressedkeys &~= KEY_FORWARD;
2055         }
2056         else
2057         {       // no x input
2058                 self.pressedkeys &~= KEY_FORWARD;
2059                 self.pressedkeys &~= KEY_BACKWARD;
2060         }
2061
2062         if (self.movement_y > 0)
2063         {       // right key pressed
2064                 self.pressedkeys |= KEY_RIGHT;
2065                 self.pressedkeys &~= KEY_LEFT;
2066         }
2067         else if (self.movement_y < 0)
2068         {       // left key pressed
2069                 self.pressedkeys |= KEY_LEFT;
2070                 self.pressedkeys &~= KEY_RIGHT;
2071         }
2072         else
2073         {       // no y input
2074                 self.pressedkeys &~= KEY_RIGHT;
2075                 self.pressedkeys &~= KEY_LEFT;
2076         }
2077
2078         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2079                 self.pressedkeys |= KEY_JUMP;
2080         else
2081                 self.pressedkeys &~= KEY_JUMP;
2082         if (self.BUTTON_CROUCH)
2083                 self.pressedkeys |= KEY_CROUCH;
2084         else
2085                 self.pressedkeys &~= KEY_CROUCH;
2086 }
2087
2088 /*
2089 ======================
2090 spectate mode routines
2091 ======================
2092 */
2093
2094 void SpectateCopy(entity spectatee) {
2095         other = spectatee;
2096         MUTATOR_CALLHOOK(SpectateCopy);
2097         self.armortype = spectatee.armortype;
2098         self.armorvalue = spectatee.armorvalue;
2099         self.ammo_cells = spectatee.ammo_cells;
2100         self.ammo_shells = spectatee.ammo_shells;
2101         self.ammo_nails = spectatee.ammo_nails;
2102         self.ammo_rockets = spectatee.ammo_rockets;
2103         self.ammo_fuel = spectatee.ammo_fuel;
2104         self.clip_load = spectatee.clip_load;
2105         self.clip_size = spectatee.clip_size;
2106         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2107         self.health = spectatee.health;
2108         self.impulse = 0;
2109         self.items = spectatee.items;
2110         self.last_pickup = spectatee.last_pickup;
2111         self.hit_time = spectatee.hit_time;
2112         self.metertime = spectatee.metertime;
2113         self.strength_finished = spectatee.strength_finished;
2114         self.invincible_finished = spectatee.invincible_finished;
2115         self.pressedkeys = spectatee.pressedkeys;
2116         self.weapons = spectatee.weapons;
2117         self.switchweapon = spectatee.switchweapon;
2118         self.switchingweapon = spectatee.switchingweapon;
2119         self.weapon = spectatee.weapon;
2120         self.nex_charge = spectatee.nex_charge;
2121         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2122         self.hagar_load = spectatee.hagar_load;
2123         self.minelayer_mines = spectatee.minelayer_mines;
2124         self.punchangle = spectatee.punchangle;
2125         self.view_ofs = spectatee.view_ofs;
2126         self.v_angle = spectatee.v_angle;
2127         self.velocity = spectatee.velocity;
2128         self.dmg_take = spectatee.dmg_take;
2129         self.dmg_save = spectatee.dmg_save;
2130         self.dmg_inflictor = spectatee.dmg_inflictor;
2131         self.angles = spectatee.v_angle;
2132         if(!self.BUTTON_USE)
2133                 self.fixangle = TRUE;
2134         setorigin(self, spectatee.origin);
2135         setsize(self, spectatee.mins, spectatee.maxs);
2136         SetZoomState(spectatee.zoomstate);
2137
2138         anticheat_spectatecopy(spectatee);
2139
2140         //self.vehicle = spectatee.vehicle;
2141
2142         self.hud = spectatee.hud;
2143         if(spectatee.vehicle)
2144     {
2145         setorigin(self, spectatee.origin);
2146         self.velocity = spectatee.vehicle.velocity;
2147         self.v_angle += spectatee.vehicle.angles;
2148         //self.v_angle_x *= -1;
2149         self.vehicle_health = spectatee.vehicle_health;
2150         self.vehicle_shield = spectatee.vehicle_shield;
2151         self.vehicle_energy = spectatee.vehicle_energy;
2152         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2153         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2154         self.vehicle_reload1 = spectatee.vehicle_reload1;
2155         self.vehicle_reload2 = spectatee.vehicle_reload2;
2156
2157         msg_entity = self;
2158         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2159         WriteEntity(MSG_ONE, spectatee);
2160         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2161     }
2162 }
2163
2164 float SpectateUpdate() {
2165         if(!self.enemy)
2166             return 0;
2167
2168         if (self == self.enemy)
2169                 return 0;
2170
2171         if(self.enemy.classname != "player")
2172                 return 0;
2173
2174         SpectateCopy(self.enemy);
2175
2176         return 1;
2177 }
2178
2179
2180 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2181 entity CA_SpectateNext(entity start) {
2182         if (start.team == self.team) {
2183                 return start;
2184         }
2185
2186         other = start;
2187         // continue from current player
2188         while(other && other.team != self.team) {
2189                 other = find(other, classname, "player");
2190         }
2191
2192         if (!other) {
2193                 // restart from begining
2194                 other = find(other, classname, "player");
2195                 while(other && other.team != self.team) {
2196                         other = find(other, classname, "player");
2197                 }
2198         }
2199
2200         return other;
2201 }
2202
2203 float SpectateNext() {
2204         other = find(self.enemy, classname, "player");
2205         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2206                 // CA and ca players when spectating enemies is forbidden
2207                 other = CA_SpectateNext(other);
2208         } else {
2209                 // other modes and ca spectators or spectating enemies is allowed
2210                 if (!other)
2211                         other = find(other, classname, "player");
2212         }
2213
2214         if (other)
2215                 self.enemy = other;
2216
2217         if(self.enemy.classname == "player") {
2218             if(self.enemy.vehicle)
2219             {
2220             msg_entity = self;
2221             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2222             WriteEntity(MSG_ONE, self.enemy);
2223             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2224             self.movetype = MOVETYPE_NONE;
2225             accuracy_resend(self);
2226             }
2227             else
2228             {
2229             msg_entity = self;
2230             WriteByte(MSG_ONE, SVC_SETVIEW);
2231             WriteEntity(MSG_ONE, self.enemy);
2232             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2233             self.movetype = MOVETYPE_NONE;
2234             accuracy_resend(self);
2235
2236             if(!SpectateUpdate())
2237                 PutObserverInServer();
2238         }
2239         return 1;
2240         } else {
2241                 return 0;
2242         }
2243 }
2244
2245 /*
2246 =============
2247 ShowRespawnCountdown()
2248
2249 Update a respawn countdown display.
2250 =============
2251 */
2252 void ShowRespawnCountdown()
2253 {
2254         float number;
2255         if(self.deadflag == DEAD_NO) // just respawned?
2256                 return;
2257         else
2258         {
2259                 number = ceil(self.death_time - time);
2260                 if(number <= 0)
2261                         return;
2262                 if(number <= self.respawn_countdown)
2263                 {
2264                         self.respawn_countdown = number - 1;
2265                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2266                                 AnnounceTo(self, strcat(ftos(number), ""));
2267                 }
2268         }
2269 }
2270
2271 .float prevent_join_msgtime;
2272 void LeaveSpectatorMode()
2273 {
2274         if(nJoinAllowed(1)) {
2275                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2276                         self.classname = "player";
2277
2278                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2279                                 JoinBestTeam(self, FALSE, TRUE);
2280
2281                         if(autocvar_g_campaign)
2282                                 campaign_bots_may_start = 1;
2283
2284                         PutClientInServer();
2285
2286                         if(self.classname == "player")
2287                                 bprint ("^4", self.netname, "^4 is playing now\n");
2288
2289                         if(!autocvar_g_campaign)
2290                         if (time < self.jointime + autocvar_welcome_message_time)
2291                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2292
2293                         if (self.prevent_join_msgtime)
2294                         {
2295                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2296                                 self.prevent_join_msgtime = 0;
2297                         }
2298
2299                         return;
2300                 } else {
2301                         if (g_ca && self.caplayer) {
2302                         }       // do nothing
2303                         else
2304                                 stuffcmd(self,"menu_showteamselect\n");
2305                         return;
2306                 }
2307         }
2308         else {
2309                 //player may not join because of g_maxplayers is set
2310                 if (time - self.prevent_join_msgtime > 2)
2311                 {
2312                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2313                         self.prevent_join_msgtime = time;
2314                 }
2315         }
2316 }
2317
2318 /**
2319  * Determines whether the player is allowed to join. This depends on cvar
2320  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2321  * it checks whether the number of currently playing players exceeds g_maxplayers.
2322  * @return int number of free slots for players, 0 if none
2323  */
2324 float nJoinAllowed(float includeMe) {
2325         if(self.team_forced < 0)
2326                 return FALSE; // forced spectators can never join
2327
2328         // TODO simplify this
2329         entity e;
2330
2331         float totalClients;
2332         FOR_EACH_CLIENT(e)
2333                 totalClients += 1;
2334
2335         if (!autocvar_g_maxplayers)
2336                 return maxclients - totalClients + includeMe;
2337
2338         float currentlyPlaying;
2339         FOR_EACH_REALPLAYER(e)
2340                 currentlyPlaying += 1;
2341
2342         if(currentlyPlaying < autocvar_g_maxplayers)
2343                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2344
2345         return 0;
2346 }
2347
2348 /**
2349  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2350  * g_maxplayers_spectator_blocktime seconds
2351  */
2352 void checkSpectatorBlock() {
2353         if(self.classname == "spectator" || self.classname == "observer") {
2354                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2355                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2356                         dropclient(self);
2357                 }
2358         }
2359 }
2360
2361 .float motd_actived_time; // used for both motd and campaign_message
2362 void PrintWelcomeMessage()
2363 {
2364         if (self.motd_actived_time == 0) { // is there already a message showing?
2365                 if (autocvar_g_campaign) {
2366                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2367                                 self.motd_actived_time = time;
2368                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2369                         }
2370                 } else {
2371                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2372                                 self.motd_actived_time = time;
2373                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2374                         }
2375                 }
2376         } else { // showing MOTD or campaign message
2377                 if (autocvar_g_campaign) {
2378                         if (self.BUTTON_INFO)
2379                                 self.motd_actived_time = time;
2380                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2381                                 self.motd_actived_time = 0;
2382                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2383                         }
2384                 } else {
2385                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2386                                 if (self.BUTTON_INFO)
2387                                         self.motd_actived_time = time;
2388                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2389                                         self.motd_actived_time = 0;
2390                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2391                                 }
2392                         }
2393                 }
2394         }
2395 }
2396
2397 void ObserverThink()
2398 {
2399         float prefered_movetype;
2400         if (self.flags & FL_JUMPRELEASED) {
2401                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2402                         self.flags &~= FL_JUMPRELEASED;
2403                         self.flags |= FL_SPAWNING;
2404                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2405                         self.flags &~= FL_JUMPRELEASED;
2406                         if(SpectateNext() == 1) {
2407                                 self.classname = "spectator";
2408                         }
2409                 } else {
2410                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2411                         if (self.movetype != prefered_movetype)
2412                                 self.movetype = prefered_movetype;
2413                 }
2414         } else {
2415                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2416                         self.flags |= FL_JUMPRELEASED;
2417                         if(self.flags & FL_SPAWNING)
2418                         {
2419                                 self.flags &~= FL_SPAWNING;
2420                                 LeaveSpectatorMode();
2421                                 return;
2422                         }
2423                 }
2424         }
2425
2426         PrintWelcomeMessage();
2427 }
2428
2429 void SpectatorThink()
2430 {
2431         if (self.flags & FL_JUMPRELEASED) {
2432                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2433                         self.flags &~= FL_JUMPRELEASED;
2434                         self.flags |= FL_SPAWNING;
2435                 } else if(self.BUTTON_ATCK) {
2436                         self.flags &~= FL_JUMPRELEASED;
2437                         if(SpectateNext() == 1) {
2438                                 self.classname = "spectator";
2439                         } else {
2440                                 self.classname = "observer";
2441                                 PutClientInServer();
2442                         }
2443                 } else if (self.BUTTON_ATCK2) {
2444                         self.flags &~= FL_JUMPRELEASED;
2445                         self.classname = "observer";
2446                         PutClientInServer();
2447                 } else {
2448                         if(!SpectateUpdate())
2449                                 PutObserverInServer();
2450                 }
2451         } else {
2452                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2453                         self.flags |= FL_JUMPRELEASED;
2454                         if(self.flags & FL_SPAWNING)
2455                         {
2456                                 self.flags &~= FL_SPAWNING;
2457                                 LeaveSpectatorMode();
2458                                 return;
2459                         }
2460                 }
2461                 if(!SpectateUpdate())
2462                         PutObserverInServer();
2463         }
2464
2465         PrintWelcomeMessage();
2466         self.flags |= FL_CLIENT | FL_NOTARGET;
2467 }
2468
2469 float ctf_usekey();
2470 void PlayerUseKey()
2471 {
2472         if(self.classname != "player")
2473                 return;
2474
2475         if(self.vehicle)
2476         {
2477         vehicles_exit(VHEF_NORMAL);
2478         return;
2479         }
2480
2481         // a use key was pressed; call handlers
2482         if(ctf_usekey())
2483                 return;
2484
2485         MUTATOR_CALLHOOK(PlayerUseKey);
2486 }
2487
2488 .float touchexplode_time;
2489
2490 /*
2491 =============
2492 PlayerPreThink
2493
2494 Called every frame for each client before the physics are run
2495 =============
2496 */
2497 .float usekeypressed;
2498 void() ctf_setstatus;
2499 void() nexball_setstatus;
2500 .float items_added;
2501 void PlayerPreThink (void)
2502 {
2503         WarpZone_PlayerPhysics_FixVAngle();
2504
2505         self.stat_game_starttime = game_starttime;
2506         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2507         self.stat_leadlimit = autocvar_leadlimit;
2508
2509         if(frametime)
2510         {
2511                 // physics frames: update anticheat stuff
2512                 anticheat_prethink();
2513         }
2514
2515         if(blockSpectators && frametime)
2516                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2517                 checkSpectatorBlock();
2518
2519         zoomstate_set = 0;
2520
2521         if(self.netname_previous != self.netname)
2522         {
2523                 if(autocvar_sv_eventlog)
2524                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2525                 if(self.netname_previous)
2526                         strunzone(self.netname_previous);
2527                 self.netname_previous = strzone(self.netname);
2528         }
2529
2530         // version nagging
2531         if(self.version_nagtime)
2532                 if(self.cvar_g_xonoticversion)
2533                         if(time > self.version_nagtime)
2534                         {
2535                                 // don't notify git users
2536                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2537                                 {
2538                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2539                                         {
2540                                                 // notify release users if connecting to git
2541                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2542                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2543                                         }
2544                                         else
2545                                         {
2546                                                 float r;
2547                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2548                                                 if(r < 0)
2549                                                 {
2550                                                         // give users new version
2551                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2552                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2553                                                 }
2554                                                 else if(r > 0)
2555                                                 {
2556                                                         // notify users about old server version
2557                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2558                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2559                                                 }
2560                                         }
2561                                 }
2562                                 self.version_nagtime = 0;
2563                         }
2564
2565         // GOD MODE info
2566         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2567         {
2568                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2569                 self.max_armorvalue = 0;
2570         }
2571
2572 #ifdef TETRIS
2573         if (TetrisPreFrame())
2574                 return;
2575 #endif
2576
2577         MUTATOR_CALLHOOK(PlayerPreThink);
2578
2579         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2580         {
2581                 if(self.BUTTON_USE && !self.usekeypressed)
2582                         PlayerUseKey();
2583                 self.usekeypressed = self.BUTTON_USE;
2584         }
2585
2586         PrintWelcomeMessage();
2587
2588         if(self.classname == "player") {
2589 //              if(self.netname == "Wazat")
2590 //                      bprint(self.classname, "\n");
2591
2592                 CheckRules_Player();
2593
2594                 if (intermission_running)
2595                 {
2596                         IntermissionThink ();   // otherwise a button could be missed between
2597                         return;                                 // the think tics
2598                 }
2599
2600                 //don't allow the player to turn around while game is paused!
2601                 if(timeout_status == TIMEOUT_ACTIVE) {
2602                         // FIXME turn this into CSQC stuff
2603                         self.v_angle = self.lastV_angle;
2604                         self.angles = self.lastV_angle;
2605                         self.fixangle = TRUE;
2606                 }
2607
2608                 if(frametime)
2609                 {
2610 #ifndef NO_LEGACY_NETWORKING
2611                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2612 #endif
2613
2614                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2615                         {
2616                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2617                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2618                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2619
2620                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2621                                 {
2622                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2623                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2624                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2625                                 }
2626                         }
2627                         else
2628                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2629
2630                         player_powerups();
2631                 }
2632
2633                 if (g_minstagib)
2634                         minstagib_ammocheck();
2635
2636                 if (self.deadflag != DEAD_NO)
2637                 {
2638                         float button_pressed, force_respawn;
2639                         if(self.personal && g_race_qualifying)
2640                         {
2641                                 if(time > self.death_time)
2642                                 {
2643                                         self.death_time = time + 1; // only retry once a second
2644                                         respawn();
2645                                         self.impulse = 141;
2646                                 }
2647                         }
2648                         else
2649                         {
2650                                 if(frametime)
2651                                         player_anim();
2652                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2653                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2654                                 if (self.deadflag == DEAD_DYING)
2655                                 {
2656                                         if(force_respawn)
2657                                                 self.deadflag = DEAD_RESPAWNING;
2658                                         else if(!button_pressed)
2659                                                 self.deadflag = DEAD_DEAD;
2660                                 }
2661                                 else if (self.deadflag == DEAD_DEAD)
2662                                 {
2663                                         if(button_pressed)
2664                                                 self.deadflag = DEAD_RESPAWNABLE;
2665                                 }
2666                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2667                                 {
2668                                         if(!button_pressed)
2669                                                 self.deadflag = DEAD_RESPAWNING;
2670                                 }
2671                                 else if (self.deadflag == DEAD_RESPAWNING)
2672                                 {
2673                                         if(time > self.death_time)
2674                                         {
2675                                                 self.death_time = time + 1; // only retry once a second
2676                                                 respawn();
2677                                         }
2678                                 }
2679                                 ShowRespawnCountdown();
2680                         }
2681                         return;
2682                 }
2683                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2684                 // so (self.deadflag == DEAD_NO) is always true in the code below
2685
2686                 if(g_touchexplode)
2687                 if(time > self.touchexplode_time)
2688                 if(self.classname == "player")
2689                 if(self.deadflag == DEAD_NO)
2690                 if not(IS_INDEPENDENT_PLAYER(self))
2691                 FOR_EACH_PLAYER(other) if(self != other)
2692                 {
2693                         if(time > other.touchexplode_time)
2694                         if(other.deadflag == DEAD_NO)
2695                         if not(IS_INDEPENDENT_PLAYER(other))
2696                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2697                         {
2698                                 PlayerTouchExplode(self, other);
2699                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2700                         }
2701                 }
2702
2703                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2704                 {
2705                         vector dist;
2706
2707                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2708                         dist = self.prevorigin - self.origin;
2709                         dist_z = 0;
2710                         self.lms_traveled_distance += fabs(vlen(dist));
2711
2712                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2713                         {
2714                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2715                                 self.lms_traveled_distance = 0;
2716                         }
2717
2718                         if(time > self.lms_nextcheck)
2719                         {
2720                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2721                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2722                                 {
2723                                         centerprint(self, autocvar_g_lms_campcheck_message);
2724                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2725                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2726                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2727                                 }
2728                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2729                                 self.lms_traveled_distance = 0;
2730                         }
2731                 }
2732
2733                 self.prevorigin = self.origin;
2734
2735                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2736                 {
2737                         if (!self.crouch)
2738                         {
2739                                 self.crouch = TRUE;
2740                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2741                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2742                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2743                         }
2744                 }
2745                 else
2746                 {
2747                         if (self.crouch)
2748                         {
2749                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2750                                 if (!trace_startsolid)
2751                                 {
2752                                         self.crouch = FALSE;
2753                                         self.view_ofs = PL_VIEW_OFS;
2754                                         setsize (self, PL_MIN, PL_MAX);
2755                                 }
2756                         }
2757                 }
2758
2759                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2760                 {
2761                         if(self.bloodloss_timer < time)
2762                         {
2763                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2764                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2765                         }
2766                 }
2767
2768                 FixPlayermodel();
2769
2770                 GrapplingHookFrame();
2771
2772                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2773                 //if(frametime)
2774                 {
2775                         self.items &~= self.items_added;
2776
2777                         W_WeaponFrame();
2778
2779                         self.items_added = 0;
2780                         if(self.items & IT_JETPACK)
2781                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2782                                         self.items_added |= IT_FUEL;
2783
2784                         self.items |= self.items_added;
2785                 }
2786
2787                 player_regen();
2788
2789                 // rot nex charge to the charge limit
2790                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2791                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2792
2793                 if(frametime)
2794                         player_anim();
2795
2796                 if(g_ctf)
2797                         ctf_setstatus();
2798
2799                 if(g_nexball)
2800                         nexball_setstatus();
2801
2802                 // secret status
2803                 secrets_setstatus();
2804
2805                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2806
2807                 //self.angles_y=self.v_angle_y + 90;   // temp
2808         } else if(gameover) {
2809                 if (intermission_running)
2810                         IntermissionThink ();   // otherwise a button could be missed between
2811                 return;
2812         } else if(self.classname == "observer") {
2813                 ObserverThink();
2814         } else if(self.classname == "spectator") {
2815                 SpectatorThink();
2816         }
2817
2818         if(!zoomstate_set)
2819                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2820
2821         float oldspectatee_status;
2822         oldspectatee_status = self.spectatee_status;
2823         if(self.classname == "spectator")
2824                 self.spectatee_status = num_for_edict(self.enemy);
2825         else if(self.classname == "observer")
2826                 self.spectatee_status = num_for_edict(self);
2827         else
2828                 self.spectatee_status = 0;
2829         if(self.spectatee_status != oldspectatee_status)
2830         {
2831                 ClientData_Touch(self);
2832                 if(g_race || g_cts)
2833                         race_InitSpectator();
2834         }
2835
2836         if(self.teamkill_soundtime)
2837         if(time > self.teamkill_soundtime)
2838         {
2839                 self.teamkill_soundtime = 0;
2840
2841                 entity oldpusher, oldself;
2842
2843                 oldself = self; self = self.teamkill_soundsource;
2844                 oldpusher = self.pusher; self.pusher = oldself;
2845
2846                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2847
2848                 self.pusher = oldpusher;
2849                 self = oldself;
2850         }
2851
2852         if(self.taunt_soundtime)
2853         if(time > self.taunt_soundtime)
2854         {
2855                 self.taunt_soundtime = 0;
2856                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2857         }
2858
2859         target_voicescript_next(self);
2860
2861         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2862         if(!self.weapon)
2863                 self.clip_load = self.clip_size = 0;
2864 }
2865
2866 float isInvisibleString(string s)
2867 {
2868         float i, n, c;
2869         s = strdecolorize(s);
2870         for((i = 0), (n = strlen(s)); i < n; ++i)
2871         {
2872                 c = str2chr(s, i);
2873                 switch(c)
2874                 {
2875                         case 0:
2876                         case 32: // space
2877                                 break;
2878                         case 192: // charmap space
2879                                 if (!autocvar_utf8_enable)
2880                                         break;
2881                                 return FALSE;
2882                         case 160: // space in unicode fonts
2883                         case 0xE000 + 192: // utf8 charmap space
2884                                 if (autocvar_utf8_enable)
2885                                         break;
2886                         default:
2887                                 return FALSE;
2888                 }
2889         }
2890         return TRUE;
2891 }
2892
2893 /*
2894 =============
2895 PlayerPostThink
2896
2897 Called every frame for each client after the physics are run
2898 =============
2899 */
2900 .float idlekick_lasttimeleft;
2901 .entity showheadshotbbox;
2902 void showheadshotbbox_think()
2903 {
2904         if(self.owner.showheadshotbbox != self)
2905         {
2906                 remove(self);
2907                 return;
2908         }
2909         self.nextthink = time;
2910         setorigin(self, self.owner.origin);
2911         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2912 }
2913 void PlayerPostThink (void)
2914 {
2915         // Savage: Check for nameless players
2916         if (isInvisibleString(self.netname)) {
2917                 self.netname = "Player";
2918                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2919         }
2920
2921         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2922         {
2923                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2924                 {
2925                         if(self.idlekick_lasttimeleft)
2926                         {
2927                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2928                                 self.idlekick_lasttimeleft = 0;
2929                         }
2930                 }
2931                 else
2932                 {
2933                         float timeleft;
2934                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2935                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2936                         {
2937                                 if(!self.idlekick_lasttimeleft)
2938                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2939                         }
2940                         if(timeleft <= 0)
2941                         {
2942                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2943                                 AnnounceTo(self, "terminated");
2944                                 dropclient(self);
2945                                 return;
2946                         }
2947                         else if(timeleft <= 10)
2948                         {
2949                                 if(timeleft != self.idlekick_lasttimeleft)
2950                                         AnnounceTo(self, ftos(timeleft));
2951                                 self.idlekick_lasttimeleft = timeleft;
2952                         }
2953                 }
2954         }
2955
2956 #ifdef TETRIS
2957         if(self.impulse == 100)
2958                 ImpulseCommands();
2959         if (!TetrisPostFrame())
2960         {
2961 #endif
2962
2963         CheatFrame();
2964
2965         //CheckPlayerJump();
2966
2967         if(self.classname == "player") {
2968                 CheckRules_Player();
2969                 UpdateChatBubble();
2970                 if (self.impulse)
2971                         ImpulseCommands();
2972                 if (intermission_running)
2973                         return;         // intermission or finale
2974                 GetPressedKeys();
2975         } else if (self.classname == "observer") {
2976                 //do nothing
2977         } else if (self.classname == "spectator") {
2978                 //do nothing
2979         }
2980
2981 #ifdef TETRIS
2982         }
2983 #endif
2984
2985         /*
2986         float i;
2987         for(i = 0; i < 1000; ++i)
2988         {
2989                 vector end;
2990                 end = self.origin + '0 0 1024' + 512 * randomvec();
2991                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2992                 if(trace_fraction < 1)
2993                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2994                 {
2995                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2996                         break;
2997                 }
2998         }
2999         */
3000
3001         Arena_Warmup();
3002
3003         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3004
3005         if(self.waypointsprite_attachedforcarrier)
3006                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3007
3008         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3009         {
3010                 if(!self.showheadshotbbox)
3011                 {
3012                         self.showheadshotbbox = spawn();
3013                         self.showheadshotbbox.classname = "headshotbbox";
3014                         self.showheadshotbbox.owner = self;
3015                         self.showheadshotbbox.think = showheadshotbbox_think;
3016                         self.showheadshotbbox.nextthink = time;
3017                         self = self.showheadshotbbox;
3018                         self.think();
3019                         self = self.owner;
3020                 }
3021         }
3022         else
3023         {
3024                 if(self.showheadshotbbox)
3025                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3026                 remove(self.showheadshotbbox);
3027         }
3028
3029         playerdemo_write();
3030
3031         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3032         {
3033                 if(!self.stored_netname)
3034                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3035                 if(self.stored_netname != self.netname)
3036                 {
3037                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3038                         strunzone(self.stored_netname);
3039                         self.stored_netname = strzone(self.netname);
3040                 }
3041         }
3042
3043         /*
3044         if(g_race)
3045                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3046         */
3047
3048         CSQCMODEL_AUTOUPDATE();
3049 }