qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, autocvar_g_balance_campingrifle_magazinecapacity);
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(autocvar_spawn_debugview)
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > autocvar_g_spawn_furthest)
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(autocvar_spawn_debugview)
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(autocvar_spawn_debug)
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(autocvar_sv_servermodelsonly)
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602         MUTATOR_CALLHOOK(MakePlayerObserver);
 603
 604         Portal_ClearAll(self);
 605
 606         if(self.alivetime)
 607         {
 608                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 609                 self.alivetime = 0;
 610         }
 611
 612         if(self.flagcarried)
 613                 DropFlag(self.flagcarried, world, world);
 614
 615         if(self.ballcarried && g_nexball)
 616                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 617
 618         WaypointSprite_PlayerDead();
 619
 620         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 621                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 622
 623         if(self.killcount != -666) {
 624                 if(g_lms) {
 625                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 626                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 627                         else
 628                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 629                 } else
 630                         bprint ("^4", self.netname, "^4 is spectating now\n");
 631
 632                 if(self.just_joined == FALSE) {
 633                         LogTeamchange(self.playerid, -1, 4);
 634                 } else
 635                         self.just_joined = FALSE;
 636         }
 637
 638         PlayerScore_Clear(self); // clear scores when needed
 639
 640         accuracy_resend(self);
 641
 642         self.spectatortime = time;
 643
 644         self.classname = "observer";
 645         self.iscreature = FALSE;
 646         self.health = -666;
 647         self.takedamage = DAMAGE_NO;
 648         self.solid = SOLID_NOT;
 649         self.movetype = MOVETYPE_NOCLIP;
 650         self.flags = FL_CLIENT | FL_NOTARGET;
 651         self.armorvalue = 666;
 652         self.effects = 0;
 653         self.armorvalue = autocvar_g_balance_armor_start;
 654         self.pauserotarmor_finished = 0;
 655         self.pauserothealth_finished = 0;
 656         self.pauseregen_finished = 0;
 657         self.damageforcescale = 0;
 658         self.death_time = 0;
 659         self.dead_frame = 0;
 660         self.alpha = 0;
 661         self.scale = 0;
 662         self.fade_time = 0;
 663         self.pain_frame = 0;
 664         self.pain_finished = 0;
 665         self.strength_finished = 0;
 666         self.invincible_finished = 0;
 667         self.pushltime = 0;
 668         self.think = SUB_Null;
 669         self.nextthink = 0;
 670         self.hook_time = 0;
 671         self.runes = 0;
 672         self.deadflag = DEAD_NO;
 673         self.angles = spot.angles;
 674         self.angles_z = 0;
 675         self.fixangle = TRUE;
 676         self.crouch = FALSE;
 677
 678         self.view_ofs = PL_VIEW_OFS;
 679         setorigin (self, spot.origin);
 680         setsize (self, '0 0 0', '0 0 0');
 681         self.prevorigin = self.origin;
 682         self.items = 0;
 683         self.weapons = 0;
 684         self.model = "";
 685         FixPlayermodel();
 686         self.model = "";
 687         self.modelindex = 0;
 688         self.weapon = 0;
 689         self.weaponmodel = "";
 690         self.weaponentity = world;
 691         self.exteriorweaponentity = world;
 692         self.killcount = -666;
 693         self.velocity = '0 0 0';
 694         self.avelocity = '0 0 0';
 695         self.punchangle = '0 0 0';
 696         self.punchvector = '0 0 0';
 697         self.oldvelocity = self.velocity;
 698         self.fire_endtime = -1;
 699
 700         if(sv_loddistance1)
 701                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 702
 703         if(g_arena)
 704         {
 705                 if(self.version_mismatch)
 706                 {
 707                         Spawnqueue_Unmark(self);
 708                         Spawnqueue_Remove(self);
 709                 }
 710                 else
 711                 {
 712                         Spawnqueue_Insert(self);
 713                 }
 714         }
 715         else if(g_lms)
 716         {
 717                 // Only if the player cannot play at all
 718                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 719                         self.frags = FRAGS_SPECTATOR;
 720                 else
 721                         self.frags = FRAGS_LMS_LOSER;
 722         }
 723         else
 724                 self.frags = FRAGS_SPECTATOR;
 725 }
 726
 727 float RestrictSkin(float s)
 728 {
 729         if(!teams_matter)
 730                 return s;
 731         if(s == 6)
 732                 return 6;
 733         return mod(s, 3);
 734 }
 735
 736 void FixPlayermodel()
 737 {
 738         local string defaultmodel;
 739         local float defaultskin, chmdl, oldskin;
 740         local vector m1, m2;
 741
 742         defaultmodel = "";
 743
 744         if(autocvar_sv_defaultcharacter == 1) {
 745                 defaultskin = 0;
 746
 747                 if(teams_matter)
 748                 {
 749                         string s;
 750                         s = Team_ColorNameLowerCase(self.team);
 751                         if(s != "neutral")
 752                         {
 753                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 754                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 755                         }
 756                 }
 757
 758                 if(defaultmodel == "")
 759                 {
 760                         defaultmodel = autocvar_sv_defaultplayermodel;
 761                         defaultskin = autocvar_sv_defaultplayerskin;
 762                 }
 763         }
 764
 765         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 766         {
 767                 if(self.model != "")
 768                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 769                 self.model = ""; // force the != checks to return true
 770         }
 771
 772         if(defaultmodel != "")
 773         {
 774                 if (defaultmodel != self.model)
 775                 {
 776                         m1 = self.mins;
 777                         m2 = self.maxs;
 778                         setmodel_lod (self, defaultmodel);
 779                         setsize (self, m1, m2);
 780                         chmdl = TRUE;
 781                 }
 782
 783                 oldskin = self.skinindex;
 784                 self.skinindex = defaultskin;
 785         } else {
 786                 if (self.playermodel != self.model || self.playermodel == "")
 787                 {
 788                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 789                         m1 = self.mins;
 790                         m2 = self.maxs;
 791                         setmodel_lod (self, self.playermodel);
 792                         setsize (self, m1, m2);
 793                         chmdl = TRUE;
 794                 }
 795
 796                 oldskin = self.skinindex;
 797                 self.skinindex = RestrictSkin(stof(self.playerskin));
 798         }
 799
 800         if(chmdl || oldskin != self.skinindex)
 801                 self.species = player_getspecies(); // model or skin has changed
 802
 803         if(!teams_matter)
 804                 if(strlen(autocvar_sv_defaultplayercolors))
 805                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 806                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 807 }
 808
 809 void PlayerTouchExplode(entity p1, entity p2)
 810 {
 811         vector org;
 812         org = (p1.origin + p2.origin) * 0.5;
 813         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 814
 815         te_explosion(org);
 816
 817         entity e;
 818         e = spawn();
 819         setorigin(e, org);
 820         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 821         remove(e);
 822 }
 823
 824 /*
 825 =============
 826 PutClientInServer
 827
 828 Called when a client spawns in the server
 829 =============
 830 */
 831 //void() ctf_playerchanged;
 832 void PutClientInServer (void)
 833 {
 834         if(clienttype(self) == CLIENTTYPE_BOT)
 835         {
 836                 self.classname = "player";
 837         }
 838         else if(clienttype(self) == CLIENTTYPE_REAL)
 839         {
 840                 msg_entity = self;
 841                 WriteByte(MSG_ONE, SVC_SETVIEW);
 842                 WriteEntity(MSG_ONE, self);
 843         }
 844
 845         // player is dead and becomes observer
 846         // FIXME fix LMS scoring for new system
 847         if(g_lms)
 848         {
 849                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 850                         self.classname = "observer";
 851         }
 852
 853         if(g_arena || (g_ca && !allowed_to_spawn))
 854         if(!self.spawned)
 855                 self.classname = "observer";
 856
 857         if(gameover)
 858                 self.classname = "observer";
 859
 860         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 861                 entity spot, oldself;
 862                 float j;
 863
 864                 accuracy_resend(self);
 865
 866                 if(self.team < 0)
 867                         JoinBestTeam(self, FALSE, TRUE);
 868
 869                 race_PreSpawn();
 870
 871                 spot = SelectSpawnPoint (FALSE);
 872                 if(!spot)
 873                 {
 874                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 875                         return; // spawn failed
 876                 }
 877
 878                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 879
 880                 self.classname = "player";
 881                 self.wasplayer = TRUE;
 882                 self.iscreature = TRUE;
 883                 self.movetype = MOVETYPE_WALK;
 884                 self.solid = SOLID_SLIDEBOX;
 885                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 886                 if(autocvar_g_playerclip_collisions)
 887                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 888                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 889                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 890                 self.frags = FRAGS_PLAYER;
 891                 if(independent_players)
 892                         MAKE_INDEPENDENT_PLAYER(self);
 893                 self.flags = FL_CLIENT;
 894                 self.takedamage = DAMAGE_AIM;
 895                 if(g_minstagib)
 896                         self.effects = EF_FULLBRIGHT;
 897                 else
 898                         self.effects = 0;
 899                 self.air_finished = time + 12;
 900                 self.dmg = 2;
 901                 if(autocvar_g_balance_nex_charge)
 902                 {
 903                         if(autocvar_g_balance_nex_secondary_chargepool)
 904                                 self.nex_chargepool_ammo = 1;
 905                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 906                 }
 907
 908                 if(inWarmupStage)
 909                 {
 910                         self.ammo_shells = warmup_start_ammo_shells;
 911                         self.ammo_nails = warmup_start_ammo_nails;
 912                         self.ammo_rockets = warmup_start_ammo_rockets;
 913                         self.ammo_cells = warmup_start_ammo_cells;
 914                         self.ammo_fuel = warmup_start_ammo_fuel;
 915                         self.health = warmup_start_health;
 916                         self.armorvalue = warmup_start_armorvalue;
 917                         self.weapons = warmup_start_weapons;
 918                 }
 919                 else
 920                 {
 921                         self.ammo_shells = start_ammo_shells;
 922                         self.ammo_nails = start_ammo_nails;
 923                         self.ammo_rockets = start_ammo_rockets;
 924                         self.ammo_cells = start_ammo_cells;
 925                         self.ammo_fuel = start_ammo_fuel;
 926                         self.health = start_health;
 927                         self.armorvalue = start_armorvalue;
 928                         self.weapons = start_weapons;
 929                 }
 930
 931                 if(g_weaponarena_random)
 932                 {
 933                         if(g_weaponarena_random_with_laser)
 934                                 self.weapons &~= WEPBIT_LASER;
 935                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 936                         if(g_weaponarena_random_with_laser)
 937                                 self.weapons |= WEPBIT_LASER;
 938                 }
 939
 940                 self.items = start_items;
 941                 self.jump_interval = time;
 942
 943                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 944                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 945                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 946                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 947                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 948                 //extend the pause of rotting if client was reset at the beginning of the countdown
 949                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 950                         self.spawnshieldtime += game_starttime - time;
 951                         self.pauserotarmor_finished += game_starttime - time;
 952                         self.pauserothealth_finished += game_starttime - time;
 953                         self.pauseregen_finished += game_starttime - time;
 954                 }
 955                 self.damageforcescale = 2;
 956                 self.death_time = 0;
 957                 self.dead_frame = 0;
 958                 self.alpha = 0;
 959                 self.scale = 0;
 960                 self.fade_time = 0;
 961                 self.pain_frame = 0;
 962                 self.pain_finished = 0;
 963                 self.strength_finished = 0;
 964                 self.invincible_finished = 0;
 965                 self.pushltime = 0;
 966                 // players have no think function
 967                 self.think = SUB_Null;
 968                 self.nextthink = 0;
 969                 self.hook_time = 0;
 970                 self.dmg_team = 0;
 971                 self.ballistics_density = autocvar_g_ballistics_density_player;
 972
 973                 self.metertime = 0;
 974
 975                 self.runes = 0;
 976
 977                 self.deadflag = DEAD_NO;
 978
 979                 self.angles = spot.angles;
 980
 981                 self.angles_z = 0; // never spawn tilted even if the spot says to
 982                 self.fixangle = TRUE; // turn this way immediately
 983                 self.velocity = '0 0 0';
 984                 self.avelocity = '0 0 0';
 985                 self.punchangle = '0 0 0';
 986                 self.punchvector = '0 0 0';
 987                 self.oldvelocity = self.velocity;
 988                 self.fire_endtime = -1;
 989
 990                 msg_entity = self;
 991                 WRITESPECTATABLE_MSG_ONE({
 992                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 993                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 994                 });
 995
 996                 if(sv_loddistance1)
 997                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 998
 999                 self.model = "";
