qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418                 vehicles_exit(VHEF_RELESE);
 419
 420         WaypointSprite_PlayerDead();
 421
 422         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 423                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 424
 425         if(self.killcount != -666) {
 426                 if(g_lms) {
 427                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 428                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 429                         else
 430                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 431                 } else
 432                         bprint ("^4", self.netname, "^4 is spectating now\n");
 433
 434                 if(self.just_joined == FALSE) {
 435                         LogTeamchange(self.playerid, -1, 4);
 436                 } else
 437                         self.just_joined = FALSE;
 438         }
 439
 440         PlayerScore_Clear(self); // clear scores when needed
 441
 442         accuracy_resend(self);
 443
 444         self.spectatortime = time;
 445
 446         self.classname = "observer";
 447         self.iscreature = FALSE;
 448         self.teleportable = TELEPORT_SIMPLE;
 449         self.damagedbycontents = FALSE;
 450         self.health = -666;
 451         self.takedamage = DAMAGE_NO;
 452         self.solid = SOLID_NOT;
 453         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 454         self.flags = FL_CLIENT | FL_NOTARGET;
 455         self.armorvalue = 666;
 456         self.effects = 0;
 457         self.armorvalue = autocvar_g_balance_armor_start;
 458         self.pauserotarmor_finished = 0;
 459         self.pauserothealth_finished = 0;
 460         self.pauseregen_finished = 0;
 461         self.damageforcescale = 0;
 462         self.death_time = 0;
 463         self.respawn_time = 0;
 464         self.alpha = 0;
 465         self.scale = 0;
 466         self.fade_time = 0;
 467         self.pain_frame = 0;
 468         self.pain_finished = 0;
 469         self.strength_finished = 0;
 470         self.invincible_finished = 0;
 471         self.superweapons_finished = 0;
 472         self.pushltime = 0;
 473         self.istypefrag = 0;
 474         self.think = func_null;
 475         self.nextthink = 0;
 476         self.hook_time = 0;
 477         self.runes = 0;
 478         self.deadflag = DEAD_NO;
 479         self.angles = spot.angles;
 480         self.angles_z = 0;
 481         self.fixangle = TRUE;
 482         self.crouch = FALSE;
 483
 484         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 485         self.prevorigin = self.origin;
 486         self.items = 0;
 487         WEPSET_CLEAR_E(self);
 488         self.model = "";
 489         FixPlayermodel();
 490         setmodel(self, "null");
 491         self.drawonlytoclient = self;
 492
 493         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 494         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 495
 496         self.weapon = 0;
 497         self.weaponname = "";
 498         self.switchingweapon = 0;
 499         self.weaponmodel = "";
 500         self.weaponentity = world;
 501         self.exteriorweaponentity = world;
 502         self.killcount = -666;
 503         self.velocity = '0 0 0';
 504         self.avelocity = '0 0 0';
 505         self.punchangle = '0 0 0';
 506         self.punchvector = '0 0 0';
 507         self.oldvelocity = self.velocity;
 508         self.fire_endtime = -1;
 509
 510         if(g_arena)
 511         {
 512                 if(self.version_mismatch)
 513                 {
 514                         Spawnqueue_Unmark(self);
 515                         Spawnqueue_Remove(self);
 516                 }
 517                 else
 518                 {
 519                         Spawnqueue_Insert(self);
 520                 }
 521         }
 522         else if(g_lms)
 523         {
 524                 // Only if the player cannot play at all
 525                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 526                         self.frags = FRAGS_SPECTATOR;
 527                 else
 528                         self.frags = FRAGS_LMS_LOSER;
 529         }
 530         else if(g_ca)
 531         {
 532                 if(self.caplayer)
 533                         self.frags = FRAGS_LMS_LOSER;
 534                 else
 535                         self.frags = FRAGS_SPECTATOR;
 536         }
 537         else
 538                 self.frags = FRAGS_SPECTATOR;
 539 }
 540
 541 .float model_randomizer;
 542 void FixPlayermodel()
 543 {
 544         string defaultmodel;
 545         float defaultskin, chmdl, oldskin, n, i;
 546         vector m1, m2;
 547
 548         defaultmodel = "";
 549         defaultskin = 0;
 550         chmdl = FALSE;
 551
 552         if(autocvar_sv_defaultcharacter == 1)
 553         {
 554                 if(teamplay)
 555                 {
 556                         string s;
 557                         s = Team_ColorNameLowerCase(self.team);
 558                         if(s != "neutral")
 559                         {
 560                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 561                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 562                         }
 563                 }
 564
 565                 if(defaultmodel == "")
 566                 {
 567                         defaultmodel = autocvar_sv_defaultplayermodel;
 568                         defaultskin = autocvar_sv_defaultplayerskin;
 569                 }
 570
 571                 n = tokenize_console(defaultmodel);
 572                 if(n > 0)
 573                         defaultmodel = argv(floor(n * self.model_randomizer));
 574
 575                 i = strstrofs(defaultmodel, ":", 0);
 576                 if(i >= 0)
 577                 {
 578                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 579                         defaultmodel = substring(defaultmodel, 0, i);
 580                 }
 581         }
 582
 583         if(defaultmodel != "")
 584         {
 585                 if (defaultmodel != self.model)
 586                 {
 587                         m1 = self.mins;
 588                         m2 = self.maxs;
 589                         setplayermodel (self, defaultmodel);
 590                         setsize (self, m1, m2);
 591                         chmdl = TRUE;
 592                 }
 593
 594                 oldskin = self.skin;
 595                 self.skin = defaultskin;
 596         } else {
 597                 if (self.playermodel != self.model || self.playermodel == "")
 598                 {
 599                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 600                         m1 = self.mins;
 601                         m2 = self.maxs;
 602                         setplayermodel (self, self.playermodel);
 603                         setsize (self, m1, m2);
 604                         chmdl = TRUE;
 605                 }
 606
 607                 oldskin = self.skin;
 608                 self.skin = stof(self.playerskin);
 609         }
 610
 611         if(chmdl || oldskin != self.skin)
 612                 self.species = player_getspecies(); // model or skin has changed
 613
 614         if(!teamplay)
 615                 if(strlen(autocvar_sv_defaultplayercolors))
 616                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 617                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 618 }
 619
 620 void PlayerTouchExplode(entity p1, entity p2)
 621 {
 622         vector org;
 623         org = (p1.origin + p2.origin) * 0.5;
 624         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 625
 626         te_explosion(org);
 627
 628         entity e;
 629         e = spawn();
 630         setorigin(e, org);
 631         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 632         remove(e);
 633 }
 634
 635 /*
 636 =============
 637 PutClientInServer
 638
 639 Called when a client spawns in the server
 640 =============
 641 */
 642
 643 void PutClientInServer (void)
 644 {
 645         if(clienttype(self) == CLIENTTYPE_BOT)
 646         {
 647                 self.classname = "player";
 648                 if(g_ca)
 649                         self.caplayer = 1;
 650         }
 651         else if(clienttype(self) == CLIENTTYPE_REAL)
 652         {
 653                 msg_entity = self;
 654                 WriteByte(MSG_ONE, SVC_SETVIEW);
 655                 WriteEntity(MSG_ONE, self);
 656         }
 657
 658         // reset player keys
 659         self.itemkeys = 0;
 660
 661         // player is dead and becomes observer
 662         // FIXME fix LMS scoring for new system
 663         if(g_lms)
 664         {
 665                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 666                         self.classname = "observer";
 667         }
 668
 669         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 670                 self.classname = "observer";
 671
 672         if(gameover)
 673                 self.classname = "observer";
 674
 675         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 676                 entity spot, oldself;
 677                 float j;
 678
 679                 accuracy_resend(self);
 680
 681                 if(self.team < 0)
 682                         JoinBestTeam(self, FALSE, TRUE);
 683
 684                 race_PreSpawn();
 685
 686                 spot = SelectSpawnPoint (FALSE);
 687                 if(!spot)
 688                 {
 689                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 690                         return; // spawn failed
 691                 }
 692
 693                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 694
 695                 self.classname = "player";
 696                 self.wasplayer = TRUE;
 697                 self.iscreature = TRUE;
 698                 self.teleportable = TELEPORT_NORMAL;
 699                 self.damagedbycontents = TRUE;
 700                 self.movetype = MOVETYPE_WALK;
 701                 self.solid = SOLID_SLIDEBOX;
 702                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 703                 if(autocvar_g_playerclip_collisions)
 704                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 705                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 707                 self.frags = FRAGS_PLAYER;
 708                 if(INDEPENDENT_PLAYERS)
 709                         MAKE_INDEPENDENT_PLAYER(self);
 710                 self.flags = FL_CLIENT;
 711                 if(autocvar__notarget)
 712                         self.flags |= FL_NOTARGET;
 713                 self.takedamage = DAMAGE_AIM;
 714                 if(g_minstagib)
 715                         self.effects = EF_FULLBRIGHT;
 716                 else
 717                         self.effects = 0;
 718                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 719                 self.air_finished = time + 12;
 720                 self.dmg = 2;
 721                 if(autocvar_g_balance_nex_charge)
 722                 {
 723                         if(autocvar_g_balance_nex_secondary_chargepool)
 724                                 self.nex_chargepool_ammo = 1;
 725                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 726                 }
 727
 728                 if(inWarmupStage)
 729                 {
 730                         self.ammo_shells = warmup_start_ammo_shells;
 731                         self.ammo_nails = warmup_start_ammo_nails;
 732                         self.ammo_rockets = warmup_start_ammo_rockets;
 733                         self.ammo_cells = warmup_start_ammo_cells;
 734                         self.ammo_fuel = warmup_start_ammo_fuel;
 735                         self.health = warmup_start_health;
 736                         self.armorvalue = warmup_start_armorvalue;
 737                         WEPSET_COPY_EA(self, warmup_start_weapons);
 738                 }
 739                 else
 740                 {
 741                         self.ammo_shells = start_ammo_shells;
 742                         self.ammo_nails = start_ammo_nails;
 743                         self.ammo_rockets = start_ammo_rockets;
 744                         self.ammo_cells = start_ammo_cells;
 745                         self.ammo_fuel = start_ammo_fuel;
 746                         self.health = start_health;
 747                         self.armorvalue = start_armorvalue;
 748                         WEPSET_COPY_EA(self, start_weapons);
 749                 }
 750
 751                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 752                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 753                 else
 754                         self.superweapons_finished = 0;
 755
 756                 if(g_weaponarena_random)
 757                 {
 758                         if(g_weaponarena_random_with_laser)
 759                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 760                         W_RandomWeapons(self, g_weaponarena_random);
 761                         if(g_weaponarena_random_with_laser)
 762                                 WEPSET_OR_EW(self, WEP_LASER);
 763                 }
 764
 765                 self.items = start_items;
 766
 767                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 768                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 769                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 770                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 771                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 772                 //extend the pause of rotting if client was reset at the beginning of the countdown
 773                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 774                         self.spawnshieldtime += game_starttime - time;
 775                         self.pauserotarmor_finished += game_starttime - time;
 776                         self.pauserothealth_finished += game_starttime - time;
 777                         self.pauseregen_finished += game_starttime - time;
 778                 }
 779                 self.damageforcescale = 2;
 780                 self.death_time = 0;
 781                 self.respawn_time = 0;
 782                 self.scale = 0;
 783                 self.fade_time = 0;
 784                 self.pain_frame = 0;
 785                 self.pain_finished = 0;
 786                 self.strength_finished = 0;
 787                 self.invincible_finished = 0;
 788                 self.pushltime = 0;
 789                 // players have no think function
 790                 self.think = func_null;
 791                 self.nextthink = 0;
 792                 self.hook_time = 0;
 793                 self.dmg_team = 0;
 794                 self.ballistics_density = autocvar_g_ballistics_density_player;
 795
 796                 self.metertime = 0;
 797
 798                 self.runes = 0;
 799
 800                 self.deadflag = DEAD_NO;
 801
 802                 self.angles = spot.angles;
 803
 804                 self.angles_z = 0; // never spawn tilted even if the spot says to
 805                 self.fixangle = TRUE; // turn this way immediately
 806                 self.velocity = '0 0 0';
 807                 self.avelocity = '0 0 0';
 808                 self.punchangle = '0 0 0';
 809                 self.punchvector = '0 0 0';
 810                 self.oldvelocity = self.velocity;
 811                 self.fire_endtime = -1;
 812
 813                 msg_entity = self;
 814                 WRITESPECTATABLE_MSG_ONE({
 815                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 816                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 817                 });
 818
 819                 self.model = "";
 820                 FixPlayermodel();
 821                 self.drawonlytoclient = world;
 822
 823                 self.crouch = FALSE;
 824                 self.view_ofs = PL_VIEW_OFS;
 825                 setsize (self, PL_MIN, PL_MAX);
 826                 self.spawnorigin = spot.origin;
 827                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 828                 // don't reset back to last position, even if new position is stuck in solid
 829                 self.oldorigin = self.origin;
 830                 self.prevorigin = self.origin;
 831                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 832                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 833         self.hud = HUD_NORMAL;
 834
 835                 if(g_arena)
 836                 {
 837                         Spawnqueue_Remove(self);
 838                         Spawnqueue_Mark(self);
 839                 }
 840                 else if(g_ca)
 841                         self.caplayer = 1;
 842
 843                 self.event_damage = PlayerDamage;
 844
 845                 self.bot_attack = TRUE;
 846
 847                 self.statdraintime = time + 5;
 848                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 849
 850                 if(self.killcount == -666) {
 851                         PlayerScore_Clear(self);
 852                         self.killcount = 0;
 853                 }
 854
 855                 CL_SpawnWeaponentity();
 856                 self.alpha = default_player_alpha;
 857                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 858                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 859
 860                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 861                 self.lms_traveled_distance = 0;
 862                 self.speedrunning = FALSE;
 863
 864                 race_PostSpawn(spot);
 865
 866                 //stuffcmd(self, "chase_active 0");
 867                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 868
 869                 if(g_assault) {
 870                         if(self.team == assault_attacker_team)
 871                                 centerprint(self, "You are attacking!");
 872                         else
 873                                 centerprint(self, "You are defending!");
 874                 }
 875
 876                 target_voicescript_clear(self);
 877
 878                 // reset fields the weapons may use
 879                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 880                 {
 881                         weapon_action(j, WR_RESETPLAYER);
 882
 883                         // all weapons must be fully loaded when we spawn
 884                         entity e;
 885                         e = get_weaponinfo(j);
 886                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 887                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 888                 }
 889
 890                 oldself = self;
 891                 self = spot;
 892                         activator = oldself;
 893                                 string s;
 894                                 s = self.target;
 895                                 self.target = string_null;
 896                                 SUB_UseTargets();
 897                                 self.target = s;
 898                         activator = world;
 899                 self = oldself;
 900
 901                 spawn_spot = spot;
 902                 MUTATOR_CALLHOOK(PlayerSpawn);
 903
 904                 if(autocvar_spawn_debug)
 905                 {
 906                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 907                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 908                 }
 909
 910                 self.switchweapon = w_getbestweapon(self);
 911                 self.cnt = -1; // W_LastWeapon will not complain
 912                 self.weapon = 0;
 913                 self.weaponname = "";
 914                 self.switchingweapon = 0;
 915
 916                 if(!self.alivetime)
 917                         self.alivetime = time;
 918
 919                 antilag_clear(self);
 920
 921                 if (autocvar_g_spawnsound)
 922                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 923         } else if(self.classname == "observer") {
 924                 PutObserverInServer ();
 925         }
 926 }
 927
 928 .float ebouncefactor, ebouncestop; // electro's values
 929 // TODO do we need all these fields, or should we stop autodetecting runtime
 930 // changes and just have a console command to update this?
 931 float ClientInit_SendEntity(entity to, float sf)
 932 {
 933         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 934         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 935         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 947         if(sv_foginterval && world.fog != "")
 948                 WriteString(MSG_ENTITY, world.fog);
 949         else
 950                 WriteString(MSG_ENTITY, "");
 951         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 952         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 953         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 954         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 955         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 956         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 957         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 958         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 959         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 960         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 961         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 962         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 963         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 964         return TRUE;
 965 }
 966
 967 void ClientInit_CheckUpdate()
 968 {
 969         self.nextthink = time;
 970         if(self.count != autocvar_g_balance_armor_blockpercent)
 971         {
 972                 self.count = autocvar_g_balance_armor_blockpercent;
 973                 self.SendFlags |= 1;
 974         }
 975         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 976         {
 977                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 978                 self.SendFlags |= 1;
 979         }
 980         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 981         {
 982                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 983                 self.SendFlags |= 1;
 984         }
 985         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 986         {
 987                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 988                 self.SendFlags |= 1;
 989         }
 990         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 991         {
 992                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 993                 self.SendFlags |= 1;
 994         }
 995         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 996         {
 997                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 998                 self.SendFlags |= 1;
 999         }
1000 }
1001
1002 void ClientInit_Spawn()
1003 {
1004         entity o;
1005         entity e;
1006         e = spawn();
1007         e.classname = "clientinit";
1008         e.think = ClientInit_CheckUpdate;
1009         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1010
1011         o = self;
1012         self = e;
1013         ClientInit_CheckUpdate();
1014         self = o;
1015 }
1016
1017 /*
1018 =============
1019 SetNewParms
1020 =============
1021 */
1022 void SetNewParms (void)
1023 {
1024         // initialize parms for a new player
1025         parm1 = -(86400 * 366);
1026 }
1027
1028 /*
1029 =============
1030 SetChangeParms
1031 =============
1032 */
1033 void SetChangeParms (void)
1034 {
1035         // save parms for level change
1036         parm1 = self.parm_idlesince - time;
1037 }
1038
1039 /*
1040 =============
1041 DecodeLevelParms
1042 =============
1043 */
1044 void DecodeLevelParms (void)
1045 {
1046         // load parms
1047         self.parm_idlesince = parm1;
1048         if(self.parm_idlesince == -(86400 * 366))
1049                 self.parm_idlesince = time;
1050
1051         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1052         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1053 }
1054
1055 /*
1056 =============
1057 ClientKill
1058
1059 Called when a client types 'kill' in the console
1060 =============
1061 */
1062
1063 .float clientkill_nexttime;
1064 void ClientKill_Now_TeamChange()
1065 {
1066         if(self.killindicator_teamchange == -1)
1067         {
1068                 JoinBestTeam( self, FALSE, TRUE );
1069         }
1070         else if(self.killindicator_teamchange == -2)
1071         {
1072                 if(g_ca)
1073                         self.caplayer = 0;
1074                 if(blockSpectators)
1075                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1076                 PutObserverInServer();
1077         }
1078         else
1079                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1080 }
1081
1082 void ClientKill_Now()
1083 {
1084         if(self.vehicle)
1085         {
1086             vehicles_exit(VHEF_RELESE);
1087             if(!self.killindicator_teamchange)
1088             {
1089             self.vehicle_health = -1;
1090             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1091             }
1092         }
1093
1094         if(self.killindicator && !wasfreed(self.killindicator))
1095                 remove(self.killindicator);
1096
1097         self.killindicator = world;
1098
1099         if(self.killindicator_teamchange)
1100                 ClientKill_Now_TeamChange();
1101
1102         // in any case:
1103         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1104
1105         // now I am sure the player IS dead
1106 }
1107 void KillIndicator_Think()
1108 {
1109         if (gameover)
1110         {
1111                 self.owner.killindicator = world;
1112                 remove(self);
1113                 return;
1114         }
1115
1116         if (self.owner.alpha < 0 && !self.owner.vehicle)
1117         {
1118                 self.owner.killindicator = world;
1119                 remove(self);
1120                 return;
1121         }
1122
1123         if(self.cnt <= 0)
1124         {
1125                 self = self.owner;
1126                 ClientKill_Now(); // no oldself needed
1127                 return;
1128         }
1129     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1130     {
1131         self.nextthink = time + 1;
1132         self.cnt -= 1;
1133     }
1134         else
1135         {
1136                 if(self.cnt <= 10)
1137                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1138                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1139                 {
1140                         if(self.cnt <= 10)
1141                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1142                 }
1143                 self.nextthink = time + 1;
1144                 self.cnt -= 1;
1145         }
1146 }
1147
1148 float clientkilltime;
1149 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1150 {
1151         float killtime;
1152         float starttime;
1153         entity e;
1154
1155         if (gameover)
1156                 return;
1157
1158         killtime = autocvar_g_balance_kill_delay;
1159
1160         if(g_race_qualifying || g_cts)
1161                 killtime = 0;
1162
1163     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1164     {
1165                 remove(self.killindicator);
1166                 self.killindicator = world;
1167
1168         ClientKill_Now(); // allow instant kill in this case
1169         return;
1170     }
1171
1172         self.killindicator_teamchange = targetteam;
1173
1174     if(!self.killindicator)
1175         {
1176                 if(self.deadflag == DEAD_NO)
1177                 {
1178                         killtime = max(killtime, self.clientkill_nexttime - time);
1179                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1180                 }
1181
1182                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1183                 {
1184                         ClientKill_Now();
1185                 }
1186                 else
1187                 {
1188                         starttime = max(time, clientkilltime);
1189
1190                         self.killindicator = spawn();
1191                         self.killindicator.owner = self;
1192                         self.killindicator.scale = 0.5;
1193                         setattachment(self.killindicator, self, "");
1194                         setorigin(self.killindicator, '0 0 52');
1195                         self.killindicator.think = KillIndicator_Think;
1196                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1197                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1198                         self.killindicator.cnt = ceil(killtime);
1199                         self.killindicator.count = bound(0, ceil(killtime), 10);
1200                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1201
1202                         for(e = world; (e = find(e, classname, "body")) != world; )
1203                         {
1204                                 if(e.enemy != self)
1205                                         continue;
1206                                 e.killindicator = spawn();
1207                                 e.killindicator.owner = e;
1208                                 e.killindicator.scale = 0.5;
1209                                 setattachment(e.killindicator, e, "");
1210                                 setorigin(e.killindicator, '0 0 52');
1211                                 e.killindicator.think = KillIndicator_Think;
1212                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1213                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1214                                 e.killindicator.cnt = ceil(killtime);
1215                         }
1216                         self.lip = 0;
1217                 }
1218         }
1219         if(self.killindicator)
1220         {
1221                 if(targetteam == 0) // just die
1222                 {
1223                         self.killindicator.colormod = '0 0 0';
1224                         if(clienttype(self) == CLIENTTYPE_REAL)
1225                         if(self.killindicator.cnt > 0)
1226                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1227                 }
1228                 else if(targetteam == -1) // auto
1229                 {
1230                         self.killindicator.colormod = '0 1 0';
1231                         if(clienttype(self) == CLIENTTYPE_REAL)
1232                         if(self.killindicator.cnt > 0)
1233                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1234                 }
1235                 else if(targetteam == -2) // spectate
1236                 {
1237                         self.killindicator.colormod = '0.5 0.5 0.5';
1238                         if(clienttype(self) == CLIENTTYPE_REAL)
1239                         if(self.killindicator.cnt > 0)
1240                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1241                 }
1242                 else
1243                 {
1244                         self.killindicator.colormod = TeamColor(targetteam);
1245                         if(clienttype(self) == CLIENTTYPE_REAL)
1246                         if(self.killindicator.cnt > 0)
1247                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1248                 }
1249         }
1250
1251 }
1252
1253 void ClientKill (void)
1254 {
1255         if (gameover)
1256                 return;
1257
1258         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1259         {
1260                 // do nothing
1261         }
1262     else if(self.freezetag_frozen)
1263     {
1264         // do nothing
1265     }
1266         else
1267                 ClientKill_TeamChange(0);
1268 }
1269
1270 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1271 {
1272     e.killindicator = spawn();
1273     e.killindicator.owner = e;
1274     e.killindicator.think = KillIndicator_Think;
1275     e.killindicator.nextthink = time + (e.lip) * 0.05;
1276     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1277     e.killindicator.health = 1; // this is used to indicate that it should be silent
1278     e.lip = 0;
1279 }
1280
1281 void FixClientCvars(entity e)
1282 {
1283         // send prediction settings to the client
1284         stuffcmd(e, "\nin_bindmap 0 0\n");
1285         if(g_race || g_cts)
1286                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1287         if(autocvar_g_antilag == 3) // client side hitscan
1288                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1289         if(sv_gentle)
1290                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1291         /*
1292          * we no longer need to stuff this. Remove this comment block if you feel
1293          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1294         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1295         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1296         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1297         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1298         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1299         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1300         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1301         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1302         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1303         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1304         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1305         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1306         stuffcmd(e, "cl_movement_edgefriction 1\n");
1307          */
1308 }
1309
1310 float PlayerInIDList(entity p, string idlist)
1311 {
1312         float n, i;
1313         string s;
1314
1315         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1316         if not(p.crypto_idfp)
1317                 return 0;
1318
1319         // this function allows abbreviated player IDs too!
1320         n = tokenize_console(idlist);
1321         for(i = 0; i < n; ++i)
1322         {
1323                 s = argv(i);
1324                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1325                         return 1;
1326         }
1327
1328         return 0;
1329 }
1330
1331 /*
1332 =============
1333 ClientConnect
1334
1335 Called when a client connects to the server
1336 =============
1337 */
1338 string ColoredTeamName(float t);
1339 void DecodeLevelParms (void);
1340 //void dom_player_join_team(entity pl);
1341 void set_dom_state(entity e);
1342 void ClientConnect (void)
1343 {
1344         float t;
1345
1346         if(self.flags & FL_CLIENT)
1347         {
1348                 print("Warning: ClientConnect, but already connected!\n");
1349                 return;
1350         }
1351
1352         if(Ban_MaybeEnforceBanOnce(self))
1353                 return;
1354
1355         DecodeLevelParms();
1356
1357 #ifdef WATERMARK
1358         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK, "\n"));
1359 #endif
1360
1361         self.classname = "player_joining";
1362
1363         self.flags = FL_CLIENT;
1364         self.version_nagtime = time + 10 + random() * 10;
1365
1366         if(player_count<0)
1367         {
1368                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1369                 player_count = 0;
1370         }
1371
1372         PlayerScore_Attach(self);
1373         ClientData_Attach();
1374         accuracy_init(self);
1375
1376         bot_clientconnect();
1377
1378         playerdemo_init();
1379
1380         anticheat_init();
1381
1382         race_PreSpawnObserver();
1383
1384         //if(g_domination)
1385         //      dom_player_join_team(self);
1386
1387         // identify the right forced team
1388         if(autocvar_g_campaign)
1389         {
1390                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1391                 {
1392                         switch(autocvar_g_campaign_forceteam)
1393                         {
1394                                 case 1: self.team_forced = COLOR_TEAM1; break;
1395                                 case 2: self.team_forced = COLOR_TEAM2; break;
1396                                 case 3: self.team_forced = COLOR_TEAM3; break;
1397                                 case 4: self.team_forced = COLOR_TEAM4; break;
1398                                 default: self.team_forced = 0;
1399                         }
1400                 }
1401         }
1402         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1403                 self.team_forced = COLOR_TEAM1;
1404         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1405                 self.team_forced = COLOR_TEAM2;
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1407                 self.team_forced = COLOR_TEAM3;
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1409                 self.team_forced = COLOR_TEAM4;
1410         else if(autocvar_g_forced_team_otherwise == "red")
1411                 self.team_forced = COLOR_TEAM1;
1412         else if(autocvar_g_forced_team_otherwise == "blue")
1413                 self.team_forced = COLOR_TEAM2;
1414         else if(autocvar_g_forced_team_otherwise == "yellow")
1415                 self.team_forced = COLOR_TEAM3;
1416         else if(autocvar_g_forced_team_otherwise == "pink")
1417                 self.team_forced = COLOR_TEAM4;
1418         else if(autocvar_g_forced_team_otherwise == "spectate")
1419                 self.team_forced = -1;
1420         else if(autocvar_g_forced_team_otherwise == "spectator")
1421                 self.team_forced = -1;
1422         else
1423                 self.team_forced = 0;
1424
1425         if(!teamplay)
1426                 if(self.team_forced > 0)
1427                         self.team_forced = 0;
1428
1429         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1430
1431         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1432                 self.classname = "observer";
1433         } else {
1434                 if(teamplay)
1435                 {
1436                         if(autocvar_g_balance_teams)
1437                         {
1438                                 self.classname = "player";
1439                                 campaign_bots_may_start = 1;
1440                         }
1441                         else
1442                         {
1443                                 self.classname = "observer"; // do it anyway
1444                         }
1445                 }
1446                 else
1447                 {
1448                         self.classname = "player";
1449                         campaign_bots_may_start = 1;
1450                 }
1451         }
1452
1453         self.playerid = (playerid_last = playerid_last + 1);
1454
1455         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1456
1457     if(clienttype(self) == CLIENTTYPE_BOT)
1458         PlayerStats_AddPlayer(self);
1459
1460         if(autocvar_sv_eventlog)
1461                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1462
1463         LogTeamchange(self.playerid, self.team, 1);
1464
1465         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1466
1467         self.netname_previous = strzone(self.netname);
1468
1469         bprint("^4", self.netname, "^4 connected");
1470
1471         if(self.classname != "observer" && (g_domination || g_ctf))
1472                 bprint(" and joined the ", ColoredTeamName(self.team));
1473
1474         bprint("\n");
1475
1476         stuffcmd(self, strcat(clientstuff, "\n"));
1477         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1478
1479         FixClientCvars(self);
1480
1481         // spawnfunc_waypoint sprites
1482         WaypointSprite_InitClient(self);
1483
1484         // Wazat's grappling hook
1485         SetGrappleHookBindings();
1486
1487         // get version info from player
1488         stuffcmd(self, "cmd clientversion $gameversion\n");
1489
1490         // get other cvars from player
1491         GetCvars(0);
1492
1493         // notify about available teams
1494         if(teamplay)
1495         {
1496                 CheckAllowedTeams(self);
1497                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1498                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1499         }
1500         else
1501                 stuffcmd(self, "set _teams_available 0\n");
1502
1503         if(g_arena || g_ca)
1504         {
1505                 self.classname = "observer";
1506                 if(g_arena)
1507                         Spawnqueue_Insert(self);
1508         }
1509
1510         attach_entcs();
1511
1512         bot_relinkplayerlist();
1513
1514         self.spectatortime = time;
1515         if(blockSpectators)
1516         {
1517                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1518         }
1519
1520         self.jointime = time;
1521         self.allowed_timeouts = autocvar_sv_timeout_number;
1522
1523         if(clienttype(self) == CLIENTTYPE_REAL)
1524         {
1525                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1526                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1527         }
1528
1529         if(g_lms)
1530         {
1531                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1532                 {
1533                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1534                         self.frags = FRAGS_SPECTATOR;
1535                 }
1536         }
1537
1538         if(!sv_foginterval && world.fog != "")
1539                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1540
1541         SoundEntity_Attach(self);
1542
1543         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1544         {
1545                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1546                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1547         }
1548         else
1549                 self.hitplotfh = -1;
1550
1551         if(g_race || g_cts) {
1552                 string rr;
1553                 if(g_cts)
1554                         rr = CTS_RECORD;
1555                 else
1556                         rr = RACE_RECORD;
1557
1558                 msg_entity = self;
1559                 race_send_recordtime(MSG_ONE);
1560                 race_send_speedaward(MSG_ONE);
1561
1562                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1563                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1564                 race_send_speedaward_alltimebest(MSG_ONE);
1565
1566                 float i;
1567                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1568                         race_SendRankings(i, 0, 0, MSG_ONE);
1569                 }
1570         }
1571         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1572                 send_CSQC_teamnagger();
1573
1574         if (g_domination)
1575                 set_dom_state(self);
1576
1577         CheatInitClient();
1578
1579         if(!autocvar_g_campaign)
1580                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1581
1582         CSQCMODEL_AUTOINIT();
1583
1584         self.model_randomizer = random();
1585
1586     if(clienttype(self) != CLIENTTYPE_REAL)
1587         return;
1588
1589     sv_notice_join();
1590
1591     MUTATOR_CALLHOOK(ClientConnect);
1592 }
1593 /*
1594 =============
1595 ClientDisconnect
1596
1597 Called when a client disconnects from the server
1598 =============
1599 */
1600 .entity chatbubbleentity;
1601 void ReadyCount();
1602 void ClientDisconnect (void)
1603 {
1604         if(self.vehicle)
1605             vehicles_exit(VHEF_RELESE);
1606
1607         if not(self.flags & FL_CLIENT)
1608         {
1609                 print("Warning: ClientDisconnect without ClientConnect\n");
1610                 return;
1611         }
1612
1613         PlayerStats_AddGlobalInfo(self);
1614
1615         CheatShutdownClient();
1616
1617         if(self.hitplotfh >= 0)
1618         {
1619                 fclose(self.hitplotfh);
1620                 self.hitplotfh = -1;
1621         }
1622
1623         anticheat_report();
1624         anticheat_shutdown();
1625
1626         playerdemo_shutdown();
1627
1628         bot_clientdisconnect();
1629
1630         if(self.entcs)
1631                 detach_entcs();
1632
1633         if(autocvar_sv_eventlog)
1634                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1635         bprint ("^4",self.netname);
1636         bprint ("^4 disconnected\n");
1637
1638         SoundEntity_Detach(self);
1639
1640         DropAllRunes(self);
1641         MUTATOR_CALLHOOK(ClientDisconnect);
1642
1643         Portal_ClearAll(self);
1644
1645         RemoveGrapplingHook(self);
1646
1647         // Here, everything has been done that requires this player to be a client.
1648
1649         self.flags &~= FL_CLIENT;
1650
1651         if (self.chatbubbleentity)
1652                 remove (self.chatbubbleentity);
1653
1654         if (self.killindicator)
1655                 remove (self.killindicator);
1656
1657         WaypointSprite_PlayerGone();
1658
1659         bot_relinkplayerlist();
1660
1661         if(g_arena)
1662         {
1663                 Spawnqueue_Unmark(self);
1664                 Spawnqueue_Remove(self);
1665         }
1666
1667         accuracy_free(self);
1668         ClientData_Detach();
1669         PlayerScore_Detach(self);
1670
1671         if(self.netname_previous)
1672                 strunzone(self.netname_previous);
1673         if(self.clientstatus)
1674                 strunzone(self.clientstatus);
1675         if(self.weaponorder_byimpulse)
1676                 strunzone(self.weaponorder_byimpulse);
1677
1678         ClearPlayerSounds();
1679
1680         if(self.personal)
1681                 remove(self.personal);
1682
1683         self.playerid = 0;
1684         ReadyCount();
1685
1686         // free cvars
1687         GetCvars(-1);
1688 }
1689
1690 .float BUTTON_CHAT;
1691 void ChatBubbleThink()
1692 {
1693         self.nextthink = time;
1694         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1695         {
1696                 if(self.owner) // but why can that ever be world?
1697                         self.owner.chatbubbleentity = world;
1698                 remove(self);
1699                 return;
1700         }
1701         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1702 #ifdef TETRIS
1703                 || self.owner.tetris_on
1704 #endif
1705         )
1706                 self.model = self.mdl;
1707         else
1708                 self.model = "";
1709 }
1710
1711 void UpdateChatBubble()
1712 {
1713         if (self.alpha < 0)
1714                 return;
1715         // spawn a chatbubble entity if needed
1716         if (!self.chatbubbleentity)
1717         {
1718                 self.chatbubbleentity = spawn();
1719                 self.chatbubbleentity.owner = self;
1720                 self.chatbubbleentity.exteriormodeltoclient = self;
1721                 self.chatbubbleentity.think = ChatBubbleThink;
1722                 self.chatbubbleentity.nextthink = time;
1723                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1724                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1725                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1726                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1727                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1728                 self.chatbubbleentity.model = "";
1729                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1730         }
1731 }
1732
1733
1734 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1735 // added to the model skins
1736 /*void UpdateColorModHack()
1737 {
1738         float c;
1739         c = self.clientcolors & 15;
1740         // LordHavoc: only bothering to support white, green, red, yellow, blue
1741              if (!teamplay) self.colormod = '0 0 0';
1742         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1743         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1744         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1745         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1746         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1747         else self.colormod = '1 1 1';
1748 }*/
1749
1750 void respawn(void)
1751 {
1752         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1753         {
1754                 self.solid = SOLID_NOT;
1755                 self.takedamage = DAMAGE_NO;
1756                 self.movetype = MOVETYPE_FLY;
1757                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1758                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1759                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1760                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1761                 if(autocvar_g_respawn_ghosts_maxtime)
1762                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1763         }
1764
1765         CopyBody(1);
1766
1767         self.effects |= EF_NODRAW; // prevent another CopyBody
1768         PutClientInServer();
1769 }
1770
1771 void play_countdown(float finished, string samp)
1772 {
1773         if(clienttype(self) == CLIENTTYPE_REAL)
1774                 if(floor(finished - time - frametime) != floor(finished - time))
1775                         if(finished - time < 6)
1776                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1777 }
1778
1779 void player_powerups (void)
1780 {
1781         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1782         olditems = self.items;
1783
1784         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1785         {
1786                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1787                 self.modelflags |= MF_ROCKET;
1788         }
1789         else
1790         {
1791                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1792                 self.modelflags &~= MF_ROCKET;
1793         }
1794
1795         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1796
1797         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1798                 return;
1799
1800         Fire_ApplyDamage(self);
1801         Fire_ApplyEffect(self);
1802
1803         if (g_minstagib)
1804         {
1805                 self.effects |= EF_FULLBRIGHT;
1806
1807                 if (self.items & IT_STRENGTH)
1808                 {
1809                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1810                         if (time > self.strength_finished)
1811                         {
1812                                 self.alpha = default_player_alpha;
1813                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1814                                 self.items &~= IT_STRENGTH;
1815                                 sprint(self, "^3Invisibility has worn off\n");
1816                         }
1817                 }
1818                 else
1819                 {
1820                         if (time < self.strength_finished)
1821                         {
1822                                 self.alpha = g_minstagib_invis_alpha;
1823                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1824                                 self.items |= IT_STRENGTH;
1825                                 sprint(self, "^3You are invisible\n");
1826                         }
1827                 }
1828
1829                 if (self.items & IT_INVINCIBLE)
1830                 {
1831                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1832                         if (time > self.invincible_finished)
1833                         {
1834                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1835                                 sprint(self, "^3Speed has worn off\n");
1836                         }
1837                 }
1838                 else
1839                 {
1840                         if (time < self.invincible_finished)
1841                         {
1842                                 self.items = self.items | IT_INVINCIBLE;
1843                                 sprint(self, "^3You are on speed\n");
1844                         }
1845                 }
1846         }
1847         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1848         {
1849                 if (self.items & IT_STRENGTH)
1850                 {
1851                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1852                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1853                         if (time > self.strength_finished)
1854                         {
1855                                 self.items = self.items - (self.items & IT_STRENGTH);
1856                                 sprint(self, "^3Strength has worn off\n");
1857                         }
1858                 }
1859                 else
1860                 {
1861                         if (time < self.strength_finished)
1862                         {
1863                                 self.items = self.items | IT_STRENGTH;
1864                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1865                         }
1866                 }
1867                 if (self.items & IT_INVINCIBLE)
1868                 {
1869                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1870                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1871                         if (time > self.invincible_finished)
1872                         {
1873                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1874                                 sprint(self, "^3Shield has worn off\n");
1875                         }
1876                 }
1877                 else
1878                 {
1879                         if (time < self.invincible_finished)
1880                         {
1881                                 self.items = self.items | IT_INVINCIBLE;
1882                                 sprint(self, "^3Shield surrounds you\n");
1883                         }
1884                 }
1885                 if (self.items & IT_SUPERWEAPON)
1886                 {
1887                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1888                         {
1889                                 self.superweapons_finished = 0;
1890                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1891                                 sprint(self, "^3Superweapons have been lost\n");
1892                         }
1893                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1894                         {
1895                                 // don't let them run out
1896                         }
1897                         else
1898                         {
1899                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1900                                 if (time > self.superweapons_finished)
1901                                 {
1902                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1903                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1904                                         sprint(self, "^3Superweapons have broken down\n");
1905                                 }
1906                         }
1907                 }
1908                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1909                 {
1910                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1911                         {
1912                                 self.items = self.items | IT_SUPERWEAPON;
1913                                 sprint(self, "^3You now have a superweapon\n");
1914                         }
1915                         else
1916                         {
1917                                 self.superweapons_finished = 0;
1918                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1919                         }
1920                 }
1921                 else
1922                 {
1923                         self.superweapons_finished = 0;
1924                 }
1925         }
1926
1927         if(autocvar_g_nodepthtestplayers)
1928                 self.effects = self.effects | EF_NODEPTHTEST;
1929
1930         if(autocvar_g_fullbrightplayers)
1931                 self.effects = self.effects | EF_FULLBRIGHT;
1932
1933         // midair gamemode: damage only while in the air
1934         // if in midair mode, being on ground grants temporary invulnerability
1935         // (this is so that multishot weapon don't clear the ground flag on the
1936         // first damage in the frame, leaving the player vulnerable to the
1937         // remaining hits in the same frame)
1938         if (self.flags & FL_ONGROUND)
1939         if (g_midair)
1940                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1941
1942         if (time >= game_starttime)
1943         if (time < self.spawnshieldtime)
1944                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1945
1946         MUTATOR_CALLHOOK(PlayerPowerups);
1947 }
1948
1949 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1950 {
1951         if(current > stable)
1952                 return current;
1953         else if(current > stable - 0.25) // when close enough, "snap"
1954                 return stable;
1955         else
1956                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1957 }
1958
1959 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1960 {
1961         if(current < stable)
1962                 return current;
1963         else if(current < stable + 0.25) // when close enough, "snap"
1964                 return stable;
1965         else
1966                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1967 }
1968
1969 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1970 {
1971         if(current > rotstable)
1972         {
1973                 if(rotframetime > 0)
1974                 {
1975                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1976                         current = max(rotstable, current - rotlinear * rotframetime);
1977                 }
1978         }
1979         else if(current < regenstable)
1980         {
1981                 if(regenframetime > 0)
1982                 {
1983                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1984                         current = min(regenstable, current + regenlinear * regenframetime);
1985                 }
1986         }
1987
1988         if(current > limit)
1989                 current = limit;
1990
1991         return current;
1992 }
1993
1994 void player_regen (void)
1995 {
1996         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1997         maxh = autocvar_g_balance_health_rotstable;
1998         maxa = autocvar_g_balance_armor_rotstable;
1999         maxf = autocvar_g_balance_fuel_rotstable;
2000         minh = autocvar_g_balance_health_regenstable;
2001         mina = autocvar_g_balance_armor_regenstable;
2002         minf = autocvar_g_balance_fuel_regenstable;
2003         limith = autocvar_g_balance_health_limit;
2004         limita = autocvar_g_balance_armor_limit;
2005         limitf = autocvar_g_balance_fuel_limit;
2006
2007         max_mod = regen_mod = rot_mod = limit_mod = 1;
2008
2009         if (self.runes & RUNE_REGEN)
2010         {
2011                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2012                 {
2013                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2014                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2015                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2016                 }
2017                 else
2018                 {
2019                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2020                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2021                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2022                 }
2023         }
2024         else if (self.runes & CURSE_VENOM)
2025         {
2026                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2027                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2028                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2029                 else
2030                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2031                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2032                 //if (!self.runes & RUNE_REGEN)
2033                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2034         }
2035         maxh = maxh * max_mod;
2036         //maxa = maxa * max_mod;
2037         //maxf = maxf * max_mod;
2038         minh = minh * max_mod;
2039         //mina = mina * max_mod;
2040         //minf = minf * max_mod;
2041         limith = limith * limit_mod;
2042         limita = limita * limit_mod;
2043         //limitf = limitf * limit_mod;
2044
2045         if(g_lms && g_ca)
2046                 rot_mod = 0;
2047
2048         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2049         {
2050                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2051                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2052
2053                 // if player rotted to death...  die!
2054                 if(self.health < 1)
2055                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2056         }
2057
2058         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2059                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2060 }
2061
2062 float zoomstate_set;
2063 void SetZoomState(float z)
2064 {
2065         if(z != self.zoomstate)
2066         {
2067                 self.zoomstate = z;
2068                 ClientData_Touch(self);
2069         }
2070         zoomstate_set = 1;
2071 }
2072
2073 void GetPressedKeys(void) {
2074         MUTATOR_CALLHOOK(GetPressedKeys);
2075         if (self.movement_x > 0) // get if movement keys are pressed
2076         {       // forward key pressed
2077                 self.pressedkeys |= KEY_FORWARD;
2078                 self.pressedkeys &~= KEY_BACKWARD;
2079         }
2080         else if (self.movement_x < 0)
2081         {       // backward key pressed
2082                 self.pressedkeys |= KEY_BACKWARD;
2083                 self.pressedkeys &~= KEY_FORWARD;
2084         }
2085         else
2086         {       // no x input
2087                 self.pressedkeys &~= KEY_FORWARD;
2088                 self.pressedkeys &~= KEY_BACKWARD;
2089         }
2090
2091         if (self.movement_y > 0)
2092         {       // right key pressed
2093                 self.pressedkeys |= KEY_RIGHT;
2094                 self.pressedkeys &~= KEY_LEFT;
2095         }
2096         else if (self.movement_y < 0)
2097         {       // left key pressed
2098                 self.pressedkeys |= KEY_LEFT;
2099                 self.pressedkeys &~= KEY_RIGHT;
2100         }
2101         else
2102         {       // no y input
2103                 self.pressedkeys &~= KEY_RIGHT;
2104                 self.pressedkeys &~= KEY_LEFT;
2105         }
2106
2107         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2108                 self.pressedkeys |= KEY_JUMP;
2109         else
2110                 self.pressedkeys &~= KEY_JUMP;
2111         if (self.BUTTON_CROUCH)
2112                 self.pressedkeys |= KEY_CROUCH;
2113         else
2114                 self.pressedkeys &~= KEY_CROUCH;
2115
2116         if (self.BUTTON_ATCK)
2117                 self.pressedkeys |= KEY_ATCK;
2118         else
2119                 self.pressedkeys &~= KEY_ATCK;
2120         if (self.BUTTON_ATCK2)
2121                 self.pressedkeys |= KEY_ATCK2;
2122         else
2123                 self.pressedkeys &~= KEY_ATCK2;
2124 }
2125
2126 /*
2127 ======================
2128 spectate mode routines
2129 ======================
2130 */
2131
2132 void SpectateCopy(entity spectatee) {
2133         other = spectatee;
2134         MUTATOR_CALLHOOK(SpectateCopy);
2135         self.armortype = spectatee.armortype;
2136         self.armorvalue = spectatee.armorvalue;
2137         self.ammo_cells = spectatee.ammo_cells;
2138         self.ammo_shells = spectatee.ammo_shells;
2139         self.ammo_nails = spectatee.ammo_nails;
2140         self.ammo_rockets = spectatee.ammo_rockets;
2141         self.ammo_fuel = spectatee.ammo_fuel;
2142         self.clip_load = spectatee.clip_load;
2143         self.clip_size = spectatee.clip_size;
2144         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2145         self.health = spectatee.health;
2146         self.impulse = 0;
2147         self.items = spectatee.items;
2148         self.last_pickup = spectatee.last_pickup;
2149         self.hit_time = spectatee.hit_time;
2150         self.metertime = spectatee.metertime;
2151         self.strength_finished = spectatee.strength_finished;
2152         self.invincible_finished = spectatee.invincible_finished;
2153         self.pressedkeys = spectatee.pressedkeys;
2154         WEPSET_COPY_EE(self, spectatee);
2155         self.switchweapon = spectatee.switchweapon;
2156         self.switchingweapon = spectatee.switchingweapon;
2157         self.weapon = spectatee.weapon;
2158         self.nex_charge = spectatee.nex_charge;
2159         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2160         self.hagar_load = spectatee.hagar_load;
2161         self.minelayer_mines = spectatee.minelayer_mines;
2162         self.punchangle = spectatee.punchangle;
2163         self.view_ofs = spectatee.view_ofs;
2164         self.velocity = spectatee.velocity;
2165         self.dmg_take = spectatee.dmg_take;
2166         self.dmg_save = spectatee.dmg_save;
2167         self.dmg_inflictor = spectatee.dmg_inflictor;
2168         self.v_angle = spectatee.v_angle;
2169         self.angles = spectatee.v_angle;
2170         self.stat_respawn_time = spectatee.stat_respawn_time;
2171         if(!self.BUTTON_USE)
2172                 self.fixangle = TRUE;
2173         setorigin(self, spectatee.origin);
2174         setsize(self, spectatee.mins, spectatee.maxs);
2175         SetZoomState(spectatee.zoomstate);
2176
2177     anticheat_spectatecopy(spectatee);
2178         self.hud = spectatee.hud;
2179         if(spectatee.vehicle)
2180     {
2181         self.fixangle = FALSE;
2182         //self.velocity = spectatee.vehicle.velocity;
2183         self.vehicle_health = spectatee.vehicle_health;
2184         self.vehicle_shield = spectatee.vehicle_shield;
2185         self.vehicle_energy = spectatee.vehicle_energy;
2186         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2187         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2188         self.vehicle_reload1 = spectatee.vehicle_reload1;
2189         self.vehicle_reload2 = spectatee.vehicle_reload2;
2190
2191         msg_entity = self;
2192
2193         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2194             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2195             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2196             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2197
2198         //WriteByte (MSG_ONE, SVC_SETVIEW);
2199         //    WriteEntity(MSG_ONE, self);
2200         //makevectors(spectatee.v_angle);
2201         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2202     }
2203 }
2204
2205 float SpectateUpdate() {
2206         if(!self.enemy)
2207             return 0;
2208
2209         if (self == self.enemy)
2210                 return 0;
2211
2212         if(self.enemy.classname != "player")
2213                 return 0;
2214
2215         SpectateCopy(self.enemy);
2216
2217         return 1;
2218 }
2219
2220
2221 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2222 entity CA_SpectateNext(entity start) {
2223         if (start.team == self.team) {
2224                 return start;
2225         }
2226
2227         other = start;
2228         // continue from current player
2229         while(other && other.team != self.team) {
2230                 other = find(other, classname, "player");
2231         }
2232
2233         if (!other) {
2234                 // restart from begining
2235                 other = find(other, classname, "player");
2236                 while(other && other.team != self.team) {
2237                         other = find(other, classname, "player");
2238                 }
2239         }
2240
2241         return other;
2242 }
2243
2244 float SpectateNext(entity _prefer) {
2245
2246         if(_prefer)
2247                 other = _prefer;
2248         else
2249                 other = find(self.enemy, classname, "player");
2250
2251         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2252                 // CA and ca players when spectating enemies is forbidden
2253                 other = CA_SpectateNext(other);
2254         } else {
2255                 // other modes and ca spectators or spectating enemies is allowed
2256                 if (!other)
2257                         other = find(other, classname, "player");
2258         }
2259
2260         if (other)
2261                 self.enemy = other;
2262
2263         if(self.enemy.classname == "player") {
2264             /*if(self.enemy.vehicle)
2265             {
2266
2267             msg_entity = self;
2268             WriteByte(MSG_ONE, SVC_SETVIEW);
2269             WriteEntity(MSG_ONE, self.enemy);
2270             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2271
2272             self.movetype = MOVETYPE_NONE;
2273             accuracy_resend(self);
2274             }
2275             else
2276             {*/
2277             msg_entity = self;
2278             WriteByte(MSG_ONE, SVC_SETVIEW);
2279             WriteEntity(MSG_ONE, self.enemy);
2280             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2281             self.movetype = MOVETYPE_NONE;
2282             accuracy_resend(self);
2283
2284             if(!SpectateUpdate())
2285                 PutObserverInServer();
2286         //}
2287         return 1;
2288         } else {
2289                 return 0;
2290         }
2291 }
2292
2293 /*
2294 =============
2295 ShowRespawnCountdown()
2296
2297 Update a respawn countdown display.
2298 =============
2299 */
2300 void ShowRespawnCountdown()
2301 {
2302         float number;
2303         if(self.deadflag == DEAD_NO) // just respawned?
2304                 return;
2305         else
2306         {
2307                 number = ceil(self.respawn_time - time);
2308                 if(number <= 0)
2309                         return;
2310                 if(number <= self.respawn_countdown)
2311                 {
2312                         self.respawn_countdown = number - 1;
2313                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2314                                 AnnounceTo(self, strcat(ftos(number), ""));
2315                 }
2316         }
2317 }
2318
2319 .float prevent_join_msgtime;
2320 void LeaveSpectatorMode()
2321 {
2322         if(nJoinAllowed(self)) {
2323                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2324                         self.classname = "player";
2325
2326                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2327                                 JoinBestTeam(self, FALSE, TRUE);
2328
2329                         if(autocvar_g_campaign)
2330                                 campaign_bots_may_start = 1;
2331
2332                         PutClientInServer();
2333
2334                         if(self.classname == "player")
2335                                 bprint ("^4", self.netname, "^4 is playing now\n");
2336
2337                         if(!autocvar_g_campaign)
2338                         if (time < self.jointime + autocvar_welcome_message_time)
2339                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2340
2341                         if (self.prevent_join_msgtime)
2342                         {
2343                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2344                                 self.prevent_join_msgtime = 0;
2345                         }
2346
2347                         return;
2348                 } else {
2349                         if (g_ca && self.caplayer) {
2350                         }       // do nothing
2351                         else
2352                                 stuffcmd(self,"menu_showteamselect\n");
2353                         return;
2354                 }
2355         }
2356         else {
2357                 //player may not join because of g_maxplayers is set
2358                 if (time - self.prevent_join_msgtime > 2)
2359                 {
2360                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2361                         self.prevent_join_msgtime = time;
2362                 }
2363         }
2364 }
2365
2366 /**
2367  * Determines whether the player is allowed to join. This depends on cvar
2368  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2369  * it checks whether the number of currently playing players exceeds g_maxplayers.
2370  * @return int number of free slots for players, 0 if none
2371  */
2372 float nJoinAllowed(entity ignore) {
2373         if(!ignore)
2374         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2375         // so report 0 free slots if restricted
2376         {
2377                 if(autocvar_g_forced_team_otherwise == "spectate")
2378                         return 0;
2379                 if(autocvar_g_forced_team_otherwise == "spectator")
2380                         return 0;
2381         }
2382
2383         if(self.team_forced < 0)
2384                 return 0; // forced spectators can never join
2385
2386         // TODO simplify this
2387         entity e;
2388         float totalClients = 0;
2389         FOR_EACH_CLIENT(e)
2390                 if(e != ignore)
2391                         totalClients += 1;
2392
2393         if (!autocvar_g_maxplayers)
2394                 return maxclients - totalClients;
2395
2396         float currentlyPlaying = 0;
2397         FOR_EACH_REALPLAYER(e)
2398                 currentlyPlaying += 1;
2399
2400         if(currentlyPlaying < autocvar_g_maxplayers)
2401                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2402
2403         return 0;
2404 }
2405
2406 /**
2407  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2408  * g_maxplayers_spectator_blocktime seconds
2409  */
2410 void checkSpectatorBlock() {
2411         if(self.classname == "spectator" || self.classname == "observer") {
2412                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2413                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2414                         dropclient(self);
2415                 }
2416         }
2417 }
2418
2419 .float motd_actived_time; // used for both motd and campaign_message
2420 void PrintWelcomeMessage()
2421 {
2422         if (self.motd_actived_time == 0) { // is there already a message showing?
2423                 if (autocvar_g_campaign) {
2424                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2425                                 self.motd_actived_time = time;
2426                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2427                         }
2428                 } else {
2429                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2430                                 self.motd_actived_time = time;
2431                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2432                         }
2433                 }
2434         } else { // showing MOTD or campaign message
2435                 if (autocvar_g_campaign) {
2436                         if (self.BUTTON_INFO)
2437                                 self.motd_actived_time = time;
2438                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2439                                 self.motd_actived_time = 0;
2440                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2441                         }
2442                 } else {
2443                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2444                                 if (self.BUTTON_INFO)
2445                                         self.motd_actived_time = time;
2446                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2447                                         self.motd_actived_time = 0;
2448                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2449                                 }
2450                         }
2451                 }
2452         }
2453 }
2454
2455 void ObserverThink()
2456 {
2457         float prefered_movetype;
2458         if (self.flags & FL_JUMPRELEASED) {
2459                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2460                         self.flags &~= FL_JUMPRELEASED;
2461                         self.flags |= FL_SPAWNING;
2462                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2463                         self.flags &~= FL_JUMPRELEASED;
2464                         if(SpectateNext(world) == 1) {
2465                                 self.classname = "spectator";
2466                         }
2467                 } else {
2468                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2469                         if (self.movetype != prefered_movetype)
2470                                 self.movetype = prefered_movetype;
2471                 }
2472         } else {
2473                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2474                         self.flags |= FL_JUMPRELEASED;
2475                         if(self.flags & FL_SPAWNING)
2476                         {
2477                                 self.flags &~= FL_SPAWNING;
2478                                 LeaveSpectatorMode();
2479                                 return;
2480                         }
2481                 }
2482         }
2483
2484         PrintWelcomeMessage();
2485 }
2486
2487 void SpectatorThink()
2488 {
2489         if (self.flags & FL_JUMPRELEASED) {
2490                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2491                         self.flags &~= FL_JUMPRELEASED;
2492                         self.flags |= FL_SPAWNING;
2493                 } else if(self.BUTTON_ATCK) {
2494                         self.flags &~= FL_JUMPRELEASED;
2495                         if(SpectateNext(world) == 1) {
2496                                 self.classname = "spectator";
2497                         } else {
2498                                 self.classname = "observer";
2499                                 PutClientInServer();
2500                         }
2501                 } else if (self.BUTTON_ATCK2) {
2502                         self.flags &~= FL_JUMPRELEASED;
2503                         self.classname = "observer";
2504                         PutClientInServer();
2505                 } else {
2506                         if(!SpectateUpdate())
2507                                 PutObserverInServer();
2508                 }
2509         } else {
2510                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2511                         self.flags |= FL_JUMPRELEASED;
2512                         if(self.flags & FL_SPAWNING)
2513                         {
2514                                 self.flags &~= FL_SPAWNING;
2515                                 LeaveSpectatorMode();
2516                                 return;
2517                         }
2518                 }
2519                 if(!SpectateUpdate())
2520                         PutObserverInServer();
2521         }
2522
2523         PrintWelcomeMessage();
2524         self.flags |= FL_CLIENT | FL_NOTARGET;
2525 }
2526
2527 void PlayerUseKey()
2528 {
2529         if(self.classname != "player")
2530                 return;
2531
2532         if(self.vehicle)
2533         {
2534         vehicles_exit(VHEF_NORMAL);
2535         return;
2536         }
2537
2538         // a use key was pressed; call handlers
2539         MUTATOR_CALLHOOK(PlayerUseKey);
2540 }
2541
2542 .float touchexplode_time;
2543
2544 /*
2545 =============
2546 PlayerPreThink
2547
2548 Called every frame for each client before the physics are run
2549 =============
2550 */
2551 .float usekeypressed;
2552 void() nexball_setstatus;
2553 .float items_added;
2554 void PlayerPreThink (void)
2555 {
2556         WarpZone_PlayerPhysics_FixVAngle();
2557
2558         self.stat_game_starttime = game_starttime;
2559         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2560         self.stat_leadlimit = autocvar_leadlimit;
2561
2562         if(g_arena || (g_ca && !allowed_to_spawn))
2563                 self.stat_respawn_time = 0;
2564         else
2565                 self.stat_respawn_time = self.respawn_time;
2566
2567         if(frametime)
2568         {
2569                 // physics frames: update anticheat stuff
2570                 anticheat_prethink();
2571         }
2572
2573         if(blockSpectators && frametime)
2574                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2575                 checkSpectatorBlock();
2576
2577         zoomstate_set = 0;
2578
2579         if(self.netname_previous != self.netname)
2580         {
2581                 if(autocvar_sv_eventlog)
2582                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2583                 if(self.netname_previous)
2584                         strunzone(self.netname_previous);
2585                 self.netname_previous = strzone(self.netname);
2586         }
2587
2588         // version nagging
2589         if(self.version_nagtime)
2590                 if(self.cvar_g_xonoticversion)
2591                         if(time > self.version_nagtime)
2592                         {
2593                                 // don't notify git users
2594                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2595                                 {
2596                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2597                                         {
2598                                                 // notify release users if connecting to git
2599                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2600                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2601                                         }
2602                                         else
2603                                         {
2604                                                 float r;
2605                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2606                                                 if(r < 0)
2607                                                 {
2608                                                         // give users new version
2609                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2610                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2611                                                 }
2612                                                 else if(r > 0)
2613                                                 {
2614                                                         // notify users about old server version
2615                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2616                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2617                                                 }
2618                                         }
2619                                 }
2620                                 self.version_nagtime = 0;
2621                         }
2622
2623         // GOD MODE info
2624         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2625         {
2626                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2627                 self.max_armorvalue = 0;
2628         }
2629
2630 #ifdef TETRIS
2631         if (TetrisPreFrame())
2632                 return;
2633 #endif
2634
2635         MUTATOR_CALLHOOK(PlayerPreThink);
2636
2637         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2638         {
2639                 if(self.BUTTON_USE && !self.usekeypressed)
2640                         PlayerUseKey();
2641                 self.usekeypressed = self.BUTTON_USE;
2642         }
2643
2644         PrintWelcomeMessage();
2645
2646         if(self.classname == "player") {
2647 //              if(self.netname == "Wazat")
2648 //                      bprint(self.classname, "\n");
2649
2650                 CheckRules_Player();
2651
2652                 if (intermission_running)
2653                 {
2654                         IntermissionThink ();   // otherwise a button could be missed between
2655                         return;                                 // the think tics
2656                 }
2657
2658                 //don't allow the player to turn around while game is paused!
2659                 if(timeout_status == TIMEOUT_ACTIVE) {
2660                         // FIXME turn this into CSQC stuff
2661                         self.v_angle = self.lastV_angle;
2662                         self.angles = self.lastV_angle;
2663                         self.fixangle = TRUE;
2664                 }
2665
2666                 if(frametime)
2667                 {
2668 #ifndef NO_LEGACY_NETWORKING
2669                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2670 #endif
2671
2672                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2673                         {
2674                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2675                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2676                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2677
2678                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2679                                 {
2680                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2681                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2682                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2683                                 }
2684                         }
2685                         else
2686                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2687
2688                         player_powerups();
2689                 }
2690
2691                 if (g_minstagib)
2692                         minstagib_ammocheck();
2693
2694                 if (self.deadflag != DEAD_NO)
2695                 {
2696                         float button_pressed, force_respawn;
2697                         if(self.personal && g_race_qualifying)
2698                         {
2699                                 if(time > self.respawn_time)
2700                                 {
2701                                         self.respawn_time = time + 1; // only retry once a second
2702                                         respawn();
2703                                         self.impulse = 141;
2704                                 }
2705                         }
2706                         else
2707                         {
2708                                 if(frametime)
2709                                         player_anim();
2710                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2711                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2712                                 if (self.deadflag == DEAD_DYING)
2713                                 {
2714                                         if(force_respawn)
2715                                                 self.deadflag = DEAD_RESPAWNING;
2716                                         else if(!button_pressed)
2717                                                 self.deadflag = DEAD_DEAD;
2718                                 }
2719                                 else if (self.deadflag == DEAD_DEAD)
2720                                 {
2721                                         if(button_pressed)
2722                                                 self.deadflag = DEAD_RESPAWNABLE;
2723                                 }
2724                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2725                                 {
2726                                         if(!button_pressed)
2727                                                 self.deadflag = DEAD_RESPAWNING;
2728                                 }
2729                                 else if (self.deadflag == DEAD_RESPAWNING)
2730                                 {
2731                                         if(time > self.respawn_time)
2732                                         {
2733                                                 self.respawn_time = time + 1; // only retry once a second
2734                                                 respawn();
2735                                         }
2736                                 }
2737                                 ShowRespawnCountdown();
2738                         }
2739
2740                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2741                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2742                                 self.stat_respawn_time *= -1;
2743
2744                         return;
2745                 }
2746                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2747                 // so (self.deadflag == DEAD_NO) is always true in the code below
2748
2749                 if(g_touchexplode)
2750                 if(time > self.touchexplode_time)
2751                 if(self.classname == "player")
2752                 if(self.deadflag == DEAD_NO)
2753                 if not(IS_INDEPENDENT_PLAYER(self))
2754                 FOR_EACH_PLAYER(other) if(self != other)
2755                 {
2756                         if(time > other.touchexplode_time)
2757                         if(other.deadflag == DEAD_NO)
2758                         if not(IS_INDEPENDENT_PLAYER(other))
2759                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2760                         {
2761                                 PlayerTouchExplode(self, other);
2762                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2763                         }
2764                 }
2765
2766                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2767                 {
2768                         vector dist;
2769
2770                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2771                         dist = self.prevorigin - self.origin;
2772                         dist_z = 0;
2773                         self.lms_traveled_distance += fabs(vlen(dist));
2774
2775                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2776                         {
2777                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2778                                 self.lms_traveled_distance = 0;
2779                         }
2780
2781                         if(time > self.lms_nextcheck)
2782                         {
2783                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2784                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2785                                 {
2786                                         centerprint(self, autocvar_g_lms_campcheck_message);
2787                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2788                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2789                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2790                                 }
2791                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2792                                 self.lms_traveled_distance = 0;
2793                         }
2794                 }
2795
2796                 self.prevorigin = self.origin;
2797
2798                 if (!self.vehicle)
2799                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x && !self.freezetag_frozen) // prevent crouching if using melee attack
2800                 {
2801                         if (!self.crouch)
2802                         {
2803                                 self.crouch = TRUE;
2804                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2805                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2806                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2807                         }
2808                 }
2809                 else
2810                 {
2811                         if (self.crouch)
2812                         {
2813                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2814                                 if (!trace_startsolid)
2815                                 {
2816                                         self.crouch = FALSE;
2817                                         self.view_ofs = PL_VIEW_OFS;
2818                                         setsize (self, PL_MIN, PL_MAX);
2819                                 }
2820                         }
2821                 }
2822
2823                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2824                 {
2825                         if(self.bloodloss_timer < time)
2826                         {
2827                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2828                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2829                         }
2830                 }
2831
2832                 FixPlayermodel();
2833
2834                 GrapplingHookFrame();
2835
2836                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2837                 //if(frametime)
2838                 {
2839                         self.items &~= self.items_added;
2840
2841                         W_WeaponFrame();
2842
2843                         self.items_added = 0;
2844                         if(self.items & IT_JETPACK)
2845                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2846                                         self.items_added |= IT_FUEL;
2847
2848                         self.items |= self.items_added;
2849                 }
2850
2851                 player_regen();
2852
2853                 // rot nex charge to the charge limit
2854                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2855                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2856
2857                 if(frametime)
2858                         player_anim();
2859
2860                 if(g_nexball)
2861                         nexball_setstatus();
2862
2863                 // secret status
2864                 secrets_setstatus();
2865
2866                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2867
2868                 //self.angles_y=self.v_angle_y + 90;   // temp
2869         } else if(gameover) {
2870                 if (intermission_running)
2871                         IntermissionThink ();   // otherwise a button could be missed between
2872                 return;
2873         } else if(self.classname == "observer") {
2874                 ObserverThink();
2875         } else if(self.classname == "spectator") {
2876                 SpectatorThink();
2877         }
2878
2879         if(!zoomstate_set)
2880                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2881
2882         float oldspectatee_status;
2883         oldspectatee_status = self.spectatee_status;
2884         if(self.classname == "spectator")
2885                 self.spectatee_status = num_for_edict(self.enemy);
2886         else if(self.classname == "observer")
2887                 self.spectatee_status = num_for_edict(self);
2888         else
2889                 self.spectatee_status = 0;
2890         if(self.spectatee_status != oldspectatee_status)
2891         {
2892                 ClientData_Touch(self);
2893                 if(g_race || g_cts)
2894                         race_InitSpectator();
2895         }
2896
2897         if(self.teamkill_soundtime)
2898         if(time > self.teamkill_soundtime)
2899         {
2900                 self.teamkill_soundtime = 0;
2901
2902                 entity oldpusher, oldself;
2903
2904                 oldself = self; self = self.teamkill_soundsource;
2905                 oldpusher = self.pusher; self.pusher = oldself;
2906
2907                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2908
2909                 self.pusher = oldpusher;
2910                 self = oldself;
2911         }
2912
2913         if(self.taunt_soundtime)
2914         if(time > self.taunt_soundtime)
2915         {
2916                 self.taunt_soundtime = 0;
2917                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2918         }
2919
2920         target_voicescript_next(self);
2921
2922         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2923         if(!self.weapon)
2924                 self.clip_load = self.clip_size = 0;
2925 }
2926
2927 float isInvisibleString(string s)
2928 {
2929         float i, n, c;
2930         s = strdecolorize(s);
2931         for((i = 0), (n = strlen(s)); i < n; ++i)
2932         {
2933                 c = str2chr(s, i);
2934                 switch(c)
2935                 {
2936                         case 0:
2937                         case 32: // space
2938                                 break;
2939                         case 192: // charmap space
2940                                 if (!autocvar_utf8_enable)
2941                                         break;
2942                                 return FALSE;
2943                         case 160: // space in unicode fonts
2944                         case 0xE000 + 192: // utf8 charmap space
2945                                 if (autocvar_utf8_enable)
2946                                         break;
2947                         default:
2948                                 return FALSE;
2949                 }
2950         }
2951         return TRUE;
2952 }
2953
2954 /*
2955 =============
2956 PlayerPostThink
2957
2958 Called every frame for each client after the physics are run
2959 =============
2960 */
2961 .float idlekick_lasttimeleft;
2962 .entity showheadshotbbox;
2963 void showheadshotbbox_think()
2964 {
2965         if(self.owner.showheadshotbbox != self)
2966         {
2967                 remove(self);
2968                 return;
2969         }
2970         self.nextthink = time;
2971         setorigin(self, self.owner.origin);
2972         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2973 }
2974 void PlayerPostThink (void)
2975 {
2976         // Savage: Check for nameless players
2977         if (isInvisibleString(self.netname)) {
2978                 self.netname = "Player";
2979                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2980         }
2981
2982         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2983         {
2984                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2985                 {
2986                         if(self.idlekick_lasttimeleft)
2987                         {
2988                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2989                                 self.idlekick_lasttimeleft = 0;
2990                         }
2991                 }
2992                 else
2993                 {
2994                         float timeleft;
2995                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2996                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2997                         {
2998                                 if(!self.idlekick_lasttimeleft)
2999                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3000                         }
3001                         if(timeleft <= 0)
3002                         {
3003                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3004                                 AnnounceTo(self, "terminated");
3005                                 dropclient(self);
3006                                 return;
3007                         }
3008                         else if(timeleft <= 10)
3009                         {
3010                                 if(timeleft != self.idlekick_lasttimeleft)
3011                                         AnnounceTo(self, ftos(timeleft));
3012                                 self.idlekick_lasttimeleft = timeleft;
3013                         }
3014                 }
3015         }
3016
3017 #ifdef TETRIS
3018         if(self.impulse == 100)
3019                 ImpulseCommands();
3020         if (!TetrisPostFrame())
3021         {
3022 #endif
3023
3024         CheatFrame();
3025
3026         //CheckPlayerJump();
3027
3028         if(self.classname == "player") {
3029                 CheckRules_Player();
3030                 UpdateChatBubble();
3031                 if (self.impulse)
3032                         ImpulseCommands();
3033                 if (intermission_running)
3034                         return;         // intermission or finale
3035                 GetPressedKeys();
3036         }
3037
3038 #ifdef TETRIS
3039         }
3040 #endif
3041
3042         /*
3043         float i;
3044         for(i = 0; i < 1000; ++i)
3045         {
3046                 vector end;
3047                 end = self.origin + '0 0 1024' + 512 * randomvec();
3048                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3049                 if(trace_fraction < 1)
3050                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3051                 {
3052                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3053                         break;
3054                 }
3055         }
3056         */
3057
3058         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3059
3060         if(self.waypointsprite_attachedforcarrier)
3061                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3062
3063         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3064         {
3065                 if(!self.showheadshotbbox)
3066                 {
3067                         self.showheadshotbbox = spawn();
3068                         self.showheadshotbbox.classname = "headshotbbox";
3069                         self.showheadshotbbox.owner = self;
3070                         self.showheadshotbbox.think = showheadshotbbox_think;
3071                         self.showheadshotbbox.nextthink = time;
3072                         self = self.showheadshotbbox;
3073                         self.think();
3074                         self = self.owner;
3075                 }
3076         }
3077         else
3078         {
3079                 if(self.showheadshotbbox)
3080                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3081                 remove(self.showheadshotbbox);
3082         }
3083
3084         playerdemo_write();
3085
3086         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3087         {
3088                 if(!self.stored_netname)
3089                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3090                 if(self.stored_netname != self.netname)
3091                 {
3092                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3093                         strunzone(self.stored_netname);
3094                         self.stored_netname = strzone(self.netname);
3095                 }
3096         }
3097
3098         /*
3099         if(g_race)
3100                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3101         */
3102
3103         CSQCMODEL_AUTOUPDATE();
3104 }