qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(cvar("spawn_debugview"))
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > cvar("g_spawn_furthest"))
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(cvar("spawn_debugview"))
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(cvar("spawn_debug"))
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(cvar("sv_servermodelsonly"))
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602
 603         Portal_ClearAll(self);
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         self.spectatortime = time;
 634
 635         self.classname = "observer";
 636         self.iscreature = FALSE;
 637         self.health = -666;
 638         self.takedamage = DAMAGE_NO;
 639         self.solid = SOLID_NOT;
 640         self.movetype = MOVETYPE_NOCLIP;
 641         self.flags = FL_CLIENT | FL_NOTARGET;
 642         self.armorvalue = 666;
 643         self.effects = 0;
 644         self.armorvalue = cvar("g_balance_armor_start");
 645         self.pauserotarmor_finished = 0;
 646         self.pauserothealth_finished = 0;
 647         self.pauseregen_finished = 0;
 648         self.damageforcescale = 0;
 649         self.death_time = 0;
 650         self.dead_frame = 0;
 651         self.alpha = 0;
 652         self.scale = 0;
 653         self.fade_time = 0;
 654         self.pain_frame = 0;
 655         self.pain_finished = 0;
 656         self.strength_finished = 0;
 657         self.invincible_finished = 0;
 658         self.pushltime = 0;
 659         self.think = SUB_Null;
 660         self.nextthink = 0;
 661         self.hook_time = 0;
 662         self.runes = 0;
 663         self.deadflag = DEAD_NO;
 664         self.angles = spot.angles;
 665         self.angles_z = 0;
 666         self.fixangle = TRUE;
 667         self.crouch = FALSE;
 668
 669         self.view_ofs = PL_VIEW_OFS;
 670         setorigin (self, spot.origin);
 671         setsize (self, '0 0 0', '0 0 0');
 672         self.prevorigin = self.origin;
 673         self.items = 0;
 674         self.weapons = 0;
 675         self.model = "";
 676         FixPlayermodel();
 677         self.model = "";
 678         self.modelindex = 0;
 679         self.weapon = 0;
 680         self.weaponmodel = "";
 681         self.weaponentity = world;
 682         self.exteriorweaponentity = world;
 683         self.killcount = -666;
 684         self.velocity = '0 0 0';
 685         self.avelocity = '0 0 0';
 686         self.punchangle = '0 0 0';
 687         self.punchvector = '0 0 0';
 688         self.oldvelocity = self.velocity;
 689         self.fire_endtime = -1;
 690
 691         if(sv_loddistance1)
 692                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 693
 694         if(g_arena)
 695         {
 696                 if(self.version_mismatch)
 697                 {
 698                         Spawnqueue_Unmark(self);
 699                         Spawnqueue_Remove(self);
 700                 }
 701                 else
 702                 {
 703                         Spawnqueue_Insert(self);
 704                 }
 705         }
 706         else if(g_lms)
 707         {
 708                 // Only if the player cannot play at all
 709                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 710                         self.frags = FRAGS_SPECTATOR;
 711                 else
 712                         self.frags = FRAGS_LMS_LOSER;
 713         }
 714         else
 715                 self.frags = FRAGS_SPECTATOR;
 716
 717         MUTATOR_CALLHOOK(MakePlayerObserver);
 718 }
 719
 720 float RestrictSkin(float s)
 721 {
 722         if(!teams_matter)
 723                 return s;
 724         if(s == 6)
 725                 return 6;
 726         return mod(s, 3);
 727 }
 728
 729 void FixPlayermodel()
 730 {
 731         local string defaultmodel;
 732         local float defaultskin, chmdl, oldskin;
 733         local vector m1, m2;
 734
 735         defaultmodel = "";
 736
 737         if(cvar("sv_defaultcharacter") == 1) {
 738                 defaultskin = 0;
 739
 740                 if(teams_matter)
 741                 {
 742                         string s;
 743                         s = Team_ColorNameLowerCase(self.team);
 744                         if(s != "neutral")
 745                         {
 746                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 747                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 748                         }
 749                 }
 750
 751                 if(defaultmodel == "")
 752                 {
 753                         defaultmodel = cvar_string("sv_defaultplayermodel");
 754                         defaultskin = cvar("sv_defaultplayerskin");
 755                 }
 756         }
 757
 758         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 759         {
 760                 if(self.model != "")
 761                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 762                 self.model = ""; // force the != checks to return true
 763         }
 764
 765         if(defaultmodel != "")
 766         {
 767                 if (defaultmodel != self.model)
 768                 {
 769                         m1 = self.mins;
 770                         m2 = self.maxs;
 771                         setmodel_lod (self, defaultmodel);
 772                         setsize (self, m1, m2);
 773                         chmdl = TRUE;
 774                 }
 775
 776                 oldskin = self.skinindex;
 777                 self.skinindex = defaultskin;
 778         } else {
 779                 if (self.playermodel != self.model || self.playermodel == "")
 780                 {
 781                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 782                         m1 = self.mins;
 783                         m2 = self.maxs;
 784                         setmodel_lod (self, self.playermodel);
 785                         setsize (self, m1, m2);
 786                         chmdl = TRUE;
 787                 }
 788
 789                 oldskin = self.skinindex;
 790                 self.skinindex = RestrictSkin(stof(self.playerskin));
 791         }
 792
 793         if(chmdl || oldskin != self.skinindex)
 794                 self.species = player_getspecies(); // model or skin has changed
 795
 796         if(!teams_matter)
 797                 if(strlen(cvar_string("sv_defaultplayercolors")))
 798                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 799                                 setcolor(self, cvar("sv_defaultplayercolors"));
 800 }
 801
 802 void PlayerTouchExplode(entity p1, entity p2)
 803 {
 804         vector org;
 805         org = (p1.origin + p2.origin) * 0.5;
 806         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 807
 808         te_explosion(org);
 809
 810         entity e;
 811         e = spawn();
 812         setorigin(e, org);
 813         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 814         remove(e);
 815 }
 816
 817 /*
 818 =============
 819 PutClientInServer
 820
 821 Called when a client spawns in the server
 822 =============
 823 */
 824 //void() ctf_playerchanged;
 825 void PutClientInServer (void)
 826 {
 827         if(clienttype(self) == CLIENTTYPE_BOT)
 828         {
 829                 self.classname = "player";
 830         }
 831         else if(clienttype(self) == CLIENTTYPE_REAL)
 832         {
 833                 msg_entity = self;
 834                 WriteByte(MSG_ONE, SVC_SETVIEW);
 835                 WriteEntity(MSG_ONE, self);
 836         }
 837
 838         // player is dead and becomes observer
 839         // FIXME fix LMS scoring for new system
 840         if(g_lms)
 841         {
 842                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 843                         self.classname = "observer";
 844         }
 845
 846         if(g_arena || (g_ca && !allowed_to_spawn))
 847         if(!self.spawned)
 848                 self.classname = "observer";
 849
 850         if(gameover)
 851                 self.classname = "observer";
 852
 853         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 854                 entity spot, oldself;
 855                 float j;
 856
 857                 if(self.team < 0)
 858                         JoinBestTeam(self, FALSE, TRUE);
 859
 860                 race_PreSpawn();
 861
 862                 spot = SelectSpawnPoint (FALSE);
 863                 if(!spot)
 864                 {
 865                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 866                         return; // spawn failed
 867                 }
 868
 869                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 870
 871                 self.classname = "player";
 872                 self.wasplayer = TRUE;
 873                 self.iscreature = TRUE;
 874                 self.movetype = MOVETYPE_WALK;
 875                 self.solid = SOLID_SLIDEBOX;
 876                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 877                 if(cvar("g_playerclip_collisions"))
 878                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 879                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 880                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 881                 self.frags = FRAGS_PLAYER;
 882                 if(independent_players)
 883                         MAKE_INDEPENDENT_PLAYER(self);
 884                 self.flags = FL_CLIENT;
 885                 self.takedamage = DAMAGE_AIM;
 886                 if(g_minstagib)
 887                         self.effects = EF_FULLBRIGHT;
 888                 else
 889                         self.effects = 0;
 890                 self.air_finished = time + 12;
 891                 self.dmg = 2;
 892                 if(cvar("g_balance_nex_charge"))
 893                         self.nex_charge = cvar("g_balance_nex_charge_start");
 894
 895                 if(inWarmupStage)
 896                 {
 897                         self.ammo_shells = warmup_start_ammo_shells;
 898                         self.ammo_nails = warmup_start_ammo_nails;
 899                         self.ammo_rockets = warmup_start_ammo_rockets;
 900                         self.ammo_cells = warmup_start_ammo_cells;
 901                         self.ammo_fuel = warmup_start_ammo_fuel;
 902                         self.health = warmup_start_health;
 903                         self.armorvalue = warmup_start_armorvalue;
 904                         self.weapons = warmup_start_weapons;
 905                 }
 906                 else
 907                 {
 908                         self.ammo_shells = start_ammo_shells;
 909                         self.ammo_nails = start_ammo_nails;
 910                         self.ammo_rockets = start_ammo_rockets;
 911                         self.ammo_cells = start_ammo_cells;
 912                         self.ammo_fuel = start_ammo_fuel;
 913                         self.health = start_health;
 914                         self.armorvalue = start_armorvalue;
 915                         self.weapons = start_weapons;
 916                 }
 917
 918                 if(g_weaponarena_random)
 919                 {
 920                         if(g_weaponarena_random_with_laser)
 921                                 self.weapons &~= WEPBIT_LASER;
 922                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 923                         if(g_weaponarena_random_with_laser)
 924                                 self.weapons |= WEPBIT_LASER;
 925                 }
 926
 927                 self.items = start_items;
 928                 self.jump_interval = time;
 929
 930                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 931                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 932                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 933                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 934                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 935                 //extend the pause of rotting if client was reset at the beginning of the countdown
 936                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 937                         self.spawnshieldtime += game_starttime - time;
 938                         self.pauserotarmor_finished += game_starttime - time;
 939                         self.pauserothealth_finished += game_starttime - time;
 940                         self.pauseregen_finished += game_starttime - time;
 941                 }
 942                 self.damageforcescale = 2;
 943                 self.death_time = 0;
 944                 self.dead_frame = 0;
 945                 self.alpha = 0;
 946                 self.scale = 0;
 947                 self.fade_time = 0;
 948                 self.pain_frame = 0;
 949                 self.pain_finished = 0;
 950                 self.strength_finished = 0;
 951                 self.invincible_finished = 0;
 952                 self.pushltime = 0;
 953                 // players have no think function
 954                 self.think = SUB_Null;
 955                 self.nextthink = 0;
 956                 self.hook_time = 0;
 957                 self.dmg_team = 0;
 958                 self.ballistics_density = cvar("g_ballistics_density_player");
 959
 960                 self.metertime = 0;
 961
 962                 self.runes = 0;
 963
 964                 self.deadflag = DEAD_NO;
 965
 966                 self.angles = spot.angles;
 967
 968                 self.angles_z = 0; // never spawn tilted even if the spot says to
 969                 self.fixangle = TRUE; // turn this way immediately
 970                 self.velocity = '0 0 0';
 971                 self.avelocity = '0 0 0';
 972                 self.punchangle = '0 0 0';
 973                 self.punchvector = '0 0 0';
 974                 self.oldvelocity = self.velocity;
 975                 self.fire_endtime = -1;
 976
 977                 msg_entity = self;
 978                 WRITESPECTATABLE_MSG_ONE({
 979                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 980                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 981                 });
 982
 983                 if(sv_loddistance1)
 984                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 985
 986                 self.model = "";
 987                 FixPlayermodel();
 988
 989                 self.crouch = FALSE;
 990                 self.view_ofs = PL_VIEW_OFS;
 991                 setsize (self, PL_MIN, PL_MAX);
 992                 self.spawnorigin = spot.origin;
 993                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 994                 // don't reset back to last position, even if new position is stuck in solid
 995                 self.oldorigin = self.origin;
 996                 self.prevorigin = self.origin;
 997                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 998
 999                 if(g_arena)
