qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "waypointsprites.qh"
   4
   5 #include "anticheat.qh"
   6 #include "cl_impulse.qh"
   7 #include "cl_player.qh"
   8 #include "ent_cs.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "g_damage.qh"
  16 #include "g_hook.qh"
  17 #include "command/common.qh"
  18 #include "cheats.qh"
  19 #include "g_world.qh"
  20 #include "race.qh"
  21 #include "antilag.qh"
  22 #include "campaign.qh"
  23 #include "command/common.qh"
  24
  25 #include "bot/bot.qh"
  26 #include "bot/navigation.qh"
  27
  28 #include "vehicles/vehicle.qh"
  29
  30 #include "weapons/hitplot.qh"
  31 #include "weapons/weaponsystem.qh"
  32
  33 #include "../common/net_notice.qh"
  34 #include "../common/physics.qh"
  35
  36 #include "../common/triggers/subs.qh"
  37 #include "../common/triggers/triggers.qh"
  38 #include "../common/triggers/trigger/secret.qh"
  39
  40 #include "../common/items/inventory.qh"
  41
  42 #include "../common/monsters/sv_monsters.qh"
  43
  44 #include "../warpzonelib/server.qh"
  45
  46
  47 void send_CSQC_teamnagger() {
  48         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  49         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  50 }
  51
  52 float ClientData_Send(entity to, int sf)
  53 {
  54         if(to != self.owner)
  55         {
  56                 error("wtf");
  57                 return false;
  58         }
  59
  60         entity e;
  61
  62         e = to;
  63         if(IS_SPEC(to))
  64                 e = to.enemy;
  65
  66         sf = 0;
  67
  68         if(e.race_completed)
  69                 sf |= 1; // forced scoreboard
  70         if(to.spectatee_status)
  71                 sf |= 2; // spectator ent number follows
  72         if(e.zoomstate)
  73                 sf |= 4; // zoomed
  74         if(e.porto_v_angle_held)
  75                 sf |= 8; // angles held
  76
  77         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  78         WriteByte(MSG_ENTITY, sf);
  79
  80         if(sf & 2)
  81                 WriteByte(MSG_ENTITY, to.spectatee_status);
  82
  83         if(sf & 8)
  84         {
  85                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  86                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  87         }
  88
  89         return true;
  90 }
  91
  92 void ClientData_Attach()
  93 {
  94         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  95         self.clientdata.drawonlytoclient = self;
  96         self.clientdata.owner = self;
  97 }
  98
  99 void ClientData_Detach()
 100 {
 101         remove(self.clientdata);
 102         self.clientdata = world;
 103 }
 104
 105 void ClientData_Touch(entity e)
 106 {
 107         e.clientdata.SendFlags = 1;
 108
 109         // make it spectatable
 110         entity e2;
 111         FOR_EACH_REALCLIENT(e2)
 112         {
 113                 if(e2 != e)
 114                         if(IS_SPEC(e2))
 115                                 if(e2.enemy == e)
 116                                         e2.clientdata.SendFlags = 1;
 117         }
 118 }
 119
 120 .string netname_previous;
 121
 122 void SetSpectator(entity player, entity spectatee);
 123
 124
 125 /*
 126 =============
 127 CheckPlayerModel
 128
 129 Checks if the argument string can be a valid playermodel.
 130 Returns a valid one in doubt.
 131 =============
 132 */
 133 string FallbackPlayerModel;
 134 string CheckPlayerModel(string plyermodel) {
 135         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 136         {
 137                 // note: we cannot summon Don Strunzone here, some player may
 138                 // still have the model string set. In case anyone manages how
 139                 // to change a cvar default, we'll have a small leak here.
 140                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 141         }
 142         // only in right path
 143         if( substring(plyermodel,0,14) != "models/player/")
 144                 return FallbackPlayerModel;
 145         // only good file extensions
 146         if(substring(plyermodel,-4,4) != ".zym")
 147         if(substring(plyermodel,-4,4) != ".dpm")
 148         if(substring(plyermodel,-4,4) != ".iqm")
 149         if(substring(plyermodel,-4,4) != ".md3")
 150         if(substring(plyermodel,-4,4) != ".psk")
 151                 return FallbackPlayerModel;
 152         // forbid the LOD models
 153         if(substring(plyermodel, -9,5) == "_lod1")
 154                 return FallbackPlayerModel;
 155         if(substring(plyermodel, -9,5) == "_lod2")
 156                 return FallbackPlayerModel;
 157         if(plyermodel != strtolower(plyermodel))
 158                 return FallbackPlayerModel;
 159         // also, restrict to server models
 160         if(autocvar_sv_servermodelsonly)
 161         {
 162                 if(!fexists(plyermodel))
 163                         return FallbackPlayerModel;
 164         }
 165         return plyermodel;
 166 }
 167
 168 void setplayermodel(entity e, string modelname)
 169 {
 170         precache_model(modelname);
 171         setmodel(e, modelname);
 172         player_setupanimsformodel();
 173         UpdatePlayerSounds();
 174 }
 175
 176 /*
 177 =============
 178 PutObserverInServer
 179
 180 putting a client as observer in the server
 181 =============
 182 */
 183 void FixPlayermodel();
 184 void PutObserverInServer (void)
 185 {
 186         entity  spot;
 187     self.hud = HUD_NORMAL;
 188
 189         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 190
 191         spot = SelectSpawnPoint (true);
 192         if(!spot)
 193                 error("No spawnpoints for observers?!?\n");
 194         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 195
 196         if(IS_REAL_CLIENT(self))
 197         {
 198                 msg_entity = self;
 199                 WriteByte(MSG_ONE, SVC_SETVIEW);
 200                 WriteEntity(MSG_ONE, self);
 201         }
 202
 203         self.frags = FRAGS_SPECTATOR;
 204
 205         MUTATOR_CALLHOOK(MakePlayerObserver);
 206
 207         Portal_ClearAll(self);
 208
 209         Unfreeze(self);
 210
 211         if(self.alivetime)
 212         {
 213                 if(!warmup_stage)
 214                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 215                 self.alivetime = 0;
 216         }
 217
 218         if(self.vehicle)
 219                 vehicles_exit(VHEF_RELESE);
 220
 221         WaypointSprite_PlayerDead();
 222
 223         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 224                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 225
 226         if(self.killcount != -666)
 227         {
 228                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 229                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 230                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 231
 232                 if(self.just_joined == false) {
 233                         LogTeamchange(self.playerid, -1, 4);
 234                 } else
 235                         self.just_joined = false;
 236         }
 237
 238         PlayerScore_Clear(self); // clear scores when needed
 239
 240         accuracy_resend(self);
 241
 242         self.spectatortime = time;
 243
 244         self.classname = "observer";
 245         self.iscreature = false;
 246         self.teleportable = TELEPORT_SIMPLE;
 247         self.damagedbycontents = false;
 248         self.health = -666;
 249         self.takedamage = DAMAGE_NO;
 250         self.solid = SOLID_NOT;
 251         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 252         self.flags = FL_CLIENT | FL_NOTARGET;
 253         self.armorvalue = 666;
 254         self.effects = 0;
 255         self.armorvalue = autocvar_g_balance_armor_start;
 256         self.pauserotarmor_finished = 0;
 257         self.pauserothealth_finished = 0;
 258         self.pauseregen_finished = 0;
 259         self.damageforcescale = 0;
 260         self.death_time = 0;
 261         self.respawn_flags = 0;
 262         self.respawn_time = 0;
 263         self.stat_respawn_time = 0;
 264         self.alpha = 0;
 265         self.scale = 0;
 266         self.fade_time = 0;
 267         self.pain_frame = 0;
 268         self.pain_finished = 0;
 269         self.strength_finished = 0;
 270         self.invincible_finished = 0;
 271         self.superweapons_finished = 0;
 272         self.pushltime = 0;
 273         self.istypefrag = 0;
 274         self.think = func_null;
 275         self.nextthink = 0;
 276         self.hook_time = 0;
 277         self.deadflag = DEAD_NO;
 278         self.angles = spot.angles;
 279         self.angles_z = 0;
 280         self.fixangle = true;
 281         self.crouch = false;
 282         self.revival_time = 0;
 283
 284         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 285         self.prevorigin = self.origin;
 286         self.items = 0;
 287         self.weapons = '0 0 0';
 288         self.model = "";
 289         FixPlayermodel();
 290         setmodel(self, "null");
 291         self.drawonlytoclient = self;
 292
 293         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 294         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 295
 296         self.weapon = 0;
 297         self.weaponname = "";
 298         self.switchingweapon = 0;
 299         self.weaponmodel = "";
 300         self.weaponentity = world;
 301         self.exteriorweaponentity = world;
 302         self.killcount = -666;
 303         self.velocity = '0 0 0';
 304         self.avelocity = '0 0 0';
 305         self.punchangle = '0 0 0';
 306         self.punchvector = '0 0 0';
 307         self.oldvelocity = self.velocity;
 308         self.fire_endtime = -1;
 309         self.event_damage = func_null;
 310 }
 311
 312 .float model_randomizer;
 313 void FixPlayermodel()
 314 {
 315         string defaultmodel;
 316         float defaultskin, chmdl, oldskin, n, i;
 317         vector m1, m2;
 318
 319         defaultmodel = "";
 320         defaultskin = 0;
 321         chmdl = false;
 322
 323         if(autocvar_sv_defaultcharacter)
 324         {
 325                 if(teamplay)
 326                 {
 327                         string s;
 328                         s = Static_Team_ColorName_Lower(self.team);
 329                         if(s != "neutral")
 330                         {
 331                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 332                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 333                         }
 334                 }
 335
 336                 if(defaultmodel == "")
 337                 {
 338                         defaultmodel = autocvar_sv_defaultplayermodel;
 339                         defaultskin = autocvar_sv_defaultplayerskin;
 340                 }
 341
 342                 n = tokenize_console(defaultmodel);
 343                 if(n > 0)
 344                 {
 345                         defaultmodel = argv(floor(n * self.model_randomizer));
 346                         // However, do NOT randomize if the player-selected model is in the list.
 347                         for (i = 0; i < n; ++i)
 348                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 349                                         defaultmodel = argv(i);
 350                 }
 351
 352                 i = strstrofs(defaultmodel, ":", 0);
 353                 if(i >= 0)
 354                 {
 355                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 356                         defaultmodel = substring(defaultmodel, 0, i);
 357                 }
 358         }
 359
 360         if(defaultmodel != "")
 361         {
 362                 if (defaultmodel != self.model)
 363                 {
 364                         m1 = self.mins;
 365                         m2 = self.maxs;
 366                         setplayermodel (self, defaultmodel);
 367                         setsize (self, m1, m2);
 368                         chmdl = true;
 369                 }
 370
 371                 oldskin = self.skin;
 372                 self.skin = defaultskin;
 373         } else {
 374                 if (self.playermodel != self.model || self.playermodel == "")
 375                 {
 376                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 377                         m1 = self.mins;
 378                         m2 = self.maxs;
 379                         setplayermodel (self, self.playermodel);
 380                         setsize (self, m1, m2);
 381                         chmdl = true;
 382                 }
 383
 384                 oldskin = self.skin;
 385                 self.skin = stof(self.playerskin);
 386         }
 387
 388         if(chmdl || oldskin != self.skin) // model or skin has changed
 389         {
 390                 self.species = player_getspecies(); // update species
 391                 UpdatePlayerSounds(); // update skin sounds
 392         }
 393
 394         if(!teamplay)
 395                 if(strlen(autocvar_sv_defaultplayercolors))
 396                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 397                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 398 }
 399
 400 /*
 401 =============
 402 PutClientInServer
 403
 404 Called when a client spawns in the server
 405 =============
 406 */
 407 void PutClientInServer (void)
 408 {
 409         if(IS_BOT_CLIENT(self))
 410                 self.classname = "player";
 411         else if(IS_REAL_CLIENT(self))
 412         {
 413                 msg_entity = self;
 414                 WriteByte(MSG_ONE, SVC_SETVIEW);
 415                 WriteEntity(MSG_ONE, self);
 416         }
 417
 418         SetSpectator(self, world);
 419
 420         // reset player keys
 421         self.itemkeys = 0;
 422
 423         MUTATOR_CALLHOOK(PutClientInServer);
 424
 425         if(gameover)
 426                 self.classname = "observer";
 427
 428         if(IS_PLAYER(self))
 429         {
 430                 entity spot, oldself;
 431
 432                 accuracy_resend(self);
 433
 434                 if(self.team < 0)
 435                         JoinBestTeam(self, false, true);
 436
 437                 spot = SelectSpawnPoint (false);
 438                 if(!spot)
 439                 {
 440                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 441                         return; // spawn failed
 442                 }
 443
 444                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 445
 446                 if(self.vehicle)
 447                         vehicles_exit(VHEF_RELESE);
 448
 449                 self.classname = "player";
 450                 self.wasplayer = true;
 451                 self.iscreature = true;
 452                 self.teleportable = TELEPORT_NORMAL;
 453                 self.damagedbycontents = true;
 454                 self.movetype = MOVETYPE_WALK;
 455                 self.solid = SOLID_SLIDEBOX;
 456                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 457                 if(autocvar_g_playerclip_collisions)
 458                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 459                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 460                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 461                 self.frags = FRAGS_PLAYER;
 462                 if(INDEPENDENT_PLAYERS)
 463                         MAKE_INDEPENDENT_PLAYER(self);
 464                 self.flags = FL_CLIENT;
 465                 if(autocvar__notarget)
 466                         self.flags |= FL_NOTARGET;
 467                 self.takedamage = DAMAGE_AIM;
 468                 self.effects = 0;
 469                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 470                 self.air_finished = time + 12;
 471                 self.dmg = 2;
 472                 if(WEP_CVAR(vortex, charge))
 473                 {
 474                         if(WEP_CVAR_SEC(vortex, chargepool))
 475                                 self.vortex_chargepool_ammo = 1;
 476                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 477                 }
 478
 479                 if(warmup_stage)
 480                 {
 481                         self.ammo_shells = warmup_start_ammo_shells;
 482                         self.ammo_nails = warmup_start_ammo_nails;
 483                         self.ammo_rockets = warmup_start_ammo_rockets;
 484                         self.ammo_cells = warmup_start_ammo_cells;
 485                         self.ammo_plasma = warmup_start_ammo_plasma;
 486                         self.ammo_fuel = warmup_start_ammo_fuel;
 487                         self.health = warmup_start_health;
 488                         self.armorvalue = warmup_start_armorvalue;
 489                         self.weapons = WARMUP_START_WEAPONS;
 490                 }
 491                 else
 492                 {
 493                         self.ammo_shells = start_ammo_shells;
 494                         self.ammo_nails = start_ammo_nails;
 495                         self.ammo_rockets = start_ammo_rockets;
 496                         self.ammo_cells = start_ammo_cells;
 497                         self.ammo_plasma = start_ammo_plasma;
 498                         self.ammo_fuel = start_ammo_fuel;
 499                         self.health = start_health;
 500                         self.armorvalue = start_armorvalue;
 501                         self.weapons = start_weapons;
 502                 }
 503
 504                 if(self.weapons & WEPSET_SUPERWEAPONS)
 505                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 506                 else
 507                         self.superweapons_finished = 0;
 508
 509                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 510                 {
 511                         if(g_weaponarena_random_with_blaster)
 512                                 self.weapons &= ~WEPSET_BLASTER;
 513                         W_RandomWeapons(self, g_weaponarena_random);
 514                         if(g_weaponarena_random_with_blaster)
 515                                 self.weapons |= WEPSET_BLASTER;
 516                 }
 517
 518                 self.items = start_items;
 519
 520                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 521                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 522                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 523                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 524                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 525                 //extend the pause of rotting if client was reset at the beginning of the countdown
 526                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 527                         self.spawnshieldtime += game_starttime - time;
 528                         self.pauserotarmor_finished += game_starttime - time;
 529                         self.pauserothealth_finished += game_starttime - time;
 530                         self.pauseregen_finished += game_starttime - time;
 531                 }
 532                 self.damageforcescale = 2;
 533                 self.death_time = 0;
 534                 self.respawn_flags = 0;
 535                 self.respawn_time = 0;
 536                 self.stat_respawn_time = 0;
 537                 self.scale = autocvar_sv_player_scale;
 538                 self.fade_time = 0;
 539                 self.pain_frame = 0;
 540                 self.pain_finished = 0;
 541                 self.strength_finished = 0;
 542                 self.invincible_finished = 0;
 543                 self.pushltime = 0;
 544                 // players have no think function
 545                 self.think = func_null;
 546                 self.nextthink = 0;
 547                 self.hook_time = 0;
 548                 self.dmg_team = 0;
 549                 self.ballistics_density = autocvar_g_ballistics_density_player;
 550
 551                 self.metertime = 0;
 552
 553                 self.deadflag = DEAD_NO;
 554
 555                 self.angles = spot.angles;
 556
 557                 self.angles_z = 0; // never spawn tilted even if the spot says to
 558                 if(IS_BOT_CLIENT(self))
 559                         self.v_angle = self.angles;
 560                 self.fixangle = true; // turn this way immediately
 561                 self.velocity = '0 0 0';
 562                 self.avelocity = '0 0 0';
 563                 self.punchangle = '0 0 0';
 564                 self.punchvector = '0 0 0';
 565                 self.oldvelocity = self.velocity;
 566                 self.fire_endtime = -1;
 567                 self.revival_time = 0;
 568
 569                 entity spawnevent = spawn();
 570                 spawnevent.owner = self;
 571                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 572
 573                 // Cut off any still running player sounds.
 574                 stopsound(self, CH_PLAYER_SINGLE);
 575
 576                 self.model = "";
 577                 FixPlayermodel();
 578                 self.drawonlytoclient = world;
 579
 580                 self.crouch = false;
 581                 self.view_ofs = PL_VIEW_OFS;
 582                 setsize (self, PL_MIN, PL_MAX);
 583                 self.spawnorigin = spot.origin;
 584                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 585                 // don't reset back to last position, even if new position is stuck in solid
 586                 self.oldorigin = self.origin;
 587                 self.prevorigin = self.origin;
 588                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 589                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 590         self.hud = HUD_NORMAL;
 591
 592                 self.event_damage = PlayerDamage;
 593
 594                 self.bot_attack = true;
 595                 self.monster_attack = true;
 596
 597                 self.spider_slowness = 0;
 598
 599                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 600
 601                 if(self.killcount == -666) {
 602                         PlayerScore_Clear(self);
 603                         self.killcount = 0;
 604                 }
 605
 606                 CL_SpawnWeaponentity();
 607                 self.alpha = default_player_alpha;
 608                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 609                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 610
 611                 self.speedrunning = false;
 612
 613                 //stuffcmd(self, "chase_active 0");
 614                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 615
 616                 target_voicescript_clear(self);
 617
 618                 // reset fields the weapons may use
 619                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 620                 {
 621                         WEP_ACTION(j, WR_RESETPLAYER);
 622
 623                         // all weapons must be fully loaded when we spawn
 624                         entity e = get_weaponinfo(j);
 625                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 626                                 self.(weapon_load[j]) = e.reloading_ammo;
 627                 }
 628
 629                 oldself = self;
 630                 self = spot;
 631                         activator = oldself;
 632                                 string s;
 633                                 s = self.target;
 634                                 self.target = string_null;
 635                                 SUB_UseTargets();
 636                                 self.target = s;
 637                         activator = world;
 638                 self = oldself;
 639
 640                 Unfreeze(self);
 641
 642                 spawn_spot = spot;
 643                 MUTATOR_CALLHOOK(PlayerSpawn);
 644
 645                 if(autocvar_spawn_debug)
 646                 {
 647                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 648                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 649                 }
 650
 651                 self.switchweapon = w_getbestweapon(self);
 652                 self.cnt = -1; // W_LastWeapon will not complain
 653                 self.weapon = 0;
 654                 self.weaponname = "";
 655                 self.switchingweapon = 0;
 656
 657                 if(!warmup_stage)
 658                         if(!self.alivetime)
 659                                 self.alivetime = time;
 660
 661                 antilag_clear(self);
 662         }
 663         else if(IS_OBSERVER(self))
 664         {
 665                 PutObserverInServer ();
 666         }
 667 }
 668
 669 .float ebouncefactor, ebouncestop; // electro's values
 670 // TODO do we need all these fields, or should we stop autodetecting runtime
 671 // changes and just have a console command to update this?
 672 float ClientInit_SendEntity(entity to, int sf)
 673 {
 674         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 675         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 676         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 679         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 680         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 681         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 682         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 683         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 684
 685         if(sv_foginterval && world.fog != "")
 686                 WriteString(MSG_ENTITY, world.fog);
 687         else
 688                 WriteString(MSG_ENTITY, "");
 689         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 690         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 691         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 692         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 693         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 694         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 695         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 696         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 697         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 698         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 699         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 700         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 701         return true;
 702 }
 703
 704 void ClientInit_CheckUpdate()
 705 {
 706         self.nextthink = time;
 707         if(self.count != autocvar_g_balance_armor_blockpercent)
 708         {
 709                 self.count = autocvar_g_balance_armor_blockpercent;
 710                 self.SendFlags |= 1;
 711         }
 712         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 713         {
 714                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 715                 self.SendFlags |= 1;
 716         }
 717         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 718         {
 719                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 720                 self.SendFlags |= 1;
 721         }
 722         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 723         {
 724                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 725                 self.SendFlags |= 1;
 726         }
 727         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 728         {
 729                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 730                 self.SendFlags |= 1;
 731         }
 732 }
 733
 734 void ClientInit_Spawn()
 735 {
 736         entity o;
 737         entity e;
 738         e = spawn();
 739         e.classname = "clientinit";
 740         e.think = ClientInit_CheckUpdate;
 741         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 742
 743         o = self;
 744         self = e;
 745         ClientInit_CheckUpdate();
 746         self = o;
 747 }
 748
 749 /*
 750 =============
 751 SetNewParms
 752 =============
 753 */
 754 void SetNewParms (void)
 755 {
 756         // initialize parms for a new player
 757         parm1 = -(86400 * 366);
 758 }
 759
 760 /*
 761 =============
 762 SetChangeParms
 763 =============
 764 */
 765 void SetChangeParms (void)
 766 {
 767         // save parms for level change
 768         parm1 = self.parm_idlesince - time;
 769 }
 770
 771 /*
 772 =============
 773 DecodeLevelParms
 774 =============
 775 */
 776 void DecodeLevelParms (void)
 777 {
 778         // load parms
 779         self.parm_idlesince = parm1;
 780         if(self.parm_idlesince == -(86400 * 366))
 781                 self.parm_idlesince = time;
 782
 783         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 784         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 785 }
 786
 787 /*
 788 =============
 789 ClientKill
 790
 791 Called when a client types 'kill' in the console
 792 =============
 793 */
 794
 795 .float clientkill_nexttime;
 796 void ClientKill_Now_TeamChange()
 797 {
 798         if(self.killindicator_teamchange == -1)
 799         {
 800                 JoinBestTeam( self, false, true );
 801         }
 802         else if(self.killindicator_teamchange == -2)
 803         {
 804                 if(blockSpectators)
 805                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 806                 PutObserverInServer();
 807         }
 808         else
 809                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 810         self.killindicator_teamchange = 0;
 811 }
 812
 813 void ClientKill_Now()
 814 {
 815         if(self.vehicle)
 816         {
 817             vehicles_exit(VHEF_RELESE);
 818             if(!self.killindicator_teamchange)
 819             {
 820             self.vehicle_health = -1;
 821             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 822             }
 823         }
 824
 825         if(self.killindicator && !wasfreed(self.killindicator))
 826                 remove(self.killindicator);
 827
 828         self.killindicator = world;
 829
 830         if(self.killindicator_teamchange)
 831                 ClientKill_Now_TeamChange();
 832
 833         if(IS_PLAYER(self))
 834                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 835
 836         // now I am sure the player IS dead
 837 }
 838 void KillIndicator_Think()
 839 {
 840         if (gameover)
 841         {
 842                 self.owner.killindicator = world;
 843                 remove(self);
 844                 return;
 845         }
 846
 847         if (self.owner.alpha < 0 && !self.owner.vehicle)
 848         {
 849                 self.owner.killindicator = world;
 850                 remove(self);
 851                 return;
 852         }
 853
 854         if(self.cnt <= 0)
 855         {
 856                 self = self.owner;
 857                 ClientKill_Now(); // no oldself needed
 858                 return;
 859         }
 860     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 861     {
 862         self.nextthink = time + 1;
 863         self.cnt -= 1;
 864     }
 865         else
 866         {
 867                 if(self.cnt <= 10)
 868                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 869                 if(IS_REAL_CLIENT(self.owner))
 870                 {
 871                         if(self.cnt <= 10)
 872                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 873                 }
 874                 self.nextthink = time + 1;
 875                 self.cnt -= 1;
 876         }
 877 }
 878
 879 float clientkilltime;
 880 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 881 {
 882         float killtime;
 883         float starttime;
 884         entity e;
 885
 886         if (gameover)
 887                 return;
 888
 889         killtime = autocvar_g_balance_kill_delay;
 890
 891         if(g_race_qualifying || g_cts)
 892                 killtime = 0;
 893
 894     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 895     {
 896                 remove(self.killindicator);
 897                 self.killindicator = world;
 898
 899         ClientKill_Now(); // allow instant kill in this case
 900         return;
 901     }
 902
 903         self.killindicator_teamchange = targetteam;
 904
 905     if(!self.killindicator)
 906         {
 907                 if(self.deadflag == DEAD_NO)
 908                 {
 909                         killtime = max(killtime, self.clientkill_nexttime - time);
 910                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 911                 }
 912
 913                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 914                 {
 915                         ClientKill_Now();
 916                 }
 917                 else
 918                 {
 919                         starttime = max(time, clientkilltime);
 920
 921                         self.killindicator = spawn();
 922                         self.killindicator.owner = self;
 923                         self.killindicator.scale = 0.5;
 924                         setattachment(self.killindicator, self, "");
 925                         setorigin(self.killindicator, '0 0 52');
 926                         self.killindicator.think = KillIndicator_Think;
 927                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 928                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 929                         self.killindicator.cnt = ceil(killtime);
 930                         self.killindicator.count = bound(0, ceil(killtime), 10);
 931                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 932
 933                         for(e = world; (e = find(e, classname, "body")) != world; )
 934                         {
 935                                 if(e.enemy != self)
 936                                         continue;
 937                                 e.killindicator = spawn();
 938                                 e.killindicator.owner = e;
 939                                 e.killindicator.scale = 0.5;
 940                                 setattachment(e.killindicator, e, "");
 941                                 setorigin(e.killindicator, '0 0 52');
 942                                 e.killindicator.think = KillIndicator_Think;
 943                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 944                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 945                                 e.killindicator.cnt = ceil(killtime);
 946                         }
 947                         self.lip = 0;
 948                 }
 949         }
 950         if(self.killindicator)
 951         {
 952                 if(targetteam == 0) // just die
 953                 {
 954                         self.killindicator.colormod = '0 0 0';
 955                         if(IS_REAL_CLIENT(self))
 956                         if(self.killindicator.cnt > 0)
 957                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 958                 }
 959                 else if(targetteam == -1) // auto
 960                 {
 961                         self.killindicator.colormod = '0 1 0';
 962                         if(IS_REAL_CLIENT(self))
 963                         if(self.killindicator.cnt > 0)
 964                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 965                 }
 966                 else if(targetteam == -2) // spectate
 967                 {
 968                         self.killindicator.colormod = '0.5 0.5 0.5';
 969                         if(IS_REAL_CLIENT(self))
 970                         if(self.killindicator.cnt > 0)
 971                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 972                 }
 973                 else
 974                 {
 975                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 976                         if(IS_REAL_CLIENT(self))
 977                         if(self.killindicator.cnt > 0)
 978                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 979                 }
 980         }
 981
 982 }
 983
 984 void ClientKill (void)
 985 {
 986         if(gameover) return;
 987         if(self.player_blocked) return;
 988         if(self.frozen) return;
 989
 990         ClientKill_TeamChange(0);
 991 }
 992
 993 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 994 {
 995     e.killindicator = spawn();
 996     e.killindicator.owner = e;
 997     e.killindicator.think = KillIndicator_Think;
 998     e.killindicator.nextthink = time + (e.lip) * 0.05;
 999     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1000     e.killindicator.health = 1; // this is used to indicate that it should be silent
1001     e.lip = 0;
1002 }
1003
1004 void FixClientCvars(entity e)
1005 {
1006         // send prediction settings to the client
1007         stuffcmd(e, "\nin_bindmap 0 0\n");
1008         if(g_race || g_cts)
1009                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1010         if(autocvar_g_antilag == 3) // client side hitscan
1011                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1012         if(autocvar_sv_gentle)
1013                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1014 }
1015
1016 float PlayerInIDList(entity p, string idlist)
1017 {
1018         float n, i;
1019         string s;
1020
1021         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1022         if (!p.crypto_idfp)
1023                 return 0;
1024
1025         // this function allows abbreviated player IDs too!
1026         n = tokenize_console(idlist);
1027         for(i = 0; i < n; ++i)
1028         {
1029                 s = argv(i);
1030                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1031                         return 1;
1032         }
1033
1034         return 0;
1035 }
1036
1037 #ifdef DP_EXT_PRECONNECT
1038 /*
1039 =============
1040 ClientPreConnect
1041
1042 Called once (not at each match start) when a client begins a connection to the server
1043 =============
1044 */
1045 void ClientPreConnect (void)
1046 {
1047         if(autocvar_sv_eventlog)
1048         {
1049                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1050                         self.playerid,
1051                         num_for_edict(self),
1052                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1053                 ));
1054         }
1055 }
1056 #endif
1057
1058 /*
1059 =============
1060 ClientConnect
1061
1062 Called when a client connects to the server
1063 =============
1064 */
1065 void DecodeLevelParms (void);
1066 //void dom_player_join_team(entity pl);
1067 void set_dom_state(entity e);
1068 void ClientConnect (void)
1069 {
1070         float t;
1071
1072         if(IS_CLIENT(self))
1073         {
1074                 print("Warning: ClientConnect, but already connected!\n");
1075                 return;
1076         }
1077
1078         if(Ban_MaybeEnforceBanOnce(self))
1079                 return;
1080
1081         DecodeLevelParms();
1082
1083 #ifdef WATERMARK
1084         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1085 #endif
1086
1087         self.classname = "player_joining";
1088
1089         self.flags = FL_CLIENT;
1090         self.version_nagtime = time + 10 + random() * 10;
1091
1092         if(player_count<0)
1093         {
1094                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1095                 player_count = 0;
1096         }
1097
1098         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1099
1100         PlayerScore_Attach(self);
1101         ClientData_Attach();
1102         accuracy_init(self);
1103         Inventory_new(self);
1104
1105         bot_clientconnect();
1106
1107         playerdemo_init();
1108
1109         anticheat_init();
1110
1111         // identify the right forced team
1112         if(autocvar_g_campaign)
1113         {
1114                 if(IS_REAL_CLIENT(self)) // only players, not bots
1115                 {
1116                         switch(autocvar_g_campaign_forceteam)
1117                         {
1118                                 case 1: self.team_forced = NUM_TEAM_1; break;
1119                                 case 2: self.team_forced = NUM_TEAM_2; break;
1120                                 case 3: self.team_forced = NUM_TEAM_3; break;
1121                                 case 4: self.team_forced = NUM_TEAM_4; break;
1122                                 default: self.team_forced = 0;
1123                         }
1124                 }
1125         }
1126         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1127                 self.team_forced = NUM_TEAM_1;
1128         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1129                 self.team_forced = NUM_TEAM_2;
1130         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1131                 self.team_forced = NUM_TEAM_3;
1132         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1133                 self.team_forced = NUM_TEAM_4;
1134         else if(autocvar_g_forced_team_otherwise == "red")
1135                 self.team_forced = NUM_TEAM_1;
1136         else if(autocvar_g_forced_team_otherwise == "blue")
1137                 self.team_forced = NUM_TEAM_2;
1138         else if(autocvar_g_forced_team_otherwise == "yellow")
1139                 self.team_forced = NUM_TEAM_3;
1140         else if(autocvar_g_forced_team_otherwise == "pink")
1141                 self.team_forced = NUM_TEAM_4;
1142         else if(autocvar_g_forced_team_otherwise == "spectate")
1143                 self.team_forced = -1;
1144         else if(autocvar_g_forced_team_otherwise == "spectator")
1145                 self.team_forced = -1;
1146         else
1147                 self.team_forced = 0;
1148
1149         if(!teamplay)
1150                 if(self.team_forced > 0)
1151                         self.team_forced = 0;
1152
1153         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1154
1155         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1156                 self.classname = "observer";
1157         } else {
1158                 if(teamplay)
1159                 {
1160                         if(autocvar_g_balance_teams)
1161                         {
1162                                 self.classname = "player";
1163                                 campaign_bots_may_start = 1;
1164                         }
1165                         else
1166                         {
1167                                 self.classname = "observer"; // do it anyway
1168                         }
1169                 }
1170                 else
1171                 {
1172                         self.classname = "player";
1173                         campaign_bots_may_start = 1;
1174                 }
1175         }
1176
1177         self.playerid = (playerid_last = playerid_last + 1);
1178
1179         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1180
1181     if(IS_BOT_CLIENT(self))
1182         PlayerStats_GameReport_AddPlayer(self);
1183
1184         if(autocvar_sv_eventlog)
1185                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1186
1187         LogTeamchange(self.playerid, self.team, 1);
1188
1189         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1190
1191         self.netname_previous = strzone(self.netname);
1192
1193         if(IS_PLAYER(self) && teamplay)
1194                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1195         else
1196                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1197
1198         stuffcmd(self, strcat(clientstuff, "\n"));
1199         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1200
1201         FixClientCvars(self);
1202
1203         // spawnfunc_waypoint sprites
1204         WaypointSprite_InitClient(self);
1205
1206         // Wazat's grappling hook
1207         SetGrappleHookBindings();
1208
1209         // Jetpack binds
1210         stuffcmd(self, "alias +jetpack +button10\n");
1211         stuffcmd(self, "alias -jetpack -button10\n");
1212
1213         // get version info from player
1214         stuffcmd(self, "cmd clientversion $gameversion\n");
1215
1216         // get other cvars from player
1217         GetCvars(0);
1218
1219         // notify about available teams
1220         if(teamplay)
1221         {
1222                 CheckAllowedTeams(self);
1223                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1224                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1225         }
1226         else
1227                 stuffcmd(self, "set _teams_available 0\n");
1228
1229         attach_entcs();
1230
1231         bot_relinkplayerlist();
1232
1233         self.spectatortime = time;
1234         if(blockSpectators)
1235         {
1236                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1237         }
1238
1239         self.jointime = time;
1240         self.allowed_timeouts = autocvar_sv_timeout_number;
1241
1242         if(IS_REAL_CLIENT(self))
1243         {
1244                 if(!autocvar_g_campaign)
1245                 {
1246                         self.motd_actived_time = -1;
1247                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1248                 }
1249
1250                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1251                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1252         }
1253
1254         if(!sv_foginterval && world.fog != "")
1255                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1256
1257         W_HitPlotOpen(self);
1258
1259         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1260                 send_CSQC_teamnagger();
1261
1262         CheatInitClient();
1263
1264         CSQCMODEL_AUTOINIT();
1265
1266         self.model_randomizer = random();
1267
1268         if(IS_REAL_CLIENT(self))
1269                 sv_notice_join();
1270
1271         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1272                 entity oldself = self;
1273                 self = e;
1274                 e.init_for_player(oldself);
1275                 self = oldself;
1276         }
1277
1278         MUTATOR_CALLHOOK(ClientConnect);
1279 }
1280 /*
1281 =============
1282 ClientDisconnect
1283
1284 Called when a client disconnects from the server
1285 =============
1286 */
1287 .entity chatbubbleentity;
1288 void ReadyCount();
1289 void ClientDisconnect (void)
1290 {
1291         if(self.vehicle)
1292             vehicles_exit(VHEF_RELESE);
1293
1294         if (!IS_CLIENT(self))
1295         {
1296                 print("Warning: ClientDisconnect without ClientConnect\n");
1297                 return;
1298         }
1299
1300         PlayerStats_GameReport_FinalizePlayer(self);
1301
1302         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1303
1304         CheatShutdownClient();
1305
1306         W_HitPlotClose(self);
1307
1308         anticheat_report();
1309         anticheat_shutdown();
1310
1311         playerdemo_shutdown();
1312
1313         bot_clientdisconnect();
1314
1315         if(self.entcs)
1316                 detach_entcs();
1317
1318         if(autocvar_sv_eventlog)
1319                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1320
1321         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1322
1323         MUTATOR_CALLHOOK(ClientDisconnect);
1324
1325         Portal_ClearAll(self);
1326
1327         Unfreeze(self);
1328
1329         RemoveGrapplingHook(self);
1330
1331         // Here, everything has been done that requires this player to be a client.
1332
1333         self.flags &= ~FL_CLIENT;
1334
1335         if (self.chatbubbleentity)
1336                 remove (self.chatbubbleentity);
1337
1338         if (self.killindicator)
1339                 remove (self.killindicator);
1340
1341         WaypointSprite_PlayerGone();
1342
1343         bot_relinkplayerlist();
1344
1345         accuracy_free(self);
1346         Inventory_delete(self);
1347         ClientData_Detach();
1348         PlayerScore_Detach(self);
1349
1350         if(self.netname_previous)
1351                 strunzone(self.netname_previous);
1352         if(self.clientstatus)
1353                 strunzone(self.clientstatus);
1354         if(self.weaponorder_byimpulse)
1355                 strunzone(self.weaponorder_byimpulse);
1356
1357         ClearPlayerSounds();
1358
1359         if(self.personal)
1360                 remove(self.personal);
1361
1362         self.playerid = 0;
1363         ReadyCount();
1364
1365         // free cvars
1366         GetCvars(-1);
1367 }
1368
1369 .float BUTTON_CHAT;
1370 void ChatBubbleThink()
1371 {
1372         self.nextthink = time;
1373         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1374         {
1375                 if(self.owner) // but why can that ever be world?
1376                         self.owner.chatbubbleentity = world;
1377                 remove(self);
1378                 return;
1379         }
1380         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1381 #ifdef TETRIS
1382                 || self.owner.tetris_on
1383 #endif
1384         )
1385                 self.model = self.mdl;
1386         else
1387                 self.model = "";
1388 }
1389
1390 void UpdateChatBubble()
1391 {
1392         if (self.alpha < 0)
1393                 return;
1394         // spawn a chatbubble entity if needed
1395         if (!self.chatbubbleentity)
1396         {
1397                 self.chatbubbleentity = spawn();
1398                 self.chatbubbleentity.owner = self;
1399                 self.chatbubbleentity.exteriormodeltoclient = self;
1400                 self.chatbubbleentity.think = ChatBubbleThink;
1401                 self.chatbubbleentity.nextthink = time;
1402                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1403                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1404                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1405                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1406                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1407                 self.chatbubbleentity.model = "";
1408                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1409         }
1410 }
1411
1412
1413 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1414 // added to the model skins
1415 /*void UpdateColorModHack()
1416 {
1417         float c;
1418         c = self.clientcolors & 15;
1419         // LordHavoc: only bothering to support white, green, red, yellow, blue
1420              if (!teamplay) self.colormod = '0 0 0';
1421         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1422         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1423         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1424         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1425         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1426         else self.colormod = '1 1 1';
1427 }*/
1428
1429 void respawn(void)
1430 {
1431         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1432         {
1433                 self.solid = SOLID_NOT;
1434                 self.takedamage = DAMAGE_NO;
1435                 self.movetype = MOVETYPE_FLY;
1436                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1437                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1438                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1439                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1440                 if(autocvar_g_respawn_ghosts_maxtime)
1441                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1442         }
1443
1444         CopyBody(1);
1445
1446         self.effects |= EF_NODRAW; // prevent another CopyBody
1447         PutClientInServer();
1448 }
1449
1450 void play_countdown(float finished, string samp)
1451 {
1452         if(IS_REAL_CLIENT(self))
1453                 if(floor(finished - time - frametime) != floor(finished - time))
1454                         if(finished - time < 6)
1455                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1456 }
1457
1458 void player_powerups (void)
1459 {
1460         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1461         olditems = self.items;
1462
1463         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1464                 self.modelflags |= MF_ROCKET;
1465         else
1466                 self.modelflags &= ~MF_ROCKET;
1467
1468         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1469
1470         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1471                 return;
1472
1473         Fire_ApplyDamage(self);
1474         Fire_ApplyEffect(self);
1475
1476         if (!g_instagib)
1477         {
1478                 if (self.items & IT_STRENGTH)
1479                 {
1480                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1481                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1482                         if (time > self.strength_finished)
1483                         {
1484                                 self.items = self.items - (self.items & IT_STRENGTH);
1485                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1486                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1487                         }
1488                 }
1489                 else
1490                 {
1491                         if (time < self.strength_finished)
1492                         {
1493                                 self.items = self.items | IT_STRENGTH;
1494                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1495                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1496                         }
1497                 }
1498                 if (self.items & IT_INVINCIBLE)
1499                 {
1500                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1501                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1502                         if (time > self.invincible_finished)
1503                         {
1504                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1505                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1506                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1507                         }
1508                 }
1509                 else
1510                 {
1511                         if (time < self.invincible_finished)
1512                         {
1513                                 self.items = self.items | IT_INVINCIBLE;
1514                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1515                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1516                         }
1517                 }
1518                 if (self.items & IT_SUPERWEAPON)
1519                 {
1520                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1521                         {
1522                                 self.superweapons_finished = 0;
1523                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1524                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1525                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1526                         }
1527                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1528                         {
1529                                 // don't let them run out
1530                         }
1531                         else
1532                         {
1533                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1534                                 if (time > self.superweapons_finished)
1535                                 {
1536                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1537                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1538                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1539                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1540                                 }
1541                         }
1542                 }
1543                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1544                 {
1545                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1546                         {
1547                                 self.items = self.items | IT_SUPERWEAPON;
1548                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1549                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1550                         }
1551                         else
1552                         {
1553                                 self.superweapons_finished = 0;
1554                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1555                         }
1556                 }
1557                 else
1558                 {
1559                         self.superweapons_finished = 0;
1560                 }
1561         }
1562
1563         if(autocvar_g_nodepthtestplayers)
1564                 self.effects = self.effects | EF_NODEPTHTEST;
1565
1566         if(autocvar_g_fullbrightplayers)
1567                 self.effects = self.effects | EF_FULLBRIGHT;
1568
1569         if (time >= game_starttime)
1570         if (time < self.spawnshieldtime)
1571                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1572
1573         MUTATOR_CALLHOOK(PlayerPowerups);
1574 }
1575
1576 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1577 {
1578         if(current > stable)
1579                 return current;
1580         else if(current > stable - 0.25) // when close enough, "snap"
1581                 return stable;
1582         else
1583                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1584 }
1585
1586 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1587 {
1588         if(current < stable)
1589                 return current;
1590         else if(current < stable + 0.25) // when close enough, "snap"
1591                 return stable;
1592         else
1593                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1594 }
1595
1596 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1597 {
1598         if(current > rotstable)
1599         {
1600                 if(rotframetime > 0)
1601                 {
1602                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1603                         current = max(rotstable, current - rotlinear * rotframetime);
1604                 }
1605         }
1606         else if(current < regenstable)
1607         {
1608                 if(regenframetime > 0)
1609                 {
1610                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1611                         current = min(regenstable, current + regenlinear * regenframetime);
1612                 }
1613         }
1614
1615         if(current > limit)
1616                 current = limit;
1617
1618         return current;
1619 }
1620
1621 void player_regen (void)
1622 {
1623         float max_mod, regen_mod, rot_mod, limit_mod;
1624         max_mod = regen_mod = rot_mod = limit_mod = 1;
1625         regen_mod_max = max_mod;
1626         regen_mod_regen = regen_mod;
1627         regen_mod_rot = rot_mod;
1628         regen_mod_limit = limit_mod;
1629         if(!MUTATOR_CALLHOOK(PlayerRegen))
1630         if(!self.frozen)
1631         {
1632                 float minh, mina, maxh, maxa, limith, limita;
1633                 maxh = autocvar_g_balance_health_rotstable;
1634                 maxa = autocvar_g_balance_armor_rotstable;
1635                 minh = autocvar_g_balance_health_regenstable;
1636                 mina = autocvar_g_balance_armor_regenstable;
1637                 limith = autocvar_g_balance_health_limit;
1638                 limita = autocvar_g_balance_armor_limit;
1639
1640                 max_mod = regen_mod_max;
1641                 regen_mod = regen_mod_regen;
1642                 rot_mod = regen_mod_rot;
1643                 limit_mod = regen_mod_limit;
1644
1645                 maxh = maxh * max_mod;
1646                 minh = minh * max_mod;
1647                 limith = limith * limit_mod;
1648                 limita = limita * limit_mod;
1649
1650                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1651                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1652         }
1653
1654         // if player rotted to death...  die!
1655         // check this outside above checks, as player may still be able to rot to death
1656         if(self.health < 1)
1657                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1658
1659         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1660         {
1661                 float minf, maxf, limitf;
1662
1663                 maxf = autocvar_g_balance_fuel_rotstable;
1664                 minf = autocvar_g_balance_fuel_regenstable;
1665                 limitf = autocvar_g_balance_fuel_limit;
1666
1667                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1668         }
1669 }
1670
1671 float zoomstate_set;
1672 void SetZoomState(float z)
1673 {
1674         if(z != self.zoomstate)
1675         {
1676                 self.zoomstate = z;
1677                 ClientData_Touch(self);
1678         }
1679         zoomstate_set = 1;
1680 }
1681
1682 void GetPressedKeys(void) {
1683         MUTATOR_CALLHOOK(GetPressedKeys);
1684         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1685         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1686         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1687         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1688         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1689
1690         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1691         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1692         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1693         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1694         #undef X
1695 }
1696
1697 /*
1698 ======================
1699 spectate mode routines
1700 ======================
1701 */
1702
1703 void SpectateCopy(entity spectatee) {
1704         other = spectatee;
1705         MUTATOR_CALLHOOK(SpectateCopy);
1706         self.armortype = spectatee.armortype;
1707         self.armorvalue = spectatee.armorvalue;
1708         self.ammo_cells = spectatee.ammo_cells;
1709         self.ammo_plasma = spectatee.ammo_plasma;
1710         self.ammo_shells = spectatee.ammo_shells;
1711         self.ammo_nails = spectatee.ammo_nails;
1712         self.ammo_rockets = spectatee.ammo_rockets;
1713         self.ammo_fuel = spectatee.ammo_fuel;
1714         self.clip_load = spectatee.clip_load;
1715         self.clip_size = spectatee.clip_size;
1716         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1717         self.health = spectatee.health;
1718         self.impulse = 0;
1719         self.items = spectatee.items;
1720         self.last_pickup = spectatee.last_pickup;
1721         self.hit_time = spectatee.hit_time;
1722         self.metertime = spectatee.metertime;
1723         self.strength_finished = spectatee.strength_finished;
1724         self.invincible_finished = spectatee.invincible_finished;
1725         self.pressedkeys = spectatee.pressedkeys;
1726         self.weapons = spectatee.weapons;
1727         self.switchweapon = spectatee.switchweapon;
1728         self.switchingweapon = spectatee.switchingweapon;
1729         self.weapon = spectatee.weapon;
1730         self.vortex_charge = spectatee.vortex_charge;
1731         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1732         self.hagar_load = spectatee.hagar_load;
1733         self.arc_heat_percent = spectatee.arc_heat_percent;
1734         self.minelayer_mines = spectatee.minelayer_mines;
1735         self.punchangle = spectatee.punchangle;
1736         self.view_ofs = spectatee.view_ofs;
1737         self.velocity = spectatee.velocity;
1738         self.dmg_take = spectatee.dmg_take;
1739         self.dmg_save = spectatee.dmg_save;
1740         self.dmg_inflictor = spectatee.dmg_inflictor;
1741         self.v_angle = spectatee.v_angle;
1742         self.angles = spectatee.v_angle;
1743         self.frozen = spectatee.frozen;
1744         self.revive_progress = spectatee.revive_progress;
1745         if(!self.BUTTON_USE)
1746                 self.fixangle = true;
1747         setorigin(self, spectatee.origin);
1748         setsize(self, spectatee.mins, spectatee.maxs);
1749         SetZoomState(spectatee.zoomstate);
1750
1751     anticheat_spectatecopy(spectatee);
1752         self.hud = spectatee.hud;
1753         if(spectatee.vehicle)
1754     {
1755         self.fixangle = false;
1756         //self.velocity = spectatee.vehicle.velocity;
1757         self.vehicle_health = spectatee.vehicle_health;
1758         self.vehicle_shield = spectatee.vehicle_shield;
1759         self.vehicle_energy = spectatee.vehicle_energy;
1760         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1761         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1762         self.vehicle_reload1 = spectatee.vehicle_reload1;
1763         self.vehicle_reload2 = spectatee.vehicle_reload2;
1764
1765         msg_entity = self;
1766
1767         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1768             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1769             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1770             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1771
1772         //WriteByte (MSG_ONE, SVC_SETVIEW);
1773         //    WriteEntity(MSG_ONE, self);
1774         //makevectors(spectatee.v_angle);
1775         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1776     }
1777 }
1778
1779 float SpectateUpdate()
1780 {
1781         if(!self.enemy)
1782             return 0;
1783
1784         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1785         {
1786                 SetSpectator(self, world);
1787                 return 0;
1788         }
1789
1790         SpectateCopy(self.enemy);
1791
1792         return 1;
1793 }
1794
1795 float SpectateSet()
1796 {
1797         if(self.enemy.classname != "player")
1798                 return false;
1799         /*if(self.enemy.vehicle)
1800         {
1801
1802                 msg_entity = self;
1803                 WriteByte(MSG_ONE, SVC_SETVIEW);
1804                 WriteEntity(MSG_ONE, self.enemy);
1805                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1806
1807                 self.movetype = MOVETYPE_NONE;
1808                 accuracy_resend(self);
1809         }
1810         else
1811         {*/
1812                 msg_entity = self;
1813                 WriteByte(MSG_ONE, SVC_SETVIEW);
1814                 WriteEntity(MSG_ONE, self.enemy);
1815                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1816                 self.movetype = MOVETYPE_NONE;
1817                 accuracy_resend(self);
1818
1819                 if(!SpectateUpdate())
1820                         PutObserverInServer();
1821         //}
1822         return true;
1823 }
1824
1825 void SetSpectator(entity player, entity spectatee)
1826 {
1827         entity old_spectatee = player.enemy;
1828
1829         player.enemy = spectatee;
1830
1831         // WEAPONTODO
1832         // these are required to fix the spectator bug with arc
1833         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1834         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1835 }
1836
1837 float Spectate(entity pl)
1838 {
1839         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1840         if(pl.team != self.team)
1841                 return 0;
1842
1843         SetSpectator(self, pl);
1844         return SpectateSet();
1845 }
1846
1847 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1848 entity CA_SpectateNext(entity start) {
1849         if (start.team == self.team) {
1850                 return start;
1851         }
1852
1853         other = start;
1854         // continue from current player
1855         while(other && other.team != self.team) {
1856                 other = find(other, classname, "player");
1857         }
1858
1859         if (!other) {
1860                 // restart from begining
1861                 other = find(other, classname, "player");
1862                 while(other && other.team != self.team) {
1863                         other = find(other, classname, "player");
1864                 }
1865         }
1866
1867         return other;
1868 }
1869
1870 float SpectateNext()
1871 {
1872         other = find(self.enemy, classname, "player");
1873
1874         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1875                 // CA and ca players when spectating enemies is forbidden
1876                 other = CA_SpectateNext(other);
1877         } else {
1878                 // other modes and ca spectators or spectating enemies is allowed
1879                 if (!other)
1880                         other = find(other, classname, "player");
1881         }
1882
1883         if(other) { SetSpectator(self, other); }
1884
1885         return SpectateSet();
1886 }
1887
1888 float SpectatePrev()
1889 {
1890         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1891         other = findchain(classname, "player");
1892         if (!other) // no player
1893                 return false;
1894
1895         entity first = other;
1896         // skip players until current spectated player
1897         if(self.enemy)
1898         while(other && other != self.enemy)
1899                 other = other.chain;
1900
1901         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1902         {
1903                 do { other = other.chain; }
1904                 while(other && other.team != self.team);
1905
1906                 if (!other)
1907                 {
1908                         other = first;
1909                         while(other.team != self.team)
1910                                 other = other.chain;
1911                         if(other == self.enemy)
1912                                 return true;
1913                 }
1914         }
1915         else
1916         {
1917                 if(other.chain)
1918                         other = other.chain;
1919                 else
1920                         other = first;
1921         }
1922         SetSpectator(self, other);
1923         return SpectateSet();
1924 }
1925
1926 /*
1927 =============
1928 ShowRespawnCountdown()
1929
1930 Update a respawn countdown display.
1931 =============
1932 */
1933 void ShowRespawnCountdown()
1934 {
1935         float number;
1936         if(self.deadflag == DEAD_NO) // just respawned?
1937                 return;
1938         else
1939         {
1940                 number = ceil(self.respawn_time - time);
1941                 if(number <= 0)
1942                         return;
1943                 if(number <= self.respawn_countdown)
1944                 {
1945                         self.respawn_countdown = number - 1;
1946                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1947                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1948                 }
1949         }
1950 }
1951
1952 void LeaveSpectatorMode()
1953 {
1954         if(self.caplayer)
1955                 return;
1956         if(nJoinAllowed(self))
1957         {
1958                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1959                 {
1960                         self.classname = "player";
1961                         nades_RemoveBonus(self);
1962
1963                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1964                                 { JoinBestTeam(self, false, true); }
1965
1966                         if(autocvar_g_campaign)
1967                                 { campaign_bots_may_start = 1; }
1968
1969                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1970
1971                         PutClientInServer();
1972
1973                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1974                 }
1975                 else
1976                         stuffcmd(self, "menu_showteamselect\n");
1977         }
1978         else
1979         {
1980                 // Player may not join because g_maxplayers is set
1981                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1982         }
1983 }
1984
1985 /**
1986  * Determines whether the player is allowed to join. This depends on cvar
1987  * g_maxplayers, if it isn't used this function always return true, otherwise
1988  * it checks whether the number of currently playing players exceeds g_maxplayers.
1989  * @return int number of free slots for players, 0 if none
1990  */
1991 float nJoinAllowed(entity ignore) {
1992         if(!ignore)
1993         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1994         // so report 0 free slots if restricted
1995         {
1996                 if(autocvar_g_forced_team_otherwise == "spectate")
1997                         return 0;
1998                 if(autocvar_g_forced_team_otherwise == "spectator")
1999                         return 0;
2000         }
2001
2002         if(self.team_forced < 0)
2003                 return 0; // forced spectators can never join
2004
2005         // TODO simplify this
2006         entity e;
2007         float totalClients = 0;
2008         FOR_EACH_CLIENT(e)
2009                 if(e != ignore)
2010                         totalClients += 1;
2011
2012         if (!autocvar_g_maxplayers)
2013                 return maxclients - totalClients;
2014
2015         float currentlyPlaying = 0;
2016         FOR_EACH_REALCLIENT(e)
2017                 if(IS_PLAYER(e) || e.caplayer)
2018                         currentlyPlaying += 1;
2019
2020         if(currentlyPlaying < autocvar_g_maxplayers)
2021                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2022
2023         return 0;
2024 }
2025
2026 /**
2027  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2028  * g_maxplayers_spectator_blocktime seconds
2029  */
2030 void checkSpectatorBlock() {
2031         if(IS_SPEC(self) || IS_OBSERVER(self))
2032         if(!self.caplayer)
2033         if(IS_REAL_CLIENT(self))
2034         {
2035                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2036                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2037                         dropclient(self);
2038                 }
2039         }
2040 }
2041
2042 void PrintWelcomeMessage()
2043 {
2044         if(self.motd_actived_time == 0)
2045         {
2046                 if (autocvar_g_campaign) {
2047                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2048                                 self.motd_actived_time = time;
2049                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2050                         }
2051                 } else {
2052                         if (self.BUTTON_INFO) {
2053                                 self.motd_actived_time = time;
2054                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2055                         }
2056                 }
2057         }
2058         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2059         {
2060                 if (autocvar_g_campaign) {
2061                         if (self.BUTTON_INFO)
2062                                 self.motd_actived_time = time;
2063                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2064                                 self.motd_actived_time = 0;
2065                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2066                         }
2067                 } else {
2068                         if (self.BUTTON_INFO)
2069                                 self.motd_actived_time = time;
2070                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2071                                 self.motd_actived_time = 0;
2072                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2073                         }
2074                 }
2075         }
2076         else //if(self.motd_actived_time < 0) // just connected, motd is active
2077         {
2078                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2079                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2080                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2081                 {
2082                         // instanctly hide MOTD
2083                         self.motd_actived_time = 0;
2084                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2085                 }
2086         }
2087 }
2088
2089 void ObserverThink()
2090 {
2091         float prefered_movetype;
2092         if (self.flags & FL_JUMPRELEASED) {
2093                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2094                         self.flags &= ~FL_JUMPRELEASED;
2095                         self.flags |= FL_SPAWNING;
2096                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2097                         self.flags &= ~FL_JUMPRELEASED;
2098                         if(SpectateNext()) {
2099                                 self.classname = "spectator";
2100                         }
2101                 } else {
2102                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2103                         if (self.movetype != prefered_movetype)
2104                                 self.movetype = prefered_movetype;
2105                 }
2106         } else {
2107                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2108                         self.flags |= FL_JUMPRELEASED;
2109                         if(self.flags & FL_SPAWNING)
2110                         {
2111                                 self.flags &= ~FL_SPAWNING;
2112                                 LeaveSpectatorMode();
2113                                 return;
2114                         }
2115                 }
2116         }
2117 }
2118
2119 void SpectatorThink()
2120 {
2121         if (self.flags & FL_JUMPRELEASED) {
2122                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2123                         self.flags &= ~FL_JUMPRELEASED;
2124                         self.flags |= FL_SPAWNING;
2125                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2126                         self.flags &= ~FL_JUMPRELEASED;
2127                         if(SpectateNext()) {
2128                                 self.classname = "spectator";
2129                         } else {
2130                                 self.classname = "observer";
2131                                 PutClientInServer();
2132                         }
2133                         self.impulse = 0;
2134                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2135                         self.flags &= ~FL_JUMPRELEASED;
2136                         if(SpectatePrev()) {
2137                                 self.classname = "spectator";
2138                         } else {
2139                                 self.classname = "observer";
2140                                 PutClientInServer();
2141                         }
2142                         self.impulse = 0;
2143                 } else if (self.BUTTON_ATCK2) {
2144                         self.flags &= ~FL_JUMPRELEASED;
2145                         self.classname = "observer";
2146                         PutClientInServer();
2147                 } else {
2148                         if(!SpectateUpdate())
2149                                 PutObserverInServer();
2150                 }
2151         } else {
2152                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2153                         self.flags |= FL_JUMPRELEASED;
2154                         if(self.flags & FL_SPAWNING)
2155                         {
2156                                 self.flags &= ~FL_SPAWNING;
2157                                 LeaveSpectatorMode();
2158                                 return;
2159                         }
2160                 }
2161                 if(!SpectateUpdate())
2162                         PutObserverInServer();
2163         }
2164
2165         self.flags |= FL_CLIENT | FL_NOTARGET;
2166 }
2167
2168 void PlayerUseKey()
2169 {
2170         if (!IS_PLAYER(self))
2171                 return;
2172
2173         if(self.vehicle)
2174         {
2175         vehicles_exit(VHEF_NORMAL);
2176         return;
2177         }
2178
2179         // a use key was pressed; call handlers
2180         MUTATOR_CALLHOOK(PlayerUseKey);
2181 }
2182
2183 float isInvisibleString(string s)
2184 {
2185         float i, n, c;
2186         s = strdecolorize(s);
2187         for((i = 0), (n = strlen(s)); i < n; ++i)
2188         {
2189                 c = str2chr(s, i);
2190                 switch(c)
2191                 {
2192                         case 0:
2193                         case 32: // space
2194                                 break;
2195                         case 192: // charmap space
2196                                 if (!autocvar_utf8_enable)
2197                                         break;
2198                                 return false;
2199                         case 160: // space in unicode fonts
2200                         case 0xE000 + 192: // utf8 charmap space
2201                                 if (autocvar_utf8_enable)
2202                                         break;
2203                         default:
2204                                 return false;
2205                 }
2206         }
2207         return true;
2208 }
2209
2210 /*
2211 =============
2212 PlayerPreThink
2213
2214 Called every frame for each client before the physics are run
2215 =============
2216 */
2217 .float usekeypressed;
2218 void() nexball_setstatus;
2219 .int items_added;
2220 void PlayerPreThink (void)
2221 {
2222         WarpZone_PlayerPhysics_FixVAngle();
2223
2224         self.stat_game_starttime = game_starttime;
2225         self.stat_round_starttime = round_starttime;
2226         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2227         self.stat_leadlimit = autocvar_leadlimit;
2228
2229         if(frametime)
2230         {
2231                 // physics frames: update anticheat stuff
2232                 anticheat_prethink();
2233         }
2234
2235         if(blockSpectators && frametime)
2236                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2237                 checkSpectatorBlock();
2238
2239         zoomstate_set = 0;
2240
2241         // Savage: Check for nameless players
2242         if (isInvisibleString(self.netname)) {
2243                 string new_name = strzone(strcat("Player@", self.netaddress));
2244                 if(autocvar_sv_eventlog)
2245                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2246                 if(self.netname_previous)
2247                         strunzone(self.netname_previous);
2248                 self.netname_previous = strzone(new_name);
2249                 self.netname = self.netname_previous;
2250                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2251         } else if(self.netname_previous != self.netname) {
2252                 if(autocvar_sv_eventlog)
2253                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2254                 if(self.netname_previous)
2255                         strunzone(self.netname_previous);
2256                 self.netname_previous = strzone(self.netname);
2257         }
2258
2259         // version nagging
2260         if(self.version_nagtime)
2261                 if(self.cvar_g_xonoticversion)
2262                         if(time > self.version_nagtime)
2263                         {
2264                                 // don't notify git users
2265                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2266                                 {
2267                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2268                                         {
2269                                                 // notify release users if connecting to git
2270                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2271                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2272                                         }
2273                                         else
2274                                         {
2275                                                 float r;
2276                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2277                                                 if(r < 0)
2278                                                 {
2279                                                         // give users new version
2280                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2281                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2282                                                 }
2283                                                 else if(r > 0)
2284                                                 {
2285                                                         // notify users about old server version
2286                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2287                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2288                                                 }
2289                                         }
2290                                 }
2291                                 self.version_nagtime = 0;
2292                         }
2293
2294         // GOD MODE info
2295         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2296         {
2297                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2298                 self.max_armorvalue = 0;
2299         }
2300
2301 #ifdef TETRIS
2302         if (TetrisPreFrame())
2303                 return;
2304 #endif
2305
2306         if(self.frozen == 2)
2307         {
2308                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2309                 self.health = max(1, self.revive_progress * start_health);
2310                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2311
2312                 if(self.revive_progress >= 1)
2313                         Unfreeze(self);
2314         }
2315         else if(self.frozen == 3)
2316         {
2317                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2318                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2319
2320                 if(self.health < 1)
2321                 {
2322                         if(self.vehicle)
2323                                 vehicles_exit(VHEF_RELESE);
2324                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2325                 }
2326                 else if ( self.revive_progress <= 0 )
2327                         Unfreeze(self);
2328         }
2329
2330         MUTATOR_CALLHOOK(PlayerPreThink);
2331
2332         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2333         {
2334                 if(self.BUTTON_USE && !self.usekeypressed)
2335                         PlayerUseKey();
2336                 self.usekeypressed = self.BUTTON_USE;
2337         }
2338
2339         if(IS_REAL_CLIENT(self))
2340                 PrintWelcomeMessage();
2341
2342         if(IS_PLAYER(self))
2343         {
2344
2345                 CheckRules_Player();
2346
2347                 if (intermission_running)
2348                 {
2349                         IntermissionThink ();   // otherwise a button could be missed between
2350                         return;                                 // the think tics
2351                 }
2352
2353                 //don't allow the player to turn around while game is paused!
2354                 if(timeout_status == TIMEOUT_ACTIVE) {
2355                         // FIXME turn this into CSQC stuff
2356                         self.v_angle = self.lastV_angle;
2357                         self.angles = self.lastV_angle;
2358                         self.fixangle = true;
2359                 }
2360
2361                 if(frametime)
2362                 {
2363                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2364                         {
2365                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2366                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2367                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2368
2369                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2370                                 {
2371                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2372                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2373                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2374                                 }
2375                         }
2376                         else
2377                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2378
2379                         player_powerups();
2380                 }
2381
2382                 if (self.deadflag != DEAD_NO)
2383                 {
2384                         if(self.personal && g_race_qualifying)
2385                         {
2386                                 if(time > self.respawn_time)
2387                                 {
2388                                         self.respawn_time = time + 1; // only retry once a second
2389                                         self.stat_respawn_time = self.respawn_time;
2390                                         respawn();
2391                                         self.impulse = 141;
2392                                 }
2393                         }
2394                         else
2395                         {
2396                                 float button_pressed;
2397                                 if(frametime)
2398                                         player_anim();
2399                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2400
2401                                 if (self.deadflag == DEAD_DYING)
2402                                 {
2403                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2404                                                 self.deadflag = DEAD_RESPAWNING;
2405                                         else if(!button_pressed)
2406                                                 self.deadflag = DEAD_DEAD;
2407                                 }
2408                                 else if (self.deadflag == DEAD_DEAD)
2409                                 {
2410                                         if(button_pressed)
2411                                                 self.deadflag = DEAD_RESPAWNABLE;
2412                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2413                                                 self.deadflag = DEAD_RESPAWNING;
2414                                 }
2415                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2416                                 {
2417                                         if(!button_pressed)
2418                                                 self.deadflag = DEAD_RESPAWNING;
2419                                 }
2420                                 else if (self.deadflag == DEAD_RESPAWNING)
2421                                 {
2422                                         if(time > self.respawn_time)
2423                                         {
2424                                                 self.respawn_time = time + 1; // only retry once a second
2425                                                 self.respawn_time_max = self.respawn_time;
2426                                                 respawn();
2427                                         }
2428                                 }
2429
2430                                 ShowRespawnCountdown();
2431
2432                                 if(self.respawn_flags & RESPAWN_SILENT)
2433                                         self.stat_respawn_time = 0;
2434                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2435                                         self.stat_respawn_time = self.respawn_time_max;
2436                                 else
2437                                         self.stat_respawn_time = self.respawn_time;
2438                         }
2439
2440                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2441                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2442                                 self.stat_respawn_time *= -1;
2443
2444                         return;
2445                 }
2446
2447                 self.prevorigin = self.origin;
2448
2449                 float do_crouch = self.BUTTON_CROUCH;
2450                 if(self.hook.state)
2451                         do_crouch = 0;
2452                 if(self.vehicle)
2453                         do_crouch = 0;
2454                 if(self.frozen)
2455                         do_crouch = 0;
2456
2457                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2458                 // It cannot be predicted by the engine!
2459                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2460                         do_crouch = 0;
2461
2462                 if (do_crouch)
2463                 {
2464                         if (!self.crouch)
2465                         {
2466                                 self.crouch = true;
2467                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2468                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2469                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2470                         }
2471                 }
2472                 else
2473                 {
2474                         if (self.crouch)
2475                         {
2476                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2477                                 if (!trace_startsolid)
2478                                 {
2479                                         self.crouch = false;
2480                                         self.view_ofs = self.stat_pl_view_ofs;
2481                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2482                                 }
2483                         }
2484                 }
2485
2486                 FixPlayermodel();
2487
2488                 GrapplingHookFrame();
2489
2490                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2491                 //if(frametime)
2492                 {
2493                         self.items &= ~self.items_added;
2494
2495                         W_WeaponFrame();
2496
2497                         self.items_added = 0;
2498                         if(self.items & IT_JETPACK)
2499                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2500                                         self.items_added |= IT_FUEL;
2501
2502                         self.items |= self.items_added;
2503                 }
2504
2505                 player_regen();
2506
2507                 // WEAPONTODO: Add a weapon request for this
2508                 // rot vortex charge to the charge limit
2509                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2510                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2511
2512                 if(frametime)
2513                         player_anim();
2514
2515                 // secret status
2516                 secrets_setstatus();
2517
2518                 // monsters status
2519                 monsters_setstatus();
2520
2521                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2522
2523                 //self.angles_y=self.v_angle_y + 90;   // temp
2524         } else if(gameover) {
2525                 if (intermission_running)
2526                         IntermissionThink ();   // otherwise a button could be missed between
2527                 return;
2528         } else if(IS_OBSERVER(self)) {
2529                 ObserverThink();
2530         } else if(IS_SPEC(self)) {
2531                 SpectatorThink();
2532         }
2533
2534         // WEAPONTODO: Add weapon request for this
2535         if(!zoomstate_set)
2536                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2537
2538         float oldspectatee_status;
2539         oldspectatee_status = self.spectatee_status;
2540         if(IS_SPEC(self))
2541                 self.spectatee_status = num_for_edict(self.enemy);
2542         else if(IS_OBSERVER(self))
2543                 self.spectatee_status = num_for_edict(self);
2544         else
2545                 self.spectatee_status = 0;
2546         if(self.spectatee_status != oldspectatee_status)
2547         {
2548                 ClientData_Touch(self);
2549         }
2550
2551         if(self.teamkill_soundtime)
2552         if(time > self.teamkill_soundtime)
2553         {
2554                 self.teamkill_soundtime = 0;
2555
2556                 entity oldpusher, oldself;
2557
2558                 oldself = self; self = self.teamkill_soundsource;
2559                 oldpusher = self.pusher; self.pusher = oldself;
2560
2561                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2562
2563                 self.pusher = oldpusher;
2564                 self = oldself;
2565         }
2566
2567         if(self.taunt_soundtime)
2568         if(time > self.taunt_soundtime)
2569         {
2570                 self.taunt_soundtime = 0;
2571                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2572         }
2573
2574         target_voicescript_next(self);
2575
2576         // WEAPONTODO: Move into weaponsystem somehow
2577         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2578         if(!self.weapon)
2579                 self.clip_load = self.clip_size = 0;
2580 }
2581
2582 /*
2583 =============
2584 PlayerPostThink
2585
2586 Called every frame for each client after the physics are run
2587 =============
2588 */
2589 .float idlekick_lasttimeleft;
2590 void PlayerPostThink (void)
2591 {
2592         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2593         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2594         {
2595                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2596                 {
2597                         if(self.idlekick_lasttimeleft)
2598                         {
2599                                 self.idlekick_lasttimeleft = 0;
2600                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2601                         }
2602                 }
2603                 else
2604                 {
2605                         float timeleft;
2606                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2607                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2608                         {
2609                                 if(!self.idlekick_lasttimeleft)
2610                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2611                         }
2612                         if(timeleft <= 0)
2613                         {
2614                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2615                                 dropclient(self);
2616                                 return;
2617                         }
2618                         else if(timeleft <= 10)
2619                         {
2620                                 if(timeleft != self.idlekick_lasttimeleft)
2621                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2622                                 self.idlekick_lasttimeleft = timeleft;
2623                         }
2624                 }
2625         }
2626
2627 #ifdef TETRIS
2628         if(self.impulse == 100)
2629                 ImpulseCommands();
2630         if (!TetrisPostFrame())
2631         {
2632 #endif
2633
2634         CheatFrame();
2635
2636         //CheckPlayerJump();
2637
2638         if(IS_PLAYER(self)) {
2639                 CheckRules_Player();
2640                 UpdateChatBubble();
2641                 if (self.impulse)
2642                         ImpulseCommands();
2643                 if (intermission_running)
2644                         return;         // intermission or finale
2645                 GetPressedKeys();
2646         }
2647
2648 #ifdef TETRIS
2649         }
2650 #endif
2651
2652         /*
2653         float i;
2654         for(i = 0; i < 1000; ++i)
2655         {
2656                 vector end;
2657                 end = self.origin + '0 0 1024' + 512 * randomvec();
2658                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2659                 if(trace_fraction < 1)
2660                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2661                 {
2662                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2663                         break;
2664                 }
2665         }
2666         */
2667
2668         if(self.waypointsprite_attachedforcarrier)
2669                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2670
2671         playerdemo_write();
2672
2673         CSQCMODEL_AUTOUPDATE();
2674 }