qcsrc/server/cl_player.qc

   1 .entity pusher;
   2 .float pushltime;
   3 .float istypefrag;
   4
   5 .float CopyBody_nextthink;
   6 .void(void) CopyBody_think;
   7 void CopyBody_Think(void)
   8 {
   9         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
  10         {
  11                 self.CopyBody_think();
  12                 if(wasfreed(self))
  13                         return;
  14                 self.CopyBody_nextthink = self.nextthink;
  15                 self.CopyBody_think = self.think;
  16                 self.think = CopyBody_Think;
  17         }
  18         CSQCMODEL_AUTOUPDATE();
  19         self.nextthink = time;
  20 }
  21 void CopyBody(float keepvelocity)
  22 {
  23         entity oldself;
  24         if (self.effects & EF_NODRAW)
  25                 return;
  26         oldself = self;
  27         self = spawn();
  28         self.enemy = oldself;
  29         self.lip = oldself.lip;
  30         self.colormap = oldself.colormap;
  31         self.iscreature = oldself.iscreature;
  32         self.teleportable = oldself.teleportable;
  33         self.damagedbycontents = oldself.damagedbycontents;
  34         self.angles = oldself.angles;
  35         self.v_angle = oldself.v_angle;
  36         self.avelocity = oldself.avelocity;
  37         self.classname = "body";
  38         self.damageforcescale = oldself.damageforcescale;
  39         self.effects = oldself.effects;
  40         self.glowmod = oldself.glowmod;
  41         self.event_damage = oldself.event_damage;
  42         self.anim_state = oldself.anim_state;
  43         self.anim_time = oldself.anim_time;
  44         self.anim_lower_action = oldself.anim_lower_action;
  45         self.anim_lower_time = oldself.anim_lower_time;
  46         self.anim_upper_action = oldself.anim_upper_action;
  47         self.anim_upper_time = oldself.anim_upper_time;
  48         self.anim_implicit_state = oldself.anim_implicit_state;
  49         self.anim_implicit_time = oldself.anim_implicit_time;
  50         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
  51         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
  52         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
  53         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
  54         self.dphitcontentsmask = oldself.dphitcontentsmask;
  55         self.death_time = oldself.death_time;
  56         self.pain_finished = oldself.pain_finished;
  57         self.health = oldself.health;
  58         self.armorvalue = oldself.armorvalue;
  59         self.armortype = oldself.armortype;
  60         self.model = oldself.model;
  61         self.modelindex = oldself.modelindex;
  62         self.skin = oldself.skin;
  63         self.species = oldself.species;
  64         self.movetype = oldself.movetype;
  65         self.solid = oldself.solid;
  66         self.ballistics_density = oldself.ballistics_density;
  67         self.takedamage = oldself.takedamage;
  68         self.customizeentityforclient = oldself.customizeentityforclient;
  69         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
  70         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
  71         if (keepvelocity == 1)
  72                 self.velocity = oldself.velocity;
  73         self.oldvelocity = self.velocity;
  74         self.alpha = oldself.alpha;
  75         self.fade_time = oldself.fade_time;
  76         self.fade_rate = oldself.fade_rate;
  77         //self.weapon = oldself.weapon;
  78         setorigin(self, oldself.origin);
  79         setsize(self, oldself.mins, oldself.maxs);
  80         self.prevorigin = oldself.origin;
  81         self.reset = SUB_Remove;
  82
  83         Drag_MoveDrag(oldself, self);
  84
  85         if(self.colormap <= maxclients && self.colormap > 0)
  86                 self.colormap = 1024 + oldself.clientcolors;
  87
  88         CSQCMODEL_AUTOINIT();
  89         self.CopyBody_nextthink = oldself.nextthink;
  90         self.CopyBody_think = oldself.think;
  91         self.nextthink = time;
  92         self.think = CopyBody_Think;
  93         // "bake" the current animation frame for clones (they don't get clientside animation)
  94         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
  95
  96         self = oldself;
  97 }
  98
  99 float player_getspecies()
 100 {
 101         float s;
 102         get_model_parameters(self.model, self.skin);
 103         s = get_model_parameters_species;
 104         get_model_parameters(string_null, 0);
 105         if(s < 0)
 106                 return SPECIES_HUMAN;
 107         return s;
 108 }
 109
 110 void player_setupanimsformodel()
 111 {
 112         // load animation info
 113         animdecide_init(self);
 114         animdecide_setstate(self, 0, FALSE);
 115 }
 116
 117 void player_anim (void)
 118 {
 119         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 120         if(self.deadflag) {
 121                 if (!deadbits) {
 122                         // Decide on which death animation to use.
 123                         if(random() < 0.5)
 124                                 deadbits = ANIMSTATE_DEAD1;
 125                         else
 126                                 deadbits = ANIMSTATE_DEAD2;
 127                 }
 128         } else {
 129                 // Clear a previous death animation.
 130                 deadbits = 0;
 131         }
 132         float animbits = deadbits;
 133         if(self.frozen)
 134                 animbits |= ANIMSTATE_FROZEN;
 135         if(self.crouch)
 136                 animbits |= ANIMSTATE_DUCK;
 137         animdecide_setstate(self, animbits, FALSE);
 138         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 139
 140         if (self.weaponentity)
 141         {
 142                 updateanim(self.weaponentity);
 143                 if (!self.weaponentity.animstate_override)
 144                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 145         }
 146 }
 147
 148 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 149 {
 150         float take, save;
 151         vector v;
 152         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 153
 154         // damage resistance (ignore most of the damage from a bullet or similar)
 155         damage = max(damage - 5, 1);
 156
 157         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 158         take = v_x;
 159         save = v_y;
 160
 161         if(sound_allowed(MSG_BROADCAST, attacker))
 162         {
 163                 if (save > 10)
 164                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 165                 else if (take > 30)
 166                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 167                 else if (take > 10)
 168                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 169         }
 170
 171         if (take > 50)
 172                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 173         if (take > 100)
 174                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 175
 176         if (!(self.flags & FL_GODMODE))
 177         {
 178                 self.armorvalue = self.armorvalue - save;
 179                 self.health = self.health - take;
 180                 // pause regeneration for 5 seconds
 181                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 182         }
 183         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 184         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 185         self.dmg_inflictor = inflictor;
 186
 187         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 188         {
 189                 // don't use any animations as a gib
 190                 self.frame = 0;
 191                 // view just above the floor
 192                 self.view_ofs = '0 0 4';
 193
 194                 Violence_GibSplash(self, 1, 1, attacker);
 195                 self.alpha = -1;
 196                 self.solid = SOLID_NOT; // restore later
 197                 self.takedamage = DAMAGE_NO; // restore later
 198                 self.damagedbycontents = FALSE;
 199         }
 200 }
 201
 202 // g_<gametype>_str:
 203 // If 0, default is used.
 204 // If <0, 0 is used.
 205 // Otherwise, g_str (default value) is used.
 206 // For consistency, negative values there are mapped to zero too.
 207 #define GAMETYPE_DEFAULTED_SETTING(str) \
 208         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 209          (gametype_setting_tmp < 0) ? 0 : \
 210          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 211          gametype_setting_tmp)
 212
 213
 214 void calculate_player_respawn_time()
 215 {
 216         if(g_ca)
 217                 return;
 218
 219         float gametype_setting_tmp;
 220         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 221         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 222         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 223         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 224         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 225         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 226
 227         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 228         entity pl;
 229         if (teamplay)
 230         {
 231                 FOR_EACH_PLAYER(pl)
 232                         if (pl != self)
 233                                 if (pl.team == self.team)
 234                                         ++pcount;
 235                 if (sdelay_small_count == 0)
 236                         sdelay_small_count = 1;
 237                 if (sdelay_large_count == 0)
 238                         sdelay_large_count = 1;
 239         }
 240         else
 241         {
 242                 FOR_EACH_PLAYER(pl)
 243                         if (pl != self)
 244                                 ++pcount;
 245                 if (sdelay_small_count == 0)
 246                 {
 247                         if (g_cts)
 248                         {
 249                                 // Players play independently. No point in requiring enemies.
 250                                 sdelay_small_count = 1;
 251                         }
 252                         else
 253                         {
 254                                 // Players play AGAINST each other. Enemies required.
 255                                 sdelay_small_count = 2;
 256                         }
 257                 }
 258                 if (sdelay_large_count == 0)
 259                 {
 260                         if (g_cts)
 261                         {
 262                                 // Players play independently. No point in requiring enemies.
 263                                 sdelay_large_count = 1;
 264                         }
 265                         else
 266                         {
 267                                 // Players play AGAINST each other. Enemies required.
 268                                 sdelay_large_count = 2;
 269                         }
 270                 }
 271         }
 272
 273         float sdelay;
 274
 275         if (pcount <= sdelay_small_count)
 276                 sdelay = sdelay_small;
 277         else if (pcount >= sdelay_large_count)
 278                 sdelay = sdelay_large;
 279         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 280                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 281
 282         if(waves)
 283                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 284         else
 285                 self.respawn_time = time + sdelay;
 286
 287         if(sdelay < sdelay_max)
 288                 self.respawn_time_max = time + sdelay_max;
 289         else
 290                 self.respawn_time_max = self.respawn_time;
 291
 292         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 293                 self.respawn_countdown = 10; // first number to count down from is 10
 294         else
 295                 self.respawn_countdown = -1; // do not count down
 296
 297         if(autocvar_g_forced_respawn)
 298                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 299 }
 300
 301 void ClientKill_Now_TeamChange();
 302
 303 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 304 {
 305         float take, save, dh, da, j;
 306         vector v;
 307         float valid_damage_for_weaponstats;
 308         float excess;
 309
 310         dh = max(self.health, 0);
 311         da = max(self.armorvalue, 0);
 312
 313         if(!DEATH_ISSPECIAL(deathtype))
 314         {
 315                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 316                 if(self != attacker)
 317                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 318         }
 319
 320         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 321         {
 322                 // tuba causes blood to come out of the ears
 323                 vector ear1, ear2;
 324                 vector d;
 325                 float f;
 326                 ear1 = self.origin;
 327                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 328                 ear2 = ear1;
 329                 makevectors(self.angles);
 330                 ear1 += v_right * -10;
 331                 ear2 += v_right * +10;
 332                 d = inflictor.origin - self.origin;
 333                 if (d)
 334                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 335                 else
 336                         f = 0;  // Assum ecenter.
 337                 force = v_right * vlen(force);
 338                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 339                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 340                 if(f > 0)
 341                 {
 342                         hitloc = ear1;
 343                         force = force * -1;
 344                 }
 345                 else
 346                 {
 347                         hitloc = ear2;
 348                         // force is already good
 349                 }
 350         }
 351         else
 352                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 353
 354
 355         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 356         take = v_x;
 357         save = v_y;
 358
 359         if(attacker == self)
 360         {
 361                 // don't reset pushltime for self damage as it may be an attempt to
 362                 // escape a lava pit or similar
 363                 //self.pushltime = 0;
 364                 self.istypefrag = 0;
 365         }
 366         else if(IS_PLAYER(attacker))
 367         {
 368                 self.pusher = attacker;
 369                 self.pushltime = time + autocvar_g_maxpushtime;
 370                 self.istypefrag = self.BUTTON_CHAT;
 371         }
 372         else if(time < self.pushltime)
 373         {
 374                 attacker = self.pusher;
 375                 self.pushltime = max(self.pushltime, time + 0.6);
 376         }
 377         else
 378         {
 379                 self.pushltime = 0;
 380                 self.istypefrag = 0;
 381         }
 382
 383         frag_inflictor = inflictor;
 384         frag_attacker = attacker;
 385         frag_target = self;
 386         frag_damage = damage;
 387         damage_take = take;
 388         damage_save = save;
 389         damage_force = force;
 390         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 391         take = bound(0, damage_take, self.health);
 392         save = bound(0, damage_save, self.armorvalue);
 393         excess = max(0, damage - take - save);
 394
 395         if(sound_allowed(MSG_BROADCAST, attacker))
 396         {
 397                 if (save > 10)
 398                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 399                 else if (take > 30)
 400                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 401                 else if (take > 10)
 402                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 403         }
 404
 405         if (take > 50)
 406                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 407         if (take > 100)
 408                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 409
 410         if (time >= self.spawnshieldtime)
 411         {
 412                 if (!(self.flags & FL_GODMODE))
 413                 {
 414                         self.armorvalue = self.armorvalue - save;
 415                         self.health = self.health - take;
 416                         // pause regeneration for 5 seconds
 417                         if(take)
 418                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 419
 420                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 421                         {
 422                                 self.pain_finished = time + 0.5;        //Supajoe
 423
 424                                 if(autocvar_sv_gentle < 1) {
 425                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 426                                         {
 427                                                 if (!self.animstate_override)
 428                                                 {
 429                                                         if (random() > 0.5)
 430                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 431                                                         else
 432                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 433                                                 }
 434                                         }
 435
 436                                         if(sound_allowed(MSG_BROADCAST, attacker))
 437                                         if((self.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !((get_weaponinfo(DEATH_WEAPONOF(deathtype))).spawnflags & WEP_FLAG_CANCLIMB) || attacker != self) // WEAPONTODO: create separate limit for pain notification with laser
 438                                         if(self.health > 1)
 439                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 440                                         {
 441                                                 if(deathtype == DEATH_FALL)
 442                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 443                                                 else if(self.health > 75) // TODO make a "gentle" version?
 444                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 445                                                 else if(self.health > 50)
 446                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 447                                                 else if(self.health > 25)
 448                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 449                                                 else
 450                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 451                                         }
 452                                 }
 453                         }
 454
 455                         // throw off bot aim temporarily
 456                         float shake;
 457                         if(IS_BOT_CLIENT(self) && self.health >= 1)
 458                         {
 459                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 460                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 461                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 462                                 self.v_angle_x = bound(-90, self.v_angle_x, 90);
 463                         }
 464                 }
 465                 else
 466                         self.max_armorvalue += (save + take);
 467         }
 468         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 469         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 470         self.dmg_inflictor = inflictor;
 471
 472         float abot, vbot, awep;
 473         abot = (IS_BOT_CLIENT(attacker));
 474         vbot = (IS_BOT_CLIENT(self));
 475
 476         valid_damage_for_weaponstats = 0;
 477         awep = 0;
 478
 479         if(vbot || IS_REAL_CLIENT(self))
 480         if(abot || IS_REAL_CLIENT(attacker))
 481         if(attacker && self != attacker)
 482         if(DIFF_TEAM(self, attacker))
 483         {
 484                 if(DEATH_ISSPECIAL(deathtype))
 485                         awep = attacker.weapon;
 486                 else
 487                         awep = DEATH_WEAPONOF(deathtype);
 488                 valid_damage_for_weaponstats = 1;
 489         }
 490
 491         if(valid_damage_for_weaponstats)
 492         {
 493                 dh = dh - max(self.health, 0);
 494                 da = da - max(self.armorvalue, 0);
 495                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 496         }
 497
 498         if (self.health < 1)
 499         {
 500                 float defer_ClientKill_Now_TeamChange;
 501                 defer_ClientKill_Now_TeamChange = FALSE;
 502
 503                 if(self.alivetime)
 504                 {
 505                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 506                         self.alivetime = 0;
 507                 }
 508
 509                 if(valid_damage_for_weaponstats)
 510                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 511
 512                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 513                 if(sound_allowed(MSG_BROADCAST, attacker))
 514                 {
 515                         if(deathtype == DEATH_DROWN)
 516                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 517                         else
 518                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 519                 }
 520
 521                 // get rid of kill indicator
 522                 if(self.killindicator)
 523                 {
 524                         remove(self.killindicator);
 525                         self.killindicator = world;
 526                         if(self.killindicator_teamchange)
 527                                 defer_ClientKill_Now_TeamChange = TRUE;
 528
 529                         if(self.classname == "body")
 530                         if(deathtype == DEATH_KILL)
 531                         {
 532                                 // for the lemmings fans, a small harmless explosion
 533                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 534                         }
 535                 }
 536
 537                 // print an obituary message
 538                 Obituary (attacker, inflictor, self, deathtype);
 539
 540         // increment frag counter for used weapon type
 541         float w;
 542         w = DEATH_WEAPONOF(deathtype);
 543         if(WEP_VALID(w))
 544         if(accuracy_isgooddamage(attacker, self))
 545         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 546
 547                 frag_attacker = attacker;
 548                 frag_inflictor = inflictor;
 549                 frag_target = self;
 550                 frag_deathtype = deathtype;
 551                 MUTATOR_CALLHOOK(PlayerDies);
 552
 553                 WEP_ACTION(self.weapon, WR_PLAYERDEATH);
 554
 555                 RemoveGrapplingHook(self);
 556
 557                 Portal_ClearAllLater(self);
 558
 559                 self.fixangle = TRUE;
 560
 561                 if(defer_ClientKill_Now_TeamChange)
 562                         ClientKill_Now_TeamChange(); // can turn player into spectator
 563
 564                 // player could have been miraculously resuscitated ;)
 565                 // e.g. players in freezetag get frozen, they don't really die
 566                 if(self.health >= 1 || !IS_PLAYER(self))
 567                         return;
 568
 569                 // when we get here, player actually dies
 570
 571                 Unfreeze(self); // remove any icy remains
 572                 self.health = 0; // Unfreeze resets health, so we need to set it back
 573
 574                 // clear waypoints
 575                 WaypointSprite_PlayerDead();
 576                 // throw a weapon
 577                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 578
 579                 // become fully visible
 580                 self.alpha = default_player_alpha;
 581                 // make the corpse upright (not tilted)
 582                 self.angles_x = 0;
 583                 self.angles_z = 0;
 584                 // don't spin
 585                 self.avelocity = '0 0 0';
 586                 // view from the floor
 587                 self.view_ofs = '0 0 -8';
 588                 // toss the corpse
 589                 self.movetype = MOVETYPE_TOSS;
 590                 // shootable corpse
 591                 self.solid = SOLID_CORPSE;
 592                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 593                 // don't stick to the floor
 594                 self.flags &= ~FL_ONGROUND;
 595                 // dying animation
 596                 self.deadflag = DEAD_DYING;
 597
 598                 // when to allow respawn
 599                 calculate_player_respawn_time();
 600
 601                 self.death_time = time;
 602                 if (random() < 0.5)
 603                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 604                 else
 605                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 606                 if (self.maxs_z > 5)
 607                 {
 608                         self.maxs_z = 5;
 609                         setsize(self, self.mins, self.maxs);
 610                 }
 611                 // set damage function to corpse damage
 612                 self.event_damage = PlayerCorpseDamage;
 613                 // call the corpse damage function just in case it wants to gib
 614                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 615                 // set up to fade out later
 616                 SUB_SetFade (self, time + 6 + random (), 1);
 617
 618                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 619                         // remove corpse
 620                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 621                 }
 622
 623                 // reset fields the weapons may use just in case
 624                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 625                 {
 626                         WEP_ACTION(j, WR_RESETPLAYER);
 627                         ATTACK_FINISHED_FOR(self, j) = 0;
 628                 }
 629         }
 630 }
 631
 632 .float muted; // to be used by prvm_edictset server playernumber muted 1
 633 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 634 // message "": do not say, just test flood control
 635 // return value:
 636 //   1 = accept
 637 //   0 = reject
 638 //  -1 = fake accept
 639 {
 640         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 641         float flood;
 642         var .float flood_field;
 643         entity head;
 644         float ret;
 645         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 646
 647         if(!teamsay && !privatesay)
 648                 if(substring(msgin, 0, 1) == " ")
 649                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 650
 651         msgin = formatmessage(msgin);
 652
 653         if (!IS_PLAYER(source))
 654                 colorstr = "^0"; // black for spectators
 655         else if(teamplay)
 656                 colorstr = Team_ColorCode(source.team);
 657         else
 658         {
 659                 colorstr = "";
 660                 teamsay = FALSE;
 661         }
 662
 663         if(intermission_running)
 664                 teamsay = FALSE;
 665
 666         if(msgin != "")
 667                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 668
 669         /*
 670          * using bprint solves this... me stupid
 671         // how can we prevent the message from appearing in a listen server?
 672         // for now, just give "say" back and only handle say_team
 673         if(!teamsay)
 674         {
 675                 clientcommand(self, strcat("say ", msgin));
 676                 return;
 677         }
 678         */
 679
 680         if(autocvar_g_chat_teamcolors)
 681                 namestr = playername(source);
 682         else
 683                 namestr = source.netname;
 684
 685         if(strdecolorize(namestr) == namestr)
 686                 colorprefix = "^3";
 687         else
 688                 colorprefix = "^7";
 689
 690         if(msgin != "")
 691         {
 692                 if(privatesay)
 693                 {
 694                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 695                         privatemsgprefixlen = strlen(msgstr);
 696                         msgstr = strcat(msgstr, msgin);
 697                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 698                         if(autocvar_g_chat_teamcolors)
 699                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 700                         else
 701                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 702                 }
 703                 else if(teamsay)
 704                 {
 705                         msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 706                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 707                 }
 708                 else
 709                 {
 710                         msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 711                         cmsgstr = "";
 712                 }
 713                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 714         }
 715         else
 716         {
 717                 msgstr = cmsgstr = "";
 718         }
 719
 720         fullmsgstr = msgstr;
 721         fullcmsgstr = cmsgstr;
 722
 723         // FLOOD CONTROL
 724         flood = 0;
 725         flood_field = floodcontrol_chat;
 726         if(floodcontrol)
 727         {
 728                 float flood_spl;
 729                 float flood_burst;
 730                 float flood_lmax;
 731                 float lines;
 732                 if(privatesay)
 733                 {
 734                         flood_spl = autocvar_g_chat_flood_spl_tell;
 735                         flood_burst = autocvar_g_chat_flood_burst_tell;
 736                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 737                         flood_field = floodcontrol_chattell;
 738                 }
 739                 else if(teamsay)
 740                 {
 741                         flood_spl = autocvar_g_chat_flood_spl_team;
 742                         flood_burst = autocvar_g_chat_flood_burst_team;
 743                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 744                         flood_field = floodcontrol_chatteam;
 745                 }
 746                 else
 747                 {
 748                         flood_spl = autocvar_g_chat_flood_spl;
 749                         flood_burst = autocvar_g_chat_flood_burst;
 750                         flood_lmax = autocvar_g_chat_flood_lmax;
 751                         flood_field = floodcontrol_chat;
 752                 }
 753                 flood_burst = max(0, flood_burst - 1);
 754                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 755
 756                 // do flood control for the default line size
 757                 if(msgstr != "")
 758                 {
 759                         getWrappedLine_remaining = msgstr;
 760                         msgstr = "";
 761                         lines = 0;
 762                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 763                         {
 764                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 765                                 ++lines;
 766                         }
 767                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 768
 769                         if(getWrappedLine_remaining != "")
 770                         {
 771                                 msgstr = strcat(msgstr, "\n");
 772                                 flood = 2;
 773                         }
 774
 775                         if(time >= source.flood_field)
 776                         {
 777                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 778                         }
 779                         else
 780                         {
 781                                 flood = 1;
 782                                 msgstr = fullmsgstr;
 783                         }
 784                 }
 785                 else
 786                 {
 787                         if(time >= source.flood_field)
 788                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 789                         else
 790                                 flood = 1;
 791                 }
 792
 793                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 794                         source.flood_field = flood = 0;
 795         }
 796
 797         if(flood == 2) // cannot happen for empty msgstr
 798         {
 799                 if(autocvar_g_chat_flood_notify_flooder)
 800                 {
 801                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 802                         sourcecmsgstr = "";
 803                 }
 804                 else
 805                 {
 806                         sourcemsgstr = fullmsgstr;
 807                         sourcecmsgstr = fullcmsgstr;
 808                 }
 809                 cmsgstr = "";
 810         }
 811         else
 812         {
 813                 sourcemsgstr = msgstr;
 814                 sourcecmsgstr = cmsgstr;
 815         }
 816
 817         if(!privatesay)
 818         if (!IS_PLAYER(source))
 819         {
 820                 if (!intermission_running)
 821                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 822                                 teamsay = -1; // spectators
 823         }
 824
 825         if(flood)
 826                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 827
 828         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 829         if(privatesay)
 830                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 831
 832         if(source.muted)
 833         {
 834                 // always fake the message
 835                 ret = -1;
 836         }
 837         else if(flood == 1)
 838         {
 839                 if(autocvar_g_chat_flood_notify_flooder)
 840                 {
 841                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 842                         ret = 0;
 843                 }
 844                 else
 845                         ret = -1;
 846         }
 847         else
 848         {
 849                 ret = 1;
 850         }
 851
 852         if(sourcemsgstr != "" && ret != 0)
 853         {
 854                 if(ret < 0) // faked message, because the player is muted
 855                 {
 856                         sprint(source, sourcemsgstr);
 857                         if(sourcecmsgstr != "" && !privatesay)
 858                                 centerprint(source, sourcecmsgstr);
 859                 }
 860                 else if(privatesay) // private message, between 2 people only
 861                 {
 862                         sprint(source, sourcemsgstr);
 863                         sprint(privatesay, msgstr);
 864                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 865                         if(cmsgstr != "")
 866                                 centerprint(privatesay, cmsgstr);
 867                 }
 868                 else if(teamsay > 0) // team message, only sent to team mates
 869                 {
 870                         sprint(source, sourcemsgstr);
 871                         dedicated_print(msgstr); // send to server console too
 872                         if(sourcecmsgstr != "")
 873                                 centerprint(source, sourcecmsgstr);
 874                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 875                                 if(head != source)
 876                                 {
 877                                         sprint(head, msgstr);
 878                                         if(cmsgstr != "")
 879                                                 centerprint(head, cmsgstr);
 880                                 }
 881                 }
 882                 else if(teamsay < 0) // spectator message, only sent to spectators
 883                 {
 884                         sprint(source, sourcemsgstr);
 885                         dedicated_print(msgstr); // send to server console too
 886                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
 887                                 if(head != source)
 888                                         sprint(head, msgstr);
 889                 }
 890                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 891                 {
 892                         sprint(source, sourcemsgstr);
 893                         dedicated_print(msgstr); // send to server console too
 894                         FOR_EACH_REALCLIENT(head)
 895                                 if(head != source)
 896                                         sprint(head, msgstr);
 897                 }
 898                 else
 899                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 900         }
 901
 902         return ret;
 903 }
 904
 905 float GetVoiceMessageVoiceType(string type)
 906 {
 907         if(type == "taunt")
 908                 return VOICETYPE_TAUNT;
 909         if(type == "teamshoot")
 910                 return VOICETYPE_LASTATTACKER;
 911         return VOICETYPE_TEAMRADIO;
 912 }
 913
 914 string allvoicesamples;
 915 .string GetVoiceMessageSampleField(string type)
 916 {
 917         GetPlayerSoundSampleField_notFound = 0;
 918         switch(type)
 919         {
 920 #define _VOICEMSG(m) case #m: return playersound_##m;
 921                 ALLVOICEMSGS
 922 #undef _VOICEMSG
 923         }
 924         GetPlayerSoundSampleField_notFound = 1;
 925         return playersound_taunt;
 926 }
 927
 928 .string GetPlayerSoundSampleField(string type)
 929 {
 930         GetPlayerSoundSampleField_notFound = 0;
 931         switch(type)
 932         {
 933 #define _VOICEMSG(m) case #m: return playersound_##m;
 934                 ALLPLAYERSOUNDS
 935 #undef _VOICEMSG
 936         }
 937         GetPlayerSoundSampleField_notFound = 1;
 938         return playersound_taunt;
 939 }
 940
 941 void PrecacheGlobalSound(string samplestring)
 942 {
 943         float n, i;
 944         tokenize_console(samplestring);
 945         n = stof(argv(1));
 946         if(n > 0)
 947         {
 948                 for(i = 1; i <= n; ++i)
 949                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 950         }
 951         else
 952         {
 953                 precache_sound(strcat(argv(0), ".wav"));
 954         }
 955 }
 956
 957 void PrecachePlayerSounds(string f)
 958 {
 959         float fh;
 960         string s;
 961         fh = fopen(f, FILE_READ);
 962         if(fh < 0)
 963                 return;
 964         while((s = fgets(fh)))
 965         {
 966                 if(tokenize_console(s) != 3)
 967                 {
 968                         dprint("Invalid sound info line: ", s, "\n");
 969                         continue;
 970                 }
 971                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 972         }
 973         fclose(fh);
 974
 975         if (!allvoicesamples)
 976         {
 977 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
 978                 ALLVOICEMSGS
 979 #undef _VOICEMSG
 980                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
 981         }
 982 }
 983
 984 void ClearPlayerSounds()
 985 {
 986 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
 987         ALLPLAYERSOUNDS
 988         ALLVOICEMSGS
 989 #undef _VOICEMSG
 990 }
 991
 992 float LoadPlayerSounds(string f, float first)
 993 {
 994         float fh;
 995         string s;
 996         var .string field;
 997         fh = fopen(f, FILE_READ);
 998         if(fh < 0)
 999         {
1000                 dprint("Player sound file not found: ", f, "\n");
1001                 return 0;
1002         }
1003         while((s = fgets(fh)))
1004         {
1005                 if(tokenize_console(s) != 3)
1006                         continue;
1007                 field = GetPlayerSoundSampleField(argv(0));
1008                 if(GetPlayerSoundSampleField_notFound)
1009                         field = GetVoiceMessageSampleField(argv(0));
1010                 if(GetPlayerSoundSampleField_notFound)
1011                         continue;
1012                 if(self.field)
1013                         strunzone(self.field);
1014                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1015         }
1016         fclose(fh);
1017         return 1;
1018 }
1019
1020 .float modelindex_for_playersound;
1021 .float skin_for_playersound;
1022 void UpdatePlayerSounds()
1023 {
1024         if(self.modelindex == self.modelindex_for_playersound)
1025         if(self.skin == self.skin_for_playersound)
1026                 return;
1027         self.modelindex_for_playersound = self.modelindex;
1028         self.skin_for_playersound = self.skin;
1029         ClearPlayerSounds();
1030         LoadPlayerSounds("sound/player/default.sounds", 1);
1031         if(!autocvar_g_debug_defaultsounds)
1032                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1033                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1034 }
1035
1036 void FakeGlobalSound(string sample, float chan, float voicetype)
1037 {
1038         float n;
1039         float tauntrand;
1040
1041         if(sample == "")
1042                 return;
1043
1044         tokenize_console(sample);
1045         n = stof(argv(1));
1046         if(n > 0)
1047                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1048         else
1049                 sample = strcat(argv(0), ".wav"); // randomization
1050
1051         switch(voicetype)
1052         {
1053                 case VOICETYPE_LASTATTACKER_ONLY:
1054                         break;
1055                 case VOICETYPE_LASTATTACKER:
1056                         if(self.pusher)
1057                         {
1058                                 msg_entity = self;
1059                                 if(IS_REAL_CLIENT(msg_entity))
1060                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1061                         }
1062                         break;
1063                 case VOICETYPE_TEAMRADIO:
1064                         msg_entity = self;
1065                         if(msg_entity.cvar_cl_voice_directional == 1)
1066                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1067                         else
1068                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1069                         break;
1070                 case VOICETYPE_AUTOTAUNT:
1071                         if(!sv_autotaunt)
1072                                 break;
1073                         if(!sv_taunt)
1074                                 break;
1075                         if(autocvar_sv_gentle)
1076                                 break;
1077                         tauntrand = random();
1078                         msg_entity = self;
1079                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1080                         {
1081                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1082                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1083                                 else
1084                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1085                         }
1086                         break;
1087                 case VOICETYPE_TAUNT:
1088                         if(IS_PLAYER(self))
1089                                 if(self.deadflag == DEAD_NO)
1090                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1091                         if(!sv_taunt)
1092                                 break;
1093                         if(autocvar_sv_gentle)
1094                                 break;
1095                         msg_entity = self;
1096                         if (msg_entity.cvar_cl_voice_directional >= 1)
1097                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1098                         else
1099                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1100                         break;
1101                 case VOICETYPE_PLAYERSOUND:
1102                         msg_entity = self;
1103                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1104                         break;
1105                 default:
1106                         backtrace("Invalid voice type!");
1107                         break;
1108         }
1109 }
1110
1111 void GlobalSound(string sample, float chan, float voicetype)
1112 {
1113         float n;
1114         float tauntrand;
1115
1116         if(sample == "")
1117                 return;
1118
1119         tokenize_console(sample);
1120         n = stof(argv(1));
1121         if(n > 0)
1122                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1123         else
1124                 sample = strcat(argv(0), ".wav"); // randomization
1125
1126         switch(voicetype)
1127         {
1128                 case VOICETYPE_LASTATTACKER_ONLY:
1129                         if(self.pusher)
1130                         {
1131                                 msg_entity = self.pusher;
1132                                 if(IS_REAL_CLIENT(msg_entity))
1133                                 {
1134                                         if(msg_entity.cvar_cl_voice_directional == 1)
1135                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1136                                         else
1137                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1138                                 }
1139                         }
1140                         break;
1141                 case VOICETYPE_LASTATTACKER:
1142                         if(self.pusher)
1143                         {
1144                                 msg_entity = self.pusher;
1145                                 if(IS_REAL_CLIENT(msg_entity))
1146                                 {
1147                                         if(msg_entity.cvar_cl_voice_directional == 1)
1148                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1149                                         else
1150                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1151                                 }
1152                                 msg_entity = self;
1153                                 if(IS_REAL_CLIENT(msg_entity))
1154                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1155                         }
1156                         break;
1157                 case VOICETYPE_TEAMRADIO:
1158                         FOR_EACH_REALCLIENT(msg_entity)
1159                                 if(!teamplay || msg_entity.team == self.team)
1160                                 {
1161                                         if(msg_entity.cvar_cl_voice_directional == 1)
1162                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1163                                         else
1164                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1165                                 }
1166                         break;
1167                 case VOICETYPE_AUTOTAUNT:
1168                         if(!sv_autotaunt)
1169                                 break;
1170                         if(!sv_taunt)
1171                                 break;
1172                         if(autocvar_sv_gentle)
1173                                 break;
1174                         tauntrand = random();
1175                         FOR_EACH_REALCLIENT(msg_entity)
1176                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1177                                 {
1178                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1179                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1180                                         else
1181                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1182                                 }
1183                         break;
1184                 case VOICETYPE_TAUNT:
1185                         if(IS_PLAYER(self))
1186                                 if(self.deadflag == DEAD_NO)
1187                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1188                         if(!sv_taunt)
1189                                 break;
1190                         if(autocvar_sv_gentle)
1191                                 break;
1192                         FOR_EACH_REALCLIENT(msg_entity)
1193                         {
1194                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1195                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1196                                 else
1197                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1198                         }
1199                         break;
1200                 case VOICETYPE_PLAYERSOUND:
1201                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1202                         break;
1203                 default:
1204                         backtrace("Invalid voice type!");
1205                         break;
1206         }
1207 }
1208
1209 void PlayerSound(.string samplefield, float chan, float voicetype)
1210 {
1211         GlobalSound(self.samplefield, chan, voicetype);
1212 }
1213
1214 void VoiceMessage(string type, string msg)
1215 {
1216         var .string sample;
1217         float voicetype, ownteam;
1218         float flood;
1219         sample = GetVoiceMessageSampleField(type);
1220
1221         if(GetPlayerSoundSampleField_notFound)
1222         {
1223                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1224                 return;
1225         }
1226
1227         voicetype = GetVoiceMessageVoiceType(type);
1228         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1229
1230         flood = Say(self, ownteam, world, msg, 1);
1231
1232         if(IS_SPEC(self) || IS_OBSERVER(self) || flood < 0)
1233                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1234         else if (flood > 0)
1235                 GlobalSound(self.sample, CH_VOICE, voicetype);
1236 }
1237
1238 void MoveToTeam(entity client, float team_colour, float type)
1239 {
1240         float lockteams_backup;
1241
1242         lockteams_backup = lockteams;  // backup any team lock
1243
1244         lockteams = 0;  // disable locked teams
1245
1246         TeamchangeFrags(client);  // move the players frags
1247         SetPlayerColors(client, team_colour - 1);  // set the players colour
1248         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1249
1250         lockteams = lockteams_backup;  // restore the team lock
1251
1252         LogTeamchange(client.playerid, client.team, type);
1253 }