qcsrc/server/cl_client.qc

   1 #include "waypointsprites.qh"
   2
   3 #include "cl_impulse.qh"
   4 #include "cl_player.qh"
   5 #include "ent_cs.qh"
   6 #include "g_subs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "secret.qh"
  13
  14 #include "bot/bot.qh"
  15 #include "bot/navigation.qh"
  16
  17 #include "weapons/hitplot.qh"
  18 #include "weapons/weaponsystem.qh"
  19
  20 #include "../common/net_notice.qh"
  21
  22 #include "../common/monsters/sv_monsters.qh"
  23
  24 #include "../warpzonelib/server.qh"
  25
  26 float c1, c2, c3, c4;
  27
  28 void send_CSQC_teamnagger() {
  29         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  30         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  31 }
  32
  33 float ClientData_Send(entity to, int sf)
  34 {
  35         if(to != self.owner)
  36         {
  37                 error("wtf");
  38                 return false;
  39         }
  40
  41         entity e;
  42
  43         e = to;
  44         if(IS_SPEC(to))
  45                 e = to.enemy;
  46
  47         sf = 0;
  48
  49         if(e.race_completed)
  50                 sf |= 1; // forced scoreboard
  51         if(to.spectatee_status)
  52                 sf |= 2; // spectator ent number follows
  53         if(e.zoomstate)
  54                 sf |= 4; // zoomed
  55         if(e.porto_v_angle_held)
  56                 sf |= 8; // angles held
  57
  58         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  59         WriteByte(MSG_ENTITY, sf);
  60
  61         if(sf & 2)
  62                 WriteByte(MSG_ENTITY, to.spectatee_status);
  63
  64         if(sf & 8)
  65         {
  66                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  67                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  68         }
  69
  70         return true;
  71 }
  72
  73 void ClientData_Attach()
  74 {
  75         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  76         self.clientdata.drawonlytoclient = self;
  77         self.clientdata.owner = self;
  78 }
  79
  80 void ClientData_Detach()
  81 {
  82         remove(self.clientdata);
  83         self.clientdata = world;
  84 }
  85
  86 void ClientData_Touch(entity e)
  87 {
  88         e.clientdata.SendFlags = 1;
  89
  90         // make it spectatable
  91         entity e2;
  92         FOR_EACH_REALCLIENT(e2)
  93         {
  94                 if(e2 != e)
  95                         if(IS_SPEC(e2))
  96                                 if(e2.enemy == e)
  97                                         e2.clientdata.SendFlags = 1;
  98         }
  99 }
 100
 101 .string netname_previous;
 102
 103 void SetSpectator(entity player, entity spectatee);
 104
 105
 106 /*
 107 =============
 108 CheckPlayerModel
 109
 110 Checks if the argument string can be a valid playermodel.
 111 Returns a valid one in doubt.
 112 =============
 113 */
 114 string FallbackPlayerModel;
 115 string CheckPlayerModel(string plyermodel) {
 116         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 117         {
 118                 // note: we cannot summon Don Strunzone here, some player may
 119                 // still have the model string set. In case anyone manages how
 120                 // to change a cvar default, we'll have a small leak here.
 121                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 122         }
 123         // only in right path
 124         if( substring(plyermodel,0,14) != "models/player/")
 125                 return FallbackPlayerModel;
 126         // only good file extensions
 127         if(substring(plyermodel,-4,4) != ".zym")
 128         if(substring(plyermodel,-4,4) != ".dpm")
 129         if(substring(plyermodel,-4,4) != ".iqm")
 130         if(substring(plyermodel,-4,4) != ".md3")
 131         if(substring(plyermodel,-4,4) != ".psk")
 132                 return FallbackPlayerModel;
 133         // forbid the LOD models
 134         if(substring(plyermodel, -9,5) == "_lod1")
 135                 return FallbackPlayerModel;
 136         if(substring(plyermodel, -9,5) == "_lod2")
 137                 return FallbackPlayerModel;
 138         if(plyermodel != strtolower(plyermodel))
 139                 return FallbackPlayerModel;
 140         // also, restrict to server models
 141         if(autocvar_sv_servermodelsonly)
 142         {
 143                 if(!fexists(plyermodel))
 144                         return FallbackPlayerModel;
 145         }
 146         return plyermodel;
 147 }
 148
 149 void setplayermodel(entity e, string modelname)
 150 {
 151         precache_model(modelname);
 152         setmodel(e, modelname);
 153         player_setupanimsformodel();
 154         UpdatePlayerSounds();
 155 }
 156
 157 /*
 158 =============
 159 PutObserverInServer
 160
 161 putting a client as observer in the server
 162 =============
 163 */
 164 void FixPlayermodel();
 165 void PutObserverInServer (void)
 166 {
 167         entity  spot;
 168     self.hud = HUD_NORMAL;
 169
 170         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 171
 172         spot = SelectSpawnPoint (true);
 173         if(!spot)
 174                 error("No spawnpoints for observers?!?\n");
 175         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 176
 177         if(IS_REAL_CLIENT(self))
 178         {
 179                 msg_entity = self;
 180                 WriteByte(MSG_ONE, SVC_SETVIEW);
 181                 WriteEntity(MSG_ONE, self);
 182         }
 183
 184         self.frags = FRAGS_SPECTATOR;
 185
 186         MUTATOR_CALLHOOK(MakePlayerObserver);
 187
 188         Portal_ClearAll(self);
 189
 190         Unfreeze(self);
 191
 192         if(self.alivetime)
 193         {
 194                 if(!warmup_stage)
 195                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 196                 self.alivetime = 0;
 197         }
 198
 199         if(self.vehicle)
 200                 vehicles_exit(VHEF_RELESE);
 201
 202         WaypointSprite_PlayerDead();
 203
 204         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 205                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 206
 207         if(self.killcount != -666)
 208         {
 209                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 210                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 211                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 212
 213                 if(self.just_joined == false) {
 214                         LogTeamchange(self.playerid, -1, 4);
 215                 } else
 216                         self.just_joined = false;
 217         }
 218
 219         PlayerScore_Clear(self); // clear scores when needed
 220
 221         accuracy_resend(self);
 222
 223         self.spectatortime = time;
 224
 225         self.classname = "observer";
 226         self.iscreature = false;
 227         self.teleportable = TELEPORT_SIMPLE;
 228         self.damagedbycontents = false;
 229         self.health = -666;
 230         self.takedamage = DAMAGE_NO;
 231         self.solid = SOLID_NOT;
 232         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 233         self.flags = FL_CLIENT | FL_NOTARGET;
 234         self.armorvalue = 666;
 235         self.effects = 0;
 236         self.armorvalue = autocvar_g_balance_armor_start;
 237         self.pauserotarmor_finished = 0;
 238         self.pauserothealth_finished = 0;
 239         self.pauseregen_finished = 0;
 240         self.damageforcescale = 0;
 241         self.death_time = 0;
 242         self.respawn_flags = 0;
 243         self.respawn_time = 0;
 244         self.stat_respawn_time = 0;
 245         self.alpha = 0;
 246         self.scale = 0;
 247         self.fade_time = 0;
 248         self.pain_frame = 0;
 249         self.pain_finished = 0;
 250         self.strength_finished = 0;
 251         self.invincible_finished = 0;
 252         self.superweapons_finished = 0;
 253         self.pushltime = 0;
 254         self.istypefrag = 0;
 255         self.think = func_null;
 256         self.nextthink = 0;
 257         self.hook_time = 0;
 258         self.deadflag = DEAD_NO;
 259         self.angles = spot.angles;
 260         self.angles_z = 0;
 261         self.fixangle = true;
 262         self.crouch = false;
 263         self.revival_time = 0;
 264
 265         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 266         self.prevorigin = self.origin;
 267         self.items = 0;
 268         self.weapons = '0 0 0';
 269         self.model = "";
 270         FixPlayermodel();
 271         setmodel(self, "null");
 272         self.drawonlytoclient = self;
 273
 274         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 275         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 276
 277         self.weapon = 0;
 278         self.weaponname = "";
 279         self.switchingweapon = 0;
 280         self.weaponmodel = "";
 281         self.weaponentity = world;
 282         self.exteriorweaponentity = world;
 283         self.killcount = -666;
 284         self.velocity = '0 0 0';
 285         self.avelocity = '0 0 0';
 286         self.punchangle = '0 0 0';
 287         self.punchvector = '0 0 0';
 288         self.oldvelocity = self.velocity;
 289         self.fire_endtime = -1;
 290         self.event_damage = func_null;
 291 }
 292
 293 .float model_randomizer;
 294 void FixPlayermodel()
 295 {
 296         string defaultmodel;
 297         float defaultskin, chmdl, oldskin, n, i;
 298         vector m1, m2;
 299
 300         defaultmodel = "";
 301         defaultskin = 0;
 302         chmdl = false;
 303
 304         if(autocvar_sv_defaultcharacter == 1)
 305         {
 306                 if(teamplay)
 307                 {
 308                         string s;
 309                         s = Static_Team_ColorName_Lower(self.team);
 310                         if(s != "neutral")
 311                         {
 312                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 313                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 314                         }
 315                 }
 316
 317                 if(defaultmodel == "")
 318                 {
 319                         defaultmodel = autocvar_sv_defaultplayermodel;
 320                         defaultskin = autocvar_sv_defaultplayerskin;
 321                 }
 322
 323                 n = tokenize_console(defaultmodel);
 324                 if(n > 0)
 325                 {
 326                         defaultmodel = argv(floor(n * self.model_randomizer));
 327                         // However, do NOT randomize if the player-selected model is in the list.
 328                         for (i = 0; i < n; ++i)
 329                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 330                                         defaultmodel = argv(i);
 331                 }
 332
 333                 i = strstrofs(defaultmodel, ":", 0);
 334                 if(i >= 0)
 335                 {
 336                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 337                         defaultmodel = substring(defaultmodel, 0, i);
 338                 }
 339         }
 340
 341         if(defaultmodel != "")
 342         {
 343                 if (defaultmodel != self.model)
 344                 {
 345                         m1 = self.mins;
 346                         m2 = self.maxs;
 347                         setplayermodel (self, defaultmodel);
 348                         setsize (self, m1, m2);
 349                         chmdl = true;
 350                 }
 351
 352                 oldskin = self.skin;
 353                 self.skin = defaultskin;
 354         } else {
 355                 if (self.playermodel != self.model || self.playermodel == "")
 356                 {
 357                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 358                         m1 = self.mins;
 359                         m2 = self.maxs;
 360                         setplayermodel (self, self.playermodel);
 361                         setsize (self, m1, m2);
 362                         chmdl = true;
 363                 }
 364
 365                 oldskin = self.skin;
 366                 self.skin = stof(self.playerskin);
 367         }
 368
 369         if(chmdl || oldskin != self.skin) // model or skin has changed
 370         {
 371                 self.species = player_getspecies(); // update species
 372                 UpdatePlayerSounds(); // update skin sounds
 373         }
 374
 375         if(!teamplay)
 376                 if(strlen(autocvar_sv_defaultplayercolors))
 377                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 378                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 379 }
 380
 381 /*
 382 =============
 383 PutClientInServer
 384
 385 Called when a client spawns in the server
 386 =============
 387 */
 388 void PutClientInServer (void)
 389 {
 390         if(IS_BOT_CLIENT(self))
 391                 self.classname = "player";
 392         else if(IS_REAL_CLIENT(self))
 393         {
 394                 msg_entity = self;
 395                 WriteByte(MSG_ONE, SVC_SETVIEW);
 396                 WriteEntity(MSG_ONE, self);
 397         }
 398
 399         SetSpectator(self, world);
 400
 401         // reset player keys
 402         self.itemkeys = 0;
 403
 404         MUTATOR_CALLHOOK(PutClientInServer);
 405
 406         if(gameover)
 407                 self.classname = "observer";
 408
 409         if(IS_PLAYER(self))
 410         {
 411                 entity spot, oldself;
 412                 float j;
 413
 414                 accuracy_resend(self);
 415
 416                 if(self.team < 0)
 417                         JoinBestTeam(self, false, true);
 418
 419                 spot = SelectSpawnPoint (false);
 420                 if(!spot)
 421                 {
 422                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 423                         return; // spawn failed
 424                 }
 425
 426                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 427
 428                 if(self.vehicle)
 429                         vehicles_exit(VHEF_RELESE);
 430
 431                 self.classname = "player";
 432                 self.wasplayer = true;
 433                 self.iscreature = true;
 434                 self.teleportable = TELEPORT_NORMAL;
 435                 self.damagedbycontents = true;
 436                 self.movetype = MOVETYPE_WALK;
 437                 self.solid = SOLID_SLIDEBOX;
 438                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 439                 if(autocvar_g_playerclip_collisions)
 440                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 441                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 442                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 443                 self.frags = FRAGS_PLAYER;
 444                 if(INDEPENDENT_PLAYERS)
 445                         MAKE_INDEPENDENT_PLAYER(self);
 446                 self.flags = FL_CLIENT;
 447                 if(autocvar__notarget)
 448                         self.flags |= FL_NOTARGET;
 449                 self.takedamage = DAMAGE_AIM;
 450                 self.effects = 0;
 451                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 452                 self.air_finished = time + 12;
 453                 self.dmg = 2;
 454                 if(WEP_CVAR(vortex, charge))
 455                 {
 456                         if(WEP_CVAR_SEC(vortex, chargepool))
 457                                 self.vortex_chargepool_ammo = 1;
 458                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 459                 }
 460
 461                 if(warmup_stage)
 462                 {
 463                         self.ammo_shells = warmup_start_ammo_shells;
 464                         self.ammo_nails = warmup_start_ammo_nails;
 465                         self.ammo_rockets = warmup_start_ammo_rockets;
 466                         self.ammo_cells = warmup_start_ammo_cells;
 467                         self.ammo_plasma = warmup_start_ammo_plasma;
 468                         self.ammo_fuel = warmup_start_ammo_fuel;
 469                         self.health = warmup_start_health;
 470                         self.armorvalue = warmup_start_armorvalue;
 471                         self.weapons = WARMUP_START_WEAPONS;
 472                 }
 473                 else
 474                 {
 475                         self.ammo_shells = start_ammo_shells;
 476                         self.ammo_nails = start_ammo_nails;
 477                         self.ammo_rockets = start_ammo_rockets;
 478                         self.ammo_cells = start_ammo_cells;
 479                         self.ammo_plasma = start_ammo_plasma;
 480                         self.ammo_fuel = start_ammo_fuel;
 481                         self.health = start_health;
 482                         self.armorvalue = start_armorvalue;
 483                         self.weapons = start_weapons;
 484                 }
 485
 486                 if(self.weapons & WEPSET_SUPERWEAPONS)
 487                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 488                 else
 489                         self.superweapons_finished = 0;
 490
 491                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 492                 {
 493                         if(g_weaponarena_random_with_blaster)
 494                                 self.weapons &= ~WEPSET_BLASTER;
 495                         W_RandomWeapons(self, g_weaponarena_random);
 496                         if(g_weaponarena_random_with_blaster)
 497                                 self.weapons |= WEPSET_BLASTER;
 498                 }
 499
 500                 self.items = start_items;
 501
 502                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 503                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 504                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 505                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 506                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 507                 //extend the pause of rotting if client was reset at the beginning of the countdown
 508                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 509                         self.spawnshieldtime += game_starttime - time;
 510                         self.pauserotarmor_finished += game_starttime - time;
 511                         self.pauserothealth_finished += game_starttime - time;
 512                         self.pauseregen_finished += game_starttime - time;
 513                 }
 514                 self.damageforcescale = 2;
 515                 self.death_time = 0;
 516                 self.respawn_flags = 0;
 517                 self.respawn_time = 0;
 518                 self.stat_respawn_time = 0;
 519                 self.scale = 0;
 520                 self.fade_time = 0;
 521                 self.pain_frame = 0;
 522                 self.pain_finished = 0;
 523                 self.strength_finished = 0;
 524                 self.invincible_finished = 0;
 525                 self.pushltime = 0;
 526                 // players have no think function
 527                 self.think = func_null;
 528                 self.nextthink = 0;
 529                 self.hook_time = 0;
 530                 self.dmg_team = 0;
 531                 self.ballistics_density = autocvar_g_ballistics_density_player;
 532
 533                 self.metertime = 0;
 534
 535                 self.deadflag = DEAD_NO;
 536
 537                 self.angles = spot.angles;
 538
 539                 self.angles_z = 0; // never spawn tilted even if the spot says to
 540                 if(IS_BOT_CLIENT(self))
 541                         self.v_angle = self.angles;
 542                 self.fixangle = true; // turn this way immediately
 543                 self.velocity = '0 0 0';
 544                 self.avelocity = '0 0 0';
 545                 self.punchangle = '0 0 0';
 546                 self.punchvector = '0 0 0';
 547                 self.oldvelocity = self.velocity;
 548                 self.fire_endtime = -1;
 549                 self.revival_time = 0;
 550
 551                 entity spawnevent = spawn();
 552                 spawnevent.owner = self;
 553                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 554
 555                 // Cut off any still running player sounds.
 556                 stopsound(self, CH_PLAYER_SINGLE);
 557
 558                 self.model = "";
 559                 FixPlayermodel();
 560                 self.drawonlytoclient = world;
 561
 562                 self.crouch = false;
 563                 self.view_ofs = PL_VIEW_OFS;
 564                 setsize (self, PL_MIN, PL_MAX);
 565                 self.spawnorigin = spot.origin;
 566                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 567                 // don't reset back to last position, even if new position is stuck in solid
 568                 self.oldorigin = self.origin;
 569                 self.prevorigin = self.origin;
 570                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 571                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 572         self.hud = HUD_NORMAL;
 573
 574                 self.event_damage = PlayerDamage;
 575
 576                 self.bot_attack = true;
 577                 self.monster_attack = true;
 578
 579                 self.spider_slowness = 0;
 580
 581                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 582
 583                 if(self.killcount == -666) {
 584                         PlayerScore_Clear(self);
 585                         self.killcount = 0;
 586                 }
 587
 588                 CL_SpawnWeaponentity();
 589                 self.alpha = default_player_alpha;
 590                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 591                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 592
 593                 self.speedrunning = false;
 594
 595                 //stuffcmd(self, "chase_active 0");
 596                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 597
 598                 target_voicescript_clear(self);
 599
 600                 // reset fields the weapons may use
 601                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 602                 {
 603                         WEP_ACTION(j, WR_RESETPLAYER);
 604
 605                         // all weapons must be fully loaded when we spawn
 606                         entity e = get_weaponinfo(j);
 607                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 608                                 self.(weapon_load[j]) = e.reloading_ammo;
 609                 }
 610
 611                 oldself = self;
 612                 self = spot;
 613                         activator = oldself;
 614                                 string s;
 615                                 s = self.target;
 616                                 self.target = string_null;
 617                                 SUB_UseTargets();
 618                                 self.target = s;
 619                         activator = world;
 620                 self = oldself;
 621
 622                 Unfreeze(self);
 623
 624                 spawn_spot = spot;
 625                 MUTATOR_CALLHOOK(PlayerSpawn);
 626
 627                 if(autocvar_spawn_debug)
 628                 {
 629                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 630                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 631                 }
 632
 633                 self.switchweapon = w_getbestweapon(self);
 634                 self.cnt = -1; // W_LastWeapon will not complain
 635                 self.weapon = 0;
 636                 self.weaponname = "";
 637                 self.switchingweapon = 0;
 638
 639                 if(!warmup_stage)
 640                         if(!self.alivetime)
 641                                 self.alivetime = time;
 642
 643                 antilag_clear(self);
 644         }
 645         else if(IS_OBSERVER(self))
 646         {
 647                 PutObserverInServer ();
 648         }
 649 }
 650
 651 .float ebouncefactor, ebouncestop; // electro's values
 652 // TODO do we need all these fields, or should we stop autodetecting runtime
 653 // changes and just have a console command to update this?
 654 float ClientInit_SendEntity(entity to, float sf)
 655 {
 656         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 657         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 658         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 659         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 660         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 661         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 662         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 663         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 664         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 665         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 666
 667         if(sv_foginterval && world.fog != "")
 668                 WriteString(MSG_ENTITY, world.fog);
 669         else
 670                 WriteString(MSG_ENTITY, "");
 671         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 672         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 673         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 674         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 675         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 676         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 677         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 678         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 679         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 680         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 681         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 682         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 683         return true;
 684 }
 685
 686 void ClientInit_CheckUpdate()
 687 {
 688         self.nextthink = time;
 689         if(self.count != autocvar_g_balance_armor_blockpercent)
 690         {
 691                 self.count = autocvar_g_balance_armor_blockpercent;
 692                 self.SendFlags |= 1;
 693         }
 694         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 695         {
 696                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 697                 self.SendFlags |= 1;
 698         }
 699         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 700         {
 701                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 702                 self.SendFlags |= 1;
 703         }
 704         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 705         {
 706                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 707                 self.SendFlags |= 1;
 708         }
 709         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 710         {
 711                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 712                 self.SendFlags |= 1;
 713         }
 714 }
 715
 716 void ClientInit_Spawn()
 717 {
 718         entity o;
 719         entity e;
 720         e = spawn();
 721         e.classname = "clientinit";
 722         e.think = ClientInit_CheckUpdate;
 723         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 724
 725         o = self;
 726         self = e;
 727         ClientInit_CheckUpdate();
 728         self = o;
 729 }
 730
 731 /*
 732 =============
 733 SetNewParms
 734 =============
 735 */
 736 void SetNewParms (void)
 737 {
 738         // initialize parms for a new player
 739         parm1 = -(86400 * 366);
 740 }
 741
 742 /*
 743 =============
 744 SetChangeParms
 745 =============
 746 */
 747 void SetChangeParms (void)
 748 {
 749         // save parms for level change
 750         parm1 = self.parm_idlesince - time;
 751 }
 752
 753 /*
 754 =============
 755 DecodeLevelParms
 756 =============
 757 */
 758 void DecodeLevelParms (void)
 759 {
 760         // load parms
 761         self.parm_idlesince = parm1;
 762         if(self.parm_idlesince == -(86400 * 366))
 763                 self.parm_idlesince = time;
 764
 765         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 766         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 767 }
 768
 769 /*
 770 =============
 771 ClientKill
 772
 773 Called when a client types 'kill' in the console
 774 =============
 775 */
 776
 777 .float clientkill_nexttime;
 778 void ClientKill_Now_TeamChange()
 779 {
 780         if(self.killindicator_teamchange == -1)
 781         {
 782                 JoinBestTeam( self, false, true );
 783         }
 784         else if(self.killindicator_teamchange == -2)
 785         {
 786                 if(blockSpectators)
 787                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 788                 PutObserverInServer();
 789         }
 790         else
 791                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 792         self.killindicator_teamchange = 0;
 793 }
 794
 795 void ClientKill_Now()
 796 {
 797         if(self.vehicle)
 798         {
 799             vehicles_exit(VHEF_RELESE);
 800             if(!self.killindicator_teamchange)
 801             {
 802             self.vehicle_health = -1;
 803             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 804             }
 805         }
 806
 807         if(self.killindicator && !wasfreed(self.killindicator))
 808                 remove(self.killindicator);
 809
 810         self.killindicator = world;
 811
 812         if(self.killindicator_teamchange)
 813                 ClientKill_Now_TeamChange();
 814
 815         if(IS_PLAYER(self))
 816                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 817
 818         // now I am sure the player IS dead
 819 }
 820 void KillIndicator_Think()
 821 {
 822         if (gameover)
 823         {
 824                 self.owner.killindicator = world;
 825                 remove(self);
 826                 return;
 827         }
 828
 829         if (self.owner.alpha < 0 && !self.owner.vehicle)
 830         {
 831                 self.owner.killindicator = world;
 832                 remove(self);
 833                 return;
 834         }
 835
 836         if(self.cnt <= 0)
 837         {
 838                 self = self.owner;
 839                 ClientKill_Now(); // no oldself needed
 840                 return;
 841         }
 842     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 843     {
 844         self.nextthink = time + 1;
 845         self.cnt -= 1;
 846     }
 847         else
 848         {
 849                 if(self.cnt <= 10)
 850                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 851                 if(IS_REAL_CLIENT(self.owner))
 852                 {
 853                         if(self.cnt <= 10)
 854                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 855                 }
 856                 self.nextthink = time + 1;
 857                 self.cnt -= 1;
 858         }
 859 }
 860
 861 float clientkilltime;
 862 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 863 {
 864         float killtime;
 865         float starttime;
 866         entity e;
 867
 868         if (gameover)
 869                 return;
 870
 871         killtime = autocvar_g_balance_kill_delay;
 872
 873         if(g_race_qualifying || g_cts)
 874                 killtime = 0;
 875
 876     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 877     {
 878                 remove(self.killindicator);
 879                 self.killindicator = world;
 880
 881         ClientKill_Now(); // allow instant kill in this case
 882         return;
 883     }
 884
 885         self.killindicator_teamchange = targetteam;
 886
 887     if(!self.killindicator)
 888         {
 889                 if(self.deadflag == DEAD_NO)
 890                 {
 891                         killtime = max(killtime, self.clientkill_nexttime - time);
 892                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 893                 }
 894
 895                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 896                 {
 897                         ClientKill_Now();
 898                 }
 899                 else
 900                 {
 901                         starttime = max(time, clientkilltime);
 902
 903                         self.killindicator = spawn();
 904                         self.killindicator.owner = self;
 905                         self.killindicator.scale = 0.5;
 906                         setattachment(self.killindicator, self, "");
 907                         setorigin(self.killindicator, '0 0 52');
 908                         self.killindicator.think = KillIndicator_Think;
 909                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 910                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 911                         self.killindicator.cnt = ceil(killtime);
 912                         self.killindicator.count = bound(0, ceil(killtime), 10);
 913                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 914
 915                         for(e = world; (e = find(e, classname, "body")) != world; )
 916                         {
 917                                 if(e.enemy != self)
 918                                         continue;
 919                                 e.killindicator = spawn();
 920                                 e.killindicator.owner = e;
 921                                 e.killindicator.scale = 0.5;
 922                                 setattachment(e.killindicator, e, "");
 923                                 setorigin(e.killindicator, '0 0 52');
 924                                 e.killindicator.think = KillIndicator_Think;
 925                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 926                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 927                                 e.killindicator.cnt = ceil(killtime);
 928                         }
 929                         self.lip = 0;
 930                 }
 931         }
 932         if(self.killindicator)
 933         {
 934                 if(targetteam == 0) // just die
 935                 {
 936                         self.killindicator.colormod = '0 0 0';
 937                         if(IS_REAL_CLIENT(self))
 938                         if(self.killindicator.cnt > 0)
 939                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 940                 }
 941                 else if(targetteam == -1) // auto
 942                 {
 943                         self.killindicator.colormod = '0 1 0';
 944                         if(IS_REAL_CLIENT(self))
 945                         if(self.killindicator.cnt > 0)
 946                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 947                 }
 948                 else if(targetteam == -2) // spectate
 949                 {
 950                         self.killindicator.colormod = '0.5 0.5 0.5';
 951                         if(IS_REAL_CLIENT(self))
 952                         if(self.killindicator.cnt > 0)
 953                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 954                 }
 955                 else
 956                 {
 957                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 958                         if(IS_REAL_CLIENT(self))
 959                         if(self.killindicator.cnt > 0)
 960                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 961                 }
 962         }
 963
 964 }
 965
 966 void ClientKill (void)
 967 {
 968         if(gameover) return;
 969         if(self.player_blocked) return;
 970         if(self.frozen) return;
 971
 972         ClientKill_TeamChange(0);
 973 }
 974
 975 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 976 {
 977     e.killindicator = spawn();
 978     e.killindicator.owner = e;
 979     e.killindicator.think = KillIndicator_Think;
 980     e.killindicator.nextthink = time + (e.lip) * 0.05;
 981     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 982     e.killindicator.health = 1; // this is used to indicate that it should be silent
 983     e.lip = 0;
 984 }
 985
 986 void FixClientCvars(entity e)
 987 {
 988         // send prediction settings to the client
 989         stuffcmd(e, "\nin_bindmap 0 0\n");
 990         if(g_race || g_cts)
 991                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 992         if(autocvar_g_antilag == 3) // client side hitscan
 993                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 994         if(autocvar_sv_gentle)
 995                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 996 }
 997
 998 float PlayerInIDList(entity p, string idlist)
 999 {
1000         float n, i;
1001         string s;
1002
1003         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1004         if (!p.crypto_idfp)
1005                 return 0;
1006
1007         // this function allows abbreviated player IDs too!
1008         n = tokenize_console(idlist);
1009         for(i = 0; i < n; ++i)
1010         {
1011                 s = argv(i);
1012                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1013                         return 1;
1014         }
1015
1016         return 0;
1017 }
1018
1019 #ifdef DP_EXT_PRECONNECT
1020 /*
1021 =============
1022 ClientPreConnect
1023
1024 Called once (not at each match start) when a client begins a connection to the server
1025 =============
1026 */
1027 void ClientPreConnect (void)
1028 {
1029         if(autocvar_sv_eventlog)
1030         {
1031                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1032                         self.playerid,
1033                         num_for_edict(self),
1034                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1035                 ));
1036         }
1037 }
1038 #endif
1039
1040 /*
1041 =============
1042 ClientConnect
1043
1044 Called when a client connects to the server
1045 =============
1046 */
1047 void DecodeLevelParms (void);
1048 //void dom_player_join_team(entity pl);
1049 void set_dom_state(entity e);
1050 void ClientConnect (void)
1051 {
1052         float t;
1053
1054         if(IS_CLIENT(self))
1055         {
1056                 print("Warning: ClientConnect, but already connected!\n");
1057                 return;
1058         }
1059
1060         if(Ban_MaybeEnforceBanOnce(self))
1061                 return;
1062
1063         DecodeLevelParms();
1064
1065 #ifdef WATERMARK
1066         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1067 #endif
1068
1069         self.classname = "player_joining";
1070
1071         self.flags = FL_CLIENT;
1072         self.version_nagtime = time + 10 + random() * 10;
1073
1074         if(player_count<0)
1075         {
1076                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1077                 player_count = 0;
1078         }
1079
1080         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1081
1082         PlayerScore_Attach(self);
1083         ClientData_Attach();
1084         accuracy_init(self);
1085
1086         bot_clientconnect();
1087
1088         playerdemo_init();
1089
1090         anticheat_init();
1091
1092         // identify the right forced team
1093         if(autocvar_g_campaign)
1094         {
1095                 if(IS_REAL_CLIENT(self)) // only players, not bots
1096                 {
1097                         switch(autocvar_g_campaign_forceteam)
1098                         {
1099                                 case 1: self.team_forced = NUM_TEAM_1; break;
1100                                 case 2: self.team_forced = NUM_TEAM_2; break;
1101                                 case 3: self.team_forced = NUM_TEAM_3; break;
1102                                 case 4: self.team_forced = NUM_TEAM_4; break;
1103                                 default: self.team_forced = 0;
1104                         }
1105                 }
1106         }
1107         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1108                 self.team_forced = NUM_TEAM_1;
1109         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1110                 self.team_forced = NUM_TEAM_2;
1111         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1112                 self.team_forced = NUM_TEAM_3;
1113         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1114                 self.team_forced = NUM_TEAM_4;
1115         else if(autocvar_g_forced_team_otherwise == "red")
1116                 self.team_forced = NUM_TEAM_1;
1117         else if(autocvar_g_forced_team_otherwise == "blue")
1118                 self.team_forced = NUM_TEAM_2;
1119         else if(autocvar_g_forced_team_otherwise == "yellow")
1120                 self.team_forced = NUM_TEAM_3;
1121         else if(autocvar_g_forced_team_otherwise == "pink")
1122                 self.team_forced = NUM_TEAM_4;
1123         else if(autocvar_g_forced_team_otherwise == "spectate")
1124                 self.team_forced = -1;
1125         else if(autocvar_g_forced_team_otherwise == "spectator")
1126                 self.team_forced = -1;
1127         else
1128                 self.team_forced = 0;
1129
1130         if(!teamplay)
1131                 if(self.team_forced > 0)
1132                         self.team_forced = 0;
1133
1134         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1135
1136         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1137                 self.classname = "observer";
1138         } else {
1139                 if(teamplay)
1140                 {
1141                         if(autocvar_g_balance_teams)
1142                         {
1143                                 self.classname = "player";
1144                                 campaign_bots_may_start = 1;
1145                         }
1146                         else
1147                         {
1148                                 self.classname = "observer"; // do it anyway
1149                         }
1150                 }
1151                 else
1152                 {
1153                         self.classname = "player";
1154                         campaign_bots_may_start = 1;
1155                 }
1156         }
1157
1158         self.playerid = (playerid_last = playerid_last + 1);
1159
1160         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1161
1162     if(IS_BOT_CLIENT(self))
1163         PlayerStats_GameReport_AddPlayer(self);
1164
1165         if(autocvar_sv_eventlog)
1166                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1167
1168         LogTeamchange(self.playerid, self.team, 1);
1169
1170         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1171
1172         self.netname_previous = strzone(self.netname);
1173
1174         if(IS_PLAYER(self) && teamplay)
1175                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1176         else
1177                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1178
1179         stuffcmd(self, strcat(clientstuff, "\n"));
1180         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1181
1182         FixClientCvars(self);
1183
1184         // spawnfunc_waypoint sprites
1185         WaypointSprite_InitClient(self);
1186
1187         // Wazat's grappling hook
1188         SetGrappleHookBindings();
1189
1190         // Jetpack binds
1191         stuffcmd(self, "alias +jetpack +button10\n");
1192         stuffcmd(self, "alias -jetpack -button10\n");
1193
1194         // get version info from player
1195         stuffcmd(self, "cmd clientversion $gameversion\n");
1196
1197         // get other cvars from player
1198         GetCvars(0);
1199
1200         // notify about available teams
1201         if(teamplay)
1202         {
1203                 CheckAllowedTeams(self);
1204                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1205                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1206         }
1207         else
1208                 stuffcmd(self, "set _teams_available 0\n");
1209
1210         attach_entcs();
1211
1212         bot_relinkplayerlist();
1213
1214         self.spectatortime = time;
1215         if(blockSpectators)
1216         {
1217                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1218         }
1219
1220         self.jointime = time;
1221         self.allowed_timeouts = autocvar_sv_timeout_number;
1222
1223         if(IS_REAL_CLIENT(self))
1224         {
1225                 if(!autocvar_g_campaign)
1226                 {
1227                         self.motd_actived_time = -1;
1228                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1229                 }
1230
1231                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1232                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1233         }
1234
1235         if(!sv_foginterval && world.fog != "")
1236                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1237
1238         W_HitPlotOpen(self);
1239
1240         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1241                 send_CSQC_teamnagger();
1242
1243         CheatInitClient();
1244
1245         CSQCMODEL_AUTOINIT();
1246
1247         self.model_randomizer = random();
1248
1249         if(IS_REAL_CLIENT(self))
1250                 sv_notice_join();
1251
1252         MUTATOR_CALLHOOK(ClientConnect);
1253 }
1254 /*
1255 =============
1256 ClientDisconnect
1257
1258 Called when a client disconnects from the server
1259 =============
1260 */
1261 .entity chatbubbleentity;
1262 void ReadyCount();
1263 void ClientDisconnect (void)
1264 {
1265         if(self.vehicle)
1266             vehicles_exit(VHEF_RELESE);
1267
1268         if (!IS_CLIENT(self))
1269         {
1270                 print("Warning: ClientDisconnect without ClientConnect\n");
1271                 return;
1272         }
1273
1274         PlayerStats_GameReport_FinalizePlayer(self);
1275
1276         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1277
1278         CheatShutdownClient();
1279
1280         W_HitPlotClose(self);
1281
1282         anticheat_report();
1283         anticheat_shutdown();
1284
1285         playerdemo_shutdown();
1286
1287         bot_clientdisconnect();
1288
1289         if(self.entcs)
1290                 detach_entcs();
1291
1292         if(autocvar_sv_eventlog)
1293                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1294
1295         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1296
1297         MUTATOR_CALLHOOK(ClientDisconnect);
1298
1299         Portal_ClearAll(self);
1300
1301         Unfreeze(self);
1302
1303         RemoveGrapplingHook(self);
1304
1305         // Here, everything has been done that requires this player to be a client.
1306
1307         self.flags &= ~FL_CLIENT;
1308
1309         if (self.chatbubbleentity)
1310                 remove (self.chatbubbleentity);
1311
1312         if (self.killindicator)
1313                 remove (self.killindicator);
1314
1315         WaypointSprite_PlayerGone();
1316
1317         bot_relinkplayerlist();
1318
1319         accuracy_free(self);
1320         ClientData_Detach();
1321         PlayerScore_Detach(self);
1322
1323         if(self.netname_previous)
1324                 strunzone(self.netname_previous);
1325         if(self.clientstatus)
1326                 strunzone(self.clientstatus);
1327         if(self.weaponorder_byimpulse)
1328                 strunzone(self.weaponorder_byimpulse);
1329
1330         ClearPlayerSounds();
1331
1332         if(self.personal)
1333                 remove(self.personal);
1334
1335         self.playerid = 0;
1336         ReadyCount();
1337
1338         // free cvars
1339         GetCvars(-1);
1340 }
1341
1342 .float BUTTON_CHAT;
1343 void ChatBubbleThink()
1344 {
1345         self.nextthink = time;
1346         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1347         {
1348                 if(self.owner) // but why can that ever be world?
1349                         self.owner.chatbubbleentity = world;
1350                 remove(self);
1351                 return;
1352         }
1353         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1354 #ifdef TETRIS
1355                 || self.owner.tetris_on
1356 #endif
1357         )
1358                 self.model = self.mdl;
1359         else
1360                 self.model = "";
1361 }
1362
1363 void UpdateChatBubble()
1364 {
1365         if (self.alpha < 0)
1366                 return;
1367         // spawn a chatbubble entity if needed
1368         if (!self.chatbubbleentity)
1369         {
1370                 self.chatbubbleentity = spawn();
1371                 self.chatbubbleentity.owner = self;
1372                 self.chatbubbleentity.exteriormodeltoclient = self;
1373                 self.chatbubbleentity.think = ChatBubbleThink;
1374                 self.chatbubbleentity.nextthink = time;
1375                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1376                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1377                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1378                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1379                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1380                 self.chatbubbleentity.model = "";
1381                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1382         }
1383 }
1384
1385
1386 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1387 // added to the model skins
1388 /*void UpdateColorModHack()
1389 {
1390         float c;
1391         c = self.clientcolors & 15;
1392         // LordHavoc: only bothering to support white, green, red, yellow, blue
1393              if (!teamplay) self.colormod = '0 0 0';
1394         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1395         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1396         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1397         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1398         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1399         else self.colormod = '1 1 1';
1400 }*/
1401
1402 void respawn(void)
1403 {
1404         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1405         {
1406                 self.solid = SOLID_NOT;
1407                 self.takedamage = DAMAGE_NO;
1408                 self.movetype = MOVETYPE_FLY;
1409                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1410                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1411                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1412                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1413                 if(autocvar_g_respawn_ghosts_maxtime)
1414                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1415         }
1416
1417         CopyBody(1);
1418
1419         self.effects |= EF_NODRAW; // prevent another CopyBody
1420         PutClientInServer();
1421 }
1422
1423 void play_countdown(float finished, string samp)
1424 {
1425         if(IS_REAL_CLIENT(self))
1426                 if(floor(finished - time - frametime) != floor(finished - time))
1427                         if(finished - time < 6)
1428                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1429 }
1430
1431 void player_powerups (void)
1432 {
1433         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1434         olditems = self.items;
1435
1436         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1437                 self.modelflags |= MF_ROCKET;
1438         else
1439                 self.modelflags &= ~MF_ROCKET;
1440
1441         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1442
1443         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1444                 return;
1445
1446         Fire_ApplyDamage(self);
1447         Fire_ApplyEffect(self);
1448
1449         if (!g_instagib)
1450         {
1451                 if (self.items & IT_STRENGTH)
1452                 {
1453                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1454                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1455                         if (time > self.strength_finished)
1456                         {
1457                                 self.items = self.items - (self.items & IT_STRENGTH);
1458                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1459                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1460                         }
1461                 }
1462                 else
1463                 {
1464                         if (time < self.strength_finished)
1465                         {
1466                                 self.items = self.items | IT_STRENGTH;
1467                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1468                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1469                         }
1470                 }
1471                 if (self.items & IT_INVINCIBLE)
1472                 {
1473                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1474                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1475                         if (time > self.invincible_finished)
1476                         {
1477                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1478                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1479                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1480                         }
1481                 }
1482                 else
1483                 {
1484                         if (time < self.invincible_finished)
1485                         {
1486                                 self.items = self.items | IT_INVINCIBLE;
1487                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1488                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1489                         }
1490                 }
1491                 if (self.items & IT_SUPERWEAPON)
1492                 {
1493                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1494                         {
1495                                 self.superweapons_finished = 0;
1496                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1497                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1498                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1499                         }
1500                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1501                         {
1502                                 // don't let them run out
1503                         }
1504                         else
1505                         {
1506                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1507                                 if (time > self.superweapons_finished)
1508                                 {
1509                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1510                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1511                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1512                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1513                                 }
1514                         }
1515                 }
1516                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1517                 {
1518                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1519                         {
1520                                 self.items = self.items | IT_SUPERWEAPON;
1521                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1522                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1523                         }
1524                         else
1525                         {
1526                                 self.superweapons_finished = 0;
1527                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1528                         }
1529                 }
1530                 else
1531                 {
1532                         self.superweapons_finished = 0;
1533                 }
1534         }
1535
1536         if(autocvar_g_nodepthtestplayers)
1537                 self.effects = self.effects | EF_NODEPTHTEST;
1538
1539         if(autocvar_g_fullbrightplayers)
1540                 self.effects = self.effects | EF_FULLBRIGHT;
1541
1542         if (time >= game_starttime)
1543         if (time < self.spawnshieldtime)
1544                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1545
1546         MUTATOR_CALLHOOK(PlayerPowerups);
1547 }
1548
1549 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1550 {
1551         if(current > stable)
1552                 return current;
1553         else if(current > stable - 0.25) // when close enough, "snap"
1554                 return stable;
1555         else
1556                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1557 }
1558
1559 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1560 {
1561         if(current < stable)
1562                 return current;
1563         else if(current < stable + 0.25) // when close enough, "snap"
1564                 return stable;
1565         else
1566                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1567 }
1568
1569 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1570 {
1571         if(current > rotstable)
1572         {
1573                 if(rotframetime > 0)
1574                 {
1575                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1576                         current = max(rotstable, current - rotlinear * rotframetime);
1577                 }
1578         }
1579         else if(current < regenstable)
1580         {
1581                 if(regenframetime > 0)
1582                 {
1583                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1584                         current = min(regenstable, current + regenlinear * regenframetime);
1585                 }
1586         }
1587
1588         if(current > limit)
1589                 current = limit;
1590
1591         return current;
1592 }
1593
1594 void player_regen (void)
1595 {
1596         float max_mod, regen_mod, rot_mod, limit_mod;
1597         max_mod = regen_mod = rot_mod = limit_mod = 1;
1598         regen_mod_max = max_mod;
1599         regen_mod_regen = regen_mod;
1600         regen_mod_rot = rot_mod;
1601         regen_mod_limit = limit_mod;
1602         if(!MUTATOR_CALLHOOK(PlayerRegen))
1603         if(!self.frozen)
1604         {
1605                 float minh, mina, maxh, maxa, limith, limita;
1606                 maxh = autocvar_g_balance_health_rotstable;
1607                 maxa = autocvar_g_balance_armor_rotstable;
1608                 minh = autocvar_g_balance_health_regenstable;
1609                 mina = autocvar_g_balance_armor_regenstable;
1610                 limith = autocvar_g_balance_health_limit;
1611                 limita = autocvar_g_balance_armor_limit;
1612
1613                 max_mod = regen_mod_max;
1614                 regen_mod = regen_mod_regen;
1615                 rot_mod = regen_mod_rot;
1616                 limit_mod = regen_mod_limit;
1617
1618                 maxh = maxh * max_mod;
1619                 minh = minh * max_mod;
1620                 limith = limith * limit_mod;
1621                 limita = limita * limit_mod;
1622
1623                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1624                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1625         }
1626
1627         // if player rotted to death...  die!
1628         // check this outside above checks, as player may still be able to rot to death
1629         if(self.health < 1)
1630                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1631
1632         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1633         {
1634                 float minf, maxf, limitf;
1635
1636                 maxf = autocvar_g_balance_fuel_rotstable;
1637                 minf = autocvar_g_balance_fuel_regenstable;
1638                 limitf = autocvar_g_balance_fuel_limit;
1639
1640                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1641         }
1642 }
1643
1644 float zoomstate_set;
1645 void SetZoomState(float z)
1646 {
1647         if(z != self.zoomstate)
1648         {
1649                 self.zoomstate = z;
1650                 ClientData_Touch(self);
1651         }
1652         zoomstate_set = 1;
1653 }
1654
1655 void GetPressedKeys(void) {
1656         MUTATOR_CALLHOOK(GetPressedKeys);
1657         if (self.movement.x > 0) // get if movement keys are pressed
1658         {       // forward key pressed
1659                 self.pressedkeys |= KEY_FORWARD;
1660                 self.pressedkeys &= ~KEY_BACKWARD;
1661         }
1662         else if (self.movement.x < 0)
1663         {       // backward key pressed
1664                 self.pressedkeys |= KEY_BACKWARD;
1665                 self.pressedkeys &= ~KEY_FORWARD;
1666         }
1667         else
1668         {       // no x input
1669                 self.pressedkeys &= ~KEY_FORWARD;
1670                 self.pressedkeys &= ~KEY_BACKWARD;
1671         }
1672
1673         if (self.movement.y > 0)
1674         {       // right key pressed
1675                 self.pressedkeys |= KEY_RIGHT;
1676                 self.pressedkeys &= ~KEY_LEFT;
1677         }
1678         else if (self.movement.y < 0)
1679         {       // left key pressed
1680                 self.pressedkeys |= KEY_LEFT;
1681                 self.pressedkeys &= ~KEY_RIGHT;
1682         }
1683         else
1684         {       // no y input
1685                 self.pressedkeys &= ~KEY_RIGHT;
1686                 self.pressedkeys &= ~KEY_LEFT;
1687         }
1688
1689         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1690                 self.pressedkeys |= KEY_JUMP;
1691         else
1692                 self.pressedkeys &= ~KEY_JUMP;
1693         if (self.BUTTON_CROUCH)
1694                 self.pressedkeys |= KEY_CROUCH;
1695         else
1696                 self.pressedkeys &= ~KEY_CROUCH;
1697
1698         if (self.BUTTON_ATCK)
1699                 self.pressedkeys |= KEY_ATCK;
1700         else
1701                 self.pressedkeys &= ~KEY_ATCK;
1702         if (self.BUTTON_ATCK2)
1703                 self.pressedkeys |= KEY_ATCK2;
1704         else
1705                 self.pressedkeys &= ~KEY_ATCK2;
1706 }
1707
1708 /*
1709 ======================
1710 spectate mode routines
1711 ======================
1712 */
1713
1714 void SpectateCopy(entity spectatee) {
1715         other = spectatee;
1716         MUTATOR_CALLHOOK(SpectateCopy);
1717         self.armortype = spectatee.armortype;
1718         self.armorvalue = spectatee.armorvalue;
1719         self.ammo_cells = spectatee.ammo_cells;
1720         self.ammo_plasma = spectatee.ammo_plasma;
1721         self.ammo_shells = spectatee.ammo_shells;
1722         self.ammo_nails = spectatee.ammo_nails;
1723         self.ammo_rockets = spectatee.ammo_rockets;
1724         self.ammo_fuel = spectatee.ammo_fuel;
1725         self.clip_load = spectatee.clip_load;
1726         self.clip_size = spectatee.clip_size;
1727         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1728         self.health = spectatee.health;
1729         self.impulse = 0;
1730         self.items = spectatee.items;
1731         self.last_pickup = spectatee.last_pickup;
1732         self.hit_time = spectatee.hit_time;
1733         self.metertime = spectatee.metertime;
1734         self.strength_finished = spectatee.strength_finished;
1735         self.invincible_finished = spectatee.invincible_finished;
1736         self.pressedkeys = spectatee.pressedkeys;
1737         self.weapons = spectatee.weapons;
1738         self.switchweapon = spectatee.switchweapon;
1739         self.switchingweapon = spectatee.switchingweapon;
1740         self.weapon = spectatee.weapon;
1741         self.vortex_charge = spectatee.vortex_charge;
1742         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1743         self.hagar_load = spectatee.hagar_load;
1744         self.arc_heat_percent = spectatee.arc_heat_percent;
1745         self.minelayer_mines = spectatee.minelayer_mines;
1746         self.punchangle = spectatee.punchangle;
1747         self.view_ofs = spectatee.view_ofs;
1748         self.velocity = spectatee.velocity;
1749         self.dmg_take = spectatee.dmg_take;
1750         self.dmg_save = spectatee.dmg_save;
1751         self.dmg_inflictor = spectatee.dmg_inflictor;
1752         self.v_angle = spectatee.v_angle;
1753         self.angles = spectatee.v_angle;
1754         self.frozen = spectatee.frozen;
1755         self.revive_progress = spectatee.revive_progress;
1756         if(!self.BUTTON_USE)
1757                 self.fixangle = true;
1758         setorigin(self, spectatee.origin);
1759         setsize(self, spectatee.mins, spectatee.maxs);
1760         SetZoomState(spectatee.zoomstate);
1761
1762     anticheat_spectatecopy(spectatee);
1763         self.hud = spectatee.hud;
1764         if(spectatee.vehicle)
1765     {
1766         self.fixangle = false;
1767         //self.velocity = spectatee.vehicle.velocity;
1768         self.vehicle_health = spectatee.vehicle_health;
1769         self.vehicle_shield = spectatee.vehicle_shield;
1770         self.vehicle_energy = spectatee.vehicle_energy;
1771         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1772         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1773         self.vehicle_reload1 = spectatee.vehicle_reload1;
1774         self.vehicle_reload2 = spectatee.vehicle_reload2;
1775
1776         msg_entity = self;
1777
1778         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1779             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1780             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1781             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1782
1783         //WriteByte (MSG_ONE, SVC_SETVIEW);
1784         //    WriteEntity(MSG_ONE, self);
1785         //makevectors(spectatee.v_angle);
1786         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1787     }
1788 }
1789
1790 float SpectateUpdate()
1791 {
1792         if(!self.enemy)
1793             return 0;
1794
1795         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1796         {
1797                 SetSpectator(self, world);
1798                 return 0;
1799         }
1800
1801         SpectateCopy(self.enemy);
1802
1803         return 1;
1804 }
1805
1806 float SpectateSet()
1807 {
1808         if(self.enemy.classname != "player")
1809                 return false;
1810         /*if(self.enemy.vehicle)
1811         {
1812
1813                 msg_entity = self;
1814                 WriteByte(MSG_ONE, SVC_SETVIEW);
1815                 WriteEntity(MSG_ONE, self.enemy);
1816                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1817
1818                 self.movetype = MOVETYPE_NONE;
1819                 accuracy_resend(self);
1820         }
1821         else
1822         {*/
1823                 msg_entity = self;
1824                 WriteByte(MSG_ONE, SVC_SETVIEW);
1825                 WriteEntity(MSG_ONE, self.enemy);
1826                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1827                 self.movetype = MOVETYPE_NONE;
1828                 accuracy_resend(self);
1829
1830                 if(!SpectateUpdate())
1831                         PutObserverInServer();
1832         //}
1833         return true;
1834 }
1835
1836 void SetSpectator(entity player, entity spectatee)
1837 {
1838         entity old_spectatee = player.enemy;
1839
1840         player.enemy = spectatee;
1841
1842         // WEAPONTODO
1843         // these are required to fix the spectator bug with arc
1844         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1845         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1846 }
1847
1848 float Spectate(entity pl)
1849 {
1850         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1851         if(pl.team != self.team)
1852                 return 0;
1853
1854         SetSpectator(self, pl);
1855         return SpectateSet();
1856 }
1857
1858 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1859 entity CA_SpectateNext(entity start) {
1860         if (start.team == self.team) {
1861                 return start;
1862         }
1863
1864         other = start;
1865         // continue from current player
1866         while(other && other.team != self.team) {
1867                 other = find(other, classname, "player");
1868         }
1869
1870         if (!other) {
1871                 // restart from begining
1872                 other = find(other, classname, "player");
1873                 while(other && other.team != self.team) {
1874                         other = find(other, classname, "player");
1875                 }
1876         }
1877
1878         return other;
1879 }
1880
1881 float SpectateNext()
1882 {
1883         other = find(self.enemy, classname, "player");
1884
1885         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1886                 // CA and ca players when spectating enemies is forbidden
1887                 other = CA_SpectateNext(other);
1888         } else {
1889                 // other modes and ca spectators or spectating enemies is allowed
1890                 if (!other)
1891                         other = find(other, classname, "player");
1892         }
1893
1894         if(other) { SetSpectator(self, other); }
1895
1896         return SpectateSet();
1897 }
1898
1899 float SpectatePrev()
1900 {
1901         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1902         other = findchain(classname, "player");
1903         if (!other) // no player
1904                 return false;
1905
1906         entity first = other;
1907         // skip players until current spectated player
1908         if(self.enemy)
1909         while(other && other != self.enemy)
1910                 other = other.chain;
1911
1912         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1913         {
1914                 do { other = other.chain; }
1915                 while(other && other.team != self.team);
1916
1917                 if (!other)
1918                 {
1919                         other = first;
1920                         while(other.team != self.team)
1921                                 other = other.chain;
1922                         if(other == self.enemy)
1923                                 return true;
1924                 }
1925         }
1926         else
1927         {
1928                 if(other.chain)
1929                         other = other.chain;
1930                 else
1931                         other = first;
1932         }
1933         SetSpectator(self, other);
1934         return SpectateSet();
1935 }
1936
1937 /*
1938 =============
1939 ShowRespawnCountdown()
1940
1941 Update a respawn countdown display.
1942 =============
1943 */
1944 void ShowRespawnCountdown()
1945 {
1946         float number;
1947         if(self.deadflag == DEAD_NO) // just respawned?
1948                 return;
1949         else
1950         {
1951                 number = ceil(self.respawn_time - time);
1952                 if(number <= 0)
1953                         return;
1954                 if(number <= self.respawn_countdown)
1955                 {
1956                         self.respawn_countdown = number - 1;
1957                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1958                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1959                 }
1960         }
1961 }
1962
1963 void LeaveSpectatorMode()
1964 {
1965         if(self.caplayer)
1966                 return;
1967         if(nJoinAllowed(self))
1968         {
1969                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1970                 {
1971                         self.classname = "player";
1972                         nades_RemoveBonus(self);
1973
1974                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1975                                 { JoinBestTeam(self, false, true); }
1976
1977                         if(autocvar_g_campaign)
1978                                 { campaign_bots_may_start = 1; }
1979
1980                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1981
1982                         PutClientInServer();
1983
1984                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1985                 }
1986                 else
1987                         stuffcmd(self, "menu_showteamselect\n");
1988         }
1989         else
1990         {
1991                 // Player may not join because g_maxplayers is set
1992                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1993         }
1994 }
1995
1996 /**
1997  * Determines whether the player is allowed to join. This depends on cvar
1998  * g_maxplayers, if it isn't used this function always return true, otherwise
1999  * it checks whether the number of currently playing players exceeds g_maxplayers.
2000  * @return int number of free slots for players, 0 if none
2001  */
2002 float nJoinAllowed(entity ignore) {
2003         if(!ignore)
2004         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2005         // so report 0 free slots if restricted
2006         {
2007                 if(autocvar_g_forced_team_otherwise == "spectate")
2008                         return 0;
2009                 if(autocvar_g_forced_team_otherwise == "spectator")
2010                         return 0;
2011         }
2012
2013         if(self.team_forced < 0)
2014                 return 0; // forced spectators can never join
2015
2016         // TODO simplify this
2017         entity e;
2018         float totalClients = 0;
2019         FOR_EACH_CLIENT(e)
2020                 if(e != ignore)
2021                         totalClients += 1;
2022
2023         if (!autocvar_g_maxplayers)
2024                 return maxclients - totalClients;
2025
2026         float currentlyPlaying = 0;
2027         FOR_EACH_REALCLIENT(e)
2028                 if(IS_PLAYER(e) || e.caplayer)
2029                         currentlyPlaying += 1;
2030
2031         if(currentlyPlaying < autocvar_g_maxplayers)
2032                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2033
2034         return 0;
2035 }
2036
2037 /**
2038  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2039  * g_maxplayers_spectator_blocktime seconds
2040  */
2041 void checkSpectatorBlock() {
2042         if(IS_SPEC(self) || IS_OBSERVER(self))
2043         if(!self.caplayer)
2044         if(IS_REAL_CLIENT(self))
2045         {
2046                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2047                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2048                         dropclient(self);
2049                 }
2050         }
2051 }
2052
2053 void PrintWelcomeMessage()
2054 {
2055         if(self.motd_actived_time == 0)
2056         {
2057                 if (autocvar_g_campaign) {
2058                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2059                                 self.motd_actived_time = time;
2060                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2061                         }
2062                 } else {
2063                         if (self.BUTTON_INFO) {
2064                                 self.motd_actived_time = time;
2065                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2066                         }
2067                 }
2068         }
2069         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2070         {
2071                 if (autocvar_g_campaign) {
2072                         if (self.BUTTON_INFO)
2073                                 self.motd_actived_time = time;
2074                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2075                                 self.motd_actived_time = 0;
2076                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2077                         }
2078                 } else {
2079                         if (self.BUTTON_INFO)
2080                                 self.motd_actived_time = time;
2081                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2082                                 self.motd_actived_time = 0;
2083                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2084                         }
2085                 }
2086         }
2087         else //if(self.motd_actived_time < 0) // just connected, motd is active
2088         {
2089                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2090                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2091                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2092                 {
2093                         // instanctly hide MOTD
2094                         self.motd_actived_time = 0;
2095                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2096                 }
2097         }
2098 }
2099
2100 void ObserverThink()
2101 {
2102         float prefered_movetype;
2103         if (self.flags & FL_JUMPRELEASED) {
2104                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2105                         self.flags &= ~FL_JUMPRELEASED;
2106                         self.flags |= FL_SPAWNING;
2107                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2108                         self.flags &= ~FL_JUMPRELEASED;
2109                         if(SpectateNext()) {
2110                                 self.classname = "spectator";
2111                         }
2112                 } else {
2113                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2114                         if (self.movetype != prefered_movetype)
2115                                 self.movetype = prefered_movetype;
2116                 }
2117         } else {
2118                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2119                         self.flags |= FL_JUMPRELEASED;
2120                         if(self.flags & FL_SPAWNING)
2121                         {
2122                                 self.flags &= ~FL_SPAWNING;
2123                                 LeaveSpectatorMode();
2124                                 return;
2125                         }
2126                 }
2127         }
2128 }
2129
2130 void SpectatorThink()
2131 {
2132         if (self.flags & FL_JUMPRELEASED) {
2133                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2134                         self.flags &= ~FL_JUMPRELEASED;
2135                         self.flags |= FL_SPAWNING;
2136                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2137                         self.flags &= ~FL_JUMPRELEASED;
2138                         if(SpectateNext()) {
2139                                 self.classname = "spectator";
2140                         } else {
2141                                 self.classname = "observer";
2142                                 PutClientInServer();
2143                         }
2144                         self.impulse = 0;
2145                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2146                         self.flags &= ~FL_JUMPRELEASED;
2147                         if(SpectatePrev()) {
2148                                 self.classname = "spectator";
2149                         } else {
2150                                 self.classname = "observer";
2151                                 PutClientInServer();
2152                         }
2153                         self.impulse = 0;
2154                 } else if (self.BUTTON_ATCK2) {
2155                         self.flags &= ~FL_JUMPRELEASED;
2156                         self.classname = "observer";
2157                         PutClientInServer();
2158                 } else {
2159                         if(!SpectateUpdate())
2160                                 PutObserverInServer();
2161                 }
2162         } else {
2163                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2164                         self.flags |= FL_JUMPRELEASED;
2165                         if(self.flags & FL_SPAWNING)
2166                         {
2167                                 self.flags &= ~FL_SPAWNING;
2168                                 LeaveSpectatorMode();
2169                                 return;
2170                         }
2171                 }
2172                 if(!SpectateUpdate())
2173                         PutObserverInServer();
2174         }
2175
2176         self.flags |= FL_CLIENT | FL_NOTARGET;
2177 }
2178
2179 void PlayerUseKey()
2180 {
2181         if (!IS_PLAYER(self))
2182                 return;
2183
2184         if(self.vehicle)
2185         {
2186         vehicles_exit(VHEF_NORMAL);
2187         return;
2188         }
2189
2190         // a use key was pressed; call handlers
2191         MUTATOR_CALLHOOK(PlayerUseKey);
2192 }
2193
2194 float isInvisibleString(string s)
2195 {
2196         float i, n, c;
2197         s = strdecolorize(s);
2198         for((i = 0), (n = strlen(s)); i < n; ++i)
2199         {
2200                 c = str2chr(s, i);
2201                 switch(c)
2202                 {
2203                         case 0:
2204                         case 32: // space
2205                                 break;
2206                         case 192: // charmap space
2207                                 if (!autocvar_utf8_enable)
2208                                         break;
2209                                 return false;
2210                         case 160: // space in unicode fonts
2211                         case 0xE000 + 192: // utf8 charmap space
2212                                 if (autocvar_utf8_enable)
2213                                         break;
2214                         default:
2215                                 return false;
2216                 }
2217         }
2218         return true;
2219 }
2220
2221 /*
2222 =============
2223 PlayerPreThink
2224
2225 Called every frame for each client before the physics are run
2226 =============
2227 */
2228 .float usekeypressed;
2229 void() nexball_setstatus;
2230 .int items_added;
2231 void PlayerPreThink (void)
2232 {
2233         WarpZone_PlayerPhysics_FixVAngle();
2234
2235         self.stat_game_starttime = game_starttime;
2236         self.stat_round_starttime = round_starttime;
2237         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2238         self.stat_leadlimit = autocvar_leadlimit;
2239
2240         if(frametime)
2241         {
2242                 // physics frames: update anticheat stuff
2243                 anticheat_prethink();
2244         }
2245
2246         if(blockSpectators && frametime)
2247                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2248                 checkSpectatorBlock();
2249
2250         zoomstate_set = 0;
2251
2252         // Savage: Check for nameless players
2253         if (isInvisibleString(self.netname)) {
2254                 string new_name = strzone(strcat("Player@", self.netaddress));
2255                 if(autocvar_sv_eventlog)
2256                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2257                 if(self.netname_previous)
2258                         strunzone(self.netname_previous);
2259                 self.netname_previous = strzone(new_name);
2260                 self.netname = self.netname_previous;
2261                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2262         } else if(self.netname_previous != self.netname) {
2263                 if(autocvar_sv_eventlog)
2264                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2265                 if(self.netname_previous)
2266                         strunzone(self.netname_previous);
2267                 self.netname_previous = strzone(self.netname);
2268         }
2269
2270         // version nagging
2271         if(self.version_nagtime)
2272                 if(self.cvar_g_xonoticversion)
2273                         if(time > self.version_nagtime)
2274                         {
2275                                 // don't notify git users
2276                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2277                                 {
2278                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2279                                         {
2280                                                 // notify release users if connecting to git
2281                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2282                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2283                                         }
2284                                         else
2285                                         {
2286                                                 float r;
2287                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2288                                                 if(r < 0)
2289                                                 {
2290                                                         // give users new version
2291                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2292                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2293                                                 }
2294                                                 else if(r > 0)
2295                                                 {
2296                                                         // notify users about old server version
2297                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2298                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2299                                                 }
2300                                         }
2301                                 }
2302                                 self.version_nagtime = 0;
2303                         }
2304
2305         // GOD MODE info
2306         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2307         {
2308                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2309                 self.max_armorvalue = 0;
2310         }
2311
2312 #ifdef TETRIS
2313         if (TetrisPreFrame())
2314                 return;
2315 #endif
2316
2317         if(self.frozen == 2)
2318         {
2319                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2320                 self.health = max(1, self.revive_progress * start_health);
2321                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2322
2323                 if(self.revive_progress >= 1)
2324                         Unfreeze(self);
2325         }
2326         else if(self.frozen == 3)
2327         {
2328                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2329                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2330
2331                 if(self.health < 1)
2332                 {
2333                         if(self.vehicle)
2334                                 vehicles_exit(VHEF_RELESE);
2335                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2336                 }
2337                 else if ( self.revive_progress <= 0 )
2338                         Unfreeze(self);
2339         }
2340
2341         MUTATOR_CALLHOOK(PlayerPreThink);
2342
2343         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2344         {
2345                 if(self.BUTTON_USE && !self.usekeypressed)
2346                         PlayerUseKey();
2347                 self.usekeypressed = self.BUTTON_USE;
2348         }
2349
2350         if(IS_REAL_CLIENT(self))
2351                 PrintWelcomeMessage();
2352
2353         if(IS_PLAYER(self))
2354         {
2355
2356                 CheckRules_Player();
2357
2358                 if (intermission_running)
2359                 {
2360                         IntermissionThink ();   // otherwise a button could be missed between
2361                         return;                                 // the think tics
2362                 }
2363
2364                 //don't allow the player to turn around while game is paused!
2365                 if(timeout_status == TIMEOUT_ACTIVE) {
2366                         // FIXME turn this into CSQC stuff
2367                         self.v_angle = self.lastV_angle;
2368                         self.angles = self.lastV_angle;
2369                         self.fixangle = true;
2370                 }
2371
2372                 if(frametime)
2373                 {
2374                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2375                         {
2376                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2377                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2378                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2379
2380                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2381                                 {
2382                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2383                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2384                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2385                                 }
2386                         }
2387                         else
2388                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2389
2390                         player_powerups();
2391                 }
2392
2393                 if (self.deadflag != DEAD_NO)
2394                 {
2395                         if(self.personal && g_race_qualifying)
2396                         {
2397                                 if(time > self.respawn_time)
2398                                 {
2399                                         self.respawn_time = time + 1; // only retry once a second
2400                                         self.stat_respawn_time = self.respawn_time;
2401                                         respawn();
2402                                         self.impulse = 141;
2403                                 }
2404                         }
2405                         else
2406                         {
2407                                 float button_pressed;
2408                                 if(frametime)
2409                                         player_anim();
2410                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2411
2412                                 if (self.deadflag == DEAD_DYING)
2413                                 {
2414                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2415                                                 self.deadflag = DEAD_RESPAWNING;
2416                                         else if(!button_pressed)
2417                                                 self.deadflag = DEAD_DEAD;
2418                                 }
2419                                 else if (self.deadflag == DEAD_DEAD)
2420                                 {
2421                                         if(button_pressed)
2422                                                 self.deadflag = DEAD_RESPAWNABLE;
2423                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2424                                                 self.deadflag = DEAD_RESPAWNING;
2425                                 }
2426                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2427                                 {
2428                                         if(!button_pressed)
2429                                                 self.deadflag = DEAD_RESPAWNING;
2430                                 }
2431                                 else if (self.deadflag == DEAD_RESPAWNING)
2432                                 {
2433                                         if(time > self.respawn_time)
2434                                         {
2435                                                 self.respawn_time = time + 1; // only retry once a second
2436                                                 self.respawn_time_max = self.respawn_time;
2437                                                 respawn();
2438                                         }
2439                                 }
2440
2441                                 ShowRespawnCountdown();
2442
2443                                 if(self.respawn_flags & RESPAWN_SILENT)
2444                                         self.stat_respawn_time = 0;
2445                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2446                                         self.stat_respawn_time = self.respawn_time_max;
2447                                 else
2448                                         self.stat_respawn_time = self.respawn_time;
2449                         }
2450
2451                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2452                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2453                                 self.stat_respawn_time *= -1;
2454
2455                         return;
2456                 }
2457
2458                 self.prevorigin = self.origin;
2459
2460                 float do_crouch = self.BUTTON_CROUCH;
2461                 if(self.hook.state)
2462                         do_crouch = 0;
2463                 if(self.vehicle)
2464                         do_crouch = 0;
2465                 if(self.frozen)
2466                         do_crouch = 0;
2467
2468                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2469                 // It cannot be predicted by the engine!
2470                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2471                         do_crouch = 0;
2472
2473                 if (do_crouch)
2474                 {
2475                         if (!self.crouch)
2476                         {
2477                                 self.crouch = true;
2478                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2479                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2480                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2481                         }
2482                 }
2483                 else
2484                 {
2485                         if (self.crouch)
2486                         {
2487                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2488                                 if (!trace_startsolid)
2489                                 {
2490                                         self.crouch = false;
2491                                         self.view_ofs = PL_VIEW_OFS;
2492                                         setsize (self, PL_MIN, PL_MAX);
2493                                 }
2494                         }
2495                 }
2496
2497                 FixPlayermodel();
2498
2499                 GrapplingHookFrame();
2500
2501                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2502                 //if(frametime)
2503                 {
2504                         self.items &= ~self.items_added;
2505
2506                         W_WeaponFrame();
2507
2508                         self.items_added = 0;
2509                         if(self.items & IT_JETPACK)
2510                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2511                                         self.items_added |= IT_FUEL;
2512
2513                         self.items |= self.items_added;
2514                 }
2515
2516                 player_regen();
2517
2518                 // WEAPONTODO: Add a weapon request for this
2519                 // rot vortex charge to the charge limit
2520                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2521                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2522
2523                 if(frametime)
2524                         player_anim();
2525
2526                 // secret status
2527                 secrets_setstatus();
2528
2529                 // monsters status
2530                 monsters_setstatus();
2531
2532                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2533
2534                 //self.angles_y=self.v_angle_y + 90;   // temp
2535         } else if(gameover) {
2536                 if (intermission_running)
2537                         IntermissionThink ();   // otherwise a button could be missed between
2538                 return;
2539         } else if(IS_OBSERVER(self)) {
2540                 ObserverThink();
2541         } else if(IS_SPEC(self)) {
2542                 SpectatorThink();
2543         }
2544
2545         // WEAPONTODO: Add weapon request for this
2546         if(!zoomstate_set)
2547                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2548
2549         float oldspectatee_status;
2550         oldspectatee_status = self.spectatee_status;
2551         if(IS_SPEC(self))
2552                 self.spectatee_status = num_for_edict(self.enemy);
2553         else if(IS_OBSERVER(self))
2554                 self.spectatee_status = num_for_edict(self);
2555         else
2556                 self.spectatee_status = 0;
2557         if(self.spectatee_status != oldspectatee_status)
2558         {
2559                 ClientData_Touch(self);
2560         }
2561
2562         if(self.teamkill_soundtime)
2563         if(time > self.teamkill_soundtime)
2564         {
2565                 self.teamkill_soundtime = 0;
2566
2567                 entity oldpusher, oldself;
2568
2569                 oldself = self; self = self.teamkill_soundsource;
2570                 oldpusher = self.pusher; self.pusher = oldself;
2571
2572                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2573
2574                 self.pusher = oldpusher;
2575                 self = oldself;
2576         }
2577
2578         if(self.taunt_soundtime)
2579         if(time > self.taunt_soundtime)
2580         {
2581                 self.taunt_soundtime = 0;
2582                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2583         }
2584
2585         target_voicescript_next(self);
2586
2587         // WEAPONTODO: Move into weaponsystem somehow
2588         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2589         if(!self.weapon)
2590                 self.clip_load = self.clip_size = 0;
2591 }
2592
2593 /*
2594 =============
2595 PlayerPostThink
2596
2597 Called every frame for each client after the physics are run
2598 =============
2599 */
2600 .float idlekick_lasttimeleft;
2601 void PlayerPostThink (void)
2602 {
2603         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2604         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2605         {
2606                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2607                 {
2608                         if(self.idlekick_lasttimeleft)
2609                         {
2610                                 self.idlekick_lasttimeleft = 0;
2611                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2612                         }
2613                 }
2614                 else
2615                 {
2616                         float timeleft;
2617                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2618                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2619                         {
2620                                 if(!self.idlekick_lasttimeleft)
2621                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2622                         }
2623                         if(timeleft <= 0)
2624                         {
2625                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2626                                 dropclient(self);
2627                                 return;
2628                         }
2629                         else if(timeleft <= 10)
2630                         {
2631                                 if(timeleft != self.idlekick_lasttimeleft)
2632                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2633                                 self.idlekick_lasttimeleft = timeleft;
2634                         }
2635                 }
2636         }
2637
2638 #ifdef TETRIS
2639         if(self.impulse == 100)
2640                 ImpulseCommands();
2641         if (!TetrisPostFrame())
2642         {
2643 #endif
2644
2645         CheatFrame();
2646
2647         //CheckPlayerJump();
2648
2649         if(IS_PLAYER(self)) {
2650                 CheckRules_Player();
2651                 UpdateChatBubble();
2652                 if (self.impulse)
2653                         ImpulseCommands();
2654                 if (intermission_running)
2655                         return;         // intermission or finale
2656                 GetPressedKeys();
2657         }
2658
2659 #ifdef TETRIS
2660         }
2661 #endif
2662
2663         /*
2664         float i;
2665         for(i = 0; i < 1000; ++i)
2666         {
2667                 vector end;
2668                 end = self.origin + '0 0 1024' + 512 * randomvec();
2669                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2670                 if(trace_fraction < 1)
2671                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2672                 {
2673                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2674                         break;
2675                 }
2676         }
2677         */
2678
2679         if(self.waypointsprite_attachedforcarrier)
2680                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2681
2682         playerdemo_write();
2683
2684         CSQCMODEL_AUTOUPDATE();
2685 }