qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_nexvelocity(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_NEX_VELOCITY);
  13         WriteByte(MSG_ONE, bound(0, fabs(cvar("g_balance_nex_velocitydependent_halflife")), 1));
  14         WriteShort(MSG_ONE, cvar("g_balance_nex_velocitydependent_minspeed"));
  15         WriteShort(MSG_ONE, cvar("g_balance_nex_velocitydependent_maxspeed"));
  16         WriteByte(MSG_ONE, cvar("g_balance_nex_velocitydependent_falloff_rate"));
  17         WriteByte(MSG_ONE, cvar("g_balance_nex_secondary_charge"));
  18         WriteByte(MSG_ONE, cvar("g_balance_nex_secondary_charge_rate"));
  19 }
  20
  21 void send_CSQC_cr_maxbullets(entity e) {
  22         msg_entity = e;
  23         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  24         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  25         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
  26 }
  27
  28 void Announce(string snd) {
  29         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  30         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  31         WriteString(MSG_ALL, snd);
  32 }
  33
  34 void AnnounceTo(entity e, string snd) {
  35         if (clienttype(e) == CLIENTTYPE_REAL)
  36         {
  37                 msg_entity = e;
  38                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  39                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  40                 WriteString(MSG_ONE, snd);
  41         }
  42 }
  43
  44 float ClientData_Send(entity to, float sf)
  45 {
  46         if(to != self.owner)
  47         {
  48                 error("wtf");
  49                 return FALSE;
  50         }
  51
  52         entity e;
  53
  54         e = to;
  55         if(to.classname == "spectator")
  56                 e = to.enemy;
  57
  58         sf = 0;
  59
  60         if(e.race_completed)
  61                 sf |= 1; // forced scoreboard
  62         if(to.spectatee_status)
  63                 sf |= 2; // spectator ent number follows
  64         if(e.zoomstate)
  65                 sf |= 4; // zoomed
  66         if(e.porto_v_angle_held)
  67                 sf |= 8; // angles held
  68
  69         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  70         WriteByte(MSG_ENTITY, sf);
  71
  72         if(sf & 2)
  73                 WriteByte(MSG_ENTITY, to.spectatee_status);
  74
  75         if(sf & 8)
  76         {
  77                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  78                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  79         }
  80
  81         return TRUE;
  82 }
  83
  84 void ClientData_Attach()
  85 {
  86         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  87         self.clientdata.drawonlytoclient = self;
  88         self.clientdata.owner = self;
  89 }
  90
  91 void ClientData_Detach()
  92 {
  93         remove(self.clientdata);
  94         self.clientdata = world;
  95 }
  96
  97 void ClientData_Touch(entity e)
  98 {
  99         e.clientdata.SendFlags = 1;
 100
 101         // make it spectatable
 102         entity e2;
 103         FOR_EACH_REALCLIENT(e2)
 104         {
 105                 if(e2 != e)
 106                         if(e2.classname == "spectator")
 107                                 if(e2.enemy == e)
 108                                         e2.clientdata.SendFlags = 1;
 109         }
 110 }
 111
 112
 113 .vector spawnpoint_score;
 114 .string netname_previous;
 115
 116 void spawnfunc_info_player_survivor (void)
 117 {
 118         spawnfunc_info_player_deathmatch();
 119 }
 120
 121 void spawnfunc_info_player_start (void)
 122 {
 123         spawnfunc_info_player_deathmatch();
 124 }
 125
 126 void spawnfunc_info_player_deathmatch (void)
 127 {
 128         self.classname = "info_player_deathmatch";
 129         relocate_spawnpoint();
 130 }
 131
 132 void spawnpoint_use()
 133 {
 134         if(teams_matter)
 135         if(have_team_spawns > 0)
 136         {
 137                 self.team = activator.team;
 138                 some_spawn_has_been_used = 1;
 139         }
 140 };
 141
 142 // Returns:
 143 //   _x: prio (-1 if unusable)
 144 //   _y: weight
 145 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 146 {
 147         float shortest, thisdist;
 148         float prio;
 149         entity player;
 150
 151         prio = 0;
 152
 153         // filter out spots for the wrong team
 154         if(teamcheck)
 155         if(spot.team != teamcheck)
 156                 return '-1 0 0';
 157
 158         if(race_spawns)
 159                 if(spot.target == "")
 160                         return '-1 0 0';
 161
 162         if(clienttype(self) == CLIENTTYPE_REAL)
 163         {
 164                 if(spot.restriction == 1)
 165                         return '-1 0 0';
 166         }
 167         else
 168         {
 169                 if(spot.restriction == 2)
 170                         return '-1 0 0';
 171         }
 172
 173         // filter out spots for assault
 174         if(spot.target != "") {
 175                 local entity ent;
 176                 float good, found;
 177                 ent = find(world, targetname, spot.target);
 178
 179                 while(ent) {
 180                         if(ent.classname == "target_objective")
 181                         {
 182                                 found = 1;
 183                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 184                                         return '-1 0 0';
 185                                 good = 1;
 186                         }
 187                         else if(ent.classname == "trigger_race_checkpoint")
 188                         {
 189                                 found = 1;
 190                                 if(!anypoint) // spectators may spawn everywhere
 191
 192                                 {
 193                                         if(g_race_qualifying)
 194                                         {
 195                                                 // spawn at first
 196                                                 if(ent.race_checkpoint != 0)
 197                                                         return '-1 0 0';
 198                                                 if(spot.race_place != race_lowest_place_spawn)
 199                                                         return '-1 0 0';
 200                                         }
 201                                         else
 202                                         {
 203                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 204                                                         return '-1 0 0';
 205                                                 // try reusing the previous spawn
 206                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 207                                                         prio += 1;
 208                                                 if(ent.race_checkpoint == 0)
 209                                                 {
 210                                                         float pl;
 211                                                         pl = self.race_place;
 212                                                         if(pl > race_highest_place_spawn)
 213                                                                 pl = 0;
 214                                                         if(pl == 0 && !self.race_started)
 215                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 216                                                         if(spot.race_place != pl)
 217                                                                 return '-1 0 0';
 218                                                 }
 219                                         }
 220                                 }
 221                                 good = 1;
 222                         }
 223                         ent = find(ent, targetname, spot.target);
 224                 }
 225
 226                 if(found && !good)
 227                         return '-1 0 0';
 228         }
 229
 230         player = playerlist;
 231         shortest = vlen(world.maxs - world.mins);
 232         for(player = playerlist; player; player = player.chain)
 233                 if (player != self)
 234                 {
 235                         thisdist = vlen(player.origin - spot.origin);
 236                         if (thisdist < shortest)
 237                                 shortest = thisdist;
 238                 }
 239         return prio * '1 0 0' + shortest * '0 1 0';
 240 }
 241
 242 float spawn_allbad;
 243 float spawn_allgood;
 244 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 245 {
 246         local entity spot, spotlist, spotlistend;
 247         spawn_allgood = TRUE;
 248         spawn_allbad = TRUE;
 249
 250         spotlist = world;
 251         spotlistend = world;
 252
 253         for(spot = firstspot; spot; spot = spot.chain)
 254         {
 255                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 256
 257                 if(cvar("spawn_debugview"))
 258                 {
 259                         setmodel(spot, "models/runematch/rune.mdl");
 260                         if(spot.spawnpoint_score_y < mindist)
 261                         {
 262                                 spot.colormod = '1 0 0';
 263                                 spot.scale = 1;
 264                         }
 265                         else
 266                         {
 267                                 spot.colormod = '0 1 0';
 268                                 spot.scale = spot.spawnpoint_score_y / mindist;
 269                         }
 270                 }
 271
 272                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 273                 {
 274                         if(spot.spawnpoint_score_y < mindist)
 275                         {
 276                                 // too short distance
 277                                 spawn_allgood = FALSE;
 278                         }
 279                         else
 280                         {
 281                                 // perfect
 282                                 spawn_allbad = FALSE;
 283
 284                                 if(spotlistend)
 285                                         spotlistend.chain = spot;
 286                                 spotlistend = spot;
 287                                 if(!spotlist)
 288                                         spotlist = spot;
 289
 290                                 /*
 291                                 if(teamcheck)
 292                                 if(spot.team != teamcheck)
 293                                         error("invalid spawn added");
 294
 295                                 print("added ", etos(spot), "\n");
 296                                 */
 297                         }
 298                 }
 299         }
 300         if(spotlistend)
 301                 spotlistend.chain = world;
 302
 303         /*
 304                 entity e;
 305                 if(teamcheck)
 306                         for(e = spotlist; e; e = e.chain)
 307                         {
 308                                 print("seen ", etos(e), "\n");
 309                                 if(e.team != teamcheck)
 310                                         error("invalid spawn found");
 311                         }
 312         */
 313
 314         return spotlist;
 315 }
 316
 317 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 318 {
 319         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 320         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 321         local entity spot;
 322
 323         RandomSelection_Init();
 324         for(spot = firstspot; spot; spot = spot.chain)
 325                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 326
 327         return RandomSelection_chosen_ent;
 328 }
 329
 330 /*
 331 =============
 332 SelectSpawnPoint
 333
 334 Finds a point to respawn
 335 =============
 336 */
 337 entity SelectSpawnPoint (float anypoint)
 338 {
 339         local float teamcheck;
 340         local entity firstspot_new;
 341         local entity spot, firstspot, playerlist;
 342
 343         spot = find (world, classname, "testplayerstart");
 344         if (spot)
 345                 return spot;
 346
 347         teamcheck = 0;
 348
 349         if(!anypoint && have_team_spawns > 0)
 350                 teamcheck = self.team;
 351
 352         // get the list of players
 353         playerlist = findchain(classname, "player");
 354         // get the entire list of spots
 355         firstspot = findchain(classname, "info_player_deathmatch");
 356         // filter out the bad ones
 357         // (note this returns the original list if none survived)
 358         if(anypoint)
 359         {
 360                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 361         }
 362         else
 363         {
 364                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 365                 if(!firstspot_new)
 366                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 367                 firstspot = firstspot_new;
 368
 369                 // there is 50/50 chance of choosing a random spot or the furthest spot
 370                 // (this means that roughly every other spawn will be furthest, so you
 371                 // usually won't get fragged at spawn twice in a row)
 372                 if (arena_roundbased && !g_ca)
 373                 {
 374                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 375                         if(firstspot_new)
 376                                 firstspot = firstspot_new;
 377                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 378                 }
 379                 else if (random() > cvar("g_spawn_furthest"))
 380                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 381                 else
 382                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 383         }
 384
 385         if(cvar("spawn_debugview"))
 386         {
 387                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 388
 389                 entity e;
 390                 if(teamcheck)
 391                         for(e = firstspot; e; e = e.chain)
 392                                 if(e.team != teamcheck)
 393                                         error("invalid spawn found");
 394         }
 395
 396         if (!spot)
 397         {
 398                 if(cvar("spawn_debug"))
 399                         GotoNextMap();
 400                 else
 401                 {
 402                         if(some_spawn_has_been_used)
 403                                 return world; // team can't spawn any more, because of actions of other team
 404                         else
 405                                 error("Cannot find a spawn point - please fix the map!");
 406                 }
 407         }
 408
 409         return spot;
 410 }
 411
 412 /*
 413 =============
 414 CheckPlayerModel
 415
 416 Checks if the argument string can be a valid playermodel.
 417 Returns a valid one in doubt.
 418 =============
 419 */
 420 string FallbackPlayerModel;
 421 string CheckPlayerModel(string plyermodel) {
 422         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 423         {
 424                 // note: we cannot summon Don Strunzone here, some player may
 425                 // still have the model string set. In case anyone manages how
 426                 // to change a cvar default, we'll have a small leak here.
 427                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 428         }
 429         if(strlen(plyermodel) < 4)
 430                 return FallbackPlayerModel;
 431         if( substring(plyermodel,0,14) != "models/player/")
 432                 return FallbackPlayerModel;
 433         else if(cvar("sv_servermodelsonly"))
 434         {
 435                 if(substring(plyermodel,-4,4) != ".zym")
 436                 if(substring(plyermodel,-4,4) != ".dpm")
 437                 if(substring(plyermodel,-4,4) != ".iqm")
 438                 if(substring(plyermodel,-4,4) != ".md3")
 439                 if(substring(plyermodel,-4,4) != ".psk")
 440                         return FallbackPlayerModel;
 441                 // forbid the LOD models
 442                 if(substring(plyermodel, -9,5) == "_lod1")
 443                         return FallbackPlayerModel;
 444                 if(substring(plyermodel, -9,5) == "_lod2")
 445                         return FallbackPlayerModel;
 446                 if(plyermodel != strtolower(plyermodel))
 447                         return FallbackPlayerModel;
 448                 if(!fexists(plyermodel))
 449                         return FallbackPlayerModel;
 450         }
 451         return plyermodel;
 452 }
 453
 454 /*
 455 =============
 456 Client_customizeentityforclient
 457
 458 LOD reduction
 459 =============
 460 */
 461 void Client_uncustomizeentityforclient()
 462 {
 463         if(self.modelindex == 0) // no need to uncustomize then
 464                 return;
 465         self.modelindex = self.modelindex_lod0;
 466         self.skin = self.skinindex;
 467 }
 468
 469 float Client_customizeentityforclient()
 470 {
 471         entity modelsource;
 472
 473         if(self.modelindex == 0)
 474                 return TRUE;
 475
 476         // forcemodel stuff
 477
 478 #ifdef PROFILING
 479         float t0;
 480         t0 = gettime(GETTIME_HIRES); // reference
 481 #endif
 482
 483         modelsource = self;
 484
 485 #ifdef ALLOW_FORCEMODELS
 486         if(other.cvar_cl_forceplayermodelsfromxonotic)
 487                 if not(self.modelindex_lod0_from_xonotic)
 488                         modelsource = other;
 489         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 490                 modelsource = other;
 491 #endif
 492
 493         self.skin = modelsource.skinindex;
 494
 495 #if 0
 496         if(modelsource == self)
 497                 self.skin = modelsource.skinindex;
 498         else
 499                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 500 #endif
 501
 502         // self: me
 503         // other: the player viewing me
 504         float distance;
 505         float f;
 506
 507         if(other.cvar_cl_playerdetailreduction <= 0)
 508         {
 509                 if(other.cvar_cl_playerdetailreduction <= -2)
 510                         self.modelindex = modelsource.modelindex_lod2;
 511                 else if(other.cvar_cl_playerdetailreduction <= -1)
 512                         self.modelindex = modelsource.modelindex_lod1;
 513                 else
 514                         self.modelindex = modelsource.modelindex_lod0;
 515         }
 516         else
 517         {
 518                 distance = vlen(self.origin - other.origin);
 519                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 520                 if(f > sv_loddistance2)
 521                         self.modelindex = modelsource.modelindex_lod2;
 522                 else if(f > sv_loddistance1)
 523                         self.modelindex = modelsource.modelindex_lod1;
 524                 else
 525                         self.modelindex = modelsource.modelindex_lod0;
 526         }
 527
 528 #ifdef PROFILING
 529         float t1;
 530         t1 = gettime(GETTIME_HIRES); // reference
 531         client_cefc_accumulator += (t1 - t0);
 532 #endif
 533
 534         return TRUE;
 535 }
 536
 537 void setmodel_lod(entity e, string modelname)
 538 {
 539         string s;
 540
 541         if(sv_loddistance1)
 542         {
 543                 // FIXME: this only supports 3-letter extensions
 544                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 545                 if(fexists(s))
 546                 {
 547                         setmodel(e, s); // players have high precision
 548                         self.modelindex_lod1 = self.modelindex;
 549                 }
 550                 else
 551                         self.modelindex_lod1 = -1;
 552
 553                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 554                 if(fexists(s))
 555                 {
 556                         setmodel(e, s); // players have high precision
 557                         self.modelindex_lod2 = self.modelindex;
 558                 }
 559                 else
 560                         self.modelindex_lod2 = -1;
 561
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565
 566                 if(self.modelindex_lod1 < 0)
 567                         self.modelindex_lod1 = self.modelindex;
 568
 569                 if(self.modelindex_lod2 < 0)
 570                         self.modelindex_lod2 = self.modelindex;
 571         }
 572         else
 573         {
 574                 precache_model(modelname);
 575                 setmodel(e, modelname); // players have high precision
 576                 self.modelindex_lod0 = self.modelindex;
 577                         // save it for possible player model forcing
 578         }
 579
 580         s = whichpack(self.model);
 581         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 582
 583         player_setupanimsformodel();
 584         UpdatePlayerSounds();
 585 }
 586
 587 /*
 588 =============
 589 PutObserverInServer
 590
 591 putting a client as observer in the server
 592 =============
 593 */
 594 void FixPlayermodel();
 595 void PutObserverInServer (void)
 596 {
 597         entity  spot;
 598
 599         race_PreSpawnObserver();
 600
 601         spot = SelectSpawnPoint (TRUE);
 602         if(!spot)
 603                 error("No spawnpoints for observers?!?\n");
 604         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 605
 606         if(clienttype(self) == CLIENTTYPE_REAL)
 607         {
 608                 msg_entity = self;
 609                 WriteByte(MSG_ONE, SVC_SETVIEW);
 610                 WriteEntity(MSG_ONE, self);
 611         }
 612
 613         DropAllRunes(self);
 614
 615         Portal_ClearAll(self);
 616
 617         if(self.flagcarried)
 618                 DropFlag(self.flagcarried, world, world);
 619
 620         if(self.ballcarried)
 621                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 622
 623         WaypointSprite_PlayerDead();
 624
 625         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 626                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 627
 628         if(self.killcount != -666) {
 629                 if(g_lms) {
 630                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 631                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 632                         else
 633                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 634                 } else
 635                         bprint ("^4", self.netname, "^4 is spectating now\n");
 636
 637                 if(self.just_joined == FALSE) {
 638                         LogTeamchange(self.playerid, -1, 4);
 639                 } else
 640                         self.just_joined = FALSE;
 641         }
 642
 643         PlayerScore_Clear(self); // clear scores when needed
 644
 645         self.spectatortime = time;
 646
 647         self.classname = "observer";
 648         self.iscreature = FALSE;
 649         self.health = -666;
 650         self.takedamage = DAMAGE_NO;
 651         self.solid = SOLID_NOT;
 652         self.movetype = MOVETYPE_NOCLIP;
 653         self.flags = FL_CLIENT | FL_NOTARGET;
 654         self.armorvalue = 666;
 655         self.effects = 0;
 656         self.armorvalue = cvar("g_balance_armor_start");
 657         self.pauserotarmor_finished = 0;
 658         self.pauserothealth_finished = 0;
 659         self.pauseregen_finished = 0;
 660         self.damageforcescale = 0;
 661         self.death_time = 0;
 662         self.dead_frame = 0;
 663         self.alpha = 0;
 664         self.scale = 0;
 665         self.fade_time = 0;
 666         self.pain_frame = 0;
 667         self.pain_finished = 0;
 668         self.strength_finished = 0;
 669         self.invincible_finished = 0;
 670         self.pushltime = 0;
 671         self.think = SUB_Null;
 672         self.nextthink = 0;
 673         self.hook_time = 0;
 674         self.runes = 0;
 675         self.deadflag = DEAD_NO;
 676         self.angles = spot.angles;
 677         self.angles_z = 0;
 678         self.fixangle = TRUE;
 679         self.crouch = FALSE;
 680
 681         self.view_ofs = PL_VIEW_OFS;
 682         setorigin (self, spot.origin);
 683         setsize (self, '0 0 0', '0 0 0');
 684         self.prevorigin = self.origin;
 685         self.items = 0;
 686         self.weapons = 0;
 687         self.model = "";
 688         FixPlayermodel();
 689         self.model = "";
 690         self.modelindex = 0;
 691         self.weapon = 0;
 692         self.weaponmodel = "";
 693         self.weaponentity = world;
 694         self.exteriorweaponentity = world;
 695         self.killcount = -666;
 696         self.velocity = '0 0 0';
 697         self.avelocity = '0 0 0';
 698         self.punchangle = '0 0 0';
 699         self.punchvector = '0 0 0';
 700         self.oldvelocity = self.velocity;
 701         self.fire_endtime = -1;
 702
 703         if(sv_loddistance1)
 704                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 705
 706         if(g_arena)
 707         {
 708                 if(self.version_mismatch)
 709                 {
 710                         Spawnqueue_Unmark(self);
 711                         Spawnqueue_Remove(self);
 712                 }
 713                 else
 714                 {
 715                         Spawnqueue_Insert(self);
 716                 }
 717         }
 718         else if(g_lms)
 719         {
 720                 // Only if the player cannot play at all
 721                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 722                         self.frags = FRAGS_SPECTATOR;
 723                 else
 724                         self.frags = FRAGS_LMS_LOSER;
 725         }
 726         else
 727                 self.frags = FRAGS_SPECTATOR;
 728
 729         MUTATOR_CALLHOOK(MakePlayerObserver);
 730 }
 731
 732 float RestrictSkin(float s)
 733 {
 734         if(!teams_matter)
 735                 return s;
 736         if(s == 6)
 737                 return 6;
 738         return mod(s, 3);
 739 }
 740
 741 void FixPlayermodel()
 742 {
 743         local string defaultmodel;
 744         local float defaultskin, chmdl, oldskin;
 745         local vector m1, m2;
 746
 747         defaultmodel = "";
 748
 749         if(cvar("sv_defaultcharacter") == 1) {
 750                 defaultskin = 0;
 751
 752                 if(teams_matter)
 753                 {
 754                         string s;
 755                         s = Team_ColorNameLowerCase(self.team);
 756                         if(s != "neutral")
 757                         {
 758                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 759                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 760                         }
 761                 }
 762
 763                 if(defaultmodel == "")
 764                 {
 765                         defaultmodel = cvar_string("sv_defaultplayermodel");
 766                         defaultskin = cvar("sv_defaultplayerskin");
 767                 }
 768         }
 769
 770         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 771         {
 772                 if(self.model != "")
 773                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 774                 self.model = ""; // force the != checks to return true
 775         }
 776
 777         if(defaultmodel != "")
 778         {
 779                 if (defaultmodel != self.model)
 780                 {
 781                         m1 = self.mins;
 782                         m2 = self.maxs;
 783                         setmodel_lod (self, defaultmodel);
 784                         setsize (self, m1, m2);
 785                         chmdl = TRUE;
 786                 }
 787
 788                 oldskin = self.skinindex;
 789                 self.skinindex = defaultskin;
 790         } else {
 791                 if (self.playermodel != self.model || self.playermodel == "")
 792                 {
 793                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 794                         m1 = self.mins;
 795                         m2 = self.maxs;
 796                         setmodel_lod (self, self.playermodel);
 797                         setsize (self, m1, m2);
 798                         chmdl = TRUE;
 799                 }
 800
 801                 oldskin = self.skinindex;
 802                 self.skinindex = RestrictSkin(stof(self.playerskin));
 803         }
 804
 805         if(chmdl || oldskin != self.skinindex)
 806                 self.species = player_getspecies(); // model or skin has changed
 807
 808         if(!teams_matter)
 809                 if(strlen(cvar_string("sv_defaultplayercolors")))
 810                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 811                                 setcolor(self, cvar("sv_defaultplayercolors"));
 812 }
 813
 814 void PlayerTouchExplode(entity p1, entity p2)
 815 {
 816         vector org;
 817         org = (p1.origin + p2.origin) * 0.5;
 818         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 819
 820         te_explosion(org);
 821
 822         entity e;
 823         e = spawn();
 824         setorigin(e, org);
 825         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 826         remove(e);
 827 }
 828
 829 /*
 830 =============
 831 PutClientInServer
 832
 833 Called when a client spawns in the server
 834 =============
 835 */
 836 //void() ctf_playerchanged;
 837 void PutClientInServer (void)
 838 {
 839         if(clienttype(self) == CLIENTTYPE_BOT)
 840         {
 841                 self.classname = "player";
 842         }
 843         else if(clienttype(self) == CLIENTTYPE_REAL)
 844         {
 845                 msg_entity = self;
 846                 WriteByte(MSG_ONE, SVC_SETVIEW);
 847                 WriteEntity(MSG_ONE, self);
 848         }
 849
 850         // player is dead and becomes observer
 851         // FIXME fix LMS scoring for new system
 852         if(g_lms)
 853         {
 854                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 855                         self.classname = "observer";
 856         }
 857
 858         if(g_arena || (g_ca && !allowed_to_spawn))
 859         if(!self.spawned)
 860                 self.classname = "observer";
 861
 862         if(gameover)
 863                 self.classname = "observer";
 864
 865         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 866                 entity spot, oldself;
 867                 float j;
 868
 869                 if(self.team < 0)
 870                         JoinBestTeam(self, FALSE, TRUE);
 871
 872                 race_PreSpawn();
 873
 874                 spot = SelectSpawnPoint (FALSE);
 875                 if(!spot)
 876                 {
 877                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 878                         return; // spawn failed
 879                 }
 880
 881                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 882
 883                 self.classname = "player";
 884                 self.wasplayer = TRUE;
 885                 self.iscreature = TRUE;
 886                 self.movetype = MOVETYPE_WALK;
 887                 self.solid = SOLID_SLIDEBOX;
 888                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 889                 if(cvar("g_playerclip_collisions"))
 890                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 891                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 892                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 893                 self.frags = FRAGS_PLAYER;
 894                 if(independent_players)
 895                         MAKE_INDEPENDENT_PLAYER(self);
 896                 self.flags = FL_CLIENT;
 897                 self.takedamage = DAMAGE_AIM;
 898                 if(g_minstagib)
 899                         self.effects = EF_FULLBRIGHT;
 900                 else
 901                         self.effects = 0;
 902                 self.air_finished = time + 12;
 903                 self.dmg = 2;
 904
 905                 if(inWarmupStage)
 906                 {
 907                         self.ammo_shells = warmup_start_ammo_shells;
 908                         self.ammo_nails = warmup_start_ammo_nails;
 909                         self.ammo_rockets = warmup_start_ammo_rockets;
 910                         self.ammo_cells = warmup_start_ammo_cells;
 911                         self.ammo_fuel = warmup_start_ammo_fuel;
 912                         self.health = warmup_start_health;
 913                         self.armorvalue = warmup_start_armorvalue;
 914                         self.weapons = warmup_start_weapons;
 915                 }
 916                 else
 917                 {
 918                         self.ammo_shells = start_ammo_shells;
 919                         self.ammo_nails = start_ammo_nails;
 920                         self.ammo_rockets = start_ammo_rockets;
 921                         self.ammo_cells = start_ammo_cells;
 922                         self.ammo_fuel = start_ammo_fuel;
 923                         self.health = start_health;
 924                         self.armorvalue = start_armorvalue;
 925                         self.weapons = start_weapons;
 926                 }
 927
 928                 if(g_weaponarena_random)
 929                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 930
 931                 self.items = start_items;
 932                 self.jump_interval = time;
 933
 934                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 935                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 936                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 937                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 938                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 939                 //extend the pause of rotting if client was reset at the beginning of the countdown
 940                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 941                         self.spawnshieldtime += game_starttime - time;
 942                         self.pauserotarmor_finished += game_starttime - time;
 943                         self.pauserothealth_finished += game_starttime - time;
 944                         self.pauseregen_finished += game_starttime - time;
 945                 }
 946                 self.damageforcescale = 2;
 947                 self.death_time = 0;
 948                 self.dead_frame = 0;
 949                 self.alpha = 0;
 950                 self.scale = 0;
 951                 self.fade_time = 0;
 952                 self.pain_frame = 0;
 953                 self.pain_finished = 0;
 954                 self.strength_finished = 0;
 955                 self.invincible_finished = 0;
 956                 self.pushltime = 0;
 957                 // players have no think function
 958                 self.think = SUB_Null;
 959                 self.nextthink = 0;
 960                 self.hook_time = 0;
 961                 self.dmg_team = 0;
 962                 self.ballistics_density = cvar("g_ballistics_density_player");
 963
 964                 self.metertime = 0;
 965
 966                 self.runes = 0;
 967
 968                 self.deadflag = DEAD_NO;
 969
 970                 self.angles = spot.angles;
 971
 972                 self.angles_z = 0; // never spawn tilted even if the spot says to
 973                 self.fixangle = TRUE; // turn this way immediately
 974                 self.velocity = '0 0 0';
 975                 self.avelocity = '0 0 0';
 976                 self.punchangle = '0 0 0';
 977                 self.punchvector = '0 0 0';
 978                 self.oldvelocity = self.velocity;
 979                 self.fire_endtime = -1;
 980
 981                 msg_entity = self;
 982                 WRITESPECTATABLE_MSG_ONE({
 983                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 984                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 985                 });
 986
 987                 if(sv_loddistance1)
 988                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 989
 990                 self.model = "";
 991                 FixPlayermodel();
 992
 993                 self.crouch = FALSE;
 994                 self.view_ofs = PL_VIEW_OFS;
 995                 setsize (self, PL_MIN, PL_MAX);
 996                 self.spawnorigin = spot.origin;
 997                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 998                 // don't reset back to last position, even if new position is stuck in solid
 999                 self.oldorigin = self.origin;