1000                 {
1001                         Spawnqueue_Remove(self);
1002                         Spawnqueue_Mark(self);
1003                 }
1004
1005                 else if(g_ca)
1006                         self.caplayer = 1;
1007
1008                 self.event_damage = PlayerDamage;
1009
1010                 self.bot_attack = TRUE;
1011
1012                 self.statdraintime = time + 5;
1013                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1014
1015                 if(self.killcount == -666) {
1016                         PlayerScore_Clear(self);
1017                         self.killcount = 0;
1018                 }
1019
1020                 self.cnt = WEP_LASER;
1021
1022                 CL_SpawnWeaponentity();
1023                 self.alpha = default_player_alpha;
1024                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1025                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1026
1027                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1028                 self.lms_traveled_distance = 0;
1029                 self.speedrunning = FALSE;
1030
1031                 race_PostSpawn(spot);
1032
1033                 if(cvar("spawn_debug"))
1034                 {
1035                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1036                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1037                 }
1038
1039                 //stuffcmd(self, "chase_active 0");
1040                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1041
1042                 if (cvar("g_spawnsound"))
1043                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1044
1045                 if(g_assault) {
1046                         if(self.team == assault_attacker_team)
1047                                 centerprint(self, "You are attacking!");
1048                         else
1049                                 centerprint(self, "You are defending!");
1050                 }
1051
1052                 target_voicescript_clear(self);
1053
1054                 // reset fields the weapons may use
1055                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1056                         weapon_action(j, WR_RESETPLAYER);
1057
1058                 oldself = self;
1059                 self = spot;
1060                         activator = oldself;
1061                                 SUB_UseTargets();
1062                         activator = world;
1063                 self = oldself;
1064
1065                 MUTATOR_CALLHOOK(PlayerSpawn);
1066
1067                 self.switchweapon = w_getbestweapon(self);
1068                 self.cnt = self.switchweapon;
1069                 self.weapon = 0;
1070         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1071                 PutObserverInServer ();
1072         }
1073
1074         //if(g_ctf)
1075         //      ctf_playerchanged();
1076 }
1077
1078 float ClientInit_SendEntity(entity to, float sf)
1079 {
1080         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1081         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1082         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1083         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1084         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1085         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1088         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1089         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1090         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1091         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1094         if(sv_foginterval && world.fog != "")
1095                 WriteString(MSG_ENTITY, world.fog);
1096         else
1097                 WriteString(MSG_ENTITY, "");
1098         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1099         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1100         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1101         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1102         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1103         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1104         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1105         return TRUE;
1106 }
1107
1108 void ClientInit_CheckUpdate()
1109 {
1110         self.nextthink = time;
1111         if(self.count != cvar("g_balance_armor_blockpercent"))
1112         {
1113                 self.count = cvar("g_balance_armor_blockpercent");
1114                 self.SendFlags |= 1;
1115         }
1116         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1117         {
1118                 self.cnt = cvar("g_balance_weaponswitchdelay");
1119                 self.SendFlags |= 1;
1120         }
1121         if(self.bouncefactor != cvar("g_balance_grenadelauncher_bouncefactor"))
1122         {
1123                 self.bouncefactor = cvar("g_balance_grenadelauncher_bouncefactor");
1124                 self.SendFlags |= 1;
1125         }
1126         if(self.bouncestop != cvar("g_balance_grenadelauncher_bouncestop"))
1127         {
1128                 self.bouncestop = cvar("g_balance_grenadelauncher_bouncestop");
1129                 self.SendFlags |= 1;
1130         }
1131 }
1132
1133 void ClientInit_Spawn()
1134 {
1135         entity o;
1136         entity e;
1137         e = spawn();
1138         e.classname = "clientinit";
1139         e.think = ClientInit_CheckUpdate;
1140         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1141
1142         o = self;
1143         self = e;
1144         ClientInit_CheckUpdate();
1145         self = o;
1146 }
1147
1148 /*
1149 =============
1150 SetNewParms
1151 =============
1152 */
1153 void SetNewParms (void)
1154 {
1155         // initialize parms for a new player
1156         parm1 = -(86400 * 366);
1157 }
1158
1159 /*
1160 =============
1161 SetChangeParms
1162 =============
1163 */
1164 void SetChangeParms (void)
1165 {
1166         // save parms for level change
1167         parm1 = self.parm_idlesince - time;
1168 }
1169
1170 /*
1171 =============
1172 DecodeLevelParms
1173 =============
1174 */
1175 void DecodeLevelParms (void)
1176 {
1177         // load parms
1178         self.parm_idlesince = parm1;
1179         if(self.parm_idlesince == -(86400 * 366))
1180                 self.parm_idlesince = time;
1181
1182         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1183         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1184 }
1185
1186 /*
1187 =============
1188 ClientKill
1189
1190 Called when a client types 'kill' in the console
1191 =============
1192 */
1193
1194 void ClientKill_Now_TeamChange()
1195 {
1196         if(self.killindicator_teamchange == -1)
1197         {
1198                 self.team = -1;
1199                 JoinBestTeam( self, FALSE, FALSE );
1200         }
1201         else
1202                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1203 }
1204
1205 void ClientKill_Now()
1206 {
1207         if(self.killindicator_teamchange)
1208                 ClientKill_Now_TeamChange();
1209
1210         // in any case:
1211         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1212
1213         if(self.killindicator)
1214         {
1215                 dprint("Cleaned up after a leaked kill indicator.\n");
1216                 remove(self.killindicator);
1217                 self.killindicator = world;
1218         }
1219 }
1220 void KillIndicator_Think()
1221 {
1222         if (!self.owner.modelindex)
1223         {
1224                 self.owner.killindicator = world;
1225                 remove(self);
1226                 return;
1227         }
1228
1229         if(self.cnt <= 0)
1230         {
1231                 self = self.owner;
1232                 ClientKill_Now(); // no oldself needed
1233                 return;
1234         }
1235         else
1236         {
1237                 if(self.cnt <= 10)
1238                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1239                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1240                 {
1241                         if(self.cnt <= 10)
1242                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1243                         if(self.owner.killindicator_teamchange)
1244                         {
1245                                 if(self.owner.killindicator_teamchange == -1)
1246                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1247                                 else
1248                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1249                         }
1250                         else
1251                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1252                 }
1253                 self.nextthink = time + 1;
1254                 self.cnt -= 1;
1255         }
1256 }
1257
1258 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1259 {
1260         float killtime;
1261         entity e;
1262         killtime = cvar("g_balance_kill_delay");
1263
1264         if(g_race_qualifying)
1265                 killtime = 0;
1266
1267         self.killindicator_teamchange = targetteam;
1268
1269         if(!self.killindicator)
1270         {
1271                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1272                 {
1273                         ClientKill_Now();
1274                 }
1275                 else
1276                 {
1277                         self.killindicator = spawn();
1278                         self.killindicator.owner = self;
1279                         self.killindicator.scale = 0.5;
1280                         setattachment(self.killindicator, self, "");
1281                         setorigin(self.killindicator, '0 0 52');
1282                         self.killindicator.think = KillIndicator_Think;
1283                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1284                         self.killindicator.cnt = ceil(killtime);
1285                         self.killindicator.count = bound(0, ceil(killtime), 10);
1286                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1287
1288                         for(e = world; (e = find(e, classname, "body")) != world; )
1289                         {
1290                                 if(e.enemy != self)
1291                                         continue;
1292                                 e.killindicator = spawn();
1293                                 e.killindicator.owner = e;
1294                                 e.killindicator.scale = 0.5;
1295                                 setattachment(e.killindicator, e, "");
1296                                 setorigin(e.killindicator, '0 0 52');
1297                                 e.killindicator.think = KillIndicator_Think;
1298                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1299                                 e.killindicator.cnt = ceil(killtime);
1300                         }
1301                         self.lip = 0;
1302                 }
1303         }
1304         if(self.killindicator)
1305         {
1306                 if(targetteam)
1307                         self.killindicator.colormod = TeamColor(targetteam);
1308                 else
1309                         self.killindicator.colormod = '0 0 0';
1310         }
1311 }
1312
1313 void ClientKill (void)
1314 {
1315         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1316         {
1317                 // do nothing
1318         }
1319         else
1320                 ClientKill_TeamChange(0);
1321 }
1322
1323 void CTS_ClientKill_Think (void)
1324 {
1325         self = self.owner; // set self to the player to be killed
1326         sprint(self, "^1You were killed in order to prevent cheating!");
1327         ClientKill_Now();
1328 }
1329
1330 void CTS_ClientKill (float t) // silent version of ClientKill
1331 {
1332         entity e;
1333         e = spawn();
1334         e.owner = self;
1335         e.think = CTS_ClientKill_Think;
1336         e.nextthink = t;
1337 }
1338
1339 void DoTeamChange(float destteam)
1340 {
1341         float t, c0;
1342         if(!teams_matter)
1343         {
1344                 if(destteam >= 0)
1345                         SetPlayerColors(self, destteam);
1346                 return;
1347         }
1348         if(self.classname == "player")
1349         if(destteam == -1)
1350         {
1351                 CheckAllowedTeams(self);
1352                 t = FindSmallestTeam(self, TRUE);
1353                 switch(self.team)
1354                 {
1355                         case COLOR_TEAM1: c0 = c1; break;
1356                         case COLOR_TEAM2: c0 = c2; break;
1357                         case COLOR_TEAM3: c0 = c3; break;
1358                         case COLOR_TEAM4: c0 = c4; break;
1359                         default:          c0 = 999;
1360                 }
1361                 switch(t)
1362                 {
1363                         case 1:
1364                                 if(c0 > c1)
1365                                         destteam = COLOR_TEAM1;
1366                                 break;
1367                         case 2:
1368                                 if(c0 > c2)
1369                                         destteam = COLOR_TEAM2;
1370                                 break;
1371                         case 3:
1372                                 if(c0 > c3)
1373                                         destteam = COLOR_TEAM3;
1374                                 break;
1375                         case 4:
1376                                 if(c0 > c4)
1377                                         destteam = COLOR_TEAM4;
1378                                 break;
1379                 }
1380                 if(destteam == -1)
1381                         return;
1382         }
1383         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1384                 return;
1385         ClientKill_TeamChange(destteam);
1386 }
1387
1388 void FixClientCvars(entity e)
1389 {
1390         // send prediction settings to the client
1391         stuffcmd(e, "\nin_bindmap 0 0\n");
1392         if(g_race || g_cts)
1393                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1394         if(cvar("g_antilag") == 3) // client side hitscan
1395                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1396         if(sv_gentle)
1397                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1398         /*
1399          * we no longer need to stuff this. Remove this comment block if you feel
1400          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1401         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1402         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1403         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1404         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1405         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1406         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1407         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1408         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1409         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1410         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1411         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1412         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1413         stuffcmd(e, "cl_movement_edgefriction 1\n");
1414          */
1415 }
1416
1417 float PlayerInIDList(entity p, string idlist)
1418 {
1419         float n, i;
1420         string s;
1421
1422         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1423         if not(p.crypto_idfp)
1424                 return 0;
1425
1426         // this function allows abbreviated player IDs too!
1427         n = tokenize_console(idlist);
1428         for(i = 0; i < n; ++i)
1429         {
1430                 s = argv(i);
1431                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1432                         return 1;
1433         }
1434
1435         return 0;
1436 }
1437
1438 /*
1439 =============
1440 ClientConnect
1441
1442 Called when a client connects to the server
1443 =============
1444 */
1445 //void ctf_clientconnect();
1446 string ColoredTeamName(float t);
1447 void DecodeLevelParms (void);
1448 //void dom_player_join_team(entity pl);
1449 void ClientConnect (void)
1450 {
1451         float t;
1452
1453         if(self.flags & FL_CLIENT)
1454         {
1455                 print("Warning: ClientConnect, but already connected!\n");
1456                 return;
1457         }
1458
1459         if(Ban_MaybeEnforceBan(self))
1460                 return;
1461
1462         DecodeLevelParms();
1463
1464 #ifdef WATERMARK
1465         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1466 #endif
1467
1468         self.classname = "player_joining";
1469
1470         self.flags = FL_CLIENT;
1471         self.version_nagtime = time + 10 + random() * 10;
1472
1473         if(player_count<0)
1474         {
1475                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1476                 player_count = 0;
1477         }
1478
1479         PlayerScore_Attach(self);
1480         ClientData_Attach();
1481
1482         bot_clientconnect();
1483
1484         playerdemo_init();
1485
1486         anticheat_init();
1487
1488         race_PreSpawnObserver();
1489
1490         //if(g_domination)
1491         //      dom_player_join_team(self);
1492
1493         // identify the right forced team
1494         if(PlayerInIDList(self, cvar_string("g_forced_team_red")))
1495                 self.team_forced = COLOR_TEAM1;
1496         else if(PlayerInIDList(self, cvar_string("g_forced_team_blue")))
1497                 self.team_forced = COLOR_TEAM2;
1498         else if(PlayerInIDList(self, cvar_string("g_forced_team_yellow")))
1499                 self.team_forced = COLOR_TEAM3;
1500         else if(PlayerInIDList(self, cvar_string("g_forced_team_pink")))
1501                 self.team_forced = COLOR_TEAM4;
1502         else if(cvar_string("g_forced_team_otherwise") == "red")
1503                 self.team_forced = COLOR_TEAM1;
1504         else if(cvar_string("g_forced_team_otherwise") == "blue")
1505                 self.team_forced = COLOR_TEAM2;
1506         else if(cvar_string("g_forced_team_otherwise") == "yellow")
1507                 self.team_forced = COLOR_TEAM3;
1508         else if(cvar_string("g_forced_team_otherwise") == "pink")
1509                 self.team_forced = COLOR_TEAM4;
1510         else if(cvar_string("g_forced_team_otherwise") == "spectate")
1511                 self.team_forced = -1;
1512         else if(cvar_string("g_forced_team_otherwise") == "spectator")
1513                 self.team_forced = -1;
1514         else
1515                 self.team_forced = 0;
1516
1517         if(!teams_matter)
1518                 if(self.team_forced > 0)
1519                         self.team_forced = 0;
1520
1521         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1522
1523         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign") || self.team_forced < 0) {
1524                 self.classname = "observer";
1525         } else {
1526                 if(teams_matter)
1527                 {
1528                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1529                         {
1530                                 self.classname = "player";
1531                                 campaign_bots_may_start = 1;
1532                         }
1533                         else
1534                         {
1535                                 self.classname = "observer"; // do it anyway
1536                         }
1537                 }
1538                 else
1539                 {
1540                         self.classname = "player";
1541                         campaign_bots_may_start = 1;
1542                 }
1543         }
1544
1545         self.playerid = (playerid_last = playerid_last + 1);
1546
1547         if(cvar("sv_eventlog"))
1548                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1549
1550         LogTeamchange(self.playerid, self.team, 1);
1551
1552         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1553
1554         self.netname_previous = strzone(self.netname);
1555
1556         bprint("^4", self.netname, "^4 connected");
1557
1558         if(self.classname != "observer" && (g_domination || g_ctf))
1559                 bprint(" and joined the ", ColoredTeamName(self.team));
1560
1561         bprint("\n");
1562
1563         self.welcomemessage_time = 0;
1564
1565         stuffcmd(self, strcat(clientstuff, "\n"));
1566         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1567         stuffcmd(self, "cl_particles_reloadeffects\n");
1568
1569         FixClientCvars(self);
1570
1571         // spawnfunc_waypoint sprites
1572         WaypointSprite_InitClient(self);
1573
1574         // Wazat's grappling hook
1575         SetGrappleHookBindings();
1576
1577         // get autoswitch state from player when he toggles it
1578         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1579
1580         // get version info from player
1581         stuffcmd(self, "cmd clientversion $gameversion\n");
1582
1583         // get other cvars from player
1584         GetCvars(0);
1585
1586         // set cvar for team scoreboard
1587         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1588
1589         // notify about available teams
1590         if(teams_matter)
1591         {
1592                 CheckAllowedTeams(self);
1593                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1594                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1595         }
1596         else
1597                 stuffcmd(self, "set _teams_available 0\n");
1598
1599         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1600
1601         if(g_arena || g_ca)
1602         {
1603                 self.classname = "observer";
1604                 if(g_arena)
1605                         Spawnqueue_Insert(self);
1606         }
1607         /*else if(g_ctf)
1608         {
1609                 ctf_clientconnect();
1610         }*/
1611
1612         if(teams_matter || radar_showennemies)
1613                 attach_entcs();
1614
1615         bot_relinkplayerlist();
1616
1617         self.spectatortime = time;
1618         if(blockSpectators)
1619         {
1620                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1621         }
1622
1623         self.jointime = time;
1624         self.allowedTimeouts = cvar("sv_timeout_number");
1625
1626         if(clienttype(self) == CLIENTTYPE_REAL)
1627         {
1628                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1629                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1630         }
1631
1632         if(g_lms)
1633         {
1634                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1635                 {
1636                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1637                         self.frags = FRAGS_SPECTATOR;
1638                 }
1639         }
1640
1641         if(!sv_foginterval && world.fog != "")
1642                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1643
1644         SoundEntity_Attach(self);
1645
1646         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1647         {
1648                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1649                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1650         }
1651         else
1652                 self.hitplotfh = -1;
1653
1654         if(g_race || g_cts) {
1655                 string rr;
1656                 if(g_cts)
1657                         rr = CTS_RECORD;
1658                 else
1659                         rr = RACE_RECORD;
1660                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1661
1662                 msg_entity = self;
1663                 race_send_recordtime(MSG_ONE);
1664                 race_send_speedaward(MSG_ONE);
1665
1666                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1667                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1668                 race_send_speedaward_alltimebest(MSG_ONE);
1669
1670                 float i;
1671                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1672                         race_SendRankings(i, 0, 0, MSG_ONE);
1673                 }
1674         }
1675         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1676                 send_CSQC_teamnagger();
1677
1678         send_CSQC_cr_maxbullets(self);
1679
1680         CheatInitClient();
1681 }
1682
1683 /*
1684 =============
1685 ClientDisconnect
1686
1687 Called when a client disconnects from the server
1688 =============
1689 */
1690 .entity chatbubbleentity;
1691 .entity teambubbleentity;
1692 void ReadyCount();
1693 void ClientDisconnect (void)
1694 {
1695         if not(self.flags & FL_CLIENT)
1696         {
1697                 print("Warning: ClientDisconnect without ClientConnect\n");
1698                 return;
1699         }
1700
1701         CheatShutdownClient();
1702
1703         if(self.hitplotfh >= 0)
1704         {
1705                 fclose(self.hitplotfh);
1706                 self.hitplotfh = -1;
1707         }
1708
1709         anticheat_report();
1710         anticheat_shutdown();
1711
1712         playerdemo_shutdown();
1713
1714         bot_clientdisconnect();
1715
1716         if(self.entcs)
1717                 detach_entcs();
1718
1719         if(cvar("sv_eventlog"))
1720                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1721         bprint ("^4",self.netname);
1722         bprint ("^4 disconnected\n");
1723
1724         SoundEntity_Detach(self);
1725
1726         DropAllRunes(self);
1727         MUTATOR_CALLHOOK(ClientDisconnect);
1728
1729         Portal_ClearAll(self);
1730
1731         if(self.flagcarried)
1732                 DropFlag(self.flagcarried, world, world);
1733         if(self.ballcarried)
1734                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1735
1736         // Here, everything has been done that requires this player to be a client.
1737
1738         self.flags &~= FL_CLIENT;
1739
1740         if (self.chatbubbleentity)
1741                 remove (self.chatbubbleentity);
1742
1743         if (self.teambubbleentity)
1744                 remove (self.teambubbleentity);
1745
1746         if (self.killindicator)
1747                 remove (self.killindicator);
1748
1749         WaypointSprite_PlayerGone();
1750
1751         bot_relinkplayerlist();
1752
1753         if(g_arena)
1754         {
1755                 Spawnqueue_Unmark(self);
1756                 Spawnqueue_Remove(self);
1757         }
1758
1759         ClientData_Detach();
1760         PlayerScore_Detach(self);
1761
1762         if(self.netname_previous)
1763                 strunzone(self.netname_previous);
1764         if(self.clientstatus)
1765                 strunzone(self.clientstatus);
1766         if(self.weaponorder_byimpulse)
1767                 strunzone(self.weaponorder_byimpulse);
1768
1769         ClearPlayerSounds();
1770
1771         if(self.personal)
1772                 remove(self.personal);
1773
1774         self.playerid = 0;
1775         ReadyCount();
1776
1777         // free cvars
1778         GetCvars(-1);
1779 }
1780
1781 .float BUTTON_CHAT;
1782 void ChatBubbleThink()
1783 {
1784         self.nextthink = time;
1785         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1786         {
1787                 if(self.owner) // but why can that ever be world?
1788                         self.owner.chatbubbleentity = world;
1789                 remove(self);
1790                 return;
1791         }
1792         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1793 #ifdef TETRIS
1794                 || self.owner.tetris_on
1795 #endif
1796         )
1797                 self.model = self.mdl;
1798         else
1799                 self.model = "";
1800 };
1801
1802 void UpdateChatBubble()
1803 {
1804         if (!self.modelindex)
1805                 return;
1806         // spawn a chatbubble entity if needed
1807         if (!self.chatbubbleentity)
1808         {
1809                 self.chatbubbleentity = spawn();
1810                 self.chatbubbleentity.owner = self;
1811                 self.chatbubbleentity.exteriormodeltoclient = self;
1812                 self.chatbubbleentity.think = ChatBubbleThink;
1813                 self.chatbubbleentity.nextthink = time;
1814                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1815                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1816                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1817                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1818                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1819                 self.chatbubbleentity.model = "";
1820                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1821         }
1822 }
1823
1824
1825 void TeamBubbleThink()
1826 {
1827         self.nextthink = time;
1828         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1829         {
1830                 if(self.owner) // but why can that ever be world?
1831                         self.owner.teambubbleentity = world;
1832                 remove(self);
1833                 return;
1834         }
1835 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1836         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1837                 self.model = "";
1838         else
1839                 self.model = self.mdl;
1840
1841 };
1842
1843 float TeamBubble_customizeentityforclient()
1844 {
1845         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1846 }
1847
1848 void UpdateTeamBubble()
1849 {
1850         if (!self.modelindex || !teams_matter)
1851                 return;
1852         // spawn a teambubble entity if needed
1853         if (!self.teambubbleentity && teams_matter)
1854         {
1855                 self.teambubbleentity = spawn();
1856                 self.teambubbleentity.owner = self;
1857                 self.teambubbleentity.exteriormodeltoclient = self;
1858                 self.teambubbleentity.think = TeamBubbleThink;
1859                 self.teambubbleentity.nextthink = time;
1860                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1861 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1862                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1863                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1864                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1865                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1866                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1867                 self.teambubbleentity.effects = EF_LOWPRECISION;
1868         }
1869 }
1870
1871 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1872 // added to the model skins
1873 /*void UpdateColorModHack()
1874 {
1875         local float c;
1876         c = self.clientcolors & 15;
1877         // LordHavoc: only bothering to support white, green, red, yellow, blue
1878              if (!teams_matter) self.colormod = '0 0 0';
1879         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1880         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1881         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1882         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1883         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1884         else self.colormod = '1 1 1';
1885 };*/
1886
1887 .float oldcolormap;
1888 void respawn(void)
1889 {
1890         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1891         {
1892                 self.solid = SOLID_NOT;
1893                 self.takedamage = DAMAGE_NO;
1894                 self.movetype = MOVETYPE_FLY;
1895                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1896                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1897                 self.effects |= EF_ADDITIVE;
1898                 self.oldcolormap = self.colormap;
1899                 self.colormap = 512;
1900                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1901                 if(cvar("g_respawn_ghosts_maxtime"))
1902                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1903         }
1904
1905         CopyBody(1);
1906         self.effects |= EF_NODRAW; // prevent another CopyBody
1907         if(self.oldcolormap)
1908         {
1909                 self.colormap = self.oldcolormap;
1910                 self.oldcolormap = 0;
1911         }
1912         PutClientInServer();
1913 }
1914
1915 void play_countdown(float finished, string samp)
1916 {
1917         if(clienttype(self) == CLIENTTYPE_REAL)
1918                 if(floor(finished - time - frametime) != floor(finished - time))
1919                         if(finished - time < 6)
1920                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1921 }
1922
1923 /**
1924  * When sv_timeout is used this function returs strings like
1925  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1926  * Called by centerprint functions
1927  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1928  */
1929 string getTimeoutText(float addOneSecond) {
1930         if (!cvar("sv_timeout") || !timeoutStatus)
1931                 return "";
1932
1933         local string retStr;
1934         if (timeoutStatus == 1) {
1935                 if (addOneSecond == 1) {
1936                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1937                 }
1938                 else {
1939                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1940                 }
1941                 return retStr;
1942         }
1943         else if (timeoutStatus == 2) {
1944                 if (addOneSecond) {
1945                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1946                         //don't show messages like "Timeout ends in 0 seconds"...
1947                         if ((remainingTimeoutTime + 1) > 0)
1948                                 return retStr;
1949                         else
1950                                 return "";
1951                 }
1952                 else {
1953                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1954                         //don't show messages like "Timeout ends in 0 seconds"...
1955                         if (remainingTimeoutTime > 0)
1956                                 return retStr;
1957                         else
1958                                 return "";
1959                 }
1960         }
1961         else return "";
1962 }
1963
1964 void player_powerups (void)
1965 {
1966         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1967         {
1968                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1969                 self.modelflags |= MF_ROCKET;
1970         }
1971         else
1972         {
1973                 SoundEntity_StopSound(self, CHAN_PLAYER);
1974                 self.modelflags &~= MF_ROCKET;
1975         }
1976
1977         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1978
1979         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1980                 return;
1981
1982         Fire_ApplyDamage(self);
1983         Fire_ApplyEffect(self);
1984
1985         if (g_minstagib)
1986         {
1987                 self.effects |= EF_FULLBRIGHT;
1988
1989                 if (self.items & IT_STRENGTH)
1990                 {
1991                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1992                         if (time > self.strength_finished)
1993                         {
1994                                 self.alpha = default_player_alpha;
1995                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1996                                 self.items &~= IT_STRENGTH;
1997                                 sprint(self, "^3Invisibility has worn off\n");
1998                         }
1999                 }
2000                 else
2001                 {
2002                         if (time < self.strength_finished)
2003                         {
2004                                 self.alpha = g_minstagib_invis_alpha;
2005                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2006                                 self.items |= IT_STRENGTH;
2007                                 sprint(self, "^3You are invisible\n");
2008                         }
2009                 }
2010
2011                 if (self.items & IT_INVINCIBLE)
2012                 {
2013                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2014                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2015                         {
2016                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2017                                 sprint(self, "^3Speed has worn off\n");
2018                         }
2019                 }
2020                 else
2021                 {
2022                         if (time < self.invincible_finished)
2023                         {
2024                                 self.items = self.items | IT_INVINCIBLE;
2025                                 sprint(self, "^3You are on speed\n");
2026                         }
2027                 }
2028                 return;
2029         }
2030
2031         if (self.items & IT_STRENGTH)
2032         {
2033                 play_countdown(self.strength_finished, "misc/poweroff.wav");
2034                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2035                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
2036                 {
2037                         self.items = self.items - (self.items & IT_STRENGTH);
2038                         sprint(self, "^3Strength has worn off\n");
2039                 }
2040         }
2041         else
2042         {
2043                 if (time < self.strength_finished)
2044                 {
2045                         self.items = self.items | IT_STRENGTH;
2046                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
2047                 }
2048         }
2049         if (self.items & IT_INVINCIBLE)
2050         {
2051                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
2052                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2053                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2054                 {
2055                         self.items = self.items - (self.items & IT_INVINCIBLE);
2056                         sprint(self, "^3Shield has worn off\n");
2057                 }
2058         }
2059         else
2060         {
2061                 if (time < self.invincible_finished)
2062                 {
2063                         self.items = self.items | IT_INVINCIBLE;
2064                         sprint(self, "^3Shield surrounds you\n");
2065                 }
2066         }
2067
2068         if(cvar("g_nodepthtestplayers"))
2069                 self.effects = self.effects | EF_NODEPTHTEST;
2070
2071         if(cvar("g_fullbrightplayers"))
2072                 self.effects = self.effects | EF_FULLBRIGHT;
2073
2074         // midair gamemode: damage only while in the air
2075         // if in midair mode, being on ground grants temporary invulnerability
2076         // (this is so that multishot weapon don't clear the ground flag on the
2077         // first damage in the frame, leaving the player vulnerable to the
2078         // remaining hits in the same frame)
2079         if (self.flags & FL_ONGROUND)
2080         if (g_midair)
2081                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2082
2083         if (time >= game_starttime)
2084         if (time < self.spawnshieldtime)
2085                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2086 }
2087
2088 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2089 {
2090         if(current > stable)
2091                 return current;
2092         else if(current > stable - 0.25) // when close enough, "snap"
2093                 return stable;
2094         else
2095                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2096 }
2097
2098 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2099 {
2100         if(current < stable)
2101                 return current;
2102         else if(current < stable + 0.25) // when close enough, "snap"
2103                 return stable;
2104         else
2105                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2106 }
2107
2108 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2109 {
2110         if(current > rotstable)
2111         {
2112                 if(rotframetime > 0)
2113                 {
2114                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2115                         current = max(rotstable, current - rotlinear * rotframetime);
2116                 }
2117         }
2118         else if(current < regenstable)
2119         {
2120                 if(regenframetime > 0)
2121                 {
2122                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2123                         current = min(regenstable, current + regenlinear * regenframetime);
2124                 }
2125         }
2126
2127         if(current > limit)
2128                 current = limit;
2129
2130         return current;
2131 }
2132
2133 void player_regen (void)
2134 {
2135         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2136         maxh = cvar("g_balance_health_rotstable");
2137         maxa = cvar("g_balance_armor_rotstable");
2138         maxf = cvar("g_balance_fuel_rotstable");
2139         minh = cvar("g_balance_health_regenstable");
2140         mina = cvar("g_balance_armor_regenstable");
2141         minf = cvar("g_balance_fuel_regenstable");
2142         limith = cvar("g_balance_health_limit");
2143         limita = cvar("g_balance_armor_limit");
2144         limitf = cvar("g_balance_fuel_limit");
2145
2146         max_mod = regen_mod = rot_mod = limit_mod = 1;
2147
2148         if (self.runes & RUNE_REGEN)
2149         {
2150                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2151                 {
2152                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2153                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2154                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2155                 }
2156                 else
2157                 {
2158                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2159                         max_mod = cvar("g_balance_rune_regen_hpmod");
2160                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2161                 }
2162         }
2163         else if (self.runes & CURSE_VENOM)
2164         {
2165                 max_mod = cvar("g_balance_curse_venom_hpmod");
2166                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2167                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2168                 else
2169                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2170                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2171                 //if (!self.runes & RUNE_REGEN)
2172                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2173         }
2174         maxh = maxh * max_mod;
2175         //maxa = maxa * max_mod;
2176         //maxf = maxf * max_mod;
2177         minh = minh * max_mod;
2178         //mina = mina * max_mod;
2179         //minf = minf * max_mod;
2180         limith = limith * limit_mod;
2181         limita = limita * limit_mod;
2182         //limitf = limitf * limit_mod;
2183
2184         if(g_lms && g_ca)
2185                 rot_mod = 0;
2186
2187         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2188         {
2189                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2190                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2191
2192                 // if player rotted to death...  die!
2193                 if(self.health < 1)
2194                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2195         }
2196
2197         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2198                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2199 }
2200
2201 float zoomstate_set;
2202 void SetZoomState(float z)
2203 {
2204         if(z != self.zoomstate)
2205         {
2206                 self.zoomstate = z;
2207                 ClientData_Touch(self);
2208         }
2209         zoomstate_set = 1;
2210 }
2211
2212 void GetPressedKeys(void) {
2213         MUTATOR_CALLHOOK(GetPressedKeys);
2214         if (self.movement_x > 0) // get if movement keys are pressed
2215         {       // forward key pressed
2216                 self.pressedkeys |= KEY_FORWARD;
2217                 self.pressedkeys &~= KEY_BACKWARD;
2218         }
2219         else if (self.movement_x < 0)
2220         {       // backward key pressed
2221                 self.pressedkeys |= KEY_BACKWARD;
2222                 self.pressedkeys &~= KEY_FORWARD;
2223         }
2224         else
2225         {       // no x input
2226                 self.pressedkeys &~= KEY_FORWARD;
2227                 self.pressedkeys &~= KEY_BACKWARD;
2228         }
2229
2230         if (self.movement_y > 0)
2231         {       // right key pressed
2232                 self.pressedkeys |= KEY_RIGHT;
2233                 self.pressedkeys &~= KEY_LEFT;
2234         }
2235         else if (self.movement_y < 0)
2236         {       // left key pressed
2237                 self.pressedkeys |= KEY_LEFT;
2238                 self.pressedkeys &~= KEY_RIGHT;
2239         }
2240         else
2241         {       // no y input
2242                 self.pressedkeys &~= KEY_RIGHT;
2243                 self.pressedkeys &~= KEY_LEFT;
2244         }
2245
2246         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2247                 self.pressedkeys |= KEY_JUMP;
2248         else
2249                 self.pressedkeys &~= KEY_JUMP;
2250         if (self.BUTTON_CROUCH)
2251                 self.pressedkeys |= KEY_CROUCH;
2252         else
2253                 self.pressedkeys &~= KEY_CROUCH;
2254 }
2255
2256 void update_stats (float number, float hit, float fired) {
2257 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2258 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2259
2260         if(number) {
2261                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2262                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2263         } else {
2264                 self.stat_hit = hit * sv_accuracy_data_share;
2265                 self.stat_fired = fired * sv_accuracy_data_share;
2266         }
2267 }
2268
2269 /*
2270 ======================
2271 spectate mode routines
2272 ======================
2273 */
2274
2275 .float weapon_count;
2276 void SpectateCopy(entity spectatee) {
2277         if(spectatee.weapon_count < WEP_LAST) {
2278                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2279                 spectatee.weapon_count ++;
2280         } else
2281                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2282
2283         other = spectatee;
2284         MUTATOR_CALLHOOK(SpectateCopy);
2285         self.armortype = spectatee.armortype;
2286         self.armorvalue = spectatee.armorvalue;
2287         self.ammo_cells = spectatee.ammo_cells;
2288         self.ammo_shells = spectatee.ammo_shells;
2289         self.ammo_nails = spectatee.ammo_nails;
2290         self.ammo_rockets = spectatee.ammo_rockets;
2291         self.ammo_fuel = spectatee.ammo_fuel;
2292         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2293         self.health = spectatee.health;
2294         self.impulse = 0;
2295         self.items = spectatee.items;
2296         self.last_pickup = spectatee.last_pickup;
2297         self.metertime = spectatee.metertime;
2298         self.strength_finished = spectatee.strength_finished;
2299         self.invincible_finished = spectatee.invincible_finished;
2300         self.pressedkeys = spectatee.pressedkeys;
2301         self.weapons = spectatee.weapons;
2302         self.switchweapon = spectatee.switchweapon;
2303         self.weapon = spectatee.weapon;
2304         self.punchangle = spectatee.punchangle;
2305         self.view_ofs = spectatee.view_ofs;
2306         self.v_angle = spectatee.v_angle;
2307         self.velocity = spectatee.velocity;
2308         self.dmg_take = spectatee.dmg_take;
2309         self.dmg_save = spectatee.dmg_save;
2310         self.dmg_inflictor = spectatee.dmg_inflictor;
2311         self.angles = spectatee.v_angle;
2312         self.fixangle = TRUE;
2313         setorigin(self, spectatee.origin);
2314         setsize(self, spectatee.mins, spectatee.maxs);
2315         SetZoomState(spectatee.zoomstate);
2316
2317         anticheat_spectatecopy(spectatee);
2318 }
2319
2320 float SpectateUpdate() {
2321         if(!self.enemy)
2322                 return 0;
2323
2324         if (self == self.enemy)
2325                 return 0;
2326
2327         if(self.enemy.classname != "player")
2328                 return 0;
2329
2330         SpectateCopy(self.enemy);
2331
2332         return 1;
2333 }
2334
2335 float SpectateNext() {
2336         other = find(self.enemy, classname, "player");
2337
2338         if (!other)
2339                 other = find(other, classname, "player");
2340
2341         if (other)
2342                 self.enemy = other;
2343
2344         if(self.enemy.classname == "player") {
2345                 msg_entity = self;
2346                 WriteByte(MSG_ONE, SVC_SETVIEW);
2347                 WriteEntity(MSG_ONE, self.enemy);
2348                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2349                 self.movetype = MOVETYPE_NONE;
2350
2351                 self.enemy.weapon_count = 0;
2352
2353                 if(!SpectateUpdate())
2354                         PutObserverInServer();
2355
2356                 return 1;
2357         } else {
2358                 return 0;
2359         }
2360 }
2361
2362 /*
2363 =============
2364 ShowRespawnCountdown()
2365
2366 Update a respawn countdown display.
2367 =============
2368 */
2369 void ShowRespawnCountdown()
2370 {
2371         float number;
2372         if(self.deadflag == DEAD_NO) // just respawned?
2373                 return;
2374         else
2375         {
2376                 number = ceil(self.death_time - time);
2377                 if(number <= 0)
2378                         return;
2379                 if(number <= self.respawn_countdown)
2380                 {
2381                         self.respawn_countdown = number - 1;
2382                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2383                                 AnnounceTo(self, strcat(ftos(number), ""));
2384                 }
2385         }
2386 }
2387
2388 void LeaveSpectatorMode()
2389 {
2390         if(isJoinAllowed()) {
2391                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned")) || self.team_forced > 0) {
2392                         self.classname = "player";
2393
2394                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2395                                 JoinBestTeam(self, FALSE, TRUE);
2396
2397                         if(cvar("g_campaign"))
2398                                 campaign_bots_may_start = 1;
2399
2400                         self.stat_count = WEP_LAST;
2401
2402                         PutClientInServer();
2403
2404                         if(self.classname == "player")
2405                                 bprint ("^4", self.netname, "^4 is playing now\n");
2406
2407                         if(!cvar("g_campaign"))
2408                                 centerprint(self,""); // clear MOTD
2409
2410                         return;
2411                 } else {
2412                         if (g_ca && self.caplayer) {
2413                         }       // do nothing
2414                         else
2415                                 stuffcmd(self,"menu_showteamselect\n");
2416                         return;
2417                 }
2418         }
2419         else {
2420                 //player may not join because of g_maxplayers is set
2421                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2422         }
2423 }
2424
2425 /**
2426  * Determines whether the player is allowed to join. This depends on cvar
2427  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2428  * it checks whether the number of currently playing players exceeds g_maxplayers.
2429  * @return bool TRUE if the player is allowed to join, false otherwise
2430  */
2431 float isJoinAllowed() {
2432         if(self.team_forced < 0)
2433                 return FALSE; // forced spectators can never join
2434
2435         if (!cvar("g_maxplayers"))
2436                 return TRUE;
2437
2438         local entity e;
2439         local float currentlyPlaying;
2440         FOR_EACH_REALPLAYER(e) {
2441                 if(e.classname == "player")
2442                         currentlyPlaying += 1;
2443         }
2444         if(currentlyPlaying < cvar("g_maxplayers"))
2445                 return TRUE;
2446
2447         return FALSE;
2448 }
2449
2450 /**
2451  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2452  * g_maxplayers_spectator_blocktime seconds
2453  */
2454 void checkSpectatorBlock() {
2455         if(self.classname == "spectator" || self.classname == "observer") {
2456                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2457                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2458                         dropclient(self);
2459                 }
2460         }
2461 }
2462
2463 void ObserverThink()
2464 {
2465         if (self.flags & FL_JUMPRELEASED) {
2466                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2467                         self.welcomemessage_time = 0;
2468                         self.flags &~= FL_JUMPRELEASED;
2469                         self.flags |= FL_SPAWNING;
2470                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2471                         self.welcomemessage_time = 0;
2472                         self.flags &~= FL_JUMPRELEASED;
2473                         if(SpectateNext() == 1) {
2474                                 self.classname = "spectator";
2475                         }
2476                 }
2477         } else {
2478                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2479                         self.flags |= FL_JUMPRELEASED;
2480                         if(self.flags & FL_SPAWNING)
2481                         {
2482                                 self.flags &~= FL_SPAWNING;
2483                                 LeaveSpectatorMode();
2484                                 return;
2485                         }
2486                 }
2487         }
2488         PrintWelcomeMessage(self);
2489 }
2490
2491 void SpectatorThink()
2492 {
2493         if (self.flags & FL_JUMPRELEASED) {
2494                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2495                         self.welcomemessage_time = 0;
2496                         self.flags &~= FL_JUMPRELEASED;
2497                         self.flags |= FL_SPAWNING;
2498                 } else if(self.BUTTON_ATCK) {
2499                         self.welcomemessage_time = 0;
2500                         self.flags &~= FL_JUMPRELEASED;
2501                         if(SpectateNext() == 1) {
2502                                 self.classname = "spectator";
2503                         } else {
2504                                 self.classname = "observer";
2505                                 self.stat_count = WEP_LAST;
2506                                 PutClientInServer();
2507                         }
2508                 } else if (self.BUTTON_ATCK2) {
2509                         self.welcomemessage_time = 0;
2510                         self.flags &~= FL_JUMPRELEASED;
2511                         self.classname = "observer";
2512                         self.stat_count = WEP_LAST;
2513                         PutClientInServer();
2514                 } else {
2515                         if(!SpectateUpdate())
2516                                 PutObserverInServer();
2517                 }
2518         } else {
2519                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2520                         self.flags |= FL_JUMPRELEASED;
2521                         if(self.flags & FL_SPAWNING)
2522                         {
2523                                 self.flags &~= FL_SPAWNING;
2524                                 LeaveSpectatorMode();
2525                                 return;
2526                         }
2527                 }
2528         }
2529
2530         PrintWelcomeMessage(self);
2531         self.flags |= FL_CLIENT | FL_NOTARGET;
2532 }
2533
2534 .float touchexplode_time;
2535
2536 /*
2537 =============
2538 PlayerPreThink
2539
2540 Called every frame for each client before the physics are run
2541 =============
2542 */
2543 void() ctf_setstatus;
2544 void() nexball_setstatus;
2545 .float items_added;
2546 void PlayerPreThink (void)
2547 {
2548         self.stat_game_starttime = game_starttime;
2549         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2550         self.stat_leadlimit = cvar("leadlimit");
2551
2552         if(frametime)
2553         {
2554                 // physics frames: update anticheat stuff
2555                 anticheat_prethink();
2556         }
2557
2558         if(blockSpectators && frametime)
2559                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2560                 checkSpectatorBlock();
2561
2562         zoomstate_set = 0;
2563
2564         if(self.netname_previous != self.netname)
2565         {
2566                 if(cvar("sv_eventlog"))
2567                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2568                 if(self.netname_previous)
2569                         strunzone(self.netname_previous);
2570                 self.netname_previous = strzone(self.netname);
2571         }
2572
2573         // version nagging
2574         if(self.version_nagtime)
2575                 if(self.cvar_g_xonoticversion)
2576                         if(time > self.version_nagtime)
2577                         {
2578                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2579                                 {
2580                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2581                                         {
2582                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2583                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2584                                         }
2585                                         else
2586                                         {
2587                                                 float r;
2588                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2589                                                 if(r < 0)
2590                                                 {
2591                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2592                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2593                                                 }
2594                                                 else if(r > 0)
2595                                                 {
2596                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2597                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2598                                                 }
2599                                         }
2600                                 }
2601                                 self.version_nagtime = 0;
2602                         }
2603
2604         // GOD MODE info
2605         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2606         {
2607                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2608                 self.max_armorvalue = 0;
2609         }
2610
2611 #ifdef TETRIS
2612         if (TetrisPreFrame())
2613                 return;
2614 #endif
2615
2616         MUTATOR_CALLHOOK(PlayerPreThink);
2617
2618         if(self.classname == "player") {
2619 //              if(self.netname == "Wazat")
2620 //                      bprint(self.classname, "\n");
2621
2622                 CheckRules_Player();
2623
2624                 PrintWelcomeMessage(self);
2625
2626                 if (intermission_running)
2627                 {
2628                         IntermissionThink ();   // otherwise a button could be missed between
2629                         return;                                 // the think tics
2630                 }
2631
2632                 if(self.teleport_time)
2633                 if(time > self.teleport_time)
2634                 {
2635                         self.teleport_time = 0;
2636                         self.effects = self.effects - (self.effects & EF_NODRAW);
2637                 }
2638
2639                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2640                         UpdateSelectedPlayer();
2641
2642                 //don't allow the player to turn around while game is paused!
2643                 if(timeoutStatus == 2) {
2644                         self.v_angle = self.lastV_angle;
2645                         self.angles = self.lastV_angle;
2646                         self.fixangle = TRUE;
2647                 }
2648
2649                 if(frametime)
2650                 {
2651                         if(self.health <= 0 && cvar("g_deathglow"))
2652                         {
2653                                 if(self.glowmod_x > 0)
2654                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2655                                 else
2656                                         self.glowmod_x = -1;
2657                                 if(self.glowmod_y > 0)
2658                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2659                                 else
2660                                         self.glowmod_y = -1;
2661                                 if(self.glowmod_z > 0)
2662                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2663                                 else
2664                                         self.glowmod_z = -1;
2665                         }
2666                         else
2667                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2668                         player_powerups();
2669                 }
2670
2671                 if (self.deadflag != DEAD_NO)
2672                 {
2673                         float button_pressed, force_respawn;
2674                         if(self.personal && g_race_qualifying)
2675                         {
2676                                 if(time > self.death_time)
2677                                 {
2678                                         self.death_time = time + 1; // only retry once a second
2679                                         respawn();
2680                                         self.impulse = 141;
2681                                 }
2682                         }
2683                         else
2684                         {
2685                                 if(frametime)
2686                                         player_anim();
2687                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2688                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2689                                 if (self.deadflag == DEAD_DYING)
2690                                 {
2691                                         if(force_respawn)
2692                                                 self.deadflag = DEAD_RESPAWNING;
2693                                         else if(!button_pressed)
2694                                                 self.deadflag = DEAD_DEAD;
2695                                 }
2696                                 else if (self.deadflag == DEAD_DEAD)
2697                                 {
2698                                         if(button_pressed)
2699                                                 self.deadflag = DEAD_RESPAWNABLE;
2700                                 }
2701                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2702                                 {
2703                                         if(!button_pressed)
2704                                                 self.deadflag = DEAD_RESPAWNING;
2705                                 }
2706                                 else if (self.deadflag == DEAD_RESPAWNING)
2707                                 {
2708                                         if(time > self.death_time)
2709                                         {
2710                                                 self.death_time = time + 1; // only retry once a second
2711                                                 respawn();
2712                                         }
2713                                 }
2714                                 ShowRespawnCountdown();
2715                         }
2716                         return;
2717                 }
2718
2719                 if(g_touchexplode)
2720                 if(time > self.touchexplode_time)
2721                 if(self.classname == "player")
2722                 if(self.deadflag == DEAD_NO)
2723                 if not(IS_INDEPENDENT_PLAYER(self))
2724                 FOR_EACH_PLAYER(other) if(self != other)
2725                 {
2726                         if(time > other.touchexplode_time)
2727                         if(other.deadflag == DEAD_NO)
2728                         if not(IS_INDEPENDENT_PLAYER(other))
2729                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2730                         {
2731                                 PlayerTouchExplode(self, other);
2732                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2733                         }
2734                 }
2735
2736                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2737                 {
2738                         vector dist;
2739
2740                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2741                         dist = self.prevorigin - self.origin;
2742                         dist_z = 0;
2743                         self.lms_traveled_distance += fabs(vlen(dist));
2744
2745                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2746                         {
2747                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2748                                 self.lms_traveled_distance = 0;
2749                         }
2750
2751                         if(time > self.lms_nextcheck)
2752                         {
2753                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2754                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2755                                 {
2756                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2757                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2758                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2759                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2760                                 }
2761                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2762                                 self.lms_traveled_distance = 0;
2763                         }
2764                 }
2765
2766                 self.prevorigin = self.origin;
2767
2768                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2769                 {
2770                         if (!self.crouch)
2771                         {
2772                                 self.crouch = TRUE;
2773                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2774                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2775                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2776                         }
2777                 }
2778                 else
2779                 {
2780                         if (self.crouch)
2781                         {
2782                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2783                                 if (!trace_startsolid)
2784                                 {
2785                                         self.crouch = FALSE;
2786                                         self.view_ofs = PL_VIEW_OFS;
2787                                         setsize (self, PL_MIN, PL_MAX);
2788                                 }
2789                         }
2790                 }
2791
2792                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2793                 {
2794                         if(self.bloodloss_timer < time)
2795                         {
2796                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2797                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2798                         }
2799                 }
2800
2801                 FixPlayermodel();
2802
2803                 GrapplingHookFrame();
2804
2805                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2806                 //if(frametime)
2807                 {
2808                         self.items &~= self.items_added;
2809
2810                         W_WeaponFrame();
2811
2812                         self.items_added = 0;
2813                         if(self.items & IT_JETPACK)
2814                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2815                                         self.items_added |= IT_FUEL;
2816
2817                         self.items |= self.items_added;
2818                 }
2819
2820                 player_regen();
2821
2822                 // rot nex charge to the charge limit
2823                 if(cvar("g_balance_nex_charge_rot_rate") && self.nex_charge > cvar("g_balance_nex_charge_limit") && self.nex_charge_rottime < time)
2824                         self.nex_charge = bound(cvar("g_balance_nex_charge_limit"), self.nex_charge - cvar("g_balance_nex_charge_rot_rate") * frametime / W_TICSPERFRAME, 1);
2825
2826                 if(frametime)
2827                         player_anim();
2828
2829                 if (g_minstagib)
2830                         minstagib_ammocheck();
2831
2832                 ctf_setstatus();
2833                 nexball_setstatus();
2834
2835                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2836
2837                 //self.angles_y=self.v_angle_y + 90;   // temp
2838         } else if(gameover) {
2839                 if (intermission_running)
2840                         IntermissionThink ();   // otherwise a button could be missed between
2841                 return;
2842         } else if(self.classname == "observer") {
2843                 ObserverThink();
2844         } else if(self.classname == "spectator") {
2845                 SpectatorThink();
2846         }
2847
2848         if(!zoomstate_set)
2849                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2850
2851         float oldspectatee_status;
2852         oldspectatee_status = self.spectatee_status;
2853         if(self.classname == "spectator")
2854                 self.spectatee_status = num_for_edict(self.enemy);
2855         else if(self.classname == "observer")
2856                 self.spectatee_status = num_for_edict(self);
2857         else
2858                 self.spectatee_status = 0;
2859         if(self.spectatee_status != oldspectatee_status)
2860         {
2861                 ClientData_Touch(self);
2862                 if(g_race || g_cts)
2863                         race_InitSpectator();
2864         }
2865
2866         if(self.teamkill_soundtime)
2867         if(time > self.teamkill_soundtime)
2868         {
2869                 self.teamkill_soundtime = 0;
2870
2871                 entity oldpusher, oldself;
2872
2873                 oldself = self; self = self.teamkill_soundsource;
2874                 oldpusher = self.pusher; self.pusher = oldself;
2875
2876                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2877
2878                 self.pusher = oldpusher;
2879                 self = oldself;
2880         }
2881
2882         if(self.taunt_soundtime)
2883         if(time > self.taunt_soundtime)
2884         {
2885                 self.taunt_soundtime = 0;
2886                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2887         }
2888
2889         target_voicescript_next(self);
2890 }
2891
2892 float isInvisibleString(string s)
2893 {
2894         float i, n, c;
2895         s = strdecolorize(s);
2896         for((i = 0), (n = strlen(s)); i < n; ++i)
2897         {
2898                 c = str2chr(s, i);
2899                 switch(c)
2900                 {
2901                         case 0:
2902                         case 32: // space
2903                                 break;
2904                         case 192: // charmap space
2905                                 if (!cvar("utf8_enable"))
2906                                         break;
2907                                 return FALSE;
2908                         case 160: // space in unicode fonts
2909                         case 0xE000 + 192: // utf8 charmap space
2910                                 if (cvar("utf8_enable"))
2911                                         break;
2912                         default:
2913                                 return FALSE;
2914                 }
2915         }
2916         return TRUE;
2917 }
2918
2919 /*
2920 =============
2921 PlayerPostThink
2922
2923 Called every frame for each client after the physics are run
2924 =============
2925 */
2926 .float idlekick_lasttimeleft;
2927 .entity showheadshotbbox;
2928 void showheadshotbbox_think()
2929 {
2930         if(self.owner.showheadshotbbox != self)
2931         {
2932                 remove(self);
2933                 return;
2934         }
2935         self.nextthink = time;
2936         setorigin(self, self.owner.origin);
2937         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2938 }
2939 void PlayerPostThink (void)
2940 {
2941         // Savage: Check for nameless players
2942         if (isInvisibleString(self.netname)) {
2943                 self.netname = "Player";
2944                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2945         }
2946
2947         // send the clients accuracy stats to the client
2948         if(self.stat_count > 0)
2949         if(frametime)
2950         {
2951                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2952                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2953                 self.stat_count -= 1;
2954         }
2955
2956         if(sv_maxidle && frametime)
2957         {
2958                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2959                 float timeleft;
2960                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2961                 if(timeleft <= 0)
2962                 {
2963                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2964                         AnnounceTo(self, "terminated");
2965                         dropclient(self);
2966                         return;
2967                 }
2968                 else if(timeleft <= 10)
2969                 {
2970                         if(timeleft != self.idlekick_lasttimeleft)
2971                         {
2972                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2973                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2974                         }
2975                 }
2976                 else
2977                 {
2978                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2979                 }
2980                 self.idlekick_lasttimeleft = timeleft;
2981         }
2982
2983 #ifdef TETRIS
2984         if(self.impulse == 100)
2985                 ImpulseCommands();
2986         if (TetrisPostFrame())
2987                 return;
2988 #endif
2989
2990         CheatFrame();
2991
2992         if(self.classname == "player") {
2993                 CheckRules_Player();
2994                 UpdateChatBubble();
2995                 UpdateTeamBubble();
2996                 if (self.impulse)
2997                         ImpulseCommands();
2998                 if (intermission_running)
2999                         return;         // intermission or finale
3000                 GetPressedKeys();
3001         } else if (self.classname == "observer") {
3002                 //do nothing
3003         } else if (self.classname == "spectator") {
3004                 //do nothing
3005         }
3006
3007         /*
3008         float i;
3009         for(i = 0; i < 1000; ++i)
3010         {
3011                 vector end;
3012                 end = self.origin + '0 0 1024' + 512 * randomvec();
3013                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3014                 if(trace_fraction < 1)
3015                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3016                 {
3017                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3018                         break;
3019                 }
3020         }
3021         */
3022
3023         Arena_Warmup();
3024
3025         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3026
3027         if(self.waypointsprite_attachedforcarrier)
3028                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3029
3030         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3031         {
3032                 if(!self.showheadshotbbox)
3033                 {
3034                         self.showheadshotbbox = spawn();
3035                         self.showheadshotbbox.classname = "headshotbbox";
3036                         self.showheadshotbbox.owner = self;
3037                         self.showheadshotbbox.think = showheadshotbbox_think;
3038                         self.showheadshotbbox.nextthink = time;
3039                         self = self.showheadshotbbox;
3040                         self.think();
3041                         self = self.owner;
3042                 }
3043         }
3044         else
3045         {
3046                 if(self.showheadshotbbox)
3047                         remove(self.showheadshotbbox);
3048         }
3049
3050         playerdemo_write();
3051
3052         if((g_cts || g_race) && self.cvar_cl_allow_uid2name)
3053         {
3054                 if(!self.stored_netname)
3055                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3056                 if(self.stored_netname != self.netname)
3057                 {
3058                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3059                         strunzone(self.stored_netname);
3060                         self.stored_netname = strzone(self.netname);
3061                 }
3062         }
3063
3064         /*
3065         if(g_race)
3066                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3067         */
3068 }