qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > autocvar_g_spawn_furthest)
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(autocvar_spawn_debugview)
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(autocvar_spawn_debug)
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(autocvar_sv_servermodelsonly)
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595         MUTATOR_CALLHOOK(MakePlayerObserver);
 596
 597         Portal_ClearAll(self);
 598
 599         if(self.alivetime)
 600         {
 601                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 602                 self.alivetime = 0;
 603         }
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried && g_nexball)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         accuracy_resend(self);
 634
 635         self.spectatortime = time;
 636
 637         self.classname = "observer";
 638         self.iscreature = FALSE;
 639         self.health = -666;
 640         self.takedamage = DAMAGE_NO;
 641         self.solid = SOLID_NOT;
 642         self.movetype = MOVETYPE_NOCLIP;
 643         self.flags = FL_CLIENT | FL_NOTARGET;
 644         self.armorvalue = 666;
 645         self.effects = 0;
 646         self.armorvalue = autocvar_g_balance_armor_start;
 647         self.pauserotarmor_finished = 0;
 648         self.pauserothealth_finished = 0;
 649         self.pauseregen_finished = 0;
 650         self.damageforcescale = 0;
 651         self.death_time = 0;
 652         self.dead_frame = 0;
 653         self.alpha = 0;
 654         self.scale = 0;
 655         self.fade_time = 0;
 656         self.pain_frame = 0;
 657         self.pain_finished = 0;
 658         self.strength_finished = 0;
 659         self.invincible_finished = 0;
 660         self.pushltime = 0;
 661         self.think = SUB_Null;
 662         self.nextthink = 0;
 663         self.hook_time = 0;
 664         self.runes = 0;
 665         self.deadflag = DEAD_NO;
 666         self.angles = spot.angles;
 667         self.angles_z = 0;
 668         self.fixangle = TRUE;
 669         self.crouch = FALSE;
 670
 671         self.view_ofs = PL_VIEW_OFS;
 672         setorigin (self, spot.origin);
 673         setsize (self, '0 0 0', '0 0 0');
 674         self.prevorigin = self.origin;
 675         self.items = 0;
 676         self.weapons = 0;
 677         self.model = "";
 678         FixPlayermodel();
 679         self.model = "";
 680         self.modelindex = 0;
 681         self.weapon = 0;
 682         self.weaponmodel = "";
 683         self.weaponentity = world;
 684         self.exteriorweaponentity = world;
 685         self.killcount = -666;
 686         self.velocity = '0 0 0';
 687         self.avelocity = '0 0 0';
 688         self.punchangle = '0 0 0';
 689         self.punchvector = '0 0 0';
 690         self.oldvelocity = self.velocity;
 691         self.fire_endtime = -1;
 692
 693         if(sv_loddistance1)
 694                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 695
 696         if(g_arena)
 697         {
 698                 if(self.version_mismatch)
 699                 {
 700                         Spawnqueue_Unmark(self);
 701                         Spawnqueue_Remove(self);
 702                 }
 703                 else
 704                 {
 705                         Spawnqueue_Insert(self);
 706                 }
 707         }
 708         else if(g_lms)
 709         {
 710                 // Only if the player cannot play at all
 711                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 712                         self.frags = FRAGS_SPECTATOR;
 713                 else
 714                         self.frags = FRAGS_LMS_LOSER;
 715         }
 716         else
 717                 self.frags = FRAGS_SPECTATOR;
 718 }
 719
 720 void FixPlayermodel()
 721 {
 722         local string defaultmodel;
 723         local float defaultskin, chmdl, oldskin;
 724         local vector m1, m2;
 725
 726         defaultmodel = "";
 727
 728         if(autocvar_sv_defaultcharacter == 1) {
 729                 defaultskin = 0;
 730
 731                 if(teams_matter)
 732                 {
 733                         string s;
 734                         s = Team_ColorNameLowerCase(self.team);
 735                         if(s != "neutral")
 736                         {
 737                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 738                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 739                         }
 740                 }
 741
 742                 if(defaultmodel == "")
 743                 {
 744                         defaultmodel = autocvar_sv_defaultplayermodel;
 745                         defaultskin = autocvar_sv_defaultplayerskin;
 746                 }
 747         }
 748
 749         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 750         {
 751                 if(self.model != "")
 752                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 753                 self.model = ""; // force the != checks to return true
 754         }
 755
 756         if(defaultmodel != "")
 757         {
 758                 if (defaultmodel != self.model)
 759                 {
 760                         m1 = self.mins;
 761                         m2 = self.maxs;
 762                         setmodel_lod (self, defaultmodel);
 763                         setsize (self, m1, m2);
 764                         chmdl = TRUE;
 765                 }
 766
 767                 oldskin = self.skinindex;
 768                 self.skinindex = defaultskin;
 769         } else {
 770                 if (self.playermodel != self.model || self.playermodel == "")
 771                 {
 772                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 773                         m1 = self.mins;
 774                         m2 = self.maxs;
 775                         setmodel_lod (self, self.playermodel);
 776                         setsize (self, m1, m2);
 777                         chmdl = TRUE;
 778                 }
 779
 780                 oldskin = self.skinindex;
 781                 self.skinindex = stof(self.playerskin);
 782         }
 783
 784         if(chmdl || oldskin != self.skinindex)
 785                 self.species = player_getspecies(); // model or skin has changed
 786
 787         if(!teams_matter)
 788                 if(strlen(autocvar_sv_defaultplayercolors))
 789                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 790                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 791 }
 792
 793 void PlayerTouchExplode(entity p1, entity p2)
 794 {
 795         vector org;
 796         org = (p1.origin + p2.origin) * 0.5;
 797         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 798
 799         te_explosion(org);
 800
 801         entity e;
 802         e = spawn();
 803         setorigin(e, org);
 804         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 805         remove(e);
 806 }
 807
 808 /*
 809 =============
 810 PutClientInServer
 811
 812 Called when a client spawns in the server
 813 =============
 814 */
 815 //void() ctf_playerchanged;
 816 void PutClientInServer (void)
 817 {
 818         if(clienttype(self) == CLIENTTYPE_BOT)
 819         {
 820                 self.classname = "player";
 821         }
 822         else if(clienttype(self) == CLIENTTYPE_REAL)
 823         {
 824                 msg_entity = self;
 825                 WriteByte(MSG_ONE, SVC_SETVIEW);
 826                 WriteEntity(MSG_ONE, self);
 827         }
 828
 829         // player is dead and becomes observer
 830         // FIXME fix LMS scoring for new system
 831         if(g_lms)
 832         {
 833                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 834                         self.classname = "observer";
 835         }
 836
 837         if(g_arena || (g_ca && !allowed_to_spawn))
 838         if(!self.spawned)
 839                 self.classname = "observer";
 840
 841         if(gameover)
 842                 self.classname = "observer";
 843
 844         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 845                 entity spot, oldself;
 846                 float j;
 847
 848                 accuracy_resend(self);
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 870                 if(autocvar_g_playerclip_collisions)
 871                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 872                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 873                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 874                 self.frags = FRAGS_PLAYER;
 875                 if(independent_players)
 876                         MAKE_INDEPENDENT_PLAYER(self);
 877                 self.flags = FL_CLIENT;
 878                 self.takedamage = DAMAGE_AIM;
 879                 if(g_minstagib)
 880                         self.effects = EF_FULLBRIGHT;
 881                 else
 882                         self.effects = 0;
 883                 self.air_finished = time + 12;
 884                 self.dmg = 2;
 885                 if(autocvar_g_balance_nex_charge)
 886                 {
 887                         if(autocvar_g_balance_nex_secondary_chargepool)
 888                                 self.nex_chargepool_ammo = 1;
 889                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 890                 }
 891
 892                 // all weapons must be fully loaded the first time we pick them up, so set their load to maximum at respawn
 893                 self.laser_load = autocvar_g_balance_laser_reload_ammo;
 894                 self.shotgun_load = autocvar_g_balance_shotgun_reload_ammo;
 895                 self.sniperrifle_load = autocvar_g_balance_sniperrifle_reload_ammo;
 896                 self.uzi_load = autocvar_g_balance_uzi_reload_ammo;
 897                 self.grenadelauncher_load = autocvar_g_balance_grenadelauncher_reload_ammo;
 898                 self.minelayer_load = autocvar_g_balance_minelayer_reload_ammo;
 899                 self.electro_load = autocvar_g_balance_electro_reload_ammo;
 900                 self.crylink_load = autocvar_g_balance_crylink_reload_ammo;
 901                 self.hlac_load = autocvar_g_balance_hlac_reload_ammo;
 902                 self.fireball_load = autocvar_g_balance_fireball_reload_ammo;
 903                 self.seeker_load = autocvar_g_balance_fireball_reload_ammo;
 904                 self.minstanex_load = autocvar_g_balance_minstanex_reload_ammo;
 905                 self.nex_load = autocvar_g_balance_nex_reload_ammo;
 906                 self.hagar_load = autocvar_g_balance_hagar_reload_ammo;
 907                 self.rocketlauncher_load = autocvar_g_balance_rocketlauncher_reload_ammo;
 908
 909                 if(inWarmupStage)
 910                 {
 911                         self.ammo_shells = warmup_start_ammo_shells;
 912                         self.ammo_nails = warmup_start_ammo_nails;
 913                         self.ammo_rockets = warmup_start_ammo_rockets;
 914                         self.ammo_cells = warmup_start_ammo_cells;
 915                         self.ammo_fuel = warmup_start_ammo_fuel;
 916                         self.health = warmup_start_health;
 917                         self.armorvalue = warmup_start_armorvalue;
 918                         self.weapons = warmup_start_weapons;
 919                 }
 920                 else
 921                 {
 922                         self.ammo_shells = start_ammo_shells;
 923                         self.ammo_nails = start_ammo_nails;
 924                         self.ammo_rockets = start_ammo_rockets;
 925                         self.ammo_cells = start_ammo_cells;
 926                         self.ammo_fuel = start_ammo_fuel;
 927                         self.health = start_health;
 928                         self.armorvalue = start_armorvalue;
 929                         self.weapons = start_weapons;
 930                 }
 931
 932                 if(g_weaponarena_random)
 933                 {
 934                         if(g_weaponarena_random_with_laser)
 935                                 self.weapons &~= WEPBIT_LASER;
 936                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 937                         if(g_weaponarena_random_with_laser)
 938                                 self.weapons |= WEPBIT_LASER;
 939                 }
 940
 941                 self.items = start_items;
 942                 self.jump_interval = time;
 943
 944                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 945                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 946                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 947                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 948                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 949                 //extend the pause of rotting if client was reset at the beginning of the countdown
 950                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 951                         self.spawnshieldtime += game_starttime - time;
 952                         self.pauserotarmor_finished += game_starttime - time;
 953                         self.pauserothealth_finished += game_starttime - time;
 954                         self.pauseregen_finished += game_starttime - time;
 955                 }
 956                 self.damageforcescale = 2;
 957                 self.death_time = 0;
 958                 self.dead_frame = 0;
 959                 self.alpha = 0;
 960                 self.scale = 0;
 961                 self.fade_time = 0;
 962                 self.pain_frame = 0;
 963                 self.pain_finished = 0;
 964                 self.strength_finished = 0;
 965                 self.invincible_finished = 0;
 966                 self.pushltime = 0;
 967                 // players have no think function
 968                 self.think = SUB_Null;
 969                 self.nextthink = 0;
 970                 self.hook_time = 0;
 971                 self.dmg_team = 0;
 972                 self.ballistics_density = autocvar_g_ballistics_density_player;
 973
 974                 self.metertime = 0;
 975
 976                 self.runes = 0;
 977
 978                 self.deadflag = DEAD_NO;
 979
 980                 self.angles = spot.angles;
 981
 982                 self.angles_z = 0; // never spawn tilted even if the spot says to
 983                 self.fixangle = TRUE; // turn this way immediately
 984                 self.velocity = '0 0 0';
 985                 self.avelocity = '0 0 0';
 986                 self.punchangle = '0 0 0';
 987                 self.punchvector = '0 0 0';
 988                 self.oldvelocity = self.velocity;
 989                 self.fire_endtime = -1;
 990
 991                 msg_entity = self;
 992                 WRITESPECTATABLE_MSG_ONE({
 993                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 994                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 995                 });
 996
 997                 if(sv_loddistance1)
 998                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 999
