qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331                 teamcheck = self.team; // MUST be team
 332         else if(have_team_spawns == 0 && have_noteam_spawns)
 333                 teamcheck = 0; // MUST be noteam
 334         else
 335                 teamcheck = -1;
 336                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 337
 338         // get the list of players
 339         playerlist = findchain(classname, "player");
 340         // get the entire list of spots
 341         firstspot = findchain(classname, "info_player_deathmatch");
 342         // filter out the bad ones
 343         // (note this returns the original list if none survived)
 344         if(anypoint)
 345         {
 346                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 347         }
 348         else
 349         {
 350                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 351                 if(!firstspot_new)
 352                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 353                 firstspot = firstspot_new;
 354
 355                 // there is 50/50 chance of choosing a random spot or the furthest spot
 356                 // (this means that roughly every other spawn will be furthest, so you
 357                 // usually won't get fragged at spawn twice in a row)
 358                 if (arena_roundbased && !g_ca)
 359                 {
 360                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 361                         if(firstspot_new)
 362                                 firstspot = firstspot_new;
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 364                 }
 365                 else if (random() > autocvar_g_spawn_furthest)
 366                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 367                 else
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 369         }
 370
 371         if(autocvar_spawn_debugview)
 372         {
 373                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 374
 375                 entity e;
 376                 if(teamcheck >= 0)
 377                         for(e = firstspot; e; e = e.chain)
 378                                 if(e.team != teamcheck)
 379                                         error("invalid spawn found");
 380         }
 381
 382         if (!spot)
 383         {
 384                 if(autocvar_spawn_debug)
 385                         GotoNextMap();
 386                 else
 387                 {
 388                         if(some_spawn_has_been_used)
 389                                 return world; // team can't spawn any more, because of actions of other team
 390                         else
 391                                 error("Cannot find a spawn point - please fix the map!");
 392                 }
 393         }
 394
 395         return spot;
 396 }
 397
 398 /*
 399 =============
 400 CheckPlayerModel
 401
 402 Checks if the argument string can be a valid playermodel.
 403 Returns a valid one in doubt.
 404 =============
 405 */
 406 string FallbackPlayerModel;
 407 string CheckPlayerModel(string plyermodel) {
 408         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 409         {
 410                 // note: we cannot summon Don Strunzone here, some player may
 411                 // still have the model string set. In case anyone manages how
 412                 // to change a cvar default, we'll have a small leak here.
 413                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 414         }
 415         if(strlen(plyermodel) < 4)
 416                 return FallbackPlayerModel;
 417         if( substring(plyermodel,0,14) != "models/player/")
 418                 return FallbackPlayerModel;
 419         else if(autocvar_sv_servermodelsonly)
 420         {
 421                 if(substring(plyermodel,-4,4) != ".zym")
 422                 if(substring(plyermodel,-4,4) != ".dpm")
 423                 if(substring(plyermodel,-4,4) != ".iqm")
 424                 if(substring(plyermodel,-4,4) != ".md3")
 425                 if(substring(plyermodel,-4,4) != ".psk")
 426                         return FallbackPlayerModel;
 427                 // forbid the LOD models
 428                 if(substring(plyermodel, -9,5) == "_lod1")
 429                         return FallbackPlayerModel;
 430                 if(substring(plyermodel, -9,5) == "_lod2")
 431                         return FallbackPlayerModel;
 432                 if(plyermodel != strtolower(plyermodel))
 433                         return FallbackPlayerModel;
 434                 if(!fexists(plyermodel))
 435                         return FallbackPlayerModel;
 436         }
 437         return plyermodel;
 438 }
 439
 440 /*
 441 =============
 442 Client_customizeentityforclient
 443
 444 LOD reduction
 445 =============
 446 */
 447 void Client_uncustomizeentityforclient()
 448 {
 449         if(self.modelindex == 0) // no need to uncustomize then
 450                 return;
 451         self.modelindex = self.modelindex_lod0;
 452         self.skin = self.skinindex;
 453 }
 454
 455 float Client_customizeentityforclient()
 456 {
 457         entity modelsource;
 458
 459         if(self.modelindex == 0)
 460                 return TRUE;
 461
 462         // forcemodel stuff
 463
 464 #ifdef PROFILING
 465         float t0;
 466         t0 = gettime(GETTIME_HIRES); // reference
 467 #endif
 468
 469         modelsource = self;
 470
 471 #ifdef ALLOW_FORCEMODELS
 472         if(other.cvar_cl_forceplayermodelsfromxonotic)
 473                 if not(self.modelindex_lod0_from_xonotic)
 474                         modelsource = other;
 475         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 476                 modelsource = other;
 477 #endif
 478
 479         self.skin = modelsource.skinindex;
 480
 481 #if 0
 482         if(modelsource == self)
 483                 self.skin = modelsource.skinindex;
 484         else
 485                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 486 #endif
 487
 488         // self: me
 489         // other: the player viewing me
 490         float distance;
 491         float f;
 492
 493         if(other.cvar_cl_playerdetailreduction <= 0)
 494         {
 495                 if(other.cvar_cl_playerdetailreduction <= -2)
 496                         self.modelindex = modelsource.modelindex_lod2;
 497                 else if(other.cvar_cl_playerdetailreduction <= -1)
 498                         self.modelindex = modelsource.modelindex_lod1;
 499                 else
 500                         self.modelindex = modelsource.modelindex_lod0;
 501         }
 502         else
 503         {
 504                 distance = vlen(self.origin - other.origin);
 505                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 506                 if(f > sv_loddistance2)
 507                         self.modelindex = modelsource.modelindex_lod2;
 508                 else if(f > sv_loddistance1)
 509                         self.modelindex = modelsource.modelindex_lod1;
 510                 else
 511                         self.modelindex = modelsource.modelindex_lod0;
 512         }
 513
 514 #ifdef PROFILING
 515         float t1;
 516         t1 = gettime(GETTIME_HIRES); // reference
 517         client_cefc_accumulator += (t1 - t0);
 518 #endif
 519
 520         return TRUE;
 521 }
 522
 523 void setmodel_lod(entity e, string modelname)
 524 {
 525         string s;
 526
 527         if(sv_loddistance1)
 528         {
 529                 // FIXME: this only supports 3-letter extensions
 530                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 531                 if(fexists(s))
 532                 {
 533                         setmodel(e, s); // players have high precision
 534                         self.modelindex_lod1 = self.modelindex;
 535                 }
 536                 else
 537                         self.modelindex_lod1 = -1;
 538
 539                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 540                 if(fexists(s))
 541                 {
 542                         setmodel(e, s); // players have high precision
 543                         self.modelindex_lod2 = self.modelindex;
 544                 }
 545                 else
 546                         self.modelindex_lod2 = -1;
 547
 548                 precache_model(modelname);
 549                 setmodel(e, modelname); // players have high precision
 550                 self.modelindex_lod0 = self.modelindex;
 551
 552                 if(self.modelindex_lod1 < 0)
 553                         self.modelindex_lod1 = self.modelindex;
 554
 555                 if(self.modelindex_lod2 < 0)
 556                         self.modelindex_lod2 = self.modelindex;
 557         }
 558         else
 559         {
 560                 precache_model(modelname);
 561                 setmodel(e, modelname); // players have high precision
 562                 self.modelindex_lod0 = self.modelindex;
 563                         // save it for possible player model forcing
 564         }
 565
 566         s = whichpack(self.model);
 567         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 568
 569         player_setupanimsformodel();
 570         UpdatePlayerSounds();
 571 }
 572
 573 /*
 574 =============
 575 PutObserverInServer
 576
 577 putting a client as observer in the server
 578 =============
 579 */
 580 void FixPlayermodel();
 581 void PutObserverInServer (void)
 582 {
 583         entity  spot;
 584
 585         race_PreSpawnObserver();
 586
 587         spot = SelectSpawnPoint (TRUE);
 588         if(!spot)
 589                 error("No spawnpoints for observers?!?\n");
 590         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 591
 592         if(clienttype(self) == CLIENTTYPE_REAL)
 593         {
 594                 msg_entity = self;
 595                 WriteByte(MSG_ONE, SVC_SETVIEW);
 596                 WriteEntity(MSG_ONE, self);
 597         }
 598
 599         DropAllRunes(self);
 600         MUTATOR_CALLHOOK(MakePlayerObserver);
 601
 602         Portal_ClearAll(self);
 603
 604         if(self.alivetime)
 605         {
 606                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 607                 self.alivetime = 0;
 608         }
 609
 610         if(self.flagcarried)
 611                 DropFlag(self.flagcarried, world, world);
 612
 613         if(self.ballcarried && g_nexball)
 614                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 615
 616         WaypointSprite_PlayerDead();
 617
 618         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 619                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 620
 621         if(self.killcount != -666) {
 622                 if(g_lms) {
 623                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 624                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 625                         else
 626                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 627                 } else
 628                         bprint ("^4", self.netname, "^4 is spectating now\n");
 629
 630                 if(self.just_joined == FALSE) {
 631                         LogTeamchange(self.playerid, -1, 4);
 632                 } else
 633                         self.just_joined = FALSE;
 634         }
 635
 636         PlayerScore_Clear(self); // clear scores when needed
 637
 638         accuracy_resend(self);
 639
 640         self.spectatortime = time;
 641
 642         self.classname = "observer";
 643         self.iscreature = FALSE;
 644         self.health = -666;
 645         self.takedamage = DAMAGE_NO;
 646         self.solid = SOLID_NOT;
 647         self.movetype = MOVETYPE_NOCLIP;
 648         self.flags = FL_CLIENT | FL_NOTARGET;
 649         self.armorvalue = 666;
 650         self.effects = 0;
 651         self.armorvalue = autocvar_g_balance_armor_start;
 652         self.pauserotarmor_finished = 0;
 653         self.pauserothealth_finished = 0;
 654         self.pauseregen_finished = 0;
 655         self.damageforcescale = 0;
 656         self.death_time = 0;
 657         self.dead_frame = 0;
 658         self.alpha = 0;
 659         self.scale = 0;
 660         self.fade_time = 0;
 661         self.pain_frame = 0;
 662         self.pain_finished = 0;
 663         self.strength_finished = 0;
 664         self.invincible_finished = 0;
 665         self.pushltime = 0;
 666         self.think = SUB_Null;
 667         self.nextthink = 0;
 668         self.hook_time = 0;
 669         self.runes = 0;
 670         self.deadflag = DEAD_NO;
 671         self.angles = spot.angles;
 672         self.angles_z = 0;
 673         self.fixangle = TRUE;
 674         self.crouch = FALSE;
 675
 676         self.view_ofs = PL_VIEW_OFS;
 677         setorigin (self, spot.origin);
 678         setsize (self, '0 0 0', '0 0 0');
 679         self.prevorigin = self.origin;
 680         self.items = 0;
 681         self.weapons = 0;
 682         self.model = "";
 683         FixPlayermodel();
 684         self.model = "";
 685         self.modelindex = 0;
 686         self.weapon = 0;
 687         self.weaponmodel = "";
 688         self.weaponentity = world;
 689         self.exteriorweaponentity = world;
 690         self.killcount = -666;
 691         self.velocity = '0 0 0';
 692         self.avelocity = '0 0 0';
 693         self.punchangle = '0 0 0';
 694         self.punchvector = '0 0 0';
 695         self.oldvelocity = self.velocity;
 696         self.fire_endtime = -1;
 697
 698         if(sv_loddistance1)
 699                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 700
 701         if(g_arena)
 702         {
 703                 if(self.version_mismatch)
 704                 {
 705                         Spawnqueue_Unmark(self);
 706                         Spawnqueue_Remove(self);
 707                 }
 708                 else
 709                 {
 710                         Spawnqueue_Insert(self);
 711                 }
 712         }
 713         else if(g_lms)
 714         {
 715                 // Only if the player cannot play at all
 716                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 717                         self.frags = FRAGS_SPECTATOR;
 718                 else
 719                         self.frags = FRAGS_LMS_LOSER;
 720         }
 721         else
 722                 self.frags = FRAGS_SPECTATOR;
 723 }
 724
 725 void FixPlayermodel()
 726 {
 727         local string defaultmodel;
 728         local float defaultskin, chmdl, oldskin;
 729         local vector m1, m2;
 730
 731         defaultmodel = "";
 732
 733         if(autocvar_sv_defaultcharacter == 1) {
 734                 defaultskin = 0;
 735
 736                 if(teams_matter)
 737                 {
 738                         string s;
 739                         s = Team_ColorNameLowerCase(self.team);
 740                         if(s != "neutral")
 741                         {
 742                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 743                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 744                         }
 745                 }
 746
 747                 if(defaultmodel == "")
 748                 {
 749                         defaultmodel = autocvar_sv_defaultplayermodel;
 750                         defaultskin = autocvar_sv_defaultplayerskin;
 751                 }
 752         }
 753
 754         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 755         {
 756                 if(self.model != "")
 757                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 758                 self.model = ""; // force the != checks to return true
 759         }
 760
 761         if(defaultmodel != "")
 762         {
 763                 if (defaultmodel != self.model)
 764                 {
 765                         m1 = self.mins;
 766                         m2 = self.maxs;
 767                         setmodel_lod (self, defaultmodel);
 768                         setsize (self, m1, m2);
 769                         chmdl = TRUE;
 770                 }
 771
 772                 oldskin = self.skinindex;
 773                 self.skinindex = defaultskin;
 774         } else {
 775                 if (self.playermodel != self.model || self.playermodel == "")
 776                 {
 777                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 778                         m1 = self.mins;
 779                         m2 = self.maxs;
 780                         setmodel_lod (self, self.playermodel);
 781                         setsize (self, m1, m2);
 782                         chmdl = TRUE;
 783                 }
 784
 785                 oldskin = self.skinindex;
 786                 self.skinindex = stof(self.playerskin);
 787         }
 788
 789         if(chmdl || oldskin != self.skinindex)
 790                 self.species = player_getspecies(); // model or skin has changed
 791
 792         if(!teams_matter)
 793                 if(strlen(autocvar_sv_defaultplayercolors))
 794                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 795                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 796 }
 797
 798 void PlayerTouchExplode(entity p1, entity p2)
 799 {
 800         vector org;
 801         org = (p1.origin + p2.origin) * 0.5;
 802         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 803
 804         te_explosion(org);
 805
 806         entity e;
 807         e = spawn();
 808         setorigin(e, org);
 809         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 810         remove(e);
 811 }
 812
 813 /*
 814 =============
 815 PutClientInServer
 816
 817 Called when a client spawns in the server
 818 =============
 819 */
 820 //void() ctf_playerchanged;
 821 void PutClientInServer (void)
 822 {
 823         if(clienttype(self) == CLIENTTYPE_BOT)
 824         {
 825                 self.classname = "player";
 826         }
 827         else if(clienttype(self) == CLIENTTYPE_REAL)
 828         {
 829                 msg_entity = self;
 830                 WriteByte(MSG_ONE, SVC_SETVIEW);
 831                 WriteEntity(MSG_ONE, self);
 832         }
 833
 834         // player is dead and becomes observer
 835         // FIXME fix LMS scoring for new system
 836         if(g_lms)
 837         {
 838                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 839                         self.classname = "observer";
 840         }
 841
 842         if(g_arena || (g_ca && !allowed_to_spawn))
 843         if(!self.spawned)
 844                 self.classname = "observer";
 845
 846         if(gameover)
 847                 self.classname = "observer";
 848
 849         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 850                 entity spot, oldself;
 851                 float j;
 852
 853                 accuracy_resend(self);
 854
 855                 if(self.team < 0)
 856                         JoinBestTeam(self, FALSE, TRUE);
 857
 858                 race_PreSpawn();
 859
 860                 spot = SelectSpawnPoint (FALSE);
 861                 if(!spot)
 862                 {
 863                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 864                         return; // spawn failed
 865                 }
 866
 867                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 868
 869                 self.classname = "player";
 870                 self.wasplayer = TRUE;
 871                 self.iscreature = TRUE;
 872                 self.movetype = MOVETYPE_WALK;
 873                 self.solid = SOLID_SLIDEBOX;
 874                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 875                 if(autocvar_g_playerclip_collisions)
 876                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 877                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 878                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 879                 self.frags = FRAGS_PLAYER;
 880                 if(independent_players)
 881                         MAKE_INDEPENDENT_PLAYER(self);
 882                 self.flags = FL_CLIENT;
 883                 self.takedamage = DAMAGE_AIM;
 884                 if(g_minstagib)
 885                         self.effects = EF_FULLBRIGHT;
 886                 else
 887                         self.effects = 0;
 888                 self.air_finished = time + 12;
 889                 self.dmg = 2;
 890                 if(autocvar_g_balance_nex_charge)
 891                 {
 892                         if(autocvar_g_balance_nex_secondary_chargepool)
 893                                 self.nex_chargepool_ammo = 1;
 894                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 895                 }
 896
 897                 if(inWarmupStage)
 898                 {
 899                         self.ammo_shells = warmup_start_ammo_shells;
 900                         self.ammo_nails = warmup_start_ammo_nails;
 901                         self.ammo_rockets = warmup_start_ammo_rockets;
 902                         self.ammo_cells = warmup_start_ammo_cells;
 903                         self.ammo_fuel = warmup_start_ammo_fuel;
 904                         self.health = warmup_start_health;
 905                         self.armorvalue = warmup_start_armorvalue;
 906                         self.weapons = warmup_start_weapons;
 907                 }
 908                 else
 909                 {
 910                         self.ammo_shells = start_ammo_shells;
 911                         self.ammo_nails = start_ammo_nails;
 912                         self.ammo_rockets = start_ammo_rockets;
 913                         self.ammo_cells = start_ammo_cells;
 914                         self.ammo_fuel = start_ammo_fuel;
 915                         self.health = start_health;
 916                         self.armorvalue = start_armorvalue;
 917                         self.weapons = start_weapons;
 918                 }
 919
 920                 if(g_weaponarena_random)
 921                 {
 922                         if(g_weaponarena_random_with_laser)
 923                                 self.weapons &~= WEPBIT_LASER;
 924                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 925                         if(g_weaponarena_random_with_laser)
 926                                 self.weapons |= WEPBIT_LASER;
 927                 }
 928
 929                 self.items = start_items;
 930                 self.jump_interval = time;
 931
 932                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 933                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 934                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 935                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 936                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 937                 //extend the pause of rotting if client was reset at the beginning of the countdown
 938                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 939                         self.spawnshieldtime += game_starttime - time;
 940                         self.pauserotarmor_finished += game_starttime - time;
 941                         self.pauserothealth_finished += game_starttime - time;
 942                         self.pauseregen_finished += game_starttime - time;
 943                 }
 944                 self.damageforcescale = 2;
 945                 self.death_time = 0;
 946                 self.dead_frame = 0;
 947                 self.alpha = 0;
 948                 self.scale = 0;
 949                 self.fade_time = 0;
 950                 self.pain_frame = 0;
 951                 self.pain_finished = 0;
 952                 self.strength_finished = 0;
 953                 self.invincible_finished = 0;
 954                 self.pushltime = 0;
 955                 // players have no think function
 956                 self.think = SUB_Null;
 957                 self.nextthink = 0;
 958                 self.hook_time = 0;
 959                 self.dmg_team = 0;
 960                 self.ballistics_density = autocvar_g_ballistics_density_player;
 961
 962                 self.metertime = 0;
 963
 964                 self.runes = 0;
 965
 966                 self.deadflag = DEAD_NO;
 967
 968                 self.angles = spot.angles;
 969
 970                 self.angles_z = 0; // never spawn tilted even if the spot says to
 971                 self.fixangle = TRUE; // turn this way immediately
 972                 self.velocity = '0 0 0';
 973                 self.avelocity = '0 0 0';
 974                 self.punchangle = '0 0 0';
 975                 self.punchvector = '0 0 0';
 976                 self.oldvelocity = self.velocity;
 977                 self.fire_endtime = -1;
 978
 979                 msg_entity = self;
 980                 WRITESPECTATABLE_MSG_ONE({
 981                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 982                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 983                 });
 984
 985                 if(sv_loddistance1)
 986                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 987
 988                 self.model = "";
 989                 FixPlayermodel();
 990
 991                 self.crouch = FALSE;
 992                 self.view_ofs = PL_VIEW_OFS;
 993                 setsize (self, PL_MIN, PL_MAX);
 994                 self.spawnorigin = spot.origin;
 995                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 996                 // don't reset back to last position, even if new position is stuck in solid
 997                 self.oldorigin = self.origin;
 998                 self.prevorigin = self.origin;
 999                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1000
