qcsrc/server/cl_client.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "../warpzonelib/server.qh"
   7     #include "../common/constants.qh"
   8     #include "../common/teams.qh"
   9     #include "../common/util.qh"
  10     #include "../common/net_notice.qh"
  11     #include "../common/monsters/monsters.qh"
  12     #include "../common/monsters/sv_monsters.qh"
  13     #include "../common/weapons/weapons.qh"
  14     #include "t_items.qh"
  15     #include "autocvars.qh"
  16     #include "constants.qh"
  17     #include "defs.qh"
  18     #include "../common/notifications.qh"
  19     #include "../common/deathtypes.qh"
  20     #include "mutators/mutators_include.qh"
  21     #include "vehicles/vehicles_def.qh"
  22     #include "campaign.qh"
  23     #include "../common/mapinfo.qh"
  24     #include "command/common.qh"
  25     #include "command/vote.qh"
  26     #include "../csqcmodellib/sv_model.qh"
  27     #include "anticheat.qh"
  28     #include "cheats.qh"
  29     #include "../common/playerstats.qh"
  30     #include "portals.qh"
  31     #include "g_hook.qh"
  32     #include "scores.qh"
  33     #include "spawnpoints.qh"
  34     #include "ipban.qh"
  35     #include "race.qh"
  36     #include "antilag.qh"
  37     #include "playerdemo.qh"
  38 #endif
  39
  40 void send_CSQC_teamnagger() {
  41         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  42         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  43 }
  44
  45 float ClientData_Send(entity to, float sf)
  46 {
  47         if(to != self.owner)
  48         {
  49                 error("wtf");
  50                 return false;
  51         }
  52
  53         entity e;
  54
  55         e = to;
  56         if(IS_SPEC(to))
  57                 e = to.enemy;
  58
  59         sf = 0;
  60
  61         if(e.race_completed)
  62                 sf |= 1; // forced scoreboard
  63         if(to.spectatee_status)
  64                 sf |= 2; // spectator ent number follows
  65         if(e.zoomstate)
  66                 sf |= 4; // zoomed
  67         if(e.porto_v_angle_held)
  68                 sf |= 8; // angles held
  69
  70         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  71         WriteByte(MSG_ENTITY, sf);
  72
  73         if(sf & 2)
  74                 WriteByte(MSG_ENTITY, to.spectatee_status);
  75
  76         if(sf & 8)
  77         {
  78                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  79                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  80         }
  81
  82         return true;
  83 }
  84
  85 void ClientData_Attach()
  86 {
  87         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  88         self.clientdata.drawonlytoclient = self;
  89         self.clientdata.owner = self;
  90 }
  91
  92 void ClientData_Detach()
  93 {
  94         remove(self.clientdata);
  95         self.clientdata = world;
  96 }
  97
  98 void ClientData_Touch(entity e)
  99 {
 100         e.clientdata.SendFlags = 1;
 101
 102         // make it spectatable
 103         entity e2;
 104         FOR_EACH_REALCLIENT(e2)
 105         {
 106                 if(e2 != e)
 107                         if(IS_SPEC(e2))
 108                                 if(e2.enemy == e)
 109                                         e2.clientdata.SendFlags = 1;
 110         }
 111 }
 112
 113 .string netname_previous;
 114
 115 void SetSpectator(entity player, entity spectatee);
 116
 117
 118 /*
 119 =============
 120 CheckPlayerModel
 121
 122 Checks if the argument string can be a valid playermodel.
 123 Returns a valid one in doubt.
 124 =============
 125 */
 126 string FallbackPlayerModel;
 127 string CheckPlayerModel(string plyermodel) {
 128         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 129         {
 130                 // note: we cannot summon Don Strunzone here, some player may
 131                 // still have the model string set. In case anyone manages how
 132                 // to change a cvar default, we'll have a small leak here.
 133                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 134         }
 135         // only in right path
 136         if( substring(plyermodel,0,14) != "models/player/")
 137                 return FallbackPlayerModel;
 138         // only good file extensions
 139         if(substring(plyermodel,-4,4) != ".zym")
 140         if(substring(plyermodel,-4,4) != ".dpm")
 141         if(substring(plyermodel,-4,4) != ".iqm")
 142         if(substring(plyermodel,-4,4) != ".md3")
 143         if(substring(plyermodel,-4,4) != ".psk")
 144                 return FallbackPlayerModel;
 145         // forbid the LOD models
 146         if(substring(plyermodel, -9,5) == "_lod1")
 147                 return FallbackPlayerModel;
 148         if(substring(plyermodel, -9,5) == "_lod2")
 149                 return FallbackPlayerModel;
 150         if(plyermodel != strtolower(plyermodel))
 151                 return FallbackPlayerModel;
 152         // also, restrict to server models
 153         if(autocvar_sv_servermodelsonly)
 154         {
 155                 if(!fexists(plyermodel))
 156                         return FallbackPlayerModel;
 157         }
 158         return plyermodel;
 159 }
 160
 161 void setplayermodel(entity e, string modelname)
 162 {
 163         precache_model(modelname);
 164         setmodel(e, modelname);
 165         player_setupanimsformodel();
 166         UpdatePlayerSounds();
 167 }
 168
 169 /*
 170 =============
 171 PutObserverInServer
 172
 173 putting a client as observer in the server
 174 =============
 175 */
 176 void FixPlayermodel();
 177 void PutObserverInServer (void)
 178 {
 179         entity  spot;
 180     self.hud = HUD_NORMAL;
 181
 182         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 183
 184         spot = SelectSpawnPoint (true);
 185         if(!spot)
 186                 error("No spawnpoints for observers?!?\n");
 187         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 188
 189         if(IS_REAL_CLIENT(self))
 190         {
 191                 msg_entity = self;
 192                 WriteByte(MSG_ONE, SVC_SETVIEW);
 193                 WriteEntity(MSG_ONE, self);
 194         }
 195
 196         self.frags = FRAGS_SPECTATOR;
 197
 198         MUTATOR_CALLHOOK(MakePlayerObserver);
 199
 200         Portal_ClearAll(self);
 201
 202         Unfreeze(self);
 203
 204         if(self.alivetime)
 205         {
 206                 if(!warmup_stage)
 207                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 208                 self.alivetime = 0;
 209         }
 210
 211         if(self.vehicle)
 212                 vehicles_exit(VHEF_RELESE);
 213
 214         WaypointSprite_PlayerDead();
 215
 216         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 217                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 218
 219         if(self.killcount != -666)
 220         {
 221                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 222                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 223                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 224
 225                 if(self.just_joined == false) {
 226                         LogTeamchange(self.playerid, -1, 4);
 227                 } else
 228                         self.just_joined = false;
 229         }
 230
 231         PlayerScore_Clear(self); // clear scores when needed
 232
 233         accuracy_resend(self);
 234
 235         self.spectatortime = time;
 236
 237         self.classname = "observer";
 238         self.iscreature = false;
 239         self.teleportable = TELEPORT_SIMPLE;
 240         self.damagedbycontents = false;
 241         self.health = -666;
 242         self.takedamage = DAMAGE_NO;
 243         self.solid = SOLID_NOT;
 244         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 245         self.flags = FL_CLIENT | FL_NOTARGET;
 246         self.armorvalue = 666;
 247         self.effects = 0;
 248         self.armorvalue = autocvar_g_balance_armor_start;
 249         self.pauserotarmor_finished = 0;
 250         self.pauserothealth_finished = 0;
 251         self.pauseregen_finished = 0;
 252         self.damageforcescale = 0;
 253         self.death_time = 0;
 254         self.respawn_flags = 0;
 255         self.respawn_time = 0;
 256         self.stat_respawn_time = 0;
 257         self.alpha = 0;
 258         self.scale = 0;
 259         self.fade_time = 0;
 260         self.pain_frame = 0;
 261         self.pain_finished = 0;
 262         self.strength_finished = 0;
 263         self.invincible_finished = 0;
 264         self.superweapons_finished = 0;
 265         self.pushltime = 0;
 266         self.istypefrag = 0;
 267         self.think = func_null;
 268         self.nextthink = 0;
 269         self.hook_time = 0;
 270         self.deadflag = DEAD_NO;
 271         self.angles = spot.angles;
 272         self.angles_z = 0;
 273         self.fixangle = true;
 274         self.crouch = false;
 275         self.revival_time = 0;
 276
 277         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 278         self.prevorigin = self.origin;
 279         self.items = 0;
 280         self.weapons = '0 0 0';
 281         self.model = "";
 282         FixPlayermodel();
 283         setmodel(self, "null");
 284         self.drawonlytoclient = self;
 285
 286         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 287         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 288
 289         self.weapon = 0;
 290         self.weaponname = "";
 291         self.switchingweapon = 0;
 292         self.weaponmodel = "";
 293         self.weaponentity = world;
 294         self.exteriorweaponentity = world;
 295         self.killcount = -666;
 296         self.velocity = '0 0 0';
 297         self.avelocity = '0 0 0';
 298         self.punchangle = '0 0 0';
 299         self.punchvector = '0 0 0';
 300         self.oldvelocity = self.velocity;
 301         self.fire_endtime = -1;
 302         self.event_damage = func_null;
 303 }
 304
 305 .float model_randomizer;
 306 void FixPlayermodel()
 307 {
 308         string defaultmodel;
 309         float defaultskin, chmdl, oldskin, n, i;
 310         vector m1, m2;
 311
 312         defaultmodel = "";
 313         defaultskin = 0;
 314         chmdl = false;
 315
 316         if(autocvar_sv_defaultcharacter == 1)
 317         {
 318                 if(teamplay)
 319                 {
 320                         string s;
 321                         s = Static_Team_ColorName_Lower(self.team);
 322                         if(s != "neutral")
 323                         {
 324                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 325                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 326                         }
 327                 }
 328
 329                 if(defaultmodel == "")
 330                 {
 331                         defaultmodel = autocvar_sv_defaultplayermodel;
 332                         defaultskin = autocvar_sv_defaultplayerskin;
 333                 }
 334
 335                 n = tokenize_console(defaultmodel);
 336                 if(n > 0)
 337                 {
 338                         defaultmodel = argv(floor(n * self.model_randomizer));
 339                         // However, do NOT randomize if the player-selected model is in the list.
 340                         for (i = 0; i < n; ++i)
 341                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 342                                         defaultmodel = argv(i);
 343                 }
 344
 345                 i = strstrofs(defaultmodel, ":", 0);
 346                 if(i >= 0)
 347                 {
 348                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 349                         defaultmodel = substring(defaultmodel, 0, i);
 350                 }
 351         }
 352
 353         if(defaultmodel != "")
 354         {
 355                 if (defaultmodel != self.model)
 356                 {
 357                         m1 = self.mins;
 358                         m2 = self.maxs;
 359                         setplayermodel (self, defaultmodel);
 360                         setsize (self, m1, m2);
 361                         chmdl = true;
 362                 }
 363
 364                 oldskin = self.skin;
 365                 self.skin = defaultskin;
 366         } else {
 367                 if (self.playermodel != self.model || self.playermodel == "")
 368                 {
 369                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 370                         m1 = self.mins;
 371                         m2 = self.maxs;
 372                         setplayermodel (self, self.playermodel);
 373                         setsize (self, m1, m2);
 374                         chmdl = true;
 375                 }
 376
 377                 oldskin = self.skin;
 378                 self.skin = stof(self.playerskin);
 379         }
 380
 381         if(chmdl || oldskin != self.skin) // model or skin has changed
 382         {
 383                 self.species = player_getspecies(); // update species
 384                 UpdatePlayerSounds(); // update skin sounds
 385         }
 386
 387         if(!teamplay)
 388                 if(strlen(autocvar_sv_defaultplayercolors))
 389                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 390                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 391 }
 392
 393 /*
 394 =============
 395 PutClientInServer
 396
 397 Called when a client spawns in the server
 398 =============
 399 */
 400 void PutClientInServer (void)
 401 {
 402         if(IS_BOT_CLIENT(self))
 403                 self.classname = "player";
 404         else if(IS_REAL_CLIENT(self))
 405         {
 406                 msg_entity = self;
 407                 WriteByte(MSG_ONE, SVC_SETVIEW);
 408                 WriteEntity(MSG_ONE, self);
 409         }
 410
 411         SetSpectator(self, world);
 412
 413         // reset player keys
 414         self.itemkeys = 0;
 415
 416         MUTATOR_CALLHOOK(PutClientInServer);
 417
 418         if(gameover)
 419                 self.classname = "observer";
 420
 421         if(IS_PLAYER(self))
 422         {
 423                 entity spot, oldself;
 424                 float j;
 425
 426                 accuracy_resend(self);
 427
 428                 if(self.team < 0)
 429                         JoinBestTeam(self, false, true);
 430
 431                 spot = SelectSpawnPoint (false);
 432                 if(!spot)
 433                 {
 434                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 435                         return; // spawn failed
 436                 }
 437
 438                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 439
 440                 if(self.vehicle)
 441                         vehicles_exit(VHEF_RELESE);
 442
 443                 self.classname = "player";
 444                 self.wasplayer = true;
 445                 self.iscreature = true;
 446                 self.teleportable = TELEPORT_NORMAL;
 447                 self.damagedbycontents = true;
 448                 self.movetype = MOVETYPE_WALK;
 449                 self.solid = SOLID_SLIDEBOX;
 450                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 451                 if(autocvar_g_playerclip_collisions)
 452                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 453                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 454                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 455                 self.frags = FRAGS_PLAYER;
 456                 if(INDEPENDENT_PLAYERS)
 457                         MAKE_INDEPENDENT_PLAYER(self);
 458                 self.flags = FL_CLIENT;
 459                 if(autocvar__notarget)
 460                         self.flags |= FL_NOTARGET;
 461                 self.takedamage = DAMAGE_AIM;
 462                 self.effects = 0;
 463                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 464                 self.air_finished = time + 12;
 465                 self.dmg = 2;
 466                 if(WEP_CVAR(vortex, charge))
 467                 {
 468                         if(WEP_CVAR_SEC(vortex, chargepool))
 469                                 self.vortex_chargepool_ammo = 1;
 470                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 471                 }
 472
 473                 if(warmup_stage)
 474                 {
 475                         self.ammo_shells = warmup_start_ammo_shells;
 476                         self.ammo_nails = warmup_start_ammo_nails;
 477                         self.ammo_rockets = warmup_start_ammo_rockets;
 478                         self.ammo_cells = warmup_start_ammo_cells;
 479                         self.ammo_plasma = warmup_start_ammo_plasma;
 480                         self.ammo_fuel = warmup_start_ammo_fuel;
 481                         self.health = warmup_start_health;
 482                         self.armorvalue = warmup_start_armorvalue;
 483                         self.weapons = WARMUP_START_WEAPONS;
 484                 }
 485                 else
 486                 {
 487                         self.ammo_shells = start_ammo_shells;
 488                         self.ammo_nails = start_ammo_nails;
 489                         self.ammo_rockets = start_ammo_rockets;
 490                         self.ammo_cells = start_ammo_cells;
 491                         self.ammo_plasma = start_ammo_plasma;
 492                         self.ammo_fuel = start_ammo_fuel;
 493                         self.health = start_health;
 494                         self.armorvalue = start_armorvalue;
 495                         self.weapons = start_weapons;
 496                 }
 497
 498                 if(self.weapons & WEPSET_SUPERWEAPONS)
 499                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 500                 else
 501                         self.superweapons_finished = 0;
 502
 503                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 504                 {
 505                         if(g_weaponarena_random_with_blaster)
 506                                 self.weapons &= ~WEPSET_BLASTER;
 507                         W_RandomWeapons(self, g_weaponarena_random);
 508                         if(g_weaponarena_random_with_blaster)
 509                                 self.weapons |= WEPSET_BLASTER;
 510                 }
 511
 512                 self.items = start_items;
 513
 514                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 515                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 516                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 517                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 518                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 519                 //extend the pause of rotting if client was reset at the beginning of the countdown
 520                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 521                         self.spawnshieldtime += game_starttime - time;
 522                         self.pauserotarmor_finished += game_starttime - time;
 523                         self.pauserothealth_finished += game_starttime - time;
 524                         self.pauseregen_finished += game_starttime - time;
 525                 }
 526                 self.damageforcescale = 2;
 527                 self.death_time = 0;
 528                 self.respawn_flags = 0;
 529                 self.respawn_time = 0;
 530                 self.stat_respawn_time = 0;
 531                 self.scale = 0;
 532                 self.fade_time = 0;
 533                 self.pain_frame = 0;
 534                 self.pain_finished = 0;
 535                 self.strength_finished = 0;
 536                 self.invincible_finished = 0;
 537                 self.pushltime = 0;
 538                 // players have no think function
 539                 self.think = func_null;
 540                 self.nextthink = 0;
 541                 self.hook_time = 0;
 542                 self.dmg_team = 0;
 543                 self.ballistics_density = autocvar_g_ballistics_density_player;
 544
 545                 self.metertime = 0;
 546
 547                 self.deadflag = DEAD_NO;
 548
 549                 self.angles = spot.angles;
 550
 551                 self.angles_z = 0; // never spawn tilted even if the spot says to
 552                 if(IS_BOT_CLIENT(self))
 553                         self.v_angle = self.angles;
 554                 self.fixangle = true; // turn this way immediately
 555                 self.velocity = '0 0 0';
 556                 self.avelocity = '0 0 0';
 557                 self.punchangle = '0 0 0';
 558                 self.punchvector = '0 0 0';
 559                 self.oldvelocity = self.velocity;
 560                 self.fire_endtime = -1;
 561                 self.revival_time = 0;
 562
 563                 entity spawnevent = spawn();
 564                 spawnevent.owner = self;
 565                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 566
 567                 // Cut off any still running player sounds.
 568                 stopsound(self, CH_PLAYER_SINGLE);
 569
 570                 self.model = "";
 571                 FixPlayermodel();
 572                 self.drawonlytoclient = world;
 573
 574                 self.crouch = false;
 575                 self.view_ofs = PL_VIEW_OFS;
 576                 setsize (self, PL_MIN, PL_MAX);
 577                 self.spawnorigin = spot.origin;
 578                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 579                 // don't reset back to last position, even if new position is stuck in solid
 580                 self.oldorigin = self.origin;
 581                 self.prevorigin = self.origin;
 582                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 583                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 584         self.hud = HUD_NORMAL;
 585
 586                 self.event_damage = PlayerDamage;
 587
 588                 self.bot_attack = true;
 589                 self.monster_attack = true;
 590
 591                 self.spider_slowness = 0;
 592
 593                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 594
 595                 if(self.killcount == -666) {
 596                         PlayerScore_Clear(self);
 597                         self.killcount = 0;
 598                 }
 599
 600                 CL_SpawnWeaponentity();
 601                 self.alpha = default_player_alpha;
 602                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 603                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 604
 605                 self.speedrunning = false;
 606
 607                 //stuffcmd(self, "chase_active 0");
 608                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 609
 610                 target_voicescript_clear(self);
 611
 612                 // reset fields the weapons may use
 613                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 614                 {
 615                         WEP_ACTION(j, WR_RESETPLAYER);
 616
 617                         // all weapons must be fully loaded when we spawn
 618                         entity e;
 619                         e = get_weaponinfo(j);
 620                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 621                                 self.(weapon_load[j]) = e.reloading_ammo;
 622                 }
 623
 624                 oldself = self;
 625                 self = spot;
 626                         activator = oldself;
 627                                 string s;
 628                                 s = self.target;
 629                                 self.target = string_null;
 630                                 SUB_UseTargets();
 631                                 self.target = s;
 632                         activator = world;
 633                 self = oldself;
 634
 635                 Unfreeze(self);
 636
 637                 spawn_spot = spot;
 638                 MUTATOR_CALLHOOK(PlayerSpawn);
 639
 640                 if(autocvar_spawn_debug)
 641                 {
 642                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 643                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 644                 }
 645
 646                 self.switchweapon = w_getbestweapon(self);
 647                 self.cnt = -1; // W_LastWeapon will not complain
 648                 self.weapon = 0;
 649                 self.weaponname = "";
 650                 self.switchingweapon = 0;
 651
 652                 if(!warmup_stage)
 653                         if(!self.alivetime)
 654                                 self.alivetime = time;
 655
 656                 antilag_clear(self);
 657         }
 658         else if(IS_OBSERVER(self))
 659         {
 660                 PutObserverInServer ();
 661         }
 662 }
 663
 664 .float ebouncefactor, ebouncestop; // electro's values
 665 // TODO do we need all these fields, or should we stop autodetecting runtime
 666 // changes and just have a console command to update this?
 667 float ClientInit_SendEntity(entity to, float sf)
 668 {
 669         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 670         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 671         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 672         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 673         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 674         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 675         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 676         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 679
 680         if(sv_foginterval && world.fog != "")
 681                 WriteString(MSG_ENTITY, world.fog);
 682         else
 683                 WriteString(MSG_ENTITY, "");
 684         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 685         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 686         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 687         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 688         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 689         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 690         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 691         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 692         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 693         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 694         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 695         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 696         return true;
 697 }
 698
 699 void ClientInit_CheckUpdate()
 700 {
 701         self.nextthink = time;
 702         if(self.count != autocvar_g_balance_armor_blockpercent)
 703         {
 704                 self.count = autocvar_g_balance_armor_blockpercent;
 705                 self.SendFlags |= 1;
 706         }
 707         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 708         {
 709                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 710                 self.SendFlags |= 1;
 711         }
 712         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 713         {
 714                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 715                 self.SendFlags |= 1;
 716         }
 717         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 718         {
 719                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 720                 self.SendFlags |= 1;
 721         }
 722         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 723         {
 724                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 725                 self.SendFlags |= 1;
 726         }
 727 }
 728
 729 void ClientInit_Spawn()
 730 {
 731         entity o;
 732         entity e;
 733         e = spawn();
 734         e.classname = "clientinit";
 735         e.think = ClientInit_CheckUpdate;
 736         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 737
 738         o = self;
 739         self = e;
 740         ClientInit_CheckUpdate();
 741         self = o;
 742 }
 743
 744 /*
 745 =============
 746 SetNewParms
 747 =============
 748 */
 749 void SetNewParms (void)
 750 {
 751         // initialize parms for a new player
 752         parm1 = -(86400 * 366);
 753 }
 754
 755 /*
 756 =============
 757 SetChangeParms
 758 =============
 759 */
 760 void SetChangeParms (void)
 761 {
 762         // save parms for level change
 763         parm1 = self.parm_idlesince - time;
 764 }
 765
 766 /*
 767 =============
 768 DecodeLevelParms
 769 =============
 770 */
 771 void DecodeLevelParms (void)
 772 {
 773         // load parms
 774         self.parm_idlesince = parm1;
 775         if(self.parm_idlesince == -(86400 * 366))
 776                 self.parm_idlesince = time;
 777
 778         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 779         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 780 }
 781
 782 /*
 783 =============
 784 ClientKill
 785
 786 Called when a client types 'kill' in the console
 787 =============
 788 */
 789
 790 .float clientkill_nexttime;
 791 void ClientKill_Now_TeamChange()
 792 {
 793         if(self.killindicator_teamchange == -1)
 794         {
 795                 JoinBestTeam( self, false, true );
 796         }
 797         else if(self.killindicator_teamchange == -2)
 798         {
 799                 if(blockSpectators)
 800                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 801                 PutObserverInServer();
 802         }
 803         else
 804                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 805         self.killindicator_teamchange = 0;
 806 }
 807
 808 void ClientKill_Now()
 809 {
 810         if(self.vehicle)
 811         {
 812             vehicles_exit(VHEF_RELESE);
 813             if(!self.killindicator_teamchange)
 814             {
 815             self.vehicle_health = -1;
 816             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 817             }
 818         }
 819
 820         if(self.killindicator && !wasfreed(self.killindicator))
 821                 remove(self.killindicator);
 822
 823         self.killindicator = world;
 824
 825         if(self.killindicator_teamchange)
 826                 ClientKill_Now_TeamChange();
 827
 828         if(IS_PLAYER(self))
 829                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 830
 831         // now I am sure the player IS dead
 832 }
 833 void KillIndicator_Think()
 834 {
 835         if (gameover)
 836         {
 837                 self.owner.killindicator = world;
 838                 remove(self);
 839                 return;
 840         }
 841
 842         if (self.owner.alpha < 0 && !self.owner.vehicle)
 843         {
 844                 self.owner.killindicator = world;
 845                 remove(self);
 846                 return;
 847         }
 848
 849         if(self.cnt <= 0)
 850         {
 851                 self = self.owner;
 852                 ClientKill_Now(); // no oldself needed
 853                 return;
 854         }
 855     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 856     {
 857         self.nextthink = time + 1;
 858         self.cnt -= 1;
 859     }
 860         else
 861         {
 862                 if(self.cnt <= 10)
 863                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 864                 if(IS_REAL_CLIENT(self.owner))
 865                 {
 866                         if(self.cnt <= 10)
 867                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 868                 }
 869                 self.nextthink = time + 1;
 870                 self.cnt -= 1;
 871         }
 872 }
 873
 874 float clientkilltime;
 875 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 876 {
 877         float killtime;
 878         float starttime;
 879         entity e;
 880
 881         if (gameover)
 882                 return;
 883
 884         killtime = autocvar_g_balance_kill_delay;
 885
 886         if(g_race_qualifying || g_cts)
 887                 killtime = 0;
 888
 889     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 890     {
 891                 remove(self.killindicator);
 892                 self.killindicator = world;
 893
 894         ClientKill_Now(); // allow instant kill in this case
 895         return;
 896     }
 897
 898         self.killindicator_teamchange = targetteam;
 899
 900     if(!self.killindicator)
 901         {
 902                 if(self.deadflag == DEAD_NO)
 903                 {
 904                         killtime = max(killtime, self.clientkill_nexttime - time);
 905                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 906                 }
 907
 908                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 909                 {
 910                         ClientKill_Now();
 911                 }
 912                 else
 913                 {
 914                         starttime = max(time, clientkilltime);
 915
 916                         self.killindicator = spawn();
 917                         self.killindicator.owner = self;
 918                         self.killindicator.scale = 0.5;
 919                         setattachment(self.killindicator, self, "");
 920                         setorigin(self.killindicator, '0 0 52');
 921                         self.killindicator.think = KillIndicator_Think;
 922                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 923                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 924                         self.killindicator.cnt = ceil(killtime);
 925                         self.killindicator.count = bound(0, ceil(killtime), 10);
 926                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 927
 928                         for(e = world; (e = find(e, classname, "body")) != world; )
 929                         {
 930                                 if(e.enemy != self)
 931                                         continue;
 932                                 e.killindicator = spawn();
 933                                 e.killindicator.owner = e;
 934                                 e.killindicator.scale = 0.5;
 935                                 setattachment(e.killindicator, e, "");
 936                                 setorigin(e.killindicator, '0 0 52');
 937                                 e.killindicator.think = KillIndicator_Think;
 938                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 939                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 940                                 e.killindicator.cnt = ceil(killtime);
 941                         }
 942                         self.lip = 0;
 943                 }
 944         }
 945         if(self.killindicator)
 946         {
 947                 if(targetteam == 0) // just die
 948                 {
 949                         self.killindicator.colormod = '0 0 0';
 950                         if(IS_REAL_CLIENT(self))
 951                         if(self.killindicator.cnt > 0)
 952                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 953                 }
 954                 else if(targetteam == -1) // auto
 955                 {
 956                         self.killindicator.colormod = '0 1 0';
 957                         if(IS_REAL_CLIENT(self))
 958                         if(self.killindicator.cnt > 0)
 959                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 960                 }
 961                 else if(targetteam == -2) // spectate
 962                 {
 963                         self.killindicator.colormod = '0.5 0.5 0.5';
 964                         if(IS_REAL_CLIENT(self))
 965                         if(self.killindicator.cnt > 0)
 966                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 967                 }
 968                 else
 969                 {
 970                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 971                         if(IS_REAL_CLIENT(self))
 972                         if(self.killindicator.cnt > 0)
 973                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 974                 }
 975         }
 976
 977 }
 978
 979 void ClientKill (void)
 980 {
 981         if(gameover) return;
 982         if(self.player_blocked) return;
 983         if(self.frozen) return;
 984
 985         ClientKill_TeamChange(0);
 986 }
 987
 988 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 989 {
 990     e.killindicator = spawn();
 991     e.killindicator.owner = e;
 992     e.killindicator.think = KillIndicator_Think;
 993     e.killindicator.nextthink = time + (e.lip) * 0.05;
 994     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 995     e.killindicator.health = 1; // this is used to indicate that it should be silent
 996     e.lip = 0;
 997 }
 998
 999 void FixClientCvars(entity e)