1000                 self.model = "";
1001                 FixPlayermodel();
1002
1003                 self.crouch = FALSE;
1004                 self.view_ofs = PL_VIEW_OFS;
1005                 setsize (self, PL_MIN, PL_MAX);
1006                 self.spawnorigin = spot.origin;
1007                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1008                 // don't reset back to last position, even if new position is stuck in solid
1009                 self.oldorigin = self.origin;
1010                 self.prevorigin = self.origin;
1011                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1012
1013                 if(g_arena)
1014                 {
1015                         Spawnqueue_Remove(self);
1016                         Spawnqueue_Mark(self);
1017                 }
1018
1019                 else if(g_ca)
1020                         self.caplayer = 1;
1021
1022                 self.event_damage = PlayerDamage;
1023
1024                 self.bot_attack = TRUE;
1025
1026                 self.statdraintime = time + 5;
1027                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1028
1029                 if(self.killcount == -666) {
1030                         PlayerScore_Clear(self);
1031                         self.killcount = 0;
1032                 }
1033
1034                 self.cnt = WEP_LASER;
1035
1036                 CL_SpawnWeaponentity();
1037                 self.alpha = default_player_alpha;
1038                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1039                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1040
1041                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1042                 self.lms_traveled_distance = 0;
1043                 self.speedrunning = FALSE;
1044
1045                 race_PostSpawn(spot);
1046
1047                 if(autocvar_spawn_debug)
1048                 {
1049                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1050                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1051                 }
1052
1053                 //stuffcmd(self, "chase_active 0");
1054                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1055
1056                 if (autocvar_g_spawnsound)
1057                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1058
1059                 if(g_assault) {
1060                         if(self.team == assault_attacker_team)
1061                                 centerprint(self, "You are attacking!");
1062                         else
1063                                 centerprint(self, "You are defending!");
1064                 }
1065
1066                 target_voicescript_clear(self);
1067
1068                 // reset fields the weapons may use
1069                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1070                         weapon_action(j, WR_RESETPLAYER);
1071
1072                 oldself = self;
1073                 self = spot;
1074                         activator = oldself;
1075                                 SUB_UseTargets();
1076                         activator = world;
1077                 self = oldself;
1078
1079                 MUTATOR_CALLHOOK(PlayerSpawn);
1080
1081                 self.switchweapon = w_getbestweapon(self);
1082                 self.cnt = self.switchweapon;
1083                 self.weapon = 0;
1084
1085                 if(!self.alivetime)
1086                         self.alivetime = time;
1087         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1088                 PutObserverInServer ();
1089         }
1090
1091         //if(g_ctf)
1092         //      ctf_playerchanged();
1093 }
1094
1095 .float ebouncefactor, ebouncestop; // electro's values
1096 // TODO do we need all these fields, or should we stop autodetecting runtime
1097 // changes and just have a console command to update this?
1098 float ClientInit_SendEntity(entity to, float sf)
1099 {
1100         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1101         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1110         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1111         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1112         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1113         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1114         if(sv_foginterval && world.fog != "")
1115                 WriteString(MSG_ENTITY, world.fog);
1116         else
1117                 WriteString(MSG_ENTITY, "");
1118         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1119         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1120         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1121         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1122         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1123         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1124         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1125         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1126         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1127         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1128         return TRUE;
1129 }
1130
1131 void ClientInit_CheckUpdate()
1132 {
1133         self.nextthink = time;
1134         if(self.count != autocvar_g_balance_armor_blockpercent)
1135         {
1136                 self.count = autocvar_g_balance_armor_blockpercent;
1137                 self.SendFlags |= 1;
1138         }
1139         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1140         {
1141                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1142                 self.SendFlags |= 1;
1143         }
1144         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1145         {
1146                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1147                 self.SendFlags |= 1;
1148         }
1149         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1150         {
1151                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1152                 self.SendFlags |= 1;
1153         }
1154         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1155         {
1156                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1157                 self.SendFlags |= 1;
1158         }
1159         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1160         {
1161                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1162                 self.SendFlags |= 1;
1163         }
1164 }
1165
1166 void ClientInit_Spawn()
1167 {
1168         entity o;
1169         entity e;
1170         e = spawn();
1171         e.classname = "clientinit";
1172         e.think = ClientInit_CheckUpdate;
1173         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1174
1175         o = self;
1176         self = e;
1177         ClientInit_CheckUpdate();
1178         self = o;
1179 }
1180
1181 /*
1182 =============
1183 SetNewParms
1184 =============
1185 */
1186 void SetNewParms (void)
1187 {
1188         // initialize parms for a new player
1189         parm1 = -(86400 * 366);
1190 }
1191
1192 /*
1193 =============
1194 SetChangeParms
1195 =============
1196 */
1197 void SetChangeParms (void)
1198 {
1199         // save parms for level change
1200         parm1 = self.parm_idlesince - time;
1201 }
1202
1203 /*
1204 =============
1205 DecodeLevelParms
1206 =============
1207 */
1208 void DecodeLevelParms (void)
1209 {
1210         // load parms
1211         self.parm_idlesince = parm1;
1212         if(self.parm_idlesince == -(86400 * 366))
1213                 self.parm_idlesince = time;
1214
1215         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1216         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1217 }
1218
1219 /*
1220 =============
1221 ClientKill
1222
1223 Called when a client types 'kill' in the console
1224 =============
1225 */
1226
1227 .float clientkill_nexttime;
1228 void ClientKill_Now_TeamChange()
1229 {
1230         if(self.killindicator_teamchange == -1)
1231         {
1232                 self.team = -1;
1233                 JoinBestTeam( self, FALSE, FALSE );
1234         }
1235         else if(self.killindicator_teamchange == -2)
1236         {
1237                 if(g_ca)
1238                         self.caplayer = 0;
1239                 if(blockSpectators)
1240                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1241                 PutObserverInServer();
1242         }
1243         else
1244                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1245 }
1246
1247 void ClientKill_Now()
1248 {
1249         remove(self.killindicator);
1250         self.killindicator = world;
1251
1252         if(self.killindicator_teamchange)
1253                 ClientKill_Now_TeamChange();
1254
1255         // in any case:
1256         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1257
1258         // now I am sure the player IS dead
1259 }
1260 void KillIndicator_Think()
1261 {
1262         if (!self.owner.modelindex)
1263         {
1264                 self.owner.killindicator = world;
1265                 remove(self);
1266                 return;
1267         }
1268
1269         if(self.cnt <= 0)
1270         {
1271                 self = self.owner;
1272                 ClientKill_Now(); // no oldself needed
1273                 return;
1274         }
1275     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1276     {
1277         self.nextthink = time + 1;
1278         self.cnt -= 1;
1279     }
1280         else
1281         {
1282                 if(self.cnt <= 10)
1283                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1284                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1285                 {
1286                         if(self.cnt <= 10)
1287                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1288                         if(self.owner.killindicator_teamchange)
1289                         {
1290                                 if(self.owner.killindicator_teamchange == -1)
1291                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1292                                 else if(self.owner.killindicator_teamchange == -2)
1293                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1294                                 else
1295                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1296                         }
1297                         else
1298                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1299                 }
1300                 self.nextthink = time + 1;
1301                 self.cnt -= 1;
1302         }
1303 }
1304
1305 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1306 {
1307         float killtime;
1308         entity e;
1309         killtime = autocvar_g_balance_kill_delay;
1310
1311         if(g_race_qualifying || g_cts)
1312                 killtime = 0;
1313
1314     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1315     {
1316                 remove(self.killindicator);
1317                 self.killindicator = world;
1318
1319         ClientKill_Now(); // allow instant kill in this case
1320         return;
1321     }
1322
1323         self.killindicator_teamchange = targetteam;
1324
1325     if(!self.killindicator)
1326         {
1327                 if(self.modelindex && self.deadflag == DEAD_NO)
1328                 {
1329                         killtime = max(killtime, self.clientkill_nexttime - time);
1330                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1331                 }
1332
1333                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1334                 {
1335                         ClientKill_Now();
1336                 }
1337                 else
1338                 {
1339                         self.killindicator = spawn();
1340                         self.killindicator.owner = self;
1341                         self.killindicator.scale = 0.5;
1342                         setattachment(self.killindicator, self, "");
1343                         setorigin(self.killindicator, '0 0 52');
1344                         self.killindicator.think = KillIndicator_Think;
1345                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1346                         self.killindicator.cnt = ceil(killtime);
1347                         self.killindicator.count = bound(0, ceil(killtime), 10);
1348                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1349
1350                         for(e = world; (e = find(e, classname, "body")) != world; )
1351                         {
1352                                 if(e.enemy != self)
1353                                         continue;
1354                                 e.killindicator = spawn();
1355                                 e.killindicator.owner = e;
1356                                 e.killindicator.scale = 0.5;
1357                                 setattachment(e.killindicator, e, "");
1358                                 setorigin(e.killindicator, '0 0 52');
1359                                 e.killindicator.think = KillIndicator_Think;
1360                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1361                                 e.killindicator.cnt = ceil(killtime);
1362                         }
1363                         self.lip = 0;
1364                 }
1365         }
1366         if(self.killindicator)
1367         {
1368                 if(targetteam == 0) // just die
1369                         self.killindicator.colormod = '0 0 0';
1370                 else if(targetteam == -1) // auto
1371                         self.killindicator.colormod = '0 1 0';
1372                 else if(targetteam == -2) // spectate
1373                         self.killindicator.colormod = '0.5 0.5 0.5';
1374                 else
1375                         self.killindicator.colormod = TeamColor(targetteam);
1376         }
1377 }
1378
1379 void ClientKill (void)
1380 {
1381         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1382         {
1383                 // do nothing
1384         }
1385     else if(self.freezetag_frozen)
1386     {
1387         // do nothing
1388     }
1389         else
1390                 ClientKill_TeamChange(0);
1391 }
1392
1393 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1394 {
1395     e.killindicator = spawn();
1396     e.killindicator.owner = e;
1397     e.killindicator.think = KillIndicator_Think;
1398     e.killindicator.nextthink = time + (e.lip) * 0.05;
1399     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1400     e.killindicator.health = 1; // this is used to indicate that it should be silent
1401     e.lip = 0;
1402 }
1403
1404 void DoTeamChange(float destteam)
1405 {
1406         float t, c0;
1407         if(!teams_matter)
1408         {
1409                 if(destteam >= 0)
1410                         SetPlayerColors(self, destteam);
1411                 return;
1412         }
1413         if(self.classname == "player")
1414         if(destteam == -1)
1415         {
1416                 CheckAllowedTeams(self);
1417                 t = FindSmallestTeam(self, TRUE);
1418                 switch(self.team)
1419                 {
1420                         case COLOR_TEAM1: c0 = c1; break;
1421                         case COLOR_TEAM2: c0 = c2; break;
1422                         case COLOR_TEAM3: c0 = c3; break;
1423                         case COLOR_TEAM4: c0 = c4; break;
1424                         default:          c0 = 999;
1425                 }
1426                 switch(t)
1427                 {
1428                         case 1:
1429                                 if(c0 > c1)
1430                                         destteam = COLOR_TEAM1;
1431                                 break;
1432                         case 2:
1433                                 if(c0 > c2)
1434                                         destteam = COLOR_TEAM2;
1435                                 break;
1436                         case 3:
1437                                 if(c0 > c3)
1438                                         destteam = COLOR_TEAM3;
1439                                 break;
1440                         case 4:
1441                                 if(c0 > c4)
1442                                         destteam = COLOR_TEAM4;
1443                                 break;
1444                 }
1445                 if(destteam == -1)
1446                         return;
1447         }
1448         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1449                 return;
1450         ClientKill_TeamChange(destteam);
1451 }
1452
1453 void FixClientCvars(entity e)
1454 {
1455         // send prediction settings to the client
1456         stuffcmd(e, "\nin_bindmap 0 0\n");
1457         if(g_race || g_cts)
1458                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1459         if(autocvar_g_antilag == 3) // client side hitscan
1460                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1461         if(sv_gentle)
1462                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1463         /*
1464          * we no longer need to stuff this. Remove this comment block if you feel
1465          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1466         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1467         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1468         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1469         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1470         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1471         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1472         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1473         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1474         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1475         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1476         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1477         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1478         stuffcmd(e, "cl_movement_edgefriction 1\n");
1479          */
1480 }
1481
1482 float PlayerInIDList(entity p, string idlist)
1483 {
1484         float n, i;
1485         string s;
1486
1487         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1488         if not(p.crypto_idfp)
1489                 return 0;
1490
1491         // this function allows abbreviated player IDs too!
1492         n = tokenize_console(idlist);
1493         for(i = 0; i < n; ++i)
1494         {
1495                 s = argv(i);
1496                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1497                         return 1;
1498         }
1499
1500         return 0;
1501 }
1502
1503 /*
1504 =============
1505 ClientConnect
1506
1507 Called when a client connects to the server
1508 =============
1509 */
1510 //void ctf_clientconnect();
1511 string ColoredTeamName(float t);
1512 void DecodeLevelParms (void);
1513 //void dom_player_join_team(entity pl);
1514 void ClientConnect (void)
1515 {
1516         float t;
1517
1518         if(self.flags & FL_CLIENT)
1519         {
1520                 print("Warning: ClientConnect, but already connected!\n");
1521                 return;
1522         }
1523
1524         if(Ban_MaybeEnforceBan(self))
1525                 return;
1526
1527         DecodeLevelParms();
1528
1529 #ifdef WATERMARK
1530         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1531 #endif
1532
1533         self.classname = "player_joining";
1534
1535         self.flags = FL_CLIENT;
1536         self.version_nagtime = time + 10 + random() * 10;
1537
1538         if(player_count<0)
1539         {
1540                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1541                 player_count = 0;
1542         }
1543
1544         PlayerScore_Attach(self);
1545         ClientData_Attach();
1546         accuracy_init(self);
1547
1548         bot_clientconnect();
1549
1550         playerdemo_init();
1551
1552         anticheat_init();
1553
1554         race_PreSpawnObserver();
1555
1556         //if(g_domination)
1557         //      dom_player_join_team(self);
1558
1559         // identify the right forced team
1560         if(autocvar_g_campaign)
1561         {
1562                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1563                 {
1564                         switch(autocvar_g_campaign_forceteam)
1565                         {
1566                                 case 1: self.team_forced = COLOR_TEAM1; break;
1567                                 case 2: self.team_forced = COLOR_TEAM2; break;
1568                                 case 3: self.team_forced = COLOR_TEAM3; break;
1569                                 case 4: self.team_forced = COLOR_TEAM4; break;
1570                                 default: self.team_forced = 0;
1571                         }
1572                 }
1573         }
1574         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1575                 self.team_forced = COLOR_TEAM1;
1576         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1577                 self.team_forced = COLOR_TEAM2;
1578         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1579                 self.team_forced = COLOR_TEAM3;
1580         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1581                 self.team_forced = COLOR_TEAM4;
1582         else if(autocvar_g_forced_team_otherwise == "red")
1583                 self.team_forced = COLOR_TEAM1;
1584         else if(autocvar_g_forced_team_otherwise == "blue")
1585                 self.team_forced = COLOR_TEAM2;
1586         else if(autocvar_g_forced_team_otherwise == "yellow")
1587                 self.team_forced = COLOR_TEAM3;
1588         else if(autocvar_g_forced_team_otherwise == "pink")
1589                 self.team_forced = COLOR_TEAM4;
1590         else if(autocvar_g_forced_team_otherwise == "spectate")
1591                 self.team_forced = -1;
1592         else if(autocvar_g_forced_team_otherwise == "spectator")
1593                 self.team_forced = -1;
1594         else
1595                 self.team_forced = 0;
1596
1597         if(!teams_matter)
1598                 if(self.team_forced > 0)
1599                         self.team_forced = 0;
1600
1601         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1602
1603         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1604                 self.classname = "observer";
1605         } else {
1606                 if(teams_matter)
1607                 {
1608                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1609                         {
1610                                 self.classname = "player";
1611                                 campaign_bots_may_start = 1;
1612                         }
1613                         else
1614                         {
1615                                 self.classname = "observer"; // do it anyway
1616                         }
1617                 }
1618                 else
1619                 {
1620                         self.classname = "player";
1621                         campaign_bots_may_start = 1;
1622                 }
1623         }
1624
1625         self.playerid = (playerid_last = playerid_last + 1);
1626
1627         if(autocvar_sv_eventlog)
1628                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1629
1630         LogTeamchange(self.playerid, self.team, 1);
1631
1632         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1633
1634         self.netname_previous = strzone(self.netname);
1635
1636         bprint("^4", self.netname, "^4 connected");
1637
1638         if(self.classname != "observer" && (g_domination || g_ctf))
1639                 bprint(" and joined the ", ColoredTeamName(self.team));
1640
1641         bprint("\n");
1642
1643         self.welcomemessage_time = 0;
1644
1645         stuffcmd(self, strcat(clientstuff, "\n"));
1646         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1647         stuffcmd(self, "cl_particles_reloadeffects\n");
1648
1649         FixClientCvars(self);
1650
1651         // spawnfunc_waypoint sprites
1652         WaypointSprite_InitClient(self);
1653
1654         // Wazat's grappling hook
1655         SetGrappleHookBindings();
1656
1657         // get autoswitch state from player when he toggles it
1658         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1659
1660         // get version info from player
1661         stuffcmd(self, "cmd clientversion $gameversion\n");
1662
1663         // get other cvars from player
1664         GetCvars(0);
1665
1666         // notify about available teams
1667         if(teams_matter)
1668         {
1669                 CheckAllowedTeams(self);
1670                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1671                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1672         }
1673         else
1674                 stuffcmd(self, "set _teams_available 0\n");
1675
1676         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1677
1678         if(g_arena || g_ca)
1679         {
1680                 self.classname = "observer";
1681                 if(g_arena)
1682                         Spawnqueue_Insert(self);
1683         }
1684         /*else if(g_ctf)
1685         {
1686                 ctf_clientconnect();
1687         }*/
1688
1689         if(teams_matter || radar_showennemies)
1690                 attach_entcs();
1691
1692         bot_relinkplayerlist();
1693
1694         self.spectatortime = time;
1695         if(blockSpectators)
1696         {
1697                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1698         }
1699
1700         self.jointime = time;
1701         self.allowedTimeouts = autocvar_sv_timeout_number;
1702
1703         if(clienttype(self) == CLIENTTYPE_REAL)
1704         {
1705                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1706                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1707         }
1708
1709         if(g_lms)
1710         {
1711                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1712                 {
1713                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1714                         self.frags = FRAGS_SPECTATOR;
1715                 }
1716         }
1717
1718         if(!sv_foginterval && world.fog != "")
1719                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1720
1721         SoundEntity_Attach(self);
1722
1723         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1724         {
1725                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1726                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1727         }
1728         else
1729                 self.hitplotfh = -1;
1730
1731         if(g_race || g_cts) {
1732                 string rr;
1733                 if(g_cts)
1734                         rr = CTS_RECORD;
1735                 else
1736                         rr = RACE_RECORD;
1737                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1738
1739                 msg_entity = self;
1740                 race_send_recordtime(MSG_ONE);
1741                 race_send_speedaward(MSG_ONE);
1742
1743                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1744                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1745                 race_send_speedaward_alltimebest(MSG_ONE);
1746
1747                 float i;
1748                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1749                         race_SendRankings(i, 0, 0, MSG_ONE);
1750                 }
1751         }
1752         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1753                 send_CSQC_teamnagger();
1754
1755         CheatInitClient();
1756
1757         PlayerStats_AddPlayer(self);
1758 }
1759
1760 /*
1761 =============
1762 ClientDisconnect
1763
1764 Called when a client disconnects from the server
1765 =============
1766 */
1767 .entity chatbubbleentity;
1768 .entity teambubbleentity;
1769 void ReadyCount();
1770 void ClientDisconnect (void)
1771 {
1772         if not(self.flags & FL_CLIENT)
1773         {
1774                 print("Warning: ClientDisconnect without ClientConnect\n");
1775                 return;
1776         }
1777
1778         PlayerStats_AddGlobalInfo(self);
1779
1780         CheatShutdownClient();
1781
1782         if(self.hitplotfh >= 0)
1783         {
1784                 fclose(self.hitplotfh);
1785                 self.hitplotfh = -1;
1786         }
1787
1788         anticheat_report();
1789         anticheat_shutdown();
1790
1791         playerdemo_shutdown();
1792
1793         bot_clientdisconnect();
1794
1795         if(self.entcs)
1796                 detach_entcs();
1797
1798         if(autocvar_sv_eventlog)
1799                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1800         bprint ("^4",self.netname);
1801         bprint ("^4 disconnected\n");
1802
1803         SoundEntity_Detach(self);
1804
1805         DropAllRunes(self);
1806         MUTATOR_CALLHOOK(ClientDisconnect);
1807
1808         Portal_ClearAll(self);
1809
1810         if(self.flagcarried)
1811                 DropFlag(self.flagcarried, world, world);
1812         if(self.ballcarried && g_nexball)
1813                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1814
1815         // Here, everything has been done that requires this player to be a client.
1816
1817         self.flags &~= FL_CLIENT;
1818
1819         if (self.chatbubbleentity)
1820                 remove (self.chatbubbleentity);
1821
1822         if (self.teambubbleentity)
1823                 remove (self.teambubbleentity);
1824
1825         if (self.killindicator)
1826                 remove (self.killindicator);
1827
1828         WaypointSprite_PlayerGone();
1829
1830         bot_relinkplayerlist();
1831
1832         if(g_arena)
1833         {
1834                 Spawnqueue_Unmark(self);
1835                 Spawnqueue_Remove(self);
1836         }
1837
1838         accuracy_free(self);
1839         ClientData_Detach();
1840         PlayerScore_Detach(self);
1841
1842         if(self.netname_previous)
1843                 strunzone(self.netname_previous);
1844         if(self.clientstatus)
1845                 strunzone(self.clientstatus);
1846         if(self.weaponorder_byimpulse)
1847                 strunzone(self.weaponorder_byimpulse);
1848
1849         ClearPlayerSounds();
1850
1851         if(self.personal)
1852                 remove(self.personal);
1853
1854         self.playerid = 0;
1855         ReadyCount();
1856
1857         // free cvars
1858         GetCvars(-1);
1859 }
1860
1861 .float BUTTON_CHAT;
1862 void ChatBubbleThink()
1863 {
1864         self.nextthink = time;
1865         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1866         {
1867                 if(self.owner) // but why can that ever be world?
1868                         self.owner.chatbubbleentity = world;
1869                 remove(self);
1870                 return;
1871         }
1872         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1873 #ifdef TETRIS
1874                 || self.owner.tetris_on
1875 #endif
1876         )
1877                 self.model = self.mdl;
1878         else
1879                 self.model = "";
1880 };
1881
1882 void UpdateChatBubble()
1883 {
1884         if (!self.modelindex)
1885                 return;
1886         // spawn a chatbubble entity if needed
1887         if (!self.chatbubbleentity)
1888         {
1889                 self.chatbubbleentity = spawn();
1890                 self.chatbubbleentity.owner = self;
1891                 self.chatbubbleentity.exteriormodeltoclient = self;
1892                 self.chatbubbleentity.think = ChatBubbleThink;
1893                 self.chatbubbleentity.nextthink = time;
1894                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1895                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1896                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1897                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1898                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1899                 self.chatbubbleentity.model = "";
1900                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1901         }
1902 }
1903
1904
1905 void TeamBubbleThink()
1906 {
1907         self.nextthink = time;
1908         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1909         {
1910                 if(self.owner) // but why can that ever be world?
1911                         self.owner.teambubbleentity = world;
1912                 remove(self);
1913                 return;
1914         }
1915 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1916         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1917                 self.model = "";
1918         else
1919                 self.model = self.mdl;
1920
1921 };
1922
1923 float TeamBubble_customizeentityforclient()
1924 {
1925         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1926 }
1927
1928 void UpdateTeamBubble()
1929 {
1930         if (!self.modelindex || !teams_matter)
1931                 return;
1932         // spawn a teambubble entity if needed
1933         if (!self.teambubbleentity && teams_matter)
1934         {
1935                 self.teambubbleentity = spawn();
1936                 self.teambubbleentity.owner = self;
1937                 self.teambubbleentity.exteriormodeltoclient = self;
1938                 self.teambubbleentity.think = TeamBubbleThink;
1939                 self.teambubbleentity.nextthink = time;
1940                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1941 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1942                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1943                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1944                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1945                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1946                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1947                 self.teambubbleentity.effects = EF_LOWPRECISION;
1948         }
1949 }
1950
1951 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1952 // added to the model skins
1953 /*void UpdateColorModHack()
1954 {
1955         local float c;
1956         c = self.clientcolors & 15;
1957         // LordHavoc: only bothering to support white, green, red, yellow, blue
1958              if (!teams_matter) self.colormod = '0 0 0';
1959         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1960         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1961         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1962         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1963         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1964         else self.colormod = '1 1 1';
1965 };*/
1966
1967 .float oldcolormap;
1968 void respawn(void)
1969 {
1970         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1971         {
1972                 self.solid = SOLID_NOT;
1973                 self.takedamage = DAMAGE_NO;
1974                 self.movetype = MOVETYPE_FLY;
1975                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1976                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1977                 self.effects |= EF_ADDITIVE;
1978                 self.oldcolormap = self.colormap;
1979                 self.colormap = 512;
1980                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1981                 if(autocvar_g_respawn_ghosts_maxtime)
1982                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1983         }
1984
1985         CopyBody(1);
1986         self.effects |= EF_NODRAW; // prevent another CopyBody
1987         if(self.oldcolormap)
1988         {
1989                 self.colormap = self.oldcolormap;
1990                 self.oldcolormap = 0;
1991         }
1992         PutClientInServer();
1993 }
1994
1995 void play_countdown(float finished, string samp)
1996 {
1997         if(clienttype(self) == CLIENTTYPE_REAL)
1998                 if(floor(finished - time - frametime) != floor(finished - time))
1999                         if(finished - time < 6)
2000                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
2001 }
2002
2003 /**
2004  * When sv_timeout is used this function returs strings like
2005  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
2006  * Called by centerprint functions
2007  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
2008  */
2009 string getTimeoutText(float addOneSecond) {
2010         if (!autocvar_sv_timeout || !timeoutStatus)
2011                 return "";
2012
2013         local string retStr;
2014         if (timeoutStatus == 1) {
2015                 if (addOneSecond == 1) {
2016                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2017                 }
2018                 else {
2019                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2020                 }
2021                 return retStr;
2022         }
2023         else if (timeoutStatus == 2) {
2024                 if (addOneSecond) {
2025                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2026                         //don't show messages like "Timeout ends in 0 seconds"...
2027                         if ((remainingTimeoutTime + 1) > 0)
2028                                 return retStr;
2029                         else
2030                                 return "";
2031                 }
2032                 else {
2033                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2034                         //don't show messages like "Timeout ends in 0 seconds"...
2035                         if (remainingTimeoutTime > 0)
2036                                 return retStr;
2037                         else
2038                                 return "";
2039                 }
2040         }
2041         else return "";
2042 }
2043
2044 void player_powerups (void)
2045 {
2046         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2047         olditems = self.items;
2048
2049         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2050         {
2051                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2052                 self.modelflags |= MF_ROCKET;
2053         }
2054         else
2055         {
2056                 SoundEntity_StopSound(self, CHAN_PLAYER);
2057                 self.modelflags &~= MF_ROCKET;
2058         }
2059
2060         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2061
2062         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2063                 return;
2064
2065         Fire_ApplyDamage(self);
2066         Fire_ApplyEffect(self);
2067
2068         if (g_minstagib)
2069         {
2070                 self.effects |= EF_FULLBRIGHT;
2071
2072                 if (self.items & IT_STRENGTH)
2073                 {
2074                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2075                         if (time > self.strength_finished)
2076                         {
2077                                 self.alpha = default_player_alpha;
2078                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2079                                 self.items &~= IT_STRENGTH;
2080                                 sprint(self, "^3Invisibility has worn off\n");
2081                         }
2082                 }
2083                 else
2084                 {
2085                         if (time < self.strength_finished)
2086                         {
2087                                 self.alpha = g_minstagib_invis_alpha;
2088                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2089                                 self.items |= IT_STRENGTH;
2090                                 sprint(self, "^3You are invisible\n");
2091                         }
2092                 }
2093
2094                 if (self.items & IT_INVINCIBLE)
2095                 {
2096                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2097                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2098                         {
2099                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2100                                 sprint(self, "^3Speed has worn off\n");
2101                         }
2102                 }
2103                 else
2104                 {
2105                         if (time < self.invincible_finished)
2106                         {
2107                                 self.items = self.items | IT_INVINCIBLE;
2108                                 sprint(self, "^3You are on speed\n");
2109                         }
2110                 }
2111         }
2112         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2113         {
2114                 if (self.items & IT_STRENGTH)
2115                 {
2116                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2117                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2118                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2119                         {
2120                                 self.items = self.items - (self.items & IT_STRENGTH);
2121                                 sprint(self, "^3Strength has worn off\n");
2122                         }
2123                 }
2124                 else
2125                 {
2126                         if (time < self.strength_finished)
2127                         {
2128                                 self.items = self.items | IT_STRENGTH;
2129                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2130                         }
2131                 }
2132                 if (self.items & IT_INVINCIBLE)
2133                 {
2134                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2135                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2136                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2137                         {
2138                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2139                                 sprint(self, "^3Shield has worn off\n");
2140                         }
2141                 }
2142                 else
2143                 {
2144                         if (time < self.invincible_finished)
2145                         {
2146                                 self.items = self.items | IT_INVINCIBLE;
2147                                 sprint(self, "^3Shield surrounds you\n");
2148                         }
2149                 }
2150
2151                 if(autocvar_g_nodepthtestplayers)
2152                         self.effects = self.effects | EF_NODEPTHTEST;
2153
2154                 if(autocvar_g_fullbrightplayers)
2155                         self.effects = self.effects | EF_FULLBRIGHT;
2156
2157                 // midair gamemode: damage only while in the air
2158                 // if in midair mode, being on ground grants temporary invulnerability
2159                 // (this is so that multishot weapon don't clear the ground flag on the
2160                 // first damage in the frame, leaving the player vulnerable to the
2161                 // remaining hits in the same frame)
2162                 if (self.flags & FL_ONGROUND)
2163                 if (g_midair)
2164                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2165
2166                 if (time >= game_starttime)
2167                 if (time < self.spawnshieldtime)
2168                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2169         }
2170
2171         MUTATOR_CALLHOOK(PlayerPowerups);
2172 }
2173
2174 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2175 {
2176         if(current > stable)
2177                 return current;
2178         else if(current > stable - 0.25) // when close enough, "snap"
2179                 return stable;
2180         else
2181                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2182 }
2183
2184 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2185 {
2186         if(current < stable)
2187                 return current;
2188         else if(current < stable + 0.25) // when close enough, "snap"
2189                 return stable;
2190         else
2191                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2192 }
2193
2194 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2195 {
2196         if(current > rotstable)
2197         {
2198                 if(rotframetime > 0)
2199                 {
2200                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2201                         current = max(rotstable, current - rotlinear * rotframetime);
2202                 }
2203         }
2204         else if(current < regenstable)
2205         {
2206                 if(regenframetime > 0)
2207                 {
2208                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2209                         current = min(regenstable, current + regenlinear * regenframetime);
2210                 }
2211         }
2212
2213         if(current > limit)
2214                 current = limit;
2215
2216         return current;
2217 }
2218
2219 void player_regen (void)
2220 {
2221         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2222         maxh = autocvar_g_balance_health_rotstable;
2223         maxa = autocvar_g_balance_armor_rotstable;
2224         maxf = autocvar_g_balance_fuel_rotstable;
2225         minh = autocvar_g_balance_health_regenstable;
2226         mina = autocvar_g_balance_armor_regenstable;
2227         minf = autocvar_g_balance_fuel_regenstable;
2228         limith = autocvar_g_balance_health_limit;
2229         limita = autocvar_g_balance_armor_limit;
2230         limitf = autocvar_g_balance_fuel_limit;
2231
2232         max_mod = regen_mod = rot_mod = limit_mod = 1;
2233
2234         if (self.runes & RUNE_REGEN)
2235         {
2236                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2237                 {
2238                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2239                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2240                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2241                 }
2242                 else
2243                 {
2244                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2245                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2246                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2247                 }
2248         }
2249         else if (self.runes & CURSE_VENOM)
2250         {
2251                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2252                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2253                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2254                 else
2255                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2256                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2257                 //if (!self.runes & RUNE_REGEN)
2258                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2259         }
2260         maxh = maxh * max_mod;
2261         //maxa = maxa * max_mod;
2262         //maxf = maxf * max_mod;
2263         minh = minh * max_mod;
2264         //mina = mina * max_mod;
2265         //minf = minf * max_mod;
2266         limith = limith * limit_mod;
2267         limita = limita * limit_mod;
2268         //limitf = limitf * limit_mod;
2269
2270         if(g_lms && g_ca)
2271                 rot_mod = 0;
2272
2273         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2274         {
2275                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2276                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2277
2278                 // if player rotted to death...  die!
2279                 if(self.health < 1)
2280                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2281         }
2282
2283         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2284                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2285 }
2286
2287 float zoomstate_set;
2288 void SetZoomState(float z)
2289 {
2290         if(z != self.zoomstate)
2291         {
2292                 self.zoomstate = z;
2293                 ClientData_Touch(self);
2294         }
2295         zoomstate_set = 1;
2296 }
2297
2298 void GetPressedKeys(void) {
2299         MUTATOR_CALLHOOK(GetPressedKeys);
2300         if (self.movement_x > 0) // get if movement keys are pressed
2301         {       // forward key pressed
2302                 self.pressedkeys |= KEY_FORWARD;
2303                 self.pressedkeys &~= KEY_BACKWARD;
2304         }
2305         else if (self.movement_x < 0)
2306         {       // backward key pressed
2307                 self.pressedkeys |= KEY_BACKWARD;
2308                 self.pressedkeys &~= KEY_FORWARD;
2309         }
2310         else
2311         {       // no x input
2312                 self.pressedkeys &~= KEY_FORWARD;
2313                 self.pressedkeys &~= KEY_BACKWARD;
2314         }
2315
2316         if (self.movement_y > 0)
2317         {       // right key pressed
2318                 self.pressedkeys |= KEY_RIGHT;
2319                 self.pressedkeys &~= KEY_LEFT;
2320         }
2321         else if (self.movement_y < 0)
2322         {       // left key pressed
2323                 self.pressedkeys |= KEY_LEFT;
2324                 self.pressedkeys &~= KEY_RIGHT;
2325         }
2326         else
2327         {       // no y input
2328                 self.pressedkeys &~= KEY_RIGHT;
2329                 self.pressedkeys &~= KEY_LEFT;
2330         }
2331
2332         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2333                 self.pressedkeys |= KEY_JUMP;
2334         else
2335                 self.pressedkeys &~= KEY_JUMP;
2336         if (self.BUTTON_CROUCH)
2337                 self.pressedkeys |= KEY_CROUCH;
2338         else
2339                 self.pressedkeys &~= KEY_CROUCH;
2340 }
2341
2342 /*
2343 ======================
2344 spectate mode routines
2345 ======================
2346 */
2347
2348 void SpectateCopy(entity spectatee) {
2349         other = spectatee;
2350         MUTATOR_CALLHOOK(SpectateCopy);
2351         self.armortype = spectatee.armortype;
2352         self.armorvalue = spectatee.armorvalue;
2353         self.ammo_cells = spectatee.ammo_cells;
2354         self.ammo_shells = spectatee.ammo_shells;
2355         self.ammo_nails = spectatee.ammo_nails;
2356         self.ammo_rockets = spectatee.ammo_rockets;
2357         self.ammo_fuel = spectatee.ammo_fuel;
2358         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2359         self.health = spectatee.health;
2360         self.impulse = 0;
2361         self.items = spectatee.items;
2362         self.last_pickup = spectatee.last_pickup;
2363         self.metertime = spectatee.metertime;
2364         self.strength_finished = spectatee.strength_finished;
2365         self.invincible_finished = spectatee.invincible_finished;
2366         self.pressedkeys = spectatee.pressedkeys;
2367         self.weapons = spectatee.weapons;
2368         self.switchweapon = spectatee.switchweapon;
2369         self.weapon = spectatee.weapon;
2370         self.punchangle = spectatee.punchangle;
2371         self.view_ofs = spectatee.view_ofs;
2372         self.v_angle = spectatee.v_angle;
2373         self.velocity = spectatee.velocity;
2374         self.dmg_take = spectatee.dmg_take;
2375         self.dmg_save = spectatee.dmg_save;
2376         self.dmg_inflictor = spectatee.dmg_inflictor;
2377         self.angles = spectatee.v_angle;
2378         self.fixangle = TRUE;
2379         setorigin(self, spectatee.origin);
2380         setsize(self, spectatee.mins, spectatee.maxs);
2381         SetZoomState(spectatee.zoomstate);
2382
2383         anticheat_spectatecopy(spectatee);
2384 }
2385
2386 float SpectateUpdate() {
2387         if(!self.enemy)
2388                 return 0;
2389
2390         if (self == self.enemy)
2391                 return 0;
2392
2393         if(self.enemy.classname != "player")
2394                 return 0;
2395
2396         SpectateCopy(self.enemy);
2397
2398         return 1;
2399 }
2400
2401 float SpectateNext() {
2402         other = find(self.enemy, classname, "player");
2403
2404         if (!other)
2405                 other = find(other, classname, "player");
2406
2407         if (other)
2408                 self.enemy = other;
2409
2410         if(self.enemy.classname == "player") {
2411                 msg_entity = self;
2412                 WriteByte(MSG_ONE, SVC_SETVIEW);
2413                 WriteEntity(MSG_ONE, self.enemy);
2414                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2415                 self.movetype = MOVETYPE_NONE;
2416                 accuracy_resend(self);
2417
2418                 if(!SpectateUpdate())
2419                         PutObserverInServer();
2420
2421                 return 1;
2422         } else {
2423                 return 0;
2424         }
2425 }
2426
2427 /*
2428 =============
2429 ShowRespawnCountdown()
2430
2431 Update a respawn countdown display.
2432 =============
2433 */
2434 void ShowRespawnCountdown()
2435 {
2436         float number;
2437         if(self.deadflag == DEAD_NO) // just respawned?
2438                 return;
2439         else
2440         {
2441                 number = ceil(self.death_time - time);
2442                 if(number <= 0)
2443                         return;
2444                 if(number <= self.respawn_countdown)
2445                 {
2446                         self.respawn_countdown = number - 1;
2447                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2448                                 AnnounceTo(self, strcat(ftos(number), ""));
2449                 }
2450         }
2451 }
2452
2453 void LeaveSpectatorMode()
2454 {
2455         if(isJoinAllowed()) {
2456                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2457                         self.classname = "player";
2458
2459                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2460                                 JoinBestTeam(self, FALSE, TRUE);
2461
2462                         if(autocvar_g_campaign)
2463                                 campaign_bots_may_start = 1;
2464
2465                         PutClientInServer();
2466
2467                         if(self.classname == "player")
2468                                 bprint ("^4", self.netname, "^4 is playing now\n");
2469
2470                         if(!autocvar_g_campaign)
2471                                 centerprint(self,""); // clear MOTD
2472
2473                         return;
2474                 } else {
2475                         if (g_ca && self.caplayer) {
2476                         }       // do nothing
2477                         else
2478                                 stuffcmd(self,"menu_showteamselect\n");
2479                         return;
2480                 }
2481         }
2482         else {
2483                 //player may not join because of g_maxplayers is set
2484                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2485         }
2486 }
2487
2488 /**
2489  * Determines whether the player is allowed to join. This depends on cvar
2490  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2491  * it checks whether the number of currently playing players exceeds g_maxplayers.
2492  * @return bool TRUE if the player is allowed to join, false otherwise
2493  */
2494 float isJoinAllowed() {
2495         if(self.team_forced < 0)
2496                 return FALSE; // forced spectators can never join
2497
2498         if (!autocvar_g_maxplayers)
2499                 return TRUE;
2500
2501         local entity e;
2502         local float currentlyPlaying;
2503         FOR_EACH_REALPLAYER(e) {
2504                 if(e.classname == "player")
2505                         currentlyPlaying += 1;
2506         }
2507         if(currentlyPlaying < autocvar_g_maxplayers)
2508                 return TRUE;
2509
2510         return FALSE;
2511 }
2512
2513 /**
2514  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2515  * g_maxplayers_spectator_blocktime seconds
2516  */
2517 void checkSpectatorBlock() {
2518         if(self.classname == "spectator" || self.classname == "observer") {
2519                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2520                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2521                         dropclient(self);
2522                 }
2523         }
2524 }
2525
2526 void ObserverThink()
2527 {
2528         if (self.flags & FL_JUMPRELEASED) {
2529                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2530                         self.welcomemessage_time = 0;
2531                         self.flags &~= FL_JUMPRELEASED;
2532                         self.flags |= FL_SPAWNING;
2533                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2534                         self.welcomemessage_time = 0;
2535                         self.flags &~= FL_JUMPRELEASED;
2536                         if(SpectateNext() == 1) {
2537                                 self.classname = "spectator";
2538                         }
2539                 }
2540         } else {
2541                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2542                         self.flags |= FL_JUMPRELEASED;
2543                         if(self.flags & FL_SPAWNING)
2544                         {
2545                                 self.flags &~= FL_SPAWNING;
2546                                 LeaveSpectatorMode();
2547                                 return;
2548                         }
2549                 }
2550         }
2551         PrintWelcomeMessage(self);
2552 }
2553
2554 void SpectatorThink()
2555 {
2556         if (self.flags & FL_JUMPRELEASED) {
2557                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2558                         self.welcomemessage_time = 0;
2559                         self.flags &~= FL_JUMPRELEASED;
2560                         self.flags |= FL_SPAWNING;
2561                 } else if(self.BUTTON_ATCK) {
2562                         self.welcomemessage_time = 0;
2563                         self.flags &~= FL_JUMPRELEASED;
2564                         if(SpectateNext() == 1) {
2565                                 self.classname = "spectator";
2566                         } else {
2567                                 self.classname = "observer";
2568                                 PutClientInServer();
2569                         }
2570                 } else if (self.BUTTON_ATCK2) {
2571                         self.welcomemessage_time = 0;
2572                         self.flags &~= FL_JUMPRELEASED;
2573                         self.classname = "observer";
2574                         PutClientInServer();
2575                 } else {
2576                         if(!SpectateUpdate())
2577                                 PutObserverInServer();
2578                 }
2579         } else {
2580                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2581                         self.flags |= FL_JUMPRELEASED;
2582                         if(self.flags & FL_SPAWNING)
2583                         {
2584                                 self.flags &~= FL_SPAWNING;
2585                                 LeaveSpectatorMode();
2586                                 return;
2587                         }
2588                 }
2589         }
2590
2591         PrintWelcomeMessage(self);
2592         self.flags |= FL_CLIENT | FL_NOTARGET;
2593 }
2594
2595 .float touchexplode_time;
2596
2597 /*
2598 =============
2599 PlayerPreThink
2600
2601 Called every frame for each client before the physics are run
2602 =============
2603 */
2604 void() ctf_setstatus;
2605 void() nexball_setstatus;
2606 .float items_added;
2607 void PlayerPreThink (void)
2608 {
2609         self.stat_game_starttime = game_starttime;
2610         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2611         self.stat_leadlimit = autocvar_leadlimit;
2612
2613         if(frametime)
2614         {
2615                 // physics frames: update anticheat stuff
2616                 anticheat_prethink();
2617         }
2618
2619         if(blockSpectators && frametime)
2620                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2621                 checkSpectatorBlock();
2622
2623         zoomstate_set = 0;
2624
2625         if(self.netname_previous != self.netname)
2626         {
2627                 if(autocvar_sv_eventlog)
2628                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2629                 if(self.netname_previous)
2630                         strunzone(self.netname_previous);
2631                 self.netname_previous = strzone(self.netname);
2632         }
2633
2634         // version nagging
2635         if(self.version_nagtime)
2636                 if(self.cvar_g_xonoticversion)
2637                         if(time > self.version_nagtime)
2638                         {
2639                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2640                                 {
2641                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2642                                         {
2643                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2644                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2645                                         }
2646                                         else
2647                                         {
2648                                                 float r;
2649                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2650                                                 if(r < 0)
2651                                                 {
2652                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2653                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2654                                                 }
2655                                                 else if(r > 0)
2656                                                 {
2657                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2658                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2659                                                 }
2660                                         }
2661                                 }
2662                                 self.version_nagtime = 0;
2663                         }
2664
2665         // GOD MODE info
2666         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2667         {
2668                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2669                 self.max_armorvalue = 0;
2670         }
2671
2672 #ifdef TETRIS
2673         if (TetrisPreFrame())
2674                 return;
2675 #endif
2676
2677         MUTATOR_CALLHOOK(PlayerPreThink);
2678
2679         if(self.classname == "player") {
2680 //              if(self.netname == "Wazat")
2681 //                      bprint(self.classname, "\n");
2682
2683                 CheckRules_Player();
2684
2685                 PrintWelcomeMessage(self);
2686
2687                 if (intermission_running)
2688                 {
2689                         IntermissionThink ();   // otherwise a button could be missed between
2690                         return;                                 // the think tics
2691                 }
2692
2693                 if(self.teleport_time)
2694                 if(time > self.teleport_time)
2695                 {
2696                         self.teleport_time = 0;
2697                         self.effects = self.effects - (self.effects & EF_NODRAW);
2698                 }
2699
2700                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2701                         UpdateSelectedPlayer();
2702
2703                 //don't allow the player to turn around while game is paused!
2704                 if(timeoutStatus == 2) {
2705                         self.v_angle = self.lastV_angle;
2706                         self.angles = self.lastV_angle;
2707                         self.fixangle = TRUE;
2708                 }
2709
2710                 if(frametime)
2711                 {
2712                         if(self.health <= 0 && autocvar_g_deathglow)
2713                         {
2714                                 if(self.glowmod_x > 0)
2715                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2716                                 else
2717                                         self.glowmod_x = -1;
2718                                 if(self.glowmod_y > 0)
2719                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2720                                 else
2721                                         self.glowmod_y = -1;
2722                                 if(self.glowmod_z > 0)
2723                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2724                                 else
2725                                         self.glowmod_z = -1;
2726                         }
2727                         else
2728                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2729                         player_powerups();
2730                 }
2731
2732                 if (self.deadflag != DEAD_NO)
2733                 {
2734                         float button_pressed, force_respawn;
2735                         if(self.personal && g_race_qualifying)
2736                         {
2737                                 if(time > self.death_time)
2738                                 {
2739                                         self.death_time = time + 1; // only retry once a second
2740                                         respawn();
2741                                         self.impulse = 141;
2742                                 }
2743                         }
2744                         else
2745                         {
2746                                 if(frametime)
2747                                         player_anim();
2748                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2749                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2750                                 if (self.deadflag == DEAD_DYING)
2751                                 {
2752                                         if(force_respawn)
2753                                                 self.deadflag = DEAD_RESPAWNING;
2754                                         else if(!button_pressed)
2755                                                 self.deadflag = DEAD_DEAD;
2756                                 }
2757                                 else if (self.deadflag == DEAD_DEAD)
2758                                 {
2759                                         if(button_pressed)
2760                                                 self.deadflag = DEAD_RESPAWNABLE;
2761                                 }
2762                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2763                                 {
2764                                         if(!button_pressed)
2765                                                 self.deadflag = DEAD_RESPAWNING;
2766                                 }
2767                                 else if (self.deadflag == DEAD_RESPAWNING)
2768                                 {
2769                                         if(time > self.death_time)
2770                                         {
2771                                                 self.death_time = time + 1; // only retry once a second
2772                                                 respawn();
2773                                         }
2774                                 }
2775                                 ShowRespawnCountdown();
2776                         }
2777                         return;
2778                 }
2779
2780                 if(g_touchexplode)
2781                 if(time > self.touchexplode_time)
2782                 if(self.classname == "player")
2783                 if(self.deadflag == DEAD_NO)
2784                 if not(IS_INDEPENDENT_PLAYER(self))
2785                 FOR_EACH_PLAYER(other) if(self != other)
2786                 {
2787                         if(time > other.touchexplode_time)
2788                         if(other.deadflag == DEAD_NO)
2789                         if not(IS_INDEPENDENT_PLAYER(other))
2790                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2791                         {
2792                                 PlayerTouchExplode(self, other);
2793                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2794                         }
2795                 }
2796
2797                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2798                 {
2799                         vector dist;
2800
2801                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2802                         dist = self.prevorigin - self.origin;
2803                         dist_z = 0;
2804                         self.lms_traveled_distance += fabs(vlen(dist));
2805
2806                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2807                         {
2808                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2809                                 self.lms_traveled_distance = 0;
2810                         }
2811
2812                         if(time > self.lms_nextcheck)
2813                         {
2814                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2815                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2816                                 {
2817                                         centerprint(self, autocvar_g_lms_campcheck_message);
2818                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2819                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2820                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2821                                 }
2822                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2823                                 self.lms_traveled_distance = 0;
2824                         }
2825                 }
2826
2827                 self.prevorigin = self.origin;
2828
2829                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2830                 {
2831                         if (!self.crouch)
2832                         {
2833                                 self.crouch = TRUE;
2834                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2835                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2836                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2837                         }
2838                 }
2839                 else
2840                 {
2841                         if (self.crouch)
2842                         {
2843                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2844                                 if (!trace_startsolid)
2845                                 {
2846                                         self.crouch = FALSE;
2847                                         self.view_ofs = PL_VIEW_OFS;
2848                                         setsize (self, PL_MIN, PL_MAX);
2849                                 }
2850                         }
2851                 }
2852
2853                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2854                 {
2855                         if(self.bloodloss_timer < time)
2856                         {
2857                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2858                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2859                         }
2860                 }
2861
2862                 FixPlayermodel();
2863
2864                 GrapplingHookFrame();
2865
2866                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2867                 //if(frametime)
2868                 {
2869                         self.items &~= self.items_added;
2870
2871                         W_WeaponFrame();
2872
2873                         self.items_added = 0;
2874                         if(self.items & IT_JETPACK)
2875                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2876                                         self.items_added |= IT_FUEL;
2877
2878                         self.items |= self.items_added;
2879                 }
2880
2881                 player_regen();
2882
2883                 // rot nex charge to the charge limit
2884                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2885                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2886
2887                 if(frametime)
2888                         player_anim();
2889
2890                 if (g_minstagib)
2891                         minstagib_ammocheck();
2892
2893                 if(g_ctf)
2894                         ctf_setstatus();
2895
2896                 if(g_nexball)
2897                         nexball_setstatus();
2898
2899                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2900
2901                 //self.angles_y=self.v_angle_y + 90;   // temp
2902         } else if(gameover) {
2903                 if (intermission_running)
2904                         IntermissionThink ();   // otherwise a button could be missed between
2905                 return;
2906         } else if(self.classname == "observer") {
2907                 ObserverThink();
2908         } else if(self.classname == "spectator") {
2909                 SpectatorThink();
2910         }
2911
2912         if(!zoomstate_set)
2913                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2914
2915         float oldspectatee_status;
2916         oldspectatee_status = self.spectatee_status;
2917         if(self.classname == "spectator")
2918                 self.spectatee_status = num_for_edict(self.enemy);
2919         else if(self.classname == "observer")
2920                 self.spectatee_status = num_for_edict(self);
2921         else
2922                 self.spectatee_status = 0;
2923         if(self.spectatee_status != oldspectatee_status)
2924         {
2925                 ClientData_Touch(self);
2926                 if(g_race || g_cts)
2927                         race_InitSpectator();
2928         }
2929
2930         if(self.teamkill_soundtime)
2931         if(time > self.teamkill_soundtime)
2932         {
2933                 self.teamkill_soundtime = 0;
2934
2935                 entity oldpusher, oldself;
2936
2937                 oldself = self; self = self.teamkill_soundsource;
2938                 oldpusher = self.pusher; self.pusher = oldself;
2939
2940                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2941
2942                 self.pusher = oldpusher;
2943                 self = oldself;
2944         }
2945
2946         if(self.taunt_soundtime)
2947         if(time > self.taunt_soundtime)
2948         {
2949                 self.taunt_soundtime = 0;
2950                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2951         }
2952
2953         target_voicescript_next(self);
2954 }
2955
2956 float isInvisibleString(string s)
2957 {
2958         float i, n, c;
2959         s = strdecolorize(s);
2960         for((i = 0), (n = strlen(s)); i < n; ++i)
2961         {
2962                 c = str2chr(s, i);
2963                 switch(c)
2964                 {
2965                         case 0:
2966                         case 32: // space
2967                                 break;
2968                         case 192: // charmap space
2969                                 if (!autocvar_utf8_enable)
2970                                         break;
2971                                 return FALSE;
2972                         case 160: // space in unicode fonts
2973                         case 0xE000 + 192: // utf8 charmap space
2974                                 if (autocvar_utf8_enable)
2975                                         break;
2976                         default:
2977                                 return FALSE;
2978                 }
2979         }
2980         return TRUE;
2981 }
2982
2983 /*
2984 =============
2985 PlayerPostThink
2986
2987 Called every frame for each client after the physics are run
2988 =============
2989 */
2990 .float idlekick_lasttimeleft;
2991 .entity showheadshotbbox;
2992 void showheadshotbbox_think()
2993 {
2994         if(self.owner.showheadshotbbox != self)
2995         {
2996                 remove(self);
2997                 return;
2998         }
2999         self.nextthink = time;
3000         setorigin(self, self.owner.origin);
3001         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3002 }
3003 void PlayerPostThink (void)
3004 {
3005         // Savage: Check for nameless players
3006         if (isInvisibleString(self.netname)) {
3007                 self.netname = "Player";
3008                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3009         }
3010
3011         if(sv_maxidle && frametime)
3012         {
3013                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3014                 float timeleft;
3015                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3016                 if(timeleft <= 0)
3017                 {
3018                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3019                         AnnounceTo(self, "terminated");
3020                         dropclient(self);
3021                         return;
3022                 }
3023                 else if(timeleft <= 10)
3024                 {
3025                         if(timeleft != self.idlekick_lasttimeleft)
3026                         {
3027                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3028                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3029                         }
3030                 }
3031                 else
3032                 {
3033                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3034                 }
3035                 self.idlekick_lasttimeleft = timeleft;
3036         }
3037
3038 #ifdef TETRIS
3039         if(self.impulse == 100)
3040                 ImpulseCommands();
3041         if (TetrisPostFrame())
3042                 return;
3043 #endif
3044
3045         CheatFrame();
3046
3047         if(self.classname == "player") {
3048                 CheckRules_Player();
3049                 UpdateChatBubble();
3050                 UpdateTeamBubble();
3051                 if (self.impulse)
3052                         ImpulseCommands();
3053                 if (intermission_running)
3054                         return;         // intermission or finale
3055                 GetPressedKeys();
3056         } else if (self.classname == "observer") {
3057                 //do nothing
3058         } else if (self.classname == "spectator") {
3059                 //do nothing
3060         }
3061
3062         /*
3063         float i;
3064         for(i = 0; i < 1000; ++i)
3065         {
3066                 vector end;
3067                 end = self.origin + '0 0 1024' + 512 * randomvec();
3068                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3069                 if(trace_fraction < 1)
3070                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3071                 {
3072                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3073                         break;
3074                 }
3075         }
3076         */
3077
3078         Arena_Warmup();
3079
3080         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3081
3082         if(self.waypointsprite_attachedforcarrier)
3083                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3084
3085         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3086         {
3087                 if(!self.showheadshotbbox)
3088                 {
3089                         self.showheadshotbbox = spawn();
3090                         self.showheadshotbbox.classname = "headshotbbox";
3091                         self.showheadshotbbox.owner = self;
3092                         self.showheadshotbbox.think = showheadshotbbox_think;
3093                         self.showheadshotbbox.nextthink = time;
3094                         self = self.showheadshotbbox;
3095                         self.think();
3096                         self = self.owner;
3097                 }
3098         }
3099         else
3100         {
3101                 if(self.showheadshotbbox)
3102                         remove(self.showheadshotbbox);
3103         }
3104
3105         playerdemo_write();
3106
3107         if((g_cts || g_race) && self.cvar_cl_allow_uid2name == 1)
3108         {
3109                 if(!self.stored_netname)
3110                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3111                 if(self.stored_netname != self.netname)
3112                 {
3113                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3114                         strunzone(self.stored_netname);
3115                         self.stored_netname = strzone(self.netname);
3116                 }
3117         }
3118
3119         /*
3120         if(g_race)
3121                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3122         */
3123 }