qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.v_angle = oldself.v_angle;
 159         self.avelocity = oldself.avelocity;
 160         self.classname = "body";
 161         self.damageforcescale = oldself.damageforcescale;
 162         self.effects = oldself.effects;
 163         self.glowmod = oldself.glowmod;
 164         self.event_damage = oldself.event_damage;
 165         self.anim_state = oldself.anim_state;
 166         self.anim_time = oldself.anim_time;
 167         self.anim_lower_action = oldself.anim_lower_action;
 168         self.anim_lower_time = oldself.anim_lower_time;
 169         self.anim_upper_action = oldself.anim_upper_action;
 170         self.anim_upper_time = oldself.anim_upper_time;
 171         self.anim_implicit_state = oldself.anim_implicit_state;
 172         self.anim_implicit_time = oldself.anim_implicit_time;
 173         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 174         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 175         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 176         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 177         self.dphitcontentsmask = oldself.dphitcontentsmask;
 178         self.death_time = oldself.death_time;
 179         self.pain_finished = oldself.pain_finished;
 180         self.health = oldself.health;
 181         self.armorvalue = oldself.armorvalue;
 182         self.armortype = oldself.armortype;
 183         self.model = oldself.model;
 184         self.modelindex = oldself.modelindex;
 185         self.skin = oldself.skin;
 186         self.species = oldself.species;
 187         self.movetype = oldself.movetype;
 188         self.solid = oldself.solid;
 189         self.ballistics_density = oldself.ballistics_density;
 190         self.takedamage = oldself.takedamage;
 191         self.customizeentityforclient = oldself.customizeentityforclient;
 192         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 193         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 194         if (keepvelocity == 1)
 195                 self.velocity = oldself.velocity;
 196         self.oldvelocity = self.velocity;
 197         self.alpha = oldself.alpha;
 198         self.fade_time = oldself.fade_time;
 199         self.fade_rate = oldself.fade_rate;
 200         //self.weapon = oldself.weapon;
 201         setorigin(self, oldself.origin);
 202         setsize(self, oldself.mins, oldself.maxs);
 203         self.prevorigin = oldself.origin;
 204         self.reset = SUB_Remove;
 205
 206         Drag_MoveDrag(oldself, self);
 207
 208         if(self.colormap <= maxclients && self.colormap > 0)
 209                 self.colormap = 1024 + oldself.clientcolors;
 210
 211         CSQCMODEL_AUTOINIT();
 212         self.CopyBody_nextthink = oldself.nextthink;
 213         self.CopyBody_think = oldself.think;
 214         self.nextthink = time;
 215         self.think = CopyBody_Think;
 216         // "bake" the current animation frame for clones (they don't get clientside animation)
 217         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 218
 219         self = oldself;
 220 }
 221
 222 float player_getspecies()
 223 {
 224         float s;
 225         get_model_parameters(self.model, self.skin);
 226         s = get_model_parameters_species;
 227         get_model_parameters(string_null, 0);
 228         if(s < 0)
 229                 return SPECIES_HUMAN;
 230         return s;
 231 }
 232
 233 void player_setupanimsformodel()
 234 {
 235         // load animation info
 236         animdecide_init(self);
 237         animdecide_setstate(self, 0, FALSE);
 238 }
 239
 240 void player_anim (void)
 241 {
 242         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 243         if(self.deadflag) {
 244                 if (!deadbits) {
 245                         // Decide on which death animation to use.
 246                         if(random() < 0.5)
 247                                 deadbits = ANIMSTATE_DEAD1;
 248                         else
 249                                 deadbits = ANIMSTATE_DEAD2;
 250                 }
 251         } else {
 252                 // Clear a previous death animation.
 253                 deadbits = 0;
 254         }
 255         float animbits = deadbits;
 256         if(self.frozen)
 257                 animbits |= ANIMSTATE_FROZEN;
 258         if(self.crouch)
 259                 animbits |= ANIMSTATE_DUCK;
 260         animdecide_setstate(self, animbits, FALSE);
 261         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 262
 263         if (self.weaponentity)
 264         {
 265                 updateanim(self.weaponentity);
 266                 if (!self.weaponentity.animstate_override)
 267                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 268         }
 269 }
 270
 271 void SpawnThrownWeapon (vector org, float w)
 272 {
 273         if(self.weapons & WepSet_FromWeapon(self.weapon))
 274                 if(W_IsWeaponThrowable(self.weapon))
 275                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 276 }
 277
 278 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 279 {
 280         float take, save;
 281         vector v;
 282         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 283
 284         // damage resistance (ignore most of the damage from a bullet or similar)
 285         damage = max(damage - 5, 1);
 286
 287         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 288         take = v_x;
 289         save = v_y;
 290
 291         if(sound_allowed(MSG_BROADCAST, attacker))
 292         {
 293                 if (save > 10)
 294                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 295                 else if (take > 30)
 296                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 297                 else if (take > 10)
 298                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 299         }
 300
 301         if (take > 50)
 302                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 303         if (take > 100)
 304                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 305
 306         if (!(self.flags & FL_GODMODE))
 307         {
 308                 self.armorvalue = self.armorvalue - save;
 309                 self.health = self.health - take;
 310                 // pause regeneration for 5 seconds
 311                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 312         }
 313         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 314         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 315         self.dmg_inflictor = inflictor;
 316
 317         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 318         {
 319                 // don't use any animations as a gib
 320                 self.frame = 0;
 321                 // view just above the floor
 322                 self.view_ofs = '0 0 4';
 323
 324                 Violence_GibSplash(self, 1, 1, attacker);
 325                 self.alpha = -1;
 326                 self.solid = SOLID_NOT; // restore later
 327                 self.takedamage = DAMAGE_NO; // restore later
 328                 self.damagedbycontents = FALSE;
 329         }
 330 }
 331
 332 // g_<gametype>_str:
 333 // If 0, default is used.
 334 // If <0, 0 is used.
 335 // Otherwise, g_str (default value) is used.
 336 // For consistency, negative values there are mapped to zero too.
 337 #define GAMETYPE_DEFAULTED_SETTING(str) \
 338         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 339          (gametype_setting_tmp < 0) ? 0 : \
 340          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 341          gametype_setting_tmp)
 342
 343
 344 void calculate_player_respawn_time()
 345 {
 346         float gametype_setting_tmp;
 347         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 348         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 349         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 350         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 351         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 352         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 353
 354         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 355         entity pl;
 356         if (teamplay)
 357         {
 358                 FOR_EACH_PLAYER(pl)
 359                         if (pl != self)
 360                                 if (pl.team == self.team)
 361                                         ++pcount;
 362                 if (sdelay_small_count == 0)
 363                         sdelay_small_count = 1;
 364                 if (sdelay_large_count == 0)
 365                         sdelay_large_count = 1;
 366         }
 367         else
 368         {
 369                 FOR_EACH_PLAYER(pl)
 370                         if (pl != self)
 371                                 ++pcount;
 372                 if (sdelay_small_count == 0)
 373                 {
 374                         if (g_cts)
 375                         {
 376                                 // Players play independently. No point in requiring enemies.
 377                                 sdelay_small_count = 1;
 378                         }
 379                         else
 380                         {
 381                                 // Players play AGAINST each other. Enemies required.
 382                                 sdelay_small_count = 2;
 383                         }
 384                 }
 385                 if (sdelay_large_count == 0)
 386                 {
 387                         if (g_cts)
 388                         {
 389                                 // Players play independently. No point in requiring enemies.
 390                                 sdelay_large_count = 1;
 391                         }
 392                         else
 393                         {
 394                                 // Players play AGAINST each other. Enemies required.
 395                                 sdelay_large_count = 2;
 396                         }
 397                 }
 398         }
 399
 400         float sdelay;
 401
 402         if (pcount <= sdelay_small_count)
 403                 sdelay = sdelay_small;
 404         else if (pcount >= sdelay_large_count)
 405                 sdelay = sdelay_large;
 406         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 407                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 408
 409         if(waves)
 410                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 411         else
 412                 self.respawn_time = time + sdelay;
 413
 414         if(sdelay < sdelay_max)
 415                 self.respawn_time_max = time + sdelay_max;
 416         else
 417                 self.respawn_time_max = self.respawn_time;
 418
 419         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 420                 self.respawn_countdown = 10; // first number to count down from is 10
 421         else
 422                 self.respawn_countdown = -1; // do not count down
 423
 424         if(autocvar_g_forced_respawn)
 425                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 426 }
 427
 428 void ClientKill_Now_TeamChange();
 429
 430 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 431 {
 432         float take, save, dh, da, j;
 433         vector v;
 434         float valid_damage_for_weaponstats;
 435         float excess;
 436
 437         dh = max(self.health, 0);
 438         da = max(self.armorvalue, 0);
 439
 440         if(!DEATH_ISSPECIAL(deathtype))
 441         {
 442                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 443                 if(self != attacker)
 444                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 445         }
 446
 447         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 448         {
 449                 // tuba causes blood to come out of the ears
 450                 vector ear1, ear2;
 451                 vector d;
 452                 float f;
 453                 ear1 = self.origin;
 454                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 455                 ear2 = ear1;
 456                 makevectors(self.angles);
 457                 ear1 += v_right * -10;
 458                 ear2 += v_right * +10;
 459                 d = inflictor.origin - self.origin;
 460                 if (d)
 461                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 462                 else
 463                         f = 0;  // Assum ecenter.
 464                 force = v_right * vlen(force);
 465                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 466                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 467                 if(f > 0)
 468                 {
 469                         hitloc = ear1;
 470                         force = force * -1;
 471                 }
 472                 else
 473                 {
 474                         hitloc = ear2;
 475                         // force is already good
 476                 }
 477         }
 478         else
 479                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 480
 481
 482         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 483         take = v_x;
 484         save = v_y;
 485
 486         if(attacker == self)
 487         {
 488                 // don't reset pushltime for self damage as it may be an attempt to
 489                 // escape a lava pit or similar
 490                 //self.pushltime = 0;
 491                 self.istypefrag = 0;
 492         }
 493         else if(IS_PLAYER(attacker))
 494         {
 495                 self.pusher = attacker;
 496                 self.pushltime = time + autocvar_g_maxpushtime;
 497                 self.istypefrag = self.BUTTON_CHAT;
 498         }
 499         else if(time < self.pushltime)
 500         {
 501                 attacker = self.pusher;
 502                 self.pushltime = max(self.pushltime, time + 0.6);
 503         }
 504         else
 505         {
 506                 self.pushltime = 0;
 507                 self.istypefrag = 0;
 508         }
 509
 510         frag_inflictor = inflictor;
 511         frag_attacker = attacker;
 512         frag_target = self;
 513         frag_damage = damage;
 514         damage_take = take;
 515         damage_save = save;
 516         damage_force = force;
 517         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 518         take = bound(0, damage_take, self.health);
 519         save = bound(0, damage_save, self.armorvalue);
 520         excess = max(0, damage - take - save);
 521
 522         if(sound_allowed(MSG_BROADCAST, attacker))
 523         {
 524                 if (save > 10)
 525                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 526                 else if (take > 30)
 527                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 528                 else if (take > 10)
 529                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 530         }
 531
 532         if (take > 50)
 533                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 534         if (take > 100)
 535                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 536
 537         if (time >= self.spawnshieldtime)
 538         {
 539                 if (!(self.flags & FL_GODMODE))
 540                 {
 541                         self.armorvalue = self.armorvalue - save;
 542                         self.health = self.health - take;
 543                         // pause regeneration for 5 seconds
 544                         if(take)
 545                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 546
 547                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 548                         {
 549                                 self.pain_finished = time + 0.5;        //Supajoe
 550
 551                                 if(autocvar_sv_gentle < 1) {
 552                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 553                                         {
 554                                                 if (!self.animstate_override)
 555                                                 {
 556                                                         if (random() > 0.5)
 557                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 558                                                         else
 559                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 560                                                 }
 561                                         }
 562
 563                                         if(sound_allowed(MSG_BROADCAST, attacker))
 564                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 565                                         if(self.health > 1)
 566                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 567                                         {
 568                                                 if(deathtype == DEATH_FALL)
 569                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 570                                                 else if(self.health > 75) // TODO make a "gentle" version?
 571                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 572                                                 else if(self.health > 50)
 573                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 574                                                 else if(self.health > 25)
 575                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 576                                                 else
 577                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 578                                         }
 579                                 }
 580
 581                                 // throw off bot aim temporarily
 582                                 float shake;
 583                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 584                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 585                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 586                         }
 587                 }
 588                 else
 589                         self.max_armorvalue += (save + take);
 590         }
 591         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 592         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 593         self.dmg_inflictor = inflictor;
 594
 595         float abot, vbot, awep;
 596         abot = (IS_BOT_CLIENT(attacker));
 597         vbot = (IS_BOT_CLIENT(self));
 598
 599         valid_damage_for_weaponstats = 0;
 600         awep = 0;
 601
 602         if(vbot || IS_REAL_CLIENT(self))
 603         if(abot || IS_REAL_CLIENT(attacker))
 604         if(attacker && self != attacker)
 605         if(DIFF_TEAM(self, attacker))
 606         {
 607                 if(DEATH_ISSPECIAL(deathtype))
 608                         awep = attacker.weapon;
 609                 else
 610                         awep = DEATH_WEAPONOF(deathtype);
 611                 valid_damage_for_weaponstats = 1;
 612         }
 613
 614         if(valid_damage_for_weaponstats)
 615         {
 616                 dh = dh - max(self.health, 0);
 617                 da = da - max(self.armorvalue, 0);
 618                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 619         }
 620
 621         if (self.health < 1)
 622         {
 623                 float defer_ClientKill_Now_TeamChange;
 624                 defer_ClientKill_Now_TeamChange = FALSE;
 625
 626                 if(self.alivetime)
 627                 {
 628                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 629                         self.alivetime = 0;
 630                 }
 631
 632                 if(valid_damage_for_weaponstats)
 633                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 634
 635                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 636                 if(sound_allowed(MSG_BROADCAST, attacker))
 637                 {
 638                         if(deathtype == DEATH_DROWN)
 639                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 640                         else
 641                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 642                 }
 643
 644                 // get rid of kill indicator
 645                 if(self.killindicator)
 646                 {
 647                         remove(self.killindicator);
 648                         self.killindicator = world;
 649                         if(self.killindicator_teamchange)
 650                                 defer_ClientKill_Now_TeamChange = TRUE;
 651
 652                         if(self.classname == "body")
 653                         if(deathtype == DEATH_KILL)
 654                         {
 655                                 // for the lemmings fans, a small harmless explosion
 656                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 657                         }
 658                 }
 659
 660                 // print an obituary message
 661                 Obituary (attacker, inflictor, self, deathtype);
 662
 663         // increment frag counter for used weapon type
 664         float w;
 665         w = DEATH_WEAPONOF(deathtype);
 666         if(WEP_VALID(w))
 667         if(accuracy_isgooddamage(attacker, self))
 668         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 669
 670                 frag_attacker = attacker;
 671                 frag_inflictor = inflictor;
 672                 frag_target = self;
 673                 frag_deathtype = deathtype;
 674                 MUTATOR_CALLHOOK(PlayerDies);
 675
 676                 weapon_action(self.weapon, WR_PLAYERDEATH);
 677
 678                 RemoveGrapplingHook(self);
 679
 680                 Portal_ClearAllLater(self);
 681
 682                 self.fixangle = TRUE;
 683
 684                 if(defer_ClientKill_Now_TeamChange)
 685                         ClientKill_Now_TeamChange(); // can turn player into spectator
 686
 687                 // player could have been miraculously resuscitated ;)
 688                 // e.g. players in freezetag get frozen, they don't really die
 689                 if(self.health >= 1 || !IS_PLAYER(self))
 690                         return;
 691
 692                 // when we get here, player actually dies
 693
 694                 Unfreeze(self); // remove any icy remains
 695                 self.health = 0; // Unfreeze resets health, so we need to set it back
 696
 697                 // clear waypoints
 698                 WaypointSprite_PlayerDead();
 699                 // throw a weapon
 700                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 701
 702                 // become fully visible
 703                 self.alpha = default_player_alpha;
 704                 // make the corpse upright (not tilted)
 705                 self.angles_x = 0;
 706                 self.angles_z = 0;
 707                 // don't spin
 708                 self.avelocity = '0 0 0';
 709                 // view from the floor
 710                 self.view_ofs = '0 0 -8';
 711                 // toss the corpse
 712                 self.movetype = MOVETYPE_TOSS;
 713                 // shootable corpse
 714                 self.solid = SOLID_CORPSE;
 715                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 716                 // don't stick to the floor
 717                 self.flags &= ~FL_ONGROUND;
 718                 // dying animation
 719                 self.deadflag = DEAD_DYING;
 720                 // when to allow respawn
 721                 calculate_player_respawn_time();
 722
 723                 self.death_time = time;
 724                 if (random() < 0.5)
 725                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 726                 else
 727                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 728                 if (self.maxs_z > 5)
 729                 {
 730                         self.maxs_z = 5;
 731                         setsize(self, self.mins, self.maxs);
 732                 }
 733                 // set damage function to corpse damage
 734                 self.event_damage = PlayerCorpseDamage;
 735                 // call the corpse damage function just in case it wants to gib
 736                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 737                 // set up to fade out later
 738                 SUB_SetFade (self, time + 6 + random (), 1);
 739
 740                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 741                         // remove corpse
 742                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 743                 }
 744
 745                 // reset fields the weapons may use just in case
 746                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 747                 {
 748                         weapon_action(j, WR_RESETPLAYER);
 749                         ATTACK_FINISHED_FOR(self, j) = 0;
 750                 }
 751         }
 752 }
 753
 754 .float muted; // to be used by prvm_edictset server playernumber muted 1
 755 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 756 // message "": do not say, just test flood control
 757 // return value:
 758 //   1 = accept
 759 //   0 = reject
 760 //  -1 = fake accept
 761 {
 762         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 763         float flood;
 764         var .float flood_field;
 765         entity head;
 766         float ret;
 767         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 768
 769         if(!teamsay && !privatesay)
 770                 if(substring(msgin, 0, 1) == " ")
 771                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 772
 773         msgin = formatmessage(msgin);
 774
 775         if (!IS_PLAYER(source))
 776                 colorstr = "^0"; // black for spectators
 777         else if(teamplay)
 778                 colorstr = Team_ColorCode(source.team);
 779         else
 780         {
 781                 colorstr = "";
 782                 teamsay = FALSE;
 783         }
 784
 785         if(intermission_running)
 786                 teamsay = FALSE;
 787
 788         if(msgin != "")
 789                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 790
 791         /*
 792          * using bprint solves this... me stupid
 793         // how can we prevent the message from appearing in a listen server?
 794         // for now, just give "say" back and only handle say_team
 795         if(!teamsay)
 796         {
 797                 clientcommand(self, strcat("say ", msgin));
 798                 return;
 799         }
 800         */
 801
 802         if(autocvar_g_chat_teamcolors)
 803                 namestr = playername(source);
 804         else
 805                 namestr = source.netname;
 806
 807         if(strdecolorize(namestr) == namestr)
 808                 colorprefix = "^3";
 809         else
 810                 colorprefix = "^7";
 811
 812         if(msgin != "")
 813         {
 814                 if(privatesay)
 815                 {
 816                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 817                         privatemsgprefixlen = strlen(msgstr);
 818                         msgstr = strcat(msgstr, msgin);
 819                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 820                         if(autocvar_g_chat_teamcolors)
 821                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 822                         else
 823                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 824                 }
 825                 else if(teamsay)
 826                 {
 827                         msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 828                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 829                 }
 830                 else
 831                 {
 832                         msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 833                         cmsgstr = "";
 834                 }
 835                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 836         }
 837         else
 838         {
 839                 msgstr = cmsgstr = "";
 840         }
 841
 842         fullmsgstr = msgstr;
 843         fullcmsgstr = cmsgstr;
 844
 845         // FLOOD CONTROL
 846         flood = 0;
 847         flood_field = floodcontrol_chat;
 848         if(floodcontrol)
 849         {
 850                 float flood_spl;
 851                 float flood_burst;
 852                 float flood_lmax;
 853                 float lines;
 854                 if(privatesay)
 855                 {
 856                         flood_spl = autocvar_g_chat_flood_spl_tell;
 857                         flood_burst = autocvar_g_chat_flood_burst_tell;
 858                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 859                         flood_field = floodcontrol_chattell;
 860                 }
 861                 else if(teamsay)
 862                 {
 863                         flood_spl = autocvar_g_chat_flood_spl_team;
 864                         flood_burst = autocvar_g_chat_flood_burst_team;
 865                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 866                         flood_field = floodcontrol_chatteam;
 867                 }
 868                 else
 869                 {
 870                         flood_spl = autocvar_g_chat_flood_spl;
 871                         flood_burst = autocvar_g_chat_flood_burst;
 872                         flood_lmax = autocvar_g_chat_flood_lmax;
 873                         flood_field = floodcontrol_chat;
 874                 }
 875                 flood_burst = max(0, flood_burst - 1);
 876                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 877
 878                 // do flood control for the default line size
 879                 if(msgstr != "")
 880                 {
 881                         getWrappedLine_remaining = msgstr;
 882                         msgstr = "";
 883                         lines = 0;
 884                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 885                         {
 886                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 887                                 ++lines;
 888                         }
 889                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 890
 891                         if(getWrappedLine_remaining != "")
 892                         {
 893                                 msgstr = strcat(msgstr, "\n");
 894                                 flood = 2;
 895                         }
 896
 897                         if(time >= source.flood_field)
 898                         {
 899                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 900                         }
 901                         else
 902                         {
 903                                 flood = 1;
 904                                 msgstr = fullmsgstr;
 905                         }
 906                 }
 907                 else
 908                 {
 909                         if(time >= source.flood_field)
 910                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 911                         else
 912                                 flood = 1;
 913                 }
 914
 915                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 916                         source.flood_field = flood = 0;
 917         }
 918
 919         if(flood == 2) // cannot happen for empty msgstr
 920         {
 921                 if(autocvar_g_chat_flood_notify_flooder)
 922                 {
 923                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 924                         sourcecmsgstr = "";
 925                 }
 926                 else
 927                 {
 928                         sourcemsgstr = fullmsgstr;
 929                         sourcecmsgstr = fullcmsgstr;
 930                 }
 931                 cmsgstr = "";
 932         }
 933         else
 934         {
 935                 sourcemsgstr = msgstr;
 936                 sourcecmsgstr = cmsgstr;
 937         }
 938
 939         if(!privatesay)
 940         if (!IS_PLAYER(source))
 941         {
 942                 if (!intermission_running)
 943                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 944                                 teamsay = -1; // spectators
 945         }
 946
 947         if(flood)
 948                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 949
 950         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 951         if(privatesay)
 952                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 953
 954         if(source.muted)
 955         {
 956                 // always fake the message
 957                 ret = -1;
 958         }
 959         else if(flood == 1)
 960         {
 961                 if(autocvar_g_chat_flood_notify_flooder)
 962                 {
 963                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 964                         ret = 0;
 965                 }
 966                 else
 967                         ret = -1;
 968         }
 969         else
 970         {
 971                 ret = 1;
 972         }
 973
 974         if(sourcemsgstr != "" && ret != 0)
 975         {
 976                 if(ret < 0) // faked message, because the player is muted
 977                 {
 978                         sprint(source, sourcemsgstr);
 979                         if(sourcecmsgstr != "" && !privatesay)
 980                                 centerprint(source, sourcecmsgstr);
 981                 }
 982                 else if(privatesay) // private message, between 2 people only
 983                 {
 984                         sprint(source, sourcemsgstr);
 985                         sprint(privatesay, msgstr);
 986                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 987                         if(cmsgstr != "")
 988                                 centerprint(privatesay, cmsgstr);
 989                 }
 990                 else if(teamsay > 0) // team message, only sent to team mates
 991                 {
 992                         sprint(source, sourcemsgstr);
 993                         dedicated_print(msgstr); // send to server console too
 994                         if(sourcecmsgstr != "")
 995                                 centerprint(source, sourcecmsgstr);
 996                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 997                                 if(head != source)
 998                                 {
 999                                         sprint(head, msgstr);
1000                                         if(cmsgstr != "")
1001                                                 centerprint(head, cmsgstr);
1002                                 }
1003                 }
1004                 else if(teamsay < 0) // spectator message, only sent to spectators
1005                 {
1006                         sprint(source, sourcemsgstr);
1007                         dedicated_print(msgstr); // send to server console too
1008                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
1009                                 if(head != source)
1010                                         sprint(head, msgstr);
1011                 }
1012                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1013                 {
1014                         sprint(source, sourcemsgstr);
1015                         dedicated_print(msgstr); // send to server console too
1016                         FOR_EACH_REALCLIENT(head)
1017                                 if(head != source)
1018                                         sprint(head, msgstr);
1019                 }
1020                 else
1021                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1022         }
1023
1024         return ret;
1025 }
1026
1027 float GetVoiceMessageVoiceType(string type)
1028 {
1029         if(type == "taunt")
1030                 return VOICETYPE_TAUNT;
1031         if(type == "teamshoot")
1032                 return VOICETYPE_LASTATTACKER;
1033         return VOICETYPE_TEAMRADIO;
1034 }
1035
1036 string allvoicesamples;
1037 .string GetVoiceMessageSampleField(string type)
1038 {
1039         GetPlayerSoundSampleField_notFound = 0;
1040         switch(type)
1041         {
1042 #define _VOICEMSG(m) case #m: return playersound_##m;
1043                 ALLVOICEMSGS
1044 #undef _VOICEMSG
1045         }
1046         GetPlayerSoundSampleField_notFound = 1;
1047         return playersound_taunt;
1048 }
1049
1050 .string GetPlayerSoundSampleField(string type)
1051 {
1052         GetPlayerSoundSampleField_notFound = 0;
1053         switch(type)
1054         {
1055 #define _VOICEMSG(m) case #m: return playersound_##m;
1056                 ALLPLAYERSOUNDS
1057 #undef _VOICEMSG
1058         }
1059         GetPlayerSoundSampleField_notFound = 1;
1060         return playersound_taunt;
1061 }
1062
1063 void PrecacheGlobalSound(string samplestring)
1064 {
1065         float n, i;
1066         tokenize_console(samplestring);
1067         n = stof(argv(1));
1068         if(n > 0)
1069         {
1070                 for(i = 1; i <= n; ++i)
1071                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1072         }
1073         else
1074         {
1075                 precache_sound(strcat(argv(0), ".wav"));
1076         }
1077 }
1078
1079 void PrecachePlayerSounds(string f)
1080 {
1081         float fh;
1082         string s;
1083         fh = fopen(f, FILE_READ);
1084         if(fh < 0)
1085                 return;
1086         while((s = fgets(fh)))
1087         {
1088                 if(tokenize_console(s) != 3)
1089                 {
1090                         dprint("Invalid sound info line: ", s, "\n");
1091                         continue;
1092                 }
1093                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1094         }
1095         fclose(fh);
1096
1097         if (!allvoicesamples)
1098         {
1099 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1100                 ALLVOICEMSGS
1101 #undef _VOICEMSG
1102                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1103         }
1104 }
1105
1106 void ClearPlayerSounds()
1107 {
1108 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1109         ALLPLAYERSOUNDS
1110         ALLVOICEMSGS
1111 #undef _VOICEMSG
1112 }
1113
1114 float LoadPlayerSounds(string f, float first)
1115 {
1116         float fh;
1117         string s;
1118         var .string field;
1119         fh = fopen(f, FILE_READ);
1120         if(fh < 0)
1121         {
1122                 dprint("Player sound file not found: ", f, "\n");
1123                 return 0;
1124         }
1125         while((s = fgets(fh)))
1126         {
1127                 if(tokenize_console(s) != 3)
1128                         continue;
1129                 field = GetPlayerSoundSampleField(argv(0));
1130                 if(GetPlayerSoundSampleField_notFound)
1131                         field = GetVoiceMessageSampleField(argv(0));
1132                 if(GetPlayerSoundSampleField_notFound)
1133                         continue;
1134                 if(self.field)
1135                         strunzone(self.field);
1136                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1137         }
1138         fclose(fh);
1139         return 1;
1140 }
1141
1142 .float modelindex_for_playersound;
1143 .float skin_for_playersound;
1144 void UpdatePlayerSounds()
1145 {
1146         if(self.modelindex == self.modelindex_for_playersound)
1147         if(self.skin == self.skin_for_playersound)
1148                 return;
1149         self.modelindex_for_playersound = self.modelindex;
1150         self.skin_for_playersound = self.skin;
1151         ClearPlayerSounds();
1152         LoadPlayerSounds("sound/player/default.sounds", 1);
1153         if(!autocvar_g_debug_defaultsounds)
1154                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1155                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1156 }
1157
1158 void FakeGlobalSound(string sample, float chan, float voicetype)
1159 {
1160         float n;
1161         float tauntrand;
1162
1163         if(sample == "")
1164                 return;
1165
1166         tokenize_console(sample);
1167         n = stof(argv(1));
1168         if(n > 0)
1169                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1170         else
1171                 sample = strcat(argv(0), ".wav"); // randomization
1172
1173         switch(voicetype)
1174         {
1175                 case VOICETYPE_LASTATTACKER_ONLY:
1176                         break;
1177                 case VOICETYPE_LASTATTACKER:
1178                         if(self.pusher)
1179                         {
1180                                 msg_entity = self;
1181                                 if(IS_REAL_CLIENT(msg_entity))
1182                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1183                         }
1184                         break;
1185                 case VOICETYPE_TEAMRADIO:
1186                         msg_entity = self;
1187                         if(msg_entity.cvar_cl_voice_directional == 1)
1188                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1189                         else
1190                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1191                         break;
1192                 case VOICETYPE_AUTOTAUNT:
1193                         if(!sv_autotaunt)
1194                                 break;
1195                         if(!sv_taunt)
1196                                 break;
1197                         if(autocvar_sv_gentle)
1198                                 break;
1199                         tauntrand = random();
1200                         msg_entity = self;
1201                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1202                         {
1203                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1204                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1205                                 else
1206                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1207                         }
1208                         break;
1209                 case VOICETYPE_TAUNT:
1210                         if(IS_PLAYER(self))
1211                                 if(self.deadflag == DEAD_NO)
1212                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1213                         if(!sv_taunt)
1214                                 break;
1215                         if(autocvar_sv_gentle)
1216                                 break;
1217                         msg_entity = self;
1218                         if (msg_entity.cvar_cl_voice_directional >= 1)
1219                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1220                         else
1221                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1222                         break;
1223                 case VOICETYPE_PLAYERSOUND:
1224                         msg_entity = self;
1225                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1226                         break;
1227                 default:
1228                         backtrace("Invalid voice type!");
1229                         break;
1230         }
1231 }
1232
1233 void GlobalSound(string sample, float chan, float voicetype)
1234 {
1235         float n;
1236         float tauntrand;
1237
1238         if(sample == "")
1239                 return;
1240
1241         tokenize_console(sample);
1242         n = stof(argv(1));
1243         if(n > 0)
1244                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1245         else
1246                 sample = strcat(argv(0), ".wav"); // randomization
1247
1248         switch(voicetype)
1249         {
1250                 case VOICETYPE_LASTATTACKER_ONLY:
1251                         if(self.pusher)
1252                         {
1253                                 msg_entity = self.pusher;
1254                                 if(IS_REAL_CLIENT(msg_entity))
1255                                 {
1256                                         if(msg_entity.cvar_cl_voice_directional == 1)
1257                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1258                                         else
1259                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1260                                 }
1261                         }
1262                         break;
1263                 case VOICETYPE_LASTATTACKER:
1264                         if(self.pusher)
1265                         {
1266                                 msg_entity = self.pusher;
1267                                 if(IS_REAL_CLIENT(msg_entity))
1268                                 {
1269                                         if(msg_entity.cvar_cl_voice_directional == 1)
1270                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1271                                         else
1272                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1273                                 }
1274                                 msg_entity = self;
1275                                 if(IS_REAL_CLIENT(msg_entity))
1276                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1277                         }
1278                         break;
1279                 case VOICETYPE_TEAMRADIO:
1280                         FOR_EACH_REALCLIENT(msg_entity)
1281                                 if(!teamplay || msg_entity.team == self.team)
1282                                 {
1283                                         if(msg_entity.cvar_cl_voice_directional == 1)
1284                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1285                                         else
1286                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1287                                 }
1288                         break;
1289                 case VOICETYPE_AUTOTAUNT:
1290                         if(!sv_autotaunt)
1291                                 break;
1292                         if(!sv_taunt)
1293                                 break;
1294                         if(autocvar_sv_gentle)
1295                                 break;
1296                         tauntrand = random();
1297                         FOR_EACH_REALCLIENT(msg_entity)
1298                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1299                                 {
1300                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1301                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1302                                         else
1303                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1304                                 }
1305                         break;
1306                 case VOICETYPE_TAUNT:
1307                         if(IS_PLAYER(self))
1308                                 if(self.deadflag == DEAD_NO)
1309                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1310                         if(!sv_taunt)
1311                                 break;
1312                         if(autocvar_sv_gentle)
1313                                 break;
1314                         FOR_EACH_REALCLIENT(msg_entity)
1315                         {
1316                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1317                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1318                                 else
1319                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1320                         }
1321                         break;
1322                 case VOICETYPE_PLAYERSOUND:
1323                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1324                         break;
1325                 default:
1326                         backtrace("Invalid voice type!");
1327                         break;
1328         }
1329 }
1330
1331 void PlayerSound(.string samplefield, float chan, float voicetype)
1332 {
1333         GlobalSound(self.samplefield, chan, voicetype);
1334 }
1335
1336 void VoiceMessage(string type, string msg)
1337 {
1338         var .string sample;
1339         float voicetype, ownteam;
1340         float flood;
1341         sample = GetVoiceMessageSampleField(type);
1342
1343         if(GetPlayerSoundSampleField_notFound)
1344         {
1345                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1346                 return;
1347         }
1348
1349         voicetype = GetVoiceMessageVoiceType(type);
1350         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1351
1352         flood = Say(self, ownteam, world, msg, 1);
1353
1354         if (flood > 0)
1355                 GlobalSound(self.sample, CH_VOICE, voicetype);
1356         else if (flood < 0)
1357                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1358 }
1359
1360 void MoveToTeam(entity client, float team_colour, float type)
1361 {
1362         float lockteams_backup;
1363
1364         lockteams_backup = lockteams;  // backup any team lock
1365
1366         lockteams = 0;  // disable locked teams
1367
1368         TeamchangeFrags(client);  // move the players frags
1369         SetPlayerColors(client, team_colour - 1);  // set the players colour
1370         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1371
1372         lockteams = lockteams_backup;  // restore the team lock
1373
1374         LogTeamchange(client.playerid, client.team, type);
1375 }