1001                 if(g_arena)
1002                 {
1003                         Spawnqueue_Remove(self);
1004                         Spawnqueue_Mark(self);
1005                 }
1006
1007                 else if(g_ca)
1008                         self.caplayer = 1;
1009
1010                 self.event_damage = PlayerDamage;
1011
1012                 self.bot_attack = TRUE;
1013
1014                 self.statdraintime = time + 5;
1015                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1016
1017                 if(self.killcount == -666) {
1018                         PlayerScore_Clear(self);
1019                         self.killcount = 0;
1020                 }
1021
1022                 self.cnt = WEP_LASER;
1023
1024                 CL_SpawnWeaponentity();
1025                 self.alpha = default_player_alpha;
1026                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1027                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1028
1029                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1030                 self.lms_traveled_distance = 0;
1031                 self.speedrunning = FALSE;
1032
1033                 race_PostSpawn(spot);
1034
1035                 if(autocvar_spawn_debug)
1036                 {
1037                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1038                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1039                 }
1040
1041                 //stuffcmd(self, "chase_active 0");
1042                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1043
1044                 if (autocvar_g_spawnsound)
1045                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1046
1047                 if(g_assault) {
1048                         if(self.team == assault_attacker_team)
1049                                 centerprint(self, "You are attacking!");
1050                         else
1051                                 centerprint(self, "You are defending!");
1052                 }
1053
1054                 target_voicescript_clear(self);
1055
1056                 // reset fields the weapons may use
1057                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1058                 {
1059                         weapon_action(j, WR_RESETPLAYER);
1060
1061                         // all weapons must be fully loaded when we spawn
1062                         entity e;
1063                         e = get_weaponinfo(j);
1064                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1065                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1066                 }
1067
1068                 oldself = self;
1069                 self = spot;
1070                         activator = oldself;
1071                                 SUB_UseTargets();
1072                         activator = world;
1073                 self = oldself;
1074
1075                 MUTATOR_CALLHOOK(PlayerSpawn);
1076
1077                 self.switchweapon = w_getbestweapon(self);
1078                 self.cnt = self.switchweapon;
1079                 self.weapon = 0;
1080
1081                 if(!self.alivetime)
1082                         self.alivetime = time;
1083         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1084                 PutObserverInServer ();
1085         }
1086
1087         //if(g_ctf)
1088         //      ctf_playerchanged();
1089 }
1090
1091 .float ebouncefactor, ebouncestop; // electro's values
1092 // TODO do we need all these fields, or should we stop autodetecting runtime
1093 // changes and just have a console command to update this?
1094 float ClientInit_SendEntity(entity to, float sf)
1095 {
1096         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1097         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1100         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1110         if(sv_foginterval && world.fog != "")
1111                 WriteString(MSG_ENTITY, world.fog);
1112         else
1113                 WriteString(MSG_ENTITY, "");
1114         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1115         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1116         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1117         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1118         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1119         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1120         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1121         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1122         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1123         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1124         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1125         return TRUE;
1126 }
1127
1128 void ClientInit_CheckUpdate()
1129 {
1130         self.nextthink = time;
1131         if(self.count != autocvar_g_balance_armor_blockpercent)
1132         {
1133                 self.count = autocvar_g_balance_armor_blockpercent;
1134                 self.SendFlags |= 1;
1135         }
1136         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1137         {
1138                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1139                 self.SendFlags |= 1;
1140         }
1141         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1142         {
1143                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1144                 self.SendFlags |= 1;
1145         }
1146         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1147         {
1148                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1149                 self.SendFlags |= 1;
1150         }
1151         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1152         {
1153                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1154                 self.SendFlags |= 1;
1155         }
1156         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1157         {
1158                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1159                 self.SendFlags |= 1;
1160         }
1161 }
1162
1163 void ClientInit_Spawn()
1164 {
1165         entity o;
1166         entity e;
1167         e = spawn();
1168         e.classname = "clientinit";
1169         e.think = ClientInit_CheckUpdate;
1170         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1171
1172         o = self;
1173         self = e;
1174         ClientInit_CheckUpdate();
1175         self = o;
1176 }
1177
1178 /*
1179 =============
1180 SetNewParms
1181 =============
1182 */
1183 void SetNewParms (void)
1184 {
1185         // initialize parms for a new player
1186         parm1 = -(86400 * 366);
1187 }
1188
1189 /*
1190 =============
1191 SetChangeParms
1192 =============
1193 */
1194 void SetChangeParms (void)
1195 {
1196         // save parms for level change
1197         parm1 = self.parm_idlesince - time;
1198 }
1199
1200 /*
1201 =============
1202 DecodeLevelParms
1203 =============
1204 */
1205 void DecodeLevelParms (void)
1206 {
1207         // load parms
1208         self.parm_idlesince = parm1;
1209         if(self.parm_idlesince == -(86400 * 366))
1210                 self.parm_idlesince = time;
1211
1212         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1213         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1214 }
1215
1216 /*
1217 =============
1218 ClientKill
1219
1220 Called when a client types 'kill' in the console
1221 =============
1222 */
1223
1224 .float clientkill_nexttime;
1225 void ClientKill_Now_TeamChange()
1226 {
1227         if(self.killindicator_teamchange == -1)
1228         {
1229                 self.team = -1;
1230                 JoinBestTeam( self, FALSE, FALSE );
1231         }
1232         else if(self.killindicator_teamchange == -2)
1233         {
1234                 if(g_ca)
1235                         self.caplayer = 0;
1236                 if(blockSpectators)
1237                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1238                 PutObserverInServer();
1239         }
1240         else
1241                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1242 }
1243
1244 void ClientKill_Now()
1245 {
1246         remove(self.killindicator);
1247         self.killindicator = world;
1248
1249         if(self.killindicator_teamchange)
1250                 ClientKill_Now_TeamChange();
1251
1252         // in any case:
1253         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1254
1255         // now I am sure the player IS dead
1256 }
1257 void KillIndicator_Think()
1258 {
1259         if (!self.owner.modelindex)
1260         {
1261                 self.owner.killindicator = world;
1262                 remove(self);
1263                 return;
1264         }
1265
1266         if(self.cnt <= 0)
1267         {
1268                 self = self.owner;
1269                 ClientKill_Now(); // no oldself needed
1270                 return;
1271         }
1272     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1273     {
1274         self.nextthink = time + 1;
1275         self.cnt -= 1;
1276     }
1277         else
1278         {
1279                 if(self.cnt <= 10)
1280                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1281                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1282                 {
1283                         if(self.cnt <= 10)
1284                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1285                         if(self.owner.killindicator_teamchange)
1286                         {
1287                                 if(self.owner.killindicator_teamchange == -1)
1288                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1289                                 else if(self.owner.killindicator_teamchange == -2)
1290                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1291                                 else
1292                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1293                         }
1294                         else
1295                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1296                 }
1297                 self.nextthink = time + 1;
1298                 self.cnt -= 1;
1299         }
1300 }
1301
1302 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1303 {
1304         float killtime;
1305         entity e;
1306         killtime = autocvar_g_balance_kill_delay;
1307
1308         if(g_race_qualifying || g_cts)
1309                 killtime = 0;
1310
1311     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1312     {
1313                 remove(self.killindicator);
1314                 self.killindicator = world;
1315
1316         ClientKill_Now(); // allow instant kill in this case
1317         return;
1318     }
1319
1320         self.killindicator_teamchange = targetteam;
1321
1322     if(!self.killindicator)
1323         {
1324                 if(self.modelindex && self.deadflag == DEAD_NO)
1325                 {
1326                         killtime = max(killtime, self.clientkill_nexttime - time);
1327                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1328                 }
1329
1330                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1331                 {
1332                         ClientKill_Now();
1333                 }
1334                 else
1335                 {
1336                         self.killindicator = spawn();
1337                         self.killindicator.owner = self;
1338                         self.killindicator.scale = 0.5;
1339                         setattachment(self.killindicator, self, "");
1340                         setorigin(self.killindicator, '0 0 52');
1341                         self.killindicator.think = KillIndicator_Think;
1342                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1343                         self.killindicator.cnt = ceil(killtime);
1344                         self.killindicator.count = bound(0, ceil(killtime), 10);
1345                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1346
1347                         for(e = world; (e = find(e, classname, "body")) != world; )
1348                         {
1349                                 if(e.enemy != self)
1350                                         continue;
1351                                 e.killindicator = spawn();
1352                                 e.killindicator.owner = e;
1353                                 e.killindicator.scale = 0.5;
1354                                 setattachment(e.killindicator, e, "");
1355                                 setorigin(e.killindicator, '0 0 52');
1356                                 e.killindicator.think = KillIndicator_Think;
1357                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1358                                 e.killindicator.cnt = ceil(killtime);
1359                         }
1360                         self.lip = 0;
1361                 }
1362         }
1363         if(self.killindicator)
1364         {
1365                 if(targetteam == 0) // just die
1366                         self.killindicator.colormod = '0 0 0';
1367                 else if(targetteam == -1) // auto
1368                         self.killindicator.colormod = '0 1 0';
1369                 else if(targetteam == -2) // spectate
1370                         self.killindicator.colormod = '0.5 0.5 0.5';
1371                 else
1372                         self.killindicator.colormod = TeamColor(targetteam);
1373         }
1374 }
1375
1376 void ClientKill (void)
1377 {
1378         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1379         {
1380                 // do nothing
1381         }
1382     else if(self.freezetag_frozen)
1383     {
1384         // do nothing
1385     }
1386         else
1387                 ClientKill_TeamChange(0);
1388 }
1389
1390 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1391 {
1392     e.killindicator = spawn();
1393     e.killindicator.owner = e;
1394     e.killindicator.think = KillIndicator_Think;
1395     e.killindicator.nextthink = time + (e.lip) * 0.05;
1396     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1397     e.killindicator.health = 1; // this is used to indicate that it should be silent
1398     e.lip = 0;
1399 }
1400
1401 void DoTeamChange(float destteam)
1402 {
1403         float t, c0;
1404         if(!teams_matter)
1405         {
1406                 if(destteam >= 0)
1407                         SetPlayerColors(self, destteam);
1408                 return;
1409         }
1410         if(self.classname == "player")
1411         if(destteam == -1)
1412         {
1413                 CheckAllowedTeams(self);
1414                 t = FindSmallestTeam(self, TRUE);
1415                 switch(self.team)
1416                 {
1417                         case COLOR_TEAM1: c0 = c1; break;
1418                         case COLOR_TEAM2: c0 = c2; break;
1419                         case COLOR_TEAM3: c0 = c3; break;
1420                         case COLOR_TEAM4: c0 = c4; break;
1421                         default:          c0 = 999;
1422                 }
1423                 switch(t)
1424                 {
1425                         case 1:
1426                                 if(c0 > c1)
1427                                         destteam = COLOR_TEAM1;
1428                                 break;
1429                         case 2:
1430                                 if(c0 > c2)
1431                                         destteam = COLOR_TEAM2;
1432                                 break;
1433                         case 3:
1434                                 if(c0 > c3)
1435                                         destteam = COLOR_TEAM3;
1436                                 break;
1437                         case 4:
1438                                 if(c0 > c4)
1439                                         destteam = COLOR_TEAM4;
1440                                 break;
1441                 }
1442                 if(destteam == -1)
1443                         return;
1444         }
1445         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1446                 return;
1447         ClientKill_TeamChange(destteam);
1448 }
1449
1450 void FixClientCvars(entity e)
1451 {
1452         // send prediction settings to the client
1453         stuffcmd(e, "\nin_bindmap 0 0\n");
1454         if(g_race || g_cts)
1455                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1456         if(autocvar_g_antilag == 3) // client side hitscan
1457                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1458         if(sv_gentle)
1459                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1460         /*
1461          * we no longer need to stuff this. Remove this comment block if you feel
1462          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1463         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1464         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1465         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1466         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1467         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1468         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1469         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1470         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1471         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1472         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1473         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1474         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1475         stuffcmd(e, "cl_movement_edgefriction 1\n");
1476          */
1477 }
1478
1479 float PlayerInIDList(entity p, string idlist)
1480 {
1481         float n, i;
1482         string s;
1483
1484         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1485         if not(p.crypto_idfp)
1486                 return 0;
1487
1488         // this function allows abbreviated player IDs too!
1489         n = tokenize_console(idlist);
1490         for(i = 0; i < n; ++i)
1491         {
1492                 s = argv(i);
1493                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1494                         return 1;
1495         }
1496
1497         return 0;
1498 }
1499
1500 /*
1501 =============
1502 ClientConnect
1503
1504 Called when a client connects to the server
1505 =============
1506 */
1507 //void ctf_clientconnect();
1508 string ColoredTeamName(float t);
1509 void DecodeLevelParms (void);
1510 //void dom_player_join_team(entity pl);
1511 void set_dom_state(void);
1512 void ClientConnect (void)
1513 {
1514         float t;
1515
1516         if(self.flags & FL_CLIENT)
1517         {
1518                 print("Warning: ClientConnect, but already connected!\n");
1519                 return;
1520         }
1521
1522         if(Ban_MaybeEnforceBan(self))
1523                 return;
1524
1525         DecodeLevelParms();
1526
1527 #ifdef WATERMARK
1528         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1529 #endif
1530
1531         self.classname = "player_joining";
1532
1533         self.flags = FL_CLIENT;
1534         self.version_nagtime = time + 10 + random() * 10;
1535
1536         if(player_count<0)
1537         {
1538                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1539                 player_count = 0;
1540         }
1541
1542         PlayerScore_Attach(self);
1543         ClientData_Attach();
1544         accuracy_init(self);
1545
1546         bot_clientconnect();
1547
1548         playerdemo_init();
1549
1550         anticheat_init();
1551
1552         race_PreSpawnObserver();
1553
1554         //if(g_domination)
1555         //      dom_player_join_team(self);
1556
1557         // identify the right forced team
1558         if(autocvar_g_campaign)
1559         {
1560                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1561                 {
1562                         switch(autocvar_g_campaign_forceteam)
1563                         {
1564                                 case 1: self.team_forced = COLOR_TEAM1; break;
1565                                 case 2: self.team_forced = COLOR_TEAM2; break;
1566                                 case 3: self.team_forced = COLOR_TEAM3; break;
1567                                 case 4: self.team_forced = COLOR_TEAM4; break;
1568                                 default: self.team_forced = 0;
1569                         }
1570                 }
1571         }
1572         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1573                 self.team_forced = COLOR_TEAM1;
1574         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1575                 self.team_forced = COLOR_TEAM2;
1576         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1577                 self.team_forced = COLOR_TEAM3;
1578         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1579                 self.team_forced = COLOR_TEAM4;
1580         else if(autocvar_g_forced_team_otherwise == "red")
1581                 self.team_forced = COLOR_TEAM1;
1582         else if(autocvar_g_forced_team_otherwise == "blue")
1583                 self.team_forced = COLOR_TEAM2;
1584         else if(autocvar_g_forced_team_otherwise == "yellow")
1585                 self.team_forced = COLOR_TEAM3;
1586         else if(autocvar_g_forced_team_otherwise == "pink")
1587                 self.team_forced = COLOR_TEAM4;
1588         else if(autocvar_g_forced_team_otherwise == "spectate")
1589                 self.team_forced = -1;
1590         else if(autocvar_g_forced_team_otherwise == "spectator")
1591                 self.team_forced = -1;
1592         else
1593                 self.team_forced = 0;
1594
1595         if(!teams_matter)
1596                 if(self.team_forced > 0)
1597                         self.team_forced = 0;
1598
1599         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1600
1601         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1602                 self.classname = "observer";
1603         } else {
1604                 if(teams_matter)
1605                 {
1606                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1607                         {
1608                                 self.classname = "player";
1609                                 campaign_bots_may_start = 1;
1610                         }
1611                         else
1612                         {
1613                                 self.classname = "observer"; // do it anyway
1614                         }
1615                 }
1616                 else
1617                 {
1618                         self.classname = "player";
1619                         campaign_bots_may_start = 1;
1620                 }
1621         }
1622
1623         self.playerid = (playerid_last = playerid_last + 1);
1624
1625         if(autocvar_sv_eventlog)
1626                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1627
1628         LogTeamchange(self.playerid, self.team, 1);
1629
1630         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1631
1632         self.netname_previous = strzone(self.netname);
1633
1634         bprint("^4", self.netname, "^4 connected");
1635
1636         if(self.classname != "observer" && (g_domination || g_ctf))
1637                 bprint(" and joined the ", ColoredTeamName(self.team));
1638
1639         bprint("\n");
1640
1641         self.welcomemessage_time = 0;
1642
1643         stuffcmd(self, strcat(clientstuff, "\n"));
1644         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1645         stuffcmd(self, "cl_particles_reloadeffects\n");
1646
1647         FixClientCvars(self);
1648
1649         // spawnfunc_waypoint sprites
1650         WaypointSprite_InitClient(self);
1651
1652         // Wazat's grappling hook
1653         SetGrappleHookBindings();
1654
1655         // get autoswitch state from player when he toggles it
1656         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1657
1658         // get version info from player
1659         stuffcmd(self, "cmd clientversion $gameversion\n");
1660
1661         // get other cvars from player
1662         GetCvars(0);
1663
1664         // notify about available teams
1665         if(teams_matter)
1666         {
1667                 CheckAllowedTeams(self);
1668                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1669                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1670         }
1671         else
1672                 stuffcmd(self, "set _teams_available 0\n");
1673
1674         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1675
1676         if(g_arena || g_ca)
1677         {
1678                 self.classname = "observer";
1679                 if(g_arena)
1680                         Spawnqueue_Insert(self);
1681         }
1682         /*else if(g_ctf)
1683         {
1684                 ctf_clientconnect();
1685         }*/
1686
1687         if(teams_matter || radar_showennemies)
1688                 attach_entcs();
1689
1690         bot_relinkplayerlist();
1691
1692         self.spectatortime = time;
1693         if(blockSpectators)
1694         {
1695                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1696         }
1697
1698         self.jointime = time;
1699         self.allowedTimeouts = autocvar_sv_timeout_number;
1700
1701         if(clienttype(self) == CLIENTTYPE_REAL)
1702         {
1703                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1704                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1705         }
1706
1707         if(g_lms)
1708         {
1709                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1710                 {
1711                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1712                         self.frags = FRAGS_SPECTATOR;
1713                 }
1714         }
1715
1716         if(!sv_foginterval && world.fog != "")
1717                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1718
1719         SoundEntity_Attach(self);
1720
1721         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1722         {
1723                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1724                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1725         }
1726         else
1727                 self.hitplotfh = -1;
1728
1729         if(g_race || g_cts) {
1730                 string rr;
1731                 if(g_cts)
1732                         rr = CTS_RECORD;
1733                 else
1734                         rr = RACE_RECORD;
1735                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1736
1737                 msg_entity = self;
1738                 race_send_recordtime(MSG_ONE);
1739                 race_send_speedaward(MSG_ONE);
1740
1741                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1742                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1743                 race_send_speedaward_alltimebest(MSG_ONE);
1744
1745                 float i;
1746                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1747                         race_SendRankings(i, 0, 0, MSG_ONE);
1748                 }
1749         }
1750         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1751                 send_CSQC_teamnagger();
1752
1753         if (g_domination)
1754                 set_dom_state();
1755
1756         CheatInitClient();
1757
1758         PlayerStats_AddPlayer(self);
1759
1760     self.shownames = spawn();
1761     self.shownames.owner = self;
1762     self.shownames.think = shownames_think;
1763     self.shownames.nextthink = time;
1764     Net_LinkEntity(self.shownames, FALSE, 0, SendEntity_ShowNames);
1765 }
1766
1767 /*
1768 =============
1769 ClientDisconnect
1770
1771 Called when a client disconnects from the server
1772 =============
1773 */
1774 .entity chatbubbleentity;
1775 .entity teambubbleentity;
1776 void ReadyCount();
1777 void ClientDisconnect (void)
1778 {
1779         if not(self.flags & FL_CLIENT)
1780         {
1781                 print("Warning: ClientDisconnect without ClientConnect\n");
1782                 return;
1783         }
1784
1785         PlayerStats_AddGlobalInfo(self);
1786
1787         CheatShutdownClient();
1788
1789         if(self.hitplotfh >= 0)
1790         {
1791                 fclose(self.hitplotfh);
1792                 self.hitplotfh = -1;
1793         }
1794
1795         anticheat_report();
1796         anticheat_shutdown();
1797
1798         playerdemo_shutdown();
1799
1800         bot_clientdisconnect();
1801
1802         if(self.entcs)
1803                 detach_entcs();
1804
1805         if(autocvar_sv_eventlog)
1806                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1807         bprint ("^4",self.netname);
1808         bprint ("^4 disconnected\n");
1809
1810         SoundEntity_Detach(self);
1811
1812         DropAllRunes(self);
1813         MUTATOR_CALLHOOK(ClientDisconnect);
1814
1815         Portal_ClearAll(self);
1816
1817         if(self.flagcarried)
1818                 DropFlag(self.flagcarried, world, world);
1819         if(self.ballcarried && g_nexball)
1820                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1821
1822         // Here, everything has been done that requires this player to be a client.
1823
1824         self.flags &~= FL_CLIENT;
1825
1826         if (self.chatbubbleentity)
1827                 remove (self.chatbubbleentity);
1828
1829         if (self.teambubbleentity)
1830                 remove (self.teambubbleentity);
1831
1832         if (self.killindicator)
1833                 remove (self.killindicator);
1834
1835         WaypointSprite_PlayerGone();
1836
1837         bot_relinkplayerlist();
1838
1839         if(g_arena)
1840         {
1841                 Spawnqueue_Unmark(self);
1842                 Spawnqueue_Remove(self);
1843         }
1844
1845         accuracy_free(self);
1846         ClientData_Detach();
1847         PlayerScore_Detach(self);
1848
1849         if(self.netname_previous)
1850                 strunzone(self.netname_previous);
1851         if(self.clientstatus)
1852                 strunzone(self.clientstatus);
1853         if(self.weaponorder_byimpulse)
1854                 strunzone(self.weaponorder_byimpulse);
1855
1856         ClearPlayerSounds();
1857
1858         if(self.personal)
1859                 remove(self.personal);
1860
1861         self.playerid = 0;
1862         ReadyCount();
1863
1864     remove(self.shownames);
1865
1866         // free cvars
1867         GetCvars(-1);
1868 }
1869
1870 .float BUTTON_CHAT;
1871 void ChatBubbleThink()
1872 {
1873         self.nextthink = time;
1874         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1875         {
1876                 if(self.owner) // but why can that ever be world?
1877                         self.owner.chatbubbleentity = world;
1878                 remove(self);
1879                 return;
1880         }
1881         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1882 #ifdef TETRIS
1883                 || self.owner.tetris_on
1884 #endif
1885         )
1886                 self.model = self.mdl;
1887         else
1888                 self.model = "";
1889 };
1890
1891 void UpdateChatBubble()
1892 {
1893         if (!self.modelindex)
1894                 return;
1895         // spawn a chatbubble entity if needed
1896         if (!self.chatbubbleentity)
1897         {
1898                 self.chatbubbleentity = spawn();
1899                 self.chatbubbleentity.owner = self;
1900                 self.chatbubbleentity.exteriormodeltoclient = self;
1901                 self.chatbubbleentity.think = ChatBubbleThink;
1902                 self.chatbubbleentity.nextthink = time;
1903                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1904                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1905                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1906                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1907                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1908                 self.chatbubbleentity.model = "";
1909                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1910         }
1911 }
1912
1913
1914 void TeamBubbleThink()
1915 {
1916         self.nextthink = time;
1917         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1918         {
1919                 if(self.owner) // but why can that ever be world?
1920                         self.owner.teambubbleentity = world;
1921                 remove(self);
1922                 return;
1923         }
1924 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1925         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1926                 self.model = "";
1927         else
1928                 self.model = self.mdl;
1929
1930 };
1931
1932 float TeamBubble_customizeentityforclient()
1933 {
1934         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1935 }
1936
1937 void UpdateTeamBubble()
1938 {
1939         if (!self.modelindex || !teams_matter)
1940                 return;
1941         // spawn a teambubble entity if needed
1942         if (!self.teambubbleentity && teams_matter)
1943         {
1944                 self.teambubbleentity = spawn();
1945                 self.teambubbleentity.owner = self;
1946                 self.teambubbleentity.exteriormodeltoclient = self;
1947                 self.teambubbleentity.think = TeamBubbleThink;
1948                 self.teambubbleentity.nextthink = time;
1949                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1950 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1951                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1952                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1953                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1954                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1955                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1956                 self.teambubbleentity.effects = EF_LOWPRECISION;
1957         }
1958 }
1959
1960 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1961 // added to the model skins
1962 /*void UpdateColorModHack()
1963 {
1964         local float c;
1965         c = self.clientcolors & 15;
1966         // LordHavoc: only bothering to support white, green, red, yellow, blue
1967              if (!teams_matter) self.colormod = '0 0 0';
1968         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1969         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1970         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1971         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1972         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1973         else self.colormod = '1 1 1';
1974 };*/
1975
1976 .float oldcolormap;
1977 void respawn(void)
1978 {
1979         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1980         {
1981                 self.solid = SOLID_NOT;
1982                 self.takedamage = DAMAGE_NO;
1983                 self.movetype = MOVETYPE_FLY;
1984                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1985                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1986                 self.effects |= EF_ADDITIVE;
1987                 self.oldcolormap = self.colormap;
1988                 self.colormap = 512;
1989                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1990                 if(autocvar_g_respawn_ghosts_maxtime)
1991                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1992         }
1993
1994         CopyBody(1);
1995         self.effects |= EF_NODRAW; // prevent another CopyBody
1996         if(self.oldcolormap)
1997         {
1998                 self.colormap = self.oldcolormap;
1999                 self.oldcolormap = 0;
2000         }
2001         PutClientInServer();
2002 }
2003
2004 void play_countdown(float finished, string samp)
2005 {
2006         if(clienttype(self) == CLIENTTYPE_REAL)
2007                 if(floor(finished - time - frametime) != floor(finished - time))
2008                         if(finished - time < 6)
2009                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
2010 }
2011
2012 /**
2013  * When sv_timeout is used this function returs strings like
2014  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
2015  * Called by centerprint functions
2016  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
2017  */
2018 string getTimeoutText(float addOneSecond) {
2019         if (!autocvar_sv_timeout || !timeoutStatus)
2020                 return "";
2021
2022         local string retStr;
2023         if (timeoutStatus == 1) {
2024                 if (addOneSecond == 1) {
2025                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2026                 }
2027                 else {
2028                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2029                 }
2030                 return retStr;
2031         }
2032         else if (timeoutStatus == 2) {
2033                 if (addOneSecond) {
2034                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2035                         //don't show messages like "Timeout ends in 0 seconds"...
2036                         if ((remainingTimeoutTime + 1) > 0)
2037                                 return retStr;
2038                         else
2039                                 return "";
2040                 }
2041                 else {
2042                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2043                         //don't show messages like "Timeout ends in 0 seconds"...
2044                         if (remainingTimeoutTime > 0)
2045                                 return retStr;
2046                         else
2047                                 return "";
2048                 }
2049         }
2050         else return "";
2051 }
2052
2053 void player_powerups (void)
2054 {
2055         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2056         olditems = self.items;
2057
2058         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2059         {
2060                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2061                 self.modelflags |= MF_ROCKET;
2062         }
2063         else
2064         {
2065                 SoundEntity_StopSound(self, CHAN_PLAYER);
2066                 self.modelflags &~= MF_ROCKET;
2067         }
2068
2069         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2070
2071         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2072                 return;
2073
2074         Fire_ApplyDamage(self);
2075         Fire_ApplyEffect(self);
2076
2077         if (g_minstagib)
2078         {
2079                 self.effects |= EF_FULLBRIGHT;
2080
2081                 if (self.items & IT_STRENGTH)
2082                 {
2083                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2084                         if (time > self.strength_finished)
2085                         {
2086                                 self.alpha = default_player_alpha;
2087                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2088                                 self.items &~= IT_STRENGTH;
2089                                 sprint(self, "^3Invisibility has worn off\n");
2090                         }
2091                 }
2092                 else
2093                 {
2094                         if (time < self.strength_finished)
2095                         {
2096                                 self.alpha = g_minstagib_invis_alpha;
2097                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2098                                 self.items |= IT_STRENGTH;
2099                                 sprint(self, "^3You are invisible\n");
2100                         }
2101                 }
2102
2103                 if (self.items & IT_INVINCIBLE)
2104                 {
2105                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2106                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2107                         {
2108                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2109                                 sprint(self, "^3Speed has worn off\n");
2110                         }
2111                 }
2112                 else
2113                 {
2114                         if (time < self.invincible_finished)
2115                         {
2116                                 self.items = self.items | IT_INVINCIBLE;
2117                                 sprint(self, "^3You are on speed\n");
2118                         }
2119                 }
2120         }
2121         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2122         {
2123                 if (self.items & IT_STRENGTH)
2124                 {
2125                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2126                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2127                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2128                         {
2129                                 self.items = self.items - (self.items & IT_STRENGTH);
2130                                 sprint(self, "^3Strength has worn off\n");
2131                         }
2132                 }
2133                 else
2134                 {
2135                         if (time < self.strength_finished)
2136                         {
2137                                 self.items = self.items | IT_STRENGTH;
2138                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2139                         }
2140                 }
2141                 if (self.items & IT_INVINCIBLE)
2142                 {
2143                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2144                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2145                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2146                         {
2147                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2148                                 sprint(self, "^3Shield has worn off\n");
2149                         }
2150                 }
2151                 else
2152                 {
2153                         if (time < self.invincible_finished)
2154                         {
2155                                 self.items = self.items | IT_INVINCIBLE;
2156                                 sprint(self, "^3Shield surrounds you\n");
2157                         }
2158                 }
2159
2160                 if(autocvar_g_nodepthtestplayers)
2161                         self.effects = self.effects | EF_NODEPTHTEST;
2162
2163                 if(autocvar_g_fullbrightplayers)
2164                         self.effects = self.effects | EF_FULLBRIGHT;
2165
2166                 // midair gamemode: damage only while in the air
2167                 // if in midair mode, being on ground grants temporary invulnerability
2168                 // (this is so that multishot weapon don't clear the ground flag on the
2169                 // first damage in the frame, leaving the player vulnerable to the
2170                 // remaining hits in the same frame)
2171                 if (self.flags & FL_ONGROUND)
2172                 if (g_midair)
2173                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2174
2175                 if (time >= game_starttime)
2176                 if (time < self.spawnshieldtime)
2177                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2178         }
2179
2180         MUTATOR_CALLHOOK(PlayerPowerups);
2181 }
2182
2183 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2184 {
2185         if(current > stable)
2186                 return current;
2187         else if(current > stable - 0.25) // when close enough, "snap"
2188                 return stable;
2189         else
2190                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2191 }
2192
2193 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2194 {
2195         if(current < stable)
2196                 return current;
2197         else if(current < stable + 0.25) // when close enough, "snap"
2198                 return stable;
2199         else
2200                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2201 }
2202
2203 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2204 {
2205         if(current > rotstable)
2206         {
2207                 if(rotframetime > 0)
2208                 {
2209                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2210                         current = max(rotstable, current - rotlinear * rotframetime);
2211                 }
2212         }
2213         else if(current < regenstable)
2214         {
2215                 if(regenframetime > 0)
2216                 {
2217                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2218                         current = min(regenstable, current + regenlinear * regenframetime);
2219                 }
2220         }
2221
2222         if(current > limit)
2223                 current = limit;
2224
2225         return current;
2226 }
2227
2228 void player_regen (void)
2229 {
2230         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2231         maxh = autocvar_g_balance_health_rotstable;
2232         maxa = autocvar_g_balance_armor_rotstable;
2233         maxf = autocvar_g_balance_fuel_rotstable;
2234         minh = autocvar_g_balance_health_regenstable;
2235         mina = autocvar_g_balance_armor_regenstable;
2236         minf = autocvar_g_balance_fuel_regenstable;
2237         limith = autocvar_g_balance_health_limit;
2238         limita = autocvar_g_balance_armor_limit;
2239         limitf = autocvar_g_balance_fuel_limit;
2240
2241         max_mod = regen_mod = rot_mod = limit_mod = 1;
2242
2243         if (self.runes & RUNE_REGEN)
2244         {
2245                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2246                 {
2247                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2248                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2249                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2250                 }
2251                 else
2252                 {
2253                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2254                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2255                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2256                 }
2257         }
2258         else if (self.runes & CURSE_VENOM)
2259         {
2260                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2261                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2262                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2263                 else
2264                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2265                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2266                 //if (!self.runes & RUNE_REGEN)
2267                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2268         }
2269         maxh = maxh * max_mod;
2270         //maxa = maxa * max_mod;
2271         //maxf = maxf * max_mod;
2272         minh = minh * max_mod;
2273         //mina = mina * max_mod;
2274         //minf = minf * max_mod;
2275         limith = limith * limit_mod;
2276         limita = limita * limit_mod;
2277         //limitf = limitf * limit_mod;
2278
2279         if(g_lms && g_ca)
2280                 rot_mod = 0;
2281
2282         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2283         {
2284                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2285                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2286
2287                 // if player rotted to death...  die!
2288                 if(self.health < 1)
2289                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2290         }
2291
2292         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2293                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2294 }
2295
2296 float zoomstate_set;
2297 void SetZoomState(float z)
2298 {
2299         if(z != self.zoomstate)
2300         {
2301                 self.zoomstate = z;
2302                 ClientData_Touch(self);
2303         }
2304         zoomstate_set = 1;
2305 }
2306
2307 void GetPressedKeys(void) {
2308         MUTATOR_CALLHOOK(GetPressedKeys);
2309         if (self.movement_x > 0) // get if movement keys are pressed
2310         {       // forward key pressed
2311                 self.pressedkeys |= KEY_FORWARD;
2312                 self.pressedkeys &~= KEY_BACKWARD;
2313         }
2314         else if (self.movement_x < 0)
2315         {       // backward key pressed
2316                 self.pressedkeys |= KEY_BACKWARD;
2317                 self.pressedkeys &~= KEY_FORWARD;
2318         }
2319         else
2320         {       // no x input
2321                 self.pressedkeys &~= KEY_FORWARD;
2322                 self.pressedkeys &~= KEY_BACKWARD;
2323         }
2324
2325         if (self.movement_y > 0)
2326         {       // right key pressed
2327                 self.pressedkeys |= KEY_RIGHT;
2328                 self.pressedkeys &~= KEY_LEFT;
2329         }
2330         else if (self.movement_y < 0)
2331         {       // left key pressed
2332                 self.pressedkeys |= KEY_LEFT;
2333                 self.pressedkeys &~= KEY_RIGHT;
2334         }
2335         else
2336         {       // no y input
2337                 self.pressedkeys &~= KEY_RIGHT;
2338                 self.pressedkeys &~= KEY_LEFT;
2339         }
2340
2341         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2342                 self.pressedkeys |= KEY_JUMP;
2343         else
2344                 self.pressedkeys &~= KEY_JUMP;
2345         if (self.BUTTON_CROUCH)
2346                 self.pressedkeys |= KEY_CROUCH;
2347         else
2348                 self.pressedkeys &~= KEY_CROUCH;
2349 }
2350
2351 /*
2352 ======================
2353 spectate mode routines
2354 ======================
2355 */
2356
2357 void SpectateCopy(entity spectatee) {
2358         other = spectatee;
2359         MUTATOR_CALLHOOK(SpectateCopy);
2360         self.armortype = spectatee.armortype;
2361         self.armorvalue = spectatee.armorvalue;
2362         self.ammo_cells = spectatee.ammo_cells;
2363         self.ammo_shells = spectatee.ammo_shells;
2364         self.ammo_nails = spectatee.ammo_nails;
2365         self.ammo_rockets = spectatee.ammo_rockets;
2366         self.ammo_fuel = spectatee.ammo_fuel;
2367         self.clip_load = spectatee.clip_load;
2368         self.clip_size = spectatee.clip_size;
2369         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2370         self.health = spectatee.health;
2371         self.impulse = 0;
2372         self.items = spectatee.items;
2373         self.last_pickup = spectatee.last_pickup;
2374         self.hit_time = spectatee.hit_time;
2375         self.metertime = spectatee.metertime;
2376         self.strength_finished = spectatee.strength_finished;
2377         self.invincible_finished = spectatee.invincible_finished;
2378         self.pressedkeys = spectatee.pressedkeys;
2379         self.weapons = spectatee.weapons;
2380         self.switchweapon = spectatee.switchweapon;
2381         self.weapon = spectatee.weapon;
2382         self.nex_charge = spectatee.nex_charge;
2383         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2384         self.minelayer_mines = spectatee.minelayer_mines;
2385         self.punchangle = spectatee.punchangle;
2386         self.view_ofs = spectatee.view_ofs;
2387         self.v_angle = spectatee.v_angle;
2388         self.velocity = spectatee.velocity;
2389         self.dmg_take = spectatee.dmg_take;
2390         self.dmg_save = spectatee.dmg_save;
2391         self.dmg_inflictor = spectatee.dmg_inflictor;
2392         self.angles = spectatee.v_angle;
2393         self.fixangle = TRUE;
2394         setorigin(self, spectatee.origin);
2395         setsize(self, spectatee.mins, spectatee.maxs);
2396         SetZoomState(spectatee.zoomstate);
2397
2398         anticheat_spectatecopy(spectatee);
2399 }
2400
2401 float SpectateUpdate() {
2402         if(!self.enemy)
2403                 return 0;
2404
2405         if (self == self.enemy)
2406                 return 0;
2407
2408         if(self.enemy.classname != "player")
2409                 return 0;
2410
2411         SpectateCopy(self.enemy);
2412
2413         return 1;
2414 }
2415
2416 float SpectateNext() {
2417         other = find(self.enemy, classname, "player");
2418
2419         if (!other)
2420                 other = find(other, classname, "player");
2421
2422         if (other)
2423                 self.enemy = other;
2424
2425         if(self.enemy.classname == "player") {
2426                 msg_entity = self;
2427                 WriteByte(MSG_ONE, SVC_SETVIEW);
2428                 WriteEntity(MSG_ONE, self.enemy);
2429                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2430                 self.movetype = MOVETYPE_NONE;
2431                 accuracy_resend(self);
2432
2433                 if(!SpectateUpdate())
2434                         PutObserverInServer();
2435
2436                 return 1;
2437         } else {
2438                 return 0;
2439         }
2440 }
2441
2442 /*
2443 =============
2444 ShowRespawnCountdown()
2445
2446 Update a respawn countdown display.
2447 =============
2448 */
2449 void ShowRespawnCountdown()
2450 {
2451         float number;
2452         if(self.deadflag == DEAD_NO) // just respawned?
2453                 return;
2454         else
2455         {
2456                 number = ceil(self.death_time - time);
2457                 if(number <= 0)
2458                         return;
2459                 if(number <= self.respawn_countdown)
2460                 {
2461                         self.respawn_countdown = number - 1;
2462                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2463                                 AnnounceTo(self, strcat(ftos(number), ""));
2464                 }
2465         }
2466 }
2467
2468 void LeaveSpectatorMode()
2469 {
2470         if(nJoinAllowed(1)) {
2471                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2472                         self.classname = "player";
2473
2474                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2475                                 JoinBestTeam(self, FALSE, TRUE);
2476
2477                         if(autocvar_g_campaign)
2478                                 campaign_bots_may_start = 1;
2479
2480                         PutClientInServer();
2481
2482                         if(self.classname == "player")
2483                                 bprint ("^4", self.netname, "^4 is playing now\n");
2484
2485                         if(!autocvar_g_campaign)
2486                                 centerprint(self,""); // clear MOTD
2487
2488                         return;
2489                 } else {
2490                         if (g_ca && self.caplayer) {
2491                         }       // do nothing
2492                         else
2493                                 stuffcmd(self,"menu_showteamselect\n");
2494                         return;
2495                 }
2496         }
2497         else {
2498                 //player may not join because of g_maxplayers is set
2499                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2500         }
2501 }
2502
2503 /**
2504  * Determines whether the player is allowed to join. This depends on cvar
2505  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2506  * it checks whether the number of currently playing players exceeds g_maxplayers.
2507  * @return int number of free slots for players, 0 if none
2508  */
2509 float nJoinAllowed(float includeMe) {
2510         if(self.team_forced < 0)
2511                 return FALSE; // forced spectators can never join
2512
2513         // TODO simplify this
2514         local entity e;
2515
2516         local float totalClients;
2517         FOR_EACH_CLIENT(e)
2518                 totalClients += 1;
2519
2520         if (!autocvar_g_maxplayers)
2521                 return maxclients - totalClients + includeMe;
2522
2523         local float currentlyPlaying;
2524         FOR_EACH_REALPLAYER(e)
2525                 currentlyPlaying += 1;
2526
2527         if(currentlyPlaying < autocvar_g_maxplayers)
2528                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2529
2530         return 0;
2531 }
2532
2533 /**
2534  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2535  * g_maxplayers_spectator_blocktime seconds
2536  */
2537 void checkSpectatorBlock() {
2538         if(self.classname == "spectator" || self.classname == "observer") {
2539                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2540                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2541                         dropclient(self);
2542                 }
2543         }
2544 }
2545
2546 void ObserverThink()
2547 {
2548         if (self.flags & FL_JUMPRELEASED) {
2549                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2550                         self.welcomemessage_time = 0;
2551                         self.flags &~= FL_JUMPRELEASED;
2552                         self.flags |= FL_SPAWNING;
2553                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2554                         self.welcomemessage_time = 0;
2555                         self.flags &~= FL_JUMPRELEASED;
2556                         if(SpectateNext() == 1) {
2557                                 self.classname = "spectator";
2558                         }
2559                 }
2560         } else {
2561                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2562                         self.flags |= FL_JUMPRELEASED;
2563                         if(self.flags & FL_SPAWNING)
2564                         {
2565                                 self.flags &~= FL_SPAWNING;
2566                                 LeaveSpectatorMode();
2567                                 return;
2568                         }
2569                 }
2570         }
2571         PrintWelcomeMessage(self);
2572 }
2573
2574 void SpectatorThink()
2575 {
2576         if (self.flags & FL_JUMPRELEASED) {
2577                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2578                         self.welcomemessage_time = 0;
2579                         self.flags &~= FL_JUMPRELEASED;
2580                         self.flags |= FL_SPAWNING;
2581                 } else if(self.BUTTON_ATCK) {
2582                         self.welcomemessage_time = 0;
2583                         self.flags &~= FL_JUMPRELEASED;
2584                         if(SpectateNext() == 1) {
2585                                 self.classname = "spectator";
2586                         } else {
2587                                 self.classname = "observer";
2588                                 PutClientInServer();
2589                         }
2590                 } else if (self.BUTTON_ATCK2) {
2591                         self.welcomemessage_time = 0;
2592                         self.flags &~= FL_JUMPRELEASED;
2593                         self.classname = "observer";
2594                         PutClientInServer();
2595                 } else {
2596                         if(!SpectateUpdate())
2597                                 PutObserverInServer();
2598                 }
2599         } else {
2600                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2601                         self.flags |= FL_JUMPRELEASED;
2602                         if(self.flags & FL_SPAWNING)
2603                         {
2604                                 self.flags &~= FL_SPAWNING;
2605                                 LeaveSpectatorMode();
2606                                 return;
2607                         }
2608                 }
2609         }
2610
2611         PrintWelcomeMessage(self);
2612         self.flags |= FL_CLIENT | FL_NOTARGET;
2613 }
2614
2615 .float touchexplode_time;
2616
2617 /*
2618 =============
2619 PlayerPreThink
2620
2621 Called every frame for each client before the physics are run
2622 =============
2623 */
2624 void() ctf_setstatus;
2625 void() nexball_setstatus;
2626 .float items_added;
2627 void PlayerPreThink (void)
2628 {
2629         self.stat_game_starttime = game_starttime;
2630         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2631         self.stat_leadlimit = autocvar_leadlimit;
2632
2633         if(frametime)
2634         {
2635                 // physics frames: update anticheat stuff
2636                 anticheat_prethink();
2637         }
2638
2639         if(blockSpectators && frametime)
2640                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2641                 checkSpectatorBlock();
2642
2643         zoomstate_set = 0;
2644
2645         if(self.netname_previous != self.netname)
2646         {
2647                 if(autocvar_sv_eventlog)
2648                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2649                 if(self.netname_previous)
2650                         strunzone(self.netname_previous);
2651                 self.netname_previous = strzone(self.netname);
2652         }
2653
2654         // version nagging
2655         if(self.version_nagtime)
2656                 if(self.cvar_g_xonoticversion)
2657                         if(time > self.version_nagtime)
2658                         {
2659                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2660                                 {
2661                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2662                                         {
2663                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2664                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2665                                         }
2666                                         else
2667                                         {
2668                                                 float r;
2669                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2670                                                 if(r < 0)
2671                                                 {
2672                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2673                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2674                                                 }
2675                                                 else if(r > 0)
2676                                                 {
2677                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2678                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2679                                                 }
2680                                         }
2681                                 }
2682                                 self.version_nagtime = 0;
2683                         }
2684
2685         // GOD MODE info
2686         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2687         {
2688                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2689                 self.max_armorvalue = 0;
2690         }
2691
2692 #ifdef TETRIS
2693         if (TetrisPreFrame())
2694                 return;
2695 #endif
2696
2697         MUTATOR_CALLHOOK(PlayerPreThink);
2698
2699         if(self.classname == "player") {
2700 //              if(self.netname == "Wazat")
2701 //                      bprint(self.classname, "\n");
2702
2703                 CheckRules_Player();
2704
2705                 PrintWelcomeMessage(self);
2706
2707                 if (intermission_running)
2708                 {
2709                         IntermissionThink ();   // otherwise a button could be missed between
2710                         return;                                 // the think tics
2711                 }
2712
2713                 if(self.teleport_time)
2714                 if(time > self.teleport_time)
2715                 {
2716                         self.teleport_time = 0;
2717                         self.effects = self.effects - (self.effects & EF_NODRAW);
2718                 }
2719
2720                 //don't allow the player to turn around while game is paused!
2721                 if(timeoutStatus == 2) {
2722                         self.v_angle = self.lastV_angle;
2723                         self.angles = self.lastV_angle;
2724                         self.fixangle = TRUE;
2725                 }
2726
2727                 if(frametime)
2728                 {
2729                         if(self.health <= 0 && autocvar_g_deathglow)
2730                         {
2731                                 if(self.glowmod_x > 0)
2732                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2733                                 else
2734                                         self.glowmod_x = -1;
2735                                 if(self.glowmod_y > 0)
2736                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2737                                 else
2738                                         self.glowmod_y = -1;
2739                                 if(self.glowmod_z > 0)
2740                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2741                                 else
2742                                         self.glowmod_z = -1;
2743                         }
2744                         else
2745                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2746                         player_powerups();
2747                 }
2748
2749                 if (self.deadflag != DEAD_NO)
2750                 {
2751                         float button_pressed, force_respawn;
2752                         if(self.personal && g_race_qualifying)
2753                         {
2754                                 if(time > self.death_time)
2755                                 {
2756                                         self.death_time = time + 1; // only retry once a second
2757                                         respawn();
2758                                         self.impulse = 141;
2759                                 }
2760                         }
2761                         else
2762                         {
2763                                 if(frametime)
2764                                         player_anim();
2765                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2766                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2767                                 if (self.deadflag == DEAD_DYING)
2768                                 {
2769                                         if(force_respawn)
2770                                                 self.deadflag = DEAD_RESPAWNING;
2771                                         else if(!button_pressed)
2772                                                 self.deadflag = DEAD_DEAD;
2773                                 }
2774                                 else if (self.deadflag == DEAD_DEAD)
2775                                 {
2776                                         if(button_pressed)
2777                                                 self.deadflag = DEAD_RESPAWNABLE;
2778                                 }
2779                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2780                                 {
2781                                         if(!button_pressed)
2782                                                 self.deadflag = DEAD_RESPAWNING;
2783                                 }
2784                                 else if (self.deadflag == DEAD_RESPAWNING)
2785                                 {
2786                                         if(time > self.death_time)
2787                                         {
2788                                                 self.death_time = time + 1; // only retry once a second
2789                                                 respawn();
2790                                         }
2791                                 }
2792                                 ShowRespawnCountdown();
2793                         }
2794                         return;
2795                 }
2796
2797                 if(g_touchexplode)
2798                 if(time > self.touchexplode_time)
2799                 if(self.classname == "player")
2800                 if(self.deadflag == DEAD_NO)
2801                 if not(IS_INDEPENDENT_PLAYER(self))
2802                 FOR_EACH_PLAYER(other) if(self != other)
2803                 {
2804                         if(time > other.touchexplode_time)
2805                         if(other.deadflag == DEAD_NO)
2806                         if not(IS_INDEPENDENT_PLAYER(other))
2807                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2808                         {
2809                                 PlayerTouchExplode(self, other);
2810                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2811                         }
2812                 }
2813
2814                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2815                 {
2816                         vector dist;
2817
2818                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2819                         dist = self.prevorigin - self.origin;
2820                         dist_z = 0;
2821                         self.lms_traveled_distance += fabs(vlen(dist));
2822
2823                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2824                         {
2825                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2826                                 self.lms_traveled_distance = 0;
2827                         }
2828
2829                         if(time > self.lms_nextcheck)
2830                         {
2831                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2832                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2833                                 {
2834                                         centerprint(self, autocvar_g_lms_campcheck_message);
2835                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2836                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2837                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2838                                 }
2839                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2840                                 self.lms_traveled_distance = 0;
2841                         }
2842                 }
2843
2844                 self.prevorigin = self.origin;
2845
2846                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2847                 {
2848                         if (!self.crouch)
2849                         {
2850                                 self.crouch = TRUE;
2851                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2852                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2853                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2854                         }
2855                 }
2856                 else
2857                 {
2858                         if (self.crouch)
2859                         {
2860                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2861                                 if (!trace_startsolid)
2862                                 {
2863                                         self.crouch = FALSE;
2864                                         self.view_ofs = PL_VIEW_OFS;
2865                                         setsize (self, PL_MIN, PL_MAX);
2866                                 }
2867                         }
2868                 }
2869
2870                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2871                 {
2872                         if(self.bloodloss_timer < time)
2873                         {
2874                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2875                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2876                         }
2877                 }
2878
2879                 FixPlayermodel();
2880
2881                 GrapplingHookFrame();
2882
2883                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2884                 //if(frametime)
2885                 {
2886                         self.items &~= self.items_added;
2887
2888                         W_WeaponFrame();
2889
2890                         self.items_added = 0;
2891                         if(self.items & IT_JETPACK)
2892                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2893                                         self.items_added |= IT_FUEL;
2894
2895                         self.items |= self.items_added;
2896                 }
2897
2898                 player_regen();
2899
2900                 // rot nex charge to the charge limit
2901                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2902                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2903
2904                 if(frametime)
2905                         player_anim();
2906
2907                 if (g_minstagib)
2908                         minstagib_ammocheck();
2909
2910                 if(g_ctf)
2911                         ctf_setstatus();
2912
2913                 if(g_nexball)
2914                         nexball_setstatus();
2915
2916                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2917
2918                 //self.angles_y=self.v_angle_y + 90;   // temp
2919         } else if(gameover) {
2920                 if (intermission_running)
2921                         IntermissionThink ();   // otherwise a button could be missed between
2922                 return;
2923         } else if(self.classname == "observer") {
2924                 ObserverThink();
2925         } else if(self.classname == "spectator") {
2926                 SpectatorThink();
2927         }
2928
2929         if(!zoomstate_set)
2930                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2931
2932         float oldspectatee_status;
2933         oldspectatee_status = self.spectatee_status;
2934         if(self.classname == "spectator")
2935                 self.spectatee_status = num_for_edict(self.enemy);
2936         else if(self.classname == "observer")
2937                 self.spectatee_status = num_for_edict(self);
2938         else
2939                 self.spectatee_status = 0;
2940         if(self.spectatee_status != oldspectatee_status)
2941         {
2942                 ClientData_Touch(self);
2943                 if(g_race || g_cts)
2944                         race_InitSpectator();
2945         }
2946
2947         if(self.teamkill_soundtime)
2948         if(time > self.teamkill_soundtime)
2949         {
2950                 self.teamkill_soundtime = 0;
2951
2952                 entity oldpusher, oldself;
2953
2954                 oldself = self; self = self.teamkill_soundsource;
2955                 oldpusher = self.pusher; self.pusher = oldself;
2956
2957                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2958
2959                 self.pusher = oldpusher;
2960                 self = oldself;
2961         }
2962
2963         if(self.taunt_soundtime)
2964         if(time > self.taunt_soundtime)
2965         {
2966                 self.taunt_soundtime = 0;
2967                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2968         }
2969
2970         target_voicescript_next(self);
2971
2972         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2973         if(!self.weapon)
2974                 self.clip_load = self.clip_size = 0;
2975 }
2976
2977 float isInvisibleString(string s)
2978 {
2979         float i, n, c;
2980         s = strdecolorize(s);
2981         for((i = 0), (n = strlen(s)); i < n; ++i)
2982         {
2983                 c = str2chr(s, i);
2984                 switch(c)
2985                 {
2986                         case 0:
2987                         case 32: // space
2988                                 break;
2989                         case 192: // charmap space
2990                                 if (!autocvar_utf8_enable)
2991                                         break;
2992                                 return FALSE;
2993                         case 160: // space in unicode fonts
2994                         case 0xE000 + 192: // utf8 charmap space
2995                                 if (autocvar_utf8_enable)
2996                                         break;
2997                         default:
2998                                 return FALSE;
2999                 }
3000         }
3001         return TRUE;
3002 }
3003
3004 /*
3005 =============
3006 PlayerPostThink
3007
3008 Called every frame for each client after the physics are run
3009 =============
3010 */
3011 .float idlekick_lasttimeleft;
3012 .entity showheadshotbbox;
3013 void showheadshotbbox_think()
3014 {
3015         if(self.owner.showheadshotbbox != self)
3016         {
3017                 remove(self);
3018                 return;
3019         }
3020         self.nextthink = time;
3021         setorigin(self, self.owner.origin);
3022         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3023 }
3024 void PlayerPostThink (void)
3025 {
3026         // Savage: Check for nameless players
3027         if (isInvisibleString(self.netname)) {
3028                 self.netname = "Player";
3029                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3030         }
3031
3032         if(sv_maxidle && frametime)
3033         {
3034                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3035                 float timeleft;
3036                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3037                 if(timeleft <= 0)
3038                 {
3039                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3040                         AnnounceTo(self, "terminated");
3041                         dropclient(self);
3042                         return;
3043                 }
3044                 else if(timeleft <= 10)
3045                 {
3046                         if(timeleft != self.idlekick_lasttimeleft)
3047                         {
3048                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3049                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3050                         }
3051                 }
3052                 else
3053                 {
3054                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3055                 }
3056                 self.idlekick_lasttimeleft = timeleft;
3057         }
3058
3059 #ifdef TETRIS
3060         if(self.impulse == 100)
3061                 ImpulseCommands();
3062         if (TetrisPostFrame())
3063                 return;
3064 #endif
3065
3066         CheatFrame();
3067
3068         if(self.classname == "player") {
3069                 CheckRules_Player();
3070                 UpdateChatBubble();
3071                 UpdateTeamBubble();
3072                 if (self.impulse)
3073                         ImpulseCommands();
3074                 if (intermission_running)
3075                         return;         // intermission or finale
3076                 GetPressedKeys();
3077         } else if (self.classname == "observer") {
3078                 //do nothing
3079         } else if (self.classname == "spectator") {
3080                 //do nothing
3081         }
3082
3083         /*
3084         float i;
3085         for(i = 0; i < 1000; ++i)
3086         {
3087                 vector end;
3088                 end = self.origin + '0 0 1024' + 512 * randomvec();
3089                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3090                 if(trace_fraction < 1)
3091                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3092                 {
3093                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3094                         break;
3095                 }
3096         }
3097         */
3098
3099         Arena_Warmup();
3100
3101         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3102
3103         if(self.waypointsprite_attachedforcarrier)
3104                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3105
3106         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3107         {
3108                 if(!self.showheadshotbbox)
3109                 {
3110                         self.showheadshotbbox = spawn();
3111                         self.showheadshotbbox.classname = "headshotbbox";
3112                         self.showheadshotbbox.owner = self;
3113                         self.showheadshotbbox.think = showheadshotbbox_think;
3114                         self.showheadshotbbox.nextthink = time;
3115                         self = self.showheadshotbbox;
3116                         self.think();
3117                         self = self.owner;
3118                 }
3119         }
3120         else
3121         {
3122                 if(self.showheadshotbbox)
3123                         remove(self.showheadshotbbox);
3124         }
3125
3126         playerdemo_write();
3127
3128         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3129         {
3130                 if(!self.stored_netname)
3131                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3132                 if(self.stored_netname != self.netname)
3133                 {
3134                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3135                         strunzone(self.stored_netname);
3136                         self.stored_netname = strzone(self.netname);
3137                 }
3138         }
3139
3140         /*
3141         if(g_race)
3142                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3143         */
3144 }