qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 .float ladder_time;
   5 .entity ladder_entity;
   6 .float gravity;
   7 .float swamp_slowdown;
   8 .float lastflags;
   9 .float lastground;
  10 .float wasFlying;
  11 .float spectatorspeed;
  12
  13 /*
  14 =============
  15 PlayerJump
  16
  17 When you press the jump key
  18 =============
  19 */
  20 void PlayerJump (void)
  21 {
  22         if(self.frozen)
  23                 return; // no jumping in freezetag when frozen
  24
  25         float doublejump = FALSE;
  26
  27         player_multijump = doublejump;
  28         if(MUTATOR_CALLHOOK(PlayerJump))
  29                 return;
  30
  31         doublejump = player_multijump;
  32
  33         float mjumpheight;
  34
  35         if (autocvar_sv_doublejump)
  36         {
  37                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
  38                 if (trace_fraction < 1 && trace_plane_normal_z > 0.7)
  39                 {
  40                         doublejump = TRUE;
  41
  42                         // we MUST clip velocity here!
  43                         float f;
  44                         f = self.velocity * trace_plane_normal;
  45                         if(f < 0)
  46                                 self.velocity -= f * trace_plane_normal;
  47                 }
  48         }
  49
  50         mjumpheight = autocvar_sv_jumpvelocity;
  51         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  52         {
  53                 self.velocity_z = self.stat_sv_maxspeed * 0.7;
  54                 return;
  55         }
  56
  57         if (!doublejump)
  58                 if (!(self.flags & FL_ONGROUND))
  59                         return;
  60
  61         if(self.cvar_cl_movement_track_canjump)
  62                 if (!(self.flags & FL_JUMPRELEASED))
  63                         return;
  64
  65         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
  66         // velocity bounds.  Final velocity is bound between (jumpheight *
  67         // min + jumpheight) and (jumpheight * max + jumpheight);
  68
  69         if(autocvar_sv_jumpspeedcap_min != "")
  70         {
  71                 float minjumpspeed;
  72
  73                 minjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_min);
  74
  75                 if (self.velocity_z < minjumpspeed)
  76                         mjumpheight += minjumpspeed - self.velocity_z;
  77         }
  78
  79         if(autocvar_sv_jumpspeedcap_max != "")
  80         {
  81                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
  82                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
  83
  84                 if(!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && autocvar_sv_jumpspeedcap_max_disable_on_ramps))
  85                 {
  86                         float maxjumpspeed;
  87
  88                         maxjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_max);
  89
  90                         if (self.velocity_z > maxjumpspeed)
  91                                 mjumpheight -= self.velocity_z - maxjumpspeed;
  92                 }
  93         }
  94
  95         if(!(self.lastflags & FL_ONGROUND))
  96         {
  97                 if(autocvar_speedmeter)
  98                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
  99                 if(self.lastground < time - 0.3)
 100                 {
 101                         self.velocity_x *= (1 - autocvar_sv_friction_on_land);
 102                         self.velocity_y *= (1 - autocvar_sv_friction_on_land);
 103                 }
 104                 if(self.jumppadcount > 1)
 105                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 106                 self.jumppadcount = 0;
 107         }
 108
 109         self.velocity_z = self.velocity_z + mjumpheight;
 110         self.oldvelocity_z = self.velocity_z;
 111
 112         self.flags &~= FL_ONGROUND;
 113         self.flags &~= FL_JUMPRELEASED;
 114
 115         animdecide_setaction(self, ANIMACTION_JUMP, TRUE);
 116
 117         if(autocvar_g_jump_grunt)
 118                 PlayerSound(playersound_jump, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 119
 120         self.restart_jump = -1; // restart jump anim next time
 121         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 122 }
 123 void CheckWaterJump()
 124 {
 125         vector start, end;
 126
 127 // check for a jump-out-of-water
 128         makevectors (self.angles);
 129         start = self.origin;
 130         start_z = start_z + 8;
 131         v_forward_z = 0;
 132         normalize(v_forward);
 133         end = start + v_forward*24;
 134         traceline (start, end, TRUE, self);
 135         if (trace_fraction < 1)
 136         {       // solid at waist
 137                 start_z = start_z + self.maxs_z - 8;
 138                 end = start + v_forward*24;
 139                 self.movedir = trace_plane_normal * -50;
 140                 traceline (start, end, TRUE, self);
 141                 if (trace_fraction == 1)
 142                 {       // open at eye level
 143                         self.flags |= FL_WATERJUMP;
 144                         self.velocity_z = 225;
 145                         self.flags &~= FL_JUMPRELEASED;
 146                         self.teleport_time = time + 2;  // safety net
 147                         return;
 148                 }
 149         }
 150 }
 151 void CheckPlayerJump()
 152 {
 153         if (self.BUTTON_JUMP)
 154                 PlayerJump ();
 155         else
 156                 self.flags |= FL_JUMPRELEASED;
 157
 158         if (self.waterlevel == WATERLEVEL_SWIMMING)
 159                 CheckWaterJump ();
 160 }
 161
 162 float racecar_angle(float forward, float down)
 163 {
 164         float ret, angle_mult;
 165
 166         if(forward < 0)
 167         {
 168                 forward = -forward;
 169                 down = -down;
 170         }
 171
 172         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 173
 174         angle_mult = forward / (800 + forward);
 175
 176         if(ret > 180)
 177                 return ret * angle_mult + 360 * (1 - angle_mult);
 178         else
 179                 return ret * angle_mult;
 180 }
 181
 182 void RaceCarPhysics()
 183 {
 184         // using this move type for "big rigs"
 185         // the engine does not push the entity!
 186
 187         float accel, steer, f, myspeed, steerfactor;
 188         vector angles_save, rigvel;
 189
 190         angles_save = self.angles;
 191         accel = bound(-1, self.movement_x / self.stat_sv_maxspeed, 1);
 192         steer = bound(-1, self.movement_y / self.stat_sv_maxspeed, 1);
 193
 194         if(g_bugrigs_reverse_speeding)
 195         {
 196                 if(accel < 0)
 197                 {
 198                         // back accel is DIGITAL
 199                         // to prevent speedhack
 200                         if(accel < -0.5)
 201                                 accel = -1;
 202                         else
 203                                 accel = 0;
 204                 }
 205         }
 206
 207         self.angles_x = 0;
 208         self.angles_z = 0;
 209         makevectors(self.angles); // new forward direction!
 210
 211         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 212         {
 213                 float upspeed, accelfactor;
 214
 215                 myspeed = self.velocity * v_forward;
 216                 upspeed = self.velocity * v_up;
 217
 218                 // responsiveness factor for steering and acceleration
 219                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 220                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 221
 222                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 223                         steerfactor = -myspeed * g_bugrigs_steer;
 224                 else
 225                         steerfactor = -myspeed * f * g_bugrigs_steer;
 226
 227                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 228                         accelfactor = g_bugrigs_accel;
 229                 else
 230                         accelfactor = f * g_bugrigs_accel;
 231                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 232
 233                 if(accel < 0)
 234                 {
 235                         if(myspeed > 0)
 236                         {
 237                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 238                         }
 239                         else
 240                         {
 241                                 if(!g_bugrigs_reverse_speeding)
 242                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 243                         }
 244                 }
 245                 else
 246                 {
 247                         if(myspeed >= 0)
 248                         {
 249                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 250                         }
 251                         else
 252                         {
 253                                 if(g_bugrigs_reverse_stopping)
 254                                         myspeed = 0;
 255                                 else
 256                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 257                         }
 258                 }
 259                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 260                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 261
 262                 self.angles_y += steer * frametime * steerfactor; // apply steering
 263                 makevectors(self.angles); // new forward direction!
 264
 265                 myspeed += accel * accelfactor * frametime;
 266
 267                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 268         }
 269         else
 270         {
 271                 myspeed = vlen(self.velocity);
 272
 273                 // responsiveness factor for steering and acceleration
 274                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 275                 steerfactor = -myspeed * f;
 276                 self.angles_y += steer * frametime * steerfactor; // apply steering
 277
 278                 rigvel = self.velocity;
 279                 makevectors(self.angles); // new forward direction!
 280         }
 281
 282         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 283         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 284         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 285         //MAXIMA: solve(total_acceleration(v) = 0, v);
 286
 287         if(g_bugrigs_planar_movement)
 288         {
 289                 vector rigvel_xy, neworigin, up;
 290                 float mt;
 291
 292                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 293                 rigvel_xy = vec2(rigvel);
 294
 295                 if(g_bugrigs_planar_movement_car_jumping)
 296                         mt = MOVE_NORMAL;
 297                 else
 298                         mt = MOVE_NOMONSTERS;
 299
 300                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 301                 up = trace_endpos - self.origin;
 302
 303                 // BUG RIGS: align the move to the surface instead of doing collision testing
 304                 // can we move?
 305                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 306
 307                 // align to surface
 308                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 309
 310                 if(trace_fraction < 0.5)
 311                 {
 312                         trace_fraction = 1;
 313                         neworigin = self.origin;
 314                 }
 315                 else
 316                         neworigin = trace_endpos;
 317
 318                 if(trace_fraction < 1)
 319                 {
 320                         // now set angles_x so that the car points parallel to the surface
 321                         self.angles = vectoangles(
 322                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 323                                         +
 324                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 325                                         +
 326                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 327                                         );
 328                         self.flags |= FL_ONGROUND;
 329                 }
 330                 else
 331                 {
 332                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 333                         self.flags &~= FL_ONGROUND;
 334                 }
 335
 336                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 337                 self.movetype = MOVETYPE_NOCLIP;
 338         }
 339         else
 340         {
 341                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 342                 self.velocity = rigvel;
 343                 self.movetype = MOVETYPE_FLY;
 344         }
 345
 346         trace_fraction = 1;
 347         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 348         if(trace_fraction != 1)
 349         {
 350                 self.angles = vectoangles2(
 351                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 352                                 +
 353                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 354                                 +
 355                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 356                                 trace_plane_normal
 357                                 );
 358         }
 359         else
 360         {
 361                 vector vel_local;
 362
 363                 vel_local_x = v_forward * self.velocity;
 364                 vel_local_y = v_right * self.velocity;
 365                 vel_local_z = v_up * self.velocity;
 366
 367                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 368                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 369         }
 370
 371         // smooth the angles
 372         vector vf1, vu1, smoothangles;
 373         makevectors(self.angles);
 374         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 375         if(f == 0)
 376                 f = 1;
 377         vf1 = v_forward * f;
 378         vu1 = v_up * f;
 379         makevectors(angles_save);
 380         vf1 = vf1 + v_forward * (1 - f);
 381         vu1 = vu1 + v_up * (1 - f);
 382         smoothangles = vectoangles2(vf1, vu1);
 383         self.angles_x = -smoothangles_x;
 384         self.angles_z =  smoothangles_z;
 385 }
 386
 387 float IsMoveInDirection(vector mv, float angle) // key mix factor
 388 {
 389         if(mv_x == 0 && mv_y == 0)
 390                 return 0; // avoid division by zero
 391         angle -= RAD2DEG * atan2(mv_y, mv_x);
 392         angle = remainder(angle, 360) / 45;
 393         if(angle >  1)
 394                 return 0;
 395         if(angle < -1)
 396                 return 0;
 397         return 1 - fabs(angle);
 398 }
 399
 400 float GeomLerp(float a, float lerp, float b)
 401 {
 402         if(a == 0)
 403         {
 404                 if(lerp < 1)
 405                         return 0;
 406                 else
 407                         return b;
 408         }
 409         if(b == 0)
 410         {
 411                 if(lerp > 0)
 412                         return 0;
 413                 else
 414                         return a;
 415         }
 416         return a * pow(fabs(b / a), lerp);
 417 }
 418
 419 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 420 {
 421         float zspeed, xyspeed, dot, k;
 422
 423 #if 0
 424         // this doesn't play well with analog input
 425         if(self.movement_x == 0 || self.movement_y != 0)
 426                 return; // can't control movement if not moving forward or backward
 427         k = 32;
 428 #else
 429         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 430         if(k <= 0)
 431                 return;
 432 #endif
 433
 434         k *= bound(0, wishspeed / autocvar_sv_maxairspeed, 1);
 435
 436         zspeed = self.velocity_z;
 437         self.velocity_z = 0;
 438         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 439
 440         dot = self.velocity * wishdir;
 441
 442         if(dot > 0) // we can't change direction while slowing down
 443         {
 444                 k *= pow(dot, autocvar_sv_aircontrol_power)*frametime;
 445                 xyspeed = max(0, xyspeed - autocvar_sv_aircontrol_penalty * sqrt(max(0, 1 - dot*dot)) * k/32);
 446                 k *= autocvar_sv_aircontrol;
 447                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 448         }
 449
 450         self.velocity = self.velocity * xyspeed;
 451         self.velocity_z = zspeed;
 452 }
 453
 454 float AdjustAirAccelQW(float accelqw, float factor)
 455 {
 456         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 457 }
 458
 459 // example config for alternate speed clamping:
 460 //   sv_airaccel_qw 0.8
 461 //   sv_airaccel_sideways_friction 0
 462 //   prvm_globalset server speedclamp_mode 1
 463 //     (or 2)
 464 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 465 {
 466         float vel_straight;
 467         float vel_z;
 468         vector vel_perpend;
 469         float step;
 470
 471         vector vel_xy;
 472         float vel_xy_current;
 473         float vel_xy_backward, vel_xy_forward;
 474         float speedclamp;
 475
 476         if(stretchfactor > 0)
 477                 speedclamp = stretchfactor;
 478         else if(accelqw < 0)
 479                 speedclamp = 1; // full clamping, no stretch
 480         else
 481                 speedclamp = -1; // no clamping
 482
 483         if(accelqw < 0)
 484                 accelqw = -accelqw;
 485
 486         if(autocvar_sv_gameplayfix_q2airaccelerate)
 487                 wishspeed0 = wishspeed;
 488
 489         vel_straight = self.velocity * wishdir;
 490         vel_z = self.velocity_z;
 491         vel_xy = vec2(self.velocity);
 492         vel_perpend = vel_xy - vel_straight * wishdir;
 493
 494         step = accel * frametime * wishspeed0;
 495
 496         vel_xy_current  = vlen(vel_xy);
 497         if(speedlimit)
 498                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 499         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 500         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 501         if(vel_xy_backward < 0)
 502                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 503
 504         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 505
 506         if(sidefric < 0 && (vel_perpend*vel_perpend))
 507                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 508         {
 509                 float f, fminimum;
 510                 f = max(0, 1 + frametime * wishspeed * sidefric);
 511                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 512                 // this cannot be > 1
 513                 if(fminimum <= 0)
 514                         vel_perpend = vel_perpend * max(0, f);
 515                 else
 516                 {
 517                         fminimum = sqrt(fminimum);
 518                         vel_perpend = vel_perpend * max(fminimum, f);
 519                 }
 520         }
 521         else
 522                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
 523
 524         vel_xy = vel_straight * wishdir + vel_perpend;
 525
 526         if(speedclamp >= 0)
 527         {
 528                 float vel_xy_preclamp;
 529                 vel_xy_preclamp = vlen(vel_xy);
 530                 if(vel_xy_preclamp > 0) // prevent division by zero
 531                 {
 532                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 533                         if(vel_xy_current < vel_xy_preclamp)
 534                                 vel_xy = vel_xy * (vel_xy_current / vel_xy_preclamp);
 535                 }
 536         }
 537
 538         self.velocity = vel_xy + vel_z * '0 0 1';
 539 }
 540
 541 void PM_AirAccelerate(vector wishdir, float wishspeed)
 542 {
 543         vector curvel, wishvel, acceldir, curdir;
 544         float addspeed, accelspeed, curspeed, f;
 545         float dot;
 546
 547         if(wishspeed == 0)
 548                 return;
 549
 550         curvel = self.velocity;
 551         curvel_z = 0;
 552         curspeed = vlen(curvel);
 553
 554         if(wishspeed > curspeed * 1.01)
 555         {
 556                 wishspeed = min(wishspeed, curspeed + autocvar_sv_warsowbunny_airforwardaccel * self.stat_sv_maxspeed * frametime);
 557         }
 558         else
 559         {
 560                 f = max(0, (autocvar_sv_warsowbunny_topspeed - curspeed) / (autocvar_sv_warsowbunny_topspeed - self.stat_sv_maxspeed));
 561                 wishspeed = max(curspeed, self.stat_sv_maxspeed) + autocvar_sv_warsowbunny_accel * f * self.stat_sv_maxspeed * frametime;
 562         }
 563         wishvel = wishdir * wishspeed;
 564         acceldir = wishvel - curvel;
 565         addspeed = vlen(acceldir);
 566         acceldir = normalize(acceldir);
 567
 568         accelspeed = min(addspeed, autocvar_sv_warsowbunny_turnaccel * self.stat_sv_maxspeed * frametime);
 569
 570         if(autocvar_sv_warsowbunny_backtosideratio < 1)
 571         {
 572                 curdir = normalize(curvel);
 573                 dot = acceldir * curdir;
 574                 if(dot < 0)
 575                         acceldir = acceldir - (1 - autocvar_sv_warsowbunny_backtosideratio) * dot * curdir;
 576         }
 577
 578         self.velocity += accelspeed * acceldir;
 579 }
 580
 581 .vector movement_old;
 582 .float buttons_old;
 583 .vector v_angle_old;
 584 .string lastclassname;
 585
 586 .float() PlayerPhysplug;
 587
 588 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 589 .float specialcommand_pos;
 590 void SpecialCommand()
 591 {
 592 #ifdef TETRIS
 593         TetrisImpulse();
 594 #else
 595         if(!CheatImpulse(99))
 596                 print("A hollow voice says \"Plugh\".\n");
 597 #endif
 598 }
 599
 600 float speedaward_speed;
 601 string speedaward_holder;
 602 string speedaward_uid;
 603 void race_send_speedaward(float msg)
 604 {
 605         // send the best speed of the round
 606         WriteByte(msg, SVC_TEMPENTITY);
 607         WriteByte(msg, TE_CSQC_RACE);
 608         WriteByte(msg, RACE_NET_SPEED_AWARD);
 609         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 610         WriteString(msg, speedaward_holder);
 611 }
 612
 613 float speedaward_alltimebest;
 614 string speedaward_alltimebest_holder;
 615 string speedaward_alltimebest_uid;
 616 void race_send_speedaward_alltimebest(float msg)
 617 {
 618         // send the best speed
 619         WriteByte(msg, SVC_TEMPENTITY);
 620         WriteByte(msg, TE_CSQC_RACE);
 621         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 622         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 623         WriteString(msg, speedaward_alltimebest_holder);
 624 }
 625
 626 string GetMapname(void);
 627 float speedaward_lastupdate;
 628 float speedaward_lastsent;
 629 void SV_PlayerPhysics()
 630 {
 631         vector wishvel, wishdir, v;
 632         float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 633         string temps;
 634         float buttons_prev;
 635         float not_allowed_to_move;
 636         string c;
 637
 638         WarpZone_PlayerPhysics_FixVAngle();
 639
 640         maxspd_mod = 1;
 641         if(self.ballcarried)
 642                 if(g_nexball)
 643                         maxspd_mod *= autocvar_g_nexball_basketball_carrier_highspeed;
 644                 else if(g_keepaway)
 645                         maxspd_mod *= autocvar_g_keepaway_ballcarrier_highspeed;
 646
 647         maxspd_mod *= autocvar_g_movement_highspeed;
 648
 649         // fix physics stats for g_movement_highspeed
 650         // TODO maybe rather use maxairspeed? needs testing
 651         self.stat_sv_airaccel_qw = AdjustAirAccelQW(autocvar_sv_airaccel_qw, maxspd_mod);
 652         if(autocvar_sv_airstrafeaccel_qw)
 653                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(autocvar_sv_airstrafeaccel_qw, maxspd_mod);
 654         else
 655                 self.stat_sv_airstrafeaccel_qw = 0;
 656         self.stat_sv_airspeedlimit_nonqw = autocvar_sv_airspeedlimit_nonqw * maxspd_mod;
 657         self.stat_sv_maxspeed = autocvar_sv_maxspeed * maxspd_mod; // also slow walking
 658
 659     if(self.PlayerPhysplug)
 660         if(self.PlayerPhysplug())
 661             return;
 662
 663         self.race_movetime_frac += frametime;
 664         f = floor(self.race_movetime_frac);
 665         self.race_movetime_frac -= f;
 666         self.race_movetime_count += f;
 667         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 668
 669         anticheat_physics();
 670
 671         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 672
 673         if(!buttons)
 674                 c = "x";
 675         else if(buttons == 1)
 676                 c = "1";
 677         else if(buttons == 2)
 678                 c = " ";
 679         else if(buttons == 128)
 680                 c = "s";
 681         else if(buttons == 256)
 682                 c = "w";
 683         else if(buttons == 512)
 684                 c = "a";
 685         else if(buttons == 1024)
 686                 c = "d";
 687         else
 688                 c = "?";
 689
 690         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 691         {
 692                 self.specialcommand_pos += 1;
 693                 if(self.specialcommand_pos >= strlen(specialcommand))
 694                 {
 695                         self.specialcommand_pos = 0;
 696                         SpecialCommand();
 697                         return;
 698                 }
 699         }
 700         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 701                 self.specialcommand_pos = 0;
 702
 703         if(sv_maxidle > 0)
 704         {
 705                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 706                         self.parm_idlesince = time;
 707         }
 708         buttons_prev = self.buttons_old;
 709         self.buttons_old = buttons;
 710         self.movement_old = self.movement;
 711         self.v_angle_old = self.v_angle;
 712
 713         if(time < self.nickspamtime)
 714         if(self.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 715         {
 716                 // slight annoyance for nick change scripts
 717                 self.movement = -1 * self.movement;
 718                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 719
 720                 if(self.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 721                 {
 722                         self.angles_x = random() * 360;
 723                         self.angles_y = random() * 360;
 724                         // at least I'm not forcing retardedview by also assigning to angles_z
 725                         self.fixangle = TRUE;
 726                 }
 727         }
 728
 729         if (self.punchangle != '0 0 0')
 730         {
 731                 f = vlen(self.punchangle) - 10 * frametime;
 732                 if (f > 0)
 733                         self.punchangle = normalize(self.punchangle) * f;
 734                 else
 735                         self.punchangle = '0 0 0';
 736         }
 737
 738         if (self.punchvector != '0 0 0')
 739         {
 740                 f = vlen(self.punchvector) - 30 * frametime;
 741                 if (f > 0)
 742                         self.punchvector = normalize(self.punchvector) * f;
 743                 else
 744                         self.punchvector = '0 0 0';
 745         }
 746
 747         if (IS_BOT_CLIENT(self))
 748         {
 749                 if(playerdemo_read())
 750                         return;
 751                 bot_think();
 752         }
 753
 754         self.items &~= IT_USING_JETPACK;
 755
 756         if(IS_PLAYER(self))
 757         {
 758                 if(self.race_penalty)
 759                         if(time > self.race_penalty)
 760                                 self.race_penalty = 0;
 761
 762                 not_allowed_to_move = 0;
 763                 if(self.race_penalty)
 764                         not_allowed_to_move = 1;
 765                 if(!autocvar_sv_ready_restart_after_countdown)
 766                 if(time < game_starttime)
 767                         not_allowed_to_move = 1;
 768
 769                 if(not_allowed_to_move)
 770                 {
 771                         self.velocity = '0 0 0';
 772                         self.movetype = MOVETYPE_NONE;
 773                         self.disableclientprediction = 2;
 774                 }
 775                 else if(self.disableclientprediction == 2)
 776                 {
 777                         if(self.movetype == MOVETYPE_NONE)
 778                                 self.movetype = MOVETYPE_WALK;
 779                         self.disableclientprediction = 0;
 780                 }
 781         }
 782
 783         if (self.movetype == MOVETYPE_NONE)
 784                 return;
 785
 786         // when we get here, disableclientprediction cannot be 2
 787         self.disableclientprediction = 0;
 788         if(time < self.ladder_time)
 789                 self.disableclientprediction = 1;
 790
 791         if(self.frozen)
 792         {
 793                 if(autocvar_sv_dodging_frozen && IS_REAL_CLIENT(self))
 794                 {
 795                         self.movement_x = bound(-5, self.movement_x, 5);
 796                         self.movement_y = bound(-5, self.movement_y, 5);
 797                         self.movement_z = bound(-5, self.movement_z, 5);
 798                 }
 799                 else
 800                         self.movement = '0 0 0';
 801                 self.disableclientprediction = 1;
 802         }
 803
 804         MUTATOR_CALLHOOK(PlayerPhysics);
 805
 806         if(self.player_blocked)
 807         {
 808                 self.movement = '0 0 0';
 809                 self.disableclientprediction = 1;
 810         }
 811
 812         maxspd_mod = 1;
 813
 814         swampspd_mod = 1;
 815         if(self.in_swamp) {
 816                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 817         }
 818
 819         // conveyors: first fix velocity
 820         if(self.conveyor.state)
 821                 self.velocity -= self.conveyor.movedir;
 822
 823         if not(IS_PLAYER(self))
 824         {
 825                 maxspd_mod = autocvar_sv_spectator_speed_multiplier;
 826                 if(!self.spectatorspeed)
 827                         self.spectatorspeed = maxspd_mod;
 828                 if(self.impulse && self.impulse <= 19 || self.impulse >= 200 && self.impulse <= 209 || self.impulse >= 220 && self.impulse <= 229)
 829                 {
 830                         if(self.lastclassname != "player")
 831                         {
 832                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209)
 833                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 834                                 else if(self.impulse == 11)
 835                                         self.spectatorspeed = maxspd_mod;
 836                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229)
 837                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 838                                 else if(self.impulse >= 1 && self.impulse <= 9)
 839                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 840                         } // otherwise just clear
 841                         self.impulse = 0;
 842                 }
 843                 maxspd_mod = self.spectatorspeed;
 844         }
 845
 846         spd = max(self.stat_sv_maxspeed, autocvar_sv_maxairspeed) * maxspd_mod * swampspd_mod;
 847         if(self.speed != spd)
 848         {
 849                 self.speed = spd;
 850                 temps = ftos(spd);
 851                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 852                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 853                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 854                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 855         }
 856
 857         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 858         swampspd_mod = 1;
 859
 860         // if dead, behave differently
 861         if (self.deadflag)
 862                 goto end;
 863
 864         if (!self.fixangle && !g_bugrigs)
 865         {
 866                 self.angles_x = 0;
 867                 self.angles_y = self.v_angle_y;
 868                 self.angles_z = 0;
 869         }
 870
 871         if(self.flags & FL_ONGROUND)
 872         if(IS_PLAYER(self)) // no fall sounds for observers thank you very much
 873         if(self.wasFlying)
 874         {
 875                 self.wasFlying = 0;
 876
 877                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 878                 if(time >= self.ladder_time)
 879                 if not(self.hook)
 880                 {
 881                         self.nextstep = time + 0.3 + random() * 0.1;
 882                         trace_dphitq3surfaceflags = 0;
 883                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 884                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 885                         {
 886                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 887                                         GlobalSound(globalsound_metalfall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 888                                 else
 889                                         GlobalSound(globalsound_fall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 890                         }
 891                 }
 892         }
 893
 894         if(IsFlying(self))
 895                 self.wasFlying = 1;
 896
 897         if(IS_PLAYER(self))
 898                 CheckPlayerJump();
 899
 900         if (self.flags & FL_WATERJUMP )
 901         {
 902                 self.velocity_x = self.movedir_x;
 903                 self.velocity_y = self.movedir_y;
 904                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 905                 {
 906                         self.flags &~= FL_WATERJUMP;
 907                         self.teleport_time = 0;
 908                 }
 909         }
 910         else if (g_bugrigs && IS_PLAYER(self))
 911         {
 912                 RaceCarPhysics();
 913         }
 914         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY || self.movetype == MOVETYPE_FLY_WORLDONLY)
 915         {
 916                 // noclipping or flying
 917                 self.flags &~= FL_ONGROUND;
 918
 919                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
 920                 makevectors(self.v_angle);
 921                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 922                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 923                 // acceleration
 924                 wishdir = normalize(wishvel);
 925                 wishspeed = vlen(wishvel);
 926                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 927                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 928                 if (time >= self.teleport_time)
 929                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
 930         }
 931         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 932         {
 933                 // swimming
 934                 self.flags &~= FL_ONGROUND;
 935
 936                 makevectors(self.v_angle);
 937                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 938                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 939                 if (wishvel == '0 0 0')
 940                         wishvel = '0 0 -60'; // drift towards bottom
 941
 942                 wishdir = normalize(wishvel);
 943                 wishspeed = vlen(wishvel);
 944                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 945                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 946                 wishspeed = wishspeed * 0.7;
 947
 948                 // water friction
 949                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
 950
 951                 // water acceleration
 952                 PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
 953         }
 954         else if (time < self.ladder_time)
 955         {
 956                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 957                 self.flags &~= FL_ONGROUND;
 958
 959                 float g;
 960                 g = autocvar_sv_gravity * frametime;
 961                 if(self.gravity)
 962                         g *= self.gravity;
 963                 if(autocvar_sv_gameplayfix_gravityunaffectedbyticrate)
 964                 {
 965                         g *= 0.5;
 966                         self.velocity_z += g;
 967                 }
 968
 969                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
 970                 makevectors(self.v_angle);
 971                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 972                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 973                 self.velocity_z += g;
 974                 if (self.ladder_entity.classname == "func_water")
 975                 {
 976                         f = vlen(wishvel);
 977                         if (f > self.ladder_entity.speed)
 978                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 979
 980                         self.watertype = self.ladder_entity.skin;
 981                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 982                         if ((self.origin_z + self.view_ofs_z) < f)
 983                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 984                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 985                                 self.waterlevel = WATERLEVEL_SWIMMING;
 986                         else if ((self.origin_z + self.mins_z + 1) < f)
 987                                 self.waterlevel = WATERLEVEL_WETFEET;
 988                         else
 989                         {
 990                                 self.waterlevel = WATERLEVEL_NONE;
 991                                 self.watertype = CONTENT_EMPTY;
 992                         }
 993                 }
 994                 // acceleration
 995                 wishdir = normalize(wishvel);
 996                 wishspeed = vlen(wishvel);
 997                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 998                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 999                 if (time >= self.teleport_time)
1000                 {
1001                         // water acceleration
1002                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1003                 }
1004         }
1005         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!autocvar_g_jetpack_fuel || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO) && !self.frozen)
1006         {
1007                 //makevectors(self.v_angle_y * '0 1 0');
1008                 makevectors(self.v_angle);
1009                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1010                 // add remaining speed as Z component
1011                 maxairspd = autocvar_sv_maxairspeed*max(1, maxspd_mod);
1012                 // fix speedhacks :P
1013                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
1014                 // add the unused velocity as up component
1015                 wishvel_z = 0;
1016
1017                 // if(self.BUTTON_JUMP)
1018                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1019
1020                 // it is now normalized, so...
1021                 float a_side, a_up, a_add, a_diff;
1022                 a_side = autocvar_g_jetpack_acceleration_side;
1023                 a_up = autocvar_g_jetpack_acceleration_up;
1024                 a_add = autocvar_g_jetpack_antigravity * autocvar_sv_gravity;
1025
1026                 wishvel_x *= a_side;
1027                 wishvel_y *= a_side;
1028                 wishvel_z *= a_up;
1029                 wishvel_z += a_add;
1030
1031                 float best;
1032                 best = 0;
1033                 //////////////////////////////////////////////////////////////////////////////////////
1034                 // finding the maximum over all vectors of above form
1035                 // with wishvel having an absolute value of 1
1036                 //////////////////////////////////////////////////////////////////////////////////////
1037                 // we're finding the maximum over
1038                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1039                 // for z in the range from -1 to 1
1040                 //////////////////////////////////////////////////////////////////////////////////////
1041                 // maximum is EITHER attained at the single extreme point:
1042                 a_diff = a_side * a_side - a_up * a_up;
1043                 if(a_diff != 0)
1044                 {
1045                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1046                         if(f > -1 && f < 1) // can it be attained?
1047                         {
1048                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1049                                 //print("middle\n");
1050                         }
1051                 }
1052                 // OR attained at z = 1:
1053                 f = (a_up + a_add) * (a_up + a_add);
1054                 if(f > best)
1055                 {
1056                         best = f;
1057                         //print("top\n");
1058                 }
1059                 // OR attained at z = -1:
1060                 f = (a_up - a_add) * (a_up - a_add);
1061                 if(f > best)
1062                 {
1063                         best = f;
1064                         //print("bottom\n");
1065                 }
1066                 best = sqrt(best);
1067                 //////////////////////////////////////////////////////////////////////////////////////
1068
1069                 //print("best possible acceleration: ", ftos(best), "\n");
1070
1071                 float fxy, fz;
1072                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / autocvar_g_jetpack_maxspeed_side, 1);
1073                 if(wishvel_z - autocvar_sv_gravity > 0)
1074                         fz = bound(0, 1 - self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1075                 else
1076                         fz = bound(0, 1 + self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1077
1078                 float fvel;
1079                 fvel = vlen(wishvel);
1080                 wishvel_x *= fxy;
1081                 wishvel_y *= fxy;
1082                 wishvel_z = (wishvel_z - autocvar_sv_gravity) * fz + autocvar_sv_gravity;
1083
1084                 fvel = min(1, vlen(wishvel) / best);
1085                 if(autocvar_g_jetpack_fuel && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1086                         f = min(1, self.ammo_fuel / (autocvar_g_jetpack_fuel * frametime * fvel));
1087                 else
1088                         f = 1;
1089
1090                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1091
1092                 if (f > 0 && wishvel != '0 0 0')
1093                 {
1094                         self.velocity = self.velocity + wishvel * f * frametime;
1095                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1096                                 self.ammo_fuel -= autocvar_g_jetpack_fuel * frametime * fvel * f;
1097                         self.flags &~= FL_ONGROUND;
1098                         self.items |= IT_USING_JETPACK;
1099
1100                         // jetpack also inhibits health regeneration, but only for 1 second
1101                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1102                 }
1103         }
1104         else if (self.flags & FL_ONGROUND)
1105         {
1106                 // we get here if we ran out of ammo
1107                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32) && self.ammo_fuel < 0.01)
1108                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1109
1110                 // walking
1111                 makevectors(self.v_angle_y * '0 1 0');
1112                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1113
1114                 if(!(self.lastflags & FL_ONGROUND))
1115                 {
1116                         if(autocvar_speedmeter)
1117                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1118                         if(self.lastground < time - 0.3)
1119                                 self.velocity = self.velocity * (1 - autocvar_sv_friction_on_land);
1120                         if(self.jumppadcount > 1)
1121                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1122                         self.jumppadcount = 0;
1123                 }
1124
1125 #ifdef LETS_TEST_FTEQCC
1126                 if(self.velocity_x || self.velocity_y)
1127                 {
1128                         // good
1129                 }
1130                 else
1131                 {
1132                         if(self.velocity_x)
1133                                 checkclient();
1134                         if(self.velocity_y)
1135                                 checkclient();
1136                 }
1137 #endif
1138
1139                 v = self.velocity;
1140                 v_z = 0;
1141                 f = vlen(v);
1142                 if(f > 0)
1143                 {
1144                         if (f < autocvar_sv_stopspeed)
1145                                 f = 1 - frametime * (autocvar_sv_stopspeed / f) * autocvar_sv_friction;
1146                         else
1147                                 f = 1 - frametime * autocvar_sv_friction;
1148                         if (f > 0)
1149                                 self.velocity = self.velocity * f;
1150                         else
1151                                 self.velocity = '0 0 0';
1152                         /*
1153                            Mathematical analysis time!
1154
1155                            Our goal is to invert this mess.
1156
1157                            For the two cases we get:
1158                                 v = v0 * (1 - frametime * (autocvar_sv_stopspeed / v0) * autocvar_sv_friction)
1159                                   = v0 - frametime * autocvar_sv_stopspeed * autocvar_sv_friction
1160                                 v0 = v + frametime * autocvar_sv_stopspeed * autocvar_sv_friction
1161                            and
1162                                 v = v0 * (1 - frametime * autocvar_sv_friction)
1163                                 v0 = v / (1 - frametime * autocvar_sv_friction)
1164
1165                            These cases would be chosen ONLY if:
1166                                 v0 < autocvar_sv_stopspeed
1167                                 v + frametime * autocvar_sv_stopspeed * autocvar_sv_friction < autocvar_sv_stopspeed
1168                                 v < autocvar_sv_stopspeed * (1 - frametime * autocvar_sv_friction)
1169                            and, respectively:
1170                                 v0 >= autocvar_sv_stopspeed
1171                                 v / (1 - frametime * autocvar_sv_friction) >= autocvar_sv_stopspeed
1172                                 v >= autocvar_sv_stopspeed * (1 - frametime * autocvar_sv_friction)
1173                          */
1174                 }
1175
1176                 // acceleration
1177                 wishdir = normalize(wishvel);
1178                 wishspeed = vlen(wishvel);
1179                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1180                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1181                 if (self.crouch)
1182                         wishspeed = wishspeed * 0.5;
1183                 if (time >= self.teleport_time)
1184                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1185         }
1186         else
1187         {
1188                 float wishspeed0;
1189                 // we get here if we ran out of ammo
1190                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32) && self.ammo_fuel < 0.01)
1191                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1192
1193                 if(maxspd_mod < 1)
1194                 {
1195                         maxairspd = autocvar_sv_maxairspeed*maxspd_mod;
1196                         airaccel = autocvar_sv_airaccelerate*maxspd_mod;
1197                 }
1198                 else
1199                 {
1200                         maxairspd = autocvar_sv_maxairspeed;
1201                         airaccel = autocvar_sv_airaccelerate;
1202                 }
1203                 // airborn
1204                 makevectors(self.v_angle_y * '0 1 0');
1205                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1206                 // acceleration
1207                 wishdir = normalize(wishvel);
1208                 wishspeed = wishspeed0 = vlen(wishvel);
1209                 if (wishspeed0 > self.stat_sv_maxspeed*maxspd_mod)
1210                         wishspeed0 = self.stat_sv_maxspeed*maxspd_mod;
1211                 if (wishspeed > maxairspd)
1212                         wishspeed = maxairspd;
1213                 if (self.crouch)
1214                         wishspeed = wishspeed * 0.5;
1215                 if (time >= self.teleport_time)
1216                 {
1217                         float accelerating;
1218                         float wishspeed2;
1219                         float airaccelqw;
1220                         float strafity;
1221
1222                         airaccelqw = self.stat_sv_airaccel_qw;
1223                         accelerating = (self.velocity * wishdir > 0);
1224                         wishspeed2 = wishspeed;
1225
1226                         // CPM
1227                         if(autocvar_sv_airstopaccelerate)
1228                         {
1229                                 vector curdir;
1230                                 curdir = self.velocity;
1231                                 curdir_z = 0;
1232                                 curdir = normalize(curdir);
1233                                 airaccel = airaccel + (autocvar_sv_airstopaccelerate*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1234                         }
1235                         // note that for straight forward jumping:
1236                         // step = accel * frametime * wishspeed0;
1237                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1238                         // -->
1239                         // dv/dt = accel * maxspeed (when slow)
1240                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1241                         // log dv/dt = logaccel + logmaxspeed (when slow)
1242                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1243                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1244                         if(autocvar_sv_maxairstrafespeed)
1245                                 wishspeed = min(wishspeed, GeomLerp(autocvar_sv_maxairspeed*maxspd_mod, strafity, autocvar_sv_maxairstrafespeed*maxspd_mod));
1246                         if(autocvar_sv_airstrafeaccelerate)
1247                                 airaccel = GeomLerp(airaccel, strafity, autocvar_sv_airstrafeaccelerate*maxspd_mod);
1248                         if(self.stat_sv_airstrafeaccel_qw)
1249                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1250                         // !CPM
1251
1252                         if(autocvar_sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1253                                 PM_AirAccelerate(wishdir, wishspeed);
1254                         else
1255                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, autocvar_sv_airaccel_qw_stretchfactor, autocvar_sv_airaccel_sideways_friction / maxairspd, self.stat_sv_airspeedlimit_nonqw);
1256
1257                         if(autocvar_sv_aircontrol)
1258                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1259                 }
1260         }
1261
1262         if((g_cts || g_race) && !IS_OBSERVER(self)) {
1263                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1264                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1265                         speedaward_holder = self.netname;
1266                         speedaward_uid = self.crypto_idfp;
1267                         speedaward_lastupdate = time;
1268                 }
1269                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1270                         string rr;
1271                         if(g_cts)
1272                                 rr = CTS_RECORD;
1273                         else
1274                                 rr = RACE_RECORD;
1275                         race_send_speedaward(MSG_ALL);
1276                         speedaward_lastsent = speedaward_speed;
1277                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "") {
1278                                 speedaward_alltimebest = speedaward_speed;
1279                                 speedaward_alltimebest_holder = speedaward_holder;
1280                                 speedaward_alltimebest_uid = speedaward_uid;
1281                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1282                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
1283                                 race_send_speedaward_alltimebest(MSG_ALL);
1284                         }
1285                 }
1286         }
1287
1288         float xyspeed;
1289         xyspeed = vlen('1 0 0' * self.velocity_x + '0 1 0' * self.velocity_y);
1290         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge && autocvar_g_balance_nex_charge_velocity_rate && xyspeed > autocvar_g_balance_nex_charge_minspeed)
1291         {
1292                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1293                 xyspeed = min(xyspeed, autocvar_g_balance_nex_charge_maxspeed);
1294                 f = (xyspeed - autocvar_g_balance_nex_charge_minspeed) / (autocvar_g_balance_nex_charge_maxspeed - autocvar_g_balance_nex_charge_minspeed);
1295                 // add the extra charge
1296                 self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_velocity_rate * f * frametime);
1297         }
1298 :end
1299         if(self.flags & FL_ONGROUND)
1300                 self.lastground = time;
1301
1302         // conveyors: then break velocity again
1303         if(self.conveyor.state)
1304                 self.velocity += self.conveyor.movedir;
1305
1306         self.lastflags = self.flags;
1307         self.lastclassname = self.classname;
1308 }