Merge remote-tracking branch 'origin/master' into samual/serverlist
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_player.qc
1 .entity accuracy;
2 .float accuracy_frags[WEP_MAXCOUNT];
3
4 float weaponstats_buffer;
5
6 void WeaponStats_Init()
7 {
8         if(autocvar_sv_weaponstats_file != "")
9                 weaponstats_buffer = buf_create();
10         else
11                 weaponstats_buffer = -1;
12 }
13
14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
15
16 void WeaponStats_ready(entity fh, entity pass, float status)
17 {
18         float i, j, n, ibot, jbot, idx;
19         vector v;
20         string prefix, s;
21         switch(status)
22         {
23                 case URL_READY_CANWRITE:
24                         // we can write
25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
26                         url_fputs(fh, "#begin statsfile\n");
27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
28 #ifdef WATERMARK
29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
30 #endif
31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
33                         n = tokenizebyseparator(cvar_purechanges, "\n");
34                         for(i = 0; i < n; ++i)
35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
38                                 {
39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
41                                         if(v != '0 0 0')
42                                         {
43                                                 //vector is: kills hits damage
44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
46                                         }
47                                 }
48                         url_fputs(fh, "#end\n\n");
49                         url_fclose(fh);
50                         break;
51                 case URL_READY_CANREAD:
52                         // url_fclose is processing, we got a response for writing the data
53                         // this must come from HTTP
54                         print("Got response from weapon stats server:\n");
55                         while((s = url_fgets(fh)))
56                                 print("  ", s, "\n");
57                         print("End of response.\n");
58                         url_fclose(fh);
59                         break;
60                 case URL_READY_CLOSED:
61                         // url_fclose has finished
62                         print("Weapon stats written\n");
63                         buf_del(weaponstats_buffer);
64                         weaponstats_buffer = -1;
65                         break;
66                 case URL_READY_ERROR:
67                 default:
68                         print("Weapon stats writing failed: ", ftos(status), "\n");
69                         buf_del(weaponstats_buffer);
70                         weaponstats_buffer = -1;
71                         break;
72         }
73 }
74
75 void WeaponStats_Shutdown()
76 {
77         if(weaponstats_buffer < 0)
78                 return;
79         if(autocvar_sv_weaponstats_file != "")
80         {
81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
82         }
83         else
84         {
85                 buf_del(weaponstats_buffer);
86                 weaponstats_buffer = -1;
87         }
88 }
89
90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
91 {
92         float idx;
93         if(weaponstats_buffer < 0)
94                 return;
95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
96                 return;
97         if(awep > WEP_LAST || vwep > WEP_LAST)
98                 return;
99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
101 }
102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
103 {
104         if(damage < 0)
105                 error("negative damage?");
106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
107 }
108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
109 {
110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
111 }
112
113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
114 // merged player_run and player_stand to player_anim
115 // added death animations to player_anim
116 // can now spawn thrown weapons from anywhere, not just from players
117 // thrown weapons now fade out after 20 seconds
118 // created PlayerGib function
119 // PlayerDie no longer uses hitloc or damage
120 // PlayerDie now supports dying animations as well as gibbing
121 // cleaned up PlayerDie a lot
122 // added CopyBody
123
124 .entity pusher;
125 .float pushltime;
126 .float istypefrag;
127
128 .float CopyBody_nextthink;
129 .void(void) CopyBody_think;
130 void CopyBody_Think(void)
131 {
132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
133         {
134                 self.CopyBody_think();
135                 if(wasfreed(self))
136                         return;
137                 self.CopyBody_nextthink = self.nextthink;
138                 self.CopyBody_think = self.think;
139                 self.think = CopyBody_Think;
140         }
141         CSQCMODEL_AUTOUPDATE();
142         self.nextthink = time;
143 }
144 void CopyBody(float keepvelocity)
145 {
146         entity oldself;
147         if (self.effects & EF_NODRAW)
148                 return;
149         oldself = self;
150         self = spawn();
151         self.enemy = oldself;
152         self.lip = oldself.lip;
153         self.colormap = oldself.colormap;
154         self.iscreature = oldself.iscreature;
155         self.teleportable = oldself.teleportable;
156         self.damagedbycontents = oldself.damagedbycontents;
157         self.angles = oldself.angles;
158         self.avelocity = oldself.avelocity;
159         self.classname = "body";
160         self.damageforcescale = oldself.damageforcescale;
161         self.effects = oldself.effects;
162         self.glowmod = oldself.glowmod;
163         self.event_damage = oldself.event_damage;
164         self.anim_state = oldself.anim_state;
165         self.anim_time = oldself.anim_time;
166         self.anim_lower_action = oldself.anim_lower_action;
167         self.anim_lower_time = oldself.anim_lower_time;
168         self.anim_upper_action = oldself.anim_upper_action;
169         self.anim_upper_time = oldself.anim_upper_time;
170         self.anim_implicit_state = oldself.anim_implicit_state;
171         self.anim_implicit_time = oldself.anim_implicit_time;
172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
176         self.dphitcontentsmask = oldself.dphitcontentsmask;
177         self.death_time = oldself.death_time;
178         self.pain_finished = oldself.pain_finished;
179         self.health = oldself.health;
180         self.armorvalue = oldself.armorvalue;
181         self.armortype = oldself.armortype;
182         self.model = oldself.model;
183         self.modelindex = oldself.modelindex;
184         self.skin = oldself.skin;
185         self.species = oldself.species;
186         self.movetype = oldself.movetype;
187         self.solid = oldself.solid;
188         self.ballistics_density = oldself.ballistics_density;
189         self.takedamage = oldself.takedamage;
190         self.customizeentityforclient = oldself.customizeentityforclient;
191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
193         if (keepvelocity == 1)
194                 self.velocity = oldself.velocity;
195         self.oldvelocity = self.velocity;
196         self.alpha = oldself.alpha;
197         self.fade_time = oldself.fade_time;
198         self.fade_rate = oldself.fade_rate;
199         //self.weapon = oldself.weapon;
200         setorigin(self, oldself.origin);
201         setsize(self, oldself.mins, oldself.maxs);
202         self.prevorigin = oldself.origin;
203         self.reset = SUB_Remove;
204
205         Drag_MoveDrag(oldself, self);
206
207         if(self.colormap <= maxclients && self.colormap > 0)
208                 self.colormap = 1024 + oldself.clientcolors;
209
210         CSQCMODEL_AUTOINIT();
211         self.CopyBody_nextthink = oldself.nextthink;
212         self.CopyBody_think = oldself.think;
213         self.nextthink = time;
214         self.think = CopyBody_Think;
215         // "bake" the current animation frame for clones (they don't get clientside animation)
216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
217
218         self = oldself;
219 }
220
221 float player_getspecies()
222 {
223         float s;
224         get_model_parameters(self.model, self.skin);
225         s = get_model_parameters_species;
226         get_model_parameters(string_null, 0);
227         if(s < 0)
228                 return SPECIES_HUMAN;
229         return s;
230 }
231
232 void player_setupanimsformodel()
233 {
234         // load animation info
235         animdecide_init(self);
236         animdecide_setstate(self, 0, FALSE);
237 }
238
239 void player_anim (void)
240 {
241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
242         if(self.deadflag && !deadbits)
243                 if(random() < 0.5)
244                         deadbits = ANIMSTATE_DEAD1;
245                 else
246                         deadbits = ANIMSTATE_DEAD2;
247         float animbits = deadbits;
248         if(self.freezetag_frozen)
249                 animbits |= ANIMSTATE_FROZEN;
250         if(self.crouch)
251                 animbits |= ANIMSTATE_DUCK;
252         animdecide_setstate(self, animbits, FALSE);
253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
254
255         if (self.weaponentity)
256         {
257                 updateanim(self.weaponentity);
258                 if (!self.weaponentity.animstate_override)
259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
260         }
261 }
262
263 void SpawnThrownWeapon (vector org, float w)
264 {
265         if(self.weapons & WepSet_FromWeapon(self.weapon))
266                 if(W_IsWeaponThrowable(self.weapon))
267                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
268 }
269
270 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
271 {
272         float take, save;
273         vector v;
274         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
275
276         // damage resistance (ignore most of the damage from a bullet or similar)
277         damage = max(damage - 5, 1);
278
279         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
280         take = v_x;
281         save = v_y;
282
283         if(sound_allowed(MSG_BROADCAST, attacker))
284         {
285                 if (save > 10)
286                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
287                 else if (take > 30)
288                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
289                 else if (take > 10)
290                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
291         }
292
293         if (take > 50)
294                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
295         if (take > 100)
296                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
297
298         if (!(self.flags & FL_GODMODE))
299         {
300                 self.armorvalue = self.armorvalue - save;
301                 self.health = self.health - take;
302                 // pause regeneration for 5 seconds
303                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
304         }
305         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
306         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
307         self.dmg_inflictor = inflictor;
308
309         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
310         {
311                 // don't use any animations as a gib
312                 self.frame = 0;
313                 // view just above the floor
314                 self.view_ofs = '0 0 4';
315
316                 Violence_GibSplash(self, 1, 1, attacker);
317                 self.alpha = -1;
318                 self.solid = SOLID_NOT; // restore later
319                 self.takedamage = DAMAGE_NO; // restore later
320                 self.damagedbycontents = FALSE;
321         }
322 }
323
324 void ClientKill_Now_TeamChange();
325
326 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
327 {
328         float take, save, waves, sdelay, dh, da, j;
329         vector v;
330         float valid_damage_for_weaponstats;
331         float excess;
332
333         dh = max(self.health, 0);
334         da = max(self.armorvalue, 0);
335
336         if(!DEATH_ISSPECIAL(deathtype))
337         {
338                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
339                 if(self != attacker)
340                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
341         }
342
343         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
344         {
345                 // tuba causes blood to come out of the ears
346                 vector ear1, ear2;
347                 vector d;
348                 float f;
349                 ear1 = self.origin;
350                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
351                 ear2 = ear1;
352                 makevectors(self.angles);
353                 ear1 += v_right * -10;
354                 ear2 += v_right * +10;
355                 d = inflictor.origin - self.origin;
356                 if (d)
357                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
358                 else
359                         f = 0;  // Assum ecenter.
360                 force = v_right * vlen(force);
361                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
362                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
363                 if(f > 0)
364                 {
365                         hitloc = ear1;
366                         force = force * -1;
367                 }
368                 else
369                 {
370                         hitloc = ear2;
371                         // force is already good
372                 }
373         }
374         else
375                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
376
377
378         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
379         take = v_x;
380         save = v_y;
381
382         if(attacker == self)
383         {
384                 // don't reset pushltime for self damage as it may be an attempt to
385                 // escape a lava pit or similar
386                 //self.pushltime = 0;
387                 self.istypefrag = 0;
388         }
389         else if(IS_PLAYER(attacker))
390         {
391                 self.pusher = attacker;
392                 self.pushltime = time + autocvar_g_maxpushtime;
393                 self.istypefrag = self.BUTTON_CHAT;
394         }
395         else if(time < self.pushltime)
396         {
397                 attacker = self.pusher;
398                 self.pushltime = max(self.pushltime, time + 0.6);
399         }
400         else
401         {
402                 self.pushltime = 0;
403                 self.istypefrag = 0;
404         }
405
406         frag_inflictor = inflictor;
407         frag_attacker = attacker;
408         frag_target = self;
409         frag_damage = damage;
410         damage_take = take;
411         damage_save = save;
412         damage_force = force;
413         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
414         take = bound(0, damage_take, self.health);
415         save = bound(0, damage_save, self.armorvalue);
416         excess = max(0, damage - take - save);
417
418         if(sound_allowed(MSG_BROADCAST, attacker))
419         {
420                 if (save > 10)
421                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
422                 else if (take > 30)
423                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
424                 else if (take > 10)
425                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
426         }
427
428         if (take > 50)
429                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
430         if (take > 100)
431                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
432
433         if (time >= self.spawnshieldtime)
434         {
435                 if (!(self.flags & FL_GODMODE))
436                 {
437                         self.armorvalue = self.armorvalue - save;
438                         self.health = self.health - take;
439                         // pause regeneration for 5 seconds
440                         if(take)
441                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
442
443                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
444                         {
445                                 self.pain_finished = time + 0.5;        //Supajoe
446
447                                 if(autocvar_sv_gentle < 1) {
448                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
449                                         {
450                                                 if (!self.animstate_override)
451                                                 {
452                                                         if (random() > 0.5)
453                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
454                                                         else
455                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
456                                                 }
457                                         }
458
459                                         if(sound_allowed(MSG_BROADCAST, attacker))
460                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
461                                         if(self.health > 1)
462                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
463                                         {
464                                                 if(deathtype == DEATH_FALL)
465                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
466                                                 else if(self.health > 75) // TODO make a "gentle" version?
467                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
468                                                 else if(self.health > 50)
469                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
470                                                 else if(self.health > 25)
471                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
472                                                 else
473                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
474                                         }
475                                 }
476
477                                 // throw off bot aim temporarily
478                                 float shake;
479                                 shake = damage * 5 / (bound(0,skill,100) + 1);
480                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
481                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
482                         }
483                 }
484                 else
485                         self.max_armorvalue += (save + take);
486         }
487         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
488         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
489         self.dmg_inflictor = inflictor;
490
491         float abot, vbot, awep;
492         abot = (IS_BOT_CLIENT(attacker));
493         vbot = (IS_BOT_CLIENT(self));
494
495         valid_damage_for_weaponstats = 0;
496         awep = 0;
497
498         if(vbot || IS_REAL_CLIENT(self))
499         if(abot || IS_REAL_CLIENT(attacker))
500         if(attacker && self != attacker)
501         if(DIFF_TEAM(self, attacker))
502         {
503                 if(DEATH_ISSPECIAL(deathtype))
504                         awep = attacker.weapon;
505                 else
506                         awep = DEATH_WEAPONOF(deathtype);
507                 valid_damage_for_weaponstats = 1;
508         }
509
510         if(valid_damage_for_weaponstats)
511         {
512                 dh = dh - max(self.health, 0);
513                 da = da - max(self.armorvalue, 0);
514                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
515         }
516
517         if (self.health < 1)
518         {
519                 float defer_ClientKill_Now_TeamChange;
520                 defer_ClientKill_Now_TeamChange = FALSE;
521
522                 if(self.alivetime)
523                 {
524                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
525                         self.alivetime = 0;
526                 }
527
528                 if(valid_damage_for_weaponstats)
529                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
530
531                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
532                 if(sound_allowed(MSG_BROADCAST, attacker))
533                 {
534                         if(deathtype == DEATH_DROWN)
535                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
536                         else
537                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
538                 }
539
540                 // get rid of kill indicator
541                 if(self.killindicator)
542                 {
543                         remove(self.killindicator);
544                         self.killindicator = world;
545                         if(self.killindicator_teamchange)
546                                 defer_ClientKill_Now_TeamChange = TRUE;
547
548                         if(self.classname == "body")
549                         if(deathtype == DEATH_KILL)
550                         {
551                                 // for the lemmings fans, a small harmless explosion
552                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
553                         }
554                 }
555
556                 // print an obituary message
557                 Obituary (attacker, inflictor, self, deathtype);
558                 race_PreDie();
559
560         // increment frag counter for used weapon type
561         float w;
562         w = DEATH_WEAPONOF(deathtype);
563         if(WEP_VALID(w))
564         if(accuracy_isgooddamage(attacker, self))
565         attacker.accuracy.(accuracy_frags[w-1]) += 1;
566
567                 frag_attacker = attacker;
568                 frag_inflictor = inflictor;
569                 frag_target = self;
570                 frag_deathtype = deathtype;
571                 MUTATOR_CALLHOOK(PlayerDies);
572
573                 weapon_action(self.weapon, WR_PLAYERDEATH);
574
575                 RemoveGrapplingHook(self);
576
577                 Portal_ClearAllLater(self);
578
579                 if(IS_REAL_CLIENT(self))
580                 {
581                         self.fixangle = TRUE;
582                         //msg_entity = self;
583                         //WriteByte (MSG_ONE, SVC_SETANGLE);
584                         //WriteAngle (MSG_ONE, self.v_angle_x);
585                         //WriteAngle (MSG_ONE, self.v_angle_y);
586                         //WriteAngle (MSG_ONE, 80);
587                 }
588
589                 if(defer_ClientKill_Now_TeamChange)
590                         ClientKill_Now_TeamChange(); // can turn player into spectator
591
592                 // player could have been miraculously resuscitated ;)
593                 // e.g. players in freezetag get frozen, they don't really die
594                 if(self.health >= 1 || !IS_PLAYER(self))
595                         return;
596
597                 // when we get here, player actually dies
598
599                 // clear waypoints
600                 WaypointSprite_PlayerDead();
601                 // throw a weapon
602                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
603
604                 // become fully visible
605                 self.alpha = default_player_alpha;
606                 // make the corpse upright (not tilted)
607                 self.angles_x = 0;
608                 self.angles_z = 0;
609                 // don't spin
610                 self.avelocity = '0 0 0';
611                 // view from the floor
612                 self.view_ofs = '0 0 -8';
613                 // toss the corpse
614                 self.movetype = MOVETYPE_TOSS;
615                 // shootable corpse
616                 self.solid = SOLID_CORPSE;
617                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
618                 // don't stick to the floor
619                 self.flags &= ~FL_ONGROUND;
620                 // dying animation
621                 self.deadflag = DEAD_DYING;
622                 // when to allow respawn
623                 sdelay = 0;
624                 waves = 0;
625                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
626                 if(!sdelay)
627                 {
628                         if(g_cts)
629                                 sdelay = 0; // no respawn delay in CTS
630                         else
631                                 sdelay = autocvar_g_respawn_delay;
632                 }
633                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
634                 if(!waves)
635                         waves = autocvar_g_respawn_waves;
636                 if(waves)
637                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
638                 else
639                         self.respawn_time = time + sdelay;
640                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
641                         self.respawn_countdown = 10; // first number to count down from is 10
642                 else
643                         self.respawn_countdown = -1; // do not count down
644
645                 if(g_cts || autocvar_g_forced_respawn)
646                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
647
648                 self.death_time = time;
649                 if (random() < 0.5)
650                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
651                 else
652                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
653                 if (self.maxs_z > 5)
654                 {
655                         self.maxs_z = 5;
656                         setsize(self, self.mins, self.maxs);
657                 }
658                 // set damage function to corpse damage
659                 self.event_damage = PlayerCorpseDamage;
660                 // call the corpse damage function just in case it wants to gib
661                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
662                 // set up to fade out later
663                 SUB_SetFade (self, time + 6 + random (), 1);
664
665                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
666                         // remove corpse
667                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
668                 }
669
670                 // reset fields the weapons may use just in case
671                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
672                 {
673                         weapon_action(j, WR_RESETPLAYER);
674                         ATTACK_FINISHED_FOR(self, j) = 0;
675                 }
676         }
677 }
678
679 .float muted; // to be used by prvm_edictset server playernumber muted 1
680 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
681 // message "": do not say, just test flood control
682 // return value:
683 //   1 = accept
684 //   0 = reject
685 //  -1 = fake accept
686 {
687         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
688         float flood;
689         var .float flood_field;
690         entity head;
691         float ret;
692         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
693
694         if(!teamsay && !privatesay)
695                 if(substring(msgin, 0, 1) == " ")
696                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
697
698         msgin = formatmessage(msgin);
699
700         if not(IS_PLAYER(source))
701                 colorstr = "^0"; // black for spectators
702         else if(teamplay)
703                 colorstr = Team_ColorCode(source.team);
704         else
705         {
706                 colorstr = "";
707                 teamsay = FALSE;
708         }
709
710         if(intermission_running)
711                 teamsay = FALSE;
712
713         if(msgin != "")
714                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
715
716         /*
717          * using bprint solves this... me stupid
718         // how can we prevent the message from appearing in a listen server?
719         // for now, just give "say" back and only handle say_team
720         if(!teamsay)
721         {
722                 clientcommand(self, strcat("say ", msgin));
723                 return;
724         }
725         */
726
727         if(autocvar_g_chat_teamcolors)
728                 namestr = playername(source);
729         else
730                 namestr = source.netname;
731
732         if(msgin != "")
733         {
734                 if(privatesay)
735                 {
736                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
737                         privatemsgprefixlen = strlen(msgstr);
738                         msgstr = strcat(msgstr, msgin);
739                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
740                         if(autocvar_g_chat_teamcolors)
741                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
742                         else
743                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
744                 }
745                 else if(teamsay)
746                 {
747                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
748                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
749                 }
750                 else
751                 {
752                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
753                         cmsgstr = "";
754                 }
755                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
756         }
757         else
758         {
759                 msgstr = cmsgstr = "";
760         }
761
762         fullmsgstr = msgstr;
763         fullcmsgstr = cmsgstr;
764
765         // FLOOD CONTROL
766         flood = 0;
767         flood_field = floodcontrol_chat;
768         if(floodcontrol)
769         {
770                 float flood_spl;
771                 float flood_burst;
772                 float flood_lmax;
773                 float lines;
774                 if(privatesay)
775                 {
776                         flood_spl = autocvar_g_chat_flood_spl_tell;
777                         flood_burst = autocvar_g_chat_flood_burst_tell;
778                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
779                         flood_field = floodcontrol_chattell;
780                 }
781                 else if(teamsay)
782                 {
783                         flood_spl = autocvar_g_chat_flood_spl_team;
784                         flood_burst = autocvar_g_chat_flood_burst_team;
785                         flood_lmax = autocvar_g_chat_flood_lmax_team;
786                         flood_field = floodcontrol_chatteam;
787                 }
788                 else
789                 {
790                         flood_spl = autocvar_g_chat_flood_spl;
791                         flood_burst = autocvar_g_chat_flood_burst;
792                         flood_lmax = autocvar_g_chat_flood_lmax;
793                         flood_field = floodcontrol_chat;
794                 }
795                 flood_burst = max(0, flood_burst - 1);
796                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
797
798                 // do flood control for the default line size
799                 if(msgstr != "")
800                 {
801                         getWrappedLine_remaining = msgstr;
802                         msgstr = "";
803                         lines = 0;
804                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
805                         {
806                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
807                                 ++lines;
808                         }
809                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
810
811                         if(getWrappedLine_remaining != "")
812                         {
813                                 msgstr = strcat(msgstr, "\n");
814                                 flood = 2;
815                         }
816
817                         if(time >= source.flood_field)
818                         {
819                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
820                         }
821                         else
822                         {
823                                 flood = 1;
824                                 msgstr = fullmsgstr;
825                         }
826                 }
827                 else
828                 {
829                         if(time >= source.flood_field)
830                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
831                         else
832                                 flood = 1;
833                 }
834
835                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
836                         source.flood_field = flood = 0;
837         }
838
839         if(flood == 2) // cannot happen for empty msgstr
840         {
841                 if(autocvar_g_chat_flood_notify_flooder)
842                 {
843                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
844                         sourcecmsgstr = "";
845                 }
846                 else
847                 {
848                         sourcemsgstr = fullmsgstr;
849                         sourcecmsgstr = fullcmsgstr;
850                 }
851                 cmsgstr = "";
852         }
853         else
854         {
855                 sourcemsgstr = msgstr;
856                 sourcecmsgstr = cmsgstr;
857         }
858
859         if(!privatesay)
860         if not(IS_PLAYER(source))
861         {
862                 if not(intermission_running)
863                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
864                                 teamsay = -1; // spectators
865         }
866
867         if(flood)
868                 print("NOTE: ", playername(source), "^7 is flooding.\n");
869
870         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
871         if(privatesay)
872                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
873
874         if(source.muted)
875         {
876                 // always fake the message
877                 ret = -1;
878         }
879         else if(flood == 1)
880         {
881                 if(autocvar_g_chat_flood_notify_flooder)
882                 {
883                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
884                         ret = 0;
885                 }
886                 else
887                         ret = -1;
888         }
889         else
890         {
891                 ret = 1;
892         }
893
894         if(sourcemsgstr != "" && ret != 0)
895         {
896                 if(ret < 0) // faked message, because the player is muted
897                 {
898                         sprint(source, sourcemsgstr);
899                         if(sourcecmsgstr != "" && !privatesay)
900                                 centerprint(source, sourcecmsgstr);
901                 }
902                 else if(privatesay) // private message, between 2 people only
903                 {
904                         sprint(source, sourcemsgstr);
905                         sprint(privatesay, msgstr);
906                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
907                         if(cmsgstr != "")
908                                 centerprint(privatesay, cmsgstr);
909                 }
910                 else if(teamsay > 0) // team message, only sent to team mates
911                 {
912                         sprint(source, sourcemsgstr);
913                         dedicated_print(msgstr); // send to server console too
914                         if(sourcecmsgstr != "")
915                                 centerprint(source, sourcecmsgstr);
916                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
917                                 if(head != source)
918                                 {
919                                         sprint(head, msgstr);
920                                         if(cmsgstr != "")
921                                                 centerprint(head, cmsgstr);
922                                 }
923                 }
924                 else if(teamsay < 0) // spectator message, only sent to spectators
925                 {
926                         sprint(source, sourcemsgstr);
927                         dedicated_print(msgstr); // send to server console too
928                         FOR_EACH_REALCLIENT(head) if not(IS_PLAYER(head))
929                                 if(head != source)
930                                         sprint(head, msgstr);
931                 }
932                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
933                 {
934                         sprint(source, sourcemsgstr);
935                         dedicated_print(msgstr); // send to server console too
936                         FOR_EACH_REALCLIENT(head)
937                                 if(head != source)
938                                         sprint(head, msgstr);
939                 }
940                 else
941                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
942         }
943
944         return ret;
945 }
946
947 float GetVoiceMessageVoiceType(string type)
948 {
949         if(type == "taunt")
950                 return VOICETYPE_TAUNT;
951         if(type == "teamshoot")
952                 return VOICETYPE_LASTATTACKER;
953         return VOICETYPE_TEAMRADIO;
954 }
955
956 string allvoicesamples;
957 .string GetVoiceMessageSampleField(string type)
958 {
959         GetPlayerSoundSampleField_notFound = 0;
960         switch(type)
961         {
962 #define _VOICEMSG(m) case #m: return playersound_##m;
963                 ALLVOICEMSGS
964 #undef _VOICEMSG
965         }
966         GetPlayerSoundSampleField_notFound = 1;
967         return playersound_taunt;
968 }
969
970 .string GetPlayerSoundSampleField(string type)
971 {
972         GetPlayerSoundSampleField_notFound = 0;
973         switch(type)
974         {
975 #define _VOICEMSG(m) case #m: return playersound_##m;
976                 ALLPLAYERSOUNDS
977 #undef _VOICEMSG
978         }
979         GetPlayerSoundSampleField_notFound = 1;
980         return playersound_taunt;
981 }
982
983 void PrecacheGlobalSound(string samplestring)
984 {
985         float n, i;
986         tokenize_console(samplestring);
987         n = stof(argv(1));
988         if(n > 0)
989         {
990                 for(i = 1; i <= n; ++i)
991                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
992         }
993         else
994         {
995                 precache_sound(strcat(argv(0), ".wav"));
996         }
997 }
998
999 void PrecachePlayerSounds(string f)
1000 {
1001         float fh;
1002         string s;
1003         fh = fopen(f, FILE_READ);
1004         if(fh < 0)
1005                 return;
1006         while((s = fgets(fh)))
1007         {
1008                 if(tokenize_console(s) != 3)
1009                 {
1010                         dprint("Invalid sound info line: ", s, "\n");
1011                         continue;
1012                 }
1013                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1014         }
1015         fclose(fh);
1016
1017         if not(allvoicesamples)
1018         {
1019 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1020                 ALLVOICEMSGS
1021 #undef _VOICEMSG
1022                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1023         }
1024 }
1025
1026 void ClearPlayerSounds()
1027 {
1028 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1029         ALLPLAYERSOUNDS
1030         ALLVOICEMSGS
1031 #undef _VOICEMSG
1032 }
1033
1034 float LoadPlayerSounds(string f, float first)
1035 {
1036         float fh;
1037         string s;
1038         var .string field;
1039         fh = fopen(f, FILE_READ);
1040         if(fh < 0)
1041         {
1042                 dprint("Player sound file not found: ", f, "\n");
1043                 return 0;
1044         }
1045         while((s = fgets(fh)))
1046         {
1047                 if(tokenize_console(s) != 3)
1048                         continue;
1049                 field = GetPlayerSoundSampleField(argv(0));
1050                 if(GetPlayerSoundSampleField_notFound)
1051                         field = GetVoiceMessageSampleField(argv(0));
1052                 if(GetPlayerSoundSampleField_notFound)
1053                         continue;
1054                 if(self.field)
1055                         strunzone(self.field);
1056                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1057         }
1058         fclose(fh);
1059         return 1;
1060 }
1061
1062 .float modelindex_for_playersound;
1063 .float skin_for_playersound;
1064 void UpdatePlayerSounds()
1065 {
1066         if(self.modelindex == self.modelindex_for_playersound)
1067         if(self.skin == self.skin_for_playersound)
1068                 return;
1069         self.modelindex_for_playersound = self.modelindex;
1070         self.skin_for_playersound = self.skin;
1071         ClearPlayerSounds();
1072         LoadPlayerSounds("sound/player/default.sounds", 1);
1073         if(!autocvar_g_debug_defaultsounds)
1074                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1075                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1076 }
1077
1078 void FakeGlobalSound(string sample, float chan, float voicetype)
1079 {
1080         float n;
1081         float tauntrand;
1082
1083         if(sample == "")
1084                 return;
1085
1086         tokenize_console(sample);
1087         n = stof(argv(1));
1088         if(n > 0)
1089                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1090         else
1091                 sample = strcat(argv(0), ".wav"); // randomization
1092
1093         switch(voicetype)
1094         {
1095                 case VOICETYPE_LASTATTACKER_ONLY:
1096                         break;
1097                 case VOICETYPE_LASTATTACKER:
1098                         if(self.pusher)
1099                         {
1100                                 msg_entity = self;
1101                                 if(IS_REAL_CLIENT(msg_entity))
1102                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1103                         }
1104                         break;
1105                 case VOICETYPE_TEAMRADIO:
1106                         msg_entity = self;
1107                         if(msg_entity.cvar_cl_voice_directional == 1)
1108                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1109                         else
1110                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1111                         break;
1112                 case VOICETYPE_AUTOTAUNT:
1113                         if(!sv_autotaunt)
1114                                 break;
1115                         if(!sv_taunt)
1116                                 break;
1117                         if(autocvar_sv_gentle)
1118                                 break;
1119                         tauntrand = random();
1120                         msg_entity = self;
1121                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1122                         {
1123                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1124                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1125                                 else
1126                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1127                         }
1128                         break;
1129                 case VOICETYPE_TAUNT:
1130                         if(IS_PLAYER(self))
1131                                 if(self.deadflag == DEAD_NO)
1132                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1133                         if(!sv_taunt)
1134                                 break;
1135                         if(autocvar_sv_gentle)
1136                                 break;
1137                         msg_entity = self;
1138                         if (msg_entity.cvar_cl_voice_directional >= 1)
1139                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1140                         else
1141                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1142                         break;
1143                 case VOICETYPE_PLAYERSOUND:
1144                         msg_entity = self;
1145                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1146                         break;
1147                 default:
1148                         backtrace("Invalid voice type!");
1149                         break;
1150         }
1151 }
1152
1153 void GlobalSound(string sample, float chan, float voicetype)
1154 {
1155         float n;
1156         float tauntrand;
1157
1158         if(sample == "")
1159                 return;
1160
1161         tokenize_console(sample);
1162         n = stof(argv(1));
1163         if(n > 0)
1164                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1165         else
1166                 sample = strcat(argv(0), ".wav"); // randomization
1167
1168         switch(voicetype)
1169         {
1170                 case VOICETYPE_LASTATTACKER_ONLY:
1171                         if(self.pusher)
1172                         {
1173                                 msg_entity = self.pusher;
1174                                 if(IS_REAL_CLIENT(msg_entity))
1175                                 {
1176                                         if(msg_entity.cvar_cl_voice_directional == 1)
1177                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1178                                         else
1179                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1180                                 }
1181                         }
1182                         break;
1183                 case VOICETYPE_LASTATTACKER:
1184                         if(self.pusher)
1185                         {
1186                                 msg_entity = self.pusher;
1187                                 if(IS_REAL_CLIENT(msg_entity))
1188                                 {
1189                                         if(msg_entity.cvar_cl_voice_directional == 1)
1190                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1191                                         else
1192                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1193                                 }
1194                                 msg_entity = self;
1195                                 if(IS_REAL_CLIENT(msg_entity))
1196                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1197                         }
1198                         break;
1199                 case VOICETYPE_TEAMRADIO:
1200                         FOR_EACH_REALCLIENT(msg_entity)
1201                                 if(!teamplay || msg_entity.team == self.team)
1202                                 {
1203                                         if(msg_entity.cvar_cl_voice_directional == 1)
1204                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1205                                         else
1206                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1207                                 }
1208                         break;
1209                 case VOICETYPE_AUTOTAUNT:
1210                         if(!sv_autotaunt)
1211                                 break;
1212                         if(!sv_taunt)
1213                                 break;
1214                         if(autocvar_sv_gentle)
1215                                 break;
1216                         tauntrand = random();
1217                         FOR_EACH_REALCLIENT(msg_entity)
1218                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1219                                 {
1220                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1221                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1222                                         else
1223                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1224                                 }
1225                         break;
1226                 case VOICETYPE_TAUNT:
1227                         if(IS_PLAYER(self))
1228                                 if(self.deadflag == DEAD_NO)
1229                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1230                         if(!sv_taunt)
1231                                 break;
1232                         if(autocvar_sv_gentle)
1233                                 break;
1234                         FOR_EACH_REALCLIENT(msg_entity)
1235                         {
1236                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1237                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1238                                 else
1239                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1240                         }
1241                         break;
1242                 case VOICETYPE_PLAYERSOUND:
1243                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1244                         break;
1245                 default:
1246                         backtrace("Invalid voice type!");
1247                         break;
1248         }
1249 }
1250
1251 void PlayerSound(.string samplefield, float chan, float voicetype)
1252 {
1253         GlobalSound(self.samplefield, chan, voicetype);
1254 }
1255
1256 void VoiceMessage(string type, string msg)
1257 {
1258         var .string sample;
1259         float voicetype, ownteam;
1260         float flood;
1261         sample = GetVoiceMessageSampleField(type);
1262
1263         if(GetPlayerSoundSampleField_notFound)
1264         {
1265                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1266                 return;
1267         }
1268
1269         voicetype = GetVoiceMessageVoiceType(type);
1270         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1271
1272         flood = Say(self, ownteam, world, msg, 1);
1273
1274         if (flood > 0)
1275                 GlobalSound(self.sample, CH_VOICE, voicetype);
1276         else if (flood < 0)
1277                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1278 }
1279
1280 void MoveToTeam(entity client, float team_colour, float type)
1281 {
1282         float lockteams_backup;
1283
1284         lockteams_backup = lockteams;  // backup any team lock
1285
1286         lockteams = 0;  // disable locked teams
1287
1288         TeamchangeFrags(client);  // move the players frags
1289         SetPlayerColors(client, team_colour - 1);  // set the players colour
1290         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1291
1292         lockteams = lockteams_backup;  // restore the team lock
1293
1294         LogTeamchange(client.playerid, client.team, type);
1295 }