qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel = "models/player/marine.zym";
 402 string CheckPlayerModel(string plyermodel) {
 403         if(strlen(plyermodel) < 4)
 404                 return FallbackPlayerModel;
 405         if( substring(plyermodel,0,14) != "models/player/")
 406                 return FallbackPlayerModel;
 407         else if(cvar("sv_servermodelsonly"))
 408         {
 409                 if(substring(plyermodel,-4,4) != ".zym")
 410                 if(substring(plyermodel,-4,4) != ".dpm")
 411                 if(substring(plyermodel,-4,4) != ".iqm")
 412                 if(substring(plyermodel,-4,4) != ".md3")
 413                 if(substring(plyermodel,-4,4) != ".psk")
 414                         return FallbackPlayerModel;
 415                 // forbid the LOD models
 416                 if(substring(plyermodel, -9,5) == "_lod1")
 417                         return FallbackPlayerModel;
 418                 if(substring(plyermodel, -9,5) == "_lod2")
 419                         return FallbackPlayerModel;
 420                 if(plyermodel != strtolower(plyermodel))
 421                         return FallbackPlayerModel;
 422                 if(!fexists(plyermodel))
 423                         return FallbackPlayerModel;
 424         }
 425         return plyermodel;
 426 }
 427
 428 /*
 429 =============
 430 Client_customizeentityforclient
 431
 432 LOD reduction
 433 =============
 434 */
 435 void Client_uncustomizeentityforclient()
 436 {
 437         if(self.modelindex == 0) // no need to uncustomize then
 438                 return;
 439         self.modelindex = self.modelindex_lod0;
 440         self.skin = self.skinindex;
 441 }
 442
 443 float Client_customizeentityforclient()
 444 {
 445         entity modelsource;
 446
 447         if(self.modelindex == 0)
 448                 return TRUE;
 449
 450         // forcemodel stuff
 451
 452 #ifdef PROFILING
 453         float t0;
 454         t0 = gettime(GETTIME_HIRES); // reference
 455 #endif
 456
 457         modelsource = self;
 458
 459 #ifdef ALLOW_FORCEMODELS
 460         if(other.cvar_cl_forceplayermodelsfromxonotic)
 461                 if not(self.modelindex_lod0_from_xonotic)
 462                         modelsource = other;
 463         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 464                 modelsource = other;
 465 #endif
 466
 467         self.skin = modelsource.skinindex;
 468
 469 #if 0
 470         if(modelsource == self)
 471                 self.skin = modelsource.skinindex;
 472         else
 473                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 474 #endif
 475
 476         // self: me
 477         // other: the player viewing me
 478         float distance;
 479         float f;
 480
 481         if(other.cvar_cl_playerdetailreduction <= 0)
 482         {
 483                 if(other.cvar_cl_playerdetailreduction <= -2)
 484                         self.modelindex = modelsource.modelindex_lod2;
 485                 else if(other.cvar_cl_playerdetailreduction <= -1)
 486                         self.modelindex = modelsource.modelindex_lod1;
 487                 else
 488                         self.modelindex = modelsource.modelindex_lod0;
 489         }
 490         else
 491         {
 492                 distance = vlen(self.origin - other.origin);
 493                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 494                 if(f > sv_loddistance2)
 495                         self.modelindex = modelsource.modelindex_lod2;
 496                 else if(f > sv_loddistance1)
 497                         self.modelindex = modelsource.modelindex_lod1;
 498                 else
 499                         self.modelindex = modelsource.modelindex_lod0;
 500         }
 501
 502 #ifdef PROFILING
 503         float t1;
 504         t1 = gettime(GETTIME_HIRES); // reference
 505         client_cefc_accumulator += (t1 - t0);
 506 #endif
 507
 508         return TRUE;
 509 }
 510
 511 void setmodel_lod(entity e, string modelname)
 512 {
 513         string s;
 514
 515         if(sv_loddistance1)
 516         {
 517                 // FIXME: this only supports 3-letter extensions
 518                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 519                 if(fexists(s))
 520                 {
 521                         setmodel(e, s); // players have high precision
 522                         self.modelindex_lod1 = self.modelindex;
 523                 }
 524                 else
 525                         self.modelindex_lod1 = -1;
 526
 527                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 528                 if(fexists(s))
 529                 {
 530                         setmodel(e, s); // players have high precision
 531                         self.modelindex_lod2 = self.modelindex;
 532                 }
 533                 else
 534                         self.modelindex_lod2 = -1;
 535
 536                 precache_model(modelname);
 537                 setmodel(e, modelname); // players have high precision
 538                 self.modelindex_lod0 = self.modelindex;
 539
 540                 if(self.modelindex_lod1 < 0)
 541                         self.modelindex_lod1 = self.modelindex;
 542
 543                 if(self.modelindex_lod2 < 0)
 544                         self.modelindex_lod2 = self.modelindex;
 545         }
 546         else
 547         {
 548                 precache_model(modelname);
 549                 setmodel(e, modelname); // players have high precision
 550                 self.modelindex_lod0 = self.modelindex;
 551                         // save it for possible player model forcing
 552         }
 553
 554         s = whichpack(self.model);
 555         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 556
 557         player_setupanimsformodel();
 558 }
 559
 560 /*
 561 =============
 562 PutObserverInServer
 563
 564 putting a client as observer in the server
 565 =============
 566 */
 567 void FixPlayermodel();
 568 void PutObserverInServer (void)
 569 {
 570         entity  spot;
 571
 572         race_PreSpawnObserver();
 573
 574         spot = SelectSpawnPoint (TRUE);
 575         if(!spot)
 576                 error("No spawnpoints for observers?!?\n");
 577         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 578
 579         if(clienttype(self) == CLIENTTYPE_REAL)
 580         {
 581                 msg_entity = self;
 582                 WriteByte(MSG_ONE, SVC_SETVIEW);
 583                 WriteEntity(MSG_ONE, self);
 584         }
 585
 586         DropAllRunes(self);
 587
 588         Portal_ClearAll(self);
 589
 590         if(self.flagcarried)
 591                 DropFlag(self.flagcarried, world, world);
 592
 593         if(self.ballcarried)
 594                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 595
 596         WaypointSprite_PlayerDead();
 597
 598         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 599                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 600
 601         if(self.killcount != -666) {
 602                 if(g_lms) {
 603                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 604                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 605                         else
 606                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 607                 } else
 608                         bprint ("^4", self.netname, "^4 is spectating now\n");
 609
 610                 if(self.just_joined == FALSE) {
 611                         LogTeamchange(self.playerid, -1, 4);
 612                 } else
 613                         self.just_joined = FALSE;
 614         }
 615
 616         PlayerScore_Clear(self); // clear scores when needed
 617
 618         self.spectatortime = time;
 619
 620         self.classname = "observer";
 621         self.iscreature = FALSE;
 622         self.health = -666;
 623         self.takedamage = DAMAGE_NO;
 624         self.solid = SOLID_NOT;
 625         self.movetype = MOVETYPE_NOCLIP;
 626         self.flags = FL_CLIENT | FL_NOTARGET;
 627         self.armorvalue = 666;
 628         self.effects = 0;
 629         self.armorvalue = cvar("g_balance_armor_start");
 630         self.pauserotarmor_finished = 0;
 631         self.pauserothealth_finished = 0;
 632         self.pauseregen_finished = 0;
 633         self.damageforcescale = 0;
 634         self.death_time = 0;
 635         self.dead_frame = 0;
 636         self.alpha = 0;
 637         self.scale = 0;
 638         self.fade_time = 0;
 639         self.pain_frame = 0;
 640         self.pain_finished = 0;
 641         self.strength_finished = 0;
 642         self.invincible_finished = 0;
 643         self.pushltime = 0;
 644         self.think = SUB_Null;
 645         self.nextthink = 0;
 646         self.hook_time = 0;
 647         self.runes = 0;
 648         self.deadflag = DEAD_NO;
 649         self.angles = spot.angles;
 650         self.angles_z = 0;
 651         self.fixangle = TRUE;
 652         self.crouch = FALSE;
 653
 654         self.view_ofs = PL_VIEW_OFS;
 655         setorigin (self, spot.origin);
 656         setsize (self, '0 0 0', '0 0 0');
 657         self.prevorigin = self.origin;
 658         self.items = 0;
 659         self.weapons = 0;
 660         self.model = "";
 661         FixPlayermodel();
 662         self.model = "";
 663         self.modelindex = 0;
 664         self.weapon = 0;
 665         self.weaponmodel = "";
 666         self.weaponentity = world;
 667         self.exteriorweaponentity = world;
 668         self.killcount = -666;
 669         self.velocity = '0 0 0';
 670         self.avelocity = '0 0 0';
 671         self.punchangle = '0 0 0';
 672         self.punchvector = '0 0 0';
 673         self.oldvelocity = self.velocity;
 674         self.fire_endtime = -1;
 675
 676         if(sv_loddistance1)
 677                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 678
 679         if(g_arena)
 680         {
 681                 if(self.version_mismatch)
 682                 {
 683                         Spawnqueue_Unmark(self);
 684                         Spawnqueue_Remove(self);
 685                 }
 686                 else
 687                 {
 688                         Spawnqueue_Insert(self);
 689                 }
 690         }
 691         else if(g_lms)
 692         {
 693                 // Only if the player cannot play at all
 694                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 695                         self.frags = FRAGS_SPECTATOR;
 696                 else
 697                         self.frags = FRAGS_LMS_LOSER;
 698         }
 699         else
 700                 self.frags = FRAGS_SPECTATOR;
 701
 702         MUTATOR_CALLHOOK(MakePlayerObserver);
 703 }
 704
 705 float RestrictSkin(float s)
 706 {
 707         if(!teams_matter)
 708                 return s;
 709         if(s == 6)
 710                 return 6;
 711         return mod(s, 3);
 712 }
 713
 714 void FixPlayermodel()
 715 {
 716         local string defaultmodel;
 717         local float defaultskin, chmdl, oldskin;
 718         local vector m1, m2;
 719
 720         defaultmodel = "";
 721
 722         if(cvar("sv_defaultcharacter") == 1) {
 723                 defaultskin = 0;
 724
 725                 if(teams_matter)
 726                 {
 727                         string s;
 728                         s = Team_ColorNameLowerCase(self.team);
 729                         if(s != "neutral")
 730                         {
 731                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 732                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 733                         }
 734                 }
 735
 736                 if(defaultmodel == "")
 737                 {
 738                         defaultmodel = cvar_string("sv_defaultplayermodel");
 739                         defaultskin = cvar("sv_defaultplayerskin");
 740                 }
 741         }
 742
 743         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 744         {
 745                 if(self.model != "")
 746                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 747                 self.model = ""; // force the != checks to return true
 748         }
 749
 750         if(defaultmodel != "")
 751         {
 752                 if (defaultmodel != self.model)
 753                 {
 754                         m1 = self.mins;
 755                         m2 = self.maxs;
 756                         setmodel_lod (self, defaultmodel);
 757                         setsize (self, m1, m2);
 758                         chmdl = TRUE;
 759                 }
 760
 761                 oldskin = self.skinindex;
 762                 self.skinindex = defaultskin;
 763         } else {
 764                 if (self.playermodel != self.model || self.playermodel == "")
 765                 {
 766                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 767                         m1 = self.mins;
 768                         m2 = self.maxs;
 769                         setmodel_lod (self, self.playermodel);
 770                         setsize (self, m1, m2);
 771                         chmdl = TRUE;
 772                 }
 773
 774                 oldskin = self.skinindex;
 775                 self.skinindex = RestrictSkin(stof(self.playerskin));
 776         }
 777
 778         if(chmdl || oldskin != self.skinindex)
 779                 self.species = player_getspecies(); // model or skin has changed
 780
 781         if(!teams_matter)
 782                 if(strlen(cvar_string("sv_defaultplayercolors")))
 783                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 784                                 setcolor(self, cvar("sv_defaultplayercolors"));
 785 }
 786
 787 void PlayerTouchExplode(entity p1, entity p2)
 788 {
 789         vector org;
 790         org = (p1.origin + p2.origin) * 0.5;
 791         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 792
 793         te_explosion(org);
 794
 795         entity e;
 796         e = spawn();
 797         setorigin(e, org);
 798         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 799         remove(e);
 800 }
 801
 802 /*
 803 =============
 804 PutClientInServer
 805
 806 Called when a client spawns in the server
 807 =============
 808 */
 809 //void() ctf_playerchanged;
 810 void PutClientInServer (void)
 811 {
 812         if(clienttype(self) == CLIENTTYPE_BOT)
 813         {
 814                 self.classname = "player";
 815         }
 816         else if(clienttype(self) == CLIENTTYPE_REAL)
 817         {
 818                 msg_entity = self;
 819                 WriteByte(MSG_ONE, SVC_SETVIEW);
 820                 WriteEntity(MSG_ONE, self);
 821         }
 822
 823         // player is dead and becomes observer
 824         // FIXME fix LMS scoring for new system
 825         if(g_lms)
 826         {
 827                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 828                         self.classname = "observer";
 829         }
 830
 831         if(g_arena || (g_ca && !allowed_to_spawn))
 832         if(!self.spawned)
 833                 self.classname = "observer";
 834
 835         if(gameover)
 836                 self.classname = "observer";
 837
 838         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 839                 entity spot, oldself;
 840                 float j;
 841
 842                 if(self.team < 0)
 843                         JoinBestTeam(self, FALSE, TRUE);
 844
 845                 race_PreSpawn();
 846
 847                 spot = SelectSpawnPoint (FALSE);
 848                 if(!spot)
 849                 {
 850                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 851                         return; // spawn failed
 852                 }
 853
 854                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 855
 856                 self.classname = "player";
 857                 self.wasplayer = TRUE;
 858                 self.iscreature = TRUE;
 859                 self.movetype = MOVETYPE_WALK;
 860                 self.solid = SOLID_SLIDEBOX;
 861                 if(cvar("g_playerclip_collisions"))
 862                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 863                 else
 864                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 865                 self.frags = FRAGS_PLAYER;
 866                 if(independent_players)
 867                         MAKE_INDEPENDENT_PLAYER(self);
 868                 self.flags = FL_CLIENT;
 869                 self.takedamage = DAMAGE_AIM;
 870                 if(g_minstagib)
 871                         self.effects = EF_FULLBRIGHT;
 872                 else
 873                         self.effects = 0;
 874                 self.air_finished = time + 12;
 875                 self.dmg = 2;
 876
 877                 if(inWarmupStage)
 878                 {
 879                         self.ammo_shells = warmup_start_ammo_shells;
 880                         self.ammo_nails = warmup_start_ammo_nails;
 881                         self.ammo_rockets = warmup_start_ammo_rockets;
 882                         self.ammo_cells = warmup_start_ammo_cells;
 883                         self.ammo_fuel = warmup_start_ammo_fuel;
 884                         self.health = warmup_start_health;
 885                         self.armorvalue = warmup_start_armorvalue;
 886                         self.weapons = warmup_start_weapons;
 887                 }
 888                 else
 889                 {
 890                         self.ammo_shells = start_ammo_shells;
 891                         self.ammo_nails = start_ammo_nails;
 892                         self.ammo_rockets = start_ammo_rockets;
 893                         self.ammo_cells = start_ammo_cells;
 894                         self.ammo_fuel = start_ammo_fuel;
 895                         self.health = start_health;
 896                         self.armorvalue = start_armorvalue;
 897                         self.weapons = start_weapons;
 898                 }
 899
 900                 if(g_weaponarena_random)
 901                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 902
 903                 self.items = start_items;
 904                 self.jump_interval = time;
 905
 906                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 907                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 908                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 909                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 910                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 911                 //extend the pause of rotting if client was reset at the beginning of the countdown
 912                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 913                         self.spawnshieldtime += game_starttime - time;
 914                         self.pauserotarmor_finished += game_starttime - time;
 915                         self.pauserothealth_finished += game_starttime - time;
 916                         self.pauseregen_finished += game_starttime - time;
 917                 }
 918                 self.damageforcescale = 2;
 919                 self.death_time = 0;
 920                 self.dead_frame = 0;
 921                 self.alpha = 0;
 922                 self.scale = 0;
 923                 self.fade_time = 0;
 924                 self.pain_frame = 0;
 925                 self.pain_finished = 0;
 926                 self.strength_finished = 0;
 927                 self.invincible_finished = 0;
 928                 self.pushltime = 0;
 929                 // players have no think function
 930                 self.think = SUB_Null;
 931                 self.nextthink = 0;
 932                 self.hook_time = 0;
 933                 self.dmg_team = 0;
 934
 935                 self.metertime = 0;
 936
 937                 self.runes = 0;
 938
 939                 self.deadflag = DEAD_NO;
 940
 941                 self.angles = spot.angles;
 942
 943                 self.angles_z = 0; // never spawn tilted even if the spot says to
 944                 self.fixangle = TRUE; // turn this way immediately
 945                 self.velocity = '0 0 0';
 946                 self.avelocity = '0 0 0';
 947                 self.punchangle = '0 0 0';
 948                 self.punchvector = '0 0 0';
 949                 self.oldvelocity = self.velocity;
 950                 self.fire_endtime = -1;
 951
 952                 msg_entity = self;
 953                 WRITESPECTATABLE_MSG_ONE({
 954                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 955                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 956                 });
 957
 958                 if(sv_loddistance1)
 959                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 960
 961                 self.model = "";
 962                 FixPlayermodel();
 963
 964                 self.crouch = FALSE;
 965                 self.view_ofs = PL_VIEW_OFS;
 966                 setsize (self, PL_MIN, PL_MAX);
 967                 self.spawnorigin = spot.origin;
 968                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 969                 // don't reset back to last position, even if new position is stuck in solid
 970                 self.oldorigin = self.origin;
 971                 self.prevorigin = self.origin;
 972                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 973
 974                 if(g_arena)
 975                 {
 976                         Spawnqueue_Remove(self);
 977                         Spawnqueue_Mark(self);
 978                 }
 979
 980                 else if(g_ca)
 981                         self.caplayer = 1;
 982
 983                 self.event_damage = PlayerDamage;
 984
 985                 self.bot_attack = TRUE;
 986
 987                 self.statdraintime = time + 5;
 988                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 989
 990                 if(self.killcount == -666) {
 991                         PlayerScore_Clear(self);
 992                         self.killcount = 0;
 993                 }
 994
 995                 self.cnt = WEP_LASER;
 996
 997                 CL_SpawnWeaponentity();
 998                 self.alpha = default_player_alpha;
 999                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1000                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1001