1000                 self.prevorigin = self.origin;
1001                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1002
1003                 if(g_arena)
1004                 {
1005                         Spawnqueue_Remove(self);
1006                         Spawnqueue_Mark(self);
1007                 }
1008
1009                 else if(g_ca)
1010                         self.caplayer = 1;
1011
1012                 self.event_damage = PlayerDamage;
1013
1014                 self.bot_attack = TRUE;
1015
1016                 self.statdraintime = time + 5;
1017                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1018
1019                 if(self.killcount == -666) {
1020                         PlayerScore_Clear(self);
1021                         self.killcount = 0;
1022                 }
1023
1024                 self.cnt = WEP_LASER;
1025
1026                 CL_SpawnWeaponentity();
1027                 self.alpha = default_player_alpha;
1028                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1029                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1030
1031                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1032                 self.lms_traveled_distance = 0;
1033                 self.speedrunning = FALSE;
1034
1035                 race_PostSpawn(spot);
1036
1037                 if(cvar("spawn_debug"))
1038                 {
1039                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1040                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1041                 }
1042
1043                 //stuffcmd(self, "chase_active 0");
1044                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1045
1046                 if (cvar("g_spawnsound"))
1047                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1048
1049                 if(g_assault) {
1050                         if(self.team == assault_attacker_team)
1051                                 centerprint(self, "You are attacking!");
1052                         else
1053                                 centerprint(self, "You are defending!");
1054                 }
1055
1056                 target_voicescript_clear(self);
1057
1058                 // reset fields the weapons may use
1059                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1060                         weapon_action(j, WR_RESETPLAYER);
1061
1062                 oldself = self;
1063                 self = spot;
1064                         activator = oldself;
1065                                 SUB_UseTargets();
1066                         activator = world;
1067                 self = oldself;
1068
1069                 MUTATOR_CALLHOOK(PlayerSpawn);
1070
1071                 self.switchweapon = w_getbestweapon(self);
1072                 self.cnt = self.switchweapon;
1073                 self.weapon = 0;
1074         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1075                 PutObserverInServer ();
1076         }
1077
1078         //if(g_ctf)
1079         //      ctf_playerchanged();
1080 }
1081
1082 float ClientInit_SendEntity(entity to, float sf)
1083 {
1084         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1085         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1088         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1089         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1090         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1091         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1098         if(sv_foginterval && world.fog != "")
1099                 WriteString(MSG_ENTITY, world.fog);
1100         else
1101                 WriteString(MSG_ENTITY, "");
1102         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1103         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1104         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1105         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1106         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1107         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1108         return TRUE;
1109 }
1110
1111 void ClientInit_CheckUpdate()
1112 {
1113         self.nextthink = time;
1114         if(self.count != cvar("g_balance_armor_blockpercent"))
1115         {
1116                 self.count = cvar("g_balance_armor_blockpercent");
1117                 self.SendFlags |= 1;
1118         }
1119         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1120         {
1121                 self.cnt = cvar("g_balance_weaponswitchdelay");
1122                 self.SendFlags |= 1;
1123         }
1124         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1125         {
1126                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1127                 self.SendFlags |= 1;
1128         }
1129         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1130         {
1131                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1132                 self.SendFlags |= 1;
1133         }
1134 }
1135
1136 void ClientInit_Spawn()
1137 {
1138         entity o;
1139         entity e;
1140         e = spawn();
1141         e.classname = "clientinit";
1142         e.think = ClientInit_CheckUpdate;
1143         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1144
1145         o = self;
1146         self = e;
1147         ClientInit_CheckUpdate();
1148         self = o;
1149 }
1150
1151 /*
1152 =============
1153 SetNewParms
1154 =============
1155 */
1156 void SetNewParms (void)
1157 {
1158         // initialize parms for a new player
1159         parm1 = -(86400 * 366);
1160 }
1161
1162 /*
1163 =============
1164 SetChangeParms
1165 =============
1166 */
1167 void SetChangeParms (void)
1168 {
1169         // save parms for level change
1170         parm1 = self.parm_idlesince - time;
1171 }
1172
1173 /*
1174 =============
1175 DecodeLevelParms
1176 =============
1177 */
1178 void DecodeLevelParms (void)
1179 {
1180         // load parms
1181         self.parm_idlesince = parm1;
1182         if(self.parm_idlesince == -(86400 * 366))
1183                 self.parm_idlesince = time;
1184
1185         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1186         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1187 }
1188
1189 /*
1190 =============
1191 ClientKill
1192
1193 Called when a client types 'kill' in the console
1194 =============
1195 */
1196
1197 void ClientKill_Now_TeamChange()
1198 {
1199         if(self.killindicator_teamchange == -1)
1200         {
1201                 self.team = -1;
1202                 JoinBestTeam( self, FALSE, FALSE );
1203         }
1204         else
1205                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1206 }
1207
1208 void ClientKill_Now()
1209 {
1210         if(self.killindicator_teamchange)
1211                 ClientKill_Now_TeamChange();
1212
1213         // in any case:
1214         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1215
1216         if(self.killindicator)
1217         {
1218                 dprint("Cleaned up after a leaked kill indicator.\n");
1219                 remove(self.killindicator);
1220                 self.killindicator = world;
1221         }
1222 }
1223 void KillIndicator_Think()
1224 {
1225         if (!self.owner.modelindex)
1226         {
1227                 self.owner.killindicator = world;
1228                 remove(self);
1229                 return;
1230         }
1231
1232         if(self.cnt <= 0)
1233         {
1234                 self = self.owner;
1235                 ClientKill_Now(); // no oldself needed
1236                 return;
1237         }
1238         else
1239         {
1240                 if(self.cnt <= 10)
1241                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1242                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1243                 {
1244                         if(self.cnt <= 10)
1245                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1246                         if(self.owner.killindicator_teamchange)
1247                         {
1248                                 if(self.owner.killindicator_teamchange == -1)
1249                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1250                                 else
1251                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1252                         }
1253                         else
1254                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1255                 }
1256                 self.nextthink = time + 1;
1257                 self.cnt -= 1;
1258         }
1259 }
1260
1261 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1262 {
1263         float killtime;
1264         entity e;
1265         killtime = cvar("g_balance_kill_delay");
1266
1267         if(g_race_qualifying)
1268                 killtime = 0;
1269
1270         self.killindicator_teamchange = targetteam;
1271
1272         if(!self.killindicator)
1273         {
1274                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1275                 {
1276                         ClientKill_Now();
1277                 }
1278                 else
1279                 {
1280                         self.killindicator = spawn();
1281                         self.killindicator.owner = self;
1282                         self.killindicator.scale = 0.5;
1283                         setattachment(self.killindicator, self, "");
1284                         setorigin(self.killindicator, '0 0 52');
1285                         self.killindicator.think = KillIndicator_Think;
1286                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1287                         self.killindicator.cnt = ceil(killtime);
1288                         self.killindicator.count = bound(0, ceil(killtime), 10);
1289                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1290
1291                         for(e = world; (e = find(e, classname, "body")) != world; )
1292                         {
1293                                 if(e.enemy != self)
1294                                         continue;
1295                                 e.killindicator = spawn();
1296                                 e.killindicator.owner = e;
1297                                 e.killindicator.scale = 0.5;
1298                                 setattachment(e.killindicator, e, "");
1299                                 setorigin(e.killindicator, '0 0 52');
1300                                 e.killindicator.think = KillIndicator_Think;
1301                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1302                                 e.killindicator.cnt = ceil(killtime);
1303                         }
1304                         self.lip = 0;
1305                 }
1306         }
1307         if(self.killindicator)
1308         {
1309                 if(targetteam)
1310                         self.killindicator.colormod = TeamColor(targetteam);
1311                 else
1312                         self.killindicator.colormod = '0 0 0';
1313         }
1314 }
1315
1316 void ClientKill (void)
1317 {
1318         ClientKill_TeamChange(0);
1319 }
1320
1321 void DoTeamChange(float destteam)
1322 {
1323         float t, c0;
1324         if(!teams_matter)
1325         {
1326                 if(destteam >= 0)
1327                         SetPlayerColors(self, destteam);
1328                 return;
1329         }
1330         if(self.classname == "player")
1331         if(destteam == -1)
1332         {
1333                 CheckAllowedTeams(self);
1334                 t = FindSmallestTeam(self, TRUE);
1335                 switch(self.team)
1336                 {
1337                         case COLOR_TEAM1: c0 = c1; break;
1338                         case COLOR_TEAM2: c0 = c2; break;
1339                         case COLOR_TEAM3: c0 = c3; break;
1340                         case COLOR_TEAM4: c0 = c4; break;
1341                         default:          c0 = 999;
1342                 }
1343                 switch(t)
1344                 {
1345                         case 1:
1346                                 if(c0 > c1)
1347                                         destteam = COLOR_TEAM1;
1348                                 break;
1349                         case 2:
1350                                 if(c0 > c2)
1351                                         destteam = COLOR_TEAM2;
1352                                 break;
1353                         case 3:
1354                                 if(c0 > c3)
1355                                         destteam = COLOR_TEAM3;
1356                                 break;
1357                         case 4:
1358                                 if(c0 > c4)
1359                                         destteam = COLOR_TEAM4;
1360                                 break;
1361                 }
1362                 if(destteam == -1)
1363                         return;
1364         }
1365         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1366                 return;
1367         ClientKill_TeamChange(destteam);
1368 }
1369
1370 void FixClientCvars(entity e)
1371 {
1372         // send prediction settings to the client
1373         stuffcmd(e, "\nin_bindmap 0 0\n");
1374         if(g_race || g_cts)
1375                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1376         if(cvar("g_antilag") == 3) // client side hitscan
1377                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1378         if(sv_gentle)
1379                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1380         /*
1381          * we no longer need to stuff this. Remove this comment block if you feel
1382          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1383         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1384         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1385         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1386         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1387         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1388         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1389         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1390         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1391         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1392         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1393         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1394         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1395         stuffcmd(e, "cl_movement_edgefriction 1\n");
1396          */
1397 }
1398
1399 /*
1400 =============
1401 ClientConnect
1402
1403 Called when a client connects to the server
1404 =============
1405 */
1406 //void ctf_clientconnect();
1407 string ColoredTeamName(float t);
1408 void DecodeLevelParms (void);
1409 //void dom_player_join_team(entity pl);
1410 void ClientConnect (void)
1411 {
1412         float t;
1413
1414         if(self.flags & FL_CLIENT)
1415         {
1416                 print("Warning: ClientConnect, but already connected!\n");
1417                 return;
1418         }
1419
1420         if(Ban_MaybeEnforceBan(self))
1421                 return;
1422
1423         DecodeLevelParms();
1424
1425 #ifdef WATERMARK
1426         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1427 #endif
1428
1429         self.classname = "player_joining";
1430
1431         self.flags = FL_CLIENT;
1432         self.version_nagtime = time + 10 + random() * 10;
1433
1434         if(player_count<0)
1435         {
1436                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1437                 player_count = 0;
1438         }
1439
1440         PlayerScore_Attach(self);
1441         ClientData_Attach();
1442
1443         bot_clientconnect();
1444
1445         playerdemo_init();
1446
1447         anticheat_init();
1448
1449         race_PreSpawnObserver();
1450
1451         //if(g_domination)
1452         //      dom_player_join_team(self);
1453
1454         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1455
1456         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1457                 self.classname = "observer";
1458         } else {
1459                 if(teams_matter)
1460                 {
1461                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1462                         {
1463                                 self.classname = "player";
1464                                 campaign_bots_may_start = 1;
1465                         }
1466                         else
1467                         {
1468                                 self.classname = "observer"; // do it anyway
1469                         }
1470                 }
1471                 else
1472                 {
1473                         self.classname = "player";
1474                         campaign_bots_may_start = 1;
1475                 }
1476         }
1477
1478         self.playerid = (playerid_last = playerid_last + 1);
1479
1480         if(cvar("sv_eventlog"))
1481                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1482
1483         LogTeamchange(self.playerid, self.team, 1);
1484
1485         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1486
1487         self.netname_previous = strzone(self.netname);
1488
1489         bprint("^4", self.netname, "^4 connected");
1490
1491         if(self.classname != "observer" && (g_domination || g_ctf))
1492                 bprint(" and joined the ", ColoredTeamName(self.team));
1493
1494         bprint("\n");
1495
1496         self.welcomemessage_time = 0;
1497
1498         stuffcmd(self, strcat(clientstuff, "\n"));
1499         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1500         stuffcmd(self, "cl_particles_reloadeffects\n");
1501
1502         FixClientCvars(self);
1503
1504         // spawnfunc_waypoint sprites
1505         WaypointSprite_InitClient(self);
1506
1507         // Wazat's grappling hook
1508         SetGrappleHookBindings();
1509
1510         // get autoswitch state from player when he toggles it
1511         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1512
1513         // get version info from player
1514         stuffcmd(self, "cmd clientversion $gameversion\n");
1515
1516         // get other cvars from player
1517         GetCvars(0);
1518
1519         // set cvar for team scoreboard
1520         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1521
1522         // notify about available teams
1523         if(teams_matter)
1524         {
1525                 CheckAllowedTeams(self);
1526                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1527                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1528         }
1529         else
1530                 stuffcmd(self, "set _teams_available 0\n");
1531
1532         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1533
1534         if(g_arena || g_ca)
1535         {
1536                 self.classname = "observer";
1537                 if(g_arena)
1538                         Spawnqueue_Insert(self);
1539         }
1540         /*else if(g_ctf)
1541         {
1542                 ctf_clientconnect();
1543         }*/
1544
1545         if(teams_matter || radar_showennemies)
1546                 attach_entcs();
1547
1548         bot_relinkplayerlist();
1549
1550         self.spectatortime = time;
1551         if(blockSpectators)
1552         {
1553                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1554         }
1555
1556         self.jointime = time;
1557         self.allowedTimeouts = cvar("sv_timeout_number");
1558
1559         if(clienttype(self) == CLIENTTYPE_REAL)
1560         {
1561                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1562                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1563         }
1564
1565         if(g_lms)
1566         {
1567                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1568                 {
1569                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1570                         self.frags = FRAGS_SPECTATOR;
1571                 }
1572         }
1573
1574         if(!sv_foginterval && world.fog != "")
1575                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1576
1577         SoundEntity_Attach(self);
1578
1579         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1580         {
1581                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1582                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1583         }
1584         else
1585                 self.hitplotfh = -1;
1586
1587         if(g_race || g_cts) {
1588                 string rr;
1589                 if(g_cts)
1590                         rr = CTS_RECORD;
1591                 else
1592                         rr = RACE_RECORD;
1593                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1594
1595                 race_send_recordtime(MSG_ONE);
1596                 race_send_speedaward(MSG_ONE);
1597
1598                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1599                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1600                 race_send_speedaward_alltimebest(MSG_ONE);
1601
1602                 float i;
1603                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1604                         race_SendRankings(i, 0, 0, MSG_ONE);
1605                 }
1606         }
1607         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1608                 send_CSQC_teamnagger();
1609
1610         send_CSQC_nexvelocity(self);
1611         send_CSQC_cr_maxbullets(self);
1612
1613         CheatInitClient();
1614 }
1615
1616 /*
1617 =============
1618 ClientDisconnect
1619
1620 Called when a client disconnects from the server
1621 =============
1622 */
1623 .entity chatbubbleentity;
1624 .entity teambubbleentity;
1625 void ReadyCount();
1626 void ClientDisconnect (void)
1627 {
1628         if not(self.flags & FL_CLIENT)
1629         {
1630                 print("Warning: ClientDisconnect without ClientConnect\n");
1631                 return;
1632         }
1633
1634         CheatShutdownClient();
1635
1636         if(self.hitplotfh >= 0)
1637         {
1638                 fclose(self.hitplotfh);
1639                 self.hitplotfh = -1;
1640         }
1641
1642         anticheat_report();
1643         anticheat_shutdown();
1644
1645         playerdemo_shutdown();
1646
1647         bot_clientdisconnect();
1648
1649         if(self.entcs)
1650                 detach_entcs();
1651
1652         if(cvar("sv_eventlog"))
1653                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1654         bprint ("^4",self.netname);
1655         bprint ("^4 disconnected\n");
1656
1657         SoundEntity_Detach(self);
1658
1659         DropAllRunes(self);
1660         MUTATOR_CALLHOOK(ClientDisconnect);
1661
1662         Portal_ClearAll(self);
1663
1664         if(self.flagcarried)
1665                 DropFlag(self.flagcarried, world, world);
1666         if(self.ballcarried)
1667                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1668
1669         // Here, everything has been done that requires this player to be a client.
1670
1671         self.flags &~= FL_CLIENT;
1672
1673         if (self.chatbubbleentity)
1674                 remove (self.chatbubbleentity);
1675
1676         if (self.teambubbleentity)
1677                 remove (self.teambubbleentity);
1678
1679         if (self.killindicator)
1680                 remove (self.killindicator);
1681
1682         WaypointSprite_PlayerGone();
1683
1684         bot_relinkplayerlist();
1685
1686         // remove laserdot
1687         if(self.weaponentity)
1688                 if(self.weaponentity.lasertarget)
1689                         remove(self.weaponentity.lasertarget);
1690
1691         if(g_arena)
1692         {
1693                 Spawnqueue_Unmark(self);
1694                 Spawnqueue_Remove(self);
1695         }
1696
1697         ClientData_Detach();
1698         PlayerScore_Detach(self);
1699
1700         if(self.netname_previous)
1701                 strunzone(self.netname_previous);
1702         if(self.clientstatus)
1703                 strunzone(self.clientstatus);
1704
1705         ClearPlayerSounds();
1706
1707         if(self.personal)
1708                 remove(self.personal);
1709
1710         self.playerid = 0;
1711         ReadyCount();
1712
1713         // free cvars
1714         GetCvars(-1);
1715 }
1716
1717 .float BUTTON_CHAT;
1718 void ChatBubbleThink()
1719 {
1720         self.nextthink = time;
1721         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1722         {
1723                 if(self.owner) // but why can that ever be world?
1724                         self.owner.chatbubbleentity = world;
1725                 remove(self);
1726                 return;
1727         }
1728         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1729 #ifdef TETRIS
1730                 || self.owner.tetris_on
1731 #endif
1732         )
1733                 self.model = self.mdl;
1734         else
1735                 self.model = "";
1736 };
1737
1738 void UpdateChatBubble()
1739 {
1740         if (!self.modelindex)
1741                 return;
1742         // spawn a chatbubble entity if needed
1743         if (!self.chatbubbleentity)
1744         {
1745                 self.chatbubbleentity = spawn();
1746                 self.chatbubbleentity.owner = self;
1747                 self.chatbubbleentity.exteriormodeltoclient = self;
1748                 self.chatbubbleentity.think = ChatBubbleThink;
1749                 self.chatbubbleentity.nextthink = time;
1750                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1751                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1752                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1753                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1754                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1755                 self.chatbubbleentity.model = "";
1756                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1757         }
1758 }
1759
1760
1761 void TeamBubbleThink()
1762 {
1763         self.nextthink = time;
1764         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1765         {
1766                 if(self.owner) // but why can that ever be world?
1767                         self.owner.teambubbleentity = world;
1768                 remove(self);
1769                 return;
1770         }
1771 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1772         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1773                 self.model = "";
1774         else
1775                 self.model = self.mdl;
1776
1777 };
1778
1779 float TeamBubble_customizeentityforclient()
1780 {
1781         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1782 }
1783
1784 void UpdateTeamBubble()
1785 {
1786         if (!self.modelindex || !teams_matter)
1787                 return;
1788         // spawn a teambubble entity if needed
1789         if (!self.teambubbleentity && teams_matter)
1790         {
1791                 self.teambubbleentity = spawn();
1792                 self.teambubbleentity.owner = self;
1793                 self.teambubbleentity.exteriormodeltoclient = self;
1794                 self.teambubbleentity.think = TeamBubbleThink;
1795                 self.teambubbleentity.nextthink = time;
1796                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1797 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1798                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1799                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1800                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1801                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1802                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1803                 self.teambubbleentity.effects = EF_LOWPRECISION;
1804         }
1805 }
1806
1807 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1808 // added to the model skins
1809 /*void UpdateColorModHack()
1810 {
1811         local float c;
1812         c = self.clientcolors & 15;
1813         // LordHavoc: only bothering to support white, green, red, yellow, blue
1814              if (!teams_matter) self.colormod = '0 0 0';
1815         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1816         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1817         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1818         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1819         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1820         else self.colormod = '1 1 1';
1821 };*/
1822
1823 .float oldcolormap;
1824 void respawn(void)
1825 {
1826         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1827         {
1828                 self.solid = SOLID_NOT;
1829                 self.takedamage = DAMAGE_NO;
1830                 self.movetype = MOVETYPE_FLY;
1831                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1832                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1833                 self.effects |= EF_ADDITIVE;
1834                 self.oldcolormap = self.colormap;
1835                 self.colormap = 512;
1836                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1837                 if(cvar("g_respawn_ghosts_maxtime"))
1838                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1839         }
1840
1841         CopyBody(1);
1842         self.effects |= EF_NODRAW; // prevent another CopyBody
1843         if(self.oldcolormap)
1844         {
1845                 self.colormap = self.oldcolormap;
1846                 self.oldcolormap = 0;
1847         }
1848         PutClientInServer();
1849 }
1850
1851 void play_countdown(float finished, string samp)
1852 {
1853         if(clienttype(self) == CLIENTTYPE_REAL)
1854                 if(floor(finished - time - frametime) != floor(finished - time))
1855                         if(finished - time < 6)
1856                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1857 }
1858
1859 /**
1860  * When sv_timeout is used this function returs strings like
1861  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1862  * Called by centerprint functions
1863  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1864  */
1865 string getTimeoutText(float addOneSecond) {
1866         if (!cvar("sv_timeout") || !timeoutStatus)
1867                 return "";
1868
1869         local string retStr;
1870         if (timeoutStatus == 1) {
1871                 if (addOneSecond == 1) {
1872                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1873                 }
1874                 else {
1875                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1876                 }
1877                 return retStr;
1878         }
1879         else if (timeoutStatus == 2) {
1880                 if (addOneSecond) {
1881                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1882                         //don't show messages like "Timeout ends in 0 seconds"...
1883                         if ((remainingTimeoutTime + 1) > 0)
1884                                 return retStr;
1885                         else
1886                                 return "";
1887                 }
1888                 else {
1889                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1890                         //don't show messages like "Timeout ends in 0 seconds"...
1891                         if (remainingTimeoutTime > 0)
1892                                 return retStr;
1893                         else
1894                                 return "";
1895                 }
1896         }
1897         else return "";
1898 }
1899
1900 void player_powerups (void)
1901 {
1902         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1903         {
1904                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1905                 self.modelflags |= MF_ROCKET;
1906         }
1907         else
1908         {
1909                 SoundEntity_StopSound(self, CHAN_PLAYER);
1910                 self.modelflags &~= MF_ROCKET;
1911         }
1912
1913         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1914
1915         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1916                 return;
1917
1918         Fire_ApplyDamage(self);
1919         Fire_ApplyEffect(self);
1920
1921         if (g_minstagib)
1922         {
1923                 self.effects |= EF_FULLBRIGHT;
1924
1925                 if (self.items & IT_STRENGTH)
1926                 {
1927                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1928                         if (time > self.strength_finished)
1929                         {
1930                                 self.alpha = default_player_alpha;
1931                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1932                                 self.items &~= IT_STRENGTH;
1933                                 sprint(self, "^3Invisibility has worn off\n");
1934                         }
1935                 }
1936                 else
1937                 {
1938                         if (time < self.strength_finished)
1939                         {
1940                                 self.alpha = g_minstagib_invis_alpha;
1941                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1942                                 self.items |= IT_STRENGTH;
1943                                 sprint(self, "^3You are invisible\n");
1944                         }
1945                 }
1946
1947                 if (self.items & IT_INVINCIBLE)
1948                 {
1949                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1950                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1951                         {
1952                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1953                                 sprint(self, "^3Speed has worn off\n");
1954                         }
1955                 }
1956                 else
1957                 {
1958                         if (time < self.invincible_finished)
1959                         {
1960                                 self.items = self.items | IT_INVINCIBLE;
1961                                 sprint(self, "^3You are on speed\n");
1962                         }
1963                 }
1964                 return;
1965         }
1966
1967         if (self.items & IT_STRENGTH)
1968         {
1969                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1970                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1971                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1972                 {
1973                         self.items = self.items - (self.items & IT_STRENGTH);
1974                         sprint(self, "^3Strength has worn off\n");
1975                 }
1976         }
1977         else
1978         {
1979                 if (time < self.strength_finished)
1980                 {
1981                         self.items = self.items | IT_STRENGTH;
1982                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1983                 }
1984         }
1985         if (self.items & IT_INVINCIBLE)
1986         {
1987                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1988                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1989                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1990                 {
1991                         self.items = self.items - (self.items & IT_INVINCIBLE);
1992                         sprint(self, "^3Shield has worn off\n");
1993                 }
1994         }
1995         else
1996         {
1997                 if (time < self.invincible_finished)
1998                 {
1999                         self.items = self.items | IT_INVINCIBLE;
2000                         sprint(self, "^3Shield surrounds you\n");
2001                 }
2002         }
2003
2004         if(cvar("g_nodepthtestplayers"))
2005                 self.effects = self.effects | EF_NODEPTHTEST;
2006
2007         if(cvar("g_fullbrightplayers"))
2008                 self.effects = self.effects | EF_FULLBRIGHT;
2009
2010         // midair gamemode: damage only while in the air
2011         // if in midair mode, being on ground grants temporary invulnerability
2012         // (this is so that multishot weapon don't clear the ground flag on the
2013         // first damage in the frame, leaving the player vulnerable to the
2014         // remaining hits in the same frame)
2015         if (self.flags & FL_ONGROUND)
2016         if (g_midair)
2017                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2018
2019         if (time >= game_starttime)
2020         if (time < self.spawnshieldtime)
2021                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2022 }
2023
2024 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2025 {
2026         if(current > stable)
2027                 return current;
2028         else if(current > stable - 0.25) // when close enough, "snap"
2029                 return stable;
2030         else
2031                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2032 }
2033
2034 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2035 {
2036         if(current < stable)
2037                 return current;
2038         else if(current < stable + 0.25) // when close enough, "snap"
2039                 return stable;
2040         else
2041                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2042 }
2043
2044 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2045 {
2046         if(current > rotstable)
2047         {
2048                 if(rotframetime > 0)
2049                 {
2050                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2051                         current = max(rotstable, current - rotlinear * rotframetime);
2052                 }
2053         }
2054         else if(current < regenstable)
2055         {
2056                 if(regenframetime > 0)
2057                 {
2058                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2059                         current = min(regenstable, current + regenlinear * regenframetime);
2060                 }
2061         }
2062
2063         if(current > limit)
2064                 current = limit;
2065
2066         return current;
2067 }
2068
2069 void player_regen (void)
2070 {
2071         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2072         maxh = cvar("g_balance_health_rotstable");
2073         maxa = cvar("g_balance_armor_rotstable");
2074         maxf = cvar("g_balance_fuel_rotstable");
2075         minh = cvar("g_balance_health_regenstable");
2076         mina = cvar("g_balance_armor_regenstable");
2077         minf = cvar("g_balance_fuel_regenstable");
2078         limith = cvar("g_balance_health_limit");
2079         limita = cvar("g_balance_armor_limit");
2080         limitf = cvar("g_balance_fuel_limit");
2081
2082         max_mod = regen_mod = rot_mod = limit_mod = 1;
2083
2084         if (self.runes & RUNE_REGEN)
2085         {
2086                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2087                 {
2088                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2089                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2090                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2091                 }
2092                 else
2093                 {
2094                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2095                         max_mod = cvar("g_balance_rune_regen_hpmod");
2096                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2097                 }
2098         }
2099         else if (self.runes & CURSE_VENOM)
2100         {
2101                 max_mod = cvar("g_balance_curse_venom_hpmod");
2102                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2103                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2104                 else
2105                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2106                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2107                 //if (!self.runes & RUNE_REGEN)
2108                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2109         }
2110         maxh = maxh * max_mod;
2111         //maxa = maxa * max_mod;
2112         //maxf = maxf * max_mod;
2113         minh = minh * max_mod;
2114         //mina = mina * max_mod;
2115         //minf = minf * max_mod;
2116         limith = limith * limit_mod;
2117         limita = limita * limit_mod;
2118         //limitf = limitf * limit_mod;
2119
2120         if(g_lms && g_ca)
2121                 rot_mod = 0;
2122
2123         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2124         {
2125                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2126                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2127
2128                 // if player rotted to death...  die!
2129                 if(self.health < 1)
2130                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2131         }
2132
2133         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2134                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2135 }
2136
2137 float zoomstate_set;
2138 void SetZoomState(float z)
2139 {
2140         if(z != self.zoomstate)
2141         {
2142                 self.zoomstate = z;
2143                 ClientData_Touch(self);
2144         }
2145         zoomstate_set = 1;
2146 }
2147
2148 void GetPressedKeys(void) {
2149         MUTATOR_CALLHOOK(GetPressedKeys);
2150         if (self.movement_x > 0) // get if movement keys are pressed
2151         {       // forward key pressed
2152                 self.pressedkeys |= KEY_FORWARD;
2153                 self.pressedkeys &~= KEY_BACKWARD;
2154         }
2155         else if (self.movement_x < 0)
2156         {       // backward key pressed
2157                 self.pressedkeys |= KEY_BACKWARD;
2158                 self.pressedkeys &~= KEY_FORWARD;
2159         }
2160         else
2161         {       // no x input
2162                 self.pressedkeys &~= KEY_FORWARD;
2163                 self.pressedkeys &~= KEY_BACKWARD;
2164         }
2165
2166         if (self.movement_y > 0)
2167         {       // right key pressed
2168                 self.pressedkeys |= KEY_RIGHT;
2169                 self.pressedkeys &~= KEY_LEFT;
2170         }
2171         else if (self.movement_y < 0)
2172         {       // left key pressed
2173                 self.pressedkeys |= KEY_LEFT;
2174                 self.pressedkeys &~= KEY_RIGHT;
2175         }
2176         else
2177         {       // no y input
2178                 self.pressedkeys &~= KEY_RIGHT;
2179                 self.pressedkeys &~= KEY_LEFT;
2180         }
2181
2182         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2183                 self.pressedkeys |= KEY_JUMP;
2184         else
2185                 self.pressedkeys &~= KEY_JUMP;
2186         if (self.BUTTON_CROUCH)
2187                 self.pressedkeys |= KEY_CROUCH;
2188         else
2189                 self.pressedkeys &~= KEY_CROUCH;
2190 }
2191
2192 void update_stats (float number, float hit, float fired) {
2193 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2194 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2195
2196         if(number) {
2197                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2198                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2199         } else {
2200                 self.stat_hit = hit * sv_accuracy_data_share;
2201                 self.stat_fired = fired * sv_accuracy_data_share;
2202         }
2203 }
2204
2205 /*
2206 ======================
2207 spectate mode routines
2208 ======================
2209 */
2210
2211 .float weapon_count;
2212 void SpectateCopy(entity spectatee) {
2213         if(spectatee.weapon_count < WEP_LAST) {
2214                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2215                 spectatee.weapon_count ++;
2216         } else
2217                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2218
2219         other = spectatee;
2220         MUTATOR_CALLHOOK(SpectateCopy);
2221         self.armortype = spectatee.armortype;
2222         self.armorvalue = spectatee.armorvalue;
2223         self.ammo_cells = spectatee.ammo_cells;
2224         self.ammo_shells = spectatee.ammo_shells;
2225         self.ammo_nails = spectatee.ammo_nails;
2226         self.ammo_rockets = spectatee.ammo_rockets;
2227         self.ammo_fuel = spectatee.ammo_fuel;
2228         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2229         self.health = spectatee.health;
2230         self.impulse = 0;
2231         self.items = spectatee.items;
2232         self.metertime = spectatee.metertime;
2233         self.strength_finished = spectatee.strength_finished;
2234         self.invincible_finished = spectatee.invincible_finished;
2235         self.pressedkeys = spectatee.pressedkeys;
2236         self.weapons = spectatee.weapons;
2237         self.switchweapon = spectatee.switchweapon;
2238         self.weapon = spectatee.weapon;
2239         self.punchangle = spectatee.punchangle;
2240         self.view_ofs = spectatee.view_ofs;
2241         self.v_angle = spectatee.v_angle;
2242         self.velocity = spectatee.velocity;
2243         self.dmg_take = spectatee.dmg_take;
2244         self.dmg_save = spectatee.dmg_save;
2245         self.dmg_inflictor = spectatee.dmg_inflictor;
2246         self.angles = spectatee.v_angle;
2247         self.fixangle = TRUE;
2248         setorigin(self, spectatee.origin);
2249         setsize(self, spectatee.mins, spectatee.maxs);
2250         SetZoomState(spectatee.zoomstate);
2251
2252         anticheat_spectatecopy(spectatee);
2253 }
2254
2255 float SpectateUpdate() {
2256         if(!self.enemy)
2257                 return 0;
2258
2259         if (self == self.enemy)
2260                 return 0;
2261
2262         if(self.enemy.classname != "player")
2263                 return 0;
2264
2265         SpectateCopy(self.enemy);
2266
2267         return 1;
2268 }
2269
2270 float SpectateNext() {
2271         other = find(self.enemy, classname, "player");
2272
2273         if (!other)
2274                 other = find(other, classname, "player");
2275
2276         if (other)
2277                 self.enemy = other;
2278
2279         if(self.enemy.classname == "player") {
2280                 msg_entity = self;
2281                 WriteByte(MSG_ONE, SVC_SETVIEW);
2282                 WriteEntity(MSG_ONE, self.enemy);
2283                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2284                 self.movetype = MOVETYPE_NONE;
2285
2286                 self.enemy.weapon_count = 0;
2287
2288                 if(!SpectateUpdate())
2289                         PutObserverInServer();
2290
2291                 return 1;
2292         } else {
2293                 return 0;
2294         }
2295 }
2296
2297 /*
2298 =============
2299 ShowRespawnCountdown()
2300
2301 Update a respawn countdown display.
2302 =============
2303 */
2304 void ShowRespawnCountdown()
2305 {
2306         float number;
2307         if(self.deadflag == DEAD_NO) // just respawned?
2308                 return;
2309         else
2310         {
2311                 number = ceil(self.death_time - time);
2312                 if(number <= 0)
2313                         return;
2314                 if(number <= self.respawn_countdown)
2315                 {
2316                         self.respawn_countdown = number - 1;
2317                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2318                                 AnnounceTo(self, strcat(ftos(number), ""));
2319                 }
2320         }
2321 }
2322
2323 void LeaveSpectatorMode()
2324 {
2325         if(isJoinAllowed()) {
2326                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2327                         self.classname = "player";
2328
2329                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2330                                 JoinBestTeam(self, FALSE, TRUE);
2331
2332                         if(cvar("g_campaign"))
2333                                 campaign_bots_may_start = 1;
2334
2335                         self.stat_count = WEP_LAST;
2336
2337                         PutClientInServer();
2338
2339                         if(self.classname == "player")
2340                                 bprint ("^4", self.netname, "^4 is playing now\n");
2341
2342                         if(!cvar("g_campaign"))
2343                                 centerprint(self,""); // clear MOTD
2344
2345                         return;
2346                 } else {
2347                         if (g_ca && self.caplayer) {
2348                         }       // do nothing
2349                         else
2350                                 stuffcmd(self,"menu_showteamselect\n");
2351                         return;
2352                 }
2353         }
2354         else {
2355                 //player may not join because of g_maxplayers is set
2356                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2357         }
2358 }
2359
2360 /**
2361  * Determines whether the player is allowed to join. This depends on cvar
2362  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2363  * it checks whether the number of currently playing players exceeds g_maxplayers.
2364  * @return bool TRUE if the player is allowed to join, false otherwise
2365  */
2366 float isJoinAllowed() {
2367         if (!cvar("g_maxplayers"))
2368                 return TRUE;
2369
2370         local entity e;
2371         local float currentlyPlaying;
2372         FOR_EACH_REALPLAYER(e) {
2373                 if(e.classname == "player")
2374                         currentlyPlaying += 1;
2375         }
2376         if(currentlyPlaying < cvar("g_maxplayers"))
2377                 return TRUE;
2378
2379         return FALSE;
2380 }
2381
2382 /**
2383  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2384  * g_maxplayers_spectator_blocktime seconds
2385  */
2386 void checkSpectatorBlock() {
2387         if(self.classname == "spectator" || self.classname == "observer") {
2388                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2389                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2390                         dropclient(self);
2391                 }
2392         }
2393 }
2394
2395 float vercmp_recursive(string v1, string v2)
2396 {
2397         float dot1, dot2;
2398         string s1, s2;
2399         float r;
2400
2401         dot1 = strstrofs(v1, ".", 0);
2402         dot2 = strstrofs(v2, ".", 0);
2403         if(dot1 == -1)
2404                 s1 = v1;
2405         else
2406                 s1 = substring(v1, 0, dot1);
2407         if(dot2 == -1)
2408                 s2 = v2;
2409         else
2410                 s2 = substring(v2, 0, dot2);
2411
2412         r = stof(s1) - stof(s2);
2413         if(r != 0)
2414                 return r;
2415
2416         r = strcasecmp(s1, s2);
2417         if(r != 0)
2418                 return r;
2419
2420         if(dot1 == -1)
2421                 if(dot2 == -1)
2422                         return 0;
2423                 else
2424                         return -1;
2425         else
2426                 if(dot2 == -1)
2427                         return 1;
2428                 else
2429                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2430 }
2431
2432 float vercmp(string v1, string v2)
2433 {
2434         if(strcasecmp(v1, v2) == 0) // early out check
2435                 return 0;
2436         return vercmp_recursive(v1, v2);
2437 }
2438
2439 void ObserverThink()
2440 {
2441         if (self.flags & FL_JUMPRELEASED) {
2442                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2443                         self.welcomemessage_time = 0;
2444                         self.flags &~= FL_JUMPRELEASED;
2445                         self.flags |= FL_SPAWNING;
2446                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2447                         self.welcomemessage_time = 0;
2448                         self.flags &~= FL_JUMPRELEASED;
2449                         if(SpectateNext() == 1) {
2450                                 self.classname = "spectator";
2451                         }
2452                 }
2453         } else {
2454                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2455                         self.flags |= FL_JUMPRELEASED;
2456                         if(self.flags & FL_SPAWNING)
2457                         {
2458                                 self.flags &~= FL_SPAWNING;
2459                                 LeaveSpectatorMode();
2460                                 return;
2461                         }
2462                 }
2463         }
2464         PrintWelcomeMessage(self);
2465 }
2466
2467 void SpectatorThink()
2468 {
2469         if (self.flags & FL_JUMPRELEASED) {
2470                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2471                         self.welcomemessage_time = 0;
2472                         self.flags &~= FL_JUMPRELEASED;
2473                         self.flags |= FL_SPAWNING;
2474                 } else if(self.BUTTON_ATCK) {
2475                         self.welcomemessage_time = 0;
2476                         self.flags &~= FL_JUMPRELEASED;
2477                         if(SpectateNext() == 1) {
2478                                 self.classname = "spectator";
2479                         } else {
2480                                 self.classname = "observer";
2481                                 self.stat_count = WEP_LAST;
2482                                 PutClientInServer();
2483                         }
2484                 } else if (self.BUTTON_ATCK2) {
2485                         self.welcomemessage_time = 0;
2486                         self.flags &~= FL_JUMPRELEASED;
2487                         self.classname = "observer";
2488                         self.stat_count = WEP_LAST;
2489                         PutClientInServer();
2490                 } else {
2491                         if(!SpectateUpdate())
2492                                 PutObserverInServer();
2493                 }
2494         } else {
2495                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2496                         self.flags |= FL_JUMPRELEASED;
2497                         if(self.flags & FL_SPAWNING)
2498                         {
2499                                 self.flags &~= FL_SPAWNING;
2500                                 LeaveSpectatorMode();
2501                                 return;
2502                         }
2503                 }
2504         }
2505
2506         PrintWelcomeMessage(self);
2507         self.flags |= FL_CLIENT | FL_NOTARGET;
2508 }
2509
2510 .float touchexplode_time;
2511
2512 /*
2513 =============
2514 PlayerPreThink
2515
2516 Called every frame for each client before the physics are run
2517 =============
2518 */
2519 void() ctf_setstatus;
2520 void() nexball_setstatus;
2521 .float items_added;
2522 void PlayerPreThink (void)
2523 {
2524         self.stat_game_starttime = game_starttime;
2525         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2526         self.stat_leadlimit = cvar("leadlimit");
2527
2528         if(frametime)
2529         {
2530                 // physics frames: update anticheat stuff
2531                 anticheat_prethink();
2532         }
2533
2534         if(blockSpectators && frametime)
2535                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2536                 checkSpectatorBlock();
2537
2538         zoomstate_set = 0;
2539
2540         if(self.netname_previous != self.netname)
2541         {
2542                 if(cvar("sv_eventlog"))
2543                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2544                 if(self.netname_previous)
2545                         strunzone(self.netname_previous);
2546                 self.netname_previous = strzone(self.netname);
2547         }
2548
2549         // version nagging
2550         if(self.version_nagtime)
2551                 if(self.cvar_g_xonoticversion)
2552                         if(time > self.version_nagtime)
2553                         {
2554                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2555                                 {
2556                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2557                                         {
2558                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2559                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2560                                         }
2561                                         else
2562                                         {
2563                                                 float r;
2564                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2565                                                 if(r < 0)
2566                                                 {
2567                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2568                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2569                                                 }
2570                                                 else if(r > 0)
2571                                                 {
2572                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2573                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2574                                                 }
2575                                         }
2576                                 }
2577                                 self.version_nagtime = 0;
2578                         }
2579
2580         // GOD MODE info
2581         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2582         {
2583                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2584                 self.max_armorvalue = 0;
2585         }
2586
2587 #ifdef TETRIS
2588         if (TetrisPreFrame())
2589                 return;
2590 #endif
2591
2592         MUTATOR_CALLHOOK(PlayerPreThink);
2593
2594         if(self.classname == "player") {
2595 //              if(self.netname == "Wazat")
2596 //                      bprint(self.classname, "\n");
2597
2598                 CheckRules_Player();
2599
2600                 PrintWelcomeMessage(self);
2601
2602                 if (intermission_running)
2603                 {
2604                         IntermissionThink ();   // otherwise a button could be missed between
2605                         return;                                 // the think tics
2606                 }
2607
2608                 if(self.teleport_time)
2609                 if(time > self.teleport_time)
2610                 {
2611                         self.teleport_time = 0;
2612                         self.effects = self.effects - (self.effects & EF_NODRAW);
2613                 }
2614
2615                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2616                         UpdateSelectedPlayer();
2617
2618                 //don't allow the player to turn around while game is paused!
2619                 if(timeoutStatus == 2) {
2620                         self.v_angle = self.lastV_angle;
2621                         self.angles = self.lastV_angle;
2622                         self.fixangle = TRUE;
2623                 }
2624
2625                 if(frametime)
2626                 {
2627                         if(self.health <= 0 && cvar("g_deathglow"))
2628                         {
2629                                 if(self.glowmod_x > 0)
2630                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2631                                 else
2632                                         self.glowmod_x = -1;
2633                                 if(self.glowmod_y > 0)
2634                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2635                                 else
2636                                         self.glowmod_y = -1;
2637                                 if(self.glowmod_z > 0)
2638                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2639                                 else
2640                                         self.glowmod_z = -1;
2641                         }
2642                         else
2643                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2644                         player_powerups();
2645                 }
2646
2647                 if (self.deadflag != DEAD_NO)
2648                 {
2649                         float button_pressed, force_respawn;
2650                         if(self.personal && g_race_qualifying)
2651                         {
2652                                 if(time > self.death_time)
2653                                 {
2654                                         self.death_time = time + 1; // only retry once a second
2655                                         respawn();
2656                                         self.impulse = 141;
2657                                 }
2658                         }
2659                         else
2660                         {
2661                                 if(frametime)
2662                                         player_anim();
2663                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2664                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2665                                 if (self.deadflag == DEAD_DYING)
2666                                 {
2667                                         if(force_respawn)
2668                                                 self.deadflag = DEAD_RESPAWNING;
2669                                         else if(!button_pressed)
2670                                                 self.deadflag = DEAD_DEAD;
2671                                 }
2672                                 else if (self.deadflag == DEAD_DEAD)
2673                                 {
2674                                         if(button_pressed)
2675                                                 self.deadflag = DEAD_RESPAWNABLE;
2676                                 }
2677                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2678                                 {
2679                                         if(!button_pressed)
2680                                                 self.deadflag = DEAD_RESPAWNING;
2681                                 }
2682                                 else if (self.deadflag == DEAD_RESPAWNING)
2683                                 {
2684                                         if(time > self.death_time)
2685                                         {
2686                                                 self.death_time = time + 1; // only retry once a second
2687                                                 respawn();
2688                                         }
2689                                 }
2690                                 ShowRespawnCountdown();
2691                         }
2692                         return;
2693                 }
2694
2695                 if(g_touchexplode)
2696                 if(time > self.touchexplode_time)
2697                 if(self.classname == "player")
2698                 if(self.deadflag == DEAD_NO)
2699                 if not(IS_INDEPENDENT_PLAYER(self))
2700                 FOR_EACH_PLAYER(other) if(self != other)
2701                 {
2702                         if(time > other.touchexplode_time)
2703                         if(other.deadflag == DEAD_NO)
2704                         if not(IS_INDEPENDENT_PLAYER(other))
2705                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2706                         {
2707                                 PlayerTouchExplode(self, other);
2708                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2709                         }
2710                 }
2711
2712                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2713                 {
2714                         vector dist;
2715
2716                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2717                         dist = self.prevorigin - self.origin;
2718                         dist_z = 0;
2719                         self.lms_traveled_distance += fabs(vlen(dist));
2720
2721                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2722                         {
2723                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2724                                 self.lms_traveled_distance = 0;
2725                         }
2726
2727                         if(time > self.lms_nextcheck)
2728                         {
2729                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2730                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2731                                 {
2732                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2733                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2734                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2735                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2736                                 }
2737                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2738                                 self.lms_traveled_distance = 0;
2739                         }
2740                 }
2741
2742                 self.prevorigin = self.origin;
2743
2744                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2745                 {
2746                         if (!self.crouch)
2747                         {
2748                                 self.crouch = TRUE;
2749                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2750                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2751                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2752                         }
2753                 }
2754                 else
2755                 {
2756                         if (self.crouch)
2757                         {
2758                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2759                                 if (!trace_startsolid)
2760                                 {
2761                                         self.crouch = FALSE;
2762                                         self.view_ofs = PL_VIEW_OFS;
2763                                         setsize (self, PL_MIN, PL_MAX);
2764                                 }
2765                         }
2766                 }
2767
2768                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2769                 {
2770                         if(self.bloodloss_timer < time)
2771                         {
2772                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2773                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2774                         }
2775                 }
2776
2777                 FixPlayermodel();
2778
2779                 GrapplingHookFrame();
2780
2781                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2782                 //if(frametime)
2783                 {
2784                         self.items &~= self.items_added;
2785
2786                         W_WeaponFrame();
2787
2788                         self.items_added = 0;
2789                         if(self.items & IT_JETPACK)
2790                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2791                                         self.items_added |= IT_FUEL;
2792
2793                         self.items |= self.items_added;
2794                 }
2795
2796                 player_regen();
2797                 if(frametime)
2798                         player_anim();
2799
2800                 if (g_minstagib)
2801                         minstagib_ammocheck();
2802
2803                 ctf_setstatus();
2804                 nexball_setstatus();
2805
2806                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2807
2808                 //self.angles_y=self.v_angle_y + 90;   // temp
2809         } else if(gameover) {
2810                 if (intermission_running)
2811                         IntermissionThink ();   // otherwise a button could be missed between
2812                 return;
2813         } else if(self.classname == "observer") {
2814                 ObserverThink();
2815         } else if(self.classname == "spectator") {
2816                 SpectatorThink();
2817         }
2818
2819         if(!zoomstate_set)
2820                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2821
2822         float oldspectatee_status;
2823         oldspectatee_status = self.spectatee_status;
2824         if(self.classname == "spectator")
2825                 self.spectatee_status = num_for_edict(self.enemy);
2826         else if(self.classname == "observer")
2827                 self.spectatee_status = num_for_edict(self);
2828         else
2829                 self.spectatee_status = 0;
2830         if(self.spectatee_status != oldspectatee_status)
2831         {
2832                 ClientData_Touch(self);
2833                 if(g_race || g_cts)
2834                         race_InitSpectator();
2835         }
2836
2837         if(self.teamkill_soundtime)
2838         if(time > self.teamkill_soundtime)
2839         {
2840                 self.teamkill_soundtime = 0;
2841
2842                 entity oldpusher, oldself;
2843
2844                 oldself = self; self = self.teamkill_soundsource;
2845                 oldpusher = self.pusher; self.pusher = oldself;
2846
2847                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2848
2849                 self.pusher = oldpusher;
2850                 self = oldself;
2851         }
2852
2853         if(self.taunt_soundtime)
2854         if(time > self.taunt_soundtime)
2855         {
2856                 self.taunt_soundtime = 0;
2857                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2858         }
2859
2860         target_voicescript_next(self);
2861 }
2862
2863 float isInvisibleString(string s)
2864 {
2865         float i, n, c;
2866         s = strdecolorize(s);
2867         for((i = 0), (n = strlen(s)); i < n; ++i)
2868         {
2869                 c = str2chr(s, i);
2870                 switch(c)
2871                 {
2872                         case 0:
2873                         case 32: // space
2874                                 break;
2875                         case 192: // charmap space
2876                                 if (!cvar("utf8_enable"))
2877                                         break;
2878                                 return FALSE;
2879                         case 160: // space in unicode fonts
2880                         case 0xE000 + 192: // utf8 charmap space
2881                                 if (cvar("utf8_enable"))
2882                                         break;
2883                         default:
2884                                 return FALSE;
2885                 }
2886         }
2887         return TRUE;
2888 }
2889
2890 /*
2891 =============
2892 PlayerPostThink
2893
2894 Called every frame for each client after the physics are run
2895 =============
2896 */
2897 .float idlekick_lasttimeleft;
2898 .entity showheadshotbbox;
2899 void showheadshotbbox_think()
2900 {
2901         if(self.owner.showheadshotbbox != self)
2902         {
2903                 remove(self);
2904                 return;
2905         }
2906         self.nextthink = time;
2907         setorigin(self, self.owner.origin);
2908         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2909 }
2910 void PlayerPostThink (void)
2911 {
2912         // Savage: Check for nameless players
2913         if (isInvisibleString(self.netname)) {
2914                 self.netname = "Player";
2915                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2916         }
2917
2918         // send the clients accuracy stats to the client
2919         if(self.stat_count > 0)
2920         if(frametime)
2921         {
2922                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2923                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2924                 self.stat_count -= 1;
2925         }
2926
2927         if(sv_maxidle && frametime)
2928         {
2929                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2930                 float timeleft;
2931                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2932                 if(timeleft <= 0)
2933                 {
2934                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2935                         AnnounceTo(self, "terminated");
2936                         dropclient(self);
2937                         return;
2938                 }
2939                 else if(timeleft <= 10)
2940                 {
2941                         if(timeleft != self.idlekick_lasttimeleft)
2942                         {
2943                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2944                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2945                         }
2946                 }
2947                 else
2948                 {
2949                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2950                 }
2951                 self.idlekick_lasttimeleft = timeleft;
2952         }
2953
2954 #ifdef TETRIS
2955         if(self.impulse == 100)
2956                 ImpulseCommands();
2957         if (TetrisPostFrame())
2958                 return;
2959 #endif
2960
2961         CheatFrame();
2962
2963         if(self.classname == "player") {
2964                 CheckRules_Player();
2965                 UpdateChatBubble();
2966                 UpdateTeamBubble();
2967                 if (self.impulse)
2968                         ImpulseCommands();
2969                 if (intermission_running)
2970                         return;         // intermission or finale
2971                 GetPressedKeys();
2972         } else if (self.classname == "observer") {
2973                 //do nothing
2974         } else if (self.classname == "spectator") {
2975                 //do nothing
2976         }
2977
2978         /*
2979         float i;
2980         for(i = 0; i < 1000; ++i)
2981         {
2982                 vector end;
2983                 end = self.origin + '0 0 1024' + 512 * randomvec();
2984                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2985                 if(trace_fraction < 1)
2986                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2987                 {
2988                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2989                         break;
2990                 }
2991         }
2992         */
2993
2994         Arena_Warmup();
2995
2996         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2997
2998         if(self.waypointsprite_attachedforcarrier)
2999                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3000
3001         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3002         {
3003                 if(!self.showheadshotbbox)
3004                 {
3005                         self.showheadshotbbox = spawn();
3006                         self.showheadshotbbox.classname = "headshotbbox";
3007                         self.showheadshotbbox.owner = self;
3008                         self.showheadshotbbox.think = showheadshotbbox_think;
3009                         self.showheadshotbbox.nextthink = time;
3010                         self = self.showheadshotbbox;
3011                         self.think();
3012                         self = self.owner;
3013                 }
3014         }
3015         else
3016         {
3017                 if(self.showheadshotbbox)
3018                         remove(self.showheadshotbbox);
3019         }
3020
3021         playerdemo_write();
3022
3023         /*
3024         if(g_race)
3025                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3026         */
3027 }