qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.animstate_startframe = oldself.animstate_startframe;
 165         self.animstate_numframes = oldself.animstate_numframes;
 166         self.animstate_framerate = oldself.animstate_framerate;
 167         self.animstate_starttime = oldself.animstate_starttime;
 168         self.animstate_endtime = oldself.animstate_endtime;
 169         self.animstate_override = oldself.animstate_override;
 170         self.animstate_looping = oldself.animstate_looping;
 171         self.dphitcontentsmask = oldself.dphitcontentsmask;
 172         self.death_time = oldself.death_time;
 173         self.frame = oldself.frame;
 174         self.pain_finished = oldself.pain_finished;
 175         self.health = oldself.health;
 176         self.armorvalue = oldself.armorvalue;
 177         self.armortype = oldself.armortype;
 178         self.model = oldself.model;
 179         self.modelindex = oldself.modelindex;
 180         self.skin = oldself.skin;
 181         self.species = oldself.species;
 182         self.movetype = oldself.movetype;
 183         self.solid = oldself.solid;
 184         self.ballistics_density = oldself.ballistics_density;
 185         self.takedamage = oldself.takedamage;
 186         self.customizeentityforclient = oldself.customizeentityforclient;
 187         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 188         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 189         if (keepvelocity == 1)
 190                 self.velocity = oldself.velocity;
 191         self.oldvelocity = self.velocity;
 192         self.alpha = oldself.alpha;
 193         self.fade_time = oldself.fade_time;
 194         self.fade_rate = oldself.fade_rate;
 195         //self.weapon = oldself.weapon;
 196         setorigin(self, oldself.origin);
 197         setsize(self, oldself.mins, oldself.maxs);
 198         self.prevorigin = oldself.origin;
 199         self.reset = SUB_Remove;
 200
 201         Drag_MoveDrag(oldself, self);
 202
 203         if(self.colormap <= maxclients && self.colormap > 0)
 204                 self.colormap = 1024 + oldself.clientcolors;
 205
 206         CSQCMODEL_AUTOINIT();
 207         self.CopyBody_nextthink = oldself.nextthink;
 208         self.CopyBody_think = oldself.think;
 209         self.nextthink = time;
 210         self.think = CopyBody_Think;
 211
 212         self = oldself;
 213 }
 214
 215 float player_getspecies()
 216 {
 217         float s;
 218         get_model_parameters(self.model, self.skin);
 219         s = get_model_parameters_species;
 220         get_model_parameters(string_null, 0);
 221         if(s < 0)
 222                 return SPECIES_HUMAN;
 223         return s;
 224 }
 225
 226 void player_setupanimsformodel()
 227 {
 228         // defaults for legacy .zym models without animinfo files
 229         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 230         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 231         self.anim_draw = animfixfps(self, '2 1 3');
 232         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 233         self.anim_duckwalk = animfixfps(self, '4 1 1');
 234         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 235         self.anim_duckidle = animfixfps(self, '6 1 1');
 236         self.anim_idle = animfixfps(self, '7 1 1');
 237         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 238         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 239         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 240         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 241         self.anim_taunt = animfixfps(self, '12 1 0.33');
 242         self.anim_run = animfixfps(self, '13 1 1');
 243         self.anim_runbackwards = animfixfps(self, '14 1 1');
 244         self.anim_strafeleft = animfixfps(self, '15 1 1');
 245         self.anim_straferight = animfixfps(self, '16 1 1');
 246         //self.anim_dead1 = animfixfps(self, '17 1 1');
 247         //self.anim_dead2 = animfixfps(self, '18 1 1');
 248         self.anim_forwardright = animfixfps(self, '19 1 1');
 249         self.anim_forwardleft = animfixfps(self, '20 1 1');
 250         self.anim_backright = animfixfps(self, '21 1 1');
 251         self.anim_backleft  = animfixfps(self, '22 1 1');
 252         self.anim_melee = animfixfps(self, '23 1 1');
 253         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 254         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 255         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 256         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 257         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 258         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 259         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 260         // TODO introspect models for finding right "fps" value (1/duration)
 261         // reset animstate now
 262         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 263 }
 264
 265 void player_anim (void)
 266 {
 267         updateanim(self);
 268         if (self.weaponentity)
 269                 updateanim(self.weaponentity);
 270
 271         if (self.deadflag != DEAD_NO)
 272                 return;
 273
 274         if (!self.animstate_override)
 275         {
 276                 if (self.freezetag_frozen)
 277                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 278                 else if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 279                 {
 280                         if (self.crouch)
 281                         {
 282                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 283                                 {
 284                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 285                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 286                                         {
 287                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 288                                                 self.restart_jump = FALSE;
 289                                         }
 290                                 }
 291                         }
 292                         else
 293                         {
 294                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 295                 {
 296                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 297                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 298                     {
 299                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 300                         self.restart_jump = FALSE;
 301                     }
 302                 }
 303                         }
 304                 }
 305                 else if (self.crouch)
 306                 {
 307                         if (self.movement_x > 0 && self.movement_y == 0)
 308                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x < 0 && self.movement_y == 0)
 310                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x == 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x == 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x > 0 && self.movement_y > 0)
 316                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x > 0 && self.movement_y < 0)
 318                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x < 0 && self.movement_y > 0)
 320                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 321                         else if (self.movement_x < 0 && self.movement_y < 0)
 322                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 323                         else
 324                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 325                 }
 326                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 327                 {
 328                         if (self.movement_x > 0 && self.movement_y == 0)
 329                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x < 0 && self.movement_y == 0)
 331                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x == 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x == 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x > 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x > 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x < 0 && self.movement_y > 0)
 341                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 342                         else if (self.movement_x < 0 && self.movement_y < 0)
 343                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 344                         else
 345                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 346                 }
 347                 else
 348                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 349         }
 350
 351         if (self.weaponentity)
 352         if (!self.weaponentity.animstate_override)
 353                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 354 }
 355
 356 void SpawnThrownWeapon (vector org, float w)
 357 {
 358         if(g_minstagib)
 359         if(self.ammo_cells <= 0)
 360                 return;
 361
 362         if(g_pinata)
 363         {
 364                 float j;
 365                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 366                 {
 367                         if(WEPSET_CONTAINS_EW(self, j))
 368                                 if(W_IsWeaponThrowable(j))
 369                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 370                 }
 371         }
 372         else
 373         {
 374                 if(W_IsWeaponThrowable(self.weapon))
 375                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 376         }
 377 }
 378
 379 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 380 {
 381         float take, save;
 382         vector v;
 383         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 384
 385         // damage resistance (ignore most of the damage from a bullet or similar)
 386         damage = max(damage - 5, 1);
 387
 388         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 389         take = v_x;
 390         save = v_y;
 391
 392         if(sound_allowed(MSG_BROADCAST, attacker))
 393         {
 394                 if (save > 10)
 395                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 396                 else if (take > 30)
 397                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 398                 else if (take > 10)
 399                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 400         }
 401
 402         if (take > 50)
 403                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 404         if (take > 100)
 405                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 406
 407         if (!(self.flags & FL_GODMODE))
 408         {
 409                 self.armorvalue = self.armorvalue - save;
 410                 self.health = self.health - take;
 411                 // pause regeneration for 5 seconds
 412                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 413         }
 414         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 415         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 416         self.dmg_inflictor = inflictor;
 417
 418         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 419         {
 420                 // don't use any animations as a gib
 421                 self.frame = 0;
 422                 // view just above the floor
 423                 self.view_ofs = '0 0 4';
 424
 425                 Violence_GibSplash(self, 1, 1, attacker);
 426                 self.alpha = -1;
 427                 self.solid = SOLID_NOT; // restore later
 428                 self.takedamage = DAMAGE_NO; // restore later
 429                 self.damagedbycontents = FALSE;
 430         }
 431 }
 432
 433 void ClientKill_Now_TeamChange();
 434 void freezetag_CheckWinner();
 435
 436 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 437 {
 438         float take, save, waves, sdelay, dh, da, j;
 439         vector v;
 440         float valid_damage_for_weaponstats;
 441         float excess;
 442
 443         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 444                 return;
 445
 446         dh = max(self.health, 0);
 447         da = max(self.armorvalue, 0);
 448
 449         if(!DEATH_ISSPECIAL(deathtype))
 450         {
 451                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 452                 if(self != attacker)
 453                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 454         }
 455
 456         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 457         {
 458                 // tuba causes blood to come out of the ears
 459                 vector ear1, ear2;
 460                 vector d;
 461                 float f;
 462                 ear1 = self.origin;
 463                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 464                 ear2 = ear1;
 465                 makevectors(self.angles);
 466                 ear1 += v_right * -10;
 467                 ear2 += v_right * +10;
 468                 d = inflictor.origin - self.origin;
 469                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 470                 force = v_right * vlen(force);
 471                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 472                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 473                 if(f > 0)
 474                 {
 475                         hitloc = ear1;
 476                         force = force * -1;
 477                 }
 478                 else
 479                 {
 480                         hitloc = ear2;
 481                         // force is already good
 482                 }
 483         }
 484         else
 485                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 486
 487         if (!g_minstagib)
 488         {
 489                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 490                 take = v_x;
 491                 save = v_y;
 492         }
 493         else
 494         {
 495                 save = 0;
 496                 take = damage;
 497         }
 498
 499         frag_inflictor = inflictor;
 500         frag_attacker = attacker;
 501         frag_target = self;
 502         damage_take = take;
 503         damage_save = save;
 504         damage_force = force;
 505         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 506         take = bound(0, damage_take, self.health);
 507         save = bound(0, damage_save, self.armorvalue);
 508         excess = max(0, damage - take - save);
 509
 510         if(sound_allowed(MSG_BROADCAST, attacker))
 511         {
 512                 if (save > 10)
 513                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 514                 else if (take > 30)
 515                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 516                 else if (take > 10)
 517                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 518         }
 519
 520         if (take > 50)
 521                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 522         if (take > 100)
 523                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 524
 525         if (time >= self.spawnshieldtime)
 526         {
 527                 if (!(self.flags & FL_GODMODE))
 528                 {
 529                         self.armorvalue = self.armorvalue - save;
 530                         self.health = self.health - take;
 531                         // pause regeneration for 5 seconds
 532                         if(take)
 533                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 534
 535                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 536                         {
 537                                 self.pain_finished = time + 0.5;        //Supajoe
 538
 539                                 if(sv_gentle < 1) {
 540                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 541                                         {
 542                                                 if (!self.animstate_override)
 543                                                 {
 544                                                         if (random() > 0.5)
 545                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 546                                                         else
 547                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 548                                                 }
 549                                         }
 550
 551                                         if(sound_allowed(MSG_BROADCAST, attacker))
 552                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 553                                         if(self.health > 1)
 554                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 555                                         {
 556                                                 if(deathtype == DEATH_FALL)
 557                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 558                                                 else if(self.health > 75) // TODO make a "gentle" version?
 559                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 560                                                 else if(self.health > 50)
 561                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 562                                                 else if(self.health > 25)
 563                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 564                                                 else
 565                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 566                                         }
 567                                 }
 568
 569                                 // throw off bot aim temporarily
 570                                 float shake;
 571                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 572                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 573                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 574                         }
 575                 }
 576                 else
 577                         self.max_armorvalue += (save + take);
 578         }
 579         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 580         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 581         self.dmg_inflictor = inflictor;
 582
 583         if(attacker == self)
 584         {
 585                 // don't reset pushltime for self damage as it may be an attempt to
 586                 // escape a lava pit or similar
 587                 //self.pushltime = 0;
 588                 self.istypefrag = 0;
 589         }
 590         else if(attacker.classname == "player")
 591         {
 592                 self.pusher = attacker;
 593                 self.pushltime = time + autocvar_g_maxpushtime;
 594                 self.istypefrag = self.BUTTON_CHAT;
 595         }
 596         else if(time < self.pushltime)
 597         {
 598                 attacker = self.pusher;
 599                 self.pushltime = max(self.pushltime, time + 0.6);
 600         }
 601         else
 602         {
 603                 self.pushltime = 0;
 604                 self.istypefrag = 0;
 605         }
 606
 607         float abot, vbot, awep;
 608         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 609         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 610
 611         valid_damage_for_weaponstats = 0;
 612         awep = 0;
 613
 614         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 615         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 616         if(attacker && self != attacker)
 617         if(IsDifferentTeam(self, attacker))
 618         {
 619                 if(DEATH_ISSPECIAL(deathtype))
 620                         awep = attacker.weapon;
 621                 else
 622                         awep = DEATH_WEAPONOF(deathtype);
 623                 valid_damage_for_weaponstats = 1;
 624         }
 625
 626         if(valid_damage_for_weaponstats)
 627         {
 628                 dh = dh - max(self.health, 0);
 629                 da = da - max(self.armorvalue, 0);
 630                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 631         }
 632
 633         if (self.health < 1)
 634         {
 635                 float defer_ClientKill_Now_TeamChange;
 636                 defer_ClientKill_Now_TeamChange = FALSE;
 637
 638                 if(self.alivetime)
 639                 {
 640                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 641                         self.alivetime = 0;
 642                 }
 643
 644                 if(valid_damage_for_weaponstats)
 645                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 646
 647                 if(sv_gentle < 1) // TODO make a "gentle" version?
 648                 if(sound_allowed(MSG_BROADCAST, attacker))
 649                 {
 650                         if(deathtype == DEATH_DROWN)
 651                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 652                         else
 653                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 654                 }
 655
 656                 // get rid of kill indicator
 657                 if(self.killindicator)
 658                 {
 659                         remove(self.killindicator);
 660                         self.killindicator = world;
 661                         if(self.killindicator_teamchange)
 662                                 defer_ClientKill_Now_TeamChange = TRUE;
 663
 664                         if(self.classname == "body")
 665                         if(deathtype == DEATH_KILL)
 666                         {
 667                                 // for the lemmings fans, a small harmless explosion
 668                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 669                         }
 670                 }
 671
 672                 if(!g_freezetag)
 673                 {
 674                         // become fully visible
 675                         self.alpha = default_player_alpha;
 676                         // throw a weapon
 677                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 678                 }
 679
 680                 // print an obituary message
 681                 Obituary (attacker, inflictor, self, deathtype);
 682                 race_PreDie();
 683                 DropAllRunes(self);
 684
 685         // increment frag counter for used weapon type
 686         float w;
 687         w = DEATH_WEAPONOF(deathtype);
 688         if(WEP_VALID(w))
 689         if(accuracy_isgooddamage(attacker, self))
 690         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 691
 692                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 693                 {
 694                         PutClientInServer();
 695                         count_alive_players(); // re-count players
 696                         freezetag_CheckWinner();
 697                         return;
 698                 }
 699
 700                 frag_attacker = attacker;
 701                 frag_inflictor = inflictor;
 702                 frag_target = self;
 703                 MUTATOR_CALLHOOK(PlayerDies);
 704                 weapon_action(self.weapon, WR_PLAYERDEATH);
 705
 706                 RemoveGrapplingHook(self);
 707
 708                 Portal_ClearAllLater(self);
 709
 710                 if(clienttype(self) == CLIENTTYPE_REAL)
 711                 {
 712                         stuffcmd(self, "-zoom\n");
 713                         self.fixangle = TRUE;
 714                         //msg_entity = self;
 715                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 716                         //WriteAngle (MSG_ONE, self.v_angle_x);
 717                         //WriteAngle (MSG_ONE, self.v_angle_y);
 718                         //WriteAngle (MSG_ONE, 80);
 719                 }
 720
 721                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 722                         ClientKill_Now_TeamChange();
 723
 724                 if(g_arena)
 725                         Spawnqueue_Unmark(self);
 726
 727                 if(g_freezetag)
 728                         return;
 729
 730                 // when we get here, player actually dies
 731                 // clear waypoints (do this AFTER FreezeTag)
 732                 WaypointSprite_PlayerDead();
 733
 734                 // make the corpse upright (not tilted)
 735                 self.angles_x = 0;
 736                 self.angles_z = 0;
 737                 // don't spin
 738                 self.avelocity = '0 0 0';
 739                 // view from the floor
 740                 self.view_ofs = '0 0 -8';
 741                 // toss the corpse
 742                 self.movetype = MOVETYPE_TOSS;
 743                 // shootable corpse
 744                 self.solid = SOLID_CORPSE;
 745                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 746                 // don't stick to the floor
 747                 self.flags &~= FL_ONGROUND;
 748                 // dying animation
 749                 self.deadflag = DEAD_DYING;
 750                 // when to allow respawn
 751                 sdelay = 0;
 752                 waves = 0;
 753                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 754                 if(!sdelay)
 755                 {
 756                         if(g_cts)
 757                                 sdelay = 0; // no respawn delay in CTS
 758                         else
 759                                 sdelay = autocvar_g_respawn_delay;
 760                 }
 761                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 762                 if(!waves)
 763                         waves = autocvar_g_respawn_waves;
 764                 if(waves)
 765                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 766                 else
 767                         self.respawn_time = time + sdelay;
 768                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 769                         self.respawn_countdown = 10; // first number to count down from is 10
 770                 else
 771                         self.respawn_countdown = -1; // do not count down
 772                 self.death_time = time;
 773                 if (random() < 0.5)
 774                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 775                 else
 776                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 777                 if (self.maxs_z > 5)
 778                 {
 779                         self.maxs_z = 5;
 780                         setsize(self, self.mins, self.maxs);
 781                 }
 782                 // set damage function to corpse damage
 783                 self.event_damage = PlayerCorpseDamage;
 784                 // call the corpse damage function just in case it wants to gib
 785                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 786                 // set up to fade out later
 787                 SUB_SetFade (self, time + 6 + random (), 1);
 788
 789                 if(sv_gentle > 0 || autocvar_ekg) {
 790                         // remove corpse
 791                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 792                 }
 793
 794                 // reset fields the weapons may use just in case
 795                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 796                 {
 797                         weapon_action(j, WR_RESETPLAYER);
 798                         ATTACK_FINISHED_FOR(self, j) = 0;
 799                 }
 800         }
 801 }
 802
 803 .float muted; // to be used by prvm_edictset server playernumber muted 1
 804 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 805 // message "": do not say, just test flood control
 806 // return value:
 807 //   1 = accept
 808 //   0 = reject
 809 //  -1 = fake accept
 810 {
 811         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 812         float flood;
 813         var .float flood_field;
 814         entity head;
 815         float ret;
 816         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 817
 818         if(!teamsay && !privatesay)
 819                 if(substring(msgin, 0, 1) == " ")
 820                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 821
 822         msgin = formatmessage(msgin);
 823
 824         if(source.classname != "player")
 825                 colorstr = "^0"; // black for spectators
 826         else if(teamplay)
 827                 colorstr = Team_ColorCode(source.team);
 828         else
 829         {
 830                 colorstr = "";
 831                 teamsay = FALSE;
 832         }
 833
 834         if(intermission_running)
 835                 teamsay = FALSE;
 836
 837         if(msgin != "")
 838                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 839
 840         /*
 841          * using bprint solves this... me stupid
 842         // how can we prevent the message from appearing in a listen server?
 843         // for now, just give "say" back and only handle say_team
 844         if(!teamsay)
 845         {
 846                 clientcommand(self, strcat("say ", msgin));
 847                 return;
 848         }
 849         */
 850
 851         if(autocvar_g_chat_teamcolors)
 852                 namestr = playername(source);
 853         else
 854                 namestr = source.netname;
 855
 856         if(msgin != "")
 857         {
 858                 if(privatesay)
 859                 {
 860                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 861                         privatemsgprefixlen = strlen(msgstr);
 862                         msgstr = strcat(msgstr, msgin);
 863                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 864                         if(autocvar_g_chat_teamcolors)
 865                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 866                         else
 867                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 868                 }
 869                 else if(teamsay)
 870                 {
 871                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 872                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 873                 }
 874                 else
 875                 {
 876                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 877                         cmsgstr = "";
 878                 }
 879                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 880         }
 881         else
 882         {
 883                 msgstr = cmsgstr = "";
 884         }
 885
 886         fullmsgstr = msgstr;
 887         fullcmsgstr = cmsgstr;
 888
 889         // FLOOD CONTROL
 890         flood = 0;
 891         flood_field = floodcontrol_chat;
 892         if(floodcontrol)
 893         {
 894                 float flood_spl;
 895                 float flood_burst;
 896                 float flood_lmax;
 897                 float lines;
 898                 if(privatesay)
 899                 {
 900                         flood_spl = autocvar_g_chat_flood_spl_tell;
 901                         flood_burst = autocvar_g_chat_flood_burst_tell;
 902                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 903                         flood_field = floodcontrol_chattell;
 904                 }
 905                 else if(teamsay)
 906                 {
 907                         flood_spl = autocvar_g_chat_flood_spl_team;
 908                         flood_burst = autocvar_g_chat_flood_burst_team;
 909                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 910                         flood_field = floodcontrol_chatteam;
 911                 }
 912                 else
 913                 {
 914                         flood_spl = autocvar_g_chat_flood_spl;
 915                         flood_burst = autocvar_g_chat_flood_burst;
 916                         flood_lmax = autocvar_g_chat_flood_lmax;
 917                         flood_field = floodcontrol_chat;
 918                 }
 919                 flood_burst = max(0, flood_burst - 1);
 920                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 921
 922                 // do flood control for the default line size
 923                 if(msgstr != "")
 924                 {
 925                         getWrappedLine_remaining = msgstr;
 926                         msgstr = "";
 927                         lines = 0;
 928                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 929                         {
 930                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 931                                 ++lines;
 932                         }
 933                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 934
 935                         if(getWrappedLine_remaining != "")
 936                         {
 937                                 msgstr = strcat(msgstr, "\n");
 938                                 flood = 2;
 939                         }
 940
 941                         if(time >= source.flood_field)
 942                         {
 943                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 944                         }
 945                         else
 946                         {
 947                                 flood = 1;
 948                                 msgstr = fullmsgstr;
 949                         }
 950                 }
 951                 else
 952                 {
 953                         if(time >= source.flood_field)
 954                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 955                         else
 956                                 flood = 1;
 957                 }
 958
 959                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 960                         source.flood_field = flood = 0;
 961         }
 962
 963         if(flood == 2) // cannot happen for empty msgstr
 964         {
 965                 if(autocvar_g_chat_flood_notify_flooder)
 966                 {
 967                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 968                         sourcecmsgstr = "";
 969                 }
 970                 else
 971                 {
 972                         sourcemsgstr = fullmsgstr;
 973                         sourcecmsgstr = fullcmsgstr;
 974                 }
 975                 cmsgstr = "";
 976         }
 977         else
 978         {
 979                 sourcemsgstr = msgstr;
 980                 sourcecmsgstr = cmsgstr;
 981         }
 982
 983         if(!privatesay)
 984         if(source.classname != "player")
 985         {
 986                 if not(intermission_running)
 987                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 988                                 teamsay = -1; // spectators
 989         }
 990
 991         if(flood)
 992                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 993
 994         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 995         if(privatesay)
 996                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 997
 998         if(source.muted)
 999         {
1000                 // always fake the message
1001                 ret = -1;
1002         }
1003         else if(flood == 1)
1004         {
1005                 if(autocvar_g_chat_flood_notify_flooder)
1006                 {
1007                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1008                         ret = 0;
1009                 }
1010                 else
1011                         ret = -1;
1012         }
1013         else
1014         {
1015                 ret = 1;
1016         }
1017
1018         if(sourcemsgstr != "" && ret != 0)
1019         {
1020                 if(ret < 0) // faked message, because the player is muted
1021                 {
1022                         sprint(source, sourcemsgstr);
1023                         if(sourcecmsgstr != "" && !privatesay)
1024                                 centerprint(source, sourcecmsgstr);
1025                 }
1026                 else if(privatesay) // private message, between 2 people only, not sent to server console
1027                 {
1028                         sprint(source, sourcemsgstr);
1029                         sprint(privatesay, msgstr);
1030                         if(cmsgstr != "")
1031                                 centerprint(privatesay, cmsgstr);
1032                 }
1033                 else if(teamsay > 0) // team message, only sent to team mates
1034                 {
1035                         sprint(source, sourcemsgstr);
1036                         //print(msgstr); // send to server console too
1037                         if(sourcecmsgstr != "")
1038                                 centerprint(source, sourcecmsgstr);
1039                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1040                                 if(head != source)
1041                                 {
1042                                         sprint(head, msgstr);
1043                                         if(cmsgstr != "")
1044                                                 centerprint(head, cmsgstr);
1045                                 }
1046                 }
1047                 else if(teamsay < 0) // spectator message, only sent to spectators
1048                 {
1049                         sprint(source, sourcemsgstr);
1050                         //print(msgstr); // send to server console too
1051                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1052                                 if(head != source)
1053                                         sprint(head, msgstr);
1054                 }
1055                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1056                 {
1057                         sprint(source, sourcemsgstr);
1058                         //print(msgstr); // send to server console too
1059                         FOR_EACH_REALCLIENT(head)
1060                                 if(head != source)
1061                                         sprint(head, msgstr);
1062                 }
1063                 else
1064                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1065         }
1066
1067         return ret;
1068 }
1069
1070 float GetVoiceMessageVoiceType(string type)
1071 {
1072         if(type == "taunt")
1073                 return VOICETYPE_TAUNT;
1074         if(type == "teamshoot")
1075                 return VOICETYPE_LASTATTACKER;
1076         return VOICETYPE_TEAMRADIO;
1077 }
1078
1079 string allvoicesamples;
1080 .string GetVoiceMessageSampleField(string type)
1081 {
1082         GetPlayerSoundSampleField_notFound = 0;
1083         switch(type)
1084         {
1085 #define _VOICEMSG(m) case #m: return playersound_##m;
1086                 ALLVOICEMSGS
1087 #undef _VOICEMSG
1088         }
1089         GetPlayerSoundSampleField_notFound = 1;
1090         return playersound_taunt;
1091 }
1092
1093 .string GetPlayerSoundSampleField(string type)
1094 {
1095         GetPlayerSoundSampleField_notFound = 0;
1096         switch(type)
1097         {
1098 #define _VOICEMSG(m) case #m: return playersound_##m;
1099                 ALLPLAYERSOUNDS
1100 #undef _VOICEMSG
1101         }
1102         GetPlayerSoundSampleField_notFound = 1;
1103         return playersound_taunt;
1104 }
1105
1106 void PrecacheGlobalSound(string samplestring)
1107 {
1108         float n, i;
1109         tokenize_console(samplestring);
1110         n = stof(argv(1));
1111         if(n > 0)
1112         {
1113                 for(i = 1; i <= n; ++i)
1114                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1115         }
1116         else
1117         {
1118                 precache_sound(strcat(argv(0), ".wav"));
1119         }
1120 }
1121
1122 void PrecachePlayerSounds(string f)
1123 {
1124         float fh;
1125         string s;
1126         fh = fopen(f, FILE_READ);
1127         if(fh < 0)
1128                 return;
1129         while((s = fgets(fh)))
1130         {
1131                 if(tokenize_console(s) != 3)
1132                 {
1133                         dprint("Invalid sound info line: ", s, "\n");
1134                         continue;
1135                 }
1136                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1137         }
1138         fclose(fh);
1139
1140         if not(allvoicesamples)
1141         {
1142 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1143                 ALLVOICEMSGS
1144 #undef _VOICEMSG
1145                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1146         }
1147 }
1148
1149 void ClearPlayerSounds()
1150 {
1151 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1152         ALLPLAYERSOUNDS
1153         ALLVOICEMSGS
1154 #undef _VOICEMSG
1155 }
1156
1157 float LoadPlayerSounds(string f, float first)
1158 {
1159         float fh;
1160         string s;
1161         var .string field;
1162         fh = fopen(f, FILE_READ);
1163         if(fh < 0)
1164         {
1165                 dprint("Player sound file not found: ", f, "\n");
1166                 return 0;
1167         }
1168         while((s = fgets(fh)))
1169         {
1170                 if(tokenize_console(s) != 3)
1171                         continue;
1172                 field = GetPlayerSoundSampleField(argv(0));
1173                 if(GetPlayerSoundSampleField_notFound)
1174                         field = GetVoiceMessageSampleField(argv(0));
1175                 if(GetPlayerSoundSampleField_notFound)
1176                         continue;
1177                 if(self.field)
1178                         strunzone(self.field);
1179                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1180         }
1181         fclose(fh);
1182         return 1;
1183 }
1184
1185 .float modelindex_for_playersound;
1186 .float skin_for_playersound;
1187 void UpdatePlayerSounds()
1188 {
1189         if(self.modelindex == self.modelindex_for_playersound)
1190         if(self.skin == self.skin_for_playersound)
1191                 return;
1192         self.modelindex_for_playersound = self.modelindex;
1193         self.skin_for_playersound = self.skin;
1194         ClearPlayerSounds();
1195         LoadPlayerSounds("sound/player/default.sounds", 1);
1196         if(!autocvar_g_debug_defaultsounds)
1197                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1198                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1199 }
1200
1201 void FakeGlobalSound(string sample, float chan, float voicetype)
1202 {
1203         float n;
1204         float tauntrand;
1205
1206         if(sample == "")
1207                 return;
1208
1209         tokenize_console(sample);
1210         n = stof(argv(1));
1211         if(n > 0)
1212                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1213         else
1214                 sample = strcat(argv(0), ".wav"); // randomization
1215
1216         switch(voicetype)
1217         {
1218                 case VOICETYPE_LASTATTACKER_ONLY:
1219                         break;
1220                 case VOICETYPE_LASTATTACKER:
1221                         if(self.pusher)
1222                         {
1223                                 msg_entity = self;
1224                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1225                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1226                         }
1227                         break;
1228                 case VOICETYPE_TEAMRADIO:
1229                         msg_entity = self;
1230                         if(msg_entity.cvar_cl_voice_directional == 1)
1231                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1232                         else
1233                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1234                         break;
1235                 case VOICETYPE_AUTOTAUNT:
1236                         if(!sv_autotaunt)
1237                                 break;
1238                         if(!sv_taunt)
1239                                 break;
1240                         if(sv_gentle)
1241                                 break;
1242                         tauntrand = random();
1243                         msg_entity = self;
1244                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1245                         {
1246                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1247                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1248                                 else
1249                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1250                         }
1251                         break;
1252                 case VOICETYPE_TAUNT:
1253                         if(self.classname == "player")
1254                                 if(self.deadflag == DEAD_NO)
1255                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1256                         if(!sv_taunt)
1257                                 break;
1258                         if(sv_gentle)
1259                                 break;
1260                         msg_entity = self;
1261                         if (msg_entity.cvar_cl_voice_directional >= 1)
1262                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1263                         else
1264                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1265                         break;
1266                 case VOICETYPE_PLAYERSOUND:
1267                         msg_entity = self;
1268                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1269                         break;
1270                 default:
1271                         backtrace("Invalid voice type!");
1272                         break;
1273         }
1274 }
1275
1276 void GlobalSound(string sample, float chan, float voicetype)
1277 {
1278         float n;
1279         float tauntrand;
1280
1281         if(sample == "")
1282                 return;
1283
1284         tokenize_console(sample);
1285         n = stof(argv(1));
1286         if(n > 0)
1287                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1288         else
1289                 sample = strcat(argv(0), ".wav"); // randomization
1290
1291         switch(voicetype)
1292         {
1293                 case VOICETYPE_LASTATTACKER_ONLY:
1294                         if(self.pusher)
1295                         {
1296                                 msg_entity = self.pusher;
1297                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1298                                 {
1299                                         if(msg_entity.cvar_cl_voice_directional == 1)
1300                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1301                                         else
1302                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1303                                 }
1304                         }
1305                         break;
1306                 case VOICETYPE_LASTATTACKER:
1307                         if(self.pusher)
1308                         {
1309                                 msg_entity = self.pusher;
1310                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1311                                 {
1312                                         if(msg_entity.cvar_cl_voice_directional == 1)
1313                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1314                                         else
1315                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1316                                 }
1317                                 msg_entity = self;
1318                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1319                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1320                         }
1321                         break;
1322                 case VOICETYPE_TEAMRADIO:
1323                         FOR_EACH_REALCLIENT(msg_entity)
1324                                 if(!teamplay || msg_entity.team == self.team)
1325                                 {
1326                                         if(msg_entity.cvar_cl_voice_directional == 1)
1327                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1328                                         else
1329                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1330                                 }
1331                         break;
1332                 case VOICETYPE_AUTOTAUNT:
1333                         if(!sv_autotaunt)
1334                                 break;
1335                         if(!sv_taunt)
1336                                 break;
1337                         if(sv_gentle)
1338                                 break;
1339                         tauntrand = random();
1340                         FOR_EACH_REALCLIENT(msg_entity)
1341                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1342                                 {
1343                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1344                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1345                                         else
1346                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1347                                 }
1348                         break;
1349                 case VOICETYPE_TAUNT:
1350                         if(self.classname == "player")
1351                                 if(self.deadflag == DEAD_NO)
1352                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1353                         if(!sv_taunt)
1354                                 break;
1355                         if(sv_gentle)
1356                                 break;
1357                         FOR_EACH_REALCLIENT(msg_entity)
1358                         {
1359                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1360                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1361                                 else
1362                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1363                         }
1364                         break;
1365                 case VOICETYPE_PLAYERSOUND:
1366                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1367                         break;
1368                 default:
1369                         backtrace("Invalid voice type!");
1370                         break;
1371         }
1372 }
1373
1374 void PlayerSound(.string samplefield, float chan, float voicetype)
1375 {
1376         GlobalSound(self.samplefield, chan, voicetype);
1377 }
1378
1379 void VoiceMessage(string type, string msg)
1380 {
1381         var .string sample;
1382         float voicetype, ownteam;
1383         float flood;
1384         sample = GetVoiceMessageSampleField(type);
1385
1386         if(GetPlayerSoundSampleField_notFound)
1387         {
1388                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1389                 return;
1390         }
1391
1392         voicetype = GetVoiceMessageVoiceType(type);
1393         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1394
1395         flood = Say(self, ownteam, world, msg, 1);
1396
1397         if (flood > 0)
1398                 GlobalSound(self.sample, CH_VOICE, voicetype);
1399         else if (flood < 0)
1400                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1401 }
1402
1403 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1404 {
1405 //      show_message
1406 //      0 (00) automove centerprint, admin message
1407 //      1 (01) automove centerprint, no admin message
1408 //      2 (10) no centerprint, admin message
1409 //      3 (11) no centerprint, no admin message
1410
1411         float lockteams_backup;
1412
1413         lockteams_backup = lockteams;  // backup any team lock
1414
1415         lockteams = 0;  // disable locked teams
1416
1417         TeamchangeFrags(client);  // move the players frags
1418         SetPlayerColors(client, team_colour - 1);  // set the players colour
1419         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1420
1421         lockteams = lockteams_backup;  // restore the team lock
1422
1423         LogTeamchange(client.playerid, client.team, type);
1424
1425         if not(show_message & 1) // admin message
1426                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1427
1428         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1429 }