Merge remote-tracking branch 'origin/master' into fruitiex/animations
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_physics.qc
1 .float race_penalty;
2 .float restart_jump;
3
4 .float ladder_time;
5 .entity ladder_entity;
6 .float gravity;
7 .float swamp_slowdown;
8 .float lastflags;
9 .float lastground;
10 .float wasFlying;
11 .float spectatorspeed;
12
13 .float multijump_count;
14 .float multijump_ready;
15 .float prevjumpbutton;
16
17 /*
18 =============
19 PlayerJump
20
21 When you press the jump key
22 =============
23 */
24 void PlayerJump (void)
25 {
26         if(self.freezetag_frozen)
27                 return; // no jumping in freezetag when frozen
28
29         float mjumpheight;
30         float doublejump;
31
32         doublejump = FALSE;
33         if (autocvar_sv_doublejump)
34         {
35                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
36                 if (trace_fraction < 1 && trace_plane_normal_z > 0.7)
37                         doublejump = TRUE;
38         }
39
40         mjumpheight = autocvar_sv_jumpvelocity;
41         if (self.waterlevel >= WATERLEVEL_SWIMMING)
42         {
43                 if (self.watertype == CONTENT_WATER)
44                         self.velocity_z = 200;
45                 else if (self.watertype == CONTENT_SLIME)
46                         self.velocity_z = 80;
47                 else
48                         self.velocity_z = 50;
49
50                 return;
51         }
52
53         if (autocvar_g_multijump)
54         {
55                 if (self.prevjumpbutton == FALSE && !(self.flags & FL_ONGROUND)) // jump button pressed this frame and we are in midair
56                         self.multijump_ready = TRUE;  // this is necessary to check that we released the jump button and pressed it again
57                 else
58                         self.multijump_ready = FALSE;
59         }
60
61         if(!doublejump && self.multijump_ready && self.multijump_count < autocvar_g_multijump && self.velocity_z > autocvar_g_multijump_speed)
62         {
63                 // doublejump = FALSE; // checked above in the if
64                 if (autocvar_g_multijump)
65                 {
66                         if (autocvar_g_multijump_add == 0) // in this case we make the z velocity == jumpvelocity
67                         {
68                                 if (self.velocity_z < mjumpheight)
69                                 {
70                                         doublejump = TRUE;
71                                         self.velocity_z = 0;
72                                 }
73                         }
74                         else
75                                 doublejump = TRUE;
76
77                         if(doublejump)
78                         {
79                                 if(self.movement_x != 0 || self.movement_y != 0) // don't remove all speed if player isnt pressing any movement keys
80                                 {
81                                         float curspeed;
82                                         vector wishvel, wishdir;
83
84                                         curspeed = max(
85                                                 vlen(vec2(self.velocity)), // current xy speed
86                                                 vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
87                                         );
88                                         makevectors(self.v_angle_y * '0 1 0');
89                                         wishvel = v_forward * self.movement_x + v_right * self.movement_y;
90                                         wishdir = normalize(wishvel);
91
92                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
93                                         self.velocity_y = wishdir_y * curspeed;
94                                         // keep velocity_z unchanged!
95                                 }
96                                 if (autocvar_g_multijump > 0)
97                                         self.multijump_count += 1;
98                         }
99                 }
100                 self.multijump_ready = FALSE; // require releasing and pressing the jump button again for the next jump
101         }
102
103         if (!doublejump)
104                 if (!(self.flags & FL_ONGROUND))
105                         return;
106
107         if(!sv_pogostick)
108                 if (!(self.flags & FL_JUMPRELEASED))
109                         return;
110
111         if(self.health <= g_bloodloss)
112                 return;
113
114         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
115         // velocity bounds.  Final velocity is bound between (jumpheight *
116         // min + jumpheight) and (jumpheight * max + jumpheight);
117
118         if(autocvar_sv_jumpspeedcap_min != "")
119         {
120                 float minjumpspeed;
121
122                 minjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_min);
123
124                 if (self.velocity_z < minjumpspeed)
125                         mjumpheight += minjumpspeed - self.velocity_z;
126         }
127
128         if(autocvar_sv_jumpspeedcap_max != "")
129         {
130                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
131                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
132
133                 if(!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && autocvar_sv_jumpspeedcap_max_disable_on_ramps))
134                 {
135                         float maxjumpspeed;
136
137                         maxjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_max);
138
139                         if (self.velocity_z > maxjumpspeed)
140                                 mjumpheight -= self.velocity_z - maxjumpspeed;
141                 }
142         }
143
144         if(!(self.lastflags & FL_ONGROUND))
145         {
146                 if(autocvar_speedmeter)
147                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
148                 if(self.lastground < time - 0.3)
149                 {
150                         self.velocity_x *= (1 - autocvar_sv_friction_on_land);
151                         self.velocity_y *= (1 - autocvar_sv_friction_on_land);
152                 }
153                 if(self.jumppadcount > 1)
154                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
155                 self.jumppadcount = 0;
156         }
157
158         self.velocity_z = self.velocity_z + mjumpheight;
159         self.oldvelocity_z = self.velocity_z;
160
161         self.flags &~= FL_ONGROUND;
162         self.flags &~= FL_JUMPRELEASED;
163
164         if (self.crouch)
165                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
166         else if (self.animstate_startframe != self.anim_melee_x) // jump animation shouldn't override melee until we have animation blending
167                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
168
169         if(g_jump_grunt)
170                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
171
172         self.restart_jump = -1; // restart jump anim next time
173         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
174 }
175
176 void CheckWaterJump()
177 {
178         local vector start, end;
179
180 // check for a jump-out-of-water
181         makevectors (self.angles);
182         start = self.origin;
183         start_z = start_z + 8;
184         v_forward_z = 0;
185         normalize(v_forward);
186         end = start + v_forward*24;
187         traceline (start, end, TRUE, self);
188         if (trace_fraction < 1)
189         {       // solid at waist
190                 start_z = start_z + self.maxs_z - 8;
191                 end = start + v_forward*24;
192                 self.movedir = trace_plane_normal * -50;
193                 traceline (start, end, TRUE, self);
194                 if (trace_fraction == 1)
195                 {       // open at eye level
196                         self.flags |= FL_WATERJUMP;
197                         self.velocity_z = 225;
198                         self.flags &~= FL_JUMPRELEASED;
199                         self.teleport_time = time + 2;  // safety net
200                         return;
201                 }
202         }
203 };
204
205 float racecar_angle(float forward, float down)
206 {
207         float ret, angle_mult;
208
209         if(forward < 0)
210         {
211                 forward = -forward;
212                 down = -down;
213         }
214
215         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
216
217         angle_mult = forward / (800 + forward);
218
219         if(ret > 180)
220                 return ret * angle_mult + 360 * (1 - angle_mult);
221         else
222                 return ret * angle_mult;
223 }
224
225 void RaceCarPhysics()
226 {
227         // using this move type for "big rigs"
228         // the engine does not push the entity!
229
230         float accel, steer, f, myspeed, steerfactor;
231         vector angles_save, rigvel;
232
233         angles_save = self.angles;
234         accel = bound(-1, self.movement_x / self.stat_sv_maxspeed, 1);
235         steer = bound(-1, self.movement_y / self.stat_sv_maxspeed, 1);
236
237         if(g_bugrigs_reverse_speeding)
238         {
239                 if(accel < 0)
240                 {
241                         // back accel is DIGITAL
242                         // to prevent speedhack
243                         if(accel < -0.5)
244                                 accel = -1;
245                         else
246                                 accel = 0;
247                 }
248         }
249
250         self.angles_x = 0;
251         self.angles_z = 0;
252         makevectors(self.angles); // new forward direction!
253
254         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
255         {
256                 float upspeed, accelfactor;
257
258                 myspeed = self.velocity * v_forward;
259                 upspeed = self.velocity * v_up;
260
261                 // responsiveness factor for steering and acceleration
262                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
263                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
264
265                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
266                         steerfactor = -myspeed * g_bugrigs_steer;
267                 else
268                         steerfactor = -myspeed * f * g_bugrigs_steer;
269
270                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
271                         accelfactor = g_bugrigs_accel;
272                 else
273                         accelfactor = f * g_bugrigs_accel;
274                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
275
276                 if(accel < 0)
277                 {
278                         if(myspeed > 0)
279                         {
280                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
281                         }
282                         else
283                         {
284                                 if(!g_bugrigs_reverse_speeding)
285                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
286                         }
287                 }
288                 else
289                 {
290                         if(myspeed >= 0)
291                         {
292                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
293                         }
294                         else
295                         {
296                                 if(g_bugrigs_reverse_stopping)
297                                         myspeed = 0;
298                                 else
299                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
300                         }
301                 }
302                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
303                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
304
305                 self.angles_y += steer * frametime * steerfactor; // apply steering
306                 makevectors(self.angles); // new forward direction!
307
308                 myspeed += accel * accelfactor * frametime;
309
310                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
311         }
312         else
313         {
314                 myspeed = vlen(self.velocity);
315
316                 // responsiveness factor for steering and acceleration
317                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
318                 steerfactor = -myspeed * f;
319                 self.angles_y += steer * frametime * steerfactor; // apply steering
320
321                 rigvel = self.velocity;
322                 makevectors(self.angles); // new forward direction!
323         }
324
325         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
326         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
327         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
328         //MAXIMA: solve(total_acceleration(v) = 0, v);
329
330         if(g_bugrigs_planar_movement)
331         {
332                 vector rigvel_xy, neworigin, up;
333                 float mt;
334
335                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
336                 rigvel_xy = vec2(rigvel);
337
338                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
339                         mt = MOVE_NORMAL;
340                 else
341                         mt = MOVE_NOMONSTERS;
342
343                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
344                 up = trace_endpos - self.origin;
345
346                 // BUG RIGS: align the move to the surface instead of doing collision testing
347                 // can we move?
348                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
349
350                 // align to surface
351                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
352
353                 if(trace_fraction < 0.5)
354                 {
355                         trace_fraction = 1;
356                         neworigin = self.origin;
357                 }
358                 else
359                         neworigin = trace_endpos;
360
361                 if(trace_fraction < 1)
362                 {
363                         // now set angles_x so that the car points parallel to the surface
364                         self.angles = vectoangles(
365                                         '1 0 0' * v_forward_x * trace_plane_normal_z
366                                         +
367                                         '0 1 0' * v_forward_y * trace_plane_normal_z
368                                         +
369                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
370                                         );
371                         self.flags |= FL_ONGROUND;
372                 }
373                 else
374                 {
375                         // now set angles_x so that the car points forward, but is tilted in velocity direction
376                         self.flags &~= FL_ONGROUND;
377                 }
378
379                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
380                 self.movetype = MOVETYPE_NOCLIP;
381         }
382         else
383         {
384                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
385                 self.velocity = rigvel;
386                 self.movetype = MOVETYPE_FLY;
387         }
388
389         trace_fraction = 1;
390         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
391         if(trace_fraction != 1)
392         {
393                 self.angles = vectoangles2(
394                                 '1 0 0' * v_forward_x * trace_plane_normal_z
395                                 +
396                                 '0 1 0' * v_forward_y * trace_plane_normal_z
397                                 +
398                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
399                                 trace_plane_normal
400                                 );
401         }
402         else
403         {
404                 vector vel_local;
405
406                 vel_local_x = v_forward * self.velocity;
407                 vel_local_y = v_right * self.velocity;
408                 vel_local_z = v_up * self.velocity;
409
410                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
411                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
412         }
413
414         // smooth the angles
415         vector vf1, vu1, smoothangles;
416         makevectors(self.angles);
417         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
418         if(f == 0)
419                 f = 1;
420         vf1 = v_forward * f;
421         vu1 = v_up * f;
422         makevectors(angles_save);
423         vf1 = vf1 + v_forward * (1 - f);
424         vu1 = vu1 + v_up * (1 - f);
425         smoothangles = vectoangles2(vf1, vu1);
426         self.angles_x = -smoothangles_x;
427         self.angles_z =  smoothangles_z;
428 }
429
430 float IsMoveInDirection(vector mv, float angle) // key mix factor
431 {
432         if(mv_x == 0 && mv_y == 0)
433                 return 0; // avoid division by zero
434         angle -= RAD2DEG * atan2(mv_y, mv_x);
435         angle = remainder(angle, 360) / 45;
436         if(angle >  1)
437                 return 0;
438         if(angle < -1)
439                 return 0;
440         return 1 - fabs(angle);
441 }
442
443 float GeomLerp(float a, float lerp, float b)
444 {
445         if(a == 0)
446         {
447                 if(lerp < 1)
448                         return 0;
449                 else
450                         return b;
451         }
452         if(b == 0)
453         {
454                 if(lerp > 0)
455                         return 0;
456                 else
457                         return a;
458         }
459         return a * pow(fabs(b / a), lerp);
460 }
461
462 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
463 {
464         float zspeed, xyspeed, dot, k;
465
466 #if 0
467         // this doesn't play well with analog input
468         if(self.movement_x == 0 || self.movement_y != 0)
469                 return; // can't control movement if not moving forward or backward
470         k = 32;
471 #else
472         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
473         if(k <= 0)
474                 return;
475 #endif
476
477         k *= bound(0, wishspeed / autocvar_sv_maxairspeed, 1);
478
479         zspeed = self.velocity_z;
480         self.velocity_z = 0;
481         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
482
483         dot = self.velocity * wishdir;
484
485         if(dot > 0) // we can't change direction while slowing down
486         {
487                 k *= pow(dot, autocvar_sv_aircontrol_power)*frametime;
488                 xyspeed = max(0, xyspeed - autocvar_sv_aircontrol_penalty * sqrt(max(0, 1 - dot*dot)) * k/32);
489                 k *= autocvar_sv_aircontrol;
490                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
491         }
492
493         self.velocity = self.velocity * xyspeed;
494         self.velocity_z = zspeed;
495 }
496
497 float AdjustAirAccelQW(float accelqw, float factor)
498 {
499         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
500 }
501
502 // example config for alternate speed clamping:
503 //   sv_airaccel_qw 0.8
504 //   sv_airaccel_sideways_friction 0
505 //   prvm_globalset server speedclamp_mode 1
506 //     (or 2)
507 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
508 {
509         float vel_straight;
510         float vel_z;
511         vector vel_perpend;
512         float step;
513
514         vector vel_xy;
515         float vel_xy_current;
516         float vel_xy_backward, vel_xy_forward;
517         float speedclamp;
518
519         if(stretchfactor > 0)
520                 speedclamp = stretchfactor;
521         else if(accelqw < 0)
522                 speedclamp = 1; // full clamping, no stretch
523         else
524                 speedclamp = -1; // no clamping
525
526         if(accelqw < 0)
527                 accelqw = -accelqw;
528
529         if(autocvar_sv_gameplayfix_q2airaccelerate)
530                 wishspeed0 = wishspeed;
531
532         vel_straight = self.velocity * wishdir;
533         vel_z = self.velocity_z;
534         vel_xy = vec2(self.velocity);
535         vel_perpend = vel_xy - vel_straight * wishdir;
536
537         step = accel * frametime * wishspeed0;
538
539         vel_xy_current  = vlen(vel_xy);
540         if(speedlimit)
541                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
542         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
543         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
544         if(vel_xy_backward < 0)
545                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
546
547         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
548
549         if(sidefric < 0 && (vel_perpend*vel_perpend))
550                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
551         {
552                 float f, fminimum;
553                 f = max(0, 1 + frametime * wishspeed * sidefric);
554                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
555                 // this cannot be > 1
556                 if(fminimum <= 0)
557                         vel_perpend = vel_perpend * max(0, f);
558                 else
559                 {
560                         fminimum = sqrt(fminimum);
561                         vel_perpend = vel_perpend * max(fminimum, f);
562                 }
563         }
564         else
565                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
566         
567         vel_xy = vel_straight * wishdir + vel_perpend;
568         
569         if(speedclamp >= 0)
570         {
571                 float vel_xy_preclamp;
572                 vel_xy_preclamp = vlen(vel_xy);
573                 if(vel_xy_preclamp > 0) // prevent division by zero
574                 {
575                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
576                         if(vel_xy_current < vel_xy_preclamp)
577                                 vel_xy = vel_xy * (vel_xy_current / vel_xy_preclamp);
578                 }
579         }
580
581         self.velocity = vel_xy + vel_z * '0 0 1';
582 }
583
584 void PM_AirAccelerate(vector wishdir, float wishspeed)
585 {
586         vector curvel, wishvel, acceldir, curdir;
587         float addspeed, accelspeed, curspeed, f;
588         float dot;
589
590         if(wishspeed == 0)
591                 return;
592
593         curvel = self.velocity;
594         curvel_z = 0;
595         curspeed = vlen(curvel);
596
597         if(wishspeed > curspeed * 1.01)
598         {
599                 wishspeed = min(wishspeed, curspeed + autocvar_sv_warsowbunny_airforwardaccel * self.stat_sv_maxspeed * frametime);
600         }
601         else
602         {
603                 f = max(0, (autocvar_sv_warsowbunny_topspeed - curspeed) / (autocvar_sv_warsowbunny_topspeed - self.stat_sv_maxspeed));
604                 wishspeed = max(curspeed, self.stat_sv_maxspeed) + autocvar_sv_warsowbunny_accel * f * self.stat_sv_maxspeed * frametime;
605         }
606         wishvel = wishdir * wishspeed;
607         acceldir = wishvel - curvel;
608         addspeed = vlen(acceldir);
609         acceldir = normalize(acceldir);
610
611         accelspeed = min(addspeed, autocvar_sv_warsowbunny_turnaccel * self.stat_sv_maxspeed * frametime);
612
613         if(autocvar_sv_warsowbunny_backtosideratio < 1)
614         {
615                 curdir = normalize(curvel);
616                 dot = acceldir * curdir;
617                 if(dot < 0)
618                         acceldir = acceldir - (1 - autocvar_sv_warsowbunny_backtosideratio) * dot * curdir;
619         }
620
621         self.velocity += accelspeed * acceldir;
622 }
623
624 .vector movement_old;
625 .float buttons_old;
626 .vector v_angle_old;
627 .string lastclassname;
628
629 .float() PlayerPhysplug;
630
631 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
632 .float specialcommand_pos;
633 void SpecialCommand()
634 {
635 #ifdef TETRIS
636         TetrisImpulse();
637 #else
638         if(!CheatImpulse(99))
639                 print("A hollow voice says \"Plugh\".\n");
640 #endif
641 }
642
643 float speedaward_speed;
644 string speedaward_holder;
645 string speedaward_uid;
646 void race_send_speedaward(float msg)
647 {
648         // send the best speed of the round
649         WriteByte(msg, SVC_TEMPENTITY);
650         WriteByte(msg, TE_CSQC_RACE);
651         WriteByte(msg, RACE_NET_SPEED_AWARD);
652         WriteInt24_t(msg, floor(speedaward_speed+0.5));
653         WriteString(msg, speedaward_holder);
654 }
655
656 float speedaward_alltimebest;
657 string speedaward_alltimebest_holder;
658 string speedaward_alltimebest_uid;
659 void race_send_speedaward_alltimebest(float msg)
660 {
661         // send the best speed
662         WriteByte(msg, SVC_TEMPENTITY);
663         WriteByte(msg, TE_CSQC_RACE);
664         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
665         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
666         WriteString(msg, speedaward_alltimebest_holder);
667 }
668
669 string GetMapname(void);
670 float speedaward_lastupdate;
671 float speedaward_lastsent;
672 void SV_PlayerPhysics()
673 {
674         local vector wishvel, wishdir, v;
675         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
676         string temps;
677         float buttons_prev;
678         float not_allowed_to_move;
679         string c;
680
681         WarpZone_PlayerPhysics_FixVAngle();
682         
683         maxspd_mod = 1;
684         if(g_minstagib && (self.items & IT_INVINCIBLE))
685                 maxspd_mod *= autocvar_g_minstagib_speed_highspeed;
686         if(self.ballcarried)
687                 if(g_nexball)
688                         maxspd_mod *= autocvar_g_nexball_basketball_carrier_highspeed;
689                 else if(g_keepaway)
690                         maxspd_mod *= autocvar_g_keepaway_ballcarrier_highspeed;
691
692         if(g_runematch)
693         {
694                 if(self.runes & RUNE_SPEED)
695                 {
696                         if(self.runes & CURSE_SLOW)
697                                 maxspd_mod *= autocvar_g_balance_rune_speed_combo_highspeed;
698                         else
699                                 maxspd_mod *= autocvar_g_balance_rune_speed_highspeed;
700                 }
701                 else if(self.runes & CURSE_SLOW)
702                 {
703                         maxspd_mod *= autocvar_g_balance_curse_slow_highspeed;
704                 }
705         }
706         maxspd_mod *= autocvar_g_movement_highspeed;
707
708         // fix physics stats for g_movement_highspeed
709         self.stat_sv_airaccel_qw = AdjustAirAccelQW(autocvar_sv_airaccel_qw, maxspd_mod);
710         if(autocvar_sv_airstrafeaccel_qw)
711                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(autocvar_sv_airstrafeaccel_qw, maxspd_mod);
712         else
713                 self.stat_sv_airstrafeaccel_qw = 0;
714         self.stat_sv_airspeedlimit_nonqw = autocvar_sv_airspeedlimit_nonqw * maxspd_mod;
715         self.stat_sv_maxspeed = autocvar_sv_maxspeed * maxspd_mod; // also slow walking
716
717     if(self.PlayerPhysplug)
718         if(self.PlayerPhysplug())
719             return;
720
721         self.race_movetime_frac += frametime;
722         f = floor(self.race_movetime_frac);
723         self.race_movetime_frac -= f;
724         self.race_movetime_count += f;
725         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
726
727         anticheat_physics();
728
729         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
730
731         if(!buttons)
732                 c = "x";
733         else if(buttons == 1)
734                 c = "1";
735         else if(buttons == 2)
736                 c = " ";
737         else if(buttons == 128)
738                 c = "s";
739         else if(buttons == 256)
740                 c = "w";
741         else if(buttons == 512)
742                 c = "a";
743         else if(buttons == 1024)
744                 c = "d";
745         else
746                 c = "?";
747
748         if(c == substring(specialcommand, self.specialcommand_pos, 1))
749         {
750                 self.specialcommand_pos += 1;
751                 if(self.specialcommand_pos >= strlen(specialcommand))
752                 {
753                         self.specialcommand_pos = 0;
754                         SpecialCommand();
755                         return;
756                 }
757         }
758         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
759                 self.specialcommand_pos = 0;
760
761         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
762         {
763                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
764                         self.parm_idlesince = time;
765         }
766         buttons_prev = self.buttons_old;
767         self.buttons_old = buttons;
768         self.movement_old = self.movement;
769         self.v_angle_old = self.v_angle;
770
771         if(time < self.nickspamtime)
772         if(self.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
773         {
774                 // slight annoyance for nick change scripts
775                 self.movement = -1 * self.movement;
776                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
777
778                 if(self.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
779                 {
780                         self.angles_x = random() * 360;
781                         self.angles_y = random() * 360;
782                         // at least I'm not forcing retardedview by also assigning to angles_z
783                         self.fixangle = TRUE;
784                 }
785         }
786
787         if (self.punchangle != '0 0 0')
788         {
789                 f = vlen(self.punchangle) - 10 * frametime;
790                 if (f > 0)
791                         self.punchangle = normalize(self.punchangle) * f;
792                 else
793                         self.punchangle = '0 0 0';
794         }
795
796         if (self.punchvector != '0 0 0')
797         {
798                 f = vlen(self.punchvector) - 30 * frametime;
799                 if (f > 0)
800                         self.punchvector = normalize(self.punchvector) * f;
801                 else
802                         self.punchvector = '0 0 0';
803         }
804
805         if (clienttype(self) == CLIENTTYPE_BOT)
806         {
807                 if(playerdemo_read())
808                         return;
809                 bot_think();
810         }
811         
812         self.items &~= IT_USING_JETPACK;
813
814         if(self.classname == "player")
815         {
816                 if(self.race_penalty)
817                         if(time > self.race_penalty)
818                                 self.race_penalty = 0;
819
820                 not_allowed_to_move = 0;
821                 if(self.race_penalty)
822                         not_allowed_to_move = 1;
823                 if(!autocvar_sv_ready_restart_after_countdown)
824                 if(time < game_starttime)
825                         not_allowed_to_move = 1;
826
827                 if(not_allowed_to_move)
828                 {
829                         self.velocity = '0 0 0';
830                         self.movetype = MOVETYPE_NONE;
831                         self.disableclientprediction = 2;
832                 }
833                 else if(self.disableclientprediction == 2)
834                 {
835                         if(self.movetype == MOVETYPE_NONE)
836                                 self.movetype = MOVETYPE_WALK;
837                         self.disableclientprediction = 0;
838                 }
839         }
840
841         if (self.movetype == MOVETYPE_NONE)
842                 return;
843
844         // when we get here, disableclientprediction cannot be 2
845         self.disableclientprediction = 0;
846         if(time < self.ladder_time)
847                 self.disableclientprediction = 1;
848
849         MUTATOR_CALLHOOK(PlayerPhysics);
850
851         maxspd_mod = 1;
852
853         swampspd_mod = 1;
854         if(self.in_swamp) {
855                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
856         }
857
858         if(self.classname != "player")
859         {
860                 maxspd_mod = autocvar_sv_spectator_speed_multiplier;
861                 if(!self.spectatorspeed)
862                         self.spectatorspeed = maxspd_mod;
863                 if(self.impulse && self.impulse <= 19)
864                 {
865                         if(self.lastclassname != "player")
866                         {
867                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
868                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
869                                 else if(self.impulse == 11)
870                                         self.spectatorspeed = maxspd_mod;
871                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
872                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
873                                 else if(self.impulse >= 1 && self.impulse <= 9)
874                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
875                         } // otherwise just clear
876                         self.impulse = 0;
877                 }
878                 maxspd_mod = self.spectatorspeed;
879         }
880
881         spd = max(self.stat_sv_maxspeed, autocvar_sv_maxairspeed) * maxspd_mod * swampspd_mod;
882         if(self.speed != spd)
883         {
884                 self.speed = spd;
885                 temps = ftos(spd);
886                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
887                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
888                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
889                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
890         }
891
892         maxspd_mod *= swampspd_mod; // only one common speed modder please!
893         swampspd_mod = 1;
894
895         // if dead, behave differently
896         if (self.deadflag)
897                 goto end;
898
899         if (!self.fixangle && !g_bugrigs)
900         {
901                 self.angles_x = 0;
902                 self.angles_y = self.v_angle_y;
903                 self.angles_z = 0;
904         }
905
906         if(self.flags & FL_ONGROUND)
907         if(self.wasFlying)
908         {
909                 self.wasFlying = 0;
910
911                 if(self.waterlevel < WATERLEVEL_SWIMMING)
912                 if(time >= self.ladder_time)
913                 if not(self.hook)
914                 {
915                         self.nextstep = time + 0.3 + random() * 0.1;
916                         trace_dphitq3surfaceflags = 0;
917                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
918                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
919                         {
920                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
921                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
922                                 else
923                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
924                         }
925                 }
926         }
927
928         if(IsFlying(self))
929                 self.wasFlying = 1;
930
931         if(self.classname == "player")
932         {
933                 if(self.flags & FL_ONGROUND)
934                 {
935                         if (autocvar_g_multijump > 0)
936                                 self.multijump_count = 0;
937                         else
938                                 self.multijump_count = -2; // the cvar value for infinite jumps is -1, so this needs to be smaller
939                 }
940
941                 if (self.BUTTON_JUMP)
942                         PlayerJump ();
943                 else
944                         self.flags |= FL_JUMPRELEASED;
945
946                 if (self.waterlevel == WATERLEVEL_SWIMMING)
947                         CheckWaterJump ();
948                 self.prevjumpbutton = self.BUTTON_JUMP;
949         }
950
951         if (self.flags & FL_WATERJUMP )
952         {
953                 self.velocity_x = self.movedir_x;
954                 self.velocity_y = self.movedir_y;
955                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
956                 {
957                         self.flags &~= FL_WATERJUMP;
958                         self.teleport_time = 0;
959                 }
960         }
961         else if (g_bugrigs && self.classname == "player")
962         {
963                 RaceCarPhysics();
964         }
965         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
966         {
967                 // noclipping or flying
968                 self.flags &~= FL_ONGROUND;
969
970                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
971                 makevectors(self.v_angle);
972                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
973                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
974                 // acceleration
975                 wishdir = normalize(wishvel);
976                 wishspeed = vlen(wishvel);
977                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
978                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
979                 if (time >= self.teleport_time)
980                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
981         }
982         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
983         {
984                 // swimming
985                 self.flags &~= FL_ONGROUND;
986
987                 makevectors(self.v_angle);
988                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
989                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
990                 if (wishvel == '0 0 0')
991                         wishvel = '0 0 -60'; // drift towards bottom
992
993                 wishdir = normalize(wishvel);
994                 wishspeed = vlen(wishvel);
995                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
996                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
997                 wishspeed = wishspeed * 0.7;
998
999                 // water friction
1000                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
1001
1002                 // water acceleration
1003                 PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1004         }
1005         else if (time < self.ladder_time)
1006         {
1007                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
1008                 self.flags &~= FL_ONGROUND;
1009
1010                 float g;
1011                 g = autocvar_sv_gravity * frametime;
1012                 if(self.gravity)
1013                         g *= self.gravity;
1014                 if(autocvar_sv_gameplayfix_gravityunaffectedbyticrate)
1015                 {
1016                         g *= 0.5;
1017                         self.velocity_z += g;
1018                 }
1019
1020                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
1021                 makevectors(self.v_angle);
1022                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1023                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
1024                 self.velocity_z += g;
1025                 if (self.ladder_entity.classname == "func_water")
1026                 {
1027                         f = vlen(wishvel);
1028                         if (f > self.ladder_entity.speed)
1029                                 wishvel = wishvel * (self.ladder_entity.speed / f);
1030
1031                         self.watertype = self.ladder_entity.skin;
1032                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
1033                         if ((self.origin_z + self.view_ofs_z) < f)
1034                                 self.waterlevel = WATERLEVEL_SUBMERGED;
1035                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
1036                                 self.waterlevel = WATERLEVEL_SWIMMING;
1037                         else if ((self.origin_z + self.mins_z + 1) < f)
1038                                 self.waterlevel = WATERLEVEL_WETFEET;
1039                         else
1040                         {
1041                                 self.waterlevel = WATERLEVEL_NONE;
1042                                 self.watertype = CONTENT_EMPTY;
1043                         }
1044                 }
1045                 // acceleration
1046                 wishdir = normalize(wishvel);
1047                 wishspeed = vlen(wishvel);
1048                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1049                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1050                 if (time >= self.teleport_time)
1051                 {
1052                         // water acceleration
1053                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1054                 }
1055         }
1056         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!autocvar_g_jetpack_fuel || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
1057         {
1058                 //makevectors(self.v_angle_y * '0 1 0');
1059                 makevectors(self.v_angle);
1060                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1061                 // add remaining speed as Z component
1062                 maxairspd = autocvar_sv_maxairspeed*max(1, maxspd_mod);
1063                 // fix speedhacks :P
1064                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
1065                 // add the unused velocity as up component
1066                 wishvel_z = 0;
1067
1068                 // if(self.BUTTON_JUMP)
1069                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1070
1071                 // it is now normalized, so...
1072                 float a_side, a_up, a_add, a_diff;
1073                 a_side = autocvar_g_jetpack_acceleration_side;
1074                 a_up = autocvar_g_jetpack_acceleration_up;
1075                 a_add = autocvar_g_jetpack_antigravity * autocvar_sv_gravity;
1076
1077                 wishvel_x *= a_side;
1078                 wishvel_y *= a_side;
1079                 wishvel_z *= a_up;
1080                 wishvel_z += a_add;
1081
1082                 float best;
1083                 best = 0;
1084                 //////////////////////////////////////////////////////////////////////////////////////
1085                 // finding the maximum over all vectors of above form
1086                 // with wishvel having an absolute value of 1
1087                 //////////////////////////////////////////////////////////////////////////////////////
1088                 // we're finding the maximum over
1089                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1090                 // for z in the range from -1 to 1
1091                 //////////////////////////////////////////////////////////////////////////////////////
1092                 // maximum is EITHER attained at the single extreme point:
1093                 a_diff = a_side * a_side - a_up * a_up;
1094                 if(a_diff != 0)
1095                 {
1096                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1097                         if(f > -1 && f < 1) // can it be attained?
1098                         {
1099                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1100                                 //print("middle\n");
1101                         }
1102                 }
1103                 // OR attained at z = 1:
1104                 f = (a_up + a_add) * (a_up + a_add);
1105                 if(f > best)
1106                 {
1107                         best = f;
1108                         //print("top\n");
1109                 }
1110                 // OR attained at z = -1:
1111                 f = (a_up - a_add) * (a_up - a_add);
1112                 if(f > best)
1113                 {
1114                         best = f;
1115                         //print("bottom\n");
1116                 }
1117                 best = sqrt(best);
1118                 //////////////////////////////////////////////////////////////////////////////////////
1119
1120                 //print("best possible acceleration: ", ftos(best), "\n");
1121
1122                 float fxy, fz;
1123                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / autocvar_g_jetpack_maxspeed_side, 1);
1124                 if(wishvel_z - autocvar_sv_gravity > 0)
1125                         fz = bound(0, 1 - self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1126                 else
1127                         fz = bound(0, 1 + self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1128
1129                 float fvel;
1130                 fvel = vlen(wishvel);
1131                 wishvel_x *= fxy;
1132                 wishvel_y *= fxy;
1133                 wishvel_z = (wishvel_z - autocvar_sv_gravity) * fz + autocvar_sv_gravity;
1134
1135                 fvel = min(1, vlen(wishvel) / best);
1136                 if(autocvar_g_jetpack_fuel && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1137                         f = min(1, self.ammo_fuel / (autocvar_g_jetpack_fuel * frametime * fvel));
1138                 else
1139                         f = 1;
1140
1141                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1142
1143                 if (f > 0 && wishvel != '0 0 0')
1144                 {
1145                         self.velocity = self.velocity + wishvel * f * frametime;
1146                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1147                                 self.ammo_fuel -= autocvar_g_jetpack_fuel * frametime * fvel * f;
1148                         self.flags &~= FL_ONGROUND;
1149                         self.items |= IT_USING_JETPACK;
1150
1151                         // jetpack also inhibits health regeneration, but only for 1 second
1152                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1153                 }
1154         }
1155         else if (self.flags & FL_ONGROUND)
1156         {
1157                 // we get here if we ran out of ammo
1158                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1159                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1160
1161                 // walking
1162                 makevectors(self.v_angle_y * '0 1 0');
1163                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1164
1165                 if(!(self.lastflags & FL_ONGROUND))
1166                 {
1167                         if(autocvar_speedmeter)
1168                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1169                         if(self.lastground < time - 0.3)
1170                                 self.velocity = self.velocity * (1 - autocvar_sv_friction_on_land);
1171                         if(self.jumppadcount > 1)
1172                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1173                         self.jumppadcount = 0;
1174                 }
1175
1176 #ifdef LETS_TEST_FTEQCC
1177                 if(self.velocity_x || self.velocity_y)
1178                 {
1179                         // good
1180                 }
1181                 else
1182                 {
1183                         if(self.velocity_x)
1184                                 checkclient();
1185                         if(self.velocity_y)
1186                                 checkclient();
1187                 }
1188 #endif
1189
1190                 v = self.velocity;
1191                 v_z = 0;
1192                 f = vlen(v);
1193                 if(f > 0)
1194                 {
1195                         if (f < autocvar_sv_stopspeed)
1196                                 f = 1 - frametime * (autocvar_sv_stopspeed / f) * autocvar_sv_friction;
1197                         else
1198                                 f = 1 - frametime * autocvar_sv_friction;
1199                         if (f > 0)
1200                                 self.velocity = self.velocity * f;
1201                         else
1202                                 self.velocity = '0 0 0';
1203                 }
1204
1205                 // acceleration
1206                 wishdir = normalize(wishvel);
1207                 wishspeed = vlen(wishvel);
1208                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1209                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1210                 if (self.crouch)
1211                         wishspeed = wishspeed * 0.5;
1212                 if (time >= self.teleport_time)
1213                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1214         }
1215         else
1216         {
1217                 float wishspeed0;
1218                 // we get here if we ran out of ammo
1219                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1220                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1221
1222                 if(maxspd_mod < 1)
1223                 {
1224                         maxairspd = autocvar_sv_maxairspeed*maxspd_mod;
1225                         airaccel = autocvar_sv_airaccelerate*maxspd_mod;
1226                 }
1227                 else
1228                 {
1229                         maxairspd = autocvar_sv_maxairspeed;
1230                         airaccel = autocvar_sv_airaccelerate;
1231                 }
1232                 // airborn
1233                 makevectors(self.v_angle_y * '0 1 0');
1234                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1235                 // acceleration
1236                 wishdir = normalize(wishvel);
1237                 wishspeed = wishspeed0 = vlen(wishvel);
1238                 if (wishspeed0 > self.stat_sv_maxspeed*maxspd_mod)
1239                         wishspeed0 = self.stat_sv_maxspeed*maxspd_mod;
1240                 if (wishspeed > maxairspd)
1241                         wishspeed = maxairspd;
1242                 if (self.crouch)
1243                         wishspeed = wishspeed * 0.5;
1244                 if (time >= self.teleport_time)
1245                 {
1246                         float accelerating;
1247                         float wishspeed2;
1248                         float airaccelqw;
1249                         float strafity;
1250
1251                         airaccelqw = self.stat_sv_airaccel_qw;
1252                         accelerating = (self.velocity * wishdir > 0);
1253                         wishspeed2 = wishspeed;
1254
1255                         // CPM
1256                         if(autocvar_sv_airstopaccelerate)
1257                         {
1258                                 vector curdir;
1259                                 curdir = self.velocity;
1260                                 curdir_z = 0;
1261                                 curdir = normalize(curdir);
1262                                 airaccel = airaccel + (autocvar_sv_airstopaccelerate*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1263                         }
1264                         // note that for straight forward jumping:
1265                         // step = accel * frametime * wishspeed0;
1266                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1267                         // -->
1268                         // dv/dt = accel * maxspeed (when slow)
1269                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1270                         // log dv/dt = logaccel + logmaxspeed (when slow)
1271                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1272                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1273                         if(autocvar_sv_maxairstrafespeed)
1274                                 wishspeed = min(wishspeed, GeomLerp(autocvar_sv_maxairspeed*maxspd_mod, strafity, autocvar_sv_maxairstrafespeed*maxspd_mod));
1275                         if(autocvar_sv_airstrafeaccelerate)
1276                                 airaccel = GeomLerp(airaccel, strafity, autocvar_sv_airstrafeaccelerate*maxspd_mod);
1277                         if(self.stat_sv_airstrafeaccel_qw)
1278                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1279                         // !CPM
1280
1281                         if(autocvar_sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1282                                 PM_AirAccelerate(wishdir, wishspeed);
1283                         else
1284                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, autocvar_sv_airaccel_qw_stretchfactor, autocvar_sv_airaccel_sideways_friction / maxairspd, self.stat_sv_airspeedlimit_nonqw);
1285
1286                         if(autocvar_sv_aircontrol)
1287                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1288                 }
1289         }
1290
1291         if((g_cts || g_race) && self.classname != "observer") {
1292                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1293                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1294                         speedaward_holder = self.netname;
1295                         speedaward_uid = self.crypto_idfp;
1296                         speedaward_lastupdate = time;
1297                 }
1298                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1299                         string rr;
1300                         if(g_cts)
1301                                 rr = CTS_RECORD;
1302                         else
1303                                 rr = RACE_RECORD;
1304                         race_send_speedaward(MSG_ALL);
1305                         speedaward_lastsent = speedaward_speed;
1306                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "") {
1307                                 speedaward_alltimebest = speedaward_speed;
1308                                 speedaward_alltimebest_holder = speedaward_holder;
1309                                 speedaward_alltimebest_uid = speedaward_uid;
1310                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1311                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
1312                                 race_send_speedaward_alltimebest(MSG_ALL);
1313                         }
1314                 }
1315         }
1316
1317         float xyspeed;
1318         xyspeed = vlen('1 0 0' * self.velocity_x + '0 1 0' * self.velocity_y);
1319         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge && autocvar_g_balance_nex_charge_velocity_rate && xyspeed > autocvar_g_balance_nex_charge_minspeed)
1320         {
1321                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1322                 xyspeed = min(xyspeed, autocvar_g_balance_nex_charge_maxspeed);
1323                 f = (xyspeed - autocvar_g_balance_nex_charge_minspeed) / (autocvar_g_balance_nex_charge_maxspeed - autocvar_g_balance_nex_charge_minspeed);
1324                 // add the extra charge
1325                 self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_velocity_rate * f * frametime);
1326         }
1327 :end
1328         if(self.flags & FL_ONGROUND)
1329                 self.lastground = time;
1330
1331         self.lastflags = self.flags;
1332         self.lastclassname = self.classname;
1333 };