qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (g_arena && arena_roundbased)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         if(g_lms)
 405         {
 406                 // Only if the player cannot play at all
 407                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 408                         self.frags = FRAGS_SPECTATOR;
 409                 else
 410                         self.frags = FRAGS_LMS_LOSER;
 411         }
 412         else if((g_race && g_race_qualifying) || g_cts)
 413         {
 414                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 415                         self.frags = FRAGS_LMS_LOSER;
 416                 else
 417                         self.frags = FRAGS_SPECTATOR;
 418         }
 419         else
 420                 self.frags = FRAGS_SPECTATOR;
 421
 422         DropAllRunes(self);
 423         MUTATOR_CALLHOOK(MakePlayerObserver);
 424
 425         minstagib_stop_countdown(self);
 426
 427         Portal_ClearAll(self);
 428
 429         if(self.alivetime)
 430         {
 431                 if(!inWarmupStage)
 432                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 433                 self.alivetime = 0;
 434         }
 435
 436         if(self.vehicle)
 437                 vehicles_exit(VHEF_RELESE);
 438
 439         WaypointSprite_PlayerDead();
 440
 441         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 442                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 443
 444         if(self.killcount != -666) {
 445                 if(g_lms) {
 446                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 447                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 448                         else
 449                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 450                 } else
 451                         bprint ("^4", self.netname, "^4 is spectating now\n");
 452
 453                 if(self.just_joined == FALSE) {
 454                         LogTeamchange(self.playerid, -1, 4);
 455                 } else
 456                         self.just_joined = FALSE;
 457         }
 458
 459         PlayerScore_Clear(self); // clear scores when needed
 460
 461         accuracy_resend(self);
 462
 463         self.spectatortime = time;
 464
 465         self.classname = "observer";
 466         self.iscreature = FALSE;
 467         self.teleportable = TELEPORT_SIMPLE;
 468         self.damagedbycontents = FALSE;
 469         self.health = -666;
 470         self.takedamage = DAMAGE_NO;
 471         self.solid = SOLID_NOT;
 472         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 473         self.flags = FL_CLIENT | FL_NOTARGET;
 474         self.armorvalue = 666;
 475         self.effects = 0;
 476         self.armorvalue = autocvar_g_balance_armor_start;
 477         self.pauserotarmor_finished = 0;
 478         self.pauserothealth_finished = 0;
 479         self.pauseregen_finished = 0;
 480         self.damageforcescale = 0;
 481         self.death_time = 0;
 482         self.respawn_time = 0;
 483         self.alpha = 0;
 484         self.scale = 0;
 485         self.fade_time = 0;
 486         self.pain_frame = 0;
 487         self.pain_finished = 0;
 488         self.strength_finished = 0;
 489         self.invincible_finished = 0;
 490         self.superweapons_finished = 0;
 491         self.pushltime = 0;
 492         self.istypefrag = 0;
 493         self.think = func_null;
 494         self.nextthink = 0;
 495         self.hook_time = 0;
 496         self.runes = 0;
 497         self.deadflag = DEAD_NO;
 498         self.angles = spot.angles;
 499         self.angles_z = 0;
 500         self.fixangle = TRUE;
 501         self.crouch = FALSE;
 502
 503         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 504         self.prevorigin = self.origin;
 505         self.items = 0;
 506         WEPSET_CLEAR_E(self);
 507         self.model = "";
 508         FixPlayermodel();
 509         setmodel(self, "null");
 510         self.drawonlytoclient = self;
 511
 512         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 513         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 514
 515         self.weapon = 0;
 516         self.weaponname = "";
 517         self.switchingweapon = 0;
 518         self.weaponmodel = "";
 519         self.weaponentity = world;
 520         self.exteriorweaponentity = world;
 521         self.killcount = -666;
 522         self.velocity = '0 0 0';
 523         self.avelocity = '0 0 0';
 524         self.punchangle = '0 0 0';
 525         self.punchvector = '0 0 0';
 526         self.oldvelocity = self.velocity;
 527         self.fire_endtime = -1;
 528 }
 529
 530 .float model_randomizer;
 531 void FixPlayermodel()
 532 {
 533         string defaultmodel;
 534         float defaultskin, chmdl, oldskin, n, i;
 535         vector m1, m2;
 536
 537         defaultmodel = "";
 538         defaultskin = 0;
 539         chmdl = FALSE;
 540
 541         if(autocvar_sv_defaultcharacter == 1)
 542         {
 543                 if(teamplay)
 544                 {
 545                         string s;
 546                         s = Team_ColorNameLowerCase(self.team);
 547                         if(s != "neutral")
 548                         {
 549                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 550                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 551                         }
 552                 }
 553
 554                 if(defaultmodel == "")
 555                 {
 556                         defaultmodel = autocvar_sv_defaultplayermodel;
 557                         defaultskin = autocvar_sv_defaultplayerskin;
 558                 }
 559
 560                 n = tokenize_console(defaultmodel);
 561                 if(n > 0)
 562                         defaultmodel = argv(floor(n * self.model_randomizer));
 563
 564                 i = strstrofs(defaultmodel, ":", 0);
 565                 if(i >= 0)
 566                 {
 567                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 568                         defaultmodel = substring(defaultmodel, 0, i);
 569                 }
 570         }
 571
 572         if(defaultmodel != "")
 573         {
 574                 if (defaultmodel != self.model)
 575                 {
 576                         m1 = self.mins;
 577                         m2 = self.maxs;
 578                         setplayermodel (self, defaultmodel);
 579                         setsize (self, m1, m2);
 580                         chmdl = TRUE;
 581                 }
 582
 583                 oldskin = self.skin;
 584                 self.skin = defaultskin;
 585         } else {
 586                 if (self.playermodel != self.model || self.playermodel == "")
 587                 {
 588                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 589                         m1 = self.mins;
 590                         m2 = self.maxs;
 591                         setplayermodel (self, self.playermodel);
 592                         setsize (self, m1, m2);
 593                         chmdl = TRUE;
 594                 }
 595
 596                 oldskin = self.skin;
 597                 self.skin = stof(self.playerskin);
 598         }
 599
 600         if(chmdl || oldskin != self.skin)
 601                 self.species = player_getspecies(); // model or skin has changed
 602
 603         if(!teamplay)
 604                 if(strlen(autocvar_sv_defaultplayercolors))
 605                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 606                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 607 }
 608
 609 void PlayerTouchExplode(entity p1, entity p2)
 610 {
 611         vector org;
 612         org = (p1.origin + p2.origin) * 0.5;
 613         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 614
 615         te_explosion(org);
 616
 617         entity e;
 618         e = spawn();
 619         setorigin(e, org);
 620         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 621         remove(e);
 622 }
 623
 624 /*
 625 =============
 626 PutClientInServer
 627
 628 Called when a client spawns in the server
 629 =============
 630 */
 631
 632 void PutClientInServer (void)
 633 {
 634         if(clienttype(self) == CLIENTTYPE_BOT)
 635                 self.classname = "player";
 636         else if(clienttype(self) == CLIENTTYPE_REAL)
 637         {
 638                 msg_entity = self;
 639                 WriteByte(MSG_ONE, SVC_SETVIEW);
 640                 WriteEntity(MSG_ONE, self);
 641         }
 642
 643         // reset player keys
 644         self.itemkeys = 0;
 645
 646         // player is dead and becomes observer
 647         // FIXME fix LMS scoring for new system
 648         if(g_lms)
 649         {
 650                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 651                         self.classname = "observer";
 652         }
 653
 654         MUTATOR_CALLHOOK(PutClientInServer);
 655
 656         if(gameover)
 657                 self.classname = "observer";
 658
 659         if(self.classname == "player") {
 660                 entity spot, oldself;
 661                 float j;
 662
 663                 accuracy_resend(self);
 664
 665                 if(self.team < 0)
 666                         JoinBestTeam(self, FALSE, TRUE);
 667
 668                 race_PreSpawn();
 669
 670                 spot = SelectSpawnPoint (FALSE);
 671                 if(!spot)
 672                 {
 673                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 674                         return; // spawn failed
 675                 }
 676
 677                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 678
 679                 self.classname = "player";
 680                 self.wasplayer = TRUE;
 681                 self.iscreature = TRUE;
 682                 self.teleportable = TELEPORT_NORMAL;
 683                 self.damagedbycontents = TRUE;
 684                 self.movetype = MOVETYPE_WALK;
 685                 self.solid = SOLID_SLIDEBOX;
 686                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 687                 if(autocvar_g_playerclip_collisions)
 688                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 689                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 690                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 691                 self.frags = FRAGS_PLAYER;
 692                 if(INDEPENDENT_PLAYERS)
 693                         MAKE_INDEPENDENT_PLAYER(self);
 694                 self.flags = FL_CLIENT;
 695                 if(autocvar__notarget)
 696                         self.flags |= FL_NOTARGET;
 697                 self.takedamage = DAMAGE_AIM;
 698                 if(g_minstagib)
 699                         self.effects = EF_FULLBRIGHT;
 700                 else
 701                         self.effects = 0;
 702                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 703                 self.air_finished = time + 12;
 704                 self.dmg = 2;
 705                 if(autocvar_g_balance_nex_charge)
 706                 {
 707                         if(autocvar_g_balance_nex_secondary_chargepool)
 708                                 self.nex_chargepool_ammo = 1;
 709                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 710                 }
 711
 712                 if(inWarmupStage)
 713                 {
 714                         self.ammo_shells = warmup_start_ammo_shells;
 715                         self.ammo_nails = warmup_start_ammo_nails;
 716                         self.ammo_rockets = warmup_start_ammo_rockets;
 717                         self.ammo_cells = warmup_start_ammo_cells;
 718                         self.ammo_fuel = warmup_start_ammo_fuel;
 719                         self.health = warmup_start_health;
 720                         self.armorvalue = warmup_start_armorvalue;
 721                         WEPSET_COPY_EA(self, warmup_start_weapons);
 722                 }
 723                 else
 724                 {
 725                         self.ammo_shells = start_ammo_shells;
 726                         self.ammo_nails = start_ammo_nails;
 727                         self.ammo_rockets = start_ammo_rockets;
 728                         self.ammo_cells = start_ammo_cells;
 729                         self.ammo_fuel = start_ammo_fuel;
 730                         self.health = start_health;
 731                         self.armorvalue = start_armorvalue;
 732                         WEPSET_COPY_EA(self, start_weapons);
 733                 }
 734
 735                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 736                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 737                 else
 738                         self.superweapons_finished = 0;
 739
 740                 if(g_weaponarena_random)
 741                 {
 742                         if(g_weaponarena_random_with_laser)
 743                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 744                         W_RandomWeapons(self, g_weaponarena_random);
 745                         if(g_weaponarena_random_with_laser)
 746                                 WEPSET_OR_EW(self, WEP_LASER);
 747                 }
 748
 749                 self.items = start_items;
 750
 751                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 752                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 753                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 754                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 755                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 756                 //extend the pause of rotting if client was reset at the beginning of the countdown
 757                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 758                         self.spawnshieldtime += game_starttime - time;
 759                         self.pauserotarmor_finished += game_starttime - time;
 760                         self.pauserothealth_finished += game_starttime - time;
 761                         self.pauseregen_finished += game_starttime - time;
 762                 }
 763                 self.damageforcescale = 2;
 764                 self.death_time = 0;
 765                 self.respawn_time = 0;
 766                 self.scale = 0;
 767                 self.fade_time = 0;
 768                 self.pain_frame = 0;
 769                 self.pain_finished = 0;
 770                 self.strength_finished = 0;
 771                 self.invincible_finished = 0;
 772                 self.pushltime = 0;
 773                 // players have no think function
 774                 self.think = func_null;
 775                 self.nextthink = 0;
 776                 self.hook_time = 0;
 777                 self.dmg_team = 0;
 778                 self.ballistics_density = autocvar_g_ballistics_density_player;
 779
 780                 self.metertime = 0;
 781
 782                 self.runes = 0;
 783
 784                 self.deadflag = DEAD_NO;
 785
 786                 self.angles = spot.angles;
 787
 788                 self.angles_z = 0; // never spawn tilted even if the spot says to
 789                 self.fixangle = TRUE; // turn this way immediately
 790                 self.velocity = '0 0 0';
 791                 self.avelocity = '0 0 0';
 792                 self.punchangle = '0 0 0';
 793                 self.punchvector = '0 0 0';
 794                 self.oldvelocity = self.velocity;
 795                 self.fire_endtime = -1;
 796
 797                 msg_entity = self;
 798                 WRITESPECTATABLE_MSG_ONE({
 799                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 800                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 801                 });
 802
 803                 self.model = "";
 804                 FixPlayermodel();
 805                 self.drawonlytoclient = world;
 806
 807                 self.crouch = FALSE;
 808                 self.view_ofs = PL_VIEW_OFS;
 809                 setsize (self, PL_MIN, PL_MAX);
 810                 self.spawnorigin = spot.origin;
 811                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 812                 // don't reset back to last position, even if new position is stuck in solid
 813                 self.oldorigin = self.origin;
 814                 self.prevorigin = self.origin;
 815                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 816                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 817         self.hud = HUD_NORMAL;
 818
 819                 self.event_damage = PlayerDamage;
 820
 821                 self.bot_attack = TRUE;
 822
 823                 self.statdraintime = time + 5;
 824                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 825
 826                 if(self.killcount == -666) {
 827                         PlayerScore_Clear(self);
 828                         self.killcount = 0;
 829                 }
 830
 831                 CL_SpawnWeaponentity();
 832                 self.alpha = default_player_alpha;
 833                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 834                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 835
 836                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 837                 self.lms_traveled_distance = 0;
 838                 self.speedrunning = FALSE;
 839
 840                 race_PostSpawn(spot);
 841
 842                 //stuffcmd(self, "chase_active 0");
 843                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 844
 845                 if(g_assault) {
 846                         if(self.team == assault_attacker_team)
 847                                 centerprint(self, "You are attacking!");
 848                         else
 849                                 centerprint(self, "You are defending!");
 850                 }
 851
 852                 target_voicescript_clear(self);
 853
 854                 // reset fields the weapons may use
 855                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 856                 {
 857                         weapon_action(j, WR_RESETPLAYER);
 858
 859                         // all weapons must be fully loaded when we spawn
 860                         entity e;
 861                         e = get_weaponinfo(j);
 862                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 863                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 864                 }
 865
 866                 oldself = self;
 867                 self = spot;
 868                         activator = oldself;
 869                                 string s;
 870                                 s = self.target;
 871                                 self.target = string_null;
 872                                 SUB_UseTargets();
 873                                 self.target = s;
 874                         activator = world;
 875                 self = oldself;
 876
 877                 spawn_spot = spot;
 878                 MUTATOR_CALLHOOK(PlayerSpawn);
 879
 880                 if(autocvar_spawn_debug)
 881                 {
 882                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 883                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 884                 }
 885
 886                 self.switchweapon = w_getbestweapon(self);
 887                 self.cnt = -1; // W_LastWeapon will not complain
 888                 self.weapon = 0;
 889                 self.weaponname = "";
 890                 self.switchingweapon = 0;
 891
 892                 if(!inWarmupStage)
 893                         if(!self.alivetime)
 894                                 self.alivetime = time;
 895
 896                 antilag_clear(self);
 897
 898                 if (autocvar_g_spawnsound)
 899                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 900         } else if(self.classname == "observer") {
 901                 PutObserverInServer ();
 902         }
 903 }
 904
 905 .float ebouncefactor, ebouncestop; // electro's values
 906 // TODO do we need all these fields, or should we stop autodetecting runtime
 907 // changes and just have a console command to update this?
 908 float ClientInit_SendEntity(entity to, float sf)
 909 {
 910         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 911         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 912         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 913         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 914         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 915         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 916         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 917         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 918         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 919         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 920         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 921         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 922         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 923         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 924         if(sv_foginterval && world.fog != "")
 925                 WriteString(MSG_ENTITY, world.fog);
 926         else
 927                 WriteString(MSG_ENTITY, "");
 928         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 929         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 930         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 931         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 932         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 933         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 934         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 935         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 936         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 937         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 938         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 939         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 940         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 941         return TRUE;
 942 }
 943
 944 void ClientInit_CheckUpdate()
 945 {
 946         self.nextthink = time;
 947         if(self.count != autocvar_g_balance_armor_blockpercent)
 948         {
 949                 self.count = autocvar_g_balance_armor_blockpercent;
 950                 self.SendFlags |= 1;
 951         }
 952         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 953         {
 954                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 955                 self.SendFlags |= 1;
 956         }
 957         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 958         {
 959                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 960                 self.SendFlags |= 1;
 961         }
 962         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 963         {
 964                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 965                 self.SendFlags |= 1;
 966         }
 967         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 968         {
 969                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 970                 self.SendFlags |= 1;
 971         }
 972         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 973         {
 974                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 975                 self.SendFlags |= 1;
 976         }
 977 }
 978
 979 void ClientInit_Spawn()
 980 {
 981         entity o;
 982         entity e;
 983         e = spawn();
 984         e.classname = "clientinit";
 985         e.think = ClientInit_CheckUpdate;
 986         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 987
 988         o = self;
 989         self = e;
 990         ClientInit_CheckUpdate();
 991         self = o;
 992 }
 993
 994 /*
 995 =============
 996 SetNewParms
 997 =============
 998 */
 999 void SetNewParms (void)