1002                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1003                 self.lms_traveled_distance = 0;
1004                 self.speedrunning = FALSE;
1005
1006                 race_PostSpawn(spot);
1007
1008                 if(cvar("spawn_debug"))
1009                 {
1010                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1011                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1012                 }
1013
1014                 //stuffcmd(self, "chase_active 0");
1015                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1016
1017                 if (cvar("g_spawnsound"))
1018                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1019
1020                 if(g_assault) {
1021                         if(self.team == assault_attacker_team)
1022                                 centerprint(self, "You are attacking!");
1023                         else
1024                                 centerprint(self, "You are defending!");
1025                 }
1026
1027                 target_voicescript_clear(self);
1028
1029                 // reset fields the weapons may use
1030                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1031                         weapon_action(j, WR_RESETPLAYER);
1032
1033                 oldself = self;
1034                 self = spot;
1035                         activator = oldself;
1036                                 SUB_UseTargets();
1037                         activator = world;
1038                 self = oldself;
1039
1040                 MUTATOR_CALLHOOK(PlayerSpawn);
1041
1042                 self.switchweapon = w_getbestweapon(self);
1043                 self.cnt = self.switchweapon;
1044                 self.weapon = 0;
1045         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1046                 PutObserverInServer ();
1047         }
1048
1049         //if(g_ctf)
1050         //      ctf_playerchanged();
1051 }
1052
1053 float ClientInit_SendEntity(entity to, float sf)
1054 {
1055         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1056         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1057         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1058         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1059         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1060
1061         if(sv_foginterval && world.fog != "")
1062                 WriteString(MSG_ENTITY, world.fog);
1063         else
1064                 WriteString(MSG_ENTITY, "");
1065         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1066         WriteByte(MSG_ENTITY, cvar("g_balance_weaponswitchdelay") * 255.0);
1067         return TRUE;
1068 }
1069
1070 void ClientInit_Spawn()
1071 {
1072         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1073 }
1074
1075 /*
1076 =============
1077 SetNewParms
1078 =============
1079 */
1080 void SetNewParms (void)
1081 {
1082         // initialize parms for a new player
1083         parm1 = -(86400 * 366);
1084 }
1085
1086 /*
1087 =============
1088 SetChangeParms
1089 =============
1090 */
1091 void SetChangeParms (void)
1092 {
1093         // save parms for level change
1094         parm1 = self.parm_idlesince - time;
1095 }
1096
1097 /*
1098 =============
1099 DecodeLevelParms
1100 =============
1101 */
1102 void DecodeLevelParms (void)
1103 {
1104         // load parms
1105         self.parm_idlesince = parm1;
1106         if(self.parm_idlesince == -(86400 * 366))
1107                 self.parm_idlesince = time;
1108
1109         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1110         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1111 }
1112
1113 /*
1114 =============
1115 ClientKill
1116
1117 Called when a client types 'kill' in the console
1118 =============
1119 */
1120
1121 void ClientKill_Now_TeamChange()
1122 {
1123         if(self.killindicator_teamchange == -1)
1124         {
1125                 self.team = -1;
1126                 JoinBestTeam( self, FALSE, FALSE );
1127         }
1128         else
1129                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1130 }
1131
1132 void ClientKill_Now()
1133 {
1134         if(self.killindicator_teamchange)
1135                 ClientKill_Now_TeamChange();
1136
1137         // in any case:
1138         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1139
1140         if(self.killindicator)
1141         {
1142                 dprint("Cleaned up after a leaked kill indicator.\n");
1143                 remove(self.killindicator);
1144                 self.killindicator = world;
1145         }
1146 }
1147 void KillIndicator_Think()
1148 {
1149         if (!self.owner.modelindex)
1150         {
1151                 self.owner.killindicator = world;
1152                 remove(self);
1153                 return;
1154         }
1155
1156         if(self.cnt <= 0)
1157         {
1158                 self = self.owner;
1159                 ClientKill_Now(); // no oldself needed
1160                 return;
1161         }
1162         else
1163         {
1164                 if(self.cnt <= 10)
1165                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1166                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1167                 {
1168                         if(self.cnt <= 10)
1169                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1170                         if(self.owner.killindicator_teamchange)
1171                         {
1172                                 if(self.owner.killindicator_teamchange == -1)
1173                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1174                                 else
1175                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1176                         }
1177                         else
1178                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1179                 }
1180                 self.nextthink = time + 1;
1181                 self.cnt -= 1;
1182         }
1183 }
1184
1185 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1186 {
1187         float killtime;
1188         entity e;
1189         killtime = cvar("g_balance_kill_delay");
1190
1191         if(g_race_qualifying)
1192                 killtime = 0;
1193
1194         self.killindicator_teamchange = targetteam;
1195
1196         if(!self.killindicator)
1197         {
1198                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1199                 {
1200                         ClientKill_Now();
1201                 }
1202                 else
1203                 {
1204                         self.killindicator = spawn();
1205                         self.killindicator.owner = self;
1206                         self.killindicator.scale = 0.5;
1207                         setattachment(self.killindicator, self, "");
1208                         setorigin(self.killindicator, '0 0 52');
1209                         self.killindicator.think = KillIndicator_Think;
1210                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1211                         self.killindicator.cnt = ceil(killtime);
1212                         self.killindicator.count = bound(0, ceil(killtime), 10);
1213                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1214
1215                         for(e = world; (e = find(e, classname, "body")) != world; )
1216                         {
1217                                 if(e.enemy != self)
1218                                         continue;
1219                                 e.killindicator = spawn();
1220                                 e.killindicator.owner = e;
1221                                 e.killindicator.scale = 0.5;
1222                                 setattachment(e.killindicator, e, "");
1223                                 setorigin(e.killindicator, '0 0 52');
1224                                 e.killindicator.think = KillIndicator_Think;
1225                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1226                                 e.killindicator.cnt = ceil(killtime);
1227                         }
1228                         self.lip = 0;
1229                 }
1230         }
1231         if(self.killindicator)
1232         {
1233                 if(targetteam)
1234                         self.killindicator.colormod = TeamColor(targetteam);
1235                 else
1236                         self.killindicator.colormod = '0 0 0';
1237         }
1238 }
1239
1240 void ClientKill (void)
1241 {
1242         ClientKill_TeamChange(0);
1243 }
1244
1245 void DoTeamChange(float destteam)
1246 {
1247         float t, c0;
1248         if(!teams_matter)
1249         {
1250                 if(destteam >= 0)
1251                         SetPlayerColors(self, destteam);
1252                 return;
1253         }
1254         if(self.classname == "player")
1255         if(destteam == -1)
1256         {
1257                 CheckAllowedTeams(self);
1258                 t = FindSmallestTeam(self, TRUE);
1259                 switch(self.team)
1260                 {
1261                         case COLOR_TEAM1: c0 = c1; break;
1262                         case COLOR_TEAM2: c0 = c2; break;
1263                         case COLOR_TEAM3: c0 = c3; break;
1264                         case COLOR_TEAM4: c0 = c4; break;
1265                         default:          c0 = 999;
1266                 }
1267                 switch(t)
1268                 {
1269                         case 1:
1270                                 if(c0 > c1)
1271                                         destteam = COLOR_TEAM1;
1272                                 break;
1273                         case 2:
1274                                 if(c0 > c2)
1275                                         destteam = COLOR_TEAM2;
1276                                 break;
1277                         case 3:
1278                                 if(c0 > c3)
1279                                         destteam = COLOR_TEAM3;
1280                                 break;
1281                         case 4:
1282                                 if(c0 > c4)
1283                                         destteam = COLOR_TEAM4;
1284                                 break;
1285                 }
1286                 if(destteam == -1)
1287                         return;
1288         }
1289         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1290                 return;
1291         ClientKill_TeamChange(destteam);
1292 }
1293
1294 void FixClientCvars(entity e)
1295 {
1296         // send prediction settings to the client
1297         stuffcmd(e, "\nin_bindmap 0 0\n");
1298         if(g_race || g_cts)
1299                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1300         if(cvar("g_antilag") == 3) // client side hitscan
1301                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1302                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1303         /*
1304          * we no longer need to stuff this. Remove this comment block if you feel
1305          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1306         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1307         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1308         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1309         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1310         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1311         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1312         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1313         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1314         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1315         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1316         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1317         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1318         stuffcmd(e, "cl_movement_edgefriction 1\n");
1319          */
1320 }
1321
1322 /*
1323 =============
1324 ClientConnect
1325
1326 Called when a client connects to the server
1327 =============
1328 */
1329 //void ctf_clientconnect();
1330 string ColoredTeamName(float t);
1331 void DecodeLevelParms (void);
1332 //void dom_player_join_team(entity pl);
1333 #ifdef UID
1334 .float uid_kicktime;
1335 .string uid;
1336 #endif
1337 void ClientConnect (void)
1338 {
1339         float t;
1340
1341         if(self.flags & FL_CLIENT)
1342         {
1343                 print("Warning: ClientConnect, but already connected!\n");
1344                 return;
1345         }
1346
1347         if(Ban_MaybeEnforceBan(self))
1348                 return;
1349
1350         DecodeLevelParms();
1351
1352         self.classname = "player_joining";
1353
1354         self.flags = FL_CLIENT;
1355         self.version_nagtime = time + 10 + random() * 10;
1356
1357         if(player_count<0)
1358         {
1359                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1360                 player_count = 0;
1361         }
1362
1363         PlayerScore_Attach(self);
1364         ClientData_Attach();
1365
1366         bot_clientconnect();
1367
1368         playerdemo_init();
1369
1370         anticheat_init();
1371
1372         race_PreSpawnObserver();
1373
1374         //if(g_domination)
1375         //      dom_player_join_team(self);
1376
1377         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1378
1379         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1380                 self.classname = "observer";
1381         } else {
1382                 if(teams_matter)
1383                 {
1384                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1385                         {
1386                                 self.classname = "player";
1387                                 campaign_bots_may_start = 1;
1388                         }
1389                         else
1390                         {
1391                                 self.classname = "observer"; // do it anyway
1392                         }
1393                 }
1394                 else
1395                 {
1396                         self.classname = "player";
1397                         campaign_bots_may_start = 1;
1398                 }
1399         }
1400
1401         self.playerid = (playerid_last = playerid_last + 1);
1402
1403         if(cvar("sv_eventlog"))
1404                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1405
1406         LogTeamchange(self.playerid, self.team, 1);
1407
1408         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1409
1410         self.netname_previous = strzone(self.netname);
1411
1412         bprint("^4", self.netname, "^4 connected");
1413
1414         if(self.classname != "observer" && (g_domination || g_ctf))
1415                 bprint(" and joined the ", ColoredTeamName(self.team));
1416
1417         bprint("\n");
1418
1419         self.welcomemessage_time = 0;
1420
1421         stuffcmd(self, strcat(clientstuff, "\n"));
1422         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1423         stuffcmd(self, "cl_particles_reloadeffects\n");
1424
1425         FixClientCvars(self);
1426
1427         // spawnfunc_waypoint sprites
1428         WaypointSprite_InitClient(self);
1429
1430         // Wazat's grappling hook
1431         SetGrappleHookBindings();
1432
1433         // get autoswitch state from player when he toggles it
1434         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1435
1436         // get version info from player
1437         stuffcmd(self, "cmd clientversion $gameversion\n");
1438
1439         // get other cvars from player
1440         GetCvars(0);
1441
1442         // set cvar for team scoreboard
1443         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1444
1445         // notify about available teams
1446         if(teams_matter)
1447         {
1448                 CheckAllowedTeams(self);
1449                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1450                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1451         }
1452         else
1453                 stuffcmd(self, "set _teams_available 0\n");
1454
1455         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1456
1457         if(g_arena || g_ca)
1458         {
1459                 self.classname = "observer";
1460                 if(g_arena)
1461                         Spawnqueue_Insert(self);
1462         }
1463         /*else if(g_ctf)
1464         {
1465                 ctf_clientconnect();
1466         }*/
1467
1468         if(teams_matter || radar_showennemies)
1469                 attach_entcs();
1470
1471         bot_relinkplayerlist();
1472
1473         self.spectatortime = time;
1474         if(blockSpectators)
1475         {
1476                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1477         }
1478
1479         self.jointime = time;
1480         self.allowedTimeouts = cvar("sv_timeout_number");
1481
1482         if(clienttype(self) == CLIENTTYPE_REAL)
1483         {
1484                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1485                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1486         }
1487
1488         if(g_lms)
1489         {
1490                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1491                 {
1492                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1493                         self.frags = FRAGS_SPECTATOR;
1494                 }
1495         }
1496
1497         if(!sv_foginterval && world.fog != "")
1498                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1499
1500         SoundEntity_Attach(self);
1501
1502         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1503         {
1504                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1505                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1506         }
1507         else
1508                 self.hitplotfh = -1;
1509
1510 #ifdef UID
1511         if(clienttype(self) == CLIENTTYPE_REAL)
1512         if not(self.uid)
1513                 self.uid_kicktime = time + 60;
1514 #endif
1515
1516         if(g_race || g_cts) {
1517                 string rr;
1518                 if(g_cts)
1519                         rr = CTS_RECORD;
1520                 else
1521                         rr = RACE_RECORD;
1522                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1523
1524                 race_send_recordtime(MSG_ONE);
1525                 race_send_speedaward(MSG_ONE);
1526
1527                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1528                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1529                 race_send_speedaward_alltimebest(MSG_ONE);
1530
1531                 float i;
1532                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1533                         race_SendRankings(i, 0, 0, MSG_ONE);
1534                 }
1535         }
1536         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1537                 send_CSQC_teamnagger();
1538
1539         CheatInitClient();
1540 }
1541
1542 /*
1543 =============
1544 ClientDisconnect
1545
1546 Called when a client disconnects from the server
1547 =============
1548 */
1549 .entity chatbubbleentity;
1550 .entity teambubbleentity;
1551 void ReadyCount();
1552 void ClientDisconnect (void)
1553 {
1554         if not(self.flags & FL_CLIENT)
1555         {
1556                 print("Warning: ClientDisconnect without ClientConnect\n");
1557                 return;
1558         }
1559
1560         CheatShutdownClient();
1561
1562         if(self.hitplotfh >= 0)
1563         {
1564                 fclose(self.hitplotfh);
1565                 self.hitplotfh = -1;
1566         }
1567
1568         anticheat_report();
1569         anticheat_shutdown();
1570
1571         playerdemo_shutdown();
1572
1573         bot_clientdisconnect();
1574
1575         if(self.entcs)
1576                 detach_entcs();
1577
1578         if(cvar("sv_eventlog"))
1579                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1580         bprint ("^4",self.netname);
1581         bprint ("^4 disconnected\n");
1582
1583         SoundEntity_Detach(self);
1584
1585         DropAllRunes(self);
1586         MUTATOR_CALLHOOK(ClientDisconnect);
1587
1588         Portal_ClearAll(self);
1589
1590         if(self.flagcarried)
1591                 DropFlag(self.flagcarried, world, world);
1592         if(self.ballcarried)
1593                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1594
1595         // Here, everything has been done that requires this player to be a client.
1596
1597         self.flags &~= FL_CLIENT;
1598
1599         if (self.chatbubbleentity)
1600                 remove (self.chatbubbleentity);
1601
1602         if (self.teambubbleentity)
1603                 remove (self.teambubbleentity);
1604
1605         if (self.killindicator)
1606                 remove (self.killindicator);
1607
1608         WaypointSprite_PlayerGone();
1609
1610         bot_relinkplayerlist();
1611
1612         // remove laserdot
1613         if(self.weaponentity)
1614                 if(self.weaponentity.lasertarget)
1615                         remove(self.weaponentity.lasertarget);
1616
1617         if(g_arena)
1618         {
1619                 Spawnqueue_Unmark(self);
1620                 Spawnqueue_Remove(self);
1621         }
1622
1623         ClientData_Detach();
1624         PlayerScore_Detach(self);
1625
1626         if(self.netname_previous)
1627                 strunzone(self.netname_previous);
1628         if(self.clientstatus)
1629                 strunzone(self.clientstatus);
1630
1631         ClearPlayerSounds();
1632
1633         if(self.personal)
1634                 remove(self.personal);
1635
1636         self.playerid = 0;
1637         ReadyCount();
1638
1639         // free cvars
1640         GetCvars(-1);
1641 }
1642
1643 .float BUTTON_CHAT;
1644 void ChatBubbleThink()
1645 {
1646         self.nextthink = time;
1647         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1648         {
1649                 if(self.owner) // but why can that ever be world?
1650                         self.owner.chatbubbleentity = world;
1651                 remove(self);
1652                 return;
1653         }
1654         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1655 #ifdef TETRIS
1656                 || self.owner.tetris_on
1657 #endif
1658         )
1659                 self.model = self.mdl;
1660         else
1661                 self.model = "";
1662 };
1663
1664 void UpdateChatBubble()
1665 {
1666         if (!self.modelindex)
1667                 return;
1668         // spawn a chatbubble entity if needed
1669         if (!self.chatbubbleentity)
1670         {
1671                 self.chatbubbleentity = spawn();
1672                 self.chatbubbleentity.owner = self;
1673                 self.chatbubbleentity.exteriormodeltoclient = self;
1674                 self.chatbubbleentity.think = ChatBubbleThink;
1675                 self.chatbubbleentity.nextthink = time;
1676                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1677                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1678                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1679                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1680                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1681                 self.chatbubbleentity.model = "";
1682                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1683         }
1684 }
1685
1686
1687 void TeamBubbleThink()
1688 {
1689         self.nextthink = time;
1690         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1691         {
1692                 if(self.owner) // but why can that ever be world?
1693                         self.owner.teambubbleentity = world;
1694                 remove(self);
1695                 return;
1696         }
1697 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1698         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1699                 self.model = "";
1700         else
1701                 self.model = self.mdl;
1702
1703 };
1704
1705 float TeamBubble_customizeentityforclient()
1706 {
1707         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1708 }
1709
1710 void UpdateTeamBubble()
1711 {
1712         if (!self.modelindex || !teams_matter)
1713                 return;
1714         // spawn a teambubble entity if needed
1715         if (!self.teambubbleentity && teams_matter)
1716         {
1717                 self.teambubbleentity = spawn();
1718                 self.teambubbleentity.owner = self;
1719                 self.teambubbleentity.exteriormodeltoclient = self;
1720                 self.teambubbleentity.think = TeamBubbleThink;
1721                 self.teambubbleentity.nextthink = time;
1722                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1723 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1724                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1725                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1726                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1727                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1728                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1729                 self.teambubbleentity.effects = EF_LOWPRECISION;
1730         }
1731 }
1732
1733 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1734 // added to the model skins
1735 /*void UpdateColorModHack()
1736 {
1737         local float c;
1738         c = self.clientcolors & 15;
1739         // LordHavoc: only bothering to support white, green, red, yellow, blue
1740              if (!teams_matter) self.colormod = '0 0 0';
1741         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1742         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1743         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1744         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1745         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1746         else self.colormod = '1 1 1';
1747 };*/
1748
1749 void respawn(void)
1750 {
1751         CopyBody(1);
1752         self.effects |= EF_NODRAW; // prevent another CopyBody
1753         PutClientInServer();
1754 }
1755
1756 void play_countdown(float finished, string samp)
1757 {
1758         if(clienttype(self) == CLIENTTYPE_REAL)
1759                 if(floor(finished - time - frametime) != floor(finished - time))
1760                         if(finished - time < 6)
1761                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1762 }
1763
1764 /**
1765  * When sv_timeout is used this function returs strings like
1766  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1767  * Called by centerprint functions
1768  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1769  */
1770 string getTimeoutText(float addOneSecond) {
1771         if (!cvar("sv_timeout") || !timeoutStatus)
1772                 return "";
1773
1774         local string retStr;
1775         if (timeoutStatus == 1) {
1776                 if (addOneSecond == 1) {
1777                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1778                 }
1779                 else {
1780                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1781                 }
1782                 return retStr;
1783         }
1784         else if (timeoutStatus == 2) {
1785                 if (addOneSecond) {
1786                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1787                         //don't show messages like "Timeout ends in 0 seconds"...
1788                         if ((remainingTimeoutTime + 1) > 0)
1789                                 return retStr;
1790                         else
1791                                 return "";
1792                 }
1793                 else {
1794                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1795                         //don't show messages like "Timeout ends in 0 seconds"...
1796                         if (remainingTimeoutTime > 0)
1797                                 return retStr;
1798                         else
1799                                 return "";
1800                 }
1801         }
1802         else return "";
1803 }
1804
1805 void player_powerups (void)
1806 {
1807         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1808         {
1809                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1810                 self.modelflags |= MF_ROCKET;
1811         }
1812         else
1813         {
1814                 SoundEntity_StopSound(self, CHAN_PLAYER);
1815                 self.modelflags &~= MF_ROCKET;
1816         }
1817
1818         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1819
1820         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1821                 return;
1822
1823         Fire_ApplyDamage(self);
1824         Fire_ApplyEffect(self);
1825
1826         if (g_minstagib)
1827         {
1828                 self.effects |= EF_FULLBRIGHT;
1829
1830                 if (self.items & IT_STRENGTH)
1831                 {
1832                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1833                         if (time > self.strength_finished)
1834                         {
1835                                 self.alpha = default_player_alpha;
1836                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1837                                 self.items &~= IT_STRENGTH;
1838                                 sprint(self, "^3Invisibility has worn off\n");
1839                         }
1840                 }
1841                 else
1842                 {
1843                         if (time < self.strength_finished)
1844                         {
1845                                 self.alpha = g_minstagib_invis_alpha;
1846                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1847                                 self.items |= IT_STRENGTH;
1848                                 sprint(self, "^3You are invisible\n");
1849                         }
1850                 }
1851
1852                 if (self.items & IT_INVINCIBLE)
1853                 {
1854                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1855                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1856                         {
1857                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1858                                 sprint(self, "^3Speed has worn off\n");
1859                         }
1860                 }
1861                 else
1862                 {
1863                         if (time < self.invincible_finished)
1864                         {
1865                                 self.items = self.items | IT_INVINCIBLE;
1866                                 sprint(self, "^3You are on speed\n");
1867                         }
1868                 }
1869                 return;
1870         }
1871
1872         if (self.items & IT_STRENGTH)
1873         {
1874                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1875                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1876                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1877                 {
1878                         self.items = self.items - (self.items & IT_STRENGTH);
1879                         sprint(self, "^3Strength has worn off\n");
1880                 }
1881         }
1882         else
1883         {
1884                 if (time < self.strength_finished)
1885                 {
1886                         self.items = self.items | IT_STRENGTH;
1887                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1888                 }
1889         }
1890         if (self.items & IT_INVINCIBLE)
1891         {
1892                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1893                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1894                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1895                 {
1896                         self.items = self.items - (self.items & IT_INVINCIBLE);
1897                         sprint(self, "^3Shield has worn off\n");
1898                 }
1899         }
1900         else
1901         {
1902                 if (time < self.invincible_finished)
1903                 {
1904                         self.items = self.items | IT_INVINCIBLE;
1905                         sprint(self, "^3Shield surrounds you\n");
1906                 }
1907         }
1908
1909         if(cvar("g_nodepthtestplayers"))
1910                 self.effects = self.effects | EF_NODEPTHTEST;
1911
1912         if(cvar("g_fullbrightplayers"))
1913                 self.effects = self.effects | EF_FULLBRIGHT;
1914
1915         // midair gamemode: damage only while in the air
1916         // if in midair mode, being on ground grants temporary invulnerability
1917         // (this is so that multishot weapon don't clear the ground flag on the
1918         // first damage in the frame, leaving the player vulnerable to the
1919         // remaining hits in the same frame)
1920         if (self.flags & FL_ONGROUND)
1921         if (g_midair)
1922                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1923
1924         if (time >= game_starttime)
1925         if (time < self.spawnshieldtime)
1926                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1927 }
1928
1929 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1930 {
1931         if(current > stable)
1932                 return current;
1933         else if(current > stable - 0.25) // when close enough, "snap"
1934                 return stable;
1935         else
1936                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1937 }
1938
1939 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1940 {
1941         if(current < stable)
1942                 return current;
1943         else if(current < stable + 0.25) // when close enough, "snap"
1944                 return stable;
1945         else
1946                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1947 }
1948
1949 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1950 {
1951         if(current > rotstable)
1952         {
1953                 if(rotframetime > 0)
1954                 {
1955                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1956                         current = max(rotstable, current - rotlinear * rotframetime);
1957                 }
1958         }
1959         else if(current < regenstable)
1960         {
1961                 if(regenframetime > 0)
1962                 {
1963                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1964                         current = min(regenstable, current + regenlinear * regenframetime);
1965                 }
1966         }
1967
1968         if(current > limit)
1969                 current = limit;
1970
1971         return current;
1972 }
1973
1974 void player_regen (void)
1975 {
1976         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1977         maxh = cvar("g_balance_health_rotstable");
1978         maxa = cvar("g_balance_armor_rotstable");
1979         maxf = cvar("g_balance_fuel_rotstable");
1980         minh = cvar("g_balance_health_regenstable");
1981         mina = cvar("g_balance_armor_regenstable");
1982         minf = cvar("g_balance_fuel_regenstable");
1983         limith = cvar("g_balance_health_limit");
1984         limita = cvar("g_balance_armor_limit");
1985         limitf = cvar("g_balance_fuel_limit");
1986
1987         max_mod = regen_mod = rot_mod = limit_mod = 1;
1988
1989         if (self.runes & RUNE_REGEN)
1990         {
1991                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1992                 {
1993                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1994                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1995                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1996                 }
1997                 else
1998                 {
1999                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2000                         max_mod = cvar("g_balance_rune_regen_hpmod");
2001                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2002                 }
2003         }
2004         else if (self.runes & CURSE_VENOM)
2005         {
2006                 max_mod = cvar("g_balance_curse_venom_hpmod");
2007                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2008                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2009                 else
2010                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2011                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2012                 //if (!self.runes & RUNE_REGEN)
2013                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2014         }
2015         maxh = maxh * max_mod;
2016         //maxa = maxa * max_mod;
2017         //maxf = maxf * max_mod;
2018         minh = minh * max_mod;
2019         //mina = mina * max_mod;
2020         //minf = minf * max_mod;
2021         limith = limith * limit_mod;
2022         limita = limita * limit_mod;
2023         //limitf = limitf * limit_mod;
2024
2025         if(g_lms && g_ca)
2026                 rot_mod = 0;
2027
2028         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2029         {
2030                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2031                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2032
2033                 // if player rotted to death...  die!
2034                 if(self.health < 1)
2035                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2036         }
2037
2038         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2039                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2040 }
2041
2042 float zoomstate_set;
2043 void SetZoomState(float z)
2044 {
2045         if(z != self.zoomstate)
2046         {
2047                 self.zoomstate = z;
2048                 ClientData_Touch(self);
2049         }
2050         zoomstate_set = 1;
2051 }
2052
2053 void GetPressedKeys(void) {
2054         MUTATOR_CALLHOOK(GetPressedKeys);
2055         if (self.movement_x > 0) // get if movement keys are pressed
2056         {       // forward key pressed
2057                 self.pressedkeys |= KEY_FORWARD;
2058                 self.pressedkeys &~= KEY_BACKWARD;
2059         }
2060         else if (self.movement_x < 0)
2061         {       // backward key pressed
2062                 self.pressedkeys |= KEY_BACKWARD;
2063                 self.pressedkeys &~= KEY_FORWARD;
2064         }
2065         else
2066         {       // no x input
2067                 self.pressedkeys &~= KEY_FORWARD;
2068                 self.pressedkeys &~= KEY_BACKWARD;
2069         }
2070
2071         if (self.movement_y > 0)
2072         {       // right key pressed
2073                 self.pressedkeys |= KEY_RIGHT;
2074                 self.pressedkeys &~= KEY_LEFT;
2075         }
2076         else if (self.movement_y < 0)
2077         {       // left key pressed
2078                 self.pressedkeys |= KEY_LEFT;
2079                 self.pressedkeys &~= KEY_RIGHT;
2080         }
2081         else
2082         {       // no y input
2083                 self.pressedkeys &~= KEY_RIGHT;
2084                 self.pressedkeys &~= KEY_LEFT;
2085         }
2086
2087         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2088                 self.pressedkeys |= KEY_JUMP;
2089         else
2090                 self.pressedkeys &~= KEY_JUMP;
2091         if (self.BUTTON_CROUCH)
2092                 self.pressedkeys |= KEY_CROUCH;
2093         else
2094                 self.pressedkeys &~= KEY_CROUCH;
2095 }
2096
2097 void update_stats (float number, float hit, float fired) {
2098 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2099 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2100
2101         if(number) {
2102                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2103                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2104         } else {
2105                 self.stat_hit = hit * sv_accuracy_data_share;
2106                 self.stat_fired = fired * sv_accuracy_data_share;
2107         }
2108 }
2109
2110 /*
2111 ======================
2112 spectate mode routines
2113 ======================
2114 */
2115
2116 .float weapon_count;
2117 void SpectateCopy(entity spectatee) {
2118         if(spectatee.weapon_count < WEP_LAST) {
2119                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2120                 spectatee.weapon_count ++;
2121         } else
2122                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2123
2124         other = spectatee;
2125         MUTATOR_CALLHOOK(SpectateCopy);
2126         self.armortype = spectatee.armortype;
2127         self.armorvalue = spectatee.armorvalue;
2128         self.ammo_cells = spectatee.ammo_cells;
2129         self.ammo_shells = spectatee.ammo_shells;
2130         self.ammo_nails = spectatee.ammo_nails;
2131         self.ammo_rockets = spectatee.ammo_rockets;
2132         self.ammo_fuel = spectatee.ammo_fuel;
2133         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2134         self.health = spectatee.health;
2135         self.impulse = 0;
2136         self.items = spectatee.items;
2137         self.metertime = spectatee.metertime;
2138         self.strength_finished = spectatee.strength_finished;
2139         self.invincible_finished = spectatee.invincible_finished;
2140         self.pressedkeys = spectatee.pressedkeys;
2141         self.weapons = spectatee.weapons;
2142         self.switchweapon = spectatee.switchweapon;
2143         self.weapon = spectatee.weapon;
2144         self.punchangle = spectatee.punchangle;
2145         self.view_ofs = spectatee.view_ofs;
2146         self.v_angle = spectatee.v_angle;
2147         self.velocity = spectatee.velocity;
2148         self.dmg_take = spectatee.dmg_take;
2149         self.dmg_save = spectatee.dmg_save;
2150         self.dmg_inflictor = spectatee.dmg_inflictor;
2151         self.angles = spectatee.v_angle;
2152         self.fixangle = TRUE;
2153         setorigin(self, spectatee.origin);
2154         setsize(self, spectatee.mins, spectatee.maxs);
2155         SetZoomState(spectatee.zoomstate);
2156
2157         anticheat_spectatecopy(spectatee);
2158 }
2159
2160 float SpectateUpdate() {
2161         if(!self.enemy)
2162                 return 0;
2163
2164         if (self == self.enemy)
2165                 return 0;
2166
2167         if(self.enemy.classname != "player")
2168                 return 0;
2169
2170         SpectateCopy(self.enemy);
2171
2172         return 1;
2173 }
2174
2175 float SpectateNext() {
2176         other = find(self.enemy, classname, "player");
2177
2178         if (!other)
2179                 other = find(other, classname, "player");
2180
2181         if (other)
2182                 self.enemy = other;
2183
2184         if(self.enemy.classname == "player") {
2185                 msg_entity = self;
2186                 WriteByte(MSG_ONE, SVC_SETVIEW);
2187                 WriteEntity(MSG_ONE, self.enemy);
2188                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2189                 self.movetype = MOVETYPE_NONE;
2190
2191                 self.enemy.weapon_count = 0;
2192
2193                 if(!SpectateUpdate())
2194                         PutObserverInServer();
2195
2196                 return 1;
2197         } else {
2198                 return 0;
2199         }
2200 }
2201
2202 /*
2203 =============
2204 ShowRespawnCountdown()
2205
2206 Update a respawn countdown display.
2207 =============
2208 */
2209 void ShowRespawnCountdown()
2210 {
2211         float number;
2212         if(self.deadflag == DEAD_NO) // just respawned?
2213                 return;
2214         else
2215         {
2216                 number = ceil(self.death_time - time);
2217                 if(number <= 0)
2218                         return;
2219                 if(number <= self.respawn_countdown)
2220                 {
2221                         self.respawn_countdown = number - 1;
2222                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2223                                 AnnounceTo(self, strcat(ftos(number), ""));
2224                 }
2225         }
2226 }
2227
2228 void LeaveSpectatorMode()
2229 {
2230         if(isJoinAllowed()) {
2231                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2232                         self.classname = "player";
2233
2234                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2235                                 JoinBestTeam(self, FALSE, TRUE);
2236
2237                         if(cvar("g_campaign"))
2238                                 campaign_bots_may_start = 1;
2239
2240                         self.stat_count = WEP_LAST;
2241
2242                         PutClientInServer();
2243
2244                         if(self.classname == "player")
2245                                 bprint ("^4", self.netname, "^4 is playing now\n");
2246
2247                         if(!cvar("g_campaign"))
2248                                 centerprint(self,""); // clear MOTD
2249
2250                         return;
2251                 } else {
2252                         if (g_ca && self.caplayer) {
2253                         }       // do nothing
2254                         else
2255                                 stuffcmd(self,"menu_showteamselect\n");
2256                         return;
2257                 }
2258         }
2259         else {
2260                 //player may not join because of g_maxplayers is set
2261                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2262         }
2263 }
2264
2265 /**
2266  * Determines whether the player is allowed to join. This depends on cvar
2267  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2268  * it checks whether the number of currently playing players exceeds g_maxplayers.
2269  * @return bool TRUE if the player is allowed to join, false otherwise
2270  */
2271 float isJoinAllowed() {
2272         if (!cvar("g_maxplayers"))
2273                 return TRUE;
2274
2275         local entity e;
2276         local float currentlyPlaying;
2277         FOR_EACH_REALPLAYER(e) {
2278                 if(e.classname == "player")
2279                         currentlyPlaying += 1;
2280         }
2281         if(currentlyPlaying < cvar("g_maxplayers"))
2282                 return TRUE;
2283
2284         return FALSE;
2285 }
2286
2287 /**
2288  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2289  * g_maxplayers_spectator_blocktime seconds
2290  */
2291 void checkSpectatorBlock() {
2292         if(self.classname == "spectator" || self.classname == "observer") {
2293                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2294                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2295                         dropclient(self);
2296                 }
2297         }
2298 }
2299
2300 float vercmp_recursive(string v1, string v2)
2301 {
2302         float dot1, dot2;
2303         string s1, s2;
2304         float r;
2305
2306         dot1 = strstrofs(v1, ".", 0);
2307         dot2 = strstrofs(v2, ".", 0);
2308         if(dot1 == -1)
2309                 s1 = v1;
2310         else
2311                 s1 = substring(v1, 0, dot1);
2312         if(dot2 == -1)
2313                 s2 = v2;
2314         else
2315                 s2 = substring(v2, 0, dot2);
2316
2317         r = stof(s1) - stof(s2);
2318         if(r != 0)
2319                 return r;
2320
2321         r = strcasecmp(s1, s2);
2322         if(r != 0)
2323                 return r;
2324
2325         if(dot1 == -1)
2326                 if(dot2 == -1)
2327                         return 0;
2328                 else
2329                         return -1;
2330         else
2331                 if(dot2 == -1)
2332                         return 1;
2333                 else
2334                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2335 }
2336
2337 float vercmp(string v1, string v2)
2338 {
2339         if(strcasecmp(v1, v2) == 0) // early out check
2340                 return 0;
2341         return vercmp_recursive(v1, v2);
2342 }
2343
2344 void ObserverThink()
2345 {
2346         if (self.flags & FL_JUMPRELEASED) {
2347                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2348                         self.welcomemessage_time = 0;
2349                         self.flags &~= FL_JUMPRELEASED;
2350                         self.flags |= FL_SPAWNING;
2351                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2352                         self.welcomemessage_time = 0;
2353                         self.flags &~= FL_JUMPRELEASED;
2354                         if(SpectateNext() == 1) {
2355                                 self.classname = "spectator";
2356                         }
2357                 }
2358         } else {
2359                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2360                         self.flags |= FL_JUMPRELEASED;
2361                         if(self.flags & FL_SPAWNING)
2362                         {
2363                                 self.flags &~= FL_SPAWNING;
2364                                 LeaveSpectatorMode();
2365                                 return;
2366                         }
2367                 }
2368         }
2369         PrintWelcomeMessage(self);
2370 }
2371
2372 void SpectatorThink()
2373 {
2374         if (self.flags & FL_JUMPRELEASED) {
2375                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2376                         self.welcomemessage_time = 0;
2377                         self.flags &~= FL_JUMPRELEASED;
2378                         self.flags |= FL_SPAWNING;
2379                 } else if(self.BUTTON_ATCK) {
2380                         self.welcomemessage_time = 0;
2381                         self.flags &~= FL_JUMPRELEASED;
2382                         if(SpectateNext() == 1) {
2383                                 self.classname = "spectator";
2384                         } else {
2385                                 self.classname = "observer";
2386                                 self.stat_count = WEP_LAST;
2387                                 PutClientInServer();
2388                         }
2389                 } else if (self.BUTTON_ATCK2) {
2390                         self.welcomemessage_time = 0;
2391                         self.flags &~= FL_JUMPRELEASED;
2392                         self.classname = "observer";
2393                         self.stat_count = WEP_LAST;
2394                         PutClientInServer();
2395                 } else {
2396                         if(!SpectateUpdate())
2397                                 PutObserverInServer();
2398                 }
2399         } else {
2400                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2401                         self.flags |= FL_JUMPRELEASED;
2402                         if(self.flags & FL_SPAWNING)
2403                         {
2404                                 self.flags &~= FL_SPAWNING;
2405                                 LeaveSpectatorMode();
2406                                 return;
2407                         }
2408                 }
2409         }
2410
2411         PrintWelcomeMessage(self);
2412         self.flags |= FL_CLIENT | FL_NOTARGET;
2413 }
2414
2415 .float touchexplode_time;
2416
2417 /*
2418 =============
2419 PlayerPreThink
2420
2421 Called every frame for each client before the physics are run
2422 =============
2423 */
2424 void() ctf_setstatus;
2425 void() nexball_setstatus;
2426 .float items_added;
2427 void PlayerPreThink (void)
2428 {
2429         self.stat_game_starttime = game_starttime;
2430         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2431         self.stat_leadlimit = cvar("leadlimit");
2432
2433         if(frametime)
2434         {
2435                 // physics frames: update anticheat stuff
2436                 anticheat_prethink();
2437         }
2438
2439         if(blockSpectators && frametime)
2440                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2441                 checkSpectatorBlock();
2442
2443         zoomstate_set = 0;
2444
2445         if(self.netname_previous != self.netname)
2446         {
2447                 if(cvar("sv_eventlog"))
2448                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2449                 if(self.netname_previous)
2450                         strunzone(self.netname_previous);
2451                 self.netname_previous = strzone(self.netname);
2452         }
2453
2454         // version nagging
2455         if(self.version_nagtime)
2456                 if(self.cvar_g_xonoticversion)
2457                         if(time > self.version_nagtime)
2458                         {
2459                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2460                                 {
2461                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2462                                         {
2463                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2464                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2465                                         }
2466                                         else
2467                                         {
2468                                                 float r;
2469                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2470                                                 if(r < 0)
2471                                                 {
2472                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2473                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2474                                                 }
2475                                                 else if(r > 0)
2476                                                 {
2477                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2478                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2479                                                 }
2480                                         }
2481                                 }
2482                                 self.version_nagtime = 0;
2483                         }
2484
2485         // GOD MODE info
2486         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2487         {
2488                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2489                 self.max_armorvalue = 0;
2490         }
2491
2492 #ifdef TETRIS
2493         if (TetrisPreFrame())
2494                 return;
2495 #endif
2496
2497         MUTATOR_CALLHOOK(PlayerPreThink);
2498
2499         if(self.classname == "player") {
2500 //              if(self.netname == "Wazat")
2501 //                      bprint(self.classname, "\n");
2502
2503                 CheckRules_Player();
2504
2505                 PrintWelcomeMessage(self);
2506
2507                 if (intermission_running)
2508                 {
2509                         IntermissionThink ();   // otherwise a button could be missed between
2510                         return;                                 // the think tics
2511                 }
2512
2513                 if(self.teleport_time)
2514                 if(time > self.teleport_time)
2515                 {
2516                         self.teleport_time = 0;
2517                         self.effects = self.effects - (self.effects & EF_NODRAW);
2518                 }
2519
2520                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2521                         UpdateSelectedPlayer();
2522
2523                 //don't allow the player to turn around while game is paused!
2524                 if(timeoutStatus == 2) {
2525                         self.v_angle = self.lastV_angle;
2526                         self.angles = self.lastV_angle;
2527                         self.fixangle = TRUE;
2528                 }
2529
2530                 if(frametime)
2531                 {
2532                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2533                         player_powerups();
2534                 }
2535
2536                 if (self.deadflag != DEAD_NO)
2537                 {
2538                         float button_pressed, force_respawn;
2539                         if(self.personal && g_race_qualifying)
2540                         {
2541                                 if(time > self.death_time)
2542                                 {
2543                                         self.death_time = time + 1; // only retry once a second
2544                                         respawn();
2545                                         self.impulse = 141;
2546                                 }
2547                         }
2548                         else
2549                         {
2550                                 if(frametime)
2551                                         player_anim();
2552                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2553                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2554                                 if (self.deadflag == DEAD_DYING)
2555                                 {
2556                                         if(force_respawn)
2557                                                 self.deadflag = DEAD_RESPAWNING;
2558                                         else if(!button_pressed)
2559                                                 self.deadflag = DEAD_DEAD;
2560                                 }
2561                                 else if (self.deadflag == DEAD_DEAD)
2562                                 {
2563                                         if(button_pressed)
2564                                                 self.deadflag = DEAD_RESPAWNABLE;
2565                                 }
2566                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2567                                 {
2568                                         if(!button_pressed)
2569                                                 self.deadflag = DEAD_RESPAWNING;
2570                                 }
2571                                 else if (self.deadflag == DEAD_RESPAWNING)
2572                                 {
2573                                         if(time > self.death_time)
2574                                         {
2575                                                 self.death_time = time + 1; // only retry once a second
2576                                                 respawn();
2577                                         }
2578                                 }
2579                                 ShowRespawnCountdown();
2580                         }
2581                         return;
2582                 }
2583
2584                 if(g_touchexplode)
2585                 if(time > self.touchexplode_time)
2586                 if(self.classname == "player")
2587                 if(self.deadflag == DEAD_NO)
2588                 if not(IS_INDEPENDENT_PLAYER(self))
2589                 FOR_EACH_PLAYER(other) if(self != other)
2590                 {
2591                         if(time > other.touchexplode_time)
2592                         if(other.classname == "player")
2593                         if(other.deadflag == DEAD_NO)
2594                         if not(IS_INDEPENDENT_PLAYER(other))
2595                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2596                         {
2597                                 PlayerTouchExplode(self, other);
2598                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2599                         }
2600                 }
2601
2602                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2603                 {
2604                         vector dist;
2605
2606                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2607                         dist = self.prevorigin - self.origin;
2608                         dist_z = 0;
2609                         self.lms_traveled_distance += fabs(vlen(dist));
2610
2611                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2612                         {
2613                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2614                                 self.lms_traveled_distance = 0;
2615                         }
2616
2617                         if(time > self.lms_nextcheck)
2618                         {
2619                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2620                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2621                                 {
2622                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2623                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2624                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2625                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2626                                 }
2627                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2628                                 self.lms_traveled_distance = 0;
2629                         }
2630                 }
2631
2632                 self.prevorigin = self.origin;
2633
2634                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2635                 {
2636                         if (!self.crouch)
2637                         {
2638                                 self.crouch = TRUE;
2639                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2640                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2641                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2642                         }
2643                 }
2644                 else
2645                 {
2646                         if (self.crouch)
2647                         {
2648                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2649                                 if (!trace_startsolid)
2650                                 {
2651                                         self.crouch = FALSE;
2652                                         self.view_ofs = PL_VIEW_OFS;
2653                                         setsize (self, PL_MIN, PL_MAX);
2654                                 }
2655                         }
2656                 }
2657
2658                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2659                 {
2660                         if(self.bloodloss_timer < time)
2661                         {
2662                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2663                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2664                         }
2665                 }
2666
2667                 FixPlayermodel();
2668
2669                 GrapplingHookFrame();
2670
2671                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2672                 //if(frametime)
2673                 {
2674                         self.items &~= self.items_added;
2675
2676                         W_WeaponFrame();
2677
2678                         self.items_added = 0;
2679                         if(self.items & IT_JETPACK)
2680                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2681                                         self.items_added |= IT_FUEL;
2682
2683                         self.items |= self.items_added;
2684                 }
2685
2686                 player_regen();
2687                 if(frametime)
2688                         player_anim();
2689
2690                 if (g_minstagib)
2691                         minstagib_ammocheck();
2692
2693                 ctf_setstatus();
2694                 nexball_setstatus();
2695
2696                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2697
2698                 //self.angles_y=self.v_angle_y + 90;   // temp
2699         } else if(gameover) {
2700                 if (intermission_running)
2701                         IntermissionThink ();   // otherwise a button could be missed between
2702                 return;
2703         } else if(self.classname == "observer") {
2704                 ObserverThink();
2705         } else if(self.classname == "spectator") {
2706                 SpectatorThink();
2707         }
2708
2709         if(!zoomstate_set)
2710                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2711
2712         float oldspectatee_status;
2713         oldspectatee_status = self.spectatee_status;
2714         if(self.classname == "spectator")
2715                 self.spectatee_status = num_for_edict(self.enemy);
2716         else if(self.classname == "observer")
2717                 self.spectatee_status = num_for_edict(self);
2718         else
2719                 self.spectatee_status = 0;
2720         if(self.spectatee_status != oldspectatee_status)
2721         {
2722                 ClientData_Touch(self);
2723                 if(g_race || g_cts)
2724                         race_InitSpectator();
2725         }
2726
2727         if(self.teamkill_soundtime)
2728         if(time > self.teamkill_soundtime)
2729         {
2730                 self.teamkill_soundtime = 0;
2731
2732                 entity oldpusher, oldself;
2733
2734                 oldself = self; self = self.teamkill_soundsource;
2735                 oldpusher = self.pusher; self.pusher = oldself;
2736
2737                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2738
2739                 self.pusher = oldpusher;
2740                 self = oldself;
2741         }
2742
2743         if(self.taunt_soundtime)
2744         if(time > self.taunt_soundtime)
2745         {
2746                 self.taunt_soundtime = 0;
2747                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2748         }
2749
2750         target_voicescript_next(self);
2751 }
2752
2753 float isInvisibleString(string s)
2754 {
2755         float i, n, c;
2756         s = strdecolorize(s);
2757         for((i = 0), (n = strlen(s)); i < n; ++i)
2758         {
2759                 c = str2chr(s, i);
2760                 switch(c)
2761                 {
2762                         case 0:
2763                         case 32:
2764                         case 160:
2765                                 break;
2766                         default:
2767                                 return FALSE;
2768                 }
2769         }
2770         return TRUE;
2771 }
2772
2773 /*
2774 =============
2775 PlayerPostThink
2776
2777 Called every frame for each client after the physics are run
2778 =============
2779 */
2780 .float idlekick_lasttimeleft;
2781 void PlayerPostThink (void)
2782 {
2783         // Savage: Check for nameless players
2784         if (isInvisibleString(self.netname)) {
2785                 self.netname = "Player";
2786                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2787         }
2788
2789         // send the clients accuracy stats to the client
2790         if(self.stat_count > 0)
2791         if(frametime)
2792         {
2793                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2794                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2795                 self.stat_count -= 1;
2796         }
2797
2798 #ifdef UID
2799         if(self.uid_kicktime)
2800         if(time > self.uid_kicktime)
2801         {
2802                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2803                 dropclient(self);
2804                 return;
2805         }
2806 #endif
2807
2808         if(sv_maxidle && frametime)
2809         {
2810                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2811                 float timeleft;
2812                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2813                 if(timeleft <= 0)
2814                 {
2815                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2816                         AnnounceTo(self, "terminated");
2817                         dropclient(self);
2818                         return;
2819                 }
2820                 else if(timeleft <= 10)
2821                 {
2822                         if(timeleft != self.idlekick_lasttimeleft)
2823                         {
2824                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2825                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2826                         }
2827                 }
2828                 else
2829                 {
2830                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2831                 }
2832                 self.idlekick_lasttimeleft = timeleft;
2833         }
2834
2835 #ifdef TETRIS
2836         if(self.impulse == 100)
2837                 ImpulseCommands();
2838         if (TetrisPostFrame())
2839                 return;
2840 #endif
2841
2842         CheatFrame();
2843
2844         if(self.classname == "player") {
2845                 CheckRules_Player();
2846                 UpdateChatBubble();
2847                 UpdateTeamBubble();
2848                 if (self.impulse)
2849                         ImpulseCommands();
2850                 if (intermission_running)
2851                         return;         // intermission or finale
2852                 GetPressedKeys();
2853         } else if (self.classname == "observer") {
2854                 //do nothing
2855         } else if (self.classname == "spectator") {
2856                 //do nothing
2857         }
2858
2859         /*
2860         float i;
2861         for(i = 0; i < 1000; ++i)
2862         {
2863                 vector end;
2864                 end = self.origin + '0 0 1024' + 512 * randomvec();
2865                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2866                 if(trace_fraction < 1)
2867                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2868                 {
2869                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2870                         break;
2871                 }
2872         }
2873         */
2874
2875         Arena_Warmup();
2876
2877         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2878
2879         if(self.waypointsprite_attachedforcarrier)
2880                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2881
2882         playerdemo_write();
2883
2884         /*
2885         if(g_race)
2886                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2887         */
2888 }