qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_killfile != "" || autocvar_sv_weaponstats_damagefile != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(autocvar_sv_weaponstats_killfile != "")
  22         {
  23                 fh = fopen(autocvar_sv_weaponstats_killfile, FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(autocvar_sv_weaponstats_damagefile != "")
  43         {
  44                 fh = fopen(autocvar_sv_weaponstats_damagefile, FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.model, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 333 }
 334
 335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 336 {
 337         local float take, save;
 338         vector v;
 339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 340
 341         // damage resistance (ignore most of the damage from a bullet or similar)
 342         damage = max(damage - 5, 1);
 343
 344         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 345         take = v_x;
 346         save = v_y;
 347
 348         if(sound_allowed(MSG_BROADCAST, attacker))
 349         {
 350                 if (save > 10)
 351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 30)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 354                 else if (take > 10)
 355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 356         }
 357
 358         if (take > 50)
 359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 360         if (take > 100)
 361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 362
 363         if (!(self.flags & FL_GODMODE))
 364         {
 365                 self.armorvalue = self.armorvalue - save;
 366                 self.health = self.health - take;
 367                 // pause regeneration for 5 seconds
 368                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 369         }
 370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 372         self.dmg_inflictor = inflictor;
 373
 374         if (self.health <= -100 && self.modelindex != 0)
 375         {
 376                 // don't use any animations as a gib
 377                 self.frame = 0;
 378                 self.dead_frame = 0;
 379                 // view just above the floor
 380                 self.view_ofs = '0 0 4';
 381
 382                 Violence_GibSplash(self, 1, 1, attacker);
 383                 self.modelindex = 0; // restore later
 384                 self.solid = SOLID_NOT; // restore later
 385         }
 386 }
 387
 388 void ClientKill_Now_TeamChange();
 389 void freezetag_CheckWinner();
 390 void freezetag_Unfreeze();
 391
 392 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 393 {
 394         local float take, save, waves, sdelay, dh, da, j;
 395         vector v;
 396         float valid_damage_for_weaponstats;
 397
 398         dh = max(self.health, 0);
 399         da = max(self.armorvalue, 0);
 400
 401         if(!DEATH_ISSPECIAL(deathtype))
 402         {
 403                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 404                 if(self != attacker)
 405                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 406         }
 407
 408         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 409         {
 410                 // tuba causes blood to come out of the ears
 411                 vector ear1, ear2;
 412                 vector d;
 413                 float f;
 414                 ear1 = self.origin;
 415                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 416                 ear2 = ear1;
 417                 makevectors(self.angles);
 418                 ear1 += v_right * -10;
 419                 ear2 += v_right * +10;
 420                 d = inflictor.origin - self.origin;
 421                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 422                 force = v_right * vlen(force);
 423                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 424                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 425                 if(f > 0)
 426                 {
 427                         hitloc = ear1;
 428                         force = force * -1;
 429                 }
 430                 else
 431                 {
 432                         hitloc = ear2;
 433                         // force is already good
 434                 }
 435         }
 436         else
 437                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 438
 439         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 440                 return;
 441
 442         if (!g_minstagib)
 443         {
 444                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 445                 take = v_x;
 446                 save = v_y;
 447         }
 448         else
 449         {
 450                 save = 0;
 451                 take = damage;
 452         }
 453
 454         frag_inflictor = inflictor;
 455         frag_attacker = attacker;
 456         frag_target = self;
 457         damage_take = take;
 458         damage_save = save;
 459         damage_force = force;
 460         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 461         take = bound(0, damage_take, self.health);
 462         save = bound(0, damage_save, self.armorvalue);
 463
 464         if(sound_allowed(MSG_BROADCAST, attacker))
 465         {
 466                 if (save > 10)
 467                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 468                 else if (take > 30)
 469                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 470                 else if (take > 10)
 471                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 472         }
 473
 474         if (take > 50)
 475                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 476         if (take > 100)
 477                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 478
 479         if (time >= self.spawnshieldtime)
 480         {
 481                 if (!(self.flags & FL_GODMODE))
 482                 {
 483                         self.armorvalue = self.armorvalue - save;
 484                         self.health = self.health - take;
 485                         // pause regeneration for 5 seconds
 486                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 487
 488                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 489                         {
 490                                 self.pain_finished = time + 0.5;        //Supajoe
 491
 492                                 if(sv_gentle < 1) {
 493                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 494                                         {
 495                                                 if (random() > 0.5)
 496                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 497                                                 else
 498                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 499                                         }
 500
 501                                         if(sound_allowed(MSG_BROADCAST, attacker))
 502                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 503                                         if(self.health > 1)
 504                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 505                                         {
 506                                                 if(deathtype == DEATH_FALL)
 507                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 508                                                 else if(self.health > 75) // TODO make a "gentle" version?
 509                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 510                                                 else if(self.health > 50)
 511                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 512                                                 else if(self.health > 25)
 513                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 514                                                 else
 515                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 516                                         }
 517                                 }
 518
 519                                 // throw off bot aim temporarily
 520                                 local float shake;
 521                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 522                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 523                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 524                         }
 525                 }
 526                 else
 527                         self.max_armorvalue += (save + take);
 528         }
 529         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 530         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 531         self.dmg_inflictor = inflictor;
 532
 533         if(attacker == self)
 534         {
 535                 // don't reset pushltime for self damage as it may be an attempt to
 536                 // escape a lava pit or similar
 537                 //self.pushltime = 0;
 538         }
 539         else if(attacker.classname == "player" || attacker.classname == "gib")
 540         {
 541                 self.pusher = attacker;
 542                 self.pushltime = time + autocvar_g_maxpushtime;
 543         }
 544         else if(time < self.pushltime)
 545         {
 546                 attacker = self.pusher;
 547                 self.pushltime = max(self.pushltime, time + 0.6);
 548         }
 549         else
 550                 self.pushltime = 0;
 551
 552         valid_damage_for_weaponstats = 0;
 553         if(clienttype(self) == CLIENTTYPE_REAL)
 554         if(clienttype(attacker) == CLIENTTYPE_REAL)
 555         if(self != attacker)
 556         if(!DEATH_ISSPECIAL(deathtype))
 557         if(IsDifferentTeam(self, attacker))
 558                 valid_damage_for_weaponstats = 1;
 559
 560         if(valid_damage_for_weaponstats)
 561         {
 562                 dh = dh - max(self.health, 0);
 563                 da = da - max(self.armorvalue, 0);
 564                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 565         }
 566
 567         if (self.health < 1)
 568         {
 569                 float defer_ClientKill_Now_TeamChange;
 570                 defer_ClientKill_Now_TeamChange = FALSE;
 571
 572                 if(self.alivetime)
 573                 {
 574                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 575                         self.alivetime = 0;
 576                 }
 577
 578                 if(valid_damage_for_weaponstats)
 579                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 580
 581                 if(sv_gentle < 1) // TODO make a "gentle" version?
 582                 if(sound_allowed(MSG_BROADCAST, attacker))
 583                 {
 584                         if(deathtype == DEATH_DROWN)
 585                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 586                         else
 587                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 588                 }
 589
 590                 // get rid of kill indicator
 591                 if(self.killindicator)
 592                 {
 593                         remove(self.killindicator);
 594                         self.killindicator = world;
 595                         if(self.killindicator_teamchange)
 596                                 defer_ClientKill_Now_TeamChange = TRUE;
 597
 598                         if(self.classname == "body")
 599                         if(deathtype == DEATH_KILL)
 600                         {
 601                                 // for the lemmings fans, a small harmless explosion
 602                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 603                         }
 604                 }
 605
 606                 if(!g_freezetag)
 607                 {
 608                         // become fully visible
 609                         self.alpha = 1;
 610                         // clear selected player display
 611                         ClearSelectedPlayer();
 612                         // throw a weapon
 613                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 614                 }
 615
 616                 // print an obituary message
 617                 Obituary (attacker, inflictor, self, deathtype);
 618                 race_PreDie();
 619                 DropAllRunes(self);
 620
 621                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 622                 {
 623                         PutClientInServer();
 624                         count_alive_players(); // re-count players
 625                         freezetag_CheckWinner();
 626                         return;
 627                 }
 628
 629                 frag_attacker = attacker;
 630                 frag_inflictor = inflictor;
 631                 frag_target = self;
 632                 MUTATOR_CALLHOOK(PlayerDies);
 633
 634                 if(g_freezetag)
 635             return;
 636
 637                 if(self.flagcarried)
 638                 {
 639                         if(attacker.classname != "player" && attacker.classname != "gib")
 640                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 641                         else if(attacker.team == self.team)
 642                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 643                         else
 644                                 DropFlag(self.flagcarried, world, attacker);
 645                 }
 646                 if(self.ballcarried && g_nexball)
 647                         DropBall(self.ballcarried, self.origin, self.velocity);
 648                 Portal_ClearAllLater(self);
 649                 // clear waypoints
 650                 WaypointSprite_PlayerDead();
 651                 // make the corpse upright (not tilted)
 652                 self.angles_x = 0;
 653                 self.angles_z = 0;
 654                 // don't spin
 655                 self.avelocity = '0 0 0';
 656                 // view from the floor
 657                 self.view_ofs = '0 0 -8';
 658                 // toss the corpse
 659                 self.movetype = MOVETYPE_TOSS;
 660                 // shootable corpse
 661                 self.solid = SOLID_CORPSE;
 662                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 663                 // don't stick to the floor
 664                 self.flags &~= FL_ONGROUND;
 665                 // dying animation
 666                 self.deadflag = DEAD_DYING;
 667                 // when to allow respawn
 668                 sdelay = 0;
 669                 waves = 0;
 670                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 671                 if(!sdelay)
 672         {
 673             if(g_cts)
 674                 sdelay = 0; // no respawn delay in CTS
 675             else
 676                 sdelay = autocvar_g_respawn_delay;
 677         }
 678                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 679                 if(!waves)
 680                         waves = autocvar_g_respawn_waves;
 681                 if(waves)
 682                         self.death_time = ceil((time + sdelay) / waves) * waves;
 683                 else
 684                         self.death_time = time + sdelay;
 685                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 686                         self.respawn_countdown = 10; // first number to count down from is 10
 687                 else
 688                         self.respawn_countdown = -1; // do not count down
 689                 if (random() < 0.5)
 690                 {
 691                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 692                         self.dead_frame = self.anim_dead1_x;
 693                 }
 694                 else
 695                 {
 696                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 697                         self.dead_frame = self.anim_dead2_x;
 698                 }
 699                 // set damage function to corpse damage
 700                 self.event_damage = PlayerCorpseDamage;
 701                 // call the corpse damage function just in case it wants to gib
 702                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 703                 // set up to fade out later
 704                 SUB_SetFade (self, time + 6 + random (), 1);
 705
 706                 if(clienttype(self) == CLIENTTYPE_REAL)
 707                 {
 708                         self.fixangle = TRUE;
 709                         //msg_entity = self;
 710                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 711                         //WriteAngle (MSG_ONE, self.v_angle_x);
 712                         //WriteAngle (MSG_ONE, self.v_angle_y);
 713                         //WriteAngle (MSG_ONE, 80);
 714                 }
 715
 716                 if(g_arena)
 717                         Spawnqueue_Unmark(self);
 718
 719                 if(defer_ClientKill_Now_TeamChange)
 720                         ClientKill_Now_TeamChange();
 721
 722                 if(sv_gentle > 0 || autocvar_ekg) {
 723                         // remove corpse
 724                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 725                 }
 726
 727                 // reset fields the weapons may use just in case
 728         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 729                 {
 730             weapon_action(j, WR_RESETPLAYER);
 731                         ATTACK_FINISHED_FOR(self, j) = 0;
 732                 }
 733         }
 734 }
 735
 736 float UpdateSelectedPlayer_countvalue(float v)
 737 {
 738         return max(0, (v - 1.0) / 0.5);
 739 }
 740
 741 // returns: -2 if no hit, otherwise cos of the angle
 742 // uses the global v_angle
 743 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 744 {
 745         vector so, d;
 746         float c;
 747
 748         if(p == self)
 749                 return -2;
 750
 751         if(p.deadflag)
 752                 return -2;
 753
 754         so = self.origin + self.view_ofs;
 755         d = p.origin - so;
 756
 757         // misaimed?
 758         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 759                 return -2;
 760
 761         // now find the cos of the angle...
 762         c = normalize(d) * v_forward;
 763
 764         if(c <= mincosangle)
 765                 return -2;
 766
 767         // not visible in any way? forget it
 768         if(!checkpvs(so, p))
 769                 return -2;
 770
 771         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 772         if(trace_fraction < 1)
 773                 return -2;
 774
 775         return c;
 776 }
 777
 778 void ClearSelectedPlayer()
 779 {
 780         if(self.selected_player)
 781         {
 782                 centerprint_expire(self, CENTERPRIO_POINT);
 783                 self.selected_player = world;
 784                 self.selected_player_display_needs_update = FALSE;
 785         }
 786 }
 787
 788 void UpdateSelectedPlayer()
 789 {
 790         entity selected;
 791         float selected_score;
 792         selected = world;
 793         selected_score = 0.95; // 18 degrees
 794
 795         if(!autocvar_sv_allow_shownames)
 796                 return;
 797
 798         if(clienttype(self) != CLIENTTYPE_REAL)
 799                 return;
 800
 801         if(self.cvar_cl_shownames == 0)
 802                 return;
 803
 804         if(self.cvar_cl_shownames == 1 && !teams_matter)
 805                 return;
 806
 807         makevectors(self.v_angle); // sets v_forward
 808
 809         // 1. cursor trace is always right
 810         WarpZone_crosshair_trace(self);
 811         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 812         {
 813                 selected = trace_ent;
 814         }
 815         else
 816         {
 817                 // 2. if we don't have a cursor trace, find the player which is least
 818                 //    mis-aimed at
 819                 entity p;
 820                 FOR_EACH_PLAYER(p)
 821                 {
 822                         float c;
 823                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 824                         if(c >= -1)
 825                         {
 826                                 selected = p;
 827                                 selected_score = c;
 828                         }
 829                 }
 830         }
 831
 832         if(selected)
 833         {
 834                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 835         }
 836         else
 837         {
 838                 if(time < self.selected_player_display_timeout)
 839                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 840                                 selected = self.selected_player;
 841         }
 842
 843         if(selected)
 844         {
 845                 if(selected == self.selected_player)
 846                 {
 847                         float save;
 848                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 849                         self.selected_player_count = self.selected_player_count + frametime;
 850                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 851                         {
 852                                 string namestr, healthstr;
 853                                 namestr = playername(selected);
 854                                 if(teams_matter)
 855                                 {
 856                                         healthstr = ftos(floor(selected.health));
 857                                         if(self.team == selected.team)
 858                                         {
 859                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 860                                                 self.selected_player_display_needs_update = TRUE;
 861                                         }
 862                                 }
 863                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 864                         }
 865                 }
 866                 else
 867                 {
 868                         ClearSelectedPlayer();
 869                         self.selected_player = selected;
 870                         self.selected_player_time = time;
 871                         self.selected_player_count = 0;
 872                         self.selected_player_display_needs_update = FALSE;
 873                 }
 874         }
 875         else
 876         {
 877                 ClearSelectedPlayer();
 878         }
 879
 880         if(self.selected_player)
 881                 self.last_selected_player = self.selected_player;
 882 }
 883
 884 .float muted; // to be used by prvm_edictset server playernumber muted 1
 885 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 886 // message "": do not say, just test flood control
 887 // return value:
 888 //   1 = accept
 889 //   0 = reject
 890 //  -1 = fake accept
 891 {
 892         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 893         float flood, privatemsgprefixlen;
 894         var .float flood_field;
 895         entity head;
 896         float ret;
 897
 898         if(Ban_MaybeEnforceBan(source))
 899                 return 0;
 900
 901         if(!teamsay && !privatesay)
 902                 if(substring(msgin, 0, 1) == " ")
 903                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 904
 905         msgin = formatmessage(msgin);
 906
 907         if(source.classname != "player")
 908                 colorstr = "^0"; // black for spectators
 909         else if(teams_matter)
 910                 colorstr = Team_ColorCode(source.team);
 911         else
 912                 teamsay = FALSE;
 913
 914         if(intermission_running)
 915                 teamsay = FALSE;
 916
 917         if(msgin != "")
 918                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 919
 920         /*
 921          * using bprint solves this... me stupid
 922         // how can we prevent the message from appearing in a listen server?
 923         // for now, just give "say" back and only handle say_team
 924         if(!teamsay)
 925         {
 926                 clientcommand(self, strcat("say ", msgin));
 927                 return;
 928         }
 929         */
 930
 931         if(autocvar_g_chat_teamcolors)
 932                 namestr = playername(source);
 933         else
 934                 namestr = source.netname;
 935
 936         if(msgin != "")
 937         {
 938                 if(privatesay)
 939                 {
 940                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 941                         privatemsgprefixlen = strlen(msgstr);
 942                         msgstr = strcat(msgstr, msgin);
 943                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 944                         if(autocvar_g_chat_teamcolors)
 945                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 946                         else
 947                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 948                 }
 949                 else if(teamsay)
 950                 {
 951                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 952                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 953                 }
 954                 else
 955                 {
 956                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 957                         cmsgstr = "";
 958                 }
 959                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 960         }
 961         else
 962         {
 963                 msgstr = cmsgstr = "";
 964         }
 965
 966         fullmsgstr = msgstr;
 967         fullcmsgstr = cmsgstr;
 968
 969         // FLOOD CONTROL
 970         flood = 0;
 971         if(floodcontrol)
 972         {
 973                 float flood_spl;
 974                 float flood_burst;
 975                 float flood_lmax;
 976                 float lines;
 977                 if(privatesay)
 978                 {
 979                         flood_spl = autocvar_g_chat_flood_spl_tell;
 980                         flood_burst = autocvar_g_chat_flood_burst_tell;
 981                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 982                         flood_field = floodcontrol_chattell;
 983                 }
 984                 else if(teamsay)
 985                 {
 986                         flood_spl = autocvar_g_chat_flood_spl_team;
 987                         flood_burst = autocvar_g_chat_flood_burst_team;
 988                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 989                         flood_field = floodcontrol_chatteam;
 990                 }
 991                 else
 992                 {
 993                         flood_spl = autocvar_g_chat_flood_spl;
 994                         flood_burst = autocvar_g_chat_flood_burst;
 995                         flood_lmax = autocvar_g_chat_flood_lmax;
 996                         flood_field = floodcontrol_chat;
 997                 }
 998                 flood_burst = max(0, flood_burst - 1);
 999                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1000
1001                 // do flood control for the default line size
1002                 if(msgstr != "")
1003                 {
1004                         getWrappedLine_remaining = msgstr;
1005                         msgstr = "";
1006                         lines = 0;
1007                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1008                         {
1009                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1010                                 ++lines;
1011                         }
1012                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1013
1014                         if(getWrappedLine_remaining != "")
1015                         {
1016                                 msgstr = strcat(msgstr, "\n");
1017                                 flood = 2;
1018                         }
1019
1020                         if(time >= source.flood_field)
1021                         {
1022                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1023                         }
1024                         else
1025                         {
1026                                 flood = 1;
1027                                 msgstr = fullmsgstr;
1028                         }
1029                 }
1030                 else
1031                 {
1032                         if(time >= source.flood_field)
1033                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1034                         else
1035                                 flood = 1;
1036                 }
1037
1038                 if (timeoutStatus == 2) //when game is paused, no flood protection
1039                         source.flood_field = flood = 0;
1040         }
1041
1042         if(flood == 2) // cannot happen for empty msgstr
1043         {
1044                 if(autocvar_g_chat_flood_notify_flooder)
1045                 {
1046                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1047                         sourcecmsgstr = "";
1048                 }
1049                 else
1050                 {
1051                         sourcemsgstr = fullmsgstr;
1052                         sourcecmsgstr = fullcmsgstr;
1053                 }
1054                 cmsgstr = "";
1055         }
1056         else
1057         {
1058                 sourcemsgstr = msgstr;
1059                 sourcecmsgstr = cmsgstr;
1060         }
1061
1062         if(!privatesay)
1063         if(source.classname != "player")
1064         {
1065                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
1066                         teamsay = -1; // spectators
1067         }
1068
1069         if(flood)
1070                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1071
1072         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1073         if(privatesay)
1074                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1075
1076         if(source.muted)
1077         {
1078                 // always fake the message
1079                 ret = -1;
1080         }
1081         else if(flood == 1)
1082         {
1083                 if(autocvar_g_chat_flood_notify_flooder)
1084                 {
1085                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1086                         ret = 0;
1087                 }
1088                 else
1089                         ret = -1;
1090         }
1091         else
1092         {
1093                 ret = 1;
1094         }
1095
1096         if(sourcemsgstr != "" && ret != 0)
1097         {
1098                 if(ret < 0) // fake
1099                 {
1100                         sprint(source, sourcemsgstr);
1101                         if(sourcecmsgstr != "" && !privatesay)
1102                                 centerprint(source, sourcecmsgstr);
1103                 }
1104                 else if(privatesay)
1105                 {
1106                         sprint(source, sourcemsgstr);
1107                         sprint(privatesay, msgstr);
1108                         if(cmsgstr != "")
1109                                 centerprint(privatesay, cmsgstr);
1110                 }
1111                 else if(teamsay > 0)
1112                 {
1113                         sprint(source, sourcemsgstr);
1114                         if(sourcecmsgstr != "")
1115                                 centerprint(source, sourcecmsgstr);
1116                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1117                                 if(head != source)
1118                                 {
1119                                         sprint(head, msgstr);
1120                                         if(cmsgstr != "")
1121                                                 centerprint(head, cmsgstr);
1122                                 }
1123                 }
1124                 else if(teamsay < 0)
1125                 {
1126                         sprint(source, sourcemsgstr);
1127                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1128                                 if(head != source)
1129                                         sprint(head, msgstr);
1130                 }
1131                 else if(sourcemsgstr != msgstr)
1132                 {
1133                         sprint(source, sourcemsgstr);
1134                         FOR_EACH_REALCLIENT(head)
1135                                 if(head != source)
1136                                         sprint(head, msgstr);
1137                 }
1138                 else
1139                         bprint(msgstr);
1140         }
1141
1142         return ret;
1143 }
1144
1145 float GetVoiceMessageVoiceType(string type)
1146 {
1147         if(type == "taunt")
1148                 return VOICETYPE_TAUNT;
1149         if(type == "teamshoot")
1150                 return VOICETYPE_LASTATTACKER;
1151         return VOICETYPE_TEAMRADIO;
1152 }
1153
1154 string allvoicesamples;
1155 .string GetVoiceMessageSampleField(string type)
1156 {
1157         GetPlayerSoundSampleField_notFound = 0;
1158         switch(type)
1159         {
1160 #define _VOICEMSG(m) case #m: return playersound_##m;
1161                 ALLVOICEMSGS
1162 #undef _VOICEMSG
1163         }
1164         GetPlayerSoundSampleField_notFound = 1;
1165         return playersound_taunt;
1166 }
1167
1168 .string GetPlayerSoundSampleField(string type)
1169 {
1170         GetPlayerSoundSampleField_notFound = 0;
1171         switch(type)
1172         {
1173 #define _VOICEMSG(m) case #m: return playersound_##m;
1174                 ALLPLAYERSOUNDS
1175 #undef _VOICEMSG
1176         }
1177         GetPlayerSoundSampleField_notFound = 1;
1178         return playersound_taunt;
1179 }
1180
1181 void PrecacheGlobalSound(string samplestring)
1182 {
1183         float n, i;
1184         tokenize_console(samplestring);
1185         n = stof(argv(1));
1186         if(n > 0)
1187         {
1188                 for(i = 1; i <= n; ++i)
1189                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1190         }
1191         else
1192         {
1193                 precache_sound(strcat(argv(0), ".wav"));
1194         }
1195 }
1196
1197 void PrecachePlayerSounds(string f)
1198 {
1199         float fh;
1200         string s;
1201         fh = fopen(f, FILE_READ);
1202         if(fh < 0)
1203                 return;
1204         while((s = fgets(fh)))
1205         {
1206                 if(tokenize_console(s) != 3)
1207                 {
1208                         dprint("Invalid sound info line: ", s, "\n");
1209                         continue;
1210                 }
1211                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1212         }
1213         fclose(fh);
1214
1215         if not(allvoicesamples)
1216         {
1217 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1218                 ALLVOICEMSGS
1219 #undef _VOICEMSG
1220                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1221         }
1222 }
1223
1224 void ClearPlayerSounds()
1225 {
1226 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1227         ALLPLAYERSOUNDS
1228         ALLVOICEMSGS
1229 #undef _VOICEMSG
1230 }
1231
1232 float LoadPlayerSounds(string f, float first)
1233 {
1234         float fh;
1235         string s;
1236         var .string field;
1237         fh = fopen(f, FILE_READ);
1238         if(fh < 0)
1239         {
1240                 dprint("Player sound file not found: ", f, "\n");
1241                 return 0;
1242         }
1243         while((s = fgets(fh)))
1244         {
1245                 if(tokenize_console(s) != 3)
1246                         continue;
1247                 field = GetPlayerSoundSampleField(argv(0));
1248                 if(GetPlayerSoundSampleField_notFound)
1249                         field = GetVoiceMessageSampleField(argv(0));
1250                 if(GetPlayerSoundSampleField_notFound)
1251                         continue;
1252                 if(self.field)
1253                         strunzone(self.field);
1254                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1255         }
1256         fclose(fh);
1257         return 1;
1258 }
1259
1260 .float modelindex_for_playersound;
1261 .float skinindex_for_playersound;
1262 void UpdatePlayerSounds()
1263 {
1264         if(self.modelindex == self.modelindex_for_playersound)
1265         if(self.skinindex == self.skinindex_for_playersound)
1266                 return;
1267         self.modelindex_for_playersound = self.modelindex;
1268         self.skinindex_for_playersound = self.skinindex;
1269         ClearPlayerSounds();
1270         LoadPlayerSounds("sound/player/default.sounds", 1);
1271         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1272                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1273 }
1274
1275 void FakeGlobalSound(string sample, float chan, float voicetype)
1276 {
1277         float n;
1278         float tauntrand;
1279
1280         if(sample == "")
1281                 return;
1282
1283         tokenize_console(sample);
1284         n = stof(argv(1));
1285         if(n > 0)
1286                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1287         else
1288                 sample = strcat(argv(0), ".wav"); // randomization
1289
1290         switch(voicetype)
1291         {
1292                 case VOICETYPE_LASTATTACKER_ONLY:
1293                         break;
1294                 case VOICETYPE_LASTATTACKER:
1295                         if(self.pusher)
1296                         {
1297                                 msg_entity = self;
1298                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1299                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1300                         }
1301                         break;
1302                 case VOICETYPE_TEAMRADIO:
1303                         msg_entity = self;
1304                         if(msg_entity.cvar_cl_voice_directional == 1)
1305                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1306                         else
1307                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1308                         break;
1309                 case VOICETYPE_AUTOTAUNT:
1310                         if(!sv_autotaunt)
1311                                 break;
1312                         if(!sv_taunt)
1313                                 break;
1314                         if(sv_gentle)
1315                                 break;
1316                         tauntrand = random();
1317                         msg_entity = self;
1318                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1319                         {
1320                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1321                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1322                                 else
1323                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1324                         }
1325                         break;
1326                 case VOICETYPE_TAUNT:
1327                         if(self.classname == "player")
1328                                 if(self.deadflag == DEAD_NO)
1329                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1330                         if(!sv_taunt)
1331                                 break;
1332                         if(sv_gentle)
1333                                 break;
1334                         msg_entity = self;
1335                         if (msg_entity.cvar_cl_voice_directional >= 1)
1336                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1337                         else
1338                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1339                         break;
1340                 case VOICETYPE_PLAYERSOUND:
1341                         msg_entity = self;
1342                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1343                         break;
1344                 default:
1345                         backtrace("Invalid voice type!");
1346                         break;
1347         }
1348 }
1349
1350 void GlobalSound(string sample, float chan, float voicetype)
1351 {
1352         float n;
1353         float tauntrand;
1354
1355         if(sample == "")
1356                 return;
1357
1358         tokenize_console(sample);
1359         n = stof(argv(1));
1360         if(n > 0)
1361                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1362         else
1363                 sample = strcat(argv(0), ".wav"); // randomization
1364
1365         switch(voicetype)
1366         {
1367                 case VOICETYPE_LASTATTACKER_ONLY:
1368                         if(self.pusher)
1369                         {
1370                                 msg_entity = self.pusher;
1371                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1372                                 {
1373                                         if(msg_entity.cvar_cl_voice_directional == 1)
1374                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1375                                         else
1376                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1377                                 }
1378                         }
1379                         break;
1380                 case VOICETYPE_LASTATTACKER:
1381                         if(self.pusher)
1382                         {
1383                                 msg_entity = self.pusher;
1384                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1385                                 {
1386                                         if(msg_entity.cvar_cl_voice_directional == 1)
1387                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1388                                         else
1389                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1390                                 }
1391                                 msg_entity = self;
1392                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1393                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1394                         }
1395                         break;
1396                 case VOICETYPE_TEAMRADIO:
1397                         FOR_EACH_REALCLIENT(msg_entity)
1398                                 if(!teams_matter || msg_entity.team == self.team)
1399                                 {
1400                                         if(msg_entity.cvar_cl_voice_directional == 1)
1401                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1402                                         else
1403                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1404                                 }
1405                         break;
1406                 case VOICETYPE_AUTOTAUNT:
1407                         if(!sv_autotaunt)
1408                                 break;
1409                         if(!sv_taunt)
1410                                 break;
1411                         if(sv_gentle)
1412                                 break;
1413                         tauntrand = random();
1414                         FOR_EACH_REALCLIENT(msg_entity)
1415                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1416                                 {
1417                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1418                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1419                                         else
1420                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1421                                 }
1422                         break;
1423                 case VOICETYPE_TAUNT:
1424                         if(self.classname == "player")
1425                                 if(self.deadflag == DEAD_NO)
1426                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1427                         if(!sv_taunt)
1428                                 break;
1429                         if(sv_gentle)
1430                                 break;
1431                         FOR_EACH_REALCLIENT(msg_entity)
1432                         {
1433                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1434                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1435                                 else
1436                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1437                         }
1438                         break;
1439                 case VOICETYPE_PLAYERSOUND:
1440                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1441                         break;
1442                 default:
1443                         backtrace("Invalid voice type!");
1444                         break;
1445         }
1446 }
1447
1448 void PlayerSound(.string samplefield, float chan, float voicetype)
1449 {
1450         GlobalSound(self.samplefield, chan, voicetype);
1451 }
1452
1453 void VoiceMessage(string type, string msg)
1454 {
1455         var .string sample;
1456         float voicetype, ownteam;
1457         float flood;
1458         sample = GetVoiceMessageSampleField(type);
1459
1460         if(GetPlayerSoundSampleField_notFound)
1461         {
1462                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1463                 return;
1464         }
1465
1466         voicetype = GetVoiceMessageVoiceType(type);
1467         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1468
1469         flood = Say(self, ownteam, world, msg, 1);
1470
1471         if (flood > 0)
1472                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1473         else if (flood < 0)
1474                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1475 }
1476
1477 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1478 {
1479 //      show_message
1480 //      0 (00) automove centerprint, admin message
1481 //      1 (01) automove centerprint, no admin message
1482 //      2 (10) no centerprint, admin message
1483 //      3 (11) no centerprint, no admin message
1484
1485         float lockteams_backup;
1486
1487         lockteams_backup = lockteams;  // backup any team lock
1488
1489         lockteams = 0;  // disable locked teams
1490
1491         TeamchangeFrags(client);  // move the players frags
1492         SetPlayerColors(client, team_colour - 1);  // set the players colour
1493         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1494
1495         lockteams = lockteams_backup;  // restore the team lock
1496
1497         LogTeamchange(client.playerid, client.team, type);
1498
1499         if not(show_message & 1) // admin message
1500                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1501
1502         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1503 }