qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap();
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         if (g_minstagib)
 408                 minstagib_stop_countdown();
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         if(self.ballcarried && g_nexball)
 425                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 426
 427         WaypointSprite_PlayerDead();
 428
 429         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 430                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 431
 432         if(self.killcount != -666) {
 433                 if(g_lms) {
 434                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 435                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 436                         else
 437                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 438                 } else
 439                         bprint ("^4", self.netname, "^4 is spectating now\n");
 440
 441                 if(self.just_joined == FALSE) {
 442                         LogTeamchange(self.playerid, -1, 4);
 443                 } else
 444                         self.just_joined = FALSE;
 445         }
 446
 447         PlayerScore_Clear(self); // clear scores when needed
 448
 449         accuracy_resend(self);
 450
 451         self.spectatortime = time;
 452
 453         self.classname = "observer";
 454         self.iscreature = FALSE;
 455         self.damagedbycontents = FALSE;
 456         self.health = -666;
 457         self.takedamage = DAMAGE_NO;
 458         self.solid = SOLID_NOT;
 459         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 460         self.flags = FL_CLIENT | FL_NOTARGET;
 461         self.armorvalue = 666;
 462         self.effects = 0;
 463         self.armorvalue = autocvar_g_balance_armor_start;
 464         self.pauserotarmor_finished = 0;
 465         self.pauserothealth_finished = 0;
 466         self.pauseregen_finished = 0;
 467         self.damageforcescale = 0;
 468         self.death_time = 0;
 469         self.dead_frame = 0;
 470         self.alpha = 0;
 471         self.scale = 0;
 472         self.fade_time = 0;
 473         self.pain_frame = 0;
 474         self.pain_finished = 0;
 475         self.strength_finished = 0;
 476         self.invincible_finished = 0;
 477         self.pushltime = 0;
 478         self.think = SUB_Null;
 479         self.nextthink = 0;
 480         self.hook_time = 0;
 481         self.runes = 0;
 482         self.deadflag = DEAD_NO;
 483         self.angles = spot.angles;
 484         self.angles_z = 0;
 485         self.fixangle = TRUE;
 486         self.crouch = FALSE;
 487
 488         setorigin (self, spot.origin);
 489         self.prevorigin = self.origin;
 490         self.items = 0;
 491         self.weapons = 0;
 492         self.model = "";
 493         FixPlayermodel();
 494         setmodel(self, "null");
 495         self.drawonlytoclient = self;
 496
 497         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 498         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 499
 500         self.weapon = 0;
 501         self.weaponname = "";
 502         self.switchingweapon = 0;
 503         self.weaponmodel = "";
 504         self.weaponentity = world;
 505         self.exteriorweaponentity = world;
 506         self.killcount = -666;
 507         self.velocity = '0 0 0';
 508         self.avelocity = '0 0 0';
 509         self.punchangle = '0 0 0';
 510         self.punchvector = '0 0 0';
 511         self.oldvelocity = self.velocity;
 512         self.fire_endtime = -1;
 513
 514         if(g_arena)
 515         {
 516                 if(self.version_mismatch)
 517                 {
 518                         Spawnqueue_Unmark(self);
 519                         Spawnqueue_Remove(self);
 520                 }
 521                 else
 522                 {
 523                         Spawnqueue_Insert(self);
 524                 }
 525         }
 526         else if(g_lms)
 527         {
 528                 // Only if the player cannot play at all
 529                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 530                         self.frags = FRAGS_SPECTATOR;
 531                 else
 532                         self.frags = FRAGS_LMS_LOSER;
 533         }
 534         else if(g_ca)
 535         {
 536                 if(self.caplayer)
 537                         self.frags = FRAGS_LMS_LOSER;
 538                 else
 539                         self.frags = FRAGS_SPECTATOR;
 540         }
 541         else
 542                 self.frags = FRAGS_SPECTATOR;
 543 }
 544
 545 .float model_randomizer;
 546 void FixPlayermodel()
 547 {
 548         string defaultmodel;
 549         float defaultskin, chmdl, oldskin, n, i;
 550         vector m1, m2;
 551
 552         defaultmodel = "";
 553
 554         if(autocvar_sv_defaultcharacter == 1)
 555         {
 556                 defaultskin = 0;
 557
 558                 if(teamplay)
 559                 {
 560                         string s;
 561                         s = Team_ColorNameLowerCase(self.team);
 562                         if(s != "neutral")
 563                         {
 564                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 565                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 566                         }
 567                 }
 568
 569                 if(defaultmodel == "")
 570                 {
 571                         defaultmodel = autocvar_sv_defaultplayermodel;
 572                         defaultskin = autocvar_sv_defaultplayerskin;
 573                 }
 574
 575                 n = tokenize_console(defaultmodel);
 576                 if(n > 0)
 577                         defaultmodel = argv(floor(n * self.model_randomizer));
 578
 579                 i = strstrofs(defaultmodel, ":", 0);
 580                 if(i >= 0)
 581                 {
 582                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 583                         defaultmodel = substring(defaultmodel, 0, i);
 584                 }
 585         }
 586
 587         if(defaultmodel != "")
 588         {
 589                 if (defaultmodel != self.model)
 590                 {
 591                         m1 = self.mins;
 592                         m2 = self.maxs;
 593                         setplayermodel (self, defaultmodel);
 594                         setsize (self, m1, m2);
 595                         chmdl = TRUE;
 596                 }
 597
 598                 oldskin = self.skin;
 599                 self.skin = defaultskin;
 600         } else {
 601                 if (self.playermodel != self.model || self.playermodel == "")
 602                 {
 603                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 604                         m1 = self.mins;
 605                         m2 = self.maxs;
 606                         setplayermodel (self, self.playermodel);
 607                         setsize (self, m1, m2);
 608                         chmdl = TRUE;
 609                 }
 610
 611                 oldskin = self.skin;
 612                 self.skin = stof(self.playerskin);
 613         }
 614
 615         if(chmdl || oldskin != self.skin)
 616                 self.species = player_getspecies(); // model or skin has changed
 617
 618         if(!teamplay)
 619                 if(strlen(autocvar_sv_defaultplayercolors))
 620                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 621                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 622 }
 623
 624 void PlayerTouchExplode(entity p1, entity p2)
 625 {
 626         vector org;
 627         org = (p1.origin + p2.origin) * 0.5;
 628         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 629
 630         te_explosion(org);
 631
 632         entity e;
 633         e = spawn();
 634         setorigin(e, org);
 635         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 636         remove(e);
 637 }
 638
 639 /*
 640 =============
 641 PutClientInServer
 642
 643 Called when a client spawns in the server
 644 =============
 645 */
 646 //void() ctf_playerchanged;
 647 void PutClientInServer (void)
 648 {
 649         if(clienttype(self) == CLIENTTYPE_BOT)
 650         {
 651                 self.classname = "player";
 652         }
 653         else if(clienttype(self) == CLIENTTYPE_REAL)
 654         {
 655                 msg_entity = self;
 656                 WriteByte(MSG_ONE, SVC_SETVIEW);
 657                 WriteEntity(MSG_ONE, self);
 658         }
 659
 660         // reset player keys
 661         self.itemkeys = 0;
 662
 663         // player is dead and becomes observer
 664         // FIXME fix LMS scoring for new system
 665         if(g_lms)
 666         {
 667                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 668                         self.classname = "observer";
 669         }
 670
 671         if(g_arena || (g_ca && !allowed_to_spawn))
 672         if(!self.spawned)
 673                 self.classname = "observer";
 674
 675         if(gameover)
 676                 self.classname = "observer";
 677
 678         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 679                 entity spot, oldself;
 680                 float j;
 681
 682                 accuracy_resend(self);
 683
 684                 if(self.team < 0)
 685                         JoinBestTeam(self, FALSE, TRUE);
 686
 687                 race_PreSpawn();
 688
 689                 spot = SelectSpawnPoint (FALSE);
 690                 if(!spot)
 691                 {
 692                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 693                         return; // spawn failed
 694                 }
 695
 696                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 697
 698                 self.classname = "player";
 699                 self.wasplayer = TRUE;
 700                 self.iscreature = TRUE;
 701                 self.damagedbycontents = TRUE;
 702                 self.movetype = MOVETYPE_WALK;
 703                 self.solid = SOLID_SLIDEBOX;
 704                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 705                 if(autocvar_g_playerclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 707                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 708                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 709                 self.frags = FRAGS_PLAYER;
 710                 if(INDEPENDENT_PLAYERS)
 711                         MAKE_INDEPENDENT_PLAYER(self);
 712                 self.flags = FL_CLIENT;
 713                 if(autocvar__notarget)
 714                         self.flags |= FL_NOTARGET;
 715                 self.takedamage = DAMAGE_AIM;
 716                 if(g_minstagib)
 717                         self.effects = EF_FULLBRIGHT;
 718                 else
 719                         self.effects = 0;
 720                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 721                 self.air_finished = time + 12;
 722                 self.dmg = 2;
 723                 if(autocvar_g_balance_nex_charge)
 724                 {
 725                         if(autocvar_g_balance_nex_secondary_chargepool)
 726                                 self.nex_chargepool_ammo = 1;
 727                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 728                 }
 729
 730                 if(inWarmupStage)
 731                 {
 732                         self.ammo_shells = warmup_start_ammo_shells;
 733                         self.ammo_nails = warmup_start_ammo_nails;
 734                         self.ammo_rockets = warmup_start_ammo_rockets;
 735                         self.ammo_cells = warmup_start_ammo_cells;
 736                         self.ammo_fuel = warmup_start_ammo_fuel;
 737                         self.health = warmup_start_health;
 738                         self.armorvalue = warmup_start_armorvalue;
 739                         self.weapons = warmup_start_weapons;
 740                 }
 741                 else
 742                 {
 743                         self.ammo_shells = start_ammo_shells;
 744                         self.ammo_nails = start_ammo_nails;
 745                         self.ammo_rockets = start_ammo_rockets;
 746                         self.ammo_cells = start_ammo_cells;
 747                         self.ammo_fuel = start_ammo_fuel;
 748                         self.health = start_health;
 749                         self.armorvalue = start_armorvalue;
 750                         self.weapons = start_weapons;
 751                 }
 752
 753                 if(g_weaponarena_random)
 754                 {
 755                         if(g_weaponarena_random_with_laser)
 756                                 self.weapons &~= WEPBIT_LASER;
 757                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 758                         if(g_weaponarena_random_with_laser)
 759                                 self.weapons |= WEPBIT_LASER;
 760                 }
 761
 762                 self.items = start_items;
 763                 self.jump_interval = time;
 764
 765                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 766                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 767                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 768                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 769                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 770                 //extend the pause of rotting if client was reset at the beginning of the countdown
 771                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 772                         self.spawnshieldtime += game_starttime - time;
 773                         self.pauserotarmor_finished += game_starttime - time;
 774                         self.pauserothealth_finished += game_starttime - time;
 775                         self.pauseregen_finished += game_starttime - time;
 776                 }
 777                 self.damageforcescale = 2;
 778                 self.death_time = 0;
 779                 self.dead_frame = 0;
 780                 self.alpha = 0;
 781                 self.scale = 0;
 782                 self.fade_time = 0;
 783                 self.pain_frame = 0;
 784                 self.pain_finished = 0;
 785                 self.strength_finished = 0;
 786                 self.invincible_finished = 0;
 787                 self.pushltime = 0;
 788                 // players have no think function
 789                 self.think = SUB_Null;
 790                 self.nextthink = 0;
 791                 self.hook_time = 0;
 792                 self.dmg_team = 0;
 793                 self.ballistics_density = autocvar_g_ballistics_density_player;
 794
 795                 self.metertime = 0;
 796
 797                 self.runes = 0;
 798
 799                 self.deadflag = DEAD_NO;
 800
 801                 self.angles = spot.angles;
 802
 803                 self.angles_z = 0; // never spawn tilted even if the spot says to
 804                 self.fixangle = TRUE; // turn this way immediately
 805                 self.velocity = '0 0 0';
 806                 self.avelocity = '0 0 0';
 807                 self.punchangle = '0 0 0';
 808                 self.punchvector = '0 0 0';
 809                 self.oldvelocity = self.velocity;
 810                 self.fire_endtime = -1;
 811
 812                 msg_entity = self;
 813                 WRITESPECTATABLE_MSG_ONE({
 814                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 815                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 816                 });
 817
 818                 self.model = "";
 819                 FixPlayermodel();
 820                 self.drawonlytoclient = world;
 821
 822                 self.crouch = FALSE;
 823                 self.view_ofs = PL_VIEW_OFS;
 824                 setsize (self, PL_MIN, PL_MAX);
 825                 self.spawnorigin = spot.origin;
 826                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 827                 // don't reset back to last position, even if new position is stuck in solid
 828                 self.oldorigin = self.origin;
 829                 self.prevorigin = self.origin;
 830                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 831                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 832         self.hud = HUD_NORMAL;
 833
 834                 if(g_arena)
 835                 {
 836                         Spawnqueue_Remove(self);
 837                         Spawnqueue_Mark(self);
 838                 }
 839
 840                 else if(g_ca)
 841                         self.caplayer = 1;
 842
 843                 self.event_damage = PlayerDamage;
 844
 845                 self.bot_attack = TRUE;
 846
 847                 self.statdraintime = time + 5;
 848                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 849
 850                 if(self.killcount == -666) {
 851                         PlayerScore_Clear(self);
 852                         self.killcount = 0;
 853                 }
 854
 855                 CL_SpawnWeaponentity();
 856                 self.alpha = default_player_alpha;
 857                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 858                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 859
 860                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 861                 self.lms_traveled_distance = 0;
 862                 self.speedrunning = FALSE;
 863
 864                 race_PostSpawn(spot);
 865
 866                 //stuffcmd(self, "chase_active 0");
 867                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 868
 869                 if (autocvar_g_spawnsound)
 870                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 871
 872                 if(g_assault) {
 873                         if(self.team == assault_attacker_team)
 874                                 centerprint(self, "You are attacking!");
 875                         else
 876                                 centerprint(self, "You are defending!");
 877                 }
 878
 879                 target_voicescript_clear(self);
 880
 881                 // reset fields the weapons may use
 882                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 883                 {
 884                         weapon_action(j, WR_RESETPLAYER);
 885
 886                         // all weapons must be fully loaded when we spawn
 887                         entity e;
 888                         e = get_weaponinfo(j);
 889                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 890                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 891                 }
 892
 893                 oldself = self;
 894                 self = spot;
 895                         activator = oldself;
 896                                 string s;
 897                                 s = self.target;
 898                                 self.target = string_null;
 899                                 SUB_UseTargets();
 900                                 self.target = s;
 901                         activator = world;
 902                 self = oldself;
 903
 904                 spawn_spot = spot;
 905                 MUTATOR_CALLHOOK(PlayerSpawn);
 906
 907                 if(autocvar_spawn_debug)
 908                 {
 909                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 910                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 911                 }
 912
 913                 self.switchweapon = w_getbestweapon(self);
 914                 self.cnt = -1; // W_LastWeapon will not complain
 915                 self.weapon = 0;
 916                 self.weaponname = "";
 917                 self.switchingweapon = 0;
 918
 919                 if(!self.alivetime)
 920                         self.alivetime = time;
 921
 922                 antilag_clear(self);
 923         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
 924                 PutObserverInServer ();
 925         }
 926
 927         //if(g_ctf)
 928         //      ctf_playerchanged();
 929 }
 930
 931 .float ebouncefactor, ebouncestop; // electro's values
 932 // TODO do we need all these fields, or should we stop autodetecting runtime
 933 // changes and just have a console command to update this?
 934 float ClientInit_SendEntity(entity to, float sf)
 935 {
 936         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 937         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 950         if(sv_foginterval && world.fog != "")
 951                 WriteString(MSG_ENTITY, world.fog);
 952         else
 953                 WriteString(MSG_ENTITY, "");
 954         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 955         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 956         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 957         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 958         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 959         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 960         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 961         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 962         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 963         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 964         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 965         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 966         return TRUE;
 967 }
 968
 969 void ClientInit_CheckUpdate()
 970 {
 971         self.nextthink = time;
 972         if(self.count != autocvar_g_balance_armor_blockpercent)
 973         {
 974                 self.count = autocvar_g_balance_armor_blockpercent;
 975                 self.SendFlags |= 1;
 976         }
 977         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 978         {
 979                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 980                 self.SendFlags |= 1;
 981         }
 982         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 983         {
 984                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 985                 self.SendFlags |= 1;
 986         }
 987         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 988         {
 989                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 990                 self.SendFlags |= 1;
 991         }
 992         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 993         {
 994                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 995                 self.SendFlags |= 1;
 996         }
 997         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 998         {
 999                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1000                 self.SendFlags |= 1;
1001         }
1002 }
1003
1004 void ClientInit_Spawn()
1005 {
1006         entity o;
1007         entity e;
1008         e = spawn();
1009         e.classname = "clientinit";
1010         e.think = ClientInit_CheckUpdate;
1011         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1012
1013         o = self;
1014         self = e;
1015         ClientInit_CheckUpdate();
1016         self = o;
1017 }
1018
1019 /*
1020 =============
1021 SetNewParms
1022 =============
1023 */
1024 void SetNewParms (void)
1025 {
1026         // initialize parms for a new player
1027         parm1 = -(86400 * 366);
1028 }
1029
1030 /*
1031 =============
1032 SetChangeParms
1033 =============
1034 */
1035 void SetChangeParms (void)
1036 {
1037         // save parms for level change
1038         parm1 = self.parm_idlesince - time;
1039 }
1040
1041 /*
1042 =============
1043 DecodeLevelParms
1044 =============
1045 */
1046 void DecodeLevelParms (void)
1047 {
1048         // load parms
1049         self.parm_idlesince = parm1;
1050         if(self.parm_idlesince == -(86400 * 366))
1051                 self.parm_idlesince = time;
1052
1053         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1054         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1055 }
1056
1057 /*
1058 =============
1059 ClientKill
1060
1061 Called when a client types 'kill' in the console
1062 =============
1063 */
1064
1065 .float clientkill_nexttime;
1066 void ClientKill_Now_TeamChange()
1067 {
1068         if(self.killindicator_teamchange == -1)
1069         {
1070                 self.team = -1;
1071                 JoinBestTeam( self, FALSE, FALSE );
1072         }
1073         else if(self.killindicator_teamchange == -2)
1074         {
1075                 if(g_ca)
1076                         self.caplayer = 0;
1077                 if(blockSpectators)
1078                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1079                 PutObserverInServer();
1080         }
1081         else
1082                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1083 }
1084
1085 void ClientKill_Now()
1086 {
1087         if(self.vehicle)
1088         {
1089             vehicles_exit(VHEF_RELESE);
1090             if(!self.killindicator_teamchange)
1091             {
1092             self.vehicle_health = -1;
1093             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1094             }
1095         }
1096
1097         if(self.killindicator && !wasfreed(self.killindicator))
1098                 remove(self.killindicator);
1099
1100         self.killindicator = world;
1101
1102         if(self.killindicator_teamchange)
1103                 ClientKill_Now_TeamChange();
1104
1105         // in any case:
1106         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1107
1108         // now I am sure the player IS dead
1109 }
1110 void KillIndicator_Think()
1111 {
1112         if (gameover)
1113         {
1114                 self.owner.killindicator = world;
1115                 remove(self);
1116                 return;
1117         }
1118
1119         if (self.owner.effects & CSQCMODEL_EF_INVISIBLE)
1120         {
1121                 self.owner.killindicator = world;
1122                 remove(self);
1123                 return;
1124         }
1125
1126         if(self.cnt <= 0)
1127         {
1128                 self = self.owner;
1129                 ClientKill_Now(); // no oldself needed
1130                 return;
1131         }
1132     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1133     {
1134         self.nextthink = time + 1;
1135         self.cnt -= 1;
1136     }
1137         else
1138         {
1139                 if(self.cnt <= 10)
1140                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1141                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1142                 {
1143                         if(self.cnt <= 10)
1144                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1145                 }
1146                 self.nextthink = time + 1;
1147                 self.cnt -= 1;
1148         }
1149 }
1150
1151 float clientkilltime;
1152 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1153 {
1154         float killtime;
1155         float starttime;
1156         entity e;
1157
1158         if (gameover)
1159                 return;
1160
1161         killtime = autocvar_g_balance_kill_delay;
1162
1163         if(g_race_qualifying || g_cts)
1164                 killtime = 0;
1165
1166     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1167     {
1168                 remove(self.killindicator);
1169                 self.killindicator = world;
1170
1171         ClientKill_Now(); // allow instant kill in this case
1172         return;
1173     }
1174
1175         self.killindicator_teamchange = targetteam;
1176
1177     if(!self.killindicator)
1178         {
1179                 if(self.deadflag == DEAD_NO)
1180                 {
1181                         killtime = max(killtime, self.clientkill_nexttime - time);
1182                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1183                 }
1184
1185                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1186                 {
1187                         ClientKill_Now();
1188                 }
1189                 else
1190                 {
1191                         starttime = max(time, clientkilltime);
1192
1193                         self.killindicator = spawn();
1194                         self.killindicator.owner = self;
1195                         self.killindicator.scale = 0.5;
1196                         setattachment(self.killindicator, self, "");
1197                         setorigin(self.killindicator, '0 0 52');
1198                         self.killindicator.think = KillIndicator_Think;
1199                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1200                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1201                         self.killindicator.cnt = ceil(killtime);
1202                         self.killindicator.count = bound(0, ceil(killtime), 10);
1203                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1204
1205                         for(e = world; (e = find(e, classname, "body")) != world; )
1206                         {
1207                                 if(e.enemy != self)
1208                                         continue;
1209                                 e.killindicator = spawn();
1210                                 e.killindicator.owner = e;
1211                                 e.killindicator.scale = 0.5;
1212                                 setattachment(e.killindicator, e, "");
1213                                 setorigin(e.killindicator, '0 0 52');
1214                                 e.killindicator.think = KillIndicator_Think;
1215                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1216                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1217                                 e.killindicator.cnt = ceil(killtime);
1218                         }
1219                         self.lip = 0;
1220                 }
1221         }
1222         if(self.killindicator)
1223         {
1224                 if(targetteam == 0) // just die
1225                 {
1226                         self.killindicator.colormod = '0 0 0';
1227                         if(clienttype(self) == CLIENTTYPE_REAL)
1228                         if(self.killindicator.cnt > 0)
1229                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1230                 }
1231                 else if(targetteam == -1) // auto
1232                 {
1233                         self.killindicator.colormod = '0 1 0';
1234                         if(clienttype(self) == CLIENTTYPE_REAL)
1235                         if(self.killindicator.cnt > 0)
1236                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1237                 }
1238                 else if(targetteam == -2) // spectate
1239                 {
1240                         self.killindicator.colormod = '0.5 0.5 0.5';
1241                         if(clienttype(self) == CLIENTTYPE_REAL)
1242                         if(self.killindicator.cnt > 0)
1243                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1244                 }
1245                 else
1246                 {
1247                         self.killindicator.colormod = TeamColor(targetteam);
1248                         if(clienttype(self) == CLIENTTYPE_REAL)
1249                         if(self.killindicator.cnt > 0)
1250                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1251                 }
1252         }
1253
1254 }
1255
1256 void ClientKill (void)
1257 {
1258         if (gameover)
1259                 return;
1260
1261         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1262         {
1263                 // do nothing
1264         }
1265     else if(self.freezetag_frozen)
1266     {
1267         // do nothing
1268     }
1269         else
1270                 ClientKill_TeamChange(0);
1271 }
1272
1273 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1274 {
1275     e.killindicator = spawn();
1276     e.killindicator.owner = e;
1277     e.killindicator.think = KillIndicator_Think;
1278     e.killindicator.nextthink = time + (e.lip) * 0.05;
1279     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1280     e.killindicator.health = 1; // this is used to indicate that it should be silent
1281     e.lip = 0;
1282 }
1283
1284 void FixClientCvars(entity e)
1285 {
1286         // send prediction settings to the client
1287         stuffcmd(e, "\nin_bindmap 0 0\n");
1288         if(g_race || g_cts)
1289                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1290         if(autocvar_g_antilag == 3) // client side hitscan
1291                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1292         if(sv_gentle)
1293                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1294         /*
1295          * we no longer need to stuff this. Remove this comment block if you feel
1296          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1297         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1298         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1299         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1300         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1301         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1302         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1303         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1304         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1305         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1306         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1307         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1308         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1309         stuffcmd(e, "cl_movement_edgefriction 1\n");
1310          */
1311 }
1312
1313 float PlayerInIDList(entity p, string idlist)
1314 {
1315         float n, i;
1316         string s;
1317
1318         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1319         if not(p.crypto_idfp)
1320                 return 0;
1321
1322         // this function allows abbreviated player IDs too!
1323         n = tokenize_console(idlist);
1324         for(i = 0; i < n; ++i)
1325         {
1326                 s = argv(i);
1327                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1328                         return 1;
1329         }
1330
1331         return 0;
1332 }
1333
1334 /*
1335 =============
1336 ClientConnect
1337
1338 Called when a client connects to the server
1339 =============
1340 */
1341 //void ctf_clientconnect();
1342 string ColoredTeamName(float t);
1343 void DecodeLevelParms (void);
1344 //void dom_player_join_team(entity pl);
1345 void set_dom_state(entity e);
1346 void ClientConnect (void)
1347 {
1348         float t;
1349
1350         if(self.flags & FL_CLIENT)
1351         {
1352                 print("Warning: ClientConnect, but already connected!\n");
1353                 return;
1354         }
1355
1356         if(Ban_MaybeEnforceBan(self))
1357                 return;
1358
1359         DecodeLevelParms();
1360
1361 #ifdef WATERMARK
1362         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1363 #endif
1364
1365         self.classname = "player_joining";
1366
1367         self.flags = FL_CLIENT;
1368         self.version_nagtime = time + 10 + random() * 10;
1369
1370         if(player_count<0)
1371         {
1372                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1373                 player_count = 0;
1374         }
1375
1376         PlayerScore_Attach(self);
1377         ClientData_Attach();
1378         accuracy_init(self);
1379
1380         bot_clientconnect();
1381
1382         playerdemo_init();
1383
1384         anticheat_init();
1385
1386         race_PreSpawnObserver();
1387
1388         //if(g_domination)
1389         //      dom_player_join_team(self);
1390
1391         // identify the right forced team
1392         if(autocvar_g_campaign)
1393         {
1394                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1395                 {
1396                         switch(autocvar_g_campaign_forceteam)
1397                         {
1398                                 case 1: self.team_forced = COLOR_TEAM1; break;
1399                                 case 2: self.team_forced = COLOR_TEAM2; break;
1400                                 case 3: self.team_forced = COLOR_TEAM3; break;
1401                                 case 4: self.team_forced = COLOR_TEAM4; break;
1402                                 default: self.team_forced = 0;
1403                         }
1404                 }
1405         }
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1407                 self.team_forced = COLOR_TEAM1;
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1409                 self.team_forced = COLOR_TEAM2;
1410         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1411                 self.team_forced = COLOR_TEAM3;
1412         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1413                 self.team_forced = COLOR_TEAM4;
1414         else if(autocvar_g_forced_team_otherwise == "red")
1415                 self.team_forced = COLOR_TEAM1;
1416         else if(autocvar_g_forced_team_otherwise == "blue")
1417                 self.team_forced = COLOR_TEAM2;
1418         else if(autocvar_g_forced_team_otherwise == "yellow")
1419                 self.team_forced = COLOR_TEAM3;
1420         else if(autocvar_g_forced_team_otherwise == "pink")
1421                 self.team_forced = COLOR_TEAM4;
1422         else if(autocvar_g_forced_team_otherwise == "spectate")
1423                 self.team_forced = -1;
1424         else if(autocvar_g_forced_team_otherwise == "spectator")
1425                 self.team_forced = -1;
1426         else
1427                 self.team_forced = 0;
1428
1429         if(!teamplay)
1430                 if(self.team_forced > 0)
1431                         self.team_forced = 0;
1432
1433         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1434
1435         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1436                 self.classname = "observer";
1437         } else {
1438                 if(teamplay)
1439                 {
1440                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1441                         {
1442                                 self.classname = "player";
1443                                 campaign_bots_may_start = 1;
1444                         }
1445                         else
1446                         {
1447                                 self.classname = "observer"; // do it anyway
1448                         }
1449                 }
1450                 else
1451                 {
1452                         self.classname = "player";
1453                         campaign_bots_may_start = 1;
1454                 }
1455         }
1456
1457         self.playerid = (playerid_last = playerid_last + 1);
1458
1459         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1460
1461     if(clienttype(self) == CLIENTTYPE_BOT)
1462         PlayerStats_AddPlayer(self);
1463
1464         if(autocvar_sv_eventlog)
1465                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1466
1467         LogTeamchange(self.playerid, self.team, 1);
1468
1469         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1470
1471         self.netname_previous = strzone(self.netname);
1472
1473         bprint("^4", self.netname, "^4 connected");
1474
1475         if(self.classname != "observer" && (g_domination || g_ctf))
1476                 bprint(" and joined the ", ColoredTeamName(self.team));
1477
1478         bprint("\n");
1479
1480         stuffcmd(self, strcat(clientstuff, "\n"));
1481         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1482
1483         FixClientCvars(self);
1484
1485         // spawnfunc_waypoint sprites
1486         WaypointSprite_InitClient(self);
1487
1488         // Wazat's grappling hook
1489         SetGrappleHookBindings();
1490
1491         // get version info from player
1492         stuffcmd(self, "cmd clientversion $gameversion\n");
1493
1494         // get other cvars from player
1495         GetCvars(0);
1496
1497         // notify about available teams
1498         if(teamplay)
1499         {
1500                 CheckAllowedTeams(self);
1501                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1502                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1503         }
1504         else
1505                 stuffcmd(self, "set _teams_available 0\n");
1506
1507         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1508
1509         if(g_arena || g_ca)
1510         {
1511                 self.classname = "observer";
1512                 if(g_arena)
1513                         Spawnqueue_Insert(self);
1514         }
1515         /*else if(g_ctf)
1516         {
1517                 ctf_clientconnect();
1518         }*/
1519
1520         attach_entcs();
1521
1522         bot_relinkplayerlist();
1523
1524         self.spectatortime = time;
1525         if(blockSpectators)
1526         {
1527                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1528         }
1529
1530         self.jointime = time;
1531         self.allowedTimeouts = autocvar_sv_timeout_number;
1532
1533         if(clienttype(self) == CLIENTTYPE_REAL)
1534         {
1535                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1536                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1537         }
1538
1539         if(g_lms)
1540         {
1541                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1542                 {
1543                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1544                         self.frags = FRAGS_SPECTATOR;
1545                 }
1546         }
1547
1548         if(!sv_foginterval && world.fog != "")
1549                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1550
1551         SoundEntity_Attach(self);
1552
1553         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1554         {
1555                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1556                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1557         }
1558         else
1559                 self.hitplotfh = -1;
1560
1561         if(g_race || g_cts) {
1562                 string rr;
1563                 if(g_cts)
1564                         rr = CTS_RECORD;
1565                 else
1566                         rr = RACE_RECORD;
1567                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1568
1569                 msg_entity = self;
1570                 race_send_recordtime(MSG_ONE);
1571                 race_send_speedaward(MSG_ONE);
1572
1573                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1574                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1575                 race_send_speedaward_alltimebest(MSG_ONE);
1576
1577                 float i;
1578                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1579                         race_SendRankings(i, 0, 0, MSG_ONE);
1580                 }
1581         }
1582         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1583                 send_CSQC_teamnagger();
1584
1585         if (g_domination)
1586                 set_dom_state(self);
1587
1588         CheatInitClient();
1589
1590         if(!autocvar_g_campaign)
1591                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1592
1593         CSQCMODEL_AUTOINIT();
1594
1595         self.model_randomizer = random();
1596 }
1597
1598 /*
1599 =============
1600 ClientDisconnect
1601
1602 Called when a client disconnects from the server
1603 =============
1604 */
1605 .entity chatbubbleentity;
1606 void ReadyCount();
1607 void ClientDisconnect (void)
1608 {
1609         if(self.vehicle)
1610             vehicles_exit(VHEF_RELESE);
1611
1612         if not(self.flags & FL_CLIENT)
1613         {
1614                 print("Warning: ClientDisconnect without ClientConnect\n");
1615                 return;
1616         }
1617
1618         PlayerStats_AddGlobalInfo(self);
1619
1620         CheatShutdownClient();
1621
1622         if(self.hitplotfh >= 0)
1623         {
1624                 fclose(self.hitplotfh);
1625                 self.hitplotfh = -1;
1626         }
1627
1628         anticheat_report();
1629         anticheat_shutdown();
1630
1631         playerdemo_shutdown();
1632
1633         bot_clientdisconnect();
1634
1635         if(self.entcs)
1636                 detach_entcs();
1637
1638         if(autocvar_sv_eventlog)
1639                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1640         bprint ("^4",self.netname);
1641         bprint ("^4 disconnected\n");
1642
1643         SoundEntity_Detach(self);
1644
1645         DropAllRunes(self);
1646         MUTATOR_CALLHOOK(ClientDisconnect);
1647
1648         Portal_ClearAll(self);
1649
1650         RemoveGrapplingHook(self);
1651         if(self.flagcarried)
1652                 DropFlag(self.flagcarried, world, world);
1653         if(self.ballcarried && g_nexball)
1654                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1655
1656         // Here, everything has been done that requires this player to be a client.
1657
1658         self.flags &~= FL_CLIENT;
1659
1660         if (self.chatbubbleentity)
1661                 remove (self.chatbubbleentity);
1662
1663         if (self.killindicator)
1664                 remove (self.killindicator);
1665
1666         WaypointSprite_PlayerGone();
1667
1668         bot_relinkplayerlist();
1669
1670         if(g_arena)
1671         {
1672                 Spawnqueue_Unmark(self);
1673                 Spawnqueue_Remove(self);
1674         }
1675
1676         accuracy_free(self);
1677         ClientData_Detach();
1678         PlayerScore_Detach(self);
1679
1680         if(self.netname_previous)
1681                 strunzone(self.netname_previous);
1682         if(self.clientstatus)
1683                 strunzone(self.clientstatus);
1684         if(self.weaponorder_byimpulse)
1685                 strunzone(self.weaponorder_byimpulse);
1686
1687         ClearPlayerSounds();
1688
1689         if(self.personal)
1690                 remove(self.personal);
1691
1692         self.playerid = 0;
1693         ReadyCount();
1694
1695         // free cvars
1696         GetCvars(-1);
1697 }
1698
1699 .float BUTTON_CHAT;
1700 void ChatBubbleThink()
1701 {
1702         self.nextthink = time;
1703         if ((self.owner.effects & CSQCMODEL_EF_INVISIBLE) || self.owner.chatbubbleentity != self)
1704         {
1705                 if(self.owner) // but why can that ever be world?
1706                         self.owner.chatbubbleentity = world;
1707                 remove(self);
1708                 return;
1709         }
1710         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1711 #ifdef TETRIS
1712                 || self.owner.tetris_on
1713 #endif
1714         )
1715                 self.model = self.mdl;
1716         else
1717                 self.model = "";
1718 }
1719
1720 void UpdateChatBubble()
1721 {
1722         if (self.effects & CSQCMODEL_EF_INVISIBLE)
1723                 return;
1724         // spawn a chatbubble entity if needed
1725         if (!self.chatbubbleentity)
1726         {
1727                 self.chatbubbleentity = spawn();
1728                 self.chatbubbleentity.owner = self;
1729                 self.chatbubbleentity.exteriormodeltoclient = self;
1730                 self.chatbubbleentity.think = ChatBubbleThink;
1731                 self.chatbubbleentity.nextthink = time;
1732                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1733                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1734                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1735                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1736                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1737                 self.chatbubbleentity.model = "";
1738                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1739         }
1740 }
1741
1742
1743 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1744 // added to the model skins
1745 /*void UpdateColorModHack()
1746 {
1747         float c;
1748         c = self.clientcolors & 15;
1749         // LordHavoc: only bothering to support white, green, red, yellow, blue
1750              if (!teamplay) self.colormod = '0 0 0';
1751         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1752         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1753         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1754         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1755         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1756         else self.colormod = '1 1 1';
1757 }*/
1758
1759 .float oldcolormap;
1760 void respawn(void)
1761 {
1762         if(!(self.effects & CSQCMODEL_EF_INVISIBLE) && autocvar_g_respawn_ghosts)
1763         {
1764                 self.solid = SOLID_NOT;
1765                 self.takedamage = DAMAGE_NO;
1766                 self.movetype = MOVETYPE_FLY;
1767                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1768                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1769                 self.effects |= EF_ADDITIVE;
1770                 self.oldcolormap = self.colormap;
1771                 self.colormap = 0; // this originally was 512, but raises a warning in the engine, so get rid of it
1772                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1773                 if(autocvar_g_respawn_ghosts_maxtime)
1774                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1775         }
1776
1777         CopyBody(1);
1778         self.effects |= EF_NODRAW; // prevent another CopyBody
1779         if(self.oldcolormap)
1780         {
1781                 self.colormap = self.oldcolormap;
1782                 self.oldcolormap = 0;
1783         }
1784         PutClientInServer();
1785 }
1786
1787 void play_countdown(float finished, string samp)
1788 {
1789         if(clienttype(self) == CLIENTTYPE_REAL)
1790                 if(floor(finished - time - frametime) != floor(finished - time))
1791                         if(finished - time < 6)
1792                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1793 }
1794
1795 void player_powerups (void)
1796 {
1797         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1798         olditems = self.items;
1799
1800         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1801         {
1802                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1803                 self.modelflags |= MF_ROCKET;
1804         }
1805         else
1806         {
1807                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1808                 self.modelflags &~= MF_ROCKET;
1809         }
1810
1811         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1812
1813         if((self.effects & CSQCMODEL_EF_INVISIBLE) || self.deadflag) // don't apply the flags if the player is gibbed
1814                 return;
1815
1816         Fire_ApplyDamage(self);
1817         Fire_ApplyEffect(self);
1818
1819         if (g_minstagib)
1820         {
1821                 self.effects |= EF_FULLBRIGHT;
1822
1823                 if (self.items & IT_STRENGTH)
1824                 {
1825                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1826                         if (time > self.strength_finished)
1827                         {
1828                                 self.alpha = default_player_alpha;
1829                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1830                                 self.items &~= IT_STRENGTH;
1831                                 sprint(self, "^3Invisibility has worn off\n");
1832                         }
1833                 }
1834                 else
1835                 {
1836                         if (time < self.strength_finished)
1837                         {
1838                                 self.alpha = g_minstagib_invis_alpha;
1839                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1840                                 self.items |= IT_STRENGTH;
1841                                 sprint(self, "^3You are invisible\n");
1842                         }
1843                 }
1844
1845                 if (self.items & IT_INVINCIBLE)
1846                 {
1847                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1848                         if (time > self.invincible_finished)
1849                         {
1850                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1851                                 sprint(self, "^3Speed has worn off\n");
1852                         }
1853                 }
1854                 else
1855                 {
1856                         if (time < self.invincible_finished)
1857                         {
1858                                 self.items = self.items | IT_INVINCIBLE;
1859                                 sprint(self, "^3You are on speed\n");
1860                         }
1861                 }
1862         }
1863         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1864         {
1865                 if (self.items & IT_STRENGTH)
1866                 {
1867                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1868                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1869                         if (time > self.strength_finished)
1870                         {
1871                                 self.items = self.items - (self.items & IT_STRENGTH);
1872                                 sprint(self, "^3Strength has worn off\n");
1873                         }
1874                 }
1875                 else
1876                 {
1877                         if (time < self.strength_finished)
1878                         {
1879                                 self.items = self.items | IT_STRENGTH;
1880                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1881                         }
1882                 }
1883                 if (self.items & IT_INVINCIBLE)
1884                 {
1885                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1886                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1887                         if (time > self.invincible_finished)
1888                         {
1889                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1890                                 sprint(self, "^3Shield has worn off\n");
1891                         }
1892                 }
1893                 else
1894                 {
1895                         if (time < self.invincible_finished)
1896                         {
1897                                 self.items = self.items | IT_INVINCIBLE;
1898                                 sprint(self, "^3Shield surrounds you\n");
1899                         }
1900                 }
1901
1902                 if(autocvar_g_nodepthtestplayers)
1903                         self.effects = self.effects | EF_NODEPTHTEST;
1904
1905                 if(autocvar_g_fullbrightplayers)
1906                         self.effects = self.effects | EF_FULLBRIGHT;
1907
1908                 // midair gamemode: damage only while in the air
1909                 // if in midair mode, being on ground grants temporary invulnerability
1910                 // (this is so that multishot weapon don't clear the ground flag on the
1911                 // first damage in the frame, leaving the player vulnerable to the
1912                 // remaining hits in the same frame)
1913                 if (self.flags & FL_ONGROUND)
1914                 if (g_midair)
1915                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1916
1917                 if (time >= game_starttime)
1918                 if (time < self.spawnshieldtime)
1919                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1920         }
1921
1922         MUTATOR_CALLHOOK(PlayerPowerups);
1923 }
1924
1925 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1926 {
1927         if(current > stable)
1928                 return current;
1929         else if(current > stable - 0.25) // when close enough, "snap"
1930                 return stable;
1931         else
1932                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1933 }
1934
1935 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1936 {
1937         if(current < stable)
1938                 return current;
1939         else if(current < stable + 0.25) // when close enough, "snap"
1940                 return stable;
1941         else
1942                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1943 }
1944
1945 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1946 {
1947         if(current > rotstable)
1948         {
1949                 if(rotframetime > 0)
1950                 {
1951                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1952                         current = max(rotstable, current - rotlinear * rotframetime);
1953                 }
1954         }
1955         else if(current < regenstable)
1956         {
1957                 if(regenframetime > 0)
1958                 {
1959                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1960                         current = min(regenstable, current + regenlinear * regenframetime);
1961                 }
1962         }
1963
1964         if(current > limit)
1965                 current = limit;
1966
1967         return current;
1968 }
1969
1970 void player_regen (void)
1971 {
1972         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1973         maxh = autocvar_g_balance_health_rotstable;
1974         maxa = autocvar_g_balance_armor_rotstable;
1975         maxf = autocvar_g_balance_fuel_rotstable;
1976         minh = autocvar_g_balance_health_regenstable;
1977         mina = autocvar_g_balance_armor_regenstable;
1978         minf = autocvar_g_balance_fuel_regenstable;
1979         limith = autocvar_g_balance_health_limit;
1980         limita = autocvar_g_balance_armor_limit;
1981         limitf = autocvar_g_balance_fuel_limit;
1982
1983         max_mod = regen_mod = rot_mod = limit_mod = 1;
1984
1985         if (self.runes & RUNE_REGEN)
1986         {
1987                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1988                 {
1989                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1990                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1991                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1992                 }
1993                 else
1994                 {
1995                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
1996                         max_mod = autocvar_g_balance_rune_regen_hpmod;
1997                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
1998                 }
1999         }
2000         else if (self.runes & CURSE_VENOM)
2001         {
2002                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2003                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2004                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2005                 else
2006                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2007                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2008                 //if (!self.runes & RUNE_REGEN)
2009                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2010         }
2011         maxh = maxh * max_mod;
2012         //maxa = maxa * max_mod;
2013         //maxf = maxf * max_mod;
2014         minh = minh * max_mod;
2015         //mina = mina * max_mod;
2016         //minf = minf * max_mod;
2017         limith = limith * limit_mod;
2018         limita = limita * limit_mod;
2019         //limitf = limitf * limit_mod;
2020
2021         if(g_lms && g_ca)
2022                 rot_mod = 0;
2023
2024         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2025         {
2026                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2027                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2028
2029                 // if player rotted to death...  die!
2030                 if(self.health < 1)
2031                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2032         }
2033
2034         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2035                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2036 }
2037
2038 float zoomstate_set;
2039 void SetZoomState(float z)
2040 {
2041         if(z != self.zoomstate)
2042         {
2043                 self.zoomstate = z;
2044                 ClientData_Touch(self);
2045         }
2046         zoomstate_set = 1;
2047 }
2048
2049 void GetPressedKeys(void) {
2050         MUTATOR_CALLHOOK(GetPressedKeys);
2051         if (self.movement_x > 0) // get if movement keys are pressed
2052         {       // forward key pressed
2053                 self.pressedkeys |= KEY_FORWARD;
2054                 self.pressedkeys &~= KEY_BACKWARD;
2055         }
2056         else if (self.movement_x < 0)
2057         {       // backward key pressed
2058                 self.pressedkeys |= KEY_BACKWARD;
2059                 self.pressedkeys &~= KEY_FORWARD;
2060         }
2061         else
2062         {       // no x input
2063                 self.pressedkeys &~= KEY_FORWARD;
2064                 self.pressedkeys &~= KEY_BACKWARD;
2065         }
2066
2067         if (self.movement_y > 0)
2068         {       // right key pressed
2069                 self.pressedkeys |= KEY_RIGHT;
2070                 self.pressedkeys &~= KEY_LEFT;
2071         }
2072         else if (self.movement_y < 0)
2073         {       // left key pressed
2074                 self.pressedkeys |= KEY_LEFT;
2075                 self.pressedkeys &~= KEY_RIGHT;
2076         }
2077         else
2078         {       // no y input
2079                 self.pressedkeys &~= KEY_RIGHT;
2080                 self.pressedkeys &~= KEY_LEFT;
2081         }
2082
2083         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2084                 self.pressedkeys |= KEY_JUMP;
2085         else
2086                 self.pressedkeys &~= KEY_JUMP;
2087         if (self.BUTTON_CROUCH)
2088                 self.pressedkeys |= KEY_CROUCH;
2089         else
2090                 self.pressedkeys &~= KEY_CROUCH;
2091 }
2092
2093 /*
2094 ======================
2095 spectate mode routines
2096 ======================
2097 */
2098
2099 void SpectateCopy(entity spectatee) {
2100         other = spectatee;
2101         MUTATOR_CALLHOOK(SpectateCopy);
2102         self.armortype = spectatee.armortype;
2103         self.armorvalue = spectatee.armorvalue;
2104         self.ammo_cells = spectatee.ammo_cells;
2105         self.ammo_shells = spectatee.ammo_shells;
2106         self.ammo_nails = spectatee.ammo_nails;
2107         self.ammo_rockets = spectatee.ammo_rockets;
2108         self.ammo_fuel = spectatee.ammo_fuel;
2109         self.clip_load = spectatee.clip_load;
2110         self.clip_size = spectatee.clip_size;
2111         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2112         self.health = spectatee.health;
2113         self.impulse = 0;
2114         self.items = spectatee.items;
2115         self.last_pickup = spectatee.last_pickup;
2116         self.hit_time = spectatee.hit_time;
2117         self.metertime = spectatee.metertime;
2118         self.strength_finished = spectatee.strength_finished;
2119         self.invincible_finished = spectatee.invincible_finished;
2120         self.pressedkeys = spectatee.pressedkeys;
2121         self.weapons = spectatee.weapons;
2122         self.switchweapon = spectatee.switchweapon;
2123         self.switchingweapon = spectatee.switchingweapon;
2124         self.weapon = spectatee.weapon;
2125         self.nex_charge = spectatee.nex_charge;
2126         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2127         self.hagar_load = spectatee.hagar_load;
2128         self.minelayer_mines = spectatee.minelayer_mines;
2129         self.punchangle = spectatee.punchangle;
2130         self.view_ofs = spectatee.view_ofs;
2131         self.v_angle = spectatee.v_angle;
2132         self.velocity = spectatee.velocity;
2133         self.dmg_take = spectatee.dmg_take;
2134         self.dmg_save = spectatee.dmg_save;
2135         self.dmg_inflictor = spectatee.dmg_inflictor;
2136         self.angles = spectatee.v_angle;
2137         if(!self.BUTTON_USE)
2138                 self.fixangle = TRUE;
2139         setorigin(self, spectatee.origin);
2140         setsize(self, spectatee.mins, spectatee.maxs);
2141         SetZoomState(spectatee.zoomstate);
2142
2143         anticheat_spectatecopy(spectatee);
2144
2145         //self.vehicle = spectatee.vehicle;
2146
2147         self.hud = spectatee.hud;
2148         if(spectatee.vehicle)
2149     {
2150         setorigin(self, spectatee.origin);
2151         self.velocity = spectatee.vehicle.velocity;
2152         self.v_angle += spectatee.vehicle.angles;
2153         //self.v_angle_x *= -1;
2154         self.vehicle_health = spectatee.vehicle_health;
2155         self.vehicle_shield = spectatee.vehicle_shield;
2156         self.vehicle_energy = spectatee.vehicle_energy;
2157         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2158         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2159         self.vehicle_reload1 = spectatee.vehicle_reload1;
2160         self.vehicle_reload2 = spectatee.vehicle_reload2;
2161
2162         msg_entity = self;
2163         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2164         WriteEntity(MSG_ONE, spectatee);
2165         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2166     }
2167 }
2168
2169 float SpectateUpdate() {
2170         if(!self.enemy)
2171             return 0;
2172
2173         if (self == self.enemy)
2174                 return 0;
2175
2176         if(self.enemy.classname != "player")
2177                 return 0;
2178
2179         SpectateCopy(self.enemy);
2180
2181         return 1;
2182 }
2183
2184
2185 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2186 entity CA_SpectateNext(entity start) {
2187         if (start.team == self.team) {
2188                 return start;
2189         }
2190
2191         other = start;
2192         // continue from current player
2193         while(other && other.team != self.team) {
2194                 other = find(other, classname, "player");
2195         }
2196
2197         if (!other) {
2198                 // restart from begining
2199                 other = find(other, classname, "player");
2200                 while(other && other.team != self.team) {
2201                         other = find(other, classname, "player");
2202                 }
2203         }
2204
2205         return other;
2206 }
2207
2208 float SpectateNext() {
2209         other = find(self.enemy, classname, "player");
2210         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2211                 // CA and ca players when spectating enemies is forbidden
2212                 other = CA_SpectateNext(other);
2213         } else {
2214                 // other modes and ca spectators or spectating enemies is allowed
2215                 if (!other)
2216                         other = find(other, classname, "player");
2217         }
2218
2219         if (other)
2220                 self.enemy = other;
2221
2222         if(self.enemy.classname == "player") {
2223             if(self.enemy.vehicle)
2224             {
2225             msg_entity = self;
2226             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2227             WriteEntity(MSG_ONE, self.enemy);
2228             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2229             self.movetype = MOVETYPE_NONE;
2230             accuracy_resend(self);
2231             }
2232             else
2233             {
2234             msg_entity = self;
2235             WriteByte(MSG_ONE, SVC_SETVIEW);
2236             WriteEntity(MSG_ONE, self.enemy);
2237             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2238             self.movetype = MOVETYPE_NONE;
2239             accuracy_resend(self);
2240
2241             if(!SpectateUpdate())
2242                 PutObserverInServer();
2243         }
2244         return 1;
2245         } else {
2246                 return 0;
2247         }
2248 }
2249
2250 /*
2251 =============
2252 ShowRespawnCountdown()
2253
2254 Update a respawn countdown display.
2255 =============
2256 */
2257 void ShowRespawnCountdown()
2258 {
2259         float number;
2260         if(self.deadflag == DEAD_NO) // just respawned?
2261                 return;
2262         else
2263         {
2264                 number = ceil(self.death_time - time);
2265                 if(number <= 0)
2266                         return;
2267                 if(number <= self.respawn_countdown)
2268                 {
2269                         self.respawn_countdown = number - 1;
2270                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2271                                 AnnounceTo(self, strcat(ftos(number), ""));
2272                 }
2273         }
2274 }
2275
2276 .float prevent_join_msgtime;
2277 void LeaveSpectatorMode()
2278 {
2279         if(nJoinAllowed(1)) {
2280                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2281                         self.classname = "player";
2282
2283                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2284                                 JoinBestTeam(self, FALSE, TRUE);
2285
2286                         if(autocvar_g_campaign)
2287                                 campaign_bots_may_start = 1;
2288
2289                         PutClientInServer();
2290
2291                         if(self.classname == "player")
2292                                 bprint ("^4", self.netname, "^4 is playing now\n");
2293
2294                         if(!autocvar_g_campaign)
2295                         if (time < self.jointime + autocvar_welcome_message_time)
2296                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2297
2298                         if (self.prevent_join_msgtime)
2299                         {
2300                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2301                                 self.prevent_join_msgtime = 0;
2302                         }
2303
2304                         return;
2305                 } else {
2306                         if (g_ca && self.caplayer) {
2307                         }       // do nothing
2308                         else
2309                                 stuffcmd(self,"menu_showteamselect\n");
2310                         return;
2311                 }
2312         }
2313         else {
2314                 //player may not join because of g_maxplayers is set
2315                 if (time - self.prevent_join_msgtime > 2)
2316                 {
2317                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2318                         self.prevent_join_msgtime = time;
2319                 }
2320         }
2321 }
2322
2323 /**
2324  * Determines whether the player is allowed to join. This depends on cvar
2325  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2326  * it checks whether the number of currently playing players exceeds g_maxplayers.
2327  * @return int number of free slots for players, 0 if none
2328  */
2329 float nJoinAllowed(float includeMe) {
2330         if(self.team_forced < 0)
2331                 return FALSE; // forced spectators can never join
2332
2333         // TODO simplify this
2334         entity e;
2335
2336         float totalClients;
2337         FOR_EACH_CLIENT(e)
2338                 totalClients += 1;
2339
2340         if (!autocvar_g_maxplayers)
2341                 return maxclients - totalClients + includeMe;
2342
2343         float currentlyPlaying;
2344         FOR_EACH_REALPLAYER(e)
2345                 currentlyPlaying += 1;
2346
2347         if(currentlyPlaying < autocvar_g_maxplayers)
2348                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2349
2350         return 0;
2351 }
2352
2353 /**
2354  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2355  * g_maxplayers_spectator_blocktime seconds
2356  */
2357 void checkSpectatorBlock() {
2358         if(self.classname == "spectator" || self.classname == "observer") {
2359                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2360                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2361                         dropclient(self);
2362                 }
2363         }
2364 }
2365
2366 .float motd_actived_time; // used for both motd and campaign_message
2367 void PrintWelcomeMessage()
2368 {
2369         if (self.motd_actived_time == 0) { // is there already a message showing?
2370                 if (autocvar_g_campaign) {
2371                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2372                                 self.motd_actived_time = time;
2373                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2374                         }
2375                 } else {
2376                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2377                                 self.motd_actived_time = time;
2378                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2379                         }
2380                 }
2381         } else { // showing MOTD or campaign message
2382                 if (autocvar_g_campaign) {
2383                         if (self.BUTTON_INFO)
2384                                 self.motd_actived_time = time;
2385                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2386                                 self.motd_actived_time = 0;
2387                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2388                         }
2389                 } else {
2390                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2391                                 if (self.BUTTON_INFO)
2392                                         self.motd_actived_time = time;
2393                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2394                                         self.motd_actived_time = 0;
2395                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2396                                 }
2397                         }
2398                 }
2399         }
2400 }
2401
2402 void ObserverThink()
2403 {
2404         float prefered_movetype;
2405         if (self.flags & FL_JUMPRELEASED) {
2406                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2407                         self.flags &~= FL_JUMPRELEASED;
2408                         self.flags |= FL_SPAWNING;
2409                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2410                         self.flags &~= FL_JUMPRELEASED;
2411                         if(SpectateNext() == 1) {
2412                                 self.classname = "spectator";
2413                         }
2414                 } else {
2415                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2416                         if (self.movetype != prefered_movetype)
2417                                 self.movetype = prefered_movetype;
2418                 }
2419         } else {
2420                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2421                         self.flags |= FL_JUMPRELEASED;
2422                         if(self.flags & FL_SPAWNING)
2423                         {
2424                                 self.flags &~= FL_SPAWNING;
2425                                 LeaveSpectatorMode();
2426                                 return;
2427                         }
2428                 }
2429         }
2430
2431         PrintWelcomeMessage();
2432 }
2433
2434 void SpectatorThink()
2435 {
2436         if (self.flags & FL_JUMPRELEASED) {
2437                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2438                         self.flags &~= FL_JUMPRELEASED;
2439                         self.flags |= FL_SPAWNING;
2440                 } else if(self.BUTTON_ATCK) {
2441                         self.flags &~= FL_JUMPRELEASED;
2442                         if(SpectateNext() == 1) {
2443                                 self.classname = "spectator";
2444                         } else {
2445                                 self.classname = "observer";
2446                                 PutClientInServer();
2447                         }
2448                 } else if (self.BUTTON_ATCK2) {
2449                         self.flags &~= FL_JUMPRELEASED;
2450                         self.classname = "observer";
2451                         PutClientInServer();
2452                 } else {
2453                         if(!SpectateUpdate())
2454                                 PutObserverInServer();
2455                 }
2456         } else {
2457                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2458                         self.flags |= FL_JUMPRELEASED;
2459                         if(self.flags & FL_SPAWNING)
2460                         {
2461                                 self.flags &~= FL_SPAWNING;
2462                                 LeaveSpectatorMode();
2463                                 return;
2464                         }
2465                 }
2466                 if(!SpectateUpdate())
2467                         PutObserverInServer();
2468         }
2469
2470         PrintWelcomeMessage();
2471         self.flags |= FL_CLIENT | FL_NOTARGET;
2472 }
2473
2474 float ctf_usekey();
2475 void PlayerUseKey()
2476 {
2477         if(self.classname != "player")
2478                 return;
2479
2480         if(self.vehicle)
2481         {
2482         vehicles_exit(VHEF_NORMAL);
2483         return;
2484         }
2485
2486         // a use key was pressed; call handlers
2487         if(ctf_usekey())
2488                 return;
2489
2490         MUTATOR_CALLHOOK(PlayerUseKey);
2491 }
2492
2493 .float touchexplode_time;
2494
2495 /*
2496 =============
2497 PlayerPreThink
2498
2499 Called every frame for each client before the physics are run
2500 =============
2501 */
2502 .float usekeypressed;
2503 void() ctf_setstatus;
2504 void() nexball_setstatus;
2505 .float items_added;
2506 void PlayerPreThink (void)
2507 {
2508         WarpZone_PlayerPhysics_FixVAngle();
2509
2510         self.stat_game_starttime = game_starttime;
2511         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2512         self.stat_leadlimit = autocvar_leadlimit;
2513
2514         if(frametime)
2515         {
2516                 // physics frames: update anticheat stuff
2517                 anticheat_prethink();
2518         }
2519
2520         if(blockSpectators && frametime)
2521                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2522                 checkSpectatorBlock();
2523
2524         zoomstate_set = 0;
2525
2526         if(self.netname_previous != self.netname)
2527         {
2528                 if(autocvar_sv_eventlog)
2529                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2530                 if(self.netname_previous)
2531                         strunzone(self.netname_previous);
2532                 self.netname_previous = strzone(self.netname);
2533         }
2534
2535         // version nagging
2536         if(self.version_nagtime)
2537                 if(self.cvar_g_xonoticversion)
2538                         if(time > self.version_nagtime)
2539                         {
2540                                 // don't notify git users
2541                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2542                                 {
2543                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2544                                         {
2545                                                 // notify release users if connecting to git
2546                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2547                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2548                                         }
2549                                         else
2550                                         {
2551                                                 float r;
2552                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2553                                                 if(r < 0)
2554                                                 {
2555                                                         // give users new version
2556                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2557                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2558                                                 }
2559                                                 else if(r > 0)
2560                                                 {
2561                                                         // notify users about old server version
2562                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2563                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2564                                                 }
2565                                         }
2566                                 }
2567                                 self.version_nagtime = 0;
2568                         }
2569
2570         // GOD MODE info
2571         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2572         {
2573                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2574                 self.max_armorvalue = 0;
2575         }
2576
2577 #ifdef TETRIS
2578         if (TetrisPreFrame())
2579                 return;
2580 #endif
2581
2582         MUTATOR_CALLHOOK(PlayerPreThink);
2583
2584         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2585         {
2586                 if(self.BUTTON_USE && !self.usekeypressed)
2587                         PlayerUseKey();
2588                 self.usekeypressed = self.BUTTON_USE;
2589         }
2590
2591         PrintWelcomeMessage();
2592
2593         if(self.classname == "player") {
2594 //              if(self.netname == "Wazat")
2595 //                      bprint(self.classname, "\n");
2596
2597                 CheckRules_Player();
2598
2599                 if (intermission_running)
2600                 {
2601                         IntermissionThink ();   // otherwise a button could be missed between
2602                         return;                                 // the think tics
2603                 }
2604
2605                 //don't allow the player to turn around while game is paused!
2606                 if(timeoutStatus == 2) {
2607                         // FIXME turn this into CSQC stuff
2608                         self.v_angle = self.lastV_angle;
2609                         self.angles = self.lastV_angle;
2610                         self.fixangle = TRUE;
2611                 }
2612
2613                 if(frametime)
2614                 {
2615 #ifndef NO_LEGACY_NETWORKING
2616                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2617 #endif
2618
2619                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2620                         {
2621                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2622                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2623                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2624
2625                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2626                                 {
2627                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2628                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2629                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2630                                 }
2631                         }
2632                         else
2633                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2634
2635                         player_powerups();
2636                 }
2637
2638                 if (g_minstagib)
2639                         minstagib_ammocheck();
2640
2641                 if (self.deadflag != DEAD_NO)
2642                 {
2643                         float button_pressed, force_respawn;
2644                         if(self.personal && g_race_qualifying)
2645                         {
2646                                 if(time > self.death_time)
2647                                 {
2648                                         self.death_time = time + 1; // only retry once a second
2649                                         respawn();
2650                                         self.impulse = 141;
2651                                 }
2652                         }
2653                         else
2654                         {
2655                                 if(frametime)
2656                                         player_anim();
2657                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2658                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2659                                 if (self.deadflag == DEAD_DYING)
2660                                 {
2661                                         if(force_respawn)
2662                                                 self.deadflag = DEAD_RESPAWNING;
2663                                         else if(!button_pressed)
2664                                                 self.deadflag = DEAD_DEAD;
2665                                 }
2666                                 else if (self.deadflag == DEAD_DEAD)
2667                                 {
2668                                         if(button_pressed)
2669                                                 self.deadflag = DEAD_RESPAWNABLE;
2670                                 }
2671                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2672                                 {
2673                                         if(!button_pressed)
2674                                                 self.deadflag = DEAD_RESPAWNING;
2675                                 }
2676                                 else if (self.deadflag == DEAD_RESPAWNING)
2677                                 {
2678                                         if(time > self.death_time)
2679                                         {
2680                                                 self.death_time = time + 1; // only retry once a second
2681                                                 respawn();
2682                                         }
2683                                 }
2684                                 ShowRespawnCountdown();
2685                         }
2686                         return;
2687                 }
2688                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2689                 // so (self.deadflag == DEAD_NO) is always true in the code below
2690
2691                 if(g_touchexplode)
2692                 if(time > self.touchexplode_time)
2693                 if(self.classname == "player")
2694                 if(self.deadflag == DEAD_NO)
2695                 if not(IS_INDEPENDENT_PLAYER(self))
2696                 FOR_EACH_PLAYER(other) if(self != other)
2697                 {
2698                         if(time > other.touchexplode_time)
2699                         if(other.deadflag == DEAD_NO)
2700                         if not(IS_INDEPENDENT_PLAYER(other))
2701                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2702                         {
2703                                 PlayerTouchExplode(self, other);
2704                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2705                         }
2706                 }
2707
2708                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2709                 {
2710                         vector dist;
2711
2712                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2713                         dist = self.prevorigin - self.origin;
2714                         dist_z = 0;
2715                         self.lms_traveled_distance += fabs(vlen(dist));
2716
2717                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2718                         {
2719                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2720                                 self.lms_traveled_distance = 0;
2721                         }
2722
2723                         if(time > self.lms_nextcheck)
2724                         {
2725                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2726                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2727                                 {
2728                                         centerprint(self, autocvar_g_lms_campcheck_message);
2729                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2730                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2731                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2732                                 }
2733                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2734                                 self.lms_traveled_distance = 0;
2735                         }
2736                 }
2737
2738                 self.prevorigin = self.origin;
2739
2740                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2741                 {
2742                         if (!self.crouch)
2743                         {
2744                                 self.crouch = TRUE;
2745                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2746                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2747                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2748                         }
2749                 }
2750                 else
2751                 {
2752                         if (self.crouch)
2753                         {
2754                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2755                                 if (!trace_startsolid)
2756                                 {
2757                                         self.crouch = FALSE;
2758                                         self.view_ofs = PL_VIEW_OFS;
2759                                         setsize (self, PL_MIN, PL_MAX);
2760                                 }
2761                         }
2762                 }
2763
2764                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2765                 {
2766                         if(self.bloodloss_timer < time)
2767                         {
2768                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2769                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2770                         }
2771                 }
2772
2773                 FixPlayermodel();
2774
2775                 GrapplingHookFrame();
2776
2777                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2778                 //if(frametime)
2779                 {
2780                         self.items &~= self.items_added;
2781
2782                         W_WeaponFrame();
2783
2784                         self.items_added = 0;
2785                         if(self.items & IT_JETPACK)
2786                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2787                                         self.items_added |= IT_FUEL;
2788
2789                         self.items |= self.items_added;
2790                 }
2791
2792                 player_regen();
2793
2794                 // rot nex charge to the charge limit
2795                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2796                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2797
2798                 if(frametime)
2799                         player_anim();
2800
2801                 if(g_ctf)
2802                         ctf_setstatus();
2803
2804                 if(g_nexball)
2805                         nexball_setstatus();
2806
2807                 // secret status
2808                 secrets_setstatus();
2809
2810                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2811
2812                 //self.angles_y=self.v_angle_y + 90;   // temp
2813         } else if(gameover) {
2814                 if (intermission_running)
2815                         IntermissionThink ();   // otherwise a button could be missed between
2816                 return;
2817         } else if(self.classname == "observer") {
2818                 ObserverThink();
2819         } else if(self.classname == "spectator") {
2820                 SpectatorThink();
2821         }
2822
2823         if(!zoomstate_set)
2824                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2825
2826         float oldspectatee_status;
2827         oldspectatee_status = self.spectatee_status;
2828         if(self.classname == "spectator")
2829                 self.spectatee_status = num_for_edict(self.enemy);
2830         else if(self.classname == "observer")
2831                 self.spectatee_status = num_for_edict(self);
2832         else
2833                 self.spectatee_status = 0;
2834         if(self.spectatee_status != oldspectatee_status)
2835         {
2836                 ClientData_Touch(self);
2837                 if(g_race || g_cts)
2838                         race_InitSpectator();
2839         }
2840
2841         if(self.teamkill_soundtime)
2842         if(time > self.teamkill_soundtime)
2843         {
2844                 self.teamkill_soundtime = 0;
2845
2846                 entity oldpusher, oldself;
2847
2848                 oldself = self; self = self.teamkill_soundsource;
2849                 oldpusher = self.pusher; self.pusher = oldself;
2850
2851                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2852
2853                 self.pusher = oldpusher;
2854                 self = oldself;
2855         }
2856
2857         if(self.taunt_soundtime)
2858         if(time > self.taunt_soundtime)
2859         {
2860                 self.taunt_soundtime = 0;
2861                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2862         }
2863
2864         target_voicescript_next(self);
2865
2866         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2867         if(!self.weapon)
2868                 self.clip_load = self.clip_size = 0;
2869 }
2870
2871 float isInvisibleString(string s)
2872 {
2873         float i, n, c;
2874         s = strdecolorize(s);
2875         for((i = 0), (n = strlen(s)); i < n; ++i)
2876         {
2877                 c = str2chr(s, i);
2878                 switch(c)
2879                 {
2880                         case 0:
2881                         case 32: // space
2882                                 break;
2883                         case 192: // charmap space
2884                                 if (!autocvar_utf8_enable)
2885                                         break;
2886                                 return FALSE;
2887                         case 160: // space in unicode fonts
2888                         case 0xE000 + 192: // utf8 charmap space
2889                                 if (autocvar_utf8_enable)
2890                                         break;
2891                         default:
2892                                 return FALSE;
2893                 }
2894         }
2895         return TRUE;
2896 }
2897
2898 /*
2899 =============
2900 PlayerPostThink
2901
2902 Called every frame for each client after the physics are run
2903 =============
2904 */
2905 .float idlekick_lasttimeleft;
2906 .entity showheadshotbbox;
2907 void showheadshotbbox_think()
2908 {
2909         if(self.owner.showheadshotbbox != self)
2910         {
2911                 remove(self);
2912                 return;
2913         }
2914         self.nextthink = time;
2915         setorigin(self, self.owner.origin);
2916         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2917 }
2918 void PlayerPostThink (void)
2919 {
2920         // Savage: Check for nameless players
2921         if (isInvisibleString(self.netname)) {
2922                 self.netname = "Player";
2923                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2924         }
2925
2926         if(sv_maxidle && frametime)
2927         {
2928                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2929                 float timeleft;
2930                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2931                 {
2932                         if(self.idlekick_lasttimeleft)
2933                         {
2934                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2935                                 self.idlekick_lasttimeleft = 0;
2936                         }
2937                         return;
2938                 }
2939                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2940                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2941                 {
2942                         if(!self.idlekick_lasttimeleft)
2943                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2944                 }
2945                 if(timeleft <= 0)
2946                 {
2947                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2948                         AnnounceTo(self, "terminated");
2949                         dropclient(self);
2950                         return;
2951                 }
2952                 else if(timeleft <= 10)
2953                 {
2954                         if(timeleft != self.idlekick_lasttimeleft)
2955                                 AnnounceTo(self, ftos(timeleft));
2956                         self.idlekick_lasttimeleft = timeleft;
2957                 }
2958         }
2959
2960 #ifdef TETRIS
2961         if(self.impulse == 100)
2962                 ImpulseCommands();
2963         if (TetrisPostFrame())
2964                 return;
2965 #endif
2966
2967         CheatFrame();
2968
2969         //CheckPlayerJump();
2970
2971         if(self.classname == "player") {
2972                 CheckRules_Player();
2973                 UpdateChatBubble();
2974                 if (self.impulse)
2975                         ImpulseCommands();
2976                 if (intermission_running)
2977                         return;         // intermission or finale
2978                 GetPressedKeys();
2979         } else if (self.classname == "observer") {
2980                 //do nothing
2981         } else if (self.classname == "spectator") {
2982                 //do nothing
2983         }
2984
2985         /*
2986         float i;
2987         for(i = 0; i < 1000; ++i)
2988         {
2989                 vector end;
2990                 end = self.origin + '0 0 1024' + 512 * randomvec();
2991                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2992                 if(trace_fraction < 1)
2993                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2994                 {
2995                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2996                         break;
2997                 }
2998         }
2999         */
3000
3001         Arena_Warmup();
3002
3003         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3004
3005         if(self.waypointsprite_attachedforcarrier)
3006                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3007
3008         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3009         {
3010                 if(!self.showheadshotbbox)
3011                 {
3012                         self.showheadshotbbox = spawn();
3013                         self.showheadshotbbox.classname = "headshotbbox";
3014                         self.showheadshotbbox.owner = self;
3015                         self.showheadshotbbox.think = showheadshotbbox_think;
3016                         self.showheadshotbbox.nextthink = time;
3017                         self = self.showheadshotbbox;
3018                         self.think();
3019                         self = self.owner;
3020                 }
3021         }
3022         else
3023         {
3024                 if(self.showheadshotbbox)
3025                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3026                 remove(self.showheadshotbbox);
3027         }
3028
3029         playerdemo_write();
3030
3031         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3032         {
3033                 if(!self.stored_netname)
3034                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3035                 if(self.stored_netname != self.netname)
3036                 {
3037                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3038                         strunzone(self.stored_netname);
3039                         self.stored_netname = strzone(self.netname);
3040                 }
3041         }
3042
3043         /*
3044         if(g_race)
3045                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3046         */
3047
3048         CSQCMODEL_AUTOUPDATE();
3049 }