qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_killfile != "" || autocvar_sv_weaponstats_damagefile != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(autocvar_sv_weaponstats_killfile != "")
  22         {
  23                 fh = fopen(autocvar_sv_weaponstats_killfile, FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(autocvar_sv_weaponstats_damagefile != "")
  43         {
  44                 fh = fopen(autocvar_sv_weaponstats_damagefile, FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.model, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 333 }
 334
 335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 336 {
 337         local float take, save;
 338         vector v;
 339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 340
 341         // damage resistance (ignore most of the damage from a bullet or similar)
 342         damage = max(damage - 5, 1);
 343
 344         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 345         take = v_x;
 346         save = v_y;
 347
 348         if(sound_allowed(MSG_BROADCAST, attacker))
 349         {
 350                 if (save > 10)
 351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 30)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 354                 else if (take > 10)
 355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 356         }
 357
 358         if (take > 50)
 359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 360         if (take > 100)
 361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 362
 363         if (!(self.flags & FL_GODMODE))
 364         {
 365                 self.armorvalue = self.armorvalue - save;
 366                 self.health = self.health - take;
 367                 // pause regeneration for 5 seconds
 368                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 369         }
 370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 372         self.dmg_inflictor = inflictor;
 373
 374         if (self.health <= -100 && self.modelindex != 0)
 375         {
 376                 // don't use any animations as a gib
 377                 self.frame = 0;
 378                 self.dead_frame = 0;
 379                 // view just above the floor
 380                 self.view_ofs = '0 0 4';
 381
 382                 Violence_GibSplash(self, 1, 1, attacker);
 383                 self.modelindex = 0; // restore later
 384                 self.solid = SOLID_NOT; // restore later
 385         }
 386 }
 387
 388 void ClientKill_Now_TeamChange();
 389 void freezetag_CheckWinner();
 390 void freezetag_Unfreeze();
 391
 392 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 393 {
 394         local float take, save, waves, sdelay, dh, da, j;
 395         vector v;
 396         float valid_damage_for_weaponstats;
 397
 398         dh = max(self.health, 0);
 399         da = max(self.armorvalue, 0);
 400
 401         if(!DEATH_ISSPECIAL(deathtype))
 402         {
 403                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 404                 if(self != attacker)
 405                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 406         }
 407
 408         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 409         {
 410                 // tuba causes blood to come out of the ears
 411                 vector ear1, ear2;
 412                 vector d;
 413                 float f;
 414                 ear1 = self.origin;
 415                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 416                 ear2 = ear1;
 417                 makevectors(self.angles);
 418                 ear1 += v_right * -10;
 419                 ear2 += v_right * +10;
 420                 d = inflictor.origin - self.origin;
 421                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 422                 force = v_right * vlen(force);
 423                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 424                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 425                 if(f > 0)
 426                 {
 427                         hitloc = ear1;
 428                         force = force * -1;
 429                 }
 430                 else
 431                 {
 432                         hitloc = ear2;
 433                         // force is already good
 434                 }
 435         }
 436         else
 437                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 438
 439         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 440                 return;
 441
 442         if (!g_minstagib)
 443         {
 444                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 445                 take = v_x;
 446                 save = v_y;
 447         }
 448         else
 449         {
 450                 save = 0;
 451                 take = damage;
 452         }
 453
 454         frag_inflictor = inflictor;
 455         frag_attacker = attacker;
 456         frag_target = self;
 457         damage_take = take;
 458         damage_save = save;
 459         damage_force = force;
 460         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 461         take = bound(0, damage_take, self.health);
 462         save = bound(0, damage_save, self.armorvalue);
 463
 464         if(sound_allowed(MSG_BROADCAST, attacker))
 465         {
 466                 if (save > 10)
 467                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 468                 else if (take > 30)
 469                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 470                 else if (take > 10)
 471                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 472         }
 473
 474         if (take > 50)
 475                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 476         if (take > 100)
 477                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 478
 479         if (time >= self.spawnshieldtime)
 480         {
 481                 if (!(self.flags & FL_GODMODE))
 482                 {
 483                         self.armorvalue = self.armorvalue - save;
 484                         self.health = self.health - take;
 485                         // pause regeneration for 5 seconds
 486                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 487
 488                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 489                         {
 490                                 self.pain_finished = time + 0.5;        //Supajoe
 491
 492                                 if(sv_gentle < 1) {
 493                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 494                                         {
 495                                                 if (random() > 0.5)
 496                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 497                                                 else
 498                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 499                                         }
 500
 501                                         if(sound_allowed(MSG_BROADCAST, attacker))
 502                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 503                                         if(self.health > 1)
 504                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 505                                         {
 506                                                 if(deathtype == DEATH_FALL)
 507                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 508                                                 else if(self.health > 75) // TODO make a "gentle" version?
 509                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 510                                                 else if(self.health > 50)
 511                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 512                                                 else if(self.health > 25)
 513                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 514                                                 else
 515                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 516                                         }
 517                                 }
 518
 519                                 // throw off bot aim temporarily
 520                                 local float shake;
 521                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 522                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 523                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 524                         }
 525                 }
 526                 else
 527                         self.max_armorvalue += (save + take);
 528         }
 529         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 530         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 531         self.dmg_inflictor = inflictor;
 532
 533         if(attacker == self)
 534         {
 535                 // don't reset pushltime for self damage as it may be an attempt to
 536                 // escape a lava pit or similar
 537                 //self.pushltime = 0;
 538         }
 539         else if(attacker.classname == "player" || attacker.classname == "gib")
 540         {
 541                 self.pusher = attacker;
 542                 self.pushltime = time + autocvar_g_maxpushtime;
 543         }
 544         else if(time < self.pushltime)
 545         {
 546                 attacker = self.pusher;
 547                 self.pushltime = max(self.pushltime, time + 0.6);
 548         }
 549         else
 550                 self.pushltime = 0;
 551
 552         valid_damage_for_weaponstats = 0;
 553         if(clienttype(self) == CLIENTTYPE_REAL)
 554         if(clienttype(attacker) == CLIENTTYPE_REAL)
 555         if(self != attacker)
 556         if(!DEATH_ISSPECIAL(deathtype))
 557         if(IsDifferentTeam(self, attacker))
 558                 valid_damage_for_weaponstats = 1;
 559
 560         if(valid_damage_for_weaponstats)
 561         {
 562                 dh = dh - max(self.health, 0);
 563                 da = da - max(self.armorvalue, 0);
 564                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 565         }
 566
 567         if (self.health < 1)
 568         {
 569                 float defer_ClientKill_Now_TeamChange;
 570                 defer_ClientKill_Now_TeamChange = FALSE;
 571
 572                 if(self.alivetime)
 573                 {
 574                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 575                         self.alivetime = 0;
 576                 }
 577
 578                 if(valid_damage_for_weaponstats)
 579                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 580
 581                 if(sv_gentle < 1) // TODO make a "gentle" version?
 582                 if(sound_allowed(MSG_BROADCAST, attacker))
 583                 {
 584                         if(deathtype == DEATH_DROWN)
 585                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 586                         else
 587                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 588                 }
 589
 590                 // get rid of kill indicator
 591                 if(self.killindicator)
 592                 {
 593                         remove(self.killindicator);
 594                         self.killindicator = world;
 595                         if(self.killindicator_teamchange)
 596                                 defer_ClientKill_Now_TeamChange = TRUE;
 597
 598                         if(self.classname == "body")
 599                         if(deathtype == DEATH_KILL)
 600                         {
 601                                 // for the lemmings fans, a small harmless explosion
 602                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 603                         }
 604                 }
 605
 606                 if(!g_freezetag)
 607                 {
 608                         // become fully visible
 609                         self.alpha = 1;
 610                         // clear selected player display
 611                         ClearSelectedPlayer();
 612                         // throw a weapon
 613                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 614                 }
 615
 616                 // print an obituary message
 617                 Obituary (attacker, inflictor, self, deathtype);
 618                 race_PreDie();
 619                 DropAllRunes(self);
 620
 621                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 622                 {
 623                         PutClientInServer();
 624                         count_alive_players(); // re-count players
 625                         freezetag_CheckWinner();
 626                         return;
 627                 }
 628
 629                 frag_attacker = attacker;
 630                 frag_inflictor = inflictor;
 631                 frag_target = self;
 632                 MUTATOR_CALLHOOK(PlayerDies);
 633
 634                 if(g_freezetag)
 635             return;
 636
 637                 if(self.flagcarried)
 638                 {
 639                         if(attacker.classname != "player" && attacker.classname != "gib")
 640                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 641                         else if(attacker.team == self.team)
 642                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 643                         else
 644                                 DropFlag(self.flagcarried, world, attacker);
 645                 }
 646                 if(self.ballcarried && g_nexball)
 647                         DropBall(self.ballcarried, self.origin, self.velocity);
 648                 Portal_ClearAllLater(self);
 649                 // clear waypoints
 650                 WaypointSprite_PlayerDead();
 651                 // make the corpse upright (not tilted)
 652                 self.angles_x = 0;
 653                 self.angles_z = 0;
 654                 // don't spin
 655                 self.avelocity = '0 0 0';
 656                 // view from the floor
 657                 self.view_ofs = '0 0 -8';
 658                 // toss the corpse
 659                 self.movetype = MOVETYPE_TOSS;
 660                 // shootable corpse
 661                 self.solid = SOLID_CORPSE;
 662                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 663                 // don't stick to the floor
 664                 self.flags &~= FL_ONGROUND;
 665                 // dying animation
 666                 self.deadflag = DEAD_DYING;
 667                 // when to allow respawn
 668                 sdelay = 0;
 669                 waves = 0;
 670                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 671                 if(!sdelay)
 672                         sdelay = autocvar_g_respawn_delay;
 673                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 674                 if(!waves)
 675                         waves = autocvar_g_respawn_waves;
 676                 if(waves)
 677                         self.death_time = ceil((time + sdelay) / waves) * waves;
 678                 else
 679                         self.death_time = time + sdelay;
 680                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 681                         self.respawn_countdown = 10; // first number to count down from is 10
 682                 else
 683                         self.respawn_countdown = -1; // do not count down
 684                 if (random() < 0.5)
 685                 {
 686                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 687                         self.dead_frame = self.anim_dead1_x;
 688                 }
 689                 else
 690                 {
 691                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 692                         self.dead_frame = self.anim_dead2_x;
 693                 }
 694                 // set damage function to corpse damage
 695                 self.event_damage = PlayerCorpseDamage;
 696                 // call the corpse damage function just in case it wants to gib
 697                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 698                 // set up to fade out later
 699                 SUB_SetFade (self, time + 6 + random (), 1);
 700
 701                 if(clienttype(self) == CLIENTTYPE_REAL)
 702                 {
 703                         self.fixangle = TRUE;
 704                         //msg_entity = self;
 705                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 706                         //WriteAngle (MSG_ONE, self.v_angle_x);
 707                         //WriteAngle (MSG_ONE, self.v_angle_y);
 708                         //WriteAngle (MSG_ONE, 80);
 709                 }
 710
 711                 if(g_arena)
 712                         Spawnqueue_Unmark(self);
 713
 714                 if(defer_ClientKill_Now_TeamChange)
 715                         ClientKill_Now_TeamChange();
 716
 717                 if(sv_gentle > 0 || autocvar_ekg) {
 718                         // remove corpse
 719                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 720                 }
 721
 722                 // reset fields the weapons may use just in case
 723         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 724                 {
 725             weapon_action(j, WR_RESETPLAYER);
 726                         ATTACK_FINISHED_FOR(self, j) = 0;
 727                 }
 728         }
 729 }
 730
 731 float UpdateSelectedPlayer_countvalue(float v)
 732 {
 733         return max(0, (v - 1.0) / 0.5);
 734 }
 735
 736 // returns: -2 if no hit, otherwise cos of the angle
 737 // uses the global v_angle
 738 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 739 {
 740         vector so, d;
 741         float c;
 742
 743         if(p == self)
 744                 return -2;
 745
 746         if(p.deadflag)
 747                 return -2;
 748
 749         so = self.origin + self.view_ofs;
 750         d = p.origin - so;
 751
 752         // misaimed?
 753         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 754                 return -2;
 755
 756         // now find the cos of the angle...
 757         c = normalize(d) * v_forward;
 758
 759         if(c <= mincosangle)
 760                 return -2;
 761
 762         // not visible in any way? forget it
 763         if(!checkpvs(so, p))
 764                 return -2;
 765
 766         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 767         if(trace_fraction < 1)
 768                 return -2;
 769
 770         return c;
 771 }
 772
 773 void ClearSelectedPlayer()
 774 {
 775         if(self.selected_player)
 776         {
 777                 centerprint_expire(self, CENTERPRIO_POINT);
 778                 self.selected_player = world;
 779                 self.selected_player_display_needs_update = FALSE;
 780         }
 781 }
 782
 783 void UpdateSelectedPlayer()
 784 {
 785         entity selected;
 786         float selected_score;
 787         selected = world;
 788         selected_score = 0.95; // 18 degrees
 789
 790         if(!autocvar_sv_allow_shownames)
 791                 return;
 792
 793         if(clienttype(self) != CLIENTTYPE_REAL)
 794                 return;
 795
 796         if(self.cvar_cl_shownames == 0)
 797                 return;
 798
 799         if(self.cvar_cl_shownames == 1 && !teams_matter)
 800                 return;
 801
 802         makevectors(self.v_angle); // sets v_forward
 803
 804         // 1. cursor trace is always right
 805         WarpZone_crosshair_trace(self);
 806         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 807         {
 808                 selected = trace_ent;
 809         }
 810         else
 811         {
 812                 // 2. if we don't have a cursor trace, find the player which is least
 813                 //    mis-aimed at
 814                 entity p;
 815                 FOR_EACH_PLAYER(p)
 816                 {
 817                         float c;
 818                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 819                         if(c >= -1)
 820                         {
 821                                 selected = p;
 822                                 selected_score = c;
 823                         }
 824                 }
 825         }
 826
 827         if(selected)
 828         {
 829                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 830         }
 831         else
 832         {
 833                 if(time < self.selected_player_display_timeout)
 834                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 835                                 selected = self.selected_player;
 836         }
 837
 838         if(selected)
 839         {
 840                 if(selected == self.selected_player)
 841                 {
 842                         float save;
 843                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 844                         self.selected_player_count = self.selected_player_count + frametime;
 845                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 846                         {
 847                                 string namestr, healthstr;
 848                                 namestr = playername(selected);
 849                                 if(teams_matter)
 850                                 {
 851                                         healthstr = ftos(floor(selected.health));
 852                                         if(self.team == selected.team)
 853                                         {
 854                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 855                                                 self.selected_player_display_needs_update = TRUE;
 856                                         }
 857                                 }
 858                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 859                         }
 860                 }
 861                 else
 862                 {
 863                         ClearSelectedPlayer();
 864                         self.selected_player = selected;
 865                         self.selected_player_time = time;
 866                         self.selected_player_count = 0;
 867                         self.selected_player_display_needs_update = FALSE;
 868                 }
 869         }
 870         else
 871         {
 872                 ClearSelectedPlayer();
 873         }
 874
 875         if(self.selected_player)
 876                 self.last_selected_player = self.selected_player;
 877 }
 878
 879 .float muted; // to be used by prvm_edictset server playernumber muted 1
 880 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 881 // message "": do not say, just test flood control
 882 // return value:
 883 //   1 = accept
 884 //   0 = reject
 885 //  -1 = fake accept
 886 {
 887         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 888         float flood, privatemsgprefixlen;
 889         var .float flood_field;
 890         entity head;
 891         float ret;
 892
 893         if(Ban_MaybeEnforceBan(source))
 894                 return 0;
 895
 896         if(!teamsay && !privatesay)
 897                 if(substring(msgin, 0, 1) == " ")
 898                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 899
 900         msgin = formatmessage(msgin);
 901
 902         if(source.classname != "player")
 903                 colorstr = "^0"; // black for spectators
 904         else if(teams_matter)
 905                 colorstr = Team_ColorCode(source.team);
 906         else
 907                 teamsay = FALSE;
 908
 909         if(intermission_running)
 910                 teamsay = FALSE;
 911
 912         if(msgin != "")
 913                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 914
 915         /*
 916          * using bprint solves this... me stupid
 917         // how can we prevent the message from appearing in a listen server?
 918         // for now, just give "say" back and only handle say_team
 919         if(!teamsay)
 920         {
 921                 clientcommand(self, strcat("say ", msgin));
 922                 return;
 923         }
 924         */
 925
 926         if(autocvar_g_chat_teamcolors)
 927                 namestr = playername(source);
 928         else
 929                 namestr = source.netname;
 930
 931         if(msgin != "")
 932         {
 933                 if(privatesay)
 934                 {
 935                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 936                         privatemsgprefixlen = strlen(msgstr);
 937                         msgstr = strcat(msgstr, msgin);
 938                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 939                         if(autocvar_g_chat_teamcolors)
 940                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 941                         else
 942                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 943                 }
 944                 else if(teamsay)
 945                 {
 946                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 947                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 948                 }
 949                 else
 950                 {
 951                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 952                         cmsgstr = "";
 953                 }
 954                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 955         }
 956         else
 957         {
 958                 msgstr = cmsgstr = "";
 959         }
 960
 961         fullmsgstr = msgstr;
 962         fullcmsgstr = cmsgstr;
 963
 964         // FLOOD CONTROL
 965         flood = 0;
 966         if(floodcontrol)
 967         {
 968                 float flood_spl;
 969                 float flood_burst;
 970                 float flood_lmax;
 971                 float lines;
 972                 if(privatesay)
 973                 {
 974                         flood_spl = autocvar_g_chat_flood_spl_tell;
 975                         flood_burst = autocvar_g_chat_flood_burst_tell;
 976                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 977                         flood_field = floodcontrol_chattell;
 978                 }
 979                 else if(teamsay)
 980                 {
 981                         flood_spl = autocvar_g_chat_flood_spl_team;
 982                         flood_burst = autocvar_g_chat_flood_burst_team;
 983                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 984                         flood_field = floodcontrol_chatteam;
 985                 }
 986                 else
 987                 {
 988                         flood_spl = autocvar_g_chat_flood_spl;
 989                         flood_burst = autocvar_g_chat_flood_burst;
 990                         flood_lmax = autocvar_g_chat_flood_lmax;
 991                         flood_field = floodcontrol_chat;
 992                 }
 993                 flood_burst = max(0, flood_burst - 1);
 994                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 995
 996                 // do flood control for the default line size
 997                 if(msgstr != "")
 998                 {
 999                         getWrappedLine_remaining = msgstr;
1000                         msgstr = "";
1001                         lines = 0;
1002                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1003                         {
1004                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1005                                 ++lines;
1006                         }
1007                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1008
1009                         if(getWrappedLine_remaining != "")
1010                         {
1011                                 msgstr = strcat(msgstr, "\n");
1012                                 flood = 2;
1013                         }
1014
1015                         if(time >= source.flood_field)
1016                         {
1017                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1018                         }
1019                         else
1020                         {
1021                                 flood = 1;
1022                                 msgstr = fullmsgstr;
1023                         }
1024                 }
1025                 else
1026                 {
1027                         if(time >= source.flood_field)
1028                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1029                         else
1030                                 flood = 1;
1031                 }
1032
1033                 if (timeoutStatus == 2) //when game is paused, no flood protection
1034                         source.flood_field = flood = 0;
1035         }
1036
1037         if(flood == 2) // cannot happen for empty msgstr
1038         {
1039                 if(autocvar_g_chat_flood_notify_flooder)
1040                 {
1041                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1042                         sourcecmsgstr = "";
1043                 }
1044                 else
1045                 {
1046                         sourcemsgstr = fullmsgstr;
1047                         sourcecmsgstr = fullcmsgstr;
1048                 }
1049                 cmsgstr = "";
1050         }
1051         else
1052         {
1053                 sourcemsgstr = msgstr;
1054                 sourcecmsgstr = cmsgstr;
1055         }
1056
1057         if(!privatesay)
1058         if(source.classname != "player")
1059         {
1060                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
1061                         teamsay = -1; // spectators
1062         }
1063
1064         if(flood)
1065                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1066
1067         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1068         if(privatesay)
1069                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1070
1071         if(source.muted)
1072         {
1073                 // always fake the message
1074                 ret = -1;
1075         }
1076         else if(flood == 1)
1077         {
1078                 if(autocvar_g_chat_flood_notify_flooder)
1079                 {
1080                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1081                         ret = 0;
1082                 }
1083                 else
1084                         ret = -1;
1085         }
1086         else
1087         {
1088                 ret = 1;
1089         }
1090
1091         if(sourcemsgstr != "" && ret != 0)
1092         {
1093                 if(ret < 0) // fake
1094                 {
1095                         sprint(source, sourcemsgstr);
1096                         if(sourcecmsgstr != "" && !privatesay)
1097                                 centerprint(source, sourcecmsgstr);
1098                 }
1099                 else if(privatesay)
1100                 {
1101                         sprint(source, sourcemsgstr);
1102                         sprint(privatesay, msgstr);
1103                         if(cmsgstr != "")
1104                                 centerprint(privatesay, cmsgstr);
1105                 }
1106                 else if(teamsay > 0)
1107                 {
1108                         sprint(source, sourcemsgstr);
1109                         if(sourcecmsgstr != "")
1110                                 centerprint(source, sourcecmsgstr);
1111                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1112                                 if(head != source)
1113                                 {
1114                                         sprint(head, msgstr);
1115                                         if(cmsgstr != "")
1116                                                 centerprint(head, cmsgstr);
1117                                 }
1118                 }
1119                 else if(teamsay < 0)
1120                 {
1121                         sprint(source, sourcemsgstr);
1122                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1123                                 if(head != source)
1124                                         sprint(head, msgstr);
1125                 }
1126                 else if(sourcemsgstr != msgstr)
1127                 {
1128                         sprint(source, sourcemsgstr);
1129                         FOR_EACH_REALCLIENT(head)
1130                                 if(head != source)
1131                                         sprint(head, msgstr);
1132                 }
1133                 else
1134                         bprint(msgstr);
1135         }
1136
1137         return ret;
1138 }
1139
1140 float GetVoiceMessageVoiceType(string type)
1141 {
1142         if(type == "taunt")
1143                 return VOICETYPE_TAUNT;
1144         if(type == "teamshoot")
1145                 return VOICETYPE_LASTATTACKER;
1146         return VOICETYPE_TEAMRADIO;
1147 }
1148
1149 string allvoicesamples;
1150 .string GetVoiceMessageSampleField(string type)
1151 {
1152         GetPlayerSoundSampleField_notFound = 0;
1153         switch(type)
1154         {
1155 #define _VOICEMSG(m) case #m: return playersound_##m;
1156                 ALLVOICEMSGS
1157 #undef _VOICEMSG
1158         }
1159         GetPlayerSoundSampleField_notFound = 1;
1160         return playersound_taunt;
1161 }
1162
1163 .string GetPlayerSoundSampleField(string type)
1164 {
1165         GetPlayerSoundSampleField_notFound = 0;
1166         switch(type)
1167         {
1168 #define _VOICEMSG(m) case #m: return playersound_##m;
1169                 ALLPLAYERSOUNDS
1170 #undef _VOICEMSG
1171         }
1172         GetPlayerSoundSampleField_notFound = 1;
1173         return playersound_taunt;
1174 }
1175
1176 void PrecacheGlobalSound(string samplestring)
1177 {
1178         float n, i;
1179         tokenize_console(samplestring);
1180         n = stof(argv(1));
1181         if(n > 0)
1182         {
1183                 for(i = 1; i <= n; ++i)
1184                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1185         }
1186         else
1187         {
1188                 precache_sound(strcat(argv(0), ".wav"));
1189         }
1190 }
1191
1192 void PrecachePlayerSounds(string f)
1193 {
1194         float fh;
1195         string s;
1196         fh = fopen(f, FILE_READ);
1197         if(fh < 0)
1198                 return;
1199         while((s = fgets(fh)))
1200         {
1201                 if(tokenize_console(s) != 3)
1202                 {
1203                         dprint("Invalid sound info line: ", s, "\n");
1204                         continue;
1205                 }
1206                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1207         }
1208         fclose(fh);
1209
1210         if not(allvoicesamples)
1211         {
1212 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1213                 ALLVOICEMSGS
1214 #undef _VOICEMSG
1215                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1216         }
1217 }
1218
1219 void ClearPlayerSounds()
1220 {
1221 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1222         ALLPLAYERSOUNDS
1223         ALLVOICEMSGS
1224 #undef _VOICEMSG
1225 }
1226
1227 float LoadPlayerSounds(string f, float first)
1228 {
1229         float fh;
1230         string s;
1231         var .string field;
1232         fh = fopen(f, FILE_READ);
1233         if(fh < 0)
1234         {
1235                 dprint("Player sound file not found: ", f, "\n");
1236                 return 0;
1237         }
1238         while((s = fgets(fh)))
1239         {
1240                 if(tokenize_console(s) != 3)
1241                         continue;
1242                 field = GetPlayerSoundSampleField(argv(0));
1243                 if(GetPlayerSoundSampleField_notFound)
1244                         field = GetVoiceMessageSampleField(argv(0));
1245                 if(GetPlayerSoundSampleField_notFound)
1246                         continue;
1247                 if(self.field)
1248                         strunzone(self.field);
1249                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1250         }
1251         fclose(fh);
1252         return 1;
1253 }
1254
1255 .float modelindex_for_playersound;
1256 .float skinindex_for_playersound;
1257 void UpdatePlayerSounds()
1258 {
1259         if(self.modelindex == self.modelindex_for_playersound)
1260         if(self.skinindex == self.skinindex_for_playersound)
1261                 return;
1262         self.modelindex_for_playersound = self.modelindex;
1263         self.skinindex_for_playersound = self.skinindex;
1264         ClearPlayerSounds();
1265         LoadPlayerSounds("sound/player/default.sounds", 1);
1266         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1267                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1268 }
1269
1270 void FakeGlobalSound(string sample, float chan, float voicetype)
1271 {
1272         float n;
1273         float tauntrand;
1274
1275         if(sample == "")
1276                 return;
1277
1278         tokenize_console(sample);
1279         n = stof(argv(1));
1280         if(n > 0)
1281                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1282         else
1283                 sample = strcat(argv(0), ".wav"); // randomization
1284
1285         switch(voicetype)
1286         {
1287                 case VOICETYPE_LASTATTACKER_ONLY:
1288                         break;
1289                 case VOICETYPE_LASTATTACKER:
1290                         if(self.pusher)
1291                         {
1292                                 msg_entity = self;
1293                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1294                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1295                         }
1296                         break;
1297                 case VOICETYPE_TEAMRADIO:
1298                         msg_entity = self;
1299                         if(msg_entity.cvar_cl_voice_directional == 1)
1300                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1301                         else
1302                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1303                         break;
1304                 case VOICETYPE_AUTOTAUNT:
1305                         if(!sv_autotaunt)
1306                                 break;
1307                         if(!sv_taunt)
1308                                 break;
1309                         if(sv_gentle)
1310                                 break;
1311                         tauntrand = random();
1312                         msg_entity = self;
1313                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1314                         {
1315                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1316                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1317                                 else
1318                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1319                         }
1320                         break;
1321                 case VOICETYPE_TAUNT:
1322                         if(self.classname == "player")
1323                                 if(self.deadflag == DEAD_NO)
1324                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1325                         if(!sv_taunt)
1326                                 break;
1327                         if(sv_gentle)
1328                                 break;
1329                         msg_entity = self;
1330                         if (msg_entity.cvar_cl_voice_directional >= 1)
1331                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1332                         else
1333                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1334                         break;
1335                 case VOICETYPE_PLAYERSOUND:
1336                         msg_entity = self;
1337                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1338                         break;
1339                 default:
1340                         backtrace("Invalid voice type!");
1341                         break;
1342         }
1343 }
1344
1345 void GlobalSound(string sample, float chan, float voicetype)
1346 {
1347         float n;
1348         float tauntrand;
1349
1350         if(sample == "")
1351                 return;
1352
1353         tokenize_console(sample);
1354         n = stof(argv(1));
1355         if(n > 0)
1356                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1357         else
1358                 sample = strcat(argv(0), ".wav"); // randomization
1359
1360         switch(voicetype)
1361         {
1362                 case VOICETYPE_LASTATTACKER_ONLY:
1363                         if(self.pusher)
1364                         {
1365                                 msg_entity = self.pusher;
1366                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1367                                 {
1368                                         if(msg_entity.cvar_cl_voice_directional == 1)
1369                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1370                                         else
1371                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1372                                 }
1373                         }
1374                         break;
1375                 case VOICETYPE_LASTATTACKER:
1376                         if(self.pusher)
1377                         {
1378                                 msg_entity = self.pusher;
1379                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1380                                 {
1381                                         if(msg_entity.cvar_cl_voice_directional == 1)
1382                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1383                                         else
1384                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1385                                 }
1386                                 msg_entity = self;
1387                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1388                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1389                         }
1390                         break;
1391                 case VOICETYPE_TEAMRADIO:
1392                         FOR_EACH_REALCLIENT(msg_entity)
1393                                 if(!teams_matter || msg_entity.team == self.team)
1394                                 {
1395                                         if(msg_entity.cvar_cl_voice_directional == 1)
1396                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1397                                         else
1398                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1399                                 }
1400                         break;
1401                 case VOICETYPE_AUTOTAUNT:
1402                         if(!sv_autotaunt)
1403                                 break;
1404                         if(!sv_taunt)
1405                                 break;
1406                         if(sv_gentle)
1407                                 break;
1408                         tauntrand = random();
1409                         FOR_EACH_REALCLIENT(msg_entity)
1410                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1411                                 {
1412                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1413                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1414                                         else
1415                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1416                                 }
1417                         break;
1418                 case VOICETYPE_TAUNT:
1419                         if(self.classname == "player")
1420                                 if(self.deadflag == DEAD_NO)
1421                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1422                         if(!sv_taunt)
1423                                 break;
1424                         if(sv_gentle)
1425                                 break;
1426                         FOR_EACH_REALCLIENT(msg_entity)
1427                         {
1428                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1429                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1430                                 else
1431                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1432                         }
1433                         break;
1434                 case VOICETYPE_PLAYERSOUND:
1435                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1436                         break;
1437                 default:
1438                         backtrace("Invalid voice type!");
1439                         break;
1440         }
1441 }
1442
1443 void PlayerSound(.string samplefield, float chan, float voicetype)
1444 {
1445         GlobalSound(self.samplefield, chan, voicetype);
1446 }
1447
1448 void VoiceMessage(string type, string msg)
1449 {
1450         var .string sample;
1451         float voicetype, ownteam;
1452         float flood;
1453         sample = GetVoiceMessageSampleField(type);
1454
1455         if(GetPlayerSoundSampleField_notFound)
1456         {
1457                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1458                 return;
1459         }
1460
1461         voicetype = GetVoiceMessageVoiceType(type);
1462         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1463
1464         flood = Say(self, ownteam, world, msg, 1);
1465
1466         if (flood > 0)
1467                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1468         else if (flood < 0)
1469                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1470 }
1471
1472 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1473 {
1474 //      show_message
1475 //      0 (00) automove centerprint, admin message
1476 //      1 (01) automove centerprint, no admin message
1477 //      2 (10) no centerprint, admin message
1478 //      3 (11) no centerprint, no admin message
1479
1480         float lockteams_backup;
1481
1482         lockteams_backup = lockteams;  // backup any team lock
1483
1484         lockteams = 0;  // disable locked teams
1485
1486         TeamchangeFrags(client);  // move the players frags
1487         SetPlayerColors(client, team_colour - 1);  // set the players colour
1488         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1489
1490         lockteams = lockteams_backup;  // restore the team lock
1491
1492         LogTeamchange(client.playerid, client.team, type);
1493
1494         if not(show_message & 1) // admin message
1495                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1496
1497         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1498 }