Code cleanups + keepaway powerups, this one might be questionable and might require...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_player.qc
1 float weaponstats_buffer;
2
3 void WeaponStats_Init()
4 {
5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
6                 weaponstats_buffer = buf_create();
7         else
8                 weaponstats_buffer = -1;
9 }
10
11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
12
13 void WeaponStats_Shutdown()
14 {
15         float i, j, idx, f;
16         float fh;
17         string prefix;
18         if(weaponstats_buffer < 0)
19                 return;
20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
21         if(cvar_string("sv_weaponstats_killfile") != "")
22         {
23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
24                 if(fh >= 0)
25                 {
26                         fputs(fh, "#begin killfile\n");
27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
31                                 {
32                                         idx = WEAPONSTATS_GETINDEX(i, j);
33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
34                                         if(f != 0)
35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
36                                 }
37                         fputs(fh, "#end\n\n");
38                         fclose(fh);
39                         print("Weapon kill stats written\n");
40                 }
41         }
42         if(cvar_string("sv_weaponstats_damagefile") != "")
43         {
44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
45                 if(fh >= 0)
46                 {
47                         fputs(fh, "#begin damagefile\n");
48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
52                                 {
53                                         idx = WEAPONSTATS_GETINDEX(i, j);
54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
55                                         if(f != 0)
56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
57                                 }
58                         fputs(fh, "#end\n\n");
59                         fclose(fh);
60                         print("Weapon damage stats written\n");
61                 }
62         }
63         buf_del(weaponstats_buffer);
64         weaponstats_buffer = -1;
65 }
66
67 void WeaponStats_LogItem(float awep, float vwep, vector item)
68 {
69         float idx;
70         if(weaponstats_buffer < 0)
71                 return;
72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
73                 return;
74         if(awep > WEP_LAST || vwep > WEP_LAST)
75                 return;
76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
78 }
79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
80 {
81         if(damage < 0)
82                 error("negative damage?");
83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
84 }
85 void WeaponStats_LogKill(float awep, float vwep)
86 {
87         WeaponStats_LogItem(awep, vwep, '0 1 0');
88 }
89
90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
91 // merged player_run and player_stand to player_anim
92 // added death animations to player_anim
93 // can now spawn thrown weapons from anywhere, not just from players
94 // thrown weapons now fade out after 20 seconds
95 // created PlayerGib function
96 // PlayerDie no longer uses hitloc or damage
97 // PlayerDie now supports dying animations as well as gibbing
98 // cleaned up PlayerDie a lot
99 // added CopyBody
100
101 .entity pusher;
102 .float pushltime;
103
104 void CopyBody(float keepvelocity)
105 {
106         local entity oldself;
107         if (self.effects & EF_NODRAW)
108                 return;
109         oldself = self;
110         self = spawn();
111         self.enemy = oldself;
112         self.lip = oldself.lip;
113         self.colormap = oldself.colormap;
114         self.glowmod = oldself.glowmod;
115         self.iscreature = oldself.iscreature;
116         self.angles = oldself.angles;
117         self.avelocity = oldself.avelocity;
118         self.classname = "body";
119         self.damageforcescale = oldself.damageforcescale;
120         self.effects = oldself.effects;
121         self.event_damage = oldself.event_damage;
122         self.animstate_startframe = oldself.animstate_startframe;
123         self.animstate_numframes = oldself.animstate_numframes;
124         self.animstate_framerate = oldself.animstate_framerate;
125         self.animstate_starttime = oldself.animstate_starttime;
126         self.animstate_endtime = oldself.animstate_endtime;
127         self.animstate_override = oldself.animstate_override;
128         self.animstate_looping = oldself.animstate_looping;
129         self.frame = oldself.frame;
130         self.dead_frame = oldself.dead_frame;
131         self.pain_finished = oldself.pain_finished;
132         self.health = oldself.health;
133         self.armorvalue = oldself.armorvalue;
134         self.armortype = oldself.armortype;
135         self.model = oldself.model;
136         self.modelindex = oldself.modelindex;
137         self.modelindex_lod0 = oldself.modelindex_lod0;
138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
139         self.modelindex_lod1 = oldself.modelindex_lod1;
140         self.modelindex_lod2 = oldself.modelindex_lod2;
141         self.skinindex = oldself.skinindex;
142         self.species = oldself.species;
143         self.movetype = oldself.movetype;
144         self.nextthink = oldself.nextthink;
145         self.solid = oldself.solid;
146         self.ballistics_density = oldself.ballistics_density;
147         self.takedamage = oldself.takedamage;
148         self.think = oldself.think;
149         self.customizeentityforclient = oldself.customizeentityforclient;
150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
152         if (keepvelocity == 1)
153                 self.velocity = oldself.velocity;
154         self.oldvelocity = self.velocity;
155         self.fade_time = oldself.fade_time;
156         self.fade_rate = oldself.fade_rate;
157         //self.weapon = oldself.weapon;
158         setorigin(self, oldself.origin);
159         setsize(self, oldself.mins, oldself.maxs);
160         self.prevorigin = oldself.origin;
161         self.reset = SUB_Remove;
162
163         Drag_MoveDrag(oldself, self);
164
165         self = oldself;
166 }
167
168 float player_getspecies()
169 {
170         float s;
171         get_model_parameters(self.playermodel, self.skinindex);
172         s = get_model_parameters_species;
173         get_model_parameters(string_null, 0);
174         if(s < 0)
175                 return SPECIES_HUMAN;
176         return s;
177 }
178
179 void player_setupanimsformodel()
180 {
181         local string animfilename;
182         local float animfile;
183         // defaults for legacy .zym models without animinfo files
184         self.anim_die1 = '0 1 0.5'; // 2 seconds
185         self.anim_die2 = '1 1 0.5'; // 2 seconds
186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
188         self.anim_duckwalk = '4 1 1';
189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
190         self.anim_duckidle = '6 1 1';
191         self.anim_idle = '7 1 1';
192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
197         self.anim_run = '13 1 1';
198         self.anim_runbackwards = '14 1 1';
199         self.anim_strafeleft = '15 1 1';
200         self.anim_straferight = '16 1 1';
201         self.anim_dead1 = '17 1 1';
202         self.anim_dead2 = '18 1 1';
203         self.anim_forwardright = '19 1 1';
204         self.anim_forwardleft = '20 1 1';
205         self.anim_backright = '21 1 1';
206         self.anim_backleft  = '22 1 1';
207         animparseerror = FALSE;
208         animfilename = strcat(self.model, ".animinfo");
209         animfile = fopen(animfilename, FILE_READ);
210         if (animfile >= 0)
211         {
212                 self.anim_die1         = animparseline(animfile);
213                 self.anim_die2         = animparseline(animfile);
214                 self.anim_draw         = animparseline(animfile);
215                 self.anim_duck         = animparseline(animfile);
216                 self.anim_duckwalk     = animparseline(animfile);
217                 self.anim_duckjump     = animparseline(animfile);
218                 self.anim_duckidle     = animparseline(animfile);
219                 self.anim_idle         = animparseline(animfile);
220                 self.anim_jump         = animparseline(animfile);
221                 self.anim_pain1        = animparseline(animfile);
222                 self.anim_pain2        = animparseline(animfile);
223                 self.anim_shoot        = animparseline(animfile);
224                 self.anim_taunt        = animparseline(animfile);
225                 self.anim_run          = animparseline(animfile);
226                 self.anim_runbackwards = animparseline(animfile);
227                 self.anim_strafeleft   = animparseline(animfile);
228                 self.anim_straferight  = animparseline(animfile);
229                 self.anim_forwardright = animparseline(animfile);
230                 self.anim_forwardleft  = animparseline(animfile);
231                 self.anim_backright    = animparseline(animfile);
232                 self.anim_backleft     = animparseline(animfile);
233                 fclose(animfile);
234
235                 // derived anims
236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
238
239                 if (animparseerror)
240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
241         }
242         else
243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
244         // reset animstate now
245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
246 };
247
248 void player_anim (void)
249 {
250         updateanim(self);
251         if (self.weaponentity)
252                 updateanim(self.weaponentity);
253
254         if (self.deadflag != DEAD_NO)
255         {
256                 if (time > self.animstate_endtime)
257                 {
258                         if (self.maxs_z > 5)
259                         {
260                                 self.maxs_z = 5;
261                                 setsize(self, self.mins, self.maxs);
262                         }
263                         self.frame = self.dead_frame;
264                 }
265                 return;
266         }
267
268         if (!self.animstate_override)
269         {
270                 if (!(self.flags & FL_ONGROUND))
271                 {
272                         if (self.crouch)
273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
274                         else
275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
276                         self.restart_jump = FALSE;
277                 }
278                 else if (self.crouch)
279                 {
280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
282                         else
283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
284                 }
285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
286                 {
287                         if (self.movement_x > 0 && self.movement_y == 0)
288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
289                         else if (self.movement_x < 0 && self.movement_y == 0)
290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
291                         else if (self.movement_x == 0 && self.movement_y > 0)
292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
293                         else if (self.movement_x == 0 && self.movement_y < 0)
294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
295                         else if (self.movement_x > 0 && self.movement_y > 0)
296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
297                         else if (self.movement_x > 0 && self.movement_y < 0)
298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
299                         else if (self.movement_x < 0 && self.movement_y > 0)
300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
301                         else if (self.movement_x < 0 && self.movement_y < 0)
302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
303                         else
304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
305                 }
306                 else
307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
308         }
309
310         if (self.weaponentity)
311         if (!self.weaponentity.animstate_override)
312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
313 }
314
315 void SpawnThrownWeapon (vector org, float w)
316 {
317         if(g_minstagib)
318         if(self.ammo_cells <= 0)
319                 return;
320
321         if(g_pinata)
322         {
323                 float j;
324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
325                 {
326                         if(self.weapons & W_WeaponBit(j))
327                                 if(W_IsWeaponThrowable(j))
328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
329                 }
330         }
331         else
332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
333 }
334
335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
336 {
337         local float take, save;
338         vector v;
339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
340
341         // damage resistance (ignore most of the damage from a bullet or similar)
342         damage = max(damage - 5, 1);
343
344         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
345         take = v_x;
346         save = v_y;
347
348         if(sound_allowed(MSG_BROADCAST, attacker))
349         {
350                 if (save > 10)
351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
352                 else if (take > 30)
353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
354                 else if (take > 10)
355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
356         }
357
358         if (take > 50)
359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
360         if (take > 100)
361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
362
363         if (!(self.flags & FL_GODMODE))
364         {
365                 self.armorvalue = self.armorvalue - save;
366                 self.health = self.health - take;
367                 // pause regeneration for 5 seconds
368                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
369         }
370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
372         self.dmg_inflictor = inflictor;
373
374         if (self.health <= -100 && self.modelindex != 0)
375         {
376                 // don't use any animations as a gib
377                 self.frame = 0;
378                 self.dead_frame = 0;
379                 // view just above the floor
380                 self.view_ofs = '0 0 4';
381
382                 Violence_GibSplash(self, 1, 1, attacker);
383                 self.modelindex = 0; // restore later
384                 self.solid = SOLID_NOT; // restore later
385         }
386 }
387
388 void ClientKill_Now_TeamChange();
389
390 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
391 {
392         local float take, save, waves, sdelay, dh, da, j;
393         vector v;
394         float valid_damage_for_weaponstats;
395
396         dh = max(self.health, 0);
397         da = max(self.armorvalue, 0);
398
399         if(!DEATH_ISSPECIAL(deathtype))
400         {
401                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
402                 if(self != attacker)
403                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
404         }
405
406         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
407         {
408                 // tuba causes blood to come out of the ears
409                 vector ear1, ear2;
410                 vector d;
411                 float f;
412                 ear1 = self.origin;
413                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
414                 ear2 = ear1;
415                 makevectors(self.angles);
416                 ear1 += v_right * -10;
417                 ear2 += v_right * +10;
418                 d = inflictor.origin - self.origin;
419                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
420                 force = v_right * vlen(force);
421                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
422                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
423                 if(f > 0)
424                 {
425                         hitloc = ear1;
426                         force = force * -1;
427                 }
428                 else
429                 {
430                         hitloc = ear2;
431                         // force is already good
432                 }
433         }
434         else
435                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
436
437         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
438                 return;
439
440         if (!g_minstagib)
441         {
442                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
443                 take = v_x;
444                 save = v_y;
445         }
446         else
447         {
448                 save = 0;
449                 take = damage;
450         }
451
452         frag_inflictor = inflictor;
453         frag_attacker = attacker;
454         frag_target = self;
455         damage_take = take;
456         damage_save = save;
457         damage_force = force;
458         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
459         take = bound(0, damage_take, self.health);
460         save = bound(0, damage_save, self.armorvalue);
461
462         if(sound_allowed(MSG_BROADCAST, attacker))
463         {
464                 if (save > 10)
465                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
466                 else if (take > 30)
467                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
468                 else if (take > 10)
469                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
470         }
471
472         if (take > 50)
473                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
474         if (take > 100)
475                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
476
477         if (time >= self.spawnshieldtime)
478         {
479                 if (!(self.flags & FL_GODMODE))
480                 {
481                         self.armorvalue = self.armorvalue - save;
482                         self.health = self.health - take;
483                         // pause regeneration for 5 seconds
484                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
485
486                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
487                         {
488                                 self.pain_finished = time + 0.5;        //Supajoe
489
490                                 if(sv_gentle < 1) {
491                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
492                                         {
493                                                 if (random() > 0.5)
494                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
495                                                 else
496                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
497                                         }
498
499                                         if(sound_allowed(MSG_BROADCAST, attacker))
500                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
501                                         if(self.health > 1)
502                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
503                                         {
504                                                 if(deathtype == DEATH_FALL)
505                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
506                                                 else if(self.health > 75) // TODO make a "gentle" version?
507                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
508                                                 else if(self.health > 50)
509                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
510                                                 else if(self.health > 25)
511                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
512                                                 else
513                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
514                                         }
515                                 }
516
517                                 // throw off bot aim temporarily
518                                 local float shake;
519                                 shake = damage * 5 / (bound(0,skill,100) + 1);
520                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
521                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
522                         }
523                 }
524                 else
525                         self.max_armorvalue += (save + take);
526         }
527         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
528         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
529         self.dmg_inflictor = inflictor;
530
531         if(attacker == self)
532         {
533                 // don't reset pushltime for self damage as it may be an attempt to
534                 // escape a lava pit or similar
535                 //self.pushltime = 0;
536         }
537         else if(attacker.classname == "player" || attacker.classname == "gib")
538         {
539                 self.pusher = attacker;
540                 self.pushltime = time + cvar("g_maxpushtime");
541         }
542         else if(time < self.pushltime)
543         {
544                 attacker = self.pusher;
545                 self.pushltime = max(self.pushltime, time + 0.6);
546         }
547         else
548                 self.pushltime = 0;
549
550         valid_damage_for_weaponstats = 0;
551         if(clienttype(self) == CLIENTTYPE_REAL)
552         if(clienttype(attacker) == CLIENTTYPE_REAL)
553         if(self != attacker)
554         if(!DEATH_ISSPECIAL(deathtype))
555         if(IsDifferentTeam(self, attacker))
556                 valid_damage_for_weaponstats = 1;
557         
558         if(valid_damage_for_weaponstats)
559         {
560                 dh = dh - max(self.health, 0);
561                 da = da - max(self.armorvalue, 0);
562                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
563         }
564
565         if (self.health < 1)
566         {
567                 float defer_ClientKill_Now_TeamChange;
568                 defer_ClientKill_Now_TeamChange = FALSE;
569
570                 if(valid_damage_for_weaponstats)
571                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
572
573                 if(sv_gentle < 1) // TODO make a "gentle" version?
574                 if(sound_allowed(MSG_BROADCAST, attacker))
575                 {
576                         if(deathtype == DEATH_DROWN)
577                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
578                         else
579                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
580                 }
581
582                 // get rid of kill indicator
583                 if(self.killindicator)
584                 {
585                         remove(self.killindicator);
586                         self.killindicator = world;
587                         if(self.killindicator_teamchange)
588                                 defer_ClientKill_Now_TeamChange = TRUE;
589
590                         if(self.classname == "body")
591                         if(deathtype == DEATH_KILL)
592                         {
593                                 // for the lemmings fans, a small harmless explosion
594                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
595                         }
596                 }
597
598                 // become fully visible
599                 self.alpha = 1;
600                 // clear selected player display
601                 ClearSelectedPlayer();
602                 // throw a weapon
603                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
604                 // print an obituary message
605                 Obituary (attacker, inflictor, self, deathtype);
606                 race_PreDie();
607                 DropAllRunes(self);
608
609                 frag_attacker = attacker;
610                 frag_inflictor = inflictor;
611                 frag_target = self;
612                 MUTATOR_CALLHOOK(PlayerDies);
613
614                 if(self.flagcarried)
615                 {
616                         if(attacker.classname != "player" && attacker.classname != "gib")
617                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
618                         else if(attacker.team == self.team)
619                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
620                         else
621                                 DropFlag(self.flagcarried, world, attacker);
622                 }
623                 if(self.ballcarried && g_nexball)
624                         DropBall(self.ballcarried, self.origin, self.velocity);
625                 Portal_ClearAllLater(self);
626                 // clear waypoints
627                 WaypointSprite_PlayerDead();
628                 // make the corpse upright (not tilted)
629                 self.angles_x = 0;
630                 self.angles_z = 0;
631                 // don't spin
632                 self.avelocity = '0 0 0';
633                 // view from the floor
634                 self.view_ofs = '0 0 -8';
635                 // toss the corpse
636                 self.movetype = MOVETYPE_TOSS;
637                 // shootable corpse
638                 self.solid = SOLID_CORPSE;
639                 self.ballistics_density = cvar("g_ballistics_density_corpse");
640                 // don't stick to the floor
641                 self.flags &~= FL_ONGROUND;
642                 // dying animation
643                 self.deadflag = DEAD_DYING;
644                 // when to allow respawn
645                 sdelay = 0;
646                 waves = 0;
647                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
648                 if(!sdelay)
649                         sdelay = cvar("g_respawn_delay");
650                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
651                 if(!waves)
652                         waves = cvar("g_respawn_waves");
653                 if(waves)
654                         self.death_time = ceil((time + sdelay) / waves) * waves;
655                 else
656                         self.death_time = time + sdelay;
657                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
658                         self.respawn_countdown = 10; // first number to count down from is 10
659                 else
660                         self.respawn_countdown = -1; // do not count down
661                 if (random() < 0.5)
662                 {
663                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
664                         self.dead_frame = self.anim_dead1_x;
665                 }
666                 else
667                 {
668                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
669                         self.dead_frame = self.anim_dead2_x;
670                 }
671                 // set damage function to corpse damage
672                 self.event_damage = PlayerCorpseDamage;
673                 // call the corpse damage function just in case it wants to gib
674                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
675                 // set up to fade out later
676                 SUB_SetFade (self, time + 6 + random (), 1);
677
678                 if(clienttype(self) == CLIENTTYPE_REAL)
679                 {
680                         self.fixangle = TRUE;
681                         //msg_entity = self;
682                         //WriteByte (MSG_ONE, SVC_SETANGLE);
683                         //WriteAngle (MSG_ONE, self.v_angle_x);
684                         //WriteAngle (MSG_ONE, self.v_angle_y);
685                         //WriteAngle (MSG_ONE, 80);
686                 }
687
688                 if(g_arena)
689                         Spawnqueue_Unmark(self);
690
691                 if(defer_ClientKill_Now_TeamChange)
692                         ClientKill_Now_TeamChange();
693
694                 if(sv_gentle > 0 || cvar("ekg")) {
695                         // remove corpse
696                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
697                 }
698
699                 // reset fields the weapons may use just in case
700         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
701                 {
702             weapon_action(j, WR_RESETPLAYER);
703                         ATTACK_FINISHED_FOR(self, j) = 0;
704                 }
705         }
706 }
707
708 float UpdateSelectedPlayer_countvalue(float v)
709 {
710         return max(0, (v - 1.0) / 0.5);
711 }
712
713 // returns: -2 if no hit, otherwise cos of the angle
714 // uses the global v_angle
715 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
716 {
717         vector so, d;
718         float c;
719
720         if(p == self)
721                 return -2;
722
723         if(p.deadflag)
724                 return -2;
725
726         so = self.origin + self.view_ofs;
727         d = p.origin - so;
728
729         // misaimed?
730         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
731                 return -2;
732
733         // now find the cos of the angle...
734         c = normalize(d) * v_forward;
735
736         if(c <= mincosangle)
737                 return -2;
738
739         // not visible in any way? forget it
740         if(!checkpvs(so, p))
741                 return -2;
742
743         traceline(so, p.origin, MOVE_NOMONSTERS, self);
744         if(trace_fraction < 1)
745                 return -2;
746
747         return c;
748 }
749
750 void ClearSelectedPlayer()
751 {
752         if(self.selected_player)
753         {
754                 centerprint_expire(self, CENTERPRIO_POINT);
755                 self.selected_player = world;
756                 self.selected_player_display_needs_update = FALSE;
757         }
758 }
759
760 void UpdateSelectedPlayer()
761 {
762         entity selected;
763         float selected_score;
764         selected = world;
765         selected_score = 0.95; // 18 degrees
766
767         if(!cvar("sv_allow_shownames"))
768                 return;
769
770         if(clienttype(self) != CLIENTTYPE_REAL)
771                 return;
772
773         if(self.cvar_cl_shownames == 0)
774                 return;
775
776         if(self.cvar_cl_shownames == 1 && !teams_matter)
777                 return;
778
779         makevectors(self.v_angle); // sets v_forward
780
781         // 1. cursor trace is always right
782         WarpZone_crosshair_trace(self);
783         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
784         {
785                 selected = trace_ent;
786         }
787         else
788         {
789                 // 2. if we don't have a cursor trace, find the player which is least
790                 //    mis-aimed at
791                 entity p;
792                 FOR_EACH_PLAYER(p)
793                 {
794                         float c;
795                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
796                         if(c >= -1)
797                         {
798                                 selected = p;
799                                 selected_score = c;
800                         }
801                 }
802         }
803
804         if(selected)
805         {
806                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
807         }
808         else
809         {
810                 if(time < self.selected_player_display_timeout)
811                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
812                                 selected = self.selected_player;
813         }
814
815         if(selected)
816         {
817                 if(selected == self.selected_player)
818                 {
819                         float save;
820                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
821                         self.selected_player_count = self.selected_player_count + frametime;
822                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
823                         {
824                                 string namestr, healthstr;
825                                 namestr = playername(selected);
826                                 if(teams_matter)
827                                 {
828                                         healthstr = ftos(floor(selected.health));
829                                         if(self.team == selected.team)
830                                         {
831                                                 namestr = strcat(namestr, " (", healthstr, "%)");
832                                                 self.selected_player_display_needs_update = TRUE;
833                                         }
834                                 }
835                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
836                         }
837                 }
838                 else
839                 {
840                         ClearSelectedPlayer();
841                         self.selected_player = selected;
842                         self.selected_player_time = time;
843                         self.selected_player_count = 0;
844                         self.selected_player_display_needs_update = FALSE;
845                 }
846         }
847         else
848         {
849                 ClearSelectedPlayer();
850         }
851
852         if(self.selected_player)
853                 self.last_selected_player = self.selected_player;
854 }
855
856 .float muted; // to be used by prvm_edictset server playernumber muted 1
857 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
858 // message "": do not say, just test flood control
859 // return value:
860 //   1 = accept
861 //   0 = reject
862 //  -1 = fake accept
863 {
864         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
865         float flood, privatemsgprefixlen;
866         var .float flood_field;
867         entity head;
868         float ret;
869
870         if(Ban_MaybeEnforceBan(source))
871                 return 0;
872
873         if(!teamsay && !privatesay)
874                 if(substring(msgin, 0, 1) == " ")
875                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
876
877         msgin = formatmessage(msgin);
878
879         if(source.classname != "player")
880                 colorstr = "^0"; // black for spectators
881         else if(teams_matter)
882                 colorstr = Team_ColorCode(source.team);
883         else
884                 teamsay = FALSE;
885
886         if(intermission_running)
887                 teamsay = FALSE;
888
889         if(msgin != "")
890                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
891
892         /*
893          * using bprint solves this... me stupid
894         // how can we prevent the message from appearing in a listen server?
895         // for now, just give "say" back and only handle say_team
896         if(!teamsay)
897         {
898                 clientcommand(self, strcat("say ", msgin));
899                 return;
900         }
901         */
902
903         if(cvar("g_chat_teamcolors"))
904                 namestr = playername(source);
905         else
906                 namestr = source.netname;
907
908         if(msgin != "")
909         {
910                 if(privatesay)
911                 {
912                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
913                         privatemsgprefixlen = strlen(msgstr);
914                         msgstr = strcat(msgstr, msgin);
915                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
916                         if(cvar("g_chat_teamcolors"))
917                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
918                         else
919                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
920                 }
921                 else if(teamsay)
922                 {
923                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
924                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
925                 }
926                 else
927                 {
928                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
929                         cmsgstr = "";
930                 }
931                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
932         }
933         else
934         {
935                 msgstr = cmsgstr = "";
936         }
937
938         fullmsgstr = msgstr;
939         fullcmsgstr = cmsgstr;
940
941         // FLOOD CONTROL
942         flood = 0;
943         if(floodcontrol)
944         {
945                 float flood_spl;
946                 float flood_burst;
947                 float flood_lmax;
948                 float lines;
949                 if(privatesay)
950                 {
951                         flood_spl = cvar("g_chat_flood_spl_tell");
952                         flood_burst = cvar("g_chat_flood_burst_tell");
953                         flood_lmax = cvar("g_chat_flood_lmax_tell");
954                         flood_field = floodcontrol_chattell;
955                 }
956                 else if(teamsay)
957                 {
958                         flood_spl = cvar("g_chat_flood_spl_team");
959                         flood_burst = cvar("g_chat_flood_burst_team");
960                         flood_lmax = cvar("g_chat_flood_lmax_team");
961                         flood_field = floodcontrol_chatteam;
962                 }
963                 else
964                 {
965                         flood_spl = cvar("g_chat_flood_spl");
966                         flood_burst = cvar("g_chat_flood_burst");
967                         flood_lmax = cvar("g_chat_flood_lmax");
968                         flood_field = floodcontrol_chat;
969                 }
970                 flood_burst = max(0, flood_burst - 1);
971                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
972
973                 // do flood control for the default line size
974                 if(msgstr != "")
975                 {
976                         getWrappedLine_remaining = msgstr;
977                         msgstr = "";
978                         lines = 0;
979                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
980                         {
981                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
982                                 ++lines;
983                         }
984                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
985
986                         if(getWrappedLine_remaining != "")
987                         {
988                                 msgstr = strcat(msgstr, "\n");
989                                 flood = 2;
990                         }
991
992                         if(time >= source.flood_field)
993                         {
994                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
995                         }
996                         else
997                         {
998                                 flood = 1;
999                                 msgstr = fullmsgstr;
1000                         }
1001                 }
1002                 else
1003                 {
1004                         if(time >= source.flood_field)
1005                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1006                         else
1007                                 flood = 1;
1008                 }
1009
1010                 if (timeoutStatus == 2) //when game is paused, no flood protection
1011                         source.flood_field = flood = 0;
1012         }
1013
1014         if(flood == 2) // cannot happen for empty msgstr
1015         {
1016                 if(cvar("g_chat_flood_notify_flooder"))
1017                 {
1018                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1019                         sourcecmsgstr = "";
1020                 }
1021                 else
1022                 {
1023                         sourcemsgstr = fullmsgstr;
1024                         sourcecmsgstr = fullcmsgstr;
1025                 }
1026                 cmsgstr = "";
1027         }
1028         else
1029         {
1030                 sourcemsgstr = msgstr;
1031                 sourcecmsgstr = cmsgstr;
1032         }
1033
1034         if(!privatesay)
1035         if(source.classname != "player")
1036         {
1037                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1038                         teamsay = -1; // spectators
1039         }
1040
1041         if(flood)
1042                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1043
1044         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1045         if(privatesay)
1046                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1047
1048         if(source.muted)
1049         {
1050                 // always fake the message
1051                 ret = -1;
1052         }
1053         else if(flood == 1)
1054         {
1055                 if(cvar("g_chat_flood_notify_flooder"))
1056                 {
1057                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1058                         ret = 0;
1059                 }
1060                 else
1061                         ret = -1;
1062         }
1063         else
1064         {
1065                 ret = 1;
1066         }
1067
1068         if(sourcemsgstr != "" && ret != 0)
1069         {
1070                 if(ret < 0) // fake
1071                 {
1072                         sprint(source, sourcemsgstr);
1073                         if(sourcecmsgstr != "" && !privatesay)
1074                                 centerprint(source, sourcecmsgstr);
1075                 }
1076                 else if(privatesay)
1077                 {
1078                         sprint(source, sourcemsgstr);
1079                         sprint(privatesay, msgstr);
1080                         if(cmsgstr != "")
1081                                 centerprint(privatesay, cmsgstr);
1082                 }
1083                 else if(teamsay > 0)
1084                 {
1085                         sprint(source, sourcemsgstr);
1086                         if(sourcecmsgstr != "")
1087                                 centerprint(source, sourcecmsgstr);
1088                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1089                                 if(head != source)
1090                                 {
1091                                         sprint(head, msgstr);
1092                                         if(cmsgstr != "")
1093                                                 centerprint(head, cmsgstr);
1094                                 }
1095                 }
1096                 else if(teamsay < 0)
1097                 {
1098                         sprint(source, sourcemsgstr);
1099                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1100                                 if(head != source)
1101                                         sprint(head, msgstr);
1102                 }
1103                 else if(sourcemsgstr != msgstr)
1104                 {
1105                         sprint(source, sourcemsgstr);
1106                         FOR_EACH_REALCLIENT(head)
1107                                 if(head != source)
1108                                         sprint(head, msgstr);
1109                 }
1110                 else
1111                         bprint(msgstr);
1112         }
1113
1114         return ret;
1115 }
1116
1117 float GetVoiceMessageVoiceType(string type)
1118 {
1119         if(type == "taunt")
1120                 return VOICETYPE_TAUNT;
1121         if(type == "teamshoot")
1122                 return VOICETYPE_LASTATTACKER;
1123         return VOICETYPE_TEAMRADIO;
1124 }
1125
1126 string allvoicesamples;
1127 float GetPlayerSoundSampleField_notFound;
1128 float GetPlayerSoundSampleField_fixed;
1129 .string GetVoiceMessageSampleField(string type)
1130 {
1131         GetPlayerSoundSampleField_notFound = 0;
1132         GetPlayerSoundSampleField_fixed = 0;
1133         switch(type)
1134         {
1135 #define _VOICEMSG(m) case #m: return playersound_##m;
1136                 ALLVOICEMSGS
1137 #undef _VOICEMSG
1138         }
1139         GetPlayerSoundSampleField_notFound = 1;
1140         return playersound_taunt;
1141 }
1142
1143 .string GetPlayerSoundSampleField(string type)
1144 {
1145         GetPlayerSoundSampleField_notFound = 0;
1146         GetPlayerSoundSampleField_fixed = 0;
1147         switch(type)
1148         {
1149 #define _VOICEMSG(m) case #m: return playersound_##m;
1150                 ALLPLAYERSOUNDS
1151 #undef _VOICEMSG
1152         }
1153         GetPlayerSoundSampleField_notFound = 1;
1154         return playersound_taunt;
1155 }
1156
1157 void PrecacheGlobalSound(string samplestring)
1158 {
1159         float n, i;
1160         tokenize_console(samplestring);
1161         n = stof(argv(1));
1162         if(n > 0)
1163         {
1164                 for(i = 1; i <= n; ++i)
1165                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1166         }
1167         else
1168         {
1169                 precache_sound(strcat(argv(0), ".wav"));
1170         }
1171 }
1172
1173 void PrecachePlayerSounds(string f)
1174 {
1175         float fh;
1176         string s;
1177         fh = fopen(f, FILE_READ);
1178         if(fh < 0)
1179                 return;
1180         while((s = fgets(fh)))
1181         {
1182                 if(tokenize_console(s) != 3)
1183                 {
1184                         dprint("Invalid sound info line: ", s, "\n");
1185                         continue;
1186                 }
1187                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1188         }
1189         fclose(fh);
1190
1191         if not(allvoicesamples)
1192         {
1193 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1194                 ALLVOICEMSGS
1195 #undef _VOICEMSG
1196                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1197         }
1198 }
1199
1200 void ClearPlayerSounds()
1201 {
1202 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1203         ALLPLAYERSOUNDS
1204         ALLVOICEMSGS
1205 #undef _VOICEMSG
1206 }
1207
1208 void LoadPlayerSounds(string f, float first)
1209 {
1210         float fh;
1211         string s;
1212         var .string field;
1213         fh = fopen(f, FILE_READ);
1214         if(fh < 0)
1215         {
1216                 dprint("Player sound file not found: ", f, "\n");
1217                 return;
1218         }
1219         while((s = fgets(fh)))
1220         {
1221                 if(tokenize_console(s) != 3)
1222                         continue;
1223                 field = GetPlayerSoundSampleField(argv(0));
1224                 if(GetPlayerSoundSampleField_notFound)
1225                         field = GetVoiceMessageSampleField(argv(0));
1226                 if(GetPlayerSoundSampleField_notFound)
1227                         continue;
1228                 if(GetPlayerSoundSampleField_fixed)
1229                         if not(first)
1230                                 continue;
1231                 if(self.field)
1232                         strunzone(self.field);
1233                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1234         }
1235         fclose(fh);
1236 }
1237
1238 .float modelindex_for_playersound;
1239 .float skinindex_for_playersound;
1240 void UpdatePlayerSounds()
1241 {
1242         if(self.modelindex == self.modelindex_for_playersound)
1243         if(self.skinindex == self.skinindex_for_playersound)
1244                 return;
1245         self.modelindex_for_playersound = self.modelindex;
1246         self.skinindex_for_playersound = self.skinindex;
1247         ClearPlayerSounds();
1248         LoadPlayerSounds("sound/player/default.sounds", 1);
1249         LoadPlayerSounds(get_model_datafilename(self.playermodel, self.skinindex, "sounds"), 0);
1250 }
1251
1252 void FakeGlobalSound(string sample, float chan, float voicetype)
1253 {
1254         float n;
1255         float tauntrand;
1256
1257         if(sample == "")
1258                 return;
1259
1260         tokenize_console(sample);
1261         n = stof(argv(1));
1262         if(n > 0)
1263                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1264         else
1265                 sample = strcat(argv(0), ".wav"); // randomization
1266
1267         switch(voicetype)
1268         {
1269                 case VOICETYPE_LASTATTACKER_ONLY:
1270                         break;
1271                 case VOICETYPE_LASTATTACKER:
1272                         if(self.pusher)
1273                         {
1274                                 msg_entity = self;
1275                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1276                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1277                         }
1278                         break;
1279                 case VOICETYPE_TEAMRADIO:
1280                         msg_entity = self;
1281                         if(msg_entity.cvar_cl_voice_directional == 1)
1282                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1283                         else
1284                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1285                         break;
1286                 case VOICETYPE_AUTOTAUNT:
1287                         if(!sv_autotaunt)
1288                                 break;
1289                         if(!sv_taunt)
1290                                 break;
1291                         if(sv_gentle)
1292                                 break;
1293                         tauntrand = random();
1294                         msg_entity = self;
1295                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1296                         {
1297                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1298                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1299                                 else
1300                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1301                         }
1302                         break;
1303                 case VOICETYPE_TAUNT:
1304                         if(self.classname == "player")
1305                                 if(self.deadflag == DEAD_NO)
1306                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1307                         if(!sv_taunt)
1308                                 break;
1309                         if(sv_gentle)
1310                                 break;
1311                         msg_entity = self;
1312                         if (msg_entity.cvar_cl_voice_directional >= 1)
1313                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1314                         else
1315                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1316                         break;
1317                 case VOICETYPE_PLAYERSOUND:
1318                         msg_entity = self;
1319                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1320                         break;
1321                 default:
1322                         backtrace("Invalid voice type!");
1323                         break;
1324         }
1325 }
1326
1327 void GlobalSound(string sample, float chan, float voicetype)
1328 {
1329         float n;
1330         float tauntrand;
1331
1332         if(sample == "")
1333                 return;
1334
1335         tokenize_console(sample);
1336         n = stof(argv(1));
1337         if(n > 0)
1338                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1339         else
1340                 sample = strcat(argv(0), ".wav"); // randomization
1341
1342         switch(voicetype)
1343         {
1344                 case VOICETYPE_LASTATTACKER_ONLY:
1345                         if(self.pusher)
1346                         {
1347                                 msg_entity = self.pusher;
1348                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1349                                 {
1350                                         if(msg_entity.cvar_cl_voice_directional == 1)
1351                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1352                                         else
1353                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1354                                 }
1355                         }
1356                         break;
1357                 case VOICETYPE_LASTATTACKER:
1358                         if(self.pusher)
1359                         {
1360                                 msg_entity = self.pusher;
1361                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1362                                 {
1363                                         if(msg_entity.cvar_cl_voice_directional == 1)
1364                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1365                                         else
1366                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1367                                 }
1368                                 msg_entity = self;
1369                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1370                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1371                         }
1372                         break;
1373                 case VOICETYPE_TEAMRADIO:
1374                         FOR_EACH_REALCLIENT(msg_entity)
1375                                 if(!teams_matter || msg_entity.team == self.team)
1376                                 {
1377                                         if(msg_entity.cvar_cl_voice_directional == 1)
1378                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1379                                         else
1380                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1381                                 }
1382                         break;
1383                 case VOICETYPE_AUTOTAUNT:
1384                         if(!sv_autotaunt)
1385                                 break;
1386                         if(!sv_taunt)
1387                                 break;
1388                         if(sv_gentle)
1389                                 break;
1390                         tauntrand = random();
1391                         FOR_EACH_REALCLIENT(msg_entity)
1392                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1393                                 {
1394                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1395                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1396                                         else
1397                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1398                                 }
1399                         break;
1400                 case VOICETYPE_TAUNT:
1401                         if(self.classname == "player")
1402                                 if(self.deadflag == DEAD_NO)
1403                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1404                         if(!sv_taunt)
1405                                 break;
1406                         if(sv_gentle)
1407                                 break;
1408                         FOR_EACH_REALCLIENT(msg_entity)
1409                         {
1410                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1411                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1412                                 else
1413                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1414                         }
1415                         break;
1416                 case VOICETYPE_PLAYERSOUND:
1417                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1418                         break;
1419                 default:
1420                         backtrace("Invalid voice type!");
1421                         break;
1422         }
1423 }
1424
1425 void PlayerSound(.string samplefield, float chan, float voicetype)
1426 {
1427         GlobalSound(self.samplefield, chan, voicetype);
1428 }
1429
1430 void VoiceMessage(string type, string msg)
1431 {
1432         var .string sample;
1433         float voicetype, ownteam;
1434         float flood;
1435         sample = GetVoiceMessageSampleField(type);
1436
1437         if(GetPlayerSoundSampleField_notFound)
1438         {
1439                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1440                 return;
1441         }
1442
1443         voicetype = GetVoiceMessageVoiceType(type);
1444         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1445
1446         flood = Say(self, ownteam, world, msg, 1);
1447
1448         if (flood > 0)
1449                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1450         else if (flood < 0)
1451                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1452 }
1453
1454 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1455 {
1456 //      show_message
1457 //      0 (00) automove centerprint, admin message
1458 //      1 (01) automove centerprint, no admin message
1459 //      2 (10) no centerprint, admin message
1460 //      3 (11) no centerprint, no admin message
1461
1462         float lockteams_backup;
1463
1464         lockteams_backup = lockteams;  // backup any team lock
1465
1466         lockteams = 0;  // disable locked teams
1467
1468         TeamchangeFrags(client);  // move the players frags
1469         SetPlayerColors(client, team_colour - 1);  // set the players colour
1470         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1471
1472         lockteams = lockteams_backup;  // restore the team lock
1473
1474         LogTeamchange(client.playerid, client.team, type);
1475
1476         if not(show_message & 1) // admin message
1477                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1478
1479         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1480 }