qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         MUTATOR_CALLHOOK(MakePlayerObserver);
 405
 406         minstagib_stop_countdown(self);
 407
 408         Portal_ClearAll(self);
 409
 410         if(self.alivetime)
 411         {
 412                 if(!inWarmupStage)
 413                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418                 vehicles_exit(VHEF_RELESE);
 419
 420         WaypointSprite_PlayerDead();
 421
 422         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 423                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 424
 425         if(self.killcount != -666) {
 426                 if(g_lms) {
 427                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
 428                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
 429                         else
 430                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
 431                 } else { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname); }
 432
 433                 if(self.just_joined == FALSE) {
 434                         LogTeamchange(self.playerid, -1, 4);
 435                 } else
 436                         self.just_joined = FALSE;
 437         }
 438
 439         PlayerScore_Clear(self); // clear scores when needed
 440
 441         accuracy_resend(self);
 442
 443         self.spectatortime = time;
 444
 445         self.classname = "observer";
 446         self.iscreature = FALSE;
 447         self.teleportable = TELEPORT_SIMPLE;
 448         self.damagedbycontents = FALSE;
 449         self.health = -666;
 450         self.takedamage = DAMAGE_NO;
 451         self.solid = SOLID_NOT;
 452         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 453         self.flags = FL_CLIENT | FL_NOTARGET;
 454         self.armorvalue = 666;
 455         self.effects = 0;
 456         self.armorvalue = autocvar_g_balance_armor_start;
 457         self.pauserotarmor_finished = 0;
 458         self.pauserothealth_finished = 0;
 459         self.pauseregen_finished = 0;
 460         self.damageforcescale = 0;
 461         self.death_time = 0;
 462         self.respawn_time = 0;
 463         self.alpha = 0;
 464         self.scale = 0;
 465         self.fade_time = 0;
 466         self.pain_frame = 0;
 467         self.pain_finished = 0;
 468         self.strength_finished = 0;
 469         self.invincible_finished = 0;
 470         self.superweapons_finished = 0;
 471         self.pushltime = 0;
 472         self.istypefrag = 0;
 473         self.think = func_null;
 474         self.nextthink = 0;
 475         self.hook_time = 0;
 476         self.deadflag = DEAD_NO;
 477         self.angles = spot.angles;
 478         self.angles_z = 0;
 479         self.fixangle = TRUE;
 480         self.crouch = FALSE;
 481
 482         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 483         self.prevorigin = self.origin;
 484         self.items = 0;
 485         WEPSET_CLEAR_E(self);
 486         self.model = "";
 487         FixPlayermodel();
 488         setmodel(self, "null");
 489         self.drawonlytoclient = self;
 490
 491         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 492         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 493
 494         self.weapon = 0;
 495         self.weaponname = "";
 496         self.switchingweapon = 0;
 497         self.weaponmodel = "";
 498         self.weaponentity = world;
 499         self.exteriorweaponentity = world;
 500         self.killcount = -666;
 501         self.velocity = '0 0 0';
 502         self.avelocity = '0 0 0';
 503         self.punchangle = '0 0 0';
 504         self.punchvector = '0 0 0';
 505         self.oldvelocity = self.velocity;
 506         self.fire_endtime = -1;
 507
 508         if(g_arena)
 509         {
 510                 if(self.version_mismatch)
 511                 {
 512                         self.frags = FRAGS_SPECTATOR;
 513                         Spawnqueue_Unmark(self);
 514                         Spawnqueue_Remove(self);
 515                 }
 516                 else
 517                 {
 518                         self.frags = FRAGS_LMS_LOSER;
 519                         Spawnqueue_Insert(self);
 520                 }
 521         }
 522         else if(g_ca)
 523         {
 524                 if(self.caplayer)
 525                         self.frags = FRAGS_LMS_LOSER;
 526                 else
 527                         self.frags = FRAGS_SPECTATOR;
 528         }
 529         else if((g_race && g_race_qualifying) || g_cts)
 530         {
 531                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 532                         self.frags = FRAGS_LMS_LOSER;
 533                 else
 534                         self.frags = FRAGS_SPECTATOR;
 535         }
 536         else
 537                 self.frags = FRAGS_SPECTATOR;
 538 }
 539
 540 .float model_randomizer;
 541 void FixPlayermodel()
 542 {
 543         string defaultmodel;
 544         float defaultskin, chmdl, oldskin, n, i;
 545         vector m1, m2;
 546
 547         defaultmodel = "";
 548         defaultskin = 0;
 549         chmdl = FALSE;
 550
 551         if(autocvar_sv_defaultcharacter == 1)
 552         {
 553                 if(teamplay)
 554                 {
 555                         string s;
 556                         s = Team_ColorName_Lower(self.team);
 557                         if(s != "neutral")
 558                         {
 559                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 560                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 561                         }
 562                 }
 563
 564                 if(defaultmodel == "")
 565                 {
 566                         defaultmodel = autocvar_sv_defaultplayermodel;
 567                         defaultskin = autocvar_sv_defaultplayerskin;
 568                 }
 569
 570                 n = tokenize_console(defaultmodel);
 571                 if(n > 0)
 572                         defaultmodel = argv(floor(n * self.model_randomizer));
 573
 574                 i = strstrofs(defaultmodel, ":", 0);
 575                 if(i >= 0)
 576                 {
 577                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 578                         defaultmodel = substring(defaultmodel, 0, i);
 579                 }
 580         }
 581
 582         if(defaultmodel != "")
 583         {
 584                 if (defaultmodel != self.model)
 585                 {
 586                         m1 = self.mins;
 587                         m2 = self.maxs;
 588                         setplayermodel (self, defaultmodel);
 589                         setsize (self, m1, m2);
 590                         chmdl = TRUE;
 591                 }
 592
 593                 oldskin = self.skin;
 594                 self.skin = defaultskin;
 595         } else {
 596                 if (self.playermodel != self.model || self.playermodel == "")
 597                 {
 598                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 599                         m1 = self.mins;
 600                         m2 = self.maxs;
 601                         setplayermodel (self, self.playermodel);
 602                         setsize (self, m1, m2);
 603                         chmdl = TRUE;
 604                 }
 605
 606                 oldskin = self.skin;
 607                 self.skin = stof(self.playerskin);
 608         }
 609
 610         if(chmdl || oldskin != self.skin) // model or skin has changed
 611         {
 612                 self.species = player_getspecies(); // update species
 613                 UpdatePlayerSounds(); // update skin sounds
 614         }
 615
 616         if(!teamplay)
 617                 if(strlen(autocvar_sv_defaultplayercolors))
 618                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 619                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 620 }
 621
 622 void PlayerTouchExplode(entity p1, entity p2)
 623 {
 624         vector org;
 625         org = (p1.origin + p2.origin) * 0.5;
 626         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 627
 628         te_explosion(org);
 629
 630         entity e;
 631         e = spawn();
 632         setorigin(e, org);
 633         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 634         remove(e);
 635 }
 636
 637 /*
 638 =============
 639 PutClientInServer
 640
 641 Called when a client spawns in the server
 642 =============
 643 */
 644
 645 void PutClientInServer (void)
 646 {
 647         if(clienttype(self) == CLIENTTYPE_BOT)
 648         {
 649                 self.classname = "player";
 650                 if(g_ca)
 651                         self.caplayer = 1;
 652         }
 653         else if(clienttype(self) == CLIENTTYPE_REAL)
 654         {
 655                 msg_entity = self;
 656                 WriteByte(MSG_ONE, SVC_SETVIEW);
 657                 WriteEntity(MSG_ONE, self);
 658         }
 659
 660         // reset player keys
 661         self.itemkeys = 0;
 662
 663         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 664                 self.classname = "observer";
 665
 666         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 667                 self.classname = "observer";
 668
 669         if(gameover)
 670                 self.classname = "observer";
 671
 672         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 673                 entity spot, oldself;
 674                 float j;
 675
 676                 accuracy_resend(self);
 677
 678                 if(self.team < 0)
 679                         JoinBestTeam(self, FALSE, TRUE);
 680
 681                 race_PreSpawn();
 682
 683                 spot = SelectSpawnPoint (FALSE);
 684                 if(!spot)
 685                 {
 686                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 687                         return; // spawn failed
 688                 }
 689
 690                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 691
 692                 self.classname = "player";
 693                 self.wasplayer = TRUE;
 694                 self.iscreature = TRUE;
 695                 self.teleportable = TELEPORT_NORMAL;
 696                 self.damagedbycontents = TRUE;
 697                 self.movetype = MOVETYPE_WALK;
 698                 self.solid = SOLID_SLIDEBOX;
 699                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 700                 if(autocvar_g_playerclip_collisions)
 701                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 702                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 703                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 704                 self.frags = FRAGS_PLAYER;
 705                 if(INDEPENDENT_PLAYERS)
 706                         MAKE_INDEPENDENT_PLAYER(self);
 707                 self.flags = FL_CLIENT;
 708                 if(autocvar__notarget)
 709                         self.flags |= FL_NOTARGET;
 710                 self.takedamage = DAMAGE_AIM;
 711                 if(g_minstagib)
 712                         self.effects = EF_FULLBRIGHT;
 713                 else
 714                         self.effects = 0;
 715                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 716                 self.air_finished = time + 12;
 717                 self.dmg = 2;
 718                 if(autocvar_g_balance_nex_charge)
 719                 {
 720                         if(autocvar_g_balance_nex_secondary_chargepool)
 721                                 self.nex_chargepool_ammo = 1;
 722                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 723                 }
 724
 725                 if(inWarmupStage)
 726                 {
 727                         self.ammo_shells = warmup_start_ammo_shells;
 728                         self.ammo_nails = warmup_start_ammo_nails;
 729                         self.ammo_rockets = warmup_start_ammo_rockets;
 730                         self.ammo_cells = warmup_start_ammo_cells;
 731                         self.ammo_fuel = warmup_start_ammo_fuel;
 732                         self.health = warmup_start_health;
 733                         self.armorvalue = warmup_start_armorvalue;
 734                         WEPSET_COPY_EA(self, warmup_start_weapons);
 735                 }
 736                 else
 737                 {
 738                         self.ammo_shells = start_ammo_shells;
 739                         self.ammo_nails = start_ammo_nails;
 740                         self.ammo_rockets = start_ammo_rockets;
 741                         self.ammo_cells = start_ammo_cells;
 742                         self.ammo_fuel = start_ammo_fuel;
 743                         self.health = start_health;
 744                         self.armorvalue = start_armorvalue;
 745                         WEPSET_COPY_EA(self, start_weapons);
 746                 }
 747
 748                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 749                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 750                 else
 751                         self.superweapons_finished = 0;
 752
 753                 if(g_weaponarena_random)
 754                 {
 755                         if(g_weaponarena_random_with_laser)
 756                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 757                         W_RandomWeapons(self, g_weaponarena_random);
 758                         if(g_weaponarena_random_with_laser)
 759                                 WEPSET_OR_EW(self, WEP_LASER);
 760                 }
 761
 762                 self.items = start_items;
 763
 764                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 765                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 766                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 767                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 768                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 769                 //extend the pause of rotting if client was reset at the beginning of the countdown
 770                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 771                         self.spawnshieldtime += game_starttime - time;
 772                         self.pauserotarmor_finished += game_starttime - time;
 773                         self.pauserothealth_finished += game_starttime - time;
 774                         self.pauseregen_finished += game_starttime - time;
 775                 }
 776                 self.damageforcescale = 2;
 777                 self.death_time = 0;
 778                 self.respawn_time = 0;
 779                 self.scale = 0;
 780                 self.fade_time = 0;
 781                 self.pain_frame = 0;
 782                 self.pain_finished = 0;
 783                 self.strength_finished = 0;
 784                 self.invincible_finished = 0;
 785                 self.pushltime = 0;
 786                 // players have no think function
 787                 self.think = func_null;
 788                 self.nextthink = 0;
 789                 self.hook_time = 0;
 790                 self.dmg_team = 0;
 791                 self.ballistics_density = autocvar_g_ballistics_density_player;
 792
 793                 self.metertime = 0;
 794
 795                 self.deadflag = DEAD_NO;
 796
 797                 self.angles = spot.angles;
 798
 799                 self.angles_z = 0; // never spawn tilted even if the spot says to
 800                 self.fixangle = TRUE; // turn this way immediately
 801                 self.velocity = '0 0 0';
 802                 self.avelocity = '0 0 0';
 803                 self.punchangle = '0 0 0';
 804                 self.punchvector = '0 0 0';
 805                 self.oldvelocity = self.velocity;
 806                 self.fire_endtime = -1;
 807
 808                 msg_entity = self;
 809                 WRITESPECTATABLE_MSG_ONE({
 810                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 811                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 812                 });
 813
 814                 self.model = "";
 815                 FixPlayermodel();
 816                 self.drawonlytoclient = world;
 817
 818                 self.crouch = FALSE;
 819                 self.view_ofs = PL_VIEW_OFS;
 820                 setsize (self, PL_MIN, PL_MAX);
 821                 self.spawnorigin = spot.origin;
 822                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 823                 // don't reset back to last position, even if new position is stuck in solid
 824                 self.oldorigin = self.origin;
 825                 self.prevorigin = self.origin;
 826                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 827                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 828         self.hud = HUD_NORMAL;
 829
 830                 if(g_arena)
 831                 {
 832                         Spawnqueue_Remove(self);
 833                         Spawnqueue_Mark(self);
 834                 }
 835                 else if(g_ca)
 836                         self.caplayer = 1;
 837
 838                 self.event_damage = PlayerDamage;
 839
 840                 self.bot_attack = TRUE;
 841
 842                 self.statdraintime = time + 5;
 843                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 844
 845                 if(self.killcount == -666) {
 846                         PlayerScore_Clear(self);
 847                         self.killcount = 0;
 848                 }
 849
 850                 CL_SpawnWeaponentity();
 851                 self.alpha = default_player_alpha;
 852                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 853                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 854
 855                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 856                 self.lms_traveled_distance = 0;
 857                 self.speedrunning = FALSE;
 858
 859                 race_PostSpawn(spot);
 860
 861                 //stuffcmd(self, "chase_active 0");
 862                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 863
 864                 if(g_assault) {
 865                         if(self.team == assault_attacker_team)
 866                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
 867                         else
 868                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
 869                 }
 870
 871                 target_voicescript_clear(self);
 872
 873                 // reset fields the weapons may use
 874                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 875                 {
 876                         weapon_action(j, WR_RESETPLAYER);
 877
 878                         // all weapons must be fully loaded when we spawn
 879                         entity e;
 880                         e = get_weaponinfo(j);
 881                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 882                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 883                 }
 884
 885                 oldself = self;
 886                 self = spot;
 887                         activator = oldself;
 888                                 string s;
 889                                 s = self.target;
 890                                 self.target = string_null;
 891                                 SUB_UseTargets();
 892                                 self.target = s;
 893                         activator = world;
 894                 self = oldself;
 895
 896                 spawn_spot = spot;
 897                 MUTATOR_CALLHOOK(PlayerSpawn);
 898
 899                 if(autocvar_spawn_debug)
 900                 {
 901                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 902                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 903                 }
 904
 905                 self.switchweapon = w_getbestweapon(self);
 906                 self.cnt = -1; // W_LastWeapon will not complain
 907                 self.weapon = 0;
 908                 self.weaponname = "";
 909                 self.switchingweapon = 0;
 910
 911                 if(!inWarmupStage)
 912                         if(!self.alivetime)
 913                                 self.alivetime = time;
 914
 915                 antilag_clear(self);
 916
 917                 if (autocvar_g_spawnsound)
 918                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 919         } else if(self.classname == "observer") {
 920                 PutObserverInServer ();
 921         }
 922 }
 923
 924 .float ebouncefactor, ebouncestop; // electro's values
 925 // TODO do we need all these fields, or should we stop autodetecting runtime
 926 // changes and just have a console command to update this?
 927 float ClientInit_SendEntity(entity to, float sf)
 928 {
 929         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 930         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 931         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 932         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 933         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 934         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 935         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 943         if(sv_foginterval && world.fog != "")
 944                 WriteString(MSG_ENTITY, world.fog);
 945         else
 946                 WriteString(MSG_ENTITY, "");
 947         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 948         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 949         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 950         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 951         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 952         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 953         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 954         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 955         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 956         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 957         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 958         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 959         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 960         return TRUE;
 961 }
 962
 963 void ClientInit_CheckUpdate()
 964 {
 965         self.nextthink = time;
 966         if(self.count != autocvar_g_balance_armor_blockpercent)
 967         {
 968                 self.count = autocvar_g_balance_armor_blockpercent;
 969                 self.SendFlags |= 1;
 970         }
 971         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 972         {
 973                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 974                 self.SendFlags |= 1;
 975         }
 976         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 977         {
 978                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 979                 self.SendFlags |= 1;
 980         }
 981         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 982         {
 983                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 984                 self.SendFlags |= 1;
 985         }
 986         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 987         {
 988                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 989                 self.SendFlags |= 1;
 990         }
 991         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 992         {
 993                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 994                 self.SendFlags |= 1;
 995         }
 996 }
 997
 998 void ClientInit_Spawn()
 999 {
1000         entity o;
1001         entity e;
1002         e = spawn();
1003         e.classname = "clientinit";
1004         e.think = ClientInit_CheckUpdate;
1005         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1006
1007         o = self;
1008         self = e;
1009         ClientInit_CheckUpdate();
1010         self = o;
1011 }
1012
1013 /*
1014 =============
1015 SetNewParms
1016 =============
1017 */
1018 void SetNewParms (void)
1019 {
1020         // initialize parms for a new player
1021         parm1 = -(86400 * 366);
1022 }
1023
1024 /*
1025 =============
1026 SetChangeParms
1027 =============
1028 */
1029 void SetChangeParms (void)
1030 {
1031         // save parms for level change
1032         parm1 = self.parm_idlesince - time;
1033 }
1034
1035 /*
1036 =============
1037 DecodeLevelParms
1038 =============
1039 */
1040 void DecodeLevelParms (void)
1041 {
1042         // load parms
1043         self.parm_idlesince = parm1;
1044         if(self.parm_idlesince == -(86400 * 366))
1045                 self.parm_idlesince = time;
1046
1047         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1048         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1049 }
1050
1051 /*
1052 =============
1053 ClientKill
1054
1055 Called when a client types 'kill' in the console
1056 =============
1057 */
1058
1059 .float clientkill_nexttime;
1060 void ClientKill_Now_TeamChange()
1061 {
1062         if(self.killindicator_teamchange == -1)
1063         {
1064                 JoinBestTeam( self, FALSE, TRUE );
1065         }
1066         else if(self.killindicator_teamchange == -2)
1067         {
1068                 if(g_ca)
1069                         self.caplayer = 0;
1070                 if(blockSpectators)
1071                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1072                 PutObserverInServer();
1073         }
1074         else
1075                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1076 }
1077
1078 void ClientKill_Now()
1079 {
1080         if(self.vehicle)
1081         {
1082             vehicles_exit(VHEF_RELESE);
1083             if(!self.killindicator_teamchange)
1084             {
1085             self.vehicle_health = -1;
1086             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1087             }
1088         }
1089
1090         if(self.killindicator && !wasfreed(self.killindicator))
1091                 remove(self.killindicator);
1092
1093         self.killindicator = world;
1094
1095         if(self.killindicator_teamchange)
1096                 ClientKill_Now_TeamChange();
1097
1098         // in any case:
1099         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1100
1101         // now I am sure the player IS dead
1102 }
1103 void KillIndicator_Think()
1104 {
1105         if (gameover)
1106         {
1107                 self.owner.killindicator = world;
1108                 remove(self);
1109                 return;
1110         }
1111
1112         if (self.owner.alpha < 0 && !self.owner.vehicle)
1113         {
1114                 self.owner.killindicator = world;
1115                 remove(self);
1116                 return;
1117         }
1118
1119         if(self.cnt <= 0)
1120         {
1121                 self = self.owner;
1122                 ClientKill_Now(); // no oldself needed
1123                 return;
1124         }
1125     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1126     {
1127         self.nextthink = time + 1;
1128         self.cnt -= 1;
1129     }
1130         else
1131         {
1132                 if(self.cnt <= 10)
1133                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1134                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1135                 {
1136                         if(self.cnt <= 10)
1137                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1138                 }
1139                 self.nextthink = time + 1;
1140                 self.cnt -= 1;
1141         }
1142 }
1143
1144 float clientkilltime;
1145 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1146 {
1147         float killtime;
1148         float starttime;
1149         entity e;
1150
1151         if (gameover)
1152                 return;
1153
1154         killtime = autocvar_g_balance_kill_delay;
1155
1156         if(g_race_qualifying || g_cts)
1157                 killtime = 0;
1158
1159     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1160     {
1161                 remove(self.killindicator);
1162                 self.killindicator = world;
1163
1164         ClientKill_Now(); // allow instant kill in this case
1165         return;
1166     }
1167
1168         self.killindicator_teamchange = targetteam;
1169
1170     if(!self.killindicator)
1171         {
1172                 if(self.deadflag == DEAD_NO)
1173                 {
1174                         killtime = max(killtime, self.clientkill_nexttime - time);
1175                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1176                 }
1177
1178                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1179                 {
1180                         ClientKill_Now();
1181                 }
1182                 else
1183                 {
1184                         starttime = max(time, clientkilltime);
1185
1186                         self.killindicator = spawn();
1187                         self.killindicator.owner = self;
1188                         self.killindicator.scale = 0.5;
1189                         setattachment(self.killindicator, self, "");
1190                         setorigin(self.killindicator, '0 0 52');
1191                         self.killindicator.think = KillIndicator_Think;
1192                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1193                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1194                         self.killindicator.cnt = ceil(killtime);
1195                         self.killindicator.count = bound(0, ceil(killtime), 10);
1196                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1197
1198                         for(e = world; (e = find(e, classname, "body")) != world; )
1199                         {
1200                                 if(e.enemy != self)
1201                                         continue;
1202                                 e.killindicator = spawn();
1203                                 e.killindicator.owner = e;
1204                                 e.killindicator.scale = 0.5;
1205                                 setattachment(e.killindicator, e, "");
1206                                 setorigin(e.killindicator, '0 0 52');
1207                                 e.killindicator.think = KillIndicator_Think;
1208                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1209                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1210                                 e.killindicator.cnt = ceil(killtime);
1211                         }
1212                         self.lip = 0;
1213                 }
1214         }
1215         if(self.killindicator)
1216         {
1217                 if(targetteam == 0) // just die
1218                 {
1219                         self.killindicator.colormod = '0 0 0';
1220                         if(clienttype(self) == CLIENTTYPE_REAL)
1221                         if(self.killindicator.cnt > 0)
1222                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1223                 }
1224                 else if(targetteam == -1) // auto
1225                 {
1226                         self.killindicator.colormod = '0 1 0';
1227                         if(clienttype(self) == CLIENTTYPE_REAL)
1228                         if(self.killindicator.cnt > 0)
1229                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1230                 }
1231                 else if(targetteam == -2) // spectate
1232                 {
1233                         self.killindicator.colormod = '0.5 0.5 0.5';
1234                         if(clienttype(self) == CLIENTTYPE_REAL)
1235                         if(self.killindicator.cnt > 0)
1236                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1237                 }
1238                 else
1239                 {
1240                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1241                         if(clienttype(self) == CLIENTTYPE_REAL)
1242                         if(self.killindicator.cnt > 0)
1243                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1244                 }
1245         }
1246
1247 }
1248
1249 void ClientKill (void)
1250 {
1251         if (gameover)
1252                 return;
1253
1254         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1255         {
1256                 // do nothing
1257         }
1258     else if(self.freezetag_frozen)
1259     {
1260         // do nothing
1261     }
1262         else
1263                 ClientKill_TeamChange(0);
1264 }
1265
1266 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1267 {
1268     e.killindicator = spawn();
1269     e.killindicator.owner = e;
1270     e.killindicator.think = KillIndicator_Think;
1271     e.killindicator.nextthink = time + (e.lip) * 0.05;
1272     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1273     e.killindicator.health = 1; // this is used to indicate that it should be silent
1274     e.lip = 0;
1275 }
1276
1277 void FixClientCvars(entity e)
1278 {
1279         // send prediction settings to the client
1280         stuffcmd(e, "\nin_bindmap 0 0\n");
1281         if(g_race || g_cts)
1282                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1283         if(autocvar_g_antilag == 3) // client side hitscan
1284                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1285         if(autocvar_sv_gentle)
1286                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1287         /*
1288          * we no longer need to stuff this. Remove this comment block if you feel
1289          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1290         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1291         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1292         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1293         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1294         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1295         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1296         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1297         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1298         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1299         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1300         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1301         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1302         stuffcmd(e, "cl_movement_edgefriction 1\n");
1303          */
1304 }
1305
1306 float PlayerInIDList(entity p, string idlist)
1307 {
1308         float n, i;
1309         string s;
1310
1311         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1312         if not(p.crypto_idfp)
1313                 return 0;
1314
1315         // this function allows abbreviated player IDs too!
1316         n = tokenize_console(idlist);
1317         for(i = 0; i < n; ++i)
1318         {
1319                 s = argv(i);
1320                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1321                         return 1;
1322         }
1323
1324         return 0;
1325 }
1326
1327 /*
1328 =============
1329 ClientConnect
1330
1331 Called when a client connects to the server
1332 =============
1333 */
1334 void DecodeLevelParms (void);
1335 //void dom_player_join_team(entity pl);
1336 void set_dom_state(entity e);
1337 void ClientConnect (void)
1338 {
1339         float t;
1340
1341         if(self.flags & FL_CLIENT)
1342         {
1343                 print("Warning: ClientConnect, but already connected!\n");
1344                 return;
1345         }
1346
1347         if(Ban_MaybeEnforceBanOnce(self))
1348                 return;
1349
1350         DecodeLevelParms();
1351
1352 #ifdef WATERMARK
1353         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1354 #endif
1355
1356         self.classname = "player_joining";
1357
1358         self.flags = FL_CLIENT;
1359         self.version_nagtime = time + 10 + random() * 10;
1360
1361         if(player_count<0)
1362         {
1363                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1364                 player_count = 0;
1365         }
1366
1367         PlayerScore_Attach(self);
1368         ClientData_Attach();
1369         accuracy_init(self);
1370
1371         bot_clientconnect();
1372
1373         playerdemo_init();
1374
1375         anticheat_init();
1376
1377         race_PreSpawnObserver();
1378
1379         // identify the right forced team
1380         if(autocvar_g_campaign)
1381         {
1382                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1383                 {
1384                         switch(autocvar_g_campaign_forceteam)
1385                         {
1386                                 case 1: self.team_forced = NUM_TEAM_1; break;
1387                                 case 2: self.team_forced = NUM_TEAM_2; break;
1388                                 case 3: self.team_forced = NUM_TEAM_3; break;
1389                                 case 4: self.team_forced = NUM_TEAM_4; break;
1390                                 default: self.team_forced = 0;
1391                         }
1392                 }
1393         }
1394         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1395                 self.team_forced = NUM_TEAM_1;
1396         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1397                 self.team_forced = NUM_TEAM_2;
1398         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1399                 self.team_forced = NUM_TEAM_3;
1400         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1401                 self.team_forced = NUM_TEAM_4;
1402         else if(autocvar_g_forced_team_otherwise == "red")
1403                 self.team_forced = NUM_TEAM_1;
1404         else if(autocvar_g_forced_team_otherwise == "blue")
1405                 self.team_forced = NUM_TEAM_2;
1406         else if(autocvar_g_forced_team_otherwise == "yellow")
1407                 self.team_forced = NUM_TEAM_3;
1408         else if(autocvar_g_forced_team_otherwise == "pink")
1409                 self.team_forced = NUM_TEAM_4;
1410         else if(autocvar_g_forced_team_otherwise == "spectate")
1411                 self.team_forced = -1;
1412         else if(autocvar_g_forced_team_otherwise == "spectator")
1413                 self.team_forced = -1;
1414         else
1415                 self.team_forced = 0;
1416
1417         if(!teamplay)
1418                 if(self.team_forced > 0)
1419                         self.team_forced = 0;
1420
1421         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1422
1423         if(autocvar_g_campaign || self.team_forced < 0) {
1424                 self.classname = "observer";
1425         } else {
1426                 if(teamplay)
1427                 {
1428                         if(autocvar_g_balance_teams)
1429                         {
1430                                 self.classname = "player";
1431                                 campaign_bots_may_start = 1;
1432                         }
1433                         else
1434                         {
1435                                 self.classname = "observer"; // do it anyway
1436                         }
1437                 }
1438                 else
1439                 {
1440                         self.classname = "player";
1441                         campaign_bots_may_start = 1;
1442                 }
1443         }
1444
1445         self.playerid = (playerid_last = playerid_last + 1);
1446
1447         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1448
1449     if(clienttype(self) == CLIENTTYPE_BOT)
1450         PlayerStats_AddPlayer(self);
1451
1452         if(autocvar_sv_eventlog)
1453                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1454
1455         LogTeamchange(self.playerid, self.team, 1);
1456
1457         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1458
1459         self.netname_previous = strzone(self.netname);
1460
1461         if((self.classname == STR_PLAYER && teamplay))
1462                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1463         else
1464                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1465
1466         stuffcmd(self, strcat(clientstuff, "\n"));
1467         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1468
1469         FixClientCvars(self);
1470
1471         // spawnfunc_waypoint sprites
1472         WaypointSprite_InitClient(self);
1473
1474         // Wazat's grappling hook
1475         SetGrappleHookBindings();
1476
1477         // get version info from player
1478         stuffcmd(self, "cmd clientversion $gameversion\n");
1479
1480         // get other cvars from player
1481         GetCvars(0);
1482
1483         // notify about available teams
1484         if(teamplay)
1485         {
1486                 CheckAllowedTeams(self);
1487                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1488                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1489         }
1490         else
1491                 stuffcmd(self, "set _teams_available 0\n");
1492
1493         if(g_arena || g_ca)
1494         {
1495                 self.classname = "observer";
1496                 if(g_arena)
1497                         Spawnqueue_Insert(self);
1498         }
1499
1500         attach_entcs();
1501
1502         bot_relinkplayerlist();
1503
1504         self.spectatortime = time;
1505         if(blockSpectators)
1506         {
1507                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1508         }
1509
1510         self.jointime = time;
1511         self.allowed_timeouts = autocvar_sv_timeout_number;
1512
1513         if(clienttype(self) == CLIENTTYPE_REAL)
1514         {
1515                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1516                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1517         }
1518
1519         if(!sv_foginterval && world.fog != "")
1520                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1521
1522         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1523         {
1524                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1525                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1526         }
1527         else
1528                 self.hitplotfh = -1;
1529
1530         if(g_race || g_cts) {
1531                 string rr;
1532                 if(g_cts)
1533                         rr = CTS_RECORD;
1534                 else
1535                         rr = RACE_RECORD;
1536
1537                 msg_entity = self;
1538                 race_send_recordtime(MSG_ONE);
1539                 race_send_speedaward(MSG_ONE);
1540
1541                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1542                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1543                 race_send_speedaward_alltimebest(MSG_ONE);
1544
1545                 float i;
1546                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1547                         race_SendRankings(i, 0, 0, MSG_ONE);
1548                 }
1549         }
1550         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1551                 send_CSQC_teamnagger();
1552
1553         CheatInitClient();
1554
1555         if(!autocvar_g_campaign)
1556                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1557
1558         CSQCMODEL_AUTOINIT();
1559
1560         self.model_randomizer = random();
1561
1562     if(clienttype(self) != CLIENTTYPE_REAL)
1563         return;
1564
1565     sv_notice_join();
1566
1567     MUTATOR_CALLHOOK(ClientConnect);
1568 }
1569 /*
1570 =============
1571 ClientDisconnect
1572
1573 Called when a client disconnects from the server
1574 =============
1575 */
1576 .entity chatbubbleentity;
1577 void ReadyCount();
1578 void ClientDisconnect (void)
1579 {
1580         if(self.vehicle)
1581             vehicles_exit(VHEF_RELESE);
1582
1583         if not(self.flags & FL_CLIENT)
1584         {
1585                 print("Warning: ClientDisconnect without ClientConnect\n");
1586                 return;
1587         }
1588
1589         PlayerStats_AddGlobalInfo(self);
1590
1591         CheatShutdownClient();
1592
1593         if(self.hitplotfh >= 0)
1594         {
1595                 fclose(self.hitplotfh);
1596                 self.hitplotfh = -1;
1597         }
1598
1599         anticheat_report();
1600         anticheat_shutdown();
1601
1602         playerdemo_shutdown();
1603
1604         bot_clientdisconnect();
1605
1606         if(self.entcs)
1607                 detach_entcs();
1608
1609         if(autocvar_sv_eventlog)
1610                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1611
1612         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1613
1614         MUTATOR_CALLHOOK(ClientDisconnect);
1615
1616         Portal_ClearAll(self);
1617
1618         RemoveGrapplingHook(self);
1619
1620         // Here, everything has been done that requires this player to be a client.
1621
1622         self.flags &~= FL_CLIENT;
1623
1624         if (self.chatbubbleentity)
1625                 remove (self.chatbubbleentity);
1626
1627         if (self.killindicator)
1628                 remove (self.killindicator);
1629
1630         WaypointSprite_PlayerGone();
1631
1632         bot_relinkplayerlist();
1633
1634         if(g_arena)
1635         {
1636                 Spawnqueue_Unmark(self);
1637                 Spawnqueue_Remove(self);
1638         }
1639
1640         accuracy_free(self);
1641         ClientData_Detach();
1642         PlayerScore_Detach(self);
1643
1644         if(self.netname_previous)
1645                 strunzone(self.netname_previous);
1646         if(self.clientstatus)
1647                 strunzone(self.clientstatus);
1648         if(self.weaponorder_byimpulse)
1649                 strunzone(self.weaponorder_byimpulse);
1650
1651         ClearPlayerSounds();
1652
1653         if(self.personal)
1654                 remove(self.personal);
1655
1656         self.playerid = 0;
1657         ReadyCount();
1658
1659         // free cvars
1660         GetCvars(-1);
1661 }
1662
1663 .float BUTTON_CHAT;
1664 void ChatBubbleThink()
1665 {
1666         self.nextthink = time;
1667         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1668         {
1669                 if(self.owner) // but why can that ever be world?
1670                         self.owner.chatbubbleentity = world;
1671                 remove(self);
1672                 return;
1673         }
1674         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1675 #ifdef TETRIS
1676                 || self.owner.tetris_on
1677 #endif
1678         )
1679                 self.model = self.mdl;
1680         else
1681                 self.model = "";
1682 }
1683
1684 void UpdateChatBubble()
1685 {
1686         if (self.alpha < 0)
1687                 return;
1688         // spawn a chatbubble entity if needed
1689         if (!self.chatbubbleentity)
1690         {
1691                 self.chatbubbleentity = spawn();
1692                 self.chatbubbleentity.owner = self;
1693                 self.chatbubbleentity.exteriormodeltoclient = self;
1694                 self.chatbubbleentity.think = ChatBubbleThink;
1695                 self.chatbubbleentity.nextthink = time;
1696                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1697                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1698                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1699                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1700                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1701                 self.chatbubbleentity.model = "";
1702                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1703         }
1704 }
1705
1706
1707 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1708 // added to the model skins
1709 /*void UpdateColorModHack()
1710 {
1711         float c;
1712         c = self.clientcolors & 15;
1713         // LordHavoc: only bothering to support white, green, red, yellow, blue
1714              if (!teamplay) self.colormod = '0 0 0';
1715         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1716         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1717         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1718         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1719         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1720         else self.colormod = '1 1 1';
1721 }*/
1722
1723 void respawn(void)
1724 {
1725         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1726         {
1727                 self.solid = SOLID_NOT;
1728                 self.takedamage = DAMAGE_NO;
1729                 self.movetype = MOVETYPE_FLY;
1730                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1731                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1732                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1733                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1734                 if(autocvar_g_respawn_ghosts_maxtime)
1735                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1736         }
1737
1738         CopyBody(1);
1739
1740         self.effects |= EF_NODRAW; // prevent another CopyBody
1741         PutClientInServer();
1742 }
1743
1744 void play_countdown(float finished, string samp)
1745 {
1746         if(clienttype(self) == CLIENTTYPE_REAL)
1747                 if(floor(finished - time - frametime) != floor(finished - time))
1748                         if(finished - time < 6)
1749                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1750 }
1751
1752 void player_powerups (void)
1753 {
1754         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1755         olditems = self.items;
1756
1757         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1758                 self.modelflags |= MF_ROCKET;
1759         else
1760                 self.modelflags &~= MF_ROCKET;
1761
1762         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1763
1764         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1765                 return;
1766
1767         Fire_ApplyDamage(self);
1768         Fire_ApplyEffect(self);
1769
1770         if (g_minstagib)
1771         {
1772                 self.effects |= EF_FULLBRIGHT;
1773
1774                 if (self.items & IT_STRENGTH)
1775                 {
1776                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1777                         if (time > self.strength_finished)
1778                         {
1779                                 self.alpha = default_player_alpha;
1780                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1781                                 self.items &~= IT_STRENGTH;
1782                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1783                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1784                         }
1785                 }
1786                 else
1787                 {
1788                         if (time < self.strength_finished)
1789                         {
1790                                 self.alpha = g_minstagib_invis_alpha;
1791                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1792                                 self.items |= IT_STRENGTH;
1793                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1794                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1795                         }
1796                 }
1797
1798                 if (self.items & IT_INVINCIBLE)
1799                 {
1800                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1801                         if (time > self.invincible_finished)
1802                         {
1803                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1804                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1805                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1806                         }
1807                 }
1808                 else
1809                 {
1810                         if (time < self.invincible_finished)
1811                         {
1812                                 self.items = self.items | IT_INVINCIBLE;
1813                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1814                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1815                         }
1816                 }
1817         }
1818         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1819         {
1820                 if (self.items & IT_STRENGTH)
1821                 {
1822                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1823                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1824                         if (time > self.strength_finished)
1825                         {
1826                                 self.items = self.items - (self.items & IT_STRENGTH);
1827                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1828                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1829                         }
1830                 }
1831                 else
1832                 {
1833                         if (time < self.strength_finished)
1834                         {
1835                                 self.items = self.items | IT_STRENGTH;
1836                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1837                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1838                         }
1839                 }
1840                 if (self.items & IT_INVINCIBLE)
1841                 {
1842                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1843                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1844                         if (time > self.invincible_finished)
1845                         {
1846                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1847                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1848                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1849                         }
1850                 }
1851                 else
1852                 {
1853                         if (time < self.invincible_finished)
1854                         {
1855                                 self.items = self.items | IT_INVINCIBLE;
1856                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1857                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1858                         }
1859                 }
1860                 if (self.items & IT_SUPERWEAPON)
1861                 {
1862                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1863                         {
1864                                 self.superweapons_finished = 0;
1865                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1866                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1867                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1868                         }
1869                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1870                         {
1871                                 // don't let them run out
1872                         }
1873                         else
1874                         {
1875                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1876                                 if (time > self.superweapons_finished)
1877                                 {
1878                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1879                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1880                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1881                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1882                                 }
1883                         }
1884                 }
1885                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1886                 {
1887                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1888                         {
1889                                 self.items = self.items | IT_SUPERWEAPON;
1890                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1891                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1892                         }
1893                         else
1894                         {
1895                                 self.superweapons_finished = 0;
1896                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1897                         }
1898                 }
1899                 else
1900                 {
1901                         self.superweapons_finished = 0;
1902                 }
1903         }
1904
1905         if(autocvar_g_nodepthtestplayers)
1906                 self.effects = self.effects | EF_NODEPTHTEST;
1907
1908         if(autocvar_g_fullbrightplayers)
1909                 self.effects = self.effects | EF_FULLBRIGHT;
1910
1911         // midair gamemode: damage only while in the air
1912         // if in midair mode, being on ground grants temporary invulnerability
1913         // (this is so that multishot weapon don't clear the ground flag on the
1914         // first damage in the frame, leaving the player vulnerable to the
1915         // remaining hits in the same frame)
1916         if (self.flags & FL_ONGROUND)
1917         if (g_midair)
1918                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1919
1920         if (time >= game_starttime)
1921         if (time < self.spawnshieldtime)
1922                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1923
1924         MUTATOR_CALLHOOK(PlayerPowerups);
1925 }
1926
1927 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1928 {
1929         if(current > stable)
1930                 return current;
1931         else if(current > stable - 0.25) // when close enough, "snap"
1932                 return stable;
1933         else
1934                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1935 }
1936
1937 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1938 {
1939         if(current < stable)
1940                 return current;
1941         else if(current < stable + 0.25) // when close enough, "snap"
1942                 return stable;
1943         else
1944                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1945 }
1946
1947 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1948 {
1949         if(current > rotstable)
1950         {
1951                 if(rotframetime > 0)
1952                 {
1953                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1954                         current = max(rotstable, current - rotlinear * rotframetime);
1955                 }
1956         }
1957         else if(current < regenstable)
1958         {
1959                 if(regenframetime > 0)
1960                 {
1961                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1962                         current = min(regenstable, current + regenlinear * regenframetime);
1963                 }
1964         }
1965
1966         if(current > limit)
1967                 current = limit;
1968
1969         return current;
1970 }
1971
1972 void player_regen (void)
1973 {
1974         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1975         maxh = autocvar_g_balance_health_rotstable;
1976         maxa = autocvar_g_balance_armor_rotstable;
1977         maxf = autocvar_g_balance_fuel_rotstable;
1978         minh = autocvar_g_balance_health_regenstable;
1979         mina = autocvar_g_balance_armor_regenstable;
1980         minf = autocvar_g_balance_fuel_regenstable;
1981         limith = autocvar_g_balance_health_limit;
1982         limita = autocvar_g_balance_armor_limit;
1983         limitf = autocvar_g_balance_fuel_limit;
1984
1985         max_mod = regen_mod = rot_mod = limit_mod = 1;
1986
1987         maxh = maxh * max_mod;
1988         //maxa = maxa * max_mod;
1989         //maxf = maxf * max_mod;
1990         minh = minh * max_mod;
1991         //mina = mina * max_mod;
1992         //minf = minf * max_mod;
1993         limith = limith * limit_mod;
1994         limita = limita * limit_mod;
1995         //limitf = limitf * limit_mod;
1996
1997         if(g_lms && g_ca)
1998                 rot_mod = 0;
1999
2000         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2001         {
2002                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2003                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2004
2005                 // if player rotted to death...  die!
2006                 if(self.health < 1)
2007                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2008         }
2009
2010         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2011                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2012 }
2013
2014 float zoomstate_set;
2015 void SetZoomState(float z)
2016 {
2017         if(z != self.zoomstate)
2018         {
2019                 self.zoomstate = z;
2020                 ClientData_Touch(self);
2021         }
2022         zoomstate_set = 1;
2023 }
2024
2025 void GetPressedKeys(void) {
2026         MUTATOR_CALLHOOK(GetPressedKeys);
2027         if (self.movement_x > 0) // get if movement keys are pressed
2028         {       // forward key pressed
2029                 self.pressedkeys |= KEY_FORWARD;
2030                 self.pressedkeys &~= KEY_BACKWARD;
2031         }
2032         else if (self.movement_x < 0)
2033         {       // backward key pressed
2034                 self.pressedkeys |= KEY_BACKWARD;
2035                 self.pressedkeys &~= KEY_FORWARD;
2036         }
2037         else
2038         {       // no x input
2039                 self.pressedkeys &~= KEY_FORWARD;
2040                 self.pressedkeys &~= KEY_BACKWARD;
2041         }
2042
2043         if (self.movement_y > 0)
2044         {       // right key pressed
2045                 self.pressedkeys |= KEY_RIGHT;
2046                 self.pressedkeys &~= KEY_LEFT;
2047         }
2048         else if (self.movement_y < 0)
2049         {       // left key pressed
2050                 self.pressedkeys |= KEY_LEFT;
2051                 self.pressedkeys &~= KEY_RIGHT;
2052         }
2053         else
2054         {       // no y input
2055                 self.pressedkeys &~= KEY_RIGHT;
2056                 self.pressedkeys &~= KEY_LEFT;
2057         }
2058
2059         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2060                 self.pressedkeys |= KEY_JUMP;
2061         else
2062                 self.pressedkeys &~= KEY_JUMP;
2063         if (self.BUTTON_CROUCH)
2064                 self.pressedkeys |= KEY_CROUCH;
2065         else
2066                 self.pressedkeys &~= KEY_CROUCH;
2067
2068         if (self.BUTTON_ATCK)
2069                 self.pressedkeys |= KEY_ATCK;
2070         else
2071                 self.pressedkeys &~= KEY_ATCK;
2072         if (self.BUTTON_ATCK2)
2073                 self.pressedkeys |= KEY_ATCK2;
2074         else
2075                 self.pressedkeys &~= KEY_ATCK2;
2076 }
2077
2078 /*
2079 ======================
2080 spectate mode routines
2081 ======================
2082 */
2083
2084 void SpectateCopy(entity spectatee) {
2085         other = spectatee;
2086         MUTATOR_CALLHOOK(SpectateCopy);
2087         self.armortype = spectatee.armortype;
2088         self.armorvalue = spectatee.armorvalue;
2089         self.ammo_cells = spectatee.ammo_cells;
2090         self.ammo_shells = spectatee.ammo_shells;
2091         self.ammo_nails = spectatee.ammo_nails;
2092         self.ammo_rockets = spectatee.ammo_rockets;
2093         self.ammo_fuel = spectatee.ammo_fuel;
2094         self.clip_load = spectatee.clip_load;
2095         self.clip_size = spectatee.clip_size;
2096         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2097         self.health = spectatee.health;
2098         self.impulse = 0;
2099         self.items = spectatee.items;
2100         self.last_pickup = spectatee.last_pickup;
2101         self.hit_time = spectatee.hit_time;
2102         self.metertime = spectatee.metertime;
2103         self.strength_finished = spectatee.strength_finished;
2104         self.invincible_finished = spectatee.invincible_finished;
2105         self.pressedkeys = spectatee.pressedkeys;
2106         WEPSET_COPY_EE(self, spectatee);
2107         self.switchweapon = spectatee.switchweapon;
2108         self.switchingweapon = spectatee.switchingweapon;
2109         self.weapon = spectatee.weapon;
2110         self.nex_charge = spectatee.nex_charge;
2111         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2112         self.hagar_load = spectatee.hagar_load;
2113         self.minelayer_mines = spectatee.minelayer_mines;
2114         self.punchangle = spectatee.punchangle;
2115         self.view_ofs = spectatee.view_ofs;
2116         self.velocity = spectatee.velocity;
2117         self.dmg_take = spectatee.dmg_take;
2118         self.dmg_save = spectatee.dmg_save;
2119         self.dmg_inflictor = spectatee.dmg_inflictor;
2120         self.v_angle = spectatee.v_angle;
2121         self.angles = spectatee.v_angle;
2122         self.stat_respawn_time = spectatee.stat_respawn_time;
2123         if(!self.BUTTON_USE)
2124                 self.fixangle = TRUE;
2125         setorigin(self, spectatee.origin);
2126         setsize(self, spectatee.mins, spectatee.maxs);
2127         SetZoomState(spectatee.zoomstate);
2128
2129     anticheat_spectatecopy(spectatee);
2130         self.hud = spectatee.hud;
2131         if(spectatee.vehicle)
2132     {
2133         self.fixangle = FALSE;
2134         //self.velocity = spectatee.vehicle.velocity;
2135         self.vehicle_health = spectatee.vehicle_health;
2136         self.vehicle_shield = spectatee.vehicle_shield;
2137         self.vehicle_energy = spectatee.vehicle_energy;
2138         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2139         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2140         self.vehicle_reload1 = spectatee.vehicle_reload1;
2141         self.vehicle_reload2 = spectatee.vehicle_reload2;
2142
2143         msg_entity = self;
2144
2145         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2146             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2147             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2148             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2149
2150         //WriteByte (MSG_ONE, SVC_SETVIEW);
2151         //    WriteEntity(MSG_ONE, self);
2152         //makevectors(spectatee.v_angle);
2153         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2154     }
2155 }
2156
2157 float SpectateUpdate() {
2158         if(!self.enemy)
2159             return 0;
2160
2161         if (self == self.enemy)
2162                 return 0;
2163
2164         if(self.enemy.classname != "player")
2165                 return 0;
2166
2167         SpectateCopy(self.enemy);
2168
2169         return 1;
2170 }
2171
2172
2173 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2174 entity CA_SpectateNext(entity start) {
2175         if (start.team == self.team) {
2176                 return start;
2177         }
2178
2179         other = start;
2180         // continue from current player
2181         while(other && other.team != self.team) {
2182                 other = find(other, classname, "player");
2183         }
2184
2185         if (!other) {
2186                 // restart from begining
2187                 other = find(other, classname, "player");
2188                 while(other && other.team != self.team) {
2189                         other = find(other, classname, "player");
2190                 }
2191         }
2192
2193         return other;
2194 }
2195
2196 float SpectateNext(entity _prefer) {
2197
2198         if(_prefer)
2199                 other = _prefer;
2200         else
2201                 other = find(self.enemy, classname, "player");
2202
2203         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2204                 // CA and ca players when spectating enemies is forbidden
2205                 other = CA_SpectateNext(other);
2206         } else {
2207                 // other modes and ca spectators or spectating enemies is allowed
2208                 if (!other)
2209                         other = find(other, classname, "player");
2210         }
2211
2212         if (other)
2213                 self.enemy = other;
2214
2215         if(self.enemy.classname == "player") {
2216             /*if(self.enemy.vehicle)
2217             {
2218
2219             msg_entity = self;
2220             WriteByte(MSG_ONE, SVC_SETVIEW);
2221             WriteEntity(MSG_ONE, self.enemy);
2222             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2223
2224             self.movetype = MOVETYPE_NONE;
2225             accuracy_resend(self);
2226             }
2227             else
2228             {*/
2229             msg_entity = self;
2230             WriteByte(MSG_ONE, SVC_SETVIEW);
2231             WriteEntity(MSG_ONE, self.enemy);
2232             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2233             self.movetype = MOVETYPE_NONE;
2234             accuracy_resend(self);
2235
2236             if(!SpectateUpdate())
2237                 PutObserverInServer();
2238         //}
2239         return 1;
2240         } else {
2241                 return 0;
2242         }
2243 }
2244
2245 /*
2246 =============
2247 ShowRespawnCountdown()
2248
2249 Update a respawn countdown display.
2250 =============
2251 */
2252 void ShowRespawnCountdown()
2253 {
2254         float number;
2255         if(self.deadflag == DEAD_NO) // just respawned?
2256                 return;
2257         else
2258         {
2259                 number = ceil(self.respawn_time - time);
2260                 if(number <= 0)
2261                         return;
2262                 if(number <= self.respawn_countdown)
2263                 {
2264                         self.respawn_countdown = number - 1;
2265                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2266                                 AnnounceTo(self, strcat(ftos(number), ""));
2267                 }
2268         }
2269 }
2270
2271 void LeaveSpectatorMode()
2272 {
2273         if(nJoinAllowed(self))
2274         {
2275                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2276                 {
2277                         self.classname = "player";
2278
2279                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2280                                 { JoinBestTeam(self, FALSE, TRUE); }
2281
2282                         if(autocvar_g_campaign)
2283                                 { campaign_bots_may_start = 1; }
2284                         else
2285                                 { Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD); }
2286
2287                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2288
2289                         PutClientInServer();
2290
2291                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2292                 }
2293                 else if not(g_ca && self.caplayer) { stuffcmd(self, "menu_showteamselect\n"); }
2294         }
2295         else
2296         {
2297                 // Player may not join because g_maxplayers is set
2298                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2299         }
2300 }
2301
2302 /**
2303  * Determines whether the player is allowed to join. This depends on cvar
2304  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2305  * it checks whether the number of currently playing players exceeds g_maxplayers.
2306  * @return int number of free slots for players, 0 if none
2307  */
2308 float nJoinAllowed(entity ignore) {
2309         if(!ignore)
2310         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2311         // so report 0 free slots if restricted
2312         {
2313                 if(autocvar_g_forced_team_otherwise == "spectate")
2314                         return 0;
2315                 if(autocvar_g_forced_team_otherwise == "spectator")
2316                         return 0;
2317         }
2318
2319         if(self.team_forced < 0)
2320                 return 0; // forced spectators can never join
2321
2322         // TODO simplify this
2323         entity e;
2324         float totalClients = 0;
2325         FOR_EACH_CLIENT(e)
2326                 if(e != ignore)
2327                         totalClients += 1;
2328
2329         if (!autocvar_g_maxplayers)
2330                 return maxclients - totalClients;
2331
2332         float currentlyPlaying = 0;
2333         FOR_EACH_REALPLAYER(e)
2334                 currentlyPlaying += 1;
2335
2336         if(currentlyPlaying < autocvar_g_maxplayers)
2337                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2338
2339         return 0;
2340 }
2341
2342 /**
2343  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2344  * g_maxplayers_spectator_blocktime seconds
2345  */
2346 void checkSpectatorBlock() {
2347         if(self.classname == "spectator" || self.classname == "observer") {
2348                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2349                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2350                         dropclient(self);
2351                 }
2352         }
2353 }
2354
2355 .float motd_actived_time; // used for both motd and campaign_message
2356 void PrintWelcomeMessage()
2357 {
2358         if (self.motd_actived_time == 0) { // is there already a message showing?
2359                 if (autocvar_g_campaign) {
2360                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2361                                 self.motd_actived_time = time;
2362                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2363                         }
2364                 } else {
2365                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2366                                 self.motd_actived_time = time;
2367                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2368                         }
2369                 }
2370         } else { // showing MOTD or campaign message
2371                 if (autocvar_g_campaign) {
2372                         if (self.BUTTON_INFO)
2373                                 self.motd_actived_time = time;
2374                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2375                                 self.motd_actived_time = 0;
2376                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2377                         }
2378                 } else {
2379                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2380                                 if (self.BUTTON_INFO)
2381                                         self.motd_actived_time = time;
2382                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2383                                         self.motd_actived_time = 0;
2384                                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2385                                 }
2386                         }
2387                 }
2388         }
2389 }
2390
2391 void ObserverThink()
2392 {
2393         float prefered_movetype;
2394         if (self.flags & FL_JUMPRELEASED) {
2395                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2396                         self.flags &~= FL_JUMPRELEASED;
2397                         self.flags |= FL_SPAWNING;
2398                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2399                         self.flags &~= FL_JUMPRELEASED;
2400                         if(SpectateNext(world) == 1) {
2401                                 self.classname = "spectator";
2402                         }
2403                 } else {
2404                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2405                         if (self.movetype != prefered_movetype)
2406                                 self.movetype = prefered_movetype;
2407                 }
2408         } else {
2409                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2410                         self.flags |= FL_JUMPRELEASED;
2411                         if(self.flags & FL_SPAWNING)
2412                         {
2413                                 self.flags &~= FL_SPAWNING;
2414                                 LeaveSpectatorMode();
2415                                 return;
2416                         }
2417                 }
2418         }
2419
2420         PrintWelcomeMessage();
2421 }
2422
2423 void SpectatorThink()
2424 {
2425         if (self.flags & FL_JUMPRELEASED) {
2426                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2427                         self.flags &~= FL_JUMPRELEASED;
2428                         self.flags |= FL_SPAWNING;
2429                 } else if(self.BUTTON_ATCK) {
2430                         self.flags &~= FL_JUMPRELEASED;
2431                         if(SpectateNext(world) == 1) {
2432                                 self.classname = "spectator";
2433                         } else {
2434                                 self.classname = "observer";
2435                                 PutClientInServer();
2436                         }
2437                 } else if (self.BUTTON_ATCK2) {
2438                         self.flags &~= FL_JUMPRELEASED;
2439                         self.classname = "observer";
2440                         PutClientInServer();
2441                 } else {
2442                         if(!SpectateUpdate())
2443                                 PutObserverInServer();
2444                 }
2445         } else {
2446                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2447                         self.flags |= FL_JUMPRELEASED;
2448                         if(self.flags & FL_SPAWNING)
2449                         {
2450                                 self.flags &~= FL_SPAWNING;
2451                                 LeaveSpectatorMode();
2452                                 return;
2453                         }
2454                 }
2455                 if(!SpectateUpdate())
2456                         PutObserverInServer();
2457         }
2458
2459         PrintWelcomeMessage();
2460         self.flags |= FL_CLIENT | FL_NOTARGET;
2461 }
2462
2463 void PlayerUseKey()
2464 {
2465         if(self.classname != "player")
2466                 return;
2467
2468         if(self.vehicle)
2469         {
2470         vehicles_exit(VHEF_NORMAL);
2471         return;
2472         }
2473
2474         // a use key was pressed; call handlers
2475         MUTATOR_CALLHOOK(PlayerUseKey);
2476 }
2477
2478 .float touchexplode_time;
2479
2480 /*
2481 =============
2482 PlayerPreThink
2483
2484 Called every frame for each client before the physics are run
2485 =============
2486 */
2487 .float usekeypressed;
2488 void() nexball_setstatus;
2489 .float items_added;
2490 void PlayerPreThink (void)
2491 {
2492         WarpZone_PlayerPhysics_FixVAngle();
2493
2494         self.stat_game_starttime = game_starttime;
2495         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2496         self.stat_leadlimit = autocvar_leadlimit;
2497
2498         if(g_arena || (g_ca && !allowed_to_spawn))
2499                 self.stat_respawn_time = 0;
2500         else
2501                 self.stat_respawn_time = self.respawn_time;
2502
2503         if(frametime)
2504         {
2505                 // physics frames: update anticheat stuff
2506                 anticheat_prethink();
2507         }
2508
2509         if(blockSpectators && frametime)
2510                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2511                 checkSpectatorBlock();
2512
2513         zoomstate_set = 0;
2514
2515         if(self.netname_previous != self.netname)
2516         {
2517                 if(autocvar_sv_eventlog)
2518                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2519                 if(self.netname_previous)
2520                         strunzone(self.netname_previous);
2521                 self.netname_previous = strzone(self.netname);
2522         }
2523
2524         // version nagging
2525         if(self.version_nagtime)
2526                 if(self.cvar_g_xonoticversion)
2527                         if(time > self.version_nagtime)
2528                         {
2529                                 // don't notify git users
2530                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2531                                 {
2532                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2533                                         {
2534                                                 // notify release users if connecting to git
2535                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2536                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2537                                         }
2538                                         else
2539                                         {
2540                                                 float r;
2541                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2542                                                 if(r < 0)
2543                                                 {
2544                                                         // give users new version
2545                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2546                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2547                                                 }
2548                                                 else if(r > 0)
2549                                                 {
2550                                                         // notify users about old server version
2551                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2552                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2553                                                 }
2554                                         }
2555                                 }
2556                                 self.version_nagtime = 0;
2557                         }
2558
2559         // GOD MODE info
2560         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2561         {
2562                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2563                 self.max_armorvalue = 0;
2564         }
2565
2566 #ifdef TETRIS
2567         if (TetrisPreFrame())
2568                 return;
2569 #endif
2570
2571         MUTATOR_CALLHOOK(PlayerPreThink);
2572
2573         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2574         {
2575                 if(self.BUTTON_USE && !self.usekeypressed)
2576                         PlayerUseKey();
2577                 self.usekeypressed = self.BUTTON_USE;
2578         }
2579
2580         PrintWelcomeMessage();
2581
2582         if(self.classname == "player") {
2583 //              if(self.netname == "Wazat")
2584 //                      bprint(self.classname, "\n");
2585
2586                 CheckRules_Player();
2587
2588                 if (intermission_running)
2589                 {
2590                         IntermissionThink ();   // otherwise a button could be missed between
2591                         return;                                 // the think tics
2592                 }
2593
2594                 //don't allow the player to turn around while game is paused!
2595                 if(timeout_status == TIMEOUT_ACTIVE) {
2596                         // FIXME turn this into CSQC stuff
2597                         self.v_angle = self.lastV_angle;
2598                         self.angles = self.lastV_angle;
2599                         self.fixangle = TRUE;
2600                 }
2601
2602                 if(frametime)
2603                 {
2604                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2605                         {
2606                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2607                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2608                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2609
2610                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2611                                 {
2612                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2613                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2614                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2615                                 }
2616                         }
2617                         else
2618                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2619
2620                         player_powerups();
2621                 }
2622
2623                 if (g_minstagib)
2624                         minstagib_ammocheck();
2625
2626                 if (self.deadflag != DEAD_NO)
2627                 {
2628                         float button_pressed, force_respawn;
2629                         if(self.personal && g_race_qualifying)
2630                         {
2631                                 if(time > self.respawn_time)
2632                                 {
2633                                         self.respawn_time = time + 1; // only retry once a second
2634                                         respawn();
2635                                         self.impulse = 141;
2636                                 }
2637                         }
2638                         else
2639                         {
2640                                 if(frametime)
2641                                         player_anim();
2642                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2643                                 force_respawn = (g_ca || g_cts || autocvar_g_forced_respawn);
2644                                 if (self.deadflag == DEAD_DYING)
2645                                 {
2646                                         if(force_respawn)
2647                                                 self.deadflag = DEAD_RESPAWNING;
2648                                         else if(!button_pressed)
2649                                                 self.deadflag = DEAD_DEAD;
2650                                 }
2651                                 else if (self.deadflag == DEAD_DEAD)
2652                                 {
2653                                         if(button_pressed)
2654                                                 self.deadflag = DEAD_RESPAWNABLE;
2655                                 }
2656                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2657                                 {
2658                                         if(!button_pressed)
2659                                                 self.deadflag = DEAD_RESPAWNING;
2660                                 }
2661                                 else if (self.deadflag == DEAD_RESPAWNING)
2662                                 {
2663                                         if(time > self.respawn_time)
2664                                         {
2665                                                 self.respawn_time = time + 1; // only retry once a second
2666                                                 respawn();
2667                                         }
2668                                 }
2669                                 ShowRespawnCountdown();
2670                         }
2671
2672                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2673                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2674                                 self.stat_respawn_time *= -1;
2675
2676                         return;
2677                 }
2678                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2679                 // so (self.deadflag == DEAD_NO) is always true in the code below
2680
2681                 if(g_touchexplode)
2682                 if(time > self.touchexplode_time)
2683                 if(self.classname == "player")
2684                 if(self.deadflag == DEAD_NO)
2685                 if not(IS_INDEPENDENT_PLAYER(self))
2686                 FOR_EACH_PLAYER(other) if(self != other)
2687                 {
2688                         if(time > other.touchexplode_time)
2689                         if(other.deadflag == DEAD_NO)
2690                         if not(IS_INDEPENDENT_PLAYER(other))
2691                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2692                         {
2693                                 PlayerTouchExplode(self, other);
2694                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2695                         }
2696                 }
2697
2698                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2699                 {
2700                         vector dist;
2701
2702                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2703                         dist = self.prevorigin - self.origin;
2704                         dist_z = 0;
2705                         self.lms_traveled_distance += fabs(vlen(dist));
2706
2707                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2708                         {
2709                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2710                                 self.lms_traveled_distance = 0;
2711                         }
2712
2713                         if(time > self.lms_nextcheck)
2714                         {
2715                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2716                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2717                                 {
2718                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_CAMPCHECK);
2719                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2720                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2721                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2722                                 }
2723                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2724                                 self.lms_traveled_distance = 0;
2725                         }
2726                 }
2727
2728                 self.prevorigin = self.origin;
2729
2730                 float do_crouch = self.BUTTON_CROUCH;
2731                 if(self.hook.state)
2732                         do_crouch = 0;
2733                 if(self.health <= g_bloodloss)
2734                         do_crouch = 1;
2735                 if(self.vehicle)
2736                         do_crouch = 0;
2737                 if(self.freezetag_frozen)
2738                         do_crouch = 0;
2739                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2740                         do_crouch = 0;
2741
2742                 if (do_crouch)
2743                 {
2744                         if (!self.crouch)
2745                         {
2746                                 self.crouch = TRUE;
2747                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2748                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2749                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2750                         }
2751                 }
2752                 else
2753                 {
2754                         if (self.crouch)
2755                         {
2756                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2757                                 if (!trace_startsolid)
2758                                 {
2759                                         self.crouch = FALSE;
2760                                         self.view_ofs = PL_VIEW_OFS;
2761                                         setsize (self, PL_MIN, PL_MAX);
2762                                 }
2763                         }
2764                 }
2765
2766                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2767                 {
2768                         if(self.bloodloss_timer < time)
2769                         {
2770                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2771                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2772                         }
2773                 }
2774
2775                 FixPlayermodel();
2776
2777                 GrapplingHookFrame();
2778
2779                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2780                 //if(frametime)
2781                 {
2782                         self.items &~= self.items_added;
2783
2784                         W_WeaponFrame();
2785
2786                         self.items_added = 0;
2787                         if(self.items & IT_JETPACK)
2788                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2789                                         self.items_added |= IT_FUEL;
2790
2791                         self.items |= self.items_added;
2792                 }
2793
2794                 player_regen();
2795
2796                 // rot nex charge to the charge limit
2797                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2798                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2799
2800                 if(frametime)
2801                         player_anim();
2802
2803                 if(g_nexball)
2804                         nexball_setstatus();
2805
2806                 // secret status
2807                 secrets_setstatus();
2808
2809                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2810
2811                 //self.angles_y=self.v_angle_y + 90;   // temp
2812         } else if(gameover) {
2813                 if (intermission_running)
2814                         IntermissionThink ();   // otherwise a button could be missed between
2815                 return;
2816         } else if(self.classname == "observer") {
2817                 ObserverThink();
2818         } else if(self.classname == "spectator") {
2819                 SpectatorThink();
2820         }
2821
2822         if(!zoomstate_set)
2823                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2824
2825         float oldspectatee_status;
2826         oldspectatee_status = self.spectatee_status;
2827         if(self.classname == "spectator")
2828                 self.spectatee_status = num_for_edict(self.enemy);
2829         else if(self.classname == "observer")
2830                 self.spectatee_status = num_for_edict(self);
2831         else
2832                 self.spectatee_status = 0;
2833         if(self.spectatee_status != oldspectatee_status)
2834         {
2835                 ClientData_Touch(self);
2836                 if(g_race || g_cts)
2837                         race_InitSpectator();
2838         }
2839
2840         if(self.teamkill_soundtime)
2841         if(time > self.teamkill_soundtime)
2842         {
2843                 self.teamkill_soundtime = 0;
2844
2845                 entity oldpusher, oldself;
2846
2847                 oldself = self; self = self.teamkill_soundsource;
2848                 oldpusher = self.pusher; self.pusher = oldself;
2849
2850                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2851
2852                 self.pusher = oldpusher;
2853                 self = oldself;
2854         }
2855
2856         if(self.taunt_soundtime)
2857         if(time > self.taunt_soundtime)
2858         {
2859                 self.taunt_soundtime = 0;
2860                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2861         }
2862
2863         target_voicescript_next(self);
2864
2865         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2866         if(!self.weapon)
2867                 self.clip_load = self.clip_size = 0;
2868 }
2869
2870 float isInvisibleString(string s)
2871 {
2872         float i, n, c;
2873         s = strdecolorize(s);
2874         for((i = 0), (n = strlen(s)); i < n; ++i)
2875         {
2876                 c = str2chr(s, i);
2877                 switch(c)
2878                 {
2879                         case 0:
2880                         case 32: // space
2881                                 break;
2882                         case 192: // charmap space
2883                                 if (!autocvar_utf8_enable)
2884                                         break;
2885                                 return FALSE;
2886                         case 160: // space in unicode fonts
2887                         case 0xE000 + 192: // utf8 charmap space
2888                                 if (autocvar_utf8_enable)
2889                                         break;
2890                         default:
2891                                 return FALSE;
2892                 }
2893         }
2894         return TRUE;
2895 }
2896
2897 /*
2898 =============
2899 PlayerPostThink
2900
2901 Called every frame for each client after the physics are run
2902 =============
2903 */
2904 .float idlekick_lasttimeleft;
2905 void PlayerPostThink (void)
2906 {
2907         // Savage: Check for nameless players
2908         if (isInvisibleString(self.netname)) {
2909                 self.netname = "Player";
2910                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2911         }
2912
2913         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2914         {
2915                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2916                 {
2917                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2918                 }
2919                 else
2920                 {
2921                         float timeleft;
2922                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2923                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2924                         {
2925                                 if(!self.idlekick_lasttimeleft)
2926                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2927                         }
2928                         if(timeleft <= 0)
2929                         {
2930                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2931                                 dropclient(self);
2932                                 return;
2933                         }
2934                         else if(timeleft <= 10)
2935                         {
2936                                 if(timeleft != self.idlekick_lasttimeleft)
2937                                         AnnounceTo(self, ftos(timeleft));
2938                                 self.idlekick_lasttimeleft = timeleft;
2939                         }
2940                 }
2941         }
2942
2943 #ifdef TETRIS
2944         if(self.impulse == 100)
2945                 ImpulseCommands();
2946         if (!TetrisPostFrame())
2947         {
2948 #endif
2949
2950         CheatFrame();
2951
2952         //CheckPlayerJump();
2953
2954         if(self.classname == "player") {
2955                 CheckRules_Player();
2956                 UpdateChatBubble();
2957                 if (self.impulse)
2958                         ImpulseCommands();
2959                 if (intermission_running)
2960                         return;         // intermission or finale
2961                 GetPressedKeys();
2962         }
2963
2964 #ifdef TETRIS
2965         }
2966 #endif
2967
2968         /*
2969         float i;
2970         for(i = 0; i < 1000; ++i)
2971         {
2972                 vector end;
2973                 end = self.origin + '0 0 1024' + 512 * randomvec();
2974                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2975                 if(trace_fraction < 1)
2976                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2977                 {
2978                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2979                         break;
2980                 }
2981         }
2982         */
2983
2984         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2985
2986         if(self.waypointsprite_attachedforcarrier)
2987                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2988
2989         playerdemo_write();
2990
2991         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2992         {
2993                 if not(self.stored_netname)
2994                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2995                 if(self.stored_netname != self.netname)
2996                 {
2997                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2998                         strunzone(self.stored_netname);
2999                         self.stored_netname = strzone(self.netname);
3000                 }
3001         }
3002
3003         /*
3004         if(g_race)
3005                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3006         */
3007
3008         CSQCMODEL_AUTOUPDATE();
3009 }