qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 if(!inWarmupStage)
 414                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419                 vehicles_exit(VHEF_RELESE);
 420
 421         WaypointSprite_PlayerDead();
 422
 423         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 424                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 425
 426         if(self.killcount != -666) {
 427                 if(g_lms) {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 429                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 430                         else
 431                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 432                 } else
 433                         bprint ("^4", self.netname, "^4 is spectating now\n");
 434
 435                 if(self.just_joined == FALSE) {
 436                         LogTeamchange(self.playerid, -1, 4);
 437                 } else
 438                         self.just_joined = FALSE;
 439         }
 440
 441         PlayerScore_Clear(self); // clear scores when needed
 442
 443         accuracy_resend(self);
 444
 445         self.spectatortime = time;
 446
 447         self.classname = "observer";
 448         self.iscreature = FALSE;
 449         self.teleportable = TELEPORT_SIMPLE;
 450         self.damagedbycontents = FALSE;
 451         self.health = -666;
 452         self.takedamage = DAMAGE_NO;
 453         self.solid = SOLID_NOT;
 454         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 455         self.flags = FL_CLIENT | FL_NOTARGET;
 456         self.armorvalue = 666;
 457         self.effects = 0;
 458         self.armorvalue = autocvar_g_balance_armor_start;
 459         self.pauserotarmor_finished = 0;
 460         self.pauserothealth_finished = 0;
 461         self.pauseregen_finished = 0;
 462         self.damageforcescale = 0;
 463         self.death_time = 0;
 464         self.respawn_time = 0;
 465         self.alpha = 0;
 466         self.scale = 0;
 467         self.fade_time = 0;
 468         self.pain_frame = 0;
 469         self.pain_finished = 0;
 470         self.strength_finished = 0;
 471         self.invincible_finished = 0;
 472         self.superweapons_finished = 0;
 473         self.pushltime = 0;
 474         self.istypefrag = 0;
 475         self.think = func_null;
 476         self.nextthink = 0;
 477         self.hook_time = 0;
 478         self.runes = 0;
 479         self.deadflag = DEAD_NO;
 480         self.angles = spot.angles;
 481         self.angles_z = 0;
 482         self.fixangle = TRUE;
 483         self.crouch = FALSE;
 484
 485         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 486         self.prevorigin = self.origin;
 487         self.items = 0;
 488         WEPSET_CLEAR_E(self);
 489         self.model = "";
 490         FixPlayermodel();
 491         setmodel(self, "null");
 492         self.drawonlytoclient = self;
 493
 494         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 495         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 496
 497         self.weapon = 0;
 498         self.weaponname = "";
 499         self.switchingweapon = 0;
 500         self.weaponmodel = "";
 501         self.weaponentity = world;
 502         self.exteriorweaponentity = world;
 503         self.killcount = -666;
 504         self.velocity = '0 0 0';
 505         self.avelocity = '0 0 0';
 506         self.punchangle = '0 0 0';
 507         self.punchvector = '0 0 0';
 508         self.oldvelocity = self.velocity;
 509         self.fire_endtime = -1;
 510
 511         if(g_arena)
 512         {
 513                 if(self.version_mismatch)
 514                 {
 515                         self.frags = FRAGS_SPECTATOR;
 516                         Spawnqueue_Unmark(self);
 517                         Spawnqueue_Remove(self);
 518                 }
 519                 else
 520                 {
 521                         self.frags = FRAGS_LMS_LOSER;
 522                         Spawnqueue_Insert(self);
 523                 }
 524         }
 525         else if(g_lms)
 526         {
 527                 // Only if the player cannot play at all
 528                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 529                         self.frags = FRAGS_SPECTATOR;
 530                 else
 531                         self.frags = FRAGS_LMS_LOSER;
 532         }
 533         else if(g_ca)
 534         {
 535                 if(self.caplayer)
 536                         self.frags = FRAGS_LMS_LOSER;
 537                 else
 538                         self.frags = FRAGS_SPECTATOR;
 539         }
 540         else if((g_race && g_race_qualifying) || g_cts)
 541         {
 542                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 543                         self.frags = FRAGS_LMS_LOSER;
 544                 else
 545                         self.frags = FRAGS_SPECTATOR;
 546         }
 547         else
 548                 self.frags = FRAGS_SPECTATOR;
 549 }
 550
 551 .float model_randomizer;
 552 void FixPlayermodel()
 553 {
 554         string defaultmodel;
 555         float defaultskin, chmdl, oldskin, n, i;
 556         vector m1, m2;
 557
 558         defaultmodel = "";
 559         defaultskin = 0;
 560         chmdl = FALSE;
 561
 562         if(autocvar_sv_defaultcharacter == 1)
 563         {
 564                 if(teamplay)
 565                 {
 566                         string s;
 567                         s = Team_ColorName_Lower(self.team);
 568                         if(s != "neutral")
 569                         {
 570                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 571                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 572                         }
 573                 }
 574
 575                 if(defaultmodel == "")
 576                 {
 577                         defaultmodel = autocvar_sv_defaultplayermodel;
 578                         defaultskin = autocvar_sv_defaultplayerskin;
 579                 }
 580
 581                 n = tokenize_console(defaultmodel);
 582                 if(n > 0)
 583                         defaultmodel = argv(floor(n * self.model_randomizer));
 584
 585                 i = strstrofs(defaultmodel, ":", 0);
 586                 if(i >= 0)
 587                 {
 588                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 589                         defaultmodel = substring(defaultmodel, 0, i);
 590                 }
 591         }
 592
 593         if(defaultmodel != "")
 594         {
 595                 if (defaultmodel != self.model)
 596                 {
 597                         m1 = self.mins;
 598                         m2 = self.maxs;
 599                         setplayermodel (self, defaultmodel);
 600                         setsize (self, m1, m2);
 601                         chmdl = TRUE;
 602                 }
 603
 604                 oldskin = self.skin;
 605                 self.skin = defaultskin;
 606         } else {
 607                 if (self.playermodel != self.model || self.playermodel == "")
 608                 {
 609                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 610                         m1 = self.mins;
 611                         m2 = self.maxs;
 612                         setplayermodel (self, self.playermodel);
 613                         setsize (self, m1, m2);
 614                         chmdl = TRUE;
 615                 }
 616
 617                 oldskin = self.skin;
 618                 self.skin = stof(self.playerskin);
 619         }
 620
 621         if(chmdl || oldskin != self.skin)
 622                 self.species = player_getspecies(); // model or skin has changed
 623
 624         if(!teamplay)
 625                 if(strlen(autocvar_sv_defaultplayercolors))
 626                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 627                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 628 }
 629
 630 void PlayerTouchExplode(entity p1, entity p2)
 631 {
 632         vector org;
 633         org = (p1.origin + p2.origin) * 0.5;
 634         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 635
 636         te_explosion(org);
 637
 638         entity e;
 639         e = spawn();
 640         setorigin(e, org);
 641         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 642         remove(e);
 643 }
 644
 645 /*
 646 =============
 647 PutClientInServer
 648
 649 Called when a client spawns in the server
 650 =============
 651 */
 652
 653 void PutClientInServer (void)
 654 {
 655         if(clienttype(self) == CLIENTTYPE_BOT)
 656         {
 657                 self.classname = "player";
 658                 if(g_ca)
 659                         self.caplayer = 1;
 660         }
 661         else if(clienttype(self) == CLIENTTYPE_REAL)
 662         {
 663                 msg_entity = self;
 664                 WriteByte(MSG_ONE, SVC_SETVIEW);
 665                 WriteEntity(MSG_ONE, self);
 666         }
 667
 668         // reset player keys
 669         self.itemkeys = 0;
 670
 671         // player is dead and becomes observer
 672         // FIXME fix LMS scoring for new system
 673         if(g_lms)
 674         {
 675                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 676                         self.classname = "observer";
 677         }
 678
 679         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 680                 self.classname = "observer";
 681
 682         if(gameover)
 683                 self.classname = "observer";
 684
 685         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 686                 entity spot, oldself;
 687                 float j;
 688
 689                 accuracy_resend(self);
 690
 691                 if(self.team < 0)
 692                         JoinBestTeam(self, FALSE, TRUE);
 693
 694                 race_PreSpawn();
 695
 696                 spot = SelectSpawnPoint (FALSE);
 697                 if(!spot)
 698                 {
 699                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 700                         return; // spawn failed
 701                 }
 702
 703                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 704
 705                 self.classname = "player";
 706                 self.wasplayer = TRUE;
 707                 self.iscreature = TRUE;
 708                 self.teleportable = TELEPORT_NORMAL;
 709                 self.damagedbycontents = TRUE;
 710                 self.movetype = MOVETYPE_WALK;
 711                 self.solid = SOLID_SLIDEBOX;
 712                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 713                 if(autocvar_g_playerclip_collisions)
 714                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 715                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 716                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 717                 self.frags = FRAGS_PLAYER;
 718                 if(INDEPENDENT_PLAYERS)
 719                         MAKE_INDEPENDENT_PLAYER(self);
 720                 self.flags = FL_CLIENT;
 721                 if(autocvar__notarget)
 722                         self.flags |= FL_NOTARGET;
 723                 self.takedamage = DAMAGE_AIM;
 724                 if(g_minstagib)
 725                         self.effects = EF_FULLBRIGHT;
 726                 else
 727                         self.effects = 0;
 728                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 729                 self.air_finished = time + 12;
 730                 self.dmg = 2;
 731                 if(autocvar_g_balance_nex_charge)
 732                 {
 733                         if(autocvar_g_balance_nex_secondary_chargepool)
 734                                 self.nex_chargepool_ammo = 1;
 735                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 736                 }
 737
 738                 if(inWarmupStage)
 739                 {
 740                         self.ammo_shells = warmup_start_ammo_shells;
 741                         self.ammo_nails = warmup_start_ammo_nails;
 742                         self.ammo_rockets = warmup_start_ammo_rockets;
 743                         self.ammo_cells = warmup_start_ammo_cells;
 744                         self.ammo_fuel = warmup_start_ammo_fuel;
 745                         self.health = warmup_start_health;
 746                         self.armorvalue = warmup_start_armorvalue;
 747                         WEPSET_COPY_EA(self, warmup_start_weapons);
 748                 }
 749                 else
 750                 {
 751                         self.ammo_shells = start_ammo_shells;
 752                         self.ammo_nails = start_ammo_nails;
 753                         self.ammo_rockets = start_ammo_rockets;
 754                         self.ammo_cells = start_ammo_cells;
 755                         self.ammo_fuel = start_ammo_fuel;
 756                         self.health = start_health;
 757                         self.armorvalue = start_armorvalue;
 758                         WEPSET_COPY_EA(self, start_weapons);
 759                 }
 760
 761                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 762                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 763                 else
 764                         self.superweapons_finished = 0;
 765
 766                 if(g_weaponarena_random)
 767                 {
 768                         if(g_weaponarena_random_with_laser)
 769                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 770                         W_RandomWeapons(self, g_weaponarena_random);
 771                         if(g_weaponarena_random_with_laser)
 772                                 WEPSET_OR_EW(self, WEP_LASER);
 773                 }
 774
 775                 self.items = start_items;
 776
 777                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 778                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 779                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 780                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 781                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 782                 //extend the pause of rotting if client was reset at the beginning of the countdown
 783                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 784                         self.spawnshieldtime += game_starttime - time;
 785                         self.pauserotarmor_finished += game_starttime - time;
 786                         self.pauserothealth_finished += game_starttime - time;
 787                         self.pauseregen_finished += game_starttime - time;
 788                 }
 789                 self.damageforcescale = 2;
 790                 self.death_time = 0;
 791                 self.respawn_time = 0;
 792                 self.scale = 0;
 793                 self.fade_time = 0;
 794                 self.pain_frame = 0;
 795                 self.pain_finished = 0;
 796                 self.strength_finished = 0;
 797                 self.invincible_finished = 0;
 798                 self.pushltime = 0;
 799                 // players have no think function
 800                 self.think = func_null;
 801                 self.nextthink = 0;
 802                 self.hook_time = 0;
 803                 self.dmg_team = 0;
 804                 self.ballistics_density = autocvar_g_ballistics_density_player;
 805
 806                 self.metertime = 0;
 807
 808                 self.runes = 0;
 809
 810                 self.deadflag = DEAD_NO;
 811
 812                 self.angles = spot.angles;
 813
 814                 self.angles_z = 0; // never spawn tilted even if the spot says to
 815                 self.fixangle = TRUE; // turn this way immediately
 816                 self.velocity = '0 0 0';
 817                 self.avelocity = '0 0 0';
 818                 self.punchangle = '0 0 0';
 819                 self.punchvector = '0 0 0';
 820                 self.oldvelocity = self.velocity;
 821                 self.fire_endtime = -1;
 822
 823                 msg_entity = self;
 824                 WRITESPECTATABLE_MSG_ONE({
 825                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 826                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 827                 });
 828
 829                 self.model = "";
 830                 FixPlayermodel();
 831                 self.drawonlytoclient = world;
 832
 833                 self.crouch = FALSE;
 834                 self.view_ofs = PL_VIEW_OFS;
 835                 setsize (self, PL_MIN, PL_MAX);
 836                 self.spawnorigin = spot.origin;
 837                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 838                 // don't reset back to last position, even if new position is stuck in solid
 839                 self.oldorigin = self.origin;
 840                 self.prevorigin = self.origin;
 841                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 842                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 843         self.hud = HUD_NORMAL;
 844
 845                 if(g_arena)
 846                 {
 847                         Spawnqueue_Remove(self);
 848                         Spawnqueue_Mark(self);
 849                 }
 850                 else if(g_ca)
 851                         self.caplayer = 1;
 852
 853                 self.event_damage = PlayerDamage;
 854
 855                 self.bot_attack = TRUE;
 856
 857                 self.statdraintime = time + 5;
 858                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 859
 860                 if(self.killcount == -666) {
 861                         PlayerScore_Clear(self);
 862                         self.killcount = 0;
 863                 }
 864
 865                 CL_SpawnWeaponentity();
 866                 self.alpha = default_player_alpha;
 867                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 868                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 869
 870                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 871                 self.lms_traveled_distance = 0;
 872                 self.speedrunning = FALSE;
 873
 874                 race_PostSpawn(spot);
 875
 876                 //stuffcmd(self, "chase_active 0");
 877                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 878
 879                 if(g_assault) {
 880                         if(self.team == assault_attacker_team)
 881                                 centerprint(self, "You are attacking!");
 882                         else
 883                                 centerprint(self, "You are defending!");
 884                 }
 885
 886                 target_voicescript_clear(self);
 887
 888                 // reset fields the weapons may use
 889                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 890                 {
 891                         weapon_action(j, WR_RESETPLAYER);
 892
 893                         // all weapons must be fully loaded when we spawn
 894                         entity e;
 895                         e = get_weaponinfo(j);
 896                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 897                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 898                 }
 899
 900                 oldself = self;
 901                 self = spot;
 902                         activator = oldself;
 903                                 string s;
 904                                 s = self.target;
 905                                 self.target = string_null;
 906                                 SUB_UseTargets();
 907                                 self.target = s;
 908                         activator = world;
 909                 self = oldself;
 910
 911                 spawn_spot = spot;
 912                 MUTATOR_CALLHOOK(PlayerSpawn);
 913
 914                 if(autocvar_spawn_debug)
 915                 {
 916                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 917                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 918                 }
 919
 920                 self.switchweapon = w_getbestweapon(self);
 921                 self.cnt = -1; // W_LastWeapon will not complain
 922                 self.weapon = 0;
 923                 self.weaponname = "";
 924                 self.switchingweapon = 0;
 925
 926                 if(!inWarmupStage)
 927                         if(!self.alivetime)
 928                                 self.alivetime = time;
 929
 930                 antilag_clear(self);
 931
 932                 if (autocvar_g_spawnsound)
 933                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 934         } else if(self.classname == "observer") {
 935                 PutObserverInServer ();
 936         }
 937 }
 938
 939 .float ebouncefactor, ebouncestop; // electro's values
 940 // TODO do we need all these fields, or should we stop autodetecting runtime
 941 // changes and just have a console command to update this?
 942 float ClientInit_SendEntity(entity to, float sf)
 943 {
 944         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 945         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 951         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 952         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 953         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 954         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 955         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 956         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 957         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 958         if(sv_foginterval && world.fog != "")
 959                 WriteString(MSG_ENTITY, world.fog);
 960         else
 961                 WriteString(MSG_ENTITY, "");
 962         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 963         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 964         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 965         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 966         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 967         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 968         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 969         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 970         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 971         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 972         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 973         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 974         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 975         return TRUE;
 976 }
 977
 978 void ClientInit_CheckUpdate()
 979 {
 980         self.nextthink = time;
 981         if(self.count != autocvar_g_balance_armor_blockpercent)
 982         {
 983                 self.count = autocvar_g_balance_armor_blockpercent;
 984                 self.SendFlags |= 1;
 985         }
 986         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 987         {
 988                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 989                 self.SendFlags |= 1;
 990         }
 991         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 992         {
 993                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 994                 self.SendFlags |= 1;
 995         }
 996         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 997         {
 998                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 999                 self.SendFlags |= 1;
1000         }
1001         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1002         {
1003                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1004                 self.SendFlags |= 1;
1005         }
1006         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1007         {
1008                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1009                 self.SendFlags |= 1;
1010         }
1011 }
1012
1013 void ClientInit_Spawn()
1014 {
1015         entity o;
1016         entity e;
1017         e = spawn();
1018         e.classname = "clientinit";
1019         e.think = ClientInit_CheckUpdate;
1020         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1021
1022         o = self;
1023         self = e;
1024         ClientInit_CheckUpdate();
1025         self = o;
1026 }
1027
1028 /*
1029 =============
1030 SetNewParms
1031 =============
1032 */
1033 void SetNewParms (void)
1034 {
1035         // initialize parms for a new player
1036         parm1 = -(86400 * 366);
1037 }
1038
1039 /*
1040 =============
1041 SetChangeParms
1042 =============
1043 */
1044 void SetChangeParms (void)
1045 {
1046         // save parms for level change
1047         parm1 = self.parm_idlesince - time;
1048 }
1049
1050 /*
1051 =============
1052 DecodeLevelParms
1053 =============
1054 */
1055 void DecodeLevelParms (void)
1056 {
1057         // load parms
1058         self.parm_idlesince = parm1;
1059         if(self.parm_idlesince == -(86400 * 366))
1060                 self.parm_idlesince = time;
1061
1062         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1063         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1064 }
1065
1066 /*
1067 =============
1068 ClientKill
1069
1070 Called when a client types 'kill' in the console
1071 =============
1072 */
1073
1074 .float clientkill_nexttime;
1075 void ClientKill_Now_TeamChange()
1076 {
1077         if(self.killindicator_teamchange == -1)
1078         {
1079                 JoinBestTeam( self, FALSE, TRUE );
1080         }
1081         else if(self.killindicator_teamchange == -2)
1082         {
1083                 if(g_ca)
1084                         self.caplayer = 0;
1085                 if(blockSpectators)
1086                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1087                 PutObserverInServer();
1088         }
1089         else
1090                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1091 }
1092
1093 void ClientKill_Now()
1094 {
1095         if(self.vehicle)
1096         {
1097             vehicles_exit(VHEF_RELESE);
1098             if(!self.killindicator_teamchange)
1099             {
1100             self.vehicle_health = -1;
1101             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1102             }
1103         }
1104
1105         if(self.killindicator && !wasfreed(self.killindicator))
1106                 remove(self.killindicator);
1107
1108         self.killindicator = world;
1109
1110         if(self.killindicator_teamchange)
1111                 ClientKill_Now_TeamChange();
1112
1113         // in any case:
1114         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1115
1116         // now I am sure the player IS dead
1117 }
1118 void KillIndicator_Think()
1119 {
1120         if (gameover)
1121         {
1122                 self.owner.killindicator = world;
1123                 remove(self);
1124                 return;
1125         }
1126
1127         if (self.owner.alpha < 0 && !self.owner.vehicle)
1128         {
1129                 self.owner.killindicator = world;
1130                 remove(self);
1131                 return;
1132         }
1133
1134         if(self.cnt <= 0)
1135         {
1136                 self = self.owner;
1137                 ClientKill_Now(); // no oldself needed
1138                 return;
1139         }
1140     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1141     {
1142         self.nextthink = time + 1;
1143         self.cnt -= 1;
1144     }
1145         else
1146         {
1147                 if(self.cnt <= 10)
1148                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1149                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1150                 {
1151                         if(self.cnt <= 10)
1152                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1153                 }
1154                 self.nextthink = time + 1;
1155                 self.cnt -= 1;
1156         }
1157 }
1158
1159 float clientkilltime;
1160 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1161 {
1162         float killtime;
1163         float starttime;
1164         entity e;
1165
1166         if (gameover)
1167                 return;
1168
1169         killtime = autocvar_g_balance_kill_delay;
1170
1171         if(g_race_qualifying || g_cts)
1172                 killtime = 0;
1173
1174     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1175     {
1176                 remove(self.killindicator);
1177                 self.killindicator = world;
1178
1179         ClientKill_Now(); // allow instant kill in this case
1180         return;
1181     }
1182
1183         self.killindicator_teamchange = targetteam;
1184
1185     if(!self.killindicator)
1186         {
1187                 if(self.deadflag == DEAD_NO)
1188                 {
1189                         killtime = max(killtime, self.clientkill_nexttime - time);
1190                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1191                 }
1192
1193                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1194                 {
1195                         ClientKill_Now();
1196                 }
1197                 else
1198                 {
1199                         starttime = max(time, clientkilltime);
1200
1201                         self.killindicator = spawn();
1202                         self.killindicator.owner = self;
1203                         self.killindicator.scale = 0.5;
1204                         setattachment(self.killindicator, self, "");
1205                         setorigin(self.killindicator, '0 0 52');
1206                         self.killindicator.think = KillIndicator_Think;
1207                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1208                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1209                         self.killindicator.cnt = ceil(killtime);
1210                         self.killindicator.count = bound(0, ceil(killtime), 10);
1211                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1212
1213                         for(e = world; (e = find(e, classname, "body")) != world; )
1214                         {
1215                                 if(e.enemy != self)
1216                                         continue;
1217                                 e.killindicator = spawn();
1218                                 e.killindicator.owner = e;
1219                                 e.killindicator.scale = 0.5;
1220                                 setattachment(e.killindicator, e, "");
1221                                 setorigin(e.killindicator, '0 0 52');
1222                                 e.killindicator.think = KillIndicator_Think;
1223                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1224                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1225                                 e.killindicator.cnt = ceil(killtime);
1226                         }
1227                         self.lip = 0;
1228                 }
1229         }
1230         if(self.killindicator)
1231         {
1232                 if(targetteam == 0) // just die
1233                 {
1234                         self.killindicator.colormod = '0 0 0';
1235                         if(clienttype(self) == CLIENTTYPE_REAL)
1236                         if(self.killindicator.cnt > 0)
1237                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1238                 }
1239                 else if(targetteam == -1) // auto
1240                 {
1241                         self.killindicator.colormod = '0 1 0';
1242                         if(clienttype(self) == CLIENTTYPE_REAL)
1243                         if(self.killindicator.cnt > 0)
1244                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1245                 }
1246                 else if(targetteam == -2) // spectate
1247                 {
1248                         self.killindicator.colormod = '0.5 0.5 0.5';
1249                         if(clienttype(self) == CLIENTTYPE_REAL)
1250                         if(self.killindicator.cnt > 0)
1251                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1252                 }
1253                 else
1254                 {
1255                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1256                         if(clienttype(self) == CLIENTTYPE_REAL)
1257                         if(self.killindicator.cnt > 0)
1258                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("^7Changing to ", Team_ColoredFullName(targetteam), "^7 in %d seconds"), 1, self.killindicator.cnt);
1259                 }
1260         }
1261
1262 }
1263
1264 void ClientKill (void)
1265 {
1266         if (gameover)
1267                 return;
1268
1269         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1270         {
1271                 // do nothing
1272         }
1273     else if(self.freezetag_frozen)
1274     {
1275         // do nothing
1276     }
1277         else
1278                 ClientKill_TeamChange(0);
1279 }
1280
1281 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1282 {
1283     e.killindicator = spawn();
1284     e.killindicator.owner = e;
1285     e.killindicator.think = KillIndicator_Think;
1286     e.killindicator.nextthink = time + (e.lip) * 0.05;
1287     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1288     e.killindicator.health = 1; // this is used to indicate that it should be silent
1289     e.lip = 0;
1290 }
1291
1292 void FixClientCvars(entity e)
1293 {
1294         // send prediction settings to the client
1295         stuffcmd(e, "\nin_bindmap 0 0\n");
1296         if(g_race || g_cts)
1297                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1298         if(autocvar_g_antilag == 3) // client side hitscan
1299                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1300         if(autocvar_sv_gentle)
1301                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1302         /*
1303          * we no longer need to stuff this. Remove this comment block if you feel
1304          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1305         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1306         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1307         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1308         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1309         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1310         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1311         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1312         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1313         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1314         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1315         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1316         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1317         stuffcmd(e, "cl_movement_edgefriction 1\n");
1318          */
1319 }
1320
1321 float PlayerInIDList(entity p, string idlist)
1322 {
1323         float n, i;
1324         string s;
1325
1326         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1327         if not(p.crypto_idfp)
1328                 return 0;
1329
1330         // this function allows abbreviated player IDs too!
1331         n = tokenize_console(idlist);
1332         for(i = 0; i < n; ++i)
1333         {
1334                 s = argv(i);
1335                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1336                         return 1;
1337         }
1338
1339         return 0;
1340 }
1341
1342 /*
1343 =============
1344 ClientConnect
1345
1346 Called when a client connects to the server
1347 =============
1348 */
1349 void DecodeLevelParms (void);
1350 //void dom_player_join_team(entity pl);
1351 void set_dom_state(entity e);
1352 void ClientConnect (void)
1353 {
1354         float t;
1355
1356         if(self.flags & FL_CLIENT)
1357         {
1358                 print("Warning: ClientConnect, but already connected!\n");
1359                 return;
1360         }
1361
1362         if(Ban_MaybeEnforceBanOnce(self))
1363                 return;
1364
1365         DecodeLevelParms();
1366
1367 #ifdef WATERMARK
1368         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK, "\n"));
1369 #endif
1370
1371         self.classname = "player_joining";
1372
1373         self.flags = FL_CLIENT;
1374         self.version_nagtime = time + 10 + random() * 10;
1375
1376         if(self.netaddress == "local")
1377         {
1378                 print("^3server is local!\n");
1379
1380                 if(server_is_local)
1381                         print("Multiple local clients???");
1382                 else
1383                         server_is_local = TRUE;
1384         }
1385
1386         if(player_count<0)
1387         {
1388                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1389                 player_count = 0;
1390         }
1391
1392         PlayerScore_Attach(self);
1393         ClientData_Attach();
1394         accuracy_init(self);
1395
1396         bot_clientconnect();
1397
1398         playerdemo_init();
1399
1400         anticheat_init();
1401
1402         race_PreSpawnObserver();
1403
1404         // identify the right forced team
1405         if(autocvar_g_campaign)
1406         {
1407                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1408                 {
1409                         switch(autocvar_g_campaign_forceteam)
1410                         {
1411                                 case 1: self.team_forced = FL_TEAM_1; break;
1412                                 case 2: self.team_forced = FL_TEAM_2; break;
1413                                 case 3: self.team_forced = FL_TEAM_3; break;
1414                                 case 4: self.team_forced = FL_TEAM_4; break;
1415                                 default: self.team_forced = 0;
1416                         }
1417                 }
1418         }
1419         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1420                 self.team_forced = FL_TEAM_1;
1421         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1422                 self.team_forced = FL_TEAM_2;
1423         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1424                 self.team_forced = FL_TEAM_3;
1425         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1426                 self.team_forced = FL_TEAM_4;
1427         else if(autocvar_g_forced_team_otherwise == "red")
1428                 self.team_forced = FL_TEAM_1;
1429         else if(autocvar_g_forced_team_otherwise == "blue")
1430                 self.team_forced = FL_TEAM_2;
1431         else if(autocvar_g_forced_team_otherwise == "yellow")
1432                 self.team_forced = FL_TEAM_3;
1433         else if(autocvar_g_forced_team_otherwise == "pink")
1434                 self.team_forced = FL_TEAM_4;
1435         else if(autocvar_g_forced_team_otherwise == "spectate")
1436                 self.team_forced = -1;
1437         else if(autocvar_g_forced_team_otherwise == "spectator")
1438                 self.team_forced = -1;
1439         else
1440                 self.team_forced = 0;
1441
1442         if(!teamplay)
1443                 if(self.team_forced > 0)
1444                         self.team_forced = 0;
1445
1446         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1447
1448         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1449                 self.classname = "observer";
1450         } else {
1451                 if(teamplay)
1452                 {
1453                         if(autocvar_g_balance_teams)
1454                         {
1455                                 self.classname = "player";
1456                                 campaign_bots_may_start = 1;
1457                         }
1458                         else
1459                         {
1460                                 self.classname = "observer"; // do it anyway
1461                         }
1462                 }
1463                 else
1464                 {
1465                         self.classname = "player";
1466                         campaign_bots_may_start = 1;
1467                 }
1468         }
1469
1470         self.playerid = (playerid_last = playerid_last + 1);
1471
1472         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1473
1474     if(clienttype(self) == CLIENTTYPE_BOT)
1475         PlayerStats_AddPlayer(self);
1476
1477         if(autocvar_sv_eventlog)
1478                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1479
1480         LogTeamchange(self.playerid, self.team, 1);
1481
1482         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1483
1484         self.netname_previous = strzone(self.netname);
1485
1486         bprint("^4", self.netname, "^4 connected");
1487
1488         if(self.classname != "observer" && (g_domination || g_ctf))
1489                 bprint(" and joined the ", Team_ColoredFullName(self.team));
1490
1491         bprint("\n");
1492
1493         stuffcmd(self, strcat(clientstuff, "\n"));
1494         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1495
1496         FixClientCvars(self);
1497
1498         // spawnfunc_waypoint sprites
1499         WaypointSprite_InitClient(self);
1500
1501         // Wazat's grappling hook
1502         SetGrappleHookBindings();
1503
1504         // get version info from player
1505         stuffcmd(self, "cmd clientversion $gameversion\n");
1506
1507         // get other cvars from player
1508         GetCvars(0);
1509
1510         // notify about available teams
1511         if(teamplay)
1512         {
1513                 CheckAllowedTeams(self);
1514                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1515                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1516         }
1517         else
1518                 stuffcmd(self, "set _teams_available 0\n");
1519
1520         if(g_arena || g_ca)
1521         {
1522                 self.classname = "observer";
1523                 if(g_arena)
1524                         Spawnqueue_Insert(self);
1525         }
1526
1527         attach_entcs();
1528
1529         bot_relinkplayerlist();
1530
1531         self.spectatortime = time;
1532         if(blockSpectators)
1533         {
1534                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1535         }
1536
1537         self.jointime = time;
1538         self.allowed_timeouts = autocvar_sv_timeout_number;
1539
1540         if(clienttype(self) == CLIENTTYPE_REAL)
1541         {
1542                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1543                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1544         }
1545
1546         if(g_lms)
1547         {
1548                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1549                 {
1550                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1551                         self.frags = FRAGS_SPECTATOR;
1552                 }
1553         }
1554
1555         if(!sv_foginterval && world.fog != "")
1556                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1557
1558         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1559         {
1560                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1561                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1562         }
1563         else
1564                 self.hitplotfh = -1;
1565
1566         if(g_race || g_cts) {
1567                 string rr;
1568                 if(g_cts)
1569                         rr = CTS_RECORD;
1570                 else
1571                         rr = RACE_RECORD;
1572
1573                 msg_entity = self;
1574                 race_send_recordtime(MSG_ONE);
1575                 race_send_speedaward(MSG_ONE);
1576
1577                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1578                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1579                 race_send_speedaward_alltimebest(MSG_ONE);
1580
1581                 float i;
1582                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1583                         race_SendRankings(i, 0, 0, MSG_ONE);
1584                 }
1585         }
1586         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1587                 send_CSQC_teamnagger();
1588
1589         CheatInitClient();
1590
1591         if(!autocvar_g_campaign)
1592                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1593
1594         CSQCMODEL_AUTOINIT();
1595
1596         self.model_randomizer = random();
1597
1598     if(clienttype(self) != CLIENTTYPE_REAL)
1599         return;
1600
1601     sv_notice_join();
1602
1603     MUTATOR_CALLHOOK(ClientConnect);
1604 }
1605 /*
1606 =============
1607 ClientDisconnect
1608
1609 Called when a client disconnects from the server
1610 =============
1611 */
1612 .entity chatbubbleentity;
1613 void ReadyCount();
1614 void ClientDisconnect (void)
1615 {
1616         if(self.vehicle)
1617             vehicles_exit(VHEF_RELESE);
1618
1619         if not(self.flags & FL_CLIENT)
1620         {
1621                 print("Warning: ClientDisconnect without ClientConnect\n");
1622                 return;
1623         }
1624
1625         PlayerStats_AddGlobalInfo(self);
1626
1627         CheatShutdownClient();
1628
1629         if(self.hitplotfh >= 0)
1630         {
1631                 fclose(self.hitplotfh);
1632                 self.hitplotfh = -1;
1633         }
1634
1635         anticheat_report();
1636         anticheat_shutdown();
1637
1638         playerdemo_shutdown();
1639
1640         bot_clientdisconnect();
1641
1642         if(self.entcs)
1643                 detach_entcs();
1644
1645         if(autocvar_sv_eventlog)
1646                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1647         bprint ("^4",self.netname);
1648         bprint ("^4 disconnected\n");
1649
1650         DropAllRunes(self);
1651         MUTATOR_CALLHOOK(ClientDisconnect);
1652
1653         Portal_ClearAll(self);
1654
1655         RemoveGrapplingHook(self);
1656
1657         // Here, everything has been done that requires this player to be a client.
1658
1659         self.flags &~= FL_CLIENT;
1660
1661         if (self.chatbubbleentity)
1662                 remove (self.chatbubbleentity);
1663
1664         if (self.killindicator)
1665                 remove (self.killindicator);
1666
1667         WaypointSprite_PlayerGone();
1668
1669         bot_relinkplayerlist();
1670
1671         if(g_arena)
1672         {
1673                 Spawnqueue_Unmark(self);
1674                 Spawnqueue_Remove(self);
1675         }
1676
1677         accuracy_free(self);
1678         ClientData_Detach();
1679         PlayerScore_Detach(self);
1680
1681         if(self.netname_previous)
1682                 strunzone(self.netname_previous);
1683         if(self.clientstatus)
1684                 strunzone(self.clientstatus);
1685         if(self.weaponorder_byimpulse)
1686                 strunzone(self.weaponorder_byimpulse);
1687
1688         ClearPlayerSounds();
1689
1690         if(self.personal)
1691                 remove(self.personal);
1692
1693         self.playerid = 0;
1694         ReadyCount();
1695
1696         // free cvars
1697         GetCvars(-1);
1698 }
1699
1700 .float BUTTON_CHAT;
1701 void ChatBubbleThink()
1702 {
1703         self.nextthink = time;
1704         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1705         {
1706                 if(self.owner) // but why can that ever be world?
1707                         self.owner.chatbubbleentity = world;
1708                 remove(self);
1709                 return;
1710         }
1711         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1712 #ifdef TETRIS
1713                 || self.owner.tetris_on
1714 #endif
1715         )
1716                 self.model = self.mdl;
1717         else
1718                 self.model = "";
1719 }
1720
1721 void UpdateChatBubble()
1722 {
1723         if (self.alpha < 0)
1724                 return;
1725         // spawn a chatbubble entity if needed
1726         if (!self.chatbubbleentity)
1727         {
1728                 self.chatbubbleentity = spawn();
1729                 self.chatbubbleentity.owner = self;
1730                 self.chatbubbleentity.exteriormodeltoclient = self;
1731                 self.chatbubbleentity.think = ChatBubbleThink;
1732                 self.chatbubbleentity.nextthink = time;
1733                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1734                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1735                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1736                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1737                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1738                 self.chatbubbleentity.model = "";
1739                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1740         }
1741 }
1742
1743
1744 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1745 // added to the model skins
1746 /*void UpdateColorModHack()
1747 {
1748         float c;
1749         c = self.clientcolors & 15;
1750         // LordHavoc: only bothering to support white, green, red, yellow, blue
1751              if (!teamplay) self.colormod = '0 0 0';
1752         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1753         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1754         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1755         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1756         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1757         else self.colormod = '1 1 1';
1758 }*/
1759
1760 void respawn(void)
1761 {
1762         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1763         {
1764                 self.solid = SOLID_NOT;
1765                 self.takedamage = DAMAGE_NO;
1766                 self.movetype = MOVETYPE_FLY;
1767                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1768                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1769                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1770                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1771                 if(autocvar_g_respawn_ghosts_maxtime)
1772                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1773         }
1774
1775         CopyBody(1);
1776
1777         self.effects |= EF_NODRAW; // prevent another CopyBody
1778         PutClientInServer();
1779 }
1780
1781 void play_countdown(float finished, string samp)
1782 {
1783         if(clienttype(self) == CLIENTTYPE_REAL)
1784                 if(floor(finished - time - frametime) != floor(finished - time))
1785                         if(finished - time < 6)
1786                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1787 }
1788
1789 void player_powerups (void)
1790 {
1791         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1792         olditems = self.items;
1793
1794         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1795                 self.modelflags |= MF_ROCKET;
1796         else
1797                 self.modelflags &~= MF_ROCKET;
1798
1799         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1800
1801         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1802                 return;
1803
1804         Fire_ApplyDamage(self);
1805         Fire_ApplyEffect(self);
1806
1807         if (g_minstagib)
1808         {
1809                 self.effects |= EF_FULLBRIGHT;
1810
1811                 if (self.items & IT_STRENGTH)
1812                 {
1813                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1814                         if (time > self.strength_finished)
1815                         {
1816                                 self.alpha = default_player_alpha;
1817                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1818                                 self.items &~= IT_STRENGTH;
1819                                 sprint(self, "^3Invisibility has worn off\n");
1820                         }
1821                 }
1822                 else
1823                 {
1824                         if (time < self.strength_finished)
1825                         {
1826                                 self.alpha = g_minstagib_invis_alpha;
1827                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1828                                 self.items |= IT_STRENGTH;
1829                                 sprint(self, "^3You are invisible\n");
1830                         }
1831                 }
1832
1833                 if (self.items & IT_INVINCIBLE)
1834                 {
1835                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1836                         if (time > self.invincible_finished)
1837                         {
1838                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1839                                 sprint(self, "^3Speed has worn off\n");
1840                         }
1841                 }
1842                 else
1843                 {
1844                         if (time < self.invincible_finished)
1845                         {
1846                                 self.items = self.items | IT_INVINCIBLE;
1847                                 sprint(self, "^3You are on speed\n");
1848                         }
1849                 }
1850         }
1851         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1852         {
1853                 if (self.items & IT_STRENGTH)
1854                 {
1855                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1856                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1857                         if (time > self.strength_finished)
1858                         {
1859                                 self.items = self.items - (self.items & IT_STRENGTH);
1860                                 sprint(self, "^3Strength has worn off\n");
1861                         }
1862                 }
1863                 else
1864                 {
1865                         if (time < self.strength_finished)
1866                         {
1867                                 self.items = self.items | IT_STRENGTH;
1868                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1869                         }
1870                 }
1871                 if (self.items & IT_INVINCIBLE)
1872                 {
1873                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1874                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1875                         if (time > self.invincible_finished)
1876                         {
1877                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1878                                 sprint(self, "^3Shield has worn off\n");
1879                         }
1880                 }
1881                 else
1882                 {
1883                         if (time < self.invincible_finished)
1884                         {
1885                                 self.items = self.items | IT_INVINCIBLE;
1886                                 sprint(self, "^3Shield surrounds you\n");
1887                         }
1888                 }
1889                 if (self.items & IT_SUPERWEAPON)
1890                 {
1891                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1892                         {
1893                                 self.superweapons_finished = 0;
1894                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1895                                 sprint(self, "^3Superweapons have been lost\n");
1896                         }
1897                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1898                         {
1899                                 // don't let them run out
1900                         }
1901                         else
1902                         {
1903                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1904                                 if (time > self.superweapons_finished)
1905                                 {
1906                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1907                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1908                                         sprint(self, "^3Superweapons have broken down\n");
1909                                 }
1910                         }
1911                 }
1912                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1913                 {
1914                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1915                         {
1916                                 self.items = self.items | IT_SUPERWEAPON;
1917                                 sprint(self, "^3You now have a superweapon\n");
1918                         }
1919                         else
1920                         {
1921                                 self.superweapons_finished = 0;
1922                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1923                         }
1924                 }
1925                 else
1926                 {
1927                         self.superweapons_finished = 0;
1928                 }
1929         }
1930
1931         if(autocvar_g_nodepthtestplayers)
1932                 self.effects = self.effects | EF_NODEPTHTEST;
1933
1934         if(autocvar_g_fullbrightplayers)
1935                 self.effects = self.effects | EF_FULLBRIGHT;
1936
1937         // midair gamemode: damage only while in the air
1938         // if in midair mode, being on ground grants temporary invulnerability
1939         // (this is so that multishot weapon don't clear the ground flag on the
1940         // first damage in the frame, leaving the player vulnerable to the
1941         // remaining hits in the same frame)
1942         if (self.flags & FL_ONGROUND)
1943         if (g_midair)
1944                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1945
1946         if (time >= game_starttime)
1947         if (time < self.spawnshieldtime)
1948                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1949
1950         MUTATOR_CALLHOOK(PlayerPowerups);
1951 }
1952
1953 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1954 {
1955         if(current > stable)
1956                 return current;
1957         else if(current > stable - 0.25) // when close enough, "snap"
1958                 return stable;
1959         else
1960                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1961 }
1962
1963 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1964 {
1965         if(current < stable)
1966                 return current;
1967         else if(current < stable + 0.25) // when close enough, "snap"
1968                 return stable;
1969         else
1970                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1971 }
1972
1973 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1974 {
1975         if(current > rotstable)
1976         {
1977                 if(rotframetime > 0)
1978                 {
1979                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1980                         current = max(rotstable, current - rotlinear * rotframetime);
1981                 }
1982         }
1983         else if(current < regenstable)
1984         {
1985                 if(regenframetime > 0)
1986                 {
1987                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1988                         current = min(regenstable, current + regenlinear * regenframetime);
1989                 }
1990         }
1991
1992         if(current > limit)
1993                 current = limit;
1994
1995         return current;
1996 }
1997
1998 void player_regen (void)
1999 {
2000         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2001         maxh = autocvar_g_balance_health_rotstable;
2002         maxa = autocvar_g_balance_armor_rotstable;
2003         maxf = autocvar_g_balance_fuel_rotstable;
2004         minh = autocvar_g_balance_health_regenstable;
2005         mina = autocvar_g_balance_armor_regenstable;
2006         minf = autocvar_g_balance_fuel_regenstable;
2007         limith = autocvar_g_balance_health_limit;
2008         limita = autocvar_g_balance_armor_limit;
2009         limitf = autocvar_g_balance_fuel_limit;
2010
2011         max_mod = regen_mod = rot_mod = limit_mod = 1;
2012
2013         if (self.runes & RUNE_REGEN)
2014         {
2015                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2016                 {
2017                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2018                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2019                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2020                 }
2021                 else
2022                 {
2023                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2024                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2025                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2026                 }
2027         }
2028         else if (self.runes & CURSE_VENOM)
2029         {
2030                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2031                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2032                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2033                 else
2034                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2035                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2036                 //if (!self.runes & RUNE_REGEN)
2037                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2038         }
2039         maxh = maxh * max_mod;
2040         //maxa = maxa * max_mod;
2041         //maxf = maxf * max_mod;
2042         minh = minh * max_mod;
2043         //mina = mina * max_mod;
2044         //minf = minf * max_mod;
2045         limith = limith * limit_mod;
2046         limita = limita * limit_mod;
2047         //limitf = limitf * limit_mod;
2048
2049         if(g_lms && g_ca)
2050                 rot_mod = 0;
2051
2052         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2053         {
2054                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2055                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2056
2057                 // if player rotted to death...  die!
2058                 if(self.health < 1)
2059                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2060         }
2061
2062         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2063                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2064 }
2065
2066 float zoomstate_set;
2067 void SetZoomState(float z)
2068 {
2069         if(z != self.zoomstate)
2070         {
2071                 self.zoomstate = z;
2072                 ClientData_Touch(self);
2073         }
2074         zoomstate_set = 1;
2075 }
2076
2077 void GetPressedKeys(void) {
2078         MUTATOR_CALLHOOK(GetPressedKeys);
2079         if (self.movement_x > 0) // get if movement keys are pressed
2080         {       // forward key pressed
2081                 self.pressedkeys |= KEY_FORWARD;
2082                 self.pressedkeys &~= KEY_BACKWARD;
2083         }
2084         else if (self.movement_x < 0)
2085         {       // backward key pressed
2086                 self.pressedkeys |= KEY_BACKWARD;
2087                 self.pressedkeys &~= KEY_FORWARD;
2088         }
2089         else
2090         {       // no x input
2091                 self.pressedkeys &~= KEY_FORWARD;
2092                 self.pressedkeys &~= KEY_BACKWARD;
2093         }
2094
2095         if (self.movement_y > 0)
2096         {       // right key pressed
2097                 self.pressedkeys |= KEY_RIGHT;
2098                 self.pressedkeys &~= KEY_LEFT;
2099         }
2100         else if (self.movement_y < 0)
2101         {       // left key pressed
2102                 self.pressedkeys |= KEY_LEFT;
2103                 self.pressedkeys &~= KEY_RIGHT;
2104         }
2105         else
2106         {       // no y input
2107                 self.pressedkeys &~= KEY_RIGHT;
2108                 self.pressedkeys &~= KEY_LEFT;
2109         }
2110
2111         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2112                 self.pressedkeys |= KEY_JUMP;
2113         else
2114                 self.pressedkeys &~= KEY_JUMP;
2115         if (self.BUTTON_CROUCH)
2116                 self.pressedkeys |= KEY_CROUCH;
2117         else
2118                 self.pressedkeys &~= KEY_CROUCH;
2119
2120         if (self.BUTTON_ATCK)
2121                 self.pressedkeys |= KEY_ATCK;
2122         else
2123                 self.pressedkeys &~= KEY_ATCK;
2124         if (self.BUTTON_ATCK2)
2125                 self.pressedkeys |= KEY_ATCK2;
2126         else
2127                 self.pressedkeys &~= KEY_ATCK2;
2128 }
2129
2130 /*
2131 ======================
2132 spectate mode routines
2133 ======================
2134 */
2135
2136 void SpectateCopy(entity spectatee) {
2137         other = spectatee;
2138         MUTATOR_CALLHOOK(SpectateCopy);
2139         self.armortype = spectatee.armortype;
2140         self.armorvalue = spectatee.armorvalue;
2141         self.ammo_cells = spectatee.ammo_cells;
2142         self.ammo_shells = spectatee.ammo_shells;
2143         self.ammo_nails = spectatee.ammo_nails;
2144         self.ammo_rockets = spectatee.ammo_rockets;
2145         self.ammo_fuel = spectatee.ammo_fuel;
2146         self.clip_load = spectatee.clip_load;
2147         self.clip_size = spectatee.clip_size;
2148         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2149         self.health = spectatee.health;
2150         self.impulse = 0;
2151         self.items = spectatee.items;
2152         self.last_pickup = spectatee.last_pickup;
2153         self.hit_time = spectatee.hit_time;
2154         self.metertime = spectatee.metertime;
2155         self.strength_finished = spectatee.strength_finished;
2156         self.invincible_finished = spectatee.invincible_finished;
2157         self.pressedkeys = spectatee.pressedkeys;
2158         WEPSET_COPY_EE(self, spectatee);
2159         self.switchweapon = spectatee.switchweapon;
2160         self.switchingweapon = spectatee.switchingweapon;
2161         self.weapon = spectatee.weapon;
2162         self.nex_charge = spectatee.nex_charge;
2163         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2164         self.hagar_load = spectatee.hagar_load;
2165         self.minelayer_mines = spectatee.minelayer_mines;
2166         self.punchangle = spectatee.punchangle;
2167         self.view_ofs = spectatee.view_ofs;
2168         self.velocity = spectatee.velocity;
2169         self.dmg_take = spectatee.dmg_take;
2170         self.dmg_save = spectatee.dmg_save;
2171         self.dmg_inflictor = spectatee.dmg_inflictor;
2172         self.v_angle = spectatee.v_angle;
2173         self.angles = spectatee.v_angle;
2174         self.stat_respawn_time = spectatee.stat_respawn_time;
2175         if(!self.BUTTON_USE)
2176                 self.fixangle = TRUE;
2177         setorigin(self, spectatee.origin);
2178         setsize(self, spectatee.mins, spectatee.maxs);
2179         SetZoomState(spectatee.zoomstate);
2180
2181     anticheat_spectatecopy(spectatee);
2182         self.hud = spectatee.hud;
2183         if(spectatee.vehicle)
2184     {
2185         self.fixangle = FALSE;
2186         //self.velocity = spectatee.vehicle.velocity;
2187         self.vehicle_health = spectatee.vehicle_health;
2188         self.vehicle_shield = spectatee.vehicle_shield;
2189         self.vehicle_energy = spectatee.vehicle_energy;
2190         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2191         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2192         self.vehicle_reload1 = spectatee.vehicle_reload1;
2193         self.vehicle_reload2 = spectatee.vehicle_reload2;
2194
2195         msg_entity = self;
2196
2197         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2198             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2199             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2200             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2201
2202         //WriteByte (MSG_ONE, SVC_SETVIEW);
2203         //    WriteEntity(MSG_ONE, self);
2204         //makevectors(spectatee.v_angle);
2205         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2206     }
2207 }
2208
2209 float SpectateUpdate() {
2210         if(!self.enemy)
2211             return 0;
2212
2213         if (self == self.enemy)
2214                 return 0;
2215
2216         if(self.enemy.classname != "player")
2217                 return 0;
2218
2219         SpectateCopy(self.enemy);
2220
2221         return 1;
2222 }
2223
2224
2225 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2226 entity CA_SpectateNext(entity start) {
2227         if (start.team == self.team) {
2228                 return start;
2229         }
2230
2231         other = start;
2232         // continue from current player
2233         while(other && other.team != self.team) {
2234                 other = find(other, classname, "player");
2235         }
2236
2237         if (!other) {
2238                 // restart from begining
2239                 other = find(other, classname, "player");
2240                 while(other && other.team != self.team) {
2241                         other = find(other, classname, "player");
2242                 }
2243         }
2244
2245         return other;
2246 }
2247
2248 float SpectateNext(entity _prefer) {
2249
2250         if(_prefer)
2251                 other = _prefer;
2252         else
2253                 other = find(self.enemy, classname, "player");
2254
2255         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2256                 // CA and ca players when spectating enemies is forbidden
2257                 other = CA_SpectateNext(other);
2258         } else {
2259                 // other modes and ca spectators or spectating enemies is allowed
2260                 if (!other)
2261                         other = find(other, classname, "player");
2262         }
2263
2264         if (other)
2265                 self.enemy = other;
2266
2267         if(self.enemy.classname == "player") {
2268             /*if(self.enemy.vehicle)
2269             {
2270
2271             msg_entity = self;
2272             WriteByte(MSG_ONE, SVC_SETVIEW);
2273             WriteEntity(MSG_ONE, self.enemy);
2274             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2275
2276             self.movetype = MOVETYPE_NONE;
2277             accuracy_resend(self);
2278             }
2279             else
2280             {*/
2281             msg_entity = self;
2282             WriteByte(MSG_ONE, SVC_SETVIEW);
2283             WriteEntity(MSG_ONE, self.enemy);
2284             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2285             self.movetype = MOVETYPE_NONE;
2286             accuracy_resend(self);
2287
2288             if(!SpectateUpdate())
2289                 PutObserverInServer();
2290         //}
2291         return 1;
2292         } else {
2293                 return 0;
2294         }
2295 }
2296
2297 /*
2298 =============
2299 ShowRespawnCountdown()
2300
2301 Update a respawn countdown display.
2302 =============
2303 */
2304 void ShowRespawnCountdown()
2305 {
2306         float number;
2307         if(self.deadflag == DEAD_NO) // just respawned?
2308                 return;
2309         else
2310         {
2311                 number = ceil(self.respawn_time - time);
2312                 if(number <= 0)
2313                         return;
2314                 if(number <= self.respawn_countdown)
2315                 {
2316                         self.respawn_countdown = number - 1;
2317                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2318                                 AnnounceTo(self, strcat(ftos(number), ""));
2319                 }
2320         }
2321 }
2322
2323 .float prevent_join_msgtime;
2324 void LeaveSpectatorMode()
2325 {
2326         if(nJoinAllowed(self)) {
2327                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2328                         self.classname = "player";
2329
2330                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2331                                 JoinBestTeam(self, FALSE, TRUE);
2332
2333                         if(autocvar_g_campaign)
2334                                 campaign_bots_may_start = 1;
2335
2336                         PutClientInServer();
2337
2338                         if(self.classname == "player")
2339                                 bprint ("^4", self.netname, "^4 is playing now\n");
2340
2341                         if(!autocvar_g_campaign)
2342                         if (time < self.jointime + autocvar_welcome_message_time)
2343                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2344
2345                         if (self.prevent_join_msgtime)
2346                         {
2347                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2348                                 self.prevent_join_msgtime = 0;
2349                         }
2350
2351                         return;
2352                 } else {
2353                         if (g_ca && self.caplayer) {
2354                         }       // do nothing
2355                         else
2356                                 stuffcmd(self,"menu_showteamselect\n");
2357                         return;
2358                 }
2359         }
2360         else {
2361                 //player may not join because of g_maxplayers is set
2362                 if (time - self.prevent_join_msgtime > 2)
2363                 {
2364                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2365                         self.prevent_join_msgtime = time;
2366                 }
2367         }
2368 }
2369
2370 /**
2371  * Determines whether the player is allowed to join. This depends on cvar
2372  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2373  * it checks whether the number of currently playing players exceeds g_maxplayers.
2374  * @return int number of free slots for players, 0 if none
2375  */
2376 float nJoinAllowed(entity ignore) {
2377         if(!ignore)
2378         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2379         // so report 0 free slots if restricted
2380         {
2381                 if(autocvar_g_forced_team_otherwise == "spectate")
2382                         return 0;
2383                 if(autocvar_g_forced_team_otherwise == "spectator")
2384                         return 0;
2385         }
2386
2387         if(self.team_forced < 0)
2388                 return 0; // forced spectators can never join
2389
2390         // TODO simplify this
2391         entity e;
2392         float totalClients = 0;
2393         FOR_EACH_CLIENT(e)
2394                 if(e != ignore)
2395                         totalClients += 1;
2396
2397         if (!autocvar_g_maxplayers)
2398                 return maxclients - totalClients;
2399
2400         float currentlyPlaying = 0;
2401         FOR_EACH_REALPLAYER(e)
2402                 currentlyPlaying += 1;
2403
2404         if(currentlyPlaying < autocvar_g_maxplayers)
2405                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2406
2407         return 0;
2408 }
2409
2410 /**
2411  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2412  * g_maxplayers_spectator_blocktime seconds
2413  */
2414 void checkSpectatorBlock() {
2415         if(self.classname == "spectator" || self.classname == "observer") {
2416                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2417                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2418                         dropclient(self);
2419                 }
2420         }
2421 }
2422
2423 .float motd_actived_time; // used for both motd and campaign_message
2424 void PrintWelcomeMessage()
2425 {
2426         if (self.motd_actived_time == 0) { // is there already a message showing?
2427                 if (autocvar_g_campaign) {
2428                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2429                                 self.motd_actived_time = time;
2430                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2431                         }
2432                 } else {
2433                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2434                                 self.motd_actived_time = time;
2435                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2436                         }
2437                 }
2438         } else { // showing MOTD or campaign message
2439                 if (autocvar_g_campaign) {
2440                         if (self.BUTTON_INFO)
2441                                 self.motd_actived_time = time;
2442                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2443                                 self.motd_actived_time = 0;
2444                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2445                         }
2446                 } else {
2447                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2448                                 if (self.BUTTON_INFO)
2449                                         self.motd_actived_time = time;
2450                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2451                                         self.motd_actived_time = 0;
2452                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2453                                 }
2454                         }
2455                 }
2456         }
2457 }
2458
2459 void ObserverThink()
2460 {
2461         float prefered_movetype;
2462         if (self.flags & FL_JUMPRELEASED) {
2463                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2464                         self.flags &~= FL_JUMPRELEASED;
2465                         self.flags |= FL_SPAWNING;
2466                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2467                         self.flags &~= FL_JUMPRELEASED;
2468                         if(SpectateNext(world) == 1) {
2469                                 self.classname = "spectator";
2470                         }
2471                 } else {
2472                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2473                         if (self.movetype != prefered_movetype)
2474                                 self.movetype = prefered_movetype;
2475                 }
2476         } else {
2477                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2478                         self.flags |= FL_JUMPRELEASED;
2479                         if(self.flags & FL_SPAWNING)
2480                         {
2481                                 self.flags &~= FL_SPAWNING;
2482                                 LeaveSpectatorMode();
2483                                 return;
2484                         }
2485                 }
2486         }
2487
2488         PrintWelcomeMessage();
2489 }
2490
2491 void SpectatorThink()
2492 {
2493         if (self.flags & FL_JUMPRELEASED) {
2494                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2495                         self.flags &~= FL_JUMPRELEASED;
2496                         self.flags |= FL_SPAWNING;
2497                 } else if(self.BUTTON_ATCK) {
2498                         self.flags &~= FL_JUMPRELEASED;
2499                         if(SpectateNext(world) == 1) {
2500                                 self.classname = "spectator";
2501                         } else {
2502                                 self.classname = "observer";
2503                                 PutClientInServer();
2504                         }
2505                 } else if (self.BUTTON_ATCK2) {
2506                         self.flags &~= FL_JUMPRELEASED;
2507                         self.classname = "observer";
2508                         PutClientInServer();
2509                 } else {
2510                         if(!SpectateUpdate())
2511                                 PutObserverInServer();
2512                 }
2513         } else {
2514                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2515                         self.flags |= FL_JUMPRELEASED;
2516                         if(self.flags & FL_SPAWNING)
2517                         {
2518                                 self.flags &~= FL_SPAWNING;
2519                                 LeaveSpectatorMode();
2520                                 return;
2521                         }
2522                 }
2523                 if(!SpectateUpdate())
2524                         PutObserverInServer();
2525         }
2526
2527         PrintWelcomeMessage();
2528         self.flags |= FL_CLIENT | FL_NOTARGET;
2529 }
2530
2531 void PlayerUseKey()
2532 {
2533         if(self.classname != "player")
2534                 return;
2535
2536         if(self.vehicle)
2537         {
2538         vehicles_exit(VHEF_NORMAL);
2539         return;
2540         }
2541
2542         // a use key was pressed; call handlers
2543         MUTATOR_CALLHOOK(PlayerUseKey);
2544 }
2545
2546 .float touchexplode_time;
2547
2548 /*
2549 =============
2550 PlayerPreThink
2551
2552 Called every frame for each client before the physics are run
2553 =============
2554 */
2555 .float usekeypressed;
2556 void() nexball_setstatus;
2557 .float items_added;
2558 void PlayerPreThink (void)
2559 {
2560         WarpZone_PlayerPhysics_FixVAngle();
2561
2562         self.stat_game_starttime = game_starttime;
2563         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2564         self.stat_leadlimit = autocvar_leadlimit;
2565
2566         if(g_arena || (g_ca && !allowed_to_spawn))
2567                 self.stat_respawn_time = 0;
2568         else
2569                 self.stat_respawn_time = self.respawn_time;
2570
2571         if(frametime)
2572         {
2573                 // physics frames: update anticheat stuff
2574                 anticheat_prethink();
2575         }
2576
2577         if(blockSpectators && frametime)
2578                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2579                 checkSpectatorBlock();
2580
2581         zoomstate_set = 0;
2582
2583         if(self.netname_previous != self.netname)
2584         {
2585                 if(autocvar_sv_eventlog)
2586                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2587                 if(self.netname_previous)
2588                         strunzone(self.netname_previous);
2589                 self.netname_previous = strzone(self.netname);
2590         }
2591
2592         // version nagging
2593         if(self.version_nagtime)
2594                 if(self.cvar_g_xonoticversion)
2595                         if(time > self.version_nagtime)
2596                         {
2597                                 // don't notify git users
2598                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2599                                 {
2600                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2601                                         {
2602                                                 // notify release users if connecting to git
2603                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2604                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2605                                         }
2606                                         else
2607                                         {
2608                                                 float r;
2609                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2610                                                 if(r < 0)
2611                                                 {
2612                                                         // give users new version
2613                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2614                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2615                                                 }
2616                                                 else if(r > 0)
2617                                                 {
2618                                                         // notify users about old server version
2619                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2620                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2621                                                 }
2622                                         }
2623                                 }
2624                                 self.version_nagtime = 0;
2625                         }
2626
2627         // GOD MODE info
2628         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2629         {
2630                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2631                 self.max_armorvalue = 0;
2632         }
2633
2634 #ifdef TETRIS
2635         if (TetrisPreFrame())
2636                 return;
2637 #endif
2638
2639         MUTATOR_CALLHOOK(PlayerPreThink);
2640
2641         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2642         {
2643                 if(self.BUTTON_USE && !self.usekeypressed)
2644                         PlayerUseKey();
2645                 self.usekeypressed = self.BUTTON_USE;
2646         }
2647
2648         PrintWelcomeMessage();
2649
2650         if(self.classname == "player") {
2651 //              if(self.netname == "Wazat")
2652 //                      bprint(self.classname, "\n");
2653
2654                 CheckRules_Player();
2655
2656                 if (intermission_running)
2657                 {
2658                         IntermissionThink ();   // otherwise a button could be missed between
2659                         return;                                 // the think tics
2660                 }
2661
2662                 //don't allow the player to turn around while game is paused!
2663                 if(timeout_status == TIMEOUT_ACTIVE) {
2664                         // FIXME turn this into CSQC stuff
2665                         self.v_angle = self.lastV_angle;
2666                         self.angles = self.lastV_angle;
2667                         self.fixangle = TRUE;
2668                 }
2669
2670                 if(frametime)
2671                 {
2672 #ifndef NO_LEGACY_NETWORKING
2673                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2674 #endif
2675
2676                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2677                         {
2678                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2679                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2680                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2681
2682                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2683                                 {
2684                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2685                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2686                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2687                                 }
2688                         }
2689                         else
2690                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2691
2692                         player_powerups();
2693                 }
2694
2695                 if (g_minstagib)
2696                         minstagib_ammocheck();
2697
2698                 if (self.deadflag != DEAD_NO)
2699                 {
2700                         float button_pressed, force_respawn;
2701                         if(self.personal && g_race_qualifying)
2702                         {
2703                                 if(time > self.respawn_time)
2704                                 {
2705                                         self.respawn_time = time + 1; // only retry once a second
2706                                         respawn();
2707                                         self.impulse = 141;
2708                                 }
2709                         }
2710                         else
2711                         {
2712                                 if(frametime)
2713                                         player_anim();
2714                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2715                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2716                                 if (self.deadflag == DEAD_DYING)
2717                                 {
2718                                         if(force_respawn)
2719                                                 self.deadflag = DEAD_RESPAWNING;
2720                                         else if(!button_pressed)
2721                                                 self.deadflag = DEAD_DEAD;
2722                                 }
2723                                 else if (self.deadflag == DEAD_DEAD)
2724                                 {
2725                                         if(button_pressed)
2726                                                 self.deadflag = DEAD_RESPAWNABLE;
2727                                 }
2728                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2729                                 {
2730                                         if(!button_pressed)
2731                                                 self.deadflag = DEAD_RESPAWNING;
2732                                 }
2733                                 else if (self.deadflag == DEAD_RESPAWNING)
2734                                 {
2735                                         if(time > self.respawn_time)
2736                                         {
2737                                                 self.respawn_time = time + 1; // only retry once a second
2738                                                 respawn();
2739                                         }
2740                                 }
2741                                 ShowRespawnCountdown();
2742                         }
2743
2744                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2745                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2746                                 self.stat_respawn_time *= -1;
2747
2748                         return;
2749                 }
2750                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2751                 // so (self.deadflag == DEAD_NO) is always true in the code below
2752
2753                 if(g_touchexplode)
2754                 if(time > self.touchexplode_time)
2755                 if(self.classname == "player")
2756                 if(self.deadflag == DEAD_NO)
2757                 if not(IS_INDEPENDENT_PLAYER(self))
2758                 FOR_EACH_PLAYER(other) if(self != other)
2759                 {
2760                         if(time > other.touchexplode_time)
2761                         if(other.deadflag == DEAD_NO)
2762                         if not(IS_INDEPENDENT_PLAYER(other))
2763                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2764                         {
2765                                 PlayerTouchExplode(self, other);
2766                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2767                         }
2768                 }
2769
2770                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2771                 {
2772                         vector dist;
2773
2774                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2775                         dist = self.prevorigin - self.origin;
2776                         dist_z = 0;
2777                         self.lms_traveled_distance += fabs(vlen(dist));
2778
2779                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2780                         {
2781                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2782                                 self.lms_traveled_distance = 0;
2783                         }
2784
2785                         if(time > self.lms_nextcheck)
2786                         {
2787                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2788                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2789                                 {
2790                                         centerprint(self, autocvar_g_lms_campcheck_message);
2791                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2792                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2793                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2794                                 }
2795                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2796                                 self.lms_traveled_distance = 0;
2797                         }
2798                 }
2799
2800                 self.prevorigin = self.origin;
2801
2802                 if (!self.vehicle)
2803                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x && !self.freezetag_frozen) // prevent crouching if using melee attack
2804                 {
2805                         if (!self.crouch)
2806                         {
2807                                 self.crouch = TRUE;
2808                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2809                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2810                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2811                         }
2812                 }
2813                 else
2814                 {
2815                         if (self.crouch)
2816                         {
2817                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2818                                 if (!trace_startsolid)
2819                                 {
2820                                         self.crouch = FALSE;
2821                                         self.view_ofs = PL_VIEW_OFS;
2822                                         setsize (self, PL_MIN, PL_MAX);
2823                                 }
2824                         }
2825                 }
2826
2827                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2828                 {
2829                         if(self.bloodloss_timer < time)
2830                         {
2831                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2832                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2833                         }
2834                 }
2835
2836                 FixPlayermodel();
2837
2838                 GrapplingHookFrame();
2839
2840                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2841                 //if(frametime)
2842                 {
2843                         self.items &~= self.items_added;
2844
2845                         W_WeaponFrame();
2846
2847                         self.items_added = 0;
2848                         if(self.items & IT_JETPACK)
2849                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2850                                         self.items_added |= IT_FUEL;
2851
2852                         self.items |= self.items_added;
2853                 }
2854
2855                 player_regen();
2856
2857                 // rot nex charge to the charge limit
2858                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2859                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2860
2861                 if(frametime)
2862                         player_anim();
2863
2864                 if(g_nexball)
2865                         nexball_setstatus();
2866
2867                 // secret status
2868                 secrets_setstatus();
2869
2870                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2871
2872                 //self.angles_y=self.v_angle_y + 90;   // temp
2873         } else if(gameover) {
2874                 if (intermission_running)
2875                         IntermissionThink ();   // otherwise a button could be missed between
2876                 return;
2877         } else if(self.classname == "observer") {
2878                 ObserverThink();
2879         } else if(self.classname == "spectator") {
2880                 SpectatorThink();
2881         }
2882
2883         if(!zoomstate_set)
2884                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2885
2886         float oldspectatee_status;
2887         oldspectatee_status = self.spectatee_status;
2888         if(self.classname == "spectator")
2889                 self.spectatee_status = num_for_edict(self.enemy);
2890         else if(self.classname == "observer")
2891                 self.spectatee_status = num_for_edict(self);
2892         else
2893                 self.spectatee_status = 0;
2894         if(self.spectatee_status != oldspectatee_status)
2895         {
2896                 ClientData_Touch(self);
2897                 if(g_race || g_cts)
2898                         race_InitSpectator();
2899         }
2900
2901         if(self.teamkill_soundtime)
2902         if(time > self.teamkill_soundtime)
2903         {
2904                 self.teamkill_soundtime = 0;
2905
2906                 entity oldpusher, oldself;
2907
2908                 oldself = self; self = self.teamkill_soundsource;
2909                 oldpusher = self.pusher; self.pusher = oldself;
2910
2911                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2912
2913                 self.pusher = oldpusher;
2914                 self = oldself;
2915         }
2916
2917         if(self.taunt_soundtime)
2918         if(time > self.taunt_soundtime)
2919         {
2920                 self.taunt_soundtime = 0;
2921                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2922         }
2923
2924         target_voicescript_next(self);
2925
2926         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2927         if(!self.weapon)
2928                 self.clip_load = self.clip_size = 0;
2929 }
2930
2931 float isInvisibleString(string s)
2932 {
2933         float i, n, c;
2934         s = strdecolorize(s);
2935         for((i = 0), (n = strlen(s)); i < n; ++i)
2936         {
2937                 c = str2chr(s, i);
2938                 switch(c)
2939                 {
2940                         case 0:
2941                         case 32: // space
2942                                 break;
2943                         case 192: // charmap space
2944                                 if (!autocvar_utf8_enable)
2945                                         break;
2946                                 return FALSE;
2947                         case 160: // space in unicode fonts
2948                         case 0xE000 + 192: // utf8 charmap space
2949                                 if (autocvar_utf8_enable)
2950                                         break;
2951                         default:
2952                                 return FALSE;
2953                 }
2954         }
2955         return TRUE;
2956 }
2957
2958 /*
2959 =============
2960 PlayerPostThink
2961
2962 Called every frame for each client after the physics are run
2963 =============
2964 */
2965 .float idlekick_lasttimeleft;
2966 .entity showheadshotbbox;
2967 void showheadshotbbox_think()
2968 {
2969         if(self.owner.showheadshotbbox != self)
2970         {
2971                 remove(self);
2972                 return;
2973         }
2974         self.nextthink = time;
2975         setorigin(self, self.owner.origin);
2976         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2977 }
2978 void PlayerPostThink (void)
2979 {
2980         // Savage: Check for nameless players
2981         if (isInvisibleString(self.netname)) {
2982                 self.netname = "Player";
2983                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2984         }
2985
2986         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2987         {
2988                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2989                 {
2990                         if(self.idlekick_lasttimeleft)
2991                         {
2992                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2993                                 self.idlekick_lasttimeleft = 0;
2994                         }
2995                 }
2996                 else
2997                 {
2998                         float timeleft;
2999                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3000                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3001                         {
3002                                 if(!self.idlekick_lasttimeleft)
3003                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3004                         }
3005                         if(timeleft <= 0)
3006                         {
3007                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3008                                 AnnounceTo(self, "terminated");
3009                                 dropclient(self);
3010                                 return;
3011                         }
3012                         else if(timeleft <= 10)
3013                         {
3014                                 if(timeleft != self.idlekick_lasttimeleft)
3015                                         AnnounceTo(self, ftos(timeleft));
3016                                 self.idlekick_lasttimeleft = timeleft;
3017                         }
3018                 }
3019         }
3020
3021 #ifdef TETRIS
3022         if(self.impulse == 100)
3023                 ImpulseCommands();
3024         if (!TetrisPostFrame())
3025         {
3026 #endif
3027
3028         CheatFrame();
3029
3030         //CheckPlayerJump();
3031
3032         if(self.classname == "player") {
3033                 CheckRules_Player();
3034                 UpdateChatBubble();
3035                 if (self.impulse)
3036                         ImpulseCommands();
3037                 if (intermission_running)
3038                         return;         // intermission or finale
3039                 GetPressedKeys();
3040         }
3041
3042 #ifdef TETRIS
3043         }
3044 #endif
3045
3046         /*
3047         float i;
3048         for(i = 0; i < 1000; ++i)
3049         {
3050                 vector end;
3051                 end = self.origin + '0 0 1024' + 512 * randomvec();
3052                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3053                 if(trace_fraction < 1)
3054                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3055                 {
3056                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3057                         break;
3058                 }
3059         }
3060         */
3061
3062         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3063
3064         if(self.waypointsprite_attachedforcarrier)
3065                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3066
3067         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3068         {
3069                 if(!self.showheadshotbbox)
3070                 {
3071                         self.showheadshotbbox = spawn();
3072                         self.showheadshotbbox.classname = "headshotbbox";
3073                         self.showheadshotbbox.owner = self;
3074                         self.showheadshotbbox.think = showheadshotbbox_think;
3075                         self.showheadshotbbox.nextthink = time;
3076                         self = self.showheadshotbbox;
3077                         self.think();
3078                         self = self.owner;
3079                 }
3080         }
3081         else
3082         {
3083                 if(self.showheadshotbbox)
3084                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3085                 remove(self.showheadshotbbox);
3086         }
3087
3088         playerdemo_write();
3089
3090         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3091         {
3092                 if not(self.stored_netname)
3093                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3094                 if(self.stored_netname != self.netname)
3095                 {
3096                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3097                         strunzone(self.stored_netname);
3098                         self.stored_netname = strzone(self.netname);
3099                 }
3100         }
3101
3102         /*
3103         if(g_race)
3104                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3105         */
3106
3107         CSQCMODEL_AUTOUPDATE();
3108 }