qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, autocvar_g_balance_campingrifle_magazinecapacity);
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(autocvar_spawn_debugview)
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > autocvar_g_spawn_furthest)
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(autocvar_spawn_debugview)
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(autocvar_spawn_debug)
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(autocvar_sv_servermodelsonly)
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602         MUTATOR_CALLHOOK(MakePlayerObserver);
 603
 604         Portal_ClearAll(self);
 605
 606         if(self.alivetime)
 607         {
 608                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 609                 self.alivetime = 0;
 610         }
 611
 612         if(self.flagcarried)
 613                 DropFlag(self.flagcarried, world, world);
 614
 615         if(self.ballcarried && g_nexball)
 616                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 617
 618         WaypointSprite_PlayerDead();
 619
 620         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 621                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 622
 623         if(self.killcount != -666) {
 624                 if(g_lms) {
 625                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 626                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 627                         else
 628                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 629                 } else
 630                         bprint ("^4", self.netname, "^4 is spectating now\n");
 631
 632                 if(self.just_joined == FALSE) {
 633                         LogTeamchange(self.playerid, -1, 4);
 634                 } else
 635                         self.just_joined = FALSE;
 636         }
 637
 638         PlayerScore_Clear(self); // clear scores when needed
 639
 640         accuracy_resend(self);
 641
 642         self.spectatortime = time;
 643
 644         self.classname = "observer";
 645         self.iscreature = FALSE;
 646         self.health = -666;
 647         self.takedamage = DAMAGE_NO;
 648         self.solid = SOLID_NOT;
 649         self.movetype = MOVETYPE_NOCLIP;
 650         self.flags = FL_CLIENT | FL_NOTARGET;
 651         self.armorvalue = 666;
 652         self.effects = 0;
 653         self.armorvalue = autocvar_g_balance_armor_start;
 654         self.pauserotarmor_finished = 0;
 655         self.pauserothealth_finished = 0;
 656         self.pauseregen_finished = 0;
 657         self.damageforcescale = 0;
 658         self.death_time = 0;
 659         self.dead_frame = 0;
 660         self.alpha = 0;
 661         self.scale = 0;
 662         self.fade_time = 0;
 663         self.pain_frame = 0;
 664         self.pain_finished = 0;
 665         self.strength_finished = 0;
 666         self.invincible_finished = 0;
 667         self.pushltime = 0;
 668         self.think = SUB_Null;
 669         self.nextthink = 0;
 670         self.hook_time = 0;
 671         self.runes = 0;
 672         self.deadflag = DEAD_NO;
 673         self.angles = spot.angles;
 674         self.angles_z = 0;
 675         self.fixangle = TRUE;
 676         self.crouch = FALSE;
 677
 678         self.view_ofs = PL_VIEW_OFS;
 679         setorigin (self, spot.origin);
 680         setsize (self, '0 0 0', '0 0 0');
 681         self.prevorigin = self.origin;
 682         self.items = 0;
 683         self.weapons = 0;
 684         self.model = "";
 685         FixPlayermodel();
 686         self.model = "";
 687         self.modelindex = 0;
 688         self.weapon = 0;
 689         self.weaponmodel = "";
 690         self.weaponentity = world;
 691         self.exteriorweaponentity = world;
 692         self.killcount = -666;
 693         self.velocity = '0 0 0';
 694         self.avelocity = '0 0 0';
 695         self.punchangle = '0 0 0';
 696         self.punchvector = '0 0 0';
 697         self.oldvelocity = self.velocity;
 698         self.fire_endtime = -1;
 699
 700         if(sv_loddistance1)
 701                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 702
 703         if(g_arena)
 704         {
 705                 if(self.version_mismatch)
 706                 {
 707                         Spawnqueue_Unmark(self);
 708                         Spawnqueue_Remove(self);
 709                 }
 710                 else
 711                 {
 712                         Spawnqueue_Insert(self);
 713                 }
 714         }
 715         else if(g_lms)
 716         {
 717                 // Only if the player cannot play at all
 718                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 719                         self.frags = FRAGS_SPECTATOR;
 720                 else
 721                         self.frags = FRAGS_LMS_LOSER;
 722         }
 723         else
 724                 self.frags = FRAGS_SPECTATOR;
 725 }
 726
 727 float RestrictSkin(float s)
 728 {
 729         if(!teams_matter)
 730                 return s;
 731         if(s == 6)
 732                 return 6;
 733         return mod(s, 3);
 734 }
 735
 736 void FixPlayermodel()
 737 {
 738         local string defaultmodel;
 739         local float defaultskin, chmdl, oldskin;
 740         local vector m1, m2;
 741
 742         defaultmodel = "";
 743
 744         if(autocvar_sv_defaultcharacter == 1) {
 745                 defaultskin = 0;
 746
 747                 if(teams_matter)
 748                 {
 749                         string s;
 750                         s = Team_ColorNameLowerCase(self.team);
 751                         if(s != "neutral")
 752                         {
 753                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 754                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 755                         }
 756                 }
 757
 758                 if(defaultmodel == "")
 759                 {
 760                         defaultmodel = autocvar_sv_defaultplayermodel;
 761                         defaultskin = autocvar_sv_defaultplayerskin;
 762                 }
 763         }
 764
 765         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 766         {
 767                 if(self.model != "")
 768                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 769                 self.model = ""; // force the != checks to return true
 770         }
 771
 772         if(defaultmodel != "")
 773         {
 774                 if (defaultmodel != self.model)
 775                 {
 776                         m1 = self.mins;
 777                         m2 = self.maxs;
 778                         setmodel_lod (self, defaultmodel);
 779                         setsize (self, m1, m2);
 780                         chmdl = TRUE;
 781                 }
 782
 783                 oldskin = self.skinindex;
 784                 self.skinindex = defaultskin;
 785         } else {
 786                 if (self.playermodel != self.model || self.playermodel == "")
 787                 {
 788                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 789                         m1 = self.mins;
 790                         m2 = self.maxs;
 791                         setmodel_lod (self, self.playermodel);
 792                         setsize (self, m1, m2);
 793                         chmdl = TRUE;
 794                 }
 795
 796                 oldskin = self.skinindex;
 797                 self.skinindex = RestrictSkin(stof(self.playerskin));
 798         }
 799
 800         if(chmdl || oldskin != self.skinindex)
 801                 self.species = player_getspecies(); // model or skin has changed
 802
 803         if(!teams_matter)
 804                 if(strlen(autocvar_sv_defaultplayercolors))
 805                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 806                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 807 }
 808
 809 void PlayerTouchExplode(entity p1, entity p2)
 810 {
 811         vector org;
 812         org = (p1.origin + p2.origin) * 0.5;
 813         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 814
 815         te_explosion(org);
 816
 817         entity e;
 818         e = spawn();
 819         setorigin(e, org);
 820         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 821         remove(e);
 822 }
 823
 824 /*
 825 =============
 826 PutClientInServer
 827
 828 Called when a client spawns in the server
 829 =============
 830 */
 831 //void() ctf_playerchanged;
 832 void PutClientInServer (void)
 833 {
 834         if(clienttype(self) == CLIENTTYPE_BOT)
 835         {
 836                 self.classname = "player";
 837         }
 838         else if(clienttype(self) == CLIENTTYPE_REAL)
 839         {
 840                 msg_entity = self;
 841                 WriteByte(MSG_ONE, SVC_SETVIEW);
 842                 WriteEntity(MSG_ONE, self);
 843         }
 844
 845         // player is dead and becomes observer
 846         // FIXME fix LMS scoring for new system
 847         if(g_lms)
 848         {
 849                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 850                         self.classname = "observer";
 851         }
 852
 853         if(g_arena || (g_ca && !allowed_to_spawn))
 854         if(!self.spawned)
 855                 self.classname = "observer";
 856
 857         if(gameover)
 858                 self.classname = "observer";
 859
 860         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 861                 entity spot, oldself;
 862                 float j;
 863
 864                 accuracy_resend(self);
 865
 866                 if(self.team < 0)
 867                         JoinBestTeam(self, FALSE, TRUE);
 868
 869                 race_PreSpawn();
 870
 871                 spot = SelectSpawnPoint (FALSE);
 872                 if(!spot)
 873                 {
 874                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 875                         return; // spawn failed
 876                 }
 877
 878                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 879
 880                 self.classname = "player";
 881                 self.wasplayer = TRUE;
 882                 self.iscreature = TRUE;
 883                 self.movetype = MOVETYPE_WALK;
 884                 self.solid = SOLID_SLIDEBOX;
 885                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 886                 if(autocvar_g_playerclip_collisions)
 887                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 888                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 889                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 890                 self.frags = FRAGS_PLAYER;
 891                 if(independent_players)
 892                         MAKE_INDEPENDENT_PLAYER(self);
 893                 self.flags = FL_CLIENT;
 894                 self.takedamage = DAMAGE_AIM;
 895                 if(g_minstagib)
 896                         self.effects = EF_FULLBRIGHT;
 897                 else
 898                         self.effects = 0;
 899                 self.air_finished = time + 12;
 900                 self.dmg = 2;
 901                 if(autocvar_g_balance_nex_charge)
 902                 {
 903                         if(autocvar_g_balance_nex_secondary_chargepool)
 904                                 self.nex_chargepool_ammo = 1;
 905                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 906                 }
 907
 908                 if(inWarmupStage)
 909                 {
 910                         self.ammo_shells = warmup_start_ammo_shells;
 911                         self.ammo_nails = warmup_start_ammo_nails;
 912                         self.ammo_rockets = warmup_start_ammo_rockets;
 913                         self.ammo_cells = warmup_start_ammo_cells;
 914                         self.ammo_fuel = warmup_start_ammo_fuel;
 915                         self.health = warmup_start_health;
 916                         self.armorvalue = warmup_start_armorvalue;
 917                         self.weapons = warmup_start_weapons;
 918                 }
 919                 else
 920                 {
 921                         self.ammo_shells = start_ammo_shells;
 922                         self.ammo_nails = start_ammo_nails;
 923                         self.ammo_rockets = start_ammo_rockets;
 924                         self.ammo_cells = start_ammo_cells;
 925                         self.ammo_fuel = start_ammo_fuel;
 926                         self.health = start_health;
 927                         self.armorvalue = start_armorvalue;
 928                         self.weapons = start_weapons;
 929                 }
 930
 931                 if(g_weaponarena_random)
 932                 {
 933                         if(g_weaponarena_random_with_laser)
 934                                 self.weapons &~= WEPBIT_LASER;
 935                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 936                         if(g_weaponarena_random_with_laser)
 937                                 self.weapons |= WEPBIT_LASER;
 938                 }
 939
 940                 self.items = start_items;
 941                 self.jump_interval = time;
 942
 943                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 944                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 945                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 946                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 947                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 948                 //extend the pause of rotting if client was reset at the beginning of the countdown
 949                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 950                         self.spawnshieldtime += game_starttime - time;
 951                         self.pauserotarmor_finished += game_starttime - time;
 952                         self.pauserothealth_finished += game_starttime - time;
 953                         self.pauseregen_finished += game_starttime - time;
 954                 }
 955                 self.damageforcescale = 2;
 956                 self.death_time = 0;
 957                 self.dead_frame = 0;
 958                 self.alpha = 0;
 959                 self.scale = 0;
 960                 self.fade_time = 0;
 961                 self.pain_frame = 0;
 962                 self.pain_finished = 0;
 963                 self.strength_finished = 0;
 964                 self.invincible_finished = 0;
 965                 self.pushltime = 0;
 966                 // players have no think function
 967                 self.think = SUB_Null;
 968                 self.nextthink = 0;
 969                 self.hook_time = 0;
 970                 self.dmg_team = 0;
 971                 self.ballistics_density = autocvar_g_ballistics_density_player;
 972
 973                 self.metertime = 0;
 974
 975                 self.runes = 0;
 976
 977                 self.deadflag = DEAD_NO;
 978
 979                 self.angles = spot.angles;
 980
 981                 self.angles_z = 0; // never spawn tilted even if the spot says to
 982                 self.fixangle = TRUE; // turn this way immediately
 983                 self.velocity = '0 0 0';
 984                 self.avelocity = '0 0 0';
 985                 self.punchangle = '0 0 0';
 986                 self.punchvector = '0 0 0';
 987                 self.oldvelocity = self.velocity;
 988                 self.fire_endtime = -1;
 989
 990                 msg_entity = self;
 991                 WRITESPECTATABLE_MSG_ONE({
 992                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 993                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 994                 });
 995
 996                 if(sv_loddistance1)
 997                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 998
 999                 self.model = "";
