qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.playermodel, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 333 }
 334
 335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 336 {
 337         local float take, save;
 338         vector v;
 339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 340
 341         // damage resistance (ignore most of the damage from a bullet or similar)
 342         damage = max(damage - 5, 1);
 343
 344         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 345         take = v_x;
 346         save = v_y;
 347
 348         if(sound_allowed(MSG_BROADCAST, attacker))
 349         {
 350                 if (save > 10)
 351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 30)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 354                 else if (take > 10)
 355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 356         }
 357
 358         if (take > 50)
 359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 360         if (take > 100)
 361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 362
 363         if (!(self.flags & FL_GODMODE))
 364         {
 365                 self.armorvalue = self.armorvalue - save;
 366                 self.health = self.health - take;
 367                 // pause regeneration for 5 seconds
 368                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 369         }
 370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 372         self.dmg_inflictor = inflictor;
 373
 374         if (self.health <= -100 && self.modelindex != 0)
 375         {
 376                 // don't use any animations as a gib
 377                 self.frame = 0;
 378                 self.dead_frame = 0;
 379                 // view just above the floor
 380                 self.view_ofs = '0 0 4';
 381
 382                 Violence_GibSplash(self, 1, 1, attacker);
 383                 self.modelindex = 0; // restore later
 384                 self.solid = SOLID_NOT; // restore later
 385         }
 386 }
 387
 388 void ClientKill_Now_TeamChange();
 389 void freezetag_CheckWinner();
 390 void freezetag_Unfreeze();
 391
 392 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 393 {
 394         local float take, save, waves, sdelay, dh, da, j;
 395         vector v;
 396         float valid_damage_for_weaponstats;
 397
 398         dh = max(self.health, 0);
 399         da = max(self.armorvalue, 0);
 400
 401         if(!DEATH_ISSPECIAL(deathtype))
 402         {
 403                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 404                 if(self != attacker)
 405                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 406         }
 407
 408         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 409         {
 410                 // tuba causes blood to come out of the ears
 411                 vector ear1, ear2;
 412                 vector d;
 413                 float f;
 414                 ear1 = self.origin;
 415                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 416                 ear2 = ear1;
 417                 makevectors(self.angles);
 418                 ear1 += v_right * -10;
 419                 ear2 += v_right * +10;
 420                 d = inflictor.origin - self.origin;
 421                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 422                 force = v_right * vlen(force);
 423                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 424                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 425                 if(f > 0)
 426                 {
 427                         hitloc = ear1;
 428                         force = force * -1;
 429                 }
 430                 else
 431                 {
 432                         hitloc = ear2;
 433                         // force is already good
 434                 }
 435         }
 436         else
 437                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 438
 439         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 440                 return;
 441
 442         if (!g_minstagib)
 443         {
 444                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 445                 take = v_x;
 446                 save = v_y;
 447         }
 448         else
 449         {
 450                 save = 0;
 451                 take = damage;
 452         }
 453
 454         frag_inflictor = inflictor;
 455         frag_attacker = attacker;
 456         frag_target = self;
 457         damage_take = take;
 458         damage_save = save;
 459         damage_force = force;
 460         MUTATOR_CALLHOOK(PlayerDamage);
 461         take = bound(0, damage_take, self.health);
 462         save = bound(0, damage_save, self.armorvalue);
 463
 464         if(sound_allowed(MSG_BROADCAST, attacker))
 465         {
 466                 if (save > 10)
 467                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 468                 else if (take > 30)
 469                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 470                 else if (take > 10)
 471                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 472         }
 473
 474         if (take > 50)
 475                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 476         if (take > 100)
 477                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 478
 479         if (time >= self.spawnshieldtime)
 480         {
 481                 if (!(self.flags & FL_GODMODE))
 482                 {
 483                         self.armorvalue = self.armorvalue - save;
 484                         self.health = self.health - take;
 485                         // pause regeneration for 5 seconds
 486                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 487
 488                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 489                         {
 490                                 self.pain_finished = time + 0.5;        //Supajoe
 491
 492                                 if(sv_gentle < 1) {
 493                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 494                                         {
 495                                                 if (random() > 0.5)
 496                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 497                                                 else
 498                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 499                                         }
 500
 501                                         if(sound_allowed(MSG_BROADCAST, attacker))
 502                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 503                                         if(self.health > 1)
 504                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 505                                         {
 506                                                 if(deathtype == DEATH_FALL)
 507                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 508                                                 else if(self.health > 75) // TODO make a "gentle" version?
 509                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 510                                                 else if(self.health > 50)
 511                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 512                                                 else if(self.health > 25)
 513                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 514                                                 else
 515                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 516                                         }
 517                                 }
 518
 519                                 // throw off bot aim temporarily
 520                                 local float shake;
 521                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 522                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 523                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 524                         }
 525                 }
 526                 else
 527                         self.max_armorvalue += (save + take);
 528         }
 529         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 530         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 531         self.dmg_inflictor = inflictor;
 532
 533         if(attacker == self)
 534         {
 535                 // don't reset pushltime for self damage as it may be an attempt to
 536                 // escape a lava pit or similar
 537                 //self.pushltime = 0;
 538         }
 539         else if(attacker.classname == "player" || attacker.classname == "gib")
 540         {
 541                 self.pusher = attacker;
 542                 self.pushltime = time + cvar("g_maxpushtime");
 543         }
 544         else if(time < self.pushltime)
 545         {
 546                 attacker = self.pusher;
 547                 self.pushltime = max(self.pushltime, time + 0.6);
 548         }
 549         else
 550                 self.pushltime = 0;
 551
 552         valid_damage_for_weaponstats = 0;
 553         if(clienttype(self) == CLIENTTYPE_REAL)
 554         if(clienttype(attacker) == CLIENTTYPE_REAL)
 555         if(self != attacker)
 556         if(!DEATH_ISSPECIAL(deathtype))
 557         if(IsDifferentTeam(self, attacker))
 558                 valid_damage_for_weaponstats = 1;
 559
 560         if(valid_damage_for_weaponstats)
 561         {
 562                 dh = dh - max(self.health, 0);
 563                 da = da - max(self.armorvalue, 0);
 564                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 565         }
 566
 567         if (self.health < 1)
 568         {
 569                 float defer_ClientKill_Now_TeamChange;
 570                 defer_ClientKill_Now_TeamChange = FALSE;
 571
 572                 if(valid_damage_for_weaponstats)
 573                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 574
 575                 if(sv_gentle < 1) // TODO make a "gentle" version?
 576                 if(sound_allowed(MSG_BROADCAST, attacker))
 577                 {
 578                         if(deathtype == DEATH_DROWN)
 579                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 580                         else
 581                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 582                 }
 583
 584                 // get rid of kill indicator
 585                 if(self.killindicator)
 586                 {
 587                         remove(self.killindicator);
 588                         self.killindicator = world;
 589                         if(self.killindicator_teamchange)
 590                                 defer_ClientKill_Now_TeamChange = TRUE;
 591
 592                         if(self.classname == "body")
 593                         if(deathtype == DEATH_KILL)
 594                         {
 595                                 // for the lemmings fans, a small harmless explosion
 596                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 597                         }
 598                 }
 599
 600                 if(!g_freezetag)
 601                 {
 602                         // become fully visible
 603                         self.alpha = 1;
 604                         // clear selected player display
 605                         ClearSelectedPlayer();
 606                         // throw a weapon
 607                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 608                 }
 609
 610                 // print an obituary message
 611                 Obituary (attacker, inflictor, self, deathtype);
 612                 race_PreDie();
 613                 DropAllRunes(self);
 614
 615                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 616                 {
 617                         PutClientInServer();
 618                         count_alive_players(); // re-count players
 619                         freezetag_CheckWinner();
 620                         return;
 621                 }
 622
 623                 frag_attacker = attacker;
 624                 frag_inflictor = inflictor;
 625                 frag_target = self;
 626                 MUTATOR_CALLHOOK(PlayerDies);
 627
 628                 if(g_freezetag)
 629             return;
 630
 631                 if(self.flagcarried)
 632                 {
 633                         if(attacker.classname != "player" && attacker.classname != "gib")
 634                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 635                         else if(attacker.team == self.team)
 636                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 637                         else
 638                                 DropFlag(self.flagcarried, world, attacker);
 639                 }
 640                 if(self.ballcarried)
 641                         DropBall(self.ballcarried, self.origin, self.velocity);
 642                 Portal_ClearAllLater(self);
 643                 // clear waypoints
 644                 WaypointSprite_PlayerDead();
 645                 // make the corpse upright (not tilted)
 646                 self.angles_x = 0;
 647                 self.angles_z = 0;
 648                 // don't spin
 649                 self.avelocity = '0 0 0';
 650                 // view from the floor
 651                 self.view_ofs = '0 0 -8';
 652                 // toss the corpse
 653                 self.movetype = MOVETYPE_TOSS;
 654                 // shootable corpse
 655                 self.solid = SOLID_CORPSE;
 656                 self.ballistics_density = cvar("g_ballistics_density_corpse");
 657                 // don't stick to the floor
 658                 self.flags &~= FL_ONGROUND;
 659                 // dying animation
 660                 self.deadflag = DEAD_DYING;
 661                 // when to allow respawn
 662                 sdelay = 0;
 663                 waves = 0;
 664                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 665                 if(!sdelay)
 666                         sdelay = cvar("g_respawn_delay");
 667                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 668                 if(!waves)
 669                         waves = cvar("g_respawn_waves");
 670                 if(waves)
 671                         self.death_time = ceil((time + sdelay) / waves) * waves;
 672                 else
 673                         self.death_time = time + sdelay;
 674                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 675                         self.respawn_countdown = 10; // first number to count down from is 10
 676                 else
 677                         self.respawn_countdown = -1; // do not count down
 678                 if (random() < 0.5)
 679                 {
 680                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 681                         self.dead_frame = self.anim_dead1_x;
 682                 }
 683                 else
 684                 {
 685                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 686                         self.dead_frame = self.anim_dead2_x;
 687                 }
 688                 // set damage function to corpse damage
 689                 self.event_damage = PlayerCorpseDamage;
 690                 // call the corpse damage function just in case it wants to gib
 691                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 692                 // set up to fade out later
 693                 SUB_SetFade (self, time + 6 + random (), 1);
 694
 695                 if(clienttype(self) == CLIENTTYPE_REAL)
 696                 {
 697                         self.fixangle = TRUE;
 698                         //msg_entity = self;
 699                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 700                         //WriteAngle (MSG_ONE, self.v_angle_x);
 701                         //WriteAngle (MSG_ONE, self.v_angle_y);
 702                         //WriteAngle (MSG_ONE, 80);
 703                 }
 704
 705                 if(g_arena)
 706                         Spawnqueue_Unmark(self);
 707
 708                 if(defer_ClientKill_Now_TeamChange)
 709                         ClientKill_Now_TeamChange();
 710
 711                 if(sv_gentle > 0 || cvar("ekg")) {
 712                         // remove corpse
 713                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 714                 }
 715
 716                 // reset fields the weapons may use just in case
 717         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 718                 {
 719             weapon_action(j, WR_RESETPLAYER);
 720                         ATTACK_FINISHED_FOR(self, j) = 0;
 721                 }
 722         }
 723 }
 724
 725 float UpdateSelectedPlayer_countvalue(float v)
 726 {
 727         return max(0, (v - 1.0) / 0.5);
 728 }
 729
 730 // returns: -2 if no hit, otherwise cos of the angle
 731 // uses the global v_angle
 732 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 733 {
 734         vector so, d;
 735         float c;
 736
 737         if(p == self)
 738                 return -2;
 739
 740         if(p.deadflag)
 741                 return -2;
 742
 743         so = self.origin + self.view_ofs;
 744         d = p.origin - so;
 745
 746         // misaimed?
 747         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 748                 return -2;
 749
 750         // now find the cos of the angle...
 751         c = normalize(d) * v_forward;
 752
 753         if(c <= mincosangle)
 754                 return -2;
 755
 756         // not visible in any way? forget it
 757         if(!checkpvs(so, p))
 758                 return -2;
 759
 760         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 761         if(trace_fraction < 1)
 762                 return -2;
 763
 764         return c;
 765 }
 766
 767 void ClearSelectedPlayer()
 768 {
 769         if(self.selected_player)
 770         {
 771                 centerprint_expire(self, CENTERPRIO_POINT);
 772                 self.selected_player = world;
 773                 self.selected_player_display_needs_update = FALSE;
 774         }
 775 }
 776
 777 void UpdateSelectedPlayer()
 778 {
 779         entity selected;
 780         float selected_score;
 781         selected = world;
 782         selected_score = 0.95; // 18 degrees
 783
 784         if(!cvar("sv_allow_shownames"))
 785                 return;
 786
 787         if(clienttype(self) != CLIENTTYPE_REAL)
 788                 return;
 789
 790         if(self.cvar_cl_shownames == 0)
 791                 return;
 792
 793         if(self.cvar_cl_shownames == 1 && !teams_matter)
 794                 return;
 795
 796         makevectors(self.v_angle); // sets v_forward
 797
 798         // 1. cursor trace is always right
 799         WarpZone_crosshair_trace(self);
 800         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 801         {
 802                 selected = trace_ent;
 803         }
 804         else
 805         {
 806                 // 2. if we don't have a cursor trace, find the player which is least
 807                 //    mis-aimed at
 808                 entity p;
 809                 FOR_EACH_PLAYER(p)
 810                 {
 811                         float c;
 812                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 813                         if(c >= -1)
 814                         {
 815                                 selected = p;
 816                                 selected_score = c;
 817                         }
 818                 }
 819         }
 820
 821         if(selected)
 822         {
 823                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 824         }
 825         else
 826         {
 827                 if(time < self.selected_player_display_timeout)
 828                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 829                                 selected = self.selected_player;
 830         }
 831
 832         if(selected)
 833         {
 834                 if(selected == self.selected_player)
 835                 {
 836                         float save;
 837                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 838                         self.selected_player_count = self.selected_player_count + frametime;
 839                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 840                         {
 841                                 string namestr, healthstr;
 842                                 namestr = playername(selected);
 843                                 if(teams_matter)
 844                                 {
 845                                         healthstr = ftos(floor(selected.health));
 846                                         if(self.team == selected.team)
 847                                         {
 848                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 849                                                 self.selected_player_display_needs_update = TRUE;
 850                                         }
 851                                 }
 852                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 853                         }
 854                 }
 855                 else
 856                 {
 857                         ClearSelectedPlayer();
 858                         self.selected_player = selected;
 859                         self.selected_player_time = time;
 860                         self.selected_player_count = 0;
 861                         self.selected_player_display_needs_update = FALSE;
 862                 }
 863         }
 864         else
 865         {
 866                 ClearSelectedPlayer();
 867         }
 868
 869         if(self.selected_player)
 870                 self.last_selected_player = self.selected_player;
 871 }
 872
 873 .float muted; // to be used by prvm_edictset server playernumber muted 1
 874 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 875 // message "": do not say, just test flood control
 876 // return value:
 877 //   1 = accept
 878 //   0 = reject
 879 //  -1 = fake accept
 880 {
 881         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 882         float flood, privatemsgprefixlen;
 883         var .float flood_field;
 884         entity head;
 885         float ret;
 886
 887         if(Ban_MaybeEnforceBan(source))
 888                 return 0;
 889
 890         if(!teamsay && !privatesay)
 891                 if(substring(msgin, 0, 1) == " ")
 892                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 893
 894         msgin = formatmessage(msgin);
 895
 896         if(source.classname != "player")
 897                 colorstr = "^0"; // black for spectators
 898         else if(teams_matter)
 899                 colorstr = Team_ColorCode(source.team);
 900         else
 901                 teamsay = FALSE;
 902
 903         if(intermission_running)
 904                 teamsay = FALSE;
 905
 906         if(msgin != "")
 907                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 908
 909         /*
 910          * using bprint solves this... me stupid
 911         // how can we prevent the message from appearing in a listen server?
 912         // for now, just give "say" back and only handle say_team
 913         if(!teamsay)
 914         {
 915                 clientcommand(self, strcat("say ", msgin));
 916                 return;
 917         }
 918         */
 919
 920         if(cvar("g_chat_teamcolors"))
 921                 namestr = playername(source);
 922         else
 923                 namestr = source.netname;
 924
 925         if(msgin != "")
 926         {
 927                 if(privatesay)
 928                 {
 929                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 930                         privatemsgprefixlen = strlen(msgstr);
 931                         msgstr = strcat(msgstr, msgin);
 932                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 933                         if(cvar("g_chat_teamcolors"))
 934                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 935                         else
 936                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 937                 }
 938                 else if(teamsay)
 939                 {
 940                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 941                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 942                 }
 943                 else
 944                 {
 945                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 946                         cmsgstr = "";
 947                 }
 948                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 949         }
 950         else
 951         {
 952                 msgstr = cmsgstr = "";
 953         }
 954
 955         fullmsgstr = msgstr;
 956         fullcmsgstr = cmsgstr;
 957
 958         // FLOOD CONTROL
 959         flood = 0;
 960         if(floodcontrol)
 961         {
 962                 float flood_spl;
 963                 float flood_burst;
 964                 float flood_lmax;
 965                 float lines;
 966                 if(privatesay)
 967                 {
 968                         flood_spl = cvar("g_chat_flood_spl_tell");
 969                         flood_burst = cvar("g_chat_flood_burst_tell");
 970                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 971                         flood_field = floodcontrol_chattell;
 972                 }
 973                 else if(teamsay)
 974                 {
 975                         flood_spl = cvar("g_chat_flood_spl_team");
 976                         flood_burst = cvar("g_chat_flood_burst_team");
 977                         flood_lmax = cvar("g_chat_flood_lmax_team");
 978                         flood_field = floodcontrol_chatteam;
 979                 }
 980                 else
 981                 {
 982                         flood_spl = cvar("g_chat_flood_spl");
 983                         flood_burst = cvar("g_chat_flood_burst");
 984                         flood_lmax = cvar("g_chat_flood_lmax");
 985                         flood_field = floodcontrol_chat;
 986                 }
 987                 flood_burst = max(0, flood_burst - 1);
 988                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 989
 990                 // do flood control for the default line size
 991                 if(msgstr != "")
 992                 {
 993                         getWrappedLine_remaining = msgstr;
 994                         msgstr = "";
 995                         lines = 0;
 996                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 997                         {
 998                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 999                                 ++lines;
1000                         }
1001                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1002
1003                         if(getWrappedLine_remaining != "")
1004                         {
1005                                 msgstr = strcat(msgstr, "\n");
1006                                 flood = 2;
1007                         }
1008
1009                         if(time >= source.flood_field)
1010                         {
1011                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1012                         }
1013                         else
1014                         {
1015                                 flood = 1;
1016                                 msgstr = fullmsgstr;
1017                         }
1018                 }
1019                 else
1020                 {
1021                         if(time >= source.flood_field)
1022                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1023                         else
1024                                 flood = 1;
1025                 }
1026
1027                 if (timeoutStatus == 2) //when game is paused, no flood protection
1028                         source.flood_field = flood = 0;
1029         }
1030
1031         if(flood == 2) // cannot happen for empty msgstr
1032         {
1033                 if(cvar("g_chat_flood_notify_flooder"))
1034                 {
1035                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1036                         sourcecmsgstr = "";
1037                 }
1038                 else
1039                 {
1040                         sourcemsgstr = fullmsgstr;
1041                         sourcecmsgstr = fullcmsgstr;
1042                 }
1043                 cmsgstr = "";
1044         }
1045         else
1046         {
1047                 sourcemsgstr = msgstr;
1048                 sourcecmsgstr = cmsgstr;
1049         }
1050
1051         if(!privatesay)
1052         if(source.classname != "player")
1053         {
1054                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1055                         teamsay = -1; // spectators
1056         }
1057
1058         if(flood)
1059                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1060
1061         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1062         if(privatesay)
1063                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1064
1065         if(source.muted)
1066         {
1067                 // always fake the message
1068                 ret = -1;
1069         }
1070         else if(flood == 1)
1071         {
1072                 if(cvar("g_chat_flood_notify_flooder"))
1073                 {
1074                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1075                         ret = 0;
1076                 }
1077                 else
1078                         ret = -1;
1079         }
1080         else
1081         {
1082                 ret = 1;
1083         }
1084
1085         if(sourcemsgstr != "" && ret != 0)
1086         {
1087                 if(ret < 0) // fake
1088                 {
1089                         sprint(source, sourcemsgstr);
1090                         if(sourcecmsgstr != "" && !privatesay)
1091                                 centerprint(source, sourcecmsgstr);
1092                 }
1093                 else if(privatesay)
1094                 {
1095                         sprint(source, sourcemsgstr);
1096                         sprint(privatesay, msgstr);
1097                         if(cmsgstr != "")
1098                                 centerprint(privatesay, cmsgstr);
1099                 }
1100                 else if(teamsay > 0)
1101                 {
1102                         sprint(source, sourcemsgstr);
1103                         if(sourcecmsgstr != "")
1104                                 centerprint(source, sourcecmsgstr);
1105                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1106                                 if(head != source)
1107                                 {
1108                                         sprint(head, msgstr);
1109                                         if(cmsgstr != "")
1110                                                 centerprint(head, cmsgstr);
1111                                 }
1112                 }
1113                 else if(teamsay < 0)
1114                 {
1115                         sprint(source, sourcemsgstr);
1116                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1117                                 if(head != source)
1118                                         sprint(head, msgstr);
1119                 }
1120                 else if(sourcemsgstr != msgstr)
1121                 {
1122                         sprint(source, sourcemsgstr);
1123                         FOR_EACH_REALCLIENT(head)
1124                                 if(head != source)
1125                                         sprint(head, msgstr);
1126                 }
1127                 else
1128                         bprint(msgstr);
1129         }
1130
1131         return ret;
1132 }
1133
1134 float GetVoiceMessageVoiceType(string type)
1135 {
1136         if(type == "taunt")
1137                 return VOICETYPE_TAUNT;
1138         if(type == "teamshoot")
1139                 return VOICETYPE_LASTATTACKER;
1140         return VOICETYPE_TEAMRADIO;
1141 }
1142
1143 string allvoicesamples;
1144 float GetPlayerSoundSampleField_notFound;
1145 float GetPlayerSoundSampleField_fixed;
1146 .string GetVoiceMessageSampleField(string type)
1147 {
1148         GetPlayerSoundSampleField_notFound = 0;
1149         GetPlayerSoundSampleField_fixed = 0;
1150         switch(type)
1151         {
1152 #define _VOICEMSG(m) case #m: return playersound_##m;
1153                 ALLVOICEMSGS
1154 #undef _VOICEMSG
1155         }
1156         GetPlayerSoundSampleField_notFound = 1;
1157         return playersound_taunt;
1158 }
1159
1160 .string GetPlayerSoundSampleField(string type)
1161 {
1162         GetPlayerSoundSampleField_notFound = 0;
1163         GetPlayerSoundSampleField_fixed = 0;
1164         switch(type)
1165         {
1166 #define _VOICEMSG(m) case #m: return playersound_##m;
1167                 ALLPLAYERSOUNDS
1168 #undef _VOICEMSG
1169         }
1170         GetPlayerSoundSampleField_notFound = 1;
1171         return playersound_taunt;
1172 }
1173
1174 void PrecacheGlobalSound(string samplestring)
1175 {
1176         float n, i;
1177         tokenize_console(samplestring);
1178         n = stof(argv(1));
1179         if(n > 0)
1180         {
1181                 for(i = 1; i <= n; ++i)
1182                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1183         }
1184         else
1185         {
1186                 precache_sound(strcat(argv(0), ".wav"));
1187         }
1188 }
1189
1190 void PrecachePlayerSounds(string f)
1191 {
1192         float fh;
1193         string s;
1194         fh = fopen(f, FILE_READ);
1195         if(fh < 0)
1196                 return;
1197         while((s = fgets(fh)))
1198         {
1199                 if(tokenize_console(s) != 3)
1200                 {
1201                         dprint("Invalid sound info line: ", s, "\n");
1202                         continue;
1203                 }
1204                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1205         }
1206         fclose(fh);
1207
1208         if not(allvoicesamples)
1209         {
1210 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1211                 ALLVOICEMSGS
1212 #undef _VOICEMSG
1213                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1214         }
1215 }
1216
1217 void ClearPlayerSounds()
1218 {
1219 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1220         ALLPLAYERSOUNDS
1221         ALLVOICEMSGS
1222 #undef _VOICEMSG
1223 }
1224
1225 void LoadPlayerSounds(string f, float first)
1226 {
1227         float fh;
1228         string s;
1229         var .string field;
1230         fh = fopen(f, FILE_READ);
1231         if(fh < 0)
1232         {
1233                 dprint("Player sound file not found: ", f, "\n");
1234                 return;
1235         }
1236         while((s = fgets(fh)))
1237         {
1238                 if(tokenize_console(s) != 3)
1239                         continue;
1240                 field = GetPlayerSoundSampleField(argv(0));
1241                 if(GetPlayerSoundSampleField_notFound)
1242                         field = GetVoiceMessageSampleField(argv(0));
1243                 if(GetPlayerSoundSampleField_notFound)
1244                         continue;
1245                 if(GetPlayerSoundSampleField_fixed)
1246                         if not(first)
1247                                 continue;
1248                 if(self.field)
1249                         strunzone(self.field);
1250                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1251         }
1252         fclose(fh);
1253 }
1254
1255 .float modelindex_for_playersound;
1256 .float skinindex_for_playersound;
1257 void UpdatePlayerSounds()
1258 {
1259         if(self.modelindex == self.modelindex_for_playersound)
1260         if(self.skinindex == self.skinindex_for_playersound)
1261                 return;
1262         self.modelindex_for_playersound = self.modelindex;
1263         self.skinindex_for_playersound = self.skinindex;
1264         ClearPlayerSounds();
1265         LoadPlayerSounds("sound/player/default.sounds", 1);
1266         LoadPlayerSounds(get_model_datafilename(self.playermodel, self.skinindex, "sounds"), 0);
1267 }
1268
1269 void FakeGlobalSound(string sample, float chan, float voicetype)
1270 {
1271         float n;
1272         float tauntrand;
1273
1274         if(sample == "")
1275                 return;
1276
1277         tokenize_console(sample);
1278         n = stof(argv(1));
1279         if(n > 0)
1280                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1281         else
1282                 sample = strcat(argv(0), ".wav"); // randomization
1283
1284         switch(voicetype)
1285         {
1286                 case VOICETYPE_LASTATTACKER_ONLY:
1287                         break;
1288                 case VOICETYPE_LASTATTACKER:
1289                         if(self.pusher)
1290                         {
1291                                 msg_entity = self;
1292                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1293                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1294                         }
1295                         break;
1296                 case VOICETYPE_TEAMRADIO:
1297                         msg_entity = self;
1298                         if(msg_entity.cvar_cl_voice_directional == 1)
1299                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1300                         else
1301                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1302                         break;
1303                 case VOICETYPE_AUTOTAUNT:
1304                         if(!sv_autotaunt)
1305                                 break;
1306                         if(!sv_taunt)
1307                                 break;
1308                         if(sv_gentle)
1309                                 break;
1310                         tauntrand = random();
1311                         msg_entity = self;
1312                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1313                         {
1314                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1315                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1316                                 else
1317                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1318                         }
1319                         break;
1320                 case VOICETYPE_TAUNT:
1321                         if(self.classname == "player")
1322                                 if(self.deadflag == DEAD_NO)
1323                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1324                         if(!sv_taunt)
1325                                 break;
1326                         if(sv_gentle)
1327                                 break;
1328                         msg_entity = self;
1329                         if (msg_entity.cvar_cl_voice_directional >= 1)
1330                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1331                         else
1332                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1333                         break;
1334                 case VOICETYPE_PLAYERSOUND:
1335                         msg_entity = self;
1336                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1337                         break;
1338                 default:
1339                         backtrace("Invalid voice type!");
1340                         break;
1341         }
1342 }
1343
1344 void GlobalSound(string sample, float chan, float voicetype)
1345 {
1346         float n;
1347         float tauntrand;
1348
1349         if(sample == "")
1350                 return;
1351
1352         tokenize_console(sample);
1353         n = stof(argv(1));
1354         if(n > 0)
1355                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1356         else
1357                 sample = strcat(argv(0), ".wav"); // randomization
1358
1359         switch(voicetype)
1360         {
1361                 case VOICETYPE_LASTATTACKER_ONLY:
1362                         if(self.pusher)
1363                         {
1364                                 msg_entity = self.pusher;
1365                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1366                                 {
1367                                         if(msg_entity.cvar_cl_voice_directional == 1)
1368                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1369                                         else
1370                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1371                                 }
1372                         }
1373                         break;
1374                 case VOICETYPE_LASTATTACKER:
1375                         if(self.pusher)
1376                         {
1377                                 msg_entity = self.pusher;
1378                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1379                                 {
1380                                         if(msg_entity.cvar_cl_voice_directional == 1)
1381                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1382                                         else
1383                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1384                                 }
1385                                 msg_entity = self;
1386                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1387                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1388                         }
1389                         break;
1390                 case VOICETYPE_TEAMRADIO:
1391                         FOR_EACH_REALCLIENT(msg_entity)
1392                                 if(!teams_matter || msg_entity.team == self.team)
1393                                 {
1394                                         if(msg_entity.cvar_cl_voice_directional == 1)
1395                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1396                                         else
1397                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1398                                 }
1399                         break;
1400                 case VOICETYPE_AUTOTAUNT:
1401                         if(!sv_autotaunt)
1402                                 break;
1403                         if(!sv_taunt)
1404                                 break;
1405                         if(sv_gentle)
1406                                 break;
1407                         tauntrand = random();
1408                         FOR_EACH_REALCLIENT(msg_entity)
1409                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1410                                 {
1411                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1412                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1413                                         else
1414                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1415                                 }
1416                         break;
1417                 case VOICETYPE_TAUNT:
1418                         if(self.classname == "player")
1419                                 if(self.deadflag == DEAD_NO)
1420                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1421                         if(!sv_taunt)
1422                                 break;
1423                         if(sv_gentle)
1424                                 break;
1425                         FOR_EACH_REALCLIENT(msg_entity)
1426                         {
1427                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1428                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1429                                 else
1430                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1431                         }
1432                         break;
1433                 case VOICETYPE_PLAYERSOUND:
1434                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1435                         break;
1436                 default:
1437                         backtrace("Invalid voice type!");
1438                         break;
1439         }
1440 }
1441
1442 void PlayerSound(.string samplefield, float chan, float voicetype)
1443 {
1444         GlobalSound(self.samplefield, chan, voicetype);
1445 }
1446
1447 void VoiceMessage(string type, string msg)
1448 {
1449         var .string sample;
1450         float voicetype, ownteam;
1451         float flood;
1452         sample = GetVoiceMessageSampleField(type);
1453
1454         if(GetPlayerSoundSampleField_notFound)
1455         {
1456                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1457                 return;
1458         }
1459
1460         voicetype = GetVoiceMessageVoiceType(type);
1461         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1462
1463         flood = Say(self, ownteam, world, msg, 1);
1464
1465         if (flood > 0)
1466                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1467         else if (flood < 0)
1468                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1469 }
1470
1471 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1472 {
1473 //      show_message
1474 //      0 (00) automove centerprint, admin message
1475 //      1 (01) automove centerprint, no admin message
1476 //      2 (10) no centerprint, admin message
1477 //      3 (11) no centerprint, no admin message
1478
1479         float lockteams_backup;
1480
1481         lockteams_backup = lockteams;  // backup any team lock
1482
1483         lockteams = 0;  // disable locked teams
1484
1485         TeamchangeFrags(client);  // move the players frags
1486         SetPlayerColors(client, team_colour - 1);  // set the players colour
1487         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1488
1489         lockteams = lockteams_backup;  // restore the team lock
1490
1491         LogTeamchange(client.playerid, client.team, type);
1492
1493         if not(show_message & 1) // admin message
1494                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1495
1496         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1497 }