qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76 void SetSpectator(entity player, entity spectatee);
  77
  78
  79 /*
  80 =============
  81 CheckPlayerModel
  82
  83 Checks if the argument string can be a valid playermodel.
  84 Returns a valid one in doubt.
  85 =============
  86 */
  87 string FallbackPlayerModel;
  88 string CheckPlayerModel(string plyermodel) {
  89         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  90         {
  91                 // note: we cannot summon Don Strunzone here, some player may
  92                 // still have the model string set. In case anyone manages how
  93                 // to change a cvar default, we'll have a small leak here.
  94                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  95         }
  96         // only in right path
  97         if( substring(plyermodel,0,14) != "models/player/")
  98                 return FallbackPlayerModel;
  99         // only good file extensions
 100         if(substring(plyermodel,-4,4) != ".zym")
 101         if(substring(plyermodel,-4,4) != ".dpm")
 102         if(substring(plyermodel,-4,4) != ".iqm")
 103         if(substring(plyermodel,-4,4) != ".md3")
 104         if(substring(plyermodel,-4,4) != ".psk")
 105                 return FallbackPlayerModel;
 106         // forbid the LOD models
 107         if(substring(plyermodel, -9,5) == "_lod1")
 108                 return FallbackPlayerModel;
 109         if(substring(plyermodel, -9,5) == "_lod2")
 110                 return FallbackPlayerModel;
 111         if(plyermodel != strtolower(plyermodel))
 112                 return FallbackPlayerModel;
 113         // also, restrict to server models
 114         if(autocvar_sv_servermodelsonly)
 115         {
 116                 if(!fexists(plyermodel))
 117                         return FallbackPlayerModel;
 118         }
 119         return plyermodel;
 120 }
 121
 122 void setplayermodel(entity e, string modelname)
 123 {
 124         precache_model(modelname);
 125         setmodel(e, modelname);
 126         player_setupanimsformodel();
 127         UpdatePlayerSounds();
 128 }
 129
 130 /*
 131 =============
 132 PutObserverInServer
 133
 134 putting a client as observer in the server
 135 =============
 136 */
 137 void FixPlayermodel();
 138 void PutObserverInServer (void)
 139 {
 140         entity  spot;
 141     self.hud = HUD_NORMAL;
 142
 143         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         self.frags = FRAGS_SPECTATOR;
 158
 159         MUTATOR_CALLHOOK(MakePlayerObserver);
 160
 161         Portal_ClearAll(self);
 162
 163         Unfreeze(self);
 164
 165         if(self.alivetime)
 166         {
 167                 if(!warmup_stage)
 168                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 169                 self.alivetime = 0;
 170         }
 171
 172         if(self.vehicle)
 173                 vehicles_exit(VHEF_RELESE);
 174
 175         WaypointSprite_PlayerDead();
 176
 177         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 178                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 179
 180         if(self.killcount != -666)
 181         {
 182                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 183                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 184                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 185
 186                 if(self.just_joined == FALSE) {
 187                         LogTeamchange(self.playerid, -1, 4);
 188                 } else
 189                         self.just_joined = FALSE;
 190         }
 191
 192         PlayerScore_Clear(self); // clear scores when needed
 193
 194         accuracy_resend(self);
 195
 196         self.spectatortime = time;
 197
 198         self.classname = "observer";
 199         self.iscreature = FALSE;
 200         self.teleportable = TELEPORT_SIMPLE;
 201         self.damagedbycontents = FALSE;
 202         self.health = -666;
 203         self.takedamage = DAMAGE_NO;
 204         self.solid = SOLID_NOT;
 205         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 206         self.flags = FL_CLIENT | FL_NOTARGET;
 207         self.armorvalue = 666;
 208         self.effects = 0;
 209         self.armorvalue = autocvar_g_balance_armor_start;
 210         self.pauserotarmor_finished = 0;
 211         self.pauserothealth_finished = 0;
 212         self.pauseregen_finished = 0;
 213         self.damageforcescale = 0;
 214         self.death_time = 0;
 215         self.respawn_flags = 0;
 216         self.respawn_time = 0;
 217         self.stat_respawn_time = 0;
 218         self.alpha = 0;
 219         self.scale = 0;
 220         self.fade_time = 0;
 221         self.pain_frame = 0;
 222         self.pain_finished = 0;
 223         self.strength_finished = 0;
 224         self.invincible_finished = 0;
 225         self.superweapons_finished = 0;
 226         self.pushltime = 0;
 227         self.istypefrag = 0;
 228         self.think = func_null;
 229         self.nextthink = 0;
 230         self.hook_time = 0;
 231         self.deadflag = DEAD_NO;
 232         self.angles = spot.angles;
 233         self.angles_z = 0;
 234         self.fixangle = TRUE;
 235         self.crouch = FALSE;
 236         self.revival_time = 0;
 237
 238         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 239         self.prevorigin = self.origin;
 240         self.items = 0;
 241         self.weapons = '0 0 0';
 242         self.model = "";
 243         FixPlayermodel();
 244         setmodel(self, "null");
 245         self.drawonlytoclient = self;
 246
 247         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 248         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 249
 250         self.weapon = 0;
 251         self.weaponname = "";
 252         self.switchingweapon = 0;
 253         self.weaponmodel = "";
 254         self.weaponentity = world;
 255         self.exteriorweaponentity = world;
 256         self.killcount = -666;
 257         self.velocity = '0 0 0';
 258         self.avelocity = '0 0 0';
 259         self.punchangle = '0 0 0';
 260         self.punchvector = '0 0 0';
 261         self.oldvelocity = self.velocity;
 262         self.fire_endtime = -1;
 263         self.event_damage = func_null;
 264 }
 265
 266 .float model_randomizer;
 267 void FixPlayermodel()
 268 {
 269         string defaultmodel;
 270         float defaultskin, chmdl, oldskin, n, i;
 271         vector m1, m2;
 272
 273         defaultmodel = "";
 274         defaultskin = 0;
 275         chmdl = FALSE;
 276
 277         if(autocvar_sv_defaultcharacter == 1)
 278         {
 279                 if(teamplay)
 280                 {
 281                         string s;
 282                         s = Static_Team_ColorName_Lower(self.team);
 283                         if(s != "neutral")
 284                         {
 285                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 286                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 287                         }
 288                 }
 289
 290                 if(defaultmodel == "")
 291                 {
 292                         defaultmodel = autocvar_sv_defaultplayermodel;
 293                         defaultskin = autocvar_sv_defaultplayerskin;
 294                 }
 295
 296                 n = tokenize_console(defaultmodel);
 297                 if(n > 0)
 298                 {
 299                         defaultmodel = argv(floor(n * self.model_randomizer));
 300                         // However, do NOT randomize if the player-selected model is in the list.
 301                         for (i = 0; i < n; ++i)
 302                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 303                                         defaultmodel = argv(i);
 304                 }
 305
 306                 i = strstrofs(defaultmodel, ":", 0);
 307                 if(i >= 0)
 308                 {
 309                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 310                         defaultmodel = substring(defaultmodel, 0, i);
 311                 }
 312         }
 313
 314         if(defaultmodel != "")
 315         {
 316                 if (defaultmodel != self.model)
 317                 {
 318                         m1 = self.mins;
 319                         m2 = self.maxs;
 320                         setplayermodel (self, defaultmodel);
 321                         setsize (self, m1, m2);
 322                         chmdl = TRUE;
 323                 }
 324
 325                 oldskin = self.skin;
 326                 self.skin = defaultskin;
 327         } else {
 328                 if (self.playermodel != self.model || self.playermodel == "")
 329                 {
 330                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 331                         m1 = self.mins;
 332                         m2 = self.maxs;
 333                         setplayermodel (self, self.playermodel);
 334                         setsize (self, m1, m2);
 335                         chmdl = TRUE;
 336                 }
 337
 338                 oldskin = self.skin;
 339                 self.skin = stof(self.playerskin);
 340         }
 341
 342         if(chmdl || oldskin != self.skin) // model or skin has changed
 343         {
 344                 self.species = player_getspecies(); // update species
 345                 UpdatePlayerSounds(); // update skin sounds
 346         }
 347
 348         if(!teamplay)
 349                 if(strlen(autocvar_sv_defaultplayercolors))
 350                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 351                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 352 }
 353
 354 /*
 355 =============
 356 PutClientInServer
 357
 358 Called when a client spawns in the server
 359 =============
 360 */
 361 void PutClientInServer (void)
 362 {
 363         if(IS_BOT_CLIENT(self))
 364                 self.classname = "player";
 365         else if(IS_REAL_CLIENT(self))
 366         {
 367                 msg_entity = self;
 368                 WriteByte(MSG_ONE, SVC_SETVIEW);
 369                 WriteEntity(MSG_ONE, self);
 370         }
 371
 372         SetSpectator(self, world);
 373
 374         // reset player keys
 375         self.itemkeys = 0;
 376
 377         MUTATOR_CALLHOOK(PutClientInServer);
 378
 379         if(gameover)
 380                 self.classname = "observer";
 381
 382         if(IS_PLAYER(self))
 383         {
 384                 entity spot, oldself;
 385                 float j;
 386
 387                 accuracy_resend(self);
 388
 389                 if(self.team < 0)
 390                         JoinBestTeam(self, FALSE, TRUE);
 391
 392                 spot = SelectSpawnPoint (FALSE);
 393                 if(!spot)
 394                 {
 395                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 396                         return; // spawn failed
 397                 }
 398
 399                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 400
 401                 if(self.vehicle)
 402                         vehicles_exit(VHEF_RELESE);
 403
 404                 self.classname = "player";
 405                 self.wasplayer = TRUE;
 406                 self.iscreature = TRUE;
 407                 self.teleportable = TELEPORT_NORMAL;
 408                 self.damagedbycontents = TRUE;
 409                 self.movetype = MOVETYPE_WALK;
 410                 self.solid = SOLID_SLIDEBOX;
 411                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 412                 if(autocvar_g_playerclip_collisions)
 413                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 414                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 415                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 416                 self.frags = FRAGS_PLAYER;
 417                 if(INDEPENDENT_PLAYERS)
 418                         MAKE_INDEPENDENT_PLAYER(self);
 419                 self.flags = FL_CLIENT;
 420                 if(autocvar__notarget)
 421                         self.flags |= FL_NOTARGET;
 422                 self.takedamage = DAMAGE_AIM;
 423                 self.effects = 0;
 424                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 425                 self.air_finished = time + 12;
 426                 self.dmg = 2;
 427                 if(WEP_CVAR(vortex, charge))
 428                 {
 429                         if(WEP_CVAR_SEC(vortex, chargepool))
 430                                 self.vortex_chargepool_ammo = 1;
 431                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 432                 }
 433
 434                 if(warmup_stage)
 435                 {
 436                         self.ammo_shells = warmup_start_ammo_shells;
 437                         self.ammo_nails = warmup_start_ammo_nails;
 438                         self.ammo_rockets = warmup_start_ammo_rockets;
 439                         self.ammo_cells = warmup_start_ammo_cells;
 440                         self.ammo_plasma = warmup_start_ammo_plasma;
 441                         self.ammo_fuel = warmup_start_ammo_fuel;
 442                         self.health = warmup_start_health;
 443                         self.armorvalue = warmup_start_armorvalue;
 444                         self.weapons = WARMUP_START_WEAPONS;
 445                 }
 446                 else
 447                 {
 448                         self.ammo_shells = start_ammo_shells;
 449                         self.ammo_nails = start_ammo_nails;
 450                         self.ammo_rockets = start_ammo_rockets;
 451                         self.ammo_cells = start_ammo_cells;
 452                         self.ammo_plasma = start_ammo_plasma;
 453                         self.ammo_fuel = start_ammo_fuel;
 454                         self.health = start_health;
 455                         self.armorvalue = start_armorvalue;
 456                         self.weapons = start_weapons;
 457                 }
 458
 459                 if(self.weapons & WEPSET_SUPERWEAPONS)
 460                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 461                 else
 462                         self.superweapons_finished = 0;
 463
 464                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 465                 {
 466                         if(g_weaponarena_random_with_blaster)
 467                                 self.weapons &= ~WEPSET_BLASTER;
 468                         W_RandomWeapons(self, g_weaponarena_random);
 469                         if(g_weaponarena_random_with_blaster)
 470                                 self.weapons |= WEPSET_BLASTER;
 471                 }
 472
 473                 self.items = start_items;
 474
 475                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 476                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 477                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 478                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 479                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 480                 //extend the pause of rotting if client was reset at the beginning of the countdown
 481                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 482                         self.spawnshieldtime += game_starttime - time;
 483                         self.pauserotarmor_finished += game_starttime - time;
 484                         self.pauserothealth_finished += game_starttime - time;
 485                         self.pauseregen_finished += game_starttime - time;
 486                 }
 487                 self.damageforcescale = 2;
 488                 self.death_time = 0;
 489                 self.respawn_flags = 0;
 490                 self.respawn_time = 0;
 491                 self.stat_respawn_time = 0;
 492                 self.scale = 0;
 493                 self.fade_time = 0;
 494                 self.pain_frame = 0;
 495                 self.pain_finished = 0;
 496                 self.strength_finished = 0;
 497                 self.invincible_finished = 0;
 498                 self.pushltime = 0;
 499                 // players have no think function
 500                 self.think = func_null;
 501                 self.nextthink = 0;
 502                 self.hook_time = 0;
 503                 self.dmg_team = 0;
 504                 self.ballistics_density = autocvar_g_ballistics_density_player;
 505
 506                 self.metertime = 0;
 507
 508                 self.deadflag = DEAD_NO;
 509
 510                 self.angles = spot.angles;
 511
 512                 self.angles_z = 0; // never spawn tilted even if the spot says to
 513                 if(IS_BOT_CLIENT(self))
 514                         self.v_angle = self.angles;
 515                 self.fixangle = TRUE; // turn this way immediately
 516                 self.velocity = '0 0 0';
 517                 self.avelocity = '0 0 0';
 518                 self.punchangle = '0 0 0';
 519                 self.punchvector = '0 0 0';
 520                 self.oldvelocity = self.velocity;
 521                 self.fire_endtime = -1;
 522                 self.revival_time = 0;
 523
 524                 entity spawnevent = spawn();
 525                 spawnevent.owner = self;
 526                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 527
 528                 // Cut off any still running player sounds.
 529                 stopsound(self, CH_PLAYER_SINGLE);
 530
 531                 self.model = "";
 532                 FixPlayermodel();
 533                 self.drawonlytoclient = world;
 534
 535                 self.crouch = FALSE;
 536                 self.view_ofs = PL_VIEW_OFS;
 537                 setsize (self, PL_MIN, PL_MAX);
 538                 self.spawnorigin = spot.origin;
 539                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 540                 // don't reset back to last position, even if new position is stuck in solid
 541                 self.oldorigin = self.origin;
 542                 self.prevorigin = self.origin;
 543                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 544                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 545         self.hud = HUD_NORMAL;
 546
 547                 self.event_damage = PlayerDamage;
 548
 549                 self.bot_attack = TRUE;
 550                 self.monster_attack = TRUE;
 551
 552                 self.spider_slowness = 0;
 553
 554                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 555
 556                 if(self.killcount == -666) {
 557                         PlayerScore_Clear(self);
 558                         self.killcount = 0;
 559                 }
 560
 561                 CL_SpawnWeaponentity();
 562                 self.alpha = default_player_alpha;
 563                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 564                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 565
 566                 self.speedrunning = FALSE;
 567
 568                 //stuffcmd(self, "chase_active 0");
 569                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 570
 571                 target_voicescript_clear(self);
 572
 573                 // reset fields the weapons may use
 574                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 575                 {
 576                         WEP_ACTION(j, WR_RESETPLAYER);
 577
 578                         // all weapons must be fully loaded when we spawn
 579                         entity e;
 580                         e = get_weaponinfo(j);
 581                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 582                                 self.(weapon_load[j]) = e.reloading_ammo;
 583                 }
 584
 585                 oldself = self;
 586                 self = spot;
 587                         activator = oldself;
 588                                 string s;
 589                                 s = self.target;
 590                                 self.target = string_null;
 591                                 SUB_UseTargets();
 592                                 self.target = s;
 593                         activator = world;
 594                 self = oldself;
 595
 596                 Unfreeze(self);
 597
 598                 spawn_spot = spot;
 599                 MUTATOR_CALLHOOK(PlayerSpawn);
 600
 601                 if(autocvar_spawn_debug)
 602                 {
 603                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 604                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 605                 }
 606
 607                 self.switchweapon = w_getbestweapon(self);
 608                 self.cnt = -1; // W_LastWeapon will not complain
 609                 self.weapon = 0;
 610                 self.weaponname = "";
 611                 self.switchingweapon = 0;
 612
 613                 if(!warmup_stage)
 614                         if(!self.alivetime)
 615                                 self.alivetime = time;
 616
 617                 antilag_clear(self);
 618         }
 619         else if(IS_OBSERVER(self))
 620         {
 621                 PutObserverInServer ();
 622         }
 623 }
 624
 625 .float ebouncefactor, ebouncestop; // electro's values
 626 // TODO do we need all these fields, or should we stop autodetecting runtime
 627 // changes and just have a console command to update this?
 628 float ClientInit_SendEntity(entity to, float sf)
 629 {
 630         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 631         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 640
 641         if(sv_foginterval && world.fog != "")
 642                 WriteString(MSG_ENTITY, world.fog);
 643         else
 644                 WriteString(MSG_ENTITY, "");
 645         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 646         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 647         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 648         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 649         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 650         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 651         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 652         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 653         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 654         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 655         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 656         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 657         return TRUE;
 658 }
 659
 660 void ClientInit_CheckUpdate()
 661 {
 662         self.nextthink = time;
 663         if(self.count != autocvar_g_balance_armor_blockpercent)
 664         {
 665                 self.count = autocvar_g_balance_armor_blockpercent;
 666                 self.SendFlags |= 1;
 667         }
 668         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 669         {
 670                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 671                 self.SendFlags |= 1;
 672         }
 673         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 674         {
 675                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 676                 self.SendFlags |= 1;
 677         }
 678         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 679         {
 680                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 681                 self.SendFlags |= 1;
 682         }
 683         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 684         {
 685                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 686                 self.SendFlags |= 1;
 687         }
 688 }
 689
 690 void ClientInit_Spawn()
 691 {
 692         entity o;
 693         entity e;
 694         e = spawn();
 695         e.classname = "clientinit";
 696         e.think = ClientInit_CheckUpdate;
 697         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 698
 699         o = self;
 700         self = e;
 701         ClientInit_CheckUpdate();
 702         self = o;
 703 }
 704
 705 /*
 706 =============
 707 SetNewParms
 708 =============
 709 */
 710 void SetNewParms (void)
 711 {
 712         // initialize parms for a new player
 713         parm1 = -(86400 * 366);
 714 }
 715
 716 /*
 717 =============
 718 SetChangeParms
 719 =============
 720 */
 721 void SetChangeParms (void)
 722 {
 723         // save parms for level change
 724         parm1 = self.parm_idlesince - time;
 725 }
 726
 727 /*
 728 =============
 729 DecodeLevelParms
 730 =============
 731 */
 732 void DecodeLevelParms (void)
 733 {
 734         // load parms
 735         self.parm_idlesince = parm1;
 736         if(self.parm_idlesince == -(86400 * 366))
 737                 self.parm_idlesince = time;
 738
 739         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 740         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 741 }
 742
 743 /*
 744 =============
 745 ClientKill
 746
 747 Called when a client types 'kill' in the console
 748 =============
 749 */
 750
 751 .float clientkill_nexttime;
 752 void ClientKill_Now_TeamChange()
 753 {
 754         if(self.killindicator_teamchange == -1)
 755         {
 756                 JoinBestTeam( self, FALSE, TRUE );
 757         }
 758         else if(self.killindicator_teamchange == -2)
 759         {
 760                 if(blockSpectators)
 761                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 762                 PutObserverInServer();
 763         }
 764         else
 765                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 766         self.killindicator_teamchange = 0;
 767 }
 768
 769 void ClientKill_Now()
 770 {
 771         if(self.vehicle)
 772         {
 773             vehicles_exit(VHEF_RELESE);
 774             if(!self.killindicator_teamchange)
 775             {
 776             self.vehicle_health = -1;
 777             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 778             }
 779         }
 780
 781         if(self.killindicator && !wasfreed(self.killindicator))
 782                 remove(self.killindicator);
 783
 784         self.killindicator = world;
 785
 786         if(self.killindicator_teamchange)
 787                 ClientKill_Now_TeamChange();
 788
 789         if(IS_PLAYER(self))
 790                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 791
 792         // now I am sure the player IS dead
 793 }
 794 void KillIndicator_Think()
 795 {
 796         if (gameover)
 797         {
 798                 self.owner.killindicator = world;
 799                 remove(self);
 800                 return;
 801         }
 802
 803         if (self.owner.alpha < 0 && !self.owner.vehicle)
 804         {
 805                 self.owner.killindicator = world;
 806                 remove(self);
 807                 return;
 808         }
 809
 810         if(self.cnt <= 0)
 811         {
 812                 self = self.owner;
 813                 ClientKill_Now(); // no oldself needed
 814                 return;
 815         }
 816     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 817     {
 818         self.nextthink = time + 1;
 819         self.cnt -= 1;
 820     }
 821         else
 822         {
 823                 if(self.cnt <= 10)
 824                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 825                 if(IS_REAL_CLIENT(self.owner))
 826                 {
 827                         if(self.cnt <= 10)
 828                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 829                 }
 830                 self.nextthink = time + 1;
 831                 self.cnt -= 1;
 832         }
 833 }
 834
 835 float clientkilltime;
 836 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 837 {
 838         float killtime;
 839         float starttime;
 840         entity e;
 841
 842         if (gameover)
 843                 return;
 844
 845         killtime = autocvar_g_balance_kill_delay;
 846
 847         if(g_race_qualifying || g_cts)
 848                 killtime = 0;
 849
 850     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 851     {
 852                 remove(self.killindicator);
 853                 self.killindicator = world;
 854
 855         ClientKill_Now(); // allow instant kill in this case
 856         return;
 857     }
 858
 859         self.killindicator_teamchange = targetteam;
 860
 861     if(!self.killindicator)
 862         {
 863                 if(self.deadflag == DEAD_NO)
 864                 {
 865                         killtime = max(killtime, self.clientkill_nexttime - time);
 866                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 867                 }
 868
 869                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 870                 {
 871                         ClientKill_Now();
 872                 }
 873                 else
 874                 {
 875                         starttime = max(time, clientkilltime);
 876
 877                         self.killindicator = spawn();
 878                         self.killindicator.owner = self;
 879                         self.killindicator.scale = 0.5;
 880                         setattachment(self.killindicator, self, "");
 881                         setorigin(self.killindicator, '0 0 52');
 882                         self.killindicator.think = KillIndicator_Think;
 883                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 884                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 885                         self.killindicator.cnt = ceil(killtime);
 886                         self.killindicator.count = bound(0, ceil(killtime), 10);
 887                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 888
 889                         for(e = world; (e = find(e, classname, "body")) != world; )
 890                         {
 891                                 if(e.enemy != self)
 892                                         continue;
 893                                 e.killindicator = spawn();
 894                                 e.killindicator.owner = e;
 895                                 e.killindicator.scale = 0.5;
 896                                 setattachment(e.killindicator, e, "");
 897                                 setorigin(e.killindicator, '0 0 52');
 898                                 e.killindicator.think = KillIndicator_Think;
 899                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 900                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 901                                 e.killindicator.cnt = ceil(killtime);
 902                         }
 903                         self.lip = 0;
 904                 }
 905         }
 906         if(self.killindicator)
 907         {
 908                 if(targetteam == 0) // just die
 909                 {
 910                         self.killindicator.colormod = '0 0 0';
 911                         if(IS_REAL_CLIENT(self))
 912                         if(self.killindicator.cnt > 0)
 913                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 914                 }
 915                 else if(targetteam == -1) // auto
 916                 {
 917                         self.killindicator.colormod = '0 1 0';
 918                         if(IS_REAL_CLIENT(self))
 919                         if(self.killindicator.cnt > 0)
 920                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 921                 }
 922                 else if(targetteam == -2) // spectate
 923                 {
 924                         self.killindicator.colormod = '0.5 0.5 0.5';
 925                         if(IS_REAL_CLIENT(self))
 926                         if(self.killindicator.cnt > 0)
 927                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 928                 }
 929                 else
 930                 {
 931                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 932                         if(IS_REAL_CLIENT(self))
 933                         if(self.killindicator.cnt > 0)
 934                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 935                 }
 936         }
 937
 938 }
 939
 940 void ClientKill (void)
 941 {
 942         if(gameover) return;
 943         if(self.player_blocked) return;
 944         if(self.frozen) return;
 945
 946         ClientKill_TeamChange(0);
 947 }
 948
 949 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 950 {
 951     e.killindicator = spawn();
 952     e.killindicator.owner = e;
 953     e.killindicator.think = KillIndicator_Think;
 954     e.killindicator.nextthink = time + (e.lip) * 0.05;
 955     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 956     e.killindicator.health = 1; // this is used to indicate that it should be silent
 957     e.lip = 0;
 958 }
 959
 960 void FixClientCvars(entity e)
 961 {
 962         // send prediction settings to the client
 963         stuffcmd(e, "\nin_bindmap 0 0\n");
 964         if(g_race || g_cts)
 965                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 966         if(autocvar_g_antilag == 3) // client side hitscan
 967                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 968         if(autocvar_sv_gentle)
 969                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 970 }
 971
 972 float PlayerInIDList(entity p, string idlist)
 973 {
 974         float n, i;
 975         string s;
 976
 977         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 978         if (!p.crypto_idfp)
 979                 return 0;
 980
 981         // this function allows abbreviated player IDs too!
 982         n = tokenize_console(idlist);
 983         for(i = 0; i < n; ++i)
 984         {
 985                 s = argv(i);
 986                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 987                         return 1;
 988         }
 989
 990         return 0;
 991 }
 992
 993 /*
 994 =============
 995 ClientPreConnect
 996
 997 Called once (not at each match start) when a client begins a connection to the server
 998 =============
 999 */
