qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 float sv_accelerate;
   5 float sv_friction;
   6 float sv_maxspeed;
   7 float sv_airaccelerate;
   8 float sv_maxairspeed;
   9 float sv_stopspeed;
  10 float sv_gravity;
  11 float sv_airaccel_sideways_friction;
  12 float sv_airaccel_qw;
  13 float sv_airstopaccelerate;
  14 float sv_airstrafeaccelerate;
  15 float sv_maxairstrafespeed;
  16 float sv_airstrafeaccel_qw;
  17 float sv_aircontrol;
  18 float sv_aircontrol_power;
  19 float sv_aircontrol_penalty;
  20 float sv_warsowbunny_airforwardaccel;
  21 float sv_warsowbunny_accel;
  22 float sv_warsowbunny_topspeed;
  23 float sv_warsowbunny_turnaccel;
  24 float sv_warsowbunny_backtosideratio;
  25 float sv_airspeedlimit_nonqw;
  26
  27 .float ladder_time;
  28 .entity ladder_entity;
  29 .float gravity;
  30 .float swamp_slowdown;
  31 .float lastflags;
  32 .float lastground;
  33 .float wasFlying;
  34 .float spectatorspeed;
  35
  36 .float multijump_count;
  37 .float multijump_ready;
  38 .float prevjumpbutton;
  39
  40 /*
  41 =============
  42 PlayerJump
  43
  44 When you press the jump key
  45 =============
  46 */
  47 void PlayerJump (void)
  48 {
  49         if(g_freezetag && self.freezetag_frozen)
  50                 return; // no jumping in freezetag when frozen
  51
  52         float mjumpheight;
  53         float doublejump;
  54
  55         doublejump = FALSE;
  56         if (sv_doublejump)
  57         {
  58                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
  59                 if (trace_fraction < 1 && trace_plane_normal_z > 0.7)
  60                         doublejump = TRUE;
  61         }
  62
  63         mjumpheight = cvar("sv_jumpvelocity");
  64         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  65         {
  66                 if (self.watertype == CONTENT_WATER)
  67                         self.velocity_z = 200;
  68                 else if (self.watertype == CONTENT_SLIME)
  69                         self.velocity_z = 80;
  70                 else
  71                         self.velocity_z = 50;
  72
  73                 return;
  74         }
  75
  76         if (cvar("g_multijump"))
  77         {
  78                 if (self.prevjumpbutton == FALSE && !(self.flags & FL_ONGROUND)) // jump button pressed this frame and we are in midair
  79                         self.multijump_ready = TRUE;  // this is necessary to check that we released the jump button and pressed it again
  80                 else
  81                         self.multijump_ready = FALSE;
  82         }
  83
  84         if(!doublejump && self.multijump_ready && self.multijump_count < cvar("g_multijump") && self.velocity_z > cvar("g_multijump_speed"))
  85         {
  86                 // doublejump = FALSE; // checked above in the if
  87                 if (cvar("g_multijump") > 0)
  88                 {
  89                         if (cvar("g_multijump_add") == 0) // in this case we make the z velocity == jumpvelocity
  90                         {
  91                                 if (self.velocity_z < mjumpheight)
  92                                 {
  93                                         doublejump = TRUE;
  94                                         self.velocity_z = 0;
  95                                 }
  96                         }
  97                         else
  98                                 doublejump = TRUE;
  99
 100                         if(doublejump)
 101                         {
 102                                 if(self.movement_x != 0 || self.movement_y != 0) // don't remove all speed if player isnt pressing any movement keys
 103                                 {
 104                                         float curspeed;
 105                                         vector wishvel, wishdir;
 106
 107                                         curspeed = max(
 108                                                 vlen(vec2(self.velocity)), // current xy speed
 109                                                 vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
 110                                         );
 111                                         makevectors(self.v_angle_y * '0 1 0');
 112                                         wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 113                                         wishdir = normalize(wishvel);
 114
 115                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
 116                                         self.velocity_y = wishdir_y * curspeed;
 117                                         // keep velocity_z unchanged!
 118                                 }
 119                                 self.multijump_count += 1;
 120                         }
 121                 }
 122                 self.multijump_ready = FALSE; // require releasing and pressing the jump button again for the next jump
 123         }
 124
 125         if (!doublejump)
 126                 if (!(self.flags & FL_ONGROUND))
 127                         return;
 128
 129         if(!sv_pogostick)
 130                 if (!(self.flags & FL_JUMPRELEASED))
 131                         return;
 132
 133         if(self.health <= g_bloodloss)
 134                 return;
 135
 136         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 137         // velocity bounds.  Final velocity is bound between (jumpheight *
 138         // min + jumpheight) and (jumpheight * max + jumpheight);
 139
 140         if(cvar_string("sv_jumpspeedcap_min") != "")
 141         {
 142                 float minjumpspeed;
 143
 144                 minjumpspeed = mjumpheight * cvar("sv_jumpspeedcap_min");
 145
 146                 if (self.velocity_z < minjumpspeed)
 147                         mjumpheight += minjumpspeed - self.velocity_z;
 148         }
 149
 150         if(cvar_string("sv_jumpspeedcap_max") != "")
 151         {
 152                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 153                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 154
 155                 if(!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && cvar("sv_jumpspeedcap_max_disable_on_ramps")))
 156                 {
 157                         float maxjumpspeed;
 158
 159                         maxjumpspeed = mjumpheight * cvar("sv_jumpspeedcap_max");
 160
 161                         if (self.velocity_z > maxjumpspeed)
 162                                 mjumpheight -= self.velocity_z - maxjumpspeed;
 163                 }
 164         }
 165
 166         if(!(self.lastflags & FL_ONGROUND))
 167         {
 168                 if(cvar("speedmeter"))
 169                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 170                 if(self.lastground < time - 0.3)
 171                 {
 172                         self.velocity_x *= (1 - cvar("sv_friction_on_land"));
 173                         self.velocity_y *= (1 - cvar("sv_friction_on_land"));
 174                 }
 175                 if(self.jumppadcount > 1)
 176                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 177                 self.jumppadcount = 0;
 178         }
 179
 180         self.velocity_z = self.velocity_z + mjumpheight;
 181         self.oldvelocity_z = self.velocity_z;
 182
 183         self.flags &~= FL_ONGROUND;
 184         self.flags &~= FL_JUMPRELEASED;
 185
 186         if (self.crouch)
 187                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 188         else
 189                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 190
 191         if(g_jump_grunt)
 192                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 193
 194         self.restart_jump = -1; // restart jump anim next time
 195         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 196 }
 197
 198 void CheckWaterJump()
 199 {
 200         local vector start, end;
 201
 202 // check for a jump-out-of-water
 203         makevectors (self.angles);
 204         start = self.origin;
 205         start_z = start_z + 8;
 206         v_forward_z = 0;
 207         normalize(v_forward);
 208         end = start + v_forward*24;
 209         traceline (start, end, TRUE, self);
 210         if (trace_fraction < 1)
 211         {       // solid at waist
 212                 start_z = start_z + self.maxs_z - 8;
 213                 end = start + v_forward*24;
 214                 self.movedir = trace_plane_normal * -50;
 215                 traceline (start, end, TRUE, self);
 216                 if (trace_fraction == 1)
 217                 {       // open at eye level
 218                         self.flags |= FL_WATERJUMP;
 219                         self.velocity_z = 225;
 220                         self.flags &~= FL_JUMPRELEASED;
 221                         self.teleport_time = time + 2;  // safety net
 222                         return;
 223                 }
 224         }
 225 };
 226
 227 float racecar_angle(float forward, float down)
 228 {
 229         float ret, angle_mult;
 230
 231         if(forward < 0)
 232         {
 233                 forward = -forward;
 234                 down = -down;
 235         }
 236
 237         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 238
 239         angle_mult = forward / (800 + forward);
 240
 241         if(ret > 180)
 242                 return ret * angle_mult + 360 * (1 - angle_mult);
 243         else
 244                 return ret * angle_mult;
 245 }
 246
 247 void RaceCarPhysics()
 248 {
 249         // using this move type for "big rigs"
 250         // the engine does not push the entity!
 251
 252         float accel, steer, f, myspeed, steerfactor;
 253         vector angles_save, rigvel;
 254
 255         angles_save = self.angles;
 256         accel = bound(-1, self.movement_x / self.stat_sv_maxspeed, 1);
 257         steer = bound(-1, self.movement_y / self.stat_sv_maxspeed, 1);
 258
 259         if(g_bugrigs_reverse_speeding)
 260         {
 261                 if(accel < 0)
 262                 {
 263                         // back accel is DIGITAL
 264                         // to prevent speedhack
 265                         if(accel < -0.5)
 266                                 accel = -1;
 267                         else
 268                                 accel = 0;
 269                 }
 270         }
 271
 272         self.angles_x = 0;
 273         self.angles_z = 0;
 274         makevectors(self.angles); // new forward direction!
 275
 276         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 277         {
 278                 float upspeed, accelfactor;
 279
 280                 myspeed = self.velocity * v_forward;
 281                 upspeed = self.velocity * v_up;
 282
 283                 // responsiveness factor for steering and acceleration
 284                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 285                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 286
 287                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 288                         steerfactor = -myspeed * g_bugrigs_steer;
 289                 else
 290                         steerfactor = -myspeed * f * g_bugrigs_steer;
 291
 292                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 293                         accelfactor = g_bugrigs_accel;
 294                 else
 295                         accelfactor = f * g_bugrigs_accel;
 296                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 297
 298                 if(accel < 0)
 299                 {
 300                         if(myspeed > 0)
 301                         {
 302                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 303                         }
 304                         else
 305                         {
 306                                 if(!g_bugrigs_reverse_speeding)
 307                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 308                         }
 309                 }
 310                 else
 311                 {
 312                         if(myspeed >= 0)
 313                         {
 314                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 315                         }
 316                         else
 317                         {
 318                                 if(g_bugrigs_reverse_stopping)
 319                                         myspeed = 0;
 320                                 else
 321                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 322                         }
 323                 }
 324                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 325                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 326
 327                 self.angles_y += steer * frametime * steerfactor; // apply steering
 328                 makevectors(self.angles); // new forward direction!
 329
 330                 myspeed += accel * accelfactor * frametime;
 331
 332                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 333         }
 334         else
 335         {
 336                 myspeed = vlen(self.velocity);
 337
 338                 // responsiveness factor for steering and acceleration
 339                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 340                 steerfactor = -myspeed * f;
 341                 self.angles_y += steer * frametime * steerfactor; // apply steering
 342
 343                 rigvel = self.velocity;
 344                 makevectors(self.angles); // new forward direction!
 345         }
 346
 347         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 348         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 349         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 350         //MAXIMA: solve(total_acceleration(v) = 0, v);
 351
 352         if(g_bugrigs_planar_movement)
 353         {
 354                 vector rigvel_xy, neworigin, up;
 355                 float mt;
 356
 357                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 358                 rigvel_xy = vec2(rigvel);
 359
 360                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 361                         mt = MOVE_NORMAL;
 362                 else
 363                         mt = MOVE_NOMONSTERS;
 364
 365                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 366                 up = trace_endpos - self.origin;
 367
 368                 // BUG RIGS: align the move to the surface instead of doing collision testing
 369                 // can we move?
 370                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 371
 372                 // align to surface
 373                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 374
 375                 if(trace_fraction < 0.5)
 376                 {
 377                         trace_fraction = 1;
 378                         neworigin = self.origin;
 379                 }
 380                 else
 381                         neworigin = trace_endpos;
 382
 383                 if(trace_fraction < 1)
 384                 {
 385                         // now set angles_x so that the car points parallel to the surface
 386                         self.angles = vectoangles(
 387                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 388                                         +
 389                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 390                                         +
 391                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 392                                         );
 393                         self.flags |= FL_ONGROUND;
 394                 }
 395                 else
 396                 {
 397                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 398                         self.flags &~= FL_ONGROUND;
 399                 }
 400
 401                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 402                 self.movetype = MOVETYPE_NOCLIP;
 403         }
 404         else
 405         {
 406                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 407                 self.velocity = rigvel;
 408                 self.movetype = MOVETYPE_FLY;
 409         }
 410
 411         trace_fraction = 1;
 412         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 413         if(trace_fraction != 1)
 414         {
 415                 self.angles = vectoangles2(
 416                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 417                                 +
 418                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 419                                 +
 420                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 421                                 trace_plane_normal
 422                                 );
 423         }
 424         else
 425         {
 426                 vector vel_local;
 427
 428                 vel_local_x = v_forward * self.velocity;
 429                 vel_local_y = v_right * self.velocity;
 430                 vel_local_z = v_up * self.velocity;
 431
 432                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 433                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 434         }
 435
 436         // smooth the angles
 437         vector vf1, vu1, smoothangles;
 438         makevectors(self.angles);
 439         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 440         if(f == 0)
 441                 f = 1;
 442         vf1 = v_forward * f;
 443         vu1 = v_up * f;
 444         makevectors(angles_save);
 445         vf1 = vf1 + v_forward * (1 - f);
 446         vu1 = vu1 + v_up * (1 - f);
 447         smoothangles = vectoangles2(vf1, vu1);
 448         self.angles_x = -smoothangles_x;
 449         self.angles_z =  smoothangles_z;
 450 }
 451
 452 float IsMoveInDirection(vector mv, float angle) // key mix factor
 453 {
 454         if(mv_x == 0 && mv_y == 0)
 455                 return 0; // avoid division by zero
 456         angle -= RAD2DEG * atan2(mv_y, mv_x);
 457         angle = remainder(angle, 360) / 45;
 458         if(angle >  1)
 459                 return 0;
 460         if(angle < -1)
 461                 return 0;
 462         return 1 - fabs(angle);
 463 }
 464
 465 float GeomLerp(float a, float lerp, float b)
 466 {
 467         if(a == 0)
 468         {
 469                 if(lerp < 1)
 470                         return 0;
 471                 else
 472                         return b;
 473         }
 474         if(b == 0)
 475         {
 476                 if(lerp > 0)
 477                         return 0;
 478                 else
 479                         return a;
 480         }
 481         return a * pow(fabs(b / a), lerp);
 482 }
 483
 484 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 485 {
 486         float zspeed, xyspeed, dot, k;
 487
 488 #if 0
 489         // this doesn't play well with analog input
 490         if(self.movement_x == 0 || self.movement_y != 0)
 491                 return; // can't control movement if not moving forward or backward
 492         k = 32;
 493 #else
 494         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 495         if(k <= 0)
 496                 return;
 497 #endif
 498
 499         k *= bound(0, wishspeed / sv_maxairspeed, 1);
 500
 501         zspeed = self.velocity_z;
 502         self.velocity_z = 0;
 503         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 504
 505         dot = self.velocity * wishdir;
 506
 507         if(dot > 0) // we can't change direction while slowing down
 508         {
 509                 k *= pow(dot, sv_aircontrol_power)*frametime;
 510                 xyspeed = max(0, xyspeed - sv_aircontrol_penalty * sqrt(max(0, 1 - dot*dot)) * k/32);
 511                 k *= sv_aircontrol;
 512                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 513         }
 514
 515         self.velocity = self.velocity * xyspeed;
 516         self.velocity_z = zspeed;
 517 }
 518
 519 float AdjustAirAccelQW(float accelqw, float factor)
 520 {
 521         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 522 }
 523
 524 // example config for alternate speed clamping:
 525 //   sv_airaccel_qw 0.8
 526 //   sv_airaccel_sideways_friction 0
 527 //   prvm_globalset server speedclamp_mode 1
 528 //     (or 2)
 529 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float sidefric, float speedlimit)
 530 {
 531         float vel_straight;
 532         float vel_z;
 533         vector vel_perpend;
 534         float step;
 535
 536         vector vel_xy;
 537         float vel_xy_current;
 538         float vel_xy_backward, vel_xy_forward;
 539         float speedclamp;
 540
 541         speedclamp = (accelqw < 0);
 542         if(speedclamp)
 543                 accelqw = -accelqw;
 544
 545         if(cvar("sv_gameplayfix_q2airaccelerate"))
 546                 wishspeed0 = wishspeed;
 547
 548         vel_straight = self.velocity * wishdir;
 549         vel_z = self.velocity_z;
 550         vel_xy = vec2(self.velocity);
 551         vel_perpend = vel_xy - vel_straight * wishdir;
 552
 553         step = accel * frametime * wishspeed0;
 554
 555         vel_xy_current  = vlen(vel_xy);
 556         if(speedlimit)
 557                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 558         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 559         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 560         if(vel_xy_backward < 0)
 561                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 562
 563         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 564
 565         if(sidefric < 0 && (vel_perpend*vel_perpend))
 566                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 567         {
 568                 float f, fminimum;
 569                 f = max(0, 1 + frametime * wishspeed * sidefric);
 570                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 571                 // this cannot be > 1
 572                 if(fminimum <= 0)
 573                         vel_perpend = vel_perpend * max(0, f);
 574                 else
 575                 {
 576                         fminimum = sqrt(fminimum);
 577                         vel_perpend = vel_perpend * max(fminimum, f);
 578                 }
 579         }
 580         else
 581                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
 582
 583         vel_xy = vel_straight * wishdir + vel_perpend;
 584
 585         if(speedclamp)
 586         {
 587                 // ensure we don't get too fast or decelerate faster than we should
 588                 vel_xy_current = min(vlen(vel_xy), vel_xy_forward);
 589                 if(vel_xy_current > 0) // prevent division by zero
 590                         vel_xy = normalize(vel_xy) * vel_xy_current;
 591         }
 592
 593         self.velocity = vel_xy + vel_z * '0 0 1';
 594 }
 595
 596 void PM_AirAccelerate(vector wishdir, float wishspeed)
 597 {
 598         vector curvel, wishvel, acceldir, curdir;
 599         float addspeed, accelspeed, curspeed, f;
 600         float dot;
 601
 602         if(wishspeed == 0)
 603                 return;
 604
 605         curvel = self.velocity;
 606         curvel_z = 0;
 607         curspeed = vlen(curvel);
 608
 609         if(wishspeed > curspeed * 1.01)
 610         {
 611                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * self.stat_sv_maxspeed * frametime);
 612         }
 613         else
 614         {
 615                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - self.stat_sv_maxspeed));
 616                 wishspeed = max(curspeed, self.stat_sv_maxspeed) + sv_warsowbunny_accel * f * self.stat_sv_maxspeed * frametime;
 617         }
 618         wishvel = wishdir * wishspeed;
 619         acceldir = wishvel - curvel;
 620         addspeed = vlen(acceldir);
 621         acceldir = normalize(acceldir);
 622
 623         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * self.stat_sv_maxspeed * frametime);
 624
 625         if(sv_warsowbunny_backtosideratio < 1)
 626         {
 627                 curdir = normalize(curvel);
 628                 dot = acceldir * curdir;
 629                 if(dot < 0)
 630                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 631         }
 632
 633         self.velocity += accelspeed * acceldir;
 634 }
 635
 636 .vector movement_old;
 637 .float buttons_old;
 638 .vector v_angle_old;
 639 .string lastclassname;
 640
 641 .float() PlayerPhysplug;
 642
 643 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 644 .float specialcommand_pos;
 645 void SpecialCommand()
 646 {
 647 #ifdef TETRIS
 648         TetrisImpulse();
 649 #else
 650         if(!CheatImpulse(99))
 651                 print("A hollow voice says \"Plugh\".\n");
 652 #endif
 653 }
 654
 655 float speedaward_speed;
 656 string speedaward_holder;
 657 string speedaward_uid;
 658 void race_send_speedaward(float msg)
 659 {
 660         // send the best speed of the round
 661         WriteByte(msg, SVC_TEMPENTITY);
 662         WriteByte(msg, TE_CSQC_RACE);
 663         WriteByte(msg, RACE_NET_SPEED_AWARD);
 664         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 665         WriteString(msg, speedaward_holder);
 666 }
 667
 668 float speedaward_alltimebest;
 669 string speedaward_alltimebest_holder;
 670 string speedaward_alltimebest_uid;
 671 void race_send_speedaward_alltimebest(float msg)
 672 {
 673         // send the best speed
 674         WriteByte(msg, SVC_TEMPENTITY);
 675         WriteByte(msg, TE_CSQC_RACE);
 676         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 677         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 678         WriteString(msg, speedaward_alltimebest_holder);
 679 }
 680
 681 string GetMapname(void);
 682 float speedaward_lastupdate;
 683 float speedaward_lastsent;
 684 void SV_PlayerPhysics()
 685 {
 686         local vector wishvel, wishdir, v;
 687         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 688         string temps;
 689         float buttons_prev;
 690         float not_allowed_to_move;
 691         string c;
 692
 693         maxspd_mod = 1;
 694         if(g_minstagib && (self.items & IT_INVINCIBLE))
 695                 maxspd_mod *= cvar("g_minstagib_speed_highspeed");
 696         if(g_nexball && self.ballcarried)
 697                 maxspd_mod *= cvar("g_nexball_basketball_carrier_highspeed");
 698         if(g_runematch)
 699         {
 700                 if(self.runes & RUNE_SPEED)
 701                 {
 702                         if(self.runes & CURSE_SLOW)
 703                                 maxspd_mod *= cvar("g_balance_rune_speed_combo_highspeed");
 704                         else
 705                                 maxspd_mod *= cvar("g_balance_rune_speed_highspeed");
 706                 }
 707                 else if(self.runes & CURSE_SLOW)
 708                 {
 709                         maxspd_mod *= cvar("g_balance_curse_slow_highspeed");
 710                 }
 711         }
 712         maxspd_mod *= autocvar_g_movement_highspeed;
 713
 714         // fix physics stats for g_movement_highspeed
 715         self.stat_sv_airaccel_qw = AdjustAirAccelQW(sv_airaccel_qw, maxspd_mod);
 716         if(sv_airstrafeaccel_qw)
 717                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(sv_airstrafeaccel_qw, maxspd_mod);
 718         else
 719                 self.stat_sv_airstrafeaccel_qw = 0;
 720         self.stat_sv_airspeedlimit_nonqw = sv_airspeedlimit_nonqw * maxspd_mod;
 721         self.stat_sv_maxspeed = sv_maxspeed * maxspd_mod; // also slow walking
 722
 723     if(self.PlayerPhysplug)
 724         if(self.PlayerPhysplug())
 725             return;
 726
 727         self.race_movetime_frac += frametime;
 728         f = floor(self.race_movetime_frac);
 729         self.race_movetime_frac -= f;
 730         self.race_movetime_count += f;
 731         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 732
 733         anticheat_physics();
 734
 735         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 736
 737         if(!buttons)
 738                 c = "x";
 739         else if(buttons == 1)
 740                 c = "1";
 741         else if(buttons == 2)
 742                 c = " ";
 743         else if(buttons == 128)
 744                 c = "s";
 745         else if(buttons == 256)
 746                 c = "w";
 747         else if(buttons == 512)
 748                 c = "a";
 749         else if(buttons == 1024)
 750                 c = "d";
 751         else
 752                 c = "?";
 753
 754         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 755         {
 756                 self.specialcommand_pos += 1;
 757                 if(self.specialcommand_pos >= strlen(specialcommand))
 758                 {
 759                         self.specialcommand_pos = 0;
 760                         SpecialCommand();
 761                         return;
 762                 }
 763         }
 764         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 765                 self.specialcommand_pos = 0;
 766
 767         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 768         {
 769                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 770                         self.parm_idlesince = time;
 771         }
 772         buttons_prev = self.buttons_old;
 773         self.buttons_old = buttons;
 774         self.movement_old = self.movement;
 775         self.v_angle_old = self.v_angle;
 776
 777         if(time < self.nickspamtime)
 778         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 779         {
 780                 // slight annoyance for nick change scripts
 781                 self.movement = -1 * self.movement;
 782                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 783
 784                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 785                 {
 786                         self.angles_x = random() * 360;
 787                         self.angles_y = random() * 360;
 788                         // at least I'm not forcing retardedview by also assigning to angles_z
 789                         self.fixangle = 1;
 790                 }
 791         }
 792
 793         if (self.punchangle != '0 0 0')
 794         {
 795                 f = vlen(self.punchangle) - 10 * frametime;
 796                 if (f > 0)
 797                         self.punchangle = normalize(self.punchangle) * f;
 798                 else
 799                         self.punchangle = '0 0 0';
 800         }
 801
 802         if (self.punchvector != '0 0 0')
 803         {
 804                 f = vlen(self.punchvector) - 30 * frametime;
 805                 if (f > 0)
 806                         self.punchvector = normalize(self.punchvector) * f;
 807                 else
 808                         self.punchvector = '0 0 0';
 809         }
 810
 811         if (clienttype(self) == CLIENTTYPE_BOT)
 812         {
 813                 if(playerdemo_read())
 814                         return;
 815                 bot_think();
 816         }
 817
 818         MUTATOR_CALLHOOK(PlayerPhysics);
 819
 820         self.items &~= IT_USING_JETPACK;
 821
 822         if(self.classname == "player")
 823         {
 824                 if(self.race_penalty)
 825                         if(time > self.race_penalty)
 826                                 self.race_penalty = 0;
 827
 828                 not_allowed_to_move = 0;
 829                 if(self.race_penalty)
 830                         not_allowed_to_move = 1;
 831                 if(!cvar("sv_ready_restart_after_countdown"))
 832                 if(time < game_starttime)
 833                         not_allowed_to_move = 1;
 834
 835                 if(not_allowed_to_move)
 836                 {
 837                         self.velocity = '0 0 0';
 838                         self.movetype = MOVETYPE_NONE;
 839                         self.disableclientprediction = 2;
 840                 }
 841                 else if(self.disableclientprediction == 2)
 842                 {
 843                         if(self.movetype == MOVETYPE_NONE)
 844                                 self.movetype = MOVETYPE_WALK;
 845                         self.disableclientprediction = 0;
 846                 }
 847         }
 848
 849         if (self.movetype == MOVETYPE_NONE)
 850                 return;
 851
 852         maxspd_mod = 1;
 853
 854         swampspd_mod = 1;
 855         if(self.in_swamp) {
 856                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 857         }
 858
 859         if(self.classname != "player")
 860         {
 861                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 862                 if(!self.spectatorspeed)
 863                         self.spectatorspeed = maxspd_mod;
 864                 if(self.impulse && self.impulse <= 19)
 865                 {
 866                         if(self.lastclassname != "player")
 867                         {
 868                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 869                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 870                                 else if(self.impulse == 11)
 871                                         self.spectatorspeed = maxspd_mod;
 872                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 873                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 874                                 else if(self.impulse >= 1 && self.impulse <= 9)
 875                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 876                         } // otherwise just clear
 877                         self.impulse = 0;
 878                 }
 879                 maxspd_mod = self.spectatorspeed;
 880         }
 881
 882         spd = max(self.stat_sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 883         if(self.speed != spd)
 884         {
 885                 self.speed = spd;
 886                 temps = ftos(spd);
 887                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 888                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 889                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 890                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 891         }
 892
 893         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 894         swampspd_mod = 1;
 895
 896         // if dead, behave differently
 897         if (self.deadflag)
 898                 goto end;
 899
 900         if (!self.fixangle && !g_bugrigs)
 901         {
 902                 self.angles_x = 0;
 903                 self.angles_y = self.v_angle_y;
 904                 self.angles_z = 0;
 905         }
 906
 907         if(self.flags & FL_ONGROUND)
 908         if(self.wasFlying)
 909         {
 910                 self.wasFlying = 0;
 911
 912                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 913                 if(time >= self.ladder_time)
 914                 if not(self.hook)
 915                 {
 916                         self.nextstep = time + 0.3 + random() * 0.1;
 917                         trace_dphitq3surfaceflags = 0;
 918                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 919                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 920                         {
 921                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 922                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 923                                 else
 924                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 925                         }
 926                 }
 927         }
 928
 929         if(IsFlying(self))
 930                 self.wasFlying = 1;
 931
 932         if(self.classname == "player")
 933         {
 934                 if(self.flags & FL_ONGROUND)
 935                 {
 936                         if (cvar("g_multijump") > 0)
 937                                 self.multijump_count = 0;
 938                         else
 939                                 self.multijump_count = -2; // the cvar value for infinite jumps is -1, so this needs to be smaller
 940                 }
 941
 942                 if (self.BUTTON_JUMP)
 943                         PlayerJump ();
 944                 else
 945                         self.flags |= FL_JUMPRELEASED;
 946
 947                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 948                         CheckWaterJump ();
 949                 self.prevjumpbutton = self.BUTTON_JUMP;
 950         }
 951
 952         if (self.flags & FL_WATERJUMP )
 953         {
 954                 self.velocity_x = self.movedir_x;
 955                 self.velocity_y = self.movedir_y;
 956                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 957                 {
 958                         self.flags &~= FL_WATERJUMP;
 959                         self.teleport_time = 0;
 960                 }
 961         }
 962         else if (g_bugrigs && self.classname == "player")
 963         {
 964                 RaceCarPhysics();
 965         }
 966         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 967         {
 968                 // noclipping or flying
 969                 self.flags &~= FL_ONGROUND;
 970
 971                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 972                 makevectors(self.v_angle);
 973                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 974                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 975                 // acceleration
 976                 wishdir = normalize(wishvel);
 977                 wishspeed = vlen(wishvel);
 978                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 979                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 980                 if (time >= self.teleport_time)
 981                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0, 0);
 982         }
 983         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 984         {
 985                 // swimming
 986                 self.flags &~= FL_ONGROUND;
 987
 988                 makevectors(self.v_angle);
 989                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 990                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 991                 if (wishvel == '0 0 0')
 992                         wishvel = '0 0 -60'; // drift towards bottom
 993
 994                 wishdir = normalize(wishvel);
 995                 wishspeed = vlen(wishvel);
 996                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 997                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 998                 wishspeed = wishspeed * 0.7;
 999
1000                 // water friction
1001                 self.velocity = self.velocity * (1 - frametime * sv_friction);
1002
1003                 // water acceleration
1004                 PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0, 0);
1005         }
1006         else if (time < self.ladder_time)
1007         {
1008                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
1009                 self.flags &~= FL_ONGROUND;
1010
1011                 self.velocity = self.velocity * (1 - frametime * sv_friction);
1012                 makevectors(self.v_angle);
1013                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1014                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
1015                 if (self.gravity)
1016                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
1017                 else
1018                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
1019                 if (self.ladder_entity.classname == "func_water")
1020                 {
1021                         f = vlen(wishvel);
1022                         if (f > self.ladder_entity.speed)
1023                                 wishvel = wishvel * (self.ladder_entity.speed / f);
1024
1025                         self.watertype = self.ladder_entity.skin;
1026                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
1027                         if ((self.origin_z + self.view_ofs_z) < f)
1028                                 self.waterlevel = WATERLEVEL_SUBMERGED;
1029                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
1030                                 self.waterlevel = WATERLEVEL_SWIMMING;
1031                         else if ((self.origin_z + self.mins_z + 1) < f)
1032                                 self.waterlevel = WATERLEVEL_WETFEET;
1033                         else
1034                         {
1035                                 self.waterlevel = WATERLEVEL_NONE;
1036                                 self.watertype = CONTENT_EMPTY;
1037                         }
1038                 }
1039                 // acceleration
1040                 wishdir = normalize(wishvel);
1041                 wishspeed = vlen(wishvel);
1042                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1043                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1044                 if (time >= self.teleport_time)
1045                 {
1046                         // water acceleration
1047                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0, 0);
1048                 }
1049         }
1050         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
1051         {
1052                 //makevectors(self.v_angle_y * '0 1 0');
1053                 makevectors(self.v_angle);
1054                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1055                 // add remaining speed as Z component
1056                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
1057                 // fix speedhacks :P
1058                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
1059                 // add the unused velocity as up component
1060                 wishvel_z = 0;
1061
1062                 // if(self.BUTTON_JUMP)
1063                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1064
1065                 // it is now normalized, so...
1066                 float a_side, a_up, a_add, a_diff;
1067                 a_side = cvar("g_jetpack_acceleration_side");
1068                 a_up = cvar("g_jetpack_acceleration_up");
1069                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
1070
1071                 wishvel_x *= a_side;
1072                 wishvel_y *= a_side;
1073                 wishvel_z *= a_up;
1074                 wishvel_z += a_add;
1075
1076                 float best;
1077                 best = 0;
1078                 //////////////////////////////////////////////////////////////////////////////////////
1079                 // finding the maximum over all vectors of above form
1080                 // with wishvel having an absolute value of 1
1081                 //////////////////////////////////////////////////////////////////////////////////////
1082                 // we're finding the maximum over
1083                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1084                 // for z in the range from -1 to 1
1085                 //////////////////////////////////////////////////////////////////////////////////////
1086                 // maximum is EITHER attained at the single extreme point:
1087                 a_diff = a_side * a_side - a_up * a_up;
1088                 if(a_diff != 0)
1089                 {
1090                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1091                         if(f > -1 && f < 1) // can it be attained?
1092                         {
1093                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1094                                 //print("middle\n");
1095                         }
1096                 }
1097                 // OR attained at z = 1:
1098                 f = (a_up + a_add) * (a_up + a_add);
1099                 if(f > best)
1100                 {
1101                         best = f;
1102                         //print("top\n");
1103                 }
1104                 // OR attained at z = -1:
1105                 f = (a_up - a_add) * (a_up - a_add);
1106                 if(f > best)
1107                 {
1108                         best = f;
1109                         //print("bottom\n");
1110                 }
1111                 best = sqrt(best);
1112                 //////////////////////////////////////////////////////////////////////////////////////
1113
1114                 //print("best possible acceleration: ", ftos(best), "\n");
1115
1116                 float fxy, fz;
1117                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
1118                 if(wishvel_z - sv_gravity > 0)
1119                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
1120                 else
1121                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
1122
1123                 float fvel;
1124                 fvel = vlen(wishvel);
1125                 wishvel_x *= fxy;
1126                 wishvel_y *= fxy;
1127                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
1128
1129                 fvel = min(1, vlen(wishvel) / best);
1130                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1131                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
1132                 else
1133                         f = 1;
1134
1135                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1136
1137                 if (f > 0 && wishvel != '0 0 0')
1138                 {
1139                         self.velocity = self.velocity + wishvel * f * frametime;
1140                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1141                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
1142                         self.flags &~= FL_ONGROUND;
1143                         self.items |= IT_USING_JETPACK;
1144
1145                         // jetpack also inhibits health regeneration, but only for 1 second
1146                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1147                 }
1148         }
1149         else if (self.flags & FL_ONGROUND)
1150         {
1151                 // we get here if we ran out of ammo
1152                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1153                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1154
1155                 // walking
1156                 makevectors(self.v_angle_y * '0 1 0');
1157                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1158
1159                 if(!(self.lastflags & FL_ONGROUND))
1160                 {
1161                         if(cvar("speedmeter"))
1162                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1163                         if(self.lastground < time - 0.3)
1164                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1165                         if(self.jumppadcount > 1)
1166                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1167                         self.jumppadcount = 0;
1168                 }
1169
1170 #ifdef LETS_TEST_FTEQCC
1171                 if(self.velocity_x || self.velocity_y)
1172                 {
1173                         // good
1174                 }
1175                 else
1176                 {
1177                         if(self.velocity_x)
1178                                 checkclient();
1179                         if(self.velocity_y)
1180                                 checkclient();
1181                 }
1182 #endif
1183
1184                 v = self.velocity;
1185                 v_z = 0;
1186                 f = vlen(v);
1187                 if(f > 0)
1188                 {
1189                         if (f < sv_stopspeed)
1190                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1191                         else
1192                                 f = 1 - frametime * sv_friction;
1193                         if (f > 0)
1194                                 self.velocity = self.velocity * f;
1195                         else
1196                                 self.velocity = '0 0 0';
1197                 }
1198
1199                 // acceleration
1200                 wishdir = normalize(wishvel);
1201                 wishspeed = vlen(wishvel);
1202                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1203                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1204                 if (self.crouch)
1205                         wishspeed = wishspeed * 0.5;
1206                 if (time >= self.teleport_time)
1207                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0, 0);
1208         }
1209         else
1210         {
1211                 float wishspeed0;
1212                 // we get here if we ran out of ammo
1213                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1214                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1215
1216                 if(maxspd_mod < 1)
1217                 {
1218                         maxairspd = sv_maxairspeed*maxspd_mod;
1219                         airaccel = sv_airaccelerate*maxspd_mod;
1220                 }
1221                 else
1222                 {
1223                         maxairspd = sv_maxairspeed;
1224                         airaccel = sv_airaccelerate;
1225                 }
1226                 // airborn
1227                 makevectors(self.v_angle_y * '0 1 0');
1228                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1229                 // acceleration
1230                 wishdir = normalize(wishvel);
1231                 wishspeed = wishspeed0 = vlen(wishvel);
1232                 if (wishspeed0 > self.stat_sv_maxspeed*maxspd_mod)
1233                         wishspeed0 = self.stat_sv_maxspeed*maxspd_mod;
1234                 if (wishspeed > maxairspd)
1235                         wishspeed = maxairspd;
1236                 if (self.crouch)
1237                         wishspeed = wishspeed * 0.5;
1238                 if (time >= self.teleport_time)
1239                 {
1240                         float accelerating;
1241                         float wishspeed2;
1242                         float airaccelqw;
1243                         float strafity;
1244
1245                         airaccelqw = self.stat_sv_airaccel_qw;
1246                         accelerating = (self.velocity * wishdir > 0);
1247                         wishspeed2 = wishspeed;
1248
1249                         // CPM
1250                         if(sv_airstopaccelerate)
1251                         {
1252                                 vector curdir;
1253                                 curdir = self.velocity;
1254                                 curdir_z = 0;
1255                                 curdir = normalize(curdir);
1256                                 airaccel = airaccel + (sv_airstopaccelerate*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1257                         }
1258                         // note that for straight forward jumping:
1259                         // step = accel * frametime * wishspeed0;
1260                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1261                         // -->
1262                         // dv/dt = accel * maxspeed (when slow)
1263                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1264                         // log dv/dt = logaccel + logmaxspeed (when slow)
1265                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1266                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1267                         if(sv_maxairstrafespeed)
1268                                 wishspeed = min(wishspeed, GeomLerp(sv_maxairspeed*maxspd_mod, strafity, sv_maxairstrafespeed*maxspd_mod));
1269                         if(sv_airstrafeaccelerate)
1270                                 airaccel = GeomLerp(airaccel, strafity, sv_airstrafeaccelerate*maxspd_mod);
1271                         if(self.stat_sv_airstrafeaccel_qw)
1272                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1273                         // !CPM
1274
1275                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1276                                 PM_AirAccelerate(wishdir, wishspeed);
1277                         else
1278                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd, self.stat_sv_airspeedlimit_nonqw);
1279
1280                         if(sv_aircontrol)
1281                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1282                 }
1283         }
1284
1285         if((g_cts || g_race) && self.classname != "observer") {
1286                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1287                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1288                         speedaward_holder = self.netname;
1289                         speedaward_uid = self.crypto_idfp;
1290                         speedaward_lastupdate = time;
1291                 }
1292                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1293                         string rr;
1294                         if(g_cts)
1295                                 rr = CTS_RECORD;
1296                         else
1297                                 rr = RACE_RECORD;
1298                         race_send_speedaward(MSG_ALL);
1299                         speedaward_lastsent = speedaward_speed;
1300                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "") {
1301                                 speedaward_alltimebest = speedaward_speed;
1302                                 speedaward_alltimebest_holder = speedaward_holder;
1303                                 speedaward_alltimebest_uid = speedaward_uid;
1304                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1305                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
1306                                 race_send_speedaward_alltimebest(MSG_ALL);
1307                         }
1308                 }
1309         }
1310
1311         float xyspeed;
1312         xyspeed = vlen('1 0 0' * self.velocity_x + '0 1 0' * self.velocity_y);
1313         if(self.weapon == WEP_NEX && cvar("g_balance_nex_charge") && cvar("g_balance_nex_charge_velocity_rate") && xyspeed > cvar("g_balance_nex_charge_minspeed"))
1314         {
1315                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1316                 xyspeed = min(xyspeed, cvar("g_balance_nex_charge_maxspeed"));
1317                 f = (xyspeed - cvar("g_balance_nex_charge_minspeed")) / (cvar("g_balance_nex_charge_maxspeed") - cvar("g_balance_nex_charge_minspeed"));
1318                 // add the extra charge
1319                 self.nex_charge = min(1, self.nex_charge + cvar("g_balance_nex_charge_velocity_rate") * f * frametime);
1320         }
1321 :end
1322         if(self.flags & FL_ONGROUND)
1323                 self.lastground = time;
1324
1325         self.lastflags = self.flags;
1326         self.lastclassname = self.classname;
1327 };