]> de.git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/server/cl_player.qc
Merge remote-tracking branch 'origin/Mario/mutator_minstagib'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_player.qc
1 .entity accuracy;
2 .float accuracy_frags[WEP_MAXCOUNT];
3
4 float weaponstats_buffer;
5
6 void WeaponStats_Init()
7 {
8         if(autocvar_sv_weaponstats_file != "")
9                 weaponstats_buffer = buf_create();
10         else
11                 weaponstats_buffer = -1;
12 }
13
14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
15
16 void WeaponStats_ready(entity fh, entity pass, float status)
17 {
18         float i, j, n, ibot, jbot, idx;
19         vector v;
20         string prefix, s;
21         switch(status)
22         {
23                 case URL_READY_CANWRITE:
24                         // we can write
25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
26                         url_fputs(fh, "#begin statsfile\n");
27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
28 #ifdef WATERMARK
29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
30 #endif
31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
33                         n = tokenizebyseparator(cvar_purechanges, "\n");
34                         for(i = 0; i < n; ++i)
35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
38                                 {
39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
41                                         if(v != '0 0 0')
42                                         {
43                                                 //vector is: kills hits damage
44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
46                                         }
47                                 }
48                         url_fputs(fh, "#end\n\n");
49                         url_fclose(fh);
50                         break;
51                 case URL_READY_CANREAD:
52                         // url_fclose is processing, we got a response for writing the data
53                         // this must come from HTTP
54                         print("Got response from weapon stats server:\n");
55                         while((s = url_fgets(fh)))
56                                 print("  ", s, "\n");
57                         print("End of response.\n");
58                         url_fclose(fh);
59                         break;
60                 case URL_READY_CLOSED:
61                         // url_fclose has finished
62                         print("Weapon stats written\n");
63                         buf_del(weaponstats_buffer);
64                         weaponstats_buffer = -1;
65                         break;
66                 case URL_READY_ERROR:
67                 default:
68                         print("Weapon stats writing failed: ", ftos(status), "\n");
69                         buf_del(weaponstats_buffer);
70                         weaponstats_buffer = -1;
71                         break;
72         }
73 }
74
75 void WeaponStats_Shutdown()
76 {
77         if(weaponstats_buffer < 0)
78                 return;
79         if(autocvar_sv_weaponstats_file != "")
80         {
81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
82         }
83         else
84         {
85                 buf_del(weaponstats_buffer);
86                 weaponstats_buffer = -1;
87         }
88 }
89
90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
91 {
92         float idx;
93         if(weaponstats_buffer < 0)
94                 return;
95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
96                 return;
97         if(awep > WEP_LAST || vwep > WEP_LAST)
98                 return;
99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
101 }
102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
103 {
104         if(damage < 0)
105                 error("negative damage?");
106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
107 }
108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
109 {
110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
111 }
112
113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
114 // merged player_run and player_stand to player_anim
115 // added death animations to player_anim
116 // can now spawn thrown weapons from anywhere, not just from players
117 // thrown weapons now fade out after 20 seconds
118 // created PlayerGib function
119 // PlayerDie no longer uses hitloc or damage
120 // PlayerDie now supports dying animations as well as gibbing
121 // cleaned up PlayerDie a lot
122 // added CopyBody
123
124 .entity pusher;
125 .float pushltime;
126 .float istypefrag;
127
128 .float CopyBody_nextthink;
129 .void(void) CopyBody_think;
130 void CopyBody_Think(void)
131 {
132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
133         {
134                 self.CopyBody_think();
135                 if(wasfreed(self))
136                         return;
137                 self.CopyBody_nextthink = self.nextthink;
138                 self.CopyBody_think = self.think;
139                 self.think = CopyBody_Think;
140         }
141         CSQCMODEL_AUTOUPDATE();
142         self.nextthink = time;
143 }
144 void CopyBody(float keepvelocity)
145 {
146         entity oldself;
147         if (self.effects & EF_NODRAW)
148                 return;
149         oldself = self;
150         self = spawn();
151         self.enemy = oldself;
152         self.lip = oldself.lip;
153         self.colormap = oldself.colormap;
154         self.iscreature = oldself.iscreature;
155         self.teleportable = oldself.teleportable;
156         self.damagedbycontents = oldself.damagedbycontents;
157         self.angles = oldself.angles;
158         self.avelocity = oldself.avelocity;
159         self.classname = "body";
160         self.damageforcescale = oldself.damageforcescale;
161         self.effects = oldself.effects;
162         self.glowmod = oldself.glowmod;
163         self.event_damage = oldself.event_damage;
164         self.anim_state = oldself.anim_state;
165         self.anim_time = oldself.anim_time;
166         self.anim_lower_action = oldself.anim_lower_action;
167         self.anim_lower_time = oldself.anim_lower_time;
168         self.anim_upper_action = oldself.anim_upper_action;
169         self.anim_upper_time = oldself.anim_upper_time;
170         self.anim_implicit_state = oldself.anim_implicit_state;
171         self.anim_implicit_time = oldself.anim_implicit_time;
172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
176         self.dphitcontentsmask = oldself.dphitcontentsmask;
177         self.death_time = oldself.death_time;
178         self.pain_finished = oldself.pain_finished;
179         self.health = oldself.health;
180         self.armorvalue = oldself.armorvalue;
181         self.armortype = oldself.armortype;
182         self.model = oldself.model;
183         self.modelindex = oldself.modelindex;
184         self.skin = oldself.skin;
185         self.species = oldself.species;
186         self.movetype = oldself.movetype;
187         self.solid = oldself.solid;
188         self.ballistics_density = oldself.ballistics_density;
189         self.takedamage = oldself.takedamage;
190         self.customizeentityforclient = oldself.customizeentityforclient;
191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
193         if (keepvelocity == 1)
194                 self.velocity = oldself.velocity;
195         self.oldvelocity = self.velocity;
196         self.alpha = oldself.alpha;
197         self.fade_time = oldself.fade_time;
198         self.fade_rate = oldself.fade_rate;
199         //self.weapon = oldself.weapon;
200         setorigin(self, oldself.origin);
201         setsize(self, oldself.mins, oldself.maxs);
202         self.prevorigin = oldself.origin;
203         self.reset = SUB_Remove;
204
205         Drag_MoveDrag(oldself, self);
206
207         if(self.colormap <= maxclients && self.colormap > 0)
208                 self.colormap = 1024 + oldself.clientcolors;
209
210         CSQCMODEL_AUTOINIT();
211         self.CopyBody_nextthink = oldself.nextthink;
212         self.CopyBody_think = oldself.think;
213         self.nextthink = time;
214         self.think = CopyBody_Think;
215         // "bake" the current animation frame for clones (they don't get clientside animation)
216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
217
218         self = oldself;
219 }
220
221 float player_getspecies()
222 {
223         float s;
224         get_model_parameters(self.model, self.skin);
225         s = get_model_parameters_species;
226         get_model_parameters(string_null, 0);
227         if(s < 0)
228                 return SPECIES_HUMAN;
229         return s;
230 }
231
232 void player_setupanimsformodel()
233 {
234         // load animation info
235         animdecide_init(self);
236         animdecide_setstate(self, 0, FALSE);
237 }
238
239 void player_anim (void)
240 {
241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
242         if(self.deadflag && !deadbits)
243                 if(random() < 0.5)
244                         deadbits = ANIMSTATE_DEAD1;
245                 else
246                         deadbits = ANIMSTATE_DEAD2;
247         float animbits = deadbits;
248         if(self.freezetag_frozen)
249                 animbits |= ANIMSTATE_FROZEN;
250         if(self.crouch)
251                 animbits |= ANIMSTATE_DUCK;
252         animdecide_setstate(self, animbits, FALSE);
253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
254
255         if (self.weaponentity)
256         {
257                 updateanim(self.weaponentity);
258                 if (!self.weaponentity.animstate_override)
259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
260         }
261 }
262
263 void SpawnThrownWeapon (vector org, float w)
264 {
265         if(g_pinata)
266         {
267                 float j;
268                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
269                 {
270                         if(WEPSET_CONTAINS_EW(self, j))
271                                 if(W_IsWeaponThrowable(j))
272                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
273                 }
274         }
275         else
276         {
277                 if(W_IsWeaponThrowable(self.weapon))
278                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
279         }
280 }
281
282 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
283 {
284         float take, save;
285         vector v;
286         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
287
288         // damage resistance (ignore most of the damage from a bullet or similar)
289         damage = max(damage - 5, 1);
290
291         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
292         take = v_x;
293         save = v_y;
294
295         if(sound_allowed(MSG_BROADCAST, attacker))
296         {
297                 if (save > 10)
298                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
299                 else if (take > 30)
300                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
301                 else if (take > 10)
302                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
303         }
304
305         if (take > 50)
306                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
307         if (take > 100)
308                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
309
310         if (!(self.flags & FL_GODMODE))
311         {
312                 self.armorvalue = self.armorvalue - save;
313                 self.health = self.health - take;
314                 // pause regeneration for 5 seconds
315                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
316         }
317         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
318         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
319         self.dmg_inflictor = inflictor;
320
321         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
322         {
323                 // don't use any animations as a gib
324                 self.frame = 0;
325                 // view just above the floor
326                 self.view_ofs = '0 0 4';
327
328                 Violence_GibSplash(self, 1, 1, attacker);
329                 self.alpha = -1;
330                 self.solid = SOLID_NOT; // restore later
331                 self.takedamage = DAMAGE_NO; // restore later
332                 self.damagedbycontents = FALSE;
333         }
334 }
335
336 void ClientKill_Now_TeamChange();
337
338 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
339 {
340         float take, save, waves, sdelay, dh, da, j;
341         vector v;
342         float valid_damage_for_weaponstats;
343         float excess;
344
345         dh = max(self.health, 0);
346         da = max(self.armorvalue, 0);
347
348         if(!DEATH_ISSPECIAL(deathtype))
349         {
350                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
351                 if(self != attacker)
352                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
353         }
354
355         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
356         {
357                 // tuba causes blood to come out of the ears
358                 vector ear1, ear2;
359                 vector d;
360                 float f;
361                 ear1 = self.origin;
362                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
363                 ear2 = ear1;
364                 makevectors(self.angles);
365                 ear1 += v_right * -10;
366                 ear2 += v_right * +10;
367                 d = inflictor.origin - self.origin;
368                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
369                 force = v_right * vlen(force);
370                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
371                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
372                 if(f > 0)
373                 {
374                         hitloc = ear1;
375                         force = force * -1;
376                 }
377                 else
378                 {
379                         hitloc = ear2;
380                         // force is already good
381                 }
382         }
383         else
384                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
385
386
387         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
388         take = v_x;
389         save = v_y;
390
391         if(attacker == self)
392         {
393                 // don't reset pushltime for self damage as it may be an attempt to
394                 // escape a lava pit or similar
395                 //self.pushltime = 0;
396                 self.istypefrag = 0;
397         }
398         else if(attacker.classname == "player")
399         {
400                 self.pusher = attacker;
401                 self.pushltime = time + autocvar_g_maxpushtime;
402                 self.istypefrag = self.BUTTON_CHAT;
403         }
404         else if(time < self.pushltime)
405         {
406                 attacker = self.pusher;
407                 self.pushltime = max(self.pushltime, time + 0.6);
408         }
409         else
410         {
411                 self.pushltime = 0;
412                 self.istypefrag = 0;
413         }
414
415         frag_inflictor = inflictor;
416         frag_attacker = attacker;
417         frag_target = self;
418         damage_take = take;
419         damage_save = save;
420         damage_force = force;
421         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
422         take = bound(0, damage_take, self.health);
423         save = bound(0, damage_save, self.armorvalue);
424         excess = max(0, damage - take - save);
425
426         if(sound_allowed(MSG_BROADCAST, attacker))
427         {
428                 if (save > 10)
429                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
430                 else if (take > 30)
431                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
432                 else if (take > 10)
433                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
434         }
435
436         if (take > 50)
437                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
438         if (take > 100)
439                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
440
441         if (time >= self.spawnshieldtime)
442         {
443                 if (!(self.flags & FL_GODMODE))
444                 {
445                         self.armorvalue = self.armorvalue - save;
446                         self.health = self.health - take;
447                         // pause regeneration for 5 seconds
448                         if(take)
449                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
450
451                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
452                         {
453                                 self.pain_finished = time + 0.5;        //Supajoe
454
455                                 if(autocvar_sv_gentle < 1) {
456                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
457                                         {
458                                                 if (!self.animstate_override)
459                                                 {
460                                                         if (random() > 0.5)
461                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
462                                                         else
463                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
464                                                 }
465                                         }
466
467                                         if(sound_allowed(MSG_BROADCAST, attacker))
468                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
469                                         if(self.health > 1)
470                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
471                                         {
472                                                 if(deathtype == DEATH_FALL)
473                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
474                                                 else if(self.health > 75) // TODO make a "gentle" version?
475                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
476                                                 else if(self.health > 50)
477                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
478                                                 else if(self.health > 25)
479                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
480                                                 else
481                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
482                                         }
483                                 }
484
485                                 // throw off bot aim temporarily
486                                 float shake;
487                                 shake = damage * 5 / (bound(0,skill,100) + 1);
488                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
489                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
490                         }
491                 }
492                 else
493                         self.max_armorvalue += (save + take);
494         }
495         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
496         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
497         self.dmg_inflictor = inflictor;
498
499         if(g_ca && self != attacker && attacker.classname == "player")
500                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
501
502         float abot, vbot, awep;
503         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
504         vbot = (clienttype(self) == CLIENTTYPE_BOT);
505
506         valid_damage_for_weaponstats = 0;
507         awep = 0;
508
509         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
510         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
511         if(attacker && self != attacker)
512         if(IsDifferentTeam(self, attacker))
513         {
514                 if(DEATH_ISSPECIAL(deathtype))
515                         awep = attacker.weapon;
516                 else
517                         awep = DEATH_WEAPONOF(deathtype);
518                 valid_damage_for_weaponstats = 1;
519         }
520
521         if(valid_damage_for_weaponstats)
522         {
523                 dh = dh - max(self.health, 0);
524                 da = da - max(self.armorvalue, 0);
525                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
526         }
527
528         if (self.health < 1)
529         {
530                 float defer_ClientKill_Now_TeamChange;
531                 defer_ClientKill_Now_TeamChange = FALSE;
532
533                 if(self.alivetime)
534                 {
535                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
536                         self.alivetime = 0;
537                 }
538
539                 if(valid_damage_for_weaponstats)
540                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
541
542                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
543                 if(sound_allowed(MSG_BROADCAST, attacker))
544                 {
545                         if(deathtype == DEATH_DROWN)
546                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
547                         else
548                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
549                 }
550
551                 // get rid of kill indicator
552                 if(self.killindicator)
553                 {
554                         remove(self.killindicator);
555                         self.killindicator = world;
556                         if(self.killindicator_teamchange)
557                                 defer_ClientKill_Now_TeamChange = TRUE;
558
559                         if(self.classname == "body")
560                         if(deathtype == DEATH_KILL)
561                         {
562                                 // for the lemmings fans, a small harmless explosion
563                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
564                         }
565                 }
566
567                 // print an obituary message
568                 Obituary (attacker, inflictor, self, deathtype);
569                 race_PreDie();
570
571         // increment frag counter for used weapon type
572         float w;
573         w = DEATH_WEAPONOF(deathtype);
574         if(WEP_VALID(w))
575         if(accuracy_isgooddamage(attacker, self))
576         attacker.accuracy.(accuracy_frags[w-1]) += 1;
577
578                 frag_attacker = attacker;
579                 frag_inflictor = inflictor;
580                 frag_target = self;
581                 frag_deathtype = deathtype;
582                 MUTATOR_CALLHOOK(PlayerDies);
583
584                 weapon_action(self.weapon, WR_PLAYERDEATH);
585
586                 RemoveGrapplingHook(self);
587
588                 Portal_ClearAllLater(self);
589
590                 if(clienttype(self) == CLIENTTYPE_REAL)
591                 {
592                         self.fixangle = TRUE;
593                         //msg_entity = self;
594                         //WriteByte (MSG_ONE, SVC_SETANGLE);
595                         //WriteAngle (MSG_ONE, self.v_angle_x);
596                         //WriteAngle (MSG_ONE, self.v_angle_y);
597                         //WriteAngle (MSG_ONE, 80);
598                 }
599
600                 if(defer_ClientKill_Now_TeamChange)
601                         ClientKill_Now_TeamChange(); // can turn player into spectator
602
603                 // player could have been miraculously resuscitated ;)
604                 // e.g. players in freezetag get frozen, they don't really die
605                 if(self.health >= 1 || self.classname != "player")
606                         return;
607
608                 // when we get here, player actually dies
609
610                 // clear waypoints
611                 WaypointSprite_PlayerDead();
612                 // throw a weapon
613                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
614
615                 // become fully visible
616                 self.alpha = default_player_alpha;
617                 // make the corpse upright (not tilted)
618                 self.angles_x = 0;
619                 self.angles_z = 0;
620                 // don't spin
621                 self.avelocity = '0 0 0';
622                 // view from the floor
623                 self.view_ofs = '0 0 -8';
624                 // toss the corpse
625                 self.movetype = MOVETYPE_TOSS;
626                 // shootable corpse
627                 self.solid = SOLID_CORPSE;
628                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
629                 // don't stick to the floor
630                 self.flags &~= FL_ONGROUND;
631                 // dying animation
632                 self.deadflag = DEAD_DYING;
633                 // when to allow respawn
634                 sdelay = 0;
635                 waves = 0;
636                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
637                 if(!sdelay)
638                 {
639                         if(g_cts)
640                                 sdelay = 0; // no respawn delay in CTS
641                         else
642                                 sdelay = autocvar_g_respawn_delay;
643                 }
644                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
645                 if(!waves)
646                         waves = autocvar_g_respawn_waves;
647                 if(waves)
648                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
649                 else
650                         self.respawn_time = time + sdelay;
651                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
652                         self.respawn_countdown = 10; // first number to count down from is 10
653                 else
654                         self.respawn_countdown = -1; // do not count down
655
656                 if(g_cts || autocvar_g_forced_respawn)
657                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
658
659                 self.death_time = time;
660                 if (random() < 0.5)
661                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
662                 else
663                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
664                 if (self.maxs_z > 5)
665                 {
666                         self.maxs_z = 5;
667                         setsize(self, self.mins, self.maxs);
668                 }
669                 // set damage function to corpse damage
670                 self.event_damage = PlayerCorpseDamage;
671                 // call the corpse damage function just in case it wants to gib
672                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
673                 // set up to fade out later
674                 SUB_SetFade (self, time + 6 + random (), 1);
675
676                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
677                         // remove corpse
678                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
679                 }
680
681                 // reset fields the weapons may use just in case
682                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
683                 {
684                         weapon_action(j, WR_RESETPLAYER);
685                         ATTACK_FINISHED_FOR(self, j) = 0;
686                 }
687         }
688 }
689
690 .float muted; // to be used by prvm_edictset server playernumber muted 1
691 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
692 // message "": do not say, just test flood control
693 // return value:
694 //   1 = accept
695 //   0 = reject
696 //  -1 = fake accept
697 {
698         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
699         float flood;
700         var .float flood_field;
701         entity head;
702         float ret;
703         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
704
705         if(!teamsay && !privatesay)
706                 if(substring(msgin, 0, 1) == " ")
707                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
708
709         msgin = formatmessage(msgin);
710
711         if(source.classname != "player")
712                 colorstr = "^0"; // black for spectators
713         else if(teamplay)
714                 colorstr = Team_ColorCode(source.team);
715         else
716         {
717                 colorstr = "";
718                 teamsay = FALSE;
719         }
720
721         if(intermission_running)
722                 teamsay = FALSE;
723
724         if(msgin != "")
725                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
726
727         /*
728          * using bprint solves this... me stupid
729         // how can we prevent the message from appearing in a listen server?
730         // for now, just give "say" back and only handle say_team
731         if(!teamsay)
732         {
733                 clientcommand(self, strcat("say ", msgin));
734                 return;
735         }
736         */
737
738         if(autocvar_g_chat_teamcolors)
739                 namestr = playername(source);
740         else
741                 namestr = source.netname;
742
743         if(msgin != "")
744         {
745                 if(privatesay)
746                 {
747                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
748                         privatemsgprefixlen = strlen(msgstr);
749                         msgstr = strcat(msgstr, msgin);
750                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
751                         if(autocvar_g_chat_teamcolors)
752                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
753                         else
754                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
755                 }
756                 else if(teamsay)
757                 {
758                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
759                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
760                 }
761                 else
762                 {
763                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
764                         cmsgstr = "";
765                 }
766                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
767         }
768         else
769         {
770                 msgstr = cmsgstr = "";
771         }
772
773         fullmsgstr = msgstr;
774         fullcmsgstr = cmsgstr;
775
776         // FLOOD CONTROL
777         flood = 0;
778         flood_field = floodcontrol_chat;
779         if(floodcontrol)
780         {
781                 float flood_spl;
782                 float flood_burst;
783                 float flood_lmax;
784                 float lines;
785                 if(privatesay)
786                 {
787                         flood_spl = autocvar_g_chat_flood_spl_tell;
788                         flood_burst = autocvar_g_chat_flood_burst_tell;
789                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
790                         flood_field = floodcontrol_chattell;
791                 }
792                 else if(teamsay)
793                 {
794                         flood_spl = autocvar_g_chat_flood_spl_team;
795                         flood_burst = autocvar_g_chat_flood_burst_team;
796                         flood_lmax = autocvar_g_chat_flood_lmax_team;
797                         flood_field = floodcontrol_chatteam;
798                 }
799                 else
800                 {
801                         flood_spl = autocvar_g_chat_flood_spl;
802                         flood_burst = autocvar_g_chat_flood_burst;
803                         flood_lmax = autocvar_g_chat_flood_lmax;
804                         flood_field = floodcontrol_chat;
805                 }
806                 flood_burst = max(0, flood_burst - 1);
807                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
808
809                 // do flood control for the default line size
810                 if(msgstr != "")
811                 {
812                         getWrappedLine_remaining = msgstr;
813                         msgstr = "";
814                         lines = 0;
815                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
816                         {
817                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
818                                 ++lines;
819                         }
820                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
821
822                         if(getWrappedLine_remaining != "")
823                         {
824                                 msgstr = strcat(msgstr, "\n");
825                                 flood = 2;
826                         }
827
828                         if(time >= source.flood_field)
829                         {
830                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
831                         }
832                         else
833                         {
834                                 flood = 1;
835                                 msgstr = fullmsgstr;
836                         }
837                 }
838                 else
839                 {
840                         if(time >= source.flood_field)
841                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
842                         else
843                                 flood = 1;
844                 }
845
846                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
847                         source.flood_field = flood = 0;
848         }
849
850         if(flood == 2) // cannot happen for empty msgstr
851         {
852                 if(autocvar_g_chat_flood_notify_flooder)
853                 {
854                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
855                         sourcecmsgstr = "";
856                 }
857                 else
858                 {
859                         sourcemsgstr = fullmsgstr;
860                         sourcecmsgstr = fullcmsgstr;
861                 }
862                 cmsgstr = "";
863         }
864         else
865         {
866                 sourcemsgstr = msgstr;
867                 sourcecmsgstr = cmsgstr;
868         }
869
870         if(!privatesay)
871         if(source.classname != "player")
872         {
873                 if not(intermission_running)
874                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
875                                 teamsay = -1; // spectators
876         }
877
878         if(flood)
879                 print("NOTE: ", playername(source), "^7 is flooding.\n");
880
881         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
882         if(privatesay)
883                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
884
885         if(source.muted)
886         {
887                 // always fake the message
888                 ret = -1;
889         }
890         else if(flood == 1)
891         {
892                 if(autocvar_g_chat_flood_notify_flooder)
893                 {
894                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
895                         ret = 0;
896                 }
897                 else
898                         ret = -1;
899         }
900         else
901         {
902                 ret = 1;
903         }
904
905         if(sourcemsgstr != "" && ret != 0)
906         {
907                 if(ret < 0) // faked message, because the player is muted
908                 {
909                         sprint(source, sourcemsgstr);
910                         if(sourcecmsgstr != "" && !privatesay)
911                                 centerprint(source, sourcecmsgstr);
912                 }
913                 else if(privatesay) // private message, between 2 people only
914                 {
915                         sprint(source, sourcemsgstr);
916                         sprint(privatesay, msgstr);
917                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
918                         if(cmsgstr != "")
919                                 centerprint(privatesay, cmsgstr);
920                 }
921                 else if(teamsay > 0) // team message, only sent to team mates
922                 {
923                         sprint(source, sourcemsgstr);
924                         dedicated_print(msgstr); // send to server console too
925                         if(sourcecmsgstr != "")
926                                 centerprint(source, sourcecmsgstr);
927                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
928                                 if(head != source)
929                                 {
930                                         sprint(head, msgstr);
931                                         if(cmsgstr != "")
932                                                 centerprint(head, cmsgstr);
933                                 }
934                 }
935                 else if(teamsay < 0) // spectator message, only sent to spectators
936                 {
937                         sprint(source, sourcemsgstr);
938                         dedicated_print(msgstr); // send to server console too
939                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
940                                 if(head != source)
941                                         sprint(head, msgstr);
942                 }
943                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
944                 {
945                         sprint(source, sourcemsgstr);
946                         dedicated_print(msgstr); // send to server console too
947                         FOR_EACH_REALCLIENT(head)
948                                 if(head != source)
949                                         sprint(head, msgstr);
950                 }
951                 else
952                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
953         }
954
955         return ret;
956 }
957
958 float GetVoiceMessageVoiceType(string type)
959 {
960         if(type == "taunt")
961                 return VOICETYPE_TAUNT;
962         if(type == "teamshoot")
963                 return VOICETYPE_LASTATTACKER;
964         return VOICETYPE_TEAMRADIO;
965 }
966
967 string allvoicesamples;
968 .string GetVoiceMessageSampleField(string type)
969 {
970         GetPlayerSoundSampleField_notFound = 0;
971         switch(type)
972         {
973 #define _VOICEMSG(m) case #m: return playersound_##m;
974                 ALLVOICEMSGS
975 #undef _VOICEMSG
976         }
977         GetPlayerSoundSampleField_notFound = 1;
978         return playersound_taunt;
979 }
980
981 .string GetPlayerSoundSampleField(string type)
982 {
983         GetPlayerSoundSampleField_notFound = 0;
984         switch(type)
985         {
986 #define _VOICEMSG(m) case #m: return playersound_##m;
987                 ALLPLAYERSOUNDS
988 #undef _VOICEMSG
989         }
990         GetPlayerSoundSampleField_notFound = 1;
991         return playersound_taunt;
992 }
993
994 void PrecacheGlobalSound(string samplestring)
995 {
996         float n, i;
997         tokenize_console(samplestring);
998         n = stof(argv(1));
999         if(n > 0)
1000         {
1001                 for(i = 1; i <= n; ++i)
1002                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1003         }
1004         else
1005         {
1006                 precache_sound(strcat(argv(0), ".wav"));
1007         }
1008 }
1009
1010 void PrecachePlayerSounds(string f)
1011 {
1012         float fh;
1013         string s;
1014         fh = fopen(f, FILE_READ);
1015         if(fh < 0)
1016                 return;
1017         while((s = fgets(fh)))
1018         {
1019                 if(tokenize_console(s) != 3)
1020                 {
1021                         dprint("Invalid sound info line: ", s, "\n");
1022                         continue;
1023                 }
1024                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1025         }
1026         fclose(fh);
1027
1028         if not(allvoicesamples)
1029         {
1030 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1031                 ALLVOICEMSGS
1032 #undef _VOICEMSG
1033                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1034         }
1035 }
1036
1037 void ClearPlayerSounds()
1038 {
1039 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1040         ALLPLAYERSOUNDS
1041         ALLVOICEMSGS
1042 #undef _VOICEMSG
1043 }
1044
1045 float LoadPlayerSounds(string f, float first)
1046 {
1047         float fh;
1048         string s;
1049         var .string field;
1050         fh = fopen(f, FILE_READ);
1051         if(fh < 0)
1052         {
1053                 dprint("Player sound file not found: ", f, "\n");
1054                 return 0;
1055         }
1056         while((s = fgets(fh)))
1057         {
1058                 if(tokenize_console(s) != 3)
1059                         continue;
1060                 field = GetPlayerSoundSampleField(argv(0));
1061                 if(GetPlayerSoundSampleField_notFound)
1062                         field = GetVoiceMessageSampleField(argv(0));
1063                 if(GetPlayerSoundSampleField_notFound)
1064                         continue;
1065                 if(self.field)
1066                         strunzone(self.field);
1067                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1068         }
1069         fclose(fh);
1070         return 1;
1071 }
1072
1073 .float modelindex_for_playersound;
1074 .float skin_for_playersound;
1075 void UpdatePlayerSounds()
1076 {
1077         if(self.modelindex == self.modelindex_for_playersound)
1078         if(self.skin == self.skin_for_playersound)
1079                 return;
1080         self.modelindex_for_playersound = self.modelindex;
1081         self.skin_for_playersound = self.skin;
1082         ClearPlayerSounds();
1083         LoadPlayerSounds("sound/player/default.sounds", 1);
1084         if(!autocvar_g_debug_defaultsounds)
1085                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1086                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1087 }
1088
1089 void FakeGlobalSound(string sample, float chan, float voicetype)
1090 {
1091         float n;
1092         float tauntrand;
1093
1094         if(sample == "")
1095                 return;
1096
1097         tokenize_console(sample);
1098         n = stof(argv(1));
1099         if(n > 0)
1100                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1101         else
1102                 sample = strcat(argv(0), ".wav"); // randomization
1103
1104         switch(voicetype)
1105         {
1106                 case VOICETYPE_LASTATTACKER_ONLY:
1107                         break;
1108                 case VOICETYPE_LASTATTACKER:
1109                         if(self.pusher)
1110                         {
1111                                 msg_entity = self;
1112                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1113                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1114                         }
1115                         break;
1116                 case VOICETYPE_TEAMRADIO:
1117                         msg_entity = self;
1118                         if(msg_entity.cvar_cl_voice_directional == 1)
1119                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1120                         else
1121                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1122                         break;
1123                 case VOICETYPE_AUTOTAUNT:
1124                         if(!sv_autotaunt)
1125                                 break;
1126                         if(!sv_taunt)
1127                                 break;
1128                         if(autocvar_sv_gentle)
1129                                 break;
1130                         tauntrand = random();
1131                         msg_entity = self;
1132                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1133                         {
1134                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1135                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1136                                 else
1137                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1138                         }
1139                         break;
1140                 case VOICETYPE_TAUNT:
1141                         if(self.classname == "player")
1142                                 if(self.deadflag == DEAD_NO)
1143                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1144                         if(!sv_taunt)
1145                                 break;
1146                         if(autocvar_sv_gentle)
1147                                 break;
1148                         msg_entity = self;
1149                         if (msg_entity.cvar_cl_voice_directional >= 1)
1150                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1151                         else
1152                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1153                         break;
1154                 case VOICETYPE_PLAYERSOUND:
1155                         msg_entity = self;
1156                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1157                         break;
1158                 default:
1159                         backtrace("Invalid voice type!");
1160                         break;
1161         }
1162 }
1163
1164 void GlobalSound(string sample, float chan, float voicetype)
1165 {
1166         float n;
1167         float tauntrand;
1168
1169         if(sample == "")
1170                 return;
1171
1172         tokenize_console(sample);
1173         n = stof(argv(1));
1174         if(n > 0)
1175                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1176         else
1177                 sample = strcat(argv(0), ".wav"); // randomization
1178
1179         switch(voicetype)
1180         {
1181                 case VOICETYPE_LASTATTACKER_ONLY:
1182                         if(self.pusher)
1183                         {
1184                                 msg_entity = self.pusher;
1185                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1186                                 {
1187                                         if(msg_entity.cvar_cl_voice_directional == 1)
1188                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1189                                         else
1190                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1191                                 }
1192                         }
1193                         break;
1194                 case VOICETYPE_LASTATTACKER:
1195                         if(self.pusher)
1196                         {
1197                                 msg_entity = self.pusher;
1198                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1199                                 {
1200                                         if(msg_entity.cvar_cl_voice_directional == 1)
1201                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1202                                         else
1203                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1204                                 }
1205                                 msg_entity = self;
1206                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1207                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1208                         }
1209                         break;
1210                 case VOICETYPE_TEAMRADIO:
1211                         FOR_EACH_REALCLIENT(msg_entity)
1212                                 if(!teamplay || msg_entity.team == self.team)
1213                                 {
1214                                         if(msg_entity.cvar_cl_voice_directional == 1)
1215                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1216                                         else
1217                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1218                                 }
1219                         break;
1220                 case VOICETYPE_AUTOTAUNT:
1221                         if(!sv_autotaunt)
1222                                 break;
1223                         if(!sv_taunt)
1224                                 break;
1225                         if(autocvar_sv_gentle)
1226                                 break;
1227                         tauntrand = random();
1228                         FOR_EACH_REALCLIENT(msg_entity)
1229                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1230                                 {
1231                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1232                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1233                                         else
1234                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1235                                 }
1236                         break;
1237                 case VOICETYPE_TAUNT:
1238                         if(self.classname == "player")
1239                                 if(self.deadflag == DEAD_NO)
1240                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1241                         if(!sv_taunt)
1242                                 break;
1243                         if(autocvar_sv_gentle)
1244                                 break;
1245                         FOR_EACH_REALCLIENT(msg_entity)
1246                         {
1247                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1248                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1249                                 else
1250                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1251                         }
1252                         break;
1253                 case VOICETYPE_PLAYERSOUND:
1254                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1255                         break;
1256                 default:
1257                         backtrace("Invalid voice type!");
1258                         break;
1259         }
1260 }
1261
1262 void PlayerSound(.string samplefield, float chan, float voicetype)
1263 {
1264         GlobalSound(self.samplefield, chan, voicetype);
1265 }
1266
1267 void VoiceMessage(string type, string msg)
1268 {
1269         var .string sample;
1270         float voicetype, ownteam;
1271         float flood;
1272         sample = GetVoiceMessageSampleField(type);
1273
1274         if(GetPlayerSoundSampleField_notFound)
1275         {
1276                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1277                 return;
1278         }
1279
1280         voicetype = GetVoiceMessageVoiceType(type);
1281         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1282
1283         flood = Say(self, ownteam, world, msg, 1);
1284
1285         if (flood > 0)
1286                 GlobalSound(self.sample, CH_VOICE, voicetype);
1287         else if (flood < 0)
1288                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1289 }
1290
1291 void MoveToTeam(entity client, float team_colour, float type)
1292 {
1293         float lockteams_backup;
1294
1295         lockteams_backup = lockteams;  // backup any team lock
1296
1297         lockteams = 0;  // disable locked teams
1298
1299         TeamchangeFrags(client);  // move the players frags
1300         SetPlayerColors(client, team_colour - 1);  // set the players colour
1301         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1302
1303         lockteams = lockteams_backup;  // restore the team lock
1304
1305         LogTeamchange(client.playerid, client.team, type);
1306 }