qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76 void SetSpectator(entity player, entity spectatee);
  77
  78
  79 /*
  80 =============
  81 CheckPlayerModel
  82
  83 Checks if the argument string can be a valid playermodel.
  84 Returns a valid one in doubt.
  85 =============
  86 */
  87 string FallbackPlayerModel;
  88 string CheckPlayerModel(string plyermodel) {
  89         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  90         {
  91                 // note: we cannot summon Don Strunzone here, some player may
  92                 // still have the model string set. In case anyone manages how
  93                 // to change a cvar default, we'll have a small leak here.
  94                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  95         }
  96         // only in right path
  97         if( substring(plyermodel,0,14) != "models/player/")
  98                 return FallbackPlayerModel;
  99         // only good file extensions
 100         if(substring(plyermodel,-4,4) != ".zym")
 101         if(substring(plyermodel,-4,4) != ".dpm")
 102         if(substring(plyermodel,-4,4) != ".iqm")
 103         if(substring(plyermodel,-4,4) != ".md3")
 104         if(substring(plyermodel,-4,4) != ".psk")
 105                 return FallbackPlayerModel;
 106         // forbid the LOD models
 107         if(substring(plyermodel, -9,5) == "_lod1")
 108                 return FallbackPlayerModel;
 109         if(substring(plyermodel, -9,5) == "_lod2")
 110                 return FallbackPlayerModel;
 111         if(plyermodel != strtolower(plyermodel))
 112                 return FallbackPlayerModel;
 113         // also, restrict to server models
 114         if(autocvar_sv_servermodelsonly)
 115         {
 116                 if(!fexists(plyermodel))
 117                         return FallbackPlayerModel;
 118         }
 119         return plyermodel;
 120 }
 121
 122 void setplayermodel(entity e, string modelname)
 123 {
 124         precache_model(modelname);
 125         setmodel(e, modelname);
 126         player_setupanimsformodel();
 127         UpdatePlayerSounds();
 128 }
 129
 130 /*
 131 =============
 132 PutObserverInServer
 133
 134 putting a client as observer in the server
 135 =============
 136 */
 137 void FixPlayermodel();
 138 void PutObserverInServer (void)
 139 {
 140         entity  spot;
 141     self.hud = HUD_NORMAL;
 142
 143         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         self.frags = FRAGS_SPECTATOR;
 158
 159         MUTATOR_CALLHOOK(MakePlayerObserver);
 160
 161         Portal_ClearAll(self);
 162
 163         Unfreeze(self);
 164
 165         if(self.alivetime)
 166         {
 167                 if(!warmup_stage)
 168                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 169                 self.alivetime = 0;
 170         }
 171
 172         if(self.vehicle)
 173                 vehicles_exit(VHEF_RELESE);
 174
 175         WaypointSprite_PlayerDead();
 176
 177         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 178                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 179
 180         if(self.killcount != -666)
 181         {
 182                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 183                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 184                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 185
 186                 if(self.just_joined == FALSE) {
 187                         LogTeamchange(self.playerid, -1, 4);
 188                 } else
 189                         self.just_joined = FALSE;
 190         }
 191
 192         PlayerScore_Clear(self); // clear scores when needed
 193
 194         accuracy_resend(self);
 195
 196         self.spectatortime = time;
 197
 198         self.classname = "observer";
 199         self.iscreature = FALSE;
 200         self.teleportable = TELEPORT_SIMPLE;
 201         self.damagedbycontents = FALSE;
 202         self.health = -666;
 203         self.takedamage = DAMAGE_NO;
 204         self.solid = SOLID_NOT;
 205         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 206         self.flags = FL_CLIENT | FL_NOTARGET;
 207         self.armorvalue = 666;
 208         self.effects = 0;
 209         self.armorvalue = autocvar_g_balance_armor_start;
 210         self.pauserotarmor_finished = 0;
 211         self.pauserothealth_finished = 0;
 212         self.pauseregen_finished = 0;
 213         self.damageforcescale = 0;
 214         self.death_time = 0;
 215         self.respawn_flags = 0;
 216         self.respawn_time = 0;
 217         self.stat_respawn_time = 0;
 218         self.alpha = 0;
 219         self.scale = 0;
 220         self.fade_time = 0;
 221         self.pain_frame = 0;
 222         self.pain_finished = 0;
 223         self.strength_finished = 0;
 224         self.invincible_finished = 0;
 225         self.superweapons_finished = 0;
 226         self.pushltime = 0;
 227         self.istypefrag = 0;
 228         self.think = func_null;
 229         self.nextthink = 0;
 230         self.hook_time = 0;
 231         self.deadflag = DEAD_NO;
 232         self.angles = spot.angles;
 233         self.angles_z = 0;
 234         self.fixangle = TRUE;
 235         self.crouch = FALSE;
 236         self.revival_time = 0;
 237
 238         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 239         self.prevorigin = self.origin;
 240         self.items = 0;
 241         self.weapons = '0 0 0';
 242         self.model = "";
 243         FixPlayermodel();
 244         setmodel(self, "null");
 245         self.drawonlytoclient = self;
 246
 247         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 248         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 249
 250         self.weapon = 0;
 251         self.weaponname = "";
 252         self.switchingweapon = 0;
 253         self.weaponmodel = "";
 254         self.weaponentity = world;
 255         self.exteriorweaponentity = world;
 256         self.killcount = -666;
 257         self.velocity = '0 0 0';
 258         self.avelocity = '0 0 0';
 259         self.punchangle = '0 0 0';
 260         self.punchvector = '0 0 0';
 261         self.oldvelocity = self.velocity;
 262         self.fire_endtime = -1;
 263 }
 264
 265 .float model_randomizer;
 266 void FixPlayermodel()
 267 {
 268         string defaultmodel;
 269         float defaultskin, chmdl, oldskin, n, i;
 270         vector m1, m2;
 271
 272         defaultmodel = "";
 273         defaultskin = 0;
 274         chmdl = FALSE;
 275
 276         if(autocvar_sv_defaultcharacter == 1)
 277         {
 278                 if(teamplay)
 279                 {
 280                         string s;
 281                         s = Static_Team_ColorName_Lower(self.team);
 282                         if(s != "neutral")
 283                         {
 284                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 285                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 286                         }
 287                 }
 288
 289                 if(defaultmodel == "")
 290                 {
 291                         defaultmodel = autocvar_sv_defaultplayermodel;
 292                         defaultskin = autocvar_sv_defaultplayerskin;
 293                 }
 294
 295                 n = tokenize_console(defaultmodel);
 296                 if(n > 0)
 297                 {
 298                         defaultmodel = argv(floor(n * self.model_randomizer));
 299                         // However, do NOT randomize if the player-selected model is in the list.
 300                         for (i = 0; i < n; ++i)
 301                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 302                                         defaultmodel = argv(i);
 303                 }
 304
 305                 i = strstrofs(defaultmodel, ":", 0);
 306                 if(i >= 0)
 307                 {
 308                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 309                         defaultmodel = substring(defaultmodel, 0, i);
 310                 }
 311         }
 312
 313         if(defaultmodel != "")
 314         {
 315                 if (defaultmodel != self.model)
 316                 {
 317                         m1 = self.mins;
 318                         m2 = self.maxs;
 319                         setplayermodel (self, defaultmodel);
 320                         setsize (self, m1, m2);
 321                         chmdl = TRUE;
 322                 }
 323
 324                 oldskin = self.skin;
 325                 self.skin = defaultskin;
 326         } else {
 327                 if (self.playermodel != self.model || self.playermodel == "")
 328                 {
 329                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 330                         m1 = self.mins;
 331                         m2 = self.maxs;
 332                         setplayermodel (self, self.playermodel);
 333                         setsize (self, m1, m2);
 334                         chmdl = TRUE;
 335                 }
 336
 337                 oldskin = self.skin;
 338                 self.skin = stof(self.playerskin);
 339         }
 340
 341         if(chmdl || oldskin != self.skin) // model or skin has changed
 342         {
 343                 self.species = player_getspecies(); // update species
 344                 UpdatePlayerSounds(); // update skin sounds
 345         }
 346
 347         if(!teamplay)
 348                 if(strlen(autocvar_sv_defaultplayercolors))
 349                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 350                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 351 }
 352
 353 /*
 354 =============
 355 PutClientInServer
 356
 357 Called when a client spawns in the server
 358 =============
 359 */
 360 void PutClientInServer (void)
 361 {
 362         if(IS_BOT_CLIENT(self))
 363                 self.classname = "player";
 364         else if(IS_REAL_CLIENT(self))
 365         {
 366                 msg_entity = self;
 367                 WriteByte(MSG_ONE, SVC_SETVIEW);
 368                 WriteEntity(MSG_ONE, self);
 369         }
 370
 371         SetSpectator(self, world);
 372
 373         // reset player keys
 374         self.itemkeys = 0;
 375
 376         MUTATOR_CALLHOOK(PutClientInServer);
 377
 378         if(gameover)
 379                 self.classname = "observer";
 380
 381         if(IS_PLAYER(self))
 382         {
 383                 entity spot, oldself;
 384                 float j;
 385
 386                 accuracy_resend(self);
 387
 388                 if(self.team < 0)
 389                         JoinBestTeam(self, FALSE, TRUE);
 390
 391                 spot = SelectSpawnPoint (FALSE);
 392                 if(!spot)
 393                 {
 394                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 395                         return; // spawn failed
 396                 }
 397
 398                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 399
 400                 if(self.vehicle)
 401                         vehicles_exit(VHEF_RELESE);
 402
 403                 self.classname = "player";
 404                 self.wasplayer = TRUE;
 405                 self.iscreature = TRUE;
 406                 self.teleportable = TELEPORT_NORMAL;
 407                 self.damagedbycontents = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 411                 if(autocvar_g_playerclip_collisions)
 412                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 413                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 414                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 415                 self.frags = FRAGS_PLAYER;
 416                 if(INDEPENDENT_PLAYERS)
 417                         MAKE_INDEPENDENT_PLAYER(self);
 418                 self.flags = FL_CLIENT;
 419                 if(autocvar__notarget)
 420                         self.flags |= FL_NOTARGET;
 421                 self.takedamage = DAMAGE_AIM;
 422                 self.effects = 0;
 423                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 424                 self.air_finished = time + 12;
 425                 self.dmg = 2;
 426                 if(WEP_CVAR(vortex, charge))
 427                 {
 428                         if(WEP_CVAR_SEC(vortex, chargepool))
 429                                 self.vortex_chargepool_ammo = 1;
 430                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 431                 }
 432
 433                 if(warmup_stage)
 434                 {
 435                         self.ammo_shells = warmup_start_ammo_shells;
 436                         self.ammo_nails = warmup_start_ammo_nails;
 437                         self.ammo_rockets = warmup_start_ammo_rockets;
 438                         self.ammo_cells = warmup_start_ammo_cells;
 439                         self.ammo_plasma = warmup_start_ammo_plasma;
 440                         self.ammo_fuel = warmup_start_ammo_fuel;
 441                         self.health = warmup_start_health;
 442                         self.armorvalue = warmup_start_armorvalue;
 443                         self.weapons = WARMUP_START_WEAPONS;
 444                 }
 445                 else
 446                 {
 447                         self.ammo_shells = start_ammo_shells;
 448                         self.ammo_nails = start_ammo_nails;
 449                         self.ammo_rockets = start_ammo_rockets;
 450                         self.ammo_cells = start_ammo_cells;
 451                         self.ammo_plasma = start_ammo_plasma;
 452                         self.ammo_fuel = start_ammo_fuel;
 453                         self.health = start_health;
 454                         self.armorvalue = start_armorvalue;
 455                         self.weapons = start_weapons;
 456                 }
 457
 458                 if(self.weapons & WEPSET_SUPERWEAPONS)
 459                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 460                 else
 461                         self.superweapons_finished = 0;
 462
 463                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 464                 {
 465                         if(g_weaponarena_random_with_blaster)
 466                                 self.weapons &= ~WEPSET_BLASTER;
 467                         W_RandomWeapons(self, g_weaponarena_random);
 468                         if(g_weaponarena_random_with_blaster)
 469                                 self.weapons |= WEPSET_BLASTER;
 470                 }
 471
 472                 self.items = start_items;
 473
 474                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 475                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 476                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 477                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 478                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 479                 //extend the pause of rotting if client was reset at the beginning of the countdown
 480                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 481                         self.spawnshieldtime += game_starttime - time;
 482                         self.pauserotarmor_finished += game_starttime - time;
 483                         self.pauserothealth_finished += game_starttime - time;
 484                         self.pauseregen_finished += game_starttime - time;
 485                 }
 486                 self.damageforcescale = 2;
 487                 self.death_time = 0;
 488                 self.respawn_flags = 0;
 489                 self.respawn_time = 0;
 490                 self.stat_respawn_time = 0;
 491                 self.scale = 0;
 492                 self.fade_time = 0;
 493                 self.pain_frame = 0;
 494                 self.pain_finished = 0;
 495                 self.strength_finished = 0;
 496                 self.invincible_finished = 0;
 497                 self.pushltime = 0;
 498                 // players have no think function
 499                 self.think = func_null;
 500                 self.nextthink = 0;
 501                 self.hook_time = 0;
 502                 self.dmg_team = 0;
 503                 self.ballistics_density = autocvar_g_ballistics_density_player;
 504
 505                 self.metertime = 0;
 506
 507                 self.deadflag = DEAD_NO;
 508
 509                 self.angles = spot.angles;
 510
 511                 self.angles_z = 0; // never spawn tilted even if the spot says to
 512                 self.fixangle = TRUE; // turn this way immediately
 513                 self.velocity = '0 0 0';
 514                 self.avelocity = '0 0 0';
 515                 self.punchangle = '0 0 0';
 516                 self.punchvector = '0 0 0';
 517                 self.oldvelocity = self.velocity;
 518                 self.fire_endtime = -1;
 519                 self.revival_time = 0;
 520
 521                 entity spawnevent = spawn();
 522                 spawnevent.owner = self;
 523                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 524
 525                 // Cut off any still running player sounds.
 526                 stopsound(self, CH_PLAYER_SINGLE);
 527
 528                 self.model = "";
 529                 FixPlayermodel();
 530                 self.drawonlytoclient = world;
 531
 532                 self.crouch = FALSE;
 533                 self.view_ofs = PL_VIEW_OFS;
 534                 setsize (self, PL_MIN, PL_MAX);
 535                 self.spawnorigin = spot.origin;
 536                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 537                 // don't reset back to last position, even if new position is stuck in solid
 538                 self.oldorigin = self.origin;
 539                 self.prevorigin = self.origin;
 540                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 541                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 542         self.hud = HUD_NORMAL;
 543
 544                 self.event_damage = PlayerDamage;
 545
 546                 self.bot_attack = TRUE;
 547                 self.monster_attack = TRUE;
 548
 549                 self.spider_slowness = 0;
 550
 551                 self.statdraintime = time + 5;
 552                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 553
 554                 if(self.killcount == -666) {
 555                         PlayerScore_Clear(self);
 556                         self.killcount = 0;
 557                 }
 558
 559                 CL_SpawnWeaponentity();
 560                 self.alpha = default_player_alpha;
 561                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 562                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 563
 564                 self.speedrunning = FALSE;
 565
 566                 //stuffcmd(self, "chase_active 0");
 567                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 568
 569                 target_voicescript_clear(self);
 570
 571                 // reset fields the weapons may use
 572                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 573                 {
 574                         WEP_ACTION(j, WR_RESETPLAYER);
 575
 576                         // all weapons must be fully loaded when we spawn
 577                         entity e;
 578                         e = get_weaponinfo(j);
 579                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 580                                 self.(weapon_load[j]) = e.reloading_ammo;
 581                 }
 582
 583                 oldself = self;
 584                 self = spot;
 585                         activator = oldself;
 586                                 string s;
 587                                 s = self.target;
 588                                 self.target = string_null;
 589                                 SUB_UseTargets();
 590                                 self.target = s;
 591                         activator = world;
 592                 self = oldself;
 593
 594                 Unfreeze(self);
 595
 596                 spawn_spot = spot;
 597                 MUTATOR_CALLHOOK(PlayerSpawn);
 598
 599                 if(autocvar_spawn_debug)
 600                 {
 601                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 602                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 603                 }
 604
 605                 self.switchweapon = w_getbestweapon(self);
 606                 self.cnt = -1; // W_LastWeapon will not complain
 607                 self.weapon = 0;
 608                 self.weaponname = "";
 609                 self.switchingweapon = 0;
 610
 611                 if(!warmup_stage)
 612                         if(!self.alivetime)
 613                                 self.alivetime = time;
 614
 615                 antilag_clear(self);
 616         }
 617         else if(IS_OBSERVER(self))
 618         {
 619                 PutObserverInServer ();
 620         }
 621 }
 622
 623 .float ebouncefactor, ebouncestop; // electro's values
 624 // TODO do we need all these fields, or should we stop autodetecting runtime
 625 // changes and just have a console command to update this?
 626 float ClientInit_SendEntity(entity to, float sf)
 627 {
 628         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 629         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 638
 639         if(sv_foginterval && world.fog != "")
 640                 WriteString(MSG_ENTITY, world.fog);
 641         else
 642                 WriteString(MSG_ENTITY, "");
 643         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 644         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 645         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 646         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 647         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 648         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 649         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 650         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 651         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 652         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 653         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 654         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 655         return TRUE;
 656 }
 657
 658 void ClientInit_CheckUpdate()
 659 {
 660         self.nextthink = time;
 661         if(self.count != autocvar_g_balance_armor_blockpercent)
 662         {
 663                 self.count = autocvar_g_balance_armor_blockpercent;
 664                 self.SendFlags |= 1;
 665         }
 666         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 667         {
 668                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 669                 self.SendFlags |= 1;
 670         }
 671         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 672         {
 673                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 674                 self.SendFlags |= 1;
 675         }
 676         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 677         {
 678                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 679                 self.SendFlags |= 1;
 680         }
 681         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 682         {
 683                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 684                 self.SendFlags |= 1;
 685         }
 686 }
 687
 688 void ClientInit_Spawn()
 689 {
 690         entity o;
 691         entity e;
 692         e = spawn();
 693         e.classname = "clientinit";
 694         e.think = ClientInit_CheckUpdate;
 695         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 696
 697         o = self;
 698         self = e;
 699         ClientInit_CheckUpdate();
 700         self = o;
 701 }
 702
 703 /*
 704 =============
 705 SetNewParms
 706 =============
 707 */
 708 void SetNewParms (void)
 709 {
 710         // initialize parms for a new player
 711         parm1 = -(86400 * 366);
 712 }
 713
 714 /*
 715 =============
 716 SetChangeParms
 717 =============
 718 */
 719 void SetChangeParms (void)
 720 {
 721         // save parms for level change
 722         parm1 = self.parm_idlesince - time;
 723 }
 724
 725 /*
 726 =============
 727 DecodeLevelParms
 728 =============
 729 */
 730 void DecodeLevelParms (void)
 731 {
 732         // load parms
 733         self.parm_idlesince = parm1;
 734         if(self.parm_idlesince == -(86400 * 366))
 735                 self.parm_idlesince = time;
 736
 737         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 738         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 739 }
 740
 741 /*
 742 =============
 743 ClientKill
 744
 745 Called when a client types 'kill' in the console
 746 =============
 747 */
 748
 749 .float clientkill_nexttime;
 750 void ClientKill_Now_TeamChange()
 751 {
 752         if(self.killindicator_teamchange == -1)
 753         {
 754                 JoinBestTeam( self, FALSE, TRUE );
 755         }
 756         else if(self.killindicator_teamchange == -2)
 757         {
 758                 if(blockSpectators)
 759                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 760                 PutObserverInServer();
 761         }
 762         else
 763                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 764         self.killindicator_teamchange = 0;
 765 }
 766
 767 void ClientKill_Now()
 768 {
 769         if(self.vehicle)
 770         {
 771             vehicles_exit(VHEF_RELESE);
 772             if(!self.killindicator_teamchange)
 773             {
 774             self.vehicle_health = -1;
 775             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 776             }
 777         }
 778
 779         if(self.killindicator && !wasfreed(self.killindicator))
 780                 remove(self.killindicator);
 781
 782         self.killindicator = world;
 783
 784         if(self.killindicator_teamchange)
 785                 ClientKill_Now_TeamChange();
 786
 787         // in any case:
 788         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 789
 790         // now I am sure the player IS dead
 791 }
 792 void KillIndicator_Think()
 793 {
 794         if (gameover)
 795         {
 796                 self.owner.killindicator = world;
 797                 remove(self);
 798                 return;
 799         }
 800
 801         if (self.owner.alpha < 0 && !self.owner.vehicle)
 802         {
 803                 self.owner.killindicator = world;
 804                 remove(self);
 805                 return;
 806         }
 807
 808         if(self.cnt <= 0)
 809         {
 810                 self = self.owner;
 811                 ClientKill_Now(); // no oldself needed
 812                 return;
 813         }
 814     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 815     {
 816         self.nextthink = time + 1;
 817         self.cnt -= 1;
 818     }
 819         else
 820         {
 821                 if(self.cnt <= 10)
 822                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 823                 if(IS_REAL_CLIENT(self.owner))
 824                 {
 825                         if(self.cnt <= 10)
 826                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 827                 }
 828                 self.nextthink = time + 1;
 829                 self.cnt -= 1;
 830         }
 831 }
 832
 833 float clientkilltime;
 834 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 835 {
 836         float killtime;
 837         float starttime;
 838         entity e;
 839
 840         if (gameover)
 841                 return;
 842
 843         killtime = autocvar_g_balance_kill_delay;
 844
 845         if(g_race_qualifying || g_cts)
 846                 killtime = 0;
 847
 848     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 849     {
 850                 remove(self.killindicator);
 851                 self.killindicator = world;
 852
 853         ClientKill_Now(); // allow instant kill in this case
 854         return;
 855     }
 856
 857         self.killindicator_teamchange = targetteam;
 858
 859     if(!self.killindicator)
 860         {
 861                 if(self.deadflag == DEAD_NO)
 862                 {
 863                         killtime = max(killtime, self.clientkill_nexttime - time);
 864                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 865                 }
 866
 867                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 868                 {
 869                         ClientKill_Now();
 870                 }
 871                 else
 872                 {
 873                         starttime = max(time, clientkilltime);
 874
 875                         self.killindicator = spawn();
 876                         self.killindicator.owner = self;
 877                         self.killindicator.scale = 0.5;
 878                         setattachment(self.killindicator, self, "");
 879                         setorigin(self.killindicator, '0 0 52');
 880                         self.killindicator.think = KillIndicator_Think;
 881                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 882                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 883                         self.killindicator.cnt = ceil(killtime);
 884                         self.killindicator.count = bound(0, ceil(killtime), 10);
 885                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 886
 887                         for(e = world; (e = find(e, classname, "body")) != world; )
 888                         {
 889                                 if(e.enemy != self)
 890                                         continue;
 891                                 e.killindicator = spawn();
 892                                 e.killindicator.owner = e;
 893                                 e.killindicator.scale = 0.5;
 894                                 setattachment(e.killindicator, e, "");
 895                                 setorigin(e.killindicator, '0 0 52');
 896                                 e.killindicator.think = KillIndicator_Think;
 897                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 898                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 899                                 e.killindicator.cnt = ceil(killtime);
 900                         }
 901                         self.lip = 0;
 902                 }
 903         }
 904         if(self.killindicator)
 905         {
 906                 if(targetteam == 0) // just die
 907                 {
 908                         self.killindicator.colormod = '0 0 0';
 909                         if(IS_REAL_CLIENT(self))
 910                         if(self.killindicator.cnt > 0)
 911                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 912                 }
 913                 else if(targetteam == -1) // auto
 914                 {
 915                         self.killindicator.colormod = '0 1 0';
 916                         if(IS_REAL_CLIENT(self))
 917                         if(self.killindicator.cnt > 0)
 918                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 919                 }
 920                 else if(targetteam == -2) // spectate
 921                 {
 922                         self.killindicator.colormod = '0.5 0.5 0.5';
 923                         if(IS_REAL_CLIENT(self))
 924                         if(self.killindicator.cnt > 0)
 925                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 926                 }
 927                 else
 928                 {
 929                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 930                         if(IS_REAL_CLIENT(self))
 931                         if(self.killindicator.cnt > 0)
 932                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 933                 }
 934         }
 935
 936 }
 937
 938 void ClientKill (void)
 939 {
 940         if(gameover) return;
 941         if(self.player_blocked) return;
 942         if(self.frozen) return;
 943
 944         ClientKill_TeamChange(0);
 945 }
 946
 947 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 948 {
 949     e.killindicator = spawn();
 950     e.killindicator.owner = e;
 951     e.killindicator.think = KillIndicator_Think;
 952     e.killindicator.nextthink = time + (e.lip) * 0.05;
 953     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 954     e.killindicator.health = 1; // this is used to indicate that it should be silent
 955     e.lip = 0;
 956 }
 957
 958 void FixClientCvars(entity e)
 959 {
 960         // send prediction settings to the client
 961         stuffcmd(e, "\nin_bindmap 0 0\n");
 962         if(g_race || g_cts)
 963                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 964         if(autocvar_g_antilag == 3) // client side hitscan
 965                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 966         if(autocvar_sv_gentle)
 967                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 968         /*
 969          * we no longer need to stuff this. Remove this comment block if you feel
 970          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 971         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 972         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 973         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 974         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 975         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 976         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 977         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 978         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 979         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 980         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 981         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 982         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 983         stuffcmd(e, "cl_movement_edgefriction 1\n");
 984          */
 985 }
 986
 987 float PlayerInIDList(entity p, string idlist)
 988 {
 989         float n, i;
 990         string s;
 991
 992         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 993         if (!p.crypto_idfp)
 994                 return 0;
 995
 996         // this function allows abbreviated player IDs too!
 997         n = tokenize_console(idlist);
 998         for(i = 0; i < n; ++i)
 999         {
1000                 s = argv(i);
1001                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1002                         return 1;
1003         }
1004
1005         return 0;
1006 }
1007
1008 /*
1009 =============
1010 ClientConnect
1011
1012 Called when a client connects to the server
1013 =============
1014 */
1015 void DecodeLevelParms (void);
1016 //void dom_player_join_team(entity pl);
1017 void set_dom_state(entity e);
1018 void ClientConnect (void)
1019 {
1020         float t;
1021
1022         if(IS_CLIENT(self))
1023         {
1024                 print("Warning: ClientConnect, but already connected!\n");
1025                 return;
1026         }
1027
1028         if(Ban_MaybeEnforceBanOnce(self))
1029                 return;
1030
1031         DecodeLevelParms();
1032
1033 #ifdef WATERMARK
1034         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1035 #endif
1036
1037         self.classname = "player_joining";
1038
1039         self.flags = FL_CLIENT;
1040         self.version_nagtime = time + 10 + random() * 10;
1041
1042         if(player_count<0)
1043         {
1044                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1045                 player_count = 0;
1046         }
1047
1048         PlayerScore_Attach(self);
1049         ClientData_Attach();
1050         accuracy_init(self);
1051
1052         bot_clientconnect();
1053
1054         playerdemo_init();
1055
1056         anticheat_init();
1057
1058         // identify the right forced team
1059         if(autocvar_g_campaign)
1060         {
1061                 if(IS_REAL_CLIENT(self)) // only players, not bots
1062                 {
1063                         switch(autocvar_g_campaign_forceteam)
1064                         {
1065                                 case 1: self.team_forced = NUM_TEAM_1; break;
1066                                 case 2: self.team_forced = NUM_TEAM_2; break;
1067                                 case 3: self.team_forced = NUM_TEAM_3; break;
1068                                 case 4: self.team_forced = NUM_TEAM_4; break;
1069                                 default: self.team_forced = 0;
1070                         }
1071                 }
1072         }
1073         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1074                 self.team_forced = NUM_TEAM_1;
1075         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1076                 self.team_forced = NUM_TEAM_2;
1077         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1078                 self.team_forced = NUM_TEAM_3;
1079         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1080                 self.team_forced = NUM_TEAM_4;
1081         else if(autocvar_g_forced_team_otherwise == "red")
1082                 self.team_forced = NUM_TEAM_1;
1083         else if(autocvar_g_forced_team_otherwise == "blue")
1084                 self.team_forced = NUM_TEAM_2;
1085         else if(autocvar_g_forced_team_otherwise == "yellow")
1086                 self.team_forced = NUM_TEAM_3;
1087         else if(autocvar_g_forced_team_otherwise == "pink")
1088                 self.team_forced = NUM_TEAM_4;
1089         else if(autocvar_g_forced_team_otherwise == "spectate")
1090                 self.team_forced = -1;
1091         else if(autocvar_g_forced_team_otherwise == "spectator")
1092                 self.team_forced = -1;
1093         else
1094                 self.team_forced = 0;
1095
1096         if(!teamplay)
1097                 if(self.team_forced > 0)
1098                         self.team_forced = 0;
1099
1100         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1101
1102         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1103                 self.classname = "observer";
1104         } else {
1105                 if(teamplay)
1106                 {
1107                         if(autocvar_g_balance_teams)
1108                         {
1109                                 self.classname = "player";
1110                                 campaign_bots_may_start = 1;
1111                         }
1112                         else
1113                         {
1114                                 self.classname = "observer"; // do it anyway
1115                         }
1116                 }
1117                 else
1118                 {
1119                         self.classname = "player";
1120                         campaign_bots_may_start = 1;
1121                 }
1122         }
1123
1124         self.playerid = (playerid_last = playerid_last + 1);
1125
1126         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1127
1128     if(IS_BOT_CLIENT(self))
1129         PlayerStats_AddPlayer(self);
1130
1131         if(autocvar_sv_eventlog)
1132                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1133
1134         LogTeamchange(self.playerid, self.team, 1);
1135
1136         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1137
1138         self.netname_previous = strzone(self.netname);
1139
1140         if(IS_PLAYER(self) && teamplay)
1141                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1142         else
1143                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1144
1145         stuffcmd(self, strcat(clientstuff, "\n"));
1146         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1147
1148         FixClientCvars(self);
1149
1150         // spawnfunc_waypoint sprites
1151         WaypointSprite_InitClient(self);
1152
1153         // Wazat's grappling hook
1154         SetGrappleHookBindings();
1155
1156         // get version info from player
1157         stuffcmd(self, "cmd clientversion $gameversion\n");
1158
1159         // get other cvars from player
1160         GetCvars(0);
1161
1162         // notify about available teams
1163         if(teamplay)
1164         {
1165                 CheckAllowedTeams(self);
1166                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1167                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1168         }
1169         else
1170                 stuffcmd(self, "set _teams_available 0\n");
1171
1172         attach_entcs();
1173
1174         bot_relinkplayerlist();
1175
1176         self.spectatortime = time;
1177         if(blockSpectators)
1178         {
1179                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1180         }
1181
1182         self.jointime = time;
1183         self.allowed_timeouts = autocvar_sv_timeout_number;
1184
1185         if(IS_REAL_CLIENT(self))
1186         {
1187                 if(!autocvar_g_campaign)
1188                 {
1189                         self.motd_actived_time = -1;
1190                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1191                 }
1192
1193                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1194                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1195         }
1196
1197         if(!sv_foginterval && world.fog != "")
1198                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1199
1200         W_HitPlotOpen(self);
1201
1202         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1203                 send_CSQC_teamnagger();
1204
1205         CheatInitClient();
1206
1207         CSQCMODEL_AUTOINIT();
1208
1209         self.model_randomizer = random();
1210
1211         if(IS_REAL_CLIENT(self))
1212                 sv_notice_join();
1213
1214         MUTATOR_CALLHOOK(ClientConnect);
1215 }
1216 /*
1217 =============
1218 ClientDisconnect
1219
1220 Called when a client disconnects from the server
1221 =============
1222 */
1223 .entity chatbubbleentity;
1224 void ReadyCount();
1225 void ClientDisconnect (void)
1226 {
1227         if(self.vehicle)
1228             vehicles_exit(VHEF_RELESE);
1229
1230         if (!IS_CLIENT(self))
1231         {
1232                 print("Warning: ClientDisconnect without ClientConnect\n");
1233                 return;
1234         }
1235
1236         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1237
1238         PlayerStats_AddGlobalInfo(self);
1239
1240         CheatShutdownClient();
1241
1242         W_HitPlotClose(self);
1243
1244         anticheat_report();
1245         anticheat_shutdown();
1246
1247         playerdemo_shutdown();
1248
1249         bot_clientdisconnect();
1250
1251         if(self.entcs)
1252                 detach_entcs();
1253
1254         if(autocvar_sv_eventlog)
1255                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1256
1257         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1258
1259         MUTATOR_CALLHOOK(ClientDisconnect);
1260
1261         Portal_ClearAll(self);
1262
1263         Unfreeze(self);
1264
1265         RemoveGrapplingHook(self);
1266
1267         // Here, everything has been done that requires this player to be a client.
1268
1269         self.flags &= ~FL_CLIENT;
1270
1271         if (self.chatbubbleentity)
1272                 remove (self.chatbubbleentity);
1273
1274         if (self.killindicator)
1275                 remove (self.killindicator);
1276
1277         WaypointSprite_PlayerGone();
1278
1279         bot_relinkplayerlist();
1280
1281         accuracy_free(self);
1282         ClientData_Detach();
1283         PlayerScore_Detach(self);
1284
1285         if(self.netname_previous)
1286                 strunzone(self.netname_previous);
1287         if(self.clientstatus)
1288                 strunzone(self.clientstatus);
1289         if(self.weaponorder_byimpulse)
1290                 strunzone(self.weaponorder_byimpulse);
1291
1292         ClearPlayerSounds();
1293
1294         if(self.personal)
1295                 remove(self.personal);
1296
1297         self.playerid = 0;
1298         ReadyCount();
1299
1300         // free cvars
1301         GetCvars(-1);
1302 }
1303
1304 .float BUTTON_CHAT;
1305 void ChatBubbleThink()
1306 {
1307         self.nextthink = time;
1308         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1309         {
1310                 if(self.owner) // but why can that ever be world?
1311                         self.owner.chatbubbleentity = world;
1312                 remove(self);
1313                 return;
1314         }
1315         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1316 #ifdef TETRIS
1317                 || self.owner.tetris_on
1318 #endif
1319         )
1320                 self.model = self.mdl;
1321         else
1322                 self.model = "";
1323 }
1324
1325 void UpdateChatBubble()
1326 {
1327         if (self.alpha < 0)
1328                 return;
1329         // spawn a chatbubble entity if needed
1330         if (!self.chatbubbleentity)
1331         {
1332                 self.chatbubbleentity = spawn();
1333                 self.chatbubbleentity.owner = self;
1334                 self.chatbubbleentity.exteriormodeltoclient = self;
1335                 self.chatbubbleentity.think = ChatBubbleThink;
1336                 self.chatbubbleentity.nextthink = time;
1337                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1338                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1339                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1340                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1341                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1342                 self.chatbubbleentity.model = "";
1343                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1344         }
1345 }
1346
1347
1348 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1349 // added to the model skins
1350 /*void UpdateColorModHack()
1351 {
1352         float c;
1353         c = self.clientcolors & 15;
1354         // LordHavoc: only bothering to support white, green, red, yellow, blue
1355              if (!teamplay) self.colormod = '0 0 0';
1356         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1357         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1358         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1359         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1360         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1361         else self.colormod = '1 1 1';
1362 }*/
1363
1364 void respawn(void)
1365 {
1366         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1367         {
1368                 self.solid = SOLID_NOT;
1369                 self.takedamage = DAMAGE_NO;
1370                 self.movetype = MOVETYPE_FLY;
1371                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1372                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1373                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1374                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1375                 if(autocvar_g_respawn_ghosts_maxtime)
1376                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1377         }
1378
1379         CopyBody(1);
1380
1381         self.effects |= EF_NODRAW; // prevent another CopyBody
1382         PutClientInServer();
1383 }
1384
1385 void play_countdown(float finished, string samp)
1386 {
1387         if(IS_REAL_CLIENT(self))
1388                 if(floor(finished - time - frametime) != floor(finished - time))
1389                         if(finished - time < 6)
1390                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1391 }
1392
1393 void player_powerups (void)
1394 {
1395         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1396         olditems = self.items;
1397
1398         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1399                 self.modelflags |= MF_ROCKET;
1400         else
1401                 self.modelflags &= ~MF_ROCKET;
1402
1403         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1404
1405         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1406                 return;
1407
1408         Fire_ApplyDamage(self);
1409         Fire_ApplyEffect(self);
1410
1411         if (!g_instagib)
1412         {
1413                 if (self.items & IT_STRENGTH)
1414                 {
1415                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1416                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1417                         if (time > self.strength_finished)
1418                         {
1419                                 self.items = self.items - (self.items & IT_STRENGTH);
1420                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1421                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1422                         }
1423                 }
1424                 else
1425                 {
1426                         if (time < self.strength_finished)
1427                         {
1428                                 self.items = self.items | IT_STRENGTH;
1429                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1430                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1431                         }
1432                 }
1433                 if (self.items & IT_INVINCIBLE)
1434                 {
1435                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1436                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1437                         if (time > self.invincible_finished)
1438                         {
1439                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1440                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1441                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1442                         }
1443                 }
1444                 else
1445                 {
1446                         if (time < self.invincible_finished)
1447                         {
1448                                 self.items = self.items | IT_INVINCIBLE;
1449                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1450                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1451                         }
1452                 }
1453                 if (self.items & IT_SUPERWEAPON)
1454                 {
1455                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1456                         {
1457                                 self.superweapons_finished = 0;
1458                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1459                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1460                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1461                         }
1462                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1463                         {
1464                                 // don't let them run out
1465                         }
1466                         else
1467                         {
1468                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1469                                 if (time > self.superweapons_finished)
1470                                 {
1471                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1472                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1473                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1474                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1475                                 }
1476                         }
1477                 }
1478                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1479                 {
1480                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1481                         {
1482                                 self.items = self.items | IT_SUPERWEAPON;
1483                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1484                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1485                         }
1486                         else
1487                         {
1488                                 self.superweapons_finished = 0;
1489                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1490                         }
1491                 }
1492                 else
1493                 {
1494                         self.superweapons_finished = 0;
1495                 }
1496         }
1497
1498         if(autocvar_g_nodepthtestplayers)
1499                 self.effects = self.effects | EF_NODEPTHTEST;
1500
1501         if(autocvar_g_fullbrightplayers)
1502                 self.effects = self.effects | EF_FULLBRIGHT;
1503
1504         if (time >= game_starttime)
1505         if (time < self.spawnshieldtime)
1506                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1507
1508         MUTATOR_CALLHOOK(PlayerPowerups);
1509 }
1510
1511 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1512 {
1513         if(current > stable)
1514                 return current;
1515         else if(current > stable - 0.25) // when close enough, "snap"
1516                 return stable;
1517         else
1518                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1519 }
1520
1521 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1522 {
1523         if(current < stable)
1524                 return current;
1525         else if(current < stable + 0.25) // when close enough, "snap"
1526                 return stable;
1527         else
1528                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1529 }
1530
1531 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1532 {
1533         if(current > rotstable)
1534         {
1535                 if(rotframetime > 0)
1536                 {
1537                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1538                         current = max(rotstable, current - rotlinear * rotframetime);
1539                 }
1540         }
1541         else if(current < regenstable)
1542         {
1543                 if(regenframetime > 0)
1544                 {
1545                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1546                         current = min(regenstable, current + regenlinear * regenframetime);
1547                 }
1548         }
1549
1550         if(current > limit)
1551                 current = limit;
1552
1553         return current;
1554 }
1555
1556 void player_regen (void)
1557 {
1558         float max_mod, regen_mod, rot_mod, limit_mod;
1559         max_mod = regen_mod = rot_mod = limit_mod = 1;
1560         regen_mod_max = max_mod;
1561         regen_mod_regen = regen_mod;
1562         regen_mod_rot = rot_mod;
1563         regen_mod_limit = limit_mod;
1564         if(!MUTATOR_CALLHOOK(PlayerRegen))
1565         if(!self.frozen)
1566         {
1567                 float minh, mina, maxh, maxa, limith, limita;
1568                 maxh = autocvar_g_balance_health_rotstable;
1569                 maxa = autocvar_g_balance_armor_rotstable;
1570                 minh = autocvar_g_balance_health_regenstable;
1571                 mina = autocvar_g_balance_armor_regenstable;
1572                 limith = autocvar_g_balance_health_limit;
1573                 limita = autocvar_g_balance_armor_limit;
1574
1575                 max_mod = regen_mod_max;
1576                 regen_mod = regen_mod_regen;
1577                 rot_mod = regen_mod_rot;
1578                 limit_mod = regen_mod_limit;
1579
1580                 maxh = maxh * max_mod;
1581                 minh = minh * max_mod;
1582                 limith = limith * limit_mod;
1583                 limita = limita * limit_mod;
1584
1585                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1586                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1587         }
1588
1589         // if player rotted to death...  die!
1590         // check this outside above checks, as player may still be able to rot to death
1591         if(self.health < 1)
1592                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1593
1594         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1595         {
1596                 float minf, maxf, limitf;
1597
1598                 maxf = autocvar_g_balance_fuel_rotstable;
1599                 minf = autocvar_g_balance_fuel_regenstable;
1600                 limitf = autocvar_g_balance_fuel_limit;
1601
1602                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1603         }
1604 }
1605
1606 float zoomstate_set;
1607 void SetZoomState(float z)
1608 {
1609         if(z != self.zoomstate)
1610         {
1611                 self.zoomstate = z;
1612                 ClientData_Touch(self);
1613         }
1614         zoomstate_set = 1;
1615 }
1616
1617 void GetPressedKeys(void) {
1618         MUTATOR_CALLHOOK(GetPressedKeys);
1619         if (self.movement_x > 0) // get if movement keys are pressed
1620         {       // forward key pressed
1621                 self.pressedkeys |= KEY_FORWARD;
1622                 self.pressedkeys &= ~KEY_BACKWARD;
1623         }
1624         else if (self.movement_x < 0)
1625         {       // backward key pressed
1626                 self.pressedkeys |= KEY_BACKWARD;
1627                 self.pressedkeys &= ~KEY_FORWARD;
1628         }
1629         else
1630         {       // no x input
1631                 self.pressedkeys &= ~KEY_FORWARD;
1632                 self.pressedkeys &= ~KEY_BACKWARD;
1633         }
1634
1635         if (self.movement_y > 0)
1636         {       // right key pressed
1637                 self.pressedkeys |= KEY_RIGHT;
1638                 self.pressedkeys &= ~KEY_LEFT;
1639         }
1640         else if (self.movement_y < 0)
1641         {       // left key pressed
1642                 self.pressedkeys |= KEY_LEFT;
1643                 self.pressedkeys &= ~KEY_RIGHT;
1644         }
1645         else
1646         {       // no y input
1647                 self.pressedkeys &= ~KEY_RIGHT;
1648                 self.pressedkeys &= ~KEY_LEFT;
1649         }
1650
1651         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1652                 self.pressedkeys |= KEY_JUMP;
1653         else
1654                 self.pressedkeys &= ~KEY_JUMP;
1655         if (self.BUTTON_CROUCH)
1656                 self.pressedkeys |= KEY_CROUCH;
1657         else
1658                 self.pressedkeys &= ~KEY_CROUCH;
1659
1660         if (self.BUTTON_ATCK)
1661                 self.pressedkeys |= KEY_ATCK;
1662         else
1663                 self.pressedkeys &= ~KEY_ATCK;
1664         if (self.BUTTON_ATCK2)
1665                 self.pressedkeys |= KEY_ATCK2;
1666         else
1667                 self.pressedkeys &= ~KEY_ATCK2;
1668 }
1669
1670 /*
1671 ======================
1672 spectate mode routines
1673 ======================
1674 */
1675
1676 void SpectateCopy(entity spectatee) {
1677         other = spectatee;
1678         MUTATOR_CALLHOOK(SpectateCopy);
1679         self.armortype = spectatee.armortype;
1680         self.armorvalue = spectatee.armorvalue;
1681         self.ammo_cells = spectatee.ammo_cells;
1682         self.ammo_plasma = spectatee.ammo_plasma;
1683         self.ammo_shells = spectatee.ammo_shells;
1684         self.ammo_nails = spectatee.ammo_nails;
1685         self.ammo_rockets = spectatee.ammo_rockets;
1686         self.ammo_fuel = spectatee.ammo_fuel;
1687         self.clip_load = spectatee.clip_load;
1688         self.clip_size = spectatee.clip_size;
1689         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1690         self.health = spectatee.health;
1691         self.impulse = 0;
1692         self.items = spectatee.items;
1693         self.last_pickup = spectatee.last_pickup;
1694         self.hit_time = spectatee.hit_time;
1695         self.metertime = spectatee.metertime;
1696         self.strength_finished = spectatee.strength_finished;
1697         self.invincible_finished = spectatee.invincible_finished;
1698         self.pressedkeys = spectatee.pressedkeys;
1699         self.weapons = spectatee.weapons;
1700         self.switchweapon = spectatee.switchweapon;
1701         self.switchingweapon = spectatee.switchingweapon;
1702         self.weapon = spectatee.weapon;
1703         self.vortex_charge = spectatee.vortex_charge;
1704         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1705         self.hagar_load = spectatee.hagar_load;
1706         self.arc_heat_percent = spectatee.arc_heat_percent;
1707         self.minelayer_mines = spectatee.minelayer_mines;
1708         self.punchangle = spectatee.punchangle;
1709         self.view_ofs = spectatee.view_ofs;
1710         self.velocity = spectatee.velocity;
1711         self.dmg_take = spectatee.dmg_take;
1712         self.dmg_save = spectatee.dmg_save;
1713         self.dmg_inflictor = spectatee.dmg_inflictor;
1714         self.v_angle = spectatee.v_angle;
1715         self.angles = spectatee.v_angle;
1716         self.frozen = spectatee.frozen;
1717         self.revive_progress = spectatee.revive_progress;
1718         if(!self.BUTTON_USE)
1719                 self.fixangle = TRUE;
1720         setorigin(self, spectatee.origin);
1721         setsize(self, spectatee.mins, spectatee.maxs);
1722         SetZoomState(spectatee.zoomstate);
1723
1724     anticheat_spectatecopy(spectatee);
1725         self.hud = spectatee.hud;
1726         if(spectatee.vehicle)
1727     {
1728         self.fixangle = FALSE;
1729         //self.velocity = spectatee.vehicle.velocity;
1730         self.vehicle_health = spectatee.vehicle_health;
1731         self.vehicle_shield = spectatee.vehicle_shield;
1732         self.vehicle_energy = spectatee.vehicle_energy;
1733         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1734         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1735         self.vehicle_reload1 = spectatee.vehicle_reload1;
1736         self.vehicle_reload2 = spectatee.vehicle_reload2;
1737
1738         msg_entity = self;
1739
1740         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1741             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1742             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1743             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1744
1745         //WriteByte (MSG_ONE, SVC_SETVIEW);
1746         //    WriteEntity(MSG_ONE, self);
1747         //makevectors(spectatee.v_angle);
1748         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1749     }
1750 }
1751
1752 float SpectateUpdate()
1753 {
1754         if(!self.enemy)
1755             return 0;
1756
1757         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1758         {
1759                 SetSpectator(self, world);
1760                 return 0;
1761         }
1762
1763         SpectateCopy(self.enemy);
1764
1765         return 1;
1766 }
1767
1768
1769 float SpectateSet()
1770 {
1771         if(self.enemy.classname != "player")
1772                 return FALSE;
1773         /*if(self.enemy.vehicle)
1774         {
1775
1776                 msg_entity = self;
1777                 WriteByte(MSG_ONE, SVC_SETVIEW);
1778                 WriteEntity(MSG_ONE, self.enemy);
1779                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1780
1781                 self.movetype = MOVETYPE_NONE;
1782                 accuracy_resend(self);
1783         }
1784         else
1785         {*/
1786                 msg_entity = self;
1787                 WriteByte(MSG_ONE, SVC_SETVIEW);
1788                 WriteEntity(MSG_ONE, self.enemy);
1789                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1790                 self.movetype = MOVETYPE_NONE;
1791                 accuracy_resend(self);
1792
1793                 if(!SpectateUpdate())
1794                         PutObserverInServer();
1795         //}
1796         return TRUE;
1797 }
1798
1799 void SetSpectator(entity player, entity spectatee)
1800 {
1801         entity old_spectatee = player.enemy;
1802
1803         player.enemy = spectatee;
1804
1805         // WEAPONTODO
1806         // these are required to fix the spectator bug with arc
1807         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1808         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1809 }
1810
1811 float Spectate(entity pl)
1812 {
1813         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1814         if(pl.team != self.team)
1815                 return 0;
1816
1817         SetSpectator(self, pl);
1818         return SpectateSet();
1819 }
1820
1821 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1822 entity CA_SpectateNext(entity start) {
1823         if (start.team == self.team) {
1824                 return start;
1825         }
1826
1827         other = start;
1828         // continue from current player
1829         while(other && other.team != self.team) {
1830                 other = find(other, classname, "player");
1831         }
1832
1833         if (!other) {
1834                 // restart from begining
1835                 other = find(other, classname, "player");
1836                 while(other && other.team != self.team) {
1837                         other = find(other, classname, "player");
1838                 }
1839         }
1840
1841         return other;
1842 }
1843
1844 float SpectateNext()
1845 {
1846         other = find(self.enemy, classname, "player");
1847
1848         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1849                 // CA and ca players when spectating enemies is forbidden
1850                 other = CA_SpectateNext(other);
1851         } else {
1852                 // other modes and ca spectators or spectating enemies is allowed
1853                 if (!other)
1854                         other = find(other, classname, "player");
1855         }
1856
1857         if(other) { SetSpectator(self, other); }
1858
1859         return SpectateSet();
1860 }
1861
1862 float SpectatePrev()
1863 {
1864         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1865         other = findchain(classname, "player");
1866         if (!other) // no player
1867                 return FALSE;
1868
1869         entity first = other;
1870         // skip players until current spectated player
1871         if(self.enemy)
1872         while(other && other != self.enemy)
1873                 other = other.chain;
1874
1875         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1876         {
1877                 do { other = other.chain; }
1878                 while(other && other.team != self.team);
1879
1880                 if (!other)
1881                 {
1882                         other = first;
1883                         while(other.team != self.team)
1884                                 other = other.chain;
1885                         if(other == self.enemy)
1886                                 return TRUE;
1887                 }
1888         }
1889         else
1890         {
1891                 if(other.chain)
1892                         other = other.chain;
1893                 else
1894                         other = first;
1895         }
1896         SetSpectator(self, other);
1897         return SpectateSet();
1898 }
1899
1900 /*
1901 =============
1902 ShowRespawnCountdown()
1903
1904 Update a respawn countdown display.
1905 =============
1906 */
1907 void ShowRespawnCountdown()
1908 {
1909         float number;
1910         if(self.deadflag == DEAD_NO) // just respawned?
1911                 return;
1912         else
1913         {
1914                 number = ceil(self.respawn_time - time);
1915                 if(number <= 0)
1916                         return;
1917                 if(number <= self.respawn_countdown)
1918                 {
1919                         self.respawn_countdown = number - 1;
1920                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1921                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1922                 }
1923         }
1924 }
1925
1926 void LeaveSpectatorMode()
1927 {
1928         if(self.caplayer)
1929                 return;
1930         if(nJoinAllowed(self))
1931         {
1932                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1933                 {
1934                         self.classname = "player";
1935                         nades_RemoveBonus(self);
1936
1937                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1938                                 { JoinBestTeam(self, FALSE, TRUE); }
1939
1940                         if(autocvar_g_campaign)
1941                                 { campaign_bots_may_start = 1; }
1942
1943                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1944
1945                         PutClientInServer();
1946
1947                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1948                 }
1949                 else
1950                         stuffcmd(self, "menu_showteamselect\n");
1951         }
1952         else
1953         {
1954                 // Player may not join because g_maxplayers is set
1955                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1956         }
1957 }
1958
1959 /**
1960  * Determines whether the player is allowed to join. This depends on cvar
1961  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1962  * it checks whether the number of currently playing players exceeds g_maxplayers.
1963  * @return int number of free slots for players, 0 if none
1964  */
1965 float nJoinAllowed(entity ignore) {
1966         if(!ignore)
1967         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1968         // so report 0 free slots if restricted
1969         {
1970                 if(autocvar_g_forced_team_otherwise == "spectate")
1971                         return 0;
1972                 if(autocvar_g_forced_team_otherwise == "spectator")
1973                         return 0;
1974         }
1975
1976         if(self.team_forced < 0)
1977                 return 0; // forced spectators can never join
1978
1979         // TODO simplify this
1980         entity e;
1981         float totalClients = 0;
1982         FOR_EACH_CLIENT(e)
1983                 if(e != ignore)
1984                         totalClients += 1;
1985
1986         if (!autocvar_g_maxplayers)
1987                 return maxclients - totalClients;
1988
1989         float currentlyPlaying = 0;
1990         FOR_EACH_REALCLIENT(e)
1991                 if(IS_PLAYER(e) || e.caplayer == 1)
1992                         currentlyPlaying += 1;
1993
1994         if(currentlyPlaying < autocvar_g_maxplayers)
1995                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1996
1997         return 0;
1998 }
1999
2000 /**
2001  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2002  * g_maxplayers_spectator_blocktime seconds
2003  */
2004 void checkSpectatorBlock() {
2005         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2006                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2007                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2008                         dropclient(self);
2009                 }
2010         }
2011 }
2012
2013 void PrintWelcomeMessage()
2014 {
2015         if(self.motd_actived_time == 0)
2016         {
2017                 if (autocvar_g_campaign) {
2018                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2019                                 self.motd_actived_time = time;
2020                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2021                         }
2022                 } else {
2023                         if (self.BUTTON_INFO) {
2024                                 self.motd_actived_time = time;
2025                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2026                         }
2027                 }
2028         }
2029         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2030         {
2031                 if (autocvar_g_campaign) {
2032                         if (self.BUTTON_INFO)
2033                                 self.motd_actived_time = time;
2034                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2035                                 self.motd_actived_time = 0;
2036                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2037                         }
2038                 } else {
2039                         if (self.BUTTON_INFO)
2040                                 self.motd_actived_time = time;
2041                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2042                                 self.motd_actived_time = 0;
2043                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2044                         }
2045                 }
2046         }
2047         else //if(self.motd_actived_time < 0) // just connected, motd is active
2048         {
2049                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2050                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2051                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2052                 {
2053                         // instanctly hide MOTD
2054                         self.motd_actived_time = 0;
2055                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2056                 }
2057         }
2058 }
2059
2060 void ObserverThink()
2061 {
2062         float prefered_movetype;
2063         if (self.flags & FL_JUMPRELEASED) {
2064                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2065                         self.flags &= ~FL_JUMPRELEASED;
2066                         self.flags |= FL_SPAWNING;
2067                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2068                         self.flags &= ~FL_JUMPRELEASED;
2069                         if(SpectateNext()) {
2070                                 self.classname = "spectator";
2071                         }
2072                 } else {
2073                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2074                         if (self.movetype != prefered_movetype)
2075                                 self.movetype = prefered_movetype;
2076                 }
2077         } else {
2078                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2079                         self.flags |= FL_JUMPRELEASED;
2080                         if(self.flags & FL_SPAWNING)
2081                         {
2082                                 self.flags &= ~FL_SPAWNING;
2083                                 LeaveSpectatorMode();
2084                                 return;
2085                         }
2086                 }
2087         }
2088 }
2089
2090 void SpectatorThink()
2091 {
2092         if (self.flags & FL_JUMPRELEASED) {
2093                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2094                         self.flags &= ~FL_JUMPRELEASED;
2095                         self.flags |= FL_SPAWNING;
2096                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2097                         self.flags &= ~FL_JUMPRELEASED;
2098                         if(SpectateNext()) {
2099                                 self.classname = "spectator";
2100                         } else {
2101                                 self.classname = "observer";
2102                                 PutClientInServer();
2103                         }
2104                         self.impulse = 0;
2105                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2106                         self.flags &= ~FL_JUMPRELEASED;
2107                         if(SpectatePrev()) {
2108                                 self.classname = "spectator";
2109                         } else {
2110                                 self.classname = "observer";
2111                                 PutClientInServer();
2112                         }
2113                         self.impulse = 0;
2114                 } else if (self.BUTTON_ATCK2) {
2115                         self.flags &= ~FL_JUMPRELEASED;
2116                         self.classname = "observer";
2117                         PutClientInServer();
2118                 } else {
2119                         if(!SpectateUpdate())
2120                                 PutObserverInServer();
2121                 }
2122         } else {
2123                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2124                         self.flags |= FL_JUMPRELEASED;
2125                         if(self.flags & FL_SPAWNING)
2126                         {
2127                                 self.flags &= ~FL_SPAWNING;
2128                                 LeaveSpectatorMode();
2129                                 return;
2130                         }
2131                 }
2132                 if(!SpectateUpdate())
2133                         PutObserverInServer();
2134         }
2135
2136         self.flags |= FL_CLIENT | FL_NOTARGET;
2137 }
2138
2139 void PlayerUseKey()
2140 {
2141         if (!IS_PLAYER(self))
2142                 return;
2143
2144         if(self.vehicle)
2145         {
2146         vehicles_exit(VHEF_NORMAL);
2147         return;
2148         }
2149
2150         // a use key was pressed; call handlers
2151         MUTATOR_CALLHOOK(PlayerUseKey);
2152 }
2153
2154 /*
2155 =============
2156 PlayerPreThink
2157
2158 Called every frame for each client before the physics are run
2159 =============
2160 */
2161 .float usekeypressed;
2162 void() nexball_setstatus;
2163 .float items_added;
2164 void PlayerPreThink (void)
2165 {
2166         WarpZone_PlayerPhysics_FixVAngle();
2167
2168         self.stat_game_starttime = game_starttime;
2169         self.stat_round_starttime = round_starttime;
2170         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2171         self.stat_leadlimit = autocvar_leadlimit;
2172
2173         if(frametime)
2174         {
2175                 // physics frames: update anticheat stuff
2176                 anticheat_prethink();
2177         }
2178
2179         if(blockSpectators && frametime)
2180                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2181                 checkSpectatorBlock();
2182
2183         zoomstate_set = 0;
2184
2185         if(self.netname_previous != self.netname)
2186         {
2187                 if(autocvar_sv_eventlog)
2188                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2189                 if(self.netname_previous)
2190                         strunzone(self.netname_previous);
2191                 self.netname_previous = strzone(self.netname);
2192         }
2193
2194         // version nagging
2195         if(self.version_nagtime)
2196                 if(self.cvar_g_xonoticversion)
2197                         if(time > self.version_nagtime)
2198                         {
2199                                 // don't notify git users
2200                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2201                                 {
2202                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2203                                         {
2204                                                 // notify release users if connecting to git
2205                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2206                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2207                                         }
2208                                         else
2209                                         {
2210                                                 float r;
2211                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2212                                                 if(r < 0)
2213                                                 {
2214                                                         // give users new version
2215                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2216                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2217                                                 }
2218                                                 else if(r > 0)
2219                                                 {
2220                                                         // notify users about old server version
2221                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2222                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2223                                                 }
2224                                         }
2225                                 }
2226                                 self.version_nagtime = 0;
2227                         }
2228
2229         // GOD MODE info
2230         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2231         {
2232                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2233                 self.max_armorvalue = 0;
2234         }
2235
2236 #ifdef TETRIS
2237         if (TetrisPreFrame())
2238                 return;
2239 #endif
2240
2241         if(self.frozen == 2)
2242         {
2243                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2244                 self.health = max(1, self.revive_progress * start_health);
2245                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2246
2247                 if(self.revive_progress >= 1)
2248                         Unfreeze(self);
2249         }
2250         else if(self.frozen == 3)
2251         {
2252                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2253                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2254
2255                 if(self.health < 1)
2256                 {
2257                         if(self.vehicle)
2258                                 vehicles_exit(VHEF_RELESE);
2259                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2260                 }
2261                 else if ( self.revive_progress <= 0 )
2262                         Unfreeze(self);
2263         }
2264
2265         MUTATOR_CALLHOOK(PlayerPreThink);
2266
2267         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2268         {
2269                 if(self.BUTTON_USE && !self.usekeypressed)
2270                         PlayerUseKey();
2271                 self.usekeypressed = self.BUTTON_USE;
2272         }
2273
2274         if(IS_REAL_CLIENT(self))
2275                 PrintWelcomeMessage();
2276
2277         if(IS_PLAYER(self))
2278         {
2279
2280                 CheckRules_Player();
2281
2282                 if (intermission_running)
2283                 {
2284                         IntermissionThink ();   // otherwise a button could be missed between
2285                         return;                                 // the think tics
2286                 }
2287
2288                 //don't allow the player to turn around while game is paused!
2289                 if(timeout_status == TIMEOUT_ACTIVE) {
2290                         // FIXME turn this into CSQC stuff
2291                         self.v_angle = self.lastV_angle;
2292                         self.angles = self.lastV_angle;
2293                         self.fixangle = TRUE;
2294                 }
2295
2296                 if(frametime)
2297                 {
2298                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2299                         {
2300                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2301                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2302                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2303
2304                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2305                                 {
2306                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2307                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2308                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2309                                 }
2310                         }
2311                         else
2312                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2313
2314                         player_powerups();
2315                 }
2316
2317                 if (self.deadflag != DEAD_NO)
2318                 {
2319                         if(self.personal && g_race_qualifying)
2320                         {
2321                                 if(time > self.respawn_time)
2322                                 {
2323                                         self.respawn_time = time + 1; // only retry once a second
2324                                         self.stat_respawn_time = self.respawn_time;
2325                                         respawn();
2326                                         self.impulse = 141;
2327                                 }
2328                         }
2329                         else
2330                         {
2331                                 float button_pressed;
2332                                 if(frametime)
2333                                         player_anim();
2334                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2335
2336                                 if (self.deadflag == DEAD_DYING)
2337                                 {
2338                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2339                                                 self.deadflag = DEAD_RESPAWNING;
2340                                         else if(!button_pressed)
2341                                                 self.deadflag = DEAD_DEAD;
2342                                 }
2343                                 else if (self.deadflag == DEAD_DEAD)
2344                                 {
2345                                         if(button_pressed)
2346                                                 self.deadflag = DEAD_RESPAWNABLE;
2347                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2348                                                 self.deadflag = DEAD_RESPAWNING;
2349                                 }
2350                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2351                                 {
2352                                         if(!button_pressed)
2353                                                 self.deadflag = DEAD_RESPAWNING;
2354                                 }
2355                                 else if (self.deadflag == DEAD_RESPAWNING)
2356                                 {
2357                                         if(time > self.respawn_time)
2358                                         {
2359                                                 self.respawn_time = time + 1; // only retry once a second
2360                                                 self.respawn_time_max = self.respawn_time;
2361                                                 respawn();
2362                                         }
2363                                 }
2364
2365                                 ShowRespawnCountdown();
2366
2367                                 if(self.respawn_flags & RESPAWN_SILENT)
2368                                         self.stat_respawn_time = 0;
2369                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2370                                         self.stat_respawn_time = self.respawn_time_max;
2371                                 else
2372                                         self.stat_respawn_time = self.respawn_time;
2373                         }
2374
2375                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2376                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2377                                 self.stat_respawn_time *= -1;
2378
2379                         return;
2380                 }
2381
2382                 self.prevorigin = self.origin;
2383
2384                 float do_crouch = self.BUTTON_CROUCH;
2385                 if(self.hook.state)
2386                         do_crouch = 0;
2387                 if(self.vehicle)
2388                         do_crouch = 0;
2389                 if(self.frozen)
2390                         do_crouch = 0;
2391
2392                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2393                 // It cannot be predicted by the engine!
2394                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2395                         do_crouch = 0;
2396
2397                 if (do_crouch)
2398                 {
2399                         if (!self.crouch)
2400                         {
2401                                 self.crouch = TRUE;
2402                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2403                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2404                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2405                         }
2406                 }
2407                 else
2408                 {
2409                         if (self.crouch)
2410                         {
2411                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2412                                 if (!trace_startsolid)
2413                                 {
2414                                         self.crouch = FALSE;
2415                                         self.view_ofs = PL_VIEW_OFS;
2416                                         setsize (self, PL_MIN, PL_MAX);
2417                                 }
2418                         }
2419                 }
2420
2421                 FixPlayermodel();
2422
2423                 GrapplingHookFrame();
2424
2425                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2426                 //if(frametime)
2427                 {
2428                         self.items &= ~self.items_added;
2429
2430                         W_WeaponFrame();
2431
2432                         self.items_added = 0;
2433                         if(self.items & IT_JETPACK)
2434                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2435                                         self.items_added |= IT_FUEL;
2436
2437                         self.items |= self.items_added;
2438                 }
2439
2440                 player_regen();
2441
2442                 // WEAPONTODO: Add a weapon request for this
2443                 // rot nex charge to the charge limit
2444                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2445                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2446
2447                 if(frametime)
2448                         player_anim();
2449
2450                 // secret status
2451                 secrets_setstatus();
2452
2453                 // monsters status
2454                 monsters_setstatus();
2455
2456                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2457
2458                 //self.angles_y=self.v_angle_y + 90;   // temp
2459         } else if(gameover) {
2460                 if (intermission_running)
2461                         IntermissionThink ();   // otherwise a button could be missed between
2462                 return;
2463         } else if(IS_OBSERVER(self)) {
2464                 ObserverThink();
2465         } else if(IS_SPEC(self)) {
2466                 SpectatorThink();
2467         }
2468
2469         // WEAPONTODO: Add weapon request for this
2470         if(!zoomstate_set)
2471                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2472
2473         float oldspectatee_status;
2474         oldspectatee_status = self.spectatee_status;
2475         if(IS_SPEC(self))
2476                 self.spectatee_status = num_for_edict(self.enemy);
2477         else if(IS_OBSERVER(self))
2478                 self.spectatee_status = num_for_edict(self);
2479         else
2480                 self.spectatee_status = 0;
2481         if(self.spectatee_status != oldspectatee_status)
2482         {
2483                 ClientData_Touch(self);
2484         }
2485
2486         if(self.teamkill_soundtime)
2487         if(time > self.teamkill_soundtime)
2488         {
2489                 self.teamkill_soundtime = 0;
2490
2491                 entity oldpusher, oldself;
2492
2493                 oldself = self; self = self.teamkill_soundsource;
2494                 oldpusher = self.pusher; self.pusher = oldself;
2495
2496                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2497
2498                 self.pusher = oldpusher;
2499                 self = oldself;
2500         }
2501
2502         if(self.taunt_soundtime)
2503         if(time > self.taunt_soundtime)
2504         {
2505                 self.taunt_soundtime = 0;
2506                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2507         }
2508
2509         target_voicescript_next(self);
2510
2511         // WEAPONTODO: Move into weaponsystem somehow
2512         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2513         if(!self.weapon)
2514                 self.clip_load = self.clip_size = 0;
2515 }
2516
2517 float isInvisibleString(string s)
2518 {
2519         float i, n, c;
2520         s = strdecolorize(s);
2521         for((i = 0), (n = strlen(s)); i < n; ++i)
2522         {
2523                 c = str2chr(s, i);
2524                 switch(c)
2525                 {
2526                         case 0:
2527                         case 32: // space
2528                                 break;
2529                         case 192: // charmap space
2530                                 if (!autocvar_utf8_enable)
2531                                         break;
2532                                 return FALSE;
2533                         case 160: // space in unicode fonts
2534                         case 0xE000 + 192: // utf8 charmap space
2535                                 if (autocvar_utf8_enable)
2536                                         break;
2537                         default:
2538                                 return FALSE;
2539                 }
2540         }
2541         return TRUE;
2542 }
2543
2544 /*
2545 =============
2546 PlayerPostThink
2547
2548 Called every frame for each client after the physics are run
2549 =============
2550 */
2551 .float idlekick_lasttimeleft;
2552 void PlayerPostThink (void)
2553 {
2554         // Savage: Check for nameless players
2555         if (isInvisibleString(self.netname)) {
2556                 self.netname = "Player";
2557                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2558         }
2559
2560         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2561         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2562         {
2563                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2564                 {
2565                         if(self.idlekick_lasttimeleft)
2566                         {
2567                                 self.idlekick_lasttimeleft = 0;
2568                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2569                         }
2570                 }
2571                 else
2572                 {
2573                         float timeleft;
2574                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2575                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2576                         {
2577                                 if(!self.idlekick_lasttimeleft)
2578                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2579                         }
2580                         if(timeleft <= 0)
2581                         {
2582                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2583                                 dropclient(self);
2584                                 return;
2585                         }
2586                         else if(timeleft <= 10)
2587                         {
2588                                 if(timeleft != self.idlekick_lasttimeleft)
2589                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2590                                 self.idlekick_lasttimeleft = timeleft;
2591                         }
2592                 }
2593         }
2594
2595 #ifdef TETRIS
2596         if(self.impulse == 100)
2597                 ImpulseCommands();
2598         if (!TetrisPostFrame())
2599         {
2600 #endif
2601
2602         CheatFrame();
2603
2604         //CheckPlayerJump();
2605
2606         if(IS_PLAYER(self)) {
2607                 CheckRules_Player();
2608                 UpdateChatBubble();
2609                 if (self.impulse)
2610                         ImpulseCommands();
2611                 if (intermission_running)
2612                         return;         // intermission or finale
2613                 GetPressedKeys();
2614         }
2615
2616 #ifdef TETRIS
2617         }
2618 #endif
2619
2620         /*
2621         float i;
2622         for(i = 0; i < 1000; ++i)
2623         {
2624                 vector end;
2625                 end = self.origin + '0 0 1024' + 512 * randomvec();
2626                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2627                 if(trace_fraction < 1)
2628                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2629                 {
2630                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2631                         break;
2632                 }
2633         }
2634         */
2635
2636         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2637
2638         if(self.waypointsprite_attachedforcarrier)
2639                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2640
2641         playerdemo_write();
2642
2643         CSQCMODEL_AUTOUPDATE();
2644 }