qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "waypointsprites.qh"
   4
   5 #include "anticheat.qh"
   6 #include "cl_impulse.qh"
   7 #include "cl_player.qh"
   8 #include "ent_cs.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "g_damage.qh"
  16 #include "g_hook.qh"
  17 #include "command/common.qh"
  18 #include "cheats.qh"
  19 #include "g_world.qh"
  20 #include "race.qh"
  21 #include "antilag.qh"
  22 #include "campaign.qh"
  23 #include "command/common.qh"
  24
  25 #include "bot/bot.qh"
  26 #include "bot/navigation.qh"
  27
  28 #include "vehicles/vehicle.qh"
  29
  30 #include "weapons/hitplot.qh"
  31 #include "weapons/weaponsystem.qh"
  32
  33 #include "../common/net_notice.qh"
  34 #include "../common/physics.qh"
  35
  36 #include "../common/triggers/subs.qh"
  37 #include "../common/triggers/triggers.qh"
  38 #include "../common/triggers/trigger/secret.qh"
  39
  40 #include "../common/items/inventory.qh"
  41
  42 #include "../common/monsters/sv_monsters.qh"
  43
  44 #include "../warpzonelib/server.qh"
  45
  46
  47 void send_CSQC_teamnagger() {
  48         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  49         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  50 }
  51
  52 float ClientData_Send(entity to, int sf)
  53 {
  54         if(to != self.owner)
  55         {
  56                 error("wtf");
  57                 return false;
  58         }
  59
  60         entity e;
  61
  62         e = to;
  63         if(IS_SPEC(to))
  64                 e = to.enemy;
  65
  66         sf = 0;
  67
  68         if(e.race_completed)
  69                 sf |= 1; // forced scoreboard
  70         if(to.spectatee_status)
  71                 sf |= 2; // spectator ent number follows
  72         if(e.zoomstate)
  73                 sf |= 4; // zoomed
  74         if(e.porto_v_angle_held)
  75                 sf |= 8; // angles held
  76
  77         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  78         WriteByte(MSG_ENTITY, sf);
  79
  80         if(sf & 2)
  81                 WriteByte(MSG_ENTITY, to.spectatee_status);
  82
  83         if(sf & 8)
  84         {
  85                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  86                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  87         }
  88
  89         return true;
  90 }
  91
  92 void ClientData_Attach()
  93 {
  94         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  95         self.clientdata.drawonlytoclient = self;
  96         self.clientdata.owner = self;
  97 }
  98
  99 void ClientData_Detach()
 100 {
 101         remove(self.clientdata);
 102         self.clientdata = world;
 103 }
 104
 105 void ClientData_Touch(entity e)
 106 {
 107         e.clientdata.SendFlags = 1;
 108
 109         // make it spectatable
 110         entity e2;
 111         FOR_EACH_REALCLIENT(e2)
 112         {
 113                 if(e2 != e)
 114                         if(IS_SPEC(e2))
 115                                 if(e2.enemy == e)
 116                                         e2.clientdata.SendFlags = 1;
 117         }
 118 }
 119
 120 .string netname_previous;
 121
 122 void SetSpectator(entity player, entity spectatee);
 123
 124
 125 /*
 126 =============
 127 CheckPlayerModel
 128
 129 Checks if the argument string can be a valid playermodel.
 130 Returns a valid one in doubt.
 131 =============
 132 */
 133 string FallbackPlayerModel;
 134 string CheckPlayerModel(string plyermodel) {
 135         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 136         {
 137                 // note: we cannot summon Don Strunzone here, some player may
 138                 // still have the model string set. In case anyone manages how
 139                 // to change a cvar default, we'll have a small leak here.
 140                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 141         }
 142         // only in right path
 143         if( substring(plyermodel,0,14) != "models/player/")
 144                 return FallbackPlayerModel;
 145         // only good file extensions
 146         if(substring(plyermodel,-4,4) != ".zym")
 147         if(substring(plyermodel,-4,4) != ".dpm")
 148         if(substring(plyermodel,-4,4) != ".iqm")
 149         if(substring(plyermodel,-4,4) != ".md3")
 150         if(substring(plyermodel,-4,4) != ".psk")
 151                 return FallbackPlayerModel;
 152         // forbid the LOD models
 153         if(substring(plyermodel, -9,5) == "_lod1")
 154                 return FallbackPlayerModel;
 155         if(substring(plyermodel, -9,5) == "_lod2")
 156                 return FallbackPlayerModel;
 157         if(plyermodel != strtolower(plyermodel))
 158                 return FallbackPlayerModel;
 159         // also, restrict to server models
 160         if(autocvar_sv_servermodelsonly)
 161         {
 162                 if(!fexists(plyermodel))
 163                         return FallbackPlayerModel;
 164         }
 165         return plyermodel;
 166 }
 167
 168 void setplayermodel(entity e, string modelname)
 169 {
 170         precache_model(modelname);
 171         setmodel(e, modelname);
 172         player_setupanimsformodel();
 173         UpdatePlayerSounds();
 174 }
 175
 176 /*
 177 =============
 178 PutObserverInServer
 179
 180 putting a client as observer in the server
 181 =============
 182 */
 183 void FixPlayermodel();
 184 void PutObserverInServer (void)
 185 {
 186         entity  spot;
 187     self.hud = HUD_NORMAL;
 188
 189         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 190
 191         spot = SelectSpawnPoint (true);
 192         if(!spot)
 193                 error("No spawnpoints for observers?!?\n");
 194         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 195
 196         if(IS_REAL_CLIENT(self))
 197         {
 198                 Item_ItemsTime_SetTimesForPlayer(self);
 199                 msg_entity = self;
 200                 WriteByte(MSG_ONE, SVC_SETVIEW);
 201                 WriteEntity(MSG_ONE, self);
 202         }
 203
 204         self.frags = FRAGS_SPECTATOR;
 205
 206         MUTATOR_CALLHOOK(MakePlayerObserver);
 207
 208         Portal_ClearAll(self);
 209
 210         Unfreeze(self);
 211
 212         if(self.alivetime)
 213         {
 214                 if(!warmup_stage)
 215                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 216                 self.alivetime = 0;
 217         }
 218
 219         if(self.vehicle)
 220                 vehicles_exit(VHEF_RELESE);
 221
 222         WaypointSprite_PlayerDead();
 223
 224         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 225                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 226
 227         if(self.killcount != -666)
 228         {
 229                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 230                 if(!intermission_running)
 231                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 232                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 233
 234                 if(self.just_joined == false) {
 235                         LogTeamchange(self.playerid, -1, 4);
 236                 } else
 237                         self.just_joined = false;
 238         }
 239
 240         PlayerScore_Clear(self); // clear scores when needed
 241
 242         accuracy_resend(self);
 243
 244         self.spectatortime = time;
 245
 246         self.classname = "observer";
 247         self.iscreature = false;
 248         self.teleportable = TELEPORT_SIMPLE;
 249         self.damagedbycontents = false;
 250         self.health = -666;
 251         self.takedamage = DAMAGE_NO;
 252         self.solid = SOLID_NOT;
 253         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 254         self.flags = FL_CLIENT | FL_NOTARGET;
 255         self.armorvalue = 666;
 256         self.effects = 0;
 257         self.armorvalue = autocvar_g_balance_armor_start;
 258         self.pauserotarmor_finished = 0;
 259         self.pauserothealth_finished = 0;
 260         self.pauseregen_finished = 0;
 261         self.damageforcescale = 0;
 262         self.death_time = 0;
 263         self.respawn_flags = 0;
 264         self.respawn_time = 0;
 265         self.stat_respawn_time = 0;
 266         self.alpha = 0;
 267         self.scale = 0;
 268         self.fade_time = 0;
 269         self.pain_frame = 0;
 270         self.pain_finished = 0;
 271         self.strength_finished = 0;
 272         self.invincible_finished = 0;
 273         self.superweapons_finished = 0;
 274         self.pushltime = 0;
 275         self.istypefrag = 0;
 276         self.think = func_null;
 277         self.nextthink = 0;
 278         self.hook_time = 0;
 279         self.deadflag = DEAD_NO;
 280         self.angles = spot.angles;
 281         self.angles_z = 0;
 282         self.fixangle = true;
 283         self.crouch = false;
 284         self.revival_time = 0;
 285
 286         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 287         self.prevorigin = self.origin;
 288         self.items = 0;
 289         self.weapons = '0 0 0';
 290         self.model = "";
 291         FixPlayermodel();
 292         setmodel(self, "null");
 293         self.drawonlytoclient = self;
 294
 295         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 296         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 297
 298         self.weapon = 0;
 299         self.weaponname = "";
 300         self.switchingweapon = 0;
 301         self.weaponmodel = "";
 302         self.weaponentity = world;
 303         self.exteriorweaponentity = world;
 304         self.killcount = -666;
 305         self.velocity = '0 0 0';
 306         self.avelocity = '0 0 0';
 307         self.punchangle = '0 0 0';
 308         self.punchvector = '0 0 0';
 309         self.oldvelocity = self.velocity;
 310         self.fire_endtime = -1;
 311         self.event_damage = func_null;
 312 }
 313
 314 .float model_randomizer;
 315 void FixPlayermodel()
 316 {
 317         string defaultmodel;
 318         float defaultskin, chmdl, oldskin, n, i;
 319         vector m1, m2;
 320
 321         defaultmodel = "";
 322         defaultskin = 0;
 323         chmdl = false;
 324
 325         if(autocvar_sv_defaultcharacter)
 326         {
 327                 if(teamplay)
 328                 {
 329                         string s;
 330                         s = Static_Team_ColorName_Lower(self.team);
 331                         if(s != "neutral")
 332                         {
 333                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 334                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 335                         }
 336                 }
 337
 338                 if(defaultmodel == "")
 339                 {
 340                         defaultmodel = autocvar_sv_defaultplayermodel;
 341                         defaultskin = autocvar_sv_defaultplayerskin;
 342                 }
 343
 344                 n = tokenize_console(defaultmodel);
 345                 if(n > 0)
 346                 {
 347                         defaultmodel = argv(floor(n * self.model_randomizer));
 348                         // However, do NOT randomize if the player-selected model is in the list.
 349                         for (i = 0; i < n; ++i)
 350                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 351                                         defaultmodel = argv(i);
 352                 }
 353
 354                 i = strstrofs(defaultmodel, ":", 0);
 355                 if(i >= 0)
 356                 {
 357                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 358                         defaultmodel = substring(defaultmodel, 0, i);
 359                 }
 360         }
 361
 362         if(defaultmodel != "")
 363         {
 364                 if (defaultmodel != self.model)
 365                 {
 366                         m1 = self.mins;
 367                         m2 = self.maxs;
 368                         setplayermodel (self, defaultmodel);
 369                         setsize (self, m1, m2);
 370                         chmdl = true;
 371                 }
 372
 373                 oldskin = self.skin;
 374                 self.skin = defaultskin;
 375         } else {
 376                 if (self.playermodel != self.model || self.playermodel == "")
 377                 {
 378                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 379                         m1 = self.mins;
 380                         m2 = self.maxs;
 381                         setplayermodel (self, self.playermodel);
 382                         setsize (self, m1, m2);
 383                         chmdl = true;
 384                 }
 385
 386                 oldskin = self.skin;
 387                 self.skin = stof(self.playerskin);
 388         }
 389
 390         if(chmdl || oldskin != self.skin) // model or skin has changed
 391         {
 392                 self.species = player_getspecies(); // update species
 393                 UpdatePlayerSounds(); // update skin sounds
 394         }
 395
 396         if(!teamplay)
 397                 if(strlen(autocvar_sv_defaultplayercolors))
 398                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 399                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 400 }
 401
 402 /*
 403 =============
 404 PutClientInServer
 405
 406 Called when a client spawns in the server
 407 =============
 408 */
 409 void PutClientInServer (void)
 410 {
 411         if(IS_BOT_CLIENT(self))
 412                 self.classname = "player";
 413         else if(IS_REAL_CLIENT(self))
 414         {
 415                 msg_entity = self;
 416                 WriteByte(MSG_ONE, SVC_SETVIEW);
 417                 WriteEntity(MSG_ONE, self);
 418         }
 419
 420         SetSpectator(self, world);
 421
 422         // reset player keys
 423         self.itemkeys = 0;
 424
 425         MUTATOR_CALLHOOK(PutClientInServer, self);
 426
 427         if(gameover)
 428                 self.classname = "observer";
 429
 430         if(IS_PLAYER(self))
 431         {
 432                 entity spot, oldself;
 433
 434                 accuracy_resend(self);
 435
 436                 if(self.team < 0)
 437                         JoinBestTeam(self, false, true);
 438
 439                 spot = SelectSpawnPoint (false);
 440                 if(!spot)
 441                 {
 442                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 443                         return; // spawn failed
 444                 }
 445
 446                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 447
 448                 if(self.vehicle)
 449                         vehicles_exit(VHEF_RELESE);
 450
 451                 self.classname = "player";
 452                 self.wasplayer = true;
 453                 self.iscreature = true;
 454                 self.teleportable = TELEPORT_NORMAL;
 455                 self.damagedbycontents = true;
 456                 self.movetype = MOVETYPE_WALK;
 457                 self.solid = SOLID_SLIDEBOX;
 458                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 459                 if(autocvar_g_playerclip_collisions)
 460                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 461                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 462                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 463                 self.frags = FRAGS_PLAYER;
 464                 if(INDEPENDENT_PLAYERS)
 465                         MAKE_INDEPENDENT_PLAYER(self);
 466                 self.flags = FL_CLIENT;
 467                 if(autocvar__notarget)
 468                         self.flags |= FL_NOTARGET;
 469                 self.takedamage = DAMAGE_AIM;
 470                 self.effects = 0;
 471                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 472                 self.air_finished = time + 12;
 473                 self.dmg = 2;
 474                 if(WEP_CVAR(vortex, charge))
 475                 {
 476                         if(WEP_CVAR_SEC(vortex, chargepool))
 477                                 self.vortex_chargepool_ammo = 1;
 478                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 479                 }
 480
 481                 if(warmup_stage)
 482                 {
 483                         self.ammo_shells = warmup_start_ammo_shells;
 484                         self.ammo_nails = warmup_start_ammo_nails;
 485                         self.ammo_rockets = warmup_start_ammo_rockets;
 486                         self.ammo_cells = warmup_start_ammo_cells;
 487                         self.ammo_plasma = warmup_start_ammo_plasma;
 488                         self.ammo_fuel = warmup_start_ammo_fuel;
 489                         self.health = warmup_start_health;
 490                         self.armorvalue = warmup_start_armorvalue;
 491                         self.weapons = WARMUP_START_WEAPONS;
 492                 }
 493                 else
 494                 {
 495                         self.ammo_shells = start_ammo_shells;
 496                         self.ammo_nails = start_ammo_nails;
 497                         self.ammo_rockets = start_ammo_rockets;
 498                         self.ammo_cells = start_ammo_cells;
 499                         self.ammo_plasma = start_ammo_plasma;
 500                         self.ammo_fuel = start_ammo_fuel;
 501                         self.health = start_health;
 502                         self.armorvalue = start_armorvalue;
 503                         self.weapons = start_weapons;
 504                 }
 505
 506                 if(self.weapons & WEPSET_SUPERWEAPONS)
 507                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 508                 else
 509                         self.superweapons_finished = 0;
 510
 511                 if(!warmup_stage)
 512                         Item_ItemsTime_ResetTimesForPlayer(self);
 513
 514                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 515                 {
 516                         if(g_weaponarena_random_with_blaster)
 517                                 self.weapons &= ~WEPSET_BLASTER;
 518                         W_RandomWeapons(self, g_weaponarena_random);
 519                         if(g_weaponarena_random_with_blaster)
 520                                 self.weapons |= WEPSET_BLASTER;
 521                 }
 522
 523                 self.items = start_items;
 524
 525                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 526                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 527                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 528                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 529                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 530                 //extend the pause of rotting if client was reset at the beginning of the countdown
 531                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 532                         self.spawnshieldtime += game_starttime - time;
 533                         self.pauserotarmor_finished += game_starttime - time;
 534                         self.pauserothealth_finished += game_starttime - time;
 535                         self.pauseregen_finished += game_starttime - time;
 536                 }
 537                 self.damageforcescale = 2;
 538                 self.death_time = 0;
 539                 self.respawn_flags = 0;
 540                 self.respawn_time = 0;
 541                 self.stat_respawn_time = 0;
 542                 self.scale = autocvar_sv_player_scale;
 543                 self.fade_time = 0;
 544                 self.pain_frame = 0;
 545                 self.pain_finished = 0;
 546                 self.strength_finished = 0;
 547                 self.invincible_finished = 0;
 548                 self.pushltime = 0;
 549                 // players have no think function
 550                 self.think = func_null;
 551                 self.nextthink = 0;
 552                 self.hook_time = 0;
 553                 self.dmg_team = 0;
 554                 self.ballistics_density = autocvar_g_ballistics_density_player;
 555
 556                 self.metertime = 0;
 557
 558                 self.deadflag = DEAD_NO;
 559
 560                 self.angles = spot.angles;
 561
 562                 self.angles_z = 0; // never spawn tilted even if the spot says to
 563                 if(IS_BOT_CLIENT(self))
 564                         self.v_angle = self.angles;
 565                 self.fixangle = true; // turn this way immediately
 566                 self.velocity = '0 0 0';
 567                 self.avelocity = '0 0 0';
 568                 self.punchangle = '0 0 0';
 569                 self.punchvector = '0 0 0';
 570                 self.oldvelocity = self.velocity;
 571                 self.fire_endtime = -1;
 572                 self.revival_time = 0;
 573
 574                 entity spawnevent = spawn();
 575                 spawnevent.owner = self;
 576                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 577
 578                 // Cut off any still running player sounds.
 579                 stopsound(self, CH_PLAYER_SINGLE);
 580
 581                 self.model = "";
 582                 FixPlayermodel();
 583                 self.drawonlytoclient = world;
 584
 585                 self.crouch = false;
 586                 self.view_ofs = PL_VIEW_OFS;
 587                 setsize (self, PL_MIN, PL_MAX);
 588                 self.spawnorigin = spot.origin;
 589                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 590                 // don't reset back to last position, even if new position is stuck in solid
 591                 self.oldorigin = self.origin;
 592                 self.prevorigin = self.origin;
 593                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 594                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 595         self.hud = HUD_NORMAL;
 596
 597                 self.event_damage = PlayerDamage;
 598
 599                 self.bot_attack = true;
 600                 self.monster_attack = true;
 601
 602                 self.spider_slowness = 0;
 603
 604                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 605
 606                 if(self.killcount == -666) {
 607                         PlayerScore_Clear(self);
 608                         self.killcount = 0;
 609                 }
 610
 611                 CL_SpawnWeaponentity();
 612                 self.alpha = default_player_alpha;
 613                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 614                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 615
 616                 self.speedrunning = false;
 617
 618                 //stuffcmd(self, "chase_active 0");
 619                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 620
 621                 target_voicescript_clear(self);
 622
 623                 // reset fields the weapons may use
 624                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 625                 {
 626                         WEP_ACTION(j, WR_RESETPLAYER);
 627
 628                         // all weapons must be fully loaded when we spawn
 629                         entity e = get_weaponinfo(j);
 630                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 631                                 self.(weapon_load[j]) = e.reloading_ammo;
 632                 }
 633
 634                 oldself = self;
 635                 self = spot;
 636                         activator = oldself;
 637                                 string s;
 638                                 s = self.target;
 639                                 self.target = string_null;
 640                                 SUB_UseTargets();
 641                                 self.target = s;
 642                         activator = world;
 643                 self = oldself;
 644
 645                 Unfreeze(self);
 646
 647                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 648
 649                 if(autocvar_spawn_debug)
 650                 {
 651                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 652                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 653                 }
 654
 655                 self.switchweapon = w_getbestweapon(self);
 656                 self.cnt = -1; // W_LastWeapon will not complain
 657                 self.weapon = 0;
 658                 self.weaponname = "";
 659                 self.switchingweapon = 0;
 660
 661                 if(!warmup_stage)
 662                         if(!self.alivetime)
 663                                 self.alivetime = time;
 664
 665                 antilag_clear(self);
 666         }
 667         else if(IS_OBSERVER(self))
 668         {
 669                 PutObserverInServer ();
 670         }
 671 }
 672
 673 .float ebouncefactor, ebouncestop; // electro's values
 674 // TODO do we need all these fields, or should we stop autodetecting runtime
 675 // changes and just have a console command to update this?
 676 float ClientInit_SendEntity(entity to, int sf)
 677 {
 678         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 679         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 680         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 681         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 682         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 683         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 684         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 685         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 686         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 687         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 688
 689         if(sv_foginterval && world.fog != "")
 690                 WriteString(MSG_ENTITY, world.fog);
 691         else
 692                 WriteString(MSG_ENTITY, "");
 693         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 694         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 695         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 696         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 697         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 698         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 699         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 700         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 701         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 702         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 703         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 704         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 705         return true;
 706 }
 707
 708 void ClientInit_CheckUpdate()
 709 {
 710         self.nextthink = time;
 711         if(self.count != autocvar_g_balance_armor_blockpercent)
 712         {
 713                 self.count = autocvar_g_balance_armor_blockpercent;
 714                 self.SendFlags |= 1;
 715         }
 716         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 717         {
 718                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 719                 self.SendFlags |= 1;
 720         }
 721         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 722         {
 723                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 724                 self.SendFlags |= 1;
 725         }
 726         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 727         {
 728                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 729                 self.SendFlags |= 1;
 730         }
 731         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 732         {
 733                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 734                 self.SendFlags |= 1;
 735         }
 736 }
 737
 738 void ClientInit_Spawn()
 739 {
 740         entity o;
 741         entity e;
 742         e = spawn();
 743         e.classname = "clientinit";
 744         e.think = ClientInit_CheckUpdate;
 745         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 746
 747         o = self;
 748         self = e;
 749         ClientInit_CheckUpdate();
 750         self = o;
 751 }
 752
 753 /*
 754 =============
 755 SetNewParms
 756 =============
 757 */
 758 void SetNewParms (void)
 759 {
 760         // initialize parms for a new player
 761         parm1 = -(86400 * 366);
 762 }
 763
 764 /*
 765 =============
 766 SetChangeParms
 767 =============
 768 */
 769 void SetChangeParms (void)
 770 {
 771         // save parms for level change
 772         parm1 = self.parm_idlesince - time;
 773 }
 774
 775 /*
 776 =============
 777 DecodeLevelParms
 778 =============
 779 */
 780 void DecodeLevelParms (void)
 781 {
 782         // load parms
 783         self.parm_idlesince = parm1;
 784         if(self.parm_idlesince == -(86400 * 366))
 785                 self.parm_idlesince = time;
 786
 787         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 788         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 789 }
 790
 791 /*
 792 =============
 793 ClientKill
 794
 795 Called when a client types 'kill' in the console
 796 =============
 797 */
 798
 799 .float clientkill_nexttime;
 800 void ClientKill_Now_TeamChange()
 801 {
 802         if(self.killindicator_teamchange == -1)
 803         {
 804                 JoinBestTeam( self, false, true );
 805         }
 806         else if(self.killindicator_teamchange == -2)
 807         {
 808                 if(blockSpectators)
 809                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 810                 PutObserverInServer();
 811         }
 812         else
 813                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 814         self.killindicator_teamchange = 0;
 815 }
 816
 817 void ClientKill_Now()
 818 {
 819         if(self.vehicle)
 820         {
 821             vehicles_exit(VHEF_RELESE);
 822             if(!self.killindicator_teamchange)
 823             {
 824             self.vehicle_health = -1;
 825             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 826             }
 827         }
 828
 829         if(self.killindicator && !wasfreed(self.killindicator))
 830                 remove(self.killindicator);
 831
 832         self.killindicator = world;
 833
 834         if(self.killindicator_teamchange)
 835                 ClientKill_Now_TeamChange();
 836
 837         if(IS_PLAYER(self))
 838                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 839
 840         // now I am sure the player IS dead
 841 }
 842 void KillIndicator_Think()
 843 {
 844         if (gameover)
 845         {
 846                 self.owner.killindicator = world;
 847                 remove(self);
 848                 return;
 849         }
 850
 851         if (self.owner.alpha < 0 && !self.owner.vehicle)
 852         {
 853                 self.owner.killindicator = world;
 854                 remove(self);
 855                 return;
 856         }
 857
 858         if(self.cnt <= 0)
 859         {
 860                 self = self.owner;
 861                 ClientKill_Now(); // no oldself needed
 862                 return;
 863         }
 864     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 865     {
 866         self.nextthink = time + 1;
 867         self.cnt -= 1;
 868     }
 869         else
 870         {
 871                 if(self.cnt <= 10)
 872                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 873                 if(IS_REAL_CLIENT(self.owner))
 874                 {
 875                         if(self.cnt <= 10)
 876                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 877                 }
 878                 self.nextthink = time + 1;
 879                 self.cnt -= 1;
 880         }
 881 }
 882
 883 float clientkilltime;
 884 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 885 {
 886         float killtime;
 887         float starttime;
 888         entity e;
 889
 890         if (gameover)
 891                 return;
 892
 893         killtime = autocvar_g_balance_kill_delay;
 894
 895         if(g_race_qualifying || g_cts)
 896                 killtime = 0;
 897
 898     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 899     {
 900                 remove(self.killindicator);
 901                 self.killindicator = world;
 902
 903         ClientKill_Now(); // allow instant kill in this case
 904         return;
 905     }
 906
 907         self.killindicator_teamchange = targetteam;
 908
 909     if(!self.killindicator)
 910         {
 911                 if(self.deadflag == DEAD_NO)
 912                 {
 913                         killtime = max(killtime, self.clientkill_nexttime - time);
 914                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 915                 }
 916
 917                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 918                 {
 919                         ClientKill_Now();
 920                 }
 921                 else
 922                 {
 923                         starttime = max(time, clientkilltime);
 924
 925                         self.killindicator = spawn();
 926                         self.killindicator.owner = self;
 927                         self.killindicator.scale = 0.5;
 928                         setattachment(self.killindicator, self, "");
 929                         setorigin(self.killindicator, '0 0 52');
 930                         self.killindicator.think = KillIndicator_Think;
 931                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 932                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 933                         self.killindicator.cnt = ceil(killtime);
 934                         self.killindicator.count = bound(0, ceil(killtime), 10);
 935                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 936
 937                         for(e = world; (e = find(e, classname, "body")) != world; )
 938                         {
 939                                 if(e.enemy != self)
 940                                         continue;
 941                                 e.killindicator = spawn();
 942                                 e.killindicator.owner = e;
 943                                 e.killindicator.scale = 0.5;
 944                                 setattachment(e.killindicator, e, "");
 945                                 setorigin(e.killindicator, '0 0 52');
 946                                 e.killindicator.think = KillIndicator_Think;
 947                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 948                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 949                                 e.killindicator.cnt = ceil(killtime);
 950                         }
 951                         self.lip = 0;
 952                 }
 953         }
 954         if(self.killindicator)
 955         {
 956                 if(targetteam == 0) // just die
 957                 {
 958                         self.killindicator.colormod = '0 0 0';
 959                         if(IS_REAL_CLIENT(self))
 960                         if(self.killindicator.cnt > 0)
 961                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 962                 }
 963                 else if(targetteam == -1) // auto
 964                 {
 965                         self.killindicator.colormod = '0 1 0';
 966                         if(IS_REAL_CLIENT(self))
 967                         if(self.killindicator.cnt > 0)
 968                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 969                 }
 970                 else if(targetteam == -2) // spectate
 971                 {
 972                         self.killindicator.colormod = '0.5 0.5 0.5';
 973                         if(IS_REAL_CLIENT(self))
 974                         if(self.killindicator.cnt > 0)
 975                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 976                 }
 977                 else
 978                 {
 979                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 980                         if(IS_REAL_CLIENT(self))
 981                         if(self.killindicator.cnt > 0)
 982                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 983                 }
 984         }
 985
 986 }
 987
 988 void ClientKill (void)
 989 {
 990         if(gameover) return;
 991         if(self.player_blocked) return;
 992         if(self.frozen) return;
 993
 994         ClientKill_TeamChange(0);
 995 }
 996
 997 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 998 {
 999     e.killindicator = spawn();
1000     e.killindicator.owner = e;
1001     e.killindicator.think = KillIndicator_Think;
1002     e.killindicator.nextthink = time + (e.lip) * 0.05;
1003     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1004     e.killindicator.health = 1; // this is used to indicate that it should be silent
1005     e.lip = 0;
1006 }
1007
1008 void FixClientCvars(entity e)
1009 {
1010         // send prediction settings to the client
1011         stuffcmd(e, "\nin_bindmap 0 0\n");
1012         if(g_race || g_cts)
1013                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1014         if(autocvar_g_antilag == 3) // client side hitscan
1015                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1016         if(autocvar_sv_gentle)
1017                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1018 }
1019
1020 float PlayerInIDList(entity p, string idlist)
1021 {
1022         float n, i;
1023         string s;
1024
1025         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1026         if (!p.crypto_idfp)
1027                 return 0;
1028
1029         // this function allows abbreviated player IDs too!
1030         n = tokenize_console(idlist);
1031         for(i = 0; i < n; ++i)
1032         {
1033                 s = argv(i);
1034                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1035                         return 1;
1036         }
1037
1038         return 0;
1039 }
1040
1041 #ifdef DP_EXT_PRECONNECT
1042 /*
1043 =============
1044 ClientPreConnect
1045
1046 Called once (not at each match start) when a client begins a connection to the server
1047 =============
1048 */
1049 void ClientPreConnect (void)
1050 {
1051         if(autocvar_sv_eventlog)
1052         {
1053                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1054                         self.playerid,
1055                         num_for_edict(self),
1056                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1057                 ));
1058         }
1059 }
1060 #endif
1061
1062 /*
1063 =============
1064 ClientConnect
1065
1066 Called when a client connects to the server
1067 =============
1068 */
1069 void DecodeLevelParms (void);
1070 //void dom_player_join_team(entity pl);
1071 void set_dom_state(entity e);
1072 void ClientConnect (void)
1073 {
1074         float t;
1075
1076         if(IS_CLIENT(self))
1077         {
1078                 print("Warning: ClientConnect, but already connected!\n");
1079                 return;
1080         }
1081
1082         if(Ban_MaybeEnforceBanOnce(self))
1083                 return;
1084
1085         DecodeLevelParms();
1086
1087 #ifdef WATERMARK
1088         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1089 #endif
1090
1091         self.classname = "player_joining";
1092
1093         self.flags = FL_CLIENT;
1094         self.version_nagtime = time + 10 + random() * 10;
1095
1096         if(player_count<0)
1097         {
1098                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1099                 player_count = 0;
1100         }
1101
1102         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1103
1104         PlayerScore_Attach(self);
1105         ClientData_Attach();
1106         accuracy_init(self);
1107         Inventory_new(self);
1108
1109         bot_clientconnect();
1110
1111         playerdemo_init();
1112
1113         anticheat_init();
1114
1115         // identify the right forced team
1116         if(autocvar_g_campaign)
1117         {
1118                 if(IS_REAL_CLIENT(self)) // only players, not bots
1119                 {
1120                         switch(autocvar_g_campaign_forceteam)
1121                         {
1122                                 case 1: self.team_forced = NUM_TEAM_1; break;
1123                                 case 2: self.team_forced = NUM_TEAM_2; break;
1124                                 case 3: self.team_forced = NUM_TEAM_3; break;
1125                                 case 4: self.team_forced = NUM_TEAM_4; break;
1126                                 default: self.team_forced = 0;
1127                         }
1128                 }
1129         }
1130         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1131                 self.team_forced = NUM_TEAM_1;
1132         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1133                 self.team_forced = NUM_TEAM_2;
1134         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1135                 self.team_forced = NUM_TEAM_3;
1136         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1137                 self.team_forced = NUM_TEAM_4;
1138         else if(autocvar_g_forced_team_otherwise == "red")
1139                 self.team_forced = NUM_TEAM_1;
1140         else if(autocvar_g_forced_team_otherwise == "blue")
1141                 self.team_forced = NUM_TEAM_2;
1142         else if(autocvar_g_forced_team_otherwise == "yellow")
1143                 self.team_forced = NUM_TEAM_3;
1144         else if(autocvar_g_forced_team_otherwise == "pink")
1145                 self.team_forced = NUM_TEAM_4;
1146         else if(autocvar_g_forced_team_otherwise == "spectate")
1147                 self.team_forced = -1;
1148         else if(autocvar_g_forced_team_otherwise == "spectator")
1149                 self.team_forced = -1;
1150         else
1151                 self.team_forced = 0;
1152
1153         if(!teamplay)
1154                 if(self.team_forced > 0)
1155                         self.team_forced = 0;
1156
1157         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1158
1159         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1160                 self.classname = "observer";
1161         } else {
1162                 if(teamplay)
1163                 {
1164                         if(autocvar_g_balance_teams)
1165                         {
1166                                 self.classname = "player";
1167                                 campaign_bots_may_start = 1;
1168                         }
1169                         else
1170                         {
1171                                 self.classname = "observer"; // do it anyway
1172                         }
1173                 }
1174                 else
1175                 {
1176                         self.classname = "player";
1177                         campaign_bots_may_start = 1;
1178                 }
1179         }
1180
1181         self.playerid = (playerid_last = playerid_last + 1);
1182
1183         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1184
1185     if(IS_BOT_CLIENT(self))
1186         PlayerStats_GameReport_AddPlayer(self);
1187
1188         if(autocvar_sv_eventlog)
1189                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1190
1191         LogTeamchange(self.playerid, self.team, 1);
1192
1193         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1194
1195         self.netname_previous = strzone(self.netname);
1196
1197         if(IS_PLAYER(self) && teamplay)
1198                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1199         else
1200                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1201
1202         stuffcmd(self, strcat(clientstuff, "\n"));
1203         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1204
1205         FixClientCvars(self);
1206
1207         // spawnfunc_waypoint sprites
1208         WaypointSprite_InitClient(self);
1209
1210         // Wazat's grappling hook
1211         SetGrappleHookBindings();
1212
1213         // Jetpack binds
1214         stuffcmd(self, "alias +jetpack +button10\n");
1215         stuffcmd(self, "alias -jetpack -button10\n");
1216
1217         // get version info from player
1218         stuffcmd(self, "cmd clientversion $gameversion\n");
1219
1220         // get other cvars from player
1221         GetCvars(0);
1222
1223         // notify about available teams
1224         if(teamplay)
1225         {
1226                 CheckAllowedTeams(self);
1227                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1228                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1229         }
1230         else
1231                 stuffcmd(self, "set _teams_available 0\n");
1232
1233         attach_entcs();
1234
1235         bot_relinkplayerlist();
1236
1237         self.spectatortime = time;
1238         if(blockSpectators)
1239         {
1240                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1241         }
1242
1243         self.jointime = time;
1244         self.allowed_timeouts = autocvar_sv_timeout_number;
1245
1246         if(IS_REAL_CLIENT(self))
1247         {
1248                 if(!autocvar_g_campaign)
1249                 {
1250                         self.motd_actived_time = -1;
1251                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1252                 }
1253
1254                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1255                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1256         }
1257
1258         if(!sv_foginterval && world.fog != "")
1259                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1260
1261         W_HitPlotOpen(self);
1262
1263         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1264                 send_CSQC_teamnagger();
1265
1266         CheatInitClient();
1267
1268         CSQCMODEL_AUTOINIT();
1269
1270         self.model_randomizer = random();
1271
1272         if(IS_REAL_CLIENT(self))
1273                 sv_notice_join();
1274
1275         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1276                 entity oldself = self;
1277                 self = e;
1278                 e.init_for_player(oldself);
1279                 self = oldself;
1280         }
1281
1282         MUTATOR_CALLHOOK(ClientConnect, self);
1283 }
1284 /*
1285 =============
1286 ClientDisconnect
1287
1288 Called when a client disconnects from the server
1289 =============
1290 */
1291 .entity chatbubbleentity;
1292 void ReadyCount();
1293 void ClientDisconnect (void)
1294 {
1295         if(self.vehicle)
1296             vehicles_exit(VHEF_RELESE);
1297
1298         if (!IS_CLIENT(self))
1299         {
1300                 print("Warning: ClientDisconnect without ClientConnect\n");
1301                 return;
1302         }
1303
1304         PlayerStats_GameReport_FinalizePlayer(self);
1305
1306         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1307
1308         CheatShutdownClient();
1309
1310         W_HitPlotClose(self);
1311
1312         anticheat_report();
1313         anticheat_shutdown();
1314
1315         playerdemo_shutdown();
1316
1317         bot_clientdisconnect();
1318
1319         if(self.entcs)
1320                 detach_entcs();
1321
1322         if(autocvar_sv_eventlog)
1323                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1324
1325         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1326
1327         MUTATOR_CALLHOOK(ClientDisconnect);
1328
1329         Portal_ClearAll(self);
1330
1331         Unfreeze(self);
1332
1333         RemoveGrapplingHook(self);
1334
1335         // Here, everything has been done that requires this player to be a client.
1336
1337         self.flags &= ~FL_CLIENT;
1338
1339         if (self.chatbubbleentity)
1340                 remove (self.chatbubbleentity);
1341
1342         if (self.killindicator)
1343                 remove (self.killindicator);
1344
1345         WaypointSprite_PlayerGone();
1346
1347         bot_relinkplayerlist();
1348
1349         accuracy_free(self);
1350         Inventory_delete(self);
1351         ClientData_Detach();
1352         PlayerScore_Detach(self);
1353
1354         if(self.netname_previous)
1355                 strunzone(self.netname_previous);
1356         if(self.clientstatus)
1357                 strunzone(self.clientstatus);
1358         if(self.weaponorder_byimpulse)
1359                 strunzone(self.weaponorder_byimpulse);
1360
1361         ClearPlayerSounds();
1362
1363         if(self.personal)
1364                 remove(self.personal);
1365
1366         self.playerid = 0;
1367         ReadyCount();
1368
1369         // free cvars
1370         GetCvars(-1);
1371 }
1372
1373 .float BUTTON_CHAT;
1374 void ChatBubbleThink()
1375 {
1376         self.nextthink = time;
1377         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1378         {
1379                 if(self.owner) // but why can that ever be world?
1380                         self.owner.chatbubbleentity = world;
1381                 remove(self);
1382                 return;
1383         }
1384         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1385 #ifdef TETRIS
1386                 || self.owner.tetris_on
1387 #endif
1388         )
1389                 self.model = self.mdl;
1390         else
1391                 self.model = "";
1392 }
1393
1394 void UpdateChatBubble()
1395 {
1396         if (self.alpha < 0)
1397                 return;
1398         // spawn a chatbubble entity if needed
1399         if (!self.chatbubbleentity)
1400         {
1401                 self.chatbubbleentity = spawn();
1402                 self.chatbubbleentity.owner = self;
1403                 self.chatbubbleentity.exteriormodeltoclient = self;
1404                 self.chatbubbleentity.think = ChatBubbleThink;
1405                 self.chatbubbleentity.nextthink = time;
1406                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1407                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1408                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1409                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1410                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1411                 self.chatbubbleentity.model = "";
1412                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1413         }
1414 }
1415
1416
1417 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1418 // added to the model skins
1419 /*void UpdateColorModHack()
1420 {
1421         float c;
1422         c = self.clientcolors & 15;
1423         // LordHavoc: only bothering to support white, green, red, yellow, blue
1424              if (!teamplay) self.colormod = '0 0 0';
1425         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1426         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1427         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1428         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1429         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1430         else self.colormod = '1 1 1';
1431 }*/
1432
1433 void respawn(void)
1434 {
1435         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1436         {
1437                 self.solid = SOLID_NOT;
1438                 self.takedamage = DAMAGE_NO;
1439                 self.movetype = MOVETYPE_FLY;
1440                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1441                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1442                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1443                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1444                 if(autocvar_g_respawn_ghosts_maxtime)
1445                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1446         }
1447
1448         CopyBody(1);
1449
1450         self.effects |= EF_NODRAW; // prevent another CopyBody
1451         PutClientInServer();
1452 }
1453
1454 void play_countdown(float finished, string samp)
1455 {
1456         if(IS_REAL_CLIENT(self))
1457                 if(floor(finished - time - frametime) != floor(finished - time))
1458                         if(finished - time < 6)
1459                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1460 }
1461
1462 void player_powerups (void)
1463 {
1464         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1465         int items_prev = self.items;
1466
1467         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1468                 self.modelflags |= MF_ROCKET;
1469         else
1470                 self.modelflags &= ~MF_ROCKET;
1471
1472         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1473
1474         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1475                 return;
1476
1477         Fire_ApplyDamage(self);
1478         Fire_ApplyEffect(self);
1479
1480         if (!g_instagib)
1481         {
1482                 if (self.items & IT_STRENGTH)
1483                 {
1484                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1485                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1486                         if (time > self.strength_finished)
1487                         {
1488                                 self.items = self.items - (self.items & IT_STRENGTH);
1489                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1490                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1491                         }
1492                 }
1493                 else
1494                 {
1495                         if (time < self.strength_finished)
1496                         {
1497                                 self.items = self.items | IT_STRENGTH;
1498                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1499                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1500                         }
1501                 }
1502                 if (self.items & IT_INVINCIBLE)
1503                 {
1504                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1505                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1506                         if (time > self.invincible_finished)
1507                         {
1508                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1509                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1510                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1511                         }
1512                 }
1513                 else
1514                 {
1515                         if (time < self.invincible_finished)
1516                         {
1517                                 self.items = self.items | IT_INVINCIBLE;
1518                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1519                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1520                         }
1521                 }
1522                 if (self.items & IT_SUPERWEAPON)
1523                 {
1524                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1525                         {
1526                                 self.superweapons_finished = 0;
1527                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1528                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1529                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1530                         }
1531                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1532                         {
1533                                 // don't let them run out
1534                         }
1535                         else
1536                         {
1537                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1538                                 if (time > self.superweapons_finished)
1539                                 {
1540                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1541                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1542                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1543                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1544                                 }
1545                         }
1546                 }
1547                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1548                 {
1549                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1550                         {
1551                                 self.items = self.items | IT_SUPERWEAPON;
1552                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1553                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1554                         }
1555                         else
1556                         {
1557                                 self.superweapons_finished = 0;
1558                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1559                         }
1560                 }
1561                 else
1562                 {
1563                         self.superweapons_finished = 0;
1564                 }
1565         }
1566
1567         if(autocvar_g_nodepthtestplayers)
1568                 self.effects = self.effects | EF_NODEPTHTEST;
1569
1570         if(autocvar_g_fullbrightplayers)
1571                 self.effects = self.effects | EF_FULLBRIGHT;
1572
1573         if (time >= game_starttime)
1574         if (time < self.spawnshieldtime)
1575                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1576
1577         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1578 }
1579
1580 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1581 {
1582         if(current > stable)
1583                 return current;
1584         else if(current > stable - 0.25) // when close enough, "snap"
1585                 return stable;
1586         else
1587                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1588 }
1589
1590 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1591 {
1592         if(current < stable)
1593                 return current;
1594         else if(current < stable + 0.25) // when close enough, "snap"
1595                 return stable;
1596         else
1597                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1598 }
1599
1600 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1601 {
1602         if(current > rotstable)
1603         {
1604                 if(rotframetime > 0)
1605                 {
1606                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1607                         current = max(rotstable, current - rotlinear * rotframetime);
1608                 }
1609         }
1610         else if(current < regenstable)
1611         {
1612                 if(regenframetime > 0)
1613                 {
1614                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1615                         current = min(regenstable, current + regenlinear * regenframetime);
1616                 }
1617         }
1618
1619         if(current > limit)
1620                 current = limit;
1621
1622         return current;
1623 }
1624
1625 void player_regen (void)
1626 {
1627         float max_mod, regen_mod, rot_mod, limit_mod;
1628         max_mod = regen_mod = rot_mod = limit_mod = 1;
1629         if(!MUTATOR_CALLHOOK(PlayerRegen, max_mod, regen_mod, rot_mod, limit_mod))
1630         if(!self.frozen)
1631         {
1632                 float minh, mina, maxh, maxa, limith, limita;
1633                 maxh = autocvar_g_balance_health_rotstable;
1634                 maxa = autocvar_g_balance_armor_rotstable;
1635                 minh = autocvar_g_balance_health_regenstable;
1636                 mina = autocvar_g_balance_armor_regenstable;
1637                 limith = autocvar_g_balance_health_limit;
1638                 limita = autocvar_g_balance_armor_limit;
1639
1640                 max_mod = regen_mod_max;
1641                 regen_mod = regen_mod_regen;
1642                 rot_mod = regen_mod_rot;
1643                 limit_mod = regen_mod_limit;
1644
1645                 maxh = maxh * max_mod;
1646                 minh = minh * max_mod;
1647                 limith = limith * limit_mod;
1648                 limita = limita * limit_mod;
1649
1650                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1651                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1652         }
1653
1654         // if player rotted to death...  die!
1655         // check this outside above checks, as player may still be able to rot to death
1656         if(self.health < 1)
1657                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1658
1659         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1660         {
1661                 float minf, maxf, limitf;
1662
1663                 maxf = autocvar_g_balance_fuel_rotstable;
1664                 minf = autocvar_g_balance_fuel_regenstable;
1665                 limitf = autocvar_g_balance_fuel_limit;
1666
1667                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1668         }
1669 }
1670
1671 float zoomstate_set;
1672 void SetZoomState(float z)
1673 {
1674         if(z != self.zoomstate)
1675         {
1676                 self.zoomstate = z;
1677                 ClientData_Touch(self);
1678         }
1679         zoomstate_set = 1;
1680 }
1681
1682 void GetPressedKeys(void) {
1683         MUTATOR_CALLHOOK(GetPressedKeys);
1684         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1685         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1686         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1687         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1688         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1689
1690         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1691         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1692         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1693         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1694         #undef X
1695 }
1696
1697 /*
1698 ======================
1699 spectate mode routines
1700 ======================
1701 */
1702
1703 void SpectateCopy(entity spectatee) {
1704         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1705         self.armortype = spectatee.armortype;
1706         self.armorvalue = spectatee.armorvalue;
1707         self.ammo_cells = spectatee.ammo_cells;
1708         self.ammo_plasma = spectatee.ammo_plasma;
1709         self.ammo_shells = spectatee.ammo_shells;
1710         self.ammo_nails = spectatee.ammo_nails;
1711         self.ammo_rockets = spectatee.ammo_rockets;
1712         self.ammo_fuel = spectatee.ammo_fuel;
1713         self.clip_load = spectatee.clip_load;
1714         self.clip_size = spectatee.clip_size;
1715         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1716         self.health = spectatee.health;
1717         self.impulse = 0;
1718         self.items = spectatee.items;
1719         self.last_pickup = spectatee.last_pickup;
1720         self.hit_time = spectatee.hit_time;
1721         self.metertime = spectatee.metertime;
1722         self.strength_finished = spectatee.strength_finished;
1723         self.invincible_finished = spectatee.invincible_finished;
1724         self.pressedkeys = spectatee.pressedkeys;
1725         self.weapons = spectatee.weapons;
1726         self.switchweapon = spectatee.switchweapon;
1727         self.switchingweapon = spectatee.switchingweapon;
1728         self.weapon = spectatee.weapon;
1729         self.vortex_charge = spectatee.vortex_charge;
1730         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1731         self.hagar_load = spectatee.hagar_load;
1732         self.arc_heat_percent = spectatee.arc_heat_percent;
1733         self.minelayer_mines = spectatee.minelayer_mines;
1734         self.punchangle = spectatee.punchangle;
1735         self.view_ofs = spectatee.view_ofs;
1736         self.velocity = spectatee.velocity;
1737         self.dmg_take = spectatee.dmg_take;
1738         self.dmg_save = spectatee.dmg_save;
1739         self.dmg_inflictor = spectatee.dmg_inflictor;
1740         self.v_angle = spectatee.v_angle;
1741         self.angles = spectatee.v_angle;
1742         self.frozen = spectatee.frozen;
1743         self.revive_progress = spectatee.revive_progress;
1744         if(!self.BUTTON_USE)
1745                 self.fixangle = true;
1746         setorigin(self, spectatee.origin);
1747         setsize(self, spectatee.mins, spectatee.maxs);
1748         SetZoomState(spectatee.zoomstate);
1749
1750     anticheat_spectatecopy(spectatee);
1751         self.hud = spectatee.hud;
1752         if(spectatee.vehicle)
1753     {
1754         self.fixangle = false;
1755         //self.velocity = spectatee.vehicle.velocity;
1756         self.vehicle_health = spectatee.vehicle_health;
1757         self.vehicle_shield = spectatee.vehicle_shield;
1758         self.vehicle_energy = spectatee.vehicle_energy;
1759         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1760         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1761         self.vehicle_reload1 = spectatee.vehicle_reload1;
1762         self.vehicle_reload2 = spectatee.vehicle_reload2;
1763
1764         msg_entity = self;
1765
1766         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1767             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1768             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1769             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1770
1771         //WriteByte (MSG_ONE, SVC_SETVIEW);
1772         //    WriteEntity(MSG_ONE, self);
1773         //makevectors(spectatee.v_angle);
1774         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1775     }
1776 }
1777
1778 float SpectateUpdate()
1779 {
1780         if(!self.enemy)
1781             return 0;
1782
1783         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1784         {
1785                 SetSpectator(self, world);
1786                 return 0;
1787         }
1788
1789         SpectateCopy(self.enemy);
1790
1791         return 1;
1792 }
1793
1794 float SpectateSet()
1795 {
1796         if(self.enemy.classname != "player")
1797                 return false;
1798         /*if(self.enemy.vehicle)
1799         {
1800
1801                 msg_entity = self;
1802                 WriteByte(MSG_ONE, SVC_SETVIEW);
1803                 WriteEntity(MSG_ONE, self.enemy);
1804                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1805
1806                 self.movetype = MOVETYPE_NONE;
1807                 accuracy_resend(self);
1808         }
1809         else
1810         {*/
1811                 msg_entity = self;
1812                 WriteByte(MSG_ONE, SVC_SETVIEW);
1813                 WriteEntity(MSG_ONE, self.enemy);
1814                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1815                 self.movetype = MOVETYPE_NONE;
1816                 accuracy_resend(self);
1817
1818                 if(!SpectateUpdate())
1819                         PutObserverInServer();
1820         //}
1821         return true;
1822 }
1823
1824 void SetSpectator(entity player, entity spectatee)
1825 {
1826         entity old_spectatee = player.enemy;
1827
1828         player.enemy = spectatee;
1829
1830         // WEAPONTODO
1831         // these are required to fix the spectator bug with arc
1832         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1833         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1834 }
1835
1836 float Spectate(entity pl)
1837 {
1838         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1839         if(pl.team != self.team)
1840                 return 0;
1841
1842         SetSpectator(self, pl);
1843         return SpectateSet();
1844 }
1845
1846 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1847 entity CA_SpectateNext(entity start) {
1848         if (start.team == self.team) {
1849                 return start;
1850         }
1851
1852         other = start;
1853         // continue from current player
1854         while(other && other.team != self.team) {
1855                 other = find(other, classname, "player");
1856         }
1857
1858         if (!other) {
1859                 // restart from begining
1860                 other = find(other, classname, "player");
1861                 while(other && other.team != self.team) {
1862                         other = find(other, classname, "player");
1863                 }
1864         }
1865
1866         return other;
1867 }
1868
1869 float SpectateNext()
1870 {
1871         other = find(self.enemy, classname, "player");
1872
1873         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1874                 // CA and ca players when spectating enemies is forbidden
1875                 other = CA_SpectateNext(other);
1876         } else {
1877                 // other modes and ca spectators or spectating enemies is allowed
1878                 if (!other)
1879                         other = find(other, classname, "player");
1880         }
1881
1882         if(other) { SetSpectator(self, other); }
1883
1884         return SpectateSet();
1885 }
1886
1887 float SpectatePrev()
1888 {
1889         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1890         other = findchain(classname, "player");
1891         if (!other) // no player
1892                 return false;
1893
1894         entity first = other;
1895         // skip players until current spectated player
1896         if(self.enemy)
1897         while(other && other != self.enemy)
1898                 other = other.chain;
1899
1900         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1901         {
1902                 do { other = other.chain; }
1903                 while(other && other.team != self.team);
1904
1905                 if (!other)
1906                 {
1907                         other = first;
1908                         while(other.team != self.team)
1909                                 other = other.chain;
1910                         if(other == self.enemy)
1911                                 return true;
1912                 }
1913         }
1914         else
1915         {
1916                 if(other.chain)
1917                         other = other.chain;
1918                 else
1919                         other = first;
1920         }
1921         SetSpectator(self, other);
1922         return SpectateSet();
1923 }
1924
1925 /*
1926 =============
1927 ShowRespawnCountdown()
1928
1929 Update a respawn countdown display.
1930 =============
1931 */
1932 void ShowRespawnCountdown()
1933 {
1934         float number;
1935         if(self.deadflag == DEAD_NO) // just respawned?
1936                 return;
1937         else
1938         {
1939                 number = ceil(self.respawn_time - time);
1940                 if(number <= 0)
1941                         return;
1942                 if(number <= self.respawn_countdown)
1943                 {
1944                         self.respawn_countdown = number - 1;
1945                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1946                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1947                 }
1948         }
1949 }
1950
1951 void LeaveSpectatorMode()
1952 {
1953         if(self.caplayer)
1954                 return;
1955         if(nJoinAllowed(self))
1956         {
1957                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1958                 {
1959                         self.classname = "player";
1960                         nades_RemoveBonus(self);
1961
1962                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1963                                 { JoinBestTeam(self, false, true); }
1964
1965                         if(autocvar_g_campaign)
1966                                 { campaign_bots_may_start = 1; }
1967
1968                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1969
1970                         PutClientInServer();
1971
1972                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1973                 }
1974                 else
1975                         stuffcmd(self, "menu_showteamselect\n");
1976         }
1977         else
1978         {
1979                 // Player may not join because g_maxplayers is set
1980                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1981         }
1982 }
1983
1984 /**
1985  * Determines whether the player is allowed to join. This depends on cvar
1986  * g_maxplayers, if it isn't used this function always return true, otherwise
1987  * it checks whether the number of currently playing players exceeds g_maxplayers.
1988  * @return int number of free slots for players, 0 if none
1989  */
1990 float nJoinAllowed(entity ignore) {
1991         if(!ignore)
1992         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1993         // so report 0 free slots if restricted
1994         {
1995                 if(autocvar_g_forced_team_otherwise == "spectate")
1996                         return 0;
1997                 if(autocvar_g_forced_team_otherwise == "spectator")
1998                         return 0;
1999         }
2000
2001         if(self.team_forced < 0)
2002                 return 0; // forced spectators can never join
2003
2004         // TODO simplify this
2005         entity e;
2006         float totalClients = 0;
2007         FOR_EACH_CLIENT(e)
2008                 if(e != ignore)
2009                         totalClients += 1;
2010
2011         if (!autocvar_g_maxplayers)
2012                 return maxclients - totalClients;
2013
2014         float currentlyPlaying = 0;
2015         FOR_EACH_REALCLIENT(e)
2016                 if(IS_PLAYER(e) || e.caplayer)
2017                         currentlyPlaying += 1;
2018
2019         if(currentlyPlaying < autocvar_g_maxplayers)
2020                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2021
2022         return 0;
2023 }
2024
2025 /**
2026  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2027  * g_maxplayers_spectator_blocktime seconds
2028  */
2029 void checkSpectatorBlock() {
2030         if(IS_SPEC(self) || IS_OBSERVER(self))
2031         if(!self.caplayer)
2032         if(IS_REAL_CLIENT(self))
2033         {
2034                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2035                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2036                         dropclient(self);
2037                 }
2038         }
2039 }
2040
2041 void PrintWelcomeMessage()
2042 {
2043         if(self.motd_actived_time == 0)
2044         {
2045                 if (autocvar_g_campaign) {
2046                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2047                                 self.motd_actived_time = time;
2048                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2049                         }
2050                 } else {
2051                         if (self.BUTTON_INFO) {
2052                                 self.motd_actived_time = time;
2053                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2054                         }
2055                 }
2056         }
2057         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2058         {
2059                 if (autocvar_g_campaign) {
2060                         if (self.BUTTON_INFO)
2061                                 self.motd_actived_time = time;
2062                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2063                                 self.motd_actived_time = 0;
2064                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2065                         }
2066                 } else {
2067                         if (self.BUTTON_INFO)
2068                                 self.motd_actived_time = time;
2069                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2070                                 self.motd_actived_time = 0;
2071                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2072                         }
2073                 }
2074         }
2075         else //if(self.motd_actived_time < 0) // just connected, motd is active
2076         {
2077                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2078                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2079                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2080                 {
2081                         // instanctly hide MOTD
2082                         self.motd_actived_time = 0;
2083                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2084                 }
2085         }
2086 }
2087
2088 void ObserverThink()
2089 {
2090         float prefered_movetype;
2091         if (self.flags & FL_JUMPRELEASED) {
2092                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2093                         self.flags &= ~FL_JUMPRELEASED;
2094                         self.flags |= FL_SPAWNING;
2095                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2096                         self.flags &= ~FL_JUMPRELEASED;
2097                         if(SpectateNext()) {
2098                                 self.classname = "spectator";
2099                         }
2100                 } else {
2101                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2102                         if (self.movetype != prefered_movetype)
2103                                 self.movetype = prefered_movetype;
2104                 }
2105         } else {
2106                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2107                         self.flags |= FL_JUMPRELEASED;
2108                         if(self.flags & FL_SPAWNING)
2109                         {
2110                                 self.flags &= ~FL_SPAWNING;
2111                                 LeaveSpectatorMode();
2112                                 return;
2113                         }
2114                 }
2115         }
2116 }
2117
2118 void SpectatorThink()
2119 {
2120         if (self.flags & FL_JUMPRELEASED) {
2121                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2122                         self.flags &= ~FL_JUMPRELEASED;
2123                         self.flags |= FL_SPAWNING;
2124                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2125                         self.flags &= ~FL_JUMPRELEASED;
2126                         if(SpectateNext()) {
2127                                 self.classname = "spectator";
2128                         } else {
2129                                 self.classname = "observer";
2130                                 PutClientInServer();
2131                         }
2132                         self.impulse = 0;
2133                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2134                         self.flags &= ~FL_JUMPRELEASED;
2135                         if(SpectatePrev()) {
2136                                 self.classname = "spectator";
2137                         } else {
2138                                 self.classname = "observer";
2139                                 PutClientInServer();
2140                         }
2141                         self.impulse = 0;
2142                 } else if (self.BUTTON_ATCK2) {
2143                         self.flags &= ~FL_JUMPRELEASED;
2144                         self.classname = "observer";
2145                         PutClientInServer();
2146                 } else {
2147                         if(!SpectateUpdate())
2148                                 PutObserverInServer();
2149                 }
2150         } else {
2151                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2152                         self.flags |= FL_JUMPRELEASED;
2153                         if(self.flags & FL_SPAWNING)
2154                         {
2155                                 self.flags &= ~FL_SPAWNING;
2156                                 LeaveSpectatorMode();
2157                                 return;
2158                         }
2159                 }
2160                 if(!SpectateUpdate())
2161                         PutObserverInServer();
2162         }
2163
2164         self.flags |= FL_CLIENT | FL_NOTARGET;
2165 }
2166
2167 void PlayerUseKey()
2168 {
2169         if (!IS_PLAYER(self))
2170                 return;
2171
2172         if(self.vehicle)
2173         {
2174         vehicles_exit(VHEF_NORMAL);
2175         return;
2176         }
2177
2178         // a use key was pressed; call handlers
2179         MUTATOR_CALLHOOK(PlayerUseKey);
2180 }
2181
2182 float isInvisibleString(string s)
2183 {
2184         float i, n, c;
2185         s = strdecolorize(s);
2186         for((i = 0), (n = strlen(s)); i < n; ++i)
2187         {
2188                 c = str2chr(s, i);
2189                 switch(c)
2190                 {
2191                         case 0:
2192                         case 32: // space
2193                                 break;
2194                         case 192: // charmap space
2195                                 if (!autocvar_utf8_enable)
2196                                         break;
2197                                 return false;
2198                         case 160: // space in unicode fonts
2199                         case 0xE000 + 192: // utf8 charmap space
2200                                 if (autocvar_utf8_enable)
2201                                         break;
2202                         default:
2203                                 return false;
2204                 }
2205         }
2206         return true;
2207 }
2208
2209 /*
2210 =============
2211 PlayerPreThink
2212
2213 Called every frame for each client before the physics are run
2214 =============
2215 */
2216 .float usekeypressed;
2217 void() nexball_setstatus;
2218 .int items_added;
2219 void PlayerPreThink (void)
2220 {
2221         WarpZone_PlayerPhysics_FixVAngle();
2222
2223         self.stat_game_starttime = game_starttime;
2224         self.stat_round_starttime = round_starttime;
2225         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2226         self.stat_leadlimit = autocvar_leadlimit;
2227
2228         self.weaponsinmap = weaponsInMap;
2229
2230         if(frametime)
2231         {
2232                 // physics frames: update anticheat stuff
2233                 anticheat_prethink();
2234         }
2235
2236         if(blockSpectators && frametime)
2237                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2238                 checkSpectatorBlock();
2239
2240         zoomstate_set = 0;
2241
2242         // Savage: Check for nameless players
2243         if (isInvisibleString(self.netname)) {
2244                 string new_name = strzone(strcat("Player@", self.netaddress));
2245                 if(autocvar_sv_eventlog)
2246                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2247                 if(self.netname_previous)
2248                         strunzone(self.netname_previous);
2249                 self.netname_previous = strzone(new_name);
2250                 self.netname = self.netname_previous;
2251                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2252         } else if(self.netname_previous != self.netname) {
2253                 if(autocvar_sv_eventlog)
2254                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2255                 if(self.netname_previous)
2256                         strunzone(self.netname_previous);
2257                 self.netname_previous = strzone(self.netname);
2258         }
2259
2260         // version nagging
2261         if(self.version_nagtime)
2262                 if(self.cvar_g_xonoticversion)
2263                         if(time > self.version_nagtime)
2264                         {
2265                                 // don't notify git users
2266                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2267                                 {
2268                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2269                                         {
2270                                                 // notify release users if connecting to git
2271                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2272                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2273                                         }
2274                                         else
2275                                         {
2276                                                 float r;
2277                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2278                                                 if(r < 0)
2279                                                 {
2280                                                         // give users new version
2281                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2282                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2283                                                 }
2284                                                 else if(r > 0)
2285                                                 {
2286                                                         // notify users about old server version
2287                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2288                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2289                                                 }
2290                                         }
2291                                 }
2292                                 self.version_nagtime = 0;
2293                         }
2294
2295         // GOD MODE info
2296         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2297         {
2298                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2299                 self.max_armorvalue = 0;
2300         }
2301
2302 #ifdef TETRIS
2303         if (TetrisPreFrame())
2304                 return;
2305 #endif
2306
2307         if(self.frozen == 2)
2308         {
2309                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2310                 self.health = max(1, self.revive_progress * start_health);
2311                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2312
2313                 if(self.revive_progress >= 1)
2314                         Unfreeze(self);
2315         }
2316         else if(self.frozen == 3)
2317         {
2318                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2319                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2320
2321                 if(self.health < 1)
2322                 {
2323                         if(self.vehicle)
2324                                 vehicles_exit(VHEF_RELESE);
2325                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2326                 }
2327                 else if ( self.revive_progress <= 0 )
2328                         Unfreeze(self);
2329         }
2330
2331         MUTATOR_CALLHOOK(PlayerPreThink);
2332
2333         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2334         {
2335                 if(self.BUTTON_USE && !self.usekeypressed)
2336                         PlayerUseKey();
2337                 self.usekeypressed = self.BUTTON_USE;
2338         }
2339
2340         if(IS_REAL_CLIENT(self))
2341                 PrintWelcomeMessage();
2342
2343         if(IS_PLAYER(self))
2344         {
2345
2346                 CheckRules_Player();
2347
2348                 if (intermission_running)
2349                 {
2350                         IntermissionThink ();   // otherwise a button could be missed between
2351                         return;                                 // the think tics
2352                 }
2353
2354                 //don't allow the player to turn around while game is paused!
2355                 if(timeout_status == TIMEOUT_ACTIVE) {
2356                         // FIXME turn this into CSQC stuff
2357                         self.v_angle = self.lastV_angle;
2358                         self.angles = self.lastV_angle;
2359                         self.fixangle = true;
2360                 }
2361
2362                 if(frametime)
2363                 {
2364                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2365                         {
2366                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2367                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2368                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2369
2370                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2371                                 {
2372                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2373                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2374                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2375                                 }
2376                         }
2377                         else
2378                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2379
2380                         player_powerups();
2381                 }
2382
2383                 if (self.deadflag != DEAD_NO)
2384                 {
2385                         if(self.personal && g_race_qualifying)
2386                         {
2387                                 if(time > self.respawn_time)
2388                                 {
2389                                         self.respawn_time = time + 1; // only retry once a second
2390                                         self.stat_respawn_time = self.respawn_time;
2391                                         respawn();
2392                                         self.impulse = 141;
2393                                 }
2394                         }
2395                         else
2396                         {
2397                                 float button_pressed;
2398                                 if(frametime)
2399                                         player_anim();
2400                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2401
2402                                 if (self.deadflag == DEAD_DYING)
2403                                 {
2404                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2405                                                 self.deadflag = DEAD_RESPAWNING;
2406                                         else if(!button_pressed)
2407                                                 self.deadflag = DEAD_DEAD;
2408                                 }
2409                                 else if (self.deadflag == DEAD_DEAD)
2410                                 {
2411                                         if(button_pressed)
2412                                                 self.deadflag = DEAD_RESPAWNABLE;
2413                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2414                                                 self.deadflag = DEAD_RESPAWNING;
2415                                 }
2416                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2417                                 {
2418                                         if(!button_pressed)
2419                                                 self.deadflag = DEAD_RESPAWNING;
2420                                 }
2421                                 else if (self.deadflag == DEAD_RESPAWNING)
2422                                 {
2423                                         if(time > self.respawn_time)
2424                                         {
2425                                                 self.respawn_time = time + 1; // only retry once a second
2426                                                 self.respawn_time_max = self.respawn_time;
2427                                                 respawn();
2428                                         }
2429                                 }
2430
2431                                 ShowRespawnCountdown();
2432
2433                                 if(self.respawn_flags & RESPAWN_SILENT)
2434                                         self.stat_respawn_time = 0;
2435                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2436                                         self.stat_respawn_time = self.respawn_time_max;
2437                                 else
2438                                         self.stat_respawn_time = self.respawn_time;
2439                         }
2440
2441                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2442                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2443                                 self.stat_respawn_time *= -1;
2444
2445                         return;
2446                 }
2447
2448                 self.prevorigin = self.origin;
2449
2450                 float do_crouch = self.BUTTON_CROUCH;
2451                 if(self.hook.state)
2452                         do_crouch = 0;
2453                 if(self.vehicle)
2454                         do_crouch = 0;
2455                 if(self.frozen)
2456                         do_crouch = 0;
2457
2458                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2459                 // It cannot be predicted by the engine!
2460                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2461                         do_crouch = 0;
2462
2463                 if (do_crouch)
2464                 {
2465                         if (!self.crouch)
2466                         {
2467                                 self.crouch = true;
2468                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2469                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2470                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2471                         }
2472                 }
2473                 else
2474                 {
2475                         if (self.crouch)
2476                         {
2477                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2478                                 if (!trace_startsolid)
2479                                 {
2480                                         self.crouch = false;
2481                                         self.view_ofs = self.stat_pl_view_ofs;
2482                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2483                                 }
2484                         }
2485                 }
2486
2487                 FixPlayermodel();
2488
2489                 GrapplingHookFrame();
2490
2491                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2492                 //if(frametime)
2493                 {
2494                         self.items &= ~self.items_added;
2495
2496                         W_WeaponFrame();
2497
2498                         self.items_added = 0;
2499                         if(self.items & IT_JETPACK)
2500                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2501                                         self.items_added |= IT_FUEL;
2502
2503                         self.items |= self.items_added;
2504                 }
2505
2506                 player_regen();
2507
2508                 // WEAPONTODO: Add a weapon request for this
2509                 // rot vortex charge to the charge limit
2510                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2511                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2512
2513                 if(frametime)
2514                         player_anim();
2515
2516                 // secret status
2517                 secrets_setstatus();
2518
2519                 // monsters status
2520                 monsters_setstatus();
2521
2522                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2523
2524                 //self.angles_y=self.v_angle_y + 90;   // temp
2525         } else if(gameover) {
2526                 if (intermission_running)
2527                         IntermissionThink ();   // otherwise a button could be missed between
2528                 return;
2529         } else if(IS_OBSERVER(self)) {
2530                 ObserverThink();
2531         } else if(IS_SPEC(self)) {
2532                 SpectatorThink();
2533         }
2534
2535         // WEAPONTODO: Add weapon request for this
2536         if(!zoomstate_set)
2537                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2538
2539         float oldspectatee_status;
2540         oldspectatee_status = self.spectatee_status;
2541         if(IS_SPEC(self))
2542                 self.spectatee_status = num_for_edict(self.enemy);
2543         else if(IS_OBSERVER(self))
2544                 self.spectatee_status = num_for_edict(self);
2545         else
2546                 self.spectatee_status = 0;
2547         if(self.spectatee_status != oldspectatee_status)
2548         {
2549                 ClientData_Touch(self);
2550         }
2551
2552         if(self.teamkill_soundtime)
2553         if(time > self.teamkill_soundtime)
2554         {
2555                 self.teamkill_soundtime = 0;
2556
2557                 entity oldpusher, oldself;
2558
2559                 oldself = self; self = self.teamkill_soundsource;
2560                 oldpusher = self.pusher; self.pusher = oldself;
2561
2562                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2563
2564                 self.pusher = oldpusher;
2565                 self = oldself;
2566         }
2567
2568         if(self.taunt_soundtime)
2569         if(time > self.taunt_soundtime)
2570         {
2571                 self.taunt_soundtime = 0;
2572                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2573         }
2574
2575         target_voicescript_next(self);
2576
2577         // WEAPONTODO: Move into weaponsystem somehow
2578         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2579         if(!self.weapon)
2580                 self.clip_load = self.clip_size = 0;
2581 }
2582
2583 /*
2584 =============
2585 PlayerPostThink
2586
2587 Called every frame for each client after the physics are run
2588 =============
2589 */
2590 .float idlekick_lasttimeleft;
2591 void PlayerPostThink (void)
2592 {
2593         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2594         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2595         {
2596                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2597                 {
2598                         if(self.idlekick_lasttimeleft)
2599                         {
2600                                 self.idlekick_lasttimeleft = 0;
2601                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2602                         }
2603                 }
2604                 else
2605                 {
2606                         float timeleft;
2607                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2608                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2609                         {
2610                                 if(!self.idlekick_lasttimeleft)
2611                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2612                         }
2613                         if(timeleft <= 0)
2614                         {
2615                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2616                                 dropclient(self);
2617                                 return;
2618                         }
2619                         else if(timeleft <= 10)
2620                         {
2621                                 if(timeleft != self.idlekick_lasttimeleft)
2622                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2623                                 self.idlekick_lasttimeleft = timeleft;
2624                         }
2625                 }
2626         }
2627
2628 #ifdef TETRIS
2629         if(self.impulse == 100)
2630                 ImpulseCommands();
2631         if (!TetrisPostFrame())
2632         {
2633 #endif
2634
2635         CheatFrame();
2636
2637         //CheckPlayerJump();
2638
2639         if(IS_PLAYER(self)) {
2640                 CheckRules_Player();
2641                 UpdateChatBubble();
2642                 if (self.impulse)
2643                         ImpulseCommands();
2644                 if (intermission_running)
2645                         return;         // intermission or finale
2646                 GetPressedKeys();
2647         }
2648
2649 #ifdef TETRIS
2650         }
2651 #endif
2652
2653         /*
2654         float i;
2655         for(i = 0; i < 1000; ++i)
2656         {
2657                 vector end;
2658                 end = self.origin + '0 0 1024' + 512 * randomvec();
2659                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2660                 if(trace_fraction < 1)
2661                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2662                 {
2663                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2664                         break;
2665                 }
2666         }
2667         */
2668
2669         if(self.waypointsprite_attachedforcarrier)
2670                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2671
2672         playerdemo_write();
2673
2674         CSQCMODEL_AUTOUPDATE();
2675 }