qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(cvar("spawn_debugview"))
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > cvar("g_spawn_furthest"))
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(cvar("spawn_debugview"))
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(cvar("spawn_debug"))
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(cvar("sv_servermodelsonly"))
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602
 603         Portal_ClearAll(self);
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         self.spectatortime = time;
 634
 635         self.classname = "observer";
 636         self.iscreature = FALSE;
 637         self.health = -666;
 638         self.takedamage = DAMAGE_NO;
 639         self.solid = SOLID_NOT;
 640         self.movetype = MOVETYPE_NOCLIP;
 641         self.flags = FL_CLIENT | FL_NOTARGET;
 642         self.armorvalue = 666;
 643         self.effects = 0;
 644         self.armorvalue = cvar("g_balance_armor_start");
 645         self.pauserotarmor_finished = 0;
 646         self.pauserothealth_finished = 0;
 647         self.pauseregen_finished = 0;
 648         self.damageforcescale = 0;
 649         self.death_time = 0;
 650         self.dead_frame = 0;
 651         self.alpha = 0;
 652         self.scale = 0;
 653         self.fade_time = 0;
 654         self.pain_frame = 0;
 655         self.pain_finished = 0;
 656         self.strength_finished = 0;
 657         self.invincible_finished = 0;
 658         self.pushltime = 0;
 659         self.think = SUB_Null;
 660         self.nextthink = 0;
 661         self.hook_time = 0;
 662         self.runes = 0;
 663         self.deadflag = DEAD_NO;
 664         self.angles = spot.angles;
 665         self.angles_z = 0;
 666         self.fixangle = TRUE;
 667         self.crouch = FALSE;
 668
 669         self.view_ofs = PL_VIEW_OFS;
 670         setorigin (self, spot.origin);
 671         setsize (self, '0 0 0', '0 0 0');
 672         self.prevorigin = self.origin;
 673         self.items = 0;
 674         self.weapons = 0;
 675         self.model = "";
 676         FixPlayermodel();
 677         self.model = "";
 678         self.modelindex = 0;
 679         self.weapon = 0;
 680         self.weaponmodel = "";
 681         self.weaponentity = world;
 682         self.exteriorweaponentity = world;
 683         self.killcount = -666;
 684         self.velocity = '0 0 0';
 685         self.avelocity = '0 0 0';
 686         self.punchangle = '0 0 0';
 687         self.punchvector = '0 0 0';
 688         self.oldvelocity = self.velocity;
 689         self.fire_endtime = -1;
 690
 691         if(sv_loddistance1)
 692                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 693
 694         if(g_arena)
 695         {
 696                 if(self.version_mismatch)
 697                 {
 698                         Spawnqueue_Unmark(self);
 699                         Spawnqueue_Remove(self);
 700                 }
 701                 else
 702                 {
 703                         Spawnqueue_Insert(self);
 704                 }
 705         }
 706         else if(g_lms)
 707         {
 708                 // Only if the player cannot play at all
 709                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 710                         self.frags = FRAGS_SPECTATOR;
 711                 else
 712                         self.frags = FRAGS_LMS_LOSER;
 713         }
 714         else
 715                 self.frags = FRAGS_SPECTATOR;
 716
 717         MUTATOR_CALLHOOK(MakePlayerObserver);
 718 }
 719
 720 float RestrictSkin(float s)
 721 {
 722         if(!teams_matter)
 723                 return s;
 724         if(s == 6)
 725                 return 6;
 726         return mod(s, 3);
 727 }
 728
 729 void FixPlayermodel()
 730 {
 731         local string defaultmodel;
 732         local float defaultskin, chmdl, oldskin;
 733         local vector m1, m2;
 734
 735         defaultmodel = "";
 736
 737         if(cvar("sv_defaultcharacter") == 1) {
 738                 defaultskin = 0;
 739
 740                 if(teams_matter)
 741                 {
 742                         string s;
 743                         s = Team_ColorNameLowerCase(self.team);
 744                         if(s != "neutral")
 745                         {
 746                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 747                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 748                         }
 749                 }
 750
 751                 if(defaultmodel == "")
 752                 {
 753                         defaultmodel = cvar_string("sv_defaultplayermodel");
 754                         defaultskin = cvar("sv_defaultplayerskin");
 755                 }
 756         }
 757
 758         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 759         {
 760                 if(self.model != "")
 761                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 762                 self.model = ""; // force the != checks to return true
 763         }
 764
 765         if(defaultmodel != "")
 766         {
 767                 if (defaultmodel != self.model)
 768                 {
 769                         m1 = self.mins;
 770                         m2 = self.maxs;
 771                         setmodel_lod (self, defaultmodel);
 772                         setsize (self, m1, m2);
 773                         chmdl = TRUE;
 774                 }
 775
 776                 oldskin = self.skinindex;
 777                 self.skinindex = defaultskin;
 778         } else {
 779                 if (self.playermodel != self.model || self.playermodel == "")
 780                 {
 781                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 782                         m1 = self.mins;
 783                         m2 = self.maxs;
 784                         setmodel_lod (self, self.playermodel);
 785                         setsize (self, m1, m2);
 786                         chmdl = TRUE;
 787                 }
 788
 789                 oldskin = self.skinindex;
 790                 self.skinindex = RestrictSkin(stof(self.playerskin));
 791         }
 792
 793         if(chmdl || oldskin != self.skinindex)
 794                 self.species = player_getspecies(); // model or skin has changed
 795
 796         if(!teams_matter)
 797                 if(strlen(cvar_string("sv_defaultplayercolors")))
 798                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 799                                 setcolor(self, cvar("sv_defaultplayercolors"));
 800 }
 801
 802 void PlayerTouchExplode(entity p1, entity p2)
 803 {
 804         vector org;
 805         org = (p1.origin + p2.origin) * 0.5;
 806         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 807
 808         te_explosion(org);
 809
 810         entity e;
 811         e = spawn();
 812         setorigin(e, org);
 813         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 814         remove(e);
 815 }
 816
 817 /*
 818 =============
 819 PutClientInServer
 820
 821 Called when a client spawns in the server
 822 =============
 823 */
 824 //void() ctf_playerchanged;
 825 void PutClientInServer (void)
 826 {
 827         if(clienttype(self) == CLIENTTYPE_BOT)
 828         {
 829                 self.classname = "player";
 830         }
 831         else if(clienttype(self) == CLIENTTYPE_REAL)
 832         {
 833                 msg_entity = self;
 834                 WriteByte(MSG_ONE, SVC_SETVIEW);
 835                 WriteEntity(MSG_ONE, self);
 836         }
 837
 838         // player is dead and becomes observer
 839         // FIXME fix LMS scoring for new system
 840         if(g_lms)
 841         {
 842                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 843                         self.classname = "observer";
 844         }
 845
 846         if(g_arena || (g_ca && !allowed_to_spawn))
 847         if(!self.spawned)
 848                 self.classname = "observer";
 849
 850         if(gameover)
 851                 self.classname = "observer";
 852
 853         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 854                 entity spot, oldself;
 855                 float j;
 856
 857                 if(self.team < 0)
 858                         JoinBestTeam(self, FALSE, TRUE);
 859
 860                 race_PreSpawn();
 861
 862                 spot = SelectSpawnPoint (FALSE);
 863                 if(!spot)
 864                 {
 865                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 866                         return; // spawn failed
 867                 }
 868
 869                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 870
 871                 self.classname = "player";
 872                 self.wasplayer = TRUE;
 873                 self.iscreature = TRUE;
 874                 self.movetype = MOVETYPE_WALK;
 875                 self.solid = SOLID_SLIDEBOX;
 876                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 877                 if(cvar("g_playerclip_collisions"))
 878                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 879                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 880                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 881                 self.frags = FRAGS_PLAYER;
 882                 if(independent_players)
 883                         MAKE_INDEPENDENT_PLAYER(self);
 884                 self.flags = FL_CLIENT;
 885                 self.takedamage = DAMAGE_AIM;
 886                 if(g_minstagib)
 887                         self.effects = EF_FULLBRIGHT;
 888                 else
 889                         self.effects = 0;
 890                 self.air_finished = time + 12;
 891                 self.dmg = 2;
 892
 893                 if(inWarmupStage)
 894                 {
 895                         self.ammo_shells = warmup_start_ammo_shells;
 896                         self.ammo_nails = warmup_start_ammo_nails;
 897                         self.ammo_rockets = warmup_start_ammo_rockets;
 898                         self.ammo_cells = warmup_start_ammo_cells;
 899                         self.ammo_fuel = warmup_start_ammo_fuel;
 900                         self.health = warmup_start_health;
 901                         self.armorvalue = warmup_start_armorvalue;
 902                         self.weapons = warmup_start_weapons;
 903                 }
 904                 else
 905                 {
 906                         self.ammo_shells = start_ammo_shells;
 907                         self.ammo_nails = start_ammo_nails;
 908                         self.ammo_rockets = start_ammo_rockets;
 909                         self.ammo_cells = start_ammo_cells;
 910                         self.ammo_fuel = start_ammo_fuel;
 911                         self.health = start_health;
 912                         self.armorvalue = start_armorvalue;
 913                         self.weapons = start_weapons;
 914                 }
 915
 916                 if(g_weaponarena_random)
 917                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 918
 919                 self.items = start_items;
 920                 self.jump_interval = time;
 921
 922                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 923                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 924                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 925                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 926                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 927                 //extend the pause of rotting if client was reset at the beginning of the countdown
 928                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 929                         self.spawnshieldtime += game_starttime - time;
 930                         self.pauserotarmor_finished += game_starttime - time;
 931                         self.pauserothealth_finished += game_starttime - time;
 932                         self.pauseregen_finished += game_starttime - time;
 933                 }
 934                 self.damageforcescale = 2;
 935                 self.death_time = 0;
 936                 self.dead_frame = 0;
 937                 self.alpha = 0;
 938                 self.scale = 0;
 939                 self.fade_time = 0;
 940                 self.pain_frame = 0;
 941                 self.pain_finished = 0;
 942                 self.strength_finished = 0;
 943                 self.invincible_finished = 0;
 944                 self.pushltime = 0;
 945                 // players have no think function
 946                 self.think = SUB_Null;
 947                 self.nextthink = 0;
 948                 self.hook_time = 0;
 949                 self.dmg_team = 0;
 950                 self.ballistics_density = cvar("g_ballistics_density_player");
 951
 952                 self.metertime = 0;
 953
 954                 self.runes = 0;
 955
 956                 self.deadflag = DEAD_NO;
 957
 958                 self.angles = spot.angles;
 959
 960                 self.angles_z = 0; // never spawn tilted even if the spot says to
 961                 self.fixangle = TRUE; // turn this way immediately
 962                 self.velocity = '0 0 0';
 963                 self.avelocity = '0 0 0';
 964                 self.punchangle = '0 0 0';
 965                 self.punchvector = '0 0 0';
 966                 self.oldvelocity = self.velocity;
 967                 self.fire_endtime = -1;
 968
 969                 msg_entity = self;
 970                 WRITESPECTATABLE_MSG_ONE({
 971                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 972                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 973                 });
 974
 975                 if(sv_loddistance1)
 976                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 977
 978                 self.model = "";
 979                 FixPlayermodel();
 980
 981                 self.crouch = FALSE;
 982                 self.view_ofs = PL_VIEW_OFS;
 983                 setsize (self, PL_MIN, PL_MAX);
 984                 self.spawnorigin = spot.origin;
 985                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 986                 // don't reset back to last position, even if new position is stuck in solid
 987                 self.oldorigin = self.origin;
 988                 self.prevorigin = self.origin;
 989                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 990
 991                 if(g_arena)
 992                 {
 993                         Spawnqueue_Remove(self);
 994                         Spawnqueue_Mark(self);
 995                 }
 996
 997                 else if(g_ca)
 998                         self.caplayer = 1;
 999
