qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 if(!inWarmupStage)
 414                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419                 vehicles_exit(VHEF_RELESE);
 420
 421         WaypointSprite_PlayerDead();
 422
 423         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 424                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 425
 426         if(self.killcount != -666) {
 427                 if(g_lms) {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 429                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 430                         else
 431                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 432                 } else
 433                         bprint ("^4", self.netname, "^4 is spectating now\n");
 434
 435                 if(self.just_joined == FALSE) {
 436                         LogTeamchange(self.playerid, -1, 4);
 437                 } else
 438                         self.just_joined = FALSE;
 439         }
 440
 441         PlayerScore_Clear(self); // clear scores when needed
 442
 443         accuracy_resend(self);
 444
 445         self.spectatortime = time;
 446
 447         self.classname = "observer";
 448         self.iscreature = FALSE;
 449         self.teleportable = TELEPORT_SIMPLE;
 450         self.damagedbycontents = FALSE;
 451         self.health = -666;
 452         self.takedamage = DAMAGE_NO;
 453         self.solid = SOLID_NOT;
 454         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 455         self.flags = FL_CLIENT | FL_NOTARGET;
 456         self.armorvalue = 666;
 457         self.effects = 0;
 458         self.armorvalue = autocvar_g_balance_armor_start;
 459         self.pauserotarmor_finished = 0;
 460         self.pauserothealth_finished = 0;
 461         self.pauseregen_finished = 0;
 462         self.damageforcescale = 0;
 463         self.death_time = 0;
 464         self.respawn_time = 0;
 465         self.alpha = 0;
 466         self.scale = 0;
 467         self.fade_time = 0;
 468         self.pain_frame = 0;
 469         self.pain_finished = 0;
 470         self.strength_finished = 0;
 471         self.invincible_finished = 0;
 472         self.superweapons_finished = 0;
 473         self.pushltime = 0;
 474         self.istypefrag = 0;
 475         self.think = func_null;
 476         self.nextthink = 0;
 477         self.hook_time = 0;
 478         self.runes = 0;
 479         self.deadflag = DEAD_NO;
 480         self.angles = spot.angles;
 481         self.angles_z = 0;
 482         self.fixangle = TRUE;
 483         self.crouch = FALSE;
 484
 485         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 486         self.prevorigin = self.origin;
 487         self.items = 0;
 488         WEPSET_CLEAR_E(self);
 489         self.model = "";
 490         FixPlayermodel();
 491         setmodel(self, "null");
 492         self.drawonlytoclient = self;
 493
 494         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 495         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 496
 497         self.weapon = 0;
 498         self.weaponname = "";
 499         self.switchingweapon = 0;
 500         self.weaponmodel = "";
 501         self.weaponentity = world;
 502         self.exteriorweaponentity = world;
 503         self.killcount = -666;
 504         self.velocity = '0 0 0';
 505         self.avelocity = '0 0 0';
 506         self.punchangle = '0 0 0';
 507         self.punchvector = '0 0 0';
 508         self.oldvelocity = self.velocity;
 509         self.fire_endtime = -1;
 510
 511         if(g_arena)
 512         {
 513                 if(self.version_mismatch)
 514                 {
 515                         self.frags = FRAGS_SPECTATOR;
 516                         Spawnqueue_Unmark(self);
 517                         Spawnqueue_Remove(self);
 518                 }
 519                 else
 520                 {
 521                         self.frags = FRAGS_LMS_LOSER;
 522                         Spawnqueue_Insert(self);
 523                 }
 524         }
 525         else if(g_lms)
 526         {
 527                 // Only if the player cannot play at all
 528                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 529                         self.frags = FRAGS_SPECTATOR;
 530                 else
 531                         self.frags = FRAGS_LMS_LOSER;
 532         }
 533         else if(g_ca)
 534         {
 535                 if(self.caplayer)
 536                         self.frags = FRAGS_LMS_LOSER;
 537                 else
 538                         self.frags = FRAGS_SPECTATOR;
 539         }
 540         else if((g_race && g_race_qualifying) || g_cts)
 541         {
 542                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 543                         self.frags = FRAGS_LMS_LOSER;
 544                 else
 545                         self.frags = FRAGS_SPECTATOR;
 546         }
 547         else
 548                 self.frags = FRAGS_SPECTATOR;
 549 }
 550
 551 .float model_randomizer;
 552 void FixPlayermodel()
 553 {
 554         string defaultmodel;
 555         float defaultskin, chmdl, oldskin, n, i;
 556         vector m1, m2;
 557
 558         defaultmodel = "";
 559         defaultskin = 0;
 560         chmdl = FALSE;
 561
 562         if(autocvar_sv_defaultcharacter == 1)
 563         {
 564                 if(teamplay)
 565                 {
 566                         string s;
 567                         s = Team_ColorNameLowerCase(self.team);
 568                         if(s != "neutral")
 569                         {
 570                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 571                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 572                         }
 573                 }
 574
 575                 if(defaultmodel == "")
 576                 {
 577                         defaultmodel = autocvar_sv_defaultplayermodel;
 578                         defaultskin = autocvar_sv_defaultplayerskin;
 579                 }
 580
 581                 n = tokenize_console(defaultmodel);
 582                 if(n > 0)
 583                         defaultmodel = argv(floor(n * self.model_randomizer));
 584
 585                 i = strstrofs(defaultmodel, ":", 0);
 586                 if(i >= 0)
 587                 {
 588                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 589                         defaultmodel = substring(defaultmodel, 0, i);
 590                 }
 591         }
 592
 593         if(defaultmodel != "")
 594         {
 595                 if (defaultmodel != self.model)
 596                 {
 597                         m1 = self.mins;
 598                         m2 = self.maxs;
 599                         setplayermodel (self, defaultmodel);
 600                         setsize (self, m1, m2);
 601                         chmdl = TRUE;
 602                 }
 603
 604                 oldskin = self.skin;
 605                 self.skin = defaultskin;
 606         } else {
 607                 if (self.playermodel != self.model || self.playermodel == "")
 608                 {
 609                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 610                         m1 = self.mins;
 611                         m2 = self.maxs;
 612                         setplayermodel (self, self.playermodel);
 613                         setsize (self, m1, m2);
 614                         chmdl = TRUE;
 615                 }
 616
 617                 oldskin = self.skin;
 618                 self.skin = stof(self.playerskin);
 619         }
 620
 621         if(chmdl || oldskin != self.skin) // model or skin has changed
 622         {
 623                 self.species = player_getspecies(); // update species
 624                 UpdatePlayerSounds(); // update skin sounds
 625         }
 626
 627         if(!teamplay)
 628                 if(strlen(autocvar_sv_defaultplayercolors))
 629                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 630                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 631 }
 632
 633 void PlayerTouchExplode(entity p1, entity p2)
 634 {
 635         vector org;
 636         org = (p1.origin + p2.origin) * 0.5;
 637         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 638
 639         te_explosion(org);
 640
 641         entity e;
 642         e = spawn();
 643         setorigin(e, org);
 644         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 645         remove(e);
 646 }
 647
 648 /*
 649 =============
 650 PutClientInServer
 651
 652 Called when a client spawns in the server
 653 =============
 654 */
 655
 656 void PutClientInServer (void)
 657 {
 658         if(clienttype(self) == CLIENTTYPE_BOT)
 659         {
 660                 self.classname = "player";
 661                 if(g_ca)
 662                         self.caplayer = 1;
 663         }
 664         else if(clienttype(self) == CLIENTTYPE_REAL)
 665         {
 666                 msg_entity = self;
 667                 WriteByte(MSG_ONE, SVC_SETVIEW);
 668                 WriteEntity(MSG_ONE, self);
 669         }
 670
 671         // reset player keys
 672         self.itemkeys = 0;
 673
 674         // player is dead and becomes observer
 675         // FIXME fix LMS scoring for new system
 676         if(g_lms)
 677         {
 678                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 679                         self.classname = "observer";
 680         }
 681
 682         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 683                 self.classname = "observer";
 684
 685         if(gameover)
 686                 self.classname = "observer";
 687
 688         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 689                 entity spot, oldself;
 690                 float j;
 691
 692                 accuracy_resend(self);
 693
 694                 if(self.team < 0)
 695                         JoinBestTeam(self, FALSE, TRUE);
 696
 697                 race_PreSpawn();
 698
 699                 spot = SelectSpawnPoint (FALSE);
 700                 if(!spot)
 701                 {
 702                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 703                         return; // spawn failed
 704                 }
 705
 706                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 707
 708                 self.classname = "player";
 709                 self.wasplayer = TRUE;
 710                 self.iscreature = TRUE;
 711                 self.teleportable = TELEPORT_NORMAL;
 712                 self.damagedbycontents = TRUE;
 713                 self.movetype = MOVETYPE_WALK;
 714                 self.solid = SOLID_SLIDEBOX;
 715                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 716                 if(autocvar_g_playerclip_collisions)
 717                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 718                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 719                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 720                 self.frags = FRAGS_PLAYER;
 721                 if(INDEPENDENT_PLAYERS)
 722                         MAKE_INDEPENDENT_PLAYER(self);
 723                 self.flags = FL_CLIENT;
 724                 if(autocvar__notarget)
 725                         self.flags |= FL_NOTARGET;
 726                 self.takedamage = DAMAGE_AIM;
 727                 if(g_minstagib)
 728                         self.effects = EF_FULLBRIGHT;
 729                 else
 730                         self.effects = 0;
 731                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 732                 self.air_finished = time + 12;
 733                 self.dmg = 2;
 734                 if(autocvar_g_balance_nex_charge)
 735                 {
 736                         if(autocvar_g_balance_nex_secondary_chargepool)
 737                                 self.nex_chargepool_ammo = 1;
 738                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 739                 }
 740
 741                 if(inWarmupStage)
 742                 {
 743                         self.ammo_shells = warmup_start_ammo_shells;
 744                         self.ammo_nails = warmup_start_ammo_nails;
 745                         self.ammo_rockets = warmup_start_ammo_rockets;
 746                         self.ammo_cells = warmup_start_ammo_cells;
 747                         self.ammo_fuel = warmup_start_ammo_fuel;
 748                         self.health = warmup_start_health;
 749                         self.armorvalue = warmup_start_armorvalue;
 750                         WEPSET_COPY_EA(self, warmup_start_weapons);
 751                 }
 752                 else
 753                 {
 754                         self.ammo_shells = start_ammo_shells;
 755                         self.ammo_nails = start_ammo_nails;
 756                         self.ammo_rockets = start_ammo_rockets;
 757                         self.ammo_cells = start_ammo_cells;
 758                         self.ammo_fuel = start_ammo_fuel;
 759                         self.health = start_health;
 760                         self.armorvalue = start_armorvalue;
 761                         WEPSET_COPY_EA(self, start_weapons);
 762                 }
 763
 764                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 765                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 766                 else
 767                         self.superweapons_finished = 0;
 768
 769                 if(g_weaponarena_random)
 770                 {
 771                         if(g_weaponarena_random_with_laser)
 772                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 773                         W_RandomWeapons(self, g_weaponarena_random);
 774                         if(g_weaponarena_random_with_laser)
 775                                 WEPSET_OR_EW(self, WEP_LASER);
 776                 }
 777
 778                 self.items = start_items;
 779
 780                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 781                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 782                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 783                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 784                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 785                 //extend the pause of rotting if client was reset at the beginning of the countdown
 786                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 787                         self.spawnshieldtime += game_starttime - time;
 788                         self.pauserotarmor_finished += game_starttime - time;
 789                         self.pauserothealth_finished += game_starttime - time;
 790                         self.pauseregen_finished += game_starttime - time;
 791                 }
 792                 self.damageforcescale = 2;
 793                 self.death_time = 0;
 794                 self.respawn_time = 0;
 795                 self.scale = 0;
 796                 self.fade_time = 0;
 797                 self.pain_frame = 0;
 798                 self.pain_finished = 0;
 799                 self.strength_finished = 0;
 800                 self.invincible_finished = 0;
 801                 self.pushltime = 0;
 802                 // players have no think function
 803                 self.think = func_null;
 804                 self.nextthink = 0;
 805                 self.hook_time = 0;
 806                 self.dmg_team = 0;
 807                 self.ballistics_density = autocvar_g_ballistics_density_player;
 808
 809                 self.metertime = 0;
 810
 811                 self.runes = 0;
 812
 813                 self.deadflag = DEAD_NO;
 814
 815                 self.angles = spot.angles;
 816
 817                 self.angles_z = 0; // never spawn tilted even if the spot says to
 818                 self.fixangle = TRUE; // turn this way immediately
 819                 self.velocity = '0 0 0';
 820                 self.avelocity = '0 0 0';
 821                 self.punchangle = '0 0 0';
 822                 self.punchvector = '0 0 0';
 823                 self.oldvelocity = self.velocity;
 824                 self.fire_endtime = -1;
 825
 826                 msg_entity = self;
 827                 WRITESPECTATABLE_MSG_ONE({
 828                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 829                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 830                 });
 831
 832                 self.model = "";
 833                 FixPlayermodel();
 834                 self.drawonlytoclient = world;
 835
 836                 self.crouch = FALSE;
 837                 self.view_ofs = PL_VIEW_OFS;
 838                 setsize (self, PL_MIN, PL_MAX);
 839                 self.spawnorigin = spot.origin;
 840                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 841                 // don't reset back to last position, even if new position is stuck in solid
 842                 self.oldorigin = self.origin;
 843                 self.prevorigin = self.origin;
 844                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 845                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 846         self.hud = HUD_NORMAL;
 847
 848                 if(g_arena)
 849                 {
 850                         Spawnqueue_Remove(self);
 851                         Spawnqueue_Mark(self);
 852                 }
 853                 else if(g_ca)
 854                         self.caplayer = 1;
 855
 856                 self.event_damage = PlayerDamage;
 857
 858                 self.bot_attack = TRUE;
 859
 860                 self.statdraintime = time + 5;
 861                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 862
 863                 if(self.killcount == -666) {
 864                         PlayerScore_Clear(self);
 865                         self.killcount = 0;
 866                 }
 867
 868                 CL_SpawnWeaponentity();
 869                 self.alpha = default_player_alpha;
 870                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 871                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 872
 873                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 874                 self.lms_traveled_distance = 0;
 875                 self.speedrunning = FALSE;
 876
 877                 race_PostSpawn(spot);
 878
 879                 //stuffcmd(self, "chase_active 0");
 880                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 881
 882                 if(g_assault) {
 883                         if(self.team == assault_attacker_team)
 884                                 centerprint(self, "You are attacking!");
 885                         else
 886                                 centerprint(self, "You are defending!");
 887                 }
 888
 889                 target_voicescript_clear(self);
 890
 891                 // reset fields the weapons may use
 892                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 893                 {
 894                         weapon_action(j, WR_RESETPLAYER);
 895
 896                         // all weapons must be fully loaded when we spawn
 897                         entity e;
 898                         e = get_weaponinfo(j);
 899                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 900                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 901                 }
 902
 903                 oldself = self;
 904                 self = spot;
 905                         activator = oldself;
 906                                 string s;
 907                                 s = self.target;
 908                                 self.target = string_null;
 909                                 SUB_UseTargets();
 910                                 self.target = s;
 911                         activator = world;
 912                 self = oldself;
 913
 914                 spawn_spot = spot;
 915                 MUTATOR_CALLHOOK(PlayerSpawn);
 916
 917                 if(autocvar_spawn_debug)
 918                 {
 919                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 920                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 921                 }
 922
 923                 self.switchweapon = w_getbestweapon(self);
 924                 self.cnt = -1; // W_LastWeapon will not complain
 925                 self.weapon = 0;
 926                 self.weaponname = "";
 927                 self.switchingweapon = 0;
 928
 929                 if(!inWarmupStage)
 930                         if(!self.alivetime)
 931                                 self.alivetime = time;
 932
 933                 antilag_clear(self);
 934
 935                 if (autocvar_g_spawnsound)
 936                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 937         } else if(self.classname == "observer") {
 938                 PutObserverInServer ();
 939         }
 940 }
 941
 942 .float ebouncefactor, ebouncestop; // electro's values
 943 // TODO do we need all these fields, or should we stop autodetecting runtime
 944 // changes and just have a console command to update this?
 945 float ClientInit_SendEntity(entity to, float sf)
 946 {
 947         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 948         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 951         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 952         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 953         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 954         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 955         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 956         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 957         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 958         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 959         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 960         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 961         if(sv_foginterval && world.fog != "")
 962                 WriteString(MSG_ENTITY, world.fog);
 963         else
 964                 WriteString(MSG_ENTITY, "");
 965         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 966         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 967         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 968         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 969         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 970         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 971         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 972         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 973         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 974         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 975         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 976         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 977         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 978         return TRUE;
 979 }
 980
 981 void ClientInit_CheckUpdate()
 982 {
 983         self.nextthink = time;
 984         if(self.count != autocvar_g_balance_armor_blockpercent)
 985         {
 986                 self.count = autocvar_g_balance_armor_blockpercent;
 987                 self.SendFlags |= 1;
 988         }
 989         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 990         {
 991                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 992                 self.SendFlags |= 1;
 993         }
 994         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 995         {
 996                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 997                 self.SendFlags |= 1;
 998         }
 999         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1000         {
1001                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1002                 self.SendFlags |= 1;
1003         }
1004         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1005         {
1006                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1007                 self.SendFlags |= 1;
1008         }
1009         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1010         {
1011                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1012                 self.SendFlags |= 1;
1013         }
1014 }
1015
1016 void ClientInit_Spawn()
1017 {
1018         entity o;
1019         entity e;
1020         e = spawn();
1021         e.classname = "clientinit";
1022         e.think = ClientInit_CheckUpdate;
1023         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1024
1025         o = self;
1026         self = e;
1027         ClientInit_CheckUpdate();
1028         self = o;
1029 }
1030
1031 /*
1032 =============
1033 SetNewParms
1034 =============
1035 */
1036 void SetNewParms (void)
1037 {
1038         // initialize parms for a new player
1039         parm1 = -(86400 * 366);
1040 }
1041
1042 /*
1043 =============
1044 SetChangeParms
1045 =============
1046 */
1047 void SetChangeParms (void)
1048 {
1049         // save parms for level change
1050         parm1 = self.parm_idlesince - time;
1051 }
1052
1053 /*
1054 =============
1055 DecodeLevelParms
1056 =============
1057 */
1058 void DecodeLevelParms (void)
1059 {
1060         // load parms
1061         self.parm_idlesince = parm1;
1062         if(self.parm_idlesince == -(86400 * 366))
1063                 self.parm_idlesince = time;
1064
1065         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1066         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1067 }
1068
1069 /*
1070 =============
1071 ClientKill
1072
1073 Called when a client types 'kill' in the console
1074 =============
1075 */
1076
1077 .float clientkill_nexttime;
1078 void ClientKill_Now_TeamChange()
1079 {
1080         if(self.killindicator_teamchange == -1)
1081         {
1082                 JoinBestTeam( self, FALSE, TRUE );
1083         }
1084         else if(self.killindicator_teamchange == -2)
1085         {
1086                 if(g_ca)
1087                         self.caplayer = 0;
1088                 if(blockSpectators)
1089                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1090                 PutObserverInServer();
1091         }
1092         else
1093                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1094 }
1095
1096 void ClientKill_Now()
1097 {
1098         if(self.vehicle)
1099         {
1100             vehicles_exit(VHEF_RELESE);
1101             if(!self.killindicator_teamchange)
1102             {
1103             self.vehicle_health = -1;
1104             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1105             }
1106         }
1107
1108         if(self.killindicator && !wasfreed(self.killindicator))
1109                 remove(self.killindicator);
1110
1111         self.killindicator = world;
1112
1113         if(self.killindicator_teamchange)
1114                 ClientKill_Now_TeamChange();
1115
1116         // in any case:
1117         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1118
1119         // now I am sure the player IS dead
1120 }
1121 void KillIndicator_Think()
1122 {
1123         if (gameover)
1124         {
1125                 self.owner.killindicator = world;
1126                 remove(self);
1127                 return;
1128         }
1129
1130         if (self.owner.alpha < 0 && !self.owner.vehicle)
1131         {
1132                 self.owner.killindicator = world;
1133                 remove(self);
1134                 return;
1135         }
1136
1137         if(self.cnt <= 0)
1138         {
1139                 self = self.owner;
1140                 ClientKill_Now(); // no oldself needed
1141                 return;
1142         }
1143     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1144     {
1145         self.nextthink = time + 1;
1146         self.cnt -= 1;
1147     }
1148         else
1149         {
1150                 if(self.cnt <= 10)
1151                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1152                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1153                 {
1154                         if(self.cnt <= 10)
1155                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1156                 }
1157                 self.nextthink = time + 1;
1158                 self.cnt -= 1;
1159         }
1160 }
1161
1162 float clientkilltime;
1163 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1164 {
1165         float killtime;
1166         float starttime;
1167         entity e;
1168
1169         if (gameover)
1170                 return;
1171
1172         killtime = autocvar_g_balance_kill_delay;
1173
1174         if(g_race_qualifying || g_cts)
1175                 killtime = 0;
1176
1177     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1178     {
1179                 remove(self.killindicator);
1180                 self.killindicator = world;
1181
1182         ClientKill_Now(); // allow instant kill in this case
1183         return;
1184     }
1185
1186         self.killindicator_teamchange = targetteam;
1187
1188     if(!self.killindicator)
1189         {
1190                 if(self.deadflag == DEAD_NO)
1191                 {
1192                         killtime = max(killtime, self.clientkill_nexttime - time);
1193                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1194                 }
1195
1196                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1197                 {
1198                         ClientKill_Now();
1199                 }
1200                 else
1201                 {
1202                         starttime = max(time, clientkilltime);
1203
1204                         self.killindicator = spawn();
1205                         self.killindicator.owner = self;
1206                         self.killindicator.scale = 0.5;
1207                         setattachment(self.killindicator, self, "");
1208                         setorigin(self.killindicator, '0 0 52');
1209                         self.killindicator.think = KillIndicator_Think;
1210                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1211                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1212                         self.killindicator.cnt = ceil(killtime);
1213                         self.killindicator.count = bound(0, ceil(killtime), 10);
1214                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1215
1216                         for(e = world; (e = find(e, classname, "body")) != world; )
1217                         {
1218                                 if(e.enemy != self)
1219                                         continue;
1220                                 e.killindicator = spawn();
1221                                 e.killindicator.owner = e;
1222                                 e.killindicator.scale = 0.5;
1223                                 setattachment(e.killindicator, e, "");
1224                                 setorigin(e.killindicator, '0 0 52');
1225                                 e.killindicator.think = KillIndicator_Think;
1226                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1227                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1228                                 e.killindicator.cnt = ceil(killtime);
1229                         }
1230                         self.lip = 0;
1231                 }
1232         }
1233         if(self.killindicator)
1234         {
1235                 if(targetteam == 0) // just die
1236                 {
1237                         self.killindicator.colormod = '0 0 0';
1238                         if(clienttype(self) == CLIENTTYPE_REAL)
1239                         if(self.killindicator.cnt > 0)
1240                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1241                 }
1242                 else if(targetteam == -1) // auto
1243                 {
1244                         self.killindicator.colormod = '0 1 0';
1245                         if(clienttype(self) == CLIENTTYPE_REAL)
1246                         if(self.killindicator.cnt > 0)
1247                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1248                 }
1249                 else if(targetteam == -2) // spectate
1250                 {
1251                         self.killindicator.colormod = '0.5 0.5 0.5';
1252                         if(clienttype(self) == CLIENTTYPE_REAL)
1253                         if(self.killindicator.cnt > 0)
1254                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1255                 }
1256                 else
1257                 {
1258                         self.killindicator.colormod = TeamColor(targetteam);
1259                         if(clienttype(self) == CLIENTTYPE_REAL)
1260                         if(self.killindicator.cnt > 0)
1261                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1262                 }
1263         }
1264
1265 }
1266
1267 void ClientKill (void)
1268 {
1269         if (gameover)
1270                 return;
1271
1272         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1273         {
1274                 // do nothing
1275         }
1276     else if(self.freezetag_frozen)
1277     {
1278         // do nothing
1279     }
1280         else
1281                 ClientKill_TeamChange(0);
1282 }
1283
1284 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1285 {
1286     e.killindicator = spawn();
1287     e.killindicator.owner = e;
1288     e.killindicator.think = KillIndicator_Think;
1289     e.killindicator.nextthink = time + (e.lip) * 0.05;
1290     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1291     e.killindicator.health = 1; // this is used to indicate that it should be silent
1292     e.lip = 0;
1293 }
1294
1295 void FixClientCvars(entity e)
1296 {
1297         // send prediction settings to the client
1298         stuffcmd(e, "\nin_bindmap 0 0\n");
1299         if(g_race || g_cts)
1300                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1301         if(autocvar_g_antilag == 3) // client side hitscan
1302                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1303         if(sv_gentle)
1304                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1305         /*
1306          * we no longer need to stuff this. Remove this comment block if you feel
1307          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1308         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1309         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1310         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1311         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1312         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1313         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1314         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1315         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1316         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1317         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1318         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1319         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1320         stuffcmd(e, "cl_movement_edgefriction 1\n");
1321          */
1322 }
1323
1324 float PlayerInIDList(entity p, string idlist)
1325 {
1326         float n, i;
1327         string s;
1328
1329         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1330         if not(p.crypto_idfp)
1331                 return 0;
1332
1333         // this function allows abbreviated player IDs too!
1334         n = tokenize_console(idlist);
1335         for(i = 0; i < n; ++i)
1336         {
1337                 s = argv(i);
1338                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1339                         return 1;
1340         }
1341
1342         return 0;
1343 }
1344
1345 /*
1346 =============
1347 ClientConnect
1348
1349 Called when a client connects to the server
1350 =============
1351 */
1352 string ColoredTeamName(float t);
1353 void DecodeLevelParms (void);
1354 //void dom_player_join_team(entity pl);
1355 void set_dom_state(entity e);
1356 void ClientConnect (void)
1357 {
1358         float t;
1359
1360         if(self.flags & FL_CLIENT)
1361         {
1362                 print("Warning: ClientConnect, but already connected!\n");
1363                 return;
1364         }
1365
1366         if(Ban_MaybeEnforceBanOnce(self))
1367                 return;
1368
1369         DecodeLevelParms();
1370
1371 #ifdef WATERMARK
1372         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK, "\n"));
1373 #endif
1374
1375         self.classname = "player_joining";
1376
1377         self.flags = FL_CLIENT;
1378         self.version_nagtime = time + 10 + random() * 10;
1379
1380         if(player_count<0)
1381         {
1382                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1383                 player_count = 0;
1384         }
1385
1386         PlayerScore_Attach(self);
1387         ClientData_Attach();
1388         accuracy_init(self);
1389
1390         bot_clientconnect();
1391
1392         playerdemo_init();
1393
1394         anticheat_init();
1395
1396         race_PreSpawnObserver();
1397
1398         // identify the right forced team
1399         if(autocvar_g_campaign)
1400         {
1401                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1402                 {
1403                         switch(autocvar_g_campaign_forceteam)
1404                         {
1405                                 case 1: self.team_forced = COLOR_TEAM1; break;
1406                                 case 2: self.team_forced = COLOR_TEAM2; break;
1407                                 case 3: self.team_forced = COLOR_TEAM3; break;
1408                                 case 4: self.team_forced = COLOR_TEAM4; break;
1409                                 default: self.team_forced = 0;
1410                         }
1411                 }
1412         }
1413         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1414                 self.team_forced = COLOR_TEAM1;
1415         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1416                 self.team_forced = COLOR_TEAM2;
1417         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1418                 self.team_forced = COLOR_TEAM3;
1419         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1420                 self.team_forced = COLOR_TEAM4;
1421         else if(autocvar_g_forced_team_otherwise == "red")
1422                 self.team_forced = COLOR_TEAM1;
1423         else if(autocvar_g_forced_team_otherwise == "blue")
1424                 self.team_forced = COLOR_TEAM2;
1425         else if(autocvar_g_forced_team_otherwise == "yellow")
1426                 self.team_forced = COLOR_TEAM3;
1427         else if(autocvar_g_forced_team_otherwise == "pink")
1428                 self.team_forced = COLOR_TEAM4;
1429         else if(autocvar_g_forced_team_otherwise == "spectate")
1430                 self.team_forced = -1;
1431         else if(autocvar_g_forced_team_otherwise == "spectator")
1432                 self.team_forced = -1;
1433         else
1434                 self.team_forced = 0;
1435
1436         if(!teamplay)
1437                 if(self.team_forced > 0)
1438                         self.team_forced = 0;
1439
1440         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1441
1442         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1443                 self.classname = "observer";
1444         } else {
1445                 if(teamplay)
1446                 {
1447                         if(autocvar_g_balance_teams)
1448                         {
1449                                 self.classname = "player";
1450                                 campaign_bots_may_start = 1;
1451                         }
1452                         else
1453                         {
1454                                 self.classname = "observer"; // do it anyway
1455                         }
1456                 }
1457                 else
1458                 {
1459                         self.classname = "player";
1460                         campaign_bots_may_start = 1;
1461                 }
1462         }
1463
1464         self.playerid = (playerid_last = playerid_last + 1);
1465
1466         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1467
1468     if(clienttype(self) == CLIENTTYPE_BOT)
1469         PlayerStats_AddPlayer(self);
1470
1471         if(autocvar_sv_eventlog)
1472                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1473
1474         LogTeamchange(self.playerid, self.team, 1);
1475
1476         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1477
1478         self.netname_previous = strzone(self.netname);
1479
1480         bprint("^4", self.netname, "^4 connected");
1481
1482         if(self.classname != "observer" && (g_domination || g_ctf))
1483                 bprint(" and joined the ", ColoredTeamName(self.team));
1484
1485         bprint("\n");
1486
1487         stuffcmd(self, strcat(clientstuff, "\n"));
1488         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1489
1490         FixClientCvars(self);
1491
1492         // spawnfunc_waypoint sprites
1493         WaypointSprite_InitClient(self);
1494
1495         // Wazat's grappling hook
1496         SetGrappleHookBindings();
1497
1498         // get version info from player
1499         stuffcmd(self, "cmd clientversion $gameversion\n");
1500
1501         // get other cvars from player
1502         GetCvars(0);
1503
1504         // notify about available teams
1505         if(teamplay)
1506         {
1507                 CheckAllowedTeams(self);
1508                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1509                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1510         }
1511         else
1512                 stuffcmd(self, "set _teams_available 0\n");
1513
1514         if(g_arena || g_ca)
1515         {
1516                 self.classname = "observer";
1517                 if(g_arena)
1518                         Spawnqueue_Insert(self);
1519         }
1520
1521         attach_entcs();
1522
1523         bot_relinkplayerlist();
1524
1525         self.spectatortime = time;
1526         if(blockSpectators)
1527         {
1528                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1529         }
1530
1531         self.jointime = time;
1532         self.allowed_timeouts = autocvar_sv_timeout_number;
1533
1534         if(clienttype(self) == CLIENTTYPE_REAL)
1535         {
1536                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1537                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1538         }
1539
1540         if(g_lms)
1541         {
1542                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1543                 {
1544                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1545                         self.frags = FRAGS_SPECTATOR;
1546                 }
1547         }
1548
1549         if(!sv_foginterval && world.fog != "")
1550                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1551
1552         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1553         {
1554                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1555                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1556         }
1557         else
1558                 self.hitplotfh = -1;
1559
1560         if(g_race || g_cts) {
1561                 string rr;
1562                 if(g_cts)
1563                         rr = CTS_RECORD;
1564                 else
1565                         rr = RACE_RECORD;
1566
1567                 msg_entity = self;
1568                 race_send_recordtime(MSG_ONE);
1569                 race_send_speedaward(MSG_ONE);
1570
1571                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1572                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1573                 race_send_speedaward_alltimebest(MSG_ONE);
1574
1575                 float i;
1576                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1577                         race_SendRankings(i, 0, 0, MSG_ONE);
1578                 }
1579         }
1580         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1581                 send_CSQC_teamnagger();
1582
1583         CheatInitClient();
1584
1585         if(!autocvar_g_campaign)
1586                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1587
1588         CSQCMODEL_AUTOINIT();
1589
1590         self.model_randomizer = random();
1591
1592     if(clienttype(self) != CLIENTTYPE_REAL)
1593         return;
1594
1595     sv_notice_join();
1596
1597     MUTATOR_CALLHOOK(ClientConnect);
1598 }
1599 /*
1600 =============
1601 ClientDisconnect
1602
1603 Called when a client disconnects from the server
1604 =============
1605 */
1606 .entity chatbubbleentity;
1607 void ReadyCount();
1608 void ClientDisconnect (void)
1609 {
1610         if(self.vehicle)
1611             vehicles_exit(VHEF_RELESE);
1612
1613         if not(self.flags & FL_CLIENT)
1614         {
1615                 print("Warning: ClientDisconnect without ClientConnect\n");
1616                 return;
1617         }
1618
1619         PlayerStats_AddGlobalInfo(self);
1620
1621         CheatShutdownClient();
1622
1623         if(self.hitplotfh >= 0)
1624         {
1625                 fclose(self.hitplotfh);
1626                 self.hitplotfh = -1;
1627         }
1628
1629         anticheat_report();
1630         anticheat_shutdown();
1631
1632         playerdemo_shutdown();
1633
1634         bot_clientdisconnect();
1635
1636         if(self.entcs)
1637                 detach_entcs();
1638
1639         if(autocvar_sv_eventlog)
1640                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1641         bprint ("^4",self.netname);
1642         bprint ("^4 disconnected\n");
1643
1644         DropAllRunes(self);
1645         MUTATOR_CALLHOOK(ClientDisconnect);
1646
1647         Portal_ClearAll(self);
1648
1649         RemoveGrapplingHook(self);
1650
1651         // Here, everything has been done that requires this player to be a client.
1652
1653         self.flags &~= FL_CLIENT;
1654
1655         if (self.chatbubbleentity)
1656                 remove (self.chatbubbleentity);
1657
1658         if (self.killindicator)
1659                 remove (self.killindicator);
1660
1661         WaypointSprite_PlayerGone();
1662
1663         bot_relinkplayerlist();
1664
1665         if(g_arena)
1666         {
1667                 Spawnqueue_Unmark(self);
1668                 Spawnqueue_Remove(self);
1669         }
1670
1671         accuracy_free(self);
1672         ClientData_Detach();
1673         PlayerScore_Detach(self);
1674
1675         if(self.netname_previous)
1676                 strunzone(self.netname_previous);
1677         if(self.clientstatus)
1678                 strunzone(self.clientstatus);
1679         if(self.weaponorder_byimpulse)
1680                 strunzone(self.weaponorder_byimpulse);
1681
1682         ClearPlayerSounds();
1683
1684         if(self.personal)
1685                 remove(self.personal);
1686
1687         self.playerid = 0;
1688         ReadyCount();
1689
1690         // free cvars
1691         GetCvars(-1);
1692 }
1693
1694 .float BUTTON_CHAT;
1695 void ChatBubbleThink()
1696 {
1697         self.nextthink = time;
1698         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1699         {
1700                 if(self.owner) // but why can that ever be world?
1701                         self.owner.chatbubbleentity = world;
1702                 remove(self);
1703                 return;
1704         }
1705         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1706 #ifdef TETRIS
1707                 || self.owner.tetris_on
1708 #endif
1709         )
1710                 self.model = self.mdl;
1711         else
1712                 self.model = "";
1713 }
1714
1715 void UpdateChatBubble()
1716 {
1717         if (self.alpha < 0)
1718                 return;
1719         // spawn a chatbubble entity if needed
1720         if (!self.chatbubbleentity)
1721         {
1722                 self.chatbubbleentity = spawn();
1723                 self.chatbubbleentity.owner = self;
1724                 self.chatbubbleentity.exteriormodeltoclient = self;
1725                 self.chatbubbleentity.think = ChatBubbleThink;
1726                 self.chatbubbleentity.nextthink = time;
1727                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1728                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1729                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1730                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1731                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1732                 self.chatbubbleentity.model = "";
1733                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1734         }
1735 }
1736
1737
1738 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1739 // added to the model skins
1740 /*void UpdateColorModHack()
1741 {
1742         float c;
1743         c = self.clientcolors & 15;
1744         // LordHavoc: only bothering to support white, green, red, yellow, blue
1745              if (!teamplay) self.colormod = '0 0 0';
1746         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1747         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1748         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1749         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1750         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1751         else self.colormod = '1 1 1';
1752 }*/
1753
1754 void respawn(void)
1755 {
1756         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1757         {
1758                 self.solid = SOLID_NOT;
1759                 self.takedamage = DAMAGE_NO;
1760                 self.movetype = MOVETYPE_FLY;
1761                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1762                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1763                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1764                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1765                 if(autocvar_g_respawn_ghosts_maxtime)
1766                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1767         }
1768
1769         CopyBody(1);
1770
1771         self.effects |= EF_NODRAW; // prevent another CopyBody
1772         PutClientInServer();
1773 }
1774
1775 void play_countdown(float finished, string samp)
1776 {
1777         if(clienttype(self) == CLIENTTYPE_REAL)
1778                 if(floor(finished - time - frametime) != floor(finished - time))
1779                         if(finished - time < 6)
1780                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1781 }
1782
1783 void player_powerups (void)
1784 {
1785         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1786         olditems = self.items;
1787
1788         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1789                 self.modelflags |= MF_ROCKET;
1790         else
1791                 self.modelflags &~= MF_ROCKET;
1792
1793         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1794
1795         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1796                 return;
1797
1798         Fire_ApplyDamage(self);
1799         Fire_ApplyEffect(self);
1800
1801         if (g_minstagib)
1802         {
1803                 self.effects |= EF_FULLBRIGHT;
1804
1805                 if (self.items & IT_STRENGTH)
1806                 {
1807                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1808                         if (time > self.strength_finished)
1809                         {
1810                                 self.alpha = default_player_alpha;
1811                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1812                                 self.items &~= IT_STRENGTH;
1813                                 sprint(self, "^3Invisibility has worn off\n");
1814                         }
1815                 }
1816                 else
1817                 {
1818                         if (time < self.strength_finished)
1819                         {
1820                                 self.alpha = g_minstagib_invis_alpha;
1821                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1822                                 self.items |= IT_STRENGTH;
1823                                 sprint(self, "^3You are invisible\n");
1824                         }
1825                 }
1826
1827                 if (self.items & IT_INVINCIBLE)
1828                 {
1829                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1830                         if (time > self.invincible_finished)
1831                         {
1832                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1833                                 sprint(self, "^3Speed has worn off\n");
1834                         }
1835                 }
1836                 else
1837                 {
1838                         if (time < self.invincible_finished)
1839                         {
1840                                 self.items = self.items | IT_INVINCIBLE;
1841                                 sprint(self, "^3You are on speed\n");
1842                         }
1843                 }
1844         }
1845         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1846         {
1847                 if (self.items & IT_STRENGTH)
1848                 {
1849                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1850                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1851                         if (time > self.strength_finished)
1852                         {
1853                                 self.items = self.items - (self.items & IT_STRENGTH);
1854                                 sprint(self, "^3Strength has worn off\n");
1855                         }
1856                 }
1857                 else
1858                 {
1859                         if (time < self.strength_finished)
1860                         {
1861                                 self.items = self.items | IT_STRENGTH;
1862                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1863                         }
1864                 }
1865                 if (self.items & IT_INVINCIBLE)
1866                 {
1867                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1868                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1869                         if (time > self.invincible_finished)
1870                         {
1871                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1872                                 sprint(self, "^3Shield has worn off\n");
1873                         }
1874                 }
1875                 else
1876                 {
1877                         if (time < self.invincible_finished)
1878                         {
1879                                 self.items = self.items | IT_INVINCIBLE;
1880                                 sprint(self, "^3Shield surrounds you\n");
1881                         }
1882                 }
1883                 if (self.items & IT_SUPERWEAPON)
1884                 {
1885                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1886                         {
1887                                 self.superweapons_finished = 0;
1888                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1889                                 sprint(self, "^3Superweapons have been lost\n");
1890                         }
1891                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1892                         {
1893                                 // don't let them run out
1894                         }
1895                         else
1896                         {
1897                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1898                                 if (time > self.superweapons_finished)
1899                                 {
1900                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1901                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1902                                         sprint(self, "^3Superweapons have broken down\n");
1903                                 }
1904                         }
1905                 }
1906                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1907                 {
1908                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1909                         {
1910                                 self.items = self.items | IT_SUPERWEAPON;
1911                                 sprint(self, "^3You now have a superweapon\n");
1912                         }
1913                         else
1914                         {
1915                                 self.superweapons_finished = 0;
1916                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1917                         }
1918                 }
1919                 else
1920                 {
1921                         self.superweapons_finished = 0;
1922                 }
1923         }
1924
1925         if(autocvar_g_nodepthtestplayers)
1926                 self.effects = self.effects | EF_NODEPTHTEST;
1927
1928         if(autocvar_g_fullbrightplayers)
1929                 self.effects = self.effects | EF_FULLBRIGHT;
1930
1931         // midair gamemode: damage only while in the air
1932         // if in midair mode, being on ground grants temporary invulnerability
1933         // (this is so that multishot weapon don't clear the ground flag on the
1934         // first damage in the frame, leaving the player vulnerable to the
1935         // remaining hits in the same frame)
1936         if (self.flags & FL_ONGROUND)
1937         if (g_midair)
1938                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1939
1940         if (time >= game_starttime)
1941         if (time < self.spawnshieldtime)
1942                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1943
1944         MUTATOR_CALLHOOK(PlayerPowerups);
1945 }
1946
1947 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1948 {
1949         if(current > stable)
1950                 return current;
1951         else if(current > stable - 0.25) // when close enough, "snap"
1952                 return stable;
1953         else
1954                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1955 }
1956
1957 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1958 {
1959         if(current < stable)
1960                 return current;
1961         else if(current < stable + 0.25) // when close enough, "snap"
1962                 return stable;
1963         else
1964                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1965 }
1966
1967 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1968 {
1969         if(current > rotstable)
1970         {
1971                 if(rotframetime > 0)
1972                 {
1973                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1974                         current = max(rotstable, current - rotlinear * rotframetime);
1975                 }
1976         }
1977         else if(current < regenstable)
1978         {
1979                 if(regenframetime > 0)
1980                 {
1981                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1982                         current = min(regenstable, current + regenlinear * regenframetime);
1983                 }
1984         }
1985
1986         if(current > limit)
1987                 current = limit;
1988
1989         return current;
1990 }
1991
1992 void player_regen (void)
1993 {
1994         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1995         maxh = autocvar_g_balance_health_rotstable;
1996         maxa = autocvar_g_balance_armor_rotstable;
1997         maxf = autocvar_g_balance_fuel_rotstable;
1998         minh = autocvar_g_balance_health_regenstable;
1999         mina = autocvar_g_balance_armor_regenstable;
2000         minf = autocvar_g_balance_fuel_regenstable;
2001         limith = autocvar_g_balance_health_limit;
2002         limita = autocvar_g_balance_armor_limit;
2003         limitf = autocvar_g_balance_fuel_limit;
2004
2005         max_mod = regen_mod = rot_mod = limit_mod = 1;
2006
2007         if (self.runes & RUNE_REGEN)
2008         {
2009                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2010                 {
2011                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2012                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2013                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2014                 }
2015                 else
2016                 {
2017                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2018                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2019                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2020                 }
2021         }
2022         else if (self.runes & CURSE_VENOM)
2023         {
2024                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2025                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2026                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2027                 else
2028                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2029                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2030                 //if (!self.runes & RUNE_REGEN)
2031                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2032         }
2033         maxh = maxh * max_mod;
2034         //maxa = maxa * max_mod;
2035         //maxf = maxf * max_mod;
2036         minh = minh * max_mod;
2037         //mina = mina * max_mod;
2038         //minf = minf * max_mod;
2039         limith = limith * limit_mod;
2040         limita = limita * limit_mod;
2041         //limitf = limitf * limit_mod;
2042
2043         if(g_lms && g_ca)
2044                 rot_mod = 0;
2045
2046         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2047         {
2048                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2049                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2050
2051                 // if player rotted to death...  die!
2052                 if(self.health < 1)
2053                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2054         }
2055
2056         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2057                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2058 }
2059
2060 float zoomstate_set;
2061 void SetZoomState(float z)
2062 {
2063         if(z != self.zoomstate)
2064         {
2065                 self.zoomstate = z;
2066                 ClientData_Touch(self);
2067         }
2068         zoomstate_set = 1;
2069 }
2070
2071 void GetPressedKeys(void) {
2072         MUTATOR_CALLHOOK(GetPressedKeys);
2073         if (self.movement_x > 0) // get if movement keys are pressed
2074         {       // forward key pressed
2075                 self.pressedkeys |= KEY_FORWARD;
2076                 self.pressedkeys &~= KEY_BACKWARD;
2077         }
2078         else if (self.movement_x < 0)
2079         {       // backward key pressed
2080                 self.pressedkeys |= KEY_BACKWARD;
2081                 self.pressedkeys &~= KEY_FORWARD;
2082         }
2083         else
2084         {       // no x input
2085                 self.pressedkeys &~= KEY_FORWARD;
2086                 self.pressedkeys &~= KEY_BACKWARD;
2087         }
2088
2089         if (self.movement_y > 0)
2090         {       // right key pressed
2091                 self.pressedkeys |= KEY_RIGHT;
2092                 self.pressedkeys &~= KEY_LEFT;
2093         }
2094         else if (self.movement_y < 0)
2095         {       // left key pressed
2096                 self.pressedkeys |= KEY_LEFT;
2097                 self.pressedkeys &~= KEY_RIGHT;
2098         }
2099         else
2100         {       // no y input
2101                 self.pressedkeys &~= KEY_RIGHT;
2102                 self.pressedkeys &~= KEY_LEFT;
2103         }
2104
2105         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2106                 self.pressedkeys |= KEY_JUMP;
2107         else
2108                 self.pressedkeys &~= KEY_JUMP;
2109         if (self.BUTTON_CROUCH)
2110                 self.pressedkeys |= KEY_CROUCH;
2111         else
2112                 self.pressedkeys &~= KEY_CROUCH;
2113
2114         if (self.BUTTON_ATCK)
2115                 self.pressedkeys |= KEY_ATCK;
2116         else
2117                 self.pressedkeys &~= KEY_ATCK;
2118         if (self.BUTTON_ATCK2)
2119                 self.pressedkeys |= KEY_ATCK2;
2120         else
2121                 self.pressedkeys &~= KEY_ATCK2;
2122 }
2123
2124 /*
2125 ======================
2126 spectate mode routines
2127 ======================
2128 */
2129
2130 void SpectateCopy(entity spectatee) {
2131         other = spectatee;
2132         MUTATOR_CALLHOOK(SpectateCopy);
2133         self.armortype = spectatee.armortype;
2134         self.armorvalue = spectatee.armorvalue;
2135         self.ammo_cells = spectatee.ammo_cells;
2136         self.ammo_shells = spectatee.ammo_shells;
2137         self.ammo_nails = spectatee.ammo_nails;
2138         self.ammo_rockets = spectatee.ammo_rockets;
2139         self.ammo_fuel = spectatee.ammo_fuel;
2140         self.clip_load = spectatee.clip_load;
2141         self.clip_size = spectatee.clip_size;
2142         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2143         self.health = spectatee.health;
2144         self.impulse = 0;
2145         self.items = spectatee.items;
2146         self.last_pickup = spectatee.last_pickup;
2147         self.hit_time = spectatee.hit_time;
2148         self.metertime = spectatee.metertime;
2149         self.strength_finished = spectatee.strength_finished;
2150         self.invincible_finished = spectatee.invincible_finished;
2151         self.pressedkeys = spectatee.pressedkeys;
2152         WEPSET_COPY_EE(self, spectatee);
2153         self.switchweapon = spectatee.switchweapon;
2154         self.switchingweapon = spectatee.switchingweapon;
2155         self.weapon = spectatee.weapon;
2156         self.nex_charge = spectatee.nex_charge;
2157         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2158         self.hagar_load = spectatee.hagar_load;
2159         self.minelayer_mines = spectatee.minelayer_mines;
2160         self.punchangle = spectatee.punchangle;
2161         self.view_ofs = spectatee.view_ofs;
2162         self.velocity = spectatee.velocity;
2163         self.dmg_take = spectatee.dmg_take;
2164         self.dmg_save = spectatee.dmg_save;
2165         self.dmg_inflictor = spectatee.dmg_inflictor;
2166         self.v_angle = spectatee.v_angle;
2167         self.angles = spectatee.v_angle;
2168         self.stat_respawn_time = spectatee.stat_respawn_time;
2169         if(!self.BUTTON_USE)
2170                 self.fixangle = TRUE;
2171         setorigin(self, spectatee.origin);
2172         setsize(self, spectatee.mins, spectatee.maxs);
2173         SetZoomState(spectatee.zoomstate);
2174
2175     anticheat_spectatecopy(spectatee);
2176         self.hud = spectatee.hud;
2177         if(spectatee.vehicle)
2178     {
2179         self.fixangle = FALSE;
2180         //self.velocity = spectatee.vehicle.velocity;
2181         self.vehicle_health = spectatee.vehicle_health;
2182         self.vehicle_shield = spectatee.vehicle_shield;
2183         self.vehicle_energy = spectatee.vehicle_energy;
2184         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2185         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2186         self.vehicle_reload1 = spectatee.vehicle_reload1;
2187         self.vehicle_reload2 = spectatee.vehicle_reload2;
2188
2189         msg_entity = self;
2190
2191         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2192             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2193             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2194             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2195
2196         //WriteByte (MSG_ONE, SVC_SETVIEW);
2197         //    WriteEntity(MSG_ONE, self);
2198         //makevectors(spectatee.v_angle);
2199         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2200     }
2201 }
2202
2203 float SpectateUpdate() {
2204         if(!self.enemy)
2205             return 0;
2206
2207         if (self == self.enemy)
2208                 return 0;
2209
2210         if(self.enemy.classname != "player")
2211                 return 0;
2212
2213         SpectateCopy(self.enemy);
2214
2215         return 1;
2216 }
2217
2218
2219 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2220 entity CA_SpectateNext(entity start) {
2221         if (start.team == self.team) {
2222                 return start;
2223         }
2224
2225         other = start;
2226         // continue from current player
2227         while(other && other.team != self.team) {
2228                 other = find(other, classname, "player");
2229         }
2230
2231         if (!other) {
2232                 // restart from begining
2233                 other = find(other, classname, "player");
2234                 while(other && other.team != self.team) {
2235                         other = find(other, classname, "player");
2236                 }
2237         }
2238
2239         return other;
2240 }
2241
2242 float SpectateNext(entity _prefer) {
2243
2244         if(_prefer)
2245                 other = _prefer;
2246         else
2247                 other = find(self.enemy, classname, "player");
2248
2249         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2250                 // CA and ca players when spectating enemies is forbidden
2251                 other = CA_SpectateNext(other);
2252         } else {
2253                 // other modes and ca spectators or spectating enemies is allowed
2254                 if (!other)
2255                         other = find(other, classname, "player");
2256         }
2257
2258         if (other)
2259                 self.enemy = other;
2260
2261         if(self.enemy.classname == "player") {
2262             /*if(self.enemy.vehicle)
2263             {
2264
2265             msg_entity = self;
2266             WriteByte(MSG_ONE, SVC_SETVIEW);
2267             WriteEntity(MSG_ONE, self.enemy);
2268             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2269
2270             self.movetype = MOVETYPE_NONE;
2271             accuracy_resend(self);
2272             }
2273             else
2274             {*/
2275             msg_entity = self;
2276             WriteByte(MSG_ONE, SVC_SETVIEW);
2277             WriteEntity(MSG_ONE, self.enemy);
2278             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2279             self.movetype = MOVETYPE_NONE;
2280             accuracy_resend(self);
2281
2282             if(!SpectateUpdate())
2283                 PutObserverInServer();
2284         //}
2285         return 1;
2286         } else {
2287                 return 0;
2288         }
2289 }
2290
2291 /*
2292 =============
2293 ShowRespawnCountdown()
2294
2295 Update a respawn countdown display.
2296 =============
2297 */
2298 void ShowRespawnCountdown()
2299 {
2300         float number;
2301         if(self.deadflag == DEAD_NO) // just respawned?
2302                 return;
2303         else
2304         {
2305                 number = ceil(self.respawn_time - time);
2306                 if(number <= 0)
2307                         return;
2308                 if(number <= self.respawn_countdown)
2309                 {
2310                         self.respawn_countdown = number - 1;
2311                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2312                                 AnnounceTo(self, strcat(ftos(number), ""));
2313                 }
2314         }
2315 }
2316
2317 .float prevent_join_msgtime;
2318 void LeaveSpectatorMode()
2319 {
2320         if(nJoinAllowed(self)) {
2321                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2322                         self.classname = "player";
2323
2324                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2325                                 JoinBestTeam(self, FALSE, TRUE);
2326
2327                         if(autocvar_g_campaign)
2328                                 campaign_bots_may_start = 1;
2329
2330                         PutClientInServer();
2331
2332                         if(self.classname == "player")
2333                                 bprint ("^4", self.netname, "^4 is playing now\n");
2334
2335                         if(!autocvar_g_campaign)
2336                         if (time < self.jointime + autocvar_welcome_message_time)
2337                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2338
2339                         if (self.prevent_join_msgtime)
2340                         {
2341                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2342                                 self.prevent_join_msgtime = 0;
2343                         }
2344
2345                         return;
2346                 } else {
2347                         if (g_ca && self.caplayer) {
2348                         }       // do nothing
2349                         else
2350                                 stuffcmd(self,"menu_showteamselect\n");
2351                         return;
2352                 }
2353         }
2354         else {
2355                 //player may not join because of g_maxplayers is set
2356                 if (time - self.prevent_join_msgtime > 2)
2357                 {
2358                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2359                         self.prevent_join_msgtime = time;
2360                 }
2361         }
2362 }
2363
2364 /**
2365  * Determines whether the player is allowed to join. This depends on cvar
2366  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2367  * it checks whether the number of currently playing players exceeds g_maxplayers.
2368  * @return int number of free slots for players, 0 if none
2369  */
2370 float nJoinAllowed(entity ignore) {
2371         if(!ignore)
2372         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2373         // so report 0 free slots if restricted
2374         {
2375                 if(autocvar_g_forced_team_otherwise == "spectate")
2376                         return 0;
2377                 if(autocvar_g_forced_team_otherwise == "spectator")
2378                         return 0;
2379         }
2380
2381         if(self.team_forced < 0)
2382                 return 0; // forced spectators can never join
2383
2384         // TODO simplify this
2385         entity e;
2386         float totalClients = 0;
2387         FOR_EACH_CLIENT(e)
2388                 if(e != ignore)
2389                         totalClients += 1;
2390
2391         if (!autocvar_g_maxplayers)
2392                 return maxclients - totalClients;
2393
2394         float currentlyPlaying = 0;
2395         FOR_EACH_REALPLAYER(e)
2396                 currentlyPlaying += 1;
2397
2398         if(currentlyPlaying < autocvar_g_maxplayers)
2399                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2400
2401         return 0;
2402 }
2403
2404 /**
2405  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2406  * g_maxplayers_spectator_blocktime seconds
2407  */
2408 void checkSpectatorBlock() {
2409         if(self.classname == "spectator" || self.classname == "observer") {
2410                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2411                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2412                         dropclient(self);
2413                 }
2414         }
2415 }
2416
2417 .float motd_actived_time; // used for both motd and campaign_message
2418 void PrintWelcomeMessage()
2419 {
2420         if (self.motd_actived_time == 0) { // is there already a message showing?
2421                 if (autocvar_g_campaign) {
2422                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2423                                 self.motd_actived_time = time;
2424                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2425                         }
2426                 } else {
2427                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2428                                 self.motd_actived_time = time;
2429                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2430                         }
2431                 }
2432         } else { // showing MOTD or campaign message
2433                 if (autocvar_g_campaign) {
2434                         if (self.BUTTON_INFO)
2435                                 self.motd_actived_time = time;
2436                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2437                                 self.motd_actived_time = 0;
2438                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2439                         }
2440                 } else {
2441                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2442                                 if (self.BUTTON_INFO)
2443                                         self.motd_actived_time = time;
2444                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2445                                         self.motd_actived_time = 0;
2446                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2447                                 }
2448                         }
2449                 }
2450         }
2451 }
2452
2453 void ObserverThink()
2454 {
2455         float prefered_movetype;
2456         if (self.flags & FL_JUMPRELEASED) {
2457                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2458                         self.flags &~= FL_JUMPRELEASED;
2459                         self.flags |= FL_SPAWNING;
2460                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2461                         self.flags &~= FL_JUMPRELEASED;
2462                         if(SpectateNext(world) == 1) {
2463                                 self.classname = "spectator";
2464                         }
2465                 } else {
2466                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2467                         if (self.movetype != prefered_movetype)
2468                                 self.movetype = prefered_movetype;
2469                 }
2470         } else {
2471                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2472                         self.flags |= FL_JUMPRELEASED;
2473                         if(self.flags & FL_SPAWNING)
2474                         {
2475                                 self.flags &~= FL_SPAWNING;
2476                                 LeaveSpectatorMode();
2477                                 return;
2478                         }
2479                 }
2480         }
2481
2482         PrintWelcomeMessage();
2483 }
2484
2485 void SpectatorThink()
2486 {
2487         if (self.flags & FL_JUMPRELEASED) {
2488                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2489                         self.flags &~= FL_JUMPRELEASED;
2490                         self.flags |= FL_SPAWNING;
2491                 } else if(self.BUTTON_ATCK) {
2492                         self.flags &~= FL_JUMPRELEASED;
2493                         if(SpectateNext(world) == 1) {
2494                                 self.classname = "spectator";
2495                         } else {
2496                                 self.classname = "observer";
2497                                 PutClientInServer();
2498                         }
2499                 } else if (self.BUTTON_ATCK2) {
2500                         self.flags &~= FL_JUMPRELEASED;
2501                         self.classname = "observer";
2502                         PutClientInServer();
2503                 } else {
2504                         if(!SpectateUpdate())
2505                                 PutObserverInServer();
2506                 }
2507         } else {
2508                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2509                         self.flags |= FL_JUMPRELEASED;
2510                         if(self.flags & FL_SPAWNING)
2511                         {
2512                                 self.flags &~= FL_SPAWNING;
2513                                 LeaveSpectatorMode();
2514                                 return;
2515                         }
2516                 }
2517                 if(!SpectateUpdate())
2518                         PutObserverInServer();
2519         }
2520
2521         PrintWelcomeMessage();
2522         self.flags |= FL_CLIENT | FL_NOTARGET;
2523 }
2524
2525 void PlayerUseKey()
2526 {
2527         if(self.classname != "player")
2528                 return;
2529
2530         if(self.vehicle)
2531         {
2532         vehicles_exit(VHEF_NORMAL);
2533         return;
2534         }
2535
2536         // a use key was pressed; call handlers
2537         MUTATOR_CALLHOOK(PlayerUseKey);
2538 }
2539
2540 .float touchexplode_time;
2541
2542 /*
2543 =============
2544 PlayerPreThink
2545
2546 Called every frame for each client before the physics are run
2547 =============
2548 */
2549 .float usekeypressed;
2550 void() nexball_setstatus;
2551 .float items_added;
2552 void PlayerPreThink (void)
2553 {
2554         WarpZone_PlayerPhysics_FixVAngle();
2555
2556         self.stat_game_starttime = game_starttime;
2557         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2558         self.stat_leadlimit = autocvar_leadlimit;
2559
2560         if(g_arena || (g_ca && !allowed_to_spawn))
2561                 self.stat_respawn_time = 0;
2562         else
2563                 self.stat_respawn_time = self.respawn_time;
2564
2565         if(frametime)
2566         {
2567                 // physics frames: update anticheat stuff
2568                 anticheat_prethink();
2569         }
2570
2571         if(blockSpectators && frametime)
2572                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2573                 checkSpectatorBlock();
2574
2575         zoomstate_set = 0;
2576
2577         if(self.netname_previous != self.netname)
2578         {
2579                 if(autocvar_sv_eventlog)
2580                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2581                 if(self.netname_previous)
2582                         strunzone(self.netname_previous);
2583                 self.netname_previous = strzone(self.netname);
2584         }
2585
2586         // version nagging
2587         if(self.version_nagtime)
2588                 if(self.cvar_g_xonoticversion)
2589                         if(time > self.version_nagtime)
2590                         {
2591                                 // don't notify git users
2592                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2593                                 {
2594                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2595                                         {
2596                                                 // notify release users if connecting to git
2597                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2598                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2599                                         }
2600                                         else
2601                                         {
2602                                                 float r;
2603                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2604                                                 if(r < 0)
2605                                                 {
2606                                                         // give users new version
2607                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2608                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2609                                                 }
2610                                                 else if(r > 0)
2611                                                 {
2612                                                         // notify users about old server version
2613                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2614                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2615                                                 }
2616                                         }
2617                                 }
2618                                 self.version_nagtime = 0;
2619                         }
2620
2621         // GOD MODE info
2622         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2623         {
2624                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2625                 self.max_armorvalue = 0;
2626         }
2627
2628 #ifdef TETRIS
2629         if (TetrisPreFrame())
2630                 return;
2631 #endif
2632
2633         MUTATOR_CALLHOOK(PlayerPreThink);
2634
2635         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2636         {
2637                 if(self.BUTTON_USE && !self.usekeypressed)
2638                         PlayerUseKey();
2639                 self.usekeypressed = self.BUTTON_USE;
2640         }
2641
2642         PrintWelcomeMessage();
2643
2644         if(self.classname == "player") {
2645 //              if(self.netname == "Wazat")
2646 //                      bprint(self.classname, "\n");
2647
2648                 CheckRules_Player();
2649
2650                 if (intermission_running)
2651                 {
2652                         IntermissionThink ();   // otherwise a button could be missed between
2653                         return;                                 // the think tics
2654                 }
2655
2656                 //don't allow the player to turn around while game is paused!
2657                 if(timeout_status == TIMEOUT_ACTIVE) {
2658                         // FIXME turn this into CSQC stuff
2659                         self.v_angle = self.lastV_angle;
2660                         self.angles = self.lastV_angle;
2661                         self.fixangle = TRUE;
2662                 }
2663
2664                 if(frametime)
2665                 {
2666                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2667                         {
2668                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2669                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2670                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2671
2672                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2673                                 {
2674                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2675                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2676                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2677                                 }
2678                         }
2679                         else
2680                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2681
2682                         player_powerups();
2683                 }
2684
2685                 if (g_minstagib)
2686                         minstagib_ammocheck();
2687
2688                 if (self.deadflag != DEAD_NO)
2689                 {
2690                         float button_pressed, force_respawn;
2691                         if(self.personal && g_race_qualifying)
2692                         {
2693                                 if(time > self.respawn_time)
2694                                 {
2695                                         self.respawn_time = time + 1; // only retry once a second
2696                                         respawn();
2697                                         self.impulse = 141;
2698                                 }
2699                         }
2700                         else
2701                         {
2702                                 if(frametime)
2703                                         player_anim();
2704                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2705                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2706                                 if (self.deadflag == DEAD_DYING)
2707                                 {
2708                                         if(force_respawn)
2709                                                 self.deadflag = DEAD_RESPAWNING;
2710                                         else if(!button_pressed)
2711                                                 self.deadflag = DEAD_DEAD;
2712                                 }
2713                                 else if (self.deadflag == DEAD_DEAD)
2714                                 {
2715                                         if(button_pressed)
2716                                                 self.deadflag = DEAD_RESPAWNABLE;
2717                                 }
2718                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2719                                 {
2720                                         if(!button_pressed)
2721                                                 self.deadflag = DEAD_RESPAWNING;
2722                                 }
2723                                 else if (self.deadflag == DEAD_RESPAWNING)
2724                                 {
2725                                         if(time > self.respawn_time)
2726                                         {
2727                                                 self.respawn_time = time + 1; // only retry once a second
2728                                                 respawn();
2729                                         }
2730                                 }
2731                                 ShowRespawnCountdown();
2732                         }
2733
2734                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2735                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2736                                 self.stat_respawn_time *= -1;
2737
2738                         return;
2739                 }
2740                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2741                 // so (self.deadflag == DEAD_NO) is always true in the code below
2742
2743                 if(g_touchexplode)
2744                 if(time > self.touchexplode_time)
2745                 if(self.classname == "player")
2746                 if(self.deadflag == DEAD_NO)
2747                 if not(IS_INDEPENDENT_PLAYER(self))
2748                 FOR_EACH_PLAYER(other) if(self != other)
2749                 {
2750                         if(time > other.touchexplode_time)
2751                         if(other.deadflag == DEAD_NO)
2752                         if not(IS_INDEPENDENT_PLAYER(other))
2753                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2754                         {
2755                                 PlayerTouchExplode(self, other);
2756                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2757                         }
2758                 }
2759
2760                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2761                 {
2762                         vector dist;
2763
2764                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2765                         dist = self.prevorigin - self.origin;
2766                         dist_z = 0;
2767                         self.lms_traveled_distance += fabs(vlen(dist));
2768
2769                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2770                         {
2771                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2772                                 self.lms_traveled_distance = 0;
2773                         }
2774
2775                         if(time > self.lms_nextcheck)
2776                         {
2777                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2778                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2779                                 {
2780                                         centerprint(self, autocvar_g_lms_campcheck_message);
2781                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2782                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2783                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2784                                 }
2785                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2786                                 self.lms_traveled_distance = 0;
2787                         }
2788                 }
2789
2790                 self.prevorigin = self.origin;
2791
2792                 float do_crouch = self.BUTTON_CROUCH;
2793                 if(self.hook.state)
2794                         do_crouch = 0;
2795                 if(self.health <= g_bloodloss)
2796                         do_crouch = 1;
2797                 if(self.vehicle)
2798                         do_crouch = 0;
2799                 if(self.freezetag_frozen)
2800                         do_crouch = 0;
2801                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2802                         do_crouch = 0;
2803
2804                 if (do_crouch)
2805                 {
2806                         if (!self.crouch)
2807                         {
2808                                 self.crouch = TRUE;
2809                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2810                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2811                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2812                         }
2813                 }
2814                 else
2815                 {
2816                         if (self.crouch)
2817                         {
2818                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2819                                 if (!trace_startsolid)
2820                                 {
2821                                         self.crouch = FALSE;
2822                                         self.view_ofs = PL_VIEW_OFS;
2823                                         setsize (self, PL_MIN, PL_MAX);
2824                                 }
2825                         }
2826                 }
2827
2828                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2829                 {
2830                         if(self.bloodloss_timer < time)
2831                         {
2832                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2833                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2834                         }
2835                 }
2836
2837                 FixPlayermodel();
2838
2839                 GrapplingHookFrame();
2840
2841                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2842                 //if(frametime)
2843                 {
2844                         self.items &~= self.items_added;
2845
2846                         W_WeaponFrame();
2847
2848                         self.items_added = 0;
2849                         if(self.items & IT_JETPACK)
2850                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2851                                         self.items_added |= IT_FUEL;
2852
2853                         self.items |= self.items_added;
2854                 }
2855
2856                 player_regen();
2857
2858                 // rot nex charge to the charge limit
2859                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2860                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2861
2862                 if(frametime)
2863                         player_anim();
2864
2865                 if(g_nexball)
2866                         nexball_setstatus();
2867
2868                 // secret status
2869                 secrets_setstatus();
2870
2871                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2872
2873                 //self.angles_y=self.v_angle_y + 90;   // temp
2874         } else if(gameover) {
2875                 if (intermission_running)
2876                         IntermissionThink ();   // otherwise a button could be missed between
2877                 return;
2878         } else if(self.classname == "observer") {
2879                 ObserverThink();
2880         } else if(self.classname == "spectator") {
2881                 SpectatorThink();
2882         }
2883
2884         if(!zoomstate_set)
2885                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2886
2887         float oldspectatee_status;
2888         oldspectatee_status = self.spectatee_status;
2889         if(self.classname == "spectator")
2890                 self.spectatee_status = num_for_edict(self.enemy);
2891         else if(self.classname == "observer")
2892                 self.spectatee_status = num_for_edict(self);
2893         else
2894                 self.spectatee_status = 0;
2895         if(self.spectatee_status != oldspectatee_status)
2896         {
2897                 ClientData_Touch(self);
2898                 if(g_race || g_cts)
2899                         race_InitSpectator();
2900         }
2901
2902         if(self.teamkill_soundtime)
2903         if(time > self.teamkill_soundtime)
2904         {
2905                 self.teamkill_soundtime = 0;
2906
2907                 entity oldpusher, oldself;
2908
2909                 oldself = self; self = self.teamkill_soundsource;
2910                 oldpusher = self.pusher; self.pusher = oldself;
2911
2912                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2913
2914                 self.pusher = oldpusher;
2915                 self = oldself;
2916         }
2917
2918         if(self.taunt_soundtime)
2919         if(time > self.taunt_soundtime)
2920         {
2921                 self.taunt_soundtime = 0;
2922                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2923         }
2924
2925         target_voicescript_next(self);
2926
2927         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2928         if(!self.weapon)
2929                 self.clip_load = self.clip_size = 0;
2930 }
2931
2932 float isInvisibleString(string s)
2933 {
2934         float i, n, c;
2935         s = strdecolorize(s);
2936         for((i = 0), (n = strlen(s)); i < n; ++i)
2937         {
2938                 c = str2chr(s, i);
2939                 switch(c)
2940                 {
2941                         case 0:
2942                         case 32: // space
2943                                 break;
2944                         case 192: // charmap space
2945                                 if (!autocvar_utf8_enable)
2946                                         break;
2947                                 return FALSE;
2948                         case 160: // space in unicode fonts
2949                         case 0xE000 + 192: // utf8 charmap space
2950                                 if (autocvar_utf8_enable)
2951                                         break;
2952                         default:
2953                                 return FALSE;
2954                 }
2955         }
2956         return TRUE;
2957 }
2958
2959 /*
2960 =============
2961 PlayerPostThink
2962
2963 Called every frame for each client after the physics are run
2964 =============
2965 */
2966 .float idlekick_lasttimeleft;
2967 void PlayerPostThink (void)
2968 {
2969         // Savage: Check for nameless players
2970         if (isInvisibleString(self.netname)) {
2971                 self.netname = "Player";
2972                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2973         }
2974
2975         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2976         {
2977                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2978                 {
2979                         if(self.idlekick_lasttimeleft)
2980                         {
2981                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2982                                 self.idlekick_lasttimeleft = 0;
2983                         }
2984                 }
2985                 else
2986                 {
2987                         float timeleft;
2988                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2989                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2990                         {
2991                                 if(!self.idlekick_lasttimeleft)
2992                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2993                         }
2994                         if(timeleft <= 0)
2995                         {
2996                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2997                                 AnnounceTo(self, "terminated");
2998                                 dropclient(self);
2999                                 return;
3000                         }
3001                         else if(timeleft <= 10)
3002                         {
3003                                 if(timeleft != self.idlekick_lasttimeleft)
3004                                         AnnounceTo(self, ftos(timeleft));
3005                                 self.idlekick_lasttimeleft = timeleft;
3006                         }
3007                 }
3008         }
3009
3010 #ifdef TETRIS
3011         if(self.impulse == 100)
3012                 ImpulseCommands();
3013         if (!TetrisPostFrame())
3014         {
3015 #endif
3016
3017         CheatFrame();
3018
3019         //CheckPlayerJump();
3020
3021         if(self.classname == "player") {
3022                 CheckRules_Player();
3023                 UpdateChatBubble();
3024                 if (self.impulse)
3025                         ImpulseCommands();
3026                 if (intermission_running)
3027                         return;         // intermission or finale
3028                 GetPressedKeys();
3029         }
3030
3031 #ifdef TETRIS
3032         }
3033 #endif
3034
3035         /*
3036         float i;
3037         for(i = 0; i < 1000; ++i)
3038         {
3039                 vector end;
3040                 end = self.origin + '0 0 1024' + 512 * randomvec();
3041                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3042                 if(trace_fraction < 1)
3043                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3044                 {
3045                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3046                         break;
3047                 }
3048         }
3049         */
3050
3051         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3052
3053         if(self.waypointsprite_attachedforcarrier)
3054                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3055
3056         playerdemo_write();
3057
3058         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3059         {
3060                 if not(self.stored_netname)
3061                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3062                 if(self.stored_netname != self.netname)
3063                 {
3064                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3065                         strunzone(self.stored_netname);
3066                         self.stored_netname = strzone(self.netname);
3067                 }
3068         }
3069
3070         /*
3071         if(g_race)
3072                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3073         */
3074
3075         CSQCMODEL_AUTOUPDATE();
3076 }