qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > autocvar_g_spawn_furthest)
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(autocvar_spawn_debugview)
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(autocvar_spawn_debug)
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(autocvar_sv_servermodelsonly)
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595         MUTATOR_CALLHOOK(MakePlayerObserver);
 596
 597         Portal_ClearAll(self);
 598
 599         if(self.alivetime)
 600         {
 601                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 602                 self.alivetime = 0;
 603         }
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried && g_nexball)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         accuracy_resend(self);
 634
 635         self.spectatortime = time;
 636
 637         self.classname = "observer";
 638         self.iscreature = FALSE;
 639         self.health = -666;
 640         self.takedamage = DAMAGE_NO;
 641         self.solid = SOLID_NOT;
 642         self.movetype = MOVETYPE_NOCLIP;
 643         self.flags = FL_CLIENT | FL_NOTARGET;
 644         self.armorvalue = 666;
 645         self.effects = 0;
 646         self.armorvalue = autocvar_g_balance_armor_start;
 647         self.pauserotarmor_finished = 0;
 648         self.pauserothealth_finished = 0;
 649         self.pauseregen_finished = 0;
 650         self.damageforcescale = 0;
 651         self.death_time = 0;
 652         self.dead_frame = 0;
 653         self.alpha = 0;
 654         self.scale = 0;
 655         self.fade_time = 0;
 656         self.pain_frame = 0;
 657         self.pain_finished = 0;
 658         self.strength_finished = 0;
 659         self.invincible_finished = 0;
 660         self.pushltime = 0;
 661         self.think = SUB_Null;
 662         self.nextthink = 0;
 663         self.hook_time = 0;
 664         self.runes = 0;
 665         self.deadflag = DEAD_NO;
 666         self.angles = spot.angles;
 667         self.angles_z = 0;
 668         self.fixangle = TRUE;
 669         self.crouch = FALSE;
 670
 671         self.view_ofs = PL_VIEW_OFS;
 672         setorigin (self, spot.origin);
 673         setsize (self, '0 0 0', '0 0 0');
 674         self.prevorigin = self.origin;
 675         self.items = 0;
 676         self.weapons = 0;
 677         self.model = "";
 678         FixPlayermodel();
 679         self.model = "";
 680         self.modelindex = 0;
 681         self.weapon = 0;
 682         self.weaponmodel = "";
 683         self.weaponentity = world;
 684         self.exteriorweaponentity = world;
 685         self.killcount = -666;
 686         self.velocity = '0 0 0';
 687         self.avelocity = '0 0 0';
 688         self.punchangle = '0 0 0';
 689         self.punchvector = '0 0 0';
 690         self.oldvelocity = self.velocity;
 691         self.fire_endtime = -1;
 692
 693         if(sv_loddistance1)
 694                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 695
 696         if(g_arena)
 697         {
 698                 if(self.version_mismatch)
 699                 {
 700                         Spawnqueue_Unmark(self);
 701                         Spawnqueue_Remove(self);
 702                 }
 703                 else
 704                 {
 705                         Spawnqueue_Insert(self);
 706                 }
 707         }
 708         else if(g_lms)
 709         {
 710                 // Only if the player cannot play at all
 711                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 712                         self.frags = FRAGS_SPECTATOR;
 713                 else
 714                         self.frags = FRAGS_LMS_LOSER;
 715         }
 716         else
 717                 self.frags = FRAGS_SPECTATOR;
 718 }
 719
 720 void FixPlayermodel()
 721 {
 722         local string defaultmodel;
 723         local float defaultskin, chmdl, oldskin;
 724         local vector m1, m2;
 725
 726         defaultmodel = "";
 727
 728         if(autocvar_sv_defaultcharacter == 1) {
 729                 defaultskin = 0;
 730
 731                 if(teams_matter)
 732                 {
 733                         string s;
 734                         s = Team_ColorNameLowerCase(self.team);
 735                         if(s != "neutral")
 736                         {
 737                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 738                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 739                         }
 740                 }
 741
 742                 if(defaultmodel == "")
 743                 {
 744                         defaultmodel = autocvar_sv_defaultplayermodel;
 745                         defaultskin = autocvar_sv_defaultplayerskin;
 746                 }
 747         }
 748
 749         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 750         {
 751                 if(self.model != "")
 752                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 753                 self.model = ""; // force the != checks to return true
 754         }
 755
 756         if(defaultmodel != "")
 757         {
 758                 if (defaultmodel != self.model)
 759                 {
 760                         m1 = self.mins;
 761                         m2 = self.maxs;
 762                         setmodel_lod (self, defaultmodel);
 763                         setsize (self, m1, m2);
 764                         chmdl = TRUE;
 765                 }
 766
 767                 oldskin = self.skinindex;
 768                 self.skinindex = defaultskin;
 769         } else {
 770                 if (self.playermodel != self.model || self.playermodel == "")
 771                 {
 772                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 773                         m1 = self.mins;
 774                         m2 = self.maxs;
 775                         setmodel_lod (self, self.playermodel);
 776                         setsize (self, m1, m2);
 777                         chmdl = TRUE;
 778                 }
 779
 780                 oldskin = self.skinindex;
 781                 self.skinindex = stof(self.playerskin);
 782         }
 783
 784         if(chmdl || oldskin != self.skinindex)
 785                 self.species = player_getspecies(); // model or skin has changed
 786
 787         if(!teams_matter)
 788                 if(strlen(autocvar_sv_defaultplayercolors))
 789                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 790                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 791 }
 792
 793 void PlayerTouchExplode(entity p1, entity p2)
 794 {
 795         vector org;
 796         org = (p1.origin + p2.origin) * 0.5;
 797         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 798
 799         te_explosion(org);
 800
 801         entity e;
 802         e = spawn();
 803         setorigin(e, org);
 804         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 805         remove(e);
 806 }
 807
 808 /*
 809 =============
 810 PutClientInServer
 811
 812 Called when a client spawns in the server
 813 =============
 814 */
 815 //void() ctf_playerchanged;
 816 void PutClientInServer (void)
 817 {
 818         if(clienttype(self) == CLIENTTYPE_BOT)
 819         {
 820                 self.classname = "player";
 821         }
 822         else if(clienttype(self) == CLIENTTYPE_REAL)
 823         {
 824                 msg_entity = self;
 825                 WriteByte(MSG_ONE, SVC_SETVIEW);
 826                 WriteEntity(MSG_ONE, self);
 827         }
 828
 829         // player is dead and becomes observer
 830         // FIXME fix LMS scoring for new system
 831         if(g_lms)
 832         {
 833                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 834                         self.classname = "observer";
 835         }
 836
 837         if(g_arena || (g_ca && !allowed_to_spawn))
 838         if(!self.spawned)
 839                 self.classname = "observer";
 840
 841         if(gameover)
 842                 self.classname = "observer";
 843
 844         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 845                 entity spot, oldself;
 846                 float j;
 847
 848                 accuracy_resend(self);
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 870                 if(autocvar_g_playerclip_collisions)
 871                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 872                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 873                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 874                 self.frags = FRAGS_PLAYER;
 875                 if(independent_players)
 876                         MAKE_INDEPENDENT_PLAYER(self);
 877                 self.flags = FL_CLIENT;
 878                 self.takedamage = DAMAGE_AIM;
 879                 if(g_minstagib)
 880                         self.effects = EF_FULLBRIGHT;
 881                 else
 882                         self.effects = 0;
 883                 self.air_finished = time + 12;
 884                 self.dmg = 2;
 885                 if(autocvar_g_balance_nex_charge)
 886                 {
 887                         if(autocvar_g_balance_nex_secondary_chargepool)
 888                                 self.nex_chargepool_ammo = 1;
 889                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 890                 }
 891
 892                 if(inWarmupStage)
 893                 {
 894                         self.ammo_shells = warmup_start_ammo_shells;
 895                         self.ammo_nails = warmup_start_ammo_nails;
 896                         self.ammo_rockets = warmup_start_ammo_rockets;
 897                         self.ammo_cells = warmup_start_ammo_cells;
 898                         self.ammo_fuel = warmup_start_ammo_fuel;
 899                         self.health = warmup_start_health;
 900                         self.armorvalue = warmup_start_armorvalue;
 901                         self.weapons = warmup_start_weapons;
 902                 }
 903                 else
 904                 {
 905                         self.ammo_shells = start_ammo_shells;
 906                         self.ammo_nails = start_ammo_nails;
 907                         self.ammo_rockets = start_ammo_rockets;
 908                         self.ammo_cells = start_ammo_cells;
 909                         self.ammo_fuel = start_ammo_fuel;
 910                         self.health = start_health;
 911                         self.armorvalue = start_armorvalue;
 912                         self.weapons = start_weapons;
 913                 }
 914
 915                 if(g_weaponarena_random)
 916                 {
 917                         if(g_weaponarena_random_with_laser)
 918                                 self.weapons &~= WEPBIT_LASER;
 919                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 920                         if(g_weaponarena_random_with_laser)
 921                                 self.weapons |= WEPBIT_LASER;
 922                 }
 923
 924                 self.items = start_items;
 925                 self.jump_interval = time;
 926
 927                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 928                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 929                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 930                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 931                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 932                 //extend the pause of rotting if client was reset at the beginning of the countdown
 933                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 934                         self.spawnshieldtime += game_starttime - time;
 935                         self.pauserotarmor_finished += game_starttime - time;
 936                         self.pauserothealth_finished += game_starttime - time;
 937                         self.pauseregen_finished += game_starttime - time;
 938                 }
 939                 self.damageforcescale = 2;
 940                 self.death_time = 0;
 941                 self.dead_frame = 0;
 942                 self.alpha = 0;
 943                 self.scale = 0;
 944                 self.fade_time = 0;
 945                 self.pain_frame = 0;
 946                 self.pain_finished = 0;
 947                 self.strength_finished = 0;
 948                 self.invincible_finished = 0;
 949                 self.pushltime = 0;
 950                 // players have no think function
 951                 self.think = SUB_Null;
 952                 self.nextthink = 0;
 953                 self.hook_time = 0;
 954                 self.dmg_team = 0;
 955                 self.ballistics_density = autocvar_g_ballistics_density_player;
 956
 957                 self.metertime = 0;
 958
 959                 self.runes = 0;
 960
 961                 self.deadflag = DEAD_NO;
 962
 963                 self.angles = spot.angles;
 964
 965                 self.angles_z = 0; // never spawn tilted even if the spot says to
 966                 self.fixangle = TRUE; // turn this way immediately
 967                 self.velocity = '0 0 0';
 968                 self.avelocity = '0 0 0';
 969                 self.punchangle = '0 0 0';
 970                 self.punchvector = '0 0 0';
 971                 self.oldvelocity = self.velocity;
 972                 self.fire_endtime = -1;
 973
 974                 msg_entity = self;
 975                 WRITESPECTATABLE_MSG_ONE({
 976                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 977                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 978                 });
 979
 980                 if(sv_loddistance1)
 981                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 982
 983                 self.model = "";
 984                 FixPlayermodel();
 985
 986                 self.crouch = FALSE;
 987                 self.view_ofs = PL_VIEW_OFS;
 988                 setsize (self, PL_MIN, PL_MAX);
 989                 self.spawnorigin = spot.origin;
 990                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 991                 // don't reset back to last position, even if new position is stuck in solid
 992                 self.oldorigin = self.origin;
 993                 self.prevorigin = self.origin;
 994                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 995
 996                 if(g_arena)
 997                 {
 998                         Spawnqueue_Remove(self);
 999                         Spawnqueue_Mark(self);
1000                 }
1001
1002                 else if(g_ca)
1003                         self.caplayer = 1;
1004
1005                 self.event_damage = PlayerDamage;
1006
1007                 self.bot_attack = TRUE;
1008
1009                 self.statdraintime = time + 5;
1010                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1011
1012                 if(self.killcount == -666) {
1013                         PlayerScore_Clear(self);
1014                         self.killcount = 0;
1015                 }
1016
1017                 self.cnt = WEP_LASER;
1018
1019                 CL_SpawnWeaponentity();
1020                 self.alpha = default_player_alpha;
1021                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1022                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1023
1024                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1025                 self.lms_traveled_distance = 0;
1026                 self.speedrunning = FALSE;
1027
1028                 race_PostSpawn(spot);
1029
1030                 if(autocvar_spawn_debug)
1031                 {
1032                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1033                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1034                 }
1035
1036                 //stuffcmd(self, "chase_active 0");
1037                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1038
1039                 if (autocvar_g_spawnsound)
1040                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1041
1042                 if(g_assault) {
1043                         if(self.team == assault_attacker_team)
1044                                 centerprint(self, "You are attacking!");
1045                         else
1046                                 centerprint(self, "You are defending!");
1047                 }
1048
1049                 target_voicescript_clear(self);
1050
1051                 // reset fields the weapons may use
1052                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1053                         weapon_action(j, WR_RESETPLAYER);
1054
1055                 oldself = self;
1056                 self = spot;
1057                         activator = oldself;
1058                                 SUB_UseTargets();
1059                         activator = world;
1060                 self = oldself;
1061
1062                 MUTATOR_CALLHOOK(PlayerSpawn);
1063
1064                 self.switchweapon = w_getbestweapon(self);
1065                 self.cnt = self.switchweapon;
1066                 self.weapon = 0;
1067
1068         self.wish_reload = 0;
1069
1070                 if(!self.alivetime)
1071                         self.alivetime = time;
1072         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1073                 PutObserverInServer ();
1074         }
1075
1076         //if(g_ctf)
1077         //      ctf_playerchanged();
1078 }
1079
1080 .float ebouncefactor, ebouncestop; // electro's values
1081 // TODO do we need all these fields, or should we stop autodetecting runtime
1082 // changes and just have a console command to update this?
1083 float ClientInit_SendEntity(entity to, float sf)
1084 {
1085         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1086         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1088         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1089         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1090         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1091         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1099         if(sv_foginterval && world.fog != "")
1100                 WriteString(MSG_ENTITY, world.fog);
1101         else
1102                 WriteString(MSG_ENTITY, "");
1103         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1104         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1105         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1106         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1107         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1108         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1109         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1110         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1111         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1112         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_magazinecapacity); // rifle max bullets
1113         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1114         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1115         return TRUE;
1116 }
1117
1118 void ClientInit_CheckUpdate()
1119 {
1120         self.nextthink = time;
1121         if(self.count != autocvar_g_balance_armor_blockpercent)
1122         {
1123                 self.count = autocvar_g_balance_armor_blockpercent;
1124                 self.SendFlags |= 1;
1125         }
1126         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1127         {
1128                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1129                 self.SendFlags |= 1;
1130         }
1131         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1132         {
1133                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1134                 self.SendFlags |= 1;
1135         }
1136         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1137         {
1138                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1139                 self.SendFlags |= 1;
1140         }
1141         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1142         {
1143                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1144                 self.SendFlags |= 1;
1145         }
1146         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1147         {
1148                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1149                 self.SendFlags |= 1;
1150         }
1151 }
1152
1153 void ClientInit_Spawn()
1154 {
1155         entity o;
1156         entity e;
1157         e = spawn();
1158         e.classname = "clientinit";
1159         e.think = ClientInit_CheckUpdate;
1160         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1161
1162         o = self;
1163         self = e;
1164         ClientInit_CheckUpdate();
1165         self = o;
1166 }
1167
1168 /*
1169 =============
1170 SetNewParms
1171 =============
1172 */
1173 void SetNewParms (void)
1174 {
1175         // initialize parms for a new player
1176         parm1 = -(86400 * 366);
1177 }
1178
1179 /*
1180 =============
1181 SetChangeParms
1182 =============
1183 */
1184 void SetChangeParms (void)
1185 {
1186         // save parms for level change
1187         parm1 = self.parm_idlesince - time;
1188 }
1189
1190 /*
1191 =============
1192 DecodeLevelParms
1193 =============
1194 */
1195 void DecodeLevelParms (void)
1196 {
1197         // load parms
1198         self.parm_idlesince = parm1;
1199         if(self.parm_idlesince == -(86400 * 366))
1200                 self.parm_idlesince = time;
1201
1202         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1203         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1204 }
1205
1206 /*
1207 =============
1208 ClientKill
1209
1210 Called when a client types 'kill' in the console
1211 =============
1212 */
1213
1214 .float clientkill_nexttime;
1215 void ClientKill_Now_TeamChange()
1216 {
1217         if(self.killindicator_teamchange == -1)
1218         {
1219                 self.team = -1;
1220                 JoinBestTeam( self, FALSE, FALSE );
1221         }
1222         else if(self.killindicator_teamchange == -2)
1223         {
1224                 if(g_ca)
1225                         self.caplayer = 0;
1226                 if(blockSpectators)
1227                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1228                 PutObserverInServer();
1229         }
1230         else
1231                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1232 }
1233
1234 void ClientKill_Now()
1235 {
1236         remove(self.killindicator);
1237         self.killindicator = world;
1238
1239         if(self.killindicator_teamchange)
1240                 ClientKill_Now_TeamChange();
1241
1242         // in any case:
1243         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1244
1245         // now I am sure the player IS dead
1246 }
1247 void KillIndicator_Think()
1248 {
1249         if (!self.owner.modelindex)
1250         {
1251                 self.owner.killindicator = world;
1252                 remove(self);
1253                 return;
1254         }
1255
1256         if(self.cnt <= 0)
1257         {
1258                 self = self.owner;
1259                 ClientKill_Now(); // no oldself needed
1260                 return;
1261         }
1262     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1263     {
1264         self.nextthink = time + 1;
1265         self.cnt -= 1;
1266     }
1267         else
1268         {
1269                 if(self.cnt <= 10)
1270                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1271                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1272                 {
1273                         if(self.cnt <= 10)
1274                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1275                         if(self.owner.killindicator_teamchange)
1276                         {
1277                                 if(self.owner.killindicator_teamchange == -1)
1278                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1279                                 else if(self.owner.killindicator_teamchange == -2)
1280                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1281                                 else
1282                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1283                         }
1284                         else
1285                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1286                 }
1287                 self.nextthink = time + 1;
1288                 self.cnt -= 1;
1289         }
1290 }
1291
1292 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1293 {
1294         float killtime;
1295         entity e;
1296         killtime = autocvar_g_balance_kill_delay;
1297
1298         if(g_race_qualifying || g_cts)
1299                 killtime = 0;
1300
1301     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1302     {
1303                 remove(self.killindicator);
1304                 self.killindicator = world;
1305
1306         ClientKill_Now(); // allow instant kill in this case
1307         return;
1308     }
1309
1310         self.killindicator_teamchange = targetteam;
1311
1312     if(!self.killindicator)
1313         {
1314                 if(self.modelindex && self.deadflag == DEAD_NO)
1315                 {
1316                         killtime = max(killtime, self.clientkill_nexttime - time);
1317                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1318                 }
1319
1320                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1321                 {
1322                         ClientKill_Now();
1323                 }
1324                 else
1325                 {
1326                         self.killindicator = spawn();
1327                         self.killindicator.owner = self;
1328                         self.killindicator.scale = 0.5;
1329                         setattachment(self.killindicator, self, "");
1330                         setorigin(self.killindicator, '0 0 52');
1331                         self.killindicator.think = KillIndicator_Think;
1332                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1333                         self.killindicator.cnt = ceil(killtime);
1334                         self.killindicator.count = bound(0, ceil(killtime), 10);
1335                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1336
1337                         for(e = world; (e = find(e, classname, "body")) != world; )
1338                         {
1339                                 if(e.enemy != self)
1340                                         continue;
1341                                 e.killindicator = spawn();
1342                                 e.killindicator.owner = e;
1343                                 e.killindicator.scale = 0.5;
1344                                 setattachment(e.killindicator, e, "");
1345                                 setorigin(e.killindicator, '0 0 52');
1346                                 e.killindicator.think = KillIndicator_Think;
1347                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1348                                 e.killindicator.cnt = ceil(killtime);
1349                         }
1350                         self.lip = 0;
1351                 }
1352         }
1353         if(self.killindicator)
1354         {
1355                 if(targetteam == 0) // just die
1356                         self.killindicator.colormod = '0 0 0';
1357                 else if(targetteam == -1) // auto
1358                         self.killindicator.colormod = '0 1 0';
1359                 else if(targetteam == -2) // spectate
1360                         self.killindicator.colormod = '0.5 0.5 0.5';
1361                 else
1362                         self.killindicator.colormod = TeamColor(targetteam);
1363         }
1364 }
1365
1366 void ClientKill (void)
1367 {
1368         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1369         {
1370                 // do nothing
1371         }
1372     else if(self.freezetag_frozen)
1373     {
1374         // do nothing
1375     }
1376         else
1377                 ClientKill_TeamChange(0);
1378 }
1379
1380 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1381 {
1382     e.killindicator = spawn();
1383     e.killindicator.owner = e;
1384     e.killindicator.think = KillIndicator_Think;
1385     e.killindicator.nextthink = time + (e.lip) * 0.05;
1386     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1387     e.killindicator.health = 1; // this is used to indicate that it should be silent
1388     e.lip = 0;
1389 }
1390
1391 void DoTeamChange(float destteam)
1392 {
1393         float t, c0;
1394         if(!teams_matter)
1395         {
1396                 if(destteam >= 0)
1397                         SetPlayerColors(self, destteam);
1398                 return;
1399         }
1400         if(self.classname == "player")
1401         if(destteam == -1)
1402         {
1403                 CheckAllowedTeams(self);
1404                 t = FindSmallestTeam(self, TRUE);
1405                 switch(self.team)
1406                 {
1407                         case COLOR_TEAM1: c0 = c1; break;
1408                         case COLOR_TEAM2: c0 = c2; break;
1409                         case COLOR_TEAM3: c0 = c3; break;
1410                         case COLOR_TEAM4: c0 = c4; break;
1411                         default:          c0 = 999;
1412                 }
1413                 switch(t)
1414                 {
1415                         case 1:
1416                                 if(c0 > c1)
1417                                         destteam = COLOR_TEAM1;
1418                                 break;
1419                         case 2:
1420                                 if(c0 > c2)
1421                                         destteam = COLOR_TEAM2;
1422                                 break;
1423                         case 3:
1424                                 if(c0 > c3)
1425                                         destteam = COLOR_TEAM3;
1426                                 break;
1427                         case 4:
1428                                 if(c0 > c4)
1429                                         destteam = COLOR_TEAM4;
1430                                 break;
1431                 }
1432                 if(destteam == -1)
1433                         return;
1434         }
1435         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1436                 return;
1437         ClientKill_TeamChange(destteam);
1438 }
1439
1440 void FixClientCvars(entity e)
1441 {
1442         // send prediction settings to the client
1443         stuffcmd(e, "\nin_bindmap 0 0\n");
1444         if(g_race || g_cts)
1445                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1446         if(autocvar_g_antilag == 3) // client side hitscan
1447                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1448         if(sv_gentle)
1449                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1450         /*
1451          * we no longer need to stuff this. Remove this comment block if you feel
1452          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1453         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1454         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1455         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1456         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1457         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1458         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1459         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1460         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1461         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1462         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1463         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1464         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1465         stuffcmd(e, "cl_movement_edgefriction 1\n");
1466          */
1467 }
1468
1469 float PlayerInIDList(entity p, string idlist)
1470 {
1471         float n, i;
1472         string s;
1473
1474         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1475         if not(p.crypto_idfp)
1476                 return 0;
1477
1478         // this function allows abbreviated player IDs too!
1479         n = tokenize_console(idlist);
1480         for(i = 0; i < n; ++i)
1481         {
1482                 s = argv(i);
1483                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1484                         return 1;
1485         }
1486
1487         return 0;
1488 }
1489
1490 /*
1491 =============
1492 ClientConnect
1493
1494 Called when a client connects to the server
1495 =============
1496 */
1497 //void ctf_clientconnect();
1498 string ColoredTeamName(float t);
1499 void DecodeLevelParms (void);
1500 //void dom_player_join_team(entity pl);
1501 void ClientConnect (void)
1502 {
1503         float t;
1504
1505         if(self.flags & FL_CLIENT)
1506         {
1507                 print("Warning: ClientConnect, but already connected!\n");
1508                 return;
1509         }
1510
1511         if(Ban_MaybeEnforceBan(self))
1512                 return;
1513
1514         DecodeLevelParms();
1515
1516 #ifdef WATERMARK
1517         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1518 #endif
1519
1520         self.classname = "player_joining";
1521
1522         self.flags = FL_CLIENT;
1523         self.version_nagtime = time + 10 + random() * 10;
1524
1525         if(player_count<0)
1526         {
1527                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1528                 player_count = 0;
1529         }
1530
1531         PlayerScore_Attach(self);
1532         ClientData_Attach();
1533         accuracy_init(self);
1534
1535         bot_clientconnect();
1536
1537         playerdemo_init();
1538
1539         anticheat_init();
1540
1541         race_PreSpawnObserver();
1542
1543         //if(g_domination)
1544         //      dom_player_join_team(self);
1545
1546         // identify the right forced team
1547         if(autocvar_g_campaign)
1548         {
1549                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1550                 {
1551                         switch(autocvar_g_campaign_forceteam)
1552                         {
1553                                 case 1: self.team_forced = COLOR_TEAM1; break;
1554                                 case 2: self.team_forced = COLOR_TEAM2; break;
1555                                 case 3: self.team_forced = COLOR_TEAM3; break;
1556                                 case 4: self.team_forced = COLOR_TEAM4; break;
1557                                 default: self.team_forced = 0;
1558                         }
1559                 }
1560         }
1561         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1562                 self.team_forced = COLOR_TEAM1;
1563         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1564                 self.team_forced = COLOR_TEAM2;
1565         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1566                 self.team_forced = COLOR_TEAM3;
1567         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1568                 self.team_forced = COLOR_TEAM4;
1569         else if(autocvar_g_forced_team_otherwise == "red")
1570                 self.team_forced = COLOR_TEAM1;
1571         else if(autocvar_g_forced_team_otherwise == "blue")
1572                 self.team_forced = COLOR_TEAM2;
1573         else if(autocvar_g_forced_team_otherwise == "yellow")
1574                 self.team_forced = COLOR_TEAM3;
1575         else if(autocvar_g_forced_team_otherwise == "pink")
1576                 self.team_forced = COLOR_TEAM4;
1577         else if(autocvar_g_forced_team_otherwise == "spectate")
1578                 self.team_forced = -1;
1579         else if(autocvar_g_forced_team_otherwise == "spectator")
1580                 self.team_forced = -1;
1581         else
1582                 self.team_forced = 0;
1583
1584         if(!teams_matter)
1585                 if(self.team_forced > 0)
1586                         self.team_forced = 0;
1587
1588         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1589
1590         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1591                 self.classname = "observer";
1592         } else {
1593                 if(teams_matter)
1594                 {
1595                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1596                         {
1597                                 self.classname = "player";
1598                                 campaign_bots_may_start = 1;
1599                         }
1600                         else
1601                         {
1602                                 self.classname = "observer"; // do it anyway
1603                         }
1604                 }
1605                 else
1606                 {
1607                         self.classname = "player";
1608                         campaign_bots_may_start = 1;
1609                 }
1610         }
1611
1612         self.playerid = (playerid_last = playerid_last + 1);
1613
1614         if(autocvar_sv_eventlog)
1615                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1616
1617         LogTeamchange(self.playerid, self.team, 1);
1618
1619         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1620
1621         self.netname_previous = strzone(self.netname);
1622
1623         bprint("^4", self.netname, "^4 connected");
1624
1625         if(self.classname != "observer" && (g_domination || g_ctf))
1626                 bprint(" and joined the ", ColoredTeamName(self.team));
1627
1628         bprint("\n");
1629
1630         self.welcomemessage_time = 0;
1631
1632         stuffcmd(self, strcat(clientstuff, "\n"));
1633         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1634         stuffcmd(self, "cl_particles_reloadeffects\n");
1635
1636         FixClientCvars(self);
1637
1638         // spawnfunc_waypoint sprites
1639         WaypointSprite_InitClient(self);
1640
1641         // Wazat's grappling hook
1642         SetGrappleHookBindings();
1643
1644         // get autoswitch state from player when he toggles it
1645         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1646
1647         // get version info from player
1648         stuffcmd(self, "cmd clientversion $gameversion\n");
1649
1650         // get other cvars from player
1651         GetCvars(0);
1652
1653         // notify about available teams
1654         if(teams_matter)
1655         {
1656                 CheckAllowedTeams(self);
1657                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1658                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1659         }
1660         else
1661                 stuffcmd(self, "set _teams_available 0\n");
1662
1663         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1664
1665         if(g_arena || g_ca)
1666         {
1667                 self.classname = "observer";
1668                 if(g_arena)
1669                         Spawnqueue_Insert(self);
1670         }
1671         /*else if(g_ctf)
1672         {
1673                 ctf_clientconnect();
1674         }*/
1675
1676         if(teams_matter || radar_showennemies)
1677                 attach_entcs();
1678
1679         bot_relinkplayerlist();
1680
1681         self.spectatortime = time;
1682         if(blockSpectators)
1683         {
1684                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1685         }
1686
1687         self.jointime = time;
1688         self.allowedTimeouts = autocvar_sv_timeout_number;
1689
1690         if(clienttype(self) == CLIENTTYPE_REAL)
1691         {
1692                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1693                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1694         }
1695
1696         if(g_lms)
1697         {
1698                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1699                 {
1700                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1701                         self.frags = FRAGS_SPECTATOR;
1702                 }
1703         }
1704
1705         if(!sv_foginterval && world.fog != "")
1706                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1707
1708         SoundEntity_Attach(self);
1709
1710         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1711         {
1712                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1713                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1714         }
1715         else
1716                 self.hitplotfh = -1;
1717
1718         if(g_race || g_cts) {
1719                 string rr;
1720                 if(g_cts)
1721                         rr = CTS_RECORD;
1722                 else
1723                         rr = RACE_RECORD;
1724                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1725
1726                 msg_entity = self;
1727                 race_send_recordtime(MSG_ONE);
1728                 race_send_speedaward(MSG_ONE);
1729
1730                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1731                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1732                 race_send_speedaward_alltimebest(MSG_ONE);
1733
1734                 float i;
1735                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1736                         race_SendRankings(i, 0, 0, MSG_ONE);
1737                 }
1738         }
1739         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1740                 send_CSQC_teamnagger();
1741
1742         CheatInitClient();
1743
1744         PlayerStats_AddPlayer(self);
1745 }
1746
1747 /*
1748 =============
1749 ClientDisconnect
1750
1751 Called when a client disconnects from the server
1752 =============
1753 */
1754 .entity chatbubbleentity;
1755 .entity teambubbleentity;
1756 void ReadyCount();
1757 void ClientDisconnect (void)
1758 {
1759         if not(self.flags & FL_CLIENT)
1760         {
1761                 print("Warning: ClientDisconnect without ClientConnect\n");
1762                 return;
1763         }
1764
1765         PlayerStats_AddGlobalInfo(self);
1766
1767         CheatShutdownClient();
1768
1769         if(self.hitplotfh >= 0)
1770         {
1771                 fclose(self.hitplotfh);
1772                 self.hitplotfh = -1;
1773         }
1774
1775         anticheat_report();
1776         anticheat_shutdown();
1777
1778         playerdemo_shutdown();
1779
1780         bot_clientdisconnect();
1781
1782         if(self.entcs)
1783                 detach_entcs();
1784
1785         if(autocvar_sv_eventlog)
1786                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1787         bprint ("^4",self.netname);
1788         bprint ("^4 disconnected\n");
1789
1790         SoundEntity_Detach(self);
1791
1792         DropAllRunes(self);
1793         MUTATOR_CALLHOOK(ClientDisconnect);
1794
1795         Portal_ClearAll(self);
1796
1797         if(self.flagcarried)
1798                 DropFlag(self.flagcarried, world, world);
1799         if(self.ballcarried && g_nexball)
1800                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1801
1802         // Here, everything has been done that requires this player to be a client.
1803
1804         self.flags &~= FL_CLIENT;
1805
1806         if (self.chatbubbleentity)
1807                 remove (self.chatbubbleentity);
1808
1809         if (self.teambubbleentity)
1810                 remove (self.teambubbleentity);
1811
1812         if (self.killindicator)
1813                 remove (self.killindicator);
1814
1815         WaypointSprite_PlayerGone();
1816
1817         bot_relinkplayerlist();
1818
1819         if(g_arena)
1820         {
1821                 Spawnqueue_Unmark(self);
1822                 Spawnqueue_Remove(self);
1823         }
1824
1825         accuracy_free(self);
1826         ClientData_Detach();
1827         PlayerScore_Detach(self);
1828
1829         if(self.netname_previous)
1830                 strunzone(self.netname_previous);
1831         if(self.clientstatus)
1832                 strunzone(self.clientstatus);
1833         if(self.weaponorder_byimpulse)
1834                 strunzone(self.weaponorder_byimpulse);
1835
1836         ClearPlayerSounds();
1837
1838         if(self.personal)
1839                 remove(self.personal);
1840
1841         self.playerid = 0;
1842         ReadyCount();
1843
1844         // free cvars
1845         GetCvars(-1);
1846 }
1847
1848 .float BUTTON_CHAT;
1849 void ChatBubbleThink()
1850 {
1851         self.nextthink = time;
1852         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1853         {
1854                 if(self.owner) // but why can that ever be world?
1855                         self.owner.chatbubbleentity = world;
1856                 remove(self);
1857                 return;
1858         }
1859         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1860 #ifdef TETRIS
1861                 || self.owner.tetris_on
1862 #endif
1863         )
1864                 self.model = self.mdl;
1865         else
1866                 self.model = "";
1867 };
1868
1869 void UpdateChatBubble()
1870 {
1871         if (!self.modelindex)
1872                 return;
1873         // spawn a chatbubble entity if needed
1874         if (!self.chatbubbleentity)
1875         {
1876                 self.chatbubbleentity = spawn();
1877                 self.chatbubbleentity.owner = self;
1878                 self.chatbubbleentity.exteriormodeltoclient = self;
1879                 self.chatbubbleentity.think = ChatBubbleThink;
1880                 self.chatbubbleentity.nextthink = time;
1881                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1882                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1883                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1884                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1885                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1886                 self.chatbubbleentity.model = "";
1887                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1888         }
1889 }
1890
1891
1892 void TeamBubbleThink()
1893 {
1894         self.nextthink = time;
1895         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1896         {
1897                 if(self.owner) // but why can that ever be world?
1898                         self.owner.teambubbleentity = world;
1899                 remove(self);
1900                 return;
1901         }
1902 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1903         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1904                 self.model = "";
1905         else
1906                 self.model = self.mdl;
1907
1908 };
1909
1910 float TeamBubble_customizeentityforclient()
1911 {
1912         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1913 }
1914
1915 void UpdateTeamBubble()
1916 {
1917         if (!self.modelindex || !teams_matter)
1918                 return;
1919         // spawn a teambubble entity if needed
1920         if (!self.teambubbleentity && teams_matter)
1921         {
1922                 self.teambubbleentity = spawn();
1923                 self.teambubbleentity.owner = self;
1924                 self.teambubbleentity.exteriormodeltoclient = self;
1925                 self.teambubbleentity.think = TeamBubbleThink;
1926                 self.teambubbleentity.nextthink = time;
1927                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1928 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1929                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1930                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1931                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1932                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1933                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1934                 self.teambubbleentity.effects = EF_LOWPRECISION;
1935         }
1936 }
1937
1938 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1939 // added to the model skins
1940 /*void UpdateColorModHack()
1941 {
1942         local float c;
1943         c = self.clientcolors & 15;
1944         // LordHavoc: only bothering to support white, green, red, yellow, blue
1945              if (!teams_matter) self.colormod = '0 0 0';
1946         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1947         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1948         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1949         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1950         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1951         else self.colormod = '1 1 1';
1952 };*/
1953
1954 .float oldcolormap;
1955 void respawn(void)
1956 {
1957         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1958         {
1959                 self.solid = SOLID_NOT;
1960                 self.takedamage = DAMAGE_NO;
1961                 self.movetype = MOVETYPE_FLY;
1962                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1963                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1964                 self.effects |= EF_ADDITIVE;
1965                 self.oldcolormap = self.colormap;
1966                 self.colormap = 512;
1967                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1968                 if(autocvar_g_respawn_ghosts_maxtime)
1969                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1970         }
1971
1972         CopyBody(1);
1973         self.effects |= EF_NODRAW; // prevent another CopyBody
1974         if(self.oldcolormap)
1975         {
1976                 self.colormap = self.oldcolormap;
1977                 self.oldcolormap = 0;
1978         }
1979         PutClientInServer();
1980 }
1981
1982 void play_countdown(float finished, string samp)
1983 {
1984         if(clienttype(self) == CLIENTTYPE_REAL)
1985                 if(floor(finished - time - frametime) != floor(finished - time))
1986                         if(finished - time < 6)
1987                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1988 }
1989
1990 /**
1991  * When sv_timeout is used this function returs strings like
1992  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1993  * Called by centerprint functions
1994  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1995  */
1996 string getTimeoutText(float addOneSecond) {
1997         if (!autocvar_sv_timeout || !timeoutStatus)
1998                 return "";
1999
2000         local string retStr;
2001         if (timeoutStatus == 1) {
2002                 if (addOneSecond == 1) {
2003                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2004                 }
2005                 else {
2006                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2007                 }
2008                 return retStr;
2009         }
2010         else if (timeoutStatus == 2) {
2011                 if (addOneSecond) {
2012                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2013                         //don't show messages like "Timeout ends in 0 seconds"...
2014                         if ((remainingTimeoutTime + 1) > 0)
2015                                 return retStr;
2016                         else
2017                                 return "";
2018                 }
2019                 else {
2020                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2021                         //don't show messages like "Timeout ends in 0 seconds"...
2022                         if (remainingTimeoutTime > 0)
2023                                 return retStr;
2024                         else
2025                                 return "";
2026                 }
2027         }
2028         else return "";
2029 }
2030
2031 void player_powerups (void)
2032 {
2033         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2034         olditems = self.items;
2035
2036         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2037         {
2038                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2039                 self.modelflags |= MF_ROCKET;
2040         }
2041         else
2042         {
2043                 SoundEntity_StopSound(self, CHAN_PLAYER);
2044                 self.modelflags &~= MF_ROCKET;
2045         }
2046
2047         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2048
2049         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2050                 return;
2051
2052         Fire_ApplyDamage(self);
2053         Fire_ApplyEffect(self);
2054
2055         if (g_minstagib)
2056         {
2057                 self.effects |= EF_FULLBRIGHT;
2058
2059                 if (self.items & IT_STRENGTH)
2060                 {
2061                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2062                         if (time > self.strength_finished)
2063                         {
2064                                 self.alpha = default_player_alpha;
2065                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2066                                 self.items &~= IT_STRENGTH;
2067                                 sprint(self, "^3Invisibility has worn off\n");
2068                         }
2069                 }
2070                 else
2071                 {
2072                         if (time < self.strength_finished)
2073                         {
2074                                 self.alpha = g_minstagib_invis_alpha;
2075                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2076                                 self.items |= IT_STRENGTH;
2077                                 sprint(self, "^3You are invisible\n");
2078                         }
2079                 }
2080
2081                 if (self.items & IT_INVINCIBLE)
2082                 {
2083                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2084                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2085                         {
2086                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2087                                 sprint(self, "^3Speed has worn off\n");
2088                         }
2089                 }
2090                 else
2091                 {
2092                         if (time < self.invincible_finished)
2093                         {
2094                                 self.items = self.items | IT_INVINCIBLE;
2095                                 sprint(self, "^3You are on speed\n");
2096                         }
2097                 }
2098         }
2099         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2100         {
2101                 if (self.items & IT_STRENGTH)
2102                 {
2103                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2104                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2105                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2106                         {
2107                                 self.items = self.items - (self.items & IT_STRENGTH);
2108                                 sprint(self, "^3Strength has worn off\n");
2109                         }
2110                 }
2111                 else
2112                 {
2113                         if (time < self.strength_finished)
2114                         {
2115                                 self.items = self.items | IT_STRENGTH;
2116                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2117                         }
2118                 }
2119                 if (self.items & IT_INVINCIBLE)
2120                 {
2121                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2122                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2123                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2124                         {
2125                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2126                                 sprint(self, "^3Shield has worn off\n");
2127                         }
2128                 }
2129                 else
2130                 {
2131                         if (time < self.invincible_finished)
2132                         {
2133                                 self.items = self.items | IT_INVINCIBLE;
2134                                 sprint(self, "^3Shield surrounds you\n");
2135                         }
2136                 }
2137
2138                 if(autocvar_g_nodepthtestplayers)
2139                         self.effects = self.effects | EF_NODEPTHTEST;
2140
2141                 if(autocvar_g_fullbrightplayers)
2142                         self.effects = self.effects | EF_FULLBRIGHT;
2143
2144                 // midair gamemode: damage only while in the air
2145                 // if in midair mode, being on ground grants temporary invulnerability
2146                 // (this is so that multishot weapon don't clear the ground flag on the
2147                 // first damage in the frame, leaving the player vulnerable to the
2148                 // remaining hits in the same frame)
2149                 if (self.flags & FL_ONGROUND)
2150                 if (g_midair)
2151                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2152
2153                 if (time >= game_starttime)
2154                 if (time < self.spawnshieldtime)
2155                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2156         }
2157
2158         MUTATOR_CALLHOOK(PlayerPowerups);
2159 }
2160
2161 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2162 {
2163         if(current > stable)
2164                 return current;
2165         else if(current > stable - 0.25) // when close enough, "snap"
2166                 return stable;
2167         else
2168                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2169 }
2170
2171 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2172 {
2173         if(current < stable)
2174                 return current;
2175         else if(current < stable + 0.25) // when close enough, "snap"
2176                 return stable;
2177         else
2178                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2179 }
2180
2181 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2182 {
2183         if(current > rotstable)
2184         {
2185                 if(rotframetime > 0)
2186                 {
2187                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2188                         current = max(rotstable, current - rotlinear * rotframetime);
2189                 }
2190         }
2191         else if(current < regenstable)
2192         {
2193                 if(regenframetime > 0)
2194                 {
2195                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2196                         current = min(regenstable, current + regenlinear * regenframetime);
2197                 }
2198         }
2199
2200         if(current > limit)
2201                 current = limit;
2202
2203         return current;
2204 }
2205
2206 void player_regen (void)
2207 {
2208         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2209         maxh = autocvar_g_balance_health_rotstable;
2210         maxa = autocvar_g_balance_armor_rotstable;
2211         maxf = autocvar_g_balance_fuel_rotstable;
2212         minh = autocvar_g_balance_health_regenstable;
2213         mina = autocvar_g_balance_armor_regenstable;
2214         minf = autocvar_g_balance_fuel_regenstable;
2215         limith = autocvar_g_balance_health_limit;
2216         limita = autocvar_g_balance_armor_limit;
2217         limitf = autocvar_g_balance_fuel_limit;
2218
2219         max_mod = regen_mod = rot_mod = limit_mod = 1;
2220
2221         if (self.runes & RUNE_REGEN)
2222         {
2223                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2224                 {
2225                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2226                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2227                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2228                 }
2229                 else
2230                 {
2231                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2232                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2233                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2234                 }
2235         }
2236         else if (self.runes & CURSE_VENOM)
2237         {
2238                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2239                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2240                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2241                 else
2242                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2243                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2244                 //if (!self.runes & RUNE_REGEN)
2245                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2246         }
2247         maxh = maxh * max_mod;
2248         //maxa = maxa * max_mod;
2249         //maxf = maxf * max_mod;
2250         minh = minh * max_mod;
2251         //mina = mina * max_mod;
2252         //minf = minf * max_mod;
2253         limith = limith * limit_mod;
2254         limita = limita * limit_mod;
2255         //limitf = limitf * limit_mod;
2256
2257         if(g_lms && g_ca)
2258                 rot_mod = 0;
2259
2260         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2261         {
2262                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2263                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2264
2265                 // if player rotted to death...  die!
2266                 if(self.health < 1)
2267                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2268         }
2269
2270         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2271                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2272 }
2273
2274 float zoomstate_set;
2275 void SetZoomState(float z)
2276 {
2277         if(z != self.zoomstate)
2278         {
2279                 self.zoomstate = z;
2280                 ClientData_Touch(self);
2281         }
2282         zoomstate_set = 1;
2283 }
2284
2285 void GetPressedKeys(void) {
2286         MUTATOR_CALLHOOK(GetPressedKeys);
2287         if (self.movement_x > 0) // get if movement keys are pressed
2288         {       // forward key pressed
2289                 self.pressedkeys |= KEY_FORWARD;
2290                 self.pressedkeys &~= KEY_BACKWARD;
2291         }
2292         else if (self.movement_x < 0)
2293         {       // backward key pressed
2294                 self.pressedkeys |= KEY_BACKWARD;
2295                 self.pressedkeys &~= KEY_FORWARD;
2296         }
2297         else
2298         {       // no x input
2299                 self.pressedkeys &~= KEY_FORWARD;
2300                 self.pressedkeys &~= KEY_BACKWARD;
2301         }
2302
2303         if (self.movement_y > 0)
2304         {       // right key pressed
2305                 self.pressedkeys |= KEY_RIGHT;
2306                 self.pressedkeys &~= KEY_LEFT;
2307         }
2308         else if (self.movement_y < 0)
2309         {       // left key pressed
2310                 self.pressedkeys |= KEY_LEFT;
2311                 self.pressedkeys &~= KEY_RIGHT;
2312         }
2313         else
2314         {       // no y input
2315                 self.pressedkeys &~= KEY_RIGHT;
2316                 self.pressedkeys &~= KEY_LEFT;
2317         }
2318
2319         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2320                 self.pressedkeys |= KEY_JUMP;
2321         else
2322                 self.pressedkeys &~= KEY_JUMP;
2323         if (self.BUTTON_CROUCH)
2324                 self.pressedkeys |= KEY_CROUCH;
2325         else
2326                 self.pressedkeys &~= KEY_CROUCH;
2327 }
2328
2329 /*
2330 ======================
2331 spectate mode routines
2332 ======================
2333 */
2334
2335 void SpectateCopy(entity spectatee) {
2336         other = spectatee;
2337         MUTATOR_CALLHOOK(SpectateCopy);
2338         self.armortype = spectatee.armortype;
2339         self.armorvalue = spectatee.armorvalue;
2340         self.ammo_cells = spectatee.ammo_cells;
2341         self.ammo_shells = spectatee.ammo_shells;
2342         self.ammo_nails = spectatee.ammo_nails;
2343         self.ammo_rockets = spectatee.ammo_rockets;
2344         self.ammo_fuel = spectatee.ammo_fuel;
2345         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2346         self.health = spectatee.health;
2347         self.impulse = 0;
2348         self.items = spectatee.items;
2349         self.last_pickup = spectatee.last_pickup;
2350         self.hit_time = spectatee.hit_time;
2351         self.metertime = spectatee.metertime;
2352         self.strength_finished = spectatee.strength_finished;
2353         self.invincible_finished = spectatee.invincible_finished;
2354         self.pressedkeys = spectatee.pressedkeys;
2355         self.weapons = spectatee.weapons;
2356         self.switchweapon = spectatee.switchweapon;
2357         self.weapon = spectatee.weapon;
2358         self.nex_charge = spectatee.nex_charge;
2359         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2360         self.sniperrifle_bulletcounter = spectatee.sniperrifle_bulletcounter;
2361         self.minelayer_mines = spectatee.minelayer_mines;
2362         self.punchangle = spectatee.punchangle;
2363         self.view_ofs = spectatee.view_ofs;
2364         self.v_angle = spectatee.v_angle;
2365         self.velocity = spectatee.velocity;
2366         self.dmg_take = spectatee.dmg_take;
2367         self.dmg_save = spectatee.dmg_save;
2368         self.dmg_inflictor = spectatee.dmg_inflictor;
2369         self.angles = spectatee.v_angle;
2370         self.fixangle = TRUE;
2371         setorigin(self, spectatee.origin);
2372         setsize(self, spectatee.mins, spectatee.maxs);
2373         SetZoomState(spectatee.zoomstate);
2374
2375         anticheat_spectatecopy(spectatee);
2376 }
2377
2378 float SpectateUpdate() {
2379         if(!self.enemy)
2380                 return 0;
2381
2382         if (self == self.enemy)
2383                 return 0;
2384
2385         if(self.enemy.classname != "player")
2386                 return 0;
2387
2388         SpectateCopy(self.enemy);
2389
2390         return 1;
2391 }
2392
2393 float SpectateNext() {
2394         other = find(self.enemy, classname, "player");
2395
2396         if (!other)
2397                 other = find(other, classname, "player");
2398
2399         if (other)
2400                 self.enemy = other;
2401
2402         if(self.enemy.classname == "player") {
2403                 msg_entity = self;
2404                 WriteByte(MSG_ONE, SVC_SETVIEW);
2405                 WriteEntity(MSG_ONE, self.enemy);
2406                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2407                 self.movetype = MOVETYPE_NONE;
2408                 accuracy_resend(self);
2409
2410                 if(!SpectateUpdate())
2411                         PutObserverInServer();
2412
2413                 return 1;
2414         } else {
2415                 return 0;
2416         }
2417 }
2418
2419 /*
2420 =============
2421 ShowRespawnCountdown()
2422
2423 Update a respawn countdown display.
2424 =============
2425 */
2426 void ShowRespawnCountdown()
2427 {
2428         float number;
2429         if(self.deadflag == DEAD_NO) // just respawned?
2430                 return;
2431         else
2432         {
2433                 number = ceil(self.death_time - time);
2434                 if(number <= 0)
2435                         return;
2436                 if(number <= self.respawn_countdown)
2437                 {
2438                         self.respawn_countdown = number - 1;
2439                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2440                                 AnnounceTo(self, strcat(ftos(number), ""));
2441                 }
2442         }
2443 }
2444
2445 void LeaveSpectatorMode()
2446 {
2447         if(nJoinAllowed(1)) {
2448                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2449                         self.classname = "player";
2450
2451                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2452                                 JoinBestTeam(self, FALSE, TRUE);
2453
2454                         if(autocvar_g_campaign)
2455                                 campaign_bots_may_start = 1;
2456
2457                         PutClientInServer();
2458
2459                         if(self.classname == "player")
2460                                 bprint ("^4", self.netname, "^4 is playing now\n");
2461
2462                         if(!autocvar_g_campaign)
2463                                 centerprint(self,""); // clear MOTD
2464
2465                         return;
2466                 } else {
2467                         if (g_ca && self.caplayer) {
2468                         }       // do nothing
2469                         else
2470                                 stuffcmd(self,"menu_showteamselect\n");
2471                         return;
2472                 }
2473         }
2474         else {
2475                 //player may not join because of g_maxplayers is set
2476                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2477         }
2478 }
2479
2480 /**
2481  * Determines whether the player is allowed to join. This depends on cvar
2482  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2483  * it checks whether the number of currently playing players exceeds g_maxplayers.
2484  * @return int number of free slots for players, 0 if none
2485  */
2486 float nJoinAllowed(float includeMe) {
2487         if(self.team_forced < 0)
2488                 return FALSE; // forced spectators can never join
2489
2490         // TODO simplify this
2491         local entity e;
2492
2493         local float totalClients;
2494         FOR_EACH_CLIENT(e)
2495                 totalClients += 1;
2496
2497         if (!autocvar_g_maxplayers)
2498                 return maxclients - totalClients + includeMe;
2499
2500         local float currentlyPlaying;
2501         FOR_EACH_REALPLAYER(e)
2502                 currentlyPlaying += 1;
2503
2504         if(currentlyPlaying < autocvar_g_maxplayers)
2505                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2506
2507         return 0;
2508 }
2509
2510 /**
2511  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2512  * g_maxplayers_spectator_blocktime seconds
2513  */
2514 void checkSpectatorBlock() {
2515         if(self.classname == "spectator" || self.classname == "observer") {
2516                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2517                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2518                         dropclient(self);
2519                 }
2520         }
2521 }
2522
2523 void ObserverThink()
2524 {
2525         if (self.flags & FL_JUMPRELEASED) {
2526                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2527                         self.welcomemessage_time = 0;
2528                         self.flags &~= FL_JUMPRELEASED;
2529                         self.flags |= FL_SPAWNING;
2530                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2531                         self.welcomemessage_time = 0;
2532                         self.flags &~= FL_JUMPRELEASED;
2533                         if(SpectateNext() == 1) {
2534                                 self.classname = "spectator";
2535                         }
2536                 }
2537         } else {
2538                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2539                         self.flags |= FL_JUMPRELEASED;
2540                         if(self.flags & FL_SPAWNING)
2541                         {
2542                                 self.flags &~= FL_SPAWNING;
2543                                 LeaveSpectatorMode();
2544                                 return;
2545                         }
2546                 }
2547         }
2548         PrintWelcomeMessage(self);
2549 }
2550
2551 void SpectatorThink()
2552 {
2553         if (self.flags & FL_JUMPRELEASED) {
2554                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2555                         self.welcomemessage_time = 0;
2556                         self.flags &~= FL_JUMPRELEASED;
2557                         self.flags |= FL_SPAWNING;
2558                 } else if(self.BUTTON_ATCK) {
2559                         self.welcomemessage_time = 0;
2560                         self.flags &~= FL_JUMPRELEASED;
2561                         if(SpectateNext() == 1) {
2562                                 self.classname = "spectator";
2563                         } else {
2564                                 self.classname = "observer";
2565                                 PutClientInServer();
2566                         }
2567                 } else if (self.BUTTON_ATCK2) {
2568                         self.welcomemessage_time = 0;
2569                         self.flags &~= FL_JUMPRELEASED;
2570                         self.classname = "observer";
2571                         PutClientInServer();
2572                 } else {
2573                         if(!SpectateUpdate())
2574                                 PutObserverInServer();
2575                 }
2576         } else {
2577                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2578                         self.flags |= FL_JUMPRELEASED;
2579                         if(self.flags & FL_SPAWNING)
2580                         {
2581                                 self.flags &~= FL_SPAWNING;
2582                                 LeaveSpectatorMode();
2583                                 return;
2584                         }
2585                 }
2586         }
2587
2588         PrintWelcomeMessage(self);
2589         self.flags |= FL_CLIENT | FL_NOTARGET;
2590 }
2591
2592 .float touchexplode_time;
2593
2594 /*
2595 =============
2596 PlayerPreThink
2597
2598 Called every frame for each client before the physics are run
2599 =============
2600 */
2601 void() ctf_setstatus;
2602 void() nexball_setstatus;
2603 .float items_added;
2604 void PlayerPreThink (void)
2605 {
2606         self.stat_game_starttime = game_starttime;
2607         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2608         self.stat_leadlimit = autocvar_leadlimit;
2609
2610         if(frametime)
2611         {
2612                 // physics frames: update anticheat stuff
2613                 anticheat_prethink();
2614         }
2615
2616         if(blockSpectators && frametime)
2617                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2618                 checkSpectatorBlock();
2619
2620         zoomstate_set = 0;
2621
2622         if(self.netname_previous != self.netname)
2623         {
2624                 if(autocvar_sv_eventlog)
2625                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2626                 if(self.netname_previous)
2627                         strunzone(self.netname_previous);
2628                 self.netname_previous = strzone(self.netname);
2629         }
2630
2631         // version nagging
2632         if(self.version_nagtime)
2633                 if(self.cvar_g_xonoticversion)
2634                         if(time > self.version_nagtime)
2635                         {
2636                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2637                                 {
2638                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2639                                         {
2640                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2641                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2642                                         }
2643                                         else
2644                                         {
2645                                                 float r;
2646                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2647                                                 if(r < 0)
2648                                                 {
2649                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2650                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2651                                                 }
2652                                                 else if(r > 0)
2653                                                 {
2654                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2655                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2656                                                 }
2657                                         }
2658                                 }
2659                                 self.version_nagtime = 0;
2660                         }
2661
2662         // GOD MODE info
2663         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2664         {
2665                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2666                 self.max_armorvalue = 0;
2667         }
2668
2669 #ifdef TETRIS
2670         if (TetrisPreFrame())
2671                 return;
2672 #endif
2673
2674         MUTATOR_CALLHOOK(PlayerPreThink);
2675
2676         if(self.classname == "player") {
2677 //              if(self.netname == "Wazat")
2678 //                      bprint(self.classname, "\n");
2679
2680                 CheckRules_Player();
2681
2682                 PrintWelcomeMessage(self);
2683
2684                 if (intermission_running)
2685                 {
2686                         IntermissionThink ();   // otherwise a button could be missed between
2687                         return;                                 // the think tics
2688                 }
2689
2690                 if(self.teleport_time)
2691                 if(time > self.teleport_time)
2692                 {
2693                         self.teleport_time = 0;
2694                         self.effects = self.effects - (self.effects & EF_NODRAW);
2695                 }
2696
2697                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2698                         UpdateSelectedPlayer();
2699
2700                 //don't allow the player to turn around while game is paused!
2701                 if(timeoutStatus == 2) {
2702                         self.v_angle = self.lastV_angle;
2703                         self.angles = self.lastV_angle;
2704                         self.fixangle = TRUE;
2705                 }
2706
2707                 if(frametime)
2708                 {
2709                         if(self.health <= 0 && autocvar_g_deathglow)
2710                         {
2711                                 if(self.glowmod_x > 0)
2712                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2713                                 else
2714                                         self.glowmod_x = -1;
2715                                 if(self.glowmod_y > 0)
2716                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2717                                 else
2718                                         self.glowmod_y = -1;
2719                                 if(self.glowmod_z > 0)
2720                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2721                                 else
2722                                         self.glowmod_z = -1;
2723                         }
2724                         else
2725                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2726                         player_powerups();
2727                 }
2728
2729                 if (self.deadflag != DEAD_NO)
2730                 {
2731                         float button_pressed, force_respawn;
2732                         if(self.personal && g_race_qualifying)
2733                         {
2734                                 if(time > self.death_time)
2735                                 {
2736                                         self.death_time = time + 1; // only retry once a second
2737                                         respawn();
2738                                         self.impulse = 141;
2739                                 }
2740                         }
2741                         else
2742                         {
2743                                 if(frametime)
2744                                         player_anim();
2745                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2746                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2747                                 if (self.deadflag == DEAD_DYING)
2748                                 {
2749                                         if(force_respawn)
2750                                                 self.deadflag = DEAD_RESPAWNING;
2751                                         else if(!button_pressed)
2752                                                 self.deadflag = DEAD_DEAD;
2753                                 }
2754                                 else if (self.deadflag == DEAD_DEAD)
2755                                 {
2756                                         if(button_pressed)
2757                                                 self.deadflag = DEAD_RESPAWNABLE;
2758                                 }
2759                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2760                                 {
2761                                         if(!button_pressed)
2762                                                 self.deadflag = DEAD_RESPAWNING;
2763                                 }
2764                                 else if (self.deadflag == DEAD_RESPAWNING)
2765                                 {
2766                                         if(time > self.death_time)
2767                                         {
2768                                                 self.death_time = time + 1; // only retry once a second
2769                                                 respawn();
2770                                         }
2771                                 }
2772                                 ShowRespawnCountdown();
2773                         }
2774                         return;
2775                 }
2776
2777                 if(g_touchexplode)
2778                 if(time > self.touchexplode_time)
2779                 if(self.classname == "player")
2780                 if(self.deadflag == DEAD_NO)
2781                 if not(IS_INDEPENDENT_PLAYER(self))
2782                 FOR_EACH_PLAYER(other) if(self != other)
2783                 {
2784                         if(time > other.touchexplode_time)
2785                         if(other.deadflag == DEAD_NO)
2786                         if not(IS_INDEPENDENT_PLAYER(other))
2787                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2788                         {
2789                                 PlayerTouchExplode(self, other);
2790                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2791                         }
2792                 }
2793
2794                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2795                 {
2796                         vector dist;
2797
2798                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2799                         dist = self.prevorigin - self.origin;
2800                         dist_z = 0;
2801                         self.lms_traveled_distance += fabs(vlen(dist));
2802
2803                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2804                         {
2805                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2806                                 self.lms_traveled_distance = 0;
2807                         }
2808
2809                         if(time > self.lms_nextcheck)
2810                         {
2811                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2812                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2813                                 {
2814                                         centerprint(self, autocvar_g_lms_campcheck_message);
2815                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2816                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2817                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2818                                 }
2819                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2820                                 self.lms_traveled_distance = 0;
2821                         }
2822                 }
2823
2824                 self.prevorigin = self.origin;
2825
2826                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2827                 {
2828                         if (!self.crouch)
2829                         {
2830                                 self.crouch = TRUE;
2831                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2832                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2833                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2834                         }
2835                 }
2836                 else
2837                 {
2838                         if (self.crouch)
2839                         {
2840                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2841                                 if (!trace_startsolid)
2842                                 {
2843                                         self.crouch = FALSE;
2844                                         self.view_ofs = PL_VIEW_OFS;
2845                                         setsize (self, PL_MIN, PL_MAX);
2846                                 }
2847                         }
2848                 }
2849
2850                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2851                 {
2852                         if(self.bloodloss_timer < time)
2853                         {
2854                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2855                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2856                         }
2857                 }
2858
2859                 FixPlayermodel();
2860
2861                 GrapplingHookFrame();
2862
2863                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2864                 //if(frametime)
2865                 {
2866                         self.items &~= self.items_added;
2867
2868                         W_WeaponFrame();
2869
2870                         self.items_added = 0;
2871                         if(self.items & IT_JETPACK)
2872                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2873                                         self.items_added |= IT_FUEL;
2874
2875                         self.items |= self.items_added;
2876                 }
2877
2878                 player_regen();
2879
2880                 // rot nex charge to the charge limit
2881                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2882                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2883
2884                 if(frametime)
2885                         player_anim();
2886
2887                 if (g_minstagib)
2888                         minstagib_ammocheck();
2889
2890                 if(g_ctf)
2891                         ctf_setstatus();
2892
2893                 if(g_nexball)
2894                         nexball_setstatus();
2895
2896                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2897
2898                 //self.angles_y=self.v_angle_y + 90;   // temp
2899         } else if(gameover) {
2900                 if (intermission_running)
2901                         IntermissionThink ();   // otherwise a button could be missed between
2902                 return;
2903         } else if(self.classname == "observer") {
2904                 ObserverThink();
2905         } else if(self.classname == "spectator") {
2906                 SpectatorThink();
2907         }
2908
2909         if(!zoomstate_set)
2910                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2911
2912         float oldspectatee_status;
2913         oldspectatee_status = self.spectatee_status;
2914         if(self.classname == "spectator")
2915                 self.spectatee_status = num_for_edict(self.enemy);
2916         else if(self.classname == "observer")
2917                 self.spectatee_status = num_for_edict(self);
2918         else
2919                 self.spectatee_status = 0;
2920         if(self.spectatee_status != oldspectatee_status)
2921         {
2922                 ClientData_Touch(self);
2923                 if(g_race || g_cts)
2924                         race_InitSpectator();
2925         }
2926
2927         if(self.teamkill_soundtime)
2928         if(time > self.teamkill_soundtime)
2929         {
2930                 self.teamkill_soundtime = 0;
2931
2932                 entity oldpusher, oldself;
2933
2934                 oldself = self; self = self.teamkill_soundsource;
2935                 oldpusher = self.pusher; self.pusher = oldself;
2936
2937                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2938
2939                 self.pusher = oldpusher;
2940                 self = oldself;
2941         }
2942
2943         if(self.taunt_soundtime)
2944         if(time > self.taunt_soundtime)
2945         {
2946                 self.taunt_soundtime = 0;
2947                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2948         }
2949
2950         target_voicescript_next(self);
2951 }
2952
2953 float isInvisibleString(string s)
2954 {
2955         float i, n, c;
2956         s = strdecolorize(s);
2957         for((i = 0), (n = strlen(s)); i < n; ++i)
2958         {
2959                 c = str2chr(s, i);
2960                 switch(c)
2961                 {
2962                         case 0:
2963                         case 32: // space
2964                                 break;
2965                         case 192: // charmap space
2966                                 if (!autocvar_utf8_enable)
2967                                         break;
2968                                 return FALSE;
2969                         case 160: // space in unicode fonts
2970                         case 0xE000 + 192: // utf8 charmap space
2971                                 if (autocvar_utf8_enable)
2972                                         break;
2973                         default:
2974                                 return FALSE;
2975                 }
2976         }
2977         return TRUE;
2978 }
2979
2980 /*
2981 =============
2982 PlayerPostThink
2983
2984 Called every frame for each client after the physics are run
2985 =============
2986 */
2987 .float idlekick_lasttimeleft;
2988 .entity showheadshotbbox;
2989 void showheadshotbbox_think()
2990 {
2991         if(self.owner.showheadshotbbox != self)
2992         {
2993                 remove(self);
2994                 return;
2995         }
2996         self.nextthink = time;
2997         setorigin(self, self.owner.origin);
2998         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2999 }
3000 void PlayerPostThink (void)
3001 {
3002         // Savage: Check for nameless players
3003         if (isInvisibleString(self.netname)) {
3004                 self.netname = "Player";
3005                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3006         }
3007
3008         if(sv_maxidle && frametime)
3009         {
3010                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3011                 float timeleft;
3012                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3013                 if(timeleft <= 0)
3014                 {
3015                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3016                         AnnounceTo(self, "terminated");
3017                         dropclient(self);
3018                         return;
3019                 }
3020                 else if(timeleft <= 10)
3021                 {
3022                         if(timeleft != self.idlekick_lasttimeleft)
3023                         {
3024                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3025                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3026                         }
3027                 }
3028                 else
3029                 {
3030                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3031                 }
3032                 self.idlekick_lasttimeleft = timeleft;
3033         }
3034
3035 #ifdef TETRIS
3036         if(self.impulse == 100)
3037                 ImpulseCommands();
3038         if (TetrisPostFrame())
3039                 return;
3040 #endif
3041
3042         CheatFrame();
3043
3044         if(self.classname == "player") {
3045                 CheckRules_Player();
3046                 UpdateChatBubble();
3047                 UpdateTeamBubble();
3048                 if (self.impulse)
3049                         ImpulseCommands();
3050                 if (intermission_running)
3051                         return;         // intermission or finale
3052                 GetPressedKeys();
3053         } else if (self.classname == "observer") {
3054                 //do nothing
3055         } else if (self.classname == "spectator") {
3056                 //do nothing
3057         }
3058
3059         /*
3060         float i;
3061         for(i = 0; i < 1000; ++i)
3062         {
3063                 vector end;
3064                 end = self.origin + '0 0 1024' + 512 * randomvec();
3065                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3066                 if(trace_fraction < 1)
3067                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3068                 {
3069                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3070                         break;
3071                 }
3072         }
3073         */
3074
3075         Arena_Warmup();
3076
3077         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3078
3079         if(self.waypointsprite_attachedforcarrier)
3080                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3081
3082         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3083         {
3084                 if(!self.showheadshotbbox)
3085                 {
3086                         self.showheadshotbbox = spawn();
3087                         self.showheadshotbbox.classname = "headshotbbox";
3088                         self.showheadshotbbox.owner = self;
3089                         self.showheadshotbbox.think = showheadshotbbox_think;
3090                         self.showheadshotbbox.nextthink = time;
3091                         self = self.showheadshotbbox;
3092                         self.think();
3093                         self = self.owner;
3094                 }
3095         }
3096         else
3097         {
3098                 if(self.showheadshotbbox)
3099                         remove(self.showheadshotbbox);
3100         }
3101
3102         playerdemo_write();
3103
3104         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3105         {
3106                 if(!self.stored_netname)
3107                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3108                 if(self.stored_netname != self.netname)
3109                 {
3110                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3111                         strunzone(self.stored_netname);
3112                         self.stored_netname = strzone(self.netname);
3113                 }
3114         }
3115
3116         /*
3117         if(g_race)
3118                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3119         */
3120 }