qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ent_cs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "spawnpoints.qh"
  13 #include "g_damage.qh"
  14 #include "g_hook.qh"
  15 #include "command/common.qh"
  16 #include "cheats.qh"
  17 #include "g_world.qh"
  18 #include "race.qh"
  19 #include "antilag.qh"
  20 #include "campaign.qh"
  21 #include "command/common.qh"
  22
  23 #include "bot/bot.qh"
  24 #include "bot/navigation.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/triggers/teleporters.qh"
  28
  29 #include "weapons/hitplot.qh"
  30 #include "weapons/weaponsystem.qh"
  31
  32 #include "../common/net_notice.qh"
  33 #include "../common/physics.qh"
  34
  35 #include "../common/items/all.qc"
  36
  37 #include "../common/mutators/mutator/waypoints/all.qh"
  38
  39 #include "../common/triggers/subs.qh"
  40 #include "../common/triggers/triggers.qh"
  41 #include "../common/triggers/trigger/secret.qh"
  42
  43 #include "../common/minigames/sv_minigames.qh"
  44
  45 #include "../common/items/inventory.qh"
  46
  47 #include "../common/monsters/sv_monsters.qh"
  48
  49 #include "../lib/warpzone/server.qh"
  50
  51
  52 void send_CSQC_teamnagger() {
  53         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  54         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  55 }
  56
  57 bool ClientData_Send(entity this, entity to, int sf)
  58 {
  59         if(to != self.owner)
  60         {
  61                 error("wtf");
  62                 return false;
  63         }
  64
  65         entity e;
  66
  67         e = to;
  68         if(IS_SPEC(to))
  69                 e = to.enemy;
  70
  71         sf = 0;
  72
  73         if(e.race_completed)
  74                 sf |= 1; // forced scoreboard
  75         if(to.spectatee_status)
  76                 sf |= 2; // spectator ent number follows
  77         if(e.zoomstate)
  78                 sf |= 4; // zoomed
  79         if(e.porto_v_angle_held)
  80                 sf |= 8; // angles held
  81
  82         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  83         WriteByte(MSG_ENTITY, sf);
  84
  85         if(sf & 2)
  86                 WriteByte(MSG_ENTITY, to.spectatee_status);
  87
  88         if(sf & 8)
  89         {
  90                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  91                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  92         }
  93
  94         return true;
  95 }
  96
  97 void ClientData_Attach()
  98 {SELFPARAM();
  99         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
 100         self.clientdata.drawonlytoclient = self;
 101         self.clientdata.owner = self;
 102 }
 103
 104 void ClientData_Detach()
 105 {SELFPARAM();
 106         remove(self.clientdata);
 107         self.clientdata = world;
 108 }
 109
 110 void ClientData_Touch(entity e)
 111 {
 112         e.clientdata.SendFlags = 1;
 113
 114         // make it spectatable
 115         entity e2;
 116         FOR_EACH_REALCLIENT(e2)
 117         {
 118                 if(e2 != e)
 119                         if(IS_SPEC(e2))
 120                                 if(e2.enemy == e)
 121                                         e2.clientdata.SendFlags = 1;
 122         }
 123 }
 124
 125 .string netname_previous;
 126
 127 void SetSpectator(entity player, entity spectatee);
 128
 129
 130 /*
 131 =============
 132 CheckPlayerModel
 133
 134 Checks if the argument string can be a valid playermodel.
 135 Returns a valid one in doubt.
 136 =============
 137 */
 138 string FallbackPlayerModel;
 139 string CheckPlayerModel(string plyermodel) {
 140         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 141         {
 142                 // note: we cannot summon Don Strunzone here, some player may
 143                 // still have the model string set. In case anyone manages how
 144                 // to change a cvar default, we'll have a small leak here.
 145                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 146         }
 147         // only in right path
 148         if( substring(plyermodel,0,14) != "models/player/")
 149                 return FallbackPlayerModel;
 150         // only good file extensions
 151         if(substring(plyermodel,-4,4) != ".zym")
 152         if(substring(plyermodel,-4,4) != ".dpm")
 153         if(substring(plyermodel,-4,4) != ".iqm")
 154         if(substring(plyermodel,-4,4) != ".md3")
 155         if(substring(plyermodel,-4,4) != ".psk")
 156                 return FallbackPlayerModel;
 157         // forbid the LOD models
 158         if(substring(plyermodel, -9,5) == "_lod1")
 159                 return FallbackPlayerModel;
 160         if(substring(plyermodel, -9,5) == "_lod2")
 161                 return FallbackPlayerModel;
 162         if(plyermodel != strtolower(plyermodel))
 163                 return FallbackPlayerModel;
 164         // also, restrict to server models
 165         if(autocvar_sv_servermodelsonly)
 166         {
 167                 if(!fexists(plyermodel))
 168                         return FallbackPlayerModel;
 169         }
 170         return plyermodel;
 171 }
 172
 173 void setplayermodel(entity e, string modelname)
 174 {
 175         precache_model(modelname);
 176         _setmodel(e, modelname);
 177         player_setupanimsformodel();
 178         UpdatePlayerSounds();
 179 }
 180
 181 /*
 182 =============
 183 PutObserverInServer
 184
 185 putting a client as observer in the server
 186 =============
 187 */
 188 void FixPlayermodel();
 189 void PutObserverInServer (void)
 190 {SELFPARAM();
 191         entity  spot;
 192     self.hud = HUD_NORMAL;
 193
 194         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
 195
 196         spot = SelectSpawnPoint (true);
 197         if(!spot)
 198                 error("No spawnpoints for observers?!?\n");
 199         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 200
 201         if(IS_REAL_CLIENT(self))
 202         {
 203                 msg_entity = self;
 204                 WriteByte(MSG_ONE, SVC_SETVIEW);
 205                 WriteEntity(MSG_ONE, self);
 206         }
 207
 208         self.frags = FRAGS_SPECTATOR;
 209         self.bot_attack = false;
 210
 211         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 212
 213         Portal_ClearAll(self);
 214
 215         Unfreeze(self);
 216
 217         if(self.alivetime)
 218         {
 219                 if(!warmup_stage)
 220                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 221                 self.alivetime = 0;
 222         }
 223
 224         if(self.vehicle)
 225                 vehicles_exit(VHEF_RELEASE);
 226
 227         WaypointSprite_PlayerDead();
 228
 229         if(!mutator_returnvalue)  // mutator prevents resetting teams
 230                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 231
 232         if(self.killcount != -666)
 233         {
 234                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 235                 if(!intermission_running)
 236                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 237                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 238
 239                 if(self.just_joined == false) {
 240                         LogTeamchange(self.playerid, -1, 4);
 241                 } else
 242                         self.just_joined = false;
 243         }
 244
 245         PlayerScore_Clear(self); // clear scores when needed
 246
 247         accuracy_resend(self);
 248
 249         self.spectatortime = time;
 250
 251         self.classname = "observer";
 252         self.iscreature = false;
 253         self.teleportable = TELEPORT_SIMPLE;
 254         self.damagedbycontents = false;
 255         self.health = -666;
 256         self.takedamage = DAMAGE_NO;
 257         self.solid = SOLID_NOT;
 258         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 259         self.flags = FL_CLIENT | FL_NOTARGET;
 260         self.armorvalue = 666;
 261         self.effects = 0;
 262         self.armorvalue = autocvar_g_balance_armor_start;
 263         self.pauserotarmor_finished = 0;
 264         self.pauserothealth_finished = 0;
 265         self.pauseregen_finished = 0;
 266         self.damageforcescale = 0;
 267         self.death_time = 0;
 268         self.respawn_flags = 0;
 269         self.respawn_time = 0;
 270         self.stat_respawn_time = 0;
 271         self.alpha = 0;
 272         self.scale = 0;
 273         self.fade_time = 0;
 274         self.pain_frame = 0;
 275         self.pain_finished = 0;
 276         self.strength_finished = 0;
 277         self.invincible_finished = 0;
 278         self.superweapons_finished = 0;
 279         self.pushltime = 0;
 280         self.istypefrag = 0;
 281         self.think = func_null;
 282         self.nextthink = 0;
 283         self.hook_time = 0;
 284         self.deadflag = DEAD_NO;
 285         self.angles = spot.angles;
 286         self.angles_z = 0;
 287         self.fixangle = true;
 288         self.crouch = false;
 289         self.revival_time = 0;
 290
 291         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 292         self.prevorigin = self.origin;
 293         self.items = 0;
 294         self.weapons = '0 0 0';
 295         self.model = "";
 296         FixPlayermodel();
 297         setmodel(self, MDL_Null);
 298         self.drawonlytoclient = self;
 299
 300         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 301         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 302
 303         self.weapon = 0;
 304         self.weaponname = "";
 305         self.switchingweapon = 0;
 306         self.weaponmodel = "";
 307         self.weaponentity = world;
 308         self.exteriorweaponentity = world;
 309         self.killcount = -666;
 310         self.velocity = '0 0 0';
 311         self.avelocity = '0 0 0';
 312         self.punchangle = '0 0 0';
 313         self.punchvector = '0 0 0';
 314         self.oldvelocity = self.velocity;
 315         self.fire_endtime = -1;
 316         self.event_damage = func_null;
 317 }
 318
 319 .float model_randomizer;
 320 void FixPlayermodel()
 321 {SELFPARAM();
 322         string defaultmodel;
 323         float defaultskin, chmdl, oldskin, n, i;
 324         vector m1, m2;
 325
 326         defaultmodel = "";
 327         defaultskin = 0;
 328         chmdl = false;
 329
 330         if(autocvar_sv_defaultcharacter)
 331         {
 332                 if(teamplay)
 333                 {
 334                         string s = Static_Team_ColorName_Lower(self.team);
 335                         if (s != "neutral")
 336                         {
 337                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 338                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 339                         }
 340                 }
 341
 342                 if(defaultmodel == "")
 343                 {
 344                         defaultmodel = autocvar_sv_defaultplayermodel;
 345                         defaultskin = autocvar_sv_defaultplayerskin;
 346                 }
 347
 348                 n = tokenize_console(defaultmodel);
 349                 if(n > 0)
 350                 {
 351                         defaultmodel = argv(floor(n * self.model_randomizer));
 352                         // However, do NOT randomize if the player-selected model is in the list.
 353                         for (i = 0; i < n; ++i)
 354                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 355                                         defaultmodel = argv(i);
 356                 }
 357
 358                 i = strstrofs(defaultmodel, ":", 0);
 359                 if(i >= 0)
 360                 {
 361                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 362                         defaultmodel = substring(defaultmodel, 0, i);
 363                 }
 364         }
 365
 366         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 367         defaultmodel = ret_string;
 368         defaultskin = ret_int;
 369
 370         if(defaultmodel != "")
 371         {
 372                 if (defaultmodel != self.model)
 373                 {
 374                         m1 = self.mins;
 375                         m2 = self.maxs;
 376                         setplayermodel (self, defaultmodel);
 377                         setsize (self, m1, m2);
 378                         chmdl = true;
 379                 }
 380
 381                 oldskin = self.skin;
 382                 self.skin = defaultskin;
 383         } else {
 384                 if (self.playermodel != self.model || self.playermodel == "")
 385                 {
 386                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 387                         m1 = self.mins;
 388                         m2 = self.maxs;
 389                         setplayermodel (self, self.playermodel);
 390                         setsize (self, m1, m2);
 391                         chmdl = true;
 392                 }
 393
 394                 oldskin = self.skin;
 395                 self.skin = stof(self.playerskin);
 396         }
 397
 398         if(chmdl || oldskin != self.skin) // model or skin has changed
 399         {
 400                 self.species = player_getspecies(); // update species
 401                 UpdatePlayerSounds(); // update skin sounds
 402         }
 403
 404         if(!teamplay)
 405                 if(strlen(autocvar_sv_defaultplayercolors))
 406                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 407                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 408 }
 409
 410
 411 /** Called when a client spawns in the server */
 412 void PutClientInServer()
 413 {
 414         SELFPARAM();
 415         if(IS_BOT_CLIENT(self))
 416                 self.classname = "player";
 417         else if(IS_REAL_CLIENT(self))
 418         {
 419                 msg_entity = self;
 420                 WriteByte(MSG_ONE, SVC_SETVIEW);
 421                 WriteEntity(MSG_ONE, self);
 422         }
 423
 424         SetSpectator(self, world);
 425
 426         // reset player keys
 427         self.itemkeys = 0;
 428
 429         MUTATOR_CALLHOOK(PutClientInServer, self);
 430
 431         if(gameover)
 432                 self.classname = "observer";
 433
 434         if(IS_PLAYER(self))
 435         {
 436                 entity spot;
 437
 438                 accuracy_resend(self);
 439
 440                 if(self.team < 0)
 441                         JoinBestTeam(self, false, true);
 442
 443                 spot = SelectSpawnPoint (false);
 444                 if(!spot)
 445                 {
 446                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 447                         return; // spawn failed
 448                 }
 449
 450                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 451
 452                 self.classname = "player";
 453                 self.wasplayer = true;
 454                 self.iscreature = true;
 455                 self.teleportable = TELEPORT_NORMAL;
 456                 self.damagedbycontents = true;
 457                 self.movetype = MOVETYPE_WALK;
 458                 self.solid = SOLID_SLIDEBOX;
 459                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 460                 if(autocvar_g_playerclip_collisions)
 461                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 462                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 463                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 464                 self.frags = FRAGS_PLAYER;
 465                 if(INDEPENDENT_PLAYERS)
 466                         MAKE_INDEPENDENT_PLAYER(self);
 467                 self.flags = FL_CLIENT | FL_PICKUPITEMS;
 468                 if(autocvar__notarget)
 469                         self.flags |= FL_NOTARGET;
 470                 self.takedamage = DAMAGE_AIM;
 471                 self.effects = 0;
 472                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 473                 self.air_finished = time + 12;
 474                 self.dmg = 2;
 475                 if(WEP_CVAR(vortex, charge))
 476                 {
 477                         if(WEP_CVAR_SEC(vortex, chargepool))
 478                                 self.vortex_chargepool_ammo = 1;
 479                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 480                 }
 481
 482                 if(warmup_stage)
 483                 {
 484                         self.ammo_shells = warmup_start_ammo_shells;
 485                         self.ammo_nails = warmup_start_ammo_nails;
 486                         self.ammo_rockets = warmup_start_ammo_rockets;
 487                         self.ammo_cells = warmup_start_ammo_cells;
 488                         self.ammo_plasma = warmup_start_ammo_plasma;
 489                         self.ammo_fuel = warmup_start_ammo_fuel;
 490                         self.health = warmup_start_health;
 491                         self.armorvalue = warmup_start_armorvalue;
 492                         self.weapons = WARMUP_START_WEAPONS;
 493                 }
 494                 else
 495                 {
 496                         self.ammo_shells = start_ammo_shells;
 497                         self.ammo_nails = start_ammo_nails;
 498                         self.ammo_rockets = start_ammo_rockets;
 499                         self.ammo_cells = start_ammo_cells;
 500                         self.ammo_plasma = start_ammo_plasma;
 501                         self.ammo_fuel = start_ammo_fuel;
 502                         self.health = start_health;
 503                         self.armorvalue = start_armorvalue;
 504                         self.weapons = start_weapons;
 505                 }
 506
 507                 if(self.weapons & WEPSET_SUPERWEAPONS)
 508                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 509                 else
 510                         self.superweapons_finished = 0;
 511
 512                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 513                 {
 514                         if(g_weaponarena_random_with_blaster)
 515                                 self.weapons &= ~WEPSET(BLASTER);
 516                         W_RandomWeapons(self, g_weaponarena_random);
 517                         if(g_weaponarena_random_with_blaster)
 518                                 self.weapons |= WEPSET(BLASTER);
 519                 }
 520
 521                 self.items = start_items;
 522
 523                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 524                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 525                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 526                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 527                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 528                 //extend the pause of rotting if client was reset at the beginning of the countdown
 529                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 530                         self.spawnshieldtime += game_starttime - time;
 531                         self.pauserotarmor_finished += game_starttime - time;
 532                         self.pauserothealth_finished += game_starttime - time;
 533                         self.pauseregen_finished += game_starttime - time;
 534                 }
 535                 self.damageforcescale = 2;
 536                 self.death_time = 0;
 537                 self.respawn_flags = 0;
 538                 self.respawn_time = 0;
 539                 self.stat_respawn_time = 0;
 540                 self.scale = autocvar_sv_player_scale;
 541                 self.fade_time = 0;
 542                 self.pain_frame = 0;
 543                 self.pain_finished = 0;
 544                 self.strength_finished = 0;
 545                 self.invincible_finished = 0;
 546                 self.pushltime = 0;
 547                 // players have no think function
 548                 self.think = func_null;
 549                 self.nextthink = 0;
 550                 self.hook_time = 0;
 551                 self.dmg_team = 0;
 552                 self.ballistics_density = autocvar_g_ballistics_density_player;
 553
 554                 self.metertime = 0;
 555
 556                 self.deadflag = DEAD_NO;
 557
 558                 self.angles = spot.angles;
 559
 560                 self.angles_z = 0; // never spawn tilted even if the spot says to
 561                 if(IS_BOT_CLIENT(self))
 562                         self.v_angle = self.angles;
 563                 self.fixangle = true; // turn this way immediately
 564                 self.velocity = '0 0 0';
 565                 self.avelocity = '0 0 0';
 566                 self.punchangle = '0 0 0';
 567                 self.punchvector = '0 0 0';
 568                 self.oldvelocity = self.velocity;
 569                 self.fire_endtime = -1;
 570                 self.revival_time = 0;
 571
 572                 entity spawnevent = spawn();
 573                 spawnevent.owner = self;
 574                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 575
 576                 // Cut off any still running player sounds.
 577                 stopsound(self, CH_PLAYER_SINGLE);
 578
 579                 self.model = "";
 580                 FixPlayermodel();
 581                 self.drawonlytoclient = world;
 582
 583                 self.crouch = false;
 584                 self.view_ofs = PL_VIEW_OFS;
 585                 setsize (self, PL_MIN, PL_MAX);
 586                 self.spawnorigin = spot.origin;
 587                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 588                 // don't reset back to last position, even if new position is stuck in solid
 589                 self.oldorigin = self.origin;
 590                 self.prevorigin = self.origin;
 591                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 592                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 593         self.hud = HUD_NORMAL;
 594
 595                 self.event_damage = PlayerDamage;
 596
 597                 self.bot_attack = true;
 598                 self.monster_attack = true;
 599
 600                 self.spider_slowness = 0;
 601
 602                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 603
 604                 if(self.killcount == -666) {
 605                         PlayerScore_Clear(self);
 606                         self.killcount = 0;
 607                 }
 608
 609                 CL_SpawnWeaponentity(self);
 610                 self.alpha = default_player_alpha;
 611                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 612                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 613
 614                 self.speedrunning = false;
 615
 616                 //stuffcmd(self, "chase_active 0");
 617                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 618
 619                 target_voicescript_clear(self);
 620
 621                 // reset fields the weapons may use
 622                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 623                 {
 624                         Weapon w = get_weaponinfo(j);
 625                         w.wr_resetplayer(w);
 626
 627                         // all weapons must be fully loaded when we spawn
 628                         entity e = get_weaponinfo(j);
 629                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 630                                 self.(weapon_load[j]) = e.reloading_ammo;
 631                 }
 632
 633                 string s = spot.target;
 634                 spot.target = string_null;
 635                 activator = self;
 636                 WITH(entity, self, spot, SUB_UseTargets());
 637                 activator = world;
 638                 spot.target = s;
 639
 640                 Unfreeze(self);
 641
 642                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 643
 644                 if(autocvar_spawn_debug)
 645                 {
 646                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 647                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 648                 }
 649
 650                 self.switchweapon = w_getbestweapon(self);
 651                 self.cnt = -1; // W_LastWeapon will not complain
 652                 self.weapon = 0;
 653                 self.weaponname = "";
 654                 self.switchingweapon = 0;
 655
 656                 if(!warmup_stage)
 657                         if(!self.alivetime)
 658                                 self.alivetime = time;
 659
 660                 antilag_clear(self);
 661         }
 662         else if(IS_OBSERVER(self))
 663         {
 664                 PutObserverInServer ();
 665         }
 666 }
 667
 668 .float ebouncefactor, ebouncestop; // electro's values
 669 // TODO do we need all these fields, or should we stop autodetecting runtime
 670 // changes and just have a console command to update this?
 671 bool ClientInit_SendEntity(entity this, entity to, int sf)
 672 {
 673         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 674         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 675         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 676         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 679         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 680         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 681         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 682         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 683
 684         if(sv_foginterval && world.fog != "")
 685                 WriteString(MSG_ENTITY, world.fog);
 686         else
 687                 WriteString(MSG_ENTITY, "");
 688         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 689         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 690         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 691         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 692         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 693         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 694         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 695         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 696         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 697         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 698         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 699         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 700         return true;
 701 }
 702
 703 void ClientInit_CheckUpdate()
 704 {SELFPARAM();
 705         self.nextthink = time;
 706         if(self.count != autocvar_g_balance_armor_blockpercent)
 707         {
 708                 self.count = autocvar_g_balance_armor_blockpercent;
 709                 self.SendFlags |= 1;
 710         }
 711         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 712         {
 713                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 714                 self.SendFlags |= 1;
 715         }
 716         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 717         {
 718                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 719                 self.SendFlags |= 1;
 720         }
 721         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 722         {
 723                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 724                 self.SendFlags |= 1;
 725         }
 726         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 727         {
 728                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 729                 self.SendFlags |= 1;
 730         }
 731 }
 732
 733 void ClientInit_Spawn()
 734 {SELFPARAM();
 735         entity e = spawn();
 736         e.classname = "clientinit";
 737         e.think = ClientInit_CheckUpdate;
 738         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 739
 740         WITH(entity, self, e, ClientInit_CheckUpdate());
 741 }
 742
 743 /*
 744 =============
 745 SetNewParms
 746 =============
 747 */
 748 void SetNewParms (void)
 749 {
 750         // initialize parms for a new player
 751         parm1 = -(86400 * 366);
 752
 753         MUTATOR_CALLHOOK(SetNewParms);
 754 }
 755
 756 /*
 757 =============
 758 SetChangeParms
 759 =============
 760 */
 761 void SetChangeParms (void)
 762 {SELFPARAM();
 763         // save parms for level change
 764         parm1 = self.parm_idlesince - time;
 765
 766         MUTATOR_CALLHOOK(SetChangeParms);
 767 }
 768
 769 /*
 770 =============
 771 DecodeLevelParms
 772 =============
 773 */
 774 void DecodeLevelParms (void)
 775 {SELFPARAM();
 776         // load parms
 777         self.parm_idlesince = parm1;
 778         if(self.parm_idlesince == -(86400 * 366))
 779                 self.parm_idlesince = time;
 780
 781         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 782         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 783
 784         MUTATOR_CALLHOOK(DecodeLevelParms);
 785 }
 786
 787 /*
 788 =============
 789 ClientKill
 790
 791 Called when a client types 'kill' in the console
 792 =============
 793 */
 794
 795 .float clientkill_nexttime;
 796 void ClientKill_Now_TeamChange()
 797 {SELFPARAM();
 798         if(self.killindicator_teamchange == -1)
 799         {
 800                 JoinBestTeam( self, false, true );
 801         }
 802         else if(self.killindicator_teamchange == -2)
 803         {
 804                 if(blockSpectators)
 805                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 806                 PutObserverInServer();
 807         }
 808         else
 809                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 810         self.killindicator_teamchange = 0;
 811 }
 812
 813 void ClientKill_Now()
 814 {SELFPARAM();
 815         if(self.vehicle)
 816         {
 817             vehicles_exit(VHEF_RELEASE);
 818             if(!self.killindicator_teamchange)
 819             {
 820             self.vehicle_health = -1;
 821             Damage(self, self, self, 1 , DEATH_KILL.m_id, self.origin, '0 0 0');
 822             }
 823         }
 824
 825         if(self.killindicator && !wasfreed(self.killindicator))
 826                 remove(self.killindicator);
 827
 828         self.killindicator = world;
 829
 830         if(self.killindicator_teamchange)
 831                 ClientKill_Now_TeamChange();
 832
 833         if(IS_PLAYER(self))
 834                 Damage(self, self, self, 100000, DEATH_KILL.m_id, self.origin, '0 0 0');
 835
 836         // now I am sure the player IS dead
 837 }
 838 void KillIndicator_Think()
 839 {SELFPARAM();
 840         if (gameover)
 841         {
 842                 self.owner.killindicator = world;
 843                 remove(self);
 844                 return;
 845         }
 846
 847         if (self.owner.alpha < 0 && !self.owner.vehicle)
 848         {
 849                 self.owner.killindicator = world;
 850                 remove(self);
 851                 return;
 852         }
 853
 854         if(self.cnt <= 0)
 855         {
 856                 WITH(entity, self, self.owner, ClientKill_Now());
 857                 return;
 858         }
 859     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 860     {
 861         self.nextthink = time + 1;
 862         self.cnt -= 1;
 863     }
 864         else
 865         {
 866                 if(self.cnt <= 10)
 867                         setmodel(self, MDL_NUM(self.cnt));
 868                 if(IS_REAL_CLIENT(self.owner))
 869                 {
 870                         if(self.cnt <= 10)
 871                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 872                 }
 873                 self.nextthink = time + 1;
 874                 self.cnt -= 1;
 875         }
 876 }
 877
 878 float clientkilltime;
 879 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 880 {SELFPARAM();
 881         float killtime;
 882         float starttime;
 883         entity e;
 884
 885         if (gameover)
 886                 return;
 887
 888         killtime = autocvar_g_balance_kill_delay;
 889
 890         if(g_race_qualifying || g_cts)
 891                 killtime = 0;
 892
 893     if(MUTATOR_CALLHOOK(ClientKill, self, killtime))
 894         return;
 895
 896         self.killindicator_teamchange = targetteam;
 897
 898     if(!self.killindicator)
 899         {
 900                 if(self.deadflag == DEAD_NO)
 901                 {
 902                         killtime = max(killtime, self.clientkill_nexttime - time);
 903                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 904                 }
 905
 906                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 907                 {
 908                         ClientKill_Now();
 909                 }
 910                 else
 911                 {
 912                         starttime = max(time, clientkilltime);
 913
 914                         self.killindicator = spawn();
 915                         self.killindicator.owner = self;
 916                         self.killindicator.scale = 0.5;
 917                         setattachment(self.killindicator, self, "");
 918                         setorigin(self.killindicator, '0 0 52');
 919                         self.killindicator.think = KillIndicator_Think;
 920                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 921                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 922                         self.killindicator.cnt = ceil(killtime);
 923                         self.killindicator.count = bound(0, ceil(killtime), 10);
 924                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 925
 926                         for(e = world; (e = find(e, classname, "body")) != world; )
 927                         {
 928                                 if(e.enemy != self)
 929                                         continue;
 930                                 e.killindicator = spawn();
 931                                 e.killindicator.owner = e;
 932                                 e.killindicator.scale = 0.5;
 933                                 setattachment(e.killindicator, e, "");
 934                                 setorigin(e.killindicator, '0 0 52');
 935                                 e.killindicator.think = KillIndicator_Think;
 936                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 937                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 938                                 e.killindicator.cnt = ceil(killtime);
 939                         }
 940                         self.lip = 0;
 941                 }
 942         }
 943         if(self.killindicator)
 944         {
 945                 if(targetteam == 0) // just die
 946                 {
 947                         self.killindicator.colormod = '0 0 0';
 948                         if(IS_REAL_CLIENT(self))
 949                         if(self.killindicator.cnt > 0)
 950                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 951                 }
 952                 else if(targetteam == -1) // auto
 953                 {
 954                         self.killindicator.colormod = '0 1 0';
 955                         if(IS_REAL_CLIENT(self))
 956                         if(self.killindicator.cnt > 0)
 957                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 958                 }
 959                 else if(targetteam == -2) // spectate
 960                 {
 961                         self.killindicator.colormod = '0.5 0.5 0.5';
 962                         if(IS_REAL_CLIENT(self))
 963                         if(self.killindicator.cnt > 0)
 964                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 965                 }
 966                 else
 967                 {
 968                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 969                         if(IS_REAL_CLIENT(self))
 970                         if(self.killindicator.cnt > 0)
 971                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 972                 }
 973         }
 974
 975 }
 976
 977 void ClientKill (void)
 978 {SELFPARAM();
 979         if(gameover) return;
 980         if(self.player_blocked) return;
 981         if(self.frozen) return;
 982
 983         ClientKill_TeamChange(0);
 984 }
 985
 986 void FixClientCvars(entity e)
 987 {
 988         // send prediction settings to the client
 989         stuffcmd(e, "\nin_bindmap 0 0\n");
 990         if(autocvar_g_antilag == 3) // client side hitscan
 991                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 992         if(autocvar_sv_gentle)
 993                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 994 }
 995
 996 float PlayerInIDList(entity p, string idlist)
 997 {
 998         float n, i;
 999         string s;
1000
1001         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1002         if (!p.crypto_idfp)
1003                 return 0;
1004
1005         // this function allows abbreviated player IDs too!
1006         n = tokenize_console(idlist);
1007         for(i = 0; i < n; ++i)
1008         {
1009                 s = argv(i);
1010                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1011                         return 1;
1012         }
1013
1014         return 0;
1015 }
1016
1017 #ifdef DP_EXT_PRECONNECT
1018 /*
1019 =============
1020 ClientPreConnect
1021
1022 Called once (not at each match start) when a client begins a connection to the server
1023 =============
1024 */
1025 void ClientPreConnect (void)
1026 {SELFPARAM();
1027         if(autocvar_sv_eventlog)
1028         {
1029                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1030                         self.playerid,
1031                         num_for_edict(self),
1032                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1033                 ));
1034         }
1035 }
1036 #endif
1037
1038 /*
1039 =============
1040 ClientConnect
1041
1042 Called when a client connects to the server
1043 =============
1044 */
1045 void DecodeLevelParms (void);
1046 void ClientConnect (void)
1047 {SELFPARAM();
1048         float t;
1049
1050         if(IS_CLIENT(self))
1051         {
1052                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
1053                 return;
1054         }
1055
1056         if(Ban_MaybeEnforceBanOnce(self))
1057                 return;
1058
1059         DecodeLevelParms();
1060
1061 #ifdef WATERMARK
1062         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1063 #endif
1064
1065         self.classname = "player_joining";
1066
1067         self.flags = FL_CLIENT;
1068         self.version_nagtime = time + 10 + random() * 10;
1069
1070         if(player_count<0)
1071         {
1072                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1073                 player_count = 0;
1074         }
1075
1076         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1077
1078         PlayerScore_Attach(self);
1079         ClientData_Attach();
1080         accuracy_init(self);
1081         Inventory_new(self);
1082
1083         bot_clientconnect();
1084
1085         playerdemo_init();
1086
1087         anticheat_init();
1088
1089         // identify the right forced team
1090         if(autocvar_g_campaign)
1091         {
1092                 if(IS_REAL_CLIENT(self)) // only players, not bots
1093                 {
1094                         switch(autocvar_g_campaign_forceteam)
1095                         {
1096                                 case 1: self.team_forced = NUM_TEAM_1; break;
1097                                 case 2: self.team_forced = NUM_TEAM_2; break;
1098                                 case 3: self.team_forced = NUM_TEAM_3; break;
1099                                 case 4: self.team_forced = NUM_TEAM_4; break;
1100                                 default: self.team_forced = 0;
1101                         }
1102                 }
1103         }
1104         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1105                 self.team_forced = NUM_TEAM_1;
1106         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1107                 self.team_forced = NUM_TEAM_2;
1108         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1109                 self.team_forced = NUM_TEAM_3;
1110         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1111                 self.team_forced = NUM_TEAM_4;
1112         else if(autocvar_g_forced_team_otherwise == "red")
1113                 self.team_forced = NUM_TEAM_1;
1114         else if(autocvar_g_forced_team_otherwise == "blue")
1115                 self.team_forced = NUM_TEAM_2;
1116         else if(autocvar_g_forced_team_otherwise == "yellow")
1117                 self.team_forced = NUM_TEAM_3;
1118         else if(autocvar_g_forced_team_otherwise == "pink")
1119                 self.team_forced = NUM_TEAM_4;
1120         else if(autocvar_g_forced_team_otherwise == "spectate")
1121                 self.team_forced = -1;
1122         else if(autocvar_g_forced_team_otherwise == "spectator")
1123                 self.team_forced = -1;
1124         else
1125                 self.team_forced = 0;
1126
1127         if(!teamplay)
1128                 if(self.team_forced > 0)
1129                         self.team_forced = 0;
1130
1131         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1132
1133         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1134                 self.classname = "observer";
1135         } else {
1136                 if(teamplay)
1137                 {
1138                         if(autocvar_g_balance_teams)
1139                         {
1140                                 self.classname = "player";
1141                                 campaign_bots_may_start = 1;
1142                         }
1143                         else
1144                         {
1145                                 self.classname = "observer"; // do it anyway
1146                         }
1147                 }
1148                 else
1149                 {
1150                         self.classname = "player";
1151                         campaign_bots_may_start = 1;
1152                 }
1153         }
1154
1155         self.playerid = (playerid_last = playerid_last + 1);
1156
1157         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1158
1159     if(IS_BOT_CLIENT(self))
1160         PlayerStats_GameReport_AddPlayer(self);
1161
1162         if(autocvar_sv_eventlog)
1163                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1164
1165         LogTeamchange(self.playerid, self.team, 1);
1166
1167         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1168
1169         self.netname_previous = strzone(self.netname);
1170
1171         if(IS_PLAYER(self) && teamplay)
1172                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1173         else
1174                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1175
1176         stuffcmd(self, strcat(clientstuff, "\n"));
1177         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1178
1179         FixClientCvars(self);
1180
1181         // spawnfunc_waypoint sprites
1182         WaypointSprite_InitClient(self);
1183
1184         // Wazat's grappling hook
1185         SetGrappleHookBindings();
1186
1187         // Jetpack binds
1188         stuffcmd(self, "alias +jetpack +button10\n");
1189         stuffcmd(self, "alias -jetpack -button10\n");
1190
1191         // get version info from player
1192         stuffcmd(self, "cmd clientversion $gameversion\n");
1193
1194         // get other cvars from player
1195         GetCvars(0);
1196
1197         // notify about available teams
1198         if(teamplay)
1199         {
1200                 CheckAllowedTeams(self);
1201                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1202                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1203         }
1204         else
1205                 stuffcmd(self, "set _teams_available 0\n");
1206
1207         attach_entcs(self);
1208
1209         bot_relinkplayerlist();
1210
1211         self.spectatortime = time;
1212         if(blockSpectators)
1213         {
1214                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1215         }
1216
1217         self.jointime = time;
1218         self.allowed_timeouts = autocvar_sv_timeout_number;
1219
1220         if(IS_REAL_CLIENT(self))
1221         {
1222                 if(!autocvar_g_campaign)
1223                 {
1224                         self.motd_actived_time = -1;
1225                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1226                 }
1227
1228                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET(TUBA)))
1229                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1230         }
1231
1232         if(!sv_foginterval && world.fog != "")
1233                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1234
1235         W_HitPlotOpen(self);
1236
1237         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1238                 send_CSQC_teamnagger();
1239
1240         CheatInitClient();
1241
1242         CSQCMODEL_AUTOINIT(self);
1243
1244         self.model_randomizer = random();
1245
1246         if(IS_REAL_CLIENT(self))
1247                 sv_notice_join();
1248
1249         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1250                 WITH(entity, self, e, e.init_for_player(this));
1251         }
1252
1253         MUTATOR_CALLHOOK(ClientConnect, self);
1254 }
1255 /*
1256 =============
1257 ClientDisconnect
1258
1259 Called when a client disconnects from the server
1260 =============
1261 */
1262 .entity chatbubbleentity;
1263 void ReadyCount();
1264 void ClientDisconnect (void)
1265 {SELFPARAM();
1266         if(self.vehicle)
1267             vehicles_exit(VHEF_RELEASE);
1268
1269         if (!IS_CLIENT(self))
1270         {
1271                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1272                 return;
1273         }
1274
1275         PlayerStats_GameReport_FinalizePlayer(self);
1276
1277         if ( self.active_minigame )
1278                 part_minigame(self);
1279
1280         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1281
1282         CheatShutdownClient();
1283
1284         W_HitPlotClose(self);
1285
1286         anticheat_report();
1287         anticheat_shutdown();
1288
1289         playerdemo_shutdown();
1290
1291         bot_clientdisconnect();
1292
1293         detach_entcs(self);
1294
1295         if(autocvar_sv_eventlog)
1296                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1297
1298         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1299
1300         MUTATOR_CALLHOOK(ClientDisconnect);
1301
1302         Portal_ClearAll(self);
1303
1304         Unfreeze(self);
1305
1306         RemoveGrapplingHook(self);
1307
1308         // Here, everything has been done that requires this player to be a client.
1309
1310         self.flags &= ~FL_CLIENT;
1311
1312         if (self.chatbubbleentity)
1313                 remove (self.chatbubbleentity);
1314
1315         if (self.killindicator)
1316                 remove (self.killindicator);
1317
1318         WaypointSprite_PlayerGone();
1319
1320         bot_relinkplayerlist();
1321
1322         accuracy_free(self);
1323         Inventory_delete(self);
1324         ClientData_Detach();
1325         PlayerScore_Detach(self);
1326
1327         if(self.netname_previous)
1328                 strunzone(self.netname_previous);
1329         if(self.clientstatus)
1330                 strunzone(self.clientstatus);
1331         if(self.weaponorder_byimpulse)
1332                 strunzone(self.weaponorder_byimpulse);
1333
1334         ClearPlayerSounds();
1335
1336         if(self.personal)
1337                 remove(self.personal);
1338
1339         self.playerid = 0;
1340         ReadyCount();
1341
1342         // free cvars
1343         GetCvars(-1);
1344 }
1345
1346 .float BUTTON_CHAT;
1347 void ChatBubbleThink()
1348 {SELFPARAM();
1349         self.nextthink = time;
1350         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1351         {
1352                 if(self.owner) // but why can that ever be world?
1353                         self.owner.chatbubbleentity = world;
1354                 remove(self);
1355                 return;
1356         }
1357
1358         self.mdl = "";
1359
1360         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1361         {
1362                 if ( self.owner.active_minigame )
1363                         self.mdl = "models/sprites/minigame_busy.iqm";
1364                 else if ( self.owner.BUTTON_CHAT )
1365                         self.mdl = "models/misc/chatbubble.spr";
1366         }
1367
1368         if ( self.model != self.mdl )
1369                 _setmodel(self, self.mdl);
1370
1371 }
1372
1373 void UpdateChatBubble()
1374 {SELFPARAM();
1375         if (self.alpha < 0)
1376                 return;
1377         // spawn a chatbubble entity if needed
1378         if (!self.chatbubbleentity)
1379         {
1380                 self.chatbubbleentity = spawn();
1381                 self.chatbubbleentity.owner = self;
1382                 self.chatbubbleentity.exteriormodeltoclient = self;
1383                 self.chatbubbleentity.think = ChatBubbleThink;
1384                 self.chatbubbleentity.nextthink = time;
1385                 setmodel(self.chatbubbleentity, MDL_CHAT); // precision set below
1386                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1387                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1388                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1389                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1390                 //self.chatbubbleentity.model = "";
1391                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1392         }
1393 }
1394
1395
1396 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1397 // added to the model skins
1398 /*void UpdateColorModHack()
1399 {
1400         float c;
1401         c = self.clientcolors & 15;
1402         // LordHavoc: only bothering to support white, green, red, yellow, blue
1403              if (!teamplay) self.colormod = '0 0 0';
1404         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1405         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1406         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1407         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1408         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1409         else self.colormod = '1 1 1';
1410 }*/
1411
1412 void respawn(void)
1413 {SELFPARAM();
1414         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1415         {
1416                 self.solid = SOLID_NOT;
1417                 self.takedamage = DAMAGE_NO;
1418                 self.movetype = MOVETYPE_FLY;
1419                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1420                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1421                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1422                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1423                 if(autocvar_g_respawn_ghosts_maxtime)
1424                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1425         }
1426
1427         CopyBody(1);
1428
1429         self.effects |= EF_NODRAW; // prevent another CopyBody
1430         PutClientInServer();
1431 }
1432
1433 void play_countdown(float finished, string samp)
1434 {SELFPARAM();
1435         if(IS_REAL_CLIENT(self))
1436                 if(floor(finished - time - frametime) != floor(finished - time))
1437                         if(finished - time < 6)
1438                                 _sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1439 }
1440
1441 void player_powerups (void)
1442 {SELFPARAM();
1443         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1444         int items_prev = self.items;
1445
1446         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1447                 self.modelflags |= MF_ROCKET;
1448         else
1449                 self.modelflags &= ~MF_ROCKET;
1450
1451         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1452
1453         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1454                 return;
1455
1456         Fire_ApplyDamage(self);
1457         Fire_ApplyEffect(self);
1458
1459         if (!g_instagib)
1460         {
1461                 if (self.items & ITEM_Strength.m_itemid)
1462                 {
1463                         play_countdown(self.strength_finished, SND(POWEROFF));
1464                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1465                         if (time > self.strength_finished)
1466                         {
1467                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1468                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1469                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1470                         }
1471                 }
1472                 else
1473                 {
1474                         if (time < self.strength_finished)
1475                         {
1476                                 self.items = self.items | ITEM_Strength.m_itemid;
1477                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1478                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1479                         }
1480                 }
1481                 if (self.items & ITEM_Shield.m_itemid)
1482                 {
1483                         play_countdown(self.invincible_finished, SND(POWEROFF));
1484                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1485                         if (time > self.invincible_finished)
1486                         {
1487                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1488                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1489                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1490                         }
1491                 }
1492                 else
1493                 {
1494                         if (time < self.invincible_finished)
1495                         {
1496                                 self.items = self.items | ITEM_Shield.m_itemid;
1497                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1498                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1499                         }
1500                 }
1501                 if (self.items & IT_SUPERWEAPON)
1502                 {
1503                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1504                         {
1505                                 self.superweapons_finished = 0;
1506                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1507                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1508                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1509                         }
1510                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1511                         {
1512                                 // don't let them run out
1513                         }
1514                         else
1515                         {
1516                                 play_countdown(self.superweapons_finished, SND(POWEROFF));
1517                                 if (time > self.superweapons_finished)
1518                                 {
1519                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1520                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1521                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1522                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1523                                 }
1524                         }
1525                 }
1526                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1527                 {
1528                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1529                         {
1530                                 self.items = self.items | IT_SUPERWEAPON;
1531                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1532                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1533                         }
1534                         else
1535                         {
1536                                 self.superweapons_finished = 0;
1537                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1538                         }
1539                 }
1540                 else
1541                 {
1542                         self.superweapons_finished = 0;
1543                 }
1544         }
1545
1546         if(autocvar_g_nodepthtestplayers)
1547                 self.effects = self.effects | EF_NODEPTHTEST;
1548
1549         if(autocvar_g_fullbrightplayers)
1550                 self.effects = self.effects | EF_FULLBRIGHT;
1551
1552         if (time >= game_starttime)
1553         if (time < self.spawnshieldtime)
1554                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1555
1556         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1557 }
1558
1559 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1560 {
1561         if(current > stable)
1562                 return current;
1563         else if(current > stable - 0.25) // when close enough, "snap"
1564                 return stable;
1565         else
1566                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1567 }
1568
1569 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1570 {
1571         if(current < stable)
1572                 return current;
1573         else if(current < stable + 0.25) // when close enough, "snap"
1574                 return stable;
1575         else
1576                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1577 }
1578
1579 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1580 {
1581         if(current > rotstable)
1582         {
1583                 if(rotframetime > 0)
1584                 {
1585                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1586                         current = max(rotstable, current - rotlinear * rotframetime);
1587                 }
1588         }
1589         else if(current < regenstable)
1590         {
1591                 if(regenframetime > 0)
1592                 {
1593                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1594                         current = min(regenstable, current + regenlinear * regenframetime);
1595                 }
1596         }
1597
1598         if(current > limit)
1599                 current = limit;
1600
1601         return current;
1602 }
1603
1604 void player_regen (void)
1605 {SELFPARAM();
1606         float max_mod, regen_mod, rot_mod, limit_mod;
1607         max_mod = regen_mod = rot_mod = limit_mod = 1;
1608         regen_mod_max = max_mod;
1609         regen_mod_regen = regen_mod;
1610         regen_mod_rot = rot_mod;
1611         regen_mod_limit = limit_mod;
1612
1613         regen_health = autocvar_g_balance_health_regen;
1614         regen_health_linear = autocvar_g_balance_health_regenlinear;
1615         regen_health_rot = autocvar_g_balance_health_rot;
1616         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1617         regen_health_stable = autocvar_g_balance_health_regenstable;
1618         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1619         if(!MUTATOR_CALLHOOK(PlayerRegen))
1620         if(!self.frozen)
1621         {
1622                 float mina, maxa, limith, limita;
1623                 maxa = autocvar_g_balance_armor_rotstable;
1624                 mina = autocvar_g_balance_armor_regenstable;
1625                 limith = autocvar_g_balance_health_limit;
1626                 limita = autocvar_g_balance_armor_limit;
1627
1628                 max_mod = regen_mod_max;
1629                 regen_mod = regen_mod_regen;
1630                 rot_mod = regen_mod_rot;
1631                 limit_mod = regen_mod_limit;
1632
1633                 regen_health_rotstable = regen_health_rotstable * max_mod;
1634                 regen_health_stable = regen_health_stable * max_mod;
1635                 limith = limith * limit_mod;
1636                 limita = limita * limit_mod;
1637
1638                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1639                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1640         }
1641
1642         // if player rotted to death...  die!
1643         // check this outside above checks, as player may still be able to rot to death
1644         if(self.health < 1)
1645         {
1646                 if(self.vehicle)
1647                         vehicles_exit(VHEF_RELEASE);
1648                 self.event_damage(self, self, 1, DEATH_ROT.m_id, self.origin, '0 0 0');
1649         }
1650
1651         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1652         {
1653                 float minf, maxf, limitf;
1654
1655                 maxf = autocvar_g_balance_fuel_rotstable;
1656                 minf = autocvar_g_balance_fuel_regenstable;
1657                 limitf = autocvar_g_balance_fuel_limit;
1658
1659                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1660         }
1661 }
1662
1663 float zoomstate_set;
1664 void SetZoomState(float z)
1665 {SELFPARAM();
1666         if(z != self.zoomstate)
1667         {
1668                 self.zoomstate = z;
1669                 ClientData_Touch(self);
1670         }
1671         zoomstate_set = 1;
1672 }
1673
1674 void GetPressedKeys()
1675 {SELFPARAM();
1676         MUTATOR_CALLHOOK(GetPressedKeys);
1677         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1678         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1679         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1680         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1681         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1682
1683         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1684         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1685         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1686         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1687         #undef X
1688 }
1689
1690 /*
1691 ======================
1692 spectate mode routines
1693 ======================
1694 */
1695
1696 void SpectateCopy(entity spectatee)
1697 {SELFPARAM();
1698         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1699         self.armortype = spectatee.armortype;
1700         self.armorvalue = spectatee.armorvalue;
1701         self.ammo_cells = spectatee.ammo_cells;
1702         self.ammo_plasma = spectatee.ammo_plasma;
1703         self.ammo_shells = spectatee.ammo_shells;
1704         self.ammo_nails = spectatee.ammo_nails;
1705         self.ammo_rockets = spectatee.ammo_rockets;
1706         self.ammo_fuel = spectatee.ammo_fuel;
1707         self.clip_load = spectatee.clip_load;
1708         self.clip_size = spectatee.clip_size;
1709         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1710         self.health = spectatee.health;
1711         self.impulse = 0;
1712         self.items = spectatee.items;
1713         self.last_pickup = spectatee.last_pickup;
1714         self.hit_time = spectatee.hit_time;
1715         self.metertime = spectatee.metertime;
1716         self.strength_finished = spectatee.strength_finished;
1717         self.invincible_finished = spectatee.invincible_finished;
1718         self.pressedkeys = spectatee.pressedkeys;
1719         self.weapons = spectatee.weapons;
1720         self.switchweapon = spectatee.switchweapon;
1721         self.switchingweapon = spectatee.switchingweapon;
1722         self.weapon = spectatee.weapon;
1723         self.vortex_charge = spectatee.vortex_charge;
1724         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1725         self.hagar_load = spectatee.hagar_load;
1726         self.arc_heat_percent = spectatee.arc_heat_percent;
1727         self.minelayer_mines = spectatee.minelayer_mines;
1728         self.punchangle = spectatee.punchangle;
1729         self.view_ofs = spectatee.view_ofs;
1730         self.velocity = spectatee.velocity;
1731         self.dmg_take = spectatee.dmg_take;
1732         self.dmg_save = spectatee.dmg_save;
1733         self.dmg_inflictor = spectatee.dmg_inflictor;
1734         self.v_angle = spectatee.v_angle;
1735         self.angles = spectatee.v_angle;
1736         self.frozen = spectatee.frozen;
1737         self.revive_progress = spectatee.revive_progress;
1738         if(!self.BUTTON_USE)
1739                 self.fixangle = true;
1740         setorigin(self, spectatee.origin);
1741         setsize(self, spectatee.mins, spectatee.maxs);
1742         SetZoomState(spectatee.zoomstate);
1743
1744     anticheat_spectatecopy(spectatee);
1745         self.hud = spectatee.hud;
1746         if(spectatee.vehicle)
1747     {
1748         self.fixangle = false;
1749         //self.velocity = spectatee.vehicle.velocity;
1750         self.vehicle_health = spectatee.vehicle_health;
1751         self.vehicle_shield = spectatee.vehicle_shield;
1752         self.vehicle_energy = spectatee.vehicle_energy;
1753         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1754         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1755         self.vehicle_reload1 = spectatee.vehicle_reload1;
1756         self.vehicle_reload2 = spectatee.vehicle_reload2;
1757
1758         msg_entity = self;
1759
1760         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1761             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1762             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1763             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1764
1765         //WriteByte (MSG_ONE, SVC_SETVIEW);
1766         //    WriteEntity(MSG_ONE, self);
1767         //makevectors(spectatee.v_angle);
1768         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1769     }
1770 }
1771
1772 bool SpectateUpdate()
1773 {SELFPARAM();
1774         if(!self.enemy)
1775             return false;
1776
1777         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1778         {
1779                 SetSpectator(self, world);
1780                 return false;
1781         }
1782
1783         SpectateCopy(self.enemy);
1784
1785         return true;
1786 }
1787
1788 bool SpectateSet()
1789 {SELFPARAM();
1790         if(!IS_PLAYER(self.enemy))
1791                 return false;
1792
1793         msg_entity = self;
1794         WriteByte(MSG_ONE, SVC_SETVIEW);
1795         WriteEntity(MSG_ONE, self.enemy);
1796         self.movetype = MOVETYPE_NONE;
1797         accuracy_resend(self);
1798
1799         if(!SpectateUpdate())
1800                 PutObserverInServer();
1801
1802         return true;
1803 }
1804
1805 void SetSpectator(entity player, entity spectatee)
1806 {
1807         entity old_spectatee = player.enemy;
1808
1809         player.enemy = spectatee;
1810
1811         // WEAPONTODO
1812         // these are required to fix the spectator bug with arc
1813         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1814         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1815 }
1816
1817 bool Spectate(entity pl)
1818 {SELFPARAM();
1819         if(MUTATOR_CALLHOOK(SpectateSet, self, pl))
1820                 return false;
1821         pl = spec_player;
1822
1823         SetSpectator(self, pl);
1824         return SpectateSet();
1825 }
1826
1827 bool SpectateNext()
1828 {SELFPARAM();
1829         other = find(self.enemy, classname, "player");
1830
1831         bool mutator_returnvalue = MUTATOR_CALLHOOK(SpectateNext, self, other);
1832         other = spec_player;
1833
1834         if(!mutator_returnvalue && !other)
1835                 other = find(other, classname, "player");
1836
1837         if(other) { SetSpectator(self, other); }
1838
1839         return SpectateSet();
1840 }
1841
1842 bool SpectatePrev()
1843 {SELFPARAM();
1844         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1845         other = findchain(classname, "player");
1846         if (!other) // no player
1847                 return false;
1848
1849         entity first = other;
1850         // skip players until current spectated player
1851         if(self.enemy)
1852         while(other && other != self.enemy)
1853                 other = other.chain;
1854
1855         int mutator_returnvalue = MUTATOR_CALLHOOK(SpectatePrev, self, other, first);
1856         other = spec_player;
1857
1858         switch(mutator_returnvalue)
1859         {
1860                 case MUT_SPECPREV_FOUND: break;
1861                 case MUT_SPECPREV_RETURN: return true;
1862                 case MUT_SPECPREV_CONTINUE:
1863                 default:
1864                 {
1865                         if(other.chain)
1866                                 other = other.chain;
1867                         else
1868                                 other = first;
1869                         break;
1870                 }
1871         }
1872
1873         SetSpectator(self, other);
1874         return SpectateSet();
1875 }
1876
1877 /*
1878 =============
1879 ShowRespawnCountdown()
1880
1881 Update a respawn countdown display.
1882 =============
1883 */
1884 void ShowRespawnCountdown()
1885 {SELFPARAM();
1886         float number;
1887         if(self.deadflag == DEAD_NO) // just respawned?
1888                 return;
1889         else
1890         {
1891                 number = ceil(self.respawn_time - time);
1892                 if(number <= 0)
1893                         return;
1894                 if(number <= self.respawn_countdown)
1895                 {
1896                         self.respawn_countdown = number - 1;
1897                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1898                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1899                 }
1900         }
1901 }
1902
1903 void LeaveSpectatorMode()
1904 {SELFPARAM();
1905         if(self.caplayer)
1906                 return;
1907         if(nJoinAllowed(self))
1908         {
1909                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1910                 {
1911                         self.classname = "player";
1912                         nades_RemoveBonus(self);
1913
1914                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1915                                 { JoinBestTeam(self, false, true); }
1916
1917                         if(autocvar_g_campaign)
1918                                 { campaign_bots_may_start = 1; }
1919
1920                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1921
1922                         PutClientInServer();
1923
1924                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1925                 }
1926                 else
1927                         stuffcmd(self, "menu_showteamselect\n");
1928         }
1929         else
1930         {
1931                 // Player may not join because g_maxplayers is set
1932                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1933         }
1934 }
1935
1936 /**
1937  * Determines whether the player is allowed to join. This depends on cvar
1938  * g_maxplayers, if it isn't used this function always return true, otherwise
1939  * it checks whether the number of currently playing players exceeds g_maxplayers.
1940  * @return int number of free slots for players, 0 if none
1941  */
1942 float nJoinAllowed(entity ignore)
1943 {SELFPARAM();
1944         if(!ignore)
1945         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1946         // so report 0 free slots if restricted
1947         {
1948                 if(autocvar_g_forced_team_otherwise == "spectate")
1949                         return 0;
1950                 if(autocvar_g_forced_team_otherwise == "spectator")
1951                         return 0;
1952         }
1953
1954         if(self.team_forced < 0)
1955                 return 0; // forced spectators can never join
1956
1957         // TODO simplify this
1958         entity e;
1959         float totalClients = 0;
1960         FOR_EACH_CLIENT(e)
1961                 if(e != ignore)
1962                         totalClients += 1;
1963
1964         if (!autocvar_g_maxplayers)
1965                 return maxclients - totalClients;
1966
1967         float currentlyPlaying = 0;
1968         FOR_EACH_REALCLIENT(e)
1969                 if(IS_PLAYER(e) || e.caplayer)
1970                         currentlyPlaying += 1;
1971
1972         if(currentlyPlaying < autocvar_g_maxplayers)
1973                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1974
1975         return 0;
1976 }
1977
1978 /**
1979  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1980  * g_maxplayers_spectator_blocktime seconds
1981  */
1982 void checkSpectatorBlock()
1983 {SELFPARAM();
1984         if(IS_SPEC(self) || IS_OBSERVER(self))
1985         if(!self.caplayer)
1986         if(IS_REAL_CLIENT(self))
1987         {
1988                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1989                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1990                         dropclient(self);
1991                 }
1992         }
1993 }
1994
1995 void PrintWelcomeMessage()
1996 {SELFPARAM();
1997         if(self.motd_actived_time == 0)
1998         {
1999                 if (autocvar_g_campaign) {
2000                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2001                                 self.motd_actived_time = time;
2002                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2003                         }
2004                 } else {
2005                         if (self.BUTTON_INFO) {
2006                                 self.motd_actived_time = time;
2007                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2008                         }
2009                 }
2010         }
2011         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2012         {
2013                 if (autocvar_g_campaign) {
2014                         if (self.BUTTON_INFO)
2015                                 self.motd_actived_time = time;
2016                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2017                                 self.motd_actived_time = 0;
2018                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2019                         }
2020                 } else {
2021                         if (self.BUTTON_INFO)
2022                                 self.motd_actived_time = time;
2023                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2024                                 self.motd_actived_time = 0;
2025                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2026                         }
2027                 }
2028         }
2029         else //if(self.motd_actived_time < 0) // just connected, motd is active
2030         {
2031                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2032                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2033                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2034                 {
2035                         // instanctly hide MOTD
2036                         self.motd_actived_time = 0;
2037                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2038                 }
2039         }
2040 }
2041
2042 void ObserverThink()
2043 {SELFPARAM();
2044         if ( self.impulse )
2045         {
2046                 MinigameImpulse(self.impulse);
2047                 self.impulse = 0;
2048         }
2049         float prefered_movetype;
2050         if (self.flags & FL_JUMPRELEASED) {
2051                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2052                         self.flags &= ~FL_JUMPRELEASED;
2053                         self.flags |= FL_SPAWNING;
2054                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2055                         self.flags &= ~FL_JUMPRELEASED;
2056                         if(SpectateNext()) {
2057                                 self.classname = "spectator";
2058                         }
2059                 } else {
2060                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2061                         if (self.movetype != prefered_movetype)
2062                                 self.movetype = prefered_movetype;
2063                 }
2064         } else {
2065                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2066                         self.flags |= FL_JUMPRELEASED;
2067                         if(self.flags & FL_SPAWNING)
2068                         {
2069                                 self.flags &= ~FL_SPAWNING;
2070                                 LeaveSpectatorMode();
2071                                 return;
2072                         }
2073                 }
2074         }
2075 }
2076
2077 void SpectatorThink()
2078 {SELFPARAM();
2079         if ( self.impulse )
2080         {
2081                 if(MinigameImpulse(self.impulse))
2082                         self.impulse = 0;
2083         }
2084         if (self.flags & FL_JUMPRELEASED) {
2085                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2086                         self.flags &= ~FL_JUMPRELEASED;
2087                         self.flags |= FL_SPAWNING;
2088                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2089                         self.flags &= ~FL_JUMPRELEASED;
2090                         if(SpectateNext()) {
2091                                 self.classname = "spectator";
2092                         } else {
2093                                 self.classname = "observer";
2094                                 PutClientInServer();
2095                         }
2096                         self.impulse = 0;
2097                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2098                         self.flags &= ~FL_JUMPRELEASED;
2099                         if(SpectatePrev()) {
2100                                 self.classname = "spectator";
2101                         } else {
2102                                 self.classname = "observer";
2103                                 PutClientInServer();
2104                         }
2105                         self.impulse = 0;
2106                 } else if (self.BUTTON_ATCK2) {
2107                         self.flags &= ~FL_JUMPRELEASED;
2108                         self.classname = "observer";
2109                         PutClientInServer();
2110                 } else {
2111                         if(!SpectateUpdate())
2112                                 PutObserverInServer();
2113                 }
2114         } else {
2115                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2116                         self.flags |= FL_JUMPRELEASED;
2117                         if(self.flags & FL_SPAWNING)
2118                         {
2119                                 self.flags &= ~FL_SPAWNING;
2120                                 LeaveSpectatorMode();
2121                                 return;
2122                         }
2123                 }
2124                 if(!SpectateUpdate())
2125                         PutObserverInServer();
2126         }
2127
2128         self.flags |= FL_CLIENT | FL_NOTARGET;
2129 }
2130
2131 void vehicles_enter (entity pl, entity veh);
2132 void PlayerUseKey()
2133 {SELFPARAM();
2134         if (!IS_PLAYER(self))
2135                 return;
2136
2137         if(self.vehicle)
2138         {
2139                 if(!gameover)
2140                 {
2141                         vehicles_exit(VHEF_NORMAL);
2142                         return;
2143                 }
2144         }
2145         else if(autocvar_g_vehicles_enter)
2146         {
2147                 if(!self.frozen)
2148                 if(self.deadflag == DEAD_NO)
2149                 if(!gameover)
2150                 {
2151                         entity head, closest_target = world;
2152                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2153
2154                         while(head) // find the closest acceptable target to enter
2155                         {
2156                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2157                                 if(head.deadflag == DEAD_NO)
2158                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2159                                 if(head.takedamage != DAMAGE_NO)
2160                                 {
2161                                         if(closest_target)
2162                                         {
2163                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2164                                                 { closest_target = head; }
2165                                         }
2166                                         else { closest_target = head; }
2167                                 }
2168
2169                                 head = head.chain;
2170                         }
2171
2172                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2173                 }
2174         }
2175
2176         // a use key was pressed; call handlers
2177         MUTATOR_CALLHOOK(PlayerUseKey);
2178 }
2179
2180 float isInvisibleString(string s)
2181 {
2182         float i, n, c;
2183         s = strdecolorize(s);
2184         for((i = 0), (n = strlen(s)); i < n; ++i)
2185         {
2186                 c = str2chr(s, i);
2187                 switch(c)
2188                 {
2189                         case 0:
2190                         case 32: // space
2191                                 break;
2192                         case 192: // charmap space
2193                                 if (!autocvar_utf8_enable)
2194                                         break;
2195                                 return false;
2196                         case 160: // space in unicode fonts
2197                         case 0xE000 + 192: // utf8 charmap space
2198                                 if (autocvar_utf8_enable)
2199                                         break;
2200                         default:
2201                                 return false;
2202                 }
2203         }
2204         return true;
2205 }
2206
2207 /*
2208 =============
2209 PlayerPreThink
2210
2211 Called every frame for each client before the physics are run
2212 =============
2213 */
2214 .float usekeypressed;
2215 void() nexball_setstatus;
2216 .float last_vehiclecheck;
2217 .int items_added;
2218 void PlayerPreThink (void)
2219 {SELFPARAM();
2220         WarpZone_PlayerPhysics_FixVAngle();
2221
2222         self.stat_game_starttime = game_starttime;
2223         self.stat_round_starttime = round_starttime;
2224         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2225         self.stat_leadlimit = autocvar_leadlimit;
2226
2227         self.weaponsinmap = weaponsInMap;
2228
2229         if(frametime)
2230         {
2231                 // physics frames: update anticheat stuff
2232                 anticheat_prethink();
2233         }
2234
2235         if(blockSpectators && frametime)
2236                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2237                 checkSpectatorBlock();
2238
2239         zoomstate_set = 0;
2240
2241         // Savage: Check for nameless players
2242         if (isInvisibleString(self.netname)) {
2243                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2244                 if(autocvar_sv_eventlog)
2245                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2246                 if(self.netname_previous)
2247                         strunzone(self.netname_previous);
2248                 self.netname_previous = strzone(new_name);
2249                 self.netname = self.netname_previous;
2250                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2251         } else if(self.netname_previous != self.netname) {
2252                 if(autocvar_sv_eventlog)
2253                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2254                 if(self.netname_previous)
2255                         strunzone(self.netname_previous);
2256                 self.netname_previous = strzone(self.netname);
2257         }
2258
2259         // version nagging
2260         if(self.version_nagtime)
2261                 if(self.cvar_g_xonoticversion)
2262                         if(time > self.version_nagtime)
2263                         {
2264                                 // don't notify git users
2265                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2266                                 {
2267                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2268                                         {
2269                                                 // notify release users if connecting to git
2270                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2271                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2272                                         }
2273                                         else
2274                                         {
2275                                                 float r;
2276                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2277                                                 if(r < 0)
2278                                                 {
2279                                                         // give users new version
2280                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2281                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2282                                                 }
2283                                                 else if(r > 0)
2284                                                 {
2285                                                         // notify users about old server version
2286                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2287                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2288                                                 }
2289                                         }
2290                                 }
2291                                 self.version_nagtime = 0;
2292                         }
2293
2294         // GOD MODE info
2295         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2296         {
2297                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2298                 self.max_armorvalue = 0;
2299         }
2300
2301         if(self.frozen == 2)
2302         {
2303                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2304                 self.health = max(1, self.revive_progress * start_health);
2305                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2306
2307                 if(self.revive_progress >= 1)
2308                         Unfreeze(self);
2309         }
2310         else if(self.frozen == 3)
2311         {
2312                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2313                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2314
2315                 if(self.health < 1)
2316                 {
2317                         if(self.vehicle)
2318                                 vehicles_exit(VHEF_RELEASE);
2319                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, self.origin, '0 0 0');
2320                 }
2321                 else if ( self.revive_progress <= 0 )
2322                         Unfreeze(self);
2323         }
2324
2325         MUTATOR_CALLHOOK(PlayerPreThink);
2326
2327         if(autocvar_g_vehicles_enter)
2328         if(time > self.last_vehiclecheck)
2329         if(IS_PLAYER(self))
2330         if(!gameover)
2331         if(!self.frozen)
2332         if(!self.vehicle)
2333         if(self.deadflag == DEAD_NO)
2334         {
2335                 entity veh;
2336                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2337                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2338                 if(veh.deadflag == DEAD_NO)
2339                 if(veh.takedamage != DAMAGE_NO)
2340                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2341                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2342                 else if(!veh.owner)
2343                 if(!veh.team || SAME_TEAM(self, veh))
2344                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2345                 else if(autocvar_g_vehicles_steal)
2346                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2347
2348                 self.last_vehiclecheck = time + 1;
2349         }
2350
2351         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2352         {
2353                 if(self.BUTTON_USE && !self.usekeypressed)
2354                         PlayerUseKey();
2355                 self.usekeypressed = self.BUTTON_USE;
2356         }
2357
2358         if(IS_REAL_CLIENT(self))
2359                 PrintWelcomeMessage();
2360
2361         if(IS_PLAYER(self))
2362         {
2363
2364                 CheckRules_Player();
2365
2366                 if (intermission_running)
2367                 {
2368                         IntermissionThink ();   // otherwise a button could be missed between
2369                         return;                                 // the think tics
2370                 }
2371
2372                 //don't allow the player to turn around while game is paused!
2373                 if(timeout_status == TIMEOUT_ACTIVE) {
2374                         // FIXME turn this into CSQC stuff
2375                         self.v_angle = self.lastV_angle;
2376                         self.angles = self.lastV_angle;
2377                         self.fixangle = true;
2378                 }
2379
2380                 if(frametime)
2381                 {
2382                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2383                         {
2384                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2385                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2386                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2387
2388                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2389                                 {
2390                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2391                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2392                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2393                                 }
2394                         }
2395                         else
2396                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2397
2398                         player_powerups();
2399                 }
2400
2401                 if (self.deadflag != DEAD_NO)
2402                 {
2403                         if(self.personal && g_race_qualifying)
2404                         {
2405                                 if(time > self.respawn_time)
2406                                 {
2407                                         self.respawn_time = time + 1; // only retry once a second
2408                                         self.stat_respawn_time = self.respawn_time;
2409                                         respawn();
2410                                         self.impulse = 141;
2411                                 }
2412                         }
2413                         else
2414                         {
2415                                 float button_pressed;
2416                                 if(frametime)
2417                                         player_anim();
2418                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2419
2420                                 if (self.deadflag == DEAD_DYING)
2421                                 {
2422                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2423                                                 self.deadflag = DEAD_RESPAWNING;
2424                                         else if(!button_pressed)
2425                                                 self.deadflag = DEAD_DEAD;
2426                                 }
2427                                 else if (self.deadflag == DEAD_DEAD)
2428                                 {
2429                                         if(button_pressed)
2430                                                 self.deadflag = DEAD_RESPAWNABLE;
2431                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2432                                                 self.deadflag = DEAD_RESPAWNING;
2433                                 }
2434                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2435                                 {
2436                                         if(!button_pressed)
2437                                                 self.deadflag = DEAD_RESPAWNING;
2438                                 }
2439                                 else if (self.deadflag == DEAD_RESPAWNING)
2440                                 {
2441                                         if(time > self.respawn_time)
2442                                         {
2443                                                 self.respawn_time = time + 1; // only retry once a second
2444                                                 self.respawn_time_max = self.respawn_time;
2445                                                 respawn();
2446                                         }
2447                                 }
2448
2449                                 ShowRespawnCountdown();
2450
2451                                 if(self.respawn_flags & RESPAWN_SILENT)
2452                                         self.stat_respawn_time = 0;
2453                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2454                                         self.stat_respawn_time = self.respawn_time_max;
2455                                 else
2456                                         self.stat_respawn_time = self.respawn_time;
2457                         }
2458
2459                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2460                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2461                                 self.stat_respawn_time *= -1;
2462
2463                         return;
2464                 }
2465
2466                 self.prevorigin = self.origin;
2467
2468                 float do_crouch = self.BUTTON_CROUCH;
2469                 if(self.hook.state)
2470                         do_crouch = 0;
2471                 if(self.vehicle)
2472                         do_crouch = 0;
2473                 if(self.frozen)
2474                         do_crouch = 0;
2475
2476                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2477                 // It cannot be predicted by the engine!
2478                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2479                         do_crouch = 0;
2480
2481                 if (do_crouch)
2482                 {
2483                         if (!self.crouch)
2484                         {
2485                                 self.crouch = true;
2486                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2487                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2488                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2489                         }
2490                 }
2491                 else
2492                 {
2493                         if (self.crouch)
2494                         {
2495                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2496                                 if (!trace_startsolid)
2497                                 {
2498                                         self.crouch = false;
2499                                         self.view_ofs = self.stat_pl_view_ofs;
2500                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2501                                 }
2502                         }
2503                 }
2504
2505                 FixPlayermodel();
2506
2507                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2508                 //if(frametime)
2509                 {
2510                         self.items &= ~self.items_added;
2511
2512                         W_WeaponFrame(self);
2513
2514                         self.items_added = 0;
2515                         if(self.items & ITEM_Jetpack.m_itemid)
2516                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2517                                         self.items_added |= IT_FUEL;
2518
2519                         self.items |= self.items_added;
2520                 }
2521
2522                 player_regen();
2523
2524                 // WEAPONTODO: Add a weapon request for this
2525                 // rot vortex charge to the charge limit
2526                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2527                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2528
2529                 if(frametime)
2530                         player_anim();
2531
2532                 // secret status
2533                 secrets_setstatus();
2534
2535                 // monsters status
2536                 monsters_setstatus();
2537
2538                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2539
2540                 //self.angles_y=self.v_angle_y + 90;   // temp
2541         } else if(gameover) {
2542                 if (intermission_running)
2543                         IntermissionThink ();   // otherwise a button could be missed between
2544                 return;
2545         } else if(IS_OBSERVER(self)) {
2546                 ObserverThink();
2547         } else if(IS_SPEC(self)) {
2548                 SpectatorThink();
2549         }
2550
2551         // WEAPONTODO: Add weapon request for this
2552         if(!zoomstate_set)
2553                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2554
2555         float oldspectatee_status;
2556         oldspectatee_status = self.spectatee_status;
2557         if(IS_SPEC(self))
2558                 self.spectatee_status = num_for_edict(self.enemy);
2559         else if(IS_OBSERVER(self))
2560                 self.spectatee_status = num_for_edict(self);
2561         else
2562                 self.spectatee_status = 0;
2563         if(self.spectatee_status != oldspectatee_status)
2564         {
2565                 ClientData_Touch(self);
2566         }
2567
2568         if(self.teamkill_soundtime)
2569         if(time > self.teamkill_soundtime)
2570         {
2571                 self.teamkill_soundtime = 0;
2572
2573                 setself(self.teamkill_soundsource);
2574                 entity oldpusher = self.pusher;
2575                 self.pusher = this;
2576
2577                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2578
2579                 self.pusher = oldpusher;
2580                 setself(this);
2581         }
2582
2583         if(self.taunt_soundtime)
2584         if(time > self.taunt_soundtime)
2585         {
2586                 self.taunt_soundtime = 0;
2587                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2588         }
2589
2590         target_voicescript_next(self);
2591
2592         // WEAPONTODO: Move into weaponsystem somehow
2593         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2594         if(!self.weapon)
2595                 self.clip_load = self.clip_size = 0;
2596 }
2597
2598 /*
2599 =============
2600 PlayerPostThink
2601
2602 Called every frame for each client after the physics are run
2603 =============
2604 */
2605 .float idlekick_lasttimeleft;
2606 void PlayerPostThink (void)
2607 {SELFPARAM();
2608         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2609         if(IS_REAL_CLIENT(self))
2610         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2611         {
2612                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2613                 {
2614                         if(self.idlekick_lasttimeleft)
2615                         {
2616                                 self.idlekick_lasttimeleft = 0;
2617                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2618                         }
2619                 }
2620                 else
2621                 {
2622                         float timeleft;
2623                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2624                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2625                         {
2626                                 if(!self.idlekick_lasttimeleft)
2627                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2628                         }
2629                         if(timeleft <= 0)
2630                         {
2631                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2632                                 dropclient(self);
2633                                 return;
2634                         }
2635                         else if(timeleft <= 10)
2636                         {
2637                                 if(timeleft != self.idlekick_lasttimeleft)
2638                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2639                                 self.idlekick_lasttimeleft = timeleft;
2640                         }
2641                 }
2642         }
2643
2644         CheatFrame();
2645
2646         //CheckPlayerJump();
2647
2648         if(IS_PLAYER(self)) {
2649                 CheckRules_Player();
2650                 UpdateChatBubble();
2651                 if (self.impulse)
2652                         ImpulseCommands();
2653                 if (intermission_running)
2654                         return;         // intermission or finale
2655                 GetPressedKeys();
2656         }
2657
2658         /*
2659         float i;
2660         for(i = 0; i < 1000; ++i)
2661         {
2662                 vector end;
2663                 end = self.origin + '0 0 1024' + 512 * randomvec();
2664                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2665                 if(trace_fraction < 1)
2666                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2667                 {
2668                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2669                         break;
2670                 }
2671         }
2672         */
2673
2674         if(self.waypointsprite_attachedforcarrier)
2675                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id));
2676
2677         playerdemo_write();
2678
2679         CSQCMODEL_AUTOUPDATE(self);
2680 }