1000                 FixPlayermodel();
1001
1002                 self.crouch = FALSE;
1003                 self.view_ofs = PL_VIEW_OFS;
1004                 setsize (self, PL_MIN, PL_MAX);
1005                 self.spawnorigin = spot.origin;
1006                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1007                 // don't reset back to last position, even if new position is stuck in solid
1008                 self.oldorigin = self.origin;
1009                 self.prevorigin = self.origin;
1010                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1011
1012                 if(g_arena)
1013                 {
1014                         Spawnqueue_Remove(self);
1015                         Spawnqueue_Mark(self);
1016                 }
1017
1018                 else if(g_ca)
1019                         self.caplayer = 1;
1020
1021                 self.event_damage = PlayerDamage;
1022
1023                 self.bot_attack = TRUE;
1024
1025                 self.statdraintime = time + 5;
1026                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1027
1028                 if(self.killcount == -666) {
1029                         PlayerScore_Clear(self);
1030                         self.killcount = 0;
1031                 }
1032
1033                 self.cnt = WEP_LASER;
1034
1035                 CL_SpawnWeaponentity();
1036                 self.alpha = default_player_alpha;
1037                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1038                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1039
1040                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1041                 self.lms_traveled_distance = 0;
1042                 self.speedrunning = FALSE;
1043
1044                 race_PostSpawn(spot);
1045
1046                 if(autocvar_spawn_debug)
1047                 {
1048                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1049                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1050                 }
1051
1052                 //stuffcmd(self, "chase_active 0");
1053                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1054
1055                 if (autocvar_g_spawnsound)
1056                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1057
1058                 if(g_assault) {
1059                         if(self.team == assault_attacker_team)
1060                                 centerprint(self, "You are attacking!");
1061                         else
1062                                 centerprint(self, "You are defending!");
1063                 }
1064
1065                 target_voicescript_clear(self);
1066
1067                 // reset fields the weapons may use
1068                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1069                         weapon_action(j, WR_RESETPLAYER);
1070
1071                 oldself = self;
1072                 self = spot;
1073                         activator = oldself;
1074                                 SUB_UseTargets();
1075                         activator = world;
1076                 self = oldself;
1077
1078                 MUTATOR_CALLHOOK(PlayerSpawn);
1079
1080                 self.switchweapon = w_getbestweapon(self);
1081                 self.cnt = self.switchweapon;
1082                 self.weapon = 0;
1083
1084                 if(!self.alivetime)
1085                         self.alivetime = time;
1086         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1087                 PutObserverInServer ();
1088         }
1089
1090         //if(g_ctf)
1091         //      ctf_playerchanged();
1092 }
1093
1094 .float ebouncefactor, ebouncestop; // electro's values
1095 // TODO do we need all these fields, or should we stop autodetecting runtime
1096 // changes and just have a console command to update this?
1097 float ClientInit_SendEntity(entity to, float sf)
1098 {
1099         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1100         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1110         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1111         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1112         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1113         if(sv_foginterval && world.fog != "")
1114                 WriteString(MSG_ENTITY, world.fog);
1115         else
1116                 WriteString(MSG_ENTITY, "");
1117         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1118         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1119         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1120         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1121         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1122         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1123         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1124         WriteByte(MSG_ENTITY, autocvar_g_balance_campingrifle_secondary); // client has to know if it should zoom or not
1125         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1126         return TRUE;
1127 }
1128
1129 void ClientInit_CheckUpdate()
1130 {
1131         self.nextthink = time;
1132         if(self.count != autocvar_g_balance_armor_blockpercent)
1133         {
1134                 self.count = autocvar_g_balance_armor_blockpercent;
1135                 self.SendFlags |= 1;
1136         }
1137         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1138         {
1139                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1140                 self.SendFlags |= 1;
1141         }
1142         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1143         {
1144                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1145                 self.SendFlags |= 1;
1146         }
1147         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1148         {
1149                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1150                 self.SendFlags |= 1;
1151         }
1152         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1153         {
1154                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1155                 self.SendFlags |= 1;
1156         }
1157         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1158         {
1159                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1160                 self.SendFlags |= 1;
1161         }
1162 }
1163
1164 void ClientInit_Spawn()
1165 {
1166         entity o;
1167         entity e;
1168         e = spawn();
1169         e.classname = "clientinit";
1170         e.think = ClientInit_CheckUpdate;
1171         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1172
1173         o = self;
1174         self = e;
1175         ClientInit_CheckUpdate();
1176         self = o;
1177 }
1178
1179 /*
1180 =============
1181 SetNewParms
1182 =============
1183 */
1184 void SetNewParms (void)
1185 {
1186         // initialize parms for a new player
1187         parm1 = -(86400 * 366);
1188 }
1189
1190 /*
1191 =============
1192 SetChangeParms
1193 =============
1194 */
1195 void SetChangeParms (void)
1196 {
1197         // save parms for level change
1198         parm1 = self.parm_idlesince - time;
1199 }
1200
1201 /*
1202 =============
1203 DecodeLevelParms
1204 =============
1205 */
1206 void DecodeLevelParms (void)
1207 {
1208         // load parms
1209         self.parm_idlesince = parm1;
1210         if(self.parm_idlesince == -(86400 * 366))
1211                 self.parm_idlesince = time;
1212
1213         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1214         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1215 }
1216
1217 /*
1218 =============
1219 ClientKill
1220
1221 Called when a client types 'kill' in the console
1222 =============
1223 */
1224
1225 void ClientKill_Now_TeamChange()
1226 {
1227         if(self.killindicator_teamchange == -1)
1228         {
1229                 self.team = -1;
1230                 JoinBestTeam( self, FALSE, FALSE );
1231         }
1232         else
1233                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1234 }
1235
1236 void ClientKill_Now()
1237 {
1238         if(self.killindicator_teamchange)
1239                 ClientKill_Now_TeamChange();
1240
1241         // in any case:
1242         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1243
1244         if(self.killindicator)
1245         {
1246                 dprint("Cleaned up after a leaked kill indicator.\n");
1247                 remove(self.killindicator);
1248                 self.killindicator = world;
1249         }
1250 }
1251 void KillIndicator_Think()
1252 {
1253         if (!self.owner.modelindex)
1254         {
1255                 self.owner.killindicator = world;
1256                 remove(self);
1257                 return;
1258         }
1259
1260         if(self.cnt <= 0)
1261         {
1262                 self = self.owner;
1263                 ClientKill_Now(); // no oldself needed
1264                 return;
1265         }
1266     else if(g_cts)
1267     {
1268         self.nextthink = time + 1;
1269         self.cnt -= 1;
1270     }
1271         else
1272         {
1273                 if(self.cnt <= 10)
1274                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1275                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1276                 {
1277                         if(self.cnt <= 10)
1278                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1279                         if(self.owner.killindicator_teamchange)
1280                         {
1281                                 if(self.owner.killindicator_teamchange == -1)
1282                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1283                                 else
1284                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1285                         }
1286                         else
1287                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1288                 }
1289                 self.nextthink = time + 1;
1290                 self.cnt -= 1;
1291         }
1292 }
1293
1294 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1295 {
1296         float killtime;
1297         entity e;
1298         killtime = autocvar_g_balance_kill_delay;
1299
1300         if(g_race_qualifying)
1301                 killtime = 0;
1302
1303         self.killindicator_teamchange = targetteam;
1304
1305     if(g_cts) // allow an instant kill in CTS
1306     {
1307         if(self.killcnt < 5) // 5 kills in 5 seconds allowed
1308         {
1309             self.killcnt += 1;
1310             ClientKill_Now();
1311         }
1312         return;
1313     }
1314
1315     else if(!self.killindicator)
1316         {
1317                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1318                 {
1319                         ClientKill_Now();
1320                 }
1321                 else
1322                 {
1323                         self.killindicator = spawn();
1324                         self.killindicator.owner = self;
1325                         self.killindicator.scale = 0.5;
1326                         setattachment(self.killindicator, self, "");
1327                         setorigin(self.killindicator, '0 0 52');
1328                         self.killindicator.think = KillIndicator_Think;
1329                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1330                         self.killindicator.cnt = ceil(killtime);
1331                         self.killindicator.count = bound(0, ceil(killtime), 10);
1332                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1333
1334                         for(e = world; (e = find(e, classname, "body")) != world; )
1335                         {
1336                                 if(e.enemy != self)
1337                                         continue;
1338                                 e.killindicator = spawn();
1339                                 e.killindicator.owner = e;
1340                                 e.killindicator.scale = 0.5;
1341                                 setattachment(e.killindicator, e, "");
1342                                 setorigin(e.killindicator, '0 0 52');
1343                                 e.killindicator.think = KillIndicator_Think;
1344                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1345                                 e.killindicator.cnt = ceil(killtime);
1346                         }
1347                         self.lip = 0;
1348                 }
1349         }
1350         if(self.killindicator)
1351         {
1352                 if(targetteam)
1353                         self.killindicator.colormod = TeamColor(targetteam);
1354                 else
1355                         self.killindicator.colormod = '0 0 0';
1356         }
1357 }
1358
1359 void ClientKill (void)
1360 {
1361         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1362         {
1363                 // do nothing
1364         }
1365     else if(g_freezetag && self.freezetag_frozen == 1)
1366     {
1367         // do nothing
1368     }
1369         else
1370                 ClientKill_TeamChange(0);
1371 }
1372
1373 void CTS_ClientKill (entity e) // silent version of ClientKill
1374 {
1375     e.killindicator = spawn();
1376     e.killindicator.owner = e;
1377     e.killindicator.think = KillIndicator_Think;
1378     e.killindicator.nextthink = time + (e.lip) * 0.05;
1379     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1380     e.lip = 0;
1381 }
1382
1383 void DoTeamChange(float destteam)
1384 {
1385         float t, c0;
1386         if(!teams_matter)
1387         {
1388                 if(destteam >= 0)
1389                         SetPlayerColors(self, destteam);
1390                 return;
1391         }
1392         if(self.classname == "player")
1393         if(destteam == -1)
1394         {
1395                 CheckAllowedTeams(self);
1396                 t = FindSmallestTeam(self, TRUE);
1397                 switch(self.team)
1398                 {
1399                         case COLOR_TEAM1: c0 = c1; break;
1400                         case COLOR_TEAM2: c0 = c2; break;
1401                         case COLOR_TEAM3: c0 = c3; break;
1402                         case COLOR_TEAM4: c0 = c4; break;
1403                         default:          c0 = 999;
1404                 }
1405                 switch(t)
1406                 {
1407                         case 1:
1408                                 if(c0 > c1)
1409                                         destteam = COLOR_TEAM1;
1410                                 break;
1411                         case 2:
1412                                 if(c0 > c2)
1413                                         destteam = COLOR_TEAM2;
1414                                 break;
1415                         case 3:
1416                                 if(c0 > c3)
1417                                         destteam = COLOR_TEAM3;
1418                                 break;
1419                         case 4:
1420                                 if(c0 > c4)
1421                                         destteam = COLOR_TEAM4;
1422                                 break;
1423                 }
1424                 if(destteam == -1)
1425                         return;
1426         }
1427         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1428                 return;
1429         ClientKill_TeamChange(destteam);
1430 }
1431
1432 void FixClientCvars(entity e)
1433 {
1434         // send prediction settings to the client
1435         stuffcmd(e, "\nin_bindmap 0 0\n");
1436         if(g_race || g_cts)
1437                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1438         if(autocvar_g_antilag == 3) // client side hitscan
1439                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1440         if(sv_gentle)
1441                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1442         /*
1443          * we no longer need to stuff this. Remove this comment block if you feel
1444          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1445         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1446         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1447         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1448         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1449         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1450         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1451         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1452         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1453         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1454         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1455         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1456         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1457         stuffcmd(e, "cl_movement_edgefriction 1\n");
1458          */
1459 }
1460
1461 float PlayerInIDList(entity p, string idlist)
1462 {
1463         float n, i;
1464         string s;
1465
1466         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1467         if not(p.crypto_idfp)
1468                 return 0;
1469
1470         // this function allows abbreviated player IDs too!
1471         n = tokenize_console(idlist);
1472         for(i = 0; i < n; ++i)
1473         {
1474                 s = argv(i);
1475                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1476                         return 1;
1477         }
1478
1479         return 0;
1480 }
1481
1482 /*
1483 =============
1484 ClientConnect
1485
1486 Called when a client connects to the server
1487 =============
1488 */
1489 //void ctf_clientconnect();
1490 string ColoredTeamName(float t);
1491 void DecodeLevelParms (void);
1492 //void dom_player_join_team(entity pl);
1493 void ClientConnect (void)
1494 {
1495         float t;
1496
1497         if(self.flags & FL_CLIENT)
1498         {
1499                 print("Warning: ClientConnect, but already connected!\n");
1500                 return;
1501         }
1502
1503         if(Ban_MaybeEnforceBan(self))
1504                 return;
1505
1506         DecodeLevelParms();
1507
1508 #ifdef WATERMARK
1509         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1510 #endif
1511
1512         self.classname = "player_joining";
1513
1514         self.flags = FL_CLIENT;
1515         self.version_nagtime = time + 10 + random() * 10;
1516
1517         if(player_count<0)
1518         {
1519                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1520                 player_count = 0;
1521         }
1522
1523         PlayerScore_Attach(self);
1524         ClientData_Attach();
1525         accuracy_init(self);
1526
1527         bot_clientconnect();
1528
1529         playerdemo_init();
1530
1531         anticheat_init();
1532
1533         race_PreSpawnObserver();
1534
1535         //if(g_domination)
1536         //      dom_player_join_team(self);
1537
1538         // identify the right forced team
1539         if(autocvar_g_campaign)
1540         {
1541                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1542                 {
1543                         switch(autocvar_g_campaign_forceteam)
1544                         {
1545                                 case 1: self.team_forced = COLOR_TEAM1; break;
1546                                 case 2: self.team_forced = COLOR_TEAM2; break;
1547                                 case 3: self.team_forced = COLOR_TEAM3; break;
1548                                 case 4: self.team_forced = COLOR_TEAM4; break;
1549                                 default: self.team_forced = 0;
1550                         }
1551                 }
1552         }
1553         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1554                 self.team_forced = COLOR_TEAM1;
1555         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1556                 self.team_forced = COLOR_TEAM2;
1557         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1558                 self.team_forced = COLOR_TEAM3;
1559         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1560                 self.team_forced = COLOR_TEAM4;
1561         else if(autocvar_g_forced_team_otherwise == "red")
1562                 self.team_forced = COLOR_TEAM1;
1563         else if(autocvar_g_forced_team_otherwise == "blue")
1564                 self.team_forced = COLOR_TEAM2;
1565         else if(autocvar_g_forced_team_otherwise == "yellow")
1566                 self.team_forced = COLOR_TEAM3;
1567         else if(autocvar_g_forced_team_otherwise == "pink")
1568                 self.team_forced = COLOR_TEAM4;
1569         else if(autocvar_g_forced_team_otherwise == "spectate")
1570                 self.team_forced = -1;
1571         else if(autocvar_g_forced_team_otherwise == "spectator")
1572                 self.team_forced = -1;
1573         else
1574                 self.team_forced = 0;
1575
1576         if(!teams_matter)
1577                 if(self.team_forced > 0)
1578                         self.team_forced = 0;
1579
1580         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1581
1582         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1583                 self.classname = "observer";
1584         } else {
1585                 if(teams_matter)
1586                 {
1587                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1588                         {
1589                                 self.classname = "player";
1590                                 campaign_bots_may_start = 1;
1591                         }
1592                         else
1593                         {
1594                                 self.classname = "observer"; // do it anyway
1595                         }
1596                 }
1597                 else
1598                 {
1599                         self.classname = "player";
1600                         campaign_bots_may_start = 1;
1601                 }
1602         }
1603
1604         self.playerid = (playerid_last = playerid_last + 1);
1605
1606         if(autocvar_sv_eventlog)
1607                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1608
1609         LogTeamchange(self.playerid, self.team, 1);
1610
1611         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1612
1613         self.netname_previous = strzone(self.netname);
1614
1615         bprint("^4", self.netname, "^4 connected");
1616
1617         if(self.classname != "observer" && (g_domination || g_ctf))
1618                 bprint(" and joined the ", ColoredTeamName(self.team));
1619
1620         bprint("\n");
1621
1622         self.welcomemessage_time = 0;
1623
1624         stuffcmd(self, strcat(clientstuff, "\n"));
1625         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1626         stuffcmd(self, "cl_particles_reloadeffects\n");
1627
1628         FixClientCvars(self);
1629
1630         // spawnfunc_waypoint sprites
1631         WaypointSprite_InitClient(self);
1632
1633         // Wazat's grappling hook
1634         SetGrappleHookBindings();
1635
1636         // get autoswitch state from player when he toggles it
1637         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1638
1639         // get version info from player
1640         stuffcmd(self, "cmd clientversion $gameversion\n");
1641
1642         // get other cvars from player
1643         GetCvars(0);
1644
1645         // notify about available teams
1646         if(teams_matter)
1647         {
1648                 CheckAllowedTeams(self);
1649                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1650                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1651         }
1652         else
1653                 stuffcmd(self, "set _teams_available 0\n");
1654
1655         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1656
1657         if(g_arena || g_ca)
1658         {
1659                 self.classname = "observer";
1660                 if(g_arena)
1661                         Spawnqueue_Insert(self);
1662         }
1663         /*else if(g_ctf)
1664         {
1665                 ctf_clientconnect();
1666         }*/
1667
1668         if(teams_matter || radar_showennemies)
1669                 attach_entcs();
1670
1671         bot_relinkplayerlist();
1672
1673         self.spectatortime = time;
1674         if(blockSpectators)
1675         {
1676                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1677         }
1678
1679         self.jointime = time;
1680         self.allowedTimeouts = autocvar_sv_timeout_number;
1681
1682         if(clienttype(self) == CLIENTTYPE_REAL)
1683         {
1684                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1685                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1686         }
1687
1688         if(g_lms)
1689         {
1690                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1691                 {
1692                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1693                         self.frags = FRAGS_SPECTATOR;
1694                 }
1695         }
1696
1697         if(!sv_foginterval && world.fog != "")
1698                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1699
1700         SoundEntity_Attach(self);
1701
1702         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1703         {
1704                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1705                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1706         }
1707         else
1708                 self.hitplotfh = -1;
1709
1710         if(g_race || g_cts) {
1711                 string rr;
1712                 if(g_cts)
1713                         rr = CTS_RECORD;
1714                 else
1715                         rr = RACE_RECORD;
1716                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1717
1718                 msg_entity = self;
1719                 race_send_recordtime(MSG_ONE);
1720                 race_send_speedaward(MSG_ONE);
1721
1722                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1723                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1724                 race_send_speedaward_alltimebest(MSG_ONE);
1725
1726                 float i;
1727                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1728                         race_SendRankings(i, 0, 0, MSG_ONE);
1729                 }
1730         }
1731         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1732                 send_CSQC_teamnagger();
1733
1734         send_CSQC_cr_maxbullets(self);
1735
1736         CheatInitClient();
1737
1738         PlayerStats_AddPlayer(self);
1739 }
1740
1741 /*
1742 =============
1743 ClientDisconnect
1744
1745 Called when a client disconnects from the server
1746 =============
1747 */
1748 .entity chatbubbleentity;
1749 .entity teambubbleentity;
1750 void ReadyCount();
1751 void ClientDisconnect (void)
1752 {
1753         if not(self.flags & FL_CLIENT)
1754         {
1755                 print("Warning: ClientDisconnect without ClientConnect\n");
1756                 return;
1757         }
1758
1759         PlayerStats_AddGlobalInfo(self);
1760
1761         CheatShutdownClient();
1762
1763         if(self.hitplotfh >= 0)
1764         {
1765                 fclose(self.hitplotfh);
1766                 self.hitplotfh = -1;
1767         }
1768
1769         anticheat_report();
1770         anticheat_shutdown();
1771
1772         playerdemo_shutdown();
1773
1774         bot_clientdisconnect();
1775
1776         if(self.entcs)
1777                 detach_entcs();
1778
1779         if(autocvar_sv_eventlog)
1780                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1781         bprint ("^4",self.netname);
1782         bprint ("^4 disconnected\n");
1783
1784         SoundEntity_Detach(self);
1785
1786         DropAllRunes(self);
1787         MUTATOR_CALLHOOK(ClientDisconnect);
1788
1789         Portal_ClearAll(self);
1790
1791         if(self.flagcarried)
1792                 DropFlag(self.flagcarried, world, world);
1793         if(self.ballcarried && g_nexball)
1794                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1795
1796         // Here, everything has been done that requires this player to be a client.
1797
1798         self.flags &~= FL_CLIENT;
1799
1800         if (self.chatbubbleentity)
1801                 remove (self.chatbubbleentity);
1802
1803         if (self.teambubbleentity)
1804                 remove (self.teambubbleentity);
1805
1806         if (self.killindicator)
1807                 remove (self.killindicator);
1808
1809         WaypointSprite_PlayerGone();
1810
1811         bot_relinkplayerlist();
1812
1813         if(g_arena)
1814         {
1815                 Spawnqueue_Unmark(self);
1816                 Spawnqueue_Remove(self);
1817         }
1818
1819         accuracy_free(self);
1820         ClientData_Detach();
1821         PlayerScore_Detach(self);
1822
1823         if(self.netname_previous)
1824                 strunzone(self.netname_previous);
1825         if(self.clientstatus)
1826                 strunzone(self.clientstatus);
1827         if(self.weaponorder_byimpulse)
1828                 strunzone(self.weaponorder_byimpulse);
1829
1830         ClearPlayerSounds();
1831
1832         if(self.personal)
1833                 remove(self.personal);
1834
1835         self.playerid = 0;
1836         ReadyCount();
1837
1838         // free cvars
1839         GetCvars(-1);
1840 }
1841
1842 .float BUTTON_CHAT;
1843 void ChatBubbleThink()
1844 {
1845         self.nextthink = time;
1846         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1847         {
1848                 if(self.owner) // but why can that ever be world?
1849                         self.owner.chatbubbleentity = world;
1850                 remove(self);
1851                 return;
1852         }
1853         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1854 #ifdef TETRIS
1855                 || self.owner.tetris_on
1856 #endif
1857         )
1858                 self.model = self.mdl;
1859         else
1860                 self.model = "";
1861 };
1862
1863 void UpdateChatBubble()
1864 {
1865         if (!self.modelindex)
1866                 return;
1867         // spawn a chatbubble entity if needed
1868         if (!self.chatbubbleentity)
1869         {
1870                 self.chatbubbleentity = spawn();
1871                 self.chatbubbleentity.owner = self;
1872                 self.chatbubbleentity.exteriormodeltoclient = self;
1873                 self.chatbubbleentity.think = ChatBubbleThink;
1874                 self.chatbubbleentity.nextthink = time;
1875                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1876                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1877                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1878                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1879                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1880                 self.chatbubbleentity.model = "";
1881                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1882         }
1883 }
1884
1885
1886 void TeamBubbleThink()
1887 {
1888         self.nextthink = time;
1889         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1890         {
1891                 if(self.owner) // but why can that ever be world?
1892                         self.owner.teambubbleentity = world;
1893                 remove(self);
1894                 return;
1895         }
1896 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1897         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1898                 self.model = "";
1899         else
1900                 self.model = self.mdl;
1901
1902 };
1903
1904 float TeamBubble_customizeentityforclient()
1905 {
1906         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1907 }
1908
1909 void UpdateTeamBubble()
1910 {
1911         if (!self.modelindex || !teams_matter)
1912                 return;
1913         // spawn a teambubble entity if needed
1914         if (!self.teambubbleentity && teams_matter)
1915         {
1916                 self.teambubbleentity = spawn();
1917                 self.teambubbleentity.owner = self;
1918                 self.teambubbleentity.exteriormodeltoclient = self;
1919                 self.teambubbleentity.think = TeamBubbleThink;
1920                 self.teambubbleentity.nextthink = time;
1921                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1922 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1923                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1924                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1925                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1926                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1927                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1928                 self.teambubbleentity.effects = EF_LOWPRECISION;
1929         }
1930 }
1931
1932 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1933 // added to the model skins
1934 /*void UpdateColorModHack()
1935 {
1936         local float c;
1937         c = self.clientcolors & 15;
1938         // LordHavoc: only bothering to support white, green, red, yellow, blue
1939              if (!teams_matter) self.colormod = '0 0 0';
1940         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1941         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1942         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1943         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1944         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1945         else self.colormod = '1 1 1';
1946 };*/
1947
1948 .float oldcolormap;
1949 void respawn(void)
1950 {
1951         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1952         {
1953                 self.solid = SOLID_NOT;
1954                 self.takedamage = DAMAGE_NO;
1955                 self.movetype = MOVETYPE_FLY;
1956                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1957                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1958                 self.effects |= EF_ADDITIVE;
1959                 self.oldcolormap = self.colormap;
1960                 self.colormap = 512;
1961                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1962                 if(autocvar_g_respawn_ghosts_maxtime)
1963                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1964         }
1965
1966         CopyBody(1);
1967         self.effects |= EF_NODRAW; // prevent another CopyBody
1968         if(self.oldcolormap)
1969         {
1970                 self.colormap = self.oldcolormap;
1971                 self.oldcolormap = 0;
1972         }
1973         PutClientInServer();
1974 }
1975
1976 void play_countdown(float finished, string samp)
1977 {
1978         if(clienttype(self) == CLIENTTYPE_REAL)
1979                 if(floor(finished - time - frametime) != floor(finished - time))
1980                         if(finished - time < 6)
1981                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1982 }
1983
1984 /**
1985  * When sv_timeout is used this function returs strings like
1986  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1987  * Called by centerprint functions
1988  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1989  */
1990 string getTimeoutText(float addOneSecond) {
1991         if (!autocvar_sv_timeout || !timeoutStatus)
1992                 return "";
1993
1994         local string retStr;
1995         if (timeoutStatus == 1) {
1996                 if (addOneSecond == 1) {
1997                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1998                 }
1999                 else {
2000                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2001                 }
2002                 return retStr;
2003         }
2004         else if (timeoutStatus == 2) {
2005                 if (addOneSecond) {
2006                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2007                         //don't show messages like "Timeout ends in 0 seconds"...
2008                         if ((remainingTimeoutTime + 1) > 0)
2009                                 return retStr;
2010                         else
2011                                 return "";
2012                 }
2013                 else {
2014                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2015                         //don't show messages like "Timeout ends in 0 seconds"...
2016                         if (remainingTimeoutTime > 0)
2017                                 return retStr;
2018                         else
2019                                 return "";
2020                 }
2021         }
2022         else return "";
2023 }
2024
2025 void player_powerups (void)
2026 {
2027         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2028         olditems = self.items;
2029
2030         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2031         {
2032                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2033                 self.modelflags |= MF_ROCKET;
2034         }
2035         else
2036         {
2037                 SoundEntity_StopSound(self, CHAN_PLAYER);
2038                 self.modelflags &~= MF_ROCKET;
2039         }
2040
2041         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2042
2043         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2044                 return;
2045
2046         Fire_ApplyDamage(self);
2047         Fire_ApplyEffect(self);
2048
2049         if (g_minstagib)
2050         {
2051                 self.effects |= EF_FULLBRIGHT;
2052
2053                 if (self.items & IT_STRENGTH)
2054                 {
2055                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2056                         if (time > self.strength_finished)
2057                         {
2058                                 self.alpha = default_player_alpha;
2059                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2060                                 self.items &~= IT_STRENGTH;
2061                                 sprint(self, "^3Invisibility has worn off\n");
2062                         }
2063                 }
2064                 else
2065                 {
2066                         if (time < self.strength_finished)
2067                         {
2068                                 self.alpha = g_minstagib_invis_alpha;
2069                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2070                                 self.items |= IT_STRENGTH;
2071                                 sprint(self, "^3You are invisible\n");
2072                         }
2073                 }
2074
2075                 if (self.items & IT_INVINCIBLE)
2076                 {
2077                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2078                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2079                         {
2080                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2081                                 sprint(self, "^3Speed has worn off\n");
2082                         }
2083                 }
2084                 else
2085                 {
2086                         if (time < self.invincible_finished)
2087                         {
2088                                 self.items = self.items | IT_INVINCIBLE;
2089                                 sprint(self, "^3You are on speed\n");
2090                         }
2091                 }
2092         }
2093         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2094         {
2095                 if (self.items & IT_STRENGTH)
2096                 {
2097                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2098                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2099                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2100                         {
2101                                 self.items = self.items - (self.items & IT_STRENGTH);
2102                                 sprint(self, "^3Strength has worn off\n");
2103                         }
2104                 }
2105                 else
2106                 {
2107                         if (time < self.strength_finished)
2108                         {
2109                                 self.items = self.items | IT_STRENGTH;
2110                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2111                         }
2112                 }
2113                 if (self.items & IT_INVINCIBLE)
2114                 {
2115                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2116                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2117                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2118                         {
2119                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2120                                 sprint(self, "^3Shield has worn off\n");
2121                         }
2122                 }
2123                 else
2124                 {
2125                         if (time < self.invincible_finished)
2126                         {
2127                                 self.items = self.items | IT_INVINCIBLE;
2128                                 sprint(self, "^3Shield surrounds you\n");
2129                         }
2130                 }
2131
2132                 if(autocvar_g_nodepthtestplayers)
2133                         self.effects = self.effects | EF_NODEPTHTEST;
2134
2135                 if(autocvar_g_fullbrightplayers)
2136                         self.effects = self.effects | EF_FULLBRIGHT;
2137
2138                 // midair gamemode: damage only while in the air
2139                 // if in midair mode, being on ground grants temporary invulnerability
2140                 // (this is so that multishot weapon don't clear the ground flag on the
2141                 // first damage in the frame, leaving the player vulnerable to the
2142                 // remaining hits in the same frame)
2143                 if (self.flags & FL_ONGROUND)
2144                 if (g_midair)
2145                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2146
2147                 if (time >= game_starttime)
2148                 if (time < self.spawnshieldtime)
2149                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2150         }
2151
2152         MUTATOR_CALLHOOK(PlayerPowerups);
2153 }
2154
2155 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2156 {
2157         if(current > stable)
2158                 return current;
2159         else if(current > stable - 0.25) // when close enough, "snap"
2160                 return stable;
2161         else
2162                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2163 }
2164
2165 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2166 {
2167         if(current < stable)
2168                 return current;
2169         else if(current < stable + 0.25) // when close enough, "snap"
2170                 return stable;
2171         else
2172                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2173 }
2174
2175 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2176 {
2177         if(current > rotstable)
2178         {
2179                 if(rotframetime > 0)
2180                 {
2181                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2182                         current = max(rotstable, current - rotlinear * rotframetime);
2183                 }
2184         }
2185         else if(current < regenstable)
2186         {
2187                 if(regenframetime > 0)
2188                 {
2189                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2190                         current = min(regenstable, current + regenlinear * regenframetime);
2191                 }
2192         }
2193
2194         if(current > limit)
2195                 current = limit;
2196
2197         return current;
2198 }
2199
2200 void player_regen (void)
2201 {
2202         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2203         maxh = autocvar_g_balance_health_rotstable;
2204         maxa = autocvar_g_balance_armor_rotstable;
2205         maxf = autocvar_g_balance_fuel_rotstable;
2206         minh = autocvar_g_balance_health_regenstable;
2207         mina = autocvar_g_balance_armor_regenstable;
2208         minf = autocvar_g_balance_fuel_regenstable;
2209         limith = autocvar_g_balance_health_limit;
2210         limita = autocvar_g_balance_armor_limit;
2211         limitf = autocvar_g_balance_fuel_limit;
2212
2213         max_mod = regen_mod = rot_mod = limit_mod = 1;
2214
2215         if (self.runes & RUNE_REGEN)
2216         {
2217                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2218                 {
2219                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2220                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2221                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2222                 }
2223                 else
2224                 {
2225                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2226                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2227                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2228                 }
2229         }
2230         else if (self.runes & CURSE_VENOM)
2231         {
2232                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2233                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2234                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2235                 else
2236                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2237                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2238                 //if (!self.runes & RUNE_REGEN)
2239                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2240         }
2241         maxh = maxh * max_mod;
2242         //maxa = maxa * max_mod;
2243         //maxf = maxf * max_mod;
2244         minh = minh * max_mod;
2245         //mina = mina * max_mod;
2246         //minf = minf * max_mod;
2247         limith = limith * limit_mod;
2248         limita = limita * limit_mod;
2249         //limitf = limitf * limit_mod;
2250
2251         if(g_lms && g_ca)
2252                 rot_mod = 0;
2253
2254         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2255         {
2256                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2257                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2258
2259                 // if player rotted to death...  die!
2260                 if(self.health < 1)
2261                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2262         }
2263
2264         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2265                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2266 }
2267
2268 float zoomstate_set;
2269 void SetZoomState(float z)
2270 {
2271         if(z != self.zoomstate)
2272         {
2273                 self.zoomstate = z;
2274                 ClientData_Touch(self);
2275         }
2276         zoomstate_set = 1;
2277 }
2278
2279 void GetPressedKeys(void) {
2280         MUTATOR_CALLHOOK(GetPressedKeys);
2281         if (self.movement_x > 0) // get if movement keys are pressed
2282         {       // forward key pressed
2283                 self.pressedkeys |= KEY_FORWARD;
2284                 self.pressedkeys &~= KEY_BACKWARD;
2285         }
2286         else if (self.movement_x < 0)
2287         {       // backward key pressed
2288                 self.pressedkeys |= KEY_BACKWARD;
2289                 self.pressedkeys &~= KEY_FORWARD;
2290         }
2291         else
2292         {       // no x input
2293                 self.pressedkeys &~= KEY_FORWARD;
2294                 self.pressedkeys &~= KEY_BACKWARD;
2295         }
2296
2297         if (self.movement_y > 0)
2298         {       // right key pressed
2299                 self.pressedkeys |= KEY_RIGHT;
2300                 self.pressedkeys &~= KEY_LEFT;
2301         }
2302         else if (self.movement_y < 0)
2303         {       // left key pressed
2304                 self.pressedkeys |= KEY_LEFT;
2305                 self.pressedkeys &~= KEY_RIGHT;
2306         }
2307         else
2308         {       // no y input
2309                 self.pressedkeys &~= KEY_RIGHT;
2310                 self.pressedkeys &~= KEY_LEFT;
2311         }
2312
2313         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2314                 self.pressedkeys |= KEY_JUMP;
2315         else
2316                 self.pressedkeys &~= KEY_JUMP;
2317         if (self.BUTTON_CROUCH)
2318                 self.pressedkeys |= KEY_CROUCH;
2319         else
2320                 self.pressedkeys &~= KEY_CROUCH;
2321 }
2322
2323 /*
2324 ======================
2325 spectate mode routines
2326 ======================
2327 */
2328
2329 void SpectateCopy(entity spectatee) {
2330         other = spectatee;
2331         MUTATOR_CALLHOOK(SpectateCopy);
2332         self.armortype = spectatee.armortype;
2333         self.armorvalue = spectatee.armorvalue;
2334         self.ammo_cells = spectatee.ammo_cells;
2335         self.ammo_shells = spectatee.ammo_shells;
2336         self.ammo_nails = spectatee.ammo_nails;
2337         self.ammo_rockets = spectatee.ammo_rockets;
2338         self.ammo_fuel = spectatee.ammo_fuel;
2339         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2340         self.health = spectatee.health;
2341         self.impulse = 0;
2342         self.items = spectatee.items;
2343         self.last_pickup = spectatee.last_pickup;
2344         self.metertime = spectatee.metertime;
2345         self.strength_finished = spectatee.strength_finished;
2346         self.invincible_finished = spectatee.invincible_finished;
2347         self.pressedkeys = spectatee.pressedkeys;
2348         self.weapons = spectatee.weapons;
2349         self.switchweapon = spectatee.switchweapon;
2350         self.weapon = spectatee.weapon;
2351         self.punchangle = spectatee.punchangle;
2352         self.view_ofs = spectatee.view_ofs;
2353         self.v_angle = spectatee.v_angle;
2354         self.velocity = spectatee.velocity;
2355         self.dmg_take = spectatee.dmg_take;
2356         self.dmg_save = spectatee.dmg_save;
2357         self.dmg_inflictor = spectatee.dmg_inflictor;
2358         self.angles = spectatee.v_angle;
2359         self.fixangle = TRUE;
2360         setorigin(self, spectatee.origin);
2361         setsize(self, spectatee.mins, spectatee.maxs);
2362         SetZoomState(spectatee.zoomstate);
2363
2364         anticheat_spectatecopy(spectatee);
2365 }
2366
2367 float SpectateUpdate() {
2368         if(!self.enemy)
2369                 return 0;
2370
2371         if (self == self.enemy)
2372                 return 0;
2373
2374         if(self.enemy.classname != "player")
2375                 return 0;
2376
2377         SpectateCopy(self.enemy);
2378
2379         return 1;
2380 }
2381
2382 float SpectateNext() {
2383         other = find(self.enemy, classname, "player");
2384
2385         if (!other)
2386                 other = find(other, classname, "player");
2387
2388         if (other)
2389                 self.enemy = other;
2390
2391         if(self.enemy.classname == "player") {
2392                 msg_entity = self;
2393                 WriteByte(MSG_ONE, SVC_SETVIEW);
2394                 WriteEntity(MSG_ONE, self.enemy);
2395                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2396                 self.movetype = MOVETYPE_NONE;
2397                 accuracy_resend(self);
2398
2399                 if(!SpectateUpdate())
2400                         PutObserverInServer();
2401
2402                 return 1;
2403         } else {
2404                 return 0;
2405         }
2406 }
2407
2408 /*
2409 =============
2410 ShowRespawnCountdown()
2411
2412 Update a respawn countdown display.
2413 =============
2414 */
2415 void ShowRespawnCountdown()
2416 {
2417         float number;
2418         if(self.deadflag == DEAD_NO) // just respawned?
2419                 return;
2420         else
2421         {
2422                 number = ceil(self.death_time - time);
2423                 if(number <= 0)
2424                         return;
2425                 if(number <= self.respawn_countdown)
2426                 {
2427                         self.respawn_countdown = number - 1;
2428                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2429                                 AnnounceTo(self, strcat(ftos(number), ""));
2430                 }
2431         }
2432 }
2433
2434 void LeaveSpectatorMode()
2435 {
2436         if(isJoinAllowed()) {
2437                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2438                         self.classname = "player";
2439
2440                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2441                                 JoinBestTeam(self, FALSE, TRUE);
2442
2443                         if(autocvar_g_campaign)
2444                                 campaign_bots_may_start = 1;
2445
2446                         PutClientInServer();
2447
2448                         if(self.classname == "player")
2449                                 bprint ("^4", self.netname, "^4 is playing now\n");
2450
2451                         if(!autocvar_g_campaign)
2452                                 centerprint(self,""); // clear MOTD
2453
2454                         return;
2455                 } else {
2456                         if (g_ca && self.caplayer) {
2457                         }       // do nothing
2458                         else
2459                                 stuffcmd(self,"menu_showteamselect\n");
2460                         return;
2461                 }
2462         }
2463         else {
2464                 //player may not join because of g_maxplayers is set
2465                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2466         }
2467 }
2468
2469 /**
2470  * Determines whether the player is allowed to join. This depends on cvar
2471  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2472  * it checks whether the number of currently playing players exceeds g_maxplayers.
2473  * @return bool TRUE if the player is allowed to join, false otherwise
2474  */
2475 float isJoinAllowed() {
2476         if(self.team_forced < 0)
2477                 return FALSE; // forced spectators can never join
2478
2479         if (!autocvar_g_maxplayers)
2480                 return TRUE;
2481
2482         local entity e;
2483         local float currentlyPlaying;
2484         FOR_EACH_REALPLAYER(e) {
2485                 if(e.classname == "player")
2486                         currentlyPlaying += 1;
2487         }
2488         if(currentlyPlaying < autocvar_g_maxplayers)
2489                 return TRUE;
2490
2491         return FALSE;
2492 }
2493
2494 /**
2495  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2496  * g_maxplayers_spectator_blocktime seconds
2497  */
2498 void checkSpectatorBlock() {
2499         if(self.classname == "spectator" || self.classname == "observer") {
2500                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2501                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2502                         dropclient(self);
2503                 }
2504         }
2505 }
2506
2507 void ObserverThink()
2508 {
2509         if (self.flags & FL_JUMPRELEASED) {
2510                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2511                         self.welcomemessage_time = 0;
2512                         self.flags &~= FL_JUMPRELEASED;
2513                         self.flags |= FL_SPAWNING;
2514                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2515                         self.welcomemessage_time = 0;
2516                         self.flags &~= FL_JUMPRELEASED;
2517                         if(SpectateNext() == 1) {
2518                                 self.classname = "spectator";
2519                         }
2520                 }
2521         } else {
2522                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2523                         self.flags |= FL_JUMPRELEASED;
2524                         if(self.flags & FL_SPAWNING)
2525                         {
2526                                 self.flags &~= FL_SPAWNING;
2527                                 LeaveSpectatorMode();
2528                                 return;
2529                         }
2530                 }
2531         }
2532         PrintWelcomeMessage(self);
2533 }
2534
2535 void SpectatorThink()
2536 {
2537         if (self.flags & FL_JUMPRELEASED) {
2538                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2539                         self.welcomemessage_time = 0;
2540                         self.flags &~= FL_JUMPRELEASED;
2541                         self.flags |= FL_SPAWNING;
2542                 } else if(self.BUTTON_ATCK) {
2543                         self.welcomemessage_time = 0;
2544                         self.flags &~= FL_JUMPRELEASED;
2545                         if(SpectateNext() == 1) {
2546                                 self.classname = "spectator";
2547                         } else {
2548                                 self.classname = "observer";
2549                                 PutClientInServer();
2550                         }
2551                 } else if (self.BUTTON_ATCK2) {
2552                         self.welcomemessage_time = 0;
2553                         self.flags &~= FL_JUMPRELEASED;
2554                         self.classname = "observer";
2555                         PutClientInServer();
2556                 } else {
2557                         if(!SpectateUpdate())
2558                                 PutObserverInServer();
2559                 }
2560         } else {
2561                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2562                         self.flags |= FL_JUMPRELEASED;
2563                         if(self.flags & FL_SPAWNING)
2564                         {
2565                                 self.flags &~= FL_SPAWNING;
2566                                 LeaveSpectatorMode();
2567                                 return;
2568                         }
2569                 }
2570         }
2571
2572         PrintWelcomeMessage(self);
2573         self.flags |= FL_CLIENT | FL_NOTARGET;
2574 }
2575
2576 .float touchexplode_time;
2577
2578 /*
2579 =============
2580 PlayerPreThink
2581
2582 Called every frame for each client before the physics are run
2583 =============
2584 */
2585 void() ctf_setstatus;
2586 void() nexball_setstatus;
2587 .float items_added;
2588 void PlayerPreThink (void)
2589 {
2590         self.stat_game_starttime = game_starttime;
2591         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2592         self.stat_leadlimit = autocvar_leadlimit;
2593
2594         if(frametime)
2595         {
2596                 // physics frames: update anticheat stuff
2597                 anticheat_prethink();
2598         }
2599
2600         if(blockSpectators && frametime)
2601                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2602                 checkSpectatorBlock();
2603
2604         zoomstate_set = 0;
2605
2606         if(self.netname_previous != self.netname)
2607         {
2608                 if(autocvar_sv_eventlog)
2609                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2610                 if(self.netname_previous)
2611                         strunzone(self.netname_previous);
2612                 self.netname_previous = strzone(self.netname);
2613         }
2614
2615         // version nagging
2616         if(self.version_nagtime)
2617                 if(self.cvar_g_xonoticversion)
2618                         if(time > self.version_nagtime)
2619                         {
2620                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2621                                 {
2622                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2623                                         {
2624                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2625                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2626                                         }
2627                                         else
2628                                         {
2629                                                 float r;
2630                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2631                                                 if(r < 0)
2632                                                 {
2633                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2634                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2635                                                 }
2636                                                 else if(r > 0)
2637                                                 {
2638                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2639                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2640                                                 }
2641                                         }
2642                                 }
2643                                 self.version_nagtime = 0;
2644                         }
2645
2646         // GOD MODE info
2647         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2648         {
2649                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2650                 self.max_armorvalue = 0;
2651         }
2652
2653 #ifdef TETRIS
2654         if (TetrisPreFrame())
2655                 return;
2656 #endif
2657
2658         MUTATOR_CALLHOOK(PlayerPreThink);
2659
2660         if(self.classname == "player") {
2661 //              if(self.netname == "Wazat")
2662 //                      bprint(self.classname, "\n");
2663
2664                 CheckRules_Player();
2665
2666                 PrintWelcomeMessage(self);
2667
2668                 if (intermission_running)
2669                 {
2670                         IntermissionThink ();   // otherwise a button could be missed between
2671                         return;                                 // the think tics
2672                 }
2673
2674                 if(self.teleport_time)
2675                 if(time > self.teleport_time)
2676                 {
2677                         self.teleport_time = 0;
2678                         self.effects = self.effects - (self.effects & EF_NODRAW);
2679                 }
2680
2681                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2682                         UpdateSelectedPlayer();
2683
2684                 //don't allow the player to turn around while game is paused!
2685                 if(timeoutStatus == 2) {
2686                         self.v_angle = self.lastV_angle;
2687                         self.angles = self.lastV_angle;
2688                         self.fixangle = TRUE;
2689                 }
2690
2691                 if(frametime)
2692                 {
2693                         if(self.health <= 0 && autocvar_g_deathglow)
2694                         {
2695                                 if(self.glowmod_x > 0)
2696                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2697                                 else
2698                                         self.glowmod_x = -1;
2699                                 if(self.glowmod_y > 0)
2700                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2701                                 else
2702                                         self.glowmod_y = -1;
2703                                 if(self.glowmod_z > 0)
2704                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2705                                 else
2706                                         self.glowmod_z = -1;
2707                         }
2708                         else
2709                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2710                         player_powerups();
2711                 }
2712
2713                 if (self.deadflag != DEAD_NO)
2714                 {
2715                         float button_pressed, force_respawn;
2716                         if(self.personal && g_race_qualifying)
2717                         {
2718                                 if(time > self.death_time)
2719                                 {
2720                                         self.death_time = time + 1; // only retry once a second
2721                                         respawn();
2722                                         self.impulse = 141;
2723                                 }
2724                         }
2725                         else
2726                         {
2727                                 if(frametime)
2728                                         player_anim();
2729                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2730                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2731                                 if (self.deadflag == DEAD_DYING)
2732                                 {
2733                                         if(force_respawn)
2734                                                 self.deadflag = DEAD_RESPAWNING;
2735                                         else if(!button_pressed)
2736                                                 self.deadflag = DEAD_DEAD;
2737                                 }
2738                                 else if (self.deadflag == DEAD_DEAD)
2739                                 {
2740                                         if(button_pressed)
2741                                                 self.deadflag = DEAD_RESPAWNABLE;
2742                                 }
2743                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2744                                 {
2745                                         if(!button_pressed)
2746                                                 self.deadflag = DEAD_RESPAWNING;
2747                                 }
2748                                 else if (self.deadflag == DEAD_RESPAWNING)
2749                                 {
2750                                         if(time > self.death_time)
2751                                         {
2752                                                 self.death_time = time + 1; // only retry once a second
2753                                                 respawn();
2754                                         }
2755                                 }
2756                                 ShowRespawnCountdown();
2757                         }
2758                         return;
2759                 }
2760
2761                 if(g_touchexplode)
2762                 if(time > self.touchexplode_time)
2763                 if(self.classname == "player")
2764                 if(self.deadflag == DEAD_NO)
2765                 if not(IS_INDEPENDENT_PLAYER(self))
2766                 FOR_EACH_PLAYER(other) if(self != other)
2767                 {
2768                         if(time > other.touchexplode_time)
2769                         if(other.deadflag == DEAD_NO)
2770                         if not(IS_INDEPENDENT_PLAYER(other))
2771                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2772                         {
2773                                 PlayerTouchExplode(self, other);
2774                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2775                         }
2776                 }
2777
2778                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2779                 {
2780                         vector dist;
2781
2782                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2783                         dist = self.prevorigin - self.origin;
2784                         dist_z = 0;
2785                         self.lms_traveled_distance += fabs(vlen(dist));
2786
2787                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2788                         {
2789                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2790                                 self.lms_traveled_distance = 0;
2791                         }
2792
2793                         if(time > self.lms_nextcheck)
2794                         {
2795                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2796                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2797                                 {
2798                                         centerprint(self, autocvar_g_lms_campcheck_message);
2799                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2800                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2801                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2802                                 }
2803                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2804                                 self.lms_traveled_distance = 0;
2805                         }
2806                 }
2807
2808                 self.prevorigin = self.origin;
2809
2810                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2811                 {
2812                         if (!self.crouch)
2813                         {
2814                                 self.crouch = TRUE;
2815                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2816                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2817                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2818                         }
2819                 }
2820                 else
2821                 {
2822                         if (self.crouch)
2823                         {
2824                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2825                                 if (!trace_startsolid)
2826                                 {
2827                                         self.crouch = FALSE;
2828                                         self.view_ofs = PL_VIEW_OFS;
2829                                         setsize (self, PL_MIN, PL_MAX);
2830                                 }
2831                         }
2832                 }
2833
2834                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2835                 {
2836                         if(self.bloodloss_timer < time)
2837                         {
2838                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2839                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2840                         }
2841                 }
2842
2843                 FixPlayermodel();
2844
2845                 GrapplingHookFrame();
2846
2847                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2848                 //if(frametime)
2849                 {
2850                         self.items &~= self.items_added;
2851
2852                         W_WeaponFrame();
2853
2854                         self.items_added = 0;
2855                         if(self.items & IT_JETPACK)
2856                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2857                                         self.items_added |= IT_FUEL;
2858
2859                         self.items |= self.items_added;
2860                 }
2861
2862                 player_regen();
2863
2864                 // rot nex charge to the charge limit
2865                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2866                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2867
2868                 if(frametime)
2869                         player_anim();
2870
2871                 if (g_minstagib)
2872                         minstagib_ammocheck();
2873
2874                 if(g_ctf)
2875                         ctf_setstatus();
2876
2877                 if(g_nexball)
2878                         nexball_setstatus();
2879
2880         if(g_cts)
2881             self.killcnt = max(0, self.killcount - sys_frametime);
2882
2883                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2884
2885                 //self.angles_y=self.v_angle_y + 90;   // temp
2886         } else if(gameover) {
2887                 if (intermission_running)
2888                         IntermissionThink ();   // otherwise a button could be missed between
2889                 return;
2890         } else if(self.classname == "observer") {
2891                 ObserverThink();
2892         } else if(self.classname == "spectator") {
2893                 SpectatorThink();
2894         }
2895
2896         if(!zoomstate_set)
2897                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && autocvar_g_balance_campingrifle_secondary == 0));
2898
2899         float oldspectatee_status;
2900         oldspectatee_status = self.spectatee_status;
2901         if(self.classname == "spectator")
2902                 self.spectatee_status = num_for_edict(self.enemy);
2903         else if(self.classname == "observer")
2904                 self.spectatee_status = num_for_edict(self);
2905         else
2906                 self.spectatee_status = 0;
2907         if(self.spectatee_status != oldspectatee_status)
2908         {
2909                 ClientData_Touch(self);
2910                 if(g_race || g_cts)
2911                         race_InitSpectator();
2912         }
2913
2914         if(self.teamkill_soundtime)
2915         if(time > self.teamkill_soundtime)
2916         {
2917                 self.teamkill_soundtime = 0;
2918
2919                 entity oldpusher, oldself;
2920
2921                 oldself = self; self = self.teamkill_soundsource;
2922                 oldpusher = self.pusher; self.pusher = oldself;
2923
2924                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2925
2926                 self.pusher = oldpusher;
2927                 self = oldself;
2928         }
2929
2930         if(self.taunt_soundtime)
2931         if(time > self.taunt_soundtime)
2932         {
2933                 self.taunt_soundtime = 0;
2934                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2935         }
2936
2937         target_voicescript_next(self);
2938 }
2939
2940 float isInvisibleString(string s)
2941 {
2942         float i, n, c;
2943         s = strdecolorize(s);
2944         for((i = 0), (n = strlen(s)); i < n; ++i)
2945         {
2946                 c = str2chr(s, i);
2947                 switch(c)
2948                 {
2949                         case 0:
2950                         case 32: // space
2951                                 break;
2952                         case 192: // charmap space
2953                                 if (!autocvar_utf8_enable)
2954                                         break;
2955                                 return FALSE;
2956                         case 160: // space in unicode fonts
2957                         case 0xE000 + 192: // utf8 charmap space
2958                                 if (autocvar_utf8_enable)
2959                                         break;
2960                         default:
2961                                 return FALSE;
2962                 }
2963         }
2964         return TRUE;
2965 }
2966
2967 /*
2968 =============
2969 PlayerPostThink
2970
2971 Called every frame for each client after the physics are run
2972 =============
2973 */
2974 .float idlekick_lasttimeleft;
2975 .entity showheadshotbbox;
2976 void showheadshotbbox_think()
2977 {
2978         if(self.owner.showheadshotbbox != self)
2979         {
2980                 remove(self);
2981                 return;
2982         }
2983         self.nextthink = time;
2984         setorigin(self, self.owner.origin);
2985         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2986 }
2987 void PlayerPostThink (void)
2988 {
2989         // Savage: Check for nameless players
2990         if (isInvisibleString(self.netname)) {
2991                 self.netname = "Player";
2992                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2993         }
2994
2995         if(sv_maxidle && frametime)
2996         {
2997                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2998                 float timeleft;
2999                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3000                 if(timeleft <= 0)
3001                 {
3002                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3003                         AnnounceTo(self, "terminated");
3004                         dropclient(self);
3005                         return;
3006                 }
3007                 else if(timeleft <= 10)
3008                 {
3009                         if(timeleft != self.idlekick_lasttimeleft)
3010                         {
3011                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3012                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3013                         }
3014                 }
3015                 else
3016                 {
3017                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3018                 }
3019                 self.idlekick_lasttimeleft = timeleft;
3020         }
3021
3022 #ifdef TETRIS
3023         if(self.impulse == 100)
3024                 ImpulseCommands();
3025         if (TetrisPostFrame())
3026                 return;
3027 #endif
3028
3029         CheatFrame();
3030
3031         if(self.classname == "player") {
3032                 CheckRules_Player();
3033                 UpdateChatBubble();
3034                 UpdateTeamBubble();
3035                 if (self.impulse)
3036                         ImpulseCommands();
3037                 if (intermission_running)
3038                         return;         // intermission or finale
3039                 GetPressedKeys();
3040         } else if (self.classname == "observer") {
3041                 //do nothing
3042         } else if (self.classname == "spectator") {
3043                 //do nothing
3044         }
3045
3046         /*
3047         float i;
3048         for(i = 0; i < 1000; ++i)
3049         {
3050                 vector end;
3051                 end = self.origin + '0 0 1024' + 512 * randomvec();
3052                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3053                 if(trace_fraction < 1)
3054                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3055                 {
3056                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3057                         break;
3058                 }
3059         }
3060         */
3061
3062         Arena_Warmup();
3063
3064         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3065
3066         if(self.waypointsprite_attachedforcarrier)
3067                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3068
3069         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3070         {
3071                 if(!self.showheadshotbbox)
3072                 {
3073                         self.showheadshotbbox = spawn();
3074                         self.showheadshotbbox.classname = "headshotbbox";
3075                         self.showheadshotbbox.owner = self;
3076                         self.showheadshotbbox.think = showheadshotbbox_think;
3077                         self.showheadshotbbox.nextthink = time;
3078                         self = self.showheadshotbbox;
3079                         self.think();
3080                         self = self.owner;
3081                 }
3082         }
3083         else
3084         {
3085                 if(self.showheadshotbbox)
3086                         remove(self.showheadshotbbox);
3087         }
3088
3089         playerdemo_write();
3090
3091         if((g_cts || g_race) && self.cvar_cl_allow_uid2name == 1)
3092         {
3093                 if(!self.stored_netname)
3094                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3095                 if(self.stored_netname != self.netname)
3096                 {
3097                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3098                         strunzone(self.stored_netname);
3099                         self.stored_netname = strzone(self.netname);
3100                 }
3101         }
3102
3103         /*
3104         if(g_race)
3105                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3106         */
3107 }