qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (g_arena && arena_roundbased)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         if(g_lms)
 405         {
 406                 // Only if the player cannot play at all
 407                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 408                         self.frags = FRAGS_SPECTATOR;
 409                 else
 410                         self.frags = FRAGS_LMS_LOSER;
 411         }
 412         else if((g_race && g_race_qualifying) || g_cts)
 413         {
 414                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 415                         self.frags = FRAGS_LMS_LOSER;
 416                 else
 417                         self.frags = FRAGS_SPECTATOR;
 418         }
 419         else
 420                 self.frags = FRAGS_SPECTATOR;
 421
 422         DropAllRunes(self);
 423         MUTATOR_CALLHOOK(MakePlayerObserver);
 424
 425         minstagib_stop_countdown(self);
 426
 427         Portal_ClearAll(self);
 428
 429         if(self.alivetime)
 430         {
 431                 if(!inWarmupStage)
 432                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 433                 self.alivetime = 0;
 434         }
 435
 436         if(self.vehicle)
 437                 vehicles_exit(VHEF_RELESE);
 438
 439         WaypointSprite_PlayerDead();
 440
 441         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 442                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 443
 444         if(self.killcount != -666) {
 445                 if(g_lms) {
 446                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 447                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 448                         else
 449                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 450                 } else
 451                         bprint ("^4", self.netname, "^4 is spectating now\n");
 452
 453                 if(self.just_joined == FALSE) {
 454                         LogTeamchange(self.playerid, -1, 4);
 455                 } else
 456                         self.just_joined = FALSE;
 457         }
 458
 459         PlayerScore_Clear(self); // clear scores when needed
 460
 461         accuracy_resend(self);
 462
 463         self.spectatortime = time;
 464
 465         self.classname = "observer";
 466         self.iscreature = FALSE;
 467         self.teleportable = TELEPORT_SIMPLE;
 468         self.damagedbycontents = FALSE;
 469         self.health = -666;
 470         self.takedamage = DAMAGE_NO;
 471         self.solid = SOLID_NOT;
 472         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 473         self.flags = FL_CLIENT | FL_NOTARGET;
 474         self.armorvalue = 666;
 475         self.effects = 0;
 476         self.armorvalue = autocvar_g_balance_armor_start;
 477         self.pauserotarmor_finished = 0;
 478         self.pauserothealth_finished = 0;
 479         self.pauseregen_finished = 0;
 480         self.damageforcescale = 0;
 481         self.death_time = 0;
 482         self.respawn_time = 0;
 483         self.alpha = 0;
 484         self.scale = 0;
 485         self.fade_time = 0;
 486         self.pain_frame = 0;
 487         self.pain_finished = 0;
 488         self.strength_finished = 0;
 489         self.invincible_finished = 0;
 490         self.superweapons_finished = 0;
 491         self.pushltime = 0;
 492         self.istypefrag = 0;
 493         self.think = func_null;
 494         self.nextthink = 0;
 495         self.hook_time = 0;
 496         self.runes = 0;
 497         self.deadflag = DEAD_NO;
 498         self.angles = spot.angles;
 499         self.angles_z = 0;
 500         self.fixangle = TRUE;
 501         self.crouch = FALSE;
 502
 503         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 504         self.prevorigin = self.origin;
 505         self.items = 0;
 506         WEPSET_CLEAR_E(self);
 507         self.model = "";
 508         FixPlayermodel();
 509         setmodel(self, "null");
 510         self.drawonlytoclient = self;
 511
 512         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 513         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 514
 515         self.weapon = 0;
 516         self.weaponname = "";
 517         self.switchingweapon = 0;
 518         self.weaponmodel = "";
 519         self.weaponentity = world;
 520         self.exteriorweaponentity = world;
 521         self.killcount = -666;
 522         self.velocity = '0 0 0';
 523         self.avelocity = '0 0 0';
 524         self.punchangle = '0 0 0';
 525         self.punchvector = '0 0 0';
 526         self.oldvelocity = self.velocity;
 527         self.fire_endtime = -1;
 528 }
 529
 530 .float model_randomizer;
 531 void FixPlayermodel()
 532 {
 533         string defaultmodel;
 534         float defaultskin, chmdl, oldskin, n, i;
 535         vector m1, m2;
 536
 537         defaultmodel = "";
 538         defaultskin = 0;
 539         chmdl = FALSE;
 540
 541         if(autocvar_sv_defaultcharacter == 1)
 542         {
 543                 if(teamplay)
 544                 {
 545                         string s;
 546                         s = Team_ColorNameLowerCase(self.team);
 547                         if(s != "neutral")
 548                         {
 549                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 550                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 551                         }
 552                 }
 553
 554                 if(defaultmodel == "")
 555                 {
 556                         defaultmodel = autocvar_sv_defaultplayermodel;
 557                         defaultskin = autocvar_sv_defaultplayerskin;
 558                 }
 559
 560                 n = tokenize_console(defaultmodel);
 561                 if(n > 0)
 562                         defaultmodel = argv(floor(n * self.model_randomizer));
 563
 564                 i = strstrofs(defaultmodel, ":", 0);
 565                 if(i >= 0)
 566                 {
 567                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 568                         defaultmodel = substring(defaultmodel, 0, i);
 569                 }
 570         }
 571
 572         if(defaultmodel != "")
 573         {
 574                 if (defaultmodel != self.model)
 575                 {
 576                         m1 = self.mins;
 577                         m2 = self.maxs;
 578                         setplayermodel (self, defaultmodel);
 579                         setsize (self, m1, m2);
 580                         chmdl = TRUE;
 581                 }
 582
 583                 oldskin = self.skin;
 584                 self.skin = defaultskin;
 585         } else {
 586                 if (self.playermodel != self.model || self.playermodel == "")
 587                 {
 588                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 589                         m1 = self.mins;
 590                         m2 = self.maxs;
 591                         setplayermodel (self, self.playermodel);
 592                         setsize (self, m1, m2);
 593                         chmdl = TRUE;
 594                 }
 595
 596                 oldskin = self.skin;
 597                 self.skin = stof(self.playerskin);
 598         }
 599
 600         if(chmdl || oldskin != self.skin)
 601                 self.species = player_getspecies(); // model or skin has changed
 602
 603         if(!teamplay)
 604                 if(strlen(autocvar_sv_defaultplayercolors))
 605                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 606                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 607 }
 608
 609 void PlayerTouchExplode(entity p1, entity p2)
 610 {
 611         vector org;
 612         org = (p1.origin + p2.origin) * 0.5;
 613         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 614
 615         te_explosion(org);
 616
 617         entity e;
 618         e = spawn();
 619         setorigin(e, org);
 620         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 621         remove(e);
 622 }
 623
 624 /*
 625 =============
 626 PutClientInServer
 627
 628 Called when a client spawns in the server
 629 =============
 630 */
 631
 632 void PutClientInServer (void)
 633 {
 634         if(clienttype(self) == CLIENTTYPE_BOT)
 635                 self.classname = "player";
 636         else if(clienttype(self) == CLIENTTYPE_REAL)
 637         {
 638                 msg_entity = self;
 639                 WriteByte(MSG_ONE, SVC_SETVIEW);
 640                 WriteEntity(MSG_ONE, self);
 641         }
 642
 643         // reset player keys
 644         self.itemkeys = 0;
 645
 646         // player is dead and becomes observer
 647         // FIXME fix LMS scoring for new system
 648         if(g_lms)
 649         {
 650                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 651                         self.classname = "observer";
 652         }
 653
 654         MUTATOR_CALLHOOK(PutClientInServer);
 655
 656         if(gameover)
 657                 self.classname = "observer";
 658
 659         if(self.classname == "player") {
 660                 entity spot, oldself;
 661                 float j;
 662
 663                 accuracy_resend(self);
 664
 665                 if(self.team < 0)
 666                         JoinBestTeam(self, FALSE, TRUE);
 667
 668                 race_PreSpawn();
 669
 670                 spot = SelectSpawnPoint (FALSE);
 671                 if(!spot)
 672                 {
 673                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 674                         return; // spawn failed
 675                 }
 676
 677                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 678
 679                 self.classname = "player";
 680                 self.wasplayer = TRUE;
 681                 self.iscreature = TRUE;
 682                 self.teleportable = TELEPORT_NORMAL;
 683                 self.damagedbycontents = TRUE;
 684                 self.movetype = MOVETYPE_WALK;
 685                 self.solid = SOLID_SLIDEBOX;
 686                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 687                 if(autocvar_g_playerclip_collisions)
 688                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 689                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 690                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 691                 self.frags = FRAGS_PLAYER;
 692                 if(INDEPENDENT_PLAYERS)
 693                         MAKE_INDEPENDENT_PLAYER(self);
 694                 self.flags = FL_CLIENT;
 695                 if(autocvar__notarget)
 696                         self.flags |= FL_NOTARGET;
 697                 self.takedamage = DAMAGE_AIM;
 698                 if(g_minstagib)
 699                         self.effects = EF_FULLBRIGHT;
 700                 else
 701                         self.effects = 0;
 702                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 703                 self.air_finished = time + 12;
 704                 self.dmg = 2;
 705                 if(autocvar_g_balance_nex_charge)
 706                 {
 707                         if(autocvar_g_balance_nex_secondary_chargepool)
 708                                 self.nex_chargepool_ammo = 1;
 709                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 710                 }
 711
 712                 if(inWarmupStage)
 713                 {
 714                         self.ammo_shells = warmup_start_ammo_shells;
 715                         self.ammo_nails = warmup_start_ammo_nails;
 716                         self.ammo_rockets = warmup_start_ammo_rockets;
 717                         self.ammo_cells = warmup_start_ammo_cells;
 718                         self.ammo_fuel = warmup_start_ammo_fuel;
 719                         self.health = warmup_start_health;
 720                         self.armorvalue = warmup_start_armorvalue;
 721                         WEPSET_COPY_EA(self, warmup_start_weapons);
 722                 }
 723                 else
 724                 {
 725                         self.ammo_shells = start_ammo_shells;
 726                         self.ammo_nails = start_ammo_nails;
 727                         self.ammo_rockets = start_ammo_rockets;
 728                         self.ammo_cells = start_ammo_cells;
 729                         self.ammo_fuel = start_ammo_fuel;
 730                         self.health = start_health;
 731                         self.armorvalue = start_armorvalue;
 732                         WEPSET_COPY_EA(self, start_weapons);
 733                 }
 734
 735                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 736                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 737                 else
 738                         self.superweapons_finished = 0;
 739
 740                 if(g_weaponarena_random)
 741                 {
 742                         if(g_weaponarena_random_with_laser)
 743                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 744                         W_RandomWeapons(self, g_weaponarena_random);
 745                         if(g_weaponarena_random_with_laser)
 746                                 WEPSET_OR_EW(self, WEP_LASER);
 747                 }
 748
 749                 self.items = start_items;
 750
 751                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 752                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 753                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 754                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 755                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 756                 //extend the pause of rotting if client was reset at the beginning of the countdown
 757                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 758                         self.spawnshieldtime += game_starttime - time;
 759                         self.pauserotarmor_finished += game_starttime - time;
 760                         self.pauserothealth_finished += game_starttime - time;
 761                         self.pauseregen_finished += game_starttime - time;
 762                 }
 763                 self.damageforcescale = 2;
 764                 self.death_time = 0;
 765                 self.respawn_time = 0;
 766                 self.scale = 0;
 767                 self.fade_time = 0;
 768                 self.pain_frame = 0;
 769                 self.pain_finished = 0;
 770                 self.strength_finished = 0;
 771                 self.invincible_finished = 0;
 772                 self.pushltime = 0;
 773                 // players have no think function
 774                 self.think = func_null;
 775                 self.nextthink = 0;
 776                 self.hook_time = 0;
 777                 self.dmg_team = 0;
 778                 self.ballistics_density = autocvar_g_ballistics_density_player;
 779
 780                 self.metertime = 0;
 781
 782                 self.runes = 0;
 783
 784                 self.deadflag = DEAD_NO;
 785
 786                 self.angles = spot.angles;
 787
 788                 self.angles_z = 0; // never spawn tilted even if the spot says to
 789                 self.fixangle = TRUE; // turn this way immediately
 790                 self.velocity = '0 0 0';
 791                 self.avelocity = '0 0 0';
 792                 self.punchangle = '0 0 0';
 793                 self.punchvector = '0 0 0';
 794                 self.oldvelocity = self.velocity;
 795                 self.fire_endtime = -1;
 796
 797                 msg_entity = self;
 798                 WRITESPECTATABLE_MSG_ONE({
 799                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 800                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 801                 });
 802
 803                 self.model = "";
 804                 FixPlayermodel();
 805                 self.drawonlytoclient = world;
 806
 807                 self.crouch = FALSE;
 808                 self.view_ofs = PL_VIEW_OFS;
 809                 setsize (self, PL_MIN, PL_MAX);
 810                 self.spawnorigin = spot.origin;
 811                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 812                 // don't reset back to last position, even if new position is stuck in solid
 813                 self.oldorigin = self.origin;
 814                 self.prevorigin = self.origin;
 815                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 816                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 817         self.hud = HUD_NORMAL;
 818
 819                 self.event_damage = PlayerDamage;
 820
 821                 self.bot_attack = TRUE;
 822
 823                 self.statdraintime = time + 5;
 824                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 825
 826                 if(self.killcount == -666) {
 827                         PlayerScore_Clear(self);
 828                         self.killcount = 0;
 829                 }
 830
 831                 CL_SpawnWeaponentity();
 832                 self.alpha = default_player_alpha;
 833                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 834                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 835
 836                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 837                 self.lms_traveled_distance = 0;
 838                 self.speedrunning = FALSE;
 839
 840                 race_PostSpawn(spot);
 841
 842                 //stuffcmd(self, "chase_active 0");
 843                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 844
 845                 if(g_assault) {
 846                         if(self.team == assault_attacker_team)
 847                                 centerprint(self, "You are attacking!");
 848                         else
 849                                 centerprint(self, "You are defending!");
 850                 }
 851
 852                 target_voicescript_clear(self);
 853
 854                 // reset fields the weapons may use
 855                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 856                 {
 857                         weapon_action(j, WR_RESETPLAYER);
 858
 859                         // all weapons must be fully loaded when we spawn
 860                         entity e;
 861                         e = get_weaponinfo(j);
 862                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 863                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 864                 }
 865
 866                 oldself = self;
 867                 self = spot;
 868                         activator = oldself;
 869                                 string s;
 870                                 s = self.target;
 871                                 self.target = string_null;
 872                                 SUB_UseTargets();
 873                                 self.target = s;
 874                         activator = world;
 875                 self = oldself;
 876
 877                 spawn_spot = spot;
 878                 MUTATOR_CALLHOOK(PlayerSpawn);
 879
 880                 if(autocvar_spawn_debug)
 881                 {
 882                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 883                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 884                 }
 885
 886                 self.switchweapon = w_getbestweapon(self);
 887                 self.cnt = -1; // W_LastWeapon will not complain
 888                 self.weapon = 0;
 889                 self.weaponname = "";
 890                 self.switchingweapon = 0;
 891
 892                 if(!inWarmupStage)
 893                         if(!self.alivetime)
 894                                 self.alivetime = time;
 895
 896                 antilag_clear(self);
 897
 898                 if (autocvar_g_spawnsound)
 899                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 900         } else if(self.classname == "observer") {
 901                 PutObserverInServer ();
 902         }
 903 }
 904
 905 .float ebouncefactor, ebouncestop; // electro's values
 906 // TODO do we need all these fields, or should we stop autodetecting runtime
 907 // changes and just have a console command to update this?
 908 float ClientInit_SendEntity(entity to, float sf)
 909 {
 910         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 911         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 912         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 913         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 914         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 915         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 916         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 917         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 918         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 919         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 920         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 921         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 922         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 923         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 924         if(sv_foginterval && world.fog != "")
 925                 WriteString(MSG_ENTITY, world.fog);
 926         else
 927                 WriteString(MSG_ENTITY, "");
 928         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 929         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 930         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 931         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 932         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 933         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 934         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 935         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 936         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 937         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 938         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 939         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 940         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 941         return TRUE;
 942 }
 943
 944 void ClientInit_CheckUpdate()
 945 {
 946         self.nextthink = time;
 947         if(self.count != autocvar_g_balance_armor_blockpercent)
 948         {
 949                 self.count = autocvar_g_balance_armor_blockpercent;
 950                 self.SendFlags |= 1;
 951         }
 952         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 953         {
 954                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 955                 self.SendFlags |= 1;
 956         }
 957         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 958         {
 959                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 960                 self.SendFlags |= 1;
 961         }
 962         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 963         {
 964                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 965                 self.SendFlags |= 1;
 966         }
 967         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 968         {
 969                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 970                 self.SendFlags |= 1;
 971         }
 972         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 973         {
 974                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 975                 self.SendFlags |= 1;
 976         }
 977 }
 978
 979 void ClientInit_Spawn()
 980 {
 981         entity o;
 982         entity e;
 983         e = spawn();
 984         e.classname = "clientinit";
 985         e.think = ClientInit_CheckUpdate;
 986         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 987
 988         o = self;
 989         self = e;
 990         ClientInit_CheckUpdate();
 991         self = o;
 992 }
 993
 994 /*
 995 =============
 996 SetNewParms
 997 =============
 998 */
 999 void SetNewParms (void)