1000                 FixPlayermodel();
1001
1002                 self.crouch = FALSE;
1003                 self.view_ofs = PL_VIEW_OFS;
1004                 setsize (self, PL_MIN, PL_MAX);
1005                 self.spawnorigin = spot.origin;
1006                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1007                 // don't reset back to last position, even if new position is stuck in solid
1008                 self.oldorigin = self.origin;
1009                 self.prevorigin = self.origin;
1010                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1011
1012                 if(g_arena)
1013                 {
1014                         Spawnqueue_Remove(self);
1015                         Spawnqueue_Mark(self);
1016                 }
1017
1018                 else if(g_ca)
1019                         self.caplayer = 1;
1020
1021                 self.event_damage = PlayerDamage;
1022
1023                 self.bot_attack = TRUE;
1024
1025                 self.statdraintime = time + 5;
1026                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1027
1028                 if(self.killcount == -666) {
1029                         PlayerScore_Clear(self);
1030                         self.killcount = 0;
1031                 }
1032
1033                 self.cnt = WEP_LASER;
1034
1035                 CL_SpawnWeaponentity();
1036                 self.alpha = default_player_alpha;
1037                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1038                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1039
1040                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1041                 self.lms_traveled_distance = 0;
1042                 self.speedrunning = FALSE;
1043
1044                 race_PostSpawn(spot);
1045
1046                 if(autocvar_spawn_debug)
1047                 {
1048                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1049                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1050                 }
1051
1052                 //stuffcmd(self, "chase_active 0");
1053                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1054
1055                 if (autocvar_g_spawnsound)
1056                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1057
1058                 if(g_assault) {
1059                         if(self.team == assault_attacker_team)
1060                                 centerprint(self, "You are attacking!");
1061                         else
1062                                 centerprint(self, "You are defending!");
1063                 }
1064
1065                 target_voicescript_clear(self);
1066
1067                 // reset fields the weapons may use
1068                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1069                         weapon_action(j, WR_RESETPLAYER);
1070
1071                 oldself = self;
1072                 self = spot;
1073                         activator = oldself;
1074                                 SUB_UseTargets();
1075                         activator = world;
1076                 self = oldself;
1077
1078                 MUTATOR_CALLHOOK(PlayerSpawn);
1079
1080                 self.switchweapon = w_getbestweapon(self);
1081                 self.cnt = self.switchweapon;
1082                 self.weapon = 0;
1083
1084                 if(!self.alivetime)
1085                         self.alivetime = time;
1086         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1087                 PutObserverInServer ();
1088         }
1089
1090         //if(g_ctf)
1091         //      ctf_playerchanged();
1092 }
1093
1094 .float ebouncefactor, ebouncestop; // electro's values
1095 // TODO do we need all these fields, or should we stop autodetecting runtime
1096 // changes and just have a console command to update this?
1097 float ClientInit_SendEntity(entity to, float sf)
1098 {
1099         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1100         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1110         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1111         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1112         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1113         if(sv_foginterval && world.fog != "")
1114                 WriteString(MSG_ENTITY, world.fog);
1115         else
1116                 WriteString(MSG_ENTITY, "");
1117         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1118         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1119         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1120         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1121         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1122         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1123         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1124         WriteByte(MSG_ENTITY, autocvar_g_balance_campingrifle_secondary); // client has to know if it should zoom or not
1125         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1126         return TRUE;
1127 }
1128
1129 void ClientInit_CheckUpdate()
1130 {
1131         self.nextthink = time;
1132         if(self.count != autocvar_g_balance_armor_blockpercent)
1133         {
1134                 self.count = autocvar_g_balance_armor_blockpercent;
1135                 self.SendFlags |= 1;
1136         }
1137         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1138         {
1139                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1140                 self.SendFlags |= 1;
1141         }
1142         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1143         {
1144                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1145                 self.SendFlags |= 1;
1146         }
1147         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1148         {
1149                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1150                 self.SendFlags |= 1;
1151         }
1152         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1153         {
1154                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1155                 self.SendFlags |= 1;
1156         }
1157         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1158         {
1159                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1160                 self.SendFlags |= 1;
1161         }
1162 }
1163
1164 void ClientInit_Spawn()
1165 {
1166         entity o;
1167         entity e;
1168         e = spawn();
1169         e.classname = "clientinit";
1170         e.think = ClientInit_CheckUpdate;
1171         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1172
1173         o = self;
1174         self = e;
1175         ClientInit_CheckUpdate();
1176         self = o;
1177 }
1178
1179 /*
1180 =============
1181 SetNewParms
1182 =============
1183 */
1184 void SetNewParms (void)
1185 {
1186         // initialize parms for a new player
1187         parm1 = -(86400 * 366);
1188 }
1189
1190 /*
1191 =============
1192 SetChangeParms
1193 =============
1194 */
1195 void SetChangeParms (void)
1196 {
1197         // save parms for level change
1198         parm1 = self.parm_idlesince - time;
1199 }
1200
1201 /*
1202 =============
1203 DecodeLevelParms
1204 =============
1205 */
1206 void DecodeLevelParms (void)
1207 {
1208         // load parms
1209         self.parm_idlesince = parm1;
1210         if(self.parm_idlesince == -(86400 * 366))
1211                 self.parm_idlesince = time;
1212
1213         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1214         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1215 }
1216
1217 /*
1218 =============
1219 ClientKill
1220
1221 Called when a client types 'kill' in the console
1222 =============
1223 */
1224
1225 void ClientKill_Now_TeamChange()
1226 {
1227         if(self.killindicator_teamchange == -1)
1228         {
1229                 self.team = -1;
1230                 JoinBestTeam( self, FALSE, FALSE );
1231         }
1232         else
1233                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1234 }
1235
1236 void ClientKill_Now()
1237 {
1238         if(self.killindicator_teamchange)
1239                 ClientKill_Now_TeamChange();
1240
1241         // in any case:
1242         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1243
1244         if(self.killindicator)
1245         {
1246                 dprint("Cleaned up after a leaked kill indicator.\n");
1247                 remove(self.killindicator);
1248                 self.killindicator = world;
1249         }
1250 }
1251 void KillIndicator_Think()
1252 {
1253         if (!self.owner.modelindex)
1254         {
1255                 self.owner.killindicator = world;
1256                 remove(self);
1257                 return;
1258         }
1259
1260         if(self.cnt <= 0)
1261         {
1262                 self = self.owner;
1263                 ClientKill_Now(); // no oldself needed
1264                 return;
1265         }
1266         else
1267         {
1268                 if(self.cnt <= 10)
1269                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1270                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1271                 {
1272                         if(self.cnt <= 10)
1273                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1274                         if(self.owner.killindicator_teamchange)
1275                         {
1276                                 if(self.owner.killindicator_teamchange == -1)
1277                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1278                                 else
1279                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1280                         }
1281                         else
1282                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1283                 }
1284                 self.nextthink = time + 1;
1285                 self.cnt -= 1;
1286         }
1287 }
1288
1289 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1290 {
1291         float killtime;
1292         entity e;
1293         killtime = autocvar_g_balance_kill_delay;
1294
1295         if(g_race_qualifying)
1296                 killtime = 0;
1297
1298         self.killindicator_teamchange = targetteam;
1299
1300         if(!self.killindicator)
1301         {
1302                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1303                 {
1304                         ClientKill_Now();
1305                 }
1306                 else
1307                 {
1308                         self.killindicator = spawn();
1309                         self.killindicator.owner = self;
1310                         self.killindicator.scale = 0.5;
1311                         setattachment(self.killindicator, self, "");
1312                         setorigin(self.killindicator, '0 0 52');
1313                         self.killindicator.think = KillIndicator_Think;
1314                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1315                         self.killindicator.cnt = ceil(killtime);
1316                         self.killindicator.count = bound(0, ceil(killtime), 10);
1317                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1318
1319                         for(e = world; (e = find(e, classname, "body")) != world; )
1320                         {
1321                                 if(e.enemy != self)
1322                                         continue;
1323                                 e.killindicator = spawn();
1324                                 e.killindicator.owner = e;
1325                                 e.killindicator.scale = 0.5;
1326                                 setattachment(e.killindicator, e, "");
1327                                 setorigin(e.killindicator, '0 0 52');
1328                                 e.killindicator.think = KillIndicator_Think;
1329                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1330                                 e.killindicator.cnt = ceil(killtime);
1331                         }
1332                         self.lip = 0;
1333                 }
1334         }
1335         if(self.killindicator)
1336         {
1337                 if(targetteam)
1338                         self.killindicator.colormod = TeamColor(targetteam);
1339                 else
1340                         self.killindicator.colormod = '0 0 0';
1341         }
1342 }
1343
1344 void ClientKill (void)
1345 {
1346         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1347         {
1348                 // do nothing
1349         }
1350     else if(g_freezetag && self.freezetag_frozen == 1)
1351     {
1352         // do nothing
1353     }
1354         else
1355                 ClientKill_TeamChange(0);
1356 }
1357
1358 void CTS_ClientKill_Think (void)
1359 {
1360         self = self.owner; // set self to the player to be killed
1361         sprint(self, "^1You were killed in order to prevent cheating!");
1362         ClientKill_Now();
1363 }
1364
1365 void CTS_ClientKill (float t) // silent version of ClientKill
1366 {
1367         entity e;
1368         e = spawn();
1369         e.owner = self;
1370         e.think = CTS_ClientKill_Think;
1371         e.nextthink = t;
1372 }
1373
1374 void DoTeamChange(float destteam)
1375 {
1376         float t, c0;
1377         if(!teams_matter)
1378         {
1379                 if(destteam >= 0)
1380                         SetPlayerColors(self, destteam);
1381                 return;
1382         }
1383         if(self.classname == "player")
1384         if(destteam == -1)
1385         {
1386                 CheckAllowedTeams(self);
1387                 t = FindSmallestTeam(self, TRUE);
1388                 switch(self.team)
1389                 {
1390                         case COLOR_TEAM1: c0 = c1; break;
1391                         case COLOR_TEAM2: c0 = c2; break;
1392                         case COLOR_TEAM3: c0 = c3; break;
1393                         case COLOR_TEAM4: c0 = c4; break;
1394                         default:          c0 = 999;
1395                 }
1396                 switch(t)
1397                 {
1398                         case 1:
1399                                 if(c0 > c1)
1400                                         destteam = COLOR_TEAM1;
1401                                 break;
1402                         case 2:
1403                                 if(c0 > c2)
1404                                         destteam = COLOR_TEAM2;
1405                                 break;
1406                         case 3:
1407                                 if(c0 > c3)
1408                                         destteam = COLOR_TEAM3;
1409                                 break;
1410                         case 4:
1411                                 if(c0 > c4)
1412                                         destteam = COLOR_TEAM4;
1413                                 break;
1414                 }
1415                 if(destteam == -1)
1416                         return;
1417         }
1418         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1419                 return;
1420         ClientKill_TeamChange(destteam);
1421 }
1422
1423 void FixClientCvars(entity e)
1424 {
1425         // send prediction settings to the client
1426         stuffcmd(e, "\nin_bindmap 0 0\n");
1427         if(g_race || g_cts)
1428                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1429         if(autocvar_g_antilag == 3) // client side hitscan
1430                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1431         if(sv_gentle)
1432                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1433         /*
1434          * we no longer need to stuff this. Remove this comment block if you feel
1435          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1436         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1437         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1438         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1439         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1440         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1441         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1442         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1443         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1444         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1445         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1446         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1447         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1448         stuffcmd(e, "cl_movement_edgefriction 1\n");
1449          */
1450 }
1451
1452 float PlayerInIDList(entity p, string idlist)
1453 {
1454         float n, i;
1455         string s;
1456
1457         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1458         if not(p.crypto_idfp)
1459                 return 0;
1460
1461         // this function allows abbreviated player IDs too!
1462         n = tokenize_console(idlist);
1463         for(i = 0; i < n; ++i)
1464         {
1465                 s = argv(i);
1466                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1467                         return 1;
1468         }
1469
1470         return 0;
1471 }
1472
1473 /*
1474 =============
1475 ClientConnect
1476
1477 Called when a client connects to the server
1478 =============
1479 */
1480 //void ctf_clientconnect();
1481 string ColoredTeamName(float t);
1482 void DecodeLevelParms (void);
1483 //void dom_player_join_team(entity pl);
1484 void ClientConnect (void)
1485 {
1486         float t;
1487
1488         if(self.flags & FL_CLIENT)
1489         {
1490                 print("Warning: ClientConnect, but already connected!\n");
1491                 return;
1492         }
1493
1494         if(Ban_MaybeEnforceBan(self))
1495                 return;
1496
1497         DecodeLevelParms();
1498
1499 #ifdef WATERMARK
1500         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1501 #endif
1502
1503         self.classname = "player_joining";
1504
1505         self.flags = FL_CLIENT;
1506         self.version_nagtime = time + 10 + random() * 10;
1507
1508         if(player_count<0)
1509         {
1510                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1511                 player_count = 0;
1512         }
1513
1514         PlayerScore_Attach(self);
1515         ClientData_Attach();
1516         accuracy_init(self);
1517
1518         bot_clientconnect();
1519
1520         playerdemo_init();
1521
1522         anticheat_init();
1523
1524         race_PreSpawnObserver();
1525
1526         //if(g_domination)
1527         //      dom_player_join_team(self);
1528
1529         // identify the right forced team
1530         if(PlayerInIDList(self, autocvar_g_forced_team_red))
1531                 self.team_forced = COLOR_TEAM1;
1532         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1533                 self.team_forced = COLOR_TEAM2;
1534         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1535                 self.team_forced = COLOR_TEAM3;
1536         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1537                 self.team_forced = COLOR_TEAM4;
1538         else if(autocvar_g_forced_team_otherwise == "red")
1539                 self.team_forced = COLOR_TEAM1;
1540         else if(autocvar_g_forced_team_otherwise == "blue")
1541                 self.team_forced = COLOR_TEAM2;
1542         else if(autocvar_g_forced_team_otherwise == "yellow")
1543                 self.team_forced = COLOR_TEAM3;
1544         else if(autocvar_g_forced_team_otherwise == "pink")
1545                 self.team_forced = COLOR_TEAM4;
1546         else if(autocvar_g_forced_team_otherwise == "spectate")
1547                 self.team_forced = -1;
1548         else if(autocvar_g_forced_team_otherwise == "spectator")
1549                 self.team_forced = -1;
1550         else
1551                 self.team_forced = 0;
1552
1553         if(!teams_matter)
1554                 if(self.team_forced > 0)
1555                         self.team_forced = 0;
1556
1557         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1558
1559         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1560                 self.classname = "observer";
1561         } else {
1562                 if(teams_matter)
1563                 {
1564                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1565                         {
1566                                 self.classname = "player";
1567                                 campaign_bots_may_start = 1;
1568                         }
1569                         else
1570                         {
1571                                 self.classname = "observer"; // do it anyway
1572                         }
1573                 }
1574                 else
1575                 {
1576                         self.classname = "player";
1577                         campaign_bots_may_start = 1;
1578                 }
1579         }
1580
1581         self.playerid = (playerid_last = playerid_last + 1);
1582
1583         if(autocvar_sv_eventlog)
1584                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1585
1586         LogTeamchange(self.playerid, self.team, 1);
1587
1588         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1589
1590         self.netname_previous = strzone(self.netname);
1591
1592         bprint("^4", self.netname, "^4 connected");
1593
1594         if(self.classname != "observer" && (g_domination || g_ctf))
1595                 bprint(" and joined the ", ColoredTeamName(self.team));
1596
1597         bprint("\n");
1598
1599         self.welcomemessage_time = 0;
1600
1601         stuffcmd(self, strcat(clientstuff, "\n"));
1602         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1603         stuffcmd(self, "cl_particles_reloadeffects\n");
1604
1605         FixClientCvars(self);
1606
1607         // spawnfunc_waypoint sprites
1608         WaypointSprite_InitClient(self);
1609
1610         // Wazat's grappling hook
1611         SetGrappleHookBindings();
1612
1613         // get autoswitch state from player when he toggles it
1614         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1615
1616         // get version info from player
1617         stuffcmd(self, "cmd clientversion $gameversion\n");
1618
1619         // get other cvars from player
1620         GetCvars(0);
1621
1622         // notify about available teams
1623         if(teams_matter)
1624         {
1625                 CheckAllowedTeams(self);
1626                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1627                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1628         }
1629         else
1630                 stuffcmd(self, "set _teams_available 0\n");
1631
1632         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1633
1634         if(g_arena || g_ca)
1635         {
1636                 self.classname = "observer";
1637                 if(g_arena)
1638                         Spawnqueue_Insert(self);
1639         }
1640         /*else if(g_ctf)
1641         {
1642                 ctf_clientconnect();
1643         }*/
1644
1645         if(teams_matter || radar_showennemies)
1646                 attach_entcs();
1647
1648         bot_relinkplayerlist();
1649
1650         self.spectatortime = time;
1651         if(blockSpectators)
1652         {
1653                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1654         }
1655
1656         self.jointime = time;
1657         self.allowedTimeouts = autocvar_sv_timeout_number;
1658
1659         if(clienttype(self) == CLIENTTYPE_REAL)
1660         {
1661                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1662                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1663         }
1664
1665         if(g_lms)
1666         {
1667                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1668                 {
1669                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1670                         self.frags = FRAGS_SPECTATOR;
1671                 }
1672         }
1673
1674         if(!sv_foginterval && world.fog != "")
1675                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1676
1677         SoundEntity_Attach(self);
1678
1679         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1680         {
1681                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1682                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1683         }
1684         else
1685                 self.hitplotfh = -1;
1686
1687         if(g_race || g_cts) {
1688                 string rr;
1689                 if(g_cts)
1690                         rr = CTS_RECORD;
1691                 else
1692                         rr = RACE_RECORD;
1693                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1694
1695                 msg_entity = self;
1696                 race_send_recordtime(MSG_ONE);
1697                 race_send_speedaward(MSG_ONE);
1698
1699                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1700                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1701                 race_send_speedaward_alltimebest(MSG_ONE);
1702
1703                 float i;
1704                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1705                         race_SendRankings(i, 0, 0, MSG_ONE);
1706                 }
1707         }
1708         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1709                 send_CSQC_teamnagger();
1710
1711         send_CSQC_cr_maxbullets(self);
1712
1713         CheatInitClient();
1714
1715         PlayerStats_AddPlayer(self);
1716 }
1717
1718 /*
1719 =============
1720 ClientDisconnect
1721
1722 Called when a client disconnects from the server
1723 =============
1724 */
1725 .entity chatbubbleentity;
1726 .entity teambubbleentity;
1727 void ReadyCount();
1728 void ClientDisconnect (void)
1729 {
1730         if not(self.flags & FL_CLIENT)
1731         {
1732                 print("Warning: ClientDisconnect without ClientConnect\n");
1733                 return;
1734         }
1735
1736         PlayerStats_AddGlobalInfo(self);
1737
1738         CheatShutdownClient();
1739
1740         if(self.hitplotfh >= 0)
1741         {
1742                 fclose(self.hitplotfh);
1743                 self.hitplotfh = -1;
1744         }
1745
1746         anticheat_report();
1747         anticheat_shutdown();
1748
1749         playerdemo_shutdown();
1750
1751         bot_clientdisconnect();
1752
1753         if(self.entcs)
1754                 detach_entcs();
1755
1756         if(autocvar_sv_eventlog)
1757                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1758         bprint ("^4",self.netname);
1759         bprint ("^4 disconnected\n");
1760
1761         SoundEntity_Detach(self);
1762
1763         DropAllRunes(self);
1764         MUTATOR_CALLHOOK(ClientDisconnect);
1765
1766         Portal_ClearAll(self);
1767
1768         if(self.flagcarried)
1769                 DropFlag(self.flagcarried, world, world);
1770         if(self.ballcarried && g_nexball)
1771                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1772
1773         // Here, everything has been done that requires this player to be a client.
1774
1775         self.flags &~= FL_CLIENT;
1776
1777         if (self.chatbubbleentity)
1778                 remove (self.chatbubbleentity);
1779
1780         if (self.teambubbleentity)
1781                 remove (self.teambubbleentity);
1782
1783         if (self.killindicator)
1784                 remove (self.killindicator);
1785
1786         WaypointSprite_PlayerGone();
1787
1788         bot_relinkplayerlist();
1789
1790         if(g_arena)
1791         {
1792                 Spawnqueue_Unmark(self);
1793                 Spawnqueue_Remove(self);
1794         }
1795
1796         accuracy_free(self);
1797         ClientData_Detach();
1798         PlayerScore_Detach(self);
1799
1800         if(self.netname_previous)
1801                 strunzone(self.netname_previous);
1802         if(self.clientstatus)
1803                 strunzone(self.clientstatus);
1804         if(self.weaponorder_byimpulse)
1805                 strunzone(self.weaponorder_byimpulse);
1806
1807         ClearPlayerSounds();
1808
1809         if(self.personal)
1810                 remove(self.personal);
1811
1812         self.playerid = 0;
1813         ReadyCount();
1814
1815         // free cvars
1816         GetCvars(-1);
1817 }
1818
1819 .float BUTTON_CHAT;
1820 void ChatBubbleThink()
1821 {
1822         self.nextthink = time;
1823         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1824         {
1825                 if(self.owner) // but why can that ever be world?
1826                         self.owner.chatbubbleentity = world;
1827                 remove(self);
1828                 return;
1829         }
1830         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1831 #ifdef TETRIS
1832                 || self.owner.tetris_on
1833 #endif
1834         )
1835                 self.model = self.mdl;
1836         else
1837                 self.model = "";
1838 };
1839
1840 void UpdateChatBubble()
1841 {
1842         if (!self.modelindex)
1843                 return;
1844         // spawn a chatbubble entity if needed
1845         if (!self.chatbubbleentity)
1846         {
1847                 self.chatbubbleentity = spawn();
1848                 self.chatbubbleentity.owner = self;
1849                 self.chatbubbleentity.exteriormodeltoclient = self;
1850                 self.chatbubbleentity.think = ChatBubbleThink;
1851                 self.chatbubbleentity.nextthink = time;
1852                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1853                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1854                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1855                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1856                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1857                 self.chatbubbleentity.model = "";
1858                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1859         }
1860 }
1861
1862
1863 void TeamBubbleThink()
1864 {
1865         self.nextthink = time;
1866         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1867         {
1868                 if(self.owner) // but why can that ever be world?
1869                         self.owner.teambubbleentity = world;
1870                 remove(self);
1871                 return;
1872         }
1873 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1874         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1875                 self.model = "";
1876         else
1877                 self.model = self.mdl;
1878
1879 };
1880
1881 float TeamBubble_customizeentityforclient()
1882 {
1883         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1884 }
1885
1886 void UpdateTeamBubble()
1887 {
1888         if (!self.modelindex || !teams_matter)
1889                 return;
1890         // spawn a teambubble entity if needed
1891         if (!self.teambubbleentity && teams_matter)
1892         {
1893                 self.teambubbleentity = spawn();
1894                 self.teambubbleentity.owner = self;
1895                 self.teambubbleentity.exteriormodeltoclient = self;
1896                 self.teambubbleentity.think = TeamBubbleThink;
1897                 self.teambubbleentity.nextthink = time;
1898                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1899 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1900                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1901                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1902                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1903                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1904                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1905                 self.teambubbleentity.effects = EF_LOWPRECISION;
1906         }
1907 }
1908
1909 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1910 // added to the model skins
1911 /*void UpdateColorModHack()
1912 {
1913         local float c;
1914         c = self.clientcolors & 15;
1915         // LordHavoc: only bothering to support white, green, red, yellow, blue
1916              if (!teams_matter) self.colormod = '0 0 0';
1917         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1918         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1919         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1920         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1921         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1922         else self.colormod = '1 1 1';
1923 };*/
1924
1925 .float oldcolormap;
1926 void respawn(void)
1927 {
1928         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1929         {
1930                 self.solid = SOLID_NOT;
1931                 self.takedamage = DAMAGE_NO;
1932                 self.movetype = MOVETYPE_FLY;
1933                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1934                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1935                 self.effects |= EF_ADDITIVE;
1936                 self.oldcolormap = self.colormap;
1937                 self.colormap = 512;
1938                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1939                 if(autocvar_g_respawn_ghosts_maxtime)
1940                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1941         }
1942
1943         CopyBody(1);
1944         self.effects |= EF_NODRAW; // prevent another CopyBody
1945         if(self.oldcolormap)
1946         {
1947                 self.colormap = self.oldcolormap;
1948                 self.oldcolormap = 0;
1949         }
1950         PutClientInServer();
1951 }
1952
1953 void play_countdown(float finished, string samp)
1954 {
1955         if(clienttype(self) == CLIENTTYPE_REAL)
1956                 if(floor(finished - time - frametime) != floor(finished - time))
1957                         if(finished - time < 6)
1958                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1959 }
1960
1961 /**
1962  * When sv_timeout is used this function returs strings like
1963  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1964  * Called by centerprint functions
1965  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1966  */
1967 string getTimeoutText(float addOneSecond) {
1968         if (!autocvar_sv_timeout || !timeoutStatus)
1969                 return "";
1970
1971         local string retStr;
1972         if (timeoutStatus == 1) {
1973                 if (addOneSecond == 1) {
1974                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1975                 }
1976                 else {
1977                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1978                 }
1979                 return retStr;
1980         }
1981         else if (timeoutStatus == 2) {
1982                 if (addOneSecond) {
1983                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1984                         //don't show messages like "Timeout ends in 0 seconds"...
1985                         if ((remainingTimeoutTime + 1) > 0)
1986                                 return retStr;
1987                         else
1988                                 return "";
1989                 }
1990                 else {
1991                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1992                         //don't show messages like "Timeout ends in 0 seconds"...
1993                         if (remainingTimeoutTime > 0)
1994                                 return retStr;
1995                         else
1996                                 return "";
1997                 }
1998         }
1999         else return "";
2000 }
2001
2002 void player_powerups (void)
2003 {
2004         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2005         olditems = self.items;
2006
2007         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2008         {
2009                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2010                 self.modelflags |= MF_ROCKET;
2011         }
2012         else
2013         {
2014                 SoundEntity_StopSound(self, CHAN_PLAYER);
2015                 self.modelflags &~= MF_ROCKET;
2016         }
2017
2018         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2019
2020         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2021                 return;
2022
2023         Fire_ApplyDamage(self);
2024         Fire_ApplyEffect(self);
2025
2026         if (g_minstagib)
2027         {
2028                 self.effects |= EF_FULLBRIGHT;
2029
2030                 if (self.items & IT_STRENGTH)
2031                 {
2032                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2033                         if (time > self.strength_finished)
2034                         {
2035                                 self.alpha = default_player_alpha;
2036                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2037                                 self.items &~= IT_STRENGTH;
2038                                 sprint(self, "^3Invisibility has worn off\n");
2039                         }
2040                 }
2041                 else
2042                 {
2043                         if (time < self.strength_finished)
2044                         {
2045                                 self.alpha = g_minstagib_invis_alpha;
2046                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2047                                 self.items |= IT_STRENGTH;
2048                                 sprint(self, "^3You are invisible\n");
2049                         }
2050                 }
2051
2052                 if (self.items & IT_INVINCIBLE)
2053                 {
2054                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2055                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2056                         {
2057                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2058                                 sprint(self, "^3Speed has worn off\n");
2059                         }
2060                 }
2061                 else
2062                 {
2063                         if (time < self.invincible_finished)
2064                         {
2065                                 self.items = self.items | IT_INVINCIBLE;
2066                                 sprint(self, "^3You are on speed\n");
2067                         }
2068                 }
2069         }
2070         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2071         {
2072                 if (self.items & IT_STRENGTH)
2073                 {
2074                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2075                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2076                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2077                         {
2078                                 self.items = self.items - (self.items & IT_STRENGTH);
2079                                 sprint(self, "^3Strength has worn off\n");
2080                         }
2081                 }
2082                 else
2083                 {
2084                         if (time < self.strength_finished)
2085                         {
2086                                 self.items = self.items | IT_STRENGTH;
2087                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2088                         }
2089                 }
2090                 if (self.items & IT_INVINCIBLE)
2091                 {
2092                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2093                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2094                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2095                         {
2096                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2097                                 sprint(self, "^3Shield has worn off\n");
2098                         }
2099                 }
2100                 else
2101                 {
2102                         if (time < self.invincible_finished)
2103                         {
2104                                 self.items = self.items | IT_INVINCIBLE;
2105                                 sprint(self, "^3Shield surrounds you\n");
2106                         }
2107                 }
2108
2109                 if(autocvar_g_nodepthtestplayers)
2110                         self.effects = self.effects | EF_NODEPTHTEST;
2111
2112                 if(autocvar_g_fullbrightplayers)
2113                         self.effects = self.effects | EF_FULLBRIGHT;
2114
2115                 // midair gamemode: damage only while in the air
2116                 // if in midair mode, being on ground grants temporary invulnerability
2117                 // (this is so that multishot weapon don't clear the ground flag on the
2118                 // first damage in the frame, leaving the player vulnerable to the
2119                 // remaining hits in the same frame)
2120                 if (self.flags & FL_ONGROUND)
2121                 if (g_midair)
2122                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2123
2124                 if (time >= game_starttime)
2125                 if (time < self.spawnshieldtime)
2126                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2127         }
2128
2129         MUTATOR_CALLHOOK(PlayerPowerups);
2130 }
2131
2132 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2133 {
2134         if(current > stable)
2135                 return current;
2136         else if(current > stable - 0.25) // when close enough, "snap"
2137                 return stable;
2138         else
2139                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2140 }
2141
2142 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2143 {
2144         if(current < stable)
2145                 return current;
2146         else if(current < stable + 0.25) // when close enough, "snap"
2147                 return stable;
2148         else
2149                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2150 }
2151
2152 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2153 {
2154         if(current > rotstable)
2155         {
2156                 if(rotframetime > 0)
2157                 {
2158                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2159                         current = max(rotstable, current - rotlinear * rotframetime);
2160                 }
2161         }
2162         else if(current < regenstable)
2163         {
2164                 if(regenframetime > 0)
2165                 {
2166                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2167                         current = min(regenstable, current + regenlinear * regenframetime);
2168                 }
2169         }
2170
2171         if(current > limit)
2172                 current = limit;
2173
2174         return current;
2175 }
2176
2177 void player_regen (void)
2178 {
2179         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2180         maxh = autocvar_g_balance_health_rotstable;
2181         maxa = autocvar_g_balance_armor_rotstable;
2182         maxf = autocvar_g_balance_fuel_rotstable;
2183         minh = autocvar_g_balance_health_regenstable;
2184         mina = autocvar_g_balance_armor_regenstable;
2185         minf = autocvar_g_balance_fuel_regenstable;
2186         limith = autocvar_g_balance_health_limit;
2187         limita = autocvar_g_balance_armor_limit;
2188         limitf = autocvar_g_balance_fuel_limit;
2189
2190         max_mod = regen_mod = rot_mod = limit_mod = 1;
2191
2192         if (self.runes & RUNE_REGEN)
2193         {
2194                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2195                 {
2196                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2197                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2198                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2199                 }
2200                 else
2201                 {
2202                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2203                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2204                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2205                 }
2206         }
2207         else if (self.runes & CURSE_VENOM)
2208         {
2209                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2210                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2211                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2212                 else
2213                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2214                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2215                 //if (!self.runes & RUNE_REGEN)
2216                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2217         }
2218         maxh = maxh * max_mod;
2219         //maxa = maxa * max_mod;
2220         //maxf = maxf * max_mod;
2221         minh = minh * max_mod;
2222         //mina = mina * max_mod;
2223         //minf = minf * max_mod;
2224         limith = limith * limit_mod;
2225         limita = limita * limit_mod;
2226         //limitf = limitf * limit_mod;
2227
2228         if(g_lms && g_ca)
2229                 rot_mod = 0;
2230
2231         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2232         {
2233                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2234                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2235
2236                 // if player rotted to death...  die!
2237                 if(self.health < 1)
2238                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2239         }
2240
2241         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2242                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2243 }
2244
2245 float zoomstate_set;
2246 void SetZoomState(float z)
2247 {
2248         if(z != self.zoomstate)
2249         {
2250                 self.zoomstate = z;
2251                 ClientData_Touch(self);
2252         }
2253         zoomstate_set = 1;
2254 }
2255
2256 void GetPressedKeys(void) {
2257         MUTATOR_CALLHOOK(GetPressedKeys);
2258         if (self.movement_x > 0) // get if movement keys are pressed
2259         {       // forward key pressed
2260                 self.pressedkeys |= KEY_FORWARD;
2261                 self.pressedkeys &~= KEY_BACKWARD;
2262         }
2263         else if (self.movement_x < 0)
2264         {       // backward key pressed
2265                 self.pressedkeys |= KEY_BACKWARD;
2266                 self.pressedkeys &~= KEY_FORWARD;
2267         }
2268         else
2269         {       // no x input
2270                 self.pressedkeys &~= KEY_FORWARD;
2271                 self.pressedkeys &~= KEY_BACKWARD;
2272         }
2273
2274         if (self.movement_y > 0)
2275         {       // right key pressed
2276                 self.pressedkeys |= KEY_RIGHT;
2277                 self.pressedkeys &~= KEY_LEFT;
2278         }
2279         else if (self.movement_y < 0)
2280         {       // left key pressed
2281                 self.pressedkeys |= KEY_LEFT;
2282                 self.pressedkeys &~= KEY_RIGHT;
2283         }
2284         else
2285         {       // no y input
2286                 self.pressedkeys &~= KEY_RIGHT;
2287                 self.pressedkeys &~= KEY_LEFT;
2288         }
2289
2290         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2291                 self.pressedkeys |= KEY_JUMP;
2292         else
2293                 self.pressedkeys &~= KEY_JUMP;
2294         if (self.BUTTON_CROUCH)
2295                 self.pressedkeys |= KEY_CROUCH;
2296         else
2297                 self.pressedkeys &~= KEY_CROUCH;
2298 }
2299
2300 /*
2301 ======================
2302 spectate mode routines
2303 ======================
2304 */
2305
2306 void SpectateCopy(entity spectatee) {
2307         other = spectatee;
2308         MUTATOR_CALLHOOK(SpectateCopy);
2309         self.armortype = spectatee.armortype;
2310         self.armorvalue = spectatee.armorvalue;
2311         self.ammo_cells = spectatee.ammo_cells;
2312         self.ammo_shells = spectatee.ammo_shells;
2313         self.ammo_nails = spectatee.ammo_nails;
2314         self.ammo_rockets = spectatee.ammo_rockets;
2315         self.ammo_fuel = spectatee.ammo_fuel;
2316         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2317         self.health = spectatee.health;
2318         self.impulse = 0;
2319         self.items = spectatee.items;
2320         self.last_pickup = spectatee.last_pickup;
2321         self.metertime = spectatee.metertime;
2322         self.strength_finished = spectatee.strength_finished;
2323         self.invincible_finished = spectatee.invincible_finished;
2324         self.pressedkeys = spectatee.pressedkeys;
2325         self.weapons = spectatee.weapons;
2326         self.switchweapon = spectatee.switchweapon;
2327         self.weapon = spectatee.weapon;
2328         self.punchangle = spectatee.punchangle;
2329         self.view_ofs = spectatee.view_ofs;
2330         self.v_angle = spectatee.v_angle;
2331         self.velocity = spectatee.velocity;
2332         self.dmg_take = spectatee.dmg_take;
2333         self.dmg_save = spectatee.dmg_save;
2334         self.dmg_inflictor = spectatee.dmg_inflictor;
2335         self.angles = spectatee.v_angle;
2336         self.fixangle = TRUE;
2337         setorigin(self, spectatee.origin);
2338         setsize(self, spectatee.mins, spectatee.maxs);
2339         SetZoomState(spectatee.zoomstate);
2340
2341         anticheat_spectatecopy(spectatee);
2342 }
2343
2344 float SpectateUpdate() {
2345         if(!self.enemy)
2346                 return 0;
2347
2348         if (self == self.enemy)
2349                 return 0;
2350
2351         if(self.enemy.classname != "player")
2352                 return 0;
2353
2354         SpectateCopy(self.enemy);
2355
2356         return 1;
2357 }
2358
2359 float SpectateNext() {
2360         other = find(self.enemy, classname, "player");
2361
2362         if (!other)
2363                 other = find(other, classname, "player");
2364
2365         if (other)
2366                 self.enemy = other;
2367
2368         if(self.enemy.classname == "player") {
2369                 msg_entity = self;
2370                 WriteByte(MSG_ONE, SVC_SETVIEW);
2371                 WriteEntity(MSG_ONE, self.enemy);
2372                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2373                 self.movetype = MOVETYPE_NONE;
2374                 accuracy_resend(self);
2375
2376                 if(!SpectateUpdate())
2377                         PutObserverInServer();
2378
2379                 return 1;
2380         } else {
2381                 return 0;
2382         }
2383 }
2384
2385 /*
2386 =============
2387 ShowRespawnCountdown()
2388
2389 Update a respawn countdown display.
2390 =============
2391 */
2392 void ShowRespawnCountdown()
2393 {
2394         float number;
2395         if(self.deadflag == DEAD_NO) // just respawned?
2396                 return;
2397         else
2398         {
2399                 number = ceil(self.death_time - time);
2400                 if(number <= 0)
2401                         return;
2402                 if(number <= self.respawn_countdown)
2403                 {
2404                         self.respawn_countdown = number - 1;
2405                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2406                                 AnnounceTo(self, strcat(ftos(number), ""));
2407                 }
2408         }
2409 }
2410
2411 void LeaveSpectatorMode()
2412 {
2413         if(isJoinAllowed()) {
2414                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2415                         self.classname = "player";
2416
2417                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2418                                 JoinBestTeam(self, FALSE, TRUE);
2419
2420                         if(autocvar_g_campaign)
2421                                 campaign_bots_may_start = 1;
2422
2423                         PutClientInServer();
2424
2425                         if(self.classname == "player")
2426                                 bprint ("^4", self.netname, "^4 is playing now\n");
2427
2428                         if(!autocvar_g_campaign)
2429                                 centerprint(self,""); // clear MOTD
2430
2431                         return;
2432                 } else {
2433                         if (g_ca && self.caplayer) {
2434                         }       // do nothing
2435                         else
2436                                 stuffcmd(self,"menu_showteamselect\n");
2437                         return;
2438                 }
2439         }
2440         else {
2441                 //player may not join because of g_maxplayers is set
2442                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2443         }
2444 }
2445
2446 /**
2447  * Determines whether the player is allowed to join. This depends on cvar
2448  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2449  * it checks whether the number of currently playing players exceeds g_maxplayers.
2450  * @return bool TRUE if the player is allowed to join, false otherwise
2451  */
2452 float isJoinAllowed() {
2453         if(self.team_forced < 0)
2454                 return FALSE; // forced spectators can never join
2455
2456         if (!autocvar_g_maxplayers)
2457                 return TRUE;
2458
2459         local entity e;
2460         local float currentlyPlaying;
2461         FOR_EACH_REALPLAYER(e) {
2462                 if(e.classname == "player")
2463                         currentlyPlaying += 1;
2464         }
2465         if(currentlyPlaying < autocvar_g_maxplayers)
2466                 return TRUE;
2467
2468         return FALSE;
2469 }
2470
2471 /**
2472  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2473  * g_maxplayers_spectator_blocktime seconds
2474  */
2475 void checkSpectatorBlock() {
2476         if(self.classname == "spectator" || self.classname == "observer") {
2477                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2478                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2479                         dropclient(self);
2480                 }
2481         }
2482 }
2483
2484 void ObserverThink()
2485 {
2486         if (self.flags & FL_JUMPRELEASED) {
2487                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2488                         self.welcomemessage_time = 0;
2489                         self.flags &~= FL_JUMPRELEASED;
2490                         self.flags |= FL_SPAWNING;
2491                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2492                         self.welcomemessage_time = 0;
2493                         self.flags &~= FL_JUMPRELEASED;
2494                         if(SpectateNext() == 1) {
2495                                 self.classname = "spectator";
2496                         }
2497                 }
2498         } else {
2499                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2500                         self.flags |= FL_JUMPRELEASED;
2501                         if(self.flags & FL_SPAWNING)
2502                         {
2503                                 self.flags &~= FL_SPAWNING;
2504                                 LeaveSpectatorMode();
2505                                 return;
2506                         }
2507                 }
2508         }
2509         PrintWelcomeMessage(self);
2510 }
2511
2512 void SpectatorThink()
2513 {
2514         if (self.flags & FL_JUMPRELEASED) {
2515                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2516                         self.welcomemessage_time = 0;
2517                         self.flags &~= FL_JUMPRELEASED;
2518                         self.flags |= FL_SPAWNING;
2519                 } else if(self.BUTTON_ATCK) {
2520                         self.welcomemessage_time = 0;
2521                         self.flags &~= FL_JUMPRELEASED;
2522                         if(SpectateNext() == 1) {
2523                                 self.classname = "spectator";
2524                         } else {
2525                                 self.classname = "observer";
2526                                 PutClientInServer();
2527                         }
2528                 } else if (self.BUTTON_ATCK2) {
2529                         self.welcomemessage_time = 0;
2530                         self.flags &~= FL_JUMPRELEASED;
2531                         self.classname = "observer";
2532                         PutClientInServer();
2533                 } else {
2534                         if(!SpectateUpdate())
2535                                 PutObserverInServer();
2536                 }
2537         } else {
2538                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2539                         self.flags |= FL_JUMPRELEASED;
2540                         if(self.flags & FL_SPAWNING)
2541                         {
2542                                 self.flags &~= FL_SPAWNING;
2543                                 LeaveSpectatorMode();
2544                                 return;
2545                         }
2546                 }
2547         }
2548
2549         PrintWelcomeMessage(self);
2550         self.flags |= FL_CLIENT | FL_NOTARGET;
2551 }
2552
2553 .float touchexplode_time;
2554
2555 /*
2556 =============
2557 PlayerPreThink
2558
2559 Called every frame for each client before the physics are run
2560 =============
2561 */
2562 void() ctf_setstatus;
2563 void() nexball_setstatus;
2564 .float items_added;
2565 void PlayerPreThink (void)
2566 {
2567         self.stat_game_starttime = game_starttime;
2568         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2569         self.stat_leadlimit = autocvar_leadlimit;
2570
2571         if(frametime)
2572         {
2573                 // physics frames: update anticheat stuff
2574                 anticheat_prethink();
2575         }
2576
2577         if(blockSpectators && frametime)
2578                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2579                 checkSpectatorBlock();
2580
2581         zoomstate_set = 0;
2582
2583         if(self.netname_previous != self.netname)
2584         {
2585                 if(autocvar_sv_eventlog)
2586                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2587                 if(self.netname_previous)
2588                         strunzone(self.netname_previous);
2589                 self.netname_previous = strzone(self.netname);
2590         }
2591
2592         // version nagging
2593         if(self.version_nagtime)
2594                 if(self.cvar_g_xonoticversion)
2595                         if(time > self.version_nagtime)
2596                         {
2597                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2598                                 {
2599                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2600                                         {
2601                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2602                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2603                                         }
2604                                         else
2605                                         {
2606                                                 float r;
2607                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2608                                                 if(r < 0)
2609                                                 {
2610                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2611                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2612                                                 }
2613                                                 else if(r > 0)
2614                                                 {
2615                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2616                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2617                                                 }
2618                                         }
2619                                 }
2620                                 self.version_nagtime = 0;
2621                         }
2622
2623         // GOD MODE info
2624         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2625         {
2626                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2627                 self.max_armorvalue = 0;
2628         }
2629
2630 #ifdef TETRIS
2631         if (TetrisPreFrame())
2632                 return;
2633 #endif
2634
2635         MUTATOR_CALLHOOK(PlayerPreThink);
2636
2637         if(self.classname == "player") {
2638 //              if(self.netname == "Wazat")
2639 //                      bprint(self.classname, "\n");
2640
2641                 CheckRules_Player();
2642
2643                 PrintWelcomeMessage(self);
2644
2645                 if (intermission_running)
2646                 {
2647                         IntermissionThink ();   // otherwise a button could be missed between
2648                         return;                                 // the think tics
2649                 }
2650
2651                 if(self.teleport_time)
2652                 if(time > self.teleport_time)
2653                 {
2654                         self.teleport_time = 0;
2655                         self.effects = self.effects - (self.effects & EF_NODRAW);
2656                 }
2657
2658                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2659                         UpdateSelectedPlayer();
2660
2661                 //don't allow the player to turn around while game is paused!
2662                 if(timeoutStatus == 2) {
2663                         self.v_angle = self.lastV_angle;
2664                         self.angles = self.lastV_angle;
2665                         self.fixangle = TRUE;
2666                 }
2667
2668                 if(frametime)
2669                 {
2670                         if(self.health <= 0 && autocvar_g_deathglow)
2671                         {
2672                                 if(self.glowmod_x > 0)
2673                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2674                                 else
2675                                         self.glowmod_x = -1;
2676                                 if(self.glowmod_y > 0)
2677                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2678                                 else
2679                                         self.glowmod_y = -1;
2680                                 if(self.glowmod_z > 0)
2681                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2682                                 else
2683                                         self.glowmod_z = -1;
2684                         }
2685                         else
2686                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2687                         player_powerups();
2688                 }
2689
2690                 if (self.deadflag != DEAD_NO)
2691                 {
2692                         float button_pressed, force_respawn;
2693                         if(self.personal && g_race_qualifying)
2694                         {
2695                                 if(time > self.death_time)
2696                                 {
2697                                         self.death_time = time + 1; // only retry once a second
2698                                         respawn();
2699                                         self.impulse = 141;
2700                                 }
2701                         }
2702                         else
2703                         {
2704                                 if(frametime)
2705                                         player_anim();
2706                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2707                                 force_respawn = (g_lms || (g_ca) || autocvar_g_forced_respawn);
2708                                 if (self.deadflag == DEAD_DYING)
2709                                 {
2710                                         if(force_respawn)
2711                                                 self.deadflag = DEAD_RESPAWNING;
2712                                         else if(!button_pressed)
2713                                                 self.deadflag = DEAD_DEAD;
2714                                 }
2715                                 else if (self.deadflag == DEAD_DEAD)
2716                                 {
2717                                         if(button_pressed)
2718                                                 self.deadflag = DEAD_RESPAWNABLE;
2719                                 }
2720                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2721                                 {
2722                                         if(!button_pressed)
2723                                                 self.deadflag = DEAD_RESPAWNING;
2724                                 }
2725                                 else if (self.deadflag == DEAD_RESPAWNING)
2726                                 {
2727                                         if(time > self.death_time)
2728                                         {
2729                                                 self.death_time = time + 1; // only retry once a second
2730                                                 respawn();
2731                                         }
2732                                 }
2733                                 ShowRespawnCountdown();
2734                         }
2735                         return;
2736                 }
2737
2738                 if(g_touchexplode)
2739                 if(time > self.touchexplode_time)
2740                 if(self.classname == "player")
2741                 if(self.deadflag == DEAD_NO)
2742                 if not(IS_INDEPENDENT_PLAYER(self))
2743                 FOR_EACH_PLAYER(other) if(self != other)
2744                 {
2745                         if(time > other.touchexplode_time)
2746                         if(other.deadflag == DEAD_NO)
2747                         if not(IS_INDEPENDENT_PLAYER(other))
2748                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2749                         {
2750                                 PlayerTouchExplode(self, other);
2751                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2752                         }
2753                 }
2754
2755                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2756                 {
2757                         vector dist;
2758
2759                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2760                         dist = self.prevorigin - self.origin;
2761                         dist_z = 0;
2762                         self.lms_traveled_distance += fabs(vlen(dist));
2763
2764                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2765                         {
2766                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2767                                 self.lms_traveled_distance = 0;
2768                         }
2769
2770                         if(time > self.lms_nextcheck)
2771                         {
2772                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2773                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2774                                 {
2775                                         centerprint(self, autocvar_g_lms_campcheck_message);
2776                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2777                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2778                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2779                                 }
2780                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2781                                 self.lms_traveled_distance = 0;
2782                         }
2783                 }
2784
2785                 self.prevorigin = self.origin;
2786
2787                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2788                 {
2789                         if (!self.crouch)
2790                         {
2791                                 self.crouch = TRUE;
2792                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2793                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2794                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2795                         }
2796                 }
2797                 else
2798                 {
2799                         if (self.crouch)
2800                         {
2801                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2802                                 if (!trace_startsolid)
2803                                 {
2804                                         self.crouch = FALSE;
2805                                         self.view_ofs = PL_VIEW_OFS;
2806                                         setsize (self, PL_MIN, PL_MAX);
2807                                 }
2808                         }
2809                 }
2810
2811                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2812                 {
2813                         if(self.bloodloss_timer < time)
2814                         {
2815                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2816                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2817                         }
2818                 }
2819
2820                 FixPlayermodel();
2821
2822                 GrapplingHookFrame();
2823
2824                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2825                 //if(frametime)
2826                 {
2827                         self.items &~= self.items_added;
2828
2829                         W_WeaponFrame();
2830
2831                         self.items_added = 0;
2832                         if(self.items & IT_JETPACK)
2833                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2834                                         self.items_added |= IT_FUEL;
2835
2836                         self.items |= self.items_added;
2837                 }
2838
2839                 player_regen();
2840
2841                 // rot nex charge to the charge limit
2842                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2843                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2844
2845                 if(frametime)
2846                         player_anim();
2847
2848                 if (g_minstagib)
2849                         minstagib_ammocheck();
2850
2851                 if(g_ctf)
2852                         ctf_setstatus();
2853
2854                 if(g_nexball)
2855                         nexball_setstatus();
2856
2857                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2858
2859                 //self.angles_y=self.v_angle_y + 90;   // temp
2860         } else if(gameover) {
2861                 if (intermission_running)
2862                         IntermissionThink ();   // otherwise a button could be missed between
2863                 return;
2864         } else if(self.classname == "observer") {
2865                 ObserverThink();
2866         } else if(self.classname == "spectator") {
2867                 SpectatorThink();
2868         }
2869
2870         if(!zoomstate_set)
2871                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && autocvar_g_balance_campingrifle_secondary == 0));
2872
2873         float oldspectatee_status;
2874         oldspectatee_status = self.spectatee_status;
2875         if(self.classname == "spectator")
2876                 self.spectatee_status = num_for_edict(self.enemy);
2877         else if(self.classname == "observer")
2878                 self.spectatee_status = num_for_edict(self);
2879         else
2880                 self.spectatee_status = 0;
2881         if(self.spectatee_status != oldspectatee_status)
2882         {
2883                 ClientData_Touch(self);
2884                 if(g_race || g_cts)
2885                         race_InitSpectator();
2886         }
2887
2888         if(self.teamkill_soundtime)
2889         if(time > self.teamkill_soundtime)
2890         {
2891                 self.teamkill_soundtime = 0;
2892
2893                 entity oldpusher, oldself;
2894
2895                 oldself = self; self = self.teamkill_soundsource;
2896                 oldpusher = self.pusher; self.pusher = oldself;
2897
2898                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2899
2900                 self.pusher = oldpusher;
2901                 self = oldself;
2902         }
2903
2904         if(self.taunt_soundtime)
2905         if(time > self.taunt_soundtime)
2906         {
2907                 self.taunt_soundtime = 0;
2908                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2909         }
2910
2911         target_voicescript_next(self);
2912 }
2913
2914 float isInvisibleString(string s)
2915 {
2916         float i, n, c;
2917         s = strdecolorize(s);
2918         for((i = 0), (n = strlen(s)); i < n; ++i)
2919         {
2920                 c = str2chr(s, i);
2921                 switch(c)
2922                 {
2923                         case 0:
2924                         case 32: // space
2925                                 break;
2926                         case 192: // charmap space
2927                                 if (!autocvar_utf8_enable)
2928                                         break;
2929                                 return FALSE;
2930                         case 160: // space in unicode fonts
2931                         case 0xE000 + 192: // utf8 charmap space
2932                                 if (autocvar_utf8_enable)
2933                                         break;
2934                         default:
2935                                 return FALSE;
2936                 }
2937         }
2938         return TRUE;
2939 }
2940
2941 /*
2942 =============
2943 PlayerPostThink
2944
2945 Called every frame for each client after the physics are run
2946 =============
2947 */
2948 .float idlekick_lasttimeleft;
2949 .entity showheadshotbbox;
2950 void showheadshotbbox_think()
2951 {
2952         if(self.owner.showheadshotbbox != self)
2953         {
2954                 remove(self);
2955                 return;
2956         }
2957         self.nextthink = time;
2958         setorigin(self, self.owner.origin);
2959         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2960 }
2961 void PlayerPostThink (void)
2962 {
2963         // Savage: Check for nameless players
2964         if (isInvisibleString(self.netname)) {
2965                 self.netname = "Player";
2966                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2967         }
2968
2969         if(sv_maxidle && frametime)
2970         {
2971                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2972                 float timeleft;
2973                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2974                 if(timeleft <= 0)
2975                 {
2976                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2977                         AnnounceTo(self, "terminated");
2978                         dropclient(self);
2979                         return;
2980                 }
2981                 else if(timeleft <= 10)
2982                 {
2983                         if(timeleft != self.idlekick_lasttimeleft)
2984                         {
2985                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2986                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2987                         }
2988                 }
2989                 else
2990                 {
2991                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2992                 }
2993                 self.idlekick_lasttimeleft = timeleft;
2994         }
2995
2996 #ifdef TETRIS
2997         if(self.impulse == 100)
2998                 ImpulseCommands();
2999         if (TetrisPostFrame())
3000                 return;
3001 #endif
3002
3003         CheatFrame();
3004
3005         if(self.classname == "player") {
3006                 CheckRules_Player();
3007                 UpdateChatBubble();
3008                 UpdateTeamBubble();
3009                 if (self.impulse)
3010                         ImpulseCommands();
3011                 if (intermission_running)
3012                         return;         // intermission or finale
3013                 GetPressedKeys();
3014         } else if (self.classname == "observer") {
3015                 //do nothing
3016         } else if (self.classname == "spectator") {
3017                 //do nothing
3018         }
3019
3020         /*
3021         float i;
3022         for(i = 0; i < 1000; ++i)
3023         {
3024                 vector end;
3025                 end = self.origin + '0 0 1024' + 512 * randomvec();
3026                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3027                 if(trace_fraction < 1)
3028                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3029                 {
3030                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3031                         break;
3032                 }
3033         }
3034         */
3035
3036         Arena_Warmup();
3037
3038         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3039
3040         if(self.waypointsprite_attachedforcarrier)
3041                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3042
3043         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3044         {
3045                 if(!self.showheadshotbbox)
3046                 {
3047                         self.showheadshotbbox = spawn();
3048                         self.showheadshotbbox.classname = "headshotbbox";
3049                         self.showheadshotbbox.owner = self;
3050                         self.showheadshotbbox.think = showheadshotbbox_think;
3051                         self.showheadshotbbox.nextthink = time;
3052                         self = self.showheadshotbbox;
3053                         self.think();
3054                         self = self.owner;
3055                 }
3056         }
3057         else
3058         {
3059                 if(self.showheadshotbbox)
3060                         remove(self.showheadshotbbox);
3061         }
3062
3063         playerdemo_write();
3064
3065         if((g_cts || g_race) && self.cvar_cl_allow_uid2name == 1)
3066         {
3067                 if(!self.stored_netname)
3068                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3069                 if(self.stored_netname != self.netname)
3070                 {
3071                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3072                         strunzone(self.stored_netname);
3073                         self.stored_netname = strzone(self.netname);
3074                 }
3075         }
3076
3077         /*
3078         if(g_race)
3079                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3080         */
3081 }