qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 float sv_accelerate;
   5 float sv_friction;
   6 float sv_maxspeed;
   7 float sv_airaccelerate;
   8 float sv_maxairspeed;
   9 float sv_stopspeed;
  10 float sv_gravity;
  11 float sv_airaccel_sideways_friction;
  12 float sv_airaccel_qw;
  13 float sv_airstopaccelerate;
  14 float sv_airstrafeaccelerate;
  15 float sv_maxairstrafespeed;
  16 float sv_airstrafeaccel_qw;
  17 float sv_aircontrol;
  18 float sv_aircontrol_power;
  19 float sv_warsowbunny_airforwardaccel;
  20 float sv_warsowbunny_accel;
  21 float sv_warsowbunny_topspeed;
  22 float sv_warsowbunny_turnaccel;
  23 float sv_warsowbunny_backtosideratio;
  24 float sv_speedlimit;
  25
  26 .float ladder_time;
  27 .entity ladder_entity;
  28 .float gravity;
  29 .float swamp_slowdown;
  30 .float lastflags;
  31 .float lastground;
  32 .float wasFlying;
  33 .float spectatorspeed;
  34
  35 /*
  36 =============
  37 PlayerJump
  38
  39 When you press the jump key
  40 =============
  41 */
  42 void PlayerJump (void)
  43 {
  44         float mjumpheight;
  45
  46         mjumpheight = cvar("sv_jumpvelocity");
  47         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  48         {
  49                 if (self.watertype == CONTENT_WATER)
  50                         self.velocity_z = 200;
  51                 else if (self.watertype == CONTENT_SLIME)
  52                         self.velocity_z = 80;
  53                 else
  54                         self.velocity_z = 50;
  55
  56                 return;
  57         }
  58
  59         if (!(self.flags & FL_ONGROUND))
  60                 return;
  61
  62         if(!sv_pogostick)
  63                 if (!(self.flags & FL_JUMPRELEASED))
  64                         return;
  65
  66         if(self.health <= g_bloodloss)
  67                 return;
  68
  69         if(g_runematch)
  70         {
  71                 if(self.runes & RUNE_SPEED)
  72                 {
  73                         if(self.runes & CURSE_SLOW)
  74                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  75                         else
  76                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  77                 }
  78                 else if(self.runes & CURSE_SLOW)
  79                 {
  80                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  81                 }
  82         }
  83
  84         if(g_minstagib && (self.items & IT_INVINCIBLE))
  85         {
  86                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  87         }
  88
  89         if(cvar_string("sv_jumpspeedcap_min") != "")
  90                 self.velocity_z = max(cvar("sv_jumpvelocity") * cvar("sv_jumpspeedcap_min"), self.velocity_z);
  91         if(cvar_string("sv_jumpspeedcap_max") != "") {
  92                 if(trace_fraction < 1 && trace_plane_normal_z < 0.98 && cvar("sv_jumpspeedcap_max_disable_on_ramps")) {
  93                         // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
  94                         //print("Trace plane normal z: ", ftos(trace_plane_normal_z), ", disabling speed cap!\n");
  95                 }
  96                 else
  97                         self.velocity_z = min(cvar("sv_jumpvelocity") * cvar("sv_jumpspeedcap_max"), self.velocity_z) + trace_ent.velocity_z;
  98         }
  99
 100         if(!(self.lastflags & FL_ONGROUND))
 101         {
 102                 if(cvar("speedmeter"))
 103                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 104                 if(self.lastground < time - 0.3)
 105                 {
 106                         self.velocity_x *= (1 - cvar("sv_friction_on_land"));
 107                         self.velocity_y *= (1 - cvar("sv_friction_on_land"));
 108                 }
 109                 if(self.jumppadcount > 1)
 110                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 111                 self.jumppadcount = 0;
 112         }
 113
 114         self.velocity_z = self.velocity_z + mjumpheight;
 115         self.oldvelocity_z = self.velocity_z;
 116
 117         self.flags &~= FL_ONGROUND;
 118         self.flags &~= FL_JUMPRELEASED;
 119
 120         if (self.crouch)
 121                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 122         else
 123                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 124
 125         if(g_jump_grunt)
 126                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 127
 128         self.restart_jump = -1; // restart jump anim next time
 129         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 130 }
 131
 132 void CheckWaterJump()
 133 {
 134         local vector start, end;
 135
 136 // check for a jump-out-of-water
 137         makevectors (self.angles);
 138         start = self.origin;
 139         start_z = start_z + 8;
 140         v_forward_z = 0;
 141         normalize(v_forward);
 142         end = start + v_forward*24;
 143         traceline (start, end, TRUE, self);
 144         if (trace_fraction < 1)
 145         {       // solid at waist
 146                 start_z = start_z + self.maxs_z - 8;
 147                 end = start + v_forward*24;
 148                 self.movedir = trace_plane_normal * -50;
 149                 traceline (start, end, TRUE, self);
 150                 if (trace_fraction == 1)
 151                 {       // open at eye level
 152                         self.flags |= FL_WATERJUMP;
 153                         self.velocity_z = 225;
 154                         self.flags &~= FL_JUMPRELEASED;
 155                         self.teleport_time = time + 2;  // safety net
 156                         return;
 157                 }
 158         }
 159 };
 160
 161 float racecar_angle(float forward, float down)
 162 {
 163         float ret, angle_mult;
 164
 165         if(forward < 0)
 166         {
 167                 forward = -forward;
 168                 down = -down;
 169         }
 170
 171         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 172
 173         angle_mult = forward / (800 + forward);
 174
 175         if(ret > 180)
 176                 return ret * angle_mult + 360 * (1 - angle_mult);
 177         else
 178                 return ret * angle_mult;
 179 }
 180
 181 void RaceCarPhysics()
 182 {
 183         // using this move type for "big rigs"
 184         // the engine does not push the entity!
 185
 186         float accel, steer, f;
 187         vector angles_save, rigvel;
 188
 189         angles_save = self.angles;
 190         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 191         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 192
 193         if(g_bugrigs_reverse_speeding)
 194         {
 195                 if(accel < 0)
 196                 {
 197                         // back accel is DIGITAL
 198                         // to prevent speedhack
 199                         if(accel < -0.5)
 200                                 accel = -1;
 201                         else
 202                                 accel = 0;
 203                 }
 204         }
 205
 206         self.angles_x = 0;
 207         self.angles_z = 0;
 208         makevectors(self.angles); // new forward direction!
 209
 210         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 211         {
 212                 float myspeed, upspeed, steerfactor, accelfactor;
 213
 214                 myspeed = self.velocity * v_forward;
 215                 upspeed = self.velocity * v_up;
 216
 217                 // responsiveness factor for steering and acceleration
 218                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 219                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 220
 221                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 222                         steerfactor = -myspeed * g_bugrigs_steer;
 223                 else
 224                         steerfactor = -myspeed * f * g_bugrigs_steer;
 225
 226                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 227                         accelfactor = g_bugrigs_accel;
 228                 else
 229                         accelfactor = f * g_bugrigs_accel;
 230                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 231
 232                 if(accel < 0)
 233                 {
 234                         if(myspeed > 0)
 235                         {
 236                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 237                         }
 238                         else
 239                         {
 240                                 if(!g_bugrigs_reverse_speeding)
 241                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 242                         }
 243                 }
 244                 else
 245                 {
 246                         if(myspeed >= 0)
 247                         {
 248                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 249                         }
 250                         else
 251                         {
 252                                 if(g_bugrigs_reverse_stopping)
 253                                         myspeed = 0;
 254                                 else
 255                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 256                         }
 257                 }
 258                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 259                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 260
 261                 self.angles_y += steer * frametime * steerfactor; // apply steering
 262                 makevectors(self.angles); // new forward direction!
 263
 264                 myspeed += accel * accelfactor * frametime;
 265
 266                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 267         }
 268         else
 269         {
 270                 myspeed = vlen(self.velocity);
 271
 272                 // responsiveness factor for steering and acceleration
 273                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 274                 steerfactor = -myspeed * f;
 275                 self.angles_y += steer * frametime * steerfactor; // apply steering
 276
 277                 rigvel = self.velocity;
 278                 makevectors(self.angles); // new forward direction!
 279         }
 280
 281         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 282         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 283         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 284         //MAXIMA: solve(total_acceleration(v) = 0, v);
 285
 286         if(g_bugrigs_planar_movement)
 287         {
 288                 vector rigvel_xy, neworigin, up;
 289                 float mt;
 290
 291                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 292                 rigvel_xy = rigvel;
 293                 rigvel_xy_z = 0;
 294
 295                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 296                         mt = MOVE_NORMAL;
 297                 else
 298                         mt = MOVE_NOMONSTERS;
 299
 300                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 301                 up = trace_endpos - self.origin;
 302
 303                 // BUG RIGS: align the move to the surface instead of doing collision testing
 304                 // can we move?
 305                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 306
 307                 // align to surface
 308                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 309
 310                 if(trace_fraction < 0.5)
 311                 {
 312                         trace_fraction = 1;
 313                         neworigin = self.origin;
 314                 }
 315                 else
 316                         neworigin = trace_endpos;
 317
 318                 if(trace_fraction < 1)
 319                 {
 320                         // now set angles_x so that the car points parallel to the surface
 321                         self.angles = vectoangles(
 322                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 323                                         +
 324                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 325                                         +
 326                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 327                                         );
 328                         self.flags |= FL_ONGROUND;
 329                 }
 330                 else
 331                 {
 332                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 333                         self.flags &~= FL_ONGROUND;
 334                 }
 335
 336                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 337                 self.movetype = MOVETYPE_NOCLIP;
 338         }
 339         else
 340         {
 341                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 342                 self.velocity = rigvel;
 343                 self.movetype = MOVETYPE_FLY;
 344         }
 345
 346         trace_fraction = 1;
 347         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 348         if(trace_fraction != 1)
 349         {
 350                 self.angles = vectoangles2(
 351                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 352                                 +
 353                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 354                                 +
 355                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 356                                 trace_plane_normal
 357                                 );
 358         }
 359         else
 360         {
 361                 vector vel_local;
 362
 363                 vel_local_x = v_forward * self.velocity;
 364                 vel_local_y = v_right * self.velocity;
 365                 vel_local_z = v_up * self.velocity;
 366
 367                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 368                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 369         }
 370
 371         // smooth the angles
 372         vector vf1, vu1, smoothangles;
 373         makevectors(self.angles);
 374         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 375         if(f == 0)
 376                 f = 1;
 377         vf1 = v_forward * f;
 378         vu1 = v_up * f;
 379         makevectors(angles_save);
 380         vf1 = vf1 + v_forward * (1 - f);
 381         vu1 = vu1 + v_up * (1 - f);
 382         smoothangles = vectoangles2(vf1, vu1);
 383         self.angles_x = -smoothangles_x;
 384         self.angles_z =  smoothangles_z;
 385 }
 386
 387 float IsMoveInDirection(vector mv, float angle) // key mix factor
 388 {
 389         if(mv_x == 0 && mv_y == 0)
 390                 return 0; // avoid division by zero
 391         angle -= RAD2DEG * atan2(mv_y, mv_x);
 392         angle = remainder(angle, 360) / 45;
 393         if(angle >  1)
 394                 return 0;
 395         if(angle < -1)
 396                 return 0;
 397         return 1 - fabs(angle);
 398 }
 399
 400 float GeomLerp(float a, float lerp, float b)
 401 {
 402         if(a == 0)
 403         {
 404                 if(lerp < 1)
 405                         return 0;
 406                 else
 407                         return b;
 408         }
 409         if(b == 0)
 410         {
 411                 if(lerp > 0)
 412                         return 0;
 413                 else
 414                         return a;
 415         }
 416         return a * pow(fabs(b / a), lerp);
 417 }
 418
 419 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 420 {
 421         float zspeed, xyspeed, dot, k;
 422
 423 #if 0
 424         // this doesn't play well with analog input
 425         if(self.movement_x == 0 || self.movement_y != 0)
 426                 return; // can't control movement if not moving forward or backward
 427         k = 32;
 428 #else
 429         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 430         if(k <= 0)
 431                 return;
 432 #endif
 433
 434         k *= bound(0, wishspeed / sv_maxairspeed, 1);
 435
 436         zspeed = self.velocity_z;
 437         self.velocity_z = 0;
 438         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 439
 440         dot = self.velocity * wishdir;
 441
 442         if(dot > 0) // we can't change direction while slowing down
 443         {
 444                 k *= fabs(sv_aircontrol)*pow(dot, sv_aircontrol_power)*frametime;
 445                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 446         }
 447
 448         self.velocity = self.velocity * xyspeed;
 449         self.velocity_z = zspeed;
 450 }
 451
 452 float AdjustAirAccelQW(float accelqw, float factor)
 453 {
 454         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 455 }
 456
 457 // example config for alternate speed clamping:
 458 //   sv_airaccel_qw 0.8
 459 //   sv_airaccel_sideways_friction 0
 460 //   prvm_globalset server speedclamp_mode 1
 461 //     (or 2)
 462 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float sidefric)
 463 {
 464         float vel_straight;
 465         float vel_z;
 466         vector vel_perpend;
 467         float step;
 468
 469         vector vel_xy;
 470         float vel_xy_current;
 471         float vel_xy_backward, vel_xy_forward;
 472         float speedclamp;
 473
 474         speedclamp = (accelqw < 0);
 475         if(speedclamp)
 476                 accelqw = -accelqw;
 477
 478         if(cvar("sv_gameplayfix_q2airaccelerate"))
 479                 wishspeed0 = wishspeed;
 480
 481         vel_straight = self.velocity * wishdir;
 482         vel_z = self.velocity_z;
 483         vel_xy = self.velocity - vel_z * '0 0 1';
 484         vel_perpend = vel_xy - vel_straight * wishdir;
 485
 486         step = accel * frametime * wishspeed0;
 487
 488         vel_xy_current  = vlen(vel_xy);
 489         if(sv_speedlimit)
 490                 accelqw = AdjustAirAccelQW(accelqw, (sv_speedlimit - bound(wishspeed, vel_xy_current, sv_speedlimit)) / max(1, sv_speedlimit - wishspeed));
 491         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 492         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 493         if(vel_xy_backward < 0)
 494                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 495
 496         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 497
 498         if(sidefric < 0 && (vel_perpend*vel_perpend))
 499                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 500         {
 501                 float f, fminimum;
 502                 f = max(0, 1 + frametime * wishspeed * sidefric);
 503                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 504                 // this cannot be > 1
 505                 if(fminimum <= 0)
 506                         vel_perpend = vel_perpend * max(0, f);
 507                 else
 508                 {
 509                         fminimum = sqrt(fminimum);
 510                         vel_perpend = vel_perpend * max(fminimum, f);
 511                 }
 512         }
 513         else
 514                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
 515
 516         vel_xy = vel_straight * wishdir + vel_perpend;
 517
 518         if(speedclamp)
 519         {
 520                 // ensure we don't get too fast or decelerate faster than we should
 521                 vel_xy_current = min(vlen(vel_xy), vel_xy_forward);
 522                 if(vel_xy_current > 0) // prevent division by zero
 523                         vel_xy = normalize(vel_xy) * vel_xy_current;
 524         }
 525
 526         self.velocity = vel_xy + vel_z * '0 0 1';
 527 }
 528
 529 void PM_AirAccelerate(vector wishdir, float wishspeed)
 530 {
 531         vector curvel, wishvel, acceldir, curdir;
 532         float addspeed, accelspeed, curspeed, f;
 533         float dot;
 534
 535         if(wishspeed == 0)
 536                 return;
 537
 538         curvel = self.velocity;
 539         curvel_z = 0;
 540         curspeed = vlen(curvel);
 541
 542         if(wishspeed > curspeed * 1.01)
 543         {
 544                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * sv_maxspeed * frametime);
 545         }
 546         else
 547         {
 548                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - sv_maxspeed));
 549                 wishspeed = max(curspeed, sv_maxspeed) + sv_warsowbunny_accel * f * sv_maxspeed * frametime;
 550         }
 551         wishvel = wishdir * wishspeed;
 552         acceldir = wishvel - curvel;
 553         addspeed = vlen(acceldir);
 554         acceldir = normalize(acceldir);
 555
 556         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * sv_maxspeed * frametime);
 557
 558         if(sv_warsowbunny_backtosideratio < 1)
 559         {
 560                 curdir = normalize(curvel);
 561                 dot = acceldir * curdir;
 562                 if(dot < 0)
 563                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 564         }
 565
 566         self.velocity += accelspeed * acceldir;
 567 }
 568
 569 .vector movement_old;
 570 .float buttons_old;
 571 .vector v_angle_old;
 572 .string lastclassname;
 573
 574 .float() PlayerPhysplug;
 575
 576 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 577 .float specialcommand_pos;
 578 void SpecialCommand()
 579 {
 580 #ifdef TETRIS
 581         TetrisImpulse();
 582 #else
 583         if(!CheatImpulse(99))
 584                 print("A hollow voice says \"Plugh\".\n");
 585 #endif
 586 }
 587
 588 float speedaward_speed;
 589 string speedaward_holder;
 590 void race_send_speedaward(float msg)
 591 {
 592         // send the best speed of the round
 593         WriteByte(msg, SVC_TEMPENTITY);
 594         WriteByte(msg, TE_CSQC_RACE);
 595         WriteByte(msg, RACE_NET_SPEED_AWARD);
 596         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 597         WriteString(msg, speedaward_holder);
 598 }
 599
 600 float speedaward_alltimebest;
 601 string speedaward_alltimebest_holder;
 602 void race_send_speedaward_alltimebest(float msg)
 603 {
 604         // send the best speed
 605         WriteByte(msg, SVC_TEMPENTITY);
 606         WriteByte(msg, TE_CSQC_RACE);
 607         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 608         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 609         WriteString(msg, speedaward_alltimebest_holder);
 610 }
 611
 612 string GetMapname(void);
 613 float speedaward_lastupdate;
 614 float speedaward_lastsent;
 615 .float jumppadusetime;
 616 var float autocvar_g_movement_highspeed = 1;
 617 void SV_PlayerPhysics()
 618 {
 619         local vector wishvel, wishdir, v;
 620         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 621         string temps;
 622         float buttons_prev;
 623         float not_allowed_to_move;
 624         string c;
 625
 626         // fix physics stats for g_movement_highspeed
 627         self.stat_sv_airaccel_qw = AdjustAirAccelQW(sv_airaccel_qw, autocvar_g_movement_highspeed);
 628         if(sv_airstrafeaccel_qw)
 629                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(sv_airstrafeaccel_qw, autocvar_g_movement_highspeed);
 630         else
 631                 self.stat_sv_airstrafeaccel_qw = 0;
 632
 633     if(self.PlayerPhysplug)
 634         if(self.PlayerPhysplug())
 635             return;
 636
 637         self.race_movetime_frac += frametime;
 638         f = floor(self.race_movetime_frac);
 639         self.race_movetime_frac -= f;
 640         self.race_movetime_count += f;
 641         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 642
 643         anticheat_physics();
 644
 645         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 646
 647         if(!buttons)
 648                 c = "x";
 649         else if(buttons == 1)
 650                 c = "1";
 651         else if(buttons == 2)
 652                 c = " ";
 653         else if(buttons == 128)
 654                 c = "s";
 655         else if(buttons == 256)
 656                 c = "w";
 657         else if(buttons == 512)
 658                 c = "a";
 659         else if(buttons == 1024)
 660                 c = "d";
 661         else
 662                 c = "?";
 663
 664         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 665         {
 666                 self.specialcommand_pos += 1;
 667                 if(self.specialcommand_pos >= strlen(specialcommand))
 668                 {
 669                         self.specialcommand_pos = 0;
 670                         SpecialCommand();
 671                         return;
 672                 }
 673         }
 674         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 675                 self.specialcommand_pos = 0;
 676
 677         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 678         {
 679                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 680                         self.parm_idlesince = time;
 681         }
 682         buttons_prev = self.buttons_old;
 683         self.buttons_old = buttons;
 684         self.movement_old = self.movement;
 685         self.v_angle_old = self.v_angle;
 686
 687         if(time < self.nickspamtime)
 688         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 689         {
 690                 // slight annoyance for nick change scripts
 691                 self.movement = -1 * self.movement;
 692                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 693
 694                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 695                 {
 696                         self.angles_x = random() * 360;
 697                         self.angles_y = random() * 360;
 698                         // at least I'm not forcing retardedview by also assigning to angles_z
 699                         self.fixangle = 1;
 700                 }
 701         }
 702
 703         if (self.punchangle != '0 0 0')
 704         {
 705                 f = vlen(self.punchangle) - 10 * frametime;
 706                 if (f > 0)
 707                         self.punchangle = normalize(self.punchangle) * f;
 708                 else
 709                         self.punchangle = '0 0 0';
 710         }
 711
 712         if (self.punchvector != '0 0 0')
 713         {
 714                 f = vlen(self.punchvector) - 30 * frametime;
 715                 if (f > 0)
 716                         self.punchvector = normalize(self.punchvector) * f;
 717                 else
 718                         self.punchvector = '0 0 0';
 719         }
 720
 721         if (clienttype(self) == CLIENTTYPE_BOT)
 722         {
 723                 if(playerdemo_read())
 724                         return;
 725                 bot_think();
 726         }
 727
 728         MUTATOR_CALLHOOK(PlayerPhysics);
 729
 730         self.items &~= IT_USING_JETPACK;
 731
 732         if(self.classname == "player")
 733         {
 734                 if(self.race_penalty)
 735                         if(time > self.race_penalty)
 736                                 self.race_penalty = 0;
 737
 738                 not_allowed_to_move = 0;
 739                 if(self.race_penalty)
 740                         not_allowed_to_move = 1;
 741                 if(!cvar("sv_ready_restart_after_countdown"))
 742                 if(time < game_starttime)
 743                         not_allowed_to_move = 1;
 744
 745                 if(not_allowed_to_move)
 746                 {
 747                         self.velocity = '0 0 0';
 748                         self.movetype = MOVETYPE_NONE;
 749                         self.disableclientprediction = 2;
 750                 }
 751                 else if(self.disableclientprediction == 2)
 752                 {
 753                         if(self.movetype == MOVETYPE_NONE)
 754                                 self.movetype = MOVETYPE_WALK;
 755                         self.disableclientprediction = 0;
 756                 }
 757         }
 758
 759         if (self.movetype == MOVETYPE_NONE)
 760                 return;
 761
 762         maxspd_mod = 1;
 763
 764         if(g_runematch)
 765         {
 766                 if(self.runes & RUNE_SPEED)
 767                 {
 768                         if(self.runes & CURSE_SLOW)
 769                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 770                         else
 771                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 772                 }
 773                 else if(self.runes & CURSE_SLOW)
 774                 {
 775                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 776                 }
 777         }
 778
 779         if(g_minstagib && (self.items & IT_INVINCIBLE))
 780         {
 781                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 782         }
 783
 784         if(g_nexball && self.ballcarried)
 785         {
 786                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 787         }
 788
 789         swampspd_mod = 1;
 790         if(self.in_swamp) {
 791                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 792         }
 793
 794         if(self.classname != "player")
 795         {
 796                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 797                 if(!self.spectatorspeed)
 798                         self.spectatorspeed = maxspd_mod;
 799                 if(self.impulse && self.impulse <= 19)
 800                 {
 801                         if(self.lastclassname != "player")
 802                         {
 803                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 804                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 805                                 else if(self.impulse == 11)
 806                                         self.spectatorspeed = maxspd_mod;
 807                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 808                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 809                                 else if(self.impulse >= 1 && self.impulse <= 9)
 810                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 811                         } // otherwise just clear
 812                         self.impulse = 0;
 813                 }
 814                 maxspd_mod = self.spectatorspeed;
 815         }
 816
 817         spd = max(sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 818         if(self.speed != spd)
 819         {
 820                 self.speed = spd;
 821                 temps = ftos(spd);
 822                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 823                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 824                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 825                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 826         }
 827
 828         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 829         swampspd_mod = 1;
 830
 831         // if dead, behave differently
 832         if (self.deadflag)
 833                 goto end;
 834
 835         if (!self.fixangle && !g_bugrigs)
 836         {
 837                 self.angles_x = 0;
 838                 self.angles_y = self.v_angle_y;
 839                 self.angles_z = 0;
 840         }
 841
 842         if(self.flags & FL_ONGROUND)
 843         if(self.wasFlying)
 844         {
 845                 self.wasFlying = 0;
 846
 847                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 848                 if(time >= self.ladder_time)
 849                 if not(self.hook)
 850                 {
 851                         self.nextstep = time + 0.3 + random() * 0.1;
 852                         trace_dphitq3surfaceflags = 0;
 853                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 854                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 855                         {
 856                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 857                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 858                                 else
 859                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 860                         }
 861                 }
 862         }
 863
 864         if(IsFlying(self))
 865                 self.wasFlying = 1;
 866
 867         if(self.classname == "player")
 868         {
 869                 if(sv_doublejump && time - self.jumppadusetime > 2 * sys_frametime)
 870                 {
 871                         tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 872                         self.flags &~= FL_ONGROUND;
 873                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 874                                 self.flags |= FL_ONGROUND;
 875                 }
 876
 877                 if (self.BUTTON_JUMP)
 878                         PlayerJump ();
 879                 else
 880                         self.flags |= FL_JUMPRELEASED;
 881
 882                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 883                         CheckWaterJump ();
 884         }
 885
 886         if (self.flags & FL_WATERJUMP )
 887         {
 888                 self.velocity_x = self.movedir_x;
 889                 self.velocity_y = self.movedir_y;
 890                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 891                 {
 892                         self.flags &~= FL_WATERJUMP;
 893                         self.teleport_time = 0;
 894                 }
 895         }
 896         else if (g_bugrigs && self.classname == "player")
 897         {
 898                 RaceCarPhysics();
 899         }
 900         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 901         {
 902                 // noclipping or flying
 903                 self.flags &~= FL_ONGROUND;
 904
 905                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 906                 makevectors(self.v_angle);
 907                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 908                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 909                 // acceleration
 910                 wishdir = normalize(wishvel);
 911                 wishspeed = vlen(wishvel);
 912                 if (wishspeed > sv_maxspeed*maxspd_mod)
 913                         wishspeed = sv_maxspeed*maxspd_mod;
 914                 if (time >= self.teleport_time)
 915                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 916         }
 917         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 918         {
 919                 // swimming
 920                 self.flags &~= FL_ONGROUND;
 921
 922                 makevectors(self.v_angle);
 923                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 924                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 925                 if (wishvel == '0 0 0')
 926                         wishvel = '0 0 -60'; // drift towards bottom
 927
 928                 wishdir = normalize(wishvel);
 929                 wishspeed = vlen(wishvel);
 930                 if (wishspeed > sv_maxspeed*maxspd_mod)
 931                         wishspeed = sv_maxspeed*maxspd_mod;
 932                 wishspeed = wishspeed * 0.7;
 933
 934                 // water friction
 935                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 936
 937                 // water acceleration
 938                 PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 939         }
 940         else if (time < self.ladder_time)
 941         {
 942                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 943                 self.flags &~= FL_ONGROUND;
 944
 945                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 946                 makevectors(self.v_angle);
 947                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 948                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 949                 if (self.gravity)
 950                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 951                 else
 952                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 953                 if (self.ladder_entity.classname == "func_water")
 954                 {
 955                         f = vlen(wishvel);
 956                         if (f > self.ladder_entity.speed)
 957                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 958
 959                         self.watertype = self.ladder_entity.skin;
 960                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 961                         if ((self.origin_z + self.view_ofs_z) < f)
 962                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 963                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 964                                 self.waterlevel = WATERLEVEL_SWIMMING;
 965                         else if ((self.origin_z + self.mins_z + 1) < f)
 966                                 self.waterlevel = WATERLEVEL_WETFEET;
 967                         else
 968                         {
 969                                 self.waterlevel = WATERLEVEL_NONE;
 970                                 self.watertype = CONTENT_EMPTY;
 971                         }
 972                 }
 973                 // acceleration
 974                 wishdir = normalize(wishvel);
 975                 wishspeed = vlen(wishvel);
 976                 if (wishspeed > sv_maxspeed*maxspd_mod)
 977                         wishspeed = sv_maxspeed*maxspd_mod;
 978                 if (time >= self.teleport_time)
 979                 {
 980                         // water acceleration
 981                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 982                 }
 983         }
 984         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 985         {
 986                 //makevectors(self.v_angle_y * '0 1 0');
 987                 makevectors(self.v_angle);
 988                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 989                 // add remaining speed as Z component
 990                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 991                 // fix speedhacks :P
 992                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 993                 // add the unused velocity as up component
 994                 wishvel_z = 0;
 995
 996                 // if(self.BUTTON_JUMP)
 997                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 998
 999                 // it is now normalized, so...
1000                 float a_side, a_up, a_add, a_diff;
1001                 a_side = cvar("g_jetpack_acceleration_side");
1002                 a_up = cvar("g_jetpack_acceleration_up");
1003                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
1004
1005                 wishvel_x *= a_side;
1006                 wishvel_y *= a_side;
1007                 wishvel_z *= a_up;
1008                 wishvel_z += a_add;
1009
1010                 float best;
1011                 best = 0;
1012                 //////////////////////////////////////////////////////////////////////////////////////
1013                 // finding the maximum over all vectors of above form
1014                 // with wishvel having an absolute value of 1
1015                 //////////////////////////////////////////////////////////////////////////////////////
1016                 // we're finding the maximum over
1017                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1018                 // for z in the range from -1 to 1
1019                 //////////////////////////////////////////////////////////////////////////////////////
1020                 // maximum is EITHER attained at the single extreme point:
1021                 a_diff = a_side * a_side - a_up * a_up;
1022                 if(a_diff != 0)
1023                 {
1024                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1025                         if(f > -1 && f < 1) // can it be attained?
1026                         {
1027                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1028                                 //print("middle\n");
1029                         }
1030                 }
1031                 // OR attained at z = 1:
1032                 f = (a_up + a_add) * (a_up + a_add);
1033                 if(f > best)
1034                 {
1035                         best = f;
1036                         //print("top\n");
1037                 }
1038                 // OR attained at z = -1:
1039                 f = (a_up - a_add) * (a_up - a_add);
1040                 if(f > best)
1041                 {
1042                         best = f;
1043                         //print("bottom\n");
1044                 }
1045                 best = sqrt(best);
1046                 //////////////////////////////////////////////////////////////////////////////////////
1047
1048                 //print("best possible acceleration: ", ftos(best), "\n");
1049
1050                 float fxy, fz;
1051                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
1052                 if(wishvel_z - sv_gravity > 0)
1053                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
1054                 else
1055                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
1056
1057                 float fvel;
1058                 fvel = vlen(wishvel);
1059                 wishvel_x *= fxy;
1060                 wishvel_y *= fxy;
1061                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
1062
1063                 fvel = min(1, vlen(wishvel) / best);
1064                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1065                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
1066                 else
1067                         f = 1;
1068
1069                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1070
1071                 if (f > 0 && wishvel != '0 0 0')
1072                 {
1073                         self.velocity = self.velocity + wishvel * f * frametime;
1074                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1075                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
1076                         self.flags &~= FL_ONGROUND;
1077                         self.items |= IT_USING_JETPACK;
1078
1079                         // jetpack also inhibits health regeneration, but only for 1 second
1080                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1081                 }
1082         }
1083         else if (self.flags & FL_ONGROUND)
1084         {
1085                 // we get here if we ran out of ammo
1086                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1087                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1088
1089                 // walking
1090                 makevectors(self.v_angle_y * '0 1 0');
1091                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1092
1093                 if(!(self.lastflags & FL_ONGROUND))
1094                 {
1095                         if(cvar("speedmeter"))
1096                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1097                         if(self.lastground < time - 0.3)
1098                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1099                         if(self.jumppadcount > 1)
1100                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1101                         self.jumppadcount = 0;
1102                 }
1103
1104 #ifdef LETS_TEST_FTEQCC
1105                 if(self.velocity_x || self.velocity_y)
1106                 {
1107                         // good
1108                 }
1109                 else
1110                 {
1111                         if(self.velocity_x)
1112                                 checkclient();
1113                         if(self.velocity_y)
1114                                 checkclient();
1115                 }
1116 #endif
1117
1118                 v = self.velocity;
1119                 v_z = 0;
1120                 f = vlen(v);
1121                 if(f > 0)
1122                 {
1123                         if (f < sv_stopspeed)
1124                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1125                         else
1126                                 f = 1 - frametime * sv_friction;
1127                         if (f > 0)
1128                                 self.velocity = self.velocity * f;
1129                         else
1130                                 self.velocity = '0 0 0';
1131                 }
1132
1133                 // acceleration
1134                 wishdir = normalize(wishvel);
1135                 wishspeed = vlen(wishvel);
1136                 if (wishspeed > sv_maxspeed*maxspd_mod)
1137                         wishspeed = sv_maxspeed*maxspd_mod;
1138                 if (self.crouch)
1139                         wishspeed = wishspeed * 0.5;
1140                 if (time >= self.teleport_time)
1141                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
1142         }
1143         else
1144         {
1145                 float wishspeed0;
1146                 // we get here if we ran out of ammo
1147                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1148                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1149
1150                 if(maxspd_mod < 1)
1151                 {
1152                         maxairspd = sv_maxairspeed*maxspd_mod;
1153                         airaccel = sv_airaccelerate*maxspd_mod;
1154                 }
1155                 else
1156                 {
1157                         maxairspd = sv_maxairspeed;
1158                         airaccel = sv_airaccelerate;
1159                 }
1160                 // airborn
1161                 makevectors(self.v_angle_y * '0 1 0');
1162                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1163                 // acceleration
1164                 wishdir = normalize(wishvel);
1165                 wishspeed = wishspeed0 = vlen(wishvel);
1166                 if (wishspeed0 > sv_maxspeed*maxspd_mod)
1167                         wishspeed0 = sv_maxspeed*maxspd_mod;
1168                 if (wishspeed > maxairspd)
1169                         wishspeed = maxairspd;
1170                 if (self.crouch)
1171                         wishspeed = wishspeed * 0.5;
1172                 if (time >= self.teleport_time)
1173                 {
1174                         float accelerating;
1175                         float wishspeed2;
1176                         float airaccelqw;
1177                         float strafity;
1178
1179                         airaccelqw = self.stat_sv_airaccel_qw;
1180                         accelerating = (self.velocity * wishdir > 0);
1181                         wishspeed2 = wishspeed;
1182
1183                         // CPM
1184                         if(sv_airstopaccelerate)
1185                                 if(self.velocity * wishdir < 0)
1186                                         airaccel = sv_airstopaccelerate*maxspd_mod;
1187                         // note that for straight forward jumping:
1188                         // step = accel * frametime * wishspeed0;
1189                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1190                         // -->
1191                         // dv/dt = accel * maxspeed (when slow)
1192                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1193                         // log dv/dt = logaccel + logmaxspeed (when slow)
1194                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1195                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1196                         if(sv_maxairstrafespeed)
1197                                 wishspeed = min(wishspeed, GeomLerp(sv_maxairspeed*maxspd_mod, strafity, sv_maxairstrafespeed*maxspd_mod));
1198                         if(sv_airstrafeaccelerate)
1199                                 airaccel = GeomLerp(airaccel, strafity, sv_airstrafeaccelerate*maxspd_mod);
1200                         if(self.stat_sv_airstrafeaccel_qw)
1201                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1202                         // !CPM
1203
1204                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1205                                 PM_AirAccelerate(wishdir, wishspeed);
1206                         else
1207                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd);
1208
1209                         if(sv_aircontrol)
1210                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1211                 }
1212         }
1213
1214         if((g_cts || g_race) && self.classname != "observer") {
1215                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1216                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1217                         speedaward_holder = self.netname;
1218                         speedaward_lastupdate = time;
1219                 }
1220                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1221                         string rr;
1222                         if(g_cts)
1223                                 rr = CTS_RECORD;
1224                         else
1225                                 rr = RACE_RECORD;
1226                         race_send_speedaward(MSG_ALL);
1227                         speedaward_lastsent = speedaward_speed;
1228                         if (speedaward_speed > speedaward_alltimebest) {
1229                                 speedaward_alltimebest = speedaward_speed;
1230                                 speedaward_alltimebest_holder = speedaward_holder;
1231                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1232                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"), speedaward_alltimebest_holder);
1233                                 race_send_speedaward_alltimebest(MSG_ALL);
1234                         }
1235                 }
1236         }
1237 :end
1238         if(self.flags & FL_ONGROUND)
1239                 self.lastground = time;
1240
1241         self.lastflags = self.flags;
1242         self.lastclassname = self.classname;
1243 };