qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 .float ladder_time;
   5 .entity ladder_entity;
   6 .float gravity;
   7 .float swamp_slowdown;
   8 .float lastflags;
   9 .float lastground;
  10 .float wasFlying;
  11 .float spectatorspeed;
  12
  13 .float multijump_count;
  14 .float multijump_ready;
  15 .float prevjumpbutton;
  16
  17 /*
  18 =============
  19 PlayerJump
  20
  21 When you press the jump key
  22 =============
  23 */
  24 void PlayerJump (void)
  25 {
  26         if(self.freezetag_frozen)
  27                 return; // no jumping in freezetag when frozen
  28
  29         float mjumpheight;
  30         float doublejump;
  31
  32         doublejump = FALSE;
  33         if (autocvar_sv_doublejump)
  34         {
  35                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
  36                 if (trace_fraction < 1 && trace_plane_normal_z > 0.7)
  37                         doublejump = TRUE;
  38         }
  39
  40         mjumpheight = autocvar_sv_jumpvelocity;
  41         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  42         {
  43                 if (self.watertype == CONTENT_WATER)
  44                         self.velocity_z = 200;
  45                 else if (self.watertype == CONTENT_SLIME)
  46                         self.velocity_z = 80;
  47                 else
  48                         self.velocity_z = 50;
  49
  50                 return;
  51         }
  52
  53         if (autocvar_g_multijump)
  54         {
  55                 if (self.prevjumpbutton == FALSE && !(self.flags & FL_ONGROUND)) // jump button pressed this frame and we are in midair
  56                         self.multijump_ready = TRUE;  // this is necessary to check that we released the jump button and pressed it again
  57                 else
  58                         self.multijump_ready = FALSE;
  59         }
  60
  61         if(!doublejump && self.multijump_ready && self.multijump_count < autocvar_g_multijump && self.velocity_z > autocvar_g_multijump_speed)
  62         {
  63                 // doublejump = FALSE; // checked above in the if
  64                 if (autocvar_g_multijump)
  65                 {
  66                         if (autocvar_g_multijump_add == 0) // in this case we make the z velocity == jumpvelocity
  67                         {
  68                                 if (self.velocity_z < mjumpheight)
  69                                 {
  70                                         doublejump = TRUE;
  71                                         self.velocity_z = 0;
  72                                 }
  73                         }
  74                         else
  75                                 doublejump = TRUE;
  76
  77                         if(doublejump)
  78                         {
  79                                 if(self.movement_x != 0 || self.movement_y != 0) // don't remove all speed if player isnt pressing any movement keys
  80                                 {
  81                                         float curspeed;
  82                                         vector wishvel, wishdir;
  83
  84                                         curspeed = max(
  85                                                 vlen(vec2(self.velocity)), // current xy speed
  86                                                 vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
  87                                         );
  88                                         makevectors(self.v_angle_y * '0 1 0');
  89                                         wishvel = v_forward * self.movement_x + v_right * self.movement_y;
  90                                         wishdir = normalize(wishvel);
  91
  92                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
  93                                         self.velocity_y = wishdir_y * curspeed;
  94                                         // keep velocity_z unchanged!
  95                                 }
  96                                 if (autocvar_g_multijump > 0)
  97                                         self.multijump_count += 1;
  98                         }
  99                 }
 100                 self.multijump_ready = FALSE; // require releasing and pressing the jump button again for the next jump
 101         }
 102
 103         if (!doublejump)
 104                 if (!(self.flags & FL_ONGROUND))
 105                         return;
 106
 107         if(!sv_pogostick)
 108                 if (!(self.flags & FL_JUMPRELEASED))
 109                         return;
 110
 111         if(self.health <= g_bloodloss)
 112                 return;
 113
 114         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 115         // velocity bounds.  Final velocity is bound between (jumpheight *
 116         // min + jumpheight) and (jumpheight * max + jumpheight);
 117
 118         if(autocvar_sv_jumpspeedcap_min != "")
 119         {
 120                 float minjumpspeed;
 121
 122                 minjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_min);
 123
 124                 if (self.velocity_z < minjumpspeed)
 125                         mjumpheight += minjumpspeed - self.velocity_z;
 126         }
 127
 128         if(autocvar_sv_jumpspeedcap_max != "")
 129         {
 130                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 131                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 132
 133                 if(!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && autocvar_sv_jumpspeedcap_max_disable_on_ramps))
 134                 {
 135                         float maxjumpspeed;
 136
 137                         maxjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_max);
 138
 139                         if (self.velocity_z > maxjumpspeed)
 140                                 mjumpheight -= self.velocity_z - maxjumpspeed;
 141                 }
 142         }
 143
 144         if(!(self.lastflags & FL_ONGROUND))
 145         {
 146                 if(autocvar_speedmeter)
 147                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 148                 if(self.lastground < time - 0.3)
 149                 {
 150                         self.velocity_x *= (1 - autocvar_sv_friction_on_land);
 151                         self.velocity_y *= (1 - autocvar_sv_friction_on_land);
 152                 }
 153                 if(self.jumppadcount > 1)
 154                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 155                 self.jumppadcount = 0;
 156         }
 157
 158         self.velocity_z = self.velocity_z + mjumpheight;
 159         self.oldvelocity_z = self.velocity_z;
 160
 161         self.flags &~= FL_ONGROUND;
 162         self.flags &~= FL_JUMPRELEASED;
 163
 164         if (self.crouch)
 165                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 166         else
 167                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 168
 169         if(g_jump_grunt)
 170                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 171
 172         self.restart_jump = -1; // restart jump anim next time
 173         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 174 }
 175
 176 void CheckWaterJump()
 177 {
 178         local vector start, end;
 179
 180 // check for a jump-out-of-water
 181         makevectors (self.angles);
 182         start = self.origin;
 183         start_z = start_z + 8;
 184         v_forward_z = 0;
 185         normalize(v_forward);
 186         end = start + v_forward*24;
 187         traceline (start, end, TRUE, self);
 188         if (trace_fraction < 1)
 189         {       // solid at waist
 190                 start_z = start_z + self.maxs_z - 8;
 191                 end = start + v_forward*24;
 192                 self.movedir = trace_plane_normal * -50;
 193                 traceline (start, end, TRUE, self);
 194                 if (trace_fraction == 1)
 195                 {       // open at eye level
 196                         self.flags |= FL_WATERJUMP;
 197                         self.velocity_z = 225;
 198                         self.flags &~= FL_JUMPRELEASED;
 199                         self.teleport_time = time + 2;  // safety net
 200                         return;
 201                 }
 202         }
 203 };
 204
 205 float racecar_angle(float forward, float down)
 206 {
 207         float ret, angle_mult;
 208
 209         if(forward < 0)
 210         {
 211                 forward = -forward;
 212                 down = -down;
 213         }
 214
 215         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 216
 217         angle_mult = forward / (800 + forward);
 218
 219         if(ret > 180)
 220                 return ret * angle_mult + 360 * (1 - angle_mult);
 221         else
 222                 return ret * angle_mult;
 223 }
 224
 225 void RaceCarPhysics()
 226 {
 227         // using this move type for "big rigs"
 228         // the engine does not push the entity!
 229
 230         float accel, steer, f, myspeed, steerfactor;
 231         vector angles_save, rigvel;
 232
 233         angles_save = self.angles;
 234         accel = bound(-1, self.movement_x / self.stat_sv_maxspeed, 1);
 235         steer = bound(-1, self.movement_y / self.stat_sv_maxspeed, 1);
 236
 237         if(g_bugrigs_reverse_speeding)
 238         {
 239                 if(accel < 0)
 240                 {
 241                         // back accel is DIGITAL
 242                         // to prevent speedhack
 243                         if(accel < -0.5)
 244                                 accel = -1;
 245                         else
 246                                 accel = 0;
 247                 }
 248         }
 249
 250         self.angles_x = 0;
 251         self.angles_z = 0;
 252         makevectors(self.angles); // new forward direction!
 253
 254         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 255         {
 256                 float upspeed, accelfactor;
 257
 258                 myspeed = self.velocity * v_forward;
 259                 upspeed = self.velocity * v_up;
 260
 261                 // responsiveness factor for steering and acceleration
 262                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 263                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 264
 265                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 266                         steerfactor = -myspeed * g_bugrigs_steer;
 267                 else
 268                         steerfactor = -myspeed * f * g_bugrigs_steer;
 269
 270                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 271                         accelfactor = g_bugrigs_accel;
 272                 else
 273                         accelfactor = f * g_bugrigs_accel;
 274                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 275
 276                 if(accel < 0)
 277                 {
 278                         if(myspeed > 0)
 279                         {
 280                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 281                         }
 282                         else
 283                         {
 284                                 if(!g_bugrigs_reverse_speeding)
 285                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 286                         }
 287                 }
 288                 else
 289                 {
 290                         if(myspeed >= 0)
 291                         {
 292                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 293                         }
 294                         else
 295                         {
 296                                 if(g_bugrigs_reverse_stopping)
 297                                         myspeed = 0;
 298                                 else
 299                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 300                         }
 301                 }
 302                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 303                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 304
 305                 self.angles_y += steer * frametime * steerfactor; // apply steering
 306                 makevectors(self.angles); // new forward direction!
 307
 308                 myspeed += accel * accelfactor * frametime;
 309
 310                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 311         }
 312         else
 313         {
 314                 myspeed = vlen(self.velocity);
 315
 316                 // responsiveness factor for steering and acceleration
 317                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 318                 steerfactor = -myspeed * f;
 319                 self.angles_y += steer * frametime * steerfactor; // apply steering
 320
 321                 rigvel = self.velocity;
 322                 makevectors(self.angles); // new forward direction!
 323         }
 324
 325         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 326         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 327         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 328         //MAXIMA: solve(total_acceleration(v) = 0, v);
 329
 330         if(g_bugrigs_planar_movement)
 331         {
 332                 vector rigvel_xy, neworigin, up;
 333                 float mt;
 334
 335                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 336                 rigvel_xy = vec2(rigvel);
 337
 338                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 339                         mt = MOVE_NORMAL;
 340                 else
 341                         mt = MOVE_NOMONSTERS;
 342
 343                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 344                 up = trace_endpos - self.origin;
 345
 346                 // BUG RIGS: align the move to the surface instead of doing collision testing
 347                 // can we move?
 348                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 349
 350                 // align to surface
 351                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 352
 353                 if(trace_fraction < 0.5)
 354                 {
 355                         trace_fraction = 1;
 356                         neworigin = self.origin;
 357                 }
 358                 else
 359                         neworigin = trace_endpos;
 360
 361                 if(trace_fraction < 1)
 362                 {
 363                         // now set angles_x so that the car points parallel to the surface
 364                         self.angles = vectoangles(
 365                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 366                                         +
 367                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 368                                         +
 369                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 370                                         );
 371                         self.flags |= FL_ONGROUND;
 372                 }
 373                 else
 374                 {
 375                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 376                         self.flags &~= FL_ONGROUND;
 377                 }
 378
 379                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 380                 self.movetype = MOVETYPE_NOCLIP;
 381         }
 382         else
 383         {
 384                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 385                 self.velocity = rigvel;
 386                 self.movetype = MOVETYPE_FLY;
 387         }
 388
 389         trace_fraction = 1;
 390         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 391         if(trace_fraction != 1)
 392         {
 393                 self.angles = vectoangles2(
 394                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 395                                 +
 396                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 397                                 +
 398                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 399                                 trace_plane_normal
 400                                 );
 401         }
 402         else
 403         {
 404                 vector vel_local;
 405
 406                 vel_local_x = v_forward * self.velocity;
 407                 vel_local_y = v_right * self.velocity;
 408                 vel_local_z = v_up * self.velocity;
 409
 410                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 411                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 412         }
 413
 414         // smooth the angles
 415         vector vf1, vu1, smoothangles;
 416         makevectors(self.angles);
 417         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 418         if(f == 0)
 419                 f = 1;
 420         vf1 = v_forward * f;
 421         vu1 = v_up * f;
 422         makevectors(angles_save);
 423         vf1 = vf1 + v_forward * (1 - f);
 424         vu1 = vu1 + v_up * (1 - f);
 425         smoothangles = vectoangles2(vf1, vu1);
 426         self.angles_x = -smoothangles_x;
 427         self.angles_z =  smoothangles_z;
 428 }
 429
 430 float IsMoveInDirection(vector mv, float angle) // key mix factor
 431 {
 432         if(mv_x == 0 && mv_y == 0)
 433                 return 0; // avoid division by zero
 434         angle -= RAD2DEG * atan2(mv_y, mv_x);
 435         angle = remainder(angle, 360) / 45;
 436         if(angle >  1)
 437                 return 0;
 438         if(angle < -1)
 439                 return 0;
 440         return 1 - fabs(angle);
 441 }
 442
 443 float GeomLerp(float a, float lerp, float b)
 444 {
 445         if(a == 0)
 446         {
 447                 if(lerp < 1)
 448                         return 0;
 449                 else
 450                         return b;
 451         }
 452         if(b == 0)
 453         {
 454                 if(lerp > 0)
 455                         return 0;
 456                 else
 457                         return a;
 458         }
 459         return a * pow(fabs(b / a), lerp);
 460 }
 461
 462 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 463 {
 464         float zspeed, xyspeed, dot, k;
 465
 466 #if 0
 467         // this doesn't play well with analog input
 468         if(self.movement_x == 0 || self.movement_y != 0)
 469                 return; // can't control movement if not moving forward or backward
 470         k = 32;
 471 #else
 472         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 473         if(k <= 0)
 474                 return;
 475 #endif
 476
 477         k *= bound(0, wishspeed / autocvar_sv_maxairspeed, 1);
 478
 479         zspeed = self.velocity_z;
 480         self.velocity_z = 0;
 481         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 482
 483         dot = self.velocity * wishdir;
 484
 485         if(dot > 0) // we can't change direction while slowing down
 486         {
 487                 k *= pow(dot, autocvar_sv_aircontrol_power)*frametime;
 488                 xyspeed = max(0, xyspeed - autocvar_sv_aircontrol_penalty * sqrt(max(0, 1 - dot*dot)) * k/32);
 489                 k *= autocvar_sv_aircontrol;
 490                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 491         }
 492
 493         self.velocity = self.velocity * xyspeed;
 494         self.velocity_z = zspeed;
 495 }
 496
 497 float AdjustAirAccelQW(float accelqw, float factor)
 498 {
 499         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 500 }
 501
 502 // example config for alternate speed clamping:
 503 //   sv_airaccel_qw 0.8
 504 //   sv_airaccel_sideways_friction 0
 505 //   prvm_globalset server speedclamp_mode 1
 506 //     (or 2)
 507 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float sidefric, float speedlimit)
 508 {
 509         float vel_straight;
 510         float vel_z;
 511         vector vel_perpend;
 512         float step;
 513
 514         vector vel_xy;
 515         float vel_xy_current;
 516         float vel_xy_backward, vel_xy_forward;
 517         float speedclamp;
 518
 519         speedclamp = (accelqw < 0);
 520         if(speedclamp)
 521                 accelqw = -accelqw;
 522
 523         if(autocvar_sv_gameplayfix_q2airaccelerate)
 524                 wishspeed0 = wishspeed;
 525
 526         vel_straight = self.velocity * wishdir;
 527         vel_z = self.velocity_z;
 528         vel_xy = vec2(self.velocity);
 529         vel_perpend = vel_xy - vel_straight * wishdir;
 530
 531         step = accel * frametime * wishspeed0;
 532
 533         vel_xy_current  = vlen(vel_xy);
 534         if(speedlimit)
 535                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 536         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 537         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 538         if(vel_xy_backward < 0)
 539                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 540
 541         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 542
 543         if(sidefric < 0 && (vel_perpend*vel_perpend))
 544                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 545         {
 546                 float f, fminimum;
 547                 f = max(0, 1 + frametime * wishspeed * sidefric);
 548                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 549                 // this cannot be > 1
 550                 if(fminimum <= 0)
 551                         vel_perpend = vel_perpend * max(0, f);
 552                 else
 553                 {
 554                         fminimum = sqrt(fminimum);
 555                         vel_perpend = vel_perpend * max(fminimum, f);
 556                 }
 557         }
 558         else
 559                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
 560
 561         vel_xy = vel_straight * wishdir + vel_perpend;
 562
 563         if(speedclamp)
 564         {
 565                 // ensure we don't get too fast or decelerate faster than we should
 566                 vel_xy_current = min(vlen(vel_xy), vel_xy_forward);
 567                 if(vel_xy_current > 0) // prevent division by zero
 568                         vel_xy = normalize(vel_xy) * vel_xy_current;
 569         }
 570
 571         self.velocity = vel_xy + vel_z * '0 0 1';
 572 }
 573
 574 void PM_AirAccelerate(vector wishdir, float wishspeed)
 575 {
 576         vector curvel, wishvel, acceldir, curdir;
 577         float addspeed, accelspeed, curspeed, f;
 578         float dot;
 579
 580         if(wishspeed == 0)
 581                 return;
 582
 583         curvel = self.velocity;
 584         curvel_z = 0;
 585         curspeed = vlen(curvel);
 586
 587         if(wishspeed > curspeed * 1.01)
 588         {
 589                 wishspeed = min(wishspeed, curspeed + autocvar_sv_warsowbunny_airforwardaccel * self.stat_sv_maxspeed * frametime);
 590         }
 591         else
 592         {
 593                 f = max(0, (autocvar_sv_warsowbunny_topspeed - curspeed) / (autocvar_sv_warsowbunny_topspeed - self.stat_sv_maxspeed));
 594                 wishspeed = max(curspeed, self.stat_sv_maxspeed) + autocvar_sv_warsowbunny_accel * f * self.stat_sv_maxspeed * frametime;
 595         }
 596         wishvel = wishdir * wishspeed;
 597         acceldir = wishvel - curvel;
 598         addspeed = vlen(acceldir);
 599         acceldir = normalize(acceldir);
 600
 601         accelspeed = min(addspeed, autocvar_sv_warsowbunny_turnaccel * self.stat_sv_maxspeed * frametime);
 602
 603         if(autocvar_sv_warsowbunny_backtosideratio < 1)
 604         {
 605                 curdir = normalize(curvel);
 606                 dot = acceldir * curdir;
 607                 if(dot < 0)
 608                         acceldir = acceldir - (1 - autocvar_sv_warsowbunny_backtosideratio) * dot * curdir;
 609         }
 610
 611         self.velocity += accelspeed * acceldir;
 612 }
 613
 614 .vector movement_old;
 615 .float buttons_old;
 616 .vector v_angle_old;
 617 .string lastclassname;
 618
 619 .float() PlayerPhysplug;
 620
 621 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 622 .float specialcommand_pos;
 623 void SpecialCommand()
 624 {
 625 #ifdef TETRIS
 626         TetrisImpulse();
 627 #else
 628         if(!CheatImpulse(99))
 629                 print("A hollow voice says \"Plugh\".\n");
 630 #endif
 631 }
 632
 633 float speedaward_speed;
 634 string speedaward_holder;
 635 string speedaward_uid;
 636 void race_send_speedaward(float msg)
 637 {
 638         // send the best speed of the round
 639         WriteByte(msg, SVC_TEMPENTITY);
 640         WriteByte(msg, TE_CSQC_RACE);
 641         WriteByte(msg, RACE_NET_SPEED_AWARD);
 642         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 643         WriteString(msg, speedaward_holder);
 644 }
 645
 646 float speedaward_alltimebest;
 647 string speedaward_alltimebest_holder;
 648 string speedaward_alltimebest_uid;
 649 void race_send_speedaward_alltimebest(float msg)
 650 {
 651         // send the best speed
 652         WriteByte(msg, SVC_TEMPENTITY);
 653         WriteByte(msg, TE_CSQC_RACE);
 654         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 655         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 656         WriteString(msg, speedaward_alltimebest_holder);
 657 }
 658
 659 string GetMapname(void);
 660 float speedaward_lastupdate;
 661 float speedaward_lastsent;
 662 void SV_PlayerPhysics()
 663 {
 664         local vector wishvel, wishdir, v;
 665         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 666         string temps;
 667         float buttons_prev;
 668         float not_allowed_to_move;
 669         string c;
 670
 671         WarpZone_PlayerPhysics_FixVAngle();
 672
 673         maxspd_mod = 1;
 674         if(g_minstagib && (self.items & IT_INVINCIBLE))
 675                 maxspd_mod *= autocvar_g_minstagib_speed_highspeed;
 676         if(self.ballcarried)
 677                 if(g_nexball)
 678                         maxspd_mod *= autocvar_g_nexball_basketball_carrier_highspeed;
 679                 else if(g_keepaway)
 680                         maxspd_mod *= autocvar_g_keepaway_ballcarrier_highspeed;
 681
 682         if(g_runematch)
 683         {
 684                 if(self.runes & RUNE_SPEED)
 685                 {
 686                         if(self.runes & CURSE_SLOW)
 687                                 maxspd_mod *= autocvar_g_balance_rune_speed_combo_highspeed;
 688                         else
 689                                 maxspd_mod *= autocvar_g_balance_rune_speed_highspeed;
 690                 }
 691                 else if(self.runes & CURSE_SLOW)
 692                 {
 693                         maxspd_mod *= autocvar_g_balance_curse_slow_highspeed;
 694                 }
 695         }
 696         maxspd_mod *= autocvar_g_movement_highspeed;
 697
 698         // fix physics stats for g_movement_highspeed
 699         self.stat_sv_airaccel_qw = AdjustAirAccelQW(autocvar_sv_airaccel_qw, maxspd_mod);
 700         if(autocvar_sv_airstrafeaccel_qw)
 701                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(autocvar_sv_airstrafeaccel_qw, maxspd_mod);
 702         else
 703                 self.stat_sv_airstrafeaccel_qw = 0;
 704         self.stat_sv_airspeedlimit_nonqw = autocvar_sv_airspeedlimit_nonqw * maxspd_mod;
 705         self.stat_sv_maxspeed = autocvar_sv_maxspeed * maxspd_mod; // also slow walking
 706
 707     if(self.PlayerPhysplug)
 708         if(self.PlayerPhysplug())
 709             return;
 710
 711         self.race_movetime_frac += frametime;
 712         f = floor(self.race_movetime_frac);
 713         self.race_movetime_frac -= f;
 714         self.race_movetime_count += f;
 715         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 716
 717         anticheat_physics();
 718
 719         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 720
 721         if(!buttons)
 722                 c = "x";
 723         else if(buttons == 1)
 724                 c = "1";
 725         else if(buttons == 2)
 726                 c = " ";
 727         else if(buttons == 128)
 728                 c = "s";
 729         else if(buttons == 256)
 730                 c = "w";
 731         else if(buttons == 512)
 732                 c = "a";
 733         else if(buttons == 1024)
 734                 c = "d";
 735         else
 736                 c = "?";
 737
 738         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 739         {
 740                 self.specialcommand_pos += 1;
 741                 if(self.specialcommand_pos >= strlen(specialcommand))
 742                 {
 743                         self.specialcommand_pos = 0;
 744                         SpecialCommand();
 745                         return;
 746                 }
 747         }
 748         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 749                 self.specialcommand_pos = 0;
 750
 751         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 752         {
 753                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 754                         self.parm_idlesince = time;
 755         }
 756         buttons_prev = self.buttons_old;
 757         self.buttons_old = buttons;
 758         self.movement_old = self.movement;
 759         self.v_angle_old = self.v_angle;
 760
 761         if(time < self.nickspamtime)
 762         if(self.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 763         {
 764                 // slight annoyance for nick change scripts
 765                 self.movement = -1 * self.movement;
 766                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 767
 768                 if(self.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 769                 {
 770                         self.angles_x = random() * 360;
 771                         self.angles_y = random() * 360;
 772                         // at least I'm not forcing retardedview by also assigning to angles_z
 773                         self.fixangle = 1;
 774                 }
 775         }
 776
 777         if (self.punchangle != '0 0 0')
 778         {
 779                 f = vlen(self.punchangle) - 10 * frametime;
 780                 if (f > 0)
 781                         self.punchangle = normalize(self.punchangle) * f;
 782                 else
 783                         self.punchangle = '0 0 0';
 784         }
 785
 786         if (self.punchvector != '0 0 0')
 787         {
 788                 f = vlen(self.punchvector) - 30 * frametime;
 789                 if (f > 0)
 790                         self.punchvector = normalize(self.punchvector) * f;
 791                 else
 792                         self.punchvector = '0 0 0';
 793         }
 794
 795         if (clienttype(self) == CLIENTTYPE_BOT)
 796         {
 797                 if(playerdemo_read())
 798                         return;
 799                 bot_think();
 800         }
 801
 802         self.items &~= IT_USING_JETPACK;
 803
 804         if(self.classname == "player")
 805         {
 806                 if(self.race_penalty)
 807                         if(time > self.race_penalty)
 808                                 self.race_penalty = 0;
 809
 810                 not_allowed_to_move = 0;
 811                 if(self.race_penalty)
 812                         not_allowed_to_move = 1;
 813                 if(!autocvar_sv_ready_restart_after_countdown)
 814                 if(time < game_starttime)
 815                         not_allowed_to_move = 1;
 816
 817                 if(not_allowed_to_move)
 818                 {
 819                         self.velocity = '0 0 0';
 820                         self.movetype = MOVETYPE_NONE;
 821                         self.disableclientprediction = 2;
 822                 }
 823                 else if(self.disableclientprediction == 2)
 824                 {
 825                         if(self.movetype == MOVETYPE_NONE)
 826                                 self.movetype = MOVETYPE_WALK;
 827                         self.disableclientprediction = 0;
 828                 }
 829         }
 830
 831         if (self.movetype == MOVETYPE_NONE)
 832                 return;
 833
 834         // when we get here, disableclientprediction cannot be 2
 835         self.disableclientprediction = 0;
 836         if(time < self.ladder_time)
 837                 self.disableclientprediction = 1;
 838
 839         MUTATOR_CALLHOOK(PlayerPhysics);
 840
 841         maxspd_mod = 1;
 842
 843         swampspd_mod = 1;
 844         if(self.in_swamp) {
 845                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 846         }
 847
 848         if(self.classname != "player")
 849         {
 850                 maxspd_mod = autocvar_sv_spectator_speed_multiplier;
 851                 if(!self.spectatorspeed)
 852                         self.spectatorspeed = maxspd_mod;
 853                 if(self.impulse && self.impulse <= 19)
 854                 {
 855                         if(self.lastclassname != "player")
 856                         {
 857                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 858                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 859                                 else if(self.impulse == 11)
 860                                         self.spectatorspeed = maxspd_mod;
 861                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 862                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 863                                 else if(self.impulse >= 1 && self.impulse <= 9)
 864                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 865                         } // otherwise just clear
 866                         self.impulse = 0;
 867                 }
 868                 maxspd_mod = self.spectatorspeed;
 869         }
 870
 871         spd = max(self.stat_sv_maxspeed, autocvar_sv_maxairspeed) * maxspd_mod * swampspd_mod;
 872         if(self.speed != spd)
 873         {
 874                 self.speed = spd;
 875                 temps = ftos(spd);
 876                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 877                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 878                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 879                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 880         }
 881
 882         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 883         swampspd_mod = 1;
 884
 885         // if dead, behave differently
 886         if (self.deadflag)
 887                 goto end;
 888
 889         if (!self.fixangle && !g_bugrigs)
 890         {
 891                 self.angles_x = 0;
 892                 self.angles_y = self.v_angle_y;
 893                 self.angles_z = 0;
 894         }
 895
 896         if(self.flags & FL_ONGROUND)
 897         if(self.wasFlying)
 898         {
 899                 self.wasFlying = 0;
 900
 901                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 902                 if(time >= self.ladder_time)
 903                 if not(self.hook)
 904                 {
 905                         self.nextstep = time + 0.3 + random() * 0.1;
 906                         trace_dphitq3surfaceflags = 0;
 907                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 908                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 909                         {
 910                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 911                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 912                                 else
 913                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 914                         }
 915                 }
 916         }
 917
 918         if(IsFlying(self))
 919                 self.wasFlying = 1;
 920
 921         if(self.classname == "player")
 922         {
 923                 if(self.flags & FL_ONGROUND)
 924                 {
 925                         if (autocvar_g_multijump > 0)
 926                                 self.multijump_count = 0;
 927                         else
 928                                 self.multijump_count = -2; // the cvar value for infinite jumps is -1, so this needs to be smaller
 929                 }
 930
 931                 if (self.BUTTON_JUMP)
 932                         PlayerJump ();
 933                 else
 934                         self.flags |= FL_JUMPRELEASED;
 935
 936                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 937                         CheckWaterJump ();
 938                 self.prevjumpbutton = self.BUTTON_JUMP;
 939         }
 940
 941         if (self.flags & FL_WATERJUMP )
 942         {
 943                 self.velocity_x = self.movedir_x;
 944                 self.velocity_y = self.movedir_y;
 945                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 946                 {
 947                         self.flags &~= FL_WATERJUMP;
 948                         self.teleport_time = 0;
 949                 }
 950         }
 951         else if (g_bugrigs && self.classname == "player")
 952         {
 953                 RaceCarPhysics();
 954         }
 955         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 956         {
 957                 // noclipping or flying
 958                 self.flags &~= FL_ONGROUND;
 959
 960                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
 961                 makevectors(self.v_angle);
 962                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 963                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 964                 // acceleration
 965                 wishdir = normalize(wishvel);
 966                 wishspeed = vlen(wishvel);
 967                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 968                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 969                 if (time >= self.teleport_time)
 970                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0);
 971         }
 972         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 973         {
 974                 // swimming
 975                 self.flags &~= FL_ONGROUND;
 976
 977                 makevectors(self.v_angle);
 978                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 979                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 980                 if (wishvel == '0 0 0')
 981                         wishvel = '0 0 -60'; // drift towards bottom
 982
 983                 wishdir = normalize(wishvel);
 984                 wishspeed = vlen(wishvel);
 985                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 986                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 987                 wishspeed = wishspeed * 0.7;
 988
 989                 // water friction
 990                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
 991
 992                 // water acceleration
 993                 PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0);
 994         }
 995         else if (time < self.ladder_time)
 996         {
 997                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 998                 self.flags &~= FL_ONGROUND;
 999
1000                 float g;
1001                 g = autocvar_sv_gravity * frametime;
1002                 if(self.gravity)
1003                         g *= self.gravity;
1004                 if(autocvar_sv_gameplayfix_gravityunaffectedbyticrate)
1005                 {
1006                         g *= 0.5;
1007                         self.velocity_z += g;
1008                 }
1009
1010                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
1011                 makevectors(self.v_angle);
1012                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1013                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
1014                 self.velocity_z += g;
1015                 if (self.ladder_entity.classname == "func_water")
1016                 {
1017                         f = vlen(wishvel);
1018                         if (f > self.ladder_entity.speed)
1019                                 wishvel = wishvel * (self.ladder_entity.speed / f);
1020
1021                         self.watertype = self.ladder_entity.skin;
1022                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
1023                         if ((self.origin_z + self.view_ofs_z) < f)
1024                                 self.waterlevel = WATERLEVEL_SUBMERGED;
1025                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
1026                                 self.waterlevel = WATERLEVEL_SWIMMING;
1027                         else if ((self.origin_z + self.mins_z + 1) < f)
1028                                 self.waterlevel = WATERLEVEL_WETFEET;
1029                         else
1030                         {
1031                                 self.waterlevel = WATERLEVEL_NONE;
1032                                 self.watertype = CONTENT_EMPTY;
1033                         }
1034                 }
1035                 // acceleration
1036                 wishdir = normalize(wishvel);
1037                 wishspeed = vlen(wishvel);
1038                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1039                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1040                 if (time >= self.teleport_time)
1041                 {
1042                         // water acceleration
1043                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0);
1044                 }
1045         }
1046         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!autocvar_g_jetpack_fuel || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
1047         {
1048                 //makevectors(self.v_angle_y * '0 1 0');
1049                 makevectors(self.v_angle);
1050                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1051                 // add remaining speed as Z component
1052                 maxairspd = autocvar_sv_maxairspeed*max(1, maxspd_mod);
1053                 // fix speedhacks :P
1054                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
1055                 // add the unused velocity as up component
1056                 wishvel_z = 0;
1057
1058                 // if(self.BUTTON_JUMP)
1059                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1060
1061                 // it is now normalized, so...
1062                 float a_side, a_up, a_add, a_diff;
1063                 a_side = autocvar_g_jetpack_acceleration_side;
1064                 a_up = autocvar_g_jetpack_acceleration_up;
1065                 a_add = autocvar_g_jetpack_antigravity * autocvar_sv_gravity;
1066
1067                 wishvel_x *= a_side;
1068                 wishvel_y *= a_side;
1069                 wishvel_z *= a_up;
1070                 wishvel_z += a_add;
1071
1072                 float best;
1073                 best = 0;
1074                 //////////////////////////////////////////////////////////////////////////////////////
1075                 // finding the maximum over all vectors of above form
1076                 // with wishvel having an absolute value of 1
1077                 //////////////////////////////////////////////////////////////////////////////////////
1078                 // we're finding the maximum over
1079                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1080                 // for z in the range from -1 to 1
1081                 //////////////////////////////////////////////////////////////////////////////////////
1082                 // maximum is EITHER attained at the single extreme point:
1083                 a_diff = a_side * a_side - a_up * a_up;
1084                 if(a_diff != 0)
1085                 {
1086                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1087                         if(f > -1 && f < 1) // can it be attained?
1088                         {
1089                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1090                                 //print("middle\n");
1091                         }
1092                 }
1093                 // OR attained at z = 1:
1094                 f = (a_up + a_add) * (a_up + a_add);
1095                 if(f > best)
1096                 {
1097                         best = f;
1098                         //print("top\n");
1099                 }
1100                 // OR attained at z = -1:
1101                 f = (a_up - a_add) * (a_up - a_add);
1102                 if(f > best)
1103                 {
1104                         best = f;
1105                         //print("bottom\n");
1106                 }
1107                 best = sqrt(best);
1108                 //////////////////////////////////////////////////////////////////////////////////////
1109
1110                 //print("best possible acceleration: ", ftos(best), "\n");
1111
1112                 float fxy, fz;
1113                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / autocvar_g_jetpack_maxspeed_side, 1);
1114                 if(wishvel_z - autocvar_sv_gravity > 0)
1115                         fz = bound(0, 1 - self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1116                 else
1117                         fz = bound(0, 1 + self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1118
1119                 float fvel;
1120                 fvel = vlen(wishvel);
1121                 wishvel_x *= fxy;
1122                 wishvel_y *= fxy;
1123                 wishvel_z = (wishvel_z - autocvar_sv_gravity) * fz + autocvar_sv_gravity;
1124
1125                 fvel = min(1, vlen(wishvel) / best);
1126                 if(autocvar_g_jetpack_fuel && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1127                         f = min(1, self.ammo_fuel / (autocvar_g_jetpack_fuel * frametime * fvel));
1128                 else
1129                         f = 1;
1130
1131                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1132
1133                 if (f > 0 && wishvel != '0 0 0')
1134                 {
1135                         self.velocity = self.velocity + wishvel * f * frametime;
1136                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1137                                 self.ammo_fuel -= autocvar_g_jetpack_fuel * frametime * fvel * f;
1138                         self.flags &~= FL_ONGROUND;
1139                         self.items |= IT_USING_JETPACK;
1140
1141                         // jetpack also inhibits health regeneration, but only for 1 second
1142                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1143                 }
1144         }
1145         else if (self.flags & FL_ONGROUND)
1146         {
1147                 // we get here if we ran out of ammo
1148                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1149                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1150
1151                 // walking
1152                 makevectors(self.v_angle_y * '0 1 0');
1153                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1154
1155                 if(!(self.lastflags & FL_ONGROUND))
1156                 {
1157                         if(autocvar_speedmeter)
1158                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1159                         if(self.lastground < time - 0.3)
1160                                 self.velocity = self.velocity * (1 - autocvar_sv_friction_on_land);
1161                         if(self.jumppadcount > 1)
1162                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1163                         self.jumppadcount = 0;
1164                 }
1165
1166 #ifdef LETS_TEST_FTEQCC
1167                 if(self.velocity_x || self.velocity_y)
1168                 {
1169                         // good
1170                 }
1171                 else
1172                 {
1173                         if(self.velocity_x)
1174                                 checkclient();
1175                         if(self.velocity_y)
1176                                 checkclient();
1177                 }
1178 #endif
1179
1180                 v = self.velocity;
1181                 v_z = 0;
1182                 f = vlen(v);
1183                 if(f > 0)
1184                 {
1185                         if (f < autocvar_sv_stopspeed)
1186                                 f = 1 - frametime * (autocvar_sv_stopspeed / f) * autocvar_sv_friction;
1187                         else
1188                                 f = 1 - frametime * autocvar_sv_friction;
1189                         if (f > 0)
1190                                 self.velocity = self.velocity * f;
1191                         else
1192                                 self.velocity = '0 0 0';
1193                 }
1194
1195                 // acceleration
1196                 wishdir = normalize(wishvel);
1197                 wishspeed = vlen(wishvel);
1198                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1199                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1200                 if (self.crouch)
1201                         wishspeed = wishspeed * 0.5;
1202                 if (time >= self.teleport_time)
1203                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0);
1204         }
1205         else
1206         {
1207                 float wishspeed0;
1208                 // we get here if we ran out of ammo
1209                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1210                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1211
1212                 if(maxspd_mod < 1)
1213                 {
1214                         maxairspd = autocvar_sv_maxairspeed*maxspd_mod;
1215                         airaccel = autocvar_sv_airaccelerate*maxspd_mod;
1216                 }
1217                 else
1218                 {
1219                         maxairspd = autocvar_sv_maxairspeed;
1220                         airaccel = autocvar_sv_airaccelerate;
1221                 }
1222                 // airborn
1223                 makevectors(self.v_angle_y * '0 1 0');
1224                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1225                 // acceleration
1226                 wishdir = normalize(wishvel);
1227                 wishspeed = wishspeed0 = vlen(wishvel);
1228                 if (wishspeed0 > self.stat_sv_maxspeed*maxspd_mod)
1229                         wishspeed0 = self.stat_sv_maxspeed*maxspd_mod;
1230                 if (wishspeed > maxairspd)
1231                         wishspeed = maxairspd;
1232                 if (self.crouch)
1233                         wishspeed = wishspeed * 0.5;
1234                 if (time >= self.teleport_time)
1235                 {
1236                         float accelerating;
1237                         float wishspeed2;
1238                         float airaccelqw;
1239                         float strafity;
1240
1241                         airaccelqw = self.stat_sv_airaccel_qw;
1242                         accelerating = (self.velocity * wishdir > 0);
1243                         wishspeed2 = wishspeed;
1244
1245                         // CPM
1246                         if(autocvar_sv_airstopaccelerate)
1247                         {
1248                                 vector curdir;
1249                                 curdir = self.velocity;
1250                                 curdir_z = 0;
1251                                 curdir = normalize(curdir);
1252                                 airaccel = airaccel + (autocvar_sv_airstopaccelerate*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1253                         }
1254                         // note that for straight forward jumping:
1255                         // step = accel * frametime * wishspeed0;
1256                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1257                         // -->
1258                         // dv/dt = accel * maxspeed (when slow)
1259                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1260                         // log dv/dt = logaccel + logmaxspeed (when slow)
1261                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1262                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1263                         if(autocvar_sv_maxairstrafespeed)
1264                                 wishspeed = min(wishspeed, GeomLerp(autocvar_sv_maxairspeed*maxspd_mod, strafity, autocvar_sv_maxairstrafespeed*maxspd_mod));
1265                         if(autocvar_sv_airstrafeaccelerate)
1266                                 airaccel = GeomLerp(airaccel, strafity, autocvar_sv_airstrafeaccelerate*maxspd_mod);
1267                         if(self.stat_sv_airstrafeaccel_qw)
1268                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1269                         // !CPM
1270
1271                         if(autocvar_sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1272                                 PM_AirAccelerate(wishdir, wishspeed);
1273                         else
1274                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, autocvar_sv_airaccel_sideways_friction / maxairspd, self.stat_sv_airspeedlimit_nonqw);
1275
1276                         if(autocvar_sv_aircontrol)
1277                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1278                 }
1279         }
1280
1281         if((g_cts || g_race) && self.classname != "observer") {
1282                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1283                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1284                         speedaward_holder = self.netname;
1285                         speedaward_uid = self.crypto_idfp;
1286                         speedaward_lastupdate = time;
1287                 }
1288                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1289                         string rr;
1290                         if(g_cts)
1291                                 rr = CTS_RECORD;
1292                         else
1293                                 rr = RACE_RECORD;
1294                         race_send_speedaward(MSG_ALL);
1295                         speedaward_lastsent = speedaward_speed;
1296                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "") {
1297                                 speedaward_alltimebest = speedaward_speed;
1298                                 speedaward_alltimebest_holder = speedaward_holder;
1299                                 speedaward_alltimebest_uid = speedaward_uid;
1300                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1301                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
1302                                 race_send_speedaward_alltimebest(MSG_ALL);
1303                         }
1304                 }
1305         }
1306
1307         float xyspeed;
1308         xyspeed = vlen('1 0 0' * self.velocity_x + '0 1 0' * self.velocity_y);
1309         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge && autocvar_g_balance_nex_charge_velocity_rate && xyspeed > autocvar_g_balance_nex_charge_minspeed)
1310         {
1311                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1312                 xyspeed = min(xyspeed, autocvar_g_balance_nex_charge_maxspeed);
1313                 f = (xyspeed - autocvar_g_balance_nex_charge_minspeed) / (autocvar_g_balance_nex_charge_maxspeed - autocvar_g_balance_nex_charge_minspeed);
1314                 // add the extra charge
1315                 self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_velocity_rate * f * frametime);
1316         }
1317 :end
1318         if(self.flags & FL_ONGROUND)
1319                 self.lastground = time;
1320
1321         self.lastflags = self.flags;
1322         self.lastclassname = self.classname;
1323 };