1000 void ClientPreConnect (void)
1001 {
1002         if(autocvar_sv_eventlog)
1003         {
1004                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1005                         self.playerid,
1006                         num_for_edict(self),
1007                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1008                 ));
1009         }
1010 }
1011
1012 /*
1013 =============
1014 ClientConnect
1015
1016 Called when a client connects to the server
1017 =============
1018 */
1019 void DecodeLevelParms (void);
1020 //void dom_player_join_team(entity pl);
1021 void set_dom_state(entity e);
1022 void ClientConnect (void)
1023 {
1024         float t;
1025
1026         if(IS_CLIENT(self))
1027         {
1028                 print("Warning: ClientConnect, but already connected!\n");
1029                 return;
1030         }
1031
1032         if(Ban_MaybeEnforceBanOnce(self))
1033                 return;
1034
1035         DecodeLevelParms();
1036
1037 #ifdef WATERMARK
1038         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1039 #endif
1040
1041         self.classname = "player_joining";
1042
1043         self.flags = FL_CLIENT;
1044         self.version_nagtime = time + 10 + random() * 10;
1045
1046         if(player_count<0)
1047         {
1048                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1049                 player_count = 0;
1050         }
1051
1052         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1053
1054         PlayerScore_Attach(self);
1055         ClientData_Attach();
1056         accuracy_init(self);
1057
1058         bot_clientconnect();
1059
1060         playerdemo_init();
1061
1062         anticheat_init();
1063
1064         // identify the right forced team
1065         if(autocvar_g_campaign)
1066         {
1067                 if(IS_REAL_CLIENT(self)) // only players, not bots
1068                 {
1069                         switch(autocvar_g_campaign_forceteam)
1070                         {
1071                                 case 1: self.team_forced = NUM_TEAM_1; break;
1072                                 case 2: self.team_forced = NUM_TEAM_2; break;
1073                                 case 3: self.team_forced = NUM_TEAM_3; break;
1074                                 case 4: self.team_forced = NUM_TEAM_4; break;
1075                                 default: self.team_forced = 0;
1076                         }
1077                 }
1078         }
1079         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1080                 self.team_forced = NUM_TEAM_1;
1081         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1082                 self.team_forced = NUM_TEAM_2;
1083         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1084                 self.team_forced = NUM_TEAM_3;
1085         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1086                 self.team_forced = NUM_TEAM_4;
1087         else if(autocvar_g_forced_team_otherwise == "red")
1088                 self.team_forced = NUM_TEAM_1;
1089         else if(autocvar_g_forced_team_otherwise == "blue")
1090                 self.team_forced = NUM_TEAM_2;
1091         else if(autocvar_g_forced_team_otherwise == "yellow")
1092                 self.team_forced = NUM_TEAM_3;
1093         else if(autocvar_g_forced_team_otherwise == "pink")
1094                 self.team_forced = NUM_TEAM_4;
1095         else if(autocvar_g_forced_team_otherwise == "spectate")
1096                 self.team_forced = -1;
1097         else if(autocvar_g_forced_team_otherwise == "spectator")
1098                 self.team_forced = -1;
1099         else
1100                 self.team_forced = 0;
1101
1102         if(!teamplay)
1103                 if(self.team_forced > 0)
1104                         self.team_forced = 0;
1105
1106         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1107
1108         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1109                 self.classname = "observer";
1110         } else {
1111                 if(teamplay)
1112                 {
1113                         if(autocvar_g_balance_teams)
1114                         {
1115                                 self.classname = "player";
1116                                 campaign_bots_may_start = 1;
1117                         }
1118                         else
1119                         {
1120                                 self.classname = "observer"; // do it anyway
1121                         }
1122                 }
1123                 else
1124                 {
1125                         self.classname = "player";
1126                         campaign_bots_may_start = 1;
1127                 }
1128         }
1129
1130         self.playerid = (playerid_last = playerid_last + 1);
1131
1132         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1133
1134     if(IS_BOT_CLIENT(self))
1135         PlayerStats_GameReport_AddPlayer(self);
1136
1137         if(autocvar_sv_eventlog)
1138                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1139
1140         LogTeamchange(self.playerid, self.team, 1);
1141
1142         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1143
1144         self.netname_previous = strzone(self.netname);
1145
1146         if(IS_PLAYER(self) && teamplay)
1147                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1148         else
1149                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1150
1151         stuffcmd(self, strcat(clientstuff, "\n"));
1152         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1153
1154         FixClientCvars(self);
1155
1156         // spawnfunc_waypoint sprites
1157         WaypointSprite_InitClient(self);
1158
1159         // Wazat's grappling hook
1160         SetGrappleHookBindings();
1161
1162         // Jetpack binds
1163         stuffcmd(self, "alias +jetpack +button10\n");
1164         stuffcmd(self, "alias -jetpack -button10\n");
1165
1166         // get version info from player
1167         stuffcmd(self, "cmd clientversion $gameversion\n");
1168
1169         // get other cvars from player
1170         GetCvars(0);
1171
1172         // notify about available teams
1173         if(teamplay)
1174         {
1175                 CheckAllowedTeams(self);
1176                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1177                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1178         }
1179         else
1180                 stuffcmd(self, "set _teams_available 0\n");
1181
1182         attach_entcs();
1183
1184         bot_relinkplayerlist();
1185
1186         self.spectatortime = time;
1187         if(blockSpectators)
1188         {
1189                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1190         }
1191
1192         self.jointime = time;
1193         self.allowed_timeouts = autocvar_sv_timeout_number;
1194
1195         if(IS_REAL_CLIENT(self))
1196         {
1197                 if(!autocvar_g_campaign)
1198                 {
1199                         self.motd_actived_time = -1;
1200                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1201                 }
1202
1203                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1204                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1205         }
1206
1207         if(!sv_foginterval && world.fog != "")
1208                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1209
1210         W_HitPlotOpen(self);
1211
1212         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1213                 send_CSQC_teamnagger();
1214
1215         CheatInitClient();
1216
1217         CSQCMODEL_AUTOINIT();
1218
1219         self.model_randomizer = random();
1220
1221         if(IS_REAL_CLIENT(self))
1222                 sv_notice_join();
1223
1224         MUTATOR_CALLHOOK(ClientConnect);
1225 }
1226 /*
1227 =============
1228 ClientDisconnect
1229
1230 Called when a client disconnects from the server
1231 =============
1232 */
1233 .entity chatbubbleentity;
1234 void ReadyCount();
1235 void ClientDisconnect (void)
1236 {
1237         if(self.vehicle)
1238             vehicles_exit(VHEF_RELESE);
1239
1240         if (!IS_CLIENT(self))
1241         {
1242                 print("Warning: ClientDisconnect without ClientConnect\n");
1243                 return;
1244         }
1245
1246         PlayerStats_GameReport_FinalizePlayer(self);
1247
1248         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1249
1250         CheatShutdownClient();
1251
1252         W_HitPlotClose(self);
1253
1254         anticheat_report();
1255         anticheat_shutdown();
1256
1257         playerdemo_shutdown();
1258
1259         bot_clientdisconnect();
1260
1261         if(self.entcs)
1262                 detach_entcs();
1263
1264         if(autocvar_sv_eventlog)
1265                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1266
1267         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1268
1269         MUTATOR_CALLHOOK(ClientDisconnect);
1270
1271         Portal_ClearAll(self);
1272
1273         Unfreeze(self);
1274
1275         RemoveGrapplingHook(self);
1276
1277         // Here, everything has been done that requires this player to be a client.
1278
1279         self.flags &= ~FL_CLIENT;
1280
1281         if (self.chatbubbleentity)
1282                 remove (self.chatbubbleentity);
1283
1284         if (self.killindicator)
1285                 remove (self.killindicator);
1286
1287         WaypointSprite_PlayerGone();
1288
1289         bot_relinkplayerlist();
1290
1291         accuracy_free(self);
1292         ClientData_Detach();
1293         PlayerScore_Detach(self);
1294
1295         if(self.netname_previous)
1296                 strunzone(self.netname_previous);
1297         if(self.clientstatus)
1298                 strunzone(self.clientstatus);
1299         if(self.weaponorder_byimpulse)
1300                 strunzone(self.weaponorder_byimpulse);
1301
1302         ClearPlayerSounds();
1303
1304         if(self.personal)
1305                 remove(self.personal);
1306
1307         self.playerid = 0;
1308         ReadyCount();
1309
1310         // free cvars
1311         GetCvars(-1);
1312 }
1313
1314 .float BUTTON_CHAT;
1315 void ChatBubbleThink()
1316 {
1317         self.nextthink = time;
1318         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1319         {
1320                 if(self.owner) // but why can that ever be world?
1321                         self.owner.chatbubbleentity = world;
1322                 remove(self);
1323                 return;
1324         }
1325         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1326 #ifdef TETRIS
1327                 || self.owner.tetris_on
1328 #endif
1329         )
1330                 self.model = self.mdl;
1331         else
1332                 self.model = "";
1333 }
1334
1335 void UpdateChatBubble()
1336 {
1337         if (self.alpha < 0)
1338                 return;
1339         // spawn a chatbubble entity if needed
1340         if (!self.chatbubbleentity)
1341         {
1342                 self.chatbubbleentity = spawn();
1343                 self.chatbubbleentity.owner = self;
1344                 self.chatbubbleentity.exteriormodeltoclient = self;
1345                 self.chatbubbleentity.think = ChatBubbleThink;
1346                 self.chatbubbleentity.nextthink = time;
1347                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1348                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1349                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1350                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1351                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1352                 self.chatbubbleentity.model = "";
1353                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1354         }
1355 }
1356
1357
1358 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1359 // added to the model skins
1360 /*void UpdateColorModHack()
1361 {
1362         float c;
1363         c = self.clientcolors & 15;
1364         // LordHavoc: only bothering to support white, green, red, yellow, blue
1365              if (!teamplay) self.colormod = '0 0 0';
1366         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1367         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1368         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1369         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1370         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1371         else self.colormod = '1 1 1';
1372 }*/
1373
1374 void respawn(void)
1375 {
1376         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1377         {
1378                 self.solid = SOLID_NOT;
1379                 self.takedamage = DAMAGE_NO;
1380                 self.movetype = MOVETYPE_FLY;
1381                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1382                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1383                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1384                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1385                 if(autocvar_g_respawn_ghosts_maxtime)
1386                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1387         }
1388
1389         CopyBody(1);
1390
1391         self.effects |= EF_NODRAW; // prevent another CopyBody
1392         PutClientInServer();
1393 }
1394
1395 void play_countdown(float finished, string samp)
1396 {
1397         if(IS_REAL_CLIENT(self))
1398                 if(floor(finished - time - frametime) != floor(finished - time))
1399                         if(finished - time < 6)
1400                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1401 }
1402
1403 void player_powerups (void)
1404 {
1405         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1406         olditems = self.items;
1407
1408         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1409                 self.modelflags |= MF_ROCKET;
1410         else
1411                 self.modelflags &= ~MF_ROCKET;
1412
1413         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1414
1415         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1416                 return;
1417
1418         Fire_ApplyDamage(self);
1419         Fire_ApplyEffect(self);
1420
1421         if (!g_instagib)
1422         {
1423                 if (self.items & IT_STRENGTH)
1424                 {
1425                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1426                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1427                         if (time > self.strength_finished)
1428                         {
1429                                 self.items = self.items - (self.items & IT_STRENGTH);
1430                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1431                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1432                         }
1433                 }
1434                 else
1435                 {
1436                         if (time < self.strength_finished)
1437                         {
1438                                 self.items = self.items | IT_STRENGTH;
1439                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1440                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1441                         }
1442                 }
1443                 if (self.items & IT_INVINCIBLE)
1444                 {
1445                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1446                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1447                         if (time > self.invincible_finished)
1448                         {
1449                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1450                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1451                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1452                         }
1453                 }
1454                 else
1455                 {
1456                         if (time < self.invincible_finished)
1457                         {
1458                                 self.items = self.items | IT_INVINCIBLE;
1459                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1460                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1461                         }
1462                 }
1463                 if (self.items & IT_SUPERWEAPON)
1464                 {
1465                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1466                         {
1467                                 self.superweapons_finished = 0;
1468                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1469                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1470                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1471                         }
1472                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1473                         {
1474                                 // don't let them run out
1475                         }
1476                         else
1477                         {
1478                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1479                                 if (time > self.superweapons_finished)
1480                                 {
1481                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1482                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1483                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1484                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1485                                 }
1486                         }
1487                 }
1488                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1489                 {
1490                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1491                         {
1492                                 self.items = self.items | IT_SUPERWEAPON;
1493                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1494                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1495                         }
1496                         else
1497                         {
1498                                 self.superweapons_finished = 0;
1499                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1500                         }
1501                 }
1502                 else
1503                 {
1504                         self.superweapons_finished = 0;
1505                 }
1506         }
1507
1508         if(autocvar_g_nodepthtestplayers)
1509                 self.effects = self.effects | EF_NODEPTHTEST;
1510
1511         if(autocvar_g_fullbrightplayers)
1512                 self.effects = self.effects | EF_FULLBRIGHT;
1513
1514         if (time >= game_starttime)
1515         if (time < self.spawnshieldtime)
1516                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1517
1518         MUTATOR_CALLHOOK(PlayerPowerups);
1519 }
1520
1521 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1522 {
1523         if(current > stable)
1524                 return current;
1525         else if(current > stable - 0.25) // when close enough, "snap"
1526                 return stable;
1527         else
1528                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1529 }
1530
1531 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1532 {
1533         if(current < stable)
1534                 return current;
1535         else if(current < stable + 0.25) // when close enough, "snap"
1536                 return stable;
1537         else
1538                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1539 }
1540
1541 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1542 {
1543         if(current > rotstable)
1544         {
1545                 if(rotframetime > 0)
1546                 {
1547                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1548                         current = max(rotstable, current - rotlinear * rotframetime);
1549                 }
1550         }
1551         else if(current < regenstable)
1552         {
1553                 if(regenframetime > 0)
1554                 {
1555                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1556                         current = min(regenstable, current + regenlinear * regenframetime);
1557                 }
1558         }
1559
1560         if(current > limit)
1561                 current = limit;
1562
1563         return current;
1564 }
1565
1566 void player_regen (void)
1567 {
1568         float max_mod, regen_mod, rot_mod, limit_mod;
1569         max_mod = regen_mod = rot_mod = limit_mod = 1;
1570         regen_mod_max = max_mod;
1571         regen_mod_regen = regen_mod;
1572         regen_mod_rot = rot_mod;
1573         regen_mod_limit = limit_mod;
1574         if(!MUTATOR_CALLHOOK(PlayerRegen))
1575         if(!self.frozen)
1576         {
1577                 float minh, mina, maxh, maxa, limith, limita;
1578                 maxh = autocvar_g_balance_health_rotstable;
1579                 maxa = autocvar_g_balance_armor_rotstable;
1580                 minh = autocvar_g_balance_health_regenstable;
1581                 mina = autocvar_g_balance_armor_regenstable;
1582                 limith = autocvar_g_balance_health_limit;
1583                 limita = autocvar_g_balance_armor_limit;
1584
1585                 max_mod = regen_mod_max;
1586                 regen_mod = regen_mod_regen;
1587                 rot_mod = regen_mod_rot;
1588                 limit_mod = regen_mod_limit;
1589
1590                 maxh = maxh * max_mod;
1591                 minh = minh * max_mod;
1592                 limith = limith * limit_mod;
1593                 limita = limita * limit_mod;
1594
1595                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1596                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1597         }
1598
1599         // if player rotted to death...  die!
1600         // check this outside above checks, as player may still be able to rot to death
1601         if(self.health < 1)
1602                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1603
1604         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1605         {
1606                 float minf, maxf, limitf;
1607
1608                 maxf = autocvar_g_balance_fuel_rotstable;
1609                 minf = autocvar_g_balance_fuel_regenstable;
1610                 limitf = autocvar_g_balance_fuel_limit;
1611
1612                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1613         }
1614 }
1615
1616 float zoomstate_set;
1617 void SetZoomState(float z)
1618 {
1619         if(z != self.zoomstate)
1620         {
1621                 self.zoomstate = z;
1622                 ClientData_Touch(self);
1623         }
1624         zoomstate_set = 1;
1625 }
1626
1627 void GetPressedKeys(void) {
1628         MUTATOR_CALLHOOK(GetPressedKeys);
1629         if (self.movement_x > 0) // get if movement keys are pressed
1630         {       // forward key pressed
1631                 self.pressedkeys |= KEY_FORWARD;
1632                 self.pressedkeys &= ~KEY_BACKWARD;
1633         }
1634         else if (self.movement_x < 0)
1635         {       // backward key pressed
1636                 self.pressedkeys |= KEY_BACKWARD;
1637                 self.pressedkeys &= ~KEY_FORWARD;
1638         }
1639         else
1640         {       // no x input
1641                 self.pressedkeys &= ~KEY_FORWARD;
1642                 self.pressedkeys &= ~KEY_BACKWARD;
1643         }
1644
1645         if (self.movement_y > 0)
1646         {       // right key pressed
1647                 self.pressedkeys |= KEY_RIGHT;
1648                 self.pressedkeys &= ~KEY_LEFT;
1649         }
1650         else if (self.movement_y < 0)
1651         {       // left key pressed
1652                 self.pressedkeys |= KEY_LEFT;
1653                 self.pressedkeys &= ~KEY_RIGHT;
1654         }
1655         else
1656         {       // no y input
1657                 self.pressedkeys &= ~KEY_RIGHT;
1658                 self.pressedkeys &= ~KEY_LEFT;
1659         }
1660
1661         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1662                 self.pressedkeys |= KEY_JUMP;
1663         else
1664                 self.pressedkeys &= ~KEY_JUMP;
1665         if (self.BUTTON_CROUCH)
1666                 self.pressedkeys |= KEY_CROUCH;
1667         else
1668                 self.pressedkeys &= ~KEY_CROUCH;
1669
1670         if (self.BUTTON_ATCK)
1671                 self.pressedkeys |= KEY_ATCK;
1672         else
1673                 self.pressedkeys &= ~KEY_ATCK;
1674         if (self.BUTTON_ATCK2)
1675                 self.pressedkeys |= KEY_ATCK2;
1676         else
1677                 self.pressedkeys &= ~KEY_ATCK2;
1678 }
1679
1680 /*
1681 ======================
1682 spectate mode routines
1683 ======================
1684 */
1685
1686 void SpectateCopy(entity spectatee) {
1687         other = spectatee;
1688         MUTATOR_CALLHOOK(SpectateCopy);
1689         self.armortype = spectatee.armortype;
1690         self.armorvalue = spectatee.armorvalue;
1691         self.ammo_cells = spectatee.ammo_cells;
1692         self.ammo_plasma = spectatee.ammo_plasma;
1693         self.ammo_shells = spectatee.ammo_shells;
1694         self.ammo_nails = spectatee.ammo_nails;
1695         self.ammo_rockets = spectatee.ammo_rockets;
1696         self.ammo_fuel = spectatee.ammo_fuel;
1697         self.clip_load = spectatee.clip_load;
1698         self.clip_size = spectatee.clip_size;
1699         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1700         self.health = spectatee.health;
1701         self.impulse = 0;
1702         self.items = spectatee.items;
1703         self.last_pickup = spectatee.last_pickup;
1704         self.hit_time = spectatee.hit_time;
1705         self.metertime = spectatee.metertime;
1706         self.strength_finished = spectatee.strength_finished;
1707         self.invincible_finished = spectatee.invincible_finished;
1708         self.pressedkeys = spectatee.pressedkeys;
1709         self.weapons = spectatee.weapons;
1710         self.switchweapon = spectatee.switchweapon;
1711         self.switchingweapon = spectatee.switchingweapon;
1712         self.weapon = spectatee.weapon;
1713         self.vortex_charge = spectatee.vortex_charge;
1714         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1715         self.hagar_load = spectatee.hagar_load;
1716         self.arc_heat_percent = spectatee.arc_heat_percent;
1717         self.minelayer_mines = spectatee.minelayer_mines;
1718         self.punchangle = spectatee.punchangle;
1719         self.view_ofs = spectatee.view_ofs;
1720         self.velocity = spectatee.velocity;
1721         self.dmg_take = spectatee.dmg_take;
1722         self.dmg_save = spectatee.dmg_save;
1723         self.dmg_inflictor = spectatee.dmg_inflictor;
1724         self.v_angle = spectatee.v_angle;
1725         self.angles = spectatee.v_angle;
1726         self.frozen = spectatee.frozen;
1727         self.revive_progress = spectatee.revive_progress;
1728         if(!self.BUTTON_USE)
1729                 self.fixangle = TRUE;
1730         setorigin(self, spectatee.origin);
1731         setsize(self, spectatee.mins, spectatee.maxs);
1732         SetZoomState(spectatee.zoomstate);
1733
1734     anticheat_spectatecopy(spectatee);
1735         self.hud = spectatee.hud;
1736         if(spectatee.vehicle)
1737     {
1738         self.fixangle = FALSE;
1739         //self.velocity = spectatee.vehicle.velocity;
1740         self.vehicle_health = spectatee.vehicle_health;
1741         self.vehicle_shield = spectatee.vehicle_shield;
1742         self.vehicle_energy = spectatee.vehicle_energy;
1743         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1744         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1745         self.vehicle_reload1 = spectatee.vehicle_reload1;
1746         self.vehicle_reload2 = spectatee.vehicle_reload2;
1747
1748         msg_entity = self;
1749
1750         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1751             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1752             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1753             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1754
1755         //WriteByte (MSG_ONE, SVC_SETVIEW);
1756         //    WriteEntity(MSG_ONE, self);
1757         //makevectors(spectatee.v_angle);
1758         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1759     }
1760 }
1761
1762 float SpectateUpdate()
1763 {
1764         if(!self.enemy)
1765             return 0;
1766
1767         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1768         {
1769                 SetSpectator(self, world);
1770                 return 0;
1771         }
1772
1773         SpectateCopy(self.enemy);
1774
1775         return 1;
1776 }
1777
1778 float SpectateSet()
1779 {
1780         if(self.enemy.classname != "player")
1781                 return FALSE;
1782         /*if(self.enemy.vehicle)
1783         {
1784
1785                 msg_entity = self;
1786                 WriteByte(MSG_ONE, SVC_SETVIEW);
1787                 WriteEntity(MSG_ONE, self.enemy);
1788                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1789
1790                 self.movetype = MOVETYPE_NONE;
1791                 accuracy_resend(self);
1792         }
1793         else
1794         {*/
1795                 msg_entity = self;
1796                 WriteByte(MSG_ONE, SVC_SETVIEW);
1797                 WriteEntity(MSG_ONE, self.enemy);
1798                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1799                 self.movetype = MOVETYPE_NONE;
1800                 accuracy_resend(self);
1801
1802                 if(!SpectateUpdate())
1803                         PutObserverInServer();
1804         //}
1805         return TRUE;
1806 }
1807
1808 void SetSpectator(entity player, entity spectatee)
1809 {
1810         entity old_spectatee = player.enemy;
1811
1812         player.enemy = spectatee;
1813
1814         // WEAPONTODO
1815         // these are required to fix the spectator bug with arc
1816         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1817         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1818 }
1819
1820 float Spectate(entity pl)
1821 {
1822         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1823         if(pl.team != self.team)
1824                 return 0;
1825
1826         SetSpectator(self, pl);
1827         return SpectateSet();
1828 }
1829
1830 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1831 entity CA_SpectateNext(entity start) {
1832         if (start.team == self.team) {
1833                 return start;
1834         }
1835
1836         other = start;
1837         // continue from current player
1838         while(other && other.team != self.team) {
1839                 other = find(other, classname, "player");
1840         }
1841
1842         if (!other) {
1843                 // restart from begining
1844                 other = find(other, classname, "player");
1845                 while(other && other.team != self.team) {
1846                         other = find(other, classname, "player");
1847                 }
1848         }
1849
1850         return other;
1851 }
1852
1853 float SpectateNext()
1854 {
1855         other = find(self.enemy, classname, "player");
1856
1857         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1858                 // CA and ca players when spectating enemies is forbidden
1859                 other = CA_SpectateNext(other);
1860         } else {
1861                 // other modes and ca spectators or spectating enemies is allowed
1862                 if (!other)
1863                         other = find(other, classname, "player");
1864         }
1865
1866         if(other) { SetSpectator(self, other); }
1867
1868         return SpectateSet();
1869 }
1870
1871 float SpectatePrev()
1872 {
1873         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1874         other = findchain(classname, "player");
1875         if (!other) // no player
1876                 return FALSE;
1877
1878         entity first = other;
1879         // skip players until current spectated player
1880         if(self.enemy)
1881         while(other && other != self.enemy)
1882                 other = other.chain;
1883
1884         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1885         {
1886                 do { other = other.chain; }
1887                 while(other && other.team != self.team);
1888
1889                 if (!other)
1890                 {
1891                         other = first;
1892                         while(other.team != self.team)
1893                                 other = other.chain;
1894                         if(other == self.enemy)
1895                                 return TRUE;
1896                 }
1897         }
1898         else
1899         {
1900                 if(other.chain)
1901                         other = other.chain;
1902                 else
1903                         other = first;
1904         }
1905         SetSpectator(self, other);
1906         return SpectateSet();
1907 }
1908
1909 /*
1910 =============
1911 ShowRespawnCountdown()
1912
1913 Update a respawn countdown display.
1914 =============
1915 */
1916 void ShowRespawnCountdown()
1917 {
1918         float number;
1919         if(self.deadflag == DEAD_NO) // just respawned?
1920                 return;
1921         else
1922         {
1923                 number = ceil(self.respawn_time - time);
1924                 if(number <= 0)
1925                         return;
1926                 if(number <= self.respawn_countdown)
1927                 {
1928                         self.respawn_countdown = number - 1;
1929                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1930                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1931                 }
1932         }
1933 }
1934
1935 void LeaveSpectatorMode()
1936 {
1937         if(self.caplayer)
1938                 return;
1939         if(nJoinAllowed(self))
1940         {
1941                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1942                 {
1943                         self.classname = "player";
1944                         nades_RemoveBonus(self);
1945
1946                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1947                                 { JoinBestTeam(self, FALSE, TRUE); }
1948
1949                         if(autocvar_g_campaign)
1950                                 { campaign_bots_may_start = 1; }
1951
1952                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1953
1954                         PutClientInServer();
1955
1956                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1957                 }
1958                 else
1959                         stuffcmd(self, "menu_showteamselect\n");
1960         }
1961         else
1962         {
1963                 // Player may not join because g_maxplayers is set
1964                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1965         }
1966 }
1967
1968 /**
1969  * Determines whether the player is allowed to join. This depends on cvar
1970  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1971  * it checks whether the number of currently playing players exceeds g_maxplayers.
1972  * @return int number of free slots for players, 0 if none
1973  */
1974 float nJoinAllowed(entity ignore) {
1975         if(!ignore)
1976         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1977         // so report 0 free slots if restricted
1978         {
1979                 if(autocvar_g_forced_team_otherwise == "spectate")
1980                         return 0;
1981                 if(autocvar_g_forced_team_otherwise == "spectator")
1982                         return 0;
1983         }
1984
1985         if(self.team_forced < 0)
1986                 return 0; // forced spectators can never join
1987
1988         // TODO simplify this
1989         entity e;
1990         float totalClients = 0;
1991         FOR_EACH_CLIENT(e)
1992                 if(e != ignore)
1993                         totalClients += 1;
1994
1995         if (!autocvar_g_maxplayers)
1996                 return maxclients - totalClients;
1997
1998         float currentlyPlaying = 0;
1999         FOR_EACH_REALCLIENT(e)
2000                 if(IS_PLAYER(e) || e.caplayer)
2001                         currentlyPlaying += 1;
2002
2003         if(currentlyPlaying < autocvar_g_maxplayers)
2004                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2005
2006         return 0;
2007 }
2008
2009 /**
2010  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2011  * g_maxplayers_spectator_blocktime seconds
2012  */
2013 void checkSpectatorBlock() {
2014         if(IS_SPEC(self) || IS_OBSERVER(self))
2015         if(!self.caplayer)
2016         if(IS_REAL_CLIENT(self))
2017         {
2018                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2019                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2020                         dropclient(self);
2021                 }
2022         }
2023 }
2024
2025 void PrintWelcomeMessage()
2026 {
2027         if(self.motd_actived_time == 0)
2028         {
2029                 if (autocvar_g_campaign) {
2030                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2031                                 self.motd_actived_time = time;
2032                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2033                         }
2034                 } else {
2035                         if (self.BUTTON_INFO) {
2036                                 self.motd_actived_time = time;
2037                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2038                         }
2039                 }
2040         }
2041         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2042         {
2043                 if (autocvar_g_campaign) {
2044                         if (self.BUTTON_INFO)
2045                                 self.motd_actived_time = time;
2046                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2047                                 self.motd_actived_time = 0;
2048                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2049                         }
2050                 } else {
2051                         if (self.BUTTON_INFO)
2052                                 self.motd_actived_time = time;
2053                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2054                                 self.motd_actived_time = 0;
2055                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2056                         }
2057                 }
2058         }
2059         else //if(self.motd_actived_time < 0) // just connected, motd is active
2060         {
2061                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2062                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2063                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2064                 {
2065                         // instanctly hide MOTD
2066                         self.motd_actived_time = 0;
2067                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2068                 }
2069         }
2070 }
2071
2072 void ObserverThink()
2073 {
2074         float prefered_movetype;
2075         if (self.flags & FL_JUMPRELEASED) {
2076                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2077                         self.flags &= ~FL_JUMPRELEASED;
2078                         self.flags |= FL_SPAWNING;
2079                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2080                         self.flags &= ~FL_JUMPRELEASED;
2081                         if(SpectateNext()) {
2082                                 self.classname = "spectator";
2083                         }
2084                 } else {
2085                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2086                         if (self.movetype != prefered_movetype)
2087                                 self.movetype = prefered_movetype;
2088                 }
2089         } else {
2090                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2091                         self.flags |= FL_JUMPRELEASED;
2092                         if(self.flags & FL_SPAWNING)
2093                         {
2094                                 self.flags &= ~FL_SPAWNING;
2095                                 LeaveSpectatorMode();
2096                                 return;
2097                         }
2098                 }
2099         }
2100 }
2101
2102 void SpectatorThink()
2103 {
2104         if (self.flags & FL_JUMPRELEASED) {
2105                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2106                         self.flags &= ~FL_JUMPRELEASED;
2107                         self.flags |= FL_SPAWNING;
2108                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2109                         self.flags &= ~FL_JUMPRELEASED;
2110                         if(SpectateNext()) {
2111                                 self.classname = "spectator";
2112                         } else {
2113                                 self.classname = "observer";
2114                                 PutClientInServer();
2115                         }
2116                         self.impulse = 0;
2117                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2118                         self.flags &= ~FL_JUMPRELEASED;
2119                         if(SpectatePrev()) {
2120                                 self.classname = "spectator";
2121                         } else {
2122                                 self.classname = "observer";
2123                                 PutClientInServer();
2124                         }
2125                         self.impulse = 0;
2126                 } else if (self.BUTTON_ATCK2) {
2127                         self.flags &= ~FL_JUMPRELEASED;
2128                         self.classname = "observer";
2129                         PutClientInServer();
2130                 } else {
2131                         if(!SpectateUpdate())
2132                                 PutObserverInServer();
2133                 }
2134         } else {
2135                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2136                         self.flags |= FL_JUMPRELEASED;
2137                         if(self.flags & FL_SPAWNING)
2138                         {
2139                                 self.flags &= ~FL_SPAWNING;
2140                                 LeaveSpectatorMode();
2141                                 return;
2142                         }
2143                 }
2144                 if(!SpectateUpdate())
2145                         PutObserverInServer();
2146         }
2147
2148         self.flags |= FL_CLIENT | FL_NOTARGET;
2149 }
2150
2151 void PlayerUseKey()
2152 {
2153         if (!IS_PLAYER(self))
2154                 return;
2155
2156         if(self.vehicle)
2157         {
2158         vehicles_exit(VHEF_NORMAL);
2159         return;
2160         }
2161
2162         // a use key was pressed; call handlers
2163         MUTATOR_CALLHOOK(PlayerUseKey);
2164 }
2165
2166 float isInvisibleString(string s)
2167 {
2168         float i, n, c;
2169         s = strdecolorize(s);
2170         for((i = 0), (n = strlen(s)); i < n; ++i)
2171         {
2172                 c = str2chr(s, i);
2173                 switch(c)
2174                 {
2175                         case 0:
2176                         case 32: // space
2177                                 break;
2178                         case 192: // charmap space
2179                                 if (!autocvar_utf8_enable)
2180                                         break;
2181                                 return FALSE;
2182                         case 160: // space in unicode fonts
2183                         case 0xE000 + 192: // utf8 charmap space
2184                                 if (autocvar_utf8_enable)
2185                                         break;
2186                         default:
2187                                 return FALSE;
2188                 }
2189         }
2190         return TRUE;
2191 }
2192
2193 /*
2194 =============
2195 PlayerPreThink
2196
2197 Called every frame for each client before the physics are run
2198 =============
2199 */
2200 .float usekeypressed;
2201 void() nexball_setstatus;
2202 .float items_added;
2203 void PlayerPreThink (void)
2204 {
2205         WarpZone_PlayerPhysics_FixVAngle();
2206
2207         self.stat_game_starttime = game_starttime;
2208         self.stat_round_starttime = round_starttime;
2209         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2210         self.stat_leadlimit = autocvar_leadlimit;
2211
2212         if(frametime)
2213         {
2214                 // physics frames: update anticheat stuff
2215                 anticheat_prethink();
2216         }
2217
2218         if(blockSpectators && frametime)
2219                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2220                 checkSpectatorBlock();
2221
2222         zoomstate_set = 0;
2223
2224         // Savage: Check for nameless players
2225         if (isInvisibleString(self.netname)) {
2226                 string new_name = strzone(strcat("Player@", self.netaddress));
2227                 if(autocvar_sv_eventlog)
2228                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2229                 if(self.netname_previous)
2230                         strunzone(self.netname_previous);
2231                 self.netname_previous = strzone(new_name);
2232                 self.netname = self.netname_previous;
2233                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2234         } else if(self.netname_previous != self.netname) {
2235                 if(autocvar_sv_eventlog)
2236                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2237                 if(self.netname_previous)
2238                         strunzone(self.netname_previous);
2239                 self.netname_previous = strzone(self.netname);
2240         }
2241
2242         // version nagging
2243         if(self.version_nagtime)
2244                 if(self.cvar_g_xonoticversion)
2245                         if(time > self.version_nagtime)
2246                         {
2247                                 // don't notify git users
2248                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2249                                 {
2250                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2251                                         {
2252                                                 // notify release users if connecting to git
2253                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2254                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2255                                         }
2256                                         else
2257                                         {
2258                                                 float r;
2259                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2260                                                 if(r < 0)
2261                                                 {
2262                                                         // give users new version
2263                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2264                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2265                                                 }
2266                                                 else if(r > 0)
2267                                                 {
2268                                                         // notify users about old server version
2269                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2270                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2271                                                 }
2272                                         }
2273                                 }
2274                                 self.version_nagtime = 0;
2275                         }
2276
2277         // GOD MODE info
2278         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2279         {
2280                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2281                 self.max_armorvalue = 0;
2282         }
2283
2284 #ifdef TETRIS
2285         if (TetrisPreFrame())
2286                 return;
2287 #endif
2288
2289         if(self.frozen == 2)
2290         {
2291                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2292                 self.health = max(1, self.revive_progress * start_health);
2293                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2294
2295                 if(self.revive_progress >= 1)
2296                         Unfreeze(self);
2297         }
2298         else if(self.frozen == 3)
2299         {
2300                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2301                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2302
2303                 if(self.health < 1)
2304                 {
2305                         if(self.vehicle)
2306                                 vehicles_exit(VHEF_RELESE);
2307                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2308                 }
2309                 else if ( self.revive_progress <= 0 )
2310                         Unfreeze(self);
2311         }
2312
2313         MUTATOR_CALLHOOK(PlayerPreThink);
2314
2315         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2316         {
2317                 if(self.BUTTON_USE && !self.usekeypressed)
2318                         PlayerUseKey();
2319                 self.usekeypressed = self.BUTTON_USE;
2320         }
2321
2322         if(IS_REAL_CLIENT(self))
2323                 PrintWelcomeMessage();
2324
2325         if(IS_PLAYER(self))
2326         {
2327
2328                 CheckRules_Player();
2329
2330                 if (intermission_running)
2331                 {
2332                         IntermissionThink ();   // otherwise a button could be missed between
2333                         return;                                 // the think tics
2334                 }
2335
2336                 //don't allow the player to turn around while game is paused!
2337                 if(timeout_status == TIMEOUT_ACTIVE) {
2338                         // FIXME turn this into CSQC stuff
2339                         self.v_angle = self.lastV_angle;
2340                         self.angles = self.lastV_angle;
2341                         self.fixangle = TRUE;
2342                 }
2343
2344                 if(frametime)
2345                 {
2346                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2347                         {
2348                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2349                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2350                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2351
2352                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2353                                 {
2354                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2355                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2356                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2357                                 }
2358                         }
2359                         else
2360                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2361
2362                         player_powerups();
2363                 }
2364
2365                 if (self.deadflag != DEAD_NO)
2366                 {
2367                         if(self.personal && g_race_qualifying)
2368                         {
2369                                 if(time > self.respawn_time)
2370                                 {
2371                                         self.respawn_time = time + 1; // only retry once a second
2372                                         self.stat_respawn_time = self.respawn_time;
2373                                         respawn();
2374                                         self.impulse = 141;
2375                                 }
2376                         }
2377                         else
2378                         {
2379                                 float button_pressed;
2380                                 if(frametime)
2381                                         player_anim();
2382                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2383
2384                                 if (self.deadflag == DEAD_DYING)
2385                                 {
2386                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2387                                                 self.deadflag = DEAD_RESPAWNING;
2388                                         else if(!button_pressed)
2389                                                 self.deadflag = DEAD_DEAD;
2390                                 }
2391                                 else if (self.deadflag == DEAD_DEAD)
2392                                 {
2393                                         if(button_pressed)
2394                                                 self.deadflag = DEAD_RESPAWNABLE;
2395                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2396                                                 self.deadflag = DEAD_RESPAWNING;
2397                                 }
2398                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2399                                 {
2400                                         if(!button_pressed)
2401                                                 self.deadflag = DEAD_RESPAWNING;
2402                                 }
2403                                 else if (self.deadflag == DEAD_RESPAWNING)
2404                                 {
2405                                         if(time > self.respawn_time)
2406                                         {
2407                                                 self.respawn_time = time + 1; // only retry once a second
2408                                                 self.respawn_time_max = self.respawn_time;
2409                                                 respawn();
2410                                         }
2411                                 }
2412
2413                                 ShowRespawnCountdown();
2414
2415                                 if(self.respawn_flags & RESPAWN_SILENT)
2416                                         self.stat_respawn_time = 0;
2417                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2418                                         self.stat_respawn_time = self.respawn_time_max;
2419                                 else
2420                                         self.stat_respawn_time = self.respawn_time;
2421                         }
2422
2423                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2424                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2425                                 self.stat_respawn_time *= -1;
2426
2427                         return;
2428                 }
2429
2430                 self.prevorigin = self.origin;
2431
2432                 float do_crouch = self.BUTTON_CROUCH;
2433                 if(self.hook.state)
2434                         do_crouch = 0;
2435                 if(self.vehicle)
2436                         do_crouch = 0;
2437                 if(self.frozen)
2438                         do_crouch = 0;
2439
2440                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2441                 // It cannot be predicted by the engine!
2442                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2443                         do_crouch = 0;
2444
2445                 if (do_crouch)
2446                 {
2447                         if (!self.crouch)
2448                         {
2449                                 self.crouch = TRUE;
2450                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2451                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2452                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2453                         }
2454                 }
2455                 else
2456                 {
2457                         if (self.crouch)
2458                         {
2459                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2460                                 if (!trace_startsolid)
2461                                 {
2462                                         self.crouch = FALSE;
2463                                         self.view_ofs = PL_VIEW_OFS;
2464                                         setsize (self, PL_MIN, PL_MAX);
2465                                 }
2466                         }
2467                 }
2468
2469                 FixPlayermodel();
2470
2471                 GrapplingHookFrame();
2472
2473                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2474                 //if(frametime)
2475                 {
2476                         self.items &= ~self.items_added;
2477
2478                         W_WeaponFrame();
2479
2480                         self.items_added = 0;
2481                         if(self.items & IT_JETPACK)
2482                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2483                                         self.items_added |= IT_FUEL;
2484
2485                         self.items |= self.items_added;
2486                 }
2487
2488                 player_regen();
2489
2490                 // WEAPONTODO: Add a weapon request for this
2491                 // rot vortex charge to the charge limit
2492                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2493                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2494
2495                 if(frametime)
2496                         player_anim();
2497
2498                 // secret status
2499                 secrets_setstatus();
2500
2501                 // monsters status
2502                 monsters_setstatus();
2503
2504                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2505
2506                 //self.angles_y=self.v_angle_y + 90;   // temp
2507         } else if(gameover) {
2508                 if (intermission_running)
2509                         IntermissionThink ();   // otherwise a button could be missed between
2510                 return;
2511         } else if(IS_OBSERVER(self)) {
2512                 ObserverThink();
2513         } else if(IS_SPEC(self)) {
2514                 SpectatorThink();
2515         }
2516
2517         // WEAPONTODO: Add weapon request for this
2518         if(!zoomstate_set)
2519                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2520
2521         float oldspectatee_status;
2522         oldspectatee_status = self.spectatee_status;
2523         if(IS_SPEC(self))
2524                 self.spectatee_status = num_for_edict(self.enemy);
2525         else if(IS_OBSERVER(self))
2526                 self.spectatee_status = num_for_edict(self);
2527         else
2528                 self.spectatee_status = 0;
2529         if(self.spectatee_status != oldspectatee_status)
2530         {
2531                 ClientData_Touch(self);
2532         }
2533
2534         if(self.teamkill_soundtime)
2535         if(time > self.teamkill_soundtime)
2536         {
2537                 self.teamkill_soundtime = 0;
2538
2539                 entity oldpusher, oldself;
2540
2541                 oldself = self; self = self.teamkill_soundsource;
2542                 oldpusher = self.pusher; self.pusher = oldself;
2543
2544                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2545
2546                 self.pusher = oldpusher;
2547                 self = oldself;
2548         }
2549
2550         if(self.taunt_soundtime)
2551         if(time > self.taunt_soundtime)
2552         {
2553                 self.taunt_soundtime = 0;
2554                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2555         }
2556
2557         target_voicescript_next(self);
2558
2559         // WEAPONTODO: Move into weaponsystem somehow
2560         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2561         if(!self.weapon)
2562                 self.clip_load = self.clip_size = 0;
2563 }
2564
2565 /*
2566 =============
2567 PlayerPostThink
2568
2569 Called every frame for each client after the physics are run
2570 =============
2571 */
2572 .float idlekick_lasttimeleft;
2573 void PlayerPostThink (void)
2574 {
2575         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2576         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2577         {
2578                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2579                 {
2580                         if(self.idlekick_lasttimeleft)
2581                         {
2582                                 self.idlekick_lasttimeleft = 0;
2583                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2584                         }
2585                 }
2586                 else
2587                 {
2588                         float timeleft;
2589                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2590                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2591                         {
2592                                 if(!self.idlekick_lasttimeleft)
2593                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2594                         }
2595                         if(timeleft <= 0)
2596                         {
2597                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2598                                 dropclient(self);
2599                                 return;
2600                         }
2601                         else if(timeleft <= 10)
2602                         {
2603                                 if(timeleft != self.idlekick_lasttimeleft)
2604                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2605                                 self.idlekick_lasttimeleft = timeleft;
2606                         }
2607                 }
2608         }
2609
2610 #ifdef TETRIS
2611         if(self.impulse == 100)
2612                 ImpulseCommands();
2613         if (!TetrisPostFrame())
2614         {
2615 #endif
2616
2617         CheatFrame();
2618
2619         //CheckPlayerJump();
2620
2621         if(IS_PLAYER(self)) {
2622                 CheckRules_Player();
2623                 UpdateChatBubble();
2624                 if (self.impulse)
2625                         ImpulseCommands();
2626                 if (intermission_running)
2627                         return;         // intermission or finale
2628                 GetPressedKeys();
2629         }
2630
2631 #ifdef TETRIS
2632         }
2633 #endif
2634
2635         /*
2636         float i;
2637         for(i = 0; i < 1000; ++i)
2638         {
2639                 vector end;
2640                 end = self.origin + '0 0 1024' + 512 * randomvec();
2641                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2642                 if(trace_fraction < 1)
2643                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2644                 {
2645                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2646                         break;
2647                 }
2648         }
2649         */
2650
2651         if(self.waypointsprite_attachedforcarrier)
2652                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2653
2654         playerdemo_write();
2655
2656         CSQCMODEL_AUTOUPDATE();
2657 }