1000 {
1001         // initialize parms for a new player
1002         parm1 = -(86400 * 366);
1003 }
1004
1005 /*
1006 =============
1007 SetChangeParms
1008 =============
1009 */
1010 void SetChangeParms (void)
1011 {
1012         // save parms for level change
1013         parm1 = self.parm_idlesince - time;
1014 }
1015
1016 /*
1017 =============
1018 DecodeLevelParms
1019 =============
1020 */
1021 void DecodeLevelParms (void)
1022 {
1023         // load parms
1024         self.parm_idlesince = parm1;
1025         if(self.parm_idlesince == -(86400 * 366))
1026                 self.parm_idlesince = time;
1027
1028         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1029         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1030 }
1031
1032 /*
1033 =============
1034 ClientKill
1035
1036 Called when a client types 'kill' in the console
1037 =============
1038 */
1039
1040 .float clientkill_nexttime;
1041 void ClientKill_Now_TeamChange()
1042 {
1043         if(self.killindicator_teamchange == -1)
1044         {
1045                 JoinBestTeam( self, FALSE, TRUE );
1046         }
1047         else if(self.killindicator_teamchange == -2)
1048         {
1049                 if(blockSpectators)
1050                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1051                 PutObserverInServer();
1052         }
1053         else
1054                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1055         self.killindicator_teamchange = 0;
1056 }
1057
1058 void ClientKill_Now()
1059 {
1060         if(self.vehicle)
1061         {
1062             vehicles_exit(VHEF_RELESE);
1063             if(!self.killindicator_teamchange)
1064             {
1065             self.vehicle_health = -1;
1066             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1067             }
1068         }
1069
1070         if(self.killindicator && !wasfreed(self.killindicator))
1071                 remove(self.killindicator);
1072
1073         self.killindicator = world;
1074
1075         if(self.killindicator_teamchange)
1076                 ClientKill_Now_TeamChange();
1077
1078         // in any case:
1079         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1080
1081         // now I am sure the player IS dead
1082 }
1083 void KillIndicator_Think()
1084 {
1085         if (gameover)
1086         {
1087                 self.owner.killindicator = world;
1088                 remove(self);
1089                 return;
1090         }
1091
1092         if (self.owner.alpha < 0 && !self.owner.vehicle)
1093         {
1094                 self.owner.killindicator = world;
1095                 remove(self);
1096                 return;
1097         }
1098
1099         if(self.cnt <= 0)
1100         {
1101                 self = self.owner;
1102                 ClientKill_Now(); // no oldself needed
1103                 return;
1104         }
1105     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1106     {
1107         self.nextthink = time + 1;
1108         self.cnt -= 1;
1109     }
1110         else
1111         {
1112                 if(self.cnt <= 10)
1113                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1114                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1115                 {
1116                         if(self.cnt <= 10)
1117                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1118                 }
1119                 self.nextthink = time + 1;
1120                 self.cnt -= 1;
1121         }
1122 }
1123
1124 float clientkilltime;
1125 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1126 {
1127         float killtime;
1128         float starttime;
1129         entity e;
1130
1131         if (gameover)
1132                 return;
1133
1134         killtime = autocvar_g_balance_kill_delay;
1135
1136         if(g_race_qualifying || g_cts)
1137                 killtime = 0;
1138
1139     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1140     {
1141                 remove(self.killindicator);
1142                 self.killindicator = world;
1143
1144         ClientKill_Now(); // allow instant kill in this case
1145         return;
1146     }
1147
1148         self.killindicator_teamchange = targetteam;
1149
1150     if(!self.killindicator)
1151         {
1152                 if(self.deadflag == DEAD_NO)
1153                 {
1154                         killtime = max(killtime, self.clientkill_nexttime - time);
1155                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1156                 }
1157
1158                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1159                 {
1160                         ClientKill_Now();
1161                 }
1162                 else
1163                 {
1164                         starttime = max(time, clientkilltime);
1165
1166                         self.killindicator = spawn();
1167                         self.killindicator.owner = self;
1168                         self.killindicator.scale = 0.5;
1169                         setattachment(self.killindicator, self, "");
1170                         setorigin(self.killindicator, '0 0 52');
1171                         self.killindicator.think = KillIndicator_Think;
1172                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1173                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1174                         self.killindicator.cnt = ceil(killtime);
1175                         self.killindicator.count = bound(0, ceil(killtime), 10);
1176                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1177
1178                         for(e = world; (e = find(e, classname, "body")) != world; )
1179                         {
1180                                 if(e.enemy != self)
1181                                         continue;
1182                                 e.killindicator = spawn();
1183                                 e.killindicator.owner = e;
1184                                 e.killindicator.scale = 0.5;
1185                                 setattachment(e.killindicator, e, "");
1186                                 setorigin(e.killindicator, '0 0 52');
1187                                 e.killindicator.think = KillIndicator_Think;
1188                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1189                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1190                                 e.killindicator.cnt = ceil(killtime);
1191                         }
1192                         self.lip = 0;
1193                 }
1194         }
1195         if(self.killindicator)
1196         {
1197                 if(targetteam == 0) // just die
1198                 {
1199                         self.killindicator.colormod = '0 0 0';
1200                         if(clienttype(self) == CLIENTTYPE_REAL)
1201                         if(self.killindicator.cnt > 0)
1202                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1203                 }
1204                 else if(targetteam == -1) // auto
1205                 {
1206                         self.killindicator.colormod = '0 1 0';
1207                         if(clienttype(self) == CLIENTTYPE_REAL)
1208                         if(self.killindicator.cnt > 0)
1209                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1210                 }
1211                 else if(targetteam == -2) // spectate
1212                 {
1213                         self.killindicator.colormod = '0.5 0.5 0.5';
1214                         if(clienttype(self) == CLIENTTYPE_REAL)
1215                         if(self.killindicator.cnt > 0)
1216                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1217                 }
1218                 else
1219                 {
1220                         self.killindicator.colormod = TeamColor(targetteam);
1221                         if(clienttype(self) == CLIENTTYPE_REAL)
1222                         if(self.killindicator.cnt > 0)
1223                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1224                 }
1225         }
1226
1227 }
1228
1229 void ClientKill (void)
1230 {
1231         if(gameover) return;
1232         if(g_ca && player_count == 1) return;
1233         if(self.player_blocked) return;
1234         if(self.freezetag_frozen) return;
1235
1236         ClientKill_TeamChange(0);
1237 }
1238
1239 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1240 {
1241     e.killindicator = spawn();
1242     e.killindicator.owner = e;
1243     e.killindicator.think = KillIndicator_Think;
1244     e.killindicator.nextthink = time + (e.lip) * 0.05;
1245     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1246     e.killindicator.health = 1; // this is used to indicate that it should be silent
1247     e.lip = 0;
1248 }
1249
1250 void FixClientCvars(entity e)
1251 {
1252         // send prediction settings to the client
1253         stuffcmd(e, "\nin_bindmap 0 0\n");
1254         if(g_race || g_cts)
1255                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1256         if(autocvar_g_antilag == 3) // client side hitscan
1257                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1258         if(sv_gentle)
1259                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1260         /*
1261          * we no longer need to stuff this. Remove this comment block if you feel
1262          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1263         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1264         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1265         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1266         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1267         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1268         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1269         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1270         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1271         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1272         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1273         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1274         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1275         stuffcmd(e, "cl_movement_edgefriction 1\n");
1276          */
1277 }
1278
1279 float PlayerInIDList(entity p, string idlist)
1280 {
1281         float n, i;
1282         string s;
1283
1284         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1285         if not(p.crypto_idfp)
1286                 return 0;
1287
1288         // this function allows abbreviated player IDs too!
1289         n = tokenize_console(idlist);
1290         for(i = 0; i < n; ++i)
1291         {
1292                 s = argv(i);
1293                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1294                         return 1;
1295         }
1296
1297         return 0;
1298 }
1299
1300 /*
1301 =============
1302 ClientConnect
1303
1304 Called when a client connects to the server
1305 =============
1306 */
1307 string ColoredTeamName(float t);
1308 void DecodeLevelParms (void);
1309 //void dom_player_join_team(entity pl);
1310 void set_dom_state(entity e);
1311 void ClientConnect (void)
1312 {
1313         float t;
1314
1315         if(self.flags & FL_CLIENT)
1316         {
1317                 print("Warning: ClientConnect, but already connected!\n");
1318                 return;
1319         }
1320
1321         if(Ban_MaybeEnforceBanOnce(self))
1322                 return;
1323
1324         DecodeLevelParms();
1325
1326 #ifdef WATERMARK
1327         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK, "\n"));
1328 #endif
1329
1330         self.classname = "player_joining";
1331
1332         self.flags = FL_CLIENT;
1333         self.version_nagtime = time + 10 + random() * 10;
1334
1335         if(player_count<0)
1336         {
1337                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1338                 player_count = 0;
1339         }
1340
1341         PlayerScore_Attach(self);
1342         ClientData_Attach();
1343         accuracy_init(self);
1344
1345         bot_clientconnect();
1346
1347         playerdemo_init();
1348
1349         anticheat_init();
1350
1351         race_PreSpawnObserver();
1352
1353         // identify the right forced team
1354         if(autocvar_g_campaign)
1355         {
1356                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1357                 {
1358                         switch(autocvar_g_campaign_forceteam)
1359                         {
1360                                 case 1: self.team_forced = COLOR_TEAM1; break;
1361                                 case 2: self.team_forced = COLOR_TEAM2; break;
1362                                 case 3: self.team_forced = COLOR_TEAM3; break;
1363                                 case 4: self.team_forced = COLOR_TEAM4; break;
1364                                 default: self.team_forced = 0;
1365                         }
1366                 }
1367         }
1368         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1369                 self.team_forced = COLOR_TEAM1;
1370         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1371                 self.team_forced = COLOR_TEAM2;
1372         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1373                 self.team_forced = COLOR_TEAM3;
1374         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1375                 self.team_forced = COLOR_TEAM4;
1376         else if(autocvar_g_forced_team_otherwise == "red")
1377                 self.team_forced = COLOR_TEAM1;
1378         else if(autocvar_g_forced_team_otherwise == "blue")
1379                 self.team_forced = COLOR_TEAM2;
1380         else if(autocvar_g_forced_team_otherwise == "yellow")
1381                 self.team_forced = COLOR_TEAM3;
1382         else if(autocvar_g_forced_team_otherwise == "pink")
1383                 self.team_forced = COLOR_TEAM4;
1384         else if(autocvar_g_forced_team_otherwise == "spectate")
1385                 self.team_forced = -1;
1386         else if(autocvar_g_forced_team_otherwise == "spectator")
1387                 self.team_forced = -1;
1388         else
1389                 self.team_forced = 0;
1390
1391         if(!teamplay)
1392                 if(self.team_forced > 0)
1393                         self.team_forced = 0;
1394
1395         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1396
1397         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1398                 self.classname = "observer";
1399         } else {
1400                 if(teamplay)
1401                 {
1402                         if(autocvar_g_balance_teams)
1403                         {
1404                                 self.classname = "player";
1405                                 campaign_bots_may_start = 1;
1406                         }
1407                         else
1408                         {
1409                                 self.classname = "observer"; // do it anyway
1410                         }
1411                 }
1412                 else
1413                 {
1414                         self.classname = "player";
1415                         campaign_bots_may_start = 1;
1416                 }
1417         }
1418
1419         self.playerid = (playerid_last = playerid_last + 1);
1420
1421         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1422
1423     if(clienttype(self) == CLIENTTYPE_BOT)
1424         PlayerStats_AddPlayer(self);
1425
1426         if(autocvar_sv_eventlog)
1427                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1428
1429         LogTeamchange(self.playerid, self.team, 1);
1430
1431         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1432
1433         self.netname_previous = strzone(self.netname);
1434
1435         bprint("^4", self.netname, "^4 connected");
1436
1437         if(self.classname != "observer" && (g_domination || g_ctf))
1438                 bprint(" and joined the ", ColoredTeamName(self.team));
1439
1440         bprint("\n");
1441
1442         stuffcmd(self, strcat(clientstuff, "\n"));
1443         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1444
1445         FixClientCvars(self);
1446
1447         // spawnfunc_waypoint sprites
1448         WaypointSprite_InitClient(self);
1449
1450         // Wazat's grappling hook
1451         SetGrappleHookBindings();
1452
1453         // get version info from player
1454         stuffcmd(self, "cmd clientversion $gameversion\n");
1455
1456         // get other cvars from player
1457         GetCvars(0);
1458
1459         // notify about available teams
1460         if(teamplay)
1461         {
1462                 CheckAllowedTeams(self);
1463                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1464                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1465         }
1466         else
1467                 stuffcmd(self, "set _teams_available 0\n");
1468
1469         attach_entcs();
1470
1471         bot_relinkplayerlist();
1472
1473         self.spectatortime = time;
1474         if(blockSpectators)
1475         {
1476                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1477         }
1478
1479         self.jointime = time;
1480         self.allowed_timeouts = autocvar_sv_timeout_number;
1481
1482         if(clienttype(self) == CLIENTTYPE_REAL)
1483         {
1484                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1485                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1486         }
1487
1488         if(g_lms)
1489         {
1490                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1491                 {
1492                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1493                         self.frags = FRAGS_SPECTATOR;
1494                 }
1495         }
1496
1497         if(!sv_foginterval && world.fog != "")
1498                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1499
1500         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1501         {
1502                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1503                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1504         }
1505         else
1506                 self.hitplotfh = -1;
1507
1508         if(g_race || g_cts) {
1509                 string rr;
1510                 if(g_cts)
1511                         rr = CTS_RECORD;
1512                 else
1513                         rr = RACE_RECORD;
1514
1515                 msg_entity = self;
1516                 race_send_recordtime(MSG_ONE);
1517                 race_send_speedaward(MSG_ONE);
1518
1519                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1520                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1521                 race_send_speedaward_alltimebest(MSG_ONE);
1522
1523                 float i;
1524                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1525                         race_SendRankings(i, 0, 0, MSG_ONE);
1526                 }
1527         }
1528         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1529                 send_CSQC_teamnagger();
1530
1531         CheatInitClient();
1532
1533         if(!autocvar_g_campaign)
1534                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1535
1536         CSQCMODEL_AUTOINIT();
1537
1538         self.model_randomizer = random();
1539
1540         if(clienttype(self) == CLIENTTYPE_REAL)
1541                 sv_notice_join();
1542
1543         MUTATOR_CALLHOOK(ClientConnect);
1544 }
1545 /*
1546 =============
1547 ClientDisconnect
1548
1549 Called when a client disconnects from the server
1550 =============
1551 */
1552 .entity chatbubbleentity;
1553 void ReadyCount();
1554 void ClientDisconnect (void)
1555 {
1556         if(self.vehicle)
1557             vehicles_exit(VHEF_RELESE);
1558
1559         if not(self.flags & FL_CLIENT)
1560         {
1561                 print("Warning: ClientDisconnect without ClientConnect\n");
1562                 return;
1563         }
1564
1565         PlayerStats_AddGlobalInfo(self);
1566
1567         CheatShutdownClient();
1568
1569         if(self.hitplotfh >= 0)
1570         {
1571                 fclose(self.hitplotfh);
1572                 self.hitplotfh = -1;
1573         }
1574
1575         anticheat_report();
1576         anticheat_shutdown();
1577
1578         playerdemo_shutdown();
1579
1580         bot_clientdisconnect();
1581
1582         if(self.entcs)
1583                 detach_entcs();
1584
1585         if(autocvar_sv_eventlog)
1586                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1587         bprint ("^4",self.netname);
1588         bprint ("^4 disconnected\n");
1589
1590         DropAllRunes(self);
1591         MUTATOR_CALLHOOK(ClientDisconnect);
1592
1593         Portal_ClearAll(self);
1594
1595         RemoveGrapplingHook(self);
1596
1597         // Here, everything has been done that requires this player to be a client.
1598
1599         self.flags &~= FL_CLIENT;
1600
1601         if (self.chatbubbleentity)
1602                 remove (self.chatbubbleentity);
1603
1604         if (self.killindicator)
1605                 remove (self.killindicator);
1606
1607         WaypointSprite_PlayerGone();
1608
1609         bot_relinkplayerlist();
1610
1611         accuracy_free(self);
1612         ClientData_Detach();
1613         PlayerScore_Detach(self);
1614
1615         if(self.netname_previous)
1616                 strunzone(self.netname_previous);
1617         if(self.clientstatus)
1618                 strunzone(self.clientstatus);
1619         if(self.weaponorder_byimpulse)
1620                 strunzone(self.weaponorder_byimpulse);
1621
1622         ClearPlayerSounds();
1623
1624         if(self.personal)
1625                 remove(self.personal);
1626
1627         self.playerid = 0;
1628         ReadyCount();
1629
1630         // free cvars
1631         GetCvars(-1);
1632 }
1633
1634 .float BUTTON_CHAT;
1635 void ChatBubbleThink()
1636 {
1637         self.nextthink = time;
1638         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1639         {
1640                 if(self.owner) // but why can that ever be world?
1641                         self.owner.chatbubbleentity = world;
1642                 remove(self);
1643                 return;
1644         }
1645         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1646 #ifdef TETRIS
1647                 || self.owner.tetris_on
1648 #endif
1649         )
1650                 self.model = self.mdl;
1651         else
1652                 self.model = "";
1653 }
1654
1655 void UpdateChatBubble()
1656 {
1657         if (self.alpha < 0)
1658                 return;
1659         // spawn a chatbubble entity if needed
1660         if (!self.chatbubbleentity)
1661         {
1662                 self.chatbubbleentity = spawn();
1663                 self.chatbubbleentity.owner = self;
1664                 self.chatbubbleentity.exteriormodeltoclient = self;
1665                 self.chatbubbleentity.think = ChatBubbleThink;
1666                 self.chatbubbleentity.nextthink = time;
1667                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1668                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1669                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1670                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1671                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1672                 self.chatbubbleentity.model = "";
1673                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1674         }
1675 }
1676
1677
1678 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1679 // added to the model skins
1680 /*void UpdateColorModHack()
1681 {
1682         float c;
1683         c = self.clientcolors & 15;
1684         // LordHavoc: only bothering to support white, green, red, yellow, blue
1685              if (!teamplay) self.colormod = '0 0 0';
1686         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1687         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1688         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1689         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1690         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1691         else self.colormod = '1 1 1';
1692 }*/
1693
1694 void respawn(void)
1695 {
1696         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1697         {
1698                 self.solid = SOLID_NOT;
1699                 self.takedamage = DAMAGE_NO;
1700                 self.movetype = MOVETYPE_FLY;
1701                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1702                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1703                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1704                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1705                 if(autocvar_g_respawn_ghosts_maxtime)
1706                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1707         }
1708
1709         CopyBody(1);
1710
1711         self.effects |= EF_NODRAW; // prevent another CopyBody
1712         PutClientInServer();
1713 }
1714
1715 void play_countdown(float finished, string samp)
1716 {
1717         if(clienttype(self) == CLIENTTYPE_REAL)
1718                 if(floor(finished - time - frametime) != floor(finished - time))
1719                         if(finished - time < 6)
1720                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1721 }
1722
1723 void player_powerups (void)
1724 {
1725         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1726         olditems = self.items;
1727
1728         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1729                 self.modelflags |= MF_ROCKET;
1730         else
1731                 self.modelflags &~= MF_ROCKET;
1732
1733         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1734
1735         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1736                 return;
1737
1738         Fire_ApplyDamage(self);
1739         Fire_ApplyEffect(self);
1740
1741         if (g_minstagib)
1742         {
1743                 self.effects |= EF_FULLBRIGHT;
1744
1745                 if (self.items & IT_STRENGTH)
1746                 {
1747                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1748                         if (time > self.strength_finished)
1749                         {
1750                                 self.alpha = default_player_alpha;
1751                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1752                                 self.items &~= IT_STRENGTH;
1753                                 sprint(self, "^3Invisibility has worn off\n");
1754                         }
1755                 }
1756                 else
1757                 {
1758                         if (time < self.strength_finished)
1759                         {
1760                                 self.alpha = g_minstagib_invis_alpha;
1761                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1762                                 self.items |= IT_STRENGTH;
1763                                 sprint(self, "^3You are invisible\n");
1764                         }
1765                 }
1766
1767                 if (self.items & IT_INVINCIBLE)
1768                 {
1769                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1770                         if (time > self.invincible_finished)
1771                         {
1772                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1773                                 sprint(self, "^3Speed has worn off\n");
1774                         }
1775                 }
1776                 else
1777                 {
1778                         if (time < self.invincible_finished)
1779                         {
1780                                 self.items = self.items | IT_INVINCIBLE;
1781                                 sprint(self, "^3You are on speed\n");
1782                         }
1783                 }
1784         }
1785         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1786         {
1787                 if (self.items & IT_STRENGTH)
1788                 {
1789                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1790                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1791                         if (time > self.strength_finished)
1792                         {
1793                                 self.items = self.items - (self.items & IT_STRENGTH);
1794                                 sprint(self, "^3Strength has worn off\n");
1795                         }
1796                 }
1797                 else
1798                 {
1799                         if (time < self.strength_finished)
1800                         {
1801                                 self.items = self.items | IT_STRENGTH;
1802                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1803                         }
1804                 }
1805                 if (self.items & IT_INVINCIBLE)
1806                 {
1807                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1808                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1809                         if (time > self.invincible_finished)
1810                         {
1811                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1812                                 sprint(self, "^3Shield has worn off\n");
1813                         }
1814                 }
1815                 else
1816                 {
1817                         if (time < self.invincible_finished)
1818                         {
1819                                 self.items = self.items | IT_INVINCIBLE;
1820                                 sprint(self, "^3Shield surrounds you\n");
1821                         }
1822                 }
1823                 if (self.items & IT_SUPERWEAPON)
1824                 {
1825                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1826                         {
1827                                 self.superweapons_finished = 0;
1828                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1829                                 sprint(self, "^3Superweapons have been lost\n");
1830                         }
1831                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1832                         {
1833                                 // don't let them run out
1834                         }
1835                         else
1836                         {
1837                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1838                                 if (time > self.superweapons_finished)
1839                                 {
1840                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1841                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1842                                         sprint(self, "^3Superweapons have broken down\n");
1843                                 }
1844                         }
1845                 }
1846                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1847                 {
1848                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1849                         {
1850                                 self.items = self.items | IT_SUPERWEAPON;
1851                                 sprint(self, "^3You now have a superweapon\n");
1852                         }
1853                         else
1854                         {
1855                                 self.superweapons_finished = 0;
1856                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1857                         }
1858                 }
1859                 else
1860                 {
1861                         self.superweapons_finished = 0;
1862                 }
1863         }
1864
1865         if(autocvar_g_nodepthtestplayers)
1866                 self.effects = self.effects | EF_NODEPTHTEST;
1867
1868         if(autocvar_g_fullbrightplayers)
1869                 self.effects = self.effects | EF_FULLBRIGHT;
1870
1871         // midair gamemode: damage only while in the air
1872         // if in midair mode, being on ground grants temporary invulnerability
1873         // (this is so that multishot weapon don't clear the ground flag on the
1874         // first damage in the frame, leaving the player vulnerable to the
1875         // remaining hits in the same frame)
1876         if (self.flags & FL_ONGROUND)
1877         if (g_midair)
1878                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1879
1880         if (time >= game_starttime)
1881         if (time < self.spawnshieldtime)
1882                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1883
1884         MUTATOR_CALLHOOK(PlayerPowerups);
1885 }
1886
1887 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1888 {
1889         if(current > stable)
1890                 return current;
1891         else if(current > stable - 0.25) // when close enough, "snap"
1892                 return stable;
1893         else
1894                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1895 }
1896
1897 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1898 {
1899         if(current < stable)
1900                 return current;
1901         else if(current < stable + 0.25) // when close enough, "snap"
1902                 return stable;
1903         else
1904                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1905 }
1906
1907 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1908 {
1909         if(current > rotstable)
1910         {
1911                 if(rotframetime > 0)
1912                 {
1913                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1914                         current = max(rotstable, current - rotlinear * rotframetime);
1915                 }
1916         }
1917         else if(current < regenstable)
1918         {
1919                 if(regenframetime > 0)
1920                 {
1921                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1922                         current = min(regenstable, current + regenlinear * regenframetime);
1923                 }
1924         }
1925
1926         if(current > limit)
1927                 current = limit;
1928
1929         return current;
1930 }
1931
1932 void player_regen (void)
1933 {
1934         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1935         maxh = autocvar_g_balance_health_rotstable;
1936         maxa = autocvar_g_balance_armor_rotstable;
1937         maxf = autocvar_g_balance_fuel_rotstable;
1938         minh = autocvar_g_balance_health_regenstable;
1939         mina = autocvar_g_balance_armor_regenstable;
1940         minf = autocvar_g_balance_fuel_regenstable;
1941         limith = autocvar_g_balance_health_limit;
1942         limita = autocvar_g_balance_armor_limit;
1943         limitf = autocvar_g_balance_fuel_limit;
1944
1945         max_mod = regen_mod = rot_mod = limit_mod = 1;
1946
1947         if (self.runes & RUNE_REGEN)
1948         {
1949                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1950                 {
1951                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1952                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1953                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1954                 }
1955                 else
1956                 {
1957                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
1958                         max_mod = autocvar_g_balance_rune_regen_hpmod;
1959                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
1960                 }
1961         }
1962         else if (self.runes & CURSE_VENOM)
1963         {
1964                 max_mod = autocvar_g_balance_curse_venom_hpmod;
1965                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1966                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
1967                 else
1968                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
1969                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
1970                 //if (!self.runes & RUNE_REGEN)
1971                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
1972         }
1973         maxh = maxh * max_mod;
1974         //maxa = maxa * max_mod;
1975         //maxf = maxf * max_mod;
1976         minh = minh * max_mod;
1977         //mina = mina * max_mod;
1978         //minf = minf * max_mod;
1979         limith = limith * limit_mod;
1980         limita = limita * limit_mod;
1981         //limitf = limitf * limit_mod;
1982
1983         if(g_ca)
1984                 rot_mod = 0;
1985
1986         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1987         {
1988                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1989                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1990
1991                 // if player rotted to death...  die!
1992                 if(self.health < 1)
1993                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1994         }
1995
1996         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1997                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1998 }
1999
2000 float zoomstate_set;
2001 void SetZoomState(float z)
2002 {
2003         if(z != self.zoomstate)
2004         {
2005                 self.zoomstate = z;
2006                 ClientData_Touch(self);
2007         }
2008         zoomstate_set = 1;
2009 }
2010
2011 void GetPressedKeys(void) {
2012         MUTATOR_CALLHOOK(GetPressedKeys);
2013         if (self.movement_x > 0) // get if movement keys are pressed
2014         {       // forward key pressed
2015                 self.pressedkeys |= KEY_FORWARD;
2016                 self.pressedkeys &~= KEY_BACKWARD;
2017         }
2018         else if (self.movement_x < 0)
2019         {       // backward key pressed
2020                 self.pressedkeys |= KEY_BACKWARD;
2021                 self.pressedkeys &~= KEY_FORWARD;
2022         }
2023         else
2024         {       // no x input
2025                 self.pressedkeys &~= KEY_FORWARD;
2026                 self.pressedkeys &~= KEY_BACKWARD;
2027         }
2028
2029         if (self.movement_y > 0)
2030         {       // right key pressed
2031                 self.pressedkeys |= KEY_RIGHT;
2032                 self.pressedkeys &~= KEY_LEFT;
2033         }
2034         else if (self.movement_y < 0)
2035         {       // left key pressed
2036                 self.pressedkeys |= KEY_LEFT;
2037                 self.pressedkeys &~= KEY_RIGHT;
2038         }
2039         else
2040         {       // no y input
2041                 self.pressedkeys &~= KEY_RIGHT;
2042                 self.pressedkeys &~= KEY_LEFT;
2043         }
2044
2045         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2046                 self.pressedkeys |= KEY_JUMP;
2047         else
2048                 self.pressedkeys &~= KEY_JUMP;
2049         if (self.BUTTON_CROUCH)
2050                 self.pressedkeys |= KEY_CROUCH;
2051         else
2052                 self.pressedkeys &~= KEY_CROUCH;
2053
2054         if (self.BUTTON_ATCK)
2055                 self.pressedkeys |= KEY_ATCK;
2056         else
2057                 self.pressedkeys &~= KEY_ATCK;
2058         if (self.BUTTON_ATCK2)
2059                 self.pressedkeys |= KEY_ATCK2;
2060         else
2061                 self.pressedkeys &~= KEY_ATCK2;
2062 }
2063
2064 /*
2065 ======================
2066 spectate mode routines
2067 ======================
2068 */
2069
2070 void SpectateCopy(entity spectatee) {
2071         other = spectatee;
2072         MUTATOR_CALLHOOK(SpectateCopy);
2073         self.armortype = spectatee.armortype;
2074         self.armorvalue = spectatee.armorvalue;
2075         self.ammo_cells = spectatee.ammo_cells;
2076         self.ammo_shells = spectatee.ammo_shells;
2077         self.ammo_nails = spectatee.ammo_nails;
2078         self.ammo_rockets = spectatee.ammo_rockets;
2079         self.ammo_fuel = spectatee.ammo_fuel;
2080         self.clip_load = spectatee.clip_load;
2081         self.clip_size = spectatee.clip_size;
2082         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2083         self.health = spectatee.health;
2084         self.impulse = 0;
2085         self.items = spectatee.items;
2086         self.last_pickup = spectatee.last_pickup;
2087         self.hit_time = spectatee.hit_time;
2088         self.metertime = spectatee.metertime;
2089         self.strength_finished = spectatee.strength_finished;
2090         self.invincible_finished = spectatee.invincible_finished;
2091         self.pressedkeys = spectatee.pressedkeys;
2092         WEPSET_COPY_EE(self, spectatee);
2093         self.switchweapon = spectatee.switchweapon;
2094         self.switchingweapon = spectatee.switchingweapon;
2095         self.weapon = spectatee.weapon;
2096         self.nex_charge = spectatee.nex_charge;
2097         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2098         self.hagar_load = spectatee.hagar_load;
2099         self.minelayer_mines = spectatee.minelayer_mines;
2100         self.punchangle = spectatee.punchangle;
2101         self.view_ofs = spectatee.view_ofs;
2102         self.velocity = spectatee.velocity;
2103         self.dmg_take = spectatee.dmg_take;
2104         self.dmg_save = spectatee.dmg_save;
2105         self.dmg_inflictor = spectatee.dmg_inflictor;
2106         self.v_angle = spectatee.v_angle;
2107         self.angles = spectatee.v_angle;
2108         self.stat_respawn_time = spectatee.stat_respawn_time;
2109         if(!self.BUTTON_USE)
2110                 self.fixangle = TRUE;
2111         setorigin(self, spectatee.origin);
2112         setsize(self, spectatee.mins, spectatee.maxs);
2113         SetZoomState(spectatee.zoomstate);
2114
2115     anticheat_spectatecopy(spectatee);
2116         self.hud = spectatee.hud;
2117         if(spectatee.vehicle)
2118     {
2119         self.fixangle = FALSE;
2120         //self.velocity = spectatee.vehicle.velocity;
2121         self.vehicle_health = spectatee.vehicle_health;
2122         self.vehicle_shield = spectatee.vehicle_shield;
2123         self.vehicle_energy = spectatee.vehicle_energy;
2124         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2125         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2126         self.vehicle_reload1 = spectatee.vehicle_reload1;
2127         self.vehicle_reload2 = spectatee.vehicle_reload2;
2128
2129         msg_entity = self;
2130
2131         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2132             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2133             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2134             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2135
2136         //WriteByte (MSG_ONE, SVC_SETVIEW);
2137         //    WriteEntity(MSG_ONE, self);
2138         //makevectors(spectatee.v_angle);
2139         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2140     }
2141 }
2142
2143 float SpectateUpdate() {
2144         if(!self.enemy)
2145             return 0;
2146
2147         if (self == self.enemy)
2148                 return 0;
2149
2150         if(self.enemy.classname != "player")
2151                 return 0;
2152
2153         SpectateCopy(self.enemy);
2154
2155         return 1;
2156 }
2157
2158
2159 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2160 entity CA_SpectateNext(entity start) {
2161         if (start.team == self.team) {
2162                 return start;
2163         }
2164
2165         other = start;
2166         // continue from current player
2167         while(other && other.team != self.team) {
2168                 other = find(other, classname, "player");
2169         }
2170
2171         if (!other) {
2172                 // restart from begining
2173                 other = find(other, classname, "player");
2174                 while(other && other.team != self.team) {
2175                         other = find(other, classname, "player");
2176                 }
2177         }
2178
2179         return other;
2180 }
2181
2182 float SpectateNext(entity _prefer) {
2183
2184         if(_prefer)
2185                 other = _prefer;
2186         else
2187                 other = find(self.enemy, classname, "player");
2188
2189         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2190                 // CA and ca players when spectating enemies is forbidden
2191                 other = CA_SpectateNext(other);
2192         } else {
2193                 // other modes and ca spectators or spectating enemies is allowed
2194                 if (!other)
2195                         other = find(other, classname, "player");
2196         }
2197
2198         if (other)
2199                 self.enemy = other;
2200
2201         if(self.enemy.classname == "player") {
2202             /*if(self.enemy.vehicle)
2203             {
2204
2205             msg_entity = self;
2206             WriteByte(MSG_ONE, SVC_SETVIEW);
2207             WriteEntity(MSG_ONE, self.enemy);
2208             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2209
2210             self.movetype = MOVETYPE_NONE;
2211             accuracy_resend(self);
2212             }
2213             else
2214             {*/
2215             msg_entity = self;
2216             WriteByte(MSG_ONE, SVC_SETVIEW);
2217             WriteEntity(MSG_ONE, self.enemy);
2218             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2219             self.movetype = MOVETYPE_NONE;
2220             accuracy_resend(self);
2221
2222             if(!SpectateUpdate())
2223                 PutObserverInServer();
2224         //}
2225         return 1;
2226         } else {
2227                 return 0;
2228         }
2229 }
2230
2231 /*
2232 =============
2233 ShowRespawnCountdown()
2234
2235 Update a respawn countdown display.
2236 =============
2237 */
2238 void ShowRespawnCountdown()
2239 {
2240         float number;
2241         if(self.deadflag == DEAD_NO) // just respawned?
2242                 return;
2243         else
2244         {
2245                 number = ceil(self.respawn_time - time);
2246                 if(number <= 0)
2247                         return;
2248                 if(number <= self.respawn_countdown)
2249                 {
2250                         self.respawn_countdown = number - 1;
2251                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2252                                 AnnounceTo(self, strcat(ftos(number), ""));
2253                 }
2254         }
2255 }
2256
2257 .float prevent_join_msgtime;
2258 void LeaveSpectatorMode()
2259 {
2260         if(self.caplayer)
2261                 return;
2262         if(nJoinAllowed(self)) {
2263                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2264                         self.classname = "player";
2265
2266                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2267                                 JoinBestTeam(self, FALSE, TRUE);
2268
2269                         if(autocvar_g_campaign)
2270                                 campaign_bots_may_start = 1;
2271
2272                         PutClientInServer();
2273
2274                         if(self.classname == "player")
2275                                 bprint ("^4", self.netname, "^4 is playing now\n");
2276
2277                         if(!autocvar_g_campaign)
2278                         if (time < self.jointime + autocvar_welcome_message_time)
2279                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2280
2281                         if (self.prevent_join_msgtime)
2282                         {
2283                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2284                                 self.prevent_join_msgtime = 0;
2285                         }
2286                 } else {
2287                         stuffcmd(self, "menu_showteamselect\n");
2288                 }
2289         }
2290         else {
2291                 //player may not join because of g_maxplayers is set
2292                 if (time - self.prevent_join_msgtime > 2)
2293                 {
2294                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2295                         self.prevent_join_msgtime = time;
2296                 }
2297         }
2298 }
2299
2300 /**
2301  * Determines whether the player is allowed to join. This depends on cvar
2302  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2303  * it checks whether the number of currently playing players exceeds g_maxplayers.
2304  * @return int number of free slots for players, 0 if none
2305  */
2306 float nJoinAllowed(entity ignore) {
2307         if(!ignore)
2308         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2309         // so report 0 free slots if restricted
2310         {
2311                 if(autocvar_g_forced_team_otherwise == "spectate")
2312                         return 0;
2313                 if(autocvar_g_forced_team_otherwise == "spectator")
2314                         return 0;
2315         }
2316
2317         if(self.team_forced < 0)
2318                 return 0; // forced spectators can never join
2319
2320         // TODO simplify this
2321         entity e;
2322         float totalClients = 0;
2323         FOR_EACH_CLIENT(e)
2324                 if(e != ignore)
2325                         totalClients += 1;
2326
2327         if (!autocvar_g_maxplayers)
2328                 return maxclients - totalClients;
2329
2330         float currentlyPlaying = 0;
2331         FOR_EACH_REALCLIENT(e)
2332                 if(e.classname == "player" || e.caplayer == 1)
2333                         currentlyPlaying += 1;
2334
2335         if(currentlyPlaying < autocvar_g_maxplayers)
2336                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2337
2338         return 0;
2339 }
2340
2341 /**
2342  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2343  * g_maxplayers_spectator_blocktime seconds
2344  */
2345 void checkSpectatorBlock() {
2346         if(self.classname == "spectator" || self.classname == "observer") {
2347                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2348                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2349                         dropclient(self);
2350                 }
2351         }
2352 }
2353
2354 .float motd_actived_time; // used for both motd and campaign_message
2355 void PrintWelcomeMessage()
2356 {
2357         if (self.motd_actived_time == 0) { // is there already a message showing?
2358                 if (autocvar_g_campaign) {
2359                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2360                                 self.motd_actived_time = time;
2361                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2362                         }
2363                 } else {
2364                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2365                                 self.motd_actived_time = time;
2366                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2367                         }
2368                 }
2369         } else { // showing MOTD or campaign message
2370                 if (autocvar_g_campaign) {
2371                         if (self.BUTTON_INFO)
2372                                 self.motd_actived_time = time;
2373                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2374                                 self.motd_actived_time = 0;
2375                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2376                         }
2377                 } else {
2378                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2379                                 if (self.BUTTON_INFO)
2380                                         self.motd_actived_time = time;
2381                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2382                                         self.motd_actived_time = 0;
2383                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2384                                 }
2385                         }
2386                 }
2387         }
2388 }
2389
2390 void ObserverThink()
2391 {
2392         float prefered_movetype;
2393         if (self.flags & FL_JUMPRELEASED) {
2394                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2395                         self.flags &~= FL_JUMPRELEASED;
2396                         self.flags |= FL_SPAWNING;
2397                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2398                         self.flags &~= FL_JUMPRELEASED;
2399                         if(SpectateNext(world) == 1) {
2400                                 self.classname = "spectator";
2401                         }
2402                 } else {
2403                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2404                         if (self.movetype != prefered_movetype)
2405                                 self.movetype = prefered_movetype;
2406                 }
2407         } else {
2408                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2409                         self.flags |= FL_JUMPRELEASED;
2410                         if(self.flags & FL_SPAWNING)
2411                         {
2412                                 self.flags &~= FL_SPAWNING;
2413                                 LeaveSpectatorMode();
2414                                 return;
2415                         }
2416                 }
2417         }
2418
2419         PrintWelcomeMessage();
2420 }
2421
2422 void SpectatorThink()
2423 {
2424         if (self.flags & FL_JUMPRELEASED) {
2425                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2426                         self.flags &~= FL_JUMPRELEASED;
2427                         self.flags |= FL_SPAWNING;
2428                 } else if(self.BUTTON_ATCK) {
2429                         self.flags &~= FL_JUMPRELEASED;
2430                         if(SpectateNext(world) == 1) {
2431                                 self.classname = "spectator";
2432                         } else {
2433                                 self.classname = "observer";
2434                                 PutClientInServer();
2435                         }
2436                 } else if (self.BUTTON_ATCK2) {
2437                         self.flags &~= FL_JUMPRELEASED;
2438                         self.classname = "observer";
2439                         PutClientInServer();
2440                 } else {
2441                         if(!SpectateUpdate())
2442                                 PutObserverInServer();
2443                 }
2444         } else {
2445                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2446                         self.flags |= FL_JUMPRELEASED;
2447                         if(self.flags & FL_SPAWNING)
2448                         {
2449                                 self.flags &~= FL_SPAWNING;
2450                                 LeaveSpectatorMode();
2451                                 return;
2452                         }
2453                 }
2454                 if(!SpectateUpdate())
2455                         PutObserverInServer();
2456         }
2457
2458         PrintWelcomeMessage();
2459         self.flags |= FL_CLIENT | FL_NOTARGET;
2460 }
2461
2462 void PlayerUseKey()
2463 {
2464         if(self.classname != "player")
2465                 return;
2466
2467         if(self.vehicle)
2468         {
2469         vehicles_exit(VHEF_NORMAL);
2470         return;
2471         }
2472
2473         // a use key was pressed; call handlers
2474         MUTATOR_CALLHOOK(PlayerUseKey);
2475 }
2476
2477 .float touchexplode_time;
2478
2479 /*
2480 =============
2481 PlayerPreThink
2482
2483 Called every frame for each client before the physics are run
2484 =============
2485 */
2486 .float usekeypressed;
2487 void() nexball_setstatus;
2488 .float items_added;
2489 void PlayerPreThink (void)
2490 {
2491         WarpZone_PlayerPhysics_FixVAngle();
2492
2493         self.stat_game_starttime = game_starttime;
2494         self.stat_round_starttime = round_starttime;
2495         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2496         self.stat_leadlimit = autocvar_leadlimit;
2497
2498         self.stat_respawn_time = self.respawn_time;
2499
2500         if(frametime)
2501         {
2502                 // physics frames: update anticheat stuff
2503                 anticheat_prethink();
2504         }
2505
2506         if(blockSpectators && frametime)
2507                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2508                 checkSpectatorBlock();
2509
2510         zoomstate_set = 0;
2511
2512         if(self.netname_previous != self.netname)
2513         {
2514                 if(autocvar_sv_eventlog)
2515                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2516                 if(self.netname_previous)
2517                         strunzone(self.netname_previous);
2518                 self.netname_previous = strzone(self.netname);
2519         }
2520
2521         // version nagging
2522         if(self.version_nagtime)
2523                 if(self.cvar_g_xonoticversion)
2524                         if(time > self.version_nagtime)
2525                         {
2526                                 // don't notify git users
2527                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2528                                 {
2529                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2530                                         {
2531                                                 // notify release users if connecting to git
2532                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2533                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2534                                         }
2535                                         else
2536                                         {
2537                                                 float r;
2538                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2539                                                 if(r < 0)
2540                                                 {
2541                                                         // give users new version
2542                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2543                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2544                                                 }
2545                                                 else if(r > 0)
2546                                                 {
2547                                                         // notify users about old server version
2548                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2549                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2550                                                 }
2551                                         }
2552                                 }
2553                                 self.version_nagtime = 0;
2554                         }
2555
2556         // GOD MODE info
2557         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2558         {
2559                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2560                 self.max_armorvalue = 0;
2561         }
2562
2563 #ifdef TETRIS
2564         if (TetrisPreFrame())
2565                 return;
2566 #endif
2567
2568         MUTATOR_CALLHOOK(PlayerPreThink);
2569
2570         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2571         {
2572                 if(self.BUTTON_USE && !self.usekeypressed)
2573                         PlayerUseKey();
2574                 self.usekeypressed = self.BUTTON_USE;
2575         }
2576
2577         PrintWelcomeMessage();
2578
2579         if(self.classname == "player") {
2580 //              if(self.netname == "Wazat")
2581 //                      bprint(self.classname, "\n");
2582
2583                 CheckRules_Player();
2584
2585                 if (intermission_running)
2586                 {
2587                         IntermissionThink ();   // otherwise a button could be missed between
2588                         return;                                 // the think tics
2589                 }
2590
2591                 //don't allow the player to turn around while game is paused!
2592                 if(timeout_status == TIMEOUT_ACTIVE) {
2593                         // FIXME turn this into CSQC stuff
2594                         self.v_angle = self.lastV_angle;
2595                         self.angles = self.lastV_angle;
2596                         self.fixangle = TRUE;
2597                 }
2598
2599                 if(frametime)
2600                 {
2601                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2602                         {
2603                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2604                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2605                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2606
2607                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2608                                 {
2609                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2610                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2611                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2612                                 }
2613                         }
2614                         else
2615                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2616
2617                         player_powerups();
2618                 }
2619
2620                 if (g_minstagib)
2621                         minstagib_ammocheck();
2622
2623                 if (self.deadflag != DEAD_NO)
2624                 {
2625                         float button_pressed, force_respawn;
2626                         if(self.personal && g_race_qualifying)
2627                         {
2628                                 if(time > self.respawn_time)
2629                                 {
2630                                         self.respawn_time = time + 1; // only retry once a second
2631                                         respawn();
2632                                         self.impulse = 141;
2633                                 }
2634                         }
2635                         else
2636                         {
2637                                 if(frametime)
2638                                         player_anim();
2639                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2640                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2641                                 if (self.deadflag == DEAD_DYING)
2642                                 {
2643                                         if(force_respawn)
2644                                                 self.deadflag = DEAD_RESPAWNING;
2645                                         else if(!button_pressed)
2646                                                 self.deadflag = DEAD_DEAD;
2647                                 }
2648                                 else if (self.deadflag == DEAD_DEAD)
2649                                 {
2650                                         if(button_pressed)
2651                                                 self.deadflag = DEAD_RESPAWNABLE;
2652                                 }
2653                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2654                                 {
2655                                         if(!button_pressed)
2656                                                 self.deadflag = DEAD_RESPAWNING;
2657                                 }
2658                                 else if (self.deadflag == DEAD_RESPAWNING)
2659                                 {
2660                                         if(time > self.respawn_time)
2661                                         {
2662                                                 self.respawn_time = time + 1; // only retry once a second
2663                                                 respawn();
2664                                         }
2665                                 }
2666                                 ShowRespawnCountdown();
2667                         }
2668
2669                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2670                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2671                                 self.stat_respawn_time *= -1;
2672
2673                         return;
2674                 }
2675                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2676                 // so (self.deadflag == DEAD_NO) is always true in the code below
2677
2678                 if(g_touchexplode)
2679                 if(time > self.touchexplode_time)
2680                 if(self.classname == "player")
2681                 if(self.deadflag == DEAD_NO)
2682                 if not(IS_INDEPENDENT_PLAYER(self))
2683                 FOR_EACH_PLAYER(other) if(self != other)
2684                 {
2685                         if(time > other.touchexplode_time)
2686                         if(other.deadflag == DEAD_NO)
2687                         if not(IS_INDEPENDENT_PLAYER(other))
2688                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2689                         {
2690                                 PlayerTouchExplode(self, other);
2691                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2692                         }
2693                 }
2694
2695                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2696                 {
2697                         vector dist;
2698
2699                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2700                         dist = self.prevorigin - self.origin;
2701                         dist_z = 0;
2702                         self.lms_traveled_distance += fabs(vlen(dist));
2703
2704                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2705                         {
2706                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2707                                 self.lms_traveled_distance = 0;
2708                         }
2709
2710                         if(time > self.lms_nextcheck)
2711                         {
2712                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2713                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2714                                 {
2715                                         centerprint(self, autocvar_g_lms_campcheck_message);
2716                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2717                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2718                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2719                                 }
2720                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2721                                 self.lms_traveled_distance = 0;
2722                         }
2723                 }
2724
2725                 self.prevorigin = self.origin;
2726
2727                 float do_crouch = self.BUTTON_CROUCH;
2728                 if(self.hook.state)
2729                         do_crouch = 0;
2730                 if(self.health <= g_bloodloss)
2731                         do_crouch = 1;
2732                 if(self.vehicle)
2733                         do_crouch = 0;
2734                 if(self.freezetag_frozen)
2735                         do_crouch = 0;
2736                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2737                         do_crouch = 0;
2738
2739                 if (do_crouch)
2740                 {
2741                         if (!self.crouch)
2742                         {
2743                                 self.crouch = TRUE;
2744                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2745                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2746                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2747                         }
2748                 }
2749                 else
2750                 {
2751                         if (self.crouch)
2752                         {
2753                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2754                                 if (!trace_startsolid)
2755                                 {
2756                                         self.crouch = FALSE;
2757                                         self.view_ofs = PL_VIEW_OFS;
2758                                         setsize (self, PL_MIN, PL_MAX);
2759                                 }
2760                         }
2761                 }
2762
2763                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2764                 {
2765                         if(self.bloodloss_timer < time)
2766                         {
2767                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2768                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2769                         }
2770                 }
2771
2772                 FixPlayermodel();
2773
2774                 GrapplingHookFrame();
2775
2776                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2777                 //if(frametime)
2778                 {
2779                         self.items &~= self.items_added;
2780
2781                         W_WeaponFrame();
2782
2783                         self.items_added = 0;
2784                         if(self.items & IT_JETPACK)
2785                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2786                                         self.items_added |= IT_FUEL;
2787
2788                         self.items |= self.items_added;
2789                 }
2790
2791                 player_regen();
2792
2793                 // rot nex charge to the charge limit
2794                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2795                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2796
2797                 if(frametime)
2798                         player_anim();
2799
2800                 if(g_nexball)
2801                         nexball_setstatus();
2802
2803                 // secret status
2804                 secrets_setstatus();
2805
2806                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2807
2808                 //self.angles_y=self.v_angle_y + 90;   // temp
2809         } else if(gameover) {
2810                 if (intermission_running)
2811                         IntermissionThink ();   // otherwise a button could be missed between
2812                 return;
2813         } else if(self.classname == "observer") {
2814                 ObserverThink();
2815         } else if(self.classname == "spectator") {
2816                 SpectatorThink();
2817         }
2818
2819         if(!zoomstate_set)
2820                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2821
2822         float oldspectatee_status;
2823         oldspectatee_status = self.spectatee_status;
2824         if(self.classname == "spectator")
2825                 self.spectatee_status = num_for_edict(self.enemy);
2826         else if(self.classname == "observer")
2827                 self.spectatee_status = num_for_edict(self);
2828         else
2829                 self.spectatee_status = 0;
2830         if(self.spectatee_status != oldspectatee_status)
2831         {
2832                 ClientData_Touch(self);
2833                 if(g_race || g_cts)
2834                         race_InitSpectator();
2835         }
2836
2837         if(self.teamkill_soundtime)
2838         if(time > self.teamkill_soundtime)
2839         {
2840                 self.teamkill_soundtime = 0;
2841
2842                 entity oldpusher, oldself;
2843
2844                 oldself = self; self = self.teamkill_soundsource;
2845                 oldpusher = self.pusher; self.pusher = oldself;
2846
2847                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2848
2849                 self.pusher = oldpusher;
2850                 self = oldself;
2851         }
2852
2853         if(self.taunt_soundtime)
2854         if(time > self.taunt_soundtime)
2855         {
2856                 self.taunt_soundtime = 0;
2857                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2858         }
2859
2860         target_voicescript_next(self);
2861
2862         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2863         if(!self.weapon)
2864                 self.clip_load = self.clip_size = 0;
2865 }
2866
2867 float isInvisibleString(string s)
2868 {
2869         float i, n, c;
2870         s = strdecolorize(s);
2871         for((i = 0), (n = strlen(s)); i < n; ++i)
2872         {
2873                 c = str2chr(s, i);
2874                 switch(c)
2875                 {
2876                         case 0:
2877                         case 32: // space
2878                                 break;
2879                         case 192: // charmap space
2880                                 if (!autocvar_utf8_enable)
2881                                         break;
2882                                 return FALSE;
2883                         case 160: // space in unicode fonts
2884                         case 0xE000 + 192: // utf8 charmap space
2885                                 if (autocvar_utf8_enable)
2886                                         break;
2887                         default:
2888                                 return FALSE;
2889                 }
2890         }
2891         return TRUE;
2892 }
2893
2894 /*
2895 =============
2896 PlayerPostThink
2897
2898 Called every frame for each client after the physics are run
2899 =============
2900 */
2901 .float idlekick_lasttimeleft;
2902 void PlayerPostThink (void)
2903 {
2904         // Savage: Check for nameless players
2905         if (isInvisibleString(self.netname)) {
2906                 self.netname = "Player";
2907                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2908         }
2909
2910         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2911         {
2912                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2913                 {
2914                         if(self.idlekick_lasttimeleft)
2915                         {
2916                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2917                                 self.idlekick_lasttimeleft = 0;
2918                         }
2919                 }
2920                 else
2921                 {
2922                         float timeleft;
2923                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2924                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2925                         {
2926                                 if(!self.idlekick_lasttimeleft)
2927                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2928                         }
2929                         if(timeleft <= 0)
2930                         {
2931                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2932                                 AnnounceTo(self, "terminated");
2933                                 dropclient(self);
2934                                 return;
2935                         }
2936                         else if(timeleft <= 10)
2937                         {
2938                                 if(timeleft != self.idlekick_lasttimeleft)
2939                                         AnnounceTo(self, ftos(timeleft));
2940                                 self.idlekick_lasttimeleft = timeleft;
2941                         }
2942                 }
2943         }
2944
2945 #ifdef TETRIS
2946         if(self.impulse == 100)
2947                 ImpulseCommands();
2948         if (!TetrisPostFrame())
2949         {
2950 #endif
2951
2952         CheatFrame();
2953
2954         //CheckPlayerJump();
2955
2956         if(self.classname == "player") {
2957                 CheckRules_Player();
2958                 UpdateChatBubble();
2959                 if (self.impulse)
2960                         ImpulseCommands();
2961                 if (intermission_running)
2962                         return;         // intermission or finale
2963                 GetPressedKeys();
2964         }
2965
2966 #ifdef TETRIS
2967         }
2968 #endif
2969
2970         /*
2971         float i;
2972         for(i = 0; i < 1000; ++i)
2973         {
2974                 vector end;
2975                 end = self.origin + '0 0 1024' + 512 * randomvec();
2976                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2977                 if(trace_fraction < 1)
2978                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2979                 {
2980                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2981                         break;
2982                 }
2983         }
2984         */
2985
2986         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2987
2988         if(self.waypointsprite_attachedforcarrier)
2989                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2990
2991         playerdemo_write();
2992
2993         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2994         {
2995                 if not(self.stored_netname)
2996                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2997                 if(self.stored_netname != self.netname)
2998                 {
2999                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3000                         strunzone(self.stored_netname);
3001                         self.stored_netname = strzone(self.netname);
3002                 }
3003         }
3004
3005         /*
3006         if(g_race)
3007                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3008         */
3009
3010         CSQCMODEL_AUTOUPDATE();
3011 }