qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.v_angle = oldself.v_angle;
 159         self.avelocity = oldself.avelocity;
 160         self.classname = "body";
 161         self.damageforcescale = oldself.damageforcescale;
 162         self.effects = oldself.effects;
 163         self.glowmod = oldself.glowmod;
 164         self.event_damage = oldself.event_damage;
 165         self.anim_state = oldself.anim_state;
 166         self.anim_time = oldself.anim_time;
 167         self.anim_lower_action = oldself.anim_lower_action;
 168         self.anim_lower_time = oldself.anim_lower_time;
 169         self.anim_upper_action = oldself.anim_upper_action;
 170         self.anim_upper_time = oldself.anim_upper_time;
 171         self.anim_implicit_state = oldself.anim_implicit_state;
 172         self.anim_implicit_time = oldself.anim_implicit_time;
 173         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 174         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 175         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 176         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 177         self.dphitcontentsmask = oldself.dphitcontentsmask;
 178         self.death_time = oldself.death_time;
 179         self.pain_finished = oldself.pain_finished;
 180         self.health = oldself.health;
 181         self.armorvalue = oldself.armorvalue;
 182         self.armortype = oldself.armortype;
 183         self.model = oldself.model;
 184         self.modelindex = oldself.modelindex;
 185         self.skin = oldself.skin;
 186         self.species = oldself.species;
 187         self.movetype = oldself.movetype;
 188         self.solid = oldself.solid;
 189         self.ballistics_density = oldself.ballistics_density;
 190         self.takedamage = oldself.takedamage;
 191         self.customizeentityforclient = oldself.customizeentityforclient;
 192         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 193         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 194         if (keepvelocity == 1)
 195                 self.velocity = oldself.velocity;
 196         self.oldvelocity = self.velocity;
 197         self.alpha = oldself.alpha;
 198         self.fade_time = oldself.fade_time;
 199         self.fade_rate = oldself.fade_rate;
 200         //self.weapon = oldself.weapon;
 201         setorigin(self, oldself.origin);
 202         setsize(self, oldself.mins, oldself.maxs);
 203         self.prevorigin = oldself.origin;
 204         self.reset = SUB_Remove;
 205
 206         Drag_MoveDrag(oldself, self);
 207
 208         if(self.colormap <= maxclients && self.colormap > 0)
 209                 self.colormap = 1024 + oldself.clientcolors;
 210
 211         CSQCMODEL_AUTOINIT();
 212         self.CopyBody_nextthink = oldself.nextthink;
 213         self.CopyBody_think = oldself.think;
 214         self.nextthink = time;
 215         self.think = CopyBody_Think;
 216         // "bake" the current animation frame for clones (they don't get clientside animation)
 217         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 218
 219         self = oldself;
 220 }
 221
 222 float player_getspecies()
 223 {
 224         float s;
 225         get_model_parameters(self.model, self.skin);
 226         s = get_model_parameters_species;
 227         get_model_parameters(string_null, 0);
 228         if(s < 0)
 229                 return SPECIES_HUMAN;
 230         return s;
 231 }
 232
 233 void player_setupanimsformodel()
 234 {
 235         // load animation info
 236         animdecide_init(self);
 237         animdecide_setstate(self, 0, FALSE);
 238 }
 239
 240 void player_anim (void)
 241 {
 242         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 243         if(self.deadflag && !deadbits)
 244                 if(random() < 0.5)
 245                         deadbits = ANIMSTATE_DEAD1;
 246                 else
 247                         deadbits = ANIMSTATE_DEAD2;
 248         float animbits = deadbits;
 249         if(self.freezetag_frozen)
 250                 animbits |= ANIMSTATE_FROZEN;
 251         if(self.crouch)
 252                 animbits |= ANIMSTATE_DUCK;
 253         animdecide_setstate(self, animbits, FALSE);
 254         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 255
 256         if (self.weaponentity)
 257         {
 258                 updateanim(self.weaponentity);
 259                 if (!self.weaponentity.animstate_override)
 260                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 261         }
 262 }
 263
 264 void SpawnThrownWeapon (vector org, float w)
 265 {
 266         if(self.weapons & WepSet_FromWeapon(self.weapon))
 267                 if(W_IsWeaponThrowable(self.weapon))
 268                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 269 }
 270
 271 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 272 {
 273         float take, save;
 274         vector v;
 275         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 276
 277         // damage resistance (ignore most of the damage from a bullet or similar)
 278         damage = max(damage - 5, 1);
 279
 280         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 281         take = v_x;
 282         save = v_y;
 283
 284         if(sound_allowed(MSG_BROADCAST, attacker))
 285         {
 286                 if (save > 10)
 287                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 288                 else if (take > 30)
 289                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 290                 else if (take > 10)
 291                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 292         }
 293
 294         if (take > 50)
 295                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 296         if (take > 100)
 297                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 298
 299         if (!(self.flags & FL_GODMODE))
 300         {
 301                 self.armorvalue = self.armorvalue - save;
 302                 self.health = self.health - take;
 303                 // pause regeneration for 5 seconds
 304                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 305         }
 306         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 307         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 308         self.dmg_inflictor = inflictor;
 309
 310         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 311         {
 312                 // don't use any animations as a gib
 313                 self.frame = 0;
 314                 // view just above the floor
 315                 self.view_ofs = '0 0 4';
 316
 317                 Violence_GibSplash(self, 1, 1, attacker);
 318                 self.alpha = -1;
 319                 self.solid = SOLID_NOT; // restore later
 320                 self.takedamage = DAMAGE_NO; // restore later
 321                 self.damagedbycontents = FALSE;
 322         }
 323 }
 324
 325 void ClientKill_Now_TeamChange();
 326
 327 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 328 {
 329         float take, save, waves, sdelay, dh, da, j;
 330         vector v;
 331         float valid_damage_for_weaponstats;
 332         float excess;
 333
 334         dh = max(self.health, 0);
 335         da = max(self.armorvalue, 0);
 336
 337         if(!DEATH_ISSPECIAL(deathtype))
 338         {
 339                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 340                 if(self != attacker)
 341                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 342         }
 343
 344         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 345         {
 346                 // tuba causes blood to come out of the ears
 347                 vector ear1, ear2;
 348                 vector d;
 349                 float f;
 350                 ear1 = self.origin;
 351                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 352                 ear2 = ear1;
 353                 makevectors(self.angles);
 354                 ear1 += v_right * -10;
 355                 ear2 += v_right * +10;
 356                 d = inflictor.origin - self.origin;
 357                 if (d)
 358                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 359                 else
 360                         f = 0;  // Assum ecenter.
 361                 force = v_right * vlen(force);
 362                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 363                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 364                 if(f > 0)
 365                 {
 366                         hitloc = ear1;
 367                         force = force * -1;
 368                 }
 369                 else
 370                 {
 371                         hitloc = ear2;
 372                         // force is already good
 373                 }
 374         }
 375         else
 376                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 377
 378
 379         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 380         take = v_x;
 381         save = v_y;
 382
 383         if(attacker == self)
 384         {
 385                 // don't reset pushltime for self damage as it may be an attempt to
 386                 // escape a lava pit or similar
 387                 //self.pushltime = 0;
 388                 self.istypefrag = 0;
 389         }
 390         else if(IS_PLAYER(attacker))
 391         {
 392                 self.pusher = attacker;
 393                 self.pushltime = time + autocvar_g_maxpushtime;
 394                 self.istypefrag = self.BUTTON_CHAT;
 395         }
 396         else if(time < self.pushltime)
 397         {
 398                 attacker = self.pusher;
 399                 self.pushltime = max(self.pushltime, time + 0.6);
 400         }
 401         else
 402         {
 403                 self.pushltime = 0;
 404                 self.istypefrag = 0;
 405         }
 406
 407         frag_inflictor = inflictor;
 408         frag_attacker = attacker;
 409         frag_target = self;
 410         frag_damage = damage;
 411         damage_take = take;
 412         damage_save = save;
 413         damage_force = force;
 414         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 415         take = bound(0, damage_take, self.health);
 416         save = bound(0, damage_save, self.armorvalue);
 417         excess = max(0, damage - take - save);
 418
 419         if(sound_allowed(MSG_BROADCAST, attacker))
 420         {
 421                 if (save > 10)
 422                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 423                 else if (take > 30)
 424                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 425                 else if (take > 10)
 426                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 427         }
 428
 429         if (take > 50)
 430                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 431         if (take > 100)
 432                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 433
 434         if (time >= self.spawnshieldtime)
 435         {
 436                 if (!(self.flags & FL_GODMODE))
 437                 {
 438                         self.armorvalue = self.armorvalue - save;
 439                         self.health = self.health - take;
 440                         // pause regeneration for 5 seconds
 441                         if(take)
 442                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 443
 444                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 445                         {
 446                                 self.pain_finished = time + 0.5;        //Supajoe
 447
 448                                 if(autocvar_sv_gentle < 1) {
 449                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 450                                         {
 451                                                 if (!self.animstate_override)
 452                                                 {
 453                                                         if (random() > 0.5)
 454                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 455                                                         else
 456                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 457                                                 }
 458                                         }
 459
 460                                         if(sound_allowed(MSG_BROADCAST, attacker))
 461                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 462                                         if(self.health > 1)
 463                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 464                                         {
 465                                                 if(deathtype == DEATH_FALL)
 466                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 467                                                 else if(self.health > 75) // TODO make a "gentle" version?
 468                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 469                                                 else if(self.health > 50)
 470                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 471                                                 else if(self.health > 25)
 472                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 473                                                 else
 474                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 475                                         }
 476                                 }
 477
 478                                 // throw off bot aim temporarily
 479                                 float shake;
 480                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 481                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 482                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 483                         }
 484                 }
 485                 else
 486                         self.max_armorvalue += (save + take);
 487         }
 488         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 489         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 490         self.dmg_inflictor = inflictor;
 491
 492         float abot, vbot, awep;
 493         abot = (IS_BOT_CLIENT(attacker));
 494         vbot = (IS_BOT_CLIENT(self));
 495
 496         valid_damage_for_weaponstats = 0;
 497         awep = 0;
 498
 499         if(vbot || IS_REAL_CLIENT(self))
 500         if(abot || IS_REAL_CLIENT(attacker))
 501         if(attacker && self != attacker)
 502         if(DIFF_TEAM(self, attacker))
 503         {
 504                 if(DEATH_ISSPECIAL(deathtype))
 505                         awep = attacker.weapon;
 506                 else
 507                         awep = DEATH_WEAPONOF(deathtype);
 508                 valid_damage_for_weaponstats = 1;
 509         }
 510
 511         if(valid_damage_for_weaponstats)
 512         {
 513                 dh = dh - max(self.health, 0);
 514                 da = da - max(self.armorvalue, 0);
 515                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 516         }
 517
 518         if (self.health < 1)
 519         {
 520                 float defer_ClientKill_Now_TeamChange;
 521                 defer_ClientKill_Now_TeamChange = FALSE;
 522
 523                 if(self.alivetime)
 524                 {
 525                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 526                         self.alivetime = 0;
 527                 }
 528
 529                 if(valid_damage_for_weaponstats)
 530                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 531
 532                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 533                 if(sound_allowed(MSG_BROADCAST, attacker))
 534                 {
 535                         if(deathtype == DEATH_DROWN)
 536                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 537                         else
 538                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 539                 }
 540
 541                 // get rid of kill indicator
 542                 if(self.killindicator)
 543                 {
 544                         remove(self.killindicator);
 545                         self.killindicator = world;
 546                         if(self.killindicator_teamchange)
 547                                 defer_ClientKill_Now_TeamChange = TRUE;
 548
 549                         if(self.classname == "body")
 550                         if(deathtype == DEATH_KILL)
 551                         {
 552                                 // for the lemmings fans, a small harmless explosion
 553                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 554                         }
 555                 }
 556
 557                 // print an obituary message
 558                 Obituary (attacker, inflictor, self, deathtype);
 559                 race_PreDie();
 560
 561         // increment frag counter for used weapon type
 562         float w;
 563         w = DEATH_WEAPONOF(deathtype);
 564         if(WEP_VALID(w))
 565         if(accuracy_isgooddamage(attacker, self))
 566         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 567
 568                 frag_attacker = attacker;
 569                 frag_inflictor = inflictor;
 570                 frag_target = self;
 571                 frag_deathtype = deathtype;
 572                 MUTATOR_CALLHOOK(PlayerDies);
 573
 574                 weapon_action(self.weapon, WR_PLAYERDEATH);
 575
 576                 RemoveGrapplingHook(self);
 577
 578                 Portal_ClearAllLater(self);
 579
 580                 if(IS_REAL_CLIENT(self))
 581                 {
 582                         self.fixangle = TRUE;
 583                         //msg_entity = self;
 584                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 585                         //WriteAngle (MSG_ONE, self.v_angle_x);
 586                         //WriteAngle (MSG_ONE, self.v_angle_y);
 587                         //WriteAngle (MSG_ONE, 80);
 588                 }
 589
 590                 if(defer_ClientKill_Now_TeamChange)
 591                         ClientKill_Now_TeamChange(); // can turn player into spectator
 592
 593                 // player could have been miraculously resuscitated ;)
 594                 // e.g. players in freezetag get frozen, they don't really die
 595                 if(self.health >= 1 || !IS_PLAYER(self))
 596                         return;
 597
 598                 // when we get here, player actually dies
 599
 600                 // clear waypoints
 601                 WaypointSprite_PlayerDead();
 602                 // throw a weapon
 603                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 604
 605                 // become fully visible
 606                 self.alpha = default_player_alpha;
 607                 // make the corpse upright (not tilted)
 608                 self.angles_x = 0;
 609                 self.angles_z = 0;
 610                 // don't spin
 611                 self.avelocity = '0 0 0';
 612                 // view from the floor
 613                 self.view_ofs = '0 0 -8';
 614                 // toss the corpse
 615                 self.movetype = MOVETYPE_TOSS;
 616                 // shootable corpse
 617                 self.solid = SOLID_CORPSE;
 618                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 619                 // don't stick to the floor
 620                 self.flags &= ~FL_ONGROUND;
 621                 // dying animation
 622                 self.deadflag = DEAD_DYING;
 623                 // when to allow respawn
 624                 sdelay = 0;
 625                 waves = 0;
 626                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 627                 if(!sdelay)
 628                 {
 629                         if(g_cts)
 630                                 sdelay = 0; // no respawn delay in CTS
 631                         else
 632                                 sdelay = autocvar_g_respawn_delay;
 633                 }
 634                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 635                 if(!waves)
 636                         waves = autocvar_g_respawn_waves;
 637                 if(waves)
 638                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 639                 else
 640                         self.respawn_time = time + sdelay;
 641                 if(autocvar_g_respawn_delay_max > sdelay)
 642                         self.respawn_time_max = time + autocvar_g_respawn_delay_max;
 643                 else
 644                         self.respawn_time_max = self.respawn_time;
 645                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 646                         self.respawn_countdown = 10; // first number to count down from is 10
 647                 else
 648                         self.respawn_countdown = -1; // do not count down
 649
 650                 if(g_cts || autocvar_g_forced_respawn)
 651                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 652
 653                 self.death_time = time;
 654                 if (random() < 0.5)
 655                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 656                 else
 657                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 658                 if (self.maxs_z > 5)
 659                 {
 660                         self.maxs_z = 5;
 661                         setsize(self, self.mins, self.maxs);
 662                 }
 663                 // set damage function to corpse damage
 664                 self.event_damage = PlayerCorpseDamage;
 665                 // call the corpse damage function just in case it wants to gib
 666                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 667                 // set up to fade out later
 668                 SUB_SetFade (self, time + 6 + random (), 1);
 669
 670                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 671                         // remove corpse
 672                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 673                 }
 674
 675                 // reset fields the weapons may use just in case
 676                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 677                 {
 678                         weapon_action(j, WR_RESETPLAYER);
 679                         ATTACK_FINISHED_FOR(self, j) = 0;
 680                 }
 681         }
 682 }
 683
 684 .float muted; // to be used by prvm_edictset server playernumber muted 1
 685 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 686 // message "": do not say, just test flood control
 687 // return value:
 688 //   1 = accept
 689 //   0 = reject
 690 //  -1 = fake accept
 691 {
 692         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 693         float flood;
 694         var .float flood_field;
 695         entity head;
 696         float ret;
 697         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 698
 699         if(!teamsay && !privatesay)
 700                 if(substring(msgin, 0, 1) == " ")
 701                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 702
 703         msgin = formatmessage(msgin);
 704
 705         if (!IS_PLAYER(source))
 706                 colorstr = "^0"; // black for spectators
 707         else if(teamplay)
 708                 colorstr = Team_ColorCode(source.team);
 709         else
 710         {
 711                 colorstr = "";
 712                 teamsay = FALSE;
 713         }
 714
 715         if(intermission_running)
 716                 teamsay = FALSE;
 717
 718         if(msgin != "")
 719                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 720
 721         /*
 722          * using bprint solves this... me stupid
 723         // how can we prevent the message from appearing in a listen server?
 724         // for now, just give "say" back and only handle say_team
 725         if(!teamsay)
 726         {
 727                 clientcommand(self, strcat("say ", msgin));
 728                 return;
 729         }
 730         */
 731
 732         if(autocvar_g_chat_teamcolors)
 733                 namestr = playername(source);
 734         else
 735                 namestr = source.netname;
 736
 737         if(msgin != "")
 738         {
 739                 if(privatesay)
 740                 {
 741                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 742                         privatemsgprefixlen = strlen(msgstr);
 743                         msgstr = strcat(msgstr, msgin);
 744                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 745                         if(autocvar_g_chat_teamcolors)
 746                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 747                         else
 748                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 749                 }
 750                 else if(teamsay)
 751                 {
 752                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 753                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 754                 }
 755                 else
 756                 {
 757                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 758                         cmsgstr = "";
 759                 }
 760                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 761         }
 762         else
 763         {
 764                 msgstr = cmsgstr = "";
 765         }
 766
 767         fullmsgstr = msgstr;
 768         fullcmsgstr = cmsgstr;
 769
 770         // FLOOD CONTROL
 771         flood = 0;
 772         flood_field = floodcontrol_chat;
 773         if(floodcontrol)
 774         {
 775                 float flood_spl;
 776                 float flood_burst;
 777                 float flood_lmax;
 778                 float lines;
 779                 if(privatesay)
 780                 {
 781                         flood_spl = autocvar_g_chat_flood_spl_tell;
 782                         flood_burst = autocvar_g_chat_flood_burst_tell;
 783                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 784                         flood_field = floodcontrol_chattell;
 785                 }
 786                 else if(teamsay)
 787                 {
 788                         flood_spl = autocvar_g_chat_flood_spl_team;
 789                         flood_burst = autocvar_g_chat_flood_burst_team;
 790                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 791                         flood_field = floodcontrol_chatteam;
 792                 }
 793                 else
 794                 {
 795                         flood_spl = autocvar_g_chat_flood_spl;
 796                         flood_burst = autocvar_g_chat_flood_burst;
 797                         flood_lmax = autocvar_g_chat_flood_lmax;
 798                         flood_field = floodcontrol_chat;
 799                 }
 800                 flood_burst = max(0, flood_burst - 1);
 801                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 802
 803                 // do flood control for the default line size
 804                 if(msgstr != "")
 805                 {
 806                         getWrappedLine_remaining = msgstr;
 807                         msgstr = "";
 808                         lines = 0;
 809                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 810                         {
 811                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 812                                 ++lines;
 813                         }
 814                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 815
 816                         if(getWrappedLine_remaining != "")
 817                         {
 818                                 msgstr = strcat(msgstr, "\n");
 819                                 flood = 2;
 820                         }
 821
 822                         if(time >= source.flood_field)
 823                         {
 824                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 825                         }
 826                         else
 827                         {
 828                                 flood = 1;
 829                                 msgstr = fullmsgstr;
 830                         }
 831                 }
 832                 else
 833                 {
 834                         if(time >= source.flood_field)
 835                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 836                         else
 837                                 flood = 1;
 838                 }
 839
 840                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 841                         source.flood_field = flood = 0;
 842         }
 843
 844         if(flood == 2) // cannot happen for empty msgstr
 845         {
 846                 if(autocvar_g_chat_flood_notify_flooder)
 847                 {
 848                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 849                         sourcecmsgstr = "";
 850                 }
 851                 else
 852                 {
 853                         sourcemsgstr = fullmsgstr;
 854                         sourcecmsgstr = fullcmsgstr;
 855                 }
 856                 cmsgstr = "";
 857         }
 858         else
 859         {
 860                 sourcemsgstr = msgstr;
 861                 sourcecmsgstr = cmsgstr;
 862         }
 863
 864         if(!privatesay)
 865         if (!IS_PLAYER(source))
 866         {
 867                 if (!intermission_running)
 868                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 869                                 teamsay = -1; // spectators
 870         }
 871
 872         if(flood)
 873                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 874
 875         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 876         if(privatesay)
 877                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 878
 879         if(source.muted)
 880         {
 881                 // always fake the message
 882                 ret = -1;
 883         }
 884         else if(flood == 1)
 885         {
 886                 if(autocvar_g_chat_flood_notify_flooder)
 887                 {
 888                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 889                         ret = 0;
 890                 }
 891                 else
 892                         ret = -1;
 893         }
 894         else
 895         {
 896                 ret = 1;
 897         }
 898
 899         if(sourcemsgstr != "" && ret != 0)
 900         {
 901                 if(ret < 0) // faked message, because the player is muted
 902                 {
 903                         sprint(source, sourcemsgstr);
 904                         if(sourcecmsgstr != "" && !privatesay)
 905                                 centerprint(source, sourcecmsgstr);
 906                 }
 907                 else if(privatesay) // private message, between 2 people only
 908                 {
 909                         sprint(source, sourcemsgstr);
 910                         sprint(privatesay, msgstr);
 911                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 912                         if(cmsgstr != "")
 913                                 centerprint(privatesay, cmsgstr);
 914                 }
 915                 else if(teamsay > 0) // team message, only sent to team mates
 916                 {
 917                         sprint(source, sourcemsgstr);
 918                         dedicated_print(msgstr); // send to server console too
 919                         if(sourcecmsgstr != "")
 920                                 centerprint(source, sourcecmsgstr);
 921                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 922                                 if(head != source)
 923                                 {
 924                                         sprint(head, msgstr);
 925                                         if(cmsgstr != "")
 926                                                 centerprint(head, cmsgstr);
 927                                 }
 928                 }
 929                 else if(teamsay < 0) // spectator message, only sent to spectators
 930                 {
 931                         sprint(source, sourcemsgstr);
 932                         dedicated_print(msgstr); // send to server console too
 933                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
 934                                 if(head != source)
 935                                         sprint(head, msgstr);
 936                 }
 937                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 938                 {
 939                         sprint(source, sourcemsgstr);
 940                         dedicated_print(msgstr); // send to server console too
 941                         FOR_EACH_REALCLIENT(head)
 942                                 if(head != source)
 943                                         sprint(head, msgstr);
 944                 }
 945                 else
 946                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 947         }
 948
 949         return ret;
 950 }
 951
 952 float GetVoiceMessageVoiceType(string type)
 953 {
 954         if(type == "taunt")
 955                 return VOICETYPE_TAUNT;
 956         if(type == "teamshoot")
 957                 return VOICETYPE_LASTATTACKER;
 958         return VOICETYPE_TEAMRADIO;
 959 }
 960
 961 string allvoicesamples;
 962 .string GetVoiceMessageSampleField(string type)
 963 {
 964         GetPlayerSoundSampleField_notFound = 0;
 965         switch(type)
 966         {
 967 #define _VOICEMSG(m) case #m: return playersound_##m;
 968                 ALLVOICEMSGS
 969 #undef _VOICEMSG
 970         }
 971         GetPlayerSoundSampleField_notFound = 1;
 972         return playersound_taunt;
 973 }
 974
 975 .string GetPlayerSoundSampleField(string type)
 976 {
 977         GetPlayerSoundSampleField_notFound = 0;
 978         switch(type)
 979         {
 980 #define _VOICEMSG(m) case #m: return playersound_##m;
 981                 ALLPLAYERSOUNDS
 982 #undef _VOICEMSG
 983         }
 984         GetPlayerSoundSampleField_notFound = 1;
 985         return playersound_taunt;
 986 }
 987
 988 void PrecacheGlobalSound(string samplestring)
 989 {
 990         float n, i;
 991         tokenize_console(samplestring);
 992         n = stof(argv(1));
 993         if(n > 0)
 994         {
 995                 for(i = 1; i <= n; ++i)
 996                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 997         }
 998         else
 999         {
1000                 precache_sound(strcat(argv(0), ".wav"));
1001         }
1002 }
1003
1004 void PrecachePlayerSounds(string f)
1005 {
1006         float fh;
1007         string s;
1008         fh = fopen(f, FILE_READ);
1009         if(fh < 0)
1010                 return;
1011         while((s = fgets(fh)))
1012         {
1013                 if(tokenize_console(s) != 3)
1014                 {
1015                         dprint("Invalid sound info line: ", s, "\n");
1016                         continue;
1017                 }
1018                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1019         }
1020         fclose(fh);
1021
1022         if (!allvoicesamples)
1023         {
1024 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1025                 ALLVOICEMSGS
1026 #undef _VOICEMSG
1027                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1028         }
1029 }
1030
1031 void ClearPlayerSounds()
1032 {
1033 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1034         ALLPLAYERSOUNDS
1035         ALLVOICEMSGS
1036 #undef _VOICEMSG
1037 }
1038
1039 float LoadPlayerSounds(string f, float first)
1040 {
1041         float fh;
1042         string s;
1043         var .string field;
1044         fh = fopen(f, FILE_READ);
1045         if(fh < 0)
1046         {
1047                 dprint("Player sound file not found: ", f, "\n");
1048                 return 0;
1049         }
1050         while((s = fgets(fh)))
1051         {
1052                 if(tokenize_console(s) != 3)
1053                         continue;
1054                 field = GetPlayerSoundSampleField(argv(0));
1055                 if(GetPlayerSoundSampleField_notFound)
1056                         field = GetVoiceMessageSampleField(argv(0));
1057                 if(GetPlayerSoundSampleField_notFound)
1058                         continue;
1059                 if(self.field)
1060                         strunzone(self.field);
1061                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1062         }
1063         fclose(fh);
1064         return 1;
1065 }
1066
1067 .float modelindex_for_playersound;
1068 .float skin_for_playersound;
1069 void UpdatePlayerSounds()
1070 {
1071         if(self.modelindex == self.modelindex_for_playersound)
1072         if(self.skin == self.skin_for_playersound)
1073                 return;
1074         self.modelindex_for_playersound = self.modelindex;
1075         self.skin_for_playersound = self.skin;
1076         ClearPlayerSounds();
1077         LoadPlayerSounds("sound/player/default.sounds", 1);
1078         if(!autocvar_g_debug_defaultsounds)
1079                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1080                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1081 }
1082
1083 void FakeGlobalSound(string sample, float chan, float voicetype)
1084 {
1085         float n;
1086         float tauntrand;
1087
1088         if(sample == "")
1089                 return;
1090
1091         tokenize_console(sample);
1092         n = stof(argv(1));
1093         if(n > 0)
1094                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1095         else
1096                 sample = strcat(argv(0), ".wav"); // randomization
1097
1098         switch(voicetype)
1099         {
1100                 case VOICETYPE_LASTATTACKER_ONLY:
1101                         break;
1102                 case VOICETYPE_LASTATTACKER:
1103                         if(self.pusher)
1104                         {
1105                                 msg_entity = self;
1106                                 if(IS_REAL_CLIENT(msg_entity))
1107                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1108                         }
1109                         break;
1110                 case VOICETYPE_TEAMRADIO:
1111                         msg_entity = self;
1112                         if(msg_entity.cvar_cl_voice_directional == 1)
1113                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1114                         else
1115                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1116                         break;
1117                 case VOICETYPE_AUTOTAUNT:
1118                         if(!sv_autotaunt)
1119                                 break;
1120                         if(!sv_taunt)
1121                                 break;
1122                         if(autocvar_sv_gentle)
1123                                 break;
1124                         tauntrand = random();
1125                         msg_entity = self;
1126                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1127                         {
1128                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1129                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1130                                 else
1131                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1132                         }
1133                         break;
1134                 case VOICETYPE_TAUNT:
1135                         if(IS_PLAYER(self))
1136                                 if(self.deadflag == DEAD_NO)
1137                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1138                         if(!sv_taunt)
1139                                 break;
1140                         if(autocvar_sv_gentle)
1141                                 break;
1142                         msg_entity = self;
1143                         if (msg_entity.cvar_cl_voice_directional >= 1)
1144                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1145                         else
1146                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1147                         break;
1148                 case VOICETYPE_PLAYERSOUND:
1149                         msg_entity = self;
1150                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1151                         break;
1152                 default:
1153                         backtrace("Invalid voice type!");
1154                         break;
1155         }
1156 }
1157
1158 void GlobalSound(string sample, float chan, float voicetype)
1159 {
1160         float n;
1161         float tauntrand;
1162
1163         if(sample == "")
1164                 return;
1165
1166         tokenize_console(sample);
1167         n = stof(argv(1));
1168         if(n > 0)
1169                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1170         else
1171                 sample = strcat(argv(0), ".wav"); // randomization
1172
1173         switch(voicetype)
1174         {
1175                 case VOICETYPE_LASTATTACKER_ONLY:
1176                         if(self.pusher)
1177                         {
1178                                 msg_entity = self.pusher;
1179                                 if(IS_REAL_CLIENT(msg_entity))
1180                                 {
1181                                         if(msg_entity.cvar_cl_voice_directional == 1)
1182                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1183                                         else
1184                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1185                                 }
1186                         }
1187                         break;
1188                 case VOICETYPE_LASTATTACKER:
1189                         if(self.pusher)
1190                         {
1191                                 msg_entity = self.pusher;
1192                                 if(IS_REAL_CLIENT(msg_entity))
1193                                 {
1194                                         if(msg_entity.cvar_cl_voice_directional == 1)
1195                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1196                                         else
1197                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1198                                 }
1199                                 msg_entity = self;
1200                                 if(IS_REAL_CLIENT(msg_entity))
1201                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1202                         }
1203                         break;
1204                 case VOICETYPE_TEAMRADIO:
1205                         FOR_EACH_REALCLIENT(msg_entity)
1206                                 if(!teamplay || msg_entity.team == self.team)
1207                                 {
1208                                         if(msg_entity.cvar_cl_voice_directional == 1)
1209                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1210                                         else
1211                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1212                                 }
1213                         break;
1214                 case VOICETYPE_AUTOTAUNT:
1215                         if(!sv_autotaunt)
1216                                 break;
1217                         if(!sv_taunt)
1218                                 break;
1219                         if(autocvar_sv_gentle)
1220                                 break;
1221                         tauntrand = random();
1222                         FOR_EACH_REALCLIENT(msg_entity)
1223                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1224                                 {
1225                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1226                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1227                                         else
1228                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1229                                 }
1230                         break;
1231                 case VOICETYPE_TAUNT:
1232                         if(IS_PLAYER(self))
1233                                 if(self.deadflag == DEAD_NO)
1234                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1235                         if(!sv_taunt)
1236                                 break;
1237                         if(autocvar_sv_gentle)
1238                                 break;
1239                         FOR_EACH_REALCLIENT(msg_entity)
1240                         {
1241                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1242                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1243                                 else
1244                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1245                         }
1246                         break;
1247                 case VOICETYPE_PLAYERSOUND:
1248                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1249                         break;
1250                 default:
1251                         backtrace("Invalid voice type!");
1252                         break;
1253         }
1254 }
1255
1256 void PlayerSound(.string samplefield, float chan, float voicetype)
1257 {
1258         GlobalSound(self.samplefield, chan, voicetype);
1259 }
1260
1261 void VoiceMessage(string type, string msg)
1262 {
1263         var .string sample;
1264         float voicetype, ownteam;
1265         float flood;
1266         sample = GetVoiceMessageSampleField(type);
1267
1268         if(GetPlayerSoundSampleField_notFound)
1269         {
1270                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1271                 return;
1272         }
1273
1274         voicetype = GetVoiceMessageVoiceType(type);
1275         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1276
1277         flood = Say(self, ownteam, world, msg, 1);
1278
1279         if (flood > 0)
1280                 GlobalSound(self.sample, CH_VOICE, voicetype);
1281         else if (flood < 0)
1282                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1283 }
1284
1285 void MoveToTeam(entity client, float team_colour, float type)
1286 {
1287         float lockteams_backup;
1288
1289         lockteams_backup = lockteams;  // backup any team lock
1290
1291         lockteams = 0;  // disable locked teams
1292
1293         TeamchangeFrags(client);  // move the players frags
1294         SetPlayerColors(client, team_colour - 1);  // set the players colour
1295         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1296
1297         lockteams = lockteams_backup;  // restore the team lock
1298
1299         LogTeamchange(client.playerid, client.team, type);
1300 }