1000 {
1001         // send prediction settings to the client
1002         stuffcmd(e, "\nin_bindmap 0 0\n");
1003         if(g_race || g_cts)
1004                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1005         if(autocvar_g_antilag == 3) // client side hitscan
1006                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1007         if(autocvar_sv_gentle)
1008                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1009 }
1010
1011 float PlayerInIDList(entity p, string idlist)
1012 {
1013         float n, i;
1014         string s;
1015
1016         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1017         if (!p.crypto_idfp)
1018                 return 0;
1019
1020         // this function allows abbreviated player IDs too!
1021         n = tokenize_console(idlist);
1022         for(i = 0; i < n; ++i)
1023         {
1024                 s = argv(i);
1025                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1026                         return 1;
1027         }
1028
1029         return 0;
1030 }
1031
1032 /*
1033 =============
1034 ClientConnect
1035
1036 Called when a client connects to the server
1037 =============
1038 */
1039 void DecodeLevelParms (void);
1040 //void dom_player_join_team(entity pl);
1041 void set_dom_state(entity e);
1042 void ClientConnect (void)
1043 {
1044         float t;
1045
1046         if(IS_CLIENT(self))
1047         {
1048                 print("Warning: ClientConnect, but already connected!\n");
1049                 return;
1050         }
1051
1052         if(Ban_MaybeEnforceBanOnce(self))
1053                 return;
1054
1055         DecodeLevelParms();
1056
1057 #ifdef WATERMARK
1058         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1059 #endif
1060
1061         self.classname = "player_joining";
1062
1063         self.flags = FL_CLIENT;
1064         self.version_nagtime = time + 10 + random() * 10;
1065
1066         if(player_count<0)
1067         {
1068                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1069                 player_count = 0;
1070         }
1071
1072         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1073
1074         PlayerScore_Attach(self);
1075         ClientData_Attach();
1076         accuracy_init(self);
1077
1078         bot_clientconnect();
1079
1080         playerdemo_init();
1081
1082         anticheat_init();
1083
1084         // identify the right forced team
1085         if(autocvar_g_campaign)
1086         {
1087                 if(IS_REAL_CLIENT(self)) // only players, not bots
1088                 {
1089                         switch(autocvar_g_campaign_forceteam)
1090                         {
1091                                 case 1: self.team_forced = NUM_TEAM_1; break;
1092                                 case 2: self.team_forced = NUM_TEAM_2; break;
1093                                 case 3: self.team_forced = NUM_TEAM_3; break;
1094                                 case 4: self.team_forced = NUM_TEAM_4; break;
1095                                 default: self.team_forced = 0;
1096                         }
1097                 }
1098         }
1099         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1100                 self.team_forced = NUM_TEAM_1;
1101         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1102                 self.team_forced = NUM_TEAM_2;
1103         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1104                 self.team_forced = NUM_TEAM_3;
1105         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1106                 self.team_forced = NUM_TEAM_4;
1107         else if(autocvar_g_forced_team_otherwise == "red")
1108                 self.team_forced = NUM_TEAM_1;
1109         else if(autocvar_g_forced_team_otherwise == "blue")
1110                 self.team_forced = NUM_TEAM_2;
1111         else if(autocvar_g_forced_team_otherwise == "yellow")
1112                 self.team_forced = NUM_TEAM_3;
1113         else if(autocvar_g_forced_team_otherwise == "pink")
1114                 self.team_forced = NUM_TEAM_4;
1115         else if(autocvar_g_forced_team_otherwise == "spectate")
1116                 self.team_forced = -1;
1117         else if(autocvar_g_forced_team_otherwise == "spectator")
1118                 self.team_forced = -1;
1119         else
1120                 self.team_forced = 0;
1121
1122         if(!teamplay)
1123                 if(self.team_forced > 0)
1124                         self.team_forced = 0;
1125
1126         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1127
1128         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1129                 self.classname = "observer";
1130         } else {
1131                 if(teamplay)
1132                 {
1133                         if(autocvar_g_balance_teams)
1134                         {
1135                                 self.classname = "player";
1136                                 campaign_bots_may_start = 1;
1137                         }
1138                         else
1139                         {
1140                                 self.classname = "observer"; // do it anyway
1141                         }
1142                 }
1143                 else
1144                 {
1145                         self.classname = "player";
1146                         campaign_bots_may_start = 1;
1147                 }
1148         }
1149
1150         self.playerid = (playerid_last = playerid_last + 1);
1151
1152         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1153
1154     if(IS_BOT_CLIENT(self))
1155         PlayerStats_GameReport_AddPlayer(self);
1156
1157         if(autocvar_sv_eventlog)
1158                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1159
1160         LogTeamchange(self.playerid, self.team, 1);
1161
1162         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1163
1164         self.netname_previous = strzone(self.netname);
1165
1166         if(IS_PLAYER(self) && teamplay)
1167                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1168         else
1169                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1170
1171         stuffcmd(self, strcat(clientstuff, "\n"));
1172         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1173
1174         FixClientCvars(self);
1175
1176         // spawnfunc_waypoint sprites
1177         WaypointSprite_InitClient(self);
1178
1179         // Wazat's grappling hook
1180         SetGrappleHookBindings();
1181
1182         // Jetpack binds
1183         stuffcmd(self, "alias +jetpack +button10\n");
1184         stuffcmd(self, "alias -jetpack -button10\n");
1185
1186         // get version info from player
1187         stuffcmd(self, "cmd clientversion $gameversion\n");
1188
1189         // get other cvars from player
1190         GetCvars(0);
1191
1192         // notify about available teams
1193         if(teamplay)
1194         {
1195                 CheckAllowedTeams(self);
1196                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1197                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1198         }
1199         else
1200                 stuffcmd(self, "set _teams_available 0\n");
1201
1202         attach_entcs();
1203
1204         bot_relinkplayerlist();
1205
1206         self.spectatortime = time;
1207         if(blockSpectators)
1208         {
1209                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1210         }
1211
1212         self.jointime = time;
1213         self.allowed_timeouts = autocvar_sv_timeout_number;
1214
1215         if(IS_REAL_CLIENT(self))
1216         {
1217                 if(!autocvar_g_campaign)
1218                 {
1219                         self.motd_actived_time = -1;
1220                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1221                 }
1222
1223                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1224                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1225         }
1226
1227         if(!sv_foginterval && world.fog != "")
1228                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1229
1230         W_HitPlotOpen(self);
1231
1232         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1233                 send_CSQC_teamnagger();
1234
1235         CheatInitClient();
1236
1237         CSQCMODEL_AUTOINIT();
1238
1239         self.model_randomizer = random();
1240
1241         if(IS_REAL_CLIENT(self))
1242                 sv_notice_join();
1243
1244         MUTATOR_CALLHOOK(ClientConnect);
1245 }
1246 /*
1247 =============
1248 ClientDisconnect
1249
1250 Called when a client disconnects from the server
1251 =============
1252 */
1253 .entity chatbubbleentity;
1254 void ReadyCount();
1255 void ClientDisconnect (void)
1256 {
1257         if(self.vehicle)
1258             vehicles_exit(VHEF_RELESE);
1259
1260         if (!IS_CLIENT(self))
1261         {
1262                 print("Warning: ClientDisconnect without ClientConnect\n");
1263                 return;
1264         }
1265
1266         PlayerStats_GameReport_FinalizePlayer(self);
1267
1268         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1269
1270         CheatShutdownClient();
1271
1272         W_HitPlotClose(self);
1273
1274         anticheat_report();
1275         anticheat_shutdown();
1276
1277         playerdemo_shutdown();
1278
1279         bot_clientdisconnect();
1280
1281         if(self.entcs)
1282                 detach_entcs();
1283
1284         if(autocvar_sv_eventlog)
1285                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1286
1287         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1288
1289         MUTATOR_CALLHOOK(ClientDisconnect);
1290
1291         Portal_ClearAll(self);
1292
1293         Unfreeze(self);
1294
1295         RemoveGrapplingHook(self);
1296
1297         // Here, everything has been done that requires this player to be a client.
1298
1299         self.flags &= ~FL_CLIENT;
1300
1301         if (self.chatbubbleentity)
1302                 remove (self.chatbubbleentity);
1303
1304         if (self.killindicator)
1305                 remove (self.killindicator);
1306
1307         WaypointSprite_PlayerGone();
1308
1309         bot_relinkplayerlist();
1310
1311         accuracy_free(self);
1312         ClientData_Detach();
1313         PlayerScore_Detach(self);
1314
1315         if(self.netname_previous)
1316                 strunzone(self.netname_previous);
1317         if(self.clientstatus)
1318                 strunzone(self.clientstatus);
1319         if(self.weaponorder_byimpulse)
1320                 strunzone(self.weaponorder_byimpulse);
1321
1322         ClearPlayerSounds();
1323
1324         if(self.personal)
1325                 remove(self.personal);
1326
1327         self.playerid = 0;
1328         ReadyCount();
1329
1330         // free cvars
1331         GetCvars(-1);
1332 }
1333
1334 .float BUTTON_CHAT;
1335 void ChatBubbleThink()
1336 {
1337         self.nextthink = time;
1338         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1339         {
1340                 if(self.owner) // but why can that ever be world?
1341                         self.owner.chatbubbleentity = world;
1342                 remove(self);
1343                 return;
1344         }
1345         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1346 #ifdef TETRIS
1347                 || self.owner.tetris_on
1348 #endif
1349         )
1350                 self.model = self.mdl;
1351         else
1352                 self.model = "";
1353 }
1354
1355 void UpdateChatBubble()
1356 {
1357         if (self.alpha < 0)
1358                 return;
1359         // spawn a chatbubble entity if needed
1360         if (!self.chatbubbleentity)
1361         {
1362                 self.chatbubbleentity = spawn();
1363                 self.chatbubbleentity.owner = self;
1364                 self.chatbubbleentity.exteriormodeltoclient = self;
1365                 self.chatbubbleentity.think = ChatBubbleThink;
1366                 self.chatbubbleentity.nextthink = time;
1367                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1368                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1369                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1370                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1371                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1372                 self.chatbubbleentity.model = "";
1373                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1374         }
1375 }
1376
1377
1378 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1379 // added to the model skins
1380 /*void UpdateColorModHack()
1381 {
1382         float c;
1383         c = self.clientcolors & 15;
1384         // LordHavoc: only bothering to support white, green, red, yellow, blue
1385              if (!teamplay) self.colormod = '0 0 0';
1386         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1387         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1388         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1389         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1390         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1391         else self.colormod = '1 1 1';
1392 }*/
1393
1394 void respawn(void)
1395 {
1396         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1397         {
1398                 self.solid = SOLID_NOT;
1399                 self.takedamage = DAMAGE_NO;
1400                 self.movetype = MOVETYPE_FLY;
1401                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1402                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1403                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1404                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1405                 if(autocvar_g_respawn_ghosts_maxtime)
1406                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1407         }
1408
1409         CopyBody(1);
1410
1411         self.effects |= EF_NODRAW; // prevent another CopyBody
1412         PutClientInServer();
1413 }
1414
1415 void play_countdown(float finished, string samp)
1416 {
1417         if(IS_REAL_CLIENT(self))
1418                 if(floor(finished - time - frametime) != floor(finished - time))
1419                         if(finished - time < 6)
1420                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1421 }
1422
1423 void player_powerups (void)
1424 {
1425         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1426         olditems = self.items;
1427
1428         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1429                 self.modelflags |= MF_ROCKET;
1430         else
1431                 self.modelflags &= ~MF_ROCKET;
1432
1433         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1434
1435         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1436                 return;
1437
1438         Fire_ApplyDamage(self);
1439         Fire_ApplyEffect(self);
1440
1441         if (!g_instagib)
1442         {
1443                 if (self.items & IT_STRENGTH)
1444                 {
1445                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1446                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1447                         if (time > self.strength_finished)
1448                         {
1449                                 self.items = self.items - (self.items & IT_STRENGTH);
1450                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1451                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1452                         }
1453                 }
1454                 else
1455                 {
1456                         if (time < self.strength_finished)
1457                         {
1458                                 self.items = self.items | IT_STRENGTH;
1459                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1460                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1461                         }
1462                 }
1463                 if (self.items & IT_INVINCIBLE)
1464                 {
1465                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1466                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1467                         if (time > self.invincible_finished)
1468                         {
1469                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1470                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1471                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1472                         }
1473                 }
1474                 else
1475                 {
1476                         if (time < self.invincible_finished)
1477                         {
1478                                 self.items = self.items | IT_INVINCIBLE;
1479                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1480                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1481                         }
1482                 }
1483                 if (self.items & IT_SUPERWEAPON)
1484                 {
1485                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1486                         {
1487                                 self.superweapons_finished = 0;
1488                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1489                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1490                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1491                         }
1492                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1493                         {
1494                                 // don't let them run out
1495                         }
1496                         else
1497                         {
1498                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1499                                 if (time > self.superweapons_finished)
1500                                 {
1501                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1502                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1503                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1504                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1505                                 }
1506                         }
1507                 }
1508                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1509                 {
1510                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1511                         {
1512                                 self.items = self.items | IT_SUPERWEAPON;
1513                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1514                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1515                         }
1516                         else
1517                         {
1518                                 self.superweapons_finished = 0;
1519                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1520                         }
1521                 }
1522                 else
1523                 {
1524                         self.superweapons_finished = 0;
1525                 }
1526         }
1527
1528         if(autocvar_g_nodepthtestplayers)
1529                 self.effects = self.effects | EF_NODEPTHTEST;
1530
1531         if(autocvar_g_fullbrightplayers)
1532                 self.effects = self.effects | EF_FULLBRIGHT;
1533
1534         if (time >= game_starttime)
1535         if (time < self.spawnshieldtime)
1536                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1537
1538         MUTATOR_CALLHOOK(PlayerPowerups);
1539 }
1540
1541 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1542 {
1543         if(current > stable)
1544                 return current;
1545         else if(current > stable - 0.25) // when close enough, "snap"
1546                 return stable;
1547         else
1548                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1549 }
1550
1551 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1552 {
1553         if(current < stable)
1554                 return current;
1555         else if(current < stable + 0.25) // when close enough, "snap"
1556                 return stable;
1557         else
1558                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1559 }
1560
1561 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1562 {
1563         if(current > rotstable)
1564         {
1565                 if(rotframetime > 0)
1566                 {
1567                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1568                         current = max(rotstable, current - rotlinear * rotframetime);
1569                 }
1570         }
1571         else if(current < regenstable)
1572         {
1573                 if(regenframetime > 0)
1574                 {
1575                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1576                         current = min(regenstable, current + regenlinear * regenframetime);
1577                 }
1578         }
1579
1580         if(current > limit)
1581                 current = limit;
1582
1583         return current;
1584 }
1585
1586 void player_regen (void)
1587 {
1588         float max_mod, regen_mod, rot_mod, limit_mod;
1589         max_mod = regen_mod = rot_mod = limit_mod = 1;
1590         regen_mod_max = max_mod;
1591         regen_mod_regen = regen_mod;
1592         regen_mod_rot = rot_mod;
1593         regen_mod_limit = limit_mod;
1594         if(!MUTATOR_CALLHOOK(PlayerRegen))
1595         if(!self.frozen)
1596         {
1597                 float minh, mina, maxh, maxa, limith, limita;
1598                 maxh = autocvar_g_balance_health_rotstable;
1599                 maxa = autocvar_g_balance_armor_rotstable;
1600                 minh = autocvar_g_balance_health_regenstable;
1601                 mina = autocvar_g_balance_armor_regenstable;
1602                 limith = autocvar_g_balance_health_limit;
1603                 limita = autocvar_g_balance_armor_limit;
1604
1605                 max_mod = regen_mod_max;
1606                 regen_mod = regen_mod_regen;
1607                 rot_mod = regen_mod_rot;
1608                 limit_mod = regen_mod_limit;
1609
1610                 maxh = maxh * max_mod;
1611                 minh = minh * max_mod;
1612                 limith = limith * limit_mod;
1613                 limita = limita * limit_mod;
1614
1615                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1616                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1617         }
1618
1619         // if player rotted to death...  die!
1620         // check this outside above checks, as player may still be able to rot to death
1621         if(self.health < 1)
1622                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1623
1624         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1625         {
1626                 float minf, maxf, limitf;
1627
1628                 maxf = autocvar_g_balance_fuel_rotstable;
1629                 minf = autocvar_g_balance_fuel_regenstable;
1630                 limitf = autocvar_g_balance_fuel_limit;
1631
1632                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1633         }
1634 }
1635
1636 float zoomstate_set;
1637 void SetZoomState(float z)
1638 {
1639         if(z != self.zoomstate)
1640         {
1641                 self.zoomstate = z;
1642                 ClientData_Touch(self);
1643         }
1644         zoomstate_set = 1;
1645 }
1646
1647 void GetPressedKeys(void) {
1648         MUTATOR_CALLHOOK(GetPressedKeys);
1649         if (self.movement.x > 0) // get if movement keys are pressed
1650         {       // forward key pressed
1651                 self.pressedkeys |= KEY_FORWARD;
1652                 self.pressedkeys &= ~KEY_BACKWARD;
1653         }
1654         else if (self.movement.x < 0)
1655         {       // backward key pressed
1656                 self.pressedkeys |= KEY_BACKWARD;
1657                 self.pressedkeys &= ~KEY_FORWARD;
1658         }
1659         else
1660         {       // no x input
1661                 self.pressedkeys &= ~KEY_FORWARD;
1662                 self.pressedkeys &= ~KEY_BACKWARD;
1663         }
1664
1665         if (self.movement.y > 0)
1666         {       // right key pressed
1667                 self.pressedkeys |= KEY_RIGHT;
1668                 self.pressedkeys &= ~KEY_LEFT;
1669         }
1670         else if (self.movement.y < 0)
1671         {       // left key pressed
1672                 self.pressedkeys |= KEY_LEFT;
1673                 self.pressedkeys &= ~KEY_RIGHT;
1674         }
1675         else
1676         {       // no y input
1677                 self.pressedkeys &= ~KEY_RIGHT;
1678                 self.pressedkeys &= ~KEY_LEFT;
1679         }
1680
1681         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1682                 self.pressedkeys |= KEY_JUMP;
1683         else
1684                 self.pressedkeys &= ~KEY_JUMP;
1685         if (self.BUTTON_CROUCH)
1686                 self.pressedkeys |= KEY_CROUCH;
1687         else
1688                 self.pressedkeys &= ~KEY_CROUCH;
1689
1690         if (self.BUTTON_ATCK)
1691                 self.pressedkeys |= KEY_ATCK;
1692         else
1693                 self.pressedkeys &= ~KEY_ATCK;
1694         if (self.BUTTON_ATCK2)
1695                 self.pressedkeys |= KEY_ATCK2;
1696         else
1697                 self.pressedkeys &= ~KEY_ATCK2;
1698 }
1699
1700 /*
1701 ======================
1702 spectate mode routines
1703 ======================
1704 */
1705
1706 void SpectateCopy(entity spectatee) {
1707         other = spectatee;
1708         MUTATOR_CALLHOOK(SpectateCopy);
1709         self.armortype = spectatee.armortype;
1710         self.armorvalue = spectatee.armorvalue;
1711         self.ammo_cells = spectatee.ammo_cells;
1712         self.ammo_plasma = spectatee.ammo_plasma;
1713         self.ammo_shells = spectatee.ammo_shells;
1714         self.ammo_nails = spectatee.ammo_nails;
1715         self.ammo_rockets = spectatee.ammo_rockets;
1716         self.ammo_fuel = spectatee.ammo_fuel;
1717         self.clip_load = spectatee.clip_load;
1718         self.clip_size = spectatee.clip_size;
1719         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1720         self.health = spectatee.health;
1721         self.impulse = 0;
1722         self.items = spectatee.items;
1723         self.last_pickup = spectatee.last_pickup;
1724         self.hit_time = spectatee.hit_time;
1725         self.metertime = spectatee.metertime;
1726         self.strength_finished = spectatee.strength_finished;
1727         self.invincible_finished = spectatee.invincible_finished;
1728         self.pressedkeys = spectatee.pressedkeys;
1729         self.weapons = spectatee.weapons;
1730         self.switchweapon = spectatee.switchweapon;
1731         self.switchingweapon = spectatee.switchingweapon;
1732         self.weapon = spectatee.weapon;
1733         self.vortex_charge = spectatee.vortex_charge;
1734         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1735         self.hagar_load = spectatee.hagar_load;
1736         self.arc_heat_percent = spectatee.arc_heat_percent;
1737         self.minelayer_mines = spectatee.minelayer_mines;
1738         self.punchangle = spectatee.punchangle;
1739         self.view_ofs = spectatee.view_ofs;
1740         self.velocity = spectatee.velocity;
1741         self.dmg_take = spectatee.dmg_take;
1742         self.dmg_save = spectatee.dmg_save;
1743         self.dmg_inflictor = spectatee.dmg_inflictor;
1744         self.v_angle = spectatee.v_angle;
1745         self.angles = spectatee.v_angle;
1746         self.frozen = spectatee.frozen;
1747         self.revive_progress = spectatee.revive_progress;
1748         if(!self.BUTTON_USE)
1749                 self.fixangle = true;
1750         setorigin(self, spectatee.origin);
1751         setsize(self, spectatee.mins, spectatee.maxs);
1752         SetZoomState(spectatee.zoomstate);
1753
1754     anticheat_spectatecopy(spectatee);
1755         self.hud = spectatee.hud;
1756         if(spectatee.vehicle)
1757     {
1758         self.fixangle = false;
1759         //self.velocity = spectatee.vehicle.velocity;
1760         self.vehicle_health = spectatee.vehicle_health;
1761         self.vehicle_shield = spectatee.vehicle_shield;
1762         self.vehicle_energy = spectatee.vehicle_energy;
1763         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1764         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1765         self.vehicle_reload1 = spectatee.vehicle_reload1;
1766         self.vehicle_reload2 = spectatee.vehicle_reload2;
1767
1768         msg_entity = self;
1769
1770         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1771             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1772             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1773             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1774
1775         //WriteByte (MSG_ONE, SVC_SETVIEW);
1776         //    WriteEntity(MSG_ONE, self);
1777         //makevectors(spectatee.v_angle);
1778         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1779     }
1780 }
1781
1782 float SpectateUpdate()
1783 {
1784         if(!self.enemy)
1785             return 0;
1786
1787         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1788         {
1789                 SetSpectator(self, world);
1790                 return 0;
1791         }
1792
1793         SpectateCopy(self.enemy);
1794
1795         return 1;
1796 }
1797
1798 float SpectateSet()
1799 {
1800         if(self.enemy.classname != "player")
1801                 return false;
1802         /*if(self.enemy.vehicle)
1803         {
1804
1805                 msg_entity = self;
1806                 WriteByte(MSG_ONE, SVC_SETVIEW);
1807                 WriteEntity(MSG_ONE, self.enemy);
1808                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1809
1810                 self.movetype = MOVETYPE_NONE;
1811                 accuracy_resend(self);
1812         }
1813         else
1814         {*/
1815                 msg_entity = self;
1816                 WriteByte(MSG_ONE, SVC_SETVIEW);
1817                 WriteEntity(MSG_ONE, self.enemy);
1818                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1819                 self.movetype = MOVETYPE_NONE;
1820                 accuracy_resend(self);
1821
1822                 if(!SpectateUpdate())
1823                         PutObserverInServer();
1824         //}
1825         return true;
1826 }
1827
1828 void SetSpectator(entity player, entity spectatee)
1829 {
1830         entity old_spectatee = player.enemy;
1831
1832         player.enemy = spectatee;
1833
1834         // WEAPONTODO
1835         // these are required to fix the spectator bug with arc
1836         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1837         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1838 }
1839
1840 float Spectate(entity pl)
1841 {
1842         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1843         if(pl.team != self.team)
1844                 return 0;
1845
1846         SetSpectator(self, pl);
1847         return SpectateSet();
1848 }
1849
1850 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1851 entity CA_SpectateNext(entity start) {
1852         if (start.team == self.team) {
1853                 return start;
1854         }
1855
1856         other = start;
1857         // continue from current player
1858         while(other && other.team != self.team) {
1859                 other = find(other, classname, "player");
1860         }
1861
1862         if (!other) {
1863                 // restart from begining
1864                 other = find(other, classname, "player");
1865                 while(other && other.team != self.team) {
1866                         other = find(other, classname, "player");
1867                 }
1868         }
1869
1870         return other;
1871 }
1872
1873 float SpectateNext()
1874 {
1875         other = find(self.enemy, classname, "player");
1876
1877         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1878                 // CA and ca players when spectating enemies is forbidden
1879                 other = CA_SpectateNext(other);
1880         } else {
1881                 // other modes and ca spectators or spectating enemies is allowed
1882                 if (!other)
1883                         other = find(other, classname, "player");
1884         }
1885
1886         if(other) { SetSpectator(self, other); }
1887
1888         return SpectateSet();
1889 }
1890
1891 float SpectatePrev()
1892 {
1893         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1894         other = findchain(classname, "player");
1895         if (!other) // no player
1896                 return false;
1897
1898         entity first = other;
1899         // skip players until current spectated player
1900         if(self.enemy)
1901         while(other && other != self.enemy)
1902                 other = other.chain;
1903
1904         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1905         {
1906                 do { other = other.chain; }
1907                 while(other && other.team != self.team);
1908
1909                 if (!other)
1910                 {
1911                         other = first;
1912                         while(other.team != self.team)
1913                                 other = other.chain;
1914                         if(other == self.enemy)
1915                                 return true;
1916                 }
1917         }
1918         else
1919         {
1920                 if(other.chain)
1921                         other = other.chain;
1922                 else
1923                         other = first;
1924         }
1925         SetSpectator(self, other);
1926         return SpectateSet();
1927 }
1928
1929 /*
1930 =============
1931 ShowRespawnCountdown()
1932
1933 Update a respawn countdown display.
1934 =============
1935 */
1936 void ShowRespawnCountdown()
1937 {
1938         float number;
1939         if(self.deadflag == DEAD_NO) // just respawned?
1940                 return;
1941         else
1942         {
1943                 number = ceil(self.respawn_time - time);
1944                 if(number <= 0)
1945                         return;
1946                 if(number <= self.respawn_countdown)
1947                 {
1948                         self.respawn_countdown = number - 1;
1949                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1950                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1951                 }
1952         }
1953 }
1954
1955 void LeaveSpectatorMode()
1956 {
1957         if(self.caplayer)
1958                 return;
1959         if(nJoinAllowed(self))
1960         {
1961                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1962                 {
1963                         self.classname = "player";
1964                         nades_RemoveBonus(self);
1965
1966                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1967                                 { JoinBestTeam(self, false, true); }
1968
1969                         if(autocvar_g_campaign)
1970                                 { campaign_bots_may_start = 1; }
1971
1972                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1973
1974                         PutClientInServer();
1975
1976                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1977                 }
1978                 else
1979                         stuffcmd(self, "menu_showteamselect\n");
1980         }
1981         else
1982         {
1983                 // Player may not join because g_maxplayers is set
1984                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1985         }
1986 }
1987
1988 /**
1989  * Determines whether the player is allowed to join. This depends on cvar
1990  * g_maxplayers, if it isn't used this function always return true, otherwise
1991  * it checks whether the number of currently playing players exceeds g_maxplayers.
1992  * @return int number of free slots for players, 0 if none
1993  */
1994 float nJoinAllowed(entity ignore) {
1995         if(!ignore)
1996         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1997         // so report 0 free slots if restricted
1998         {
1999                 if(autocvar_g_forced_team_otherwise == "spectate")
2000                         return 0;
2001                 if(autocvar_g_forced_team_otherwise == "spectator")
2002                         return 0;
2003         }
2004
2005         if(self.team_forced < 0)
2006                 return 0; // forced spectators can never join
2007
2008         // TODO simplify this
2009         entity e;
2010         float totalClients = 0;
2011         FOR_EACH_CLIENT(e)
2012                 if(e != ignore)
2013                         totalClients += 1;
2014
2015         if (!autocvar_g_maxplayers)
2016                 return maxclients - totalClients;
2017
2018         float currentlyPlaying = 0;
2019         FOR_EACH_REALCLIENT(e)
2020                 if(IS_PLAYER(e) || e.caplayer)
2021                         currentlyPlaying += 1;
2022
2023         if(currentlyPlaying < autocvar_g_maxplayers)
2024                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2025
2026         return 0;
2027 }
2028
2029 /**
2030  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2031  * g_maxplayers_spectator_blocktime seconds
2032  */
2033 void checkSpectatorBlock() {
2034         if(IS_SPEC(self) || IS_OBSERVER(self))
2035         if(!self.caplayer)
2036         if(IS_REAL_CLIENT(self))
2037         {
2038                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2039                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2040                         dropclient(self);
2041                 }
2042         }
2043 }
2044
2045 void PrintWelcomeMessage()
2046 {
2047         if(self.motd_actived_time == 0)
2048         {
2049                 if (autocvar_g_campaign) {
2050                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2051                                 self.motd_actived_time = time;
2052                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2053                         }
2054                 } else {
2055                         if (self.BUTTON_INFO) {
2056                                 self.motd_actived_time = time;
2057                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2058                         }
2059                 }
2060         }
2061         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2062         {
2063                 if (autocvar_g_campaign) {
2064                         if (self.BUTTON_INFO)
2065                                 self.motd_actived_time = time;
2066                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2067                                 self.motd_actived_time = 0;
2068                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2069                         }
2070                 } else {
2071                         if (self.BUTTON_INFO)
2072                                 self.motd_actived_time = time;
2073                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2074                                 self.motd_actived_time = 0;
2075                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2076                         }
2077                 }
2078         }
2079         else //if(self.motd_actived_time < 0) // just connected, motd is active
2080         {
2081                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2082                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2083                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2084                 {
2085                         // instanctly hide MOTD
2086                         self.motd_actived_time = 0;
2087                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2088                 }
2089         }
2090 }
2091
2092 void ObserverThink()
2093 {
2094         float prefered_movetype;
2095         if (self.flags & FL_JUMPRELEASED) {
2096                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2097                         self.flags &= ~FL_JUMPRELEASED;
2098                         self.flags |= FL_SPAWNING;
2099                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2100                         self.flags &= ~FL_JUMPRELEASED;
2101                         if(SpectateNext()) {
2102                                 self.classname = "spectator";
2103                         }
2104                 } else {
2105                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2106                         if (self.movetype != prefered_movetype)
2107                                 self.movetype = prefered_movetype;
2108                 }
2109         } else {
2110                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2111                         self.flags |= FL_JUMPRELEASED;
2112                         if(self.flags & FL_SPAWNING)
2113                         {
2114                                 self.flags &= ~FL_SPAWNING;
2115                                 LeaveSpectatorMode();
2116                                 return;
2117                         }
2118                 }
2119         }
2120 }
2121
2122 void SpectatorThink()
2123 {
2124         if (self.flags & FL_JUMPRELEASED) {
2125                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2126                         self.flags &= ~FL_JUMPRELEASED;
2127                         self.flags |= FL_SPAWNING;
2128                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2129                         self.flags &= ~FL_JUMPRELEASED;
2130                         if(SpectateNext()) {
2131                                 self.classname = "spectator";
2132                         } else {
2133                                 self.classname = "observer";
2134                                 PutClientInServer();
2135                         }
2136                         self.impulse = 0;
2137                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2138                         self.flags &= ~FL_JUMPRELEASED;
2139                         if(SpectatePrev()) {
2140                                 self.classname = "spectator";
2141                         } else {
2142                                 self.classname = "observer";
2143                                 PutClientInServer();
2144                         }
2145                         self.impulse = 0;
2146                 } else if (self.BUTTON_ATCK2) {
2147                         self.flags &= ~FL_JUMPRELEASED;
2148                         self.classname = "observer";
2149                         PutClientInServer();
2150                 } else {
2151                         if(!SpectateUpdate())
2152                                 PutObserverInServer();
2153                 }
2154         } else {
2155                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2156                         self.flags |= FL_JUMPRELEASED;
2157                         if(self.flags & FL_SPAWNING)
2158                         {
2159                                 self.flags &= ~FL_SPAWNING;
2160                                 LeaveSpectatorMode();
2161                                 return;
2162                         }
2163                 }
2164                 if(!SpectateUpdate())
2165                         PutObserverInServer();
2166         }
2167
2168         self.flags |= FL_CLIENT | FL_NOTARGET;
2169 }
2170
2171 void PlayerUseKey()
2172 {
2173         if (!IS_PLAYER(self))
2174                 return;
2175
2176         if(self.vehicle)
2177         {
2178         vehicles_exit(VHEF_NORMAL);
2179         return;
2180         }
2181
2182         // a use key was pressed; call handlers
2183         MUTATOR_CALLHOOK(PlayerUseKey);
2184 }
2185
2186 float isInvisibleString(string s)
2187 {
2188         float i, n, c;
2189         s = strdecolorize(s);
2190         for((i = 0), (n = strlen(s)); i < n; ++i)
2191         {
2192                 c = str2chr(s, i);
2193                 switch(c)
2194                 {
2195                         case 0:
2196                         case 32: // space
2197                                 break;
2198                         case 192: // charmap space
2199                                 if (!autocvar_utf8_enable)
2200                                         break;
2201                                 return false;
2202                         case 160: // space in unicode fonts
2203                         case 0xE000 + 192: // utf8 charmap space
2204                                 if (autocvar_utf8_enable)
2205                                         break;
2206                         default:
2207                                 return false;
2208                 }
2209         }
2210         return true;
2211 }
2212
2213 /*
2214 =============
2215 PlayerPreThink
2216
2217 Called every frame for each client before the physics are run
2218 =============
2219 */
2220 .float usekeypressed;
2221 void() nexball_setstatus;
2222 .float items_added;
2223 void PlayerPreThink (void)
2224 {
2225         WarpZone_PlayerPhysics_FixVAngle();
2226
2227         self.stat_game_starttime = game_starttime;
2228         self.stat_round_starttime = round_starttime;
2229         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2230         self.stat_leadlimit = autocvar_leadlimit;
2231
2232         if(frametime)
2233         {
2234                 // physics frames: update anticheat stuff
2235                 anticheat_prethink();
2236         }
2237
2238         if(blockSpectators && frametime)
2239                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2240                 checkSpectatorBlock();
2241
2242         zoomstate_set = 0;
2243
2244         // Savage: Check for nameless players
2245         if (isInvisibleString(self.netname)) {
2246                 string new_name = strzone(strcat("Player@", self.netaddress));
2247                 if(autocvar_sv_eventlog)
2248                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2249                 if(self.netname_previous)
2250                         strunzone(self.netname_previous);
2251                 self.netname_previous = strzone(new_name);
2252                 self.netname = self.netname_previous;
2253                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2254         } else if(self.netname_previous != self.netname) {
2255                 if(autocvar_sv_eventlog)
2256                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2257                 if(self.netname_previous)
2258                         strunzone(self.netname_previous);
2259                 self.netname_previous = strzone(self.netname);
2260         }
2261
2262         // version nagging
2263         if(self.version_nagtime)
2264                 if(self.cvar_g_xonoticversion)
2265                         if(time > self.version_nagtime)
2266                         {
2267                                 // don't notify git users
2268                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2269                                 {
2270                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2271                                         {
2272                                                 // notify release users if connecting to git
2273                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2274                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2275                                         }
2276                                         else
2277                                         {
2278                                                 float r;
2279                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2280                                                 if(r < 0)
2281                                                 {
2282                                                         // give users new version
2283                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2284                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2285                                                 }
2286                                                 else if(r > 0)
2287                                                 {
2288                                                         // notify users about old server version
2289                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2290                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2291                                                 }
2292                                         }
2293                                 }
2294                                 self.version_nagtime = 0;
2295                         }
2296
2297         // GOD MODE info
2298         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2299         {
2300                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2301                 self.max_armorvalue = 0;
2302         }
2303
2304 #ifdef TETRIS
2305         if (TetrisPreFrame())
2306                 return;
2307 #endif
2308
2309         if(self.frozen == 2)
2310         {
2311                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2312                 self.health = max(1, self.revive_progress * start_health);
2313                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2314
2315                 if(self.revive_progress >= 1)
2316                         Unfreeze(self);
2317         }
2318         else if(self.frozen == 3)
2319         {
2320                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2321                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2322
2323                 if(self.health < 1)
2324                 {
2325                         if(self.vehicle)
2326                                 vehicles_exit(VHEF_RELESE);
2327                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2328                 }
2329                 else if ( self.revive_progress <= 0 )
2330                         Unfreeze(self);
2331         }
2332
2333         MUTATOR_CALLHOOK(PlayerPreThink);
2334
2335         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2336         {
2337                 if(self.BUTTON_USE && !self.usekeypressed)
2338                         PlayerUseKey();
2339                 self.usekeypressed = self.BUTTON_USE;
2340         }
2341
2342         if(IS_REAL_CLIENT(self))
2343                 PrintWelcomeMessage();
2344
2345         if(IS_PLAYER(self))
2346         {
2347
2348                 CheckRules_Player();
2349
2350                 if (intermission_running)
2351                 {
2352                         IntermissionThink ();   // otherwise a button could be missed between
2353                         return;                                 // the think tics
2354                 }
2355
2356                 //don't allow the player to turn around while game is paused!
2357                 if(timeout_status == TIMEOUT_ACTIVE) {
2358                         // FIXME turn this into CSQC stuff
2359                         self.v_angle = self.lastV_angle;
2360                         self.angles = self.lastV_angle;
2361                         self.fixangle = true;
2362                 }
2363
2364                 if(frametime)
2365                 {
2366                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2367                         {
2368                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2369                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2370                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2371
2372                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2373                                 {
2374                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2375                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2376                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2377                                 }
2378                         }
2379                         else
2380                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2381
2382                         player_powerups();
2383                 }
2384
2385                 if (self.deadflag != DEAD_NO)
2386                 {
2387                         if(self.personal && g_race_qualifying)
2388                         {
2389                                 if(time > self.respawn_time)
2390                                 {
2391                                         self.respawn_time = time + 1; // only retry once a second
2392                                         self.stat_respawn_time = self.respawn_time;
2393                                         respawn();
2394                                         self.impulse = 141;
2395                                 }
2396                         }
2397                         else
2398                         {
2399                                 float button_pressed;
2400                                 if(frametime)
2401                                         player_anim();
2402                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2403
2404                                 if (self.deadflag == DEAD_DYING)
2405                                 {
2406                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2407                                                 self.deadflag = DEAD_RESPAWNING;
2408                                         else if(!button_pressed)
2409                                                 self.deadflag = DEAD_DEAD;
2410                                 }
2411                                 else if (self.deadflag == DEAD_DEAD)
2412                                 {
2413                                         if(button_pressed)
2414                                                 self.deadflag = DEAD_RESPAWNABLE;
2415                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2416                                                 self.deadflag = DEAD_RESPAWNING;
2417                                 }
2418                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2419                                 {
2420                                         if(!button_pressed)
2421                                                 self.deadflag = DEAD_RESPAWNING;
2422                                 }
2423                                 else if (self.deadflag == DEAD_RESPAWNING)
2424                                 {
2425                                         if(time > self.respawn_time)
2426                                         {
2427                                                 self.respawn_time = time + 1; // only retry once a second
2428                                                 self.respawn_time_max = self.respawn_time;
2429                                                 respawn();
2430                                         }
2431                                 }
2432
2433                                 ShowRespawnCountdown();
2434
2435                                 if(self.respawn_flags & RESPAWN_SILENT)
2436                                         self.stat_respawn_time = 0;
2437                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2438                                         self.stat_respawn_time = self.respawn_time_max;
2439                                 else
2440                                         self.stat_respawn_time = self.respawn_time;
2441                         }
2442
2443                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2444                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2445                                 self.stat_respawn_time *= -1;
2446
2447                         return;
2448                 }
2449
2450                 self.prevorigin = self.origin;
2451
2452                 float do_crouch = self.BUTTON_CROUCH;
2453                 if(self.hook.state)
2454                         do_crouch = 0;
2455                 if(self.vehicle)
2456                         do_crouch = 0;
2457                 if(self.frozen)
2458                         do_crouch = 0;
2459
2460                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2461                 // It cannot be predicted by the engine!
2462                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2463                         do_crouch = 0;
2464
2465                 if (do_crouch)
2466                 {
2467                         if (!self.crouch)
2468                         {
2469                                 self.crouch = true;
2470                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2471                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2472                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2473                         }
2474                 }
2475                 else
2476                 {
2477                         if (self.crouch)
2478                         {
2479                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2480                                 if (!trace_startsolid)
2481                                 {
2482                                         self.crouch = false;
2483                                         self.view_ofs = PL_VIEW_OFS;
2484                                         setsize (self, PL_MIN, PL_MAX);
2485                                 }
2486                         }
2487                 }
2488
2489                 FixPlayermodel();
2490
2491                 GrapplingHookFrame();
2492
2493                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2494                 //if(frametime)
2495                 {
2496                         self.items &= ~self.items_added;
2497
2498                         W_WeaponFrame();
2499
2500                         self.items_added = 0;
2501                         if(self.items & IT_JETPACK)
2502                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2503                                         self.items_added |= IT_FUEL;
2504
2505                         self.items |= self.items_added;
2506                 }
2507
2508                 player_regen();
2509
2510                 // WEAPONTODO: Add a weapon request for this
2511                 // rot vortex charge to the charge limit
2512                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2513                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2514
2515                 if(frametime)
2516                         player_anim();
2517
2518                 // secret status
2519                 secrets_setstatus();
2520
2521                 // monsters status
2522                 monsters_setstatus();
2523
2524                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2525
2526                 //self.angles_y=self.v_angle_y + 90;   // temp
2527         } else if(gameover) {
2528                 if (intermission_running)
2529                         IntermissionThink ();   // otherwise a button could be missed between
2530                 return;
2531         } else if(IS_OBSERVER(self)) {
2532                 ObserverThink();
2533         } else if(IS_SPEC(self)) {
2534                 SpectatorThink();
2535         }
2536
2537         // WEAPONTODO: Add weapon request for this
2538         if(!zoomstate_set)
2539                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2540
2541         float oldspectatee_status;
2542         oldspectatee_status = self.spectatee_status;
2543         if(IS_SPEC(self))
2544                 self.spectatee_status = num_for_edict(self.enemy);
2545         else if(IS_OBSERVER(self))
2546                 self.spectatee_status = num_for_edict(self);
2547         else
2548                 self.spectatee_status = 0;
2549         if(self.spectatee_status != oldspectatee_status)
2550         {
2551                 ClientData_Touch(self);
2552         }
2553
2554         if(self.teamkill_soundtime)
2555         if(time > self.teamkill_soundtime)
2556         {
2557                 self.teamkill_soundtime = 0;
2558
2559                 entity oldpusher, oldself;
2560
2561                 oldself = self; self = self.teamkill_soundsource;
2562                 oldpusher = self.pusher; self.pusher = oldself;
2563
2564                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2565
2566                 self.pusher = oldpusher;
2567                 self = oldself;
2568         }
2569
2570         if(self.taunt_soundtime)
2571         if(time > self.taunt_soundtime)
2572         {
2573                 self.taunt_soundtime = 0;
2574                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2575         }
2576
2577         target_voicescript_next(self);
2578
2579         // WEAPONTODO: Move into weaponsystem somehow
2580         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2581         if(!self.weapon)
2582                 self.clip_load = self.clip_size = 0;
2583 }
2584
2585 /*
2586 =============
2587 PlayerPostThink
2588
2589 Called every frame for each client after the physics are run
2590 =============
2591 */
2592 .float idlekick_lasttimeleft;
2593 void PlayerPostThink (void)
2594 {
2595         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2596         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2597         {
2598                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2599                 {
2600                         if(self.idlekick_lasttimeleft)
2601                         {
2602                                 self.idlekick_lasttimeleft = 0;
2603                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2604                         }
2605                 }
2606                 else
2607                 {
2608                         float timeleft;
2609                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2610                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2611                         {
2612                                 if(!self.idlekick_lasttimeleft)
2613                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2614                         }
2615                         if(timeleft <= 0)
2616                         {
2617                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2618                                 dropclient(self);
2619                                 return;
2620                         }
2621                         else if(timeleft <= 10)
2622                         {
2623                                 if(timeleft != self.idlekick_lasttimeleft)
2624                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2625                                 self.idlekick_lasttimeleft = timeleft;
2626                         }
2627                 }
2628         }
2629
2630 #ifdef TETRIS
2631         if(self.impulse == 100)
2632                 ImpulseCommands();
2633         if (!TetrisPostFrame())
2634         {
2635 #endif
2636
2637         CheatFrame();
2638
2639         //CheckPlayerJump();
2640
2641         if(IS_PLAYER(self)) {
2642                 CheckRules_Player();
2643                 UpdateChatBubble();
2644                 if (self.impulse)
2645                         ImpulseCommands();
2646                 if (intermission_running)
2647                         return;         // intermission or finale
2648                 GetPressedKeys();
2649         }
2650
2651 #ifdef TETRIS
2652         }
2653 #endif
2654
2655         /*
2656         float i;
2657         for(i = 0; i < 1000; ++i)
2658         {
2659                 vector end;
2660                 end = self.origin + '0 0 1024' + 512 * randomvec();
2661                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2662                 if(trace_fraction < 1)
2663                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2664                 {
2665                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2666                         break;
2667                 }
2668         }
2669         */
2670
2671         if(self.waypointsprite_attachedforcarrier)
2672                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2673
2674         playerdemo_write();
2675
2676         CSQCMODEL_AUTOUPDATE();
2677 }