1000 {
1001         // initialize parms for a new player
1002         parm1 = -(86400 * 366);
1003 }
1004
1005 /*
1006 =============
1007 SetChangeParms
1008 =============
1009 */
1010 void SetChangeParms (void)
1011 {
1012         // save parms for level change
1013         parm1 = self.parm_idlesince - time;
1014 }
1015
1016 /*
1017 =============
1018 DecodeLevelParms
1019 =============
1020 */
1021 void DecodeLevelParms (void)
1022 {
1023         // load parms
1024         self.parm_idlesince = parm1;
1025         if(self.parm_idlesince == -(86400 * 366))
1026                 self.parm_idlesince = time;
1027
1028         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1029         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1030 }
1031
1032 /*
1033 =============
1034 ClientKill
1035
1036 Called when a client types 'kill' in the console
1037 =============
1038 */
1039
1040 .float clientkill_nexttime;
1041 void ClientKill_Now_TeamChange()
1042 {
1043         if(self.killindicator_teamchange == -1)
1044         {
1045                 JoinBestTeam( self, FALSE, TRUE );
1046         }
1047         else if(self.killindicator_teamchange == -2)
1048         {
1049                 if(g_ca)
1050                         self.caplayer = 0;
1051                 if(blockSpectators)
1052                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1053                 PutObserverInServer();
1054         }
1055         else
1056                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1057 }
1058
1059 void ClientKill_Now()
1060 {
1061         if(self.vehicle)
1062         {
1063             vehicles_exit(VHEF_RELESE);
1064             if(!self.killindicator_teamchange)
1065             {
1066             self.vehicle_health = -1;
1067             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1068             }
1069         }
1070
1071         if(self.killindicator && !wasfreed(self.killindicator))
1072                 remove(self.killindicator);
1073
1074         self.killindicator = world;
1075
1076         if(self.killindicator_teamchange)
1077                 ClientKill_Now_TeamChange();
1078
1079         // in any case:
1080         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1081
1082         // now I am sure the player IS dead
1083 }
1084 void KillIndicator_Think()
1085 {
1086         if (gameover)
1087         {
1088                 self.owner.killindicator = world;
1089                 remove(self);
1090                 return;
1091         }
1092
1093         if (self.owner.alpha < 0 && !self.owner.vehicle)
1094         {
1095                 self.owner.killindicator = world;
1096                 remove(self);
1097                 return;
1098         }
1099
1100         if(self.cnt <= 0)
1101         {
1102                 self = self.owner;
1103                 ClientKill_Now(); // no oldself needed
1104                 return;
1105         }
1106     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1107     {
1108         self.nextthink = time + 1;
1109         self.cnt -= 1;
1110     }
1111         else
1112         {
1113                 if(self.cnt <= 10)
1114                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1115                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1116                 {
1117                         if(self.cnt <= 10)
1118                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1119                 }
1120                 self.nextthink = time + 1;
1121                 self.cnt -= 1;
1122         }
1123 }
1124
1125 float clientkilltime;
1126 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1127 {
1128         float killtime;
1129         float starttime;
1130         entity e;
1131
1132         if (gameover)
1133                 return;
1134
1135         killtime = autocvar_g_balance_kill_delay;
1136
1137         if(g_race_qualifying || g_cts)
1138                 killtime = 0;
1139
1140     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1141     {
1142                 remove(self.killindicator);
1143                 self.killindicator = world;
1144
1145         ClientKill_Now(); // allow instant kill in this case
1146         return;
1147     }
1148
1149         self.killindicator_teamchange = targetteam;
1150
1151     if(!self.killindicator)
1152         {
1153                 if(self.deadflag == DEAD_NO)
1154                 {
1155                         killtime = max(killtime, self.clientkill_nexttime - time);
1156                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1157                 }
1158
1159                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1160                 {
1161                         ClientKill_Now();
1162                 }
1163                 else
1164                 {
1165                         starttime = max(time, clientkilltime);
1166
1167                         self.killindicator = spawn();
1168                         self.killindicator.owner = self;
1169                         self.killindicator.scale = 0.5;
1170                         setattachment(self.killindicator, self, "");
1171                         setorigin(self.killindicator, '0 0 52');
1172                         self.killindicator.think = KillIndicator_Think;
1173                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1174                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1175                         self.killindicator.cnt = ceil(killtime);
1176                         self.killindicator.count = bound(0, ceil(killtime), 10);
1177                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1178
1179                         for(e = world; (e = find(e, classname, "body")) != world; )
1180                         {
1181                                 if(e.enemy != self)
1182                                         continue;
1183                                 e.killindicator = spawn();
1184                                 e.killindicator.owner = e;
1185                                 e.killindicator.scale = 0.5;
1186                                 setattachment(e.killindicator, e, "");
1187                                 setorigin(e.killindicator, '0 0 52');
1188                                 e.killindicator.think = KillIndicator_Think;
1189                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1190                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1191                                 e.killindicator.cnt = ceil(killtime);
1192                         }
1193                         self.lip = 0;
1194                 }
1195         }
1196         if(self.killindicator)
1197         {
1198                 if(targetteam == 0) // just die
1199                 {
1200                         self.killindicator.colormod = '0 0 0';
1201                         if(clienttype(self) == CLIENTTYPE_REAL)
1202                         if(self.killindicator.cnt > 0)
1203                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1204                 }
1205                 else if(targetteam == -1) // auto
1206                 {
1207                         self.killindicator.colormod = '0 1 0';
1208                         if(clienttype(self) == CLIENTTYPE_REAL)
1209                         if(self.killindicator.cnt > 0)
1210                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1211                 }
1212                 else if(targetteam == -2) // spectate
1213                 {
1214                         self.killindicator.colormod = '0.5 0.5 0.5';
1215                         if(clienttype(self) == CLIENTTYPE_REAL)
1216                         if(self.killindicator.cnt > 0)
1217                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1218                 }
1219                 else
1220                 {
1221                         self.killindicator.colormod = TeamColor(targetteam);
1222                         if(clienttype(self) == CLIENTTYPE_REAL)
1223                         if(self.killindicator.cnt > 0)
1224                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1225                 }
1226         }
1227
1228 }
1229
1230 void ClientKill (void)
1231 {
1232         if(gameover) return;
1233         if(g_ca && player_count == 1) return;
1234         if(self.player_blocked) return;
1235         if(self.freezetag_frozen) return;
1236
1237         ClientKill_TeamChange(0);
1238 }
1239
1240 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1241 {
1242     e.killindicator = spawn();
1243     e.killindicator.owner = e;
1244     e.killindicator.think = KillIndicator_Think;
1245     e.killindicator.nextthink = time + (e.lip) * 0.05;
1246     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1247     e.killindicator.health = 1; // this is used to indicate that it should be silent
1248     e.lip = 0;
1249 }
1250
1251 void FixClientCvars(entity e)
1252 {
1253         // send prediction settings to the client
1254         stuffcmd(e, "\nin_bindmap 0 0\n");
1255         if(g_race || g_cts)
1256                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1257         if(autocvar_g_antilag == 3) // client side hitscan
1258                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1259         if(sv_gentle)
1260                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1261         /*
1262          * we no longer need to stuff this. Remove this comment block if you feel
1263          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1264         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1265         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1266         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1267         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1268         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1269         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1270         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1271         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1272         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1273         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1274         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1275         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1276         stuffcmd(e, "cl_movement_edgefriction 1\n");
1277          */
1278 }
1279
1280 float PlayerInIDList(entity p, string idlist)
1281 {
1282         float n, i;
1283         string s;
1284
1285         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1286         if not(p.crypto_idfp)
1287                 return 0;
1288
1289         // this function allows abbreviated player IDs too!
1290         n = tokenize_console(idlist);
1291         for(i = 0; i < n; ++i)
1292         {
1293                 s = argv(i);
1294                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1295                         return 1;
1296         }
1297
1298         return 0;
1299 }
1300
1301 /*
1302 =============
1303 ClientConnect
1304
1305 Called when a client connects to the server
1306 =============
1307 */
1308 string ColoredTeamName(float t);
1309 void DecodeLevelParms (void);
1310 //void dom_player_join_team(entity pl);
1311 void set_dom_state(entity e);
1312 void ClientConnect (void)
1313 {
1314         float t;
1315
1316         if(self.flags & FL_CLIENT)
1317         {
1318                 print("Warning: ClientConnect, but already connected!\n");
1319                 return;
1320         }
1321
1322         if(Ban_MaybeEnforceBanOnce(self))
1323                 return;
1324
1325         DecodeLevelParms();
1326
1327 #ifdef WATERMARK
1328         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK, "\n"));
1329 #endif
1330
1331         self.classname = "player_joining";
1332
1333         self.flags = FL_CLIENT;
1334         self.version_nagtime = time + 10 + random() * 10;
1335
1336         if(player_count<0)
1337         {
1338                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1339                 player_count = 0;
1340         }
1341
1342         PlayerScore_Attach(self);
1343         ClientData_Attach();
1344         accuracy_init(self);
1345
1346         bot_clientconnect();
1347
1348         playerdemo_init();
1349
1350         anticheat_init();
1351
1352         race_PreSpawnObserver();
1353
1354         // identify the right forced team
1355         if(autocvar_g_campaign)
1356         {
1357                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1358                 {
1359                         switch(autocvar_g_campaign_forceteam)
1360                         {
1361                                 case 1: self.team_forced = COLOR_TEAM1; break;
1362                                 case 2: self.team_forced = COLOR_TEAM2; break;
1363                                 case 3: self.team_forced = COLOR_TEAM3; break;
1364                                 case 4: self.team_forced = COLOR_TEAM4; break;
1365                                 default: self.team_forced = 0;
1366                         }
1367                 }
1368         }
1369         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1370                 self.team_forced = COLOR_TEAM1;
1371         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1372                 self.team_forced = COLOR_TEAM2;
1373         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1374                 self.team_forced = COLOR_TEAM3;
1375         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1376                 self.team_forced = COLOR_TEAM4;
1377         else if(autocvar_g_forced_team_otherwise == "red")
1378                 self.team_forced = COLOR_TEAM1;
1379         else if(autocvar_g_forced_team_otherwise == "blue")
1380                 self.team_forced = COLOR_TEAM2;
1381         else if(autocvar_g_forced_team_otherwise == "yellow")
1382                 self.team_forced = COLOR_TEAM3;
1383         else if(autocvar_g_forced_team_otherwise == "pink")
1384                 self.team_forced = COLOR_TEAM4;
1385         else if(autocvar_g_forced_team_otherwise == "spectate")
1386                 self.team_forced = -1;
1387         else if(autocvar_g_forced_team_otherwise == "spectator")
1388                 self.team_forced = -1;
1389         else
1390                 self.team_forced = 0;
1391
1392         if(!teamplay)
1393                 if(self.team_forced > 0)
1394                         self.team_forced = 0;
1395
1396         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1397
1398         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1399                 self.classname = "observer";
1400         } else {
1401                 if(teamplay)
1402                 {
1403                         if(autocvar_g_balance_teams)
1404                         {
1405                                 self.classname = "player";
1406                                 campaign_bots_may_start = 1;
1407                         }
1408                         else
1409                         {
1410                                 self.classname = "observer"; // do it anyway
1411                         }
1412                 }
1413                 else
1414                 {
1415                         self.classname = "player";
1416                         campaign_bots_may_start = 1;
1417                 }
1418         }
1419
1420         self.playerid = (playerid_last = playerid_last + 1);
1421
1422         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1423
1424     if(clienttype(self) == CLIENTTYPE_BOT)
1425         PlayerStats_AddPlayer(self);
1426
1427         if(autocvar_sv_eventlog)
1428                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1429
1430         LogTeamchange(self.playerid, self.team, 1);
1431
1432         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1433
1434         self.netname_previous = strzone(self.netname);
1435
1436         bprint("^4", self.netname, "^4 connected");
1437
1438         if(self.classname != "observer" && (g_domination || g_ctf))
1439                 bprint(" and joined the ", ColoredTeamName(self.team));
1440
1441         bprint("\n");
1442
1443         stuffcmd(self, strcat(clientstuff, "\n"));
1444         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1445
1446         FixClientCvars(self);
1447
1448         // spawnfunc_waypoint sprites
1449         WaypointSprite_InitClient(self);
1450
1451         // Wazat's grappling hook
1452         SetGrappleHookBindings();
1453
1454         // get version info from player
1455         stuffcmd(self, "cmd clientversion $gameversion\n");
1456
1457         // get other cvars from player
1458         GetCvars(0);
1459
1460         // notify about available teams
1461         if(teamplay)
1462         {
1463                 CheckAllowedTeams(self);
1464                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1465                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1466         }
1467         else
1468                 stuffcmd(self, "set _teams_available 0\n");
1469
1470         attach_entcs();
1471
1472         bot_relinkplayerlist();
1473
1474         self.spectatortime = time;
1475         if(blockSpectators)
1476         {
1477                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1478         }
1479
1480         self.jointime = time;
1481         self.allowed_timeouts = autocvar_sv_timeout_number;
1482
1483         if(clienttype(self) == CLIENTTYPE_REAL)
1484         {
1485                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1486                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1487         }
1488
1489         if(g_lms)
1490         {
1491                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1492                 {
1493                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1494                         self.frags = FRAGS_SPECTATOR;
1495                 }
1496         }
1497
1498         if(!sv_foginterval && world.fog != "")
1499                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1500
1501         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1502         {
1503                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1504                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1505         }
1506         else
1507                 self.hitplotfh = -1;
1508
1509         if(g_race || g_cts) {
1510                 string rr;
1511                 if(g_cts)
1512                         rr = CTS_RECORD;
1513                 else
1514                         rr = RACE_RECORD;
1515
1516                 msg_entity = self;
1517                 race_send_recordtime(MSG_ONE);
1518                 race_send_speedaward(MSG_ONE);
1519
1520                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1521                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1522                 race_send_speedaward_alltimebest(MSG_ONE);
1523
1524                 float i;
1525                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1526                         race_SendRankings(i, 0, 0, MSG_ONE);
1527                 }
1528         }
1529         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1530                 send_CSQC_teamnagger();
1531
1532         CheatInitClient();
1533
1534         if(!autocvar_g_campaign)
1535                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1536
1537         CSQCMODEL_AUTOINIT();
1538
1539         self.model_randomizer = random();
1540
1541         if(clienttype(self) == CLIENTTYPE_REAL)
1542                 sv_notice_join();
1543
1544         MUTATOR_CALLHOOK(ClientConnect);
1545 }
1546 /*
1547 =============
1548 ClientDisconnect
1549
1550 Called when a client disconnects from the server
1551 =============
1552 */
1553 .entity chatbubbleentity;
1554 void ReadyCount();
1555 void ClientDisconnect (void)
1556 {
1557         if(self.vehicle)
1558             vehicles_exit(VHEF_RELESE);
1559
1560         if not(self.flags & FL_CLIENT)
1561         {
1562                 print("Warning: ClientDisconnect without ClientConnect\n");
1563                 return;
1564         }
1565
1566         PlayerStats_AddGlobalInfo(self);
1567
1568         CheatShutdownClient();
1569
1570         if(self.hitplotfh >= 0)
1571         {
1572                 fclose(self.hitplotfh);
1573                 self.hitplotfh = -1;
1574         }
1575
1576         anticheat_report();
1577         anticheat_shutdown();
1578
1579         playerdemo_shutdown();
1580
1581         bot_clientdisconnect();
1582
1583         if(self.entcs)
1584                 detach_entcs();
1585
1586         if(autocvar_sv_eventlog)
1587                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1588         bprint ("^4",self.netname);
1589         bprint ("^4 disconnected\n");
1590
1591         DropAllRunes(self);
1592         MUTATOR_CALLHOOK(ClientDisconnect);
1593
1594         Portal_ClearAll(self);
1595
1596         RemoveGrapplingHook(self);
1597
1598         // Here, everything has been done that requires this player to be a client.
1599
1600         self.flags &~= FL_CLIENT;
1601
1602         if (self.chatbubbleentity)
1603                 remove (self.chatbubbleentity);
1604
1605         if (self.killindicator)
1606                 remove (self.killindicator);
1607
1608         WaypointSprite_PlayerGone();
1609
1610         bot_relinkplayerlist();
1611
1612         accuracy_free(self);
1613         ClientData_Detach();
1614         PlayerScore_Detach(self);
1615
1616         if(self.netname_previous)
1617                 strunzone(self.netname_previous);
1618         if(self.clientstatus)
1619                 strunzone(self.clientstatus);
1620         if(self.weaponorder_byimpulse)
1621                 strunzone(self.weaponorder_byimpulse);
1622
1623         ClearPlayerSounds();
1624
1625         if(self.personal)
1626                 remove(self.personal);
1627
1628         self.playerid = 0;
1629         ReadyCount();
1630
1631         // free cvars
1632         GetCvars(-1);
1633 }
1634
1635 .float BUTTON_CHAT;
1636 void ChatBubbleThink()
1637 {
1638         self.nextthink = time;
1639         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1640         {
1641                 if(self.owner) // but why can that ever be world?
1642                         self.owner.chatbubbleentity = world;
1643                 remove(self);
1644                 return;
1645         }
1646         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1647 #ifdef TETRIS
1648                 || self.owner.tetris_on
1649 #endif
1650         )
1651                 self.model = self.mdl;
1652         else
1653                 self.model = "";
1654 }
1655
1656 void UpdateChatBubble()
1657 {
1658         if (self.alpha < 0)
1659                 return;
1660         // spawn a chatbubble entity if needed
1661         if (!self.chatbubbleentity)
1662         {
1663                 self.chatbubbleentity = spawn();
1664                 self.chatbubbleentity.owner = self;
1665                 self.chatbubbleentity.exteriormodeltoclient = self;
1666                 self.chatbubbleentity.think = ChatBubbleThink;
1667                 self.chatbubbleentity.nextthink = time;
1668                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1669                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1670                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1671                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1672                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1673                 self.chatbubbleentity.model = "";
1674                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1675         }
1676 }
1677
1678
1679 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1680 // added to the model skins
1681 /*void UpdateColorModHack()
1682 {
1683         float c;
1684         c = self.clientcolors & 15;
1685         // LordHavoc: only bothering to support white, green, red, yellow, blue
1686              if (!teamplay) self.colormod = '0 0 0';
1687         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1688         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1689         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1690         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1691         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1692         else self.colormod = '1 1 1';
1693 }*/
1694
1695 void respawn(void)
1696 {
1697         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1698         {
1699                 self.solid = SOLID_NOT;
1700                 self.takedamage = DAMAGE_NO;
1701                 self.movetype = MOVETYPE_FLY;
1702                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1703                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1704                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1705                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1706                 if(autocvar_g_respawn_ghosts_maxtime)
1707                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1708         }
1709
1710         CopyBody(1);
1711
1712         self.effects |= EF_NODRAW; // prevent another CopyBody
1713         PutClientInServer();
1714 }
1715
1716 void play_countdown(float finished, string samp)
1717 {
1718         if(clienttype(self) == CLIENTTYPE_REAL)
1719                 if(floor(finished - time - frametime) != floor(finished - time))
1720                         if(finished - time < 6)
1721                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1722 }
1723
1724 void player_powerups (void)
1725 {
1726         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1727         olditems = self.items;
1728
1729         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1730                 self.modelflags |= MF_ROCKET;
1731         else
1732                 self.modelflags &~= MF_ROCKET;
1733
1734         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1735
1736         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1737                 return;
1738
1739         Fire_ApplyDamage(self);
1740         Fire_ApplyEffect(self);
1741
1742         if (g_minstagib)
1743         {
1744                 self.effects |= EF_FULLBRIGHT;
1745
1746                 if (self.items & IT_STRENGTH)
1747                 {
1748                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1749                         if (time > self.strength_finished)
1750                         {
1751                                 self.alpha = default_player_alpha;
1752                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1753                                 self.items &~= IT_STRENGTH;
1754                                 sprint(self, "^3Invisibility has worn off\n");
1755                         }
1756                 }
1757                 else
1758                 {
1759                         if (time < self.strength_finished)
1760                         {
1761                                 self.alpha = g_minstagib_invis_alpha;
1762                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1763                                 self.items |= IT_STRENGTH;
1764                                 sprint(self, "^3You are invisible\n");
1765                         }
1766                 }
1767
1768                 if (self.items & IT_INVINCIBLE)
1769                 {
1770                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1771                         if (time > self.invincible_finished)
1772                         {
1773                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1774                                 sprint(self, "^3Speed has worn off\n");
1775                         }
1776                 }
1777                 else
1778                 {
1779                         if (time < self.invincible_finished)
1780                         {
1781                                 self.items = self.items | IT_INVINCIBLE;
1782                                 sprint(self, "^3You are on speed\n");
1783                         }
1784                 }
1785         }
1786         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1787         {
1788                 if (self.items & IT_STRENGTH)
1789                 {
1790                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1791                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1792                         if (time > self.strength_finished)
1793                         {
1794                                 self.items = self.items - (self.items & IT_STRENGTH);
1795                                 sprint(self, "^3Strength has worn off\n");
1796                         }
1797                 }
1798                 else
1799                 {
1800                         if (time < self.strength_finished)
1801                         {
1802                                 self.items = self.items | IT_STRENGTH;
1803                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1804                         }
1805                 }
1806                 if (self.items & IT_INVINCIBLE)
1807                 {
1808                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1809                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1810                         if (time > self.invincible_finished)
1811                         {
1812                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1813                                 sprint(self, "^3Shield has worn off\n");
1814                         }
1815                 }
1816                 else
1817                 {
1818                         if (time < self.invincible_finished)
1819                         {
1820                                 self.items = self.items | IT_INVINCIBLE;
1821                                 sprint(self, "^3Shield surrounds you\n");
1822                         }
1823                 }
1824                 if (self.items & IT_SUPERWEAPON)
1825                 {
1826                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1827                         {
1828                                 self.superweapons_finished = 0;
1829                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1830                                 sprint(self, "^3Superweapons have been lost\n");
1831                         }
1832                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1833                         {
1834                                 // don't let them run out
1835                         }
1836                         else
1837                         {
1838                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1839                                 if (time > self.superweapons_finished)
1840                                 {
1841                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1842                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1843                                         sprint(self, "^3Superweapons have broken down\n");
1844                                 }
1845                         }
1846                 }
1847                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1848                 {
1849                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1850                         {
1851                                 self.items = self.items | IT_SUPERWEAPON;
1852                                 sprint(self, "^3You now have a superweapon\n");
1853                         }
1854                         else
1855                         {
1856                                 self.superweapons_finished = 0;
1857                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1858                         }
1859                 }
1860                 else
1861                 {
1862                         self.superweapons_finished = 0;
1863                 }
1864         }
1865
1866         if(autocvar_g_nodepthtestplayers)
1867                 self.effects = self.effects | EF_NODEPTHTEST;
1868
1869         if(autocvar_g_fullbrightplayers)
1870                 self.effects = self.effects | EF_FULLBRIGHT;
1871
1872         // midair gamemode: damage only while in the air
1873         // if in midair mode, being on ground grants temporary invulnerability
1874         // (this is so that multishot weapon don't clear the ground flag on the
1875         // first damage in the frame, leaving the player vulnerable to the
1876         // remaining hits in the same frame)
1877         if (self.flags & FL_ONGROUND)
1878         if (g_midair)
1879                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1880
1881         if (time >= game_starttime)
1882         if (time < self.spawnshieldtime)
1883                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1884
1885         MUTATOR_CALLHOOK(PlayerPowerups);
1886 }
1887
1888 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1889 {
1890         if(current > stable)
1891                 return current;
1892         else if(current > stable - 0.25) // when close enough, "snap"
1893                 return stable;
1894         else
1895                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1896 }
1897
1898 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1899 {
1900         if(current < stable)
1901                 return current;
1902         else if(current < stable + 0.25) // when close enough, "snap"
1903                 return stable;
1904         else
1905                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1906 }
1907
1908 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1909 {
1910         if(current > rotstable)
1911         {
1912                 if(rotframetime > 0)
1913                 {
1914                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1915                         current = max(rotstable, current - rotlinear * rotframetime);
1916                 }
1917         }
1918         else if(current < regenstable)
1919         {
1920                 if(regenframetime > 0)
1921                 {
1922                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1923                         current = min(regenstable, current + regenlinear * regenframetime);
1924                 }
1925         }
1926
1927         if(current > limit)
1928                 current = limit;
1929
1930         return current;
1931 }
1932
1933 void player_regen (void)
1934 {
1935         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1936         maxh = autocvar_g_balance_health_rotstable;
1937         maxa = autocvar_g_balance_armor_rotstable;
1938         maxf = autocvar_g_balance_fuel_rotstable;
1939         minh = autocvar_g_balance_health_regenstable;
1940         mina = autocvar_g_balance_armor_regenstable;
1941         minf = autocvar_g_balance_fuel_regenstable;
1942         limith = autocvar_g_balance_health_limit;
1943         limita = autocvar_g_balance_armor_limit;
1944         limitf = autocvar_g_balance_fuel_limit;
1945
1946         max_mod = regen_mod = rot_mod = limit_mod = 1;
1947
1948         if (self.runes & RUNE_REGEN)
1949         {
1950                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1951                 {
1952                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1953                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1954                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1955                 }
1956                 else
1957                 {
1958                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
1959                         max_mod = autocvar_g_balance_rune_regen_hpmod;
1960                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
1961                 }
1962         }
1963         else if (self.runes & CURSE_VENOM)
1964         {
1965                 max_mod = autocvar_g_balance_curse_venom_hpmod;
1966                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1967                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
1968                 else
1969                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
1970                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
1971                 //if (!self.runes & RUNE_REGEN)
1972                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
1973         }
1974         maxh = maxh * max_mod;
1975         //maxa = maxa * max_mod;
1976         //maxf = maxf * max_mod;
1977         minh = minh * max_mod;
1978         //mina = mina * max_mod;
1979         //minf = minf * max_mod;
1980         limith = limith * limit_mod;
1981         limita = limita * limit_mod;
1982         //limitf = limitf * limit_mod;
1983
1984         if(g_ca)
1985                 rot_mod = 0;
1986
1987         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1988         {
1989                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1990                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1991
1992                 // if player rotted to death...  die!
1993                 if(self.health < 1)
1994                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1995         }
1996
1997         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1998                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1999 }
2000
2001 float zoomstate_set;
2002 void SetZoomState(float z)
2003 {
2004         if(z != self.zoomstate)
2005         {
2006                 self.zoomstate = z;
2007                 ClientData_Touch(self);
2008         }
2009         zoomstate_set = 1;
2010 }
2011
2012 void GetPressedKeys(void) {
2013         MUTATOR_CALLHOOK(GetPressedKeys);
2014         if (self.movement_x > 0) // get if movement keys are pressed
2015         {       // forward key pressed
2016                 self.pressedkeys |= KEY_FORWARD;
2017                 self.pressedkeys &~= KEY_BACKWARD;
2018         }
2019         else if (self.movement_x < 0)
2020         {       // backward key pressed
2021                 self.pressedkeys |= KEY_BACKWARD;
2022                 self.pressedkeys &~= KEY_FORWARD;
2023         }
2024         else
2025         {       // no x input
2026                 self.pressedkeys &~= KEY_FORWARD;
2027                 self.pressedkeys &~= KEY_BACKWARD;
2028         }
2029
2030         if (self.movement_y > 0)
2031         {       // right key pressed
2032                 self.pressedkeys |= KEY_RIGHT;
2033                 self.pressedkeys &~= KEY_LEFT;
2034         }
2035         else if (self.movement_y < 0)
2036         {       // left key pressed
2037                 self.pressedkeys |= KEY_LEFT;
2038                 self.pressedkeys &~= KEY_RIGHT;
2039         }
2040         else
2041         {       // no y input
2042                 self.pressedkeys &~= KEY_RIGHT;
2043                 self.pressedkeys &~= KEY_LEFT;
2044         }
2045
2046         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2047                 self.pressedkeys |= KEY_JUMP;
2048         else
2049                 self.pressedkeys &~= KEY_JUMP;
2050         if (self.BUTTON_CROUCH)
2051                 self.pressedkeys |= KEY_CROUCH;
2052         else
2053                 self.pressedkeys &~= KEY_CROUCH;
2054
2055         if (self.BUTTON_ATCK)
2056                 self.pressedkeys |= KEY_ATCK;
2057         else
2058                 self.pressedkeys &~= KEY_ATCK;
2059         if (self.BUTTON_ATCK2)
2060                 self.pressedkeys |= KEY_ATCK2;
2061         else
2062                 self.pressedkeys &~= KEY_ATCK2;
2063 }
2064
2065 /*
2066 ======================
2067 spectate mode routines
2068 ======================
2069 */
2070
2071 void SpectateCopy(entity spectatee) {
2072         other = spectatee;
2073         MUTATOR_CALLHOOK(SpectateCopy);
2074         self.armortype = spectatee.armortype;
2075         self.armorvalue = spectatee.armorvalue;
2076         self.ammo_cells = spectatee.ammo_cells;
2077         self.ammo_shells = spectatee.ammo_shells;
2078         self.ammo_nails = spectatee.ammo_nails;
2079         self.ammo_rockets = spectatee.ammo_rockets;
2080         self.ammo_fuel = spectatee.ammo_fuel;
2081         self.clip_load = spectatee.clip_load;
2082         self.clip_size = spectatee.clip_size;
2083         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2084         self.health = spectatee.health;
2085         self.impulse = 0;
2086         self.items = spectatee.items;
2087         self.last_pickup = spectatee.last_pickup;
2088         self.hit_time = spectatee.hit_time;
2089         self.metertime = spectatee.metertime;
2090         self.strength_finished = spectatee.strength_finished;
2091         self.invincible_finished = spectatee.invincible_finished;
2092         self.pressedkeys = spectatee.pressedkeys;
2093         WEPSET_COPY_EE(self, spectatee);
2094         self.switchweapon = spectatee.switchweapon;
2095         self.switchingweapon = spectatee.switchingweapon;
2096         self.weapon = spectatee.weapon;
2097         self.nex_charge = spectatee.nex_charge;
2098         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2099         self.hagar_load = spectatee.hagar_load;
2100         self.minelayer_mines = spectatee.minelayer_mines;
2101         self.punchangle = spectatee.punchangle;
2102         self.view_ofs = spectatee.view_ofs;
2103         self.velocity = spectatee.velocity;
2104         self.dmg_take = spectatee.dmg_take;
2105         self.dmg_save = spectatee.dmg_save;
2106         self.dmg_inflictor = spectatee.dmg_inflictor;
2107         self.v_angle = spectatee.v_angle;
2108         self.angles = spectatee.v_angle;
2109         self.stat_respawn_time = spectatee.stat_respawn_time;
2110         if(!self.BUTTON_USE)
2111                 self.fixangle = TRUE;
2112         setorigin(self, spectatee.origin);
2113         setsize(self, spectatee.mins, spectatee.maxs);
2114         SetZoomState(spectatee.zoomstate);
2115
2116     anticheat_spectatecopy(spectatee);
2117         self.hud = spectatee.hud;
2118         if(spectatee.vehicle)
2119     {
2120         self.fixangle = FALSE;
2121         //self.velocity = spectatee.vehicle.velocity;
2122         self.vehicle_health = spectatee.vehicle_health;
2123         self.vehicle_shield = spectatee.vehicle_shield;
2124         self.vehicle_energy = spectatee.vehicle_energy;
2125         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2126         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2127         self.vehicle_reload1 = spectatee.vehicle_reload1;
2128         self.vehicle_reload2 = spectatee.vehicle_reload2;
2129
2130         msg_entity = self;
2131
2132         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2133             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2134             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2135             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2136
2137         //WriteByte (MSG_ONE, SVC_SETVIEW);
2138         //    WriteEntity(MSG_ONE, self);
2139         //makevectors(spectatee.v_angle);
2140         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2141     }
2142 }
2143
2144 float SpectateUpdate() {
2145         if(!self.enemy)
2146             return 0;
2147
2148         if (self == self.enemy)
2149                 return 0;
2150
2151         if(self.enemy.classname != "player")
2152                 return 0;
2153
2154         SpectateCopy(self.enemy);
2155
2156         return 1;
2157 }
2158
2159
2160 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2161 entity CA_SpectateNext(entity start) {
2162         if (start.team == self.team) {
2163                 return start;
2164         }
2165
2166         other = start;
2167         // continue from current player
2168         while(other && other.team != self.team) {
2169                 other = find(other, classname, "player");
2170         }
2171
2172         if (!other) {
2173                 // restart from begining
2174                 other = find(other, classname, "player");
2175                 while(other && other.team != self.team) {
2176                         other = find(other, classname, "player");
2177                 }
2178         }
2179
2180         return other;
2181 }
2182
2183 float SpectateNext(entity _prefer) {
2184
2185         if(_prefer)
2186                 other = _prefer;
2187         else
2188                 other = find(self.enemy, classname, "player");
2189
2190         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2191                 // CA and ca players when spectating enemies is forbidden
2192                 other = CA_SpectateNext(other);
2193         } else {
2194                 // other modes and ca spectators or spectating enemies is allowed
2195                 if (!other)
2196                         other = find(other, classname, "player");
2197         }
2198
2199         if (other)
2200                 self.enemy = other;
2201
2202         if(self.enemy.classname == "player") {
2203             /*if(self.enemy.vehicle)
2204             {
2205
2206             msg_entity = self;
2207             WriteByte(MSG_ONE, SVC_SETVIEW);
2208             WriteEntity(MSG_ONE, self.enemy);
2209             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2210
2211             self.movetype = MOVETYPE_NONE;
2212             accuracy_resend(self);
2213             }
2214             else
2215             {*/
2216             msg_entity = self;
2217             WriteByte(MSG_ONE, SVC_SETVIEW);
2218             WriteEntity(MSG_ONE, self.enemy);
2219             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2220             self.movetype = MOVETYPE_NONE;
2221             accuracy_resend(self);
2222
2223             if(!SpectateUpdate())
2224                 PutObserverInServer();
2225         //}
2226         return 1;
2227         } else {
2228                 return 0;
2229         }
2230 }
2231
2232 /*
2233 =============
2234 ShowRespawnCountdown()
2235
2236 Update a respawn countdown display.
2237 =============
2238 */
2239 void ShowRespawnCountdown()
2240 {
2241         float number;
2242         if(self.deadflag == DEAD_NO) // just respawned?
2243                 return;
2244         else
2245         {
2246                 number = ceil(self.respawn_time - time);
2247                 if(number <= 0)
2248                         return;
2249                 if(number <= self.respawn_countdown)
2250                 {
2251                         self.respawn_countdown = number - 1;
2252                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2253                                 AnnounceTo(self, strcat(ftos(number), ""));
2254                 }
2255         }
2256 }
2257
2258 .float prevent_join_msgtime;
2259 void LeaveSpectatorMode()
2260 {
2261         if(nJoinAllowed(self)) {
2262                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2263                         self.classname = "player";
2264
2265                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2266                                 JoinBestTeam(self, FALSE, TRUE);
2267
2268                         if(autocvar_g_campaign)
2269                                 campaign_bots_may_start = 1;
2270
2271                         PutClientInServer();
2272
2273                         if(self.classname == "player")
2274                                 bprint ("^4", self.netname, "^4 is playing now\n");
2275
2276                         if(!autocvar_g_campaign)
2277                         if (time < self.jointime + autocvar_welcome_message_time)
2278                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2279
2280                         if (self.prevent_join_msgtime)
2281                         {
2282                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2283                                 self.prevent_join_msgtime = 0;
2284                         }
2285
2286                         return;
2287                 } else {
2288                         if (g_ca && self.caplayer) {
2289                         }       // do nothing
2290                         else
2291                                 stuffcmd(self,"menu_showteamselect\n");
2292                         return;
2293                 }
2294         }
2295         else {
2296                 //player may not join because of g_maxplayers is set
2297                 if (time - self.prevent_join_msgtime > 2)
2298                 {
2299                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2300                         self.prevent_join_msgtime = time;
2301                 }
2302         }
2303 }
2304
2305 /**
2306  * Determines whether the player is allowed to join. This depends on cvar
2307  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2308  * it checks whether the number of currently playing players exceeds g_maxplayers.
2309  * @return int number of free slots for players, 0 if none
2310  */
2311 float nJoinAllowed(entity ignore) {
2312         if(!ignore)
2313         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2314         // so report 0 free slots if restricted
2315         {
2316                 if(autocvar_g_forced_team_otherwise == "spectate")
2317                         return 0;
2318                 if(autocvar_g_forced_team_otherwise == "spectator")
2319                         return 0;
2320         }
2321
2322         if(self.team_forced < 0)
2323                 return 0; // forced spectators can never join
2324
2325         // TODO simplify this
2326         entity e;
2327         float totalClients = 0;
2328         FOR_EACH_CLIENT(e)
2329                 if(e != ignore)
2330                         totalClients += 1;
2331
2332         if (!autocvar_g_maxplayers)
2333                 return maxclients - totalClients;
2334
2335         float currentlyPlaying = 0;
2336         FOR_EACH_REALPLAYER(e)
2337                 currentlyPlaying += 1;
2338
2339         if(currentlyPlaying < autocvar_g_maxplayers)
2340                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2341
2342         return 0;
2343 }
2344
2345 /**
2346  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2347  * g_maxplayers_spectator_blocktime seconds
2348  */
2349 void checkSpectatorBlock() {
2350         if(self.classname == "spectator" || self.classname == "observer") {
2351                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2352                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2353                         dropclient(self);
2354                 }
2355         }
2356 }
2357
2358 .float motd_actived_time; // used for both motd and campaign_message
2359 void PrintWelcomeMessage()
2360 {
2361         if (self.motd_actived_time == 0) { // is there already a message showing?
2362                 if (autocvar_g_campaign) {
2363                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2364                                 self.motd_actived_time = time;
2365                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2366                         }
2367                 } else {
2368                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2369                                 self.motd_actived_time = time;
2370                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2371                         }
2372                 }
2373         } else { // showing MOTD or campaign message
2374                 if (autocvar_g_campaign) {
2375                         if (self.BUTTON_INFO)
2376                                 self.motd_actived_time = time;
2377                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2378                                 self.motd_actived_time = 0;
2379                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2380                         }
2381                 } else {
2382                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2383                                 if (self.BUTTON_INFO)
2384                                         self.motd_actived_time = time;
2385                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2386                                         self.motd_actived_time = 0;
2387                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2388                                 }
2389                         }
2390                 }
2391         }
2392 }
2393
2394 void ObserverThink()
2395 {
2396         float prefered_movetype;
2397         if (self.flags & FL_JUMPRELEASED) {
2398                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2399                         self.flags &~= FL_JUMPRELEASED;
2400                         self.flags |= FL_SPAWNING;
2401                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2402                         self.flags &~= FL_JUMPRELEASED;
2403                         if(SpectateNext(world) == 1) {
2404                                 self.classname = "spectator";
2405                         }
2406                 } else {
2407                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2408                         if (self.movetype != prefered_movetype)
2409                                 self.movetype = prefered_movetype;
2410                 }
2411         } else {
2412                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2413                         self.flags |= FL_JUMPRELEASED;
2414                         if(self.flags & FL_SPAWNING)
2415                         {
2416                                 self.flags &~= FL_SPAWNING;
2417                                 LeaveSpectatorMode();
2418                                 return;
2419                         }
2420                 }
2421         }
2422
2423         PrintWelcomeMessage();
2424 }
2425
2426 void SpectatorThink()
2427 {
2428         if (self.flags & FL_JUMPRELEASED) {
2429                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2430                         self.flags &~= FL_JUMPRELEASED;
2431                         self.flags |= FL_SPAWNING;
2432                 } else if(self.BUTTON_ATCK) {
2433                         self.flags &~= FL_JUMPRELEASED;
2434                         if(SpectateNext(world) == 1) {
2435                                 self.classname = "spectator";
2436                         } else {
2437                                 self.classname = "observer";
2438                                 PutClientInServer();
2439                         }
2440                 } else if (self.BUTTON_ATCK2) {
2441                         self.flags &~= FL_JUMPRELEASED;
2442                         self.classname = "observer";
2443                         PutClientInServer();
2444                 } else {
2445                         if(!SpectateUpdate())
2446                                 PutObserverInServer();
2447                 }
2448         } else {
2449                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2450                         self.flags |= FL_JUMPRELEASED;
2451                         if(self.flags & FL_SPAWNING)
2452                         {
2453                                 self.flags &~= FL_SPAWNING;
2454                                 LeaveSpectatorMode();
2455                                 return;
2456                         }
2457                 }
2458                 if(!SpectateUpdate())
2459                         PutObserverInServer();
2460         }
2461
2462         PrintWelcomeMessage();
2463         self.flags |= FL_CLIENT | FL_NOTARGET;
2464 }
2465
2466 void PlayerUseKey()
2467 {
2468         if(self.classname != "player")
2469                 return;
2470
2471         if(self.vehicle)
2472         {
2473         vehicles_exit(VHEF_NORMAL);
2474         return;
2475         }
2476
2477         // a use key was pressed; call handlers
2478         MUTATOR_CALLHOOK(PlayerUseKey);
2479 }
2480
2481 .float touchexplode_time;
2482
2483 /*
2484 =============
2485 PlayerPreThink
2486
2487 Called every frame for each client before the physics are run
2488 =============
2489 */
2490 .float usekeypressed;
2491 void() nexball_setstatus;
2492 .float items_added;
2493 void PlayerPreThink (void)
2494 {
2495         WarpZone_PlayerPhysics_FixVAngle();
2496
2497         self.stat_game_starttime = game_starttime;
2498         self.stat_round_starttime = round_starttime;
2499         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2500         self.stat_leadlimit = autocvar_leadlimit;
2501
2502         self.stat_respawn_time = self.respawn_time;
2503
2504         if(frametime)
2505         {
2506                 // physics frames: update anticheat stuff
2507                 anticheat_prethink();
2508         }
2509
2510         if(blockSpectators && frametime)
2511                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2512                 checkSpectatorBlock();
2513
2514         zoomstate_set = 0;
2515
2516         if(self.netname_previous != self.netname)
2517         {
2518                 if(autocvar_sv_eventlog)
2519                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2520                 if(self.netname_previous)
2521                         strunzone(self.netname_previous);
2522                 self.netname_previous = strzone(self.netname);
2523         }
2524
2525         // version nagging
2526         if(self.version_nagtime)
2527                 if(self.cvar_g_xonoticversion)
2528                         if(time > self.version_nagtime)
2529                         {
2530                                 // don't notify git users
2531                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2532                                 {
2533                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2534                                         {
2535                                                 // notify release users if connecting to git
2536                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2537                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2538                                         }
2539                                         else
2540                                         {
2541                                                 float r;
2542                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2543                                                 if(r < 0)
2544                                                 {
2545                                                         // give users new version
2546                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2547                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2548                                                 }
2549                                                 else if(r > 0)
2550                                                 {
2551                                                         // notify users about old server version
2552                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2553                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2554                                                 }
2555                                         }
2556                                 }
2557                                 self.version_nagtime = 0;
2558                         }
2559
2560         // GOD MODE info
2561         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2562         {
2563                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2564                 self.max_armorvalue = 0;
2565         }
2566
2567 #ifdef TETRIS
2568         if (TetrisPreFrame())
2569                 return;
2570 #endif
2571
2572         MUTATOR_CALLHOOK(PlayerPreThink);
2573
2574         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2575         {
2576                 if(self.BUTTON_USE && !self.usekeypressed)
2577                         PlayerUseKey();
2578                 self.usekeypressed = self.BUTTON_USE;
2579         }
2580
2581         PrintWelcomeMessage();
2582
2583         if(self.classname == "player") {
2584 //              if(self.netname == "Wazat")
2585 //                      bprint(self.classname, "\n");
2586
2587                 CheckRules_Player();
2588
2589                 if (intermission_running)
2590                 {
2591                         IntermissionThink ();   // otherwise a button could be missed between
2592                         return;                                 // the think tics
2593                 }
2594
2595                 //don't allow the player to turn around while game is paused!
2596                 if(timeout_status == TIMEOUT_ACTIVE) {
2597                         // FIXME turn this into CSQC stuff
2598                         self.v_angle = self.lastV_angle;
2599                         self.angles = self.lastV_angle;
2600                         self.fixangle = TRUE;
2601                 }
2602
2603                 if(frametime)
2604                 {
2605                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2606                         {
2607                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2608                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2609                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2610
2611                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2612                                 {
2613                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2614                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2615                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2616                                 }
2617                         }
2618                         else
2619                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2620
2621                         player_powerups();
2622                 }
2623
2624                 if (g_minstagib)
2625                         minstagib_ammocheck();
2626
2627                 if (self.deadflag != DEAD_NO)
2628                 {
2629                         float button_pressed, force_respawn;
2630                         if(self.personal && g_race_qualifying)
2631                         {
2632                                 if(time > self.respawn_time)
2633                                 {
2634                                         self.respawn_time = time + 1; // only retry once a second
2635                                         respawn();
2636                                         self.impulse = 141;
2637                                 }
2638                         }
2639                         else
2640                         {
2641                                 if(frametime)
2642                                         player_anim();
2643                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2644                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2645                                 if (self.deadflag == DEAD_DYING)
2646                                 {
2647                                         if(force_respawn)
2648                                                 self.deadflag = DEAD_RESPAWNING;
2649                                         else if(!button_pressed)
2650                                                 self.deadflag = DEAD_DEAD;
2651                                 }
2652                                 else if (self.deadflag == DEAD_DEAD)
2653                                 {
2654                                         if(button_pressed)
2655                                                 self.deadflag = DEAD_RESPAWNABLE;
2656                                 }
2657                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2658                                 {
2659                                         if(!button_pressed)
2660                                                 self.deadflag = DEAD_RESPAWNING;
2661                                 }
2662                                 else if (self.deadflag == DEAD_RESPAWNING)
2663                                 {
2664                                         if(time > self.respawn_time)
2665                                         {
2666                                                 self.respawn_time = time + 1; // only retry once a second
2667                                                 respawn();
2668                                         }
2669                                 }
2670                                 ShowRespawnCountdown();
2671                         }
2672
2673                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2674                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2675                                 self.stat_respawn_time *= -1;
2676
2677                         return;
2678                 }
2679                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2680                 // so (self.deadflag == DEAD_NO) is always true in the code below
2681
2682                 if(g_touchexplode)
2683                 if(time > self.touchexplode_time)
2684                 if(self.classname == "player")
2685                 if(self.deadflag == DEAD_NO)
2686                 if not(IS_INDEPENDENT_PLAYER(self))
2687                 FOR_EACH_PLAYER(other) if(self != other)
2688                 {
2689                         if(time > other.touchexplode_time)
2690                         if(other.deadflag == DEAD_NO)
2691                         if not(IS_INDEPENDENT_PLAYER(other))
2692                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2693                         {
2694                                 PlayerTouchExplode(self, other);
2695                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2696                         }
2697                 }
2698
2699                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2700                 {
2701                         vector dist;
2702
2703                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2704                         dist = self.prevorigin - self.origin;
2705                         dist_z = 0;
2706                         self.lms_traveled_distance += fabs(vlen(dist));
2707
2708                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2709                         {
2710                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2711                                 self.lms_traveled_distance = 0;
2712                         }
2713
2714                         if(time > self.lms_nextcheck)
2715                         {
2716                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2717                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2718                                 {
2719                                         centerprint(self, autocvar_g_lms_campcheck_message);
2720                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2721                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2722                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2723                                 }
2724                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2725                                 self.lms_traveled_distance = 0;
2726                         }
2727                 }
2728
2729                 self.prevorigin = self.origin;
2730
2731                 float do_crouch = self.BUTTON_CROUCH;
2732                 if(self.hook.state)
2733                         do_crouch = 0;
2734                 if(self.health <= g_bloodloss)
2735                         do_crouch = 1;
2736                 if(self.vehicle)
2737                         do_crouch = 0;
2738                 if(self.freezetag_frozen)
2739                         do_crouch = 0;
2740                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2741                         do_crouch = 0;
2742
2743                 if (do_crouch)
2744                 {
2745                         if (!self.crouch)
2746                         {
2747                                 self.crouch = TRUE;
2748                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2749                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2750                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2751                         }
2752                 }
2753                 else
2754                 {
2755                         if (self.crouch)
2756                         {
2757                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2758                                 if (!trace_startsolid)
2759                                 {
2760                                         self.crouch = FALSE;
2761                                         self.view_ofs = PL_VIEW_OFS;
2762                                         setsize (self, PL_MIN, PL_MAX);
2763                                 }
2764                         }
2765                 }
2766
2767                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2768                 {
2769                         if(self.bloodloss_timer < time)
2770                         {
2771                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2772                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2773                         }
2774                 }
2775
2776                 FixPlayermodel();
2777
2778                 GrapplingHookFrame();
2779
2780                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2781                 //if(frametime)
2782                 {
2783                         self.items &~= self.items_added;
2784
2785                         W_WeaponFrame();
2786
2787                         self.items_added = 0;
2788                         if(self.items & IT_JETPACK)
2789                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2790                                         self.items_added |= IT_FUEL;
2791
2792                         self.items |= self.items_added;
2793                 }
2794
2795                 player_regen();
2796
2797                 // rot nex charge to the charge limit
2798                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2799                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2800
2801                 if(frametime)
2802                         player_anim();
2803
2804                 if(g_nexball)
2805                         nexball_setstatus();
2806
2807                 // secret status
2808                 secrets_setstatus();
2809
2810                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2811
2812                 //self.angles_y=self.v_angle_y + 90;   // temp
2813         } else if(gameover) {
2814                 if (intermission_running)
2815                         IntermissionThink ();   // otherwise a button could be missed between
2816                 return;
2817         } else if(self.classname == "observer") {
2818                 ObserverThink();
2819         } else if(self.classname == "spectator") {
2820                 SpectatorThink();
2821         }
2822
2823         if(!zoomstate_set)
2824                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2825
2826         float oldspectatee_status;
2827         oldspectatee_status = self.spectatee_status;
2828         if(self.classname == "spectator")
2829                 self.spectatee_status = num_for_edict(self.enemy);
2830         else if(self.classname == "observer")
2831                 self.spectatee_status = num_for_edict(self);
2832         else
2833                 self.spectatee_status = 0;
2834         if(self.spectatee_status != oldspectatee_status)
2835         {
2836                 ClientData_Touch(self);
2837                 if(g_race || g_cts)
2838                         race_InitSpectator();
2839         }
2840
2841         if(self.teamkill_soundtime)
2842         if(time > self.teamkill_soundtime)
2843         {
2844                 self.teamkill_soundtime = 0;
2845
2846                 entity oldpusher, oldself;
2847
2848                 oldself = self; self = self.teamkill_soundsource;
2849                 oldpusher = self.pusher; self.pusher = oldself;
2850
2851                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2852
2853                 self.pusher = oldpusher;
2854                 self = oldself;
2855         }
2856
2857         if(self.taunt_soundtime)
2858         if(time > self.taunt_soundtime)
2859         {
2860                 self.taunt_soundtime = 0;
2861                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2862         }
2863
2864         target_voicescript_next(self);
2865
2866         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2867         if(!self.weapon)
2868                 self.clip_load = self.clip_size = 0;
2869 }
2870
2871 float isInvisibleString(string s)
2872 {
2873         float i, n, c;
2874         s = strdecolorize(s);
2875         for((i = 0), (n = strlen(s)); i < n; ++i)
2876         {
2877                 c = str2chr(s, i);
2878                 switch(c)
2879                 {
2880                         case 0:
2881                         case 32: // space
2882                                 break;
2883                         case 192: // charmap space
2884                                 if (!autocvar_utf8_enable)
2885                                         break;
2886                                 return FALSE;
2887                         case 160: // space in unicode fonts
2888                         case 0xE000 + 192: // utf8 charmap space
2889                                 if (autocvar_utf8_enable)
2890                                         break;
2891                         default:
2892                                 return FALSE;
2893                 }
2894         }
2895         return TRUE;
2896 }
2897
2898 /*
2899 =============
2900 PlayerPostThink
2901
2902 Called every frame for each client after the physics are run
2903 =============
2904 */
2905 .float idlekick_lasttimeleft;
2906 void PlayerPostThink (void)
2907 {
2908         // Savage: Check for nameless players
2909         if (isInvisibleString(self.netname)) {
2910                 self.netname = "Player";
2911                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2912         }
2913
2914         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2915         {
2916                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2917                 {
2918                         if(self.idlekick_lasttimeleft)
2919                         {
2920                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2921                                 self.idlekick_lasttimeleft = 0;
2922                         }
2923                 }
2924                 else
2925                 {
2926                         float timeleft;
2927                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2928                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2929                         {
2930                                 if(!self.idlekick_lasttimeleft)
2931                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2932                         }
2933                         if(timeleft <= 0)
2934                         {
2935                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2936                                 AnnounceTo(self, "terminated");
2937                                 dropclient(self);
2938                                 return;
2939                         }
2940                         else if(timeleft <= 10)
2941                         {
2942                                 if(timeleft != self.idlekick_lasttimeleft)
2943                                         AnnounceTo(self, ftos(timeleft));
2944                                 self.idlekick_lasttimeleft = timeleft;
2945                         }
2946                 }
2947         }
2948
2949 #ifdef TETRIS
2950         if(self.impulse == 100)
2951                 ImpulseCommands();
2952         if (!TetrisPostFrame())
2953         {
2954 #endif
2955
2956         CheatFrame();
2957
2958         //CheckPlayerJump();
2959
2960         if(self.classname == "player") {
2961                 CheckRules_Player();
2962                 UpdateChatBubble();
2963                 if (self.impulse)
2964                         ImpulseCommands();
2965                 if (intermission_running)
2966                         return;         // intermission or finale
2967                 GetPressedKeys();
2968         }
2969
2970 #ifdef TETRIS
2971         }
2972 #endif
2973
2974         /*
2975         float i;
2976         for(i = 0; i < 1000; ++i)
2977         {
2978                 vector end;
2979                 end = self.origin + '0 0 1024' + 512 * randomvec();
2980                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2981                 if(trace_fraction < 1)
2982                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2983                 {
2984                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2985                         break;
2986                 }
2987         }
2988         */
2989
2990         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2991
2992         if(self.waypointsprite_attachedforcarrier)
2993                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2994
2995         playerdemo_write();
2996
2997         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2998         {
2999                 if not(self.stored_netname)
3000                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3001                 if(self.stored_netname != self.netname)
3002                 {
3003                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3004                         strunzone(self.stored_netname);
3005                         self.stored_netname = strzone(self.netname);
3006                 }
3007         }
3008
3009         /*
3010         if(g_race)
3011                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3012         */
3013
3014         CSQCMODEL_AUTOUPDATE();
3015 }