qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76
  77 /*
  78 =============
  79 CheckPlayerModel
  80
  81 Checks if the argument string can be a valid playermodel.
  82 Returns a valid one in doubt.
  83 =============
  84 */
  85 string FallbackPlayerModel;
  86 string CheckPlayerModel(string plyermodel) {
  87         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  88         {
  89                 // note: we cannot summon Don Strunzone here, some player may
  90                 // still have the model string set. In case anyone manages how
  91                 // to change a cvar default, we'll have a small leak here.
  92                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  93         }
  94         // only in right path
  95         if( substring(plyermodel,0,14) != "models/player/")
  96                 return FallbackPlayerModel;
  97         // only good file extensions
  98         if(substring(plyermodel,-4,4) != ".zym")
  99         if(substring(plyermodel,-4,4) != ".dpm")
 100         if(substring(plyermodel,-4,4) != ".iqm")
 101         if(substring(plyermodel,-4,4) != ".md3")
 102         if(substring(plyermodel,-4,4) != ".psk")
 103                 return FallbackPlayerModel;
 104         // forbid the LOD models
 105         if(substring(plyermodel, -9,5) == "_lod1")
 106                 return FallbackPlayerModel;
 107         if(substring(plyermodel, -9,5) == "_lod2")
 108                 return FallbackPlayerModel;
 109         if(plyermodel != strtolower(plyermodel))
 110                 return FallbackPlayerModel;
 111         // also, restrict to server models
 112         if(autocvar_sv_servermodelsonly)
 113         {
 114                 if(!fexists(plyermodel))
 115                         return FallbackPlayerModel;
 116         }
 117         return plyermodel;
 118 }
 119
 120 void setplayermodel(entity e, string modelname)
 121 {
 122         precache_model(modelname);
 123         setmodel(e, modelname);
 124         player_setupanimsformodel();
 125         UpdatePlayerSounds();
 126 }
 127
 128 /*
 129 =============
 130 PutObserverInServer
 131
 132 putting a client as observer in the server
 133 =============
 134 */
 135 void FixPlayermodel();
 136 void PutObserverInServer (void)
 137 {
 138         entity  spot;
 139     self.hud = HUD_NORMAL;
 140
 141         spot = SelectSpawnPoint (TRUE);
 142         if(!spot)
 143                 error("No spawnpoints for observers?!?\n");
 144         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 145
 146         if(IS_REAL_CLIENT(self))
 147         {
 148                 msg_entity = self;
 149                 WriteByte(MSG_ONE, SVC_SETVIEW);
 150                 WriteEntity(MSG_ONE, self);
 151         }
 152
 153         self.frags = FRAGS_SPECTATOR;
 154
 155         MUTATOR_CALLHOOK(MakePlayerObserver);
 156
 157         Portal_ClearAll(self);
 158
 159         Unfreeze(self);
 160
 161         if(self.alivetime)
 162         {
 163                 if(!warmup_stage)
 164                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 165                 self.alivetime = 0;
 166         }
 167
 168         if(self.vehicle)
 169                 vehicles_exit(VHEF_RELESE);
 170
 171         WaypointSprite_PlayerDead();
 172
 173         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 174                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 175
 176         if(self.killcount != -666)
 177         {
 178                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 179                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 180                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 181
 182                 if(self.just_joined == FALSE) {
 183                         LogTeamchange(self.playerid, -1, 4);
 184                 } else
 185                         self.just_joined = FALSE;
 186         }
 187
 188         PlayerScore_Clear(self); // clear scores when needed
 189
 190         accuracy_resend(self);
 191
 192         self.spectatortime = time;
 193
 194         self.classname = "observer";
 195         self.iscreature = FALSE;
 196         self.teleportable = TELEPORT_SIMPLE;
 197         self.damagedbycontents = FALSE;
 198         self.health = -666;
 199         self.takedamage = DAMAGE_NO;
 200         self.solid = SOLID_NOT;
 201         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 202         self.flags = FL_CLIENT | FL_NOTARGET;
 203         self.armorvalue = 666;
 204         self.effects = 0;
 205         self.armorvalue = autocvar_g_balance_armor_start;
 206         self.pauserotarmor_finished = 0;
 207         self.pauserothealth_finished = 0;
 208         self.pauseregen_finished = 0;
 209         self.damageforcescale = 0;
 210         self.death_time = 0;
 211         self.respawn_flags = 0;
 212         self.respawn_time = 0;
 213         self.stat_respawn_time = 0;
 214         self.alpha = 0;
 215         self.scale = 0;
 216         self.fade_time = 0;
 217         self.pain_frame = 0;
 218         self.pain_finished = 0;
 219         self.strength_finished = 0;
 220         self.invincible_finished = 0;
 221         self.superweapons_finished = 0;
 222         self.pushltime = 0;
 223         self.istypefrag = 0;
 224         self.think = func_null;
 225         self.nextthink = 0;
 226         self.hook_time = 0;
 227         self.deadflag = DEAD_NO;
 228         self.angles = spot.angles;
 229         self.angles_z = 0;
 230         self.fixangle = TRUE;
 231         self.crouch = FALSE;
 232         self.revival_time = 0;
 233
 234         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 235         self.prevorigin = self.origin;
 236         self.items = 0;
 237         self.weapons = '0 0 0';
 238         self.model = "";
 239         FixPlayermodel();
 240         setmodel(self, "null");
 241         self.drawonlytoclient = self;
 242
 243         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 244         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 245
 246         self.weapon = 0;
 247         self.weaponname = "";
 248         self.switchingweapon = 0;
 249         self.weaponmodel = "";
 250         self.weaponentity = world;
 251         self.exteriorweaponentity = world;
 252         self.killcount = -666;
 253         self.velocity = '0 0 0';
 254         self.avelocity = '0 0 0';
 255         self.punchangle = '0 0 0';
 256         self.punchvector = '0 0 0';
 257         self.oldvelocity = self.velocity;
 258         self.fire_endtime = -1;
 259 }
 260
 261 .float model_randomizer;
 262 void FixPlayermodel()
 263 {
 264         string defaultmodel;
 265         float defaultskin, chmdl, oldskin, n, i;
 266         vector m1, m2;
 267
 268         defaultmodel = "";
 269         defaultskin = 0;
 270         chmdl = FALSE;
 271
 272         if(autocvar_sv_defaultcharacter == 1)
 273         {
 274                 if(teamplay)
 275                 {
 276                         string s;
 277                         s = Static_Team_ColorName_Lower(self.team);
 278                         if(s != "neutral")
 279                         {
 280                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 281                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 282                         }
 283                 }
 284
 285                 if(defaultmodel == "")
 286                 {
 287                         defaultmodel = autocvar_sv_defaultplayermodel;
 288                         defaultskin = autocvar_sv_defaultplayerskin;
 289                 }
 290
 291                 n = tokenize_console(defaultmodel);
 292                 if(n > 0)
 293                 {
 294                         defaultmodel = argv(floor(n * self.model_randomizer));
 295                         // However, do NOT randomize if the player-selected model is in the list.
 296                         for (i = 0; i < n; ++i)
 297                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 298                                         defaultmodel = argv(i);
 299                 }
 300
 301                 i = strstrofs(defaultmodel, ":", 0);
 302                 if(i >= 0)
 303                 {
 304                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 305                         defaultmodel = substring(defaultmodel, 0, i);
 306                 }
 307         }
 308
 309         if(defaultmodel != "")
 310         {
 311                 if (defaultmodel != self.model)
 312                 {
 313                         m1 = self.mins;
 314                         m2 = self.maxs;
 315                         setplayermodel (self, defaultmodel);
 316                         setsize (self, m1, m2);
 317                         chmdl = TRUE;
 318                 }
 319
 320                 oldskin = self.skin;
 321                 self.skin = defaultskin;
 322         } else {
 323                 if (self.playermodel != self.model || self.playermodel == "")
 324                 {
 325                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 326                         m1 = self.mins;
 327                         m2 = self.maxs;
 328                         setplayermodel (self, self.playermodel);
 329                         setsize (self, m1, m2);
 330                         chmdl = TRUE;
 331                 }
 332
 333                 oldskin = self.skin;
 334                 self.skin = stof(self.playerskin);
 335         }
 336
 337         if(chmdl || oldskin != self.skin) // model or skin has changed
 338         {
 339                 self.species = player_getspecies(); // update species
 340                 UpdatePlayerSounds(); // update skin sounds
 341         }
 342
 343         if(!teamplay)
 344                 if(strlen(autocvar_sv_defaultplayercolors))
 345                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 346                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 347 }
 348
 349 /*
 350 =============
 351 PutClientInServer
 352
 353 Called when a client spawns in the server
 354 =============
 355 */
 356 void PutClientInServer (void)
 357 {
 358         if(IS_BOT_CLIENT(self))
 359                 self.classname = "player";
 360         else if(IS_REAL_CLIENT(self))
 361         {
 362                 msg_entity = self;
 363                 WriteByte(MSG_ONE, SVC_SETVIEW);
 364                 WriteEntity(MSG_ONE, self);
 365         }
 366
 367         // reset player keys
 368         self.itemkeys = 0;
 369
 370         MUTATOR_CALLHOOK(PutClientInServer);
 371
 372         if(gameover)
 373                 self.classname = "observer";
 374
 375         if(IS_PLAYER(self))
 376         {
 377                 entity spot, oldself;
 378                 float j;
 379
 380                 accuracy_resend(self);
 381
 382                 if(self.team < 0)
 383                         JoinBestTeam(self, FALSE, TRUE);
 384
 385                 spot = SelectSpawnPoint (FALSE);
 386                 if(!spot)
 387                 {
 388                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 389                         return; // spawn failed
 390                 }
 391
 392                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394                 if(self.vehicle)
 395                         vehicles_exit(VHEF_RELESE);
 396
 397                 self.classname = "player";
 398                 self.wasplayer = TRUE;
 399                 self.iscreature = TRUE;
 400                 self.teleportable = TELEPORT_NORMAL;
 401                 self.damagedbycontents = TRUE;
 402                 self.movetype = MOVETYPE_WALK;
 403                 self.solid = SOLID_SLIDEBOX;
 404                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 405                 if(autocvar_g_playerclip_collisions)
 406                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 407                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 408                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 409                 self.frags = FRAGS_PLAYER;
 410                 if(INDEPENDENT_PLAYERS)
 411                         MAKE_INDEPENDENT_PLAYER(self);
 412                 self.flags = FL_CLIENT;
 413                 if(autocvar__notarget)
 414                         self.flags |= FL_NOTARGET;
 415                 self.takedamage = DAMAGE_AIM;
 416                 self.effects = 0;
 417                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 418                 self.air_finished = time + 12;
 419                 self.dmg = 2;
 420                 if(autocvar_g_balance_nex_charge)
 421                 {
 422                         if(autocvar_g_balance_nex_secondary_chargepool)
 423                                 self.nex_chargepool_ammo = 1;
 424                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 425                 }
 426
 427                 if(warmup_stage)
 428                 {
 429                         self.ammo_shells = warmup_start_ammo_shells;
 430                         self.ammo_nails = warmup_start_ammo_nails;
 431                         self.ammo_rockets = warmup_start_ammo_rockets;
 432                         self.ammo_cells = warmup_start_ammo_cells;
 433                         self.ammo_fuel = warmup_start_ammo_fuel;
 434                         self.health = warmup_start_health;
 435                         self.armorvalue = warmup_start_armorvalue;
 436                         self.weapons = WARMUP_START_WEAPONS;
 437                 }
 438                 else
 439                 {
 440                         self.ammo_shells = start_ammo_shells;
 441                         self.ammo_nails = start_ammo_nails;
 442                         self.ammo_rockets = start_ammo_rockets;
 443                         self.ammo_cells = start_ammo_cells;
 444                         self.ammo_fuel = start_ammo_fuel;
 445                         self.health = start_health;
 446                         self.armorvalue = start_armorvalue;
 447                         self.weapons = start_weapons;
 448                 }
 449
 450                 if(self.weapons & WEPSET_SUPERWEAPONS)
 451                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 452                 else
 453                         self.superweapons_finished = 0;
 454
 455                 if(g_weaponarena_random)
 456                 {
 457                         if(g_weaponarena_random_with_laser)
 458                                 self.weapons &= ~WEPSET_LASER;
 459                         W_RandomWeapons(self, g_weaponarena_random);
 460                         if(g_weaponarena_random_with_laser)
 461                                 self.weapons |= WEPSET_LASER;
 462                 }
 463
 464                 self.items = start_items;
 465
 466                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 467                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 468                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 469                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 470                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 471                 //extend the pause of rotting if client was reset at the beginning of the countdown
 472                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 473                         self.spawnshieldtime += game_starttime - time;
 474                         self.pauserotarmor_finished += game_starttime - time;
 475                         self.pauserothealth_finished += game_starttime - time;
 476                         self.pauseregen_finished += game_starttime - time;
 477                 }
 478                 self.damageforcescale = 2;
 479                 self.death_time = 0;
 480                 self.respawn_flags = 0;
 481                 self.respawn_time = 0;
 482                 self.stat_respawn_time = 0;
 483                 self.scale = 0;
 484                 self.fade_time = 0;
 485                 self.pain_frame = 0;
 486                 self.pain_finished = 0;
 487                 self.strength_finished = 0;
 488                 self.invincible_finished = 0;
 489                 self.pushltime = 0;
 490                 // players have no think function
 491                 self.think = func_null;
 492                 self.nextthink = 0;
 493                 self.hook_time = 0;
 494                 self.dmg_team = 0;
 495                 self.ballistics_density = autocvar_g_ballistics_density_player;
 496
 497                 self.metertime = 0;
 498
 499                 self.deadflag = DEAD_NO;
 500
 501                 self.angles = spot.angles;
 502
 503                 self.angles_z = 0; // never spawn tilted even if the spot says to
 504                 self.fixangle = TRUE; // turn this way immediately
 505                 self.velocity = '0 0 0';
 506                 self.avelocity = '0 0 0';
 507                 self.punchangle = '0 0 0';
 508                 self.punchvector = '0 0 0';
 509                 self.oldvelocity = self.velocity;
 510                 self.fire_endtime = -1;
 511                 self.revival_time = 0;
 512
 513                 entity spawnevent = spawn();
 514                 spawnevent.owner = self;
 515                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 516
 517                 // Cut off any still running player sounds.
 518                 stopsound(self, CH_PLAYER_SINGLE);
 519
 520                 self.model = "";
 521                 FixPlayermodel();
 522                 self.drawonlytoclient = world;
 523
 524                 self.crouch = FALSE;
 525                 self.view_ofs = PL_VIEW_OFS;
 526                 setsize (self, PL_MIN, PL_MAX);
 527                 self.spawnorigin = spot.origin;
 528                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 529                 // don't reset back to last position, even if new position is stuck in solid
 530                 self.oldorigin = self.origin;
 531                 self.prevorigin = self.origin;
 532                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 533                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 534         self.hud = HUD_NORMAL;
 535
 536                 self.event_damage = PlayerDamage;
 537
 538                 self.bot_attack = TRUE;
 539                 self.monster_attack = TRUE;
 540
 541                 self.spider_slowness = 0;
 542
 543                 self.statdraintime = time + 5;
 544                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 545
 546                 if(self.killcount == -666) {
 547                         PlayerScore_Clear(self);
 548                         self.killcount = 0;
 549                 }
 550
 551                 CL_SpawnWeaponentity();
 552                 self.alpha = default_player_alpha;
 553                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 554                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 555
 556                 self.speedrunning = FALSE;
 557
 558                 //stuffcmd(self, "chase_active 0");
 559                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 560
 561                 target_voicescript_clear(self);
 562
 563                 // reset fields the weapons may use
 564                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 565                 {
 566                         weapon_action(j, WR_RESETPLAYER);
 567
 568                         // all weapons must be fully loaded when we spawn
 569                         entity e;
 570                         e = get_weaponinfo(j);
 571                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 572                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 573                 }
 574
 575                 oldself = self;
 576                 self = spot;
 577                         activator = oldself;
 578                                 string s;
 579                                 s = self.target;
 580                                 self.target = string_null;
 581                                 SUB_UseTargets();
 582                                 self.target = s;
 583                         activator = world;
 584                 self = oldself;
 585
 586                 Unfreeze(self);
 587
 588                 spawn_spot = spot;
 589                 MUTATOR_CALLHOOK(PlayerSpawn);
 590
 591                 if(autocvar_spawn_debug)
 592                 {
 593                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 594                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 595                 }
 596
 597                 self.switchweapon = w_getbestweapon(self);
 598                 self.cnt = -1; // W_LastWeapon will not complain
 599                 self.weapon = 0;
 600                 self.weaponname = "";
 601                 self.switchingweapon = 0;
 602
 603                 if(!warmup_stage)
 604                         if(!self.alivetime)
 605                                 self.alivetime = time;
 606
 607                 antilag_clear(self);
 608         }
 609         else if(IS_OBSERVER(self))
 610         {
 611                 PutObserverInServer ();
 612         }
 613 }
 614
 615 .float ebouncefactor, ebouncestop; // electro's values
 616 // TODO do we need all these fields, or should we stop autodetecting runtime
 617 // changes and just have a console command to update this?
 618 float ClientInit_SendEntity(entity to, float sf)
 619 {
 620         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 621         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 634         if(sv_foginterval && world.fog != "")
 635                 WriteString(MSG_ENTITY, world.fog);
 636         else
 637                 WriteString(MSG_ENTITY, "");
 638         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 639         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 640         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 641         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 642         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 643         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 644         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 645         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 646         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 647         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 648         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 649         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 650         return TRUE;
 651 }
 652
 653 void ClientInit_CheckUpdate()
 654 {
 655         self.nextthink = time;
 656         if(self.count != autocvar_g_balance_armor_blockpercent)
 657         {
 658                 self.count = autocvar_g_balance_armor_blockpercent;
 659                 self.SendFlags |= 1;
 660         }
 661         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 662         {
 663                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 664                 self.SendFlags |= 1;
 665         }
 666         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 667         {
 668                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 669                 self.SendFlags |= 1;
 670         }
 671         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 672         {
 673                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 674                 self.SendFlags |= 1;
 675         }
 676         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 677         {
 678                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 679                 self.SendFlags |= 1;
 680         }
 681 }
 682
 683 void ClientInit_Spawn()
 684 {
 685         entity o;
 686         entity e;
 687         e = spawn();
 688         e.classname = "clientinit";
 689         e.think = ClientInit_CheckUpdate;
 690         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 691
 692         o = self;
 693         self = e;
 694         ClientInit_CheckUpdate();
 695         self = o;
 696 }
 697
 698 /*
 699 =============
 700 SetNewParms
 701 =============
 702 */
 703 void SetNewParms (void)
 704 {
 705         // initialize parms for a new player
 706         parm1 = -(86400 * 366);
 707 }
 708
 709 /*
 710 =============
 711 SetChangeParms
 712 =============
 713 */
 714 void SetChangeParms (void)
 715 {
 716         // save parms for level change
 717         parm1 = self.parm_idlesince - time;
 718 }
 719
 720 /*
 721 =============
 722 DecodeLevelParms
 723 =============
 724 */
 725 void DecodeLevelParms (void)
 726 {
 727         // load parms
 728         self.parm_idlesince = parm1;
 729         if(self.parm_idlesince == -(86400 * 366))
 730                 self.parm_idlesince = time;
 731
 732         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 733         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 734 }
 735
 736 /*
 737 =============
 738 ClientKill
 739
 740 Called when a client types 'kill' in the console
 741 =============
 742 */
 743
 744 .float clientkill_nexttime;
 745 void ClientKill_Now_TeamChange()
 746 {
 747         if(self.killindicator_teamchange == -1)
 748         {
 749                 JoinBestTeam( self, FALSE, TRUE );
 750         }
 751         else if(self.killindicator_teamchange == -2)
 752         {
 753                 if(blockSpectators)
 754                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 755                 PutObserverInServer();
 756         }
 757         else
 758                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 759         self.killindicator_teamchange = 0;
 760 }
 761
 762 void ClientKill_Now()
 763 {
 764         if(self.vehicle)
 765         {
 766             vehicles_exit(VHEF_RELESE);
 767             if(!self.killindicator_teamchange)
 768             {
 769             self.vehicle_health = -1;
 770             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 771             }
 772         }
 773
 774         if(self.killindicator && !wasfreed(self.killindicator))
 775                 remove(self.killindicator);
 776
 777         self.killindicator = world;
 778
 779         if(self.killindicator_teamchange)
 780                 ClientKill_Now_TeamChange();
 781
 782         // in any case:
 783         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 784
 785         // now I am sure the player IS dead
 786 }
 787 void KillIndicator_Think()
 788 {
 789         if (gameover)
 790         {
 791                 self.owner.killindicator = world;
 792                 remove(self);
 793                 return;
 794         }
 795
 796         if (self.owner.alpha < 0 && !self.owner.vehicle)
 797         {
 798                 self.owner.killindicator = world;
 799                 remove(self);
 800                 return;
 801         }
 802
 803         if(self.cnt <= 0)
 804         {
 805                 self = self.owner;
 806                 ClientKill_Now(); // no oldself needed
 807                 return;
 808         }
 809     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 810     {
 811         self.nextthink = time + 1;
 812         self.cnt -= 1;
 813     }
 814         else
 815         {
 816                 if(self.cnt <= 10)
 817                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 818                 if(IS_REAL_CLIENT(self.owner))
 819                 {
 820                         if(self.cnt <= 10)
 821                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 822                 }
 823                 self.nextthink = time + 1;
 824                 self.cnt -= 1;
 825         }
 826 }
 827
 828 float clientkilltime;
 829 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 830 {
 831         float killtime;
 832         float starttime;
 833         entity e;
 834
 835         if (gameover)
 836                 return;
 837
 838         killtime = autocvar_g_balance_kill_delay;
 839
 840         if(g_race_qualifying || g_cts)
 841                 killtime = 0;
 842
 843     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 844     {
 845                 remove(self.killindicator);
 846                 self.killindicator = world;
 847
 848         ClientKill_Now(); // allow instant kill in this case
 849         return;
 850     }
 851
 852         self.killindicator_teamchange = targetteam;
 853
 854     if(!self.killindicator)
 855         {
 856                 if(self.deadflag == DEAD_NO)
 857                 {
 858                         killtime = max(killtime, self.clientkill_nexttime - time);
 859                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 860                 }
 861
 862                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 863                 {
 864                         ClientKill_Now();
 865                 }
 866                 else
 867                 {
 868                         starttime = max(time, clientkilltime);
 869
 870                         self.killindicator = spawn();
 871                         self.killindicator.owner = self;
 872                         self.killindicator.scale = 0.5;
 873                         setattachment(self.killindicator, self, "");
 874                         setorigin(self.killindicator, '0 0 52');
 875                         self.killindicator.think = KillIndicator_Think;
 876                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 877                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 878                         self.killindicator.cnt = ceil(killtime);
 879                         self.killindicator.count = bound(0, ceil(killtime), 10);
 880                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 881
 882                         for(e = world; (e = find(e, classname, "body")) != world; )
 883                         {
 884                                 if(e.enemy != self)
 885                                         continue;
 886                                 e.killindicator = spawn();
 887                                 e.killindicator.owner = e;
 888                                 e.killindicator.scale = 0.5;
 889                                 setattachment(e.killindicator, e, "");
 890                                 setorigin(e.killindicator, '0 0 52');
 891                                 e.killindicator.think = KillIndicator_Think;
 892                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 893                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 894                                 e.killindicator.cnt = ceil(killtime);
 895                         }
 896                         self.lip = 0;
 897                 }
 898         }
 899         if(self.killindicator)
 900         {
 901                 if(targetteam == 0) // just die
 902                 {
 903                         self.killindicator.colormod = '0 0 0';
 904                         if(IS_REAL_CLIENT(self))
 905                         if(self.killindicator.cnt > 0)
 906                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 907                 }
 908                 else if(targetteam == -1) // auto
 909                 {
 910                         self.killindicator.colormod = '0 1 0';
 911                         if(IS_REAL_CLIENT(self))
 912                         if(self.killindicator.cnt > 0)
 913                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 914                 }
 915                 else if(targetteam == -2) // spectate
 916                 {
 917                         self.killindicator.colormod = '0.5 0.5 0.5';
 918                         if(IS_REAL_CLIENT(self))
 919                         if(self.killindicator.cnt > 0)
 920                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 921                 }
 922                 else
 923                 {
 924                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 925                         if(IS_REAL_CLIENT(self))
 926                         if(self.killindicator.cnt > 0)
 927                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 928                 }
 929         }
 930
 931 }
 932
 933 void ClientKill (void)
 934 {
 935         if(gameover) return;
 936         if(self.player_blocked) return;
 937         if(self.frozen) return;
 938
 939         ClientKill_TeamChange(0);
 940 }
 941
 942 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 943 {
 944     e.killindicator = spawn();
 945     e.killindicator.owner = e;
 946     e.killindicator.think = KillIndicator_Think;
 947     e.killindicator.nextthink = time + (e.lip) * 0.05;
 948     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 949     e.killindicator.health = 1; // this is used to indicate that it should be silent
 950     e.lip = 0;
 951 }
 952
 953 void FixClientCvars(entity e)
 954 {
 955         // send prediction settings to the client
 956         stuffcmd(e, "\nin_bindmap 0 0\n");
 957         if(g_race || g_cts)
 958                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 959         if(autocvar_g_antilag == 3) // client side hitscan
 960                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 961         if(autocvar_sv_gentle)
 962                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 963         /*
 964          * we no longer need to stuff this. Remove this comment block if you feel
 965          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 966         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 967         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 968         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 969         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 970         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 971         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 972         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 973         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 974         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 975         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 976         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 977         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 978         stuffcmd(e, "cl_movement_edgefriction 1\n");
 979          */
 980 }
 981
 982 float PlayerInIDList(entity p, string idlist)
 983 {
 984         float n, i;
 985         string s;
 986
 987         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 988         if (!p.crypto_idfp)
 989                 return 0;
 990
 991         // this function allows abbreviated player IDs too!
 992         n = tokenize_console(idlist);
 993         for(i = 0; i < n; ++i)
 994         {
 995                 s = argv(i);
 996                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 997                         return 1;
 998         }
 999
1000         return 0;
1001 }
1002
1003 /*
1004 =============
1005 ClientConnect
1006
1007 Called when a client connects to the server
1008 =============
1009 */
1010 void DecodeLevelParms (void);
1011 //void dom_player_join_team(entity pl);
1012 void set_dom_state(entity e);
1013 void ClientConnect (void)
1014 {
1015         float t;
1016
1017         if(IS_CLIENT(self))
1018         {
1019                 print("Warning: ClientConnect, but already connected!\n");
1020                 return;
1021         }
1022
1023         if(Ban_MaybeEnforceBanOnce(self))
1024                 return;
1025
1026         DecodeLevelParms();
1027
1028 #ifdef WATERMARK
1029         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1030 #endif
1031
1032         self.classname = "player_joining";
1033
1034         self.flags = FL_CLIENT;
1035         self.version_nagtime = time + 10 + random() * 10;
1036
1037         if(player_count<0)
1038         {
1039                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1040                 player_count = 0;
1041         }
1042
1043         PlayerScore_Attach(self);
1044         ClientData_Attach();
1045         accuracy_init(self);
1046
1047         bot_clientconnect();
1048
1049         playerdemo_init();
1050
1051         anticheat_init();
1052
1053         // identify the right forced team
1054         if(autocvar_g_campaign)
1055         {
1056                 if(IS_REAL_CLIENT(self)) // only players, not bots
1057                 {
1058                         switch(autocvar_g_campaign_forceteam)
1059                         {
1060                                 case 1: self.team_forced = NUM_TEAM_1; break;
1061                                 case 2: self.team_forced = NUM_TEAM_2; break;
1062                                 case 3: self.team_forced = NUM_TEAM_3; break;
1063                                 case 4: self.team_forced = NUM_TEAM_4; break;
1064                                 default: self.team_forced = 0;
1065                         }
1066                 }
1067         }
1068         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1069                 self.team_forced = NUM_TEAM_1;
1070         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1071                 self.team_forced = NUM_TEAM_2;
1072         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1073                 self.team_forced = NUM_TEAM_3;
1074         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1075                 self.team_forced = NUM_TEAM_4;
1076         else if(autocvar_g_forced_team_otherwise == "red")
1077                 self.team_forced = NUM_TEAM_1;
1078         else if(autocvar_g_forced_team_otherwise == "blue")
1079                 self.team_forced = NUM_TEAM_2;
1080         else if(autocvar_g_forced_team_otherwise == "yellow")
1081                 self.team_forced = NUM_TEAM_3;
1082         else if(autocvar_g_forced_team_otherwise == "pink")
1083                 self.team_forced = NUM_TEAM_4;
1084         else if(autocvar_g_forced_team_otherwise == "spectate")
1085                 self.team_forced = -1;
1086         else if(autocvar_g_forced_team_otherwise == "spectator")
1087                 self.team_forced = -1;
1088         else
1089                 self.team_forced = 0;
1090
1091         if(!teamplay)
1092                 if(self.team_forced > 0)
1093                         self.team_forced = 0;
1094
1095         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1096
1097         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1098                 self.classname = "observer";
1099         } else {
1100                 if(teamplay)
1101                 {
1102                         if(autocvar_g_balance_teams)
1103                         {
1104                                 self.classname = "player";
1105                                 campaign_bots_may_start = 1;
1106                         }
1107                         else
1108                         {
1109                                 self.classname = "observer"; // do it anyway
1110                         }
1111                 }
1112                 else
1113                 {
1114                         self.classname = "player";
1115                         campaign_bots_may_start = 1;
1116                 }
1117         }
1118
1119         self.playerid = (playerid_last = playerid_last + 1);
1120
1121         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1122
1123     if(IS_BOT_CLIENT(self))
1124         PlayerStats_AddPlayer(self);
1125
1126         if(autocvar_sv_eventlog)
1127                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1128
1129         LogTeamchange(self.playerid, self.team, 1);
1130
1131         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1132
1133         self.netname_previous = strzone(self.netname);
1134
1135         if(IS_PLAYER(self) && teamplay)
1136                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1137         else
1138                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1139
1140         stuffcmd(self, strcat(clientstuff, "\n"));
1141         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1142
1143         FixClientCvars(self);
1144
1145         // spawnfunc_waypoint sprites
1146         WaypointSprite_InitClient(self);
1147
1148         // Wazat's grappling hook
1149         SetGrappleHookBindings();
1150
1151         // get version info from player
1152         stuffcmd(self, "cmd clientversion $gameversion\n");
1153
1154         // get other cvars from player
1155         GetCvars(0);
1156
1157         // notify about available teams
1158         if(teamplay)
1159         {
1160                 CheckAllowedTeams(self);
1161                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1162                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1163         }
1164         else
1165                 stuffcmd(self, "set _teams_available 0\n");
1166
1167         attach_entcs();
1168
1169         bot_relinkplayerlist();
1170
1171         self.spectatortime = time;
1172         if(blockSpectators)
1173         {
1174                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1175         }
1176
1177         self.jointime = time;
1178         self.allowed_timeouts = autocvar_sv_timeout_number;
1179
1180         if(IS_REAL_CLIENT(self))
1181         {
1182                 if(!autocvar_g_campaign)
1183                 {
1184                         self.motd_actived_time = -1;
1185                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1186                 }
1187
1188                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1189                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1190         }
1191
1192         if(!sv_foginterval && world.fog != "")
1193                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1194
1195         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1196         {
1197                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1198                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1199         }
1200         else
1201                 self.hitplotfh = -1;
1202
1203         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1204                 send_CSQC_teamnagger();
1205
1206         CheatInitClient();
1207
1208         CSQCMODEL_AUTOINIT();
1209
1210         self.model_randomizer = random();
1211
1212         if(IS_REAL_CLIENT(self))
1213                 sv_notice_join();
1214
1215         MUTATOR_CALLHOOK(ClientConnect);
1216 }
1217 /*
1218 =============
1219 ClientDisconnect
1220
1221 Called when a client disconnects from the server
1222 =============
1223 */
1224 .entity chatbubbleentity;
1225 void ReadyCount();
1226 void ClientDisconnect (void)
1227 {
1228         if(self.vehicle)
1229             vehicles_exit(VHEF_RELESE);
1230
1231         if (!IS_CLIENT(self))
1232         {
1233                 print("Warning: ClientDisconnect without ClientConnect\n");
1234                 return;
1235         }
1236
1237         PlayerStats_AddGlobalInfo(self);
1238
1239         CheatShutdownClient();
1240
1241         if(self.hitplotfh >= 0)
1242         {
1243                 fclose(self.hitplotfh);
1244                 self.hitplotfh = -1;
1245         }
1246
1247         anticheat_report();
1248         anticheat_shutdown();
1249
1250         playerdemo_shutdown();
1251
1252         bot_clientdisconnect();
1253
1254         if(self.entcs)
1255                 detach_entcs();
1256
1257         if(autocvar_sv_eventlog)
1258                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1259
1260         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1261
1262         MUTATOR_CALLHOOK(ClientDisconnect);
1263
1264         Portal_ClearAll(self);
1265
1266         Unfreeze(self);
1267
1268         RemoveGrapplingHook(self);
1269
1270         // Here, everything has been done that requires this player to be a client.
1271
1272         self.flags &= ~FL_CLIENT;
1273
1274         if (self.chatbubbleentity)
1275                 remove (self.chatbubbleentity);
1276
1277         if (self.killindicator)
1278                 remove (self.killindicator);
1279
1280         WaypointSprite_PlayerGone();
1281
1282         bot_relinkplayerlist();
1283
1284         accuracy_free(self);
1285         ClientData_Detach();
1286         PlayerScore_Detach(self);
1287
1288         if(self.netname_previous)
1289                 strunzone(self.netname_previous);
1290         if(self.clientstatus)
1291                 strunzone(self.clientstatus);
1292         if(self.weaponorder_byimpulse)
1293                 strunzone(self.weaponorder_byimpulse);
1294
1295         ClearPlayerSounds();
1296
1297         if(self.personal)
1298                 remove(self.personal);
1299
1300         self.playerid = 0;
1301         ReadyCount();
1302
1303         // free cvars
1304         GetCvars(-1);
1305 }
1306
1307 .float BUTTON_CHAT;
1308 void ChatBubbleThink()
1309 {
1310         self.nextthink = time;
1311         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1312         {
1313                 if(self.owner) // but why can that ever be world?
1314                         self.owner.chatbubbleentity = world;
1315                 remove(self);
1316                 return;
1317         }
1318         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1319 #ifdef TETRIS
1320                 || self.owner.tetris_on
1321 #endif
1322         )
1323                 self.model = self.mdl;
1324         else
1325                 self.model = "";
1326 }
1327
1328 void UpdateChatBubble()
1329 {
1330         if (self.alpha < 0)
1331                 return;
1332         // spawn a chatbubble entity if needed
1333         if (!self.chatbubbleentity)
1334         {
1335                 self.chatbubbleentity = spawn();
1336                 self.chatbubbleentity.owner = self;
1337                 self.chatbubbleentity.exteriormodeltoclient = self;
1338                 self.chatbubbleentity.think = ChatBubbleThink;
1339                 self.chatbubbleentity.nextthink = time;
1340                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1341                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1342                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1343                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1344                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1345                 self.chatbubbleentity.model = "";
1346                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1347         }
1348 }
1349
1350
1351 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1352 // added to the model skins
1353 /*void UpdateColorModHack()
1354 {
1355         float c;
1356         c = self.clientcolors & 15;
1357         // LordHavoc: only bothering to support white, green, red, yellow, blue
1358              if (!teamplay) self.colormod = '0 0 0';
1359         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1360         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1361         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1362         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1363         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1364         else self.colormod = '1 1 1';
1365 }*/
1366
1367 void respawn(void)
1368 {
1369         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1370         {
1371                 self.solid = SOLID_NOT;
1372                 self.takedamage = DAMAGE_NO;
1373                 self.movetype = MOVETYPE_FLY;
1374                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1375                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1376                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1377                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1378                 if(autocvar_g_respawn_ghosts_maxtime)
1379                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1380         }
1381
1382         CopyBody(1);
1383
1384         self.effects |= EF_NODRAW; // prevent another CopyBody
1385         PutClientInServer();
1386 }
1387
1388 void play_countdown(float finished, string samp)
1389 {
1390         if(IS_REAL_CLIENT(self))
1391                 if(floor(finished - time - frametime) != floor(finished - time))
1392                         if(finished - time < 6)
1393                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1394 }
1395
1396 void player_powerups (void)
1397 {
1398         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1399         olditems = self.items;
1400
1401         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1402                 self.modelflags |= MF_ROCKET;
1403         else
1404                 self.modelflags &= ~MF_ROCKET;
1405
1406         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1407
1408         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1409                 return;
1410
1411         Fire_ApplyDamage(self);
1412         Fire_ApplyEffect(self);
1413
1414         if (!g_minstagib)
1415         {
1416                 if (self.items & IT_STRENGTH)
1417                 {
1418                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1419                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1420                         if (time > self.strength_finished)
1421                         {
1422                                 self.items = self.items - (self.items & IT_STRENGTH);
1423                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1424                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1425                         }
1426                 }
1427                 else
1428                 {
1429                         if (time < self.strength_finished)
1430                         {
1431                                 self.items = self.items | IT_STRENGTH;
1432                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1433                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1434                         }
1435                 }
1436                 if (self.items & IT_INVINCIBLE)
1437                 {
1438                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1439                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1440                         if (time > self.invincible_finished)
1441                         {
1442                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1443                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1444                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1445                         }
1446                 }
1447                 else
1448                 {
1449                         if (time < self.invincible_finished)
1450                         {
1451                                 self.items = self.items | IT_INVINCIBLE;
1452                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1453                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1454                         }
1455                 }
1456                 if (self.items & IT_SUPERWEAPON)
1457                 {
1458                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1459                         {
1460                                 self.superweapons_finished = 0;
1461                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1462                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1463                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1464                         }
1465                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1466                         {
1467                                 // don't let them run out
1468                         }
1469                         else
1470                         {
1471                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1472                                 if (time > self.superweapons_finished)
1473                                 {
1474                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1475                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1476                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1477                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1478                                 }
1479                         }
1480                 }
1481                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1482                 {
1483                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1484                         {
1485                                 self.items = self.items | IT_SUPERWEAPON;
1486                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1487                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1488                         }
1489                         else
1490                         {
1491                                 self.superweapons_finished = 0;
1492                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1493                         }
1494                 }
1495                 else
1496                 {
1497                         self.superweapons_finished = 0;
1498                 }
1499         }
1500
1501         if(autocvar_g_nodepthtestplayers)
1502                 self.effects = self.effects | EF_NODEPTHTEST;
1503
1504         if(autocvar_g_fullbrightplayers)
1505                 self.effects = self.effects | EF_FULLBRIGHT;
1506
1507         if (time >= game_starttime)
1508         if (time < self.spawnshieldtime)
1509                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1510
1511         MUTATOR_CALLHOOK(PlayerPowerups);
1512 }
1513
1514 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1515 {
1516         if(current > stable)
1517                 return current;
1518         else if(current > stable - 0.25) // when close enough, "snap"
1519                 return stable;
1520         else
1521                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1522 }
1523
1524 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1525 {
1526         if(current < stable)
1527                 return current;
1528         else if(current < stable + 0.25) // when close enough, "snap"
1529                 return stable;
1530         else
1531                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1532 }
1533
1534 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1535 {
1536         if(current > rotstable)
1537         {
1538                 if(rotframetime > 0)
1539                 {
1540                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1541                         current = max(rotstable, current - rotlinear * rotframetime);
1542                 }
1543         }
1544         else if(current < regenstable)
1545         {
1546                 if(regenframetime > 0)
1547                 {
1548                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1549                         current = min(regenstable, current + regenlinear * regenframetime);
1550                 }
1551         }
1552
1553         if(current > limit)
1554                 current = limit;
1555
1556         return current;
1557 }
1558
1559 void player_regen (void)
1560 {
1561         float max_mod, regen_mod, rot_mod, limit_mod;
1562         max_mod = regen_mod = rot_mod = limit_mod = 1;
1563         regen_mod_max = max_mod;
1564         regen_mod_regen = regen_mod;
1565         regen_mod_rot = rot_mod;
1566         regen_mod_limit = limit_mod;
1567         if(!MUTATOR_CALLHOOK(PlayerRegen))
1568         if(!self.frozen)
1569         {
1570                 float minh, mina, maxh, maxa, limith, limita;
1571                 maxh = autocvar_g_balance_health_rotstable;
1572                 maxa = autocvar_g_balance_armor_rotstable;
1573                 minh = autocvar_g_balance_health_regenstable;
1574                 mina = autocvar_g_balance_armor_regenstable;
1575                 limith = autocvar_g_balance_health_limit;
1576                 limita = autocvar_g_balance_armor_limit;
1577
1578                 max_mod = regen_mod_max;
1579                 regen_mod = regen_mod_regen;
1580                 rot_mod = regen_mod_rot;
1581                 limit_mod = regen_mod_limit;
1582
1583                 maxh = maxh * max_mod;
1584                 minh = minh * max_mod;
1585                 limith = limith * limit_mod;
1586                 limita = limita * limit_mod;
1587
1588                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1589                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1590         }
1591
1592         // if player rotted to death...  die!
1593         // check this outside above checks, as player may still be able to rot to death
1594         if(self.health < 1)
1595                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1596
1597         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1598         {
1599                 float minf, maxf, limitf;
1600
1601                 maxf = autocvar_g_balance_fuel_rotstable;
1602                 minf = autocvar_g_balance_fuel_regenstable;
1603                 limitf = autocvar_g_balance_fuel_limit;
1604
1605                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1606         }
1607 }
1608
1609 float zoomstate_set;
1610 void SetZoomState(float z)
1611 {
1612         if(z != self.zoomstate)
1613         {
1614                 self.zoomstate = z;
1615                 ClientData_Touch(self);
1616         }
1617         zoomstate_set = 1;
1618 }
1619
1620 void GetPressedKeys(void) {
1621         MUTATOR_CALLHOOK(GetPressedKeys);
1622         if (self.movement_x > 0) // get if movement keys are pressed
1623         {       // forward key pressed
1624                 self.pressedkeys |= KEY_FORWARD;
1625                 self.pressedkeys &= ~KEY_BACKWARD;
1626         }
1627         else if (self.movement_x < 0)
1628         {       // backward key pressed
1629                 self.pressedkeys |= KEY_BACKWARD;
1630                 self.pressedkeys &= ~KEY_FORWARD;
1631         }
1632         else
1633         {       // no x input
1634                 self.pressedkeys &= ~KEY_FORWARD;
1635                 self.pressedkeys &= ~KEY_BACKWARD;
1636         }
1637
1638         if (self.movement_y > 0)
1639         {       // right key pressed
1640                 self.pressedkeys |= KEY_RIGHT;
1641                 self.pressedkeys &= ~KEY_LEFT;
1642         }
1643         else if (self.movement_y < 0)
1644         {       // left key pressed
1645                 self.pressedkeys |= KEY_LEFT;
1646                 self.pressedkeys &= ~KEY_RIGHT;
1647         }
1648         else
1649         {       // no y input
1650                 self.pressedkeys &= ~KEY_RIGHT;
1651                 self.pressedkeys &= ~KEY_LEFT;
1652         }
1653
1654         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1655                 self.pressedkeys |= KEY_JUMP;
1656         else
1657                 self.pressedkeys &= ~KEY_JUMP;
1658         if (self.BUTTON_CROUCH)
1659                 self.pressedkeys |= KEY_CROUCH;
1660         else
1661                 self.pressedkeys &= ~KEY_CROUCH;
1662
1663         if (self.BUTTON_ATCK)
1664                 self.pressedkeys |= KEY_ATCK;
1665         else
1666                 self.pressedkeys &= ~KEY_ATCK;
1667         if (self.BUTTON_ATCK2)
1668                 self.pressedkeys |= KEY_ATCK2;
1669         else
1670                 self.pressedkeys &= ~KEY_ATCK2;
1671 }
1672
1673 /*
1674 ======================
1675 spectate mode routines
1676 ======================
1677 */
1678
1679 void SpectateCopy(entity spectatee) {
1680         other = spectatee;
1681         MUTATOR_CALLHOOK(SpectateCopy);
1682         self.armortype = spectatee.armortype;
1683         self.armorvalue = spectatee.armorvalue;
1684         self.ammo_cells = spectatee.ammo_cells;
1685         self.ammo_shells = spectatee.ammo_shells;
1686         self.ammo_nails = spectatee.ammo_nails;
1687         self.ammo_rockets = spectatee.ammo_rockets;
1688         self.ammo_fuel = spectatee.ammo_fuel;
1689         self.clip_load = spectatee.clip_load;
1690         self.clip_size = spectatee.clip_size;
1691         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1692         self.health = spectatee.health;
1693         self.impulse = 0;
1694         self.items = spectatee.items;
1695         self.last_pickup = spectatee.last_pickup;
1696         self.hit_time = spectatee.hit_time;
1697         self.metertime = spectatee.metertime;
1698         self.strength_finished = spectatee.strength_finished;
1699         self.invincible_finished = spectatee.invincible_finished;
1700         self.pressedkeys = spectatee.pressedkeys;
1701         self.weapons = spectatee.weapons;
1702         self.switchweapon = spectatee.switchweapon;
1703         self.switchingweapon = spectatee.switchingweapon;
1704         self.weapon = spectatee.weapon;
1705         self.nex_charge = spectatee.nex_charge;
1706         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1707         self.hagar_load = spectatee.hagar_load;
1708         self.minelayer_mines = spectatee.minelayer_mines;
1709         self.punchangle = spectatee.punchangle;
1710         self.view_ofs = spectatee.view_ofs;
1711         self.velocity = spectatee.velocity;
1712         self.dmg_take = spectatee.dmg_take;
1713         self.dmg_save = spectatee.dmg_save;
1714         self.dmg_inflictor = spectatee.dmg_inflictor;
1715         self.v_angle = spectatee.v_angle;
1716         self.angles = spectatee.v_angle;
1717         self.frozen = spectatee.frozen;
1718         self.revive_progress = spectatee.revive_progress;
1719         if(!self.BUTTON_USE)
1720                 self.fixangle = TRUE;
1721         setorigin(self, spectatee.origin);
1722         setsize(self, spectatee.mins, spectatee.maxs);
1723         SetZoomState(spectatee.zoomstate);
1724
1725     anticheat_spectatecopy(spectatee);
1726         self.hud = spectatee.hud;
1727         if(spectatee.vehicle)
1728     {
1729         self.fixangle = FALSE;
1730         //self.velocity = spectatee.vehicle.velocity;
1731         self.vehicle_health = spectatee.vehicle_health;
1732         self.vehicle_shield = spectatee.vehicle_shield;
1733         self.vehicle_energy = spectatee.vehicle_energy;
1734         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1735         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1736         self.vehicle_reload1 = spectatee.vehicle_reload1;
1737         self.vehicle_reload2 = spectatee.vehicle_reload2;
1738
1739         msg_entity = self;
1740
1741         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1742             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1743             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1744             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1745
1746         //WriteByte (MSG_ONE, SVC_SETVIEW);
1747         //    WriteEntity(MSG_ONE, self);
1748         //makevectors(spectatee.v_angle);
1749         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1750     }
1751 }
1752
1753 float SpectateUpdate() {
1754         if(!self.enemy)
1755             return 0;
1756
1757         if (self == self.enemy)
1758                 return 0;
1759
1760         if (!IS_PLAYER(self.enemy))
1761                 return 0;
1762
1763         SpectateCopy(self.enemy);
1764
1765         return 1;
1766 }
1767
1768
1769 float SpectateSet()
1770 {
1771         if(self.enemy.classname != "player")
1772                 return FALSE;
1773         /*if(self.enemy.vehicle)
1774         {
1775
1776                 msg_entity = self;
1777                 WriteByte(MSG_ONE, SVC_SETVIEW);
1778                 WriteEntity(MSG_ONE, self.enemy);
1779                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1780
1781                 self.movetype = MOVETYPE_NONE;
1782                 accuracy_resend(self);
1783         }
1784         else
1785         {*/
1786                 msg_entity = self;
1787                 WriteByte(MSG_ONE, SVC_SETVIEW);
1788                 WriteEntity(MSG_ONE, self.enemy);
1789                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1790                 self.movetype = MOVETYPE_NONE;
1791                 accuracy_resend(self);
1792
1793                 if(!SpectateUpdate())
1794                         PutObserverInServer();
1795         //}
1796         return TRUE;
1797 }
1798
1799 float Spectate(entity pl)
1800 {
1801         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1802         if(pl.team != self.team)
1803                 return 0;
1804
1805         self.enemy = pl;
1806         return SpectateSet();
1807 }
1808
1809 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1810 entity CA_SpectateNext(entity start) {
1811         if (start.team == self.team) {
1812                 return start;
1813         }
1814
1815         other = start;
1816         // continue from current player
1817         while(other && other.team != self.team) {
1818                 other = find(other, classname, "player");
1819         }
1820
1821         if (!other) {
1822                 // restart from begining
1823                 other = find(other, classname, "player");
1824                 while(other && other.team != self.team) {
1825                         other = find(other, classname, "player");
1826                 }
1827         }
1828
1829         return other;
1830 }
1831
1832 float SpectateNext()
1833 {
1834         other = find(self.enemy, classname, "player");
1835
1836         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1837                 // CA and ca players when spectating enemies is forbidden
1838                 other = CA_SpectateNext(other);
1839         } else {
1840                 // other modes and ca spectators or spectating enemies is allowed
1841                 if (!other)
1842                         other = find(other, classname, "player");
1843         }
1844
1845         if (other)
1846                 self.enemy = other;
1847
1848         return SpectateSet();
1849 }
1850
1851 float SpectatePrev()
1852 {
1853         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1854         other = findchain(classname, "player");
1855         if (!other) // no player
1856                 return FALSE;
1857
1858         entity first = other;
1859         // skip players until current spectated player
1860         if(self.enemy)
1861         while(other && other != self.enemy)
1862                 other = other.chain;
1863
1864         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1865         {
1866                 do { other = other.chain; }
1867                 while(other && other.team != self.team);
1868
1869                 if (!other)
1870                 {
1871                         other = first;
1872                         while(other.team != self.team)
1873                                 other = other.chain;
1874                         if(other == self.enemy)
1875                                 return TRUE;
1876                 }
1877         }
1878         else
1879         {
1880                 if(other.chain)
1881                         other = other.chain;
1882                 else
1883                         other = first;
1884         }
1885         self.enemy = other;
1886         return SpectateSet();
1887 }
1888
1889 /*
1890 =============
1891 ShowRespawnCountdown()
1892
1893 Update a respawn countdown display.
1894 =============
1895 */
1896 void ShowRespawnCountdown()
1897 {
1898         float number;
1899         if(self.deadflag == DEAD_NO) // just respawned?
1900                 return;
1901         else
1902         {
1903                 number = ceil(self.respawn_time - time);
1904                 if(number <= 0)
1905                         return;
1906                 if(number <= self.respawn_countdown)
1907                 {
1908                         self.respawn_countdown = number - 1;
1909                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1910                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1911                 }
1912         }
1913 }
1914
1915 void LeaveSpectatorMode()
1916 {
1917         if(self.caplayer)
1918                 return;
1919         if(nJoinAllowed(self))
1920         {
1921                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1922                 {
1923                         self.classname = "player";
1924                         nades_RemoveBonus(self);
1925
1926                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1927                                 { JoinBestTeam(self, FALSE, TRUE); }
1928
1929                         if(autocvar_g_campaign)
1930                                 { campaign_bots_may_start = 1; }
1931
1932                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1933
1934                         PutClientInServer();
1935
1936                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1937                 }
1938                 else
1939                         stuffcmd(self, "menu_showteamselect\n");
1940         }
1941         else
1942         {
1943                 // Player may not join because g_maxplayers is set
1944                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1945         }
1946 }
1947
1948 /**
1949  * Determines whether the player is allowed to join. This depends on cvar
1950  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1951  * it checks whether the number of currently playing players exceeds g_maxplayers.
1952  * @return int number of free slots for players, 0 if none
1953  */
1954 float nJoinAllowed(entity ignore) {
1955         if(!ignore)
1956         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1957         // so report 0 free slots if restricted
1958         {
1959                 if(autocvar_g_forced_team_otherwise == "spectate")
1960                         return 0;
1961                 if(autocvar_g_forced_team_otherwise == "spectator")
1962                         return 0;
1963         }
1964
1965         if(self.team_forced < 0)
1966                 return 0; // forced spectators can never join
1967
1968         // TODO simplify this
1969         entity e;
1970         float totalClients = 0;
1971         FOR_EACH_CLIENT(e)
1972                 if(e != ignore)
1973                         totalClients += 1;
1974
1975         if (!autocvar_g_maxplayers)
1976                 return maxclients - totalClients;
1977
1978         float currentlyPlaying = 0;
1979         FOR_EACH_REALCLIENT(e)
1980                 if(IS_PLAYER(e) || e.caplayer == 1)
1981                         currentlyPlaying += 1;
1982
1983         if(currentlyPlaying < autocvar_g_maxplayers)
1984                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1985
1986         return 0;
1987 }
1988
1989 /**
1990  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1991  * g_maxplayers_spectator_blocktime seconds
1992  */
1993 void checkSpectatorBlock() {
1994         if(IS_SPEC(self) || IS_OBSERVER(self)) {
1995                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1996                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1997                         dropclient(self);
1998                 }
1999         }
2000 }
2001
2002 void PrintWelcomeMessage()
2003 {
2004         if(self.motd_actived_time == 0)
2005         {
2006                 if (autocvar_g_campaign) {
2007                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2008                                 self.motd_actived_time = time;
2009                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2010                         }
2011                 } else {
2012                         if (self.BUTTON_INFO) {
2013                                 self.motd_actived_time = time;
2014                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2015                         }
2016                 }
2017         }
2018         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2019         {
2020                 if (autocvar_g_campaign) {
2021                         if (self.BUTTON_INFO)
2022                                 self.motd_actived_time = time;
2023                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2024                                 self.motd_actived_time = 0;
2025                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2026                         }
2027                 } else {
2028                         if (self.BUTTON_INFO)
2029                                 self.motd_actived_time = time;
2030                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2031                                 self.motd_actived_time = 0;
2032                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2033                         }
2034                 }
2035         }
2036         else //if(self.motd_actived_time < 0) // just connected, motd is active
2037         {
2038                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2039                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2040                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2041                 {
2042                         // instanctly hide MOTD
2043                         self.motd_actived_time = 0;
2044                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2045                 }
2046         }
2047 }
2048
2049 void ObserverThink()
2050 {
2051         float prefered_movetype;
2052         if (self.flags & FL_JUMPRELEASED) {
2053                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2054                         self.flags &= ~FL_JUMPRELEASED;
2055                         self.flags |= FL_SPAWNING;
2056                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2057                         self.flags &= ~FL_JUMPRELEASED;
2058                         if(SpectateNext()) {
2059                                 self.classname = "spectator";
2060                         }
2061                 } else {
2062                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2063                         if (self.movetype != prefered_movetype)
2064                                 self.movetype = prefered_movetype;
2065                 }
2066         } else {
2067                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2068                         self.flags |= FL_JUMPRELEASED;
2069                         if(self.flags & FL_SPAWNING)
2070                         {
2071                                 self.flags &= ~FL_SPAWNING;
2072                                 LeaveSpectatorMode();
2073                                 return;
2074                         }
2075                 }
2076         }
2077 }
2078
2079 void SpectatorThink()
2080 {
2081         if (self.flags & FL_JUMPRELEASED) {
2082                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2083                         self.flags &= ~FL_JUMPRELEASED;
2084                         self.flags |= FL_SPAWNING;
2085                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2086                         self.flags &= ~FL_JUMPRELEASED;
2087                         if(SpectateNext()) {
2088                                 self.classname = "spectator";
2089                         } else {
2090                                 self.classname = "observer";
2091                                 PutClientInServer();
2092                         }
2093                         self.impulse = 0;
2094                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2095                         self.flags &= ~FL_JUMPRELEASED;
2096                         if(SpectatePrev()) {
2097                                 self.classname = "spectator";
2098                         } else {
2099                                 self.classname = "observer";
2100                                 PutClientInServer();
2101                         }
2102                         self.impulse = 0;
2103                 } else if (self.BUTTON_ATCK2) {
2104                         self.flags &= ~FL_JUMPRELEASED;
2105                         self.classname = "observer";
2106                         PutClientInServer();
2107                 } else {
2108                         if(!SpectateUpdate())
2109                                 PutObserverInServer();
2110                 }
2111         } else {
2112                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2113                         self.flags |= FL_JUMPRELEASED;
2114                         if(self.flags & FL_SPAWNING)
2115                         {
2116                                 self.flags &= ~FL_SPAWNING;
2117                                 LeaveSpectatorMode();
2118                                 return;
2119                         }
2120                 }
2121                 if(!SpectateUpdate())
2122                         PutObserverInServer();
2123         }
2124
2125         self.flags |= FL_CLIENT | FL_NOTARGET;
2126 }
2127
2128 void PlayerUseKey()
2129 {
2130         if (!IS_PLAYER(self))
2131                 return;
2132
2133         if(self.vehicle)
2134         {
2135         vehicles_exit(VHEF_NORMAL);
2136         return;
2137         }
2138
2139         // a use key was pressed; call handlers
2140         MUTATOR_CALLHOOK(PlayerUseKey);
2141 }
2142
2143 /*
2144 =============
2145 PlayerPreThink
2146
2147 Called every frame for each client before the physics are run
2148 =============
2149 */
2150 .float usekeypressed;
2151 void() nexball_setstatus;
2152 .float items_added;
2153 void PlayerPreThink (void)
2154 {
2155         WarpZone_PlayerPhysics_FixVAngle();
2156
2157         self.stat_game_starttime = game_starttime;
2158         self.stat_round_starttime = round_starttime;
2159         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2160         self.stat_leadlimit = autocvar_leadlimit;
2161
2162         if(frametime)
2163         {
2164                 // physics frames: update anticheat stuff
2165                 anticheat_prethink();
2166         }
2167
2168         if(blockSpectators && frametime)
2169                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2170                 checkSpectatorBlock();
2171
2172         zoomstate_set = 0;
2173
2174         if(self.netname_previous != self.netname)
2175         {
2176                 if(autocvar_sv_eventlog)
2177                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2178                 if(self.netname_previous)
2179                         strunzone(self.netname_previous);
2180                 self.netname_previous = strzone(self.netname);
2181         }
2182
2183         // version nagging
2184         if(self.version_nagtime)
2185                 if(self.cvar_g_xonoticversion)
2186                         if(time > self.version_nagtime)
2187                         {
2188                                 // don't notify git users
2189                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2190                                 {
2191                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2192                                         {
2193                                                 // notify release users if connecting to git
2194                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2195                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2196                                         }
2197                                         else
2198                                         {
2199                                                 float r;
2200                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2201                                                 if(r < 0)
2202                                                 {
2203                                                         // give users new version
2204                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2205                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2206                                                 }
2207                                                 else if(r > 0)
2208                                                 {
2209                                                         // notify users about old server version
2210                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2211                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2212                                                 }
2213                                         }
2214                                 }
2215                                 self.version_nagtime = 0;
2216                         }
2217
2218         // GOD MODE info
2219         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2220         {
2221                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2222                 self.max_armorvalue = 0;
2223         }
2224
2225 #ifdef TETRIS
2226         if (TetrisPreFrame())
2227                 return;
2228 #endif
2229
2230         if(self.frozen == 2)
2231         {
2232                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2233                 self.health = max(1, self.revive_progress * start_health);
2234                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2235
2236                 if(self.revive_progress >= 1)
2237                         Unfreeze(self);
2238         }
2239         else if(self.frozen == 3)
2240         {
2241                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2242                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2243
2244                 if(self.health < 1)
2245                 {
2246                         if(self.vehicle)
2247                                 vehicles_exit(VHEF_RELESE);
2248                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2249                 }
2250                 else if ( self.revive_progress <= 0 )
2251                         Unfreeze(self);
2252         }
2253
2254         MUTATOR_CALLHOOK(PlayerPreThink);
2255
2256         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2257         {
2258                 if(self.BUTTON_USE && !self.usekeypressed)
2259                         PlayerUseKey();
2260                 self.usekeypressed = self.BUTTON_USE;
2261         }
2262
2263         if(IS_REAL_CLIENT(self))
2264                 PrintWelcomeMessage();
2265
2266         if(IS_PLAYER(self))
2267         {
2268
2269                 CheckRules_Player();
2270
2271                 if (intermission_running)
2272                 {
2273                         IntermissionThink ();   // otherwise a button could be missed between
2274                         return;                                 // the think tics
2275                 }
2276
2277                 //don't allow the player to turn around while game is paused!
2278                 if(timeout_status == TIMEOUT_ACTIVE) {
2279                         // FIXME turn this into CSQC stuff
2280                         self.v_angle = self.lastV_angle;
2281                         self.angles = self.lastV_angle;
2282                         self.fixangle = TRUE;
2283                 }
2284
2285                 if(frametime)
2286                 {
2287                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2288                         {
2289                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2290                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2291                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2292
2293                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2294                                 {
2295                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2296                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2297                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2298                                 }
2299                         }
2300                         else
2301                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2302
2303                         player_powerups();
2304                 }
2305
2306                 if (self.deadflag != DEAD_NO)
2307                 {
2308                         if(self.personal && g_race_qualifying)
2309                         {
2310                                 if(time > self.respawn_time)
2311                                 {
2312                                         self.respawn_time = time + 1; // only retry once a second
2313                                         self.stat_respawn_time = self.respawn_time;
2314                                         respawn();
2315                                         self.impulse = 141;
2316                                 }
2317                         }
2318                         else
2319                         {
2320                                 float button_pressed;
2321                                 if(frametime)
2322                                         player_anim();
2323                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2324
2325                                 if (self.deadflag == DEAD_DYING)
2326                                 {
2327                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2328                                                 self.deadflag = DEAD_RESPAWNING;
2329                                         else if(!button_pressed)
2330                                                 self.deadflag = DEAD_DEAD;
2331                                 }
2332                                 else if (self.deadflag == DEAD_DEAD)
2333                                 {
2334                                         if(button_pressed)
2335                                                 self.deadflag = DEAD_RESPAWNABLE;
2336                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2337                                                 self.deadflag = DEAD_RESPAWNING;
2338                                 }
2339                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2340                                 {
2341                                         if(!button_pressed)
2342                                                 self.deadflag = DEAD_RESPAWNING;
2343                                 }
2344                                 else if (self.deadflag == DEAD_RESPAWNING)
2345                                 {
2346                                         if(time > self.respawn_time)
2347                                         {
2348                                                 self.respawn_time = time + 1; // only retry once a second
2349                                                 self.respawn_time_max = self.respawn_time;
2350                                                 respawn();
2351                                         }
2352                                 }
2353
2354                                 ShowRespawnCountdown();
2355
2356                                 if(self.respawn_flags & RESPAWN_SILENT)
2357                                         self.stat_respawn_time = 0;
2358                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2359                                         self.stat_respawn_time = self.respawn_time_max;
2360                                 else
2361                                         self.stat_respawn_time = self.respawn_time;
2362                         }
2363
2364                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2365                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2366                                 self.stat_respawn_time *= -1;
2367
2368                         return;
2369                 }
2370
2371                 self.prevorigin = self.origin;
2372
2373                 float do_crouch = self.BUTTON_CROUCH;
2374                 if(self.hook.state)
2375                         do_crouch = 0;
2376                 if(self.vehicle)
2377                         do_crouch = 0;
2378                 if(self.frozen)
2379                         do_crouch = 0;
2380                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2381                         do_crouch = 0;
2382
2383                 if (do_crouch)
2384                 {
2385                         if (!self.crouch)
2386                         {
2387                                 self.crouch = TRUE;
2388                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2389                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2390                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2391                         }
2392                 }
2393                 else
2394                 {
2395                         if (self.crouch)
2396                         {
2397                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2398                                 if (!trace_startsolid)
2399                                 {
2400                                         self.crouch = FALSE;
2401                                         self.view_ofs = PL_VIEW_OFS;
2402                                         setsize (self, PL_MIN, PL_MAX);
2403                                 }
2404                         }
2405                 }
2406
2407                 FixPlayermodel();
2408
2409                 GrapplingHookFrame();
2410
2411                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2412                 //if(frametime)
2413                 {
2414                         self.items &= ~self.items_added;
2415
2416                         W_WeaponFrame();
2417
2418                         self.items_added = 0;
2419                         if(self.items & IT_JETPACK)
2420                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2421                                         self.items_added |= IT_FUEL;
2422
2423                         self.items |= self.items_added;
2424                 }
2425
2426                 player_regen();
2427
2428                 // rot nex charge to the charge limit
2429                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2430                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2431
2432                 if(frametime)
2433                         player_anim();
2434
2435                 // secret status
2436                 secrets_setstatus();
2437
2438                 // monsters status
2439                 monsters_setstatus();
2440
2441                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2442
2443                 //self.angles_y=self.v_angle_y + 90;   // temp
2444         } else if(gameover) {
2445                 if (intermission_running)
2446                         IntermissionThink ();   // otherwise a button could be missed between
2447                 return;
2448         } else if(IS_OBSERVER(self)) {
2449                 ObserverThink();
2450         } else if(IS_SPEC(self)) {
2451                 SpectatorThink();
2452         }
2453
2454         if(!zoomstate_set)
2455                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2456
2457         float oldspectatee_status;
2458         oldspectatee_status = self.spectatee_status;
2459         if(IS_SPEC(self))
2460                 self.spectatee_status = num_for_edict(self.enemy);
2461         else if(IS_OBSERVER(self))
2462                 self.spectatee_status = num_for_edict(self);
2463         else
2464                 self.spectatee_status = 0;
2465         if(self.spectatee_status != oldspectatee_status)
2466         {
2467                 ClientData_Touch(self);
2468         }
2469
2470         if(self.teamkill_soundtime)
2471         if(time > self.teamkill_soundtime)
2472         {
2473                 self.teamkill_soundtime = 0;
2474
2475                 entity oldpusher, oldself;
2476
2477                 oldself = self; self = self.teamkill_soundsource;
2478                 oldpusher = self.pusher; self.pusher = oldself;
2479
2480                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2481
2482                 self.pusher = oldpusher;
2483                 self = oldself;
2484         }
2485
2486         if(self.taunt_soundtime)
2487         if(time > self.taunt_soundtime)
2488         {
2489                 self.taunt_soundtime = 0;
2490                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2491         }
2492
2493         target_voicescript_next(self);
2494
2495         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2496         if(!self.weapon)
2497                 self.clip_load = self.clip_size = 0;
2498 }
2499
2500 float isInvisibleString(string s)
2501 {
2502         float i, n, c;
2503         s = strdecolorize(s);
2504         for((i = 0), (n = strlen(s)); i < n; ++i)
2505         {
2506                 c = str2chr(s, i);
2507                 switch(c)
2508                 {
2509                         case 0:
2510                         case 32: // space
2511                                 break;
2512                         case 192: // charmap space
2513                                 if (!autocvar_utf8_enable)
2514                                         break;
2515                                 return FALSE;
2516                         case 160: // space in unicode fonts
2517                         case 0xE000 + 192: // utf8 charmap space
2518                                 if (autocvar_utf8_enable)
2519                                         break;
2520                         default:
2521                                 return FALSE;
2522                 }
2523         }
2524         return TRUE;
2525 }
2526
2527 /*
2528 =============
2529 PlayerPostThink
2530
2531 Called every frame for each client after the physics are run
2532 =============
2533 */
2534 .float idlekick_lasttimeleft;
2535 void PlayerPostThink (void)
2536 {
2537         // Savage: Check for nameless players
2538         if (isInvisibleString(self.netname)) {
2539                 self.netname = "Player";
2540                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2541         }
2542
2543         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2544         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2545         {
2546                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2547                 {
2548                         if(self.idlekick_lasttimeleft)
2549                         {
2550                                 self.idlekick_lasttimeleft = 0;
2551                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2552                         }
2553                 }
2554                 else
2555                 {
2556                         float timeleft;
2557                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2558                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2559                         {
2560                                 if(!self.idlekick_lasttimeleft)
2561                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2562                         }
2563                         if(timeleft <= 0)
2564                         {
2565                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2566                                 dropclient(self);
2567                                 return;
2568                         }
2569                         else if(timeleft <= 10)
2570                         {
2571                                 if(timeleft != self.idlekick_lasttimeleft)
2572                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2573                                 self.idlekick_lasttimeleft = timeleft;
2574                         }
2575                 }
2576         }
2577
2578 #ifdef TETRIS
2579         if(self.impulse == 100)
2580                 ImpulseCommands();
2581         if (!TetrisPostFrame())
2582         {
2583 #endif
2584
2585         CheatFrame();
2586
2587         //CheckPlayerJump();
2588
2589         if(IS_PLAYER(self)) {
2590                 CheckRules_Player();
2591                 UpdateChatBubble();
2592                 if (self.impulse)
2593                         ImpulseCommands();
2594                 if (intermission_running)
2595                         return;         // intermission or finale
2596                 GetPressedKeys();
2597         }
2598
2599 #ifdef TETRIS
2600         }
2601 #endif
2602
2603         /*
2604         float i;
2605         for(i = 0; i < 1000; ++i)
2606         {
2607                 vector end;
2608                 end = self.origin + '0 0 1024' + 512 * randomvec();
2609                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2610                 if(trace_fraction < 1)
2611                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2612                 {
2613                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2614                         break;
2615                 }
2616         }
2617         */
2618
2619         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2620
2621         if(self.waypointsprite_attachedforcarrier)
2622                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2623
2624         playerdemo_write();
2625
2626         CSQCMODEL_AUTOUPDATE();
2627 }