qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 float sv_accelerate;
   5 float sv_friction;
   6 float sv_maxspeed;
   7 float sv_airaccelerate;
   8 float sv_maxairspeed;
   9 float sv_stopspeed;
  10 float sv_gravity;
  11 float sv_airaccel_sideways_friction;
  12 float sv_airaccel_qw;
  13 float sv_airstopaccelerate;
  14 float sv_airstrafeaccelerate;
  15 float sv_maxairstrafespeed;
  16 float sv_airstrafeaccel_qw;
  17 float sv_aircontrol;
  18 float sv_aircontrol_power;
  19 float sv_aircontrol_penalty;
  20 float sv_warsowbunny_airforwardaccel;
  21 float sv_warsowbunny_accel;
  22 float sv_warsowbunny_topspeed;
  23 float sv_warsowbunny_turnaccel;
  24 float sv_warsowbunny_backtosideratio;
  25 float sv_airspeedlimit_nonqw;
  26
  27 .float ladder_time;
  28 .entity ladder_entity;
  29 .float gravity;
  30 .float swamp_slowdown;
  31 .float lastflags;
  32 .float lastground;
  33 .float wasFlying;
  34 .float spectatorspeed;
  35
  36 .float multijump_count;
  37 .float multijump_ready;
  38 .float prevjumpbutton;
  39
  40 /*
  41 =============
  42 PlayerJump
  43
  44 When you press the jump key
  45 =============
  46 */
  47 void PlayerJump (void)
  48 {
  49         float mjumpheight;
  50         float doublejump;
  51
  52         doublejump = FALSE;
  53         if (sv_doublejump)
  54         {
  55                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
  56                 if (trace_fraction < 1 && trace_plane_normal_z > 0.7)
  57                         doublejump = TRUE;
  58         }
  59
  60         mjumpheight = cvar("sv_jumpvelocity");
  61         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  62         {
  63                 if (self.watertype == CONTENT_WATER)
  64                         self.velocity_z = 200;
  65                 else if (self.watertype == CONTENT_SLIME)
  66                         self.velocity_z = 80;
  67                 else
  68                         self.velocity_z = 50;
  69
  70                 return;
  71         }
  72
  73         if (cvar("g_multijump"))
  74         {
  75                 if (self.prevjumpbutton == FALSE && !(self.flags & FL_ONGROUND)) // jump button pressed this frame and we are in midair
  76                         self.multijump_ready = TRUE;  // this is necessary to check that we released the jump button and pressed it again
  77                 else
  78                         self.multijump_ready = FALSE;
  79         }
  80
  81         if(!doublejump && self.multijump_ready && self.multijump_count < cvar("g_multijump") && self.velocity_z > cvar("g_multijump_speed"))
  82         {
  83                 // doublejump = FALSE; // checked above in the if
  84                 if (cvar("g_multijump") > 0)
  85                 {
  86                         if (cvar("g_multijump_add") == 0) // in this case we make the z velocity == jumpvelocity
  87                         {
  88                                 if (self.velocity_z < mjumpheight)
  89                                 {
  90                                         doublejump = TRUE;
  91                                         self.velocity_z = 0;
  92                                 }
  93                         }
  94                         else
  95                                 doublejump = TRUE;
  96
  97                         if(doublejump)
  98                         {
  99                                 if(self.movement_x != 0 || self.movement_y != 0) // don't remove all speed if player isnt pressing any movement keys
 100                                 {
 101                                         float curspeed;
 102                                         vector wishvel, wishdir;
 103
 104                                         curspeed = max(
 105                                                 vlen(vec2(self.velocity)), // current xy speed
 106                                                 vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
 107                                         );
 108                                         makevectors(self.v_angle_y * '0 1 0');
 109                                         wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 110                                         wishdir = normalize(wishvel);
 111
 112                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
 113                                         self.velocity_y = wishdir_y * curspeed;
 114                                         // keep velocity_z unchanged!
 115                                 }
 116                                 self.multijump_count += 1;
 117                         }
 118                 }
 119                 self.multijump_ready = FALSE; // require releasing and pressing the jump button again for the next jump
 120         }
 121
 122         if (!doublejump)
 123                 if (!(self.flags & FL_ONGROUND))
 124                         return;
 125
 126         if(!sv_pogostick)
 127                 if (!(self.flags & FL_JUMPRELEASED))
 128                         return;
 129
 130         if(self.health <= g_bloodloss)
 131                 return;
 132
 133         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 134         // velocity bounds.  Final velocity is bound between (jumpheight *
 135         // min + jumpheight) and (jumpheight * max + jumpheight);
 136
 137         if(cvar_string("sv_jumpspeedcap_min") != "")
 138         {
 139                 float minjumpspeed;
 140
 141                 minjumpspeed = mjumpheight * cvar("sv_jumpspeedcap_min");
 142
 143                 if (self.velocity_z < minjumpspeed)
 144                         mjumpheight += minjumpspeed - self.velocity_z;
 145         }
 146
 147         if(cvar_string("sv_jumpspeedcap_max") != "")
 148         {
 149                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 150                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 151
 152                 if(!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && cvar("sv_jumpspeedcap_max_disable_on_ramps")))
 153                 {
 154                         float maxjumpspeed;
 155
 156                         maxjumpspeed = mjumpheight * cvar("sv_jumpspeedcap_max");
 157
 158                         if (self.velocity_z > maxjumpspeed)
 159                                 mjumpheight -= self.velocity_z - maxjumpspeed;
 160                 }
 161         }
 162
 163         if(!(self.lastflags & FL_ONGROUND))
 164         {
 165                 if(cvar("speedmeter"))
 166                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 167                 if(self.lastground < time - 0.3)
 168                 {
 169                         self.velocity_x *= (1 - cvar("sv_friction_on_land"));
 170                         self.velocity_y *= (1 - cvar("sv_friction_on_land"));
 171                 }
 172                 if(self.jumppadcount > 1)
 173                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 174                 self.jumppadcount = 0;
 175         }
 176
 177         self.velocity_z = self.velocity_z + mjumpheight;
 178         self.oldvelocity_z = self.velocity_z;
 179
 180         self.flags &~= FL_ONGROUND;
 181         self.flags &~= FL_JUMPRELEASED;
 182
 183         if (self.crouch)
 184                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 185         else
 186                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 187
 188         if(g_jump_grunt)
 189                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 190
 191         self.restart_jump = -1; // restart jump anim next time
 192         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 193 }
 194
 195 void CheckWaterJump()
 196 {
 197         local vector start, end;
 198
 199 // check for a jump-out-of-water
 200         makevectors (self.angles);
 201         start = self.origin;
 202         start_z = start_z + 8;
 203         v_forward_z = 0;
 204         normalize(v_forward);
 205         end = start + v_forward*24;
 206         traceline (start, end, TRUE, self);
 207         if (trace_fraction < 1)
 208         {       // solid at waist
 209                 start_z = start_z + self.maxs_z - 8;
 210                 end = start + v_forward*24;
 211                 self.movedir = trace_plane_normal * -50;
 212                 traceline (start, end, TRUE, self);
 213                 if (trace_fraction == 1)
 214                 {       // open at eye level
 215                         self.flags |= FL_WATERJUMP;
 216                         self.velocity_z = 225;
 217                         self.flags &~= FL_JUMPRELEASED;
 218                         self.teleport_time = time + 2;  // safety net
 219                         return;
 220                 }
 221         }
 222 };
 223
 224 float racecar_angle(float forward, float down)
 225 {
 226         float ret, angle_mult;
 227
 228         if(forward < 0)
 229         {
 230                 forward = -forward;
 231                 down = -down;
 232         }
 233
 234         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 235
 236         angle_mult = forward / (800 + forward);
 237
 238         if(ret > 180)
 239                 return ret * angle_mult + 360 * (1 - angle_mult);
 240         else
 241                 return ret * angle_mult;
 242 }
 243
 244 void RaceCarPhysics()
 245 {
 246         // using this move type for "big rigs"
 247         // the engine does not push the entity!
 248
 249         float accel, steer, f, myspeed, steerfactor;
 250         vector angles_save, rigvel;
 251
 252         angles_save = self.angles;
 253         accel = bound(-1, self.movement_x / self.stat_sv_maxspeed, 1);
 254         steer = bound(-1, self.movement_y / self.stat_sv_maxspeed, 1);
 255
 256         if(g_bugrigs_reverse_speeding)
 257         {
 258                 if(accel < 0)
 259                 {
 260                         // back accel is DIGITAL
 261                         // to prevent speedhack
 262                         if(accel < -0.5)
 263                                 accel = -1;
 264                         else
 265                                 accel = 0;
 266                 }
 267         }
 268
 269         self.angles_x = 0;
 270         self.angles_z = 0;
 271         makevectors(self.angles); // new forward direction!
 272
 273         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 274         {
 275                 float upspeed, accelfactor;
 276
 277                 myspeed = self.velocity * v_forward;
 278                 upspeed = self.velocity * v_up;
 279
 280                 // responsiveness factor for steering and acceleration
 281                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 282                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 283
 284                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 285                         steerfactor = -myspeed * g_bugrigs_steer;
 286                 else
 287                         steerfactor = -myspeed * f * g_bugrigs_steer;
 288
 289                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 290                         accelfactor = g_bugrigs_accel;
 291                 else
 292                         accelfactor = f * g_bugrigs_accel;
 293                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 294
 295                 if(accel < 0)
 296                 {
 297                         if(myspeed > 0)
 298                         {
 299                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 300                         }
 301                         else
 302                         {
 303                                 if(!g_bugrigs_reverse_speeding)
 304                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 305                         }
 306                 }
 307                 else
 308                 {
 309                         if(myspeed >= 0)
 310                         {
 311                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 312                         }
 313                         else
 314                         {
 315                                 if(g_bugrigs_reverse_stopping)
 316                                         myspeed = 0;
 317                                 else
 318                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 319                         }
 320                 }
 321                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 322                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 323
 324                 self.angles_y += steer * frametime * steerfactor; // apply steering
 325                 makevectors(self.angles); // new forward direction!
 326
 327                 myspeed += accel * accelfactor * frametime;
 328
 329                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 330         }
 331         else
 332         {
 333                 myspeed = vlen(self.velocity);
 334
 335                 // responsiveness factor for steering and acceleration
 336                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 337                 steerfactor = -myspeed * f;
 338                 self.angles_y += steer * frametime * steerfactor; // apply steering
 339
 340                 rigvel = self.velocity;
 341                 makevectors(self.angles); // new forward direction!
 342         }
 343
 344         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 345         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 346         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 347         //MAXIMA: solve(total_acceleration(v) = 0, v);
 348
 349         if(g_bugrigs_planar_movement)
 350         {
 351                 vector rigvel_xy, neworigin, up;
 352                 float mt;
 353
 354                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 355                 rigvel_xy = vec2(rigvel);
 356
 357                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 358                         mt = MOVE_NORMAL;
 359                 else
 360                         mt = MOVE_NOMONSTERS;
 361
 362                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 363                 up = trace_endpos - self.origin;
 364
 365                 // BUG RIGS: align the move to the surface instead of doing collision testing
 366                 // can we move?
 367                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 368
 369                 // align to surface
 370                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 371
 372                 if(trace_fraction < 0.5)
 373                 {
 374                         trace_fraction = 1;
 375                         neworigin = self.origin;
 376                 }
 377                 else
 378                         neworigin = trace_endpos;
 379
 380                 if(trace_fraction < 1)
 381                 {
 382                         // now set angles_x so that the car points parallel to the surface
 383                         self.angles = vectoangles(
 384                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 385                                         +
 386                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 387                                         +
 388                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 389                                         );
 390                         self.flags |= FL_ONGROUND;
 391                 }
 392                 else
 393                 {
 394                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 395                         self.flags &~= FL_ONGROUND;
 396                 }
 397
 398                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 399                 self.movetype = MOVETYPE_NOCLIP;
 400         }
 401         else
 402         {
 403                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 404                 self.velocity = rigvel;
 405                 self.movetype = MOVETYPE_FLY;
 406         }
 407
 408         trace_fraction = 1;
 409         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 410         if(trace_fraction != 1)
 411         {
 412                 self.angles = vectoangles2(
 413                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 414                                 +
 415                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 416                                 +
 417                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 418                                 trace_plane_normal
 419                                 );
 420         }
 421         else
 422         {
 423                 vector vel_local;
 424
 425                 vel_local_x = v_forward * self.velocity;
 426                 vel_local_y = v_right * self.velocity;
 427                 vel_local_z = v_up * self.velocity;
 428
 429                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 430                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 431         }
 432
 433         // smooth the angles
 434         vector vf1, vu1, smoothangles;
 435         makevectors(self.angles);
 436         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 437         if(f == 0)
 438                 f = 1;
 439         vf1 = v_forward * f;
 440         vu1 = v_up * f;
 441         makevectors(angles_save);
 442         vf1 = vf1 + v_forward * (1 - f);
 443         vu1 = vu1 + v_up * (1 - f);
 444         smoothangles = vectoangles2(vf1, vu1);
 445         self.angles_x = -smoothangles_x;
 446         self.angles_z =  smoothangles_z;
 447 }
 448
 449 float IsMoveInDirection(vector mv, float angle) // key mix factor
 450 {
 451         if(mv_x == 0 && mv_y == 0)
 452                 return 0; // avoid division by zero
 453         angle -= RAD2DEG * atan2(mv_y, mv_x);
 454         angle = remainder(angle, 360) / 45;
 455         if(angle >  1)
 456                 return 0;
 457         if(angle < -1)
 458                 return 0;
 459         return 1 - fabs(angle);
 460 }
 461
 462 float GeomLerp(float a, float lerp, float b)
 463 {
 464         if(a == 0)
 465         {
 466                 if(lerp < 1)
 467                         return 0;
 468                 else
 469                         return b;
 470         }
 471         if(b == 0)
 472         {
 473                 if(lerp > 0)
 474                         return 0;
 475                 else
 476                         return a;
 477         }
 478         return a * pow(fabs(b / a), lerp);
 479 }
 480
 481 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 482 {
 483         float zspeed, xyspeed, dot, k;
 484
 485 #if 0
 486         // this doesn't play well with analog input
 487         if(self.movement_x == 0 || self.movement_y != 0)
 488                 return; // can't control movement if not moving forward or backward
 489         k = 32;
 490 #else
 491         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 492         if(k <= 0)
 493                 return;
 494 #endif
 495
 496         k *= bound(0, wishspeed / sv_maxairspeed, 1);
 497
 498         zspeed = self.velocity_z;
 499         self.velocity_z = 0;
 500         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 501
 502         dot = self.velocity * wishdir;
 503
 504         if(dot > 0) // we can't change direction while slowing down
 505         {
 506                 k *= pow(dot, sv_aircontrol_power)*frametime;
 507                 xyspeed = max(0, xyspeed - sv_aircontrol_penalty * sqrt(max(0, 1 - dot*dot)) * k/32);
 508                 k *= sv_aircontrol;
 509                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 510         }
 511
 512         self.velocity = self.velocity * xyspeed;
 513         self.velocity_z = zspeed;
 514 }
 515
 516 float AdjustAirAccelQW(float accelqw, float factor)
 517 {
 518         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 519 }
 520
 521 // example config for alternate speed clamping:
 522 //   sv_airaccel_qw 0.8
 523 //   sv_airaccel_sideways_friction 0
 524 //   prvm_globalset server speedclamp_mode 1
 525 //     (or 2)
 526 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float sidefric, float speedlimit)
 527 {
 528         float vel_straight;
 529         float vel_z;
 530         vector vel_perpend;
 531         float step;
 532
 533         vector vel_xy;
 534         float vel_xy_current;
 535         float vel_xy_backward, vel_xy_forward;
 536         float speedclamp;
 537
 538         speedclamp = (accelqw < 0);
 539         if(speedclamp)
 540                 accelqw = -accelqw;
 541
 542         if(cvar("sv_gameplayfix_q2airaccelerate"))
 543                 wishspeed0 = wishspeed;
 544
 545         vel_straight = self.velocity * wishdir;
 546         vel_z = self.velocity_z;
 547         vel_xy = vec2(self.velocity);
 548         vel_perpend = vel_xy - vel_straight * wishdir;
 549
 550         step = accel * frametime * wishspeed0;
 551
 552         vel_xy_current  = vlen(vel_xy);
 553         if(speedlimit)
 554                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 555         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 556         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 557         if(vel_xy_backward < 0)
 558                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 559
 560         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 561
 562         if(sidefric < 0 && (vel_perpend*vel_perpend))
 563                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 564         {
 565                 float f, fminimum;
 566                 f = max(0, 1 + frametime * wishspeed * sidefric);
 567                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 568                 // this cannot be > 1
 569                 if(fminimum <= 0)
 570                         vel_perpend = vel_perpend * max(0, f);
 571                 else
 572                 {
 573                         fminimum = sqrt(fminimum);
 574                         vel_perpend = vel_perpend * max(fminimum, f);
 575                 }
 576         }
 577         else
 578                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
 579
 580         vel_xy = vel_straight * wishdir + vel_perpend;
 581
 582         if(speedclamp)
 583         {
 584                 // ensure we don't get too fast or decelerate faster than we should
 585                 vel_xy_current = min(vlen(vel_xy), vel_xy_forward);
 586                 if(vel_xy_current > 0) // prevent division by zero
 587                         vel_xy = normalize(vel_xy) * vel_xy_current;
 588         }
 589
 590         self.velocity = vel_xy + vel_z * '0 0 1';
 591 }
 592
 593 void PM_AirAccelerate(vector wishdir, float wishspeed)
 594 {
 595         vector curvel, wishvel, acceldir, curdir;
 596         float addspeed, accelspeed, curspeed, f;
 597         float dot;
 598
 599         if(wishspeed == 0)
 600                 return;
 601
 602         curvel = self.velocity;
 603         curvel_z = 0;
 604         curspeed = vlen(curvel);
 605
 606         if(wishspeed > curspeed * 1.01)
 607         {
 608                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * self.stat_sv_maxspeed * frametime);
 609         }
 610         else
 611         {
 612                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - self.stat_sv_maxspeed));
 613                 wishspeed = max(curspeed, self.stat_sv_maxspeed) + sv_warsowbunny_accel * f * self.stat_sv_maxspeed * frametime;
 614         }
 615         wishvel = wishdir * wishspeed;
 616         acceldir = wishvel - curvel;
 617         addspeed = vlen(acceldir);
 618         acceldir = normalize(acceldir);
 619
 620         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * self.stat_sv_maxspeed * frametime);
 621
 622         if(sv_warsowbunny_backtosideratio < 1)
 623         {
 624                 curdir = normalize(curvel);
 625                 dot = acceldir * curdir;
 626                 if(dot < 0)
 627                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 628         }
 629
 630         self.velocity += accelspeed * acceldir;
 631 }
 632
 633 .vector movement_old;
 634 .float buttons_old;
 635 .vector v_angle_old;
 636 .string lastclassname;
 637
 638 .float() PlayerPhysplug;
 639
 640 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 641 .float specialcommand_pos;
 642 void SpecialCommand()
 643 {
 644 #ifdef TETRIS
 645         TetrisImpulse();
 646 #else
 647         if(!CheatImpulse(99))
 648                 print("A hollow voice says \"Plugh\".\n");
 649 #endif
 650 }
 651
 652 float speedaward_speed;
 653 string speedaward_holder;
 654 string speedaward_uid;
 655 void race_send_speedaward(float msg)
 656 {
 657         // send the best speed of the round
 658         WriteByte(msg, SVC_TEMPENTITY);
 659         WriteByte(msg, TE_CSQC_RACE);
 660         WriteByte(msg, RACE_NET_SPEED_AWARD);
 661         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 662         WriteString(msg, speedaward_holder);
 663 }
 664
 665 float speedaward_alltimebest;
 666 string speedaward_alltimebest_holder;
 667 string speedaward_alltimebest_uid;
 668 void race_send_speedaward_alltimebest(float msg)
 669 {
 670         // send the best speed
 671         WriteByte(msg, SVC_TEMPENTITY);
 672         WriteByte(msg, TE_CSQC_RACE);
 673         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 674         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 675         WriteString(msg, speedaward_alltimebest_holder);
 676 }
 677
 678 string GetMapname(void);
 679 float speedaward_lastupdate;
 680 float speedaward_lastsent;
 681 void SV_PlayerPhysics()
 682 {
 683         local vector wishvel, wishdir, v;
 684         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 685         string temps;
 686         float buttons_prev;
 687         float not_allowed_to_move;
 688         string c;
 689
 690         maxspd_mod = 1;
 691         if(g_minstagib && (self.items & IT_INVINCIBLE))
 692                 maxspd_mod *= cvar("g_minstagib_speed_highspeed");
 693         if(g_nexball && self.ballcarried)
 694                 maxspd_mod *= cvar("g_nexball_basketball_carrier_highspeed");
 695         if(g_runematch)
 696         {
 697                 if(self.runes & RUNE_SPEED)
 698                 {
 699                         if(self.runes & CURSE_SLOW)
 700                                 maxspd_mod *= cvar("g_balance_rune_speed_combo_highspeed");
 701                         else
 702                                 maxspd_mod *= cvar("g_balance_rune_speed_highspeed");
 703                 }
 704                 else if(self.runes & CURSE_SLOW)
 705                 {
 706                         maxspd_mod *= cvar("g_balance_curse_slow_highspeed");
 707                 }
 708         }
 709         maxspd_mod *= autocvar_g_movement_highspeed;
 710
 711         // fix physics stats for g_movement_highspeed
 712         self.stat_sv_airaccel_qw = AdjustAirAccelQW(sv_airaccel_qw, maxspd_mod);
 713         if(sv_airstrafeaccel_qw)
 714                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(sv_airstrafeaccel_qw, maxspd_mod);
 715         else
 716                 self.stat_sv_airstrafeaccel_qw = 0;
 717         self.stat_sv_airspeedlimit_nonqw = sv_airspeedlimit_nonqw * maxspd_mod;
 718         self.stat_sv_maxspeed = sv_maxspeed * maxspd_mod; // also slow walking
 719
 720     if(self.PlayerPhysplug)
 721         if(self.PlayerPhysplug())
 722             return;
 723
 724         self.race_movetime_frac += frametime;
 725         f = floor(self.race_movetime_frac);
 726         self.race_movetime_frac -= f;
 727         self.race_movetime_count += f;
 728         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 729
 730         anticheat_physics();
 731
 732         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 733
 734         if(!buttons)
 735                 c = "x";
 736         else if(buttons == 1)
 737                 c = "1";
 738         else if(buttons == 2)
 739                 c = " ";
 740         else if(buttons == 128)
 741                 c = "s";
 742         else if(buttons == 256)
 743                 c = "w";
 744         else if(buttons == 512)
 745                 c = "a";
 746         else if(buttons == 1024)
 747                 c = "d";
 748         else
 749                 c = "?";
 750
 751         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 752         {
 753                 self.specialcommand_pos += 1;
 754                 if(self.specialcommand_pos >= strlen(specialcommand))
 755                 {
 756                         self.specialcommand_pos = 0;
 757                         SpecialCommand();
 758                         return;
 759                 }
 760         }
 761         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 762                 self.specialcommand_pos = 0;
 763
 764         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 765         {
 766                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 767                         self.parm_idlesince = time;
 768         }
 769         buttons_prev = self.buttons_old;
 770         self.buttons_old = buttons;
 771         self.movement_old = self.movement;
 772         self.v_angle_old = self.v_angle;
 773
 774         if(time < self.nickspamtime)
 775         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 776         {
 777                 // slight annoyance for nick change scripts
 778                 self.movement = -1 * self.movement;
 779                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 780
 781                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 782                 {
 783                         self.angles_x = random() * 360;
 784                         self.angles_y = random() * 360;
 785                         // at least I'm not forcing retardedview by also assigning to angles_z
 786                         self.fixangle = 1;
 787                 }
 788         }
 789
 790         if (self.punchangle != '0 0 0')
 791         {
 792                 f = vlen(self.punchangle) - 10 * frametime;
 793                 if (f > 0)
 794                         self.punchangle = normalize(self.punchangle) * f;
 795                 else
 796                         self.punchangle = '0 0 0';
 797         }
 798
 799         if (self.punchvector != '0 0 0')
 800         {
 801                 f = vlen(self.punchvector) - 30 * frametime;
 802                 if (f > 0)
 803                         self.punchvector = normalize(self.punchvector) * f;
 804                 else
 805                         self.punchvector = '0 0 0';
 806         }
 807
 808         if (clienttype(self) == CLIENTTYPE_BOT)
 809         {
 810                 if(playerdemo_read())
 811                         return;
 812                 bot_think();
 813         }
 814
 815         MUTATOR_CALLHOOK(PlayerPhysics);
 816
 817         self.items &~= IT_USING_JETPACK;
 818
 819         if(self.classname == "player")
 820         {
 821                 if(self.race_penalty)
 822                         if(time > self.race_penalty)
 823                                 self.race_penalty = 0;
 824
 825                 not_allowed_to_move = 0;
 826                 if(self.race_penalty)
 827                         not_allowed_to_move = 1;
 828                 if(!cvar("sv_ready_restart_after_countdown"))
 829                 if(time < game_starttime)
 830                         not_allowed_to_move = 1;
 831
 832                 if(not_allowed_to_move)
 833                 {
 834                         self.velocity = '0 0 0';
 835                         self.movetype = MOVETYPE_NONE;
 836                         self.disableclientprediction = 2;
 837                 }
 838                 else if(self.disableclientprediction == 2)
 839                 {
 840                         if(self.movetype == MOVETYPE_NONE)
 841                                 self.movetype = MOVETYPE_WALK;
 842                         self.disableclientprediction = 0;
 843                 }
 844         }
 845
 846         if (self.movetype == MOVETYPE_NONE)
 847                 return;
 848
 849         maxspd_mod = 1;
 850
 851         swampspd_mod = 1;
 852         if(self.in_swamp) {
 853                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 854         }
 855
 856         if(self.classname != "player")
 857         {
 858                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 859                 if(!self.spectatorspeed)
 860                         self.spectatorspeed = maxspd_mod;
 861                 if(self.impulse && self.impulse <= 19)
 862                 {
 863                         if(self.lastclassname != "player")
 864                         {
 865                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 866                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 867                                 else if(self.impulse == 11)
 868                                         self.spectatorspeed = maxspd_mod;
 869                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 870                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 871                                 else if(self.impulse >= 1 && self.impulse <= 9)
 872                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 873                         } // otherwise just clear
 874                         self.impulse = 0;
 875                 }
 876                 maxspd_mod = self.spectatorspeed;
 877         }
 878
 879         spd = max(self.stat_sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 880         if(self.speed != spd)
 881         {
 882                 self.speed = spd;
 883                 temps = ftos(spd);
 884                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 885                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 886                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 887                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 888         }
 889
 890         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 891         swampspd_mod = 1;
 892
 893         // if dead, behave differently
 894         if (self.deadflag)
 895                 goto end;
 896
 897         if (!self.fixangle && !g_bugrigs)
 898         {
 899                 self.angles_x = 0;
 900                 self.angles_y = self.v_angle_y;
 901                 self.angles_z = 0;
 902         }
 903
 904         if(self.flags & FL_ONGROUND)
 905         if(self.wasFlying)
 906         {
 907                 self.wasFlying = 0;
 908
 909                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 910                 if(time >= self.ladder_time)
 911                 if not(self.hook)
 912                 {
 913                         self.nextstep = time + 0.3 + random() * 0.1;
 914                         trace_dphitq3surfaceflags = 0;
 915                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 916                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 917                         {
 918                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 919                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 920                                 else
 921                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 922                         }
 923                 }
 924         }
 925
 926         if(IsFlying(self))
 927                 self.wasFlying = 1;
 928
 929         if(self.classname == "player")
 930         {
 931                 if(self.flags & FL_ONGROUND)
 932                 {
 933                         if (cvar("g_multijump") > 0)
 934                                 self.multijump_count = 0;
 935                         else
 936                                 self.multijump_count = -2; // the cvar value for infinite jumps is -1, so this needs to be smaller
 937                 }
 938
 939                 if (self.BUTTON_JUMP)
 940                         PlayerJump ();
 941                 else
 942                         self.flags |= FL_JUMPRELEASED;
 943
 944                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 945                         CheckWaterJump ();
 946                 self.prevjumpbutton = self.BUTTON_JUMP;
 947         }
 948
 949         if (self.flags & FL_WATERJUMP )
 950         {
 951                 self.velocity_x = self.movedir_x;
 952                 self.velocity_y = self.movedir_y;
 953                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 954                 {
 955                         self.flags &~= FL_WATERJUMP;
 956                         self.teleport_time = 0;
 957                 }
 958         }
 959         else if (g_bugrigs && self.classname == "player")
 960         {
 961                 RaceCarPhysics();
 962         }
 963         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 964         {
 965                 // noclipping or flying
 966                 self.flags &~= FL_ONGROUND;
 967
 968                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 969                 makevectors(self.v_angle);
 970                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 971                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 972                 // acceleration
 973                 wishdir = normalize(wishvel);
 974                 wishspeed = vlen(wishvel);
 975                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 976                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 977                 if (time >= self.teleport_time)
 978                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0, 0);
 979         }
 980         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 981         {
 982                 // swimming
 983                 self.flags &~= FL_ONGROUND;
 984
 985                 makevectors(self.v_angle);
 986                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 987                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 988                 if (wishvel == '0 0 0')
 989                         wishvel = '0 0 -60'; // drift towards bottom
 990
 991                 wishdir = normalize(wishvel);
 992                 wishspeed = vlen(wishvel);
 993                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 994                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 995                 wishspeed = wishspeed * 0.7;
 996
 997                 // water friction
 998                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 999
1000                 // water acceleration
1001                 PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0, 0);
1002         }
1003         else if (time < self.ladder_time)
1004         {
1005                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
1006                 self.flags &~= FL_ONGROUND;
1007
1008                 self.velocity = self.velocity * (1 - frametime * sv_friction);
1009                 makevectors(self.v_angle);
1010                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1011                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
1012                 if (self.gravity)
1013                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
1014                 else
1015                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
1016                 if (self.ladder_entity.classname == "func_water")
1017                 {
1018                         f = vlen(wishvel);
1019                         if (f > self.ladder_entity.speed)
1020                                 wishvel = wishvel * (self.ladder_entity.speed / f);
1021
1022                         self.watertype = self.ladder_entity.skin;
1023                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
1024                         if ((self.origin_z + self.view_ofs_z) < f)
1025                                 self.waterlevel = WATERLEVEL_SUBMERGED;
1026                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
1027                                 self.waterlevel = WATERLEVEL_SWIMMING;
1028                         else if ((self.origin_z + self.mins_z + 1) < f)
1029                                 self.waterlevel = WATERLEVEL_WETFEET;
1030                         else
1031                         {
1032                                 self.waterlevel = WATERLEVEL_NONE;
1033                                 self.watertype = CONTENT_EMPTY;
1034                         }
1035                 }
1036                 // acceleration
1037                 wishdir = normalize(wishvel);
1038                 wishspeed = vlen(wishvel);
1039                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1040                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1041                 if (time >= self.teleport_time)
1042                 {
1043                         // water acceleration
1044                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0, 0);
1045                 }
1046         }
1047         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
1048         {
1049                 //makevectors(self.v_angle_y * '0 1 0');
1050                 makevectors(self.v_angle);
1051                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1052                 // add remaining speed as Z component
1053                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
1054                 // fix speedhacks :P
1055                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
1056                 // add the unused velocity as up component
1057                 wishvel_z = 0;
1058
1059                 // if(self.BUTTON_JUMP)
1060                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1061
1062                 // it is now normalized, so...
1063                 float a_side, a_up, a_add, a_diff;
1064                 a_side = cvar("g_jetpack_acceleration_side");
1065                 a_up = cvar("g_jetpack_acceleration_up");
1066                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
1067
1068                 wishvel_x *= a_side;
1069                 wishvel_y *= a_side;
1070                 wishvel_z *= a_up;
1071                 wishvel_z += a_add;
1072
1073                 float best;
1074                 best = 0;
1075                 //////////////////////////////////////////////////////////////////////////////////////
1076                 // finding the maximum over all vectors of above form
1077                 // with wishvel having an absolute value of 1
1078                 //////////////////////////////////////////////////////////////////////////////////////
1079                 // we're finding the maximum over
1080                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1081                 // for z in the range from -1 to 1
1082                 //////////////////////////////////////////////////////////////////////////////////////
1083                 // maximum is EITHER attained at the single extreme point:
1084                 a_diff = a_side * a_side - a_up * a_up;
1085                 if(a_diff != 0)
1086                 {
1087                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1088                         if(f > -1 && f < 1) // can it be attained?
1089                         {
1090                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1091                                 //print("middle\n");
1092                         }
1093                 }
1094                 // OR attained at z = 1:
1095                 f = (a_up + a_add) * (a_up + a_add);
1096                 if(f > best)
1097                 {
1098                         best = f;
1099                         //print("top\n");
1100                 }
1101                 // OR attained at z = -1:
1102                 f = (a_up - a_add) * (a_up - a_add);
1103                 if(f > best)
1104                 {
1105                         best = f;
1106                         //print("bottom\n");
1107                 }
1108                 best = sqrt(best);
1109                 //////////////////////////////////////////////////////////////////////////////////////
1110
1111                 //print("best possible acceleration: ", ftos(best), "\n");
1112
1113                 float fxy, fz;
1114                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
1115                 if(wishvel_z - sv_gravity > 0)
1116                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
1117                 else
1118                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
1119
1120                 float fvel;
1121                 fvel = vlen(wishvel);
1122                 wishvel_x *= fxy;
1123                 wishvel_y *= fxy;
1124                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
1125
1126                 fvel = min(1, vlen(wishvel) / best);
1127                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1128                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
1129                 else
1130                         f = 1;
1131
1132                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1133
1134                 if (f > 0 && wishvel != '0 0 0')
1135                 {
1136                         self.velocity = self.velocity + wishvel * f * frametime;
1137                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1138                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
1139                         self.flags &~= FL_ONGROUND;
1140                         self.items |= IT_USING_JETPACK;
1141
1142                         // jetpack also inhibits health regeneration, but only for 1 second
1143                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1144                 }
1145         }
1146         else if (self.flags & FL_ONGROUND)
1147         {
1148                 // we get here if we ran out of ammo
1149                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1150                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1151
1152                 // walking
1153                 makevectors(self.v_angle_y * '0 1 0');
1154                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1155
1156                 if(!(self.lastflags & FL_ONGROUND))
1157                 {
1158                         if(cvar("speedmeter"))
1159                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1160                         if(self.lastground < time - 0.3)
1161                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1162                         if(self.jumppadcount > 1)
1163                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1164                         self.jumppadcount = 0;
1165                 }
1166
1167 #ifdef LETS_TEST_FTEQCC
1168                 if(self.velocity_x || self.velocity_y)
1169                 {
1170                         // good
1171                 }
1172                 else
1173                 {
1174                         if(self.velocity_x)
1175                                 checkclient();
1176                         if(self.velocity_y)
1177                                 checkclient();
1178                 }
1179 #endif
1180
1181                 v = self.velocity;
1182                 v_z = 0;
1183                 f = vlen(v);
1184                 if(f > 0)
1185                 {
1186                         if (f < sv_stopspeed)
1187                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1188                         else
1189                                 f = 1 - frametime * sv_friction;
1190                         if (f > 0)
1191                                 self.velocity = self.velocity * f;
1192                         else
1193                                 self.velocity = '0 0 0';
1194                 }
1195
1196                 // acceleration
1197                 wishdir = normalize(wishvel);
1198                 wishspeed = vlen(wishvel);
1199                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1200                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1201                 if (self.crouch)
1202                         wishspeed = wishspeed * 0.5;
1203                 if (time >= self.teleport_time)
1204                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0, 0);
1205         }
1206         else
1207         {
1208                 float wishspeed0;
1209                 // we get here if we ran out of ammo
1210                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1211                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1212
1213                 if(maxspd_mod < 1)
1214                 {
1215                         maxairspd = sv_maxairspeed*maxspd_mod;
1216                         airaccel = sv_airaccelerate*maxspd_mod;
1217                 }
1218                 else
1219                 {
1220                         maxairspd = sv_maxairspeed;
1221                         airaccel = sv_airaccelerate;
1222                 }
1223                 // airborn
1224                 makevectors(self.v_angle_y * '0 1 0');
1225                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1226                 // acceleration
1227                 wishdir = normalize(wishvel);
1228                 wishspeed = wishspeed0 = vlen(wishvel);
1229                 if (wishspeed0 > self.stat_sv_maxspeed*maxspd_mod)
1230                         wishspeed0 = self.stat_sv_maxspeed*maxspd_mod;
1231                 if (wishspeed > maxairspd)
1232                         wishspeed = maxairspd;
1233                 if (self.crouch)
1234                         wishspeed = wishspeed * 0.5;
1235                 if (time >= self.teleport_time)
1236                 {
1237                         float accelerating;
1238                         float wishspeed2;
1239                         float airaccelqw;
1240                         float strafity;
1241
1242                         airaccelqw = self.stat_sv_airaccel_qw;
1243                         accelerating = (self.velocity * wishdir > 0);
1244                         wishspeed2 = wishspeed;
1245
1246                         // CPM
1247                         if(sv_airstopaccelerate)
1248                         {
1249                                 vector curdir;
1250                                 curdir = self.velocity;
1251                                 curdir_z = 0;
1252                                 curdir = normalize(curdir);
1253                                 airaccel = airaccel + (sv_airstopaccelerate*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1254                         }
1255                         // note that for straight forward jumping:
1256                         // step = accel * frametime * wishspeed0;
1257                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1258                         // -->
1259                         // dv/dt = accel * maxspeed (when slow)
1260                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1261                         // log dv/dt = logaccel + logmaxspeed (when slow)
1262                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1263                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1264                         if(sv_maxairstrafespeed)
1265                                 wishspeed = min(wishspeed, GeomLerp(sv_maxairspeed*maxspd_mod, strafity, sv_maxairstrafespeed*maxspd_mod));
1266                         if(sv_airstrafeaccelerate)
1267                                 airaccel = GeomLerp(airaccel, strafity, sv_airstrafeaccelerate*maxspd_mod);
1268                         if(self.stat_sv_airstrafeaccel_qw)
1269                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1270                         // !CPM
1271
1272                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1273                                 PM_AirAccelerate(wishdir, wishspeed);
1274                         else
1275                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd, self.stat_sv_airspeedlimit_nonqw);
1276
1277                         if(sv_aircontrol)
1278                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1279                 }
1280         }
1281
1282         if((g_cts || g_race) && self.classname != "observer") {
1283                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1284                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1285                         speedaward_holder = self.netname;
1286                         speedaward_uid = self.crypto_idfp;
1287                         speedaward_lastupdate = time;
1288                 }
1289                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1290                         string rr;
1291                         if(g_cts)
1292                                 rr = CTS_RECORD;
1293                         else
1294                                 rr = RACE_RECORD;
1295                         race_send_speedaward(MSG_ALL);
1296                         speedaward_lastsent = speedaward_speed;
1297                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "") {
1298                                 speedaward_alltimebest = speedaward_speed;
1299                                 speedaward_alltimebest_holder = speedaward_holder;
1300                                 speedaward_alltimebest_uid = speedaward_uid;
1301                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1302                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
1303                                 race_send_speedaward_alltimebest(MSG_ALL);
1304                         }
1305                 }
1306         }
1307
1308         float xyspeed;
1309         xyspeed = vlen('1 0 0' * self.velocity_x + '0 1 0' * self.velocity_y);
1310         if(self.weapon == WEP_NEX && cvar("g_balance_nex_charge") && cvar("g_balance_nex_charge_velocity_rate") && xyspeed > cvar("g_balance_nex_charge_minspeed"))
1311         {
1312                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1313                 xyspeed = min(xyspeed, cvar("g_balance_nex_charge_maxspeed"));
1314                 f = (xyspeed - cvar("g_balance_nex_charge_minspeed")) / (cvar("g_balance_nex_charge_maxspeed") - cvar("g_balance_nex_charge_minspeed"));
1315                 // add the extra charge
1316                 self.nex_charge = min(1, self.nex_charge + cvar("g_balance_nex_charge_velocity_rate") * f * frametime);
1317         }
1318 :end
1319         if(self.flags & FL_ONGROUND)
1320                 self.lastground = time;
1321
1322         self.lastflags = self.flags;
1323         self.lastclassname = self.classname;
1324 };