1000                 self.event_damage = PlayerDamage;
1001
1002                 self.bot_attack = TRUE;
1003
1004                 self.statdraintime = time + 5;
1005                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1006
1007                 if(self.killcount == -666) {
1008                         PlayerScore_Clear(self);
1009                         self.killcount = 0;
1010                 }
1011
1012                 self.cnt = WEP_LASER;
1013
1014                 CL_SpawnWeaponentity();
1015                 self.alpha = default_player_alpha;
1016                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1017                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1018
1019                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1020                 self.lms_traveled_distance = 0;
1021                 self.speedrunning = FALSE;
1022
1023                 race_PostSpawn(spot);
1024
1025                 if(cvar("spawn_debug"))
1026                 {
1027                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1028                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1029                 }
1030
1031                 //stuffcmd(self, "chase_active 0");
1032                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1033
1034                 if (cvar("g_spawnsound"))
1035                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1036
1037                 if(g_assault) {
1038                         if(self.team == assault_attacker_team)
1039                                 centerprint(self, "You are attacking!");
1040                         else
1041                                 centerprint(self, "You are defending!");
1042                 }
1043
1044                 target_voicescript_clear(self);
1045
1046                 // reset fields the weapons may use
1047                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1048                         weapon_action(j, WR_RESETPLAYER);
1049
1050                 oldself = self;
1051                 self = spot;
1052                         activator = oldself;
1053                                 SUB_UseTargets();
1054                         activator = world;
1055                 self = oldself;
1056
1057                 MUTATOR_CALLHOOK(PlayerSpawn);
1058
1059                 self.switchweapon = w_getbestweapon(self);
1060                 self.cnt = self.switchweapon;
1061                 self.weapon = 0;
1062         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1063                 PutObserverInServer ();
1064         }
1065
1066         //if(g_ctf)
1067         //      ctf_playerchanged();
1068 }
1069
1070 float ClientInit_SendEntity(entity to, float sf)
1071 {
1072         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1073         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1074         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1075         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1078         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1079         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1080         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1081         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1082         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1083         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1084         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1085         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1086         if(sv_foginterval && world.fog != "")
1087                 WriteString(MSG_ENTITY, world.fog);
1088         else
1089                 WriteString(MSG_ENTITY, "");
1090         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1091         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1092         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1093         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1094         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1095         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1096         return TRUE;
1097 }
1098
1099 void ClientInit_CheckUpdate()
1100 {
1101         self.nextthink = time;
1102         if(self.count != cvar("g_balance_armor_blockpercent"))
1103         {
1104                 self.count = cvar("g_balance_armor_blockpercent");
1105                 self.SendFlags |= 1;
1106         }
1107         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1108         {
1109                 self.cnt = cvar("g_balance_weaponswitchdelay");
1110                 self.SendFlags |= 1;
1111         }
1112         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1113         {
1114                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1115                 self.SendFlags |= 1;
1116         }
1117         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1118         {
1119                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1120                 self.SendFlags |= 1;
1121         }
1122 }
1123
1124 void ClientInit_Spawn()
1125 {
1126         entity o;
1127         entity e;
1128         e = spawn();
1129         e.classname = "clientinit";
1130         e.think = ClientInit_CheckUpdate;
1131         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1132
1133         o = self;
1134         self = e;
1135         ClientInit_CheckUpdate();
1136         self = o;
1137 }
1138
1139 /*
1140 =============
1141 SetNewParms
1142 =============
1143 */
1144 void SetNewParms (void)
1145 {
1146         // initialize parms for a new player
1147         parm1 = -(86400 * 366);
1148 }
1149
1150 /*
1151 =============
1152 SetChangeParms
1153 =============
1154 */
1155 void SetChangeParms (void)
1156 {
1157         // save parms for level change
1158         parm1 = self.parm_idlesince - time;
1159 }
1160
1161 /*
1162 =============
1163 DecodeLevelParms
1164 =============
1165 */
1166 void DecodeLevelParms (void)
1167 {
1168         // load parms
1169         self.parm_idlesince = parm1;
1170         if(self.parm_idlesince == -(86400 * 366))
1171                 self.parm_idlesince = time;
1172
1173         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1174         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1175 }
1176
1177 /*
1178 =============
1179 ClientKill
1180
1181 Called when a client types 'kill' in the console
1182 =============
1183 */
1184
1185 void ClientKill_Now_TeamChange()
1186 {
1187         if(self.killindicator_teamchange == -1)
1188         {
1189                 self.team = -1;
1190                 JoinBestTeam( self, FALSE, FALSE );
1191         }
1192         else
1193                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1194 }
1195
1196 void ClientKill_Now()
1197 {
1198         if(self.killindicator_teamchange)
1199                 ClientKill_Now_TeamChange();
1200
1201         // in any case:
1202         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1203
1204         if(self.killindicator)
1205         {
1206                 dprint("Cleaned up after a leaked kill indicator.\n");
1207                 remove(self.killindicator);
1208                 self.killindicator = world;
1209         }
1210 }
1211 void KillIndicator_Think()
1212 {
1213         if (!self.owner.modelindex)
1214         {
1215                 self.owner.killindicator = world;
1216                 remove(self);
1217                 return;
1218         }
1219
1220         if(self.cnt <= 0)
1221         {
1222                 self = self.owner;
1223                 ClientKill_Now(); // no oldself needed
1224                 return;
1225         }
1226         else
1227         {
1228                 if(self.cnt <= 10)
1229                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1230                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1231                 {
1232                         if(self.cnt <= 10)
1233                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1234                         if(self.owner.killindicator_teamchange)
1235                         {
1236                                 if(self.owner.killindicator_teamchange == -1)
1237                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1238                                 else
1239                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1240                         }
1241                         else
1242                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1243                 }
1244                 self.nextthink = time + 1;
1245                 self.cnt -= 1;
1246         }
1247 }
1248
1249 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1250 {
1251         float killtime;
1252         entity e;
1253         killtime = cvar("g_balance_kill_delay");
1254
1255         if(g_race_qualifying)
1256                 killtime = 0;
1257
1258         self.killindicator_teamchange = targetteam;
1259
1260         if(!self.killindicator)
1261         {
1262                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1263                 {
1264                         ClientKill_Now();
1265                 }
1266                 else
1267                 {
1268                         self.killindicator = spawn();
1269                         self.killindicator.owner = self;
1270                         self.killindicator.scale = 0.5;
1271                         setattachment(self.killindicator, self, "");
1272                         setorigin(self.killindicator, '0 0 52');
1273                         self.killindicator.think = KillIndicator_Think;
1274                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1275                         self.killindicator.cnt = ceil(killtime);
1276                         self.killindicator.count = bound(0, ceil(killtime), 10);
1277                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1278
1279                         for(e = world; (e = find(e, classname, "body")) != world; )
1280                         {
1281                                 if(e.enemy != self)
1282                                         continue;
1283                                 e.killindicator = spawn();
1284                                 e.killindicator.owner = e;
1285                                 e.killindicator.scale = 0.5;
1286                                 setattachment(e.killindicator, e, "");
1287                                 setorigin(e.killindicator, '0 0 52');
1288                                 e.killindicator.think = KillIndicator_Think;
1289                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1290                                 e.killindicator.cnt = ceil(killtime);
1291                         }
1292                         self.lip = 0;
1293                 }
1294         }
1295         if(self.killindicator)
1296         {
1297                 if(targetteam)
1298                         self.killindicator.colormod = TeamColor(targetteam);
1299                 else
1300                         self.killindicator.colormod = '0 0 0';
1301         }
1302 }
1303
1304 void ClientKill (void)
1305 {
1306         ClientKill_TeamChange(0);
1307 }
1308
1309 void DoTeamChange(float destteam)
1310 {
1311         float t, c0;
1312         if(!teams_matter)
1313         {
1314                 if(destteam >= 0)
1315                         SetPlayerColors(self, destteam);
1316                 return;
1317         }
1318         if(self.classname == "player")
1319         if(destteam == -1)
1320         {
1321                 CheckAllowedTeams(self);
1322                 t = FindSmallestTeam(self, TRUE);
1323                 switch(self.team)
1324                 {
1325                         case COLOR_TEAM1: c0 = c1; break;
1326                         case COLOR_TEAM2: c0 = c2; break;
1327                         case COLOR_TEAM3: c0 = c3; break;
1328                         case COLOR_TEAM4: c0 = c4; break;
1329                         default:          c0 = 999;
1330                 }
1331                 switch(t)
1332                 {
1333                         case 1:
1334                                 if(c0 > c1)
1335                                         destteam = COLOR_TEAM1;
1336                                 break;
1337                         case 2:
1338                                 if(c0 > c2)
1339                                         destteam = COLOR_TEAM2;
1340                                 break;
1341                         case 3:
1342                                 if(c0 > c3)
1343                                         destteam = COLOR_TEAM3;
1344                                 break;
1345                         case 4:
1346                                 if(c0 > c4)
1347                                         destteam = COLOR_TEAM4;
1348                                 break;
1349                 }
1350                 if(destteam == -1)
1351                         return;
1352         }
1353         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1354                 return;
1355         ClientKill_TeamChange(destteam);
1356 }
1357
1358 void FixClientCvars(entity e)
1359 {
1360         // send prediction settings to the client
1361         stuffcmd(e, "\nin_bindmap 0 0\n");
1362         if(g_race || g_cts)
1363                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1364         if(cvar("g_antilag") == 3) // client side hitscan
1365                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1366         if(sv_gentle)
1367                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1368         /*
1369          * we no longer need to stuff this. Remove this comment block if you feel
1370          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1371         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1372         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1373         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1374         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1375         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1376         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1377         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1378         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1379         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1380         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1381         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1382         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1383         stuffcmd(e, "cl_movement_edgefriction 1\n");
1384          */
1385 }
1386
1387 /*
1388 =============
1389 ClientConnect
1390
1391 Called when a client connects to the server
1392 =============
1393 */
1394 //void ctf_clientconnect();
1395 string ColoredTeamName(float t);
1396 void DecodeLevelParms (void);
1397 //void dom_player_join_team(entity pl);
1398 void ClientConnect (void)
1399 {
1400         float t;
1401
1402         if(self.flags & FL_CLIENT)
1403         {
1404                 print("Warning: ClientConnect, but already connected!\n");
1405                 return;
1406         }
1407
1408         if(Ban_MaybeEnforceBan(self))
1409                 return;
1410
1411         DecodeLevelParms();
1412
1413 #ifdef WATERMARK
1414         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1415 #endif
1416
1417         self.classname = "player_joining";
1418
1419         self.flags = FL_CLIENT;
1420         self.version_nagtime = time + 10 + random() * 10;
1421
1422         if(player_count<0)
1423         {
1424                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1425                 player_count = 0;
1426         }
1427
1428         PlayerScore_Attach(self);
1429         ClientData_Attach();
1430
1431         bot_clientconnect();
1432
1433         playerdemo_init();
1434
1435         anticheat_init();
1436
1437         race_PreSpawnObserver();
1438
1439         //if(g_domination)
1440         //      dom_player_join_team(self);
1441
1442         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1443
1444         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1445                 self.classname = "observer";
1446         } else {
1447                 if(teams_matter)
1448                 {
1449                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1450                         {
1451                                 self.classname = "player";
1452                                 campaign_bots_may_start = 1;
1453                         }
1454                         else
1455                         {
1456                                 self.classname = "observer"; // do it anyway
1457                         }
1458                 }
1459                 else
1460                 {
1461                         self.classname = "player";
1462                         campaign_bots_may_start = 1;
1463                 }
1464         }
1465
1466         self.playerid = (playerid_last = playerid_last + 1);
1467
1468         if(cvar("sv_eventlog"))
1469                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1470
1471         LogTeamchange(self.playerid, self.team, 1);
1472
1473         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1474
1475         self.netname_previous = strzone(self.netname);
1476
1477         bprint("^4", self.netname, "^4 connected");
1478
1479         if(self.classname != "observer" && (g_domination || g_ctf))
1480                 bprint(" and joined the ", ColoredTeamName(self.team));
1481
1482         bprint("\n");
1483
1484         self.welcomemessage_time = 0;
1485
1486         stuffcmd(self, strcat(clientstuff, "\n"));
1487         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1488         stuffcmd(self, "cl_particles_reloadeffects\n");
1489
1490         FixClientCvars(self);
1491
1492         // spawnfunc_waypoint sprites
1493         WaypointSprite_InitClient(self);
1494
1495         // Wazat's grappling hook
1496         SetGrappleHookBindings();
1497
1498         // get autoswitch state from player when he toggles it
1499         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1500
1501         // get version info from player
1502         stuffcmd(self, "cmd clientversion $gameversion\n");
1503
1504         // get other cvars from player
1505         GetCvars(0);
1506
1507         // set cvar for team scoreboard
1508         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1509
1510         // notify about available teams
1511         if(teams_matter)
1512         {
1513                 CheckAllowedTeams(self);
1514                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1515                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1516         }
1517         else
1518                 stuffcmd(self, "set _teams_available 0\n");
1519
1520         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1521
1522         if(g_arena || g_ca)
1523         {
1524                 self.classname = "observer";
1525                 if(g_arena)
1526                         Spawnqueue_Insert(self);
1527         }
1528         /*else if(g_ctf)
1529         {
1530                 ctf_clientconnect();
1531         }*/
1532
1533         if(teams_matter || radar_showennemies)
1534                 attach_entcs();
1535
1536         bot_relinkplayerlist();
1537
1538         self.spectatortime = time;
1539         if(blockSpectators)
1540         {
1541                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1542         }
1543
1544         self.jointime = time;
1545         self.allowedTimeouts = cvar("sv_timeout_number");
1546
1547         if(clienttype(self) == CLIENTTYPE_REAL)
1548         {
1549                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1550                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1551         }
1552
1553         if(g_lms)
1554         {
1555                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1556                 {
1557                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1558                         self.frags = FRAGS_SPECTATOR;
1559                 }
1560         }
1561
1562         if(!sv_foginterval && world.fog != "")
1563                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1564
1565         SoundEntity_Attach(self);
1566
1567         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1568         {
1569                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1570                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1571         }
1572         else
1573                 self.hitplotfh = -1;
1574
1575         if(g_race || g_cts) {
1576                 string rr;
1577                 if(g_cts)
1578                         rr = CTS_RECORD;
1579                 else
1580                         rr = RACE_RECORD;
1581                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1582
1583                 race_send_recordtime(MSG_ONE);
1584                 race_send_speedaward(MSG_ONE);
1585
1586                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1587                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1588                 race_send_speedaward_alltimebest(MSG_ONE);
1589
1590                 float i;
1591                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1592                         race_SendRankings(i, 0, 0, MSG_ONE);
1593                 }
1594         }
1595         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1596                 send_CSQC_teamnagger();
1597
1598         send_CSQC_cr_maxbullets(self);
1599
1600         CheatInitClient();
1601 }
1602
1603 /*
1604 =============
1605 ClientDisconnect
1606
1607 Called when a client disconnects from the server
1608 =============
1609 */
1610 .entity chatbubbleentity;
1611 .entity teambubbleentity;
1612 void ReadyCount();
1613 void ClientDisconnect (void)
1614 {
1615         if not(self.flags & FL_CLIENT)
1616         {
1617                 print("Warning: ClientDisconnect without ClientConnect\n");
1618                 return;
1619         }
1620
1621         CheatShutdownClient();
1622
1623         if(self.hitplotfh >= 0)
1624         {
1625                 fclose(self.hitplotfh);
1626                 self.hitplotfh = -1;
1627         }
1628
1629         anticheat_report();
1630         anticheat_shutdown();
1631
1632         playerdemo_shutdown();
1633
1634         bot_clientdisconnect();
1635
1636         if(self.entcs)
1637                 detach_entcs();
1638
1639         if(cvar("sv_eventlog"))
1640                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1641         bprint ("^4",self.netname);
1642         bprint ("^4 disconnected\n");
1643
1644         SoundEntity_Detach(self);
1645
1646         DropAllRunes(self);
1647         MUTATOR_CALLHOOK(ClientDisconnect);
1648
1649         Portal_ClearAll(self);
1650
1651         if(self.flagcarried)
1652                 DropFlag(self.flagcarried, world, world);
1653         if(self.ballcarried)
1654                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1655
1656         // Here, everything has been done that requires this player to be a client.
1657
1658         self.flags &~= FL_CLIENT;
1659
1660         if (self.chatbubbleentity)
1661                 remove (self.chatbubbleentity);
1662
1663         if (self.teambubbleentity)
1664                 remove (self.teambubbleentity);
1665
1666         if (self.killindicator)
1667                 remove (self.killindicator);
1668
1669         WaypointSprite_PlayerGone();
1670
1671         bot_relinkplayerlist();
1672
1673         // remove laserdot
1674         if(self.weaponentity)
1675                 if(self.weaponentity.lasertarget)
1676                         remove(self.weaponentity.lasertarget);
1677
1678         if(g_arena)
1679         {
1680                 Spawnqueue_Unmark(self);
1681                 Spawnqueue_Remove(self);
1682         }
1683
1684         ClientData_Detach();
1685         PlayerScore_Detach(self);
1686
1687         if(self.netname_previous)
1688                 strunzone(self.netname_previous);
1689         if(self.clientstatus)
1690                 strunzone(self.clientstatus);
1691
1692         ClearPlayerSounds();
1693
1694         if(self.personal)
1695                 remove(self.personal);
1696
1697         self.playerid = 0;
1698         ReadyCount();
1699
1700         // free cvars
1701         GetCvars(-1);
1702 }
1703
1704 .float BUTTON_CHAT;
1705 void ChatBubbleThink()
1706 {
1707         self.nextthink = time;
1708         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1709         {
1710                 if(self.owner) // but why can that ever be world?
1711                         self.owner.chatbubbleentity = world;
1712                 remove(self);
1713                 return;
1714         }
1715         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1716 #ifdef TETRIS
1717                 || self.owner.tetris_on
1718 #endif
1719         )
1720                 self.model = self.mdl;
1721         else
1722                 self.model = "";
1723 };
1724
1725 void UpdateChatBubble()
1726 {
1727         if (!self.modelindex)
1728                 return;
1729         // spawn a chatbubble entity if needed
1730         if (!self.chatbubbleentity)
1731         {
1732                 self.chatbubbleentity = spawn();
1733                 self.chatbubbleentity.owner = self;
1734                 self.chatbubbleentity.exteriormodeltoclient = self;
1735                 self.chatbubbleentity.think = ChatBubbleThink;
1736                 self.chatbubbleentity.nextthink = time;
1737                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1738                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1739                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1740                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1741                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1742                 self.chatbubbleentity.model = "";
1743                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1744         }
1745 }
1746
1747
1748 void TeamBubbleThink()
1749 {
1750         self.nextthink = time;
1751         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1752         {
1753                 if(self.owner) // but why can that ever be world?
1754                         self.owner.teambubbleentity = world;
1755                 remove(self);
1756                 return;
1757         }
1758 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1759         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1760                 self.model = "";
1761         else
1762                 self.model = self.mdl;
1763
1764 };
1765
1766 float TeamBubble_customizeentityforclient()
1767 {
1768         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1769 }
1770
1771 void UpdateTeamBubble()
1772 {
1773         if (!self.modelindex || !teams_matter)
1774                 return;
1775         // spawn a teambubble entity if needed
1776         if (!self.teambubbleentity && teams_matter)
1777         {
1778                 self.teambubbleentity = spawn();
1779                 self.teambubbleentity.owner = self;
1780                 self.teambubbleentity.exteriormodeltoclient = self;
1781                 self.teambubbleentity.think = TeamBubbleThink;
1782                 self.teambubbleentity.nextthink = time;
1783                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1784 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1785                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1786                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1787                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1788                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1789                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1790                 self.teambubbleentity.effects = EF_LOWPRECISION;
1791         }
1792 }
1793
1794 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1795 // added to the model skins
1796 /*void UpdateColorModHack()
1797 {
1798         local float c;
1799         c = self.clientcolors & 15;
1800         // LordHavoc: only bothering to support white, green, red, yellow, blue
1801              if (!teams_matter) self.colormod = '0 0 0';
1802         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1803         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1804         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1805         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1806         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1807         else self.colormod = '1 1 1';
1808 };*/
1809
1810 .float oldcolormap;
1811 void respawn(void)
1812 {
1813         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1814         {
1815                 self.solid = SOLID_NOT;
1816                 self.takedamage = DAMAGE_NO;
1817                 self.movetype = MOVETYPE_FLY;
1818                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1819                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1820                 self.effects |= EF_ADDITIVE;
1821                 self.oldcolormap = self.colormap;
1822                 self.colormap = 512;
1823                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1824                 if(cvar("g_respawn_ghosts_maxtime"))
1825                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1826         }
1827
1828         CopyBody(1);
1829         self.effects |= EF_NODRAW; // prevent another CopyBody
1830         if(self.oldcolormap)
1831         {
1832                 self.colormap = self.oldcolormap;
1833                 self.oldcolormap = 0;
1834         }
1835         PutClientInServer();
1836 }
1837
1838 void play_countdown(float finished, string samp)
1839 {
1840         if(clienttype(self) == CLIENTTYPE_REAL)
1841                 if(floor(finished - time - frametime) != floor(finished - time))
1842                         if(finished - time < 6)
1843                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1844 }
1845
1846 /**
1847  * When sv_timeout is used this function returs strings like
1848  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1849  * Called by centerprint functions
1850  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1851  */
1852 string getTimeoutText(float addOneSecond) {
1853         if (!cvar("sv_timeout") || !timeoutStatus)
1854                 return "";
1855
1856         local string retStr;
1857         if (timeoutStatus == 1) {
1858                 if (addOneSecond == 1) {
1859                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1860                 }
1861                 else {
1862                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1863                 }
1864                 return retStr;
1865         }
1866         else if (timeoutStatus == 2) {
1867                 if (addOneSecond) {
1868                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1869                         //don't show messages like "Timeout ends in 0 seconds"...
1870                         if ((remainingTimeoutTime + 1) > 0)
1871                                 return retStr;
1872                         else
1873                                 return "";
1874                 }
1875                 else {
1876                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1877                         //don't show messages like "Timeout ends in 0 seconds"...
1878                         if (remainingTimeoutTime > 0)
1879                                 return retStr;
1880                         else
1881                                 return "";
1882                 }
1883         }
1884         else return "";
1885 }
1886
1887 void player_powerups (void)
1888 {
1889         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1890         {
1891                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1892                 self.modelflags |= MF_ROCKET;
1893         }
1894         else
1895         {
1896                 SoundEntity_StopSound(self, CHAN_PLAYER);
1897                 self.modelflags &~= MF_ROCKET;
1898         }
1899
1900         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1901
1902         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1903                 return;
1904
1905         Fire_ApplyDamage(self);
1906         Fire_ApplyEffect(self);
1907
1908         if (g_minstagib)
1909         {
1910                 self.effects |= EF_FULLBRIGHT;
1911
1912                 if (self.items & IT_STRENGTH)
1913                 {
1914                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1915                         if (time > self.strength_finished)
1916                         {
1917                                 self.alpha = default_player_alpha;
1918                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1919                                 self.items &~= IT_STRENGTH;
1920                                 sprint(self, "^3Invisibility has worn off\n");
1921                         }
1922                 }
1923                 else
1924                 {
1925                         if (time < self.strength_finished)
1926                         {
1927                                 self.alpha = g_minstagib_invis_alpha;
1928                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1929                                 self.items |= IT_STRENGTH;
1930                                 sprint(self, "^3You are invisible\n");
1931                         }
1932                 }
1933
1934                 if (self.items & IT_INVINCIBLE)
1935                 {
1936                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1937                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1938                         {
1939                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1940                                 sprint(self, "^3Speed has worn off\n");
1941                         }
1942                 }
1943                 else
1944                 {
1945                         if (time < self.invincible_finished)
1946                         {
1947                                 self.items = self.items | IT_INVINCIBLE;
1948                                 sprint(self, "^3You are on speed\n");
1949                         }
1950                 }
1951                 return;
1952         }
1953
1954         if (self.items & IT_STRENGTH)
1955         {
1956                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1957                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1958                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1959                 {
1960                         self.items = self.items - (self.items & IT_STRENGTH);
1961                         sprint(self, "^3Strength has worn off\n");
1962                 }
1963         }
1964         else
1965         {
1966                 if (time < self.strength_finished)
1967                 {
1968                         self.items = self.items | IT_STRENGTH;
1969                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1970                 }
1971         }
1972         if (self.items & IT_INVINCIBLE)
1973         {
1974                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1975                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1976                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1977                 {
1978                         self.items = self.items - (self.items & IT_INVINCIBLE);
1979                         sprint(self, "^3Shield has worn off\n");
1980                 }
1981         }
1982         else
1983         {
1984                 if (time < self.invincible_finished)
1985                 {
1986                         self.items = self.items | IT_INVINCIBLE;
1987                         sprint(self, "^3Shield surrounds you\n");
1988                 }
1989         }
1990
1991         if(cvar("g_nodepthtestplayers"))
1992                 self.effects = self.effects | EF_NODEPTHTEST;
1993
1994         if(cvar("g_fullbrightplayers"))
1995                 self.effects = self.effects | EF_FULLBRIGHT;
1996
1997         // midair gamemode: damage only while in the air
1998         // if in midair mode, being on ground grants temporary invulnerability
1999         // (this is so that multishot weapon don't clear the ground flag on the
2000         // first damage in the frame, leaving the player vulnerable to the
2001         // remaining hits in the same frame)
2002         if (self.flags & FL_ONGROUND)
2003         if (g_midair)
2004                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2005
2006         if (time >= game_starttime)
2007         if (time < self.spawnshieldtime)
2008                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2009 }
2010
2011 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2012 {
2013         if(current > stable)
2014                 return current;
2015         else if(current > stable - 0.25) // when close enough, "snap"
2016                 return stable;
2017         else
2018                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2019 }
2020
2021 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2022 {
2023         if(current < stable)
2024                 return current;
2025         else if(current < stable + 0.25) // when close enough, "snap"
2026                 return stable;
2027         else
2028                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2029 }
2030
2031 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2032 {
2033         if(current > rotstable)
2034         {
2035                 if(rotframetime > 0)
2036                 {
2037                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2038                         current = max(rotstable, current - rotlinear * rotframetime);
2039                 }
2040         }
2041         else if(current < regenstable)
2042         {
2043                 if(regenframetime > 0)
2044                 {
2045                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2046                         current = min(regenstable, current + regenlinear * regenframetime);
2047                 }
2048         }
2049
2050         if(current > limit)
2051                 current = limit;
2052
2053         return current;
2054 }
2055
2056 void player_regen (void)
2057 {
2058         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2059         maxh = cvar("g_balance_health_rotstable");
2060         maxa = cvar("g_balance_armor_rotstable");
2061         maxf = cvar("g_balance_fuel_rotstable");
2062         minh = cvar("g_balance_health_regenstable");
2063         mina = cvar("g_balance_armor_regenstable");
2064         minf = cvar("g_balance_fuel_regenstable");
2065         limith = cvar("g_balance_health_limit");
2066         limita = cvar("g_balance_armor_limit");
2067         limitf = cvar("g_balance_fuel_limit");
2068
2069         max_mod = regen_mod = rot_mod = limit_mod = 1;
2070
2071         if (self.runes & RUNE_REGEN)
2072         {
2073                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2074                 {
2075                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2076                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2077                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2078                 }
2079                 else
2080                 {
2081                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2082                         max_mod = cvar("g_balance_rune_regen_hpmod");
2083                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2084                 }
2085         }
2086         else if (self.runes & CURSE_VENOM)
2087         {
2088                 max_mod = cvar("g_balance_curse_venom_hpmod");
2089                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2090                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2091                 else
2092                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2093                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2094                 //if (!self.runes & RUNE_REGEN)
2095                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2096         }
2097         maxh = maxh * max_mod;
2098         //maxa = maxa * max_mod;
2099         //maxf = maxf * max_mod;
2100         minh = minh * max_mod;
2101         //mina = mina * max_mod;
2102         //minf = minf * max_mod;
2103         limith = limith * limit_mod;
2104         limita = limita * limit_mod;
2105         //limitf = limitf * limit_mod;
2106
2107         if(g_lms && g_ca)
2108                 rot_mod = 0;
2109
2110         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2111         {
2112                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2113                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2114
2115                 // if player rotted to death...  die!
2116                 if(self.health < 1)
2117                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2118         }
2119
2120         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2121                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2122 }
2123
2124 float zoomstate_set;
2125 void SetZoomState(float z)
2126 {
2127         if(z != self.zoomstate)
2128         {
2129                 self.zoomstate = z;
2130                 ClientData_Touch(self);
2131         }
2132         zoomstate_set = 1;
2133 }
2134
2135 void GetPressedKeys(void) {
2136         MUTATOR_CALLHOOK(GetPressedKeys);
2137         if (self.movement_x > 0) // get if movement keys are pressed
2138         {       // forward key pressed
2139                 self.pressedkeys |= KEY_FORWARD;
2140                 self.pressedkeys &~= KEY_BACKWARD;
2141         }
2142         else if (self.movement_x < 0)
2143         {       // backward key pressed
2144                 self.pressedkeys |= KEY_BACKWARD;
2145                 self.pressedkeys &~= KEY_FORWARD;
2146         }
2147         else
2148         {       // no x input
2149                 self.pressedkeys &~= KEY_FORWARD;
2150                 self.pressedkeys &~= KEY_BACKWARD;
2151         }
2152
2153         if (self.movement_y > 0)
2154         {       // right key pressed
2155                 self.pressedkeys |= KEY_RIGHT;
2156                 self.pressedkeys &~= KEY_LEFT;
2157         }
2158         else if (self.movement_y < 0)
2159         {       // left key pressed
2160                 self.pressedkeys |= KEY_LEFT;
2161                 self.pressedkeys &~= KEY_RIGHT;
2162         }
2163         else
2164         {       // no y input
2165                 self.pressedkeys &~= KEY_RIGHT;
2166                 self.pressedkeys &~= KEY_LEFT;
2167         }
2168
2169         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2170                 self.pressedkeys |= KEY_JUMP;
2171         else
2172                 self.pressedkeys &~= KEY_JUMP;
2173         if (self.BUTTON_CROUCH)
2174                 self.pressedkeys |= KEY_CROUCH;
2175         else
2176                 self.pressedkeys &~= KEY_CROUCH;
2177 }
2178
2179 void update_stats (float number, float hit, float fired) {
2180 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2181 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2182
2183         if(number) {
2184                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2185                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2186         } else {
2187                 self.stat_hit = hit * sv_accuracy_data_share;
2188                 self.stat_fired = fired * sv_accuracy_data_share;
2189         }
2190 }
2191
2192 /*
2193 ======================
2194 spectate mode routines
2195 ======================
2196 */
2197
2198 .float weapon_count;
2199 void SpectateCopy(entity spectatee) {
2200         if(spectatee.weapon_count < WEP_LAST) {
2201                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2202                 spectatee.weapon_count ++;
2203         } else
2204                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2205
2206         other = spectatee;
2207         MUTATOR_CALLHOOK(SpectateCopy);
2208         self.armortype = spectatee.armortype;
2209         self.armorvalue = spectatee.armorvalue;
2210         self.ammo_cells = spectatee.ammo_cells;
2211         self.ammo_shells = spectatee.ammo_shells;
2212         self.ammo_nails = spectatee.ammo_nails;
2213         self.ammo_rockets = spectatee.ammo_rockets;
2214         self.ammo_fuel = spectatee.ammo_fuel;
2215         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2216         self.health = spectatee.health;
2217         self.impulse = 0;
2218         self.items = spectatee.items;
2219         self.metertime = spectatee.metertime;
2220         self.strength_finished = spectatee.strength_finished;
2221         self.invincible_finished = spectatee.invincible_finished;
2222         self.pressedkeys = spectatee.pressedkeys;
2223         self.weapons = spectatee.weapons;
2224         self.switchweapon = spectatee.switchweapon;
2225         self.weapon = spectatee.weapon;
2226         self.punchangle = spectatee.punchangle;
2227         self.view_ofs = spectatee.view_ofs;
2228         self.v_angle = spectatee.v_angle;
2229         self.velocity = spectatee.velocity;
2230         self.dmg_take = spectatee.dmg_take;
2231         self.dmg_save = spectatee.dmg_save;
2232         self.dmg_inflictor = spectatee.dmg_inflictor;
2233         self.angles = spectatee.v_angle;
2234         self.fixangle = TRUE;
2235         setorigin(self, spectatee.origin);
2236         setsize(self, spectatee.mins, spectatee.maxs);
2237         SetZoomState(spectatee.zoomstate);
2238
2239         anticheat_spectatecopy(spectatee);
2240 }
2241
2242 float SpectateUpdate() {
2243         if(!self.enemy)
2244                 return 0;
2245
2246         if (self == self.enemy)
2247                 return 0;
2248
2249         if(self.enemy.classname != "player")
2250                 return 0;
2251
2252         SpectateCopy(self.enemy);
2253
2254         return 1;
2255 }
2256
2257 float SpectateNext() {
2258         other = find(self.enemy, classname, "player");
2259
2260         if (!other)
2261                 other = find(other, classname, "player");
2262
2263         if (other)
2264                 self.enemy = other;
2265
2266         if(self.enemy.classname == "player") {
2267                 msg_entity = self;
2268                 WriteByte(MSG_ONE, SVC_SETVIEW);
2269                 WriteEntity(MSG_ONE, self.enemy);
2270                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2271                 self.movetype = MOVETYPE_NONE;
2272
2273                 self.enemy.weapon_count = 0;
2274
2275                 if(!SpectateUpdate())
2276                         PutObserverInServer();
2277
2278                 return 1;
2279         } else {
2280                 return 0;
2281         }
2282 }
2283
2284 /*
2285 =============
2286 ShowRespawnCountdown()
2287
2288 Update a respawn countdown display.
2289 =============
2290 */
2291 void ShowRespawnCountdown()
2292 {
2293         float number;
2294         if(self.deadflag == DEAD_NO) // just respawned?
2295                 return;
2296         else
2297         {
2298                 number = ceil(self.death_time - time);
2299                 if(number <= 0)
2300                         return;
2301                 if(number <= self.respawn_countdown)
2302                 {
2303                         self.respawn_countdown = number - 1;
2304                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2305                                 AnnounceTo(self, strcat(ftos(number), ""));
2306                 }
2307         }
2308 }
2309
2310 void LeaveSpectatorMode()
2311 {
2312         if(isJoinAllowed()) {
2313                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2314                         self.classname = "player";
2315
2316                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2317                                 JoinBestTeam(self, FALSE, TRUE);
2318
2319                         if(cvar("g_campaign"))
2320                                 campaign_bots_may_start = 1;
2321
2322                         self.stat_count = WEP_LAST;
2323
2324                         PutClientInServer();
2325
2326                         if(self.classname == "player")
2327                                 bprint ("^4", self.netname, "^4 is playing now\n");
2328
2329                         if(!cvar("g_campaign"))
2330                                 centerprint(self,""); // clear MOTD
2331
2332                         return;
2333                 } else {
2334                         if (g_ca && self.caplayer) {
2335                         }       // do nothing
2336                         else
2337                                 stuffcmd(self,"menu_showteamselect\n");
2338                         return;
2339                 }
2340         }
2341         else {
2342                 //player may not join because of g_maxplayers is set
2343                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2344         }
2345 }
2346
2347 /**
2348  * Determines whether the player is allowed to join. This depends on cvar
2349  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2350  * it checks whether the number of currently playing players exceeds g_maxplayers.
2351  * @return bool TRUE if the player is allowed to join, false otherwise
2352  */
2353 float isJoinAllowed() {
2354         if (!cvar("g_maxplayers"))
2355                 return TRUE;
2356
2357         local entity e;
2358         local float currentlyPlaying;
2359         FOR_EACH_REALPLAYER(e) {
2360                 if(e.classname == "player")
2361                         currentlyPlaying += 1;
2362         }
2363         if(currentlyPlaying < cvar("g_maxplayers"))
2364                 return TRUE;
2365
2366         return FALSE;
2367 }
2368
2369 /**
2370  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2371  * g_maxplayers_spectator_blocktime seconds
2372  */
2373 void checkSpectatorBlock() {
2374         if(self.classname == "spectator" || self.classname == "observer") {
2375                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2376                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2377                         dropclient(self);
2378                 }
2379         }
2380 }
2381
2382 float vercmp_recursive(string v1, string v2)
2383 {
2384         float dot1, dot2;
2385         string s1, s2;
2386         float r;
2387
2388         dot1 = strstrofs(v1, ".", 0);
2389         dot2 = strstrofs(v2, ".", 0);
2390         if(dot1 == -1)
2391                 s1 = v1;
2392         else
2393                 s1 = substring(v1, 0, dot1);
2394         if(dot2 == -1)
2395                 s2 = v2;
2396         else
2397                 s2 = substring(v2, 0, dot2);
2398
2399         r = stof(s1) - stof(s2);
2400         if(r != 0)
2401                 return r;
2402
2403         r = strcasecmp(s1, s2);
2404         if(r != 0)
2405                 return r;
2406
2407         if(dot1 == -1)
2408                 if(dot2 == -1)
2409                         return 0;
2410                 else
2411                         return -1;
2412         else
2413                 if(dot2 == -1)
2414                         return 1;
2415                 else
2416                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2417 }
2418
2419 float vercmp(string v1, string v2)
2420 {
2421         if(strcasecmp(v1, v2) == 0) // early out check
2422                 return 0;
2423         return vercmp_recursive(v1, v2);
2424 }
2425
2426 void ObserverThink()
2427 {
2428         if (self.flags & FL_JUMPRELEASED) {
2429                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2430                         self.welcomemessage_time = 0;
2431                         self.flags &~= FL_JUMPRELEASED;
2432                         self.flags |= FL_SPAWNING;
2433                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2434                         self.welcomemessage_time = 0;
2435                         self.flags &~= FL_JUMPRELEASED;
2436                         if(SpectateNext() == 1) {
2437                                 self.classname = "spectator";
2438                         }
2439                 }
2440         } else {
2441                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2442                         self.flags |= FL_JUMPRELEASED;
2443                         if(self.flags & FL_SPAWNING)
2444                         {
2445                                 self.flags &~= FL_SPAWNING;
2446                                 LeaveSpectatorMode();
2447                                 return;
2448                         }
2449                 }
2450         }
2451         PrintWelcomeMessage(self);
2452 }
2453
2454 void SpectatorThink()
2455 {
2456         if (self.flags & FL_JUMPRELEASED) {
2457                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2458                         self.welcomemessage_time = 0;
2459                         self.flags &~= FL_JUMPRELEASED;
2460                         self.flags |= FL_SPAWNING;
2461                 } else if(self.BUTTON_ATCK) {
2462                         self.welcomemessage_time = 0;
2463                         self.flags &~= FL_JUMPRELEASED;
2464                         if(SpectateNext() == 1) {
2465                                 self.classname = "spectator";
2466                         } else {
2467                                 self.classname = "observer";
2468                                 self.stat_count = WEP_LAST;
2469                                 PutClientInServer();
2470                         }
2471                 } else if (self.BUTTON_ATCK2) {
2472                         self.welcomemessage_time = 0;
2473                         self.flags &~= FL_JUMPRELEASED;
2474                         self.classname = "observer";
2475                         self.stat_count = WEP_LAST;
2476                         PutClientInServer();
2477                 } else {
2478                         if(!SpectateUpdate())
2479                                 PutObserverInServer();
2480                 }
2481         } else {
2482                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2483                         self.flags |= FL_JUMPRELEASED;
2484                         if(self.flags & FL_SPAWNING)
2485                         {
2486                                 self.flags &~= FL_SPAWNING;
2487                                 LeaveSpectatorMode();
2488                                 return;
2489                         }
2490                 }
2491         }
2492
2493         PrintWelcomeMessage(self);
2494         self.flags |= FL_CLIENT | FL_NOTARGET;
2495 }
2496
2497 .float touchexplode_time;
2498
2499 /*
2500 =============
2501 PlayerPreThink
2502
2503 Called every frame for each client before the physics are run
2504 =============
2505 */
2506 void() ctf_setstatus;
2507 void() nexball_setstatus;
2508 .float items_added;
2509 void PlayerPreThink (void)
2510 {
2511         self.stat_game_starttime = game_starttime;
2512         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2513         self.stat_leadlimit = cvar("leadlimit");
2514
2515         if(frametime)
2516         {
2517                 // physics frames: update anticheat stuff
2518                 anticheat_prethink();
2519         }
2520
2521         if(blockSpectators && frametime)
2522                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2523                 checkSpectatorBlock();
2524
2525         zoomstate_set = 0;
2526
2527         if(self.netname_previous != self.netname)
2528         {
2529                 if(cvar("sv_eventlog"))
2530                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2531                 if(self.netname_previous)
2532                         strunzone(self.netname_previous);
2533                 self.netname_previous = strzone(self.netname);
2534         }
2535
2536         // version nagging
2537         if(self.version_nagtime)
2538                 if(self.cvar_g_xonoticversion)
2539                         if(time > self.version_nagtime)
2540                         {
2541                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2542                                 {
2543                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2544                                         {
2545                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2546                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2547                                         }
2548                                         else
2549                                         {
2550                                                 float r;
2551                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2552                                                 if(r < 0)
2553                                                 {
2554                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2555                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2556                                                 }
2557                                                 else if(r > 0)
2558                                                 {
2559                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2560                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2561                                                 }
2562                                         }
2563                                 }
2564                                 self.version_nagtime = 0;
2565                         }
2566
2567         // GOD MODE info
2568         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2569         {
2570                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2571                 self.max_armorvalue = 0;
2572         }
2573
2574 #ifdef TETRIS
2575         if (TetrisPreFrame())
2576                 return;
2577 #endif
2578
2579         MUTATOR_CALLHOOK(PlayerPreThink);
2580
2581         if(self.classname == "player") {
2582 //              if(self.netname == "Wazat")
2583 //                      bprint(self.classname, "\n");
2584
2585                 CheckRules_Player();
2586
2587                 PrintWelcomeMessage(self);
2588
2589                 if (intermission_running)
2590                 {
2591                         IntermissionThink ();   // otherwise a button could be missed between
2592                         return;                                 // the think tics
2593                 }
2594
2595                 if(self.teleport_time)
2596                 if(time > self.teleport_time)
2597                 {
2598                         self.teleport_time = 0;
2599                         self.effects = self.effects - (self.effects & EF_NODRAW);
2600                 }
2601
2602                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2603                         UpdateSelectedPlayer();
2604
2605                 //don't allow the player to turn around while game is paused!
2606                 if(timeoutStatus == 2) {
2607                         self.v_angle = self.lastV_angle;
2608                         self.angles = self.lastV_angle;
2609                         self.fixangle = TRUE;
2610                 }
2611
2612                 if(frametime)
2613                 {
2614                         if(self.health <= 0 && cvar("g_deathglow"))
2615                         {
2616                                 if(self.glowmod_x > 0)
2617                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2618                                 else
2619                                         self.glowmod_x = -1;
2620                                 if(self.glowmod_y > 0)
2621                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2622                                 else
2623                                         self.glowmod_y = -1;
2624                                 if(self.glowmod_z > 0)
2625                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2626                                 else
2627                                         self.glowmod_z = -1;
2628                         }
2629                         else
2630                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2631                         player_powerups();
2632                 }
2633
2634                 if (self.deadflag != DEAD_NO)
2635                 {
2636                         float button_pressed, force_respawn;
2637                         if(self.personal && g_race_qualifying)
2638                         {
2639                                 if(time > self.death_time)
2640                                 {
2641                                         self.death_time = time + 1; // only retry once a second
2642                                         respawn();
2643                                         self.impulse = 141;
2644                                 }
2645                         }
2646                         else
2647                         {
2648                                 if(frametime)
2649                                         player_anim();
2650                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2651                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2652                                 if (self.deadflag == DEAD_DYING)
2653                                 {
2654                                         if(force_respawn)
2655                                                 self.deadflag = DEAD_RESPAWNING;
2656                                         else if(!button_pressed)
2657                                                 self.deadflag = DEAD_DEAD;
2658                                 }
2659                                 else if (self.deadflag == DEAD_DEAD)
2660                                 {
2661                                         if(button_pressed)
2662                                                 self.deadflag = DEAD_RESPAWNABLE;
2663                                 }
2664                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2665                                 {
2666                                         if(!button_pressed)
2667                                                 self.deadflag = DEAD_RESPAWNING;
2668                                 }
2669                                 else if (self.deadflag == DEAD_RESPAWNING)
2670                                 {
2671                                         if(time > self.death_time)
2672                                         {
2673                                                 self.death_time = time + 1; // only retry once a second
2674                                                 respawn();
2675                                         }
2676                                 }
2677                                 ShowRespawnCountdown();
2678                         }
2679                         return;
2680                 }
2681
2682                 if(g_touchexplode)
2683                 if(time > self.touchexplode_time)
2684                 if(self.classname == "player")
2685                 if(self.deadflag == DEAD_NO)
2686                 if not(IS_INDEPENDENT_PLAYER(self))
2687                 FOR_EACH_PLAYER(other) if(self != other)
2688                 {
2689                         if(time > other.touchexplode_time)
2690                         if(other.deadflag == DEAD_NO)
2691                         if not(IS_INDEPENDENT_PLAYER(other))
2692                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2693                         {
2694                                 PlayerTouchExplode(self, other);
2695                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2696                         }
2697                 }
2698
2699                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2700                 {
2701                         vector dist;
2702
2703                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2704                         dist = self.prevorigin - self.origin;
2705                         dist_z = 0;
2706                         self.lms_traveled_distance += fabs(vlen(dist));
2707
2708                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2709                         {
2710                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2711                                 self.lms_traveled_distance = 0;
2712                         }
2713
2714                         if(time > self.lms_nextcheck)
2715                         {
2716                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2717                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2718                                 {
2719                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2720                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2721                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2722                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2723                                 }
2724                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2725                                 self.lms_traveled_distance = 0;
2726                         }
2727                 }
2728
2729                 self.prevorigin = self.origin;
2730
2731                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2732                 {
2733                         if (!self.crouch)
2734                         {
2735                                 self.crouch = TRUE;
2736                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2737                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2738                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2739                         }
2740                 }
2741                 else
2742                 {
2743                         if (self.crouch)
2744                         {
2745                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2746                                 if (!trace_startsolid)
2747                                 {
2748                                         self.crouch = FALSE;
2749                                         self.view_ofs = PL_VIEW_OFS;
2750                                         setsize (self, PL_MIN, PL_MAX);
2751                                 }
2752                         }
2753                 }
2754
2755                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2756                 {
2757                         if(self.bloodloss_timer < time)
2758                         {
2759                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2760                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2761                         }
2762                 }
2763
2764                 FixPlayermodel();
2765
2766                 GrapplingHookFrame();
2767
2768                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2769                 //if(frametime)
2770                 {
2771                         self.items &~= self.items_added;
2772
2773                         W_WeaponFrame();
2774
2775                         self.items_added = 0;
2776                         if(self.items & IT_JETPACK)
2777                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2778                                         self.items_added |= IT_FUEL;
2779
2780                         self.items |= self.items_added;
2781                 }
2782
2783                 player_regen();
2784                 if(frametime)
2785                         player_anim();
2786
2787                 if (g_minstagib)
2788                         minstagib_ammocheck();
2789
2790                 ctf_setstatus();
2791                 nexball_setstatus();
2792
2793                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2794
2795                 //self.angles_y=self.v_angle_y + 90;   // temp
2796         } else if(gameover) {
2797                 if (intermission_running)
2798                         IntermissionThink ();   // otherwise a button could be missed between
2799                 return;
2800         } else if(self.classname == "observer") {
2801                 ObserverThink();
2802         } else if(self.classname == "spectator") {
2803                 SpectatorThink();
2804         }
2805
2806         if(!zoomstate_set)
2807                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2808
2809         float oldspectatee_status;
2810         oldspectatee_status = self.spectatee_status;
2811         if(self.classname == "spectator")
2812                 self.spectatee_status = num_for_edict(self.enemy);
2813         else if(self.classname == "observer")
2814                 self.spectatee_status = num_for_edict(self);
2815         else
2816                 self.spectatee_status = 0;
2817         if(self.spectatee_status != oldspectatee_status)
2818         {
2819                 ClientData_Touch(self);
2820                 if(g_race || g_cts)
2821                         race_InitSpectator();
2822         }
2823
2824         if(self.teamkill_soundtime)
2825         if(time > self.teamkill_soundtime)
2826         {
2827                 self.teamkill_soundtime = 0;
2828
2829                 entity oldpusher, oldself;
2830
2831                 oldself = self; self = self.teamkill_soundsource;
2832                 oldpusher = self.pusher; self.pusher = oldself;
2833
2834                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2835
2836                 self.pusher = oldpusher;
2837                 self = oldself;
2838         }
2839
2840         if(self.taunt_soundtime)
2841         if(time > self.taunt_soundtime)
2842         {
2843                 self.taunt_soundtime = 0;
2844                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2845         }
2846
2847         target_voicescript_next(self);
2848 }
2849
2850 float isInvisibleString(string s)
2851 {
2852         float i, n, c;
2853         s = strdecolorize(s);
2854         for((i = 0), (n = strlen(s)); i < n; ++i)
2855         {
2856                 c = str2chr(s, i);
2857                 switch(c)
2858                 {
2859                         case 0:
2860                         case 32: // space
2861                                 break;
2862                         case 192: // charmap space
2863                                 if (!cvar("utf8_enable"))
2864                                         break;
2865                                 return FALSE;
2866                         case 160: // space in unicode fonts
2867                         case 0xE000 + 192: // utf8 charmap space
2868                                 if (cvar("utf8_enable"))
2869                                         break;
2870                         default:
2871                                 return FALSE;
2872                 }
2873         }
2874         return TRUE;
2875 }
2876
2877 /*
2878 =============
2879 PlayerPostThink
2880
2881 Called every frame for each client after the physics are run
2882 =============
2883 */
2884 .float idlekick_lasttimeleft;
2885 .entity showheadshotbbox;
2886 void showheadshotbbox_think()
2887 {
2888         if(self.owner.showheadshotbbox != self)
2889         {
2890                 remove(self);
2891                 return;
2892         }
2893         self.nextthink = time;
2894         setorigin(self, self.owner.origin);
2895         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2896 }
2897 void PlayerPostThink (void)
2898 {
2899         // Savage: Check for nameless players
2900         if (isInvisibleString(self.netname)) {
2901                 self.netname = "Player";
2902                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2903         }
2904
2905         // send the clients accuracy stats to the client
2906         if(self.stat_count > 0)
2907         if(frametime)
2908         {
2909                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2910                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2911                 self.stat_count -= 1;
2912         }
2913
2914         if(sv_maxidle && frametime)
2915         {
2916                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2917                 float timeleft;
2918                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2919                 if(timeleft <= 0)
2920                 {
2921                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2922                         AnnounceTo(self, "terminated");
2923                         dropclient(self);
2924                         return;
2925                 }
2926                 else if(timeleft <= 10)
2927                 {
2928                         if(timeleft != self.idlekick_lasttimeleft)
2929                         {
2930                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2931                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2932                         }
2933                 }
2934                 else
2935                 {
2936                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2937                 }
2938                 self.idlekick_lasttimeleft = timeleft;
2939         }
2940
2941 #ifdef TETRIS
2942         if(self.impulse == 100)
2943                 ImpulseCommands();
2944         if (TetrisPostFrame())
2945                 return;
2946 #endif
2947
2948         CheatFrame();
2949
2950         if(self.classname == "player") {
2951                 CheckRules_Player();
2952                 UpdateChatBubble();
2953                 UpdateTeamBubble();
2954                 if (self.impulse)
2955                         ImpulseCommands();
2956                 if (intermission_running)
2957                         return;         // intermission or finale
2958                 GetPressedKeys();
2959         } else if (self.classname == "observer") {
2960                 //do nothing
2961         } else if (self.classname == "spectator") {
2962                 //do nothing
2963         }
2964
2965         /*
2966         float i;
2967         for(i = 0; i < 1000; ++i)
2968         {
2969                 vector end;
2970                 end = self.origin + '0 0 1024' + 512 * randomvec();
2971                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2972                 if(trace_fraction < 1)
2973                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2974                 {
2975                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2976                         break;
2977                 }
2978         }
2979         */
2980
2981         Arena_Warmup();
2982
2983         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2984
2985         if(self.waypointsprite_attachedforcarrier)
2986                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2987
2988         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
2989         {
2990                 if(!self.showheadshotbbox)
2991                 {
2992                         self.showheadshotbbox = spawn();
2993                         self.showheadshotbbox.classname = "headshotbbox";
2994                         self.showheadshotbbox.owner = self;
2995                         self.showheadshotbbox.think = showheadshotbbox_think;
2996                         self.showheadshotbbox.nextthink = time;
2997                         self = self.showheadshotbbox;
2998                         self.think();
2999                         self = self.owner;
3000                 }
3001         }
3002         else
3003         {
3004                 if(self.showheadshotbbox)
3005                         remove(self.showheadshotbbox);
3006         }
3007
3008         playerdemo_write();
3009
3010         /*
3011         if(g_race)
3012                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3013